apps/progs.pl

   1 #! /usr/bin/env perl
   2 # Copyright 1995-2018 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the Apache License 2.0 (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9 # Generate progs.h file by looking for command mains in list of C files
  10 # passed on the command line.
  11
  12 use strict;
  13 use warnings;
  14 use lib '.';
  15 use configdata qw/@disablables %unified_info/;
  16
  17 my $opt          = shift @ARGV;
  18 die "Unrecognised option, must be -C or -H\n"
  19     unless ($opt eq '-H' || $opt eq '-C');
  20
  21 my %commands     = ();
  22 my $cmdre        = qr/^\s*int\s+([a-z_][a-z0-9_]*)_main\(\s*int\s+argc\s*,/;
  23 my $apps_openssl = shift @ARGV;
  24 my $YEAR         = [localtime()]->[5] + 1900;
  25
  26 # because the program apps/openssl has object files as sources, and
  27 # they then have the corresponding C files as source, we need to chain
  28 # the lookups in %unified_info
  29 my @openssl_source =
  30     map { @{$unified_info{sources}->{$_}} }
  31     grep { /\.o$/ }
  32         @{$unified_info{sources}->{$apps_openssl}};
  33
  34 foreach my $filename (@openssl_source) {
  35     open F, $filename or die "Couldn't open $filename: $!\n";
  36     foreach ( grep /$cmdre/, <F> ) {
  37         my @foo = /$cmdre/;
  38         $commands{$1} = 1;
  39     }
  40     close F;
  41 }
  42
  43 @ARGV = sort keys %commands;
  44
  45 if ($opt eq '-H') {
  46     print <<"EOF";
  47 /*
  48  * WARNING: do not edit!
  49  * Generated by apps/progs.pl
  50  *
  51  * Copyright 1995-$YEAR The OpenSSL Project Authors. All Rights Reserved.
  52  *
  53  * Licensed under the Apache License 2.0 (the "License").  You may not use
  54  * this file except in compliance with the License.  You can obtain a copy
  55  * in the file LICENSE in the source distribution or at
  56  * https://www.openssl.org/source/license.html
  57  */
  58
  59 #include "function.h"
  60
  61 EOF
  62
  63     foreach (@ARGV) {
  64         printf "extern int %s_main(int argc, char *argv[]);\n", $_;
  65     }
  66     print "\n";
  67
  68     foreach (@ARGV) {
  69         printf "extern const OPTIONS %s_options[];\n", $_;
  70     }
  71     print "\n";
  72     print "extern FUNCTION functions[];\n";
  73 }
  74
  75 if ($opt eq '-C') {
  76     print <<"EOF";
  77 /*
  78  * WARNING: do not edit!
  79  * Generated by apps/progs.pl
  80  *
  81  * Copyright 1995-$YEAR The OpenSSL Project Authors. All Rights Reserved.
  82  *
  83  * Licensed under the Apache License 2.0 (the "License").  You may not use
  84  * this file except in compliance with the License.  You can obtain a copy
  85  * in the file LICENSE in the source distribution or at
  86  * https://www.openssl.org/source/license.html
  87  */
  88
  89 #include "progs.h"
  90
  91 EOF
  92
  93     my %cmd_disabler = (
  94         ciphers  => "sock",
  95         pkcs12   => "des",
  96     );
  97     my %cmd_deprecated = (
  98         rsa      => [ "3_0", "pkey",      "rsa" ],
  99         genrsa   => [ "3_0", "genpkey",   "rsa" ],
 100         rsautl   => [ "3_0", "pkeyutl",   "rsa" ],
 101         dhparam  => [ "3_0", "pkeyparam", "dh" ],
 102         dsaparam => [ "3_0", "pkeyparam", "dsa" ],
 103         dsa      => [ "3_0", "pkey",      "dsa" ],
 104         gendsa   => [ "3_0", "genpkey",   "dsa" ],
 105         ec       => [ "3_0", "pkey",      "ec" ],
 106         ecparam  => [ "3_0", "pkeyparam", "ec" ],
 107     );
 108
 109     print "FUNCTION functions[] = {\n";
 110     foreach my $cmd ( @ARGV ) {
 111         my $str =
 112             "    {FT_general, \"$cmd\", ${cmd}_main, ${cmd}_options, NULL},\n";
 113         if ($cmd =~ /^s_/) {
 114             print "#ifndef OPENSSL_NO_SOCK\n${str}#endif\n";
 115         } elsif (my $deprecated = $cmd_deprecated{$cmd}) {
 116             my @dep = @{$deprecated};
 117             print "#if ";
 118             if ($dep[2]) {
 119                 print "!defined(OPENSSL_NO_" . uc($dep[2]) . ") && ";
 120             }
 121             print "!defined(OPENSSL_NO_DEPRECATED_" . $dep[0] . ")";
 122             my $dalt = "\"" . $dep[1] . "\"";
 123             $str =~ s/NULL/$dalt/;
 124             print "\n${str}#endif\n";
 125         } elsif (grep { $cmd eq $_ } @disablables) {
 126             print "#ifndef OPENSSL_NO_" . uc($cmd) . "\n${str}#endif\n";
 127         } elsif (my $disabler = $cmd_disabler{$cmd}) {
 128             print "#ifndef OPENSSL_NO_" . uc($disabler) . "\n${str}#endif\n";
 129         } else {
 130             print $str;
 131         }
 132     }
 133
 134     my %md_disabler = (
 135         blake2b512 => "blake2",
 136         blake2s256 => "blake2",
 137     );
 138     foreach my $cmd (
 139         "md2", "md4", "md5",
 140         "gost",
 141         "sha1", "sha224", "sha256", "sha384",
 142         "sha512", "sha512-224", "sha512-256",
 143         "sha3-224", "sha3-256", "sha3-384", "sha3-512",
 144         "shake128", "shake256",
 145         "mdc2", "rmd160", "blake2b512", "blake2s256",
 146         "sm3"
 147     ) {
 148         my $str = "    {FT_md, \"$cmd\", dgst_main, NULL, NULL},\n";
 149         if (grep { $cmd eq $_ } @disablables) {
 150             print "#ifndef OPENSSL_NO_" . uc($cmd) . "\n${str}#endif\n";
 151         } elsif (my $disabler = $md_disabler{$cmd}) {
 152             print "#ifndef OPENSSL_NO_" . uc($disabler) . "\n${str}#endif\n";
 153         } else {
 154             print $str;
 155         }
 156     }
 157
 158     my %cipher_disabler = (
 159         des3  => "des",
 160         desx  => "des",
 161         cast5 => "cast",
 162     );
 163     foreach my $cmd (
 164         "aes-128-cbc", "aes-128-ecb",
 165         "aes-192-cbc", "aes-192-ecb",
 166         "aes-256-cbc", "aes-256-ecb",
 167         "aria-128-cbc", "aria-128-cfb",
 168         "aria-128-ctr", "aria-128-ecb", "aria-128-ofb",
 169         "aria-128-cfb1", "aria-128-cfb8",
 170         "aria-192-cbc", "aria-192-cfb",
 171         "aria-192-ctr", "aria-192-ecb", "aria-192-ofb",
 172         "aria-192-cfb1", "aria-192-cfb8",
 173         "aria-256-cbc", "aria-256-cfb",
 174         "aria-256-ctr", "aria-256-ecb", "aria-256-ofb",
 175         "aria-256-cfb1", "aria-256-cfb8",
 176         "camellia-128-cbc", "camellia-128-ecb",
 177         "camellia-192-cbc", "camellia-192-ecb",
 178         "camellia-256-cbc", "camellia-256-ecb",
 179         "base64", "zlib",
 180         "des", "des3", "desx", "idea", "seed", "rc4", "rc4-40",
 181         "rc2", "bf", "cast", "rc5",
 182         "des-ecb", "des-ede", "des-ede3",
 183         "des-cbc", "des-ede-cbc","des-ede3-cbc",
 184         "des-cfb", "des-ede-cfb","des-ede3-cfb",
 185         "des-ofb", "des-ede-ofb","des-ede3-ofb",
 186         "idea-cbc","idea-ecb", "idea-cfb", "idea-ofb",
 187         "seed-cbc","seed-ecb", "seed-cfb", "seed-ofb",
 188         "rc2-cbc", "rc2-ecb", "rc2-cfb","rc2-ofb", "rc2-64-cbc", "rc2-40-cbc",
 189         "bf-cbc", "bf-ecb", "bf-cfb", "bf-ofb",
 190         "cast5-cbc","cast5-ecb", "cast5-cfb","cast5-ofb",
 191         "cast-cbc", "rc5-cbc", "rc5-ecb", "rc5-cfb", "rc5-ofb",
 192         "sm4-cbc", "sm4-ecb", "sm4-cfb", "sm4-ofb", "sm4-ctr"
 193     ) {
 194         my $str = "    {FT_cipher, \"$cmd\", enc_main, enc_options, NULL},\n";
 195         (my $algo = $cmd) =~ s/-.*//g;
 196         if ($cmd eq "zlib") {
 197             print "#ifdef ZLIB\n${str}#endif\n";
 198         } elsif (grep { $algo eq $_ } @disablables) {
 199             print "#ifndef OPENSSL_NO_" . uc($algo) . "\n${str}#endif\n";
 200         } elsif (my $disabler = $cipher_disabler{$algo}) {
 201             print "#ifndef OPENSSL_NO_" . uc($disabler) . "\n${str}#endif\n";
 202         } else {
 203             print $str;
 204         }
 205     }
 206
 207     print "    {0, NULL, NULL, NULL, NULL}\n};\n";
 208 }