util/find-doc-nits

   1 #! /usr/bin/env perl
   2 # Copyright 2002-2020 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the Apache License 2.0 (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9
  10 require 5.10.0;
  11 use warnings;
  12 use strict;
  13
  14 use Carp qw(:DEFAULT cluck);
  15 use Pod::Checker;
  16 use File::Find;
  17 use File::Basename;
  18 use File::Spec::Functions;
  19 use Getopt::Std;
  20 use FindBin;
  21 use lib "$FindBin::Bin/perl";
  22
  23 use OpenSSL::Util::Pod;
  24
  25 use lib '.';
  26 use configdata;
  27
  28 # Set to 1 for debug output
  29 my $debug = 0;
  30
  31 # Where to find openssl command
  32 my $openssl = "./util/opensslwrap.sh";
  33
  34 # Options.
  35 our($opt_d);
  36 our($opt_e);
  37 our($opt_s);
  38 our($opt_o);
  39 our($opt_h);
  40 our($opt_l);
  41 our($opt_n);
  42 our($opt_p);
  43 our($opt_u);
  44 our($opt_v);
  45 our($opt_c);
  46
  47 # Print usage message and exit.
  48 sub help {
  49     print <<EOF;
  50 Find small errors (nits) in documentation.  Options:
  51     -c List undocumented commands and options
  52     -d Detailed list of undocumented (implies -u)
  53     -e Detailed list of new undocumented (implies -v)
  54     -h Print this help message
  55     -l Print bogus links
  56     -n Print nits in POD pages
  57     -o Causes -e/-v to count symbols added since 1.1.1 as new (implies -v)
  58     -u Count undocumented functions
  59     -v Count new undocumented functions
  60 EOF
  61     exit;
  62 }
  63
  64 getopts('cdehlnouv');
  65
  66 help() if $opt_h;
  67 $opt_u = 1 if $opt_d;
  68 $opt_v = 1 if $opt_o || $opt_e;
  69 die "Cannot use both -u and -v"
  70     if $opt_u && $opt_v;
  71 die "Cannot use both -d and -e"
  72     if $opt_d && $opt_e;
  73
  74 # We only need to check c, l, n, u and v.
  75 # Options d, e, o imply one of the above.
  76 die "Need one of -[cdehlnouv] flags.\n"
  77     unless $opt_c or $opt_l or $opt_n or $opt_u or $opt_v;
  78
  79
  80 my $temp = '/tmp/docnits.txt';
  81 my $OUT;
  82 my $status = 0;
  83
  84 my @sections = ( 'man1', 'man3', 'man5', 'man7' );
  85 my %mandatory_sections = (
  86     '*' => [ 'NAME', 'DESCRIPTION', 'COPYRIGHT' ],
  87     1   => [ 'SYNOPSIS', 'OPTIONS' ],
  88     3   => [ 'SYNOPSIS', 'RETURN VALUES' ],
  89     5   => [ ],
  90     7   => [ ]
  91                          );
  92
  93 # Symbols that we ignored.
  94 # They are internal macros that we currently don't document
  95 my $ignored = qr/(?| ^i2d_
  96                  |   ^d2i_
  97                  |   ^DEPRECATEDIN
  98                  |   \Q_fnsig(3)\E$
  99                  |   ^IMPLEMENT_
 100                  |   ^_?DECLARE_
 101                  )/x;
 102
 103 # Collect all POD files, both internal and public, and regardless of location
 104 # We collect them in a hash table with each file being a key, so we can attach
 105 # tags to them.  For example, internal docs will have the word "internal"
 106 # attached to them.
 107 my %files = ();
 108 # We collect files names on the fly, on known tag basis
 109 my %collected_tags = ();
 110 # We cache results based on tags
 111 my %collected_results = ();
 112
 113 # files OPTIONS
 114 #
 115 # Example:
 116 #
 117 #       files(TAGS => 'manual');
 118 #       files(TAGS => [ 'manual', 'man1' ]);
 119 #
 120 # This function returns an array of files corresponding to a set of tags
 121 # given with the options "TAGS".  The value of this option can be a single
 122 # word, or an array of several words, which work as inclusive or exclusive
 123 # selectors.  Inclusive selectors are used to add one more set of files to
 124 # the returned array, while exclusive selectors limit the set of files added
 125 # to the array.  The recognised tag values are:
 126 #
 127 # 'public_manual'       - inclusive selector, adds public manuals to the
 128 #                         returned array of files.
 129 # 'internal_manual'     - inclusive selector, adds internal manuals to the
 130 #                         returned array of files.
 131 # 'manual'              - inclusive selector, adds any manual to the returned
 132 #                         array of files.  This is really a shorthand for
 133 #                         'public_manual' and 'internal_manual' combined.
 134 # 'public_header'       - inclusive selector, adds public headers to the
 135 #                         returned array of files.
 136 # 'header'              - inclusive selector, adds any header file to the
 137 #                         returned array of files.  Since we currently only
 138 #                         care about public headers, this is exactly
 139 #                         equivalent to 'public_header', but is present for
 140 #                         consistency.
 141 #
 142 # 'man1', 'man3', 'man5', 'man7'
 143 #                       - exclusive selectors, only applicable together with
 144 #                         any of the manual selectors.  If any of these are
 145 #                         present, only the manuals from the given sections
 146 #                         will be include.  If none of these are present,
 147 #                         the manuals from all sections will be returned.
 148 #
 149 # All returned manual files come from configdata.pm.
 150 # All returned header files come from looking inside
 151 # "$config{sourcedir}/include/openssl"
 152 #
 153 sub files {
 154     my %opts = ( @_ );          # Make a copy of the arguments
 155
 156     $opts{TAGS} = [ $opts{TAGS} ] if ref($opts{TAGS}) eq '';
 157
 158     croak "No tags given, or not an array"
 159         unless exists $opts{TAGS} && ref($opts{TAGS}) eq 'ARRAY';
 160
 161     my %tags = map { $_ => 1 } @{$opts{TAGS}};
 162     $tags{public_manual} = 1
 163         if $tags{manual} && ($tags{public} // !$tags{internal});
 164     $tags{internal_manual} = 1
 165         if $tags{manual} && ($tags{internal} // !$tags{public});
 166     $tags{public_header} = 1
 167         if $tags{header} && ($tags{public} // !$tags{internal});
 168     delete $tags{manual};
 169     delete $tags{header};
 170     delete $tags{public};
 171     delete $tags{internal};
 172
 173     my $tags_as_key = join(':', sort keys %tags);
 174
 175     cluck  "DEBUG[files]: This is how we got here!" if $debug;
 176     print STDERR "DEBUG[files]: tags: $tags_as_key\n" if $debug;
 177
 178     my %tags_to_collect = ( map { $_ => 1 }
 179                             grep { !exists $collected_tags{$_} }
 180                             keys %tags );
 181
 182     if ($tags_to_collect{public_manual}) {
 183         print STDERR "DEBUG[files]: collecting public manuals\n"
 184             if $debug;
 185
 186         # The structure in configdata.pm is that $unified_info{mandocs}
 187         # contains lists of man files, and in turn, $unified_info{depends}
 188         # contains hash tables showing which POD file each of those man
 189         # files depend on.  We use that information to find the POD files,
 190         # and to attach the man section they belong to as tags
 191         foreach my $mansect ( @sections ) {
 192             foreach ( map { @{$unified_info{depends}->{$_}} }
 193                       @{$unified_info{mandocs}->{$mansect}} ) {
 194                 $files{$_} = { $mansect => 1, public_manual => 1 };
 195             }
 196         }
 197         $collected_tags{public_manual} = 1;
 198     }
 199
 200     if ($tags_to_collect{internal_manual}) {
 201         print STDERR "DEBUG[files]: collecting internal manuals\n"
 202             if $debug;
 203
 204         # We don't have the internal docs in configdata.pm.  However, they
 205         # are all in the source tree, so they're easy to find.
 206         foreach my $mansect ( @sections ) {
 207             foreach ( glob(catfile($config{sourcedir},
 208                                    'doc', 'internal', $mansect, '*.pod')) ) {
 209                 $files{$_} = { $mansect => 1, internal_manual => 1 };
 210             }
 211         }
 212         $collected_tags{internal_manual} = 1;
 213     }
 214
 215     if ($tags_to_collect{public_header}) {
 216         print STDERR "DEBUG[files]: collecting public headers\n"
 217             if $debug;
 218
 219         foreach ( glob(catfile($config{sourcedir},
 220                                'include', 'openssl', '*.h')) ) {
 221             $files{$_} = { public_header => 1 };
 222         }
 223     }
 224
 225     my @result = @{$collected_results{$tags_as_key} // []};
 226
 227     if (!@result) {
 228         # Produce a result based on caller tags
 229         foreach my $type ( ( 'public_manual', 'internal_manual' ) ) {
 230             next unless $tags{$type};
 231
 232             # If caller asked for specific sections, we care about sections.
 233             # Otherwise, we give back all of them.
 234             my @selected_sections =
 235                 grep { $tags{$_} } @sections;
 236             @selected_sections = @sections unless @selected_sections;
 237
 238             foreach my $section ( ( @selected_sections ) ) {
 239                 push @result,
 240                     ( sort { basename($a) cmp basename($b) }
 241                       grep { $files{$_}->{$type} && $files{$_}->{$section} }
 242                       keys %files );
 243             }
 244         }
 245         if ($tags{public_header}) {
 246             push @result,
 247                 ( sort { basename($a) cmp basename($b) }
 248                   grep { $files{$_}->{public_header} }
 249                   keys %files );
 250         }
 251
 252         if ($debug) {
 253             print STDERR "DEBUG[files]: result:\n";
 254             print STDERR "DEBUG[files]:     $_\n" foreach @result;
 255         }
 256         $collected_results{$tags_as_key} = [ @result ];
 257     }
 258
 259     return @result;
 260 }
 261
 262 # Print error message, set $status.
 263 sub err {
 264     print join(" ", @_), "\n";
 265     $status = 1
 266 }
 267
 268 # Cross-check functions in the NAME and SYNOPSIS section.
 269 sub name_synopsis {
 270     my $id = shift;
 271     my $filename = shift;
 272     my $contents = shift;
 273
 274     # Get NAME section and all words in it.
 275     return unless $contents =~ /=head1 NAME(.*)=head1 SYNOPSIS/ms;
 276     my $tmp = $1;
 277     $tmp =~ tr/\n/ /;
 278     err($id, "Trailing comma before - in NAME")
 279         if $tmp =~ /, *-/;
 280     $tmp =~ s/ -.*//g;
 281     err($id, "POD markup among the names in NAME")
 282         if $tmp =~ /[<>]/;
 283     $tmp =~ s/  */ /g;
 284     err($id, "Missing comma in NAME")
 285         if $tmp =~ /[^,] /;
 286
 287     my $dirname = dirname($filename);
 288     my $section = basename($dirname);
 289     my $simplename = basename($filename, ".pod");
 290     my $foundfilename = 0;
 291     my %foundfilenames = ();
 292     my %names;
 293     foreach my $n ( split ',', $tmp ) {
 294         $n =~ s/^\s+//;
 295         $n =~ s/\s+$//;
 296         err($id, "The name '$n' contains white-space")
 297             if $n =~ /\s/;
 298         $names{$n} = 1;
 299         $foundfilename++ if $n eq $simplename;
 300         $foundfilenames{$n} = 1
 301             if ( ( grep { basename($_) eq "$n.pod" }
 302                    files(TAGS => [ 'manual', $section ]) )
 303                  && $n ne $simplename );
 304     }
 305     err($id, "The following exist as other .pod files:",
 306          sort keys %foundfilenames)
 307         if %foundfilenames;
 308     err($id, "$simplename (filename) missing from NAME section")
 309         unless $foundfilename;
 310
 311     # Find all functions in SYNOPSIS
 312     return unless $contents =~ /=head1 SYNOPSIS(.*)=head1 DESCRIPTION/ms;
 313     my $syn = $1;
 314     my $ignore_until = undef;   # If defined, this is a regexp
 315     # Remove all non-code lines
 316     $syn =~ s/^(?:\s*?|\S.*?)$//msg;
 317     # Remove all comments
 318     $syn =~ s/\/\*.*?\*\///msg;
 319     while ( $syn ) {
 320         # "env" lines end at a newline.
 321         # Preprocessor lines start with a # and end at a newline.
 322         # Other lines end with a semicolon, and may cover more than
 323         # one physical line.
 324         if ( $syn !~ /^ \s*(env .*?|#.*?|.*?;)\s*$/ms ) {
 325             err($id, "Can't parse rest of synopsis:\n$syn\n(declarations not ending with a semicolon (;)?)");
 326             last;
 327         }
 328         my $line = $1;
 329         $syn = $';
 330
 331         print STDERR "DEBUG[name_synopsis] \$line = '$line'\n" if $debug;
 332
 333         # Special code to skip over documented structures
 334         if ( defined $ignore_until) {
 335             next if $line !~ /$ignore_until/;
 336             $ignore_until = undef;
 337             next;
 338         }
 339         if ( $line =~ /^\s*(?:typedef\s+)?struct(?:\s+\S+)\s*\{/ ) {
 340             $ignore_until = qr/\}.*?;/;
 341             next;
 342         }
 343
 344         my $sym;
 345         my $is_prototype = 1;
 346         $line =~ s/STACK_OF\([^)]+\)/int/g;
 347         $line =~ s/SPARSE_ARRAY_OF\([^)]+\)/int/g;
 348         $line =~ s/__declspec\([^)]+\)//;
 349
 350         ## We don't prohibit that space, to allow typedefs looking like
 351         ## this:
 352         ##
 353         ## typedef int (fantastically_long_name_breaks_80char_limit)
 354         ##     (fantastically_long_name_breaks_80char_limit *something);
 355         ##
 356         #if ( $line =~ /typedef.*\(\*?\S+\)\s+\(/ ) {
 357         #    # a callback function with whitespace before the argument list:
 358         #    # typedef ... (*NAME) (...
 359         #    # typedef ... (NAME) (...
 360         #    err($id, "Function typedef has space before arg list: $line");
 361         #}
 362
 363         if ( $line =~ /env (\S*)=/ ) {
 364             # environment variable env NAME=...
 365             $sym = $1;
 366         } elsif ( $line =~ /typedef.*\(\*?(\S+)\)\s*\(/ ) {
 367             # a callback function pointer: typedef ... (*NAME)(...
 368             # a callback function signature: typedef ... (NAME)(...
 369             $sym = $1;
 370         } elsif ( $line =~ /typedef.* (\S+)\s*\(/ ) {
 371             # a callback function signature: typedef ... NAME(...
 372             $sym = $1;
 373         } elsif ( $line =~ /typedef.* (\S+);/ ) {
 374             # a simple typedef: typedef ... NAME;
 375             $is_prototype = 0;
 376             $sym = $1;
 377         } elsif ( $line =~ /enum (\S*) \{/ ) {
 378             # an enumeration: enum ... {
 379             $sym = $1;
 380         } elsif ( $line =~ /#\s*(?:define|undef) ([A-Za-z0-9_]+)/ ) {
 381             $is_prototype = 0;
 382             $sym = $1;
 383         } elsif ( $line =~ /^[^\(]*?\(\*([A-Za-z0-9_]+)\s*\(/ ) {
 384             # a function returning a function pointer: TYPE (*NAME(args))(args)
 385             $sym = $1;
 386         } elsif ( $line =~ /^[^\(]*?([A-Za-z0-9_]+)\s*\(/ ) {
 387             # a simple function declaration
 388             $sym = $1;
 389         }
 390         else {
 391             next;
 392         }
 393
 394         print STDERR "DEBUG[name_synopsis] \$sym = '$sym'\n" if $debug;
 395
 396         err($id, "$sym missing from NAME section")
 397             unless defined $names{$sym};
 398         $names{$sym} = 2;
 399
 400         # Do some sanity checks on the prototype.
 401         err($id, "Prototype missing spaces around commas: $line")
 402             if $is_prototype && $line =~ /[a-z0-9],[^\s]/;
 403     }
 404
 405     foreach my $n ( keys %names ) {
 406         next if $names{$n} == 2;
 407         err($id, "$n missing from SYNOPSIS")
 408     }
 409 }
 410
 411 # Check if SECTION ($3) is located before BEFORE ($4)
 412 sub check_section_location {
 413     my $id = shift;
 414     my $contents = shift;
 415     my $section = shift;
 416     my $before = shift;
 417
 418     return unless $contents =~ /=head1 $section/
 419         and $contents =~ /=head1 $before/;
 420     err($id, "$section should appear before $before section")
 421         if $contents =~ /=head1 $before.*=head1 $section/ms;
 422 }
 423
 424 # Check if a =head1 is duplicated, or a =headX is duplicated within a
 425 # =head1.  Treats =head2 =head3 as equivalent -- it doesn't reset the head3
 426 # sets if it finds a =head2 -- but that is good enough for now. Also check
 427 # for proper capitalization, trailing periods, etc.
 428 sub check_head_style {
 429     my $id = shift;
 430     my $contents = shift;
 431     my %head1;
 432     my %subheads;
 433
 434     foreach my $line ( split /\n+/, $contents ) {
 435         next unless $line =~ /^=head/;
 436         if ( $line =~ /head1/ ) {
 437             err($id, "Duplicate section $line")
 438                 if defined $head1{$line};
 439             $head1{$line} = 1;
 440             %subheads = ();
 441         } else {
 442             err($id, "Duplicate subsection $line")
 443                 if defined $subheads{$line};
 444             $subheads{$line} = 1;
 445         }
 446         err($id, "Period in =head")
 447             if $line =~ /\.[^\w]/ or $line =~ /\.$/;
 448         err($id, "not all uppercase in =head1")
 449             if $line =~ /head1.*[a-z]/;
 450         err($id, "All uppercase in subhead")
 451             if $line =~ /head[234][ A-Z0-9]+$/;
 452     }
 453 }
 454
 455 # Because we have options and symbols with extra markup, we need
 456 # to take that into account, so we need a regexp that extracts
 457 # markup chunks, including recursive markup.
 458 # please read up on /(?R)/ in perlre(1)
 459 # (note: order is important, (?R) needs to come before .)
 460 # (note: non-greedy is important, or something like 'B<foo> and B<bar>'
 461 # will be captured as one item)
 462 my $markup_re =
 463     qr/(                        # Capture group
 464            [BIL]<               # The start of what we recurse on
 465            (?:(?-1)|.)*?        # recurse the whole regexp (referring to
 466                                 # the last opened capture group, i.e. the
 467                                 # start of this regexp), or pick next
 468                                 # character.  Do NOT be greedy!
 469            >                    # The end of what we recurse on
 470        )/x;                     # (the x allows this sort of split up regexp)
 471
 472 # Options must start with a dash, followed by a letter, possibly
 473 # followed by letters, digits, dashes and underscores, and the last
 474 # character must be a letter or a digit.
 475 # We do also accept the single -? or -n, where n is a digit
 476 my $option_re =
 477     qr/(?:
 478             \?                  # Single question mark
 479             |
 480             \d                  # Single digit
 481             |
 482             -                   # Single dash (--)
 483             |
 484             [[:alpha:]](?:[-_[:alnum:]]*?[[:alnum:]])?
 485        )/x;
 486
 487 # Helper function to check if a given $thing is properly marked up
 488 # option.  It returns one of these values:
 489 #     undef         if it's not an option
 490 #     ""            if it's a malformed option
 491 #     $unwrapped    the option with the outermost B<> wrapping removed.
 492 sub normalise_option {
 493     my $id = shift;
 494     my $filename = shift;
 495     my $thing = shift;
 496
 497     my $unwrapped = $thing;
 498     my $unmarked = $thing;
 499
 500     # $unwrapped is the option with the outer B<> markup removed
 501     $unwrapped =~ s/^B<//;
 502     $unwrapped =~ s/>$//;
 503     # $unmarked is the option with *all* markup removed
 504     $unmarked =~ s/[BIL]<|>//msg;
 505
 506
 507     # If we found an option, check it, collect it
 508     if ( $unwrapped =~ /^\s*-/ ) {
 509         return $unwrapped       # return option with outer B<> removed
 510             if $unmarked =~ /^-${option_re}$/;
 511         return "";              # Malformed option
 512     }
 513     return undef;               # Something else
 514 }
 515
 516 # Checks of command option (man1) formatting.  The man1 checks are
 517 # restricted to the SYNOPSIS and OPTIONS sections, the rest is too
 518 # free form, we simply cannot be too strict there.
 519
 520 sub option_check {
 521     my $id = shift;
 522     my $filename = shift;
 523     my $contents = shift;
 524
 525     my $synopsis = ($contents =~ /=head1\s+SYNOPSIS(.*?)=head1/s, $1);
 526
 527     # Some pages have more than one OPTIONS section, let's make sure
 528     # to get them all
 529     my $options = '';
 530     while ( $contents =~ /=head1\s+[A-Z ]*?OPTIONS$(.*?)(?==head1)/msg ) {
 531         $options .= $1;
 532     }
 533
 534     # Look for options with no or incorrect markup
 535     while ( $synopsis =~
 536             /(?<![-<[:alnum:]])-(?:$markup_re|.)*(?![->[:alnum:]])/msg ) {
 537         err($id, "Malformed option [1] in SYNOPSIS: $&");
 538     }
 539
 540     while ( $synopsis =~ /$markup_re/msg ) {
 541         my $found = $&;
 542         print STDERR "$id:DEBUG[option_check] SYNOPSIS: found $found\n"
 543             if $debug;
 544         my $option_uw = normalise_option($id, $filename, $found);
 545         err($id, "Malformed option [2] in SYNOPSIS: $found")
 546             if defined $option_uw && $option_uw eq '';
 547     }
 548
 549     # In OPTIONS, we look for =item paragraphs.
 550     # (?=^\s*$) detects an empty line.
 551     while ( $options =~ /=item\s+(.*?)(?=^\s*$)/msg ) {
 552         my $item = $&;
 553
 554         while ( $item =~ /(\[\s*)?($markup_re)/msg ) {
 555             my $found = $2;
 556             print STDERR "$id:DEBUG[option_check] OPTIONS: found $&\n"
 557                 if $debug;
 558             err($id, "Unexpected bracket in OPTIONS =item: $item")
 559                 if ($1 // '') ne '' && $found =~ /^B<\s*-/;
 560
 561             my $option_uw = normalise_option($id, $filename, $found);
 562             err($id, "Malformed option in OPTIONS: $found")
 563                 if defined $option_uw && $option_uw eq '';
 564         }
 565     }
 566 }
 567
 568 # Normal symbol form
 569 my $symbol_re = qr/[[:alpha:]_][_[:alnum:]]*?/;
 570
 571 # Checks of function name (man3) formatting.  The man3 checks are
 572 # easier than the man1 checks, we only check the names followed by (),
 573 # and only the names that have POD markup.
 574 sub functionname_check {
 575     my $id = shift;
 576     my $filename = shift;
 577     my $contents = shift;
 578
 579     while ( $contents =~ /($markup_re)\(\)/msg ) {
 580         print STDERR "$id:DEBUG[functionname_check] SYNOPSIS: found $&\n"
 581             if $debug;
 582
 583         my $symbol = $1;
 584         my $unmarked = $symbol;
 585         $unmarked =~ s/[BIL]<|>//msg;
 586
 587         err($id, "Malformed symbol: $symbol")
 588             unless $symbol =~ /^B<.*?>$/ && $unmarked =~ /^${symbol_re}$/
 589     }
 590
 591     # We can't do the kind of collecting coolness that option_check()
 592     # does, because there are too many things that can't be found in
 593     # name repositories like the NAME sections, such as symbol names
 594     # with a variable part (typically marked up as B<foo_I<TYPE>_bar>
 595 }
 596
 597 # This is from http://man7.org/linux/man-pages/man7/man-pages.7.html
 598 my %preferred_words = (
 599     '16bit'         => '16-bit',
 600     'a.k.a.'        => 'aka',
 601     'bitmask'       => 'bit mask',
 602     'builtin'       => 'built-in',
 603    #'epoch'         => 'Epoch', # handled specially, below
 604     'file name'     => 'filename',
 605     'file system'   => 'filesystem',
 606     'host name'     => 'hostname',
 607     'i-node'        => 'inode',
 608     'lower case'    => 'lowercase',
 609     'lower-case'    => 'lowercase',
 610     'manpage'       => 'man page',
 611     'non-blocking'  => 'nonblocking',
 612     'non-default'   => 'nondefault',
 613     'non-empty'     => 'nonempty',
 614     'non-negative'  => 'nonnegative',
 615     'non-zero'      => 'nonzero',
 616     'path name'     => 'pathname',
 617     'pre-allocated' => 'preallocated',
 618     'pseudo-terminal' => 'pseudoterminal',
 619     'real time'     => 'real-time',
 620     'realtime'      => 'real-time',
 621     'reserved port' => 'privileged port',
 622     'runtime'       => 'run time',
 623     'saved group ID'=> 'saved set-group-ID',
 624     'saved set-GID' => 'saved set-group-ID',
 625     'saved set-UID' => 'saved set-user-ID',
 626     'saved user ID' => 'saved set-user-ID',
 627     'set-GID'       => 'set-group-ID',
 628     'set-UID'       => 'set-user-ID',
 629     'setgid'        => 'set-group-ID',
 630     'setuid'        => 'set-user-ID',
 631     'sub-system'    => 'subsystem',
 632     'super block'   => 'superblock',
 633     'super-block'   => 'superblock',
 634     'super user'    => 'superuser',
 635     'super-user'    => 'superuser',
 636     'system port'   => 'privileged port',
 637     'time stamp'    => 'timestamp',
 638     'time zone'     => 'timezone',
 639     'upper case'    => 'uppercase',
 640     'upper-case'    => 'uppercase',
 641     'useable'       => 'usable',
 642     'user name'     => 'username',
 643     'userspace'     => 'user space',
 644     'zeroes'        => 'zeros'
 645 );
 646
 647 # Search manpage for words that have a different preferred use.
 648 sub wording {
 649     my $id = shift;
 650     my $contents = shift;
 651
 652     foreach my $k ( keys %preferred_words ) {
 653         # Sigh, trademark
 654         next if $k eq 'file system'
 655             and $contents =~ /Microsoft Encrypted File System/;
 656         err($id, "Found '$k' should use '$preferred_words{$k}'")
 657             if $contents =~ /\b\Q$k\E\b/i;
 658     }
 659     err($id, "Found 'epoch' should use 'Epoch'")
 660         if $contents =~ /\bepoch\b/;
 661     if ( $id =~ m@man1/@ ) {
 662         err($id, "found 'tool' in NAME, should use 'command'")
 663             if $contents =~ /=head1 NAME.*\btool\b.*=head1 SYNOPSIS/s;
 664         err($id, "found 'utility' in NAME, should use 'command'")
 665             if $contents =~ /NAME.*\butility\b.*=head1 SYNOPSIS/s;
 666
 667     }
 668 }
 669
 670 # Perform all sorts of nit/error checks on a manpage
 671 sub check {
 672     my %podinfo = @_;
 673     my $filename = $podinfo{filename};
 674     my $dirname = basename(dirname($filename));
 675     my $contents = $podinfo{contents};
 676
 677     my $id = "${filename}:1:";
 678     check_head_style($id, $contents);
 679
 680     # Check ordering of some sections in man3
 681     if ( $filename =~ m|man3/| ) {
 682         check_section_location($id, $contents, "RETURN VALUES", "EXAMPLES");
 683         check_section_location($id, $contents, "SEE ALSO", "HISTORY");
 684         check_section_location($id, $contents, "EXAMPLES", "SEE ALSO");
 685     }
 686
 687     # Make sure every link has a section.
 688     while ( $contents =~ /$markup_re/msg ) {
 689         my $target = $1;
 690         next unless $target =~ /^L<(.*)>$/;     # Skip if not L<...>
 691         $target = $1;                           # Peal away L< and >
 692         $target =~ s/\/[^\/]*$//;               # Peal away possible anchor
 693         $target =~ s/.*\|//g;                   # Peal away possible link text
 694         next if $target eq '';                  # Skip if links within page, or
 695         next if $target =~ /::/;                #   links to a Perl module, or
 696         next if $target =~ /^https?:/;          #   is a URL link, or
 697         next if $target =~ /\([1357]\)$/;       #   it has a section
 698         err($id, "Section missing in $target")
 699     }
 700     # Check for proper links to commands.
 701     while ( $contents =~ /L<([^>]*)\(1\)(?:\/.*)?>/g ) {
 702         my $target = $1;
 703         next if $target =~ /openssl-?/;
 704         next if ( grep { basename($_) eq "$target.pod" }
 705                   files(TAGS => [ 'manual', 'man1' ]) );
 706         # TODO: Filter out "foreign manual" links.
 707         next if $target =~ /ps|apropos|sha1sum|procmail|perl/;
 708         err($id, "Bad command link L<$target(1)>");
 709     }
 710     # Check for proper in-man-3 API links.
 711     while ( $contents =~ /L<([^>]*)\(3\)(?:\/.*)?>/g ) {
 712         my $target = $1;
 713         err($id, "Bad L<$target>")
 714             unless $target =~ /^[_[:alpha:]][_[:alnum:]]*$/
 715     }
 716
 717     unless ( $contents =~ /^=for openssl generic/ms ) {
 718         if ( $filename =~ m|man3/| ) {
 719             name_synopsis($id, $filename, $contents);
 720             functionname_check($id, $filename, $contents);
 721         } elsif ( $filename =~ m|man1/| ) {
 722             option_check($id, $filename, $contents)
 723         }
 724     }
 725
 726     wording($id, $contents);
 727
 728     err($id, "Doesn't start with =pod")
 729         if $contents !~ /^=pod/;
 730     err($id, "Doesn't end with =cut")
 731         if $contents !~ /=cut\n$/;
 732     err($id, "More than one cut line.")
 733         if $contents =~ /=cut.*=cut/ms;
 734     err($id, "EXAMPLE not EXAMPLES section.")
 735         if $contents =~ /=head1 EXAMPLE[^S]/;
 736     err($id, "WARNING not WARNINGS section.")
 737         if $contents =~ /=head1 WARNING[^S]/;
 738     err($id, "Missing copyright")
 739         if $contents !~ /Copyright .* The OpenSSL Project Authors/;
 740     err($id, "Copyright not last")
 741         if $contents =~ /head1 COPYRIGHT.*=head/ms;
 742     err($id, "head2 in All uppercase")
 743         if $contents =~ /head2\s+[A-Z ]+\n/;
 744     err($id, "Extra space after head")
 745         if $contents =~ /=head\d\s\s+/;
 746     err($id, "Period in NAME section")
 747         if $contents =~ /=head1 NAME.*\.\n.*=head1 SYNOPSIS/ms;
 748     err($id, "Duplicate $1 in L<>")
 749         if $contents =~ /L<([^>]*)\|([^>]*)>/ && $1 eq $2;
 750     err($id, "Bad =over $1")
 751         if $contents =~ /=over([^ ][^24])/;
 752     err($id, "Possible version style issue")
 753         if $contents =~ /OpenSSL version [019]/;
 754
 755     if ( $contents !~ /=for openssl multiple includes/ ) {
 756         # Look for multiple consecutive openssl #include lines
 757         # (non-consecutive lines are okay; see man3/MD5.pod).
 758         if ( $contents =~ /=head1 SYNOPSIS(.*)=head1 DESCRIPTION/ms ) {
 759             my $count = 0;
 760             foreach my $line ( split /\n+/, $1 ) {
 761                 if ( $line =~ m@include <openssl/@ ) {
 762                     err($id, "Has multiple includes")
 763                         if ++$count == 2;
 764                 } else {
 765                     $count = 0;
 766                 }
 767             }
 768         }
 769     }
 770
 771     open my $OUT, '>', $temp
 772         or die "Can't open $temp, $!";
 773     podchecker($filename, $OUT);
 774     close $OUT;
 775     open $OUT, '<', $temp
 776         or die "Can't read $temp, $!";
 777     while ( <$OUT> ) {
 778         next if /\(section\) in.*deprecated/;
 779         print;
 780     }
 781     close $OUT;
 782     unlink $temp || warn "Can't remove $temp, $!";
 783
 784     # Find what section this page is in; assume 3.
 785     my $section = 3;
 786     $section = $1 if $dirname =~ /man([1-9])/;
 787
 788     foreach ( (@{$mandatory_sections{'*'}}, @{$mandatory_sections{$section}}) ) {
 789         err($id, "Missing $_ head1 section")
 790             if $contents !~ /^=head1\s+${_}\s*$/m;
 791     }
 792 }
 793
 794 # Information database ###############################################
 795
 796 # Map of links in each POD file; filename => [ "foo(1)", "bar(3)", ... ]
 797 my %link_map = ();
 798 # Map of names in each POD file or from "missing" files; possible values are:
 799 # If found in a POD files, "name(s)" => filename
 800 # If found in a "missing" file or external, "name(s)" => ''
 801 my %name_map = ();
 802
 803 # State of man-page names.
 804 # %state is affected by loading util/*.num and util/*.syms
 805 # Values may be one of:
 806 # 'crypto' : belongs in libcrypto (loaded from libcrypto.num)
 807 # 'ssl' : belongs in libssl (loaded from libssl.num)
 808 # 'other' : belongs in libcrypto or libssl (loaded from other.syms)
 809 # 'internal' : Internal
 810 # 'public' : Public (generic name or external documentation)
 811 # Any of these values except 'public' may be prefixed with 'missing_'
 812 # to indicate that they are known to be missing.
 813 my %state;
 814 # %missing is affected by loading util/missing*.txt.  Values may be one of:
 815 # 'crypto' : belongs in libcrypto (loaded from libcrypto.num)
 816 # 'ssl' : belongs in libssl (loaded from libssl.num)
 817 # 'other' : belongs in libcrypto or libssl (loaded from other.syms)
 818 # 'internal' : Internal
 819 my %missing;
 820
 821 # Parse libcrypto.num, etc., and return sorted list of what's there.
 822 sub loadnum ($;$) {
 823     my $file = shift;
 824     my $type = shift;
 825     my @symbols;
 826
 827     open my $IN, '<', catfile($config{sourcedir}, $file)
 828         or die "Can't open $file, $!, stopped";
 829
 830     while ( <$IN> ) {
 831         next if /^#/;
 832         next if /\bNOEXIST\b/;
 833         my @fields = split();
 834         die "Malformed line $. in $file: $_"
 835             if scalar @fields != 2 && scalar @fields != 4;
 836         $state{$fields[0].'(3)'} = $type // 'internal';
 837     }
 838     close $IN;
 839 }
 840
 841 # Load file of symbol names that we know aren't documented.
 842 sub loadmissing($;$)
 843 {
 844     my $missingfile = shift;
 845     my $type = shift;
 846
 847     open FH, catfile($config{sourcedir}, $missingfile)
 848         or die "Can't open $missingfile";
 849     while ( <FH> ) {
 850         chomp;
 851         next if /^#/;
 852         $missing{$_} = $type // 'internal';
 853     }
 854     close FH;
 855 }
 856
 857 # Check that we have consistent public / internal documentation and declaration
 858 sub checkstate () {
 859     # Collect all known names, no matter where they come from
 860     my %names = map { $_ => 1 } (keys %name_map, keys %state, keys %missing);
 861
 862     # Check section 3, i.e. functions and macros
 863     foreach ( grep { $_ =~ /\(3\)$/ } sort keys %names ) {
 864         next if ( $name_map{$_} // '') eq '' || $_ =~ /$ignored/;
 865
 866         # If a man-page isn't recorded public or if it's recorded missing
 867         # and internal, it's declared to be internal.
 868         my $declared_internal =
 869             ($state{$_} // 'internal') eq 'internal'
 870             || ($missing{$_} // '') eq 'internal';
 871         # If a man-page isn't recorded internal or if it's recorded missing
 872         # and not internal, it's declared to be public
 873         my $declared_public =
 874             ($state{$_} // 'internal') ne 'internal'
 875             || ($missing{$_} // 'internal') ne 'internal';
 876
 877         err("$_ is supposedly public but is documented as internal")
 878             if ( $declared_public && $name_map{$_} =~ /\/internal\// );
 879         err("$_ is supposedly internal but is documented as public")
 880             if ( $declared_internal && $name_map{$_} !~ /\/internal\// );
 881     }
 882 }
 883
 884 # Check for undocumented macros; ignore those in the "missing" file
 885 # and do simple check for #define in our header files.
 886 sub checkmacros {
 887     my $count = 0;
 888     my %seen;
 889
 890     foreach my $f ( files(TAGS => 'public_header') ) {
 891         # Skip some internals we don't want to document yet.
 892         my $b = basename($f);
 893         next if $b eq 'asn1.h';
 894         next if $b eq 'asn1t.h';
 895         next if $b eq 'err.h';
 896         open(IN, $f)
 897             or die "Can't open $f, $!";
 898         while ( <IN> ) {
 899             next unless /^#\s*define\s*(\S+)\(/;
 900             my $macro = "$1(3)"; # We know they're all in section 3
 901             next if defined $name_map{$macro}
 902                 || defined $missing{$macro}
 903                 || defined $seen{$macro}
 904                 || $macro =~ /$ignored/;
 905
 906             err("$f:", "macro $macro undocumented")
 907                 if $opt_d || $opt_e;
 908             $count++;
 909             $seen{$macro} = 1;
 910         }
 911         close(IN);
 912     }
 913     err("# $count macros undocumented (count is approximate)")
 914         if $count > 0;
 915 }
 916
 917 # Find out what is undocumented (filtering out the known missing ones)
 918 # and display them.
 919 sub printem ($) {
 920     my $type = shift;
 921     my $count = 0;
 922
 923     foreach my $func ( grep { $state{$_} eq $type } sort keys %state ) {
 924         next if defined $name_map{$func}
 925             || defined $missing{$func};
 926
 927         err("$type:", "function $func undocumented")
 928             if $opt_d || $opt_e;
 929         $count++;
 930     }
 931     err("# $count lib$type names are not documented")
 932         if $count > 0;
 933 }
 934
 935 # Collect all the names in a manpage.
 936 sub collectnames {
 937     my %podinfo = @_;
 938     my $filename = $podinfo{filename};
 939     $filename =~ m|man(\d)/|;
 940     my $section = $1;
 941     my $simplename = basename($filename, ".pod");
 942     my $id = "${filename}:1:";
 943     my $is_generic = $podinfo{contents} =~ /^=for openssl generic/ms;
 944
 945     unless ( grep { $simplename eq $_ } @{$podinfo{names}} ) {
 946         err($id, "$simplename not in NAME section");
 947         push @{$podinfo{names}}, $simplename;
 948     }
 949     foreach my $name ( @{$podinfo{names}} ) {
 950         next if $name eq "";
 951         err($id, "'$name' contains whitespace")
 952             if $name =~ /\s/;
 953         my $name_sec = "$name($section)";
 954         if ( !defined $name_map{$name_sec} ) {
 955             $name_map{$name_sec} = $filename;
 956             $state{$name_sec} //=
 957                 ( $filename =~ /\/internal\// ? 'internal' : 'public' )
 958                 if $is_generic;
 959         } elsif ( $filename eq $name_map{$name_sec} ) {
 960             err($id, "$name_sec duplicated in NAME section of",
 961                  $name_map{$name_sec});
 962         } elsif ( $name_map{$name_sec} ne '' ) {
 963             err($id, "$name_sec also in NAME section of",
 964                  $name_map{$name_sec});
 965         }
 966     }
 967
 968     if ( $podinfo{contents} =~ /=for openssl foreign manual (.*)\n/ ) {
 969         foreach my $f ( split / /, $1 ) {
 970             $name_map{$f} = ''; # It still exists!
 971             $state{$f} = 'public'; # We assume!
 972         }
 973     }
 974
 975     my @links =
 976         $podinfo{contents} =~ /L<
 977                               # if the link is of the form L<something|name(s)>,
 978                               # then remove 'something'.  Note that 'something'
 979                               # may contain POD codes as well...
 980                               (?:(?:[^\|]|<[^>]*>)*\|)?
 981                               # we're only interested in references that have
 982                               # a one digit section number
 983                               ([^\/>\(]+\(\d\))
 984                              /gx;
 985     $link_map{$filename} = [ @links ];
 986 }
 987
 988 # Look for L<> ("link") references that point to files that do not exist.
 989 sub checklinks {
 990     foreach my $filename ( sort keys %link_map ) {
 991         foreach my $link ( @{$link_map{$filename}} ) {
 992             err("${filename}:1:", "reference to non-existing $link")
 993                 unless defined $name_map{$link} || defined $missing{$link};
 994             err("${filename}:1:", "reference of internal $link in public documentation $filename")
 995                 if ( ( ($state{$link} // '') eq 'internal'
 996                        || ($missing{$link} // '') eq 'internal' )
 997                      && $filename !~ /\/internal\// );
 998         }
 999     }
1000 }
1001
1002 # Cipher/digests to skip if they show up as "not implemented"
1003 # because they are, via the "-*" construct.
1004 my %skips = (
1005     'aes128' => 1,
1006     'aes192' => 1,
1007     'aes256' => 1,
1008     'aria128' => 1,
1009     'aria192' => 1,
1010     'aria256' => 1,
1011     'camellia128' => 1,
1012     'camellia192' => 1,
1013     'camellia256' => 1,
1014     'des' => 1,
1015     'des3' => 1,
1016     'idea' => 1,
1017     'cipher' => 1,
1018     'digest' => 1,
1019 );
1020
1021 # Check the flags of a command and see if everything is in the manpage
1022 sub checkflags {
1023     my $cmd = shift;
1024     my $doc = shift;
1025     my %cmdopts;
1026     my %docopts;
1027     my %localskips;
1028
1029     # Get the list of options in the command.
1030     open CFH, "$openssl list --options $cmd|"
1031         or die "Can list options for $cmd, $!";
1032     while ( <CFH> ) {
1033         chop;
1034         s/ .$//;
1035         $cmdopts{$_} = 1;
1036     }
1037     close CFH;
1038
1039     # Get the list of flags from the synopsis
1040     open CFH, "<$doc"
1041         or die "Can't open $doc, $!";
1042     while ( <CFH> ) {
1043         chop;
1044         last if /DESCRIPTION/;
1045         if ( /=for openssl ifdef (.*)/ ) {
1046             foreach my $f ( split / /, $1 ) {
1047                 $localskips{$f} = 1;
1048             }
1049             next;
1050         }
1051         my $opt;
1052         if ( /\[B<-([^ >]+)/ ) {
1053             $opt = $1;
1054         } elsif ( /^B<-([^ >]+)/ ) {
1055             $opt = $1;
1056         } else {
1057             next;
1058         }
1059         $opt = $1 if $opt =~ /I<(.*)/;
1060         $docopts{$1} = 1;
1061     }
1062     close CFH;
1063
1064     # See what's in the command not the manpage.
1065     my @undocced = sort grep { !defined $docopts{$_} } keys %cmdopts;
1066     foreach ( @undocced ) {
1067         next if /-/; # Skip the -- end-of-flags marker
1068         err("$doc: undocumented option -$_");
1069     }
1070
1071     # See what's in the command not the manpage.
1072     my @unimpl = sort grep { !defined $cmdopts{$_} } keys %docopts;
1073     foreach ( @unimpl ) {
1074         next if defined $skips{$_} || defined $localskips{$_};
1075         err("$doc: $cmd does not implement -$_");
1076     }
1077 }
1078
1079 ##
1080 ##  MAIN()
1081 ##  Do the work requested by the various getopt flags.
1082 ##  The flags are parsed in alphabetical order, just because we have
1083 ##  to have *some way* of listing them.
1084 ##
1085
1086 if ( $opt_c ) {
1087     my @commands = ();
1088
1089     # Get list of commands.
1090     open FH, "$openssl list -1 -commands|"
1091         or die "Can't list commands, $!";
1092     while ( <FH> ) {
1093         chop;
1094         push @commands, $_;
1095     }
1096     close FH;
1097
1098     # See if each has a manpage.
1099     foreach my $cmd ( @commands ) {
1100         next if $cmd eq 'help' || $cmd eq 'exit';
1101         my @doc = ( grep { basename($_) eq "openssl-$cmd.pod"
1102                            # For "tsget" and "CA.pl" pod pages
1103                            || basename($_) eq "$cmd.pod" }
1104                     files(TAGS => [ 'manual', 'man1' ]) );
1105         my $num = scalar @doc;
1106         if ($num > 1) {
1107             err("$num manuals for 'openssl $cmd': ".join(", ", @doc));
1108         } elsif ($num < 1) {
1109             err("no manual for 'openssl $cmd'");
1110         } else {
1111             checkflags($cmd, @doc);
1112         }
1113     }
1114
1115     # See what help is missing.
1116     open FH, "$openssl list --missing-help |"
1117         or die "Can't list missing help, $!";
1118     while ( <FH> ) {
1119         chop;
1120         my ($cmd, $flag) = split;
1121         err("$cmd has no help for -$flag");
1122     }
1123     close FH;
1124
1125     exit $status;
1126 }
1127
1128 # Populate %state
1129 loadnum('util/libcrypto.num', 'crypto');
1130 loadnum('util/libssl.num', 'ssl');
1131 loadnum('util/other.syms', 'other');
1132 loadnum('util/other-internal.syms');
1133 if ( $opt_o ) {
1134     loadmissing('util/missingmacro111.txt', 'crypto');
1135     loadmissing('util/missingcrypto111.txt', 'crypto');
1136     loadmissing('util/missingssl111.txt', 'ssl');
1137 } elsif ( !$opt_u ) {
1138     loadmissing('util/missingmacro.txt', 'crypto');
1139     loadmissing('util/missingcrypto.txt', 'crypto');
1140     loadmissing('util/missingssl.txt', 'ssl');
1141     loadmissing('util/missingcrypto-internal.txt');
1142     loadmissing('util/missingssl-internal.txt');
1143 }
1144
1145 if ( $opt_n || $opt_l || $opt_u || $opt_v ) {
1146     my @files_to_read = ( $opt_n && @ARGV ) ? @ARGV : files(TAGS => 'manual');
1147
1148     foreach (@files_to_read) {
1149         my %podinfo = extract_pod_info($_, { debug => $debug });
1150
1151         collectnames(%podinfo)
1152             if ( $opt_l || $opt_u || $opt_v );
1153
1154         check(%podinfo)
1155             if ( $opt_n );
1156     }
1157 }
1158
1159 if ( $opt_l ) {
1160     checklinks();
1161 }
1162
1163 if ( $opt_n ) {
1164     # If not given args, check that all man1 commands are named properly.
1165     if ( scalar @ARGV == 0 ) {
1166         foreach ( files(TAGS => [ 'public_manual', 'man1' ]) ) {
1167             next if /CA.pl/ || /openssl\.pod/ || /tsget\.pod/;
1168             err("$_ doesn't start with openssl-") unless /openssl-/;
1169         }
1170     }
1171 }
1172
1173 checkstate();
1174
1175 if ( $opt_u || $opt_v) {
1176     printem('crypto');
1177     printem('ssl');
1178     checkmacros();
1179 }
1180
1181 exit $status;