util/TLSProxy/ClientHello.pm

   1 # Written by Matt Caswell for the OpenSSL project.
   2 # ====================================================================
   3 # Copyright (c) 1998-2015 The OpenSSL Project.  All rights reserved.
   4 #
   5 # Redistribution and use in source and binary forms, with or without
   6 # modification, are permitted provided that the following conditions
   7 # are met:
   8 #
   9 # 1. Redistributions of source code must retain the above copyright
  10 #    notice, this list of conditions and the following disclaimer.
  11 #
  12 # 2. Redistributions in binary form must reproduce the above copyright
  13 #    notice, this list of conditions and the following disclaimer in
  14 #    the documentation and/or other materials provided with the
  15 #    distribution.
  16 #
  17 # 3. All advertising materials mentioning features or use of this
  18 #    software must display the following acknowledgment:
  19 #    "This product includes software developed by the OpenSSL Project
  20 #    for use in the OpenSSL Toolkit. (http://www.openssl.org/)"
  21 #
  22 # 4. The names "OpenSSL Toolkit" and "OpenSSL Project" must not be used to
  23 #    endorse or promote products derived from this software without
  24 #    prior written permission. For written permission, please contact
  25 #    openssl-core@openssl.org.
  26 #
  27 # 5. Products derived from this software may not be called "OpenSSL"
  28 #    nor may "OpenSSL" appear in their names without prior written
  29 #    permission of the OpenSSL Project.
  30 #
  31 # 6. Redistributions of any form whatsoever must retain the following
  32 #    acknowledgment:
  33 #    "This product includes software developed by the OpenSSL Project
  34 #    for use in the OpenSSL Toolkit (http://www.openssl.org/)"
  35 #
  36 # THIS SOFTWARE IS PROVIDED BY THE OpenSSL PROJECT ``AS IS'' AND ANY
  37 # EXPRESSED OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  38 # IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  39 # PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE OpenSSL PROJECT OR
  40 # ITS CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  41 # SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  42 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  43 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  44 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
  45 # STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  46 # ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
  47 # OF THE POSSIBILITY OF SUCH DAMAGE.
  48 # ====================================================================
  49 #
  50 # This product includes cryptographic software written by Eric Young
  51 # (eay@cryptsoft.com).  This product includes software written by Tim
  52 # Hudson (tjh@cryptsoft.com).
  53
  54 use strict;
  55
  56 package TLSProxy::ClientHello;
  57
  58 use parent 'TLSProxy::Message';
  59
  60 use constant {
  61     EXT_ENCRYPT_THEN_MAC => 22
  62 };
  63
  64 sub new
  65 {
  66     my $class = shift;
  67     my ($server,
  68         $data,
  69         $records,
  70         $startoffset,
  71         $message_frag_lens) = @_;
  72
  73     my $self = $class->SUPER::new(
  74         $server,
  75         1,
  76         $data,
  77         $records,
  78         $startoffset,
  79         $message_frag_lens);
  80
  81     $self->{client_version} = 0;
  82     $self->{random} = [];
  83     $self->{session_id_len} = 0;
  84     $self->{session} = "";
  85     $self->{ciphersuite_len} = 0;
  86     $self->{ciphersuites} = [];
  87     $self->{comp_meth_len} = 0;
  88     $self->{comp_meths} = [];
  89     $self->{extensions_len} = 0;
  90     $self->{extensions_data} = "";
  91
  92     return $self;
  93 }
  94
  95 sub parse
  96 {
  97     my $self = shift;
  98     my $ptr = 2;
  99     my ($client_version) = unpack('n', $self->data);
 100     my $random = substr($self->data, $ptr, 32);
 101     $ptr += 32;
 102     my $session_id_len = unpack('C', substr($self->data, $ptr));
 103     $ptr++;
 104     my $session = substr($self->data, $ptr, $session_id_len);
 105     $ptr += $session_id_len;
 106     my $ciphersuite_len = unpack('n', substr($self->data, $ptr));
 107     $ptr += 2;
 108     my @ciphersuites = unpack('n*', substr($self->data, $ptr,
 109                                            $ciphersuite_len));
 110     $ptr += $ciphersuite_len;
 111     my $comp_meth_len = unpack('C', substr($self->data, $ptr));
 112     $ptr++;
 113     my @comp_meths = unpack('C*', substr($self->data, $ptr, $comp_meth_len));
 114     $ptr += $comp_meth_len;
 115     my $extensions_len = unpack('n', substr($self->data, $ptr));
 116     $ptr += 2;
 117     #For now we just deal with this as a block of data. In the future we will
 118     #want to parse this
 119     my $extension_data = substr($self->data, $ptr);
 120
 121     if (length($extension_data) != $extensions_len) {
 122         die "Invalid extension length\n";
 123     }
 124     my %extensions = ();
 125     while (length($extension_data) >= 4) {
 126         my ($type, $size) = unpack("nn", $extension_data);
 127         my $extdata = substr($extension_data, 4, $size);
 128         $extension_data = substr($extension_data, 4 + $size);
 129         $extensions{$type} = $extdata;
 130     }
 131
 132     $self->client_version($client_version);
 133     $self->random($random);
 134     $self->session_id_len($session_id_len);
 135     $self->session($session);
 136     $self->ciphersuite_len($ciphersuite_len);
 137     $self->ciphersuites(\@ciphersuites);
 138     $self->comp_meth_len($comp_meth_len);
 139     $self->comp_meths(\@comp_meths);
 140     $self->extensions_len($extensions_len);
 141     $self->extension_data(\%extensions);
 142
 143     $self->process_extensions();
 144
 145     print "    Client Version:".$client_version."\n";
 146     print "    Session ID Len:".$session_id_len."\n";
 147     print "    Ciphersuite len:".$ciphersuite_len."\n";
 148     print "    Compression Method Len:".$comp_meth_len."\n";
 149     print "    Extensions Len:".$extensions_len."\n";
 150 }
 151
 152 #Perform any actions necessary based on the extensions we've seen
 153 sub process_extensions
 154 {
 155     my $self = shift;
 156     my %extensions = %{$self->extension_data};
 157
 158     #Clear any state from a previous run
 159     TLSProxy::Record->etm(0);
 160
 161     if (exists $extensions{&EXT_ENCRYPT_THEN_MAC}) {
 162         TLSProxy::Record->etm(1);
 163     }
 164 }
 165
 166 #Reconstruct the on-the-wire message data following changes
 167 sub set_message_contents
 168 {
 169     my $self = shift;
 170     my $data;
 171
 172     $data = pack('n', $self->client_version);
 173     $data .= $self->random;
 174     $data .= pack('C', $self->session_id_len);
 175     $data .= $self->session;
 176     $data .= pack('n', $self->ciphersuite_len);
 177     $data .= pack("n*", @{$self->ciphersuites});
 178     $data .= pack('C', $self->comp_meth_len);
 179     $data .= pack("C*", @{$self->comp_meths});
 180     $data .= pack('n', $self->extensions_len);
 181     foreach my $key (keys %{$self->extension_data}) {
 182         my $extdata = ${$self->extension_data}{$key};
 183         $data .= pack("n", $key);
 184         $data .= pack("n", length($extdata));
 185         $data .= $extdata;
 186     }
 187
 188     $self->data($data);
 189 }
 190
 191 #Read/write accessors
 192 sub client_version
 193 {
 194     my $self = shift;
 195     if (@_) {
 196       $self->{client_version} = shift;
 197     }
 198     return $self->{client_version};
 199 }
 200 sub random
 201 {
 202     my $self = shift;
 203     if (@_) {
 204       $self->{random} = shift;
 205     }
 206     return $self->{random};
 207 }
 208 sub session_id_len
 209 {
 210     my $self = shift;
 211     if (@_) {
 212       $self->{session_id_len} = shift;
 213     }
 214     return $self->{session_id_len};
 215 }
 216 sub session
 217 {
 218     my $self = shift;
 219     if (@_) {
 220       $self->{session} = shift;
 221     }
 222     return $self->{session};
 223 }
 224 sub ciphersuite_len
 225 {
 226     my $self = shift;
 227     if (@_) {
 228       $self->{ciphersuite_len} = shift;
 229     }
 230     return $self->{ciphersuite_len};
 231 }
 232 sub ciphersuites
 233 {
 234     my $self = shift;
 235     if (@_) {
 236       $self->{ciphersuites} = shift;
 237     }
 238     return $self->{ciphersuites};
 239 }
 240 sub comp_meth_len
 241 {
 242     my $self = shift;
 243     if (@_) {
 244       $self->{comp_meth_len} = shift;
 245     }
 246     return $self->{comp_meth_len};
 247 }
 248 sub comp_meths
 249 {
 250     my $self = shift;
 251     if (@_) {
 252       $self->{comp_meths} = shift;
 253     }
 254     return $self->{comp_meths};
 255 }
 256 sub extensions_len
 257 {
 258     my $self = shift;
 259     if (@_) {
 260       $self->{extensions_len} = shift;
 261     }
 262     return $self->{extensions_len};
 263 }
 264 sub extension_data
 265 {
 266     my $self = shift;
 267     if (@_) {
 268       $self->{extension_data} = shift;
 269     }
 270     return $self->{extension_data};
 271 }
 272 1;