test/recipes/80-test_ssl_new.t

   1 #! /usr/bin/env perl
   2 # Copyright 2015-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9
  10 use strict;
  11 use warnings;
  12
  13 use File::Basename;
  14 use File::Compare qw/compare_text/;
  15 use if $^O ne "VMS", 'File::Glob' => qw/glob/;
  16
  17 use OpenSSL::Test qw/:DEFAULT srctop_dir srctop_file/;
  18 use OpenSSL::Test::Utils qw/disabled alldisabled available_protocols/;
  19
  20 setup("test_ssl_new");
  21
  22 $ENV{TEST_CERTS_DIR} = srctop_dir("test", "certs");
  23 $ENV{CTLOG_FILE} = srctop_file("test", "ct", "log_list.conf");
  24
  25 my @conf_srcs =  glob(srctop_file("test", "ssl-tests", "*.conf.in"));
  26 map { s/;.*// } @conf_srcs if $^O eq "VMS";
  27 my @conf_files = map { basename($_, ".in") } @conf_srcs;
  28 map { s/\^// } @conf_files if $^O eq "VMS";
  29
  30 # We hard-code the number of tests to double-check that the globbing above
  31 # finds all files as expected.
  32 plan tests => 21;  # = scalar @conf_srcs
  33
  34 # Some test results depend on the configuration of enabled protocols. We only
  35 # verify generated sources in the default configuration.
  36 my $is_default_tls = (disabled("ssl3") && !disabled("tls1") &&
  37                       !disabled("tls1_1") && !disabled("tls1_2") &&
  38                       disabled("tls1_3"));
  39
  40 my $is_default_dtls = (!disabled("dtls1") && !disabled("dtls1_2"));
  41
  42 my @all_pre_tls1_3 = ("ssl3", "tls1", "tls1_1", "tls1_2");
  43 my $no_tls = alldisabled(available_protocols("tls"));
  44 my $no_pre_tls1_3 = alldisabled(@all_pre_tls1_3);
  45 my $no_dtls = alldisabled(available_protocols("dtls"));
  46 my $no_npn = disabled("nextprotoneg");
  47 my $no_ct = disabled("ct");
  48 my $no_ec = disabled("ec");
  49 my $no_dh = disabled("dh");
  50 my $no_dsa = disabled("dsa");
  51 my $no_ec2m = disabled("ec2m");
  52 my $no_ocsp = disabled("ocsp");
  53
  54 # Add your test here if the test conf.in generates test cases and/or
  55 # expectations dynamically based on the OpenSSL compile-time config.
  56 my %conf_dependent_tests = (
  57   "02-protocol-version.conf" => !$is_default_tls,
  58   "04-client_auth.conf" => !$is_default_tls,
  59   "07-dtls-protocol-version.conf" => !$is_default_dtls,
  60   "10-resumption.conf" => !$is_default_tls,
  61   "11-dtls_resumption.conf" => !$is_default_dtls,
  62   "17-renegotiate.conf" => disabled("tls1_2"),
  63   "18-dtls-renegotiate.conf" => disabled("dtls1_2"),
  64   "19-mac-then-encrypt.conf" => !$is_default_tls,
  65   "20-cert-select.conf" => !$is_default_tls || $no_dh || $no_dsa,
  66 );
  67
  68 # Add your test here if it should be skipped for some compile-time
  69 # configurations. Default is $no_tls but some tests have different skip
  70 # conditions.
  71 my %skip = (
  72   "07-dtls-protocol-version.conf" => $no_dtls,
  73   "08-npn.conf" => (disabled("tls1") && disabled("tls1_1")
  74                     && disabled("tls1_2")) || $no_npn,
  75   "10-resumption.conf" => disabled("tls1_1") || disabled("tls1_2"),
  76   "11-dtls_resumption.conf" => disabled("dtls1") || disabled("dtls1_2"),
  77   "12-ct.conf" => $no_tls || $no_ct || $no_ec,
  78   # We could run some of these tests without TLS 1.2 if we had a per-test
  79   # disable instruction but that's a bizarre configuration not worth
  80   # special-casing for.
  81   # We should review this once we have TLS 1.3.
  82   "13-fragmentation.conf" => disabled("tls1_2"),
  83   "14-curves.conf" => disabled("tls1_2") || $no_ec || $no_ec2m,
  84   "15-certstatus.conf" => $no_tls || $no_ocsp,
  85   "16-dtls-certstatus.conf" => $no_dtls || $no_ocsp,
  86   "18-dtls-renegotiate.conf" => $no_dtls,
  87   "19-mac-then-encrypt.conf" => $no_pre_tls1_3,
  88   "20-cert-select.conf" => disabled("tls1_2") || $no_ec,
  89   "21-key-update.conf" => disabled("tls1_3"),
  90 );
  91
  92 foreach my $conf (@conf_files) {
  93     subtest "Test configuration $conf" => sub {
  94         test_conf($conf,
  95                   $conf_dependent_tests{$conf} || $^O eq "VMS" ?  0 : 1,
  96                   defined($skip{$conf}) ? $skip{$conf} : $no_tls);
  97     }
  98 }
  99
 100 sub test_conf {
 101     plan tests => 3;
 102
 103     my ($conf, $check_source, $skip) = @_;
 104
 105     my $conf_file = srctop_file("test", "ssl-tests", $conf);
 106     my $tmp_file = "${conf}.$$.tmp";
 107     my $run_test = 1;
 108
 109   SKIP: {
 110       # "Test" 1. Generate the source.
 111       my $input_file = $conf_file . ".in";
 112
 113       skip 'failure', 2 unless
 114         ok(run(perltest(["generate_ssl_tests.pl", $input_file],
 115                         interpreter_args => [ "-I", srctop_dir("test", "testlib")],
 116                         stdout => $tmp_file)),
 117            "Getting output from generate_ssl_tests.pl.");
 118
 119     SKIP: {
 120         # Test 2. Compare against existing output in test/ssl_tests.conf.
 121         skip "Skipping generated source test for $conf", 1
 122           if !$check_source;
 123
 124         $run_test = is(cmp_text($tmp_file, $conf_file), 0,
 125                        "Comparing generated sources.");
 126       }
 127
 128       # Test 3. Run the test.
 129       skip "No tests available; skipping tests", 1 if $skip;
 130       skip "Stale sources; skipping tests", 1 if !$run_test;
 131
 132       ok(run(test(["ssl_test", $tmp_file])), "running ssl_test $conf");
 133     }
 134
 135     unlink glob $tmp_file;
 136 }
 137
 138 sub cmp_text {
 139     return compare_text(@_, sub {
 140         $_[0] =~ s/\R//g;
 141         $_[1] =~ s/\R//g;
 142         return $_[0] ne $_[1];
 143     });
 144 }