test/recipes/80-test_ssl_new.t

   1 #! /usr/bin/env perl
   2 # Copyright 2015-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9
  10 use strict;
  11 use warnings;
  12
  13 use File::Basename;
  14 use File::Compare qw/compare_text/;
  15 use if $^O ne "VMS", 'File::Glob' => qw/glob/;
  16
  17 use OpenSSL::Test qw/:DEFAULT srctop_dir srctop_file/;
  18 use OpenSSL::Test::Utils qw/disabled alldisabled available_protocols/;
  19
  20 setup("test_ssl_new");
  21
  22 $ENV{TEST_CERTS_DIR} = srctop_dir("test", "certs");
  23 $ENV{CTLOG_FILE} = srctop_file("test", "ct", "log_list.conf");
  24
  25 my @conf_srcs =  glob(srctop_file("test", "ssl-tests", "*.conf.in"));
  26 map { s/;.*// } @conf_srcs if $^O eq "VMS";
  27 my @conf_files = map { basename($_) } @conf_srcs;
  28 map { s/\.in// } @conf_files;
  29
  30 # We hard-code the number of tests to double-check that the globbing above
  31 # finds all files as expected.
  32 plan tests => 18;  # = scalar @conf_srcs
  33
  34 # Some test results depend on the configuration of enabled protocols. We only
  35 # verify generated sources in the default configuration.
  36 my $is_default_tls = (disabled("ssl3") && !disabled("tls1") &&
  37                       !disabled("tls1_1") && !disabled("tls1_2") &&
  38                       disabled("tls1_3"));
  39
  40 my $is_default_dtls = (!disabled("dtls1") && !disabled("dtls1_2"));
  41
  42 my $no_tls = alldisabled(available_protocols("tls"));
  43 my $no_dtls = alldisabled(available_protocols("dtls"));
  44 my $no_npn = disabled("nextprotoneg");
  45 my $no_ct = disabled("ct");
  46 my $no_ec = disabled("ec");
  47 my $no_ec2m = disabled("ec2m");
  48 my $no_ocsp = disabled("ocsp");
  49
  50 # Add your test here if the test conf.in generates test cases and/or
  51 # expectations dynamically based on the OpenSSL compile-time config.
  52 my %conf_dependent_tests = (
  53   "02-protocol-version.conf" => !$is_default_tls,
  54   "04-client_auth.conf" => !$is_default_tls,
  55   "07-dtls-protocol-version.conf" => !$is_default_dtls,
  56   "10-resumption.conf" => !$is_default_tls,
  57   "11-dtls_resumption.conf" => !$is_default_dtls,
  58 );
  59
  60 # Add your test here if it should be skipped for some compile-time
  61 # configurations. Default is $no_tls but some tests have different skip
  62 # conditions.
  63 my %skip = (
  64   "07-dtls-protocol-version.conf" => $no_dtls,
  65   "08-npn.conf" => $no_tls || $no_npn,
  66   "10-resumption.conf" => disabled("tls1_1") || disabled("tls1_2"),
  67   "11-dtls_resumption.conf" => disabled("dtls1") || disabled("dtls1_2"),
  68   "12-ct.conf" => $no_tls || $no_ct || $no_ec,
  69   # We could run some of these tests without TLS 1.2 if we had a per-test
  70   # disable instruction but that's a bizarre configuration not worth
  71   # special-casing for.
  72   # We should review this once we have TLS 1.3.
  73   "13-fragmentation.conf" => disabled("tls1_2"),
  74   "14-curves.conf" => disabled("tls1_2") || $no_ec || $no_ec2m,
  75   "15-certstatus.conf" => $no_tls || $no_ocsp,
  76   "16-dtls-certstatus.conf" => $no_dtls || $no_ocsp,
  77   "18-dtls-renegotiate.conf" => $no_dtls,
  78 );
  79
  80 foreach my $conf (@conf_files) {
  81     subtest "Test configuration $conf" => sub {
  82         test_conf($conf,
  83                   $conf_dependent_tests{$conf} || $^O eq "VMS" ?  0 : 1,
  84                   defined($skip{$conf}) ? $skip{$conf} : $no_tls);
  85     }
  86 }
  87
  88 sub test_conf {
  89     plan tests => 3;
  90
  91     my ($conf, $check_source, $skip) = @_;
  92
  93     my $conf_file = srctop_file("test", "ssl-tests", $conf);
  94     my $tmp_file = "${conf}.$$.tmp";
  95     my $run_test = 1;
  96
  97   SKIP: {
  98       # "Test" 1. Generate the source.
  99       my $input_file = $conf_file . ".in";
 100
 101       skip 'failure', 2 unless
 102         ok(run(perltest(["generate_ssl_tests.pl", $input_file],
 103                         interpreter_args => [ "-I", srctop_dir("test", "testlib")],
 104                         stdout => $tmp_file)),
 105            "Getting output from generate_ssl_tests.pl.");
 106
 107     SKIP: {
 108         # Test 2. Compare against existing output in test/ssl_tests.conf.
 109         skip "Skipping generated source test for $conf", 1
 110           if !$check_source;
 111
 112         $run_test = is(cmp_text($tmp_file, $conf_file), 0,
 113                        "Comparing generated sources.");
 114       }
 115
 116       # Test 3. Run the test.
 117       skip "No tests available; skipping tests", 1 if $skip;
 118       skip "Stale sources; skipping tests", 1 if !$run_test;
 119
 120       ok(run(test(["ssl_test", $tmp_file])), "running ssl_test $conf");
 121     }
 122
 123     unlink glob $tmp_file;
 124 }
 125
 126 sub cmp_text {
 127     return compare_text(@_, sub {
 128         $_[0] =~ s/\R//g;
 129         $_[1] =~ s/\R//g;
 130         return $_[0] ne $_[1];
 131     });
 132 }