test/recipes/70-test_sslsessiontick.t

   1 #! /usr/bin/env perl
   2 # Copyright 2015-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9 use strict;
  10 use OpenSSL::Test qw/:DEFAULT cmdstr srctop_file bldtop_dir/;
  11 use OpenSSL::Test::Utils;
  12 use TLSProxy::Proxy;
  13 use File::Temp qw(tempfile);
  14
  15 my $test_name = "test_sslsessiontick";
  16 setup($test_name);
  17
  18 plan skip_all => "TLSProxy isn't usable on $^O"
  19     if $^O =~ /^(VMS|MSWin32)$/;
  20
  21 plan skip_all => "$test_name needs the dynamic engine feature enabled"
  22     if disabled("engine") || disabled("dynamic-engine");
  23
  24 plan skip_all => "$test_name needs the sock feature enabled"
  25     if disabled("sock");
  26
  27 $ENV{OPENSSL_ia32cap} = '~0x200000200000000';
  28
  29 sub checkmessages($$$$$$);
  30 sub clearclient();
  31 sub clearall();
  32
  33 my $chellotickext = 0;
  34 my $shellotickext = 0;
  35 my $fullhand = 0;
  36 my $ticketseen = 0;
  37
  38 my $proxy = TLSProxy::Proxy->new(
  39     undef,
  40     cmdstr(app(["openssl"]), display => 1),
  41     srctop_file("apps", "server.pem"),
  42     (!$ENV{HARNESS_ACTIVE} || $ENV{HARNESS_VERBOSE})
  43 );
  44
  45 plan tests => 8;
  46
  47 #Test 1: By default with no existing session we should get a session ticket
  48 #Expected result: ClientHello extension seen; ServerHello extension seen
  49 #                 NewSessionTicket message seen; Full handshake
  50 $proxy->start();
  51 checkmessages(1, "Default session ticket test", 1, 1, 1, 1);
  52
  53 #Test 2: If the server does not accept tickets we should get a normal handshake
  54 #with no session tickets
  55 #Expected result: ClientHello extension seen; ServerHello extension not seen
  56 #                 NewSessionTicket message not seen; Full handshake
  57 clearall();
  58 $proxy->serverflags("-no_ticket");
  59 $proxy->start();
  60 checkmessages(2, "No server support session ticket test", 1, 0, 0, 1);
  61
  62 #Test 3: If the client does not accept tickets we should get a normal handshake
  63 #with no session tickets
  64 #Expected result: ClientHello extension not seen; ServerHello extension not seen
  65 #                 NewSessionTicket message not seen; Full handshake
  66 clearall();
  67 $proxy->clientflags("-no_ticket");
  68 $proxy->start();
  69 checkmessages(3, "No client support session ticket test", 0, 0, 0, 1);
  70
  71 #Test 4: Test session resumption with session ticket
  72 #Expected result: ClientHello extension seen; ServerHello extension not seen
  73 #                 NewSessionTicket message not seen; Abbreviated handshake
  74 clearall();
  75 (my $fh, my $session) = tempfile();
  76 $proxy->serverconnects(2);
  77 $proxy->clientflags("-sess_out ".$session);
  78 $proxy->start();
  79 $proxy->clearClient();
  80 $proxy->clientflags("-sess_in ".$session);
  81 $proxy->clientstart();
  82 checkmessages(4, "Session resumption session ticket test", 1, 0, 0, 0);
  83
  84 #Test 5: Test session resumption with ticket capable client without a ticket
  85 #Expected result: ClientHello extension seen; ServerHello extension seen
  86 #                 NewSessionTicket message seen; Abbreviated handshake
  87 clearall();
  88 ($fh, $session) = tempfile();
  89 $proxy->serverconnects(2);
  90 $proxy->clientflags("-sess_out ".$session." -no_ticket");
  91 $proxy->start();
  92 $proxy->clearClient();
  93 $proxy->clientflags("-sess_in ".$session);
  94 $proxy->clientstart();
  95 checkmessages(5, "Session resumption with ticket capable client without a "
  96                  ."ticket", 1, 1, 1, 0);
  97
  98 #Test 6: Client accepts empty ticket.
  99 #Expected result: ClientHello extension seen; ServerHello extension seen;
 100 #                 NewSessionTicket message seen; Full handshake.
 101 clearall();
 102 $proxy->filter(\&ticket_filter);
 103 $proxy->start();
 104 checkmessages(6, "Empty ticket test",  1, 1, 1, 1);
 105
 106 #Test 7-8: Client keeps existing ticket on empty ticket.
 107 clearall();
 108 ($fh, $session) = tempfile();
 109 $proxy->serverconnects(3);
 110 $proxy->filter(undef);
 111 $proxy->clientflags("-sess_out ".$session);
 112 $proxy->start();
 113 $proxy->clearClient();
 114 $proxy->clientflags("-sess_in ".$session." -sess_out ".$session);
 115 $proxy->filter(\&inject_empty_ticket_filter);
 116 $proxy->clientstart();
 117 #Expected result: ClientHello extension seen; ServerHello extension seen;
 118 #                 NewSessionTicket message seen; Abbreviated handshake.
 119 checkmessages(7, "Empty ticket resumption test",  1, 1, 1, 0);
 120 clearclient();
 121 $proxy->clientflags("-sess_in ".$session);
 122 $proxy->filter(undef);
 123 $proxy->clientstart();
 124 #Expected result: ClientHello extension seen; ServerHello extension not seen;
 125 #                 NewSessionTicket message not seen; Abbreviated handshake.
 126 checkmessages(8, "Empty ticket resumption test",  1, 0, 0, 0);
 127
 128
 129 sub ticket_filter
 130 {
 131     my $proxy = shift;
 132
 133     foreach my $message (@{$proxy->message_list}) {
 134         if ($message->mt == TLSProxy::Message::MT_NEW_SESSION_TICKET) {
 135             $message->ticket("");
 136             $message->repack();
 137         }
 138     }
 139 }
 140
 141 sub inject_empty_ticket_filter {
 142     my $proxy = shift;
 143
 144     foreach my $message (@{$proxy->message_list}) {
 145         if ($message->mt == TLSProxy::Message::MT_NEW_SESSION_TICKET) {
 146             # Only inject the message first time we're called.
 147             return;
 148         }
 149     }
 150
 151     my @new_message_list = ();
 152     foreach my $message (@{$proxy->message_list}) {
 153         push @new_message_list, $message;
 154         if ($message->mt == TLSProxy::Message::MT_SERVER_HELLO) {
 155             $message->set_extension(TLSProxy::Message::EXT_SESSION_TICKET, "");
 156             $message->repack();
 157             # Tack NewSessionTicket onto the ServerHello record.
 158             # This only works if the ServerHello is exactly one record.
 159             my $record = ${$message->records}[0];
 160
 161             my $offset = $message->startoffset + $message->encoded_length;
 162             my $newsessionticket = TLSProxy::NewSessionTicket->new(
 163                 1, "", [$record], $offset, []);
 164             $newsessionticket->repack();
 165             push @new_message_list, $newsessionticket;
 166         }
 167     }
 168     $proxy->message_list([@new_message_list]);
 169 }
 170
 171 sub checkmessages($$$$$$)
 172 {
 173     my ($testno, $testname, $testch, $testsh, $testtickseen, $testhand) = @_;
 174
 175     subtest $testname => sub {
 176
 177         foreach my $message (@{$proxy->message_list}) {
 178             if ($message->mt == TLSProxy::Message::MT_CLIENT_HELLO
 179                 || $message->mt == TLSProxy::Message::MT_SERVER_HELLO) {
 180                 #Get the extensions data
 181                 my %extensions = %{$message->extension_data};
 182                 if (defined
 183                     $extensions{TLSProxy::Message::EXT_SESSION_TICKET}) {
 184                     if ($message->mt == TLSProxy::Message::MT_CLIENT_HELLO) {
 185                         $chellotickext = 1;
 186                     } else {
 187                         $shellotickext = 1;
 188                     }
 189                 }
 190             } elsif ($message->mt == TLSProxy::Message::MT_CLIENT_KEY_EXCHANGE) {
 191                 #Must be doing a full handshake
 192                 $fullhand = 1;
 193             } elsif ($message->mt == TLSProxy::Message::MT_NEW_SESSION_TICKET) {
 194                 $ticketseen = 1;
 195             }
 196         }
 197
 198         plan tests => 5;
 199
 200         ok(TLSProxy::Message->success, "Handshake");
 201         ok(($testch && $chellotickext) || (!$testch && !$chellotickext),
 202            "ClientHello extension Session Ticket check");
 203         ok(($testsh && $shellotickext) || (!$testsh && !$shellotickext),
 204            "ServerHello extension Session Ticket check");
 205         ok(($testtickseen && $ticketseen) || (!$testtickseen && !$ticketseen),
 206            "Session Ticket message presence check");
 207         ok(($testhand && $fullhand) || (!$testhand && !$fullhand),
 208            "Session Ticket full handshake check");
 209     }
 210 }
 211
 212
 213 sub clearclient()
 214 {
 215     $chellotickext = 0;
 216     $shellotickext = 0;
 217     $fullhand = 0;
 218     $ticketseen = 0;
 219     $proxy->clearClient();
 220 }
 221
 222 sub clearall()
 223 {
 224     clearclient();
 225     $proxy->clear();
 226 }