test/recipes/70-test_sslsessiontick.t

   1 #! /usr/bin/env perl
   2 # Copyright 2015-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9 use strict;
  10 use OpenSSL::Test qw/:DEFAULT cmdstr srctop_file bldtop_dir/;
  11 use OpenSSL::Test::Utils;
  12 use TLSProxy::Proxy;
  13 use File::Temp qw(tempfile);
  14
  15 my $test_name = "test_sslsessiontick";
  16 setup($test_name);
  17
  18 plan skip_all => "TLSProxy isn't usable on $^O"
  19     if $^O =~ /^(VMS|MSWin32)$/;
  20
  21 plan skip_all => "$test_name needs the dynamic engine feature enabled"
  22     if disabled("engine") || disabled("dynamic-engine");
  23
  24 plan skip_all => "$test_name needs the sock feature enabled"
  25     if disabled("sock");
  26
  27 plan skip_all => "$test_name needs TLS enabled"
  28     if alldisabled(available_protocols("tls"));
  29
  30 $ENV{OPENSSL_ia32cap} = '~0x200000200000000';
  31
  32 sub checkmessages($$$$$$);
  33 sub clearclient();
  34 sub clearall();
  35
  36 my $chellotickext = 0;
  37 my $shellotickext = 0;
  38 my $fullhand = 0;
  39 my $ticketseen = 0;
  40
  41 my $proxy = TLSProxy::Proxy->new(
  42     undef,
  43     cmdstr(app(["openssl"]), display => 1),
  44     srctop_file("apps", "server.pem"),
  45     (!$ENV{HARNESS_ACTIVE} || $ENV{HARNESS_VERBOSE})
  46 );
  47
  48 plan tests => 10;
  49
  50 #Test 1: By default with no existing session we should get a session ticket
  51 #Expected result: ClientHello extension seen; ServerHello extension seen
  52 #                 NewSessionTicket message seen; Full handshake
  53 $proxy->start();
  54 checkmessages(1, "Default session ticket test", 1, 1, 1, 1);
  55
  56 #Test 2: If the server does not accept tickets we should get a normal handshake
  57 #with no session tickets
  58 #Expected result: ClientHello extension seen; ServerHello extension not seen
  59 #                 NewSessionTicket message not seen; Full handshake
  60 clearall();
  61 $proxy->serverflags("-no_ticket");
  62 $proxy->start();
  63 checkmessages(2, "No server support session ticket test", 1, 0, 0, 1);
  64
  65 #Test 3: If the client does not accept tickets we should get a normal handshake
  66 #with no session tickets
  67 #Expected result: ClientHello extension not seen; ServerHello extension not seen
  68 #                 NewSessionTicket message not seen; Full handshake
  69 clearall();
  70 $proxy->clientflags("-no_ticket");
  71 $proxy->start();
  72 checkmessages(3, "No client support session ticket test", 0, 0, 0, 1);
  73
  74 #Test 4: Test session resumption with session ticket
  75 #Expected result: ClientHello extension seen; ServerHello extension not seen
  76 #                 NewSessionTicket message not seen; Abbreviated handshake
  77 clearall();
  78 (my $fh, my $session) = tempfile();
  79 $proxy->serverconnects(2);
  80 $proxy->clientflags("-sess_out ".$session);
  81 $proxy->start();
  82 $proxy->clearClient();
  83 $proxy->clientflags("-sess_in ".$session);
  84 $proxy->clientstart();
  85 checkmessages(4, "Session resumption session ticket test", 1, 0, 0, 0);
  86
  87 #Test 5: Test session resumption with ticket capable client without a ticket
  88 #Expected result: ClientHello extension seen; ServerHello extension seen
  89 #                 NewSessionTicket message seen; Abbreviated handshake
  90 clearall();
  91 ($fh, $session) = tempfile();
  92 $proxy->serverconnects(2);
  93 $proxy->clientflags("-sess_out ".$session." -no_ticket");
  94 $proxy->start();
  95 $proxy->clearClient();
  96 $proxy->clientflags("-sess_in ".$session);
  97 $proxy->clientstart();
  98 checkmessages(5, "Session resumption with ticket capable client without a "
  99                  ."ticket", 1, 1, 1, 0);
 100
 101 #Test 6: Client accepts empty ticket.
 102 #Expected result: ClientHello extension seen; ServerHello extension seen;
 103 #                 NewSessionTicket message seen; Full handshake.
 104 clearall();
 105 $proxy->filter(\&ticket_filter);
 106 $proxy->start();
 107 checkmessages(6, "Empty ticket test",  1, 1, 1, 1);
 108
 109 #Test 7-8: Client keeps existing ticket on empty ticket.
 110 clearall();
 111 ($fh, $session) = tempfile();
 112 $proxy->serverconnects(3);
 113 $proxy->filter(undef);
 114 $proxy->clientflags("-sess_out ".$session);
 115 $proxy->start();
 116 $proxy->clearClient();
 117 $proxy->clientflags("-sess_in ".$session." -sess_out ".$session);
 118 $proxy->filter(\&inject_empty_ticket_filter);
 119 $proxy->clientstart();
 120 #Expected result: ClientHello extension seen; ServerHello extension seen;
 121 #                 NewSessionTicket message seen; Abbreviated handshake.
 122 checkmessages(7, "Empty ticket resumption test",  1, 1, 1, 0);
 123 clearclient();
 124 $proxy->clientflags("-sess_in ".$session);
 125 $proxy->filter(undef);
 126 $proxy->clientstart();
 127 #Expected result: ClientHello extension seen; ServerHello extension not seen;
 128 #                 NewSessionTicket message not seen; Abbreviated handshake.
 129 checkmessages(8, "Empty ticket resumption test",  1, 0, 0, 0);
 130
 131 #Test 9: Bad server sends the ServerHello extension but does not send a
 132 #NewSessionTicket
 133 #Expected result: Connection failure
 134 clearall();
 135 $proxy->serverflags("-no_ticket");
 136 $proxy->filter(\&inject_ticket_extension_filter);
 137 $proxy->start();
 138 ok(TLSProxy::Message->fail, "Server sends ticket extension but no ticket test");
 139
 140 #Test10: Bad server does not send the ServerHello extension but does send a
 141 #NewSessionTicket
 142 #Expected result: Connection failure
 143 clearall();
 144 $proxy->serverflags("-no_ticket");
 145 $proxy->filter(\&inject_empty_ticket_filter);
 146 $proxy->start();
 147 ok(TLSProxy::Message->fail, "No server ticket extension but ticket sent test");
 148
 149 sub ticket_filter
 150 {
 151     my $proxy = shift;
 152
 153     foreach my $message (@{$proxy->message_list}) {
 154         if ($message->mt == TLSProxy::Message::MT_NEW_SESSION_TICKET) {
 155             $message->ticket("");
 156             $message->repack();
 157         }
 158     }
 159 }
 160
 161 sub inject_empty_ticket_filter {
 162     my $proxy = shift;
 163
 164     foreach my $message (@{$proxy->message_list}) {
 165         if ($message->mt == TLSProxy::Message::MT_NEW_SESSION_TICKET) {
 166             # Only inject the message first time we're called.
 167             return;
 168         }
 169     }
 170
 171     my @new_message_list = ();
 172     foreach my $message (@{$proxy->message_list}) {
 173         push @new_message_list, $message;
 174         if ($message->mt == TLSProxy::Message::MT_SERVER_HELLO) {
 175             $message->set_extension(TLSProxy::Message::EXT_SESSION_TICKET, "");
 176             $message->repack();
 177             # Tack NewSessionTicket onto the ServerHello record.
 178             # This only works if the ServerHello is exactly one record.
 179             my $record = ${$message->records}[0];
 180
 181             my $offset = $message->startoffset + $message->encoded_length;
 182             my $newsessionticket = TLSProxy::NewSessionTicket->new(
 183                 1, "", [$record], $offset, []);
 184             $newsessionticket->repack();
 185             push @new_message_list, $newsessionticket;
 186         }
 187     }
 188     $proxy->message_list([@new_message_list]);
 189 }
 190
 191 sub inject_ticket_extension_filter
 192 {
 193     my $proxy = shift;
 194
 195     # We're only interested in the initial ServerHello
 196     if ($proxy->flight != 1) {
 197         return;
 198     }
 199
 200     foreach my $message (@{$proxy->message_list}) {
 201         if ($message->mt == TLSProxy::Message::MT_SERVER_HELLO) {
 202             #Add the session ticket extension to the ServerHello even though
 203             #we are not going to send a NewSessionTicket message
 204             $message->set_extension(TLSProxy::Message::EXT_SESSION_TICKET, "");
 205
 206             $message->repack();
 207         }
 208     }
 209 }
 210
 211 sub checkmessages($$$$$$)
 212 {
 213     my ($testno, $testname, $testch, $testsh, $testtickseen, $testhand) = @_;
 214
 215     subtest $testname => sub {
 216
 217         foreach my $message (@{$proxy->message_list}) {
 218             if ($message->mt == TLSProxy::Message::MT_CLIENT_HELLO
 219                 || $message->mt == TLSProxy::Message::MT_SERVER_HELLO) {
 220                 #Get the extensions data
 221                 my %extensions = %{$message->extension_data};
 222                 if (defined
 223                     $extensions{TLSProxy::Message::EXT_SESSION_TICKET}) {
 224                     if ($message->mt == TLSProxy::Message::MT_CLIENT_HELLO) {
 225                         $chellotickext = 1;
 226                     } else {
 227                         $shellotickext = 1;
 228                     }
 229                 }
 230             } elsif ($message->mt == TLSProxy::Message::MT_CLIENT_KEY_EXCHANGE) {
 231                 #Must be doing a full handshake
 232                 $fullhand = 1;
 233             } elsif ($message->mt == TLSProxy::Message::MT_NEW_SESSION_TICKET) {
 234                 $ticketseen = 1;
 235             }
 236         }
 237
 238         plan tests => 5;
 239
 240         ok(TLSProxy::Message->success, "Handshake");
 241         ok(($testch && $chellotickext) || (!$testch && !$chellotickext),
 242            "ClientHello extension Session Ticket check");
 243         ok(($testsh && $shellotickext) || (!$testsh && !$shellotickext),
 244            "ServerHello extension Session Ticket check");
 245         ok(($testtickseen && $ticketseen) || (!$testtickseen && !$ticketseen),
 246            "Session Ticket message presence check");
 247         ok(($testhand && $fullhand) || (!$testhand && !$fullhand),
 248            "Session Ticket full handshake check");
 249     }
 250 }
 251
 252
 253 sub clearclient()
 254 {
 255     $chellotickext = 0;
 256     $shellotickext = 0;
 257     $fullhand = 0;
 258     $ticketseen = 0;
 259     $proxy->clearClient();
 260 }
 261
 262 sub clearall()
 263 {
 264     clearclient();
 265     $proxy->clear();
 266 }