Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2022 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::fallback "$FindBin::Bin/external/perl/MODULES.txt";
  21 use OpenSSL::Glob;
  22 use OpenSSL::Template;
  23 use OpenSSL::config;
  24
  25 # see INSTALL.md for instructions.
  26
  27 my $orig_death_handler = $SIG{__DIE__};
  28 $SIG{__DIE__} = \&death_handler;
  29
  30 my $usage="Usage: Configure [no-<feature> ...] [enable-<feature> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]thread-pool] [[no-]default-thread-pool] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  31
  32 my $banner = <<"EOF";
  33
  34 **********************************************************************
  35 ***                                                                ***
  36 ***   OpenSSL has been successfully configured                     ***
  37 ***                                                                ***
  38 ***   If you encounter a problem while building, please open an    ***
  39 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
  40 ***   and include the output from the following command:           ***
  41 ***                                                                ***
  42 ***       perl configdata.pm --dump                                ***
  43 ***                                                                ***
  44 ***   (If you are new to OpenSSL, you might want to consult the    ***
  45 ***   'Troubleshooting' section in the INSTALL.md file first)      ***
  46 ***                                                                ***
  47 **********************************************************************
  48 EOF
  49
  50 # Options:
  51 #
  52 # --config      add the given configuration file, which will be read after
  53 #               any "Configurations*" files that are found in the same
  54 #               directory as this script.
  55 # --prefix      prefix for the OpenSSL installation, which includes the
  56 #               directories bin, lib, include, share/man, share/doc/openssl
  57 #               This becomes the value of INSTALLTOP in Makefile
  58 #               (Default: /usr/local)
  59 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  60 #               If it's a relative directory, it will be added on the directory
  61 #               given with --prefix.
  62 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  63 #               (Default: PREFIX/ssl)
  64 # --banner=".." Output specified text instead of default completion banner
  65 #
  66 # -w            Don't wait after showing a Configure warning
  67 #
  68 # --cross-compile-prefix Add specified prefix to binutils components.
  69 #
  70 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0
  71 #               Define the public APIs as they were for that version
  72 #               including patch releases.  If 'no-deprecated' is also
  73 #               given, do not compile support for interfaces deprecated
  74 #               up to and including the specified OpenSSL version.
  75 #
  76 # no-hw-xxx     do not compile support for specific crypto hardware.
  77 #               Generic OpenSSL-style methods relating to this support
  78 #               are always compiled but return NULL if the hardware
  79 #               support isn't compiled.
  80 # no-hw         do not compile support for any crypto hardware.
  81 # [no-]threads  [don't] try to create a library that is suitable for
  82 #               multithreaded applications (default is "threads" if we
  83 #               know how to do it)
  84 # [no-]thread-pool
  85 #               [don't] allow thread pool functionality
  86 # [no-]default-thread-pool
  87 #               [don't] allow default thread pool functionality
  88 # [no-]shared   [don't] try to create shared libraries when supported.
  89 # [no-]pic      [don't] try to build position independent code when supported.
  90 #               If disabled, it also disables shared and dynamic-engine.
  91 # no-asm        do not use assembler
  92 # no-egd        do not compile support for the entropy-gathering daemon APIs
  93 # [no-]zlib     [don't] compile support for zlib compression.
  94 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  95 #               library and will be loaded at run-time by the OpenSSL library.
  96 # sctp          include SCTP support
  97 # enable-quic   include QUIC support (currently just for developers as the
  98 #               implementation is by no means complete and usable)
  99 # no-uplink     Don't build support for UPLINK interface.
 100 # enable-weak-ssl-ciphers
 101 #               Enable weak ciphers that are disabled by default.
 102 # 386           generate 80386 code in assembly modules
 103 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
 104 #               mentioned '386' option implies this one
 105 # no-<cipher>   build without specified algorithm (dsa, idea, rc5, ...)
 106 # -<xxx> +<xxx> All options which are unknown to the 'Configure' script are
 107 # /<xxx>        passed through to the compiler. Unix-style options beginning
 108 #               with a '-' or '+' are recognized, as well as Windows-style
 109 #               options beginning with a '/'. If the option contains arguments
 110 #               separated by spaces, then the URL-style notation %20 can be
 111 #               used for the space character in order to avoid having to quote
 112 #               the option. For example, -opt%20arg gets expanded to -opt arg.
 113 #               In fact, any ASCII character can be encoded as %xx using its
 114 #               hexadecimal encoding.
 115 # -static       while -static is also a pass-through compiler option (and
 116 #               as such is limited to environments where it's actually
 117 #               meaningful), it triggers a number configuration options,
 118 #               namely no-pic, no-shared and no-threads. It is
 119 #               argued that the only reason to produce statically linked
 120 #               binaries (and in context it means executables linked with
 121 #               -static flag, and not just executables linked with static
 122 #               libcrypto.a) is to eliminate dependency on specific run-time,
 123 #               a.k.a. libc version. The mentioned config options are meant
 124 #               to achieve just that. Unfortunately on Linux it's impossible
 125 #               to eliminate the dependency completely for openssl executable
 126 #               because of getaddrinfo and gethostbyname calls, which can
 127 #               invoke dynamically loadable library facility anyway to meet
 128 #               the lookup requests. For this reason on Linux statically
 129 #               linked openssl executable has rather debugging value than
 130 #               production quality.
 131 #
 132 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
 133 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
 134 # Following are set automatically by this script
 135 #
 136 # MD5_ASM       use some extra md5 assembler,
 137 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 138 # RMD160_ASM    use some extra ripemd160 assembler,
 139 # SHA256_ASM    sha256_block is implemented in assembler
 140 # SHA512_ASM    sha512_block is implemented in assembler
 141 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 142
 143 # Minimum warning options... any contributions to OpenSSL should at least
 144 # get past these.  Note that we only use these with C compilers, not with
 145 # C++ compilers.
 146
 147 # -DPEDANTIC complements -pedantic and is meant to mask code that
 148 # is not strictly standard-compliant and/or implementation-specific,
 149 # e.g. inline assembly, disregards to alignment requirements, such
 150 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 151 # to be used even in sanitized builds, because sanitizer too is
 152 # supposed to and does take notice of non-standard behaviour. Then
 153 # -pedantic with pre-C9x compiler would also complain about 'long
 154 # long' not being supported. As 64-bit algorithms are common now,
 155 # it grew impossible to resolve this without sizeable additional
 156 # code, so we just tell compiler to be pedantic about everything
 157 # but 'long long' type.
 158
 159 my @gcc_devteam_warn = qw(
 160     -DPEDANTIC -pedantic -Wno-long-long -DUNUSEDRESULT_DEBUG
 161     -Wall
 162     -Wmissing-declarations
 163     -Wextra
 164     -Wno-unused-parameter
 165     -Wno-missing-field-initializers
 166     -Wswitch
 167     -Wsign-compare
 168     -Wshadow
 169     -Wformat
 170     -Wno-type-limits
 171     -Wno-tautological-constant-out-of-range-compare
 172     -Wundef
 173     -Werror
 174     -Wmissing-prototypes
 175     -Wstrict-prototypes
 176 );
 177
 178 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 179 # TODO(openssl-team): fix problems and investigate if (at least) the
 180 # following warnings can also be enabled:
 181 #       -Wcast-align
 182 #       -Wunreachable-code -- no, too ugly/compiler-specific
 183 #       -Wlanguage-extension-token -- no, we use asm()
 184 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 185 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 186 my @clang_devteam_warn = qw(
 187     -Wno-unknown-warning-option
 188     -Wswitch-default
 189     -Wno-parentheses-equality
 190     -Wno-language-extension-token
 191     -Wno-extended-offsetof
 192     -Wconditional-uninitialized
 193     -Wincompatible-pointer-types-discards-qualifiers
 194     -Wmissing-variable-declarations
 195 );
 196
 197 my @cl_devteam_warn = qw(
 198     /WX
 199 );
 200
 201 my $strict_warnings = 0;
 202
 203 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 204 # which would cover all BSD flavors. -pthread applies to them all,
 205 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 206 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 207 # which has to be accompanied by explicit -D_THREAD_SAFE and
 208 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 209 # seems to be sufficient?
 210 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 211
 212 #
 213 # API compatibility name to version number mapping.
 214 #
 215 my $apitable = {
 216     # This table expresses when API additions or changes can occur.
 217     # The numbering used changes from 3.0 and on because we updated
 218     # (solidified) our version numbering scheme at that point.
 219
 220     # From 3.0 and on, we internalise the given version number in decimal
 221     # as MAJOR * 10000 + MINOR * 100 + 0
 222     "3.0.0" => 30000,
 223     "3.0"   => 30000,
 224
 225     # Note that before 3.0, we didn't have the same version number scheme.
 226     # Still, the numbering we use here covers what we need.
 227     "1.1.1" => 10101,
 228     "1.1.0" => 10100,
 229     "1.0.2" => 10002,
 230     "1.0.1" => 10001,
 231     "1.0.0" => 10000,
 232     "0.9.8" =>   908,
 233 };
 234
 235 # For OpenSSL::config::get_platform
 236 my %guess_opts = ();
 237
 238 my $dryrun = 0;
 239
 240 our %table = ();
 241 our %config = ();
 242 our %withargs = ();
 243 our $now_printing;      # set to current entry's name in print_table_entry
 244                         # (todo: right thing would be to encapsulate name
 245                         # into %target [class] and make print_table_entry
 246                         # a method)
 247
 248 # Forward declarations ###############################################
 249
 250 # read_config(filename)
 251 #
 252 # Reads a configuration file and populates %table with the contents
 253 # (which the configuration file places in %targets).
 254 sub read_config;
 255
 256 # resolve_config(target)
 257 #
 258 # Resolves all the late evaluations, inheritances and so on for the
 259 # chosen target and any target it inherits from.
 260 sub resolve_config;
 261
 262
 263 # Information collection #############################################
 264
 265 # Unified build supports separate build dir
 266 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 267 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 268
 269 # File::Spec::Unix doesn't detect case insensitivity, so we make sure to
 270 # check if the source and build directory are really the same, and make
 271 # them so.  This avoids all kinds of confusion later on.
 272 # We must check @File::Spec::ISA rather than using File::Spec->isa() to
 273 # know if File::Spec ended up loading File::Spec::Unix.
 274 $srcdir = $blddir
 275     if (grep(/::Unix$/, @File::Spec::ISA)
 276         && samedir($srcdir, $blddir));
 277
 278 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 279
 280 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 281
 282 $config{sourcedir} = abs2rel($srcdir, $blddir);
 283 $config{builddir} = abs2rel($blddir, $blddir);
 284 # echo -n 'holy hand grenade of antioch' | openssl sha256
 285 $config{FIPSKEY} =
 286     'f4556650ac31d35461610bac4ed81b1a181b2d8a43ea2854cbae22ca74560813';
 287
 288 # Collect reconfiguration information if needed
 289 my @argvcopy=@ARGV;
 290
 291 if (grep /^reconf(igure)?$/, @argvcopy) {
 292     die "reconfiguring with other arguments present isn't supported"
 293         if scalar @argvcopy > 1;
 294     if (-f "./configdata.pm") {
 295         my $file = "./configdata.pm";
 296         unless (my $return = do $file) {
 297             die "couldn't parse $file: $@" if $@;
 298             die "couldn't do $file: $!"    unless defined $return;
 299             die "couldn't run $file"       unless $return;
 300         }
 301
 302         @argvcopy = defined($configdata::config{perlargv}) ?
 303             @{$configdata::config{perlargv}} : ();
 304         die "Incorrect data to reconfigure, please do a normal configuration\n"
 305             if (grep(/^reconf/,@argvcopy));
 306         $config{perlenv} = $configdata::config{perlenv} // {};
 307     } else {
 308         die "Insufficient data to reconfigure, please do a normal configuration\n";
 309     }
 310 }
 311
 312 $config{perlargv} = [ @argvcopy ];
 313
 314 # Historical: if known directories in crypto/ have been removed, it means
 315 # that those sub-systems are disabled.
 316 # (the other option would be to removed them from the SUBDIRS statement in
 317 # crypto/build.info)
 318 # We reverse the input list for cosmetic purely reasons, to compensate that
 319 # 'unshift' adds at the front of the list (i.e. in reverse input order).
 320 foreach ( reverse sort( 'aes', 'aria', 'bf', 'camellia', 'cast', 'des', 'dh',
 321                         'dsa', 'ec', 'hmac', 'idea', 'md2', 'md5', 'mdc2',
 322                         'rc2', 'rc4', 'rc5', 'ripemd', 'seed', 'sha',
 323                         'sm2', 'sm3', 'sm4') ) {
 324     unshift @argvcopy, "no-$_" if ! -d catdir($srcdir, 'crypto', $_);
 325 }
 326
 327 # Collect version numbers
 328 my %version = ();
 329
 330 collect_information(
 331     collect_from_file(catfile($srcdir,'VERSION.dat')),
 332     qr/\s*(\w+)\s*=\s*(.*?)\s*$/ =>
 333         sub {
 334             # Only define it if there is a value at all
 335             if ($2 ne '') {
 336                 my $k = $1;
 337                 my $v = $2;
 338                 # Some values are quoted.  Trim the quotes
 339                 $v = $1 if $v =~ /^"(.*)"$/;
 340                 $version{uc $k} = $v;
 341             }
 342         },
 343     "OTHERWISE" =>
 344         sub { die "Something wrong with this line:\n$_\nin $srcdir/VERSION.dat" },
 345     );
 346
 347 $config{major} = $version{MAJOR} // 'unknown';
 348 $config{minor} = $version{MINOR} // 'unknown';
 349 $config{patch} = $version{PATCH} // 'unknown';
 350 $config{prerelease} =
 351     defined $version{PRE_RELEASE_TAG} ? "-$version{PRE_RELEASE_TAG}" : '';
 352 $config{build_metadata} =
 353     defined $version{BUILD_METADATA} ? "+$version{BUILD_METADATA}" : '';
 354 $config{shlib_version} = $version{SHLIB_VERSION} // 'unknown';
 355 $config{release_date} = $version{RELEASE_DATE} // 'xx XXX xxxx';
 356
 357 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 358 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 359
 360 die "erroneous version information in VERSION.dat: ",
 361     "$config{version}, $config{shlib_version}\n"
 362     unless (defined $version{MAJOR}
 363             && defined $version{MINOR}
 364             && defined $version{PATCH}
 365             && defined $version{SHLIB_VERSION});
 366
 367 # Collect target configurations
 368
 369 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 370 foreach (sort glob($pattern)) {
 371     &read_config($_);
 372 }
 373
 374 if (defined env($local_config_envname)) {
 375     if ($^O eq 'VMS') {
 376         # VMS environment variables are logical names,
 377         # which can be used as is
 378         $pattern = $local_config_envname . ':' . '*.conf';
 379     } else {
 380         $pattern = catfile(env($local_config_envname), '*.conf');
 381     }
 382
 383     foreach (sort glob($pattern)) {
 384         &read_config($_);
 385     }
 386 }
 387
 388 # Save away perl command information
 389 $config{perl_cmd} = $^X;
 390 $config{perl_version} = $Config{version};
 391 $config{perl_archname} = $Config{archname};
 392
 393 $config{prefix}="";
 394 $config{openssldir}="";
 395 $config{processor}="";
 396 $config{libdir}="";
 397 my $auto_threads=1;    # enable threads automatically? true by default
 398 my $default_ranlib;
 399
 400 # Known TLS and DTLS protocols
 401 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 402 my @dtls = qw(dtls1 dtls1_2);
 403
 404 # Explicitly known options that are possible to disable.  They can
 405 # be regexps, and will be used like this: /^no-${option}$/
 406 # For developers: keep it sorted alphabetically
 407
 408 my @disablables = (
 409     "acvp-tests",
 410     "afalgeng",
 411     "aria",
 412     "asan",
 413     "asm",
 414     "async",
 415     "autoalginit",
 416     "autoerrinit",
 417     "autoload-config",
 418     "bf",
 419     "blake2",
 420     "brotli",
 421     "brotli-dynamic",
 422     "buildtest-c++",
 423     "bulk",
 424     "cached-fetch",
 425     "camellia",
 426     "capieng",
 427     "winstore",
 428     "cast",
 429     "chacha",
 430     "cmac",
 431     "cmp",
 432     "cms",
 433     "comp",
 434     "crypto-mdebug",
 435     "ct",
 436     "default-thread-pool",
 437     "deprecated",
 438     "des",
 439     "devcryptoeng",
 440     "dgram",
 441     "dh",
 442     "dsa",
 443     "dso",
 444     "dtls",
 445     "dynamic-engine",
 446     "ec",
 447     "ec2m",
 448     "ec_nistp_64_gcc_128",
 449     "ecdh",
 450     "ecdsa",
 451     "egd",
 452     "engine",
 453     "err",
 454     "external-tests",
 455     "filenames",
 456     "fips",
 457     "fips-securitychecks",
 458     "fuzz-afl",
 459     "fuzz-libfuzzer",
 460     "gost",
 461     "idea",
 462     "ktls",
 463     "legacy",
 464     "loadereng",
 465     "makedepend",
 466     "md2",
 467     "md4",
 468     "mdc2",
 469     "module",
 470     "msan",
 471     "multiblock",
 472     "nextprotoneg",
 473     "ocb",
 474     "ocsp",
 475     "padlockeng",
 476     "pic",
 477     "pinshared",
 478     "poly1305",
 479     "posix-io",
 480     "psk",
 481     "quic",
 482     "rc2",
 483     "rc4",
 484     "rc5",
 485     "rdrand",
 486     "rfc3779",
 487     "rmd160",
 488     "scrypt",
 489     "sctp",
 490     "secure-memory",
 491     "seed",
 492     "shared",
 493     "siphash",
 494     "siv",
 495     "sm2",
 496     "sm3",
 497     "sm4",
 498     "sock",
 499     "srp",
 500     "srtp",
 501     "sse2",
 502     "ssl",
 503     "ssl-trace",
 504     "static-engine",
 505     "stdio",
 506     "tests",
 507     "tfo",
 508     "thread-pool",
 509     "threads",
 510     "tls",
 511     "trace",
 512     "ts",
 513     "ubsan",
 514     "ui-console",
 515     "unit-test",
 516     "uplink",
 517     "weak-ssl-ciphers",
 518     "whirlpool",
 519     "zlib",
 520     "zlib-dynamic",
 521     "zstd",
 522     "zstd-dynamic",
 523     );
 524 foreach my $proto ((@tls, @dtls))
 525         {
 526         push(@disablables, $proto);
 527         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 528         }
 529
 530 # Internal disablables, for aliasing purposes.  They serve no special
 531 # purpose here, but allow scripts to get to know them through configdata.pm,
 532 # where these are merged with @disablables.
 533 # The actual aliasing mechanism is done via %disable_cascades
 534 my @disablables_int = qw(
 535     crmf
 536     );
 537
 538 my %deprecated_disablables = (
 539     "ssl2" => undef,
 540     "buf-freelists" => undef,
 541     "crypto-mdebug-backtrace" => undef,
 542     "hw" => "hw",               # causes cascade, but no macro
 543     "hw-padlock" => "padlockeng",
 544     "ripemd" => "rmd160",
 545     "ui" => "ui-console",
 546     "heartbeats" => undef,
 547     );
 548
 549 # All of the following are disabled by default:
 550
 551 our %disabled = ( # "what"         => "comment"
 552                   "fips"                => "default",
 553                   "asan"                => "default",
 554                   "brotli"              => "default",
 555                   "brotli-dynamic"      => "default",
 556                   "buildtest-c++"       => "default",
 557                   "crypto-mdebug"       => "default",
 558                   "crypto-mdebug-backtrace" => "default",
 559                   "devcryptoeng"        => "default",
 560                   "ec_nistp_64_gcc_128" => "default",
 561                   "egd"                 => "default",
 562                   "external-tests"      => "default",
 563                   "fuzz-afl"            => "default",
 564                   "fuzz-libfuzzer"      => "default",
 565                   "ktls"                => "default",
 566                   "md2"                 => "default",
 567                   "msan"                => "default",
 568                   "quic"                => "default",
 569                   "rc5"                 => "default",
 570                   "sctp"                => "default",
 571                   "ssl3"                => "default",
 572                   "ssl3-method"         => "default",
 573                   "tfo"                 => "default",
 574                   "trace"               => "default",
 575                   "ubsan"               => "default",
 576                   "unit-test"           => "default",
 577                   "weak-ssl-ciphers"    => "default",
 578                   "zlib"                => "default",
 579                   "zlib-dynamic"        => "default",
 580                   "zstd"                => "default",
 581                   "zstd-dynamic"        => "default",
 582                 );
 583
 584 # Note: => pair form used for aesthetics, not to truly make a hash table
 585 my @disable_cascades = (
 586     # "what"            => [ "cascade", ... ]
 587     "bulk"              => [ "shared", "dso",
 588                              "aria", "async", "autoload-config",
 589                              "blake2", "bf", "camellia", "cast", "chacha",
 590                              "cmac", "cms", "cmp", "comp", "ct",
 591                              "des", "dgram", "dh", "dsa",
 592                              "ec", "engine",
 593                              "filenames",
 594                              "idea", "ktls",
 595                              "md4", "multiblock", "nextprotoneg",
 596                              "ocsp", "ocb", "poly1305", "psk",
 597                              "rc2", "rc4", "rmd160",
 598                              "seed", "siphash", "siv",
 599                              "sm3", "sm4", "srp",
 600                              "srtp", "ssl3-method", "ssl-trace",
 601                              "tfo",
 602                              "ts", "ui-console", "whirlpool",
 603                              "fips-securitychecks" ],
 604     sub { $config{processor} eq "386" }
 605                         => [ "sse2" ],
 606     "ssl"               => [ "ssl3" ],
 607     "ssl3-method"       => [ "ssl3" ],
 608     "zlib"              => [ "zlib-dynamic" ],
 609     "brotli"            => [ "brotli-dynamic" ],
 610     "zstd"              => [ "zstd-dynamic" ],
 611     "des"               => [ "mdc2" ],
 612     "ec"                => [ "ec2m", "ecdsa", "ecdh", "sm2", "gost" ],
 613     "dgram"             => [ "dtls", "quic", "sctp" ],
 614     "sock"              => [ "dgram", "tfo" ],
 615     "dtls"              => [ @dtls ],
 616     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 617                         => [ "dtls" ],
 618
 619     "tls"               => [ @tls ],
 620     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 621                         => [ "tls" ],
 622
 623     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 624
 625     # If no modules, then no dynamic engines either
 626     "module"            => [ "dynamic-engine" ],
 627
 628     # Without shared libraries, dynamic engines aren't possible.
 629     # This is due to them having to link with libcrypto and register features
 630     # using the ENGINE functionality, and since that relies on global tables,
 631     # those *have* to be exactly the same as the ones accessed from the app,
 632     # which cannot be guaranteed if shared libraries aren't present.
 633     # (note that even with shared libraries, both the app and dynamic engines
 634     # must be linked with the same library)
 635     "shared"            => [ "dynamic-engine", "uplink" ],
 636     "dso"               => [ "dynamic-engine", "module" ],
 637     # Other modules don't necessarily have to link with libcrypto, so shared
 638     # libraries do not have to be a condition to produce those.
 639
 640     # Without position independent code, there can be no shared libraries
 641     # or modules.
 642     "pic"               => [ "shared", "module" ],
 643
 644     "module"            => [ "fips", "dso" ],
 645
 646     "engine"            => [ "dynamic-engine", grep(/eng$/, @disablables) ],
 647     "dynamic-engine"    => [ "loadereng" ],
 648     "hw"                => [ "padlockeng" ],
 649
 650     # no-autoalginit is only useful when building non-shared
 651     "autoalginit"       => [ "shared", "apps", "fips" ],
 652
 653     "stdio"             => [ "apps", "capieng", "egd" ],
 654     "apps"              => [ "tests" ],
 655     "tests"             => [ "external-tests" ],
 656     "comp"              => [ "zlib", "brotli", "zstd" ],
 657     "sm3"               => [ "sm2" ],
 658     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 659
 660     sub { !$disabled{"msan"} } => [ "asm" ],
 661
 662     "cmac"              => [ "siv" ],
 663     "legacy"            => [ "md2" ],
 664
 665     "cmp"               => [ "crmf" ],
 666
 667     "fips"              => [ "fips-securitychecks", "acvp-tests" ],
 668
 669     "threads"           => [ "thread-pool" ],
 670     "thread-pool"       => [ "default-thread-pool" ],
 671
 672     "deprecated-3.0"    => [ "engine", "srp" ]
 673     );
 674
 675 # Avoid protocol support holes.  Also disable all versions below N, if version
 676 # N is disabled while N+1 is enabled.
 677 #
 678 my @list = (reverse @tls);
 679 while ((my $first, my $second) = (shift @list, shift @list)) {
 680     last unless @list;
 681     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 682                               => [ @list ] );
 683     unshift @list, $second;
 684 }
 685 my @list = (reverse @dtls);
 686 while ((my $first, my $second) = (shift @list, shift @list)) {
 687     last unless @list;
 688     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 689                               => [ @list ] );
 690     unshift @list, $second;
 691 }
 692
 693 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 694 # To remove something from %disabled, use "enable-foo".
 695 # For symmetry, "disable-foo" is a synonym for "no-foo".
 696
 697 # For the "make variables" CPPINCLUDES and CPPDEFINES, we support lists with
 698 # platform specific list separators.  Users from those platforms should
 699 # recognise those separators from how you set up the PATH to find executables.
 700 # The default is the Unix like separator, :, but as an exception, we also
 701 # support the space as separator.
 702 my $list_separator_re =
 703     { VMS           => qr/(?<!\^),/,
 704       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 705 # All the "make variables" we support
 706 # Some get pre-populated for the sake of backward compatibility
 707 # (we supported those before the change to "make variable" support.
 708 my %user = (
 709     AR          => env('AR'),
 710     ARFLAGS     => [],
 711     AS          => undef,
 712     ASFLAGS     => [],
 713     CC          => env('CC'),
 714     CFLAGS      => [ env('CFLAGS') || () ],
 715     CXX         => env('CXX'),
 716     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 717     CPP         => undef,
 718     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 719     CPPDEFINES  => [],  # Alternative for -D
 720     CPPINCLUDES => [],  # Alternative for -I
 721     CROSS_COMPILE => env('CROSS_COMPILE'),
 722     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 723     LD          => undef,
 724     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 725     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 726     MT          => undef,
 727     MTFLAGS     => [],
 728     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 729     RANLIB      => env('RANLIB'),
 730     RC          => env('RC') || env('WINDRES'),
 731     RCFLAGS     => [ env('RCFLAGS') || () ],
 732     RM          => undef,
 733    );
 734 # Info about what "make variables" may be prefixed with the cross compiler
 735 # prefix.  This should NEVER mention any such variable with a list for value.
 736 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 737 # The same but for flags given as Configure options.  These are *additional*
 738 # input, as opposed to the VAR=string option that override the corresponding
 739 # config target attributes
 740 my %useradd = (
 741     CPPDEFINES  => [],
 742     CPPINCLUDES => [],
 743     CPPFLAGS    => [],
 744     CFLAGS      => [],
 745     CXXFLAGS    => [],
 746     LDFLAGS     => [],
 747     LDLIBS      => [],
 748     RCFLAGS     => [],
 749    );
 750
 751 my %user_synonyms = (
 752     HASHBANGPERL=> 'PERL',
 753     RC          => 'WINDRES',
 754    );
 755
 756 # Some target attributes have been renamed, this is the translation table
 757 my %target_attr_translate =(
 758     ar          => 'AR',
 759     as          => 'AS',
 760     cc          => 'CC',
 761     cxx         => 'CXX',
 762     cpp         => 'CPP',
 763     hashbangperl => 'HASHBANGPERL',
 764     ld          => 'LD',
 765     mt          => 'MT',
 766     ranlib      => 'RANLIB',
 767     rc          => 'RC',
 768     rm          => 'RM',
 769    );
 770
 771 # Initialisers coming from 'config' scripts
 772 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 773 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 774 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 775 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 776 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 777 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 778 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 779
 780 $config{openssl_api_defines}=[];
 781 $config{openssl_sys_defines}=[];
 782 $config{openssl_feature_defines}=[];
 783 $config{options}="";
 784 $config{build_type} = "release";
 785 my $target="";
 786
 787 my %cmdvars = ();               # Stores FOO='blah' type arguments
 788 my %unsupported_options = ();
 789 my %deprecated_options = ();
 790 # If you change this, update apps/version.c
 791 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 792 my @seed_sources = ();
 793 while (@argvcopy)
 794         {
 795         $_ = shift @argvcopy;
 796
 797         # Support env variable assignments among the options
 798         if (m|^(\w+)=(.+)?$|)
 799                 {
 800                 $cmdvars{$1} = $2;
 801                 # Every time a variable is given as a configuration argument,
 802                 # it acts as a reset if the variable.
 803                 if (exists $user{$1})
 804                         {
 805                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 806                         }
 807                 #if (exists $useradd{$1})
 808                 #       {
 809                 #       $useradd{$1} = [];
 810                 #       }
 811                 next;
 812                 }
 813
 814         # VMS is a case insensitive environment, and depending on settings
 815         # out of our control, we may receive options uppercased.  Let's
 816         # downcase at least the part before any equal sign.
 817         if ($^O eq "VMS")
 818                 {
 819                 s/^([^=]*)/lc($1)/e;
 820                 }
 821
 822         # some people just can't read the instructions, clang people have to...
 823         s/^-no-(?!integrated-as)/no-/;
 824
 825         # rewrite some options in "enable-..." form
 826         s /^-?-?shared$/enable-shared/;
 827         s /^sctp$/enable-sctp/;
 828         s /^threads$/enable-threads/;
 829         s /^zlib$/enable-zlib/;
 830         s /^zlib-dynamic$/enable-zlib-dynamic/;
 831         s /^fips$/enable-fips/;
 832
 833         if (/^(no|disable|enable)-(.+)$/)
 834                 {
 835                 my $word = $2;
 836                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 837                         && !exists $deprecated_disablables{$word}
 838                         && !grep { $word eq $_ } @disablables)
 839                         {
 840                         $unsupported_options{$_} = 1;
 841                         next;
 842                         }
 843                 }
 844         if (/^no-(.+)$/ || /^disable-(.+)$/)
 845                 {
 846                 foreach my $proto ((@tls, @dtls))
 847                         {
 848                         if ($1 eq "$proto-method")
 849                                 {
 850                                 $disabled{"$proto"} = "option($proto-method)";
 851                                 last;
 852                                 }
 853                         }
 854                 if ($1 eq "dtls")
 855                         {
 856                         foreach my $proto (@dtls)
 857                                 {
 858                                 $disabled{$proto} = "option(dtls)";
 859                                 }
 860                         $disabled{"dtls"} = "option(dtls)";
 861                         }
 862                 elsif ($1 eq "ssl")
 863                         {
 864                         # Last one of its kind
 865                         $disabled{"ssl3"} = "option(ssl)";
 866                         }
 867                 elsif ($1 eq "tls")
 868                         {
 869                         # XXX: Tests will fail if all SSL/TLS
 870                         # protocols are disabled.
 871                         foreach my $proto (@tls)
 872                                 {
 873                                 $disabled{$proto} = "option(tls)";
 874                                 }
 875                         }
 876                 elsif ($1 eq "static-engine")
 877                         {
 878                         delete $disabled{"dynamic-engine"};
 879                         }
 880                 elsif ($1 eq "dynamic-engine")
 881                         {
 882                         $disabled{"dynamic-engine"} = "option";
 883                         }
 884                 elsif (exists $deprecated_disablables{$1})
 885                         {
 886                         $deprecated_options{$_} = 1;
 887                         if (defined $deprecated_disablables{$1})
 888                                 {
 889                                 $disabled{$deprecated_disablables{$1}} = "option";
 890                                 }
 891                         }
 892                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 893                         {
 894                         $deprecated_options{$_} = 1;
 895                         }
 896                 else
 897                         {
 898                         $disabled{$1} = "option";
 899                         }
 900                 # No longer an automatic choice
 901                 $auto_threads = 0 if ($1 eq "threads");
 902                 }
 903         elsif (/^enable-(.+)$/)
 904                 {
 905                 if ($1 eq "static-engine")
 906                         {
 907                         $disabled{"dynamic-engine"} = "option";
 908                         }
 909                 elsif ($1 eq "dynamic-engine")
 910                         {
 911                         delete $disabled{"dynamic-engine"};
 912                         }
 913                 elsif ($1 eq "zlib-dynamic")
 914                         {
 915                         delete $disabled{"zlib"};
 916                         }
 917                 elsif ($1 eq "brotli-dynamic")
 918                         {
 919                         delete $disabled{"brotli"};
 920                         }
 921                 elsif ($1 eq "zstd-dynamic")
 922                         {
 923                         delete $disabled{"zstd"};
 924                         }
 925                 my $algo = $1;
 926                 delete $disabled{$algo};
 927
 928                 # No longer an automatic choice
 929                 $auto_threads = 0 if ($1 eq "threads");
 930                 }
 931         elsif (/^-d$/)          # From older 'config'
 932                 {
 933                 $config{build_type} = "debug";
 934                 }
 935         elsif (/^-v$/)          # From older 'config'
 936                 {
 937                 $guess_opts{verbose} = 1;
 938                 }
 939         elsif (/^-w$/)
 940                 {
 941                 $guess_opts{nowait} = 1;
 942                 }
 943         elsif (/^-t$/)          # From older 'config'
 944                 {
 945                 $dryrun = 1;
 946                 }
 947         elsif (/^--strict-warnings$/)
 948                 {
 949                 # Pretend that our strict flags is a C flag, and replace it
 950                 # with the proper flags later on
 951                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 952                 $strict_warnings=1;
 953                 }
 954         elsif (/^--debug$/)
 955                 {
 956                 $config{build_type} = "debug";
 957                 }
 958         elsif (/^--release$/)
 959                 {
 960                 $config{build_type} = "release";
 961                 }
 962         elsif (/^386$/)
 963                 { $config{processor}=386; }
 964         elsif (/^rsaref$/)
 965                 {
 966                 # No RSAref support any more since it's not needed.
 967                 # The check for the option is there so scripts aren't
 968                 # broken
 969                 }
 970         elsif (m|^[-+/]|)
 971                 {
 972                 if (/^--prefix=(.*)$/)
 973                         {
 974                         $config{prefix}=$1;
 975                         die "Directory given with --prefix MUST be absolute\n"
 976                                 unless file_name_is_absolute($config{prefix});
 977                         }
 978                 elsif (/^--api=(.*)$/)
 979                         {
 980                         my $api = $1;
 981                         die "Unknown API compatibility level $api"
 982                                 unless defined $apitable->{$api};
 983                         $config{api}=$apitable->{$api};
 984                         }
 985                 elsif (/^--libdir=(.*)$/)
 986                         {
 987                         $config{libdir}=$1;
 988                         }
 989                 elsif (/^--openssldir=(.*)$/)
 990                         {
 991                         $config{openssldir}=$1;
 992                         }
 993                 elsif (/^--with-zlib-lib=(.*)$/)
 994                         {
 995                         $withargs{zlib_lib}=$1;
 996                         }
 997                 elsif (/^--with-zlib-include=(.*)$/)
 998                         {
 999                         $withargs{zlib_include}=$1;
1000                         }
1001                 elsif (/^--with-brotli-lib=(.*)$/)
1002                         {
1003                         $withargs{brotli_lib}=$1;
1004                         }
1005                 elsif (/^--with-brotli-include=(.*)$/)
1006                         {
1007                         $withargs{brotli_include}=$1;
1008                         }
1009                 elsif (/^--with-zstd-lib=(.*)$/)
1010                         {
1011                         $withargs{zstd_lib}=$1;
1012                         }
1013                 elsif (/^--with-zstd-include=(.*)$/)
1014                         {
1015                         $withargs{zstd_include}=$1;
1016                         }
1017                 elsif (/^--with-fuzzer-lib=(.*)$/)
1018                         {
1019                         $withargs{fuzzer_lib}=$1;
1020                         }
1021                 elsif (/^--with-fuzzer-include=(.*)$/)
1022                         {
1023                         $withargs{fuzzer_include}=$1;
1024                         }
1025                 elsif (/^--with-rand-seed=(.*)$/)
1026                         {
1027                         foreach my $x (split(m|,|, $1))
1028                             {
1029                             die "Unknown --with-rand-seed choice $x\n"
1030                                 if ! grep { $x eq $_ } @known_seed_sources;
1031                             push @seed_sources, $x;
1032                             }
1033                         }
1034                 elsif (/^--fips-key=(.*)$/)
1035                         {
1036                         $user{FIPSKEY}=lc($1);
1037                         die "Non-hex character in FIPS key\n"
1038                            if $user{FIPSKEY} =~ /[^a-f0-9]/;
1039                         die "FIPS key must have even number of characters\n"
1040                            if length $1 & 1;
1041                         die "FIPS key too long (64 bytes max)\n"
1042                            if length $1 > 64;
1043                         }
1044                 elsif (/^--banner=(.*)$/)
1045                         {
1046                         $banner = $1 . "\n";
1047                         }
1048                 elsif (/^--cross-compile-prefix=(.*)$/)
1049                         {
1050                         $user{CROSS_COMPILE}=$1;
1051                         }
1052                 elsif (/^--config=(.*)$/)
1053                         {
1054                         read_config $1;
1055                         }
1056                 elsif (/^-l(.*)$/)
1057                         {
1058                         push @{$useradd{LDLIBS}}, $_;
1059                         }
1060                 elsif (/^-framework$/)
1061                         {
1062                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
1063                         }
1064                 elsif (/^-L(.*)$/ or /^-Wl,/)
1065                         {
1066                         push @{$useradd{LDFLAGS}}, $_;
1067                         }
1068                 elsif (/^-rpath$/ or /^-R$/)
1069                         # -rpath is the OSF1 rpath flag
1070                         # -R is the old Solaris rpath flag
1071                         {
1072                         my $rpath = shift(@argvcopy) || "";
1073                         $rpath .= " " if $rpath ne "";
1074                         push @{$useradd{LDFLAGS}}, $_, $rpath;
1075                         }
1076                 elsif (/^-static$/)
1077                         {
1078                         push @{$useradd{LDFLAGS}}, $_;
1079                         }
1080                 elsif (m|^[-/]D(.*)$|)
1081                         {
1082                         push @{$useradd{CPPDEFINES}}, $1;
1083                         }
1084                 elsif (m|^[-/]I(.*)$|)
1085                         {
1086                         push @{$useradd{CPPINCLUDES}}, $1;
1087                         }
1088                 elsif (/^-Wp,$/)
1089                         {
1090                         push @{$useradd{CPPFLAGS}}, $1;
1091                         }
1092                 else    # common if (/^[-+]/), just pass down...
1093                         {
1094                         # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
1095                         # This provides a simple way to pass options with arguments separated
1096                         # by spaces without quoting (e.g. -opt%20arg translates to -opt arg).
1097                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
1098                         push @{$useradd{CFLAGS}}, $_;
1099                         push @{$useradd{CXXFLAGS}}, $_;
1100                         }
1101                 }
1102         elsif (m|^/|)
1103                 {
1104                 # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
1105                 # This provides a simple way to pass options with arguments separated
1106                 # by spaces without quoting (e.g. /opt%20arg translates to /opt arg).
1107                 $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
1108                 push @{$useradd{CFLAGS}}, $_;
1109                 push @{$useradd{CXXFLAGS}}, $_;
1110                 }
1111         else
1112                 {
1113                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
1114                 $target=$_;
1115                 }
1116         unless ($_ eq $target || /^no-/ || /^disable-/)
1117                 {
1118                 # "no-..." follows later after implied deactivations
1119                 # have been derived.  (Don't take this too seriously,
1120                 # we really only write OPTIONS to the Makefile out of
1121                 # nostalgia.)
1122
1123                 if ($config{options} eq "")
1124                         { $config{options} = $_; }
1125                 else
1126                         { $config{options} .= " ".$_; }
1127                 }
1128         }
1129
1130 if (keys %deprecated_options)
1131         {
1132         warn "***** Deprecated options: ",
1133                 join(", ", keys %deprecated_options), "\n";
1134         }
1135 if (keys %unsupported_options)
1136         {
1137         die "***** Unsupported options: ",
1138                 join(", ", keys %unsupported_options), "\n";
1139         }
1140
1141 # If any %useradd entry has been set, we must check that the "make
1142 # variables" haven't been set.  We start by checking of any %useradd entry
1143 # is set.
1144 if (grep { scalar @$_ > 0 } values %useradd) {
1145     # Hash of env / make variables names.  The possible values are:
1146     # 1 - "make vars"
1147     # 2 - %useradd entry set
1148     # 3 - both set
1149     my %detected_vars =
1150         map { my $v = 0;
1151               $v += 1 if $cmdvars{$_};
1152               $v += 2 if @{$useradd{$_}};
1153               $_ => $v }
1154         keys %useradd;
1155
1156     # If any of the corresponding "make variables" is set, we error
1157     if (grep { $_ & 1 } values %detected_vars) {
1158         my $names = join(', ', grep { $detected_vars{$_} > 0 }
1159                                sort keys %detected_vars);
1160         die <<"_____";
1161 ***** Mixing make variables and additional compiler/linker flags as
1162 ***** configure command line option is not permitted.
1163 ***** Affected make variables: $names
1164 _____
1165     }
1166 }
1167
1168 # Check through all supported command line variables to see if any of them
1169 # were set, and canonicalise the values we got.  If no compiler or linker
1170 # flag or anything else that affects %useradd was set, we also check the
1171 # environment for values.
1172 my $anyuseradd =
1173     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
1174 foreach (keys %user) {
1175     my $value = $cmdvars{$_};
1176     $value //= env($_) unless $anyuseradd;
1177     $value //=
1178         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
1179     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
1180         unless $anyuseradd;
1181
1182     if (defined $value) {
1183         if (ref $user{$_} eq 'ARRAY') {
1184             if ($_ eq 'CPPDEFINES' || $_ eq 'CPPINCLUDES') {
1185                 $user{$_} = [ split /$list_separator_re/, $value ];
1186             } else {
1187                 $user{$_} = [ $value ];
1188             }
1189         } elsif (!defined $user{$_}) {
1190             $user{$_} = $value;
1191         }
1192     }
1193 }
1194
1195 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1196     && !$disabled{shared}
1197     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1198     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1199         "***** any of asan, msan or ubsan\n";
1200 }
1201
1202 # If no target was given, try guessing.
1203 unless ($target) {
1204     my %system_config = OpenSSL::config::get_platform(%guess_opts, %user);
1205
1206     # The $system_config{disable} is used to populate %disabled with
1207     # entries that aren't already there.
1208     foreach ( @{$system_config{disable} // []} ) {
1209         $disabled{$_} = 'system' unless defined $disabled{$_};
1210     }
1211     delete $system_config{disable};
1212
1213     # Override config entries with stuff from the guesser.
1214     # It's assumed that this really is nothing new.
1215     %config = ( %config, %system_config );
1216     $target = $system_config{target};
1217 }
1218
1219 sub disable {
1220     my $disable_type = shift;
1221
1222     for (@_) {
1223         $disabled{$_} = $disable_type;
1224     }
1225
1226     my @tocheckfor = (@_ ? @_ : keys %disabled);
1227     while (@tocheckfor) {
1228         my %new_tocheckfor = ();
1229         my @cascade_copy = (@disable_cascades);
1230         while (@cascade_copy) {
1231             my ($test, $descendents) =
1232                 (shift @cascade_copy, shift @cascade_copy);
1233             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1234                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1235                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1236                 }
1237             }
1238         }
1239         @tocheckfor = (keys %new_tocheckfor);
1240     }
1241 }
1242 disable();                     # First cascade run
1243
1244 our $die = sub { die @_; };
1245 if ($target eq "TABLE") {
1246     local $die = sub { warn @_; };
1247     foreach (sort keys %table) {
1248         print_table_entry($_, "TABLE");
1249     }
1250     exit 0;
1251 }
1252
1253 if ($target eq "LIST") {
1254     foreach (sort keys %table) {
1255         print $_,"\n" unless $table{$_}->{template};
1256     }
1257     exit 0;
1258 }
1259
1260 if ($target eq "HASH") {
1261     local $die = sub { warn @_; };
1262     print "%table = (\n";
1263     foreach (sort keys %table) {
1264         print_table_entry($_, "HASH");
1265     }
1266     exit 0;
1267 }
1268
1269 print "Configuring OpenSSL version $config{full_version} ";
1270 print "for target $target\n";
1271
1272 if (scalar(@seed_sources) == 0) {
1273     print "Using os-specific seed configuration\n";
1274     push @seed_sources, 'os';
1275 }
1276 if (scalar(grep { $_ eq 'egd' } @seed_sources) > 0) {
1277     delete $disabled{'egd'};
1278 }
1279 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1280     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1281     warn <<_____ if scalar(@seed_sources) == 1;
1282
1283 ============================== WARNING ===============================
1284 You have selected the --with-rand-seed=none option, which effectively
1285 disables automatic reseeding of the OpenSSL random generator.
1286 All operations depending on the random generator such as creating keys
1287 will not work unless the random generator is seeded manually by the
1288 application.
1289
1290 Please read the 'Note on random number generation' section in the
1291 INSTALL.md instructions and the RAND_DRBG(7) manual page for more
1292 details.
1293 ============================== WARNING ===============================
1294
1295 _____
1296 }
1297 push @{$config{openssl_feature_defines}},
1298      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1299         @seed_sources;
1300
1301 # Backward compatibility?
1302 if ($target =~ m/^CygWin32(-.*)$/) {
1303     $target = "Cygwin".$1;
1304 }
1305
1306 # Support for legacy targets having a name starting with 'debug-'
1307 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1308 if ($d) {
1309     $config{build_type} = "debug";
1310
1311     # If we do not find debug-foo in the table, the target is set to foo.
1312     if (!$table{$target}) {
1313         $target = $t;
1314     }
1315 }
1316
1317 if ($target) {
1318     # It's possible that we have different config targets for specific
1319     # toolchains, so we try to detect them, and go for the plain config
1320     # target if not.
1321     my $found;
1322     foreach ( ( "$target-$user{CC}", "$target", undef ) ) {
1323         $found=$_ if $table{$_} && !$table{$_}->{template};
1324         last if $found;
1325     }
1326     $target = $found;
1327 } else {
1328     # If we don't have a config target now, we try the C compiler as we
1329     # fallback
1330     my $cc = $user{CC} // 'cc';
1331     $target = $cc if $table{$cc} && !$table{$cc}->{template};
1332 }
1333
1334 &usage unless $target;
1335
1336 exit 0 if $dryrun;              # From older 'config'
1337
1338 $config{target} = $target;
1339 my %target = resolve_config($target);
1340
1341 foreach (keys %target_attr_translate) {
1342     $target{$target_attr_translate{$_}} = $target{$_}
1343         if $target{$_};
1344     delete $target{$_};
1345 }
1346
1347 %target = ( %{$table{DEFAULTS}}, %target );
1348
1349 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1350 $config{conf_files} = [ sort keys %conf_files ];
1351
1352 # Using sub disable within these loops may prove fragile, so we run
1353 # a cascade afterwards
1354 foreach my $feature (@{$target{disable}}) {
1355     if (exists $deprecated_disablables{$feature}) {
1356         warn "***** config $target disables deprecated feature $feature\n";
1357     } elsif (!grep { $feature eq $_ } @disablables) {
1358         die "***** config $target disables unknown feature $feature\n";
1359     }
1360     $disabled{$feature} = 'config';
1361 }
1362 foreach my $feature (@{$target{enable}}) {
1363     if ("default" eq ($disabled{$feature} // "")) {
1364         if (exists $deprecated_disablables{$feature}) {
1365             warn "***** config $target enables deprecated feature $feature\n";
1366         } elsif (!grep { $feature eq $_ } @disablables) {
1367             die "***** config $target enables unknown feature $feature\n";
1368         }
1369         delete $disabled{$feature};
1370     }
1371 }
1372
1373 # If uplink_arch isn't defined, disable uplink
1374 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1375 # If asm_arch isn't defined, disable asm
1376 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1377
1378 disable();                      # Run a cascade now
1379
1380 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1381 $target{cxxflags}//=$target{cflags} if $target{CXX};
1382 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1383 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1384
1385 # Fill %config with values from %user, and in case those are undefined or
1386 # empty, use values from %target (acting as a default).
1387 foreach (keys %user) {
1388     my $ref_type = ref $user{$_};
1389
1390     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1391     # and a value that's to be coerced into that type.
1392     my $mkvalue = sub {
1393         my $type = shift;
1394         my $value = shift;
1395         my $undef_p = shift;
1396
1397         die "Too many arguments for \$mkvalue" if @_;
1398
1399         while (ref $value eq 'CODE') {
1400             $value = $value->();
1401         }
1402
1403         if ($type eq 'ARRAY') {
1404             return undef unless defined $value;
1405             return undef if ref $value ne 'ARRAY' && !$value;
1406             return undef if ref $value eq 'ARRAY' && !@$value;
1407             return [ $value ] unless ref $value eq 'ARRAY';
1408         }
1409         return undef unless $value;
1410         return $value;
1411     };
1412
1413     $config{$_} =
1414         $mkvalue->($ref_type, $user{$_})
1415         || $mkvalue->($ref_type, $target{$_});
1416     delete $config{$_} unless defined $config{$_};
1417 }
1418
1419 # Finish up %config by appending things the user gave us on the command line
1420 # apart from "make variables"
1421 foreach (keys %useradd) {
1422     # The must all be lists, so we assert that here
1423     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1424         unless ref $useradd{$_} eq 'ARRAY';
1425
1426     if (defined $config{$_}) {
1427         push @{$config{$_}}, @{$useradd{$_}};
1428     } else {
1429         $config{$_} = [ @{$useradd{$_}} ];
1430     }
1431 }
1432 # At this point, we can forget everything about %user and %useradd,
1433 # because it's now all been merged into the corresponding $config entry
1434
1435 if (grep { $_ =~ /(?:^|\s)-static(?:\s|$)/ } @{$config{LDFLAGS}}) {
1436     disable('static', 'pic', 'threads');
1437 }
1438
1439 # Allow overriding the build file name
1440 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1441
1442 # Make sure build_scheme is consistent.
1443 $target{build_scheme} = [ $target{build_scheme} ]
1444     if ref($target{build_scheme}) ne "ARRAY";
1445
1446 my ($builder, $builder_platform, @builder_opts) =
1447     @{$target{build_scheme}};
1448
1449 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1450                       $builder_platform."-checker.pm")) {
1451     my $checker_path = catfile($srcdir, "Configurations", $checker);
1452     if (-f $checker_path) {
1453         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1454             ? sub { warn $@; } : sub { die $@; };
1455         if (! do $checker_path) {
1456             if ($@) {
1457                 $fn->($@);
1458             } elsif ($!) {
1459                 $fn->($!);
1460             } else {
1461                 $fn->("The detected tools didn't match the platform\n");
1462             }
1463         }
1464         last;
1465     }
1466 }
1467
1468 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1469
1470 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1471         {
1472         push @{$config{cflags}}, "-mno-cygwin";
1473         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1474         push @{$config{shared_ldflag}}, "-mno-cygwin";
1475         }
1476
1477 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1478         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1479         # minimally required architecture flags for assembly modules
1480         my $value;
1481         $value = '-mips2' if ($target =~ /mips32/);
1482         $value = '-mips3' if ($target =~ /mips64/);
1483         unshift @{$config{cflags}}, $value;
1484         unshift @{$config{cxxflags}}, $value if $config{CXX};
1485 }
1486
1487 # If threads aren't disabled, check how possible they are
1488 unless ($disabled{threads}) {
1489     if ($auto_threads) {
1490         # Enabled by default, disable it forcibly if unavailable
1491         if ($target{thread_scheme} eq "(unknown)") {
1492             disable("unavailable", 'threads');
1493         }
1494     } else {
1495         # The user chose to enable threads explicitly, let's see
1496         # if there's a chance that's possible
1497         if ($target{thread_scheme} eq "(unknown)") {
1498             # If the user asked for "threads" and we don't have internal
1499             # knowledge how to do it, [s]he is expected to provide any
1500             # system-dependent compiler options that are necessary.  We
1501             # can't truly check that the given options are correct, but
1502             # we expect the user to know what [s]He is doing.
1503             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1504                 die "You asked for multi-threading support, but didn't\n"
1505                     ,"provide any system-specific compiler options\n";
1506             }
1507         }
1508     }
1509 }
1510
1511 # Find out if clang's sanitizers have been enabled with -fsanitize
1512 # flags and ensure that the corresponding %disabled elements area
1513 # removed to reflect that the sanitizers are indeed enabled.
1514 my %detected_sanitizers = ();
1515 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1516     (my $checks = $_) =~ s/^-fsanitize=//;
1517     foreach (split /,/, $checks) {
1518         my $d = { address       => 'asan',
1519                   undefined     => 'ubsan',
1520                   memory        => 'msan' } -> {$_};
1521         next unless defined $d;
1522
1523         $detected_sanitizers{$d} = 1;
1524         if (defined $disabled{$d}) {
1525             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1526                 if $disabled{$d} ne "default";
1527             delete $disabled{$d};
1528         }
1529     }
1530 }
1531
1532 # If threads still aren't disabled, add a C macro to ensure the source
1533 # code knows about it.  Any other flag is taken care of by the configs.
1534 unless($disabled{threads}) {
1535     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1536 }
1537
1538 my $no_shared_warn=0;
1539 if (($target{shared_target} // '') eq "")
1540         {
1541         $no_shared_warn = 1
1542             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1543         disable('no-shared-target', 'pic');
1544         }
1545
1546 if ($disabled{"dynamic-engine"}) {
1547         $config{dynamic_engines} = 0;
1548 } else {
1549         $config{dynamic_engines} = 1;
1550 }
1551
1552 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1553     push @{$config{cflags}}, "-fsanitize=address";
1554 }
1555
1556 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1557     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all", "-DPEDANTIC";
1558 }
1559
1560 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1561   push @{$config{cflags}}, "-fsanitize=memory";
1562 }
1563
1564 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1565         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1566     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1567     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1568 }
1569 #
1570 # Platform fix-ups
1571 #
1572
1573 # This saves the build files from having to check
1574 if ($disabled{pic})
1575         {
1576         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1577                     shared_defines shared_includes shared_ldflag
1578                     module_cflags module_cxxflags module_cppflags
1579                     module_defines module_includes module_lflags))
1580                 {
1581                 delete $config{$_};
1582                 $target{$_} = "";
1583                 }
1584         }
1585 else
1586         {
1587         push @{$config{lib_defines}}, "OPENSSL_PIC";
1588         }
1589
1590 if ($target{sys_id} ne "")
1591         {
1592         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1593         }
1594
1595 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1596 my %predefined_CXX = $config{CXX}
1597     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1598     : ();
1599
1600 unless ($disabled{asm}) {
1601     # big endian systems can use ELFv2 ABI
1602     if ($target eq "linux-ppc64" || $target eq "BSD-ppc64") {
1603         $target{perlasm_scheme} = "linux64v2" if ($predefined_C{_CALL_ELF} == 2);
1604     }
1605 }
1606
1607 # Check for makedepend capabilities.
1608 if (!$disabled{makedepend}) {
1609     # If the attribute makedep_scheme is defined, then we assume that the
1610     # config target and its associated build file are programmed to deal
1611     # with it.
1612     # If makedep_scheme is undefined, we go looking for GCC compatible
1613     # dependency making, and if that's not available, we try to fall back
1614     # on 'makedepend'.
1615     if ($target{makedep_scheme}) {
1616         $config{makedep_scheme} = $target{makedep_scheme};
1617         # If the makedepcmd attribute is defined, copy it.  If not, the
1618         # build files will have to fend for themselves.
1619         $config{makedepcmd} = $target{makedepcmd} if $target{makedepcmd};
1620     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1621              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1622         # We know that GNU C version 3 and up as well as all clang
1623         # versions support dependency generation, but Xcode did not
1624         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1625         $config{makedep_scheme} = 'gcc';
1626     } else {
1627         # In all other cases, we look for 'makedepend', and set the
1628         # makedep_scheme value if we found it.
1629         $config{makedepcmd} = which('makedepend');
1630         $config{makedep_scheme} = 'makedepend' if $config{makedepcmd};
1631     }
1632
1633     # If no depend scheme is set, we disable makedepend
1634     disable('unavailable', 'makedepend') unless $config{makedep_scheme};
1635 }
1636
1637 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1638     # probe for -Wa,--noexecstack option...
1639     if ($predefined_C{__clang__}) {
1640         # clang has builtin assembler, which doesn't recognize --help,
1641         # but it apparently recognizes the option in question on all
1642         # supported platforms even when it's meaningless. In other words
1643         # probe would fail, but probed option always accepted...
1644         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1645     } else {
1646         my $cc = $config{CROSS_COMPILE}.$config{CC};
1647         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1648         while(<PIPE>) {
1649             if (m/--noexecstack/) {
1650                 push @{$config{cflags}}, "-Wa,--noexecstack";
1651                 last;
1652             }
1653         }
1654         close(PIPE);
1655         unlink("null.$$.o");
1656     }
1657 }
1658
1659 # Deal with bn_ops ###################################################
1660
1661 $config{bn_ll}                  =0;
1662 my $def_int="unsigned int";
1663 $config{rc4_int}                =$def_int;
1664 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1665
1666 my $count = 0;
1667 foreach (sort split(/\s+/,$target{bn_ops})) {
1668     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1669     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1670     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1671     ($config{b64l},$config{b64},$config{b32})
1672         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1673     ($config{b64l},$config{b64},$config{b32})
1674         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1675     ($config{b64l},$config{b64},$config{b32})
1676         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1677 }
1678 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1679     if $count > 1;
1680
1681 $config{api} = $config{major} * 10000 + $config{minor} * 100
1682     unless $config{api};
1683 foreach (keys %$apitable) {
1684     $disabled{"deprecated-$_"} = "deprecation"
1685         if $disabled{deprecated} && $config{api} >= $apitable->{$_};
1686 }
1687
1688 disable();                      # Run a cascade now
1689
1690 # Hack cflags for better warnings (dev option) #######################
1691
1692 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1693 # a string and works as well on command lines.
1694 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1695                         @{$config{cflags}} ];
1696 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1697                           @{$config{cxxflags}} ] if $config{CXX};
1698
1699 $config{openssl_api_defines} = [
1700     "OPENSSL_CONFIGURED_API=".$config{api},
1701 ];
1702
1703 my @strict_warnings_collection=();
1704 if ($strict_warnings)
1705         {
1706         my $wopt;
1707         my $gccver = $predefined_C{__GNUC__} // -1;
1708
1709         if ($gccver >= 4)
1710                 {
1711                 push @strict_warnings_collection, @gcc_devteam_warn;
1712                 push @strict_warnings_collection, @clang_devteam_warn
1713                     if (defined($predefined_C{__clang__}));
1714                 }
1715         elsif ($config{target} =~ /^VC-/)
1716                 {
1717                 push @strict_warnings_collection, @cl_devteam_warn;
1718                 }
1719         else
1720                 {
1721                 warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike, or MSVC"
1722                 }
1723         }
1724
1725 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1726                               ? @strict_warnings_collection
1727                               : ( $_ ) }
1728                     @{$config{CFLAGS}} ];
1729
1730 unless ($disabled{afalgeng}) {
1731     $config{afalgeng}="";
1732     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1733         push @{$config{engdirs}}, "afalg";
1734     } else {
1735         disable('not-linux', 'afalgeng');
1736     }
1737 }
1738
1739 unless ($disabled{devcryptoeng}) {
1740     if ($target =~ m/^BSD/) {
1741         my $maxver = 5*100 + 7;
1742         my $sysstr = `uname -s`;
1743         my $verstr = `uname -r`;
1744         $sysstr =~ s|\R$||;
1745         $verstr =~ s|\R$||;
1746         my ($ma, $mi, @rest) = split m|\.|, $verstr;
1747         my $ver = $ma*100 + $mi;
1748         if ($sysstr eq 'OpenBSD' && $ver >= $maxver) {
1749             disable('too-new-kernel', 'devcryptoeng');
1750         }
1751     }
1752 }
1753
1754 unless ($disabled{ktls}) {
1755     $config{ktls}="";
1756     my $cc = $config{CROSS_COMPILE}.$config{CC};
1757     if ($target =~ m/^linux/) {
1758         system("printf '#include <sys/types.h>\n#include <linux/tls.h>' | $cc -E - >/dev/null 2>&1");
1759         if ($? != 0) {
1760             disable('too-old-kernel', 'ktls');
1761         }
1762     } elsif ($target =~ m/^BSD/) {
1763         system("printf '#include <sys/types.h>\n#include <sys/ktls.h>' | $cc -E - >/dev/null 2>&1");
1764         if ($? != 0) {
1765             disable('too-old-freebsd', 'ktls');
1766         }
1767     } else {
1768         disable('not-linux-or-freebsd', 'ktls');
1769     }
1770 }
1771
1772 unless ($disabled{winstore}) {
1773     unless ($target =~ /^(?:Cygwin|mingw|VC-|BC-)/) {
1774         disable('not-windows', 'winstore');
1775     }
1776 }
1777
1778 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1779
1780 # Get the extra flags used when building shared libraries and modules.  We
1781 # do this late because some of them depend on %disabled.
1782
1783 # Make the flags to build DSOs the same as for shared libraries unless they
1784 # are already defined
1785 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1786 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1787 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1788 {
1789     my $shared_info_pl =
1790         catfile(dirname($0), "Configurations", "shared-info.pl");
1791     my %shared_info = read_eval_file($shared_info_pl);
1792     push @{$target{_conf_fname_int}}, $shared_info_pl;
1793     my $si = $target{shared_target};
1794     while (ref $si ne "HASH") {
1795         last if ! defined $si;
1796         if (ref $si eq "CODE") {
1797             $si = $si->();
1798         } else {
1799             $si = $shared_info{$si};
1800         }
1801     }
1802
1803     # Some of the 'shared_target' values don't have any entries in
1804     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1805     # template knows how to handle this.  That is currently the case for
1806     # Windows and VMS.
1807     if (defined $si) {
1808         # Just as above, copy certain shared_* attributes to the corresponding
1809         # module_ attribute unless the latter is already defined
1810         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1811         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1812         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1813         foreach (sort keys %$si) {
1814             $target{$_} = defined $target{$_}
1815                 ? add($si->{$_})->($target{$_})
1816                 : $si->{$_};
1817         }
1818     }
1819 }
1820
1821 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1822
1823 ######################################################################
1824 # Build up information for skipping certain directories depending on disabled
1825 # features, as well as setting up macros for disabled features.
1826
1827 # This is a tentative database of directories to skip.  Some entries may not
1828 # correspond to anything real, but that's ok, they will simply be ignored.
1829 # The actual processing of these entries is done in the build.info lookup
1830 # loop further down.
1831 #
1832 # The key is a Unix formatted path in the source tree, the value is an index
1833 # into %disabled_info, so any existing path gets added to a corresponding
1834 # 'skipped' entry in there with the list of skipped directories.
1835 my %skipdir = ();
1836 my %disabled_info = ();         # For configdata.pm
1837 foreach my $what (sort keys %disabled) {
1838     # There are deprecated disablables that translate to themselves.
1839     # They cause disabling cascades, but should otherwise not register.
1840     next if $deprecated_disablables{$what};
1841     # The generated $disabled{"deprecated-x.y"} entries are special
1842     # and treated properly elsewhere
1843     next if $what =~ m|^deprecated-|;
1844
1845     $config{options} .= " no-$what";
1846
1847     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1848                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1849                                 'sse2', 'legacy' )) {
1850         (my $WHAT = uc $what) =~ s|-|_|g;
1851         my $skipdir = $what;
1852
1853         # fix-up crypto/directory name(s)
1854         $skipdir = "ripemd" if $what eq "rmd160";
1855         $skipdir = "whrlpool" if $what eq "whirlpool";
1856
1857         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1858         push @{$config{openssl_feature_defines}}, $macro;
1859
1860         $skipdir{engines} = $what if $what eq 'engine';
1861         $skipdir{"crypto/$skipdir"} = $what
1862             unless $what eq 'async' || $what eq 'err' || $what eq 'dso';
1863     }
1864 }
1865
1866 if ($disabled{"dynamic-engine"}) {
1867     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1868 } else {
1869     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1870 }
1871
1872 # If we use the unified build, collect information from build.info files
1873 my %unified_info = ();
1874
1875 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1876 if ($builder eq "unified") {
1877     use Text::Template 1.46;
1878
1879     sub cleandir {
1880         my $base = shift;
1881         my $dir = shift;
1882         my $relativeto = shift || ".";
1883
1884         $dir = catdir($base,$dir) unless isabsolute($dir);
1885
1886         # Make sure the directories we're building in exists
1887         mkpath($dir);
1888
1889         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1890         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1891         return $res;
1892     }
1893
1894     sub cleanfile {
1895         my $base = shift;
1896         my $file = shift;
1897         my $relativeto = shift || ".";
1898
1899         $file = catfile($base,$file) unless isabsolute($file);
1900
1901         my $d = dirname($file);
1902         my $f = basename($file);
1903
1904         # Make sure the directories we're building in exists
1905         mkpath($d);
1906
1907         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1908         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1909         return $res;
1910     }
1911
1912     # Store the name of the template file we will build the build file from
1913     # in %config.  This may be useful for the build file itself.
1914     my @build_file_template_names =
1915         ( $builder_platform."-".$target{build_file}.".tmpl",
1916           $target{build_file}.".tmpl" );
1917     my @build_file_templates = ();
1918
1919     # First, look in the user provided directory, if given
1920     if (defined env($local_config_envname)) {
1921         @build_file_templates =
1922             map {
1923                 if ($^O eq 'VMS') {
1924                     # VMS environment variables are logical names,
1925                     # which can be used as is
1926                     $local_config_envname . ':' . $_;
1927                 } else {
1928                     catfile(env($local_config_envname), $_);
1929                 }
1930             }
1931             @build_file_template_names;
1932     }
1933     # Then, look in our standard directory
1934     push @build_file_templates,
1935         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1936           @build_file_template_names );
1937
1938     my $build_file_template;
1939     for $_ (@build_file_templates) {
1940         $build_file_template = $_;
1941         last if -f $build_file_template;
1942
1943         $build_file_template = undef;
1944     }
1945     if (!defined $build_file_template) {
1946         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1947     }
1948     $config{build_file_templates}
1949       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1950                     $blddir),
1951            $build_file_template ];
1952
1953     my @build_dirs = ( [ ] );   # current directory
1954
1955     $config{build_infos} = [ ];
1956
1957     # We want to detect configdata.pm in the source tree, so we
1958     # don't use it if the build tree is different.
1959     my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1960
1961     # Any source file that we recognise is placed in this hash table, with
1962     # the list of its intended destinations as value.  When everything has
1963     # been collected, there's a routine that checks that these source files
1964     # exist, or if they are generated, that the generator exists.
1965     my %check_exist = ();
1966     my %check_generate = ();
1967
1968     my %ordinals = ();
1969     while (@build_dirs) {
1970         my @curd = @{shift @build_dirs};
1971         my $sourced = catdir($srcdir, @curd);
1972         my $buildd = catdir($blddir, @curd);
1973
1974         my $unixdir = join('/', @curd);
1975         if (exists $skipdir{$unixdir}) {
1976             my $what = $skipdir{$unixdir};
1977             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1978             next;
1979         }
1980
1981         mkpath($buildd);
1982
1983         my $f = 'build.info';
1984         # The basic things we're trying to build
1985         my @programs = ();
1986         my @libraries = ();
1987         my @modules = ();
1988         my @scripts = ();
1989
1990         my %sources = ();
1991         my %shared_sources = ();
1992         my %includes = ();
1993         my %defines = ();
1994         my %depends = ();
1995         my %generate = ();
1996         my %imagedocs = ();
1997         my %htmldocs = ();
1998         my %mandocs = ();
1999
2000         # Support for $variablename in build.info files.
2001         # Embedded perl code is the ultimate master, still.  If its output
2002         # contains a dollar sign, it had better be escaped, or it will be
2003         # taken for a variable name prefix.
2004         my %variables = ();
2005         # Variable name syntax
2006         my $variable_name_re = qr/(?P<VARIABLE>[[:alpha:]][[:alnum:]_]*)/;
2007         # Value modifier syntaxes
2008         my $variable_subst_re = qr/\/(?P<RE>(?:\\\/|.)*?)\/(?P<SUBST>.*?)/;
2009         # Variable reference
2010         my $variable_simple_re = qr/(?<!\\)\$${variable_name_re}/;
2011         my $variable_w_mod_re =
2012             qr/(?<!\\)\$\{${variable_name_re}(?P<MOD>(?:\\\/|.)*?)\}/;
2013         # Tie it all together
2014         my $variable_re = qr/${variable_simple_re}|${variable_w_mod_re}/;
2015
2016         my $expand_variables = sub {
2017             my $value = '';
2018             my $value_rest = shift;
2019
2020             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2021                 print STDERR
2022                     "DEBUG[\$expand_variables] Parsed '$value_rest' ...\n"
2023             }
2024
2025             while ($value_rest =~ /${variable_re}/) {
2026                 # We must save important regexp values, because the next
2027                 # regexp clears them
2028                 my $mod = $+{MOD};
2029                 my $variable_value = $variables{$+{VARIABLE}};
2030
2031                 $value_rest = $';
2032                 $value .= $`;
2033
2034                 # Process modifier expressions, if present
2035                 if (defined $mod) {
2036                     if ($mod =~ /^${variable_subst_re}$/) {
2037                         my $re = $+{RE};
2038                         my $subst = $+{SUBST};
2039
2040                         $variable_value =~ s/\Q$re\E/$subst/g;
2041
2042                         if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2043                             print STDERR
2044                                 "DEBUG[\$expand_variables] ... and substituted ",
2045                                 "'$re' with '$subst'\n";
2046                         }
2047                     }
2048                 }
2049
2050                 $value .= $variable_value;
2051             }
2052             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2053                 print STDERR
2054                     "DEBUG[\$expand_variables] ... into: '$value$value_rest'\n";
2055             }
2056             return $value . $value_rest;
2057         };
2058
2059         # Support for attributes in build.info files
2060         my %attributes = ();
2061         my $handle_attributes = sub {
2062             my $attr_str = shift;
2063             my $ref = shift;
2064             my @goals = @_;
2065
2066             return unless defined $attr_str;
2067
2068             my @a = tokenize($attr_str, qr|\s*,\s*|);
2069             foreach my $a (@a) {
2070                 my $ac = 1;
2071                 my $ak = $a;
2072                 my $av = 1;
2073                 if ($a =~ m|^(!)?(.*?)\s* = \s*(.*?)$|x) {
2074                     $ac = ! $1;
2075                     $ak = $2;
2076                     $av = $3;
2077                 }
2078                 foreach my $g (@goals) {
2079                     if ($ac) {
2080                         $$ref->{$g}->{$ak} = $av;
2081                     } else {
2082                         delete $$ref->{$g}->{$ak};
2083                     }
2084                 }
2085             }
2086         };
2087
2088         # Support for pushing values on multiple indexes of a given hash
2089         # array.
2090         my $push_to = sub {
2091             my $valueref = shift;
2092             my $index_str = shift; # May be undef or empty
2093             my $attrref = shift;   # May be undef
2094             my $attr_str = shift;
2095             my @values = @_;
2096
2097             if (defined $index_str) {
2098                 my @indexes = ( '' );
2099                 if ($index_str !~ m|^\s*$|) {
2100                     @indexes = tokenize($index_str);
2101                 }
2102                 foreach (@indexes) {
2103                     push @{$valueref->{$_}}, @values;
2104                     if (defined $attrref) {
2105                         $handle_attributes->($attr_str, \$$attrref->{$_},
2106                                              @values);
2107                     }
2108                 }
2109             } else {
2110                 push @$valueref, @values;
2111                 $handle_attributes->($attr_str, $attrref, @values)
2112                     if defined $attrref;
2113             }
2114         };
2115
2116         if ($buildinfo_debug) {
2117             print STDERR "DEBUG: Reading ",catfile($sourced, $f),"\n";
2118         }
2119         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
2120         my $template =
2121             Text::Template->new(TYPE => 'FILE',
2122                                 SOURCE => catfile($sourced, $f),
2123                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
2124         die "Something went wrong with $sourced/$f: $!\n" unless $template;
2125         my @text =
2126             split /^/m,
2127             $template->fill_in(HASH => { config => \%config,
2128                                          target => \%target,
2129                                          disabled => \%disabled,
2130                                          withargs => \%withargs,
2131                                          builddir => abs2rel($buildd, $blddir),
2132                                          sourcedir => abs2rel($sourced, $blddir),
2133                                          buildtop => abs2rel($blddir, $blddir),
2134                                          sourcetop => abs2rel($srcdir, $blddir) },
2135                                DELIMITERS => [ "{-", "-}" ]);
2136
2137         # The top item of this stack has the following values
2138         # -2 positive already run and we found ELSE (following ELSIF should fail)
2139         # -1 positive already run (skip until ENDIF)
2140         # 0 negatives so far (if we're at a condition, check it)
2141         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
2142         # 2 positive ELSE (following ELSIF should fail)
2143         my @skip = ();
2144
2145         # A few useful generic regexps
2146         my $index_re = qr/\[\s*(?P<INDEX>(?:\\.|.)*?)\s*\]/;
2147         my $cond_re = qr/\[\s*(?P<COND>(?:\\.|.)*?)\s*\]/;
2148         my $attribs_re = qr/(?:\{\s*(?P<ATTRIBS>(?:\\.|.)*?)\s*\})?/;
2149         my $value_re = qr/(?P<VALUE>.*?)/;
2150         collect_information(
2151             collect_from_array([ @text ],
2152                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
2153                                                 $l1 =~ s/\\$//; $l1.$l2 }),
2154             # Info we're looking for
2155             qr/^\s* IF ${cond_re} \s*$/x
2156             => sub {
2157                 if (! @skip || $skip[$#skip] > 0) {
2158                     push @skip, !! $expand_variables->($+{COND});
2159                 } else {
2160                     push @skip, -1;
2161                 }
2162             },
2163             qr/^\s* ELSIF ${cond_re} \s*$/x
2164             => sub { die "ELSIF out of scope" if ! @skip;
2165                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
2166                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
2167                      $skip[$#skip] = !! $expand_variables->($+{COND})
2168                          if $skip[$#skip] == 0; },
2169             qr/^\s* ELSE \s*$/x
2170             => sub { die "ELSE out of scope" if ! @skip;
2171                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
2172                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
2173             qr/^\s* ENDIF \s*$/x
2174             => sub { die "ENDIF out of scope" if ! @skip;
2175                      pop @skip; },
2176             qr/^\s* ${variable_re} \s* = \s* ${value_re} \s* $/x
2177             => sub {
2178                 if (!@skip || $skip[$#skip] > 0) {
2179                     $variables{$+{VARIABLE}} = $expand_variables->($+{VALUE});
2180                 }
2181             },
2182             qr/^\s* SUBDIRS \s* = \s* ${value_re} \s* $/x
2183             => sub {
2184                 if (!@skip || $skip[$#skip] > 0) {
2185                     foreach (tokenize($expand_variables->($+{VALUE}))) {
2186                         push @build_dirs, [ @curd, splitdir($_, 1) ];
2187                     }
2188                 }
2189             },
2190             qr/^\s* PROGRAMS ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2191             => sub { $push_to->(\@programs, undef,
2192                                 \$attributes{programs}, $+{ATTRIBS},
2193                                 tokenize($expand_variables->($+{VALUE})))
2194                          if !@skip || $skip[$#skip] > 0; },
2195             qr/^\s* LIBS ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2196             => sub { $push_to->(\@libraries, undef,
2197                                 \$attributes{libraries}, $+{ATTRIBS},
2198                                 tokenize($expand_variables->($+{VALUE})))
2199                          if !@skip || $skip[$#skip] > 0; },
2200             qr/^\s* MODULES ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2201             => sub { $push_to->(\@modules, undef,
2202                                 \$attributes{modules}, $+{ATTRIBS},
2203                                 tokenize($expand_variables->($+{VALUE})))
2204                          if !@skip || $skip[$#skip] > 0; },
2205             qr/^\s* SCRIPTS ${attribs_re} \s* = \s* ${value_re} \s* $/x
2206             => sub { $push_to->(\@scripts, undef,
2207                                 \$attributes{scripts}, $+{ATTRIBS},
2208                                 tokenize($expand_variables->($+{VALUE})))
2209                          if !@skip || $skip[$#skip] > 0; },
2210             qr/^\s* IMAGEDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2211             => sub { $push_to->(\%imagedocs, $expand_variables->($+{INDEX}),
2212                                 undef, undef,
2213                                 tokenize($expand_variables->($+{VALUE})))
2214                          if !@skip || $skip[$#skip] > 0; },
2215             qr/^\s* HTMLDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2216             => sub { $push_to->(\%htmldocs, $expand_variables->($+{INDEX}),
2217                                 undef, undef,
2218                                 tokenize($expand_variables->($+{VALUE})))
2219                          if !@skip || $skip[$#skip] > 0; },
2220             qr/^\s* MANDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2221             => sub { $push_to->(\%mandocs, $expand_variables->($+{INDEX}),
2222                                 undef, undef,
2223                                 tokenize($expand_variables->($+{VALUE})))
2224                          if !@skip || $skip[$#skip] > 0; },
2225             qr/^\s* SOURCE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2226             => sub { $push_to->(\%sources, $expand_variables->($+{INDEX}),
2227                                 \$attributes{sources}, $+{ATTRIBS},
2228                                 tokenize($expand_variables->($+{VALUE})))
2229                          if !@skip || $skip[$#skip] > 0; },
2230             qr/^\s* SHARED_SOURCE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2231             => sub { $push_to->(\%shared_sources, $expand_variables->($+{INDEX}),
2232                                 \$attributes{sources}, $+{ATTRIBS},
2233                                 tokenize($expand_variables->($+{VALUE})))
2234                          if !@skip || $skip[$#skip] > 0; },
2235             qr/^\s* INCLUDE ${index_re} \s* = \s* ${value_re} \s* $/x
2236             => sub { $push_to->(\%includes, $expand_variables->($+{INDEX}),
2237                                 undef, undef,
2238                                 tokenize($expand_variables->($+{VALUE})))
2239                          if !@skip || $skip[$#skip] > 0; },
2240             qr/^\s* DEFINE ${index_re} \s* = \s* ${value_re} \s* $/x
2241             => sub { $push_to->(\%defines, $expand_variables->($+{INDEX}),
2242                                 undef, undef,
2243                                 tokenize($expand_variables->($+{VALUE})))
2244                          if !@skip || $skip[$#skip] > 0; },
2245             qr/^\s* DEPEND ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2246             => sub { $push_to->(\%depends, $expand_variables->($+{INDEX}),
2247                                 \$attributes{depends}, $+{ATTRIBS},
2248                                 tokenize($expand_variables->($+{VALUE})))
2249                          if !@skip || $skip[$#skip] > 0; },
2250             qr/^\s* GENERATE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2251             => sub { $push_to->(\%generate, $expand_variables->($+{INDEX}),
2252                                 \$attributes{generate}, $+{ATTRIBS},
2253                                 $expand_variables->($+{VALUE}))
2254                          if !@skip || $skip[$#skip] > 0; },
2255             qr/^\s* (?:\#.*)? $/x => sub { },
2256             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
2257             "BEFORE" => sub {
2258                 if ($buildinfo_debug) {
2259                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
2260                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2261                 }
2262             },
2263             "AFTER" => sub {
2264                 if ($buildinfo_debug) {
2265                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2266                 }
2267             },
2268             );
2269         die "runaway IF?" if (@skip);
2270
2271         if (grep { defined $attributes{modules}->{$_}->{engine} } keys %attributes
2272                 and !$config{dynamic_engines}) {
2273             die <<"EOF"
2274 ENGINES can only be used if configured with 'dynamic-engine'.
2275 This is usually a fault in a build.info file.
2276 EOF
2277         }
2278
2279         {
2280             my %infos = ( programs  => [ @programs  ],
2281                           libraries => [ @libraries ],
2282                           modules   => [ @modules   ],
2283                           scripts   => [ @scripts   ] );
2284             foreach my $k (keys %infos) {
2285                 foreach (@{$infos{$k}}) {
2286                     my $item = cleanfile($buildd, $_, $blddir);
2287                     $unified_info{$k}->{$item} = 1;
2288
2289                     # Fix up associated attributes
2290                     $unified_info{attributes}->{$k}->{$item} =
2291                         $attributes{$k}->{$_}
2292                         if defined $attributes{$k}->{$_};
2293                 }
2294             }
2295         }
2296
2297         # Check that we haven't defined any library as both shared and
2298         # explicitly static.  That is forbidden.
2299         my @doubles = ();
2300         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2301             (my $l = $_) =~ s/\.a$//;
2302             push @doubles, $l if defined $unified_info{libraries}->{$l};
2303         }
2304         die "these libraries are both explicitly static and shared:\n  ",
2305             join(" ", @doubles), "\n"
2306             if @doubles;
2307
2308         foreach (keys %sources) {
2309             my $dest = $_;
2310             my $ddest = cleanfile($buildd, $_, $blddir);
2311             foreach (@{$sources{$dest}}) {
2312                 my $s = cleanfile($sourced, $_, $blddir);
2313
2314                 # If it's generated or we simply don't find it in the source
2315                 # tree, we assume it's in the build tree.
2316                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2317                     $s = cleanfile($buildd, $_, $blddir);
2318                 }
2319                 my $o = $_;
2320                 # We recognise C++, C and asm files
2321                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2322                     push @{$check_exist{$s}}, $ddest;
2323                     $o =~ s/\.[csS]$/.o/; # C and assembler
2324                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2325                     $o = cleanfile($buildd, $o, $blddir);
2326                     $unified_info{sources}->{$ddest}->{$o} = -1;
2327                     $unified_info{sources}->{$o}->{$s} = -1;
2328                 } elsif ($s =~ /\.rc$/) {
2329                     # We also recognise resource files
2330                     push @{$check_exist{$s}}, $ddest;
2331                     $o =~ s/\.rc$/.res/; # Resource configuration
2332                     $o = cleanfile($buildd, $o, $blddir);
2333                     $unified_info{sources}->{$ddest}->{$o} = -1;
2334                     $unified_info{sources}->{$o}->{$s} = -1;
2335                 } else {
2336                     push @{$check_exist{$s}}, $ddest;
2337                     $unified_info{sources}->{$ddest}->{$s} = 1;
2338                 }
2339                 # Fix up associated attributes
2340                 if ($o ne $_) {
2341                     $unified_info{attributes}->{sources}->{$ddest}->{$o} =
2342                         $unified_info{attributes}->{sources}->{$o}->{$s} =
2343                         $attributes{sources}->{$dest}->{$_}
2344                         if defined $attributes{sources}->{$dest}->{$_};
2345                 } else {
2346                     $unified_info{attributes}->{sources}->{$ddest}->{$s} =
2347                         $attributes{sources}->{$dest}->{$_}
2348                         if defined $attributes{sources}->{$dest}->{$_};
2349                 }
2350             }
2351         }
2352
2353         foreach (keys %shared_sources) {
2354             my $dest = $_;
2355             my $ddest = cleanfile($buildd, $_, $blddir);
2356             foreach (@{$shared_sources{$dest}}) {
2357                 my $s = cleanfile($sourced, $_, $blddir);
2358
2359                 # If it's generated or we simply don't find it in the source
2360                 # tree, we assume it's in the build tree.
2361                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2362                     $s = cleanfile($buildd, $_, $blddir);
2363                 }
2364
2365                 my $o = $_;
2366                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2367                     # We recognise C++, C and asm files
2368                     push @{$check_exist{$s}}, $ddest;
2369                     $o =~ s/\.[csS]$/.o/; # C and assembler
2370                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2371                     $o = cleanfile($buildd, $o, $blddir);
2372                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2373                     $unified_info{sources}->{$o}->{$s} = -1;
2374                 } elsif ($s =~ /\.rc$/) {
2375                     # We also recognise resource files
2376                     push @{$check_exist{$s}}, $ddest;
2377                     $o =~ s/\.rc$/.res/; # Resource configuration
2378                     $o = cleanfile($buildd, $o, $blddir);
2379                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2380                     $unified_info{sources}->{$o}->{$s} = -1;
2381                 } elsif ($s =~ /\.ld$/) {
2382                     # We also recognise linker scripts (or corresponding)
2383                     # We know they are generated files
2384                     push @{$check_exist{$s}}, $ddest;
2385                     $o = cleanfile($buildd, $_, $blddir);
2386                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
2387                 } else {
2388                     die "unrecognised source file type for shared library: $s\n";
2389                 }
2390                 # Fix up associated attributes
2391                 if ($o ne $_) {
2392                     $unified_info{attributes}->{shared_sources}->{$ddest}->{$o} =
2393                         $unified_info{attributes}->{sources}->{$o}->{$s} =
2394                         $attributes{sources}->{$dest}->{$_}
2395                         if defined $attributes{sources}->{$dest}->{$_};
2396                 } else {
2397                     $unified_info{attributes}->{shared_sources}->{$ddest}->{$o} =
2398                         $attributes{sources}->{$dest}->{$_}
2399                         if defined $attributes{sources}->{$dest}->{$_};
2400                 }
2401             }
2402         }
2403
2404         foreach (keys %generate) {
2405             my $dest = $_;
2406             my $ddest = cleanfile($buildd, $_, $blddir);
2407             die "more than one generator for $dest: "
2408                 ,join(" ", @{$generate{$_}}),"\n"
2409                 if scalar @{$generate{$_}} > 1;
2410             my @generator = split /\s+/, $generate{$dest}->[0];
2411             my $gen = $generator[0];
2412             $generator[0] = cleanfile($sourced, $gen, $blddir);
2413
2414             # If the generator is itself generated, it's in the build tree
2415             if ($generate{$gen} || ! -f $generator[0]) {
2416                 $generator[0] = cleanfile($buildd, $gen, $blddir);
2417             }
2418             $check_generate{$ddest}->{$generator[0]}++;
2419
2420             $unified_info{generate}->{$ddest} = [ @generator ];
2421             # Fix up associated attributes
2422             $unified_info{attributes}->{generate}->{$ddest} =
2423                 $attributes{generate}->{$dest}->{$gen}
2424                 if defined $attributes{generate}->{$dest}->{$gen};
2425         }
2426
2427         foreach (keys %depends) {
2428             my $dest = $_;
2429             my $ddest = $dest;
2430
2431             if ($dest =~ /^\|(.*)\|$/) {
2432                 # Collect the raw target
2433                 $unified_info{targets}->{$1} = 1;
2434                 $ddest = $1;
2435             } elsif ($dest eq '') {
2436                 $ddest = '';
2437             } else {
2438                 $ddest = cleanfile($sourced, $_, $blddir);
2439
2440                 # If the destination doesn't exist in source, it can only be
2441                 # a generated file in the build tree.
2442                 if ($ddest eq $src_configdata || ! -f $ddest) {
2443                     $ddest = cleanfile($buildd, $_, $blddir);
2444                 }
2445             }
2446             foreach (@{$depends{$dest}}) {
2447                 my $d = cleanfile($sourced, $_, $blddir);
2448                 my $d2 = cleanfile($buildd, $_, $blddir);
2449
2450                 # If we know it's generated, or assume it is because we can't
2451                 # find it in the source tree, we set file we depend on to be
2452                 # in the build tree rather than the source tree.
2453                 if ($d eq $src_configdata
2454                     || (grep { $d2 eq $_ }
2455                         keys %{$unified_info{generate}})
2456                     || ! -f $d) {
2457                     $d = $d2;
2458                 }
2459                 $unified_info{depends}->{$ddest}->{$d} = 1;
2460
2461                 # Fix up associated attributes
2462                 $unified_info{attributes}->{depends}->{$ddest}->{$d} =
2463                     $attributes{depends}->{$dest}->{$_}
2464                     if defined $attributes{depends}->{$dest}->{$_};
2465             }
2466         }
2467
2468         foreach (keys %includes) {
2469             my $dest = $_;
2470             my $ddest = cleanfile($sourced, $_, $blddir);
2471
2472             # If the destination doesn't exist in source, it can only be
2473             # a generated file in the build tree.
2474             if ($ddest eq $src_configdata || ! -f $ddest) {
2475                 $ddest = cleanfile($buildd, $_, $blddir);
2476             }
2477             foreach (@{$includes{$dest}}) {
2478                 my $is = cleandir($sourced, $_, $blddir);
2479                 my $ib = cleandir($buildd, $_, $blddir);
2480                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2481                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2482                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2483                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2484             }
2485         }
2486
2487         foreach my $dest (keys %defines) {
2488             my $ddest;
2489
2490             if ($dest ne "") {
2491                 $ddest = cleanfile($sourced, $dest, $blddir);
2492
2493                 # If the destination doesn't exist in source, it can only
2494                 # be a generated file in the build tree.
2495                 if (! -f $ddest) {
2496                     $ddest = cleanfile($buildd, $dest, $blddir);
2497                 }
2498             }
2499             foreach my $v (@{$defines{$dest}}) {
2500                 $v =~ m|^([^=]*)(=.*)?$|;
2501                 die "0 length macro name not permitted\n" if $1 eq "";
2502                 if ($dest ne "") {
2503                     die "$1 defined more than once\n"
2504                         if defined $unified_info{defines}->{$ddest}->{$1};
2505                     $unified_info{defines}->{$ddest}->{$1} = $2;
2506                 } else {
2507                     die "$1 defined more than once\n"
2508                         if grep { $v eq $_ } @{$config{defines}};
2509                     push @{$config{defines}}, $v;
2510                 }
2511             }
2512         }
2513
2514         foreach my $section (keys %imagedocs) {
2515             foreach (@{$imagedocs{$section}}) {
2516                 my $imagedocs = cleanfile($buildd, $_, $blddir);
2517                 $unified_info{imagedocs}->{$section}->{$imagedocs} = 1;
2518             }
2519         }
2520
2521         foreach my $section (keys %htmldocs) {
2522             foreach (@{$htmldocs{$section}}) {
2523                 my $htmldocs = cleanfile($buildd, $_, $blddir);
2524                 $unified_info{htmldocs}->{$section}->{$htmldocs} = 1;
2525             }
2526         }
2527
2528         foreach my $section (keys %mandocs) {
2529             foreach (@{$mandocs{$section}}) {
2530                 my $mandocs = cleanfile($buildd, $_, $blddir);
2531                 $unified_info{mandocs}->{$section}->{$mandocs} = 1;
2532             }
2533         }
2534     }
2535
2536     my $ordinals_text = join(', ', sort keys %ordinals);
2537     warn <<"EOF" if $ordinals_text;
2538
2539 WARNING: ORDINALS were specified for $ordinals_text
2540 They are ignored and should be replaced with a combination of GENERATE,
2541 DEPEND and SHARED_SOURCE.
2542 EOF
2543
2544     # Check that each generated file is only generated once
2545     my $ambiguous_generation = 0;
2546     foreach (sort keys %check_generate) {
2547         my @generators = sort keys %{$check_generate{$_}};
2548         my $generators_txt = join(', ', @generators);
2549         if (scalar @generators > 1) {
2550             warn "$_ is GENERATEd by more than one generator ($generators_txt)\n";
2551             $ambiguous_generation++;
2552         }
2553         if ($check_generate{$_}->{$generators[0]} > 1) {
2554             warn "INFO: $_ has more than one GENERATE declaration (same generator)\n"
2555         }
2556     }
2557     die "There are ambiguous source file generations\n"
2558         if $ambiguous_generation > 0;
2559
2560     # All given source files should exist, or if generated, their
2561     # generator should exist.  This loop ensures this is true.
2562     my $missing = 0;
2563     foreach my $orig (sort keys %check_exist) {
2564         foreach my $dest (@{$check_exist{$orig}}) {
2565             if ($orig ne $src_configdata) {
2566                 if ($orig =~ /\.a$/) {
2567                     # Static library names may be used as sources, so we
2568                     # need to detect those and give them special treatment.
2569                     unless (grep { $_ eq $orig }
2570                             keys %{$unified_info{libraries}}) {
2571                         warn "$orig is given as source for $dest, but no such library is built\n";
2572                         $missing++;
2573                     }
2574                 } else {
2575                     # A source may be generated, and its generator may be
2576                     # generated as well.  We therefore loop to dig out the
2577                     # first generator.
2578                     my $gen = $orig;
2579
2580                     while (my @next = keys %{$check_generate{$gen}}) {
2581                         $gen = $next[0];
2582                     }
2583
2584                     if (! -f $gen) {
2585                         if ($gen ne $orig) {
2586                             $missing++;
2587                             warn "$orig is given as source for $dest, but its generator (leading to $gen) is missing\n";
2588                         } else {
2589                             $missing++;
2590                             warn "$orig is given as source for $dest, but is missing\n";
2591                         }
2592                     }
2593                 }
2594             }
2595         }
2596     }
2597     die "There are files missing\n" if $missing > 0;
2598
2599     # Go through the sources of all libraries and check that the same basename
2600     # doesn't appear more than once.  Some static library archivers depend on
2601     # them being unique.
2602     {
2603         my $err = 0;
2604         foreach my $prod (keys %{$unified_info{libraries}}) {
2605             my @prod_sources =
2606                 map { keys %{$unified_info{sources}->{$_}} }
2607                 keys %{$unified_info{sources}->{$prod}};
2608             my %srccnt = ();
2609
2610             # Count how many times a given each source basename
2611             # appears for each product.
2612             foreach my $src (@prod_sources) {
2613                 $srccnt{basename $src}++;
2614             }
2615
2616             foreach my $src (keys %srccnt) {
2617                 if ((my $cnt = $srccnt{$src}) > 1) {
2618                     print STDERR "$src appears $cnt times for the product $prod\n";
2619                     $err++
2620                 }
2621             }
2622         }
2623         die if $err > 0;
2624     }
2625
2626     # Massage the result
2627
2628     # If we depend on a header file or a perl module, add an inclusion of
2629     # its directory to allow smoothe inclusion
2630     foreach my $dest (keys %{$unified_info{depends}}) {
2631         next if $dest eq "";
2632         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2633             next unless $d =~ /\.(h|pm)$/;
2634             my $i = dirname($d);
2635             my $spot =
2636                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2637                 ? 'build' : 'source';
2638             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2639                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2640         }
2641     }
2642
2643     # Go through all intermediary files and change their names to something that
2644     # reflects what they will be built for.  Note that for some source files,
2645     # this leads to duplicate object files because they are used multiple times.
2646     # the goal is to rename all object files according to this scheme:
2647     #    {productname}-{midfix}-{origobjname}.[o|res]
2648     # the {midfix} is a keyword indicating the type of product, which is mostly
2649     # valuable for libraries since they come in two forms.
2650     #
2651     # This also reorganises the {sources} and {shared_sources} so that the
2652     # former only contains ALL object files that are supposed to end up in
2653     # static libraries and programs, while the latter contains ALL object files
2654     # that are supposed to end up in shared libraries and DSOs.
2655     # The main reason for having two different source structures is to allow
2656     # the same name to be used for the static and the shared variants of a
2657     # library.
2658     {
2659         # Take copies so we don't get interference from added stuff
2660         my %unified_copy = ();
2661         foreach (('sources', 'shared_sources')) {
2662             $unified_copy{$_} = { %{$unified_info{$_}} }
2663                 if defined($unified_info{$_});
2664             delete $unified_info{$_};
2665         }
2666         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2667             # $intent serves multi purposes:
2668             # - give a prefix for the new object files names
2669             # - in the case of libraries, rearrange the object files so static
2670             #   libraries use the 'sources' structure exclusively, while shared
2671             #   libraries use the 'shared_sources' structure exclusively.
2672             my $intent = {
2673                 programs  => { bin    => { src => [ 'sources' ],
2674                                            dst => 'sources' } },
2675                 libraries => { lib    => { src => [ 'sources' ],
2676                                            dst => 'sources' },
2677                                shlib  => { prodselect =>
2678                                                sub { grep !/\.a$/, @_ },
2679                                            src => [ 'sources',
2680                                                     'shared_sources' ],
2681                                            dst => 'shared_sources' } },
2682                 modules   => { dso    => { src => [ 'sources' ],
2683                                            dst => 'sources' } },
2684                 scripts   => { script => { src => [ 'sources' ],
2685                                            dst => 'sources' } }
2686                } -> {$prodtype};
2687             foreach my $kind (keys %$intent) {
2688                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2689                              && $disabled{shared});
2690
2691                 my @src = @{$intent->{$kind}->{src}};
2692                 my $dst = $intent->{$kind}->{dst};
2693                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2694                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2695                     # %prod_sources has all applicable objects as keys, and
2696                     # their corresponding sources as values
2697                     my %prod_sources =
2698                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2699                         map { keys %{$unified_copy{$_}->{$prod}} }
2700                         @src;
2701                     foreach (keys %prod_sources) {
2702                         # Only affect object files and resource files,
2703                         # the others simply get a new value
2704                         # (+1 instead of -1)
2705                         if ($_ =~ /\.(o|res)$/) {
2706                             (my $prodname = $prod) =~ s|\.a$||;
2707                             my $newobj =
2708                                 catfile(dirname($_),
2709                                         basename($prodname)
2710                                             . '-' . $kind
2711                                             . '-' . basename($_));
2712                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2713                             foreach my $src (@{$prod_sources{$_}}) {
2714                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2715                                 # Adjust source attributes
2716                                 my $attrs = $unified_info{attributes}->{sources};
2717                                 if (defined $attrs->{$prod}
2718                                     && defined $attrs->{$prod}->{$_}) {
2719                                     $attrs->{$prod}->{$newobj} =
2720                                         $attrs->{$prod}->{$_};
2721                                     delete $attrs->{$prod}->{$_};
2722                                 }
2723                                 foreach my $objsrc (keys %{$attrs->{$_} // {}}) {
2724                                     $attrs->{$newobj}->{$objsrc} =
2725                                         $attrs->{$_}->{$objsrc};
2726                                     delete $attrs->{$_}->{$objsrc};
2727                                 }
2728                             }
2729                             # Adjust dependencies
2730                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2731                                 $unified_info{depends}->{$_}->{$deps} = -1;
2732                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2733                             }
2734                             # Adjust includes
2735                             foreach my $k (('source', 'build')) {
2736                                 next unless
2737                                     defined($unified_info{includes}->{$_}->{$k});
2738                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2739                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2740                             }
2741                         } else {
2742                             $unified_info{$dst}->{$prod}->{$_} = 1;
2743                         }
2744                     }
2745                 }
2746             }
2747         }
2748     }
2749
2750     # At this point, we have a number of sources with the value -1.  They
2751     # aren't part of the local build and are probably meant for a different
2752     # platform, and can therefore be cleaned away.  That happens when making
2753     # %unified_info more efficient below.
2754
2755     ### Make unified_info a bit more efficient
2756     # One level structures
2757     foreach (("programs", "libraries", "modules", "scripts", "targets")) {
2758         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2759     }
2760     # Two level structures
2761     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends",
2762                      "imagedocs", "htmldocs", "mandocs")) {
2763         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2764             my @items =
2765                 sort
2766                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2767                 keys %{$unified_info{$l1}->{$l2}};
2768             if (@items) {
2769                 $unified_info{$l1}->{$l2} = [ @items ];
2770             } else {
2771                 delete $unified_info{$l1}->{$l2};
2772             }
2773         }
2774     }
2775     # Defines
2776     foreach my $dest (sort keys %{$unified_info{defines}}) {
2777         $unified_info{defines}->{$dest}
2778             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2779                 sort keys %{$unified_info{defines}->{$dest}} ];
2780     }
2781     # Includes
2782     foreach my $dest (sort keys %{$unified_info{includes}}) {
2783         if (defined($unified_info{includes}->{$dest}->{build})) {
2784             my @source_includes = ();
2785             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2786                 if defined($unified_info{includes}->{$dest}->{source});
2787             $unified_info{includes}->{$dest} =
2788                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2789             foreach my $inc (@source_includes) {
2790                 push @{$unified_info{includes}->{$dest}}, $inc
2791                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2792             }
2793         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2794             $unified_info{includes}->{$dest} =
2795                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2796         } else {
2797             delete $unified_info{includes}->{$dest};
2798         }
2799     }
2800
2801     # For convenience collect information regarding directories where
2802     # files are generated, those generated files and the end product
2803     # they end up in where applicable.  Then, add build rules for those
2804     # directories
2805     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2806                      "dso" => [ @{$unified_info{modules}} ],
2807                      "bin" => [ @{$unified_info{programs}} ],
2808                      "script" => [ @{$unified_info{scripts}} ],
2809                      "docs" => [ (map { @{$unified_info{imagedocs}->{$_} // []} }
2810                                   keys %{$unified_info{imagedocs} // {}}),
2811                                  (map { @{$unified_info{htmldocs}->{$_} // []} }
2812                                   keys %{$unified_info{htmldocs} // {}}),
2813                                  (map { @{$unified_info{mandocs}->{$_} // []} }
2814                                   keys %{$unified_info{mandocs} // {}}) ] );
2815     foreach my $type (sort keys %loopinfo) {
2816         foreach my $product (@{$loopinfo{$type}}) {
2817             my %dirs = ();
2818             my $pd = dirname($product);
2819
2820             foreach (@{$unified_info{sources}->{$product} // []},
2821                      @{$unified_info{shared_sources}->{$product} // []}) {
2822                 my $d = dirname($_);
2823
2824                 # We don't want to create targets for source directories
2825                 # when building out of source
2826                 next if ($config{sourcedir} ne $config{builddir}
2827                              && $d =~ m|^\Q$config{sourcedir}\E|);
2828                 # We already have a "test" target, and the current directory
2829                 # is just silly to make a target for
2830                 next if $d eq "test" || $d eq ".";
2831
2832                 $dirs{$d} = 1;
2833                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2834                     if $d ne $pd;
2835             }
2836             foreach (sort keys %dirs) {
2837                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2838                     $product;
2839             }
2840         }
2841     }
2842 }
2843
2844 # For the schemes that need it, we provide the old *_obj configs
2845 # from the *_asm_obj ones
2846 foreach (grep /_(asm|aux)_src$/, keys %target) {
2847     my $src = $_;
2848     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2849     $target{$obj} = $target{$src};
2850     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2851     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2852 }
2853
2854 # Write down our configuration where it fits #########################
2855
2856 my %template_vars = (
2857     config => \%config,
2858     target => \%target,
2859     disablables => \@disablables,
2860     disablables_int => \@disablables_int,
2861     disabled => \%disabled,
2862     withargs => \%withargs,
2863     unified_info => \%unified_info,
2864     tls => \@tls,
2865     dtls => \@dtls,
2866     makevars => [ sort keys %user ],
2867     disabled_info => \%disabled_info,
2868     user_crossable => \@user_crossable,
2869 );
2870 my $configdata_outname = 'configdata.pm';
2871 open CONFIGDATA, ">$configdata_outname.new"
2872     or die "Trying to create $configdata_outname.new: $!";
2873 my $configdata_tmplname = cleanfile($srcdir, "configdata.pm.in", $blddir);
2874 my $configdata_tmpl =
2875     OpenSSL::Template->new(TYPE => 'FILE', SOURCE => $configdata_tmplname);
2876 $configdata_tmpl->fill_in(
2877     FILENAME => $configdata_tmplname,
2878     OUTPUT => \*CONFIGDATA,
2879     HASH => { %template_vars,
2880               autowarntext => [
2881                   'WARNING: do not edit!',
2882                   "Generated by Configure from $configdata_tmplname",
2883               ] }
2884 ) or die $Text::Template::ERROR;
2885 close CONFIGDATA;
2886
2887 rename "$configdata_outname.new", $configdata_outname;
2888 if ($builder_platform eq 'unix') {
2889     my $mode = (0755 & ~umask);
2890     chmod $mode, 'configdata.pm'
2891         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2892 }
2893 print "Created $configdata_outname\n";
2894
2895 print "Running $configdata_outname\n";
2896 my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
2897 my $cmd = "$perlcmd $configdata_outname";
2898 #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2899 system($cmd);
2900 exit 1 if $? != 0;
2901
2902 $SIG{__DIE__} = $orig_death_handler;
2903
2904 print <<"EOF" if ($disabled{threads} eq "unavailable");
2905
2906 The library could not be configured for supporting multi-threaded
2907 applications as the compiler options required on this system are not known.
2908 See file INSTALL.md for details if you need multi-threading.
2909 EOF
2910
2911 print <<"EOF" if ($no_shared_warn);
2912
2913 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2914 platform, so we will pretend you gave the option 'no-pic', which also disables
2915 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2916 or position independent code, please let us know (but please first make sure
2917 you have tried with a current version of OpenSSL).
2918 EOF
2919
2920 print $banner;
2921
2922 exit(0);
2923
2924 ######################################################################
2925 #
2926 # Helpers and utility functions
2927 #
2928
2929 # Death handler, to print a helpful message in case of failure #######
2930 #
2931 sub death_handler {
2932     die @_ if $^S;              # To prevent the added message in eval blocks
2933     my $build_file = $target{build_file} // "build file";
2934     my @message = ( <<"_____", @_ );
2935
2936 Failure!  $build_file wasn't produced.
2937 Please read INSTALL.md and associated NOTES-* files.  You may also have to
2938 look over your available compiler tool chain or change your configuration.
2939
2940 _____
2941
2942     # Dying is terminal, so it's ok to reset the signal handler here.
2943     $SIG{__DIE__} = $orig_death_handler;
2944     die @message;
2945 }
2946
2947 # Configuration file reading #########################################
2948
2949 # Note: All of the helper functions are for lazy evaluation.  They all
2950 # return a CODE ref, which will return the intended value when evaluated.
2951 # Thus, whenever there's mention of a returned value, it's about that
2952 # intended value.
2953
2954 # Helper function to implement conditional value variants, with a default
2955 # plus additional values based on the value of $config{build_type}.
2956 # Arguments are given in hash table form:
2957 #
2958 #       picker(default => "Basic string: ",
2959 #              debug   => "debug",
2960 #              release => "release")
2961 #
2962 # When configuring with --debug, the resulting string will be
2963 # "Basic string: debug", and when not, it will be "Basic string: release"
2964 #
2965 # This can be used to create variants of sets of flags according to the
2966 # build type:
2967 #
2968 #       cflags => picker(default => "-Wall",
2969 #                        debug   => "-g -O0",
2970 #                        release => "-O3")
2971 #
2972 sub picker {
2973     my %opts = @_;
2974     return sub { add($opts{default} || (),
2975                      $opts{$config{build_type}} || ())->(); }
2976 }
2977
2978 # Helper function to combine several values of different types into one.
2979 # This is useful if you want to combine a string with the result of a
2980 # lazy function, such as:
2981 #
2982 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2983 #
2984 sub combine {
2985     my @stuff = @_;
2986     return sub { add(@stuff)->(); }
2987 }
2988
2989 # Helper function to implement conditional values depending on the value
2990 # of $disabled{threads}.  Can be used as follows:
2991 #
2992 #       cflags => combine("-Wall", threads("-pthread"))
2993 #
2994 sub threads {
2995     my @flags = @_;
2996     return sub { add($disabled{threads} ? () : @flags)->(); }
2997 }
2998
2999 sub shared {
3000     my @flags = @_;
3001     return sub { add($disabled{shared} ? () : @flags)->(); }
3002 }
3003
3004 our $add_called = 0;
3005 # Helper function to implement adding values to already existing configuration
3006 # values.  It handles elements that are ARRAYs, CODEs and scalars
3007 sub _add {
3008     my $separator = shift;
3009
3010     # If there's any ARRAY in the collection of values OR the separator
3011     # is undef, we will return an ARRAY of combined values, otherwise a
3012     # string of joined values with $separator as the separator.
3013     my $found_array = !defined($separator);
3014
3015     my @values =
3016         map {
3017             my $res = $_;
3018             while (ref($res) eq "CODE") {
3019                 $res = $res->();
3020             }
3021             if (defined($res)) {
3022                 if (ref($res) eq "ARRAY") {
3023                     $found_array = 1;
3024                     @$res;
3025                 } else {
3026                     $res;
3027                 }
3028             } else {
3029                 ();
3030             }
3031     } (@_);
3032
3033     $add_called = 1;
3034
3035     if ($found_array) {
3036         [ @values ];
3037     } else {
3038         join($separator, grep { defined($_) && $_ ne "" } @values);
3039     }
3040 }
3041 sub add_before {
3042     my $separator = " ";
3043     if (ref($_[$#_]) eq "HASH") {
3044         my $opts = pop;
3045         $separator = $opts->{separator};
3046     }
3047     my @x = @_;
3048     sub { _add($separator, @x, @_) };
3049 }
3050 sub add {
3051     my $separator = " ";
3052     if (ref($_[$#_]) eq "HASH") {
3053         my $opts = pop;
3054         $separator = $opts->{separator};
3055     }
3056     my @x = @_;
3057     sub { _add($separator, @_, @x) };
3058 }
3059
3060 sub read_eval_file {
3061     my $fname = shift;
3062     my $content;
3063     my @result;
3064
3065     open F, "< $fname" or die "Can't open '$fname': $!\n";
3066     {
3067         undef local $/;
3068         $content = <F>;
3069     }
3070     close F;
3071     {
3072         local $@;
3073
3074         @result = ( eval $content );
3075         warn $@ if $@;
3076     }
3077     return wantarray ? @result : $result[0];
3078 }
3079
3080 # configuration reader, evaluates the input file as a perl script and expects
3081 # it to fill %targets with target configurations.  Those are then added to
3082 # %table.
3083 sub read_config {
3084     my $fname = shift;
3085     my %targets;
3086
3087     {
3088         # Protect certain tables from tampering
3089         local %table = ();
3090
3091         %targets = read_eval_file($fname);
3092     }
3093     my %preexisting = ();
3094     foreach (sort keys %targets) {
3095         $preexisting{$_} = 1 if $table{$_};
3096     }
3097     die <<"EOF",
3098 The following config targets from $fname
3099 shadow pre-existing config targets with the same name:
3100 EOF
3101         map { "  $_\n" } sort keys %preexisting
3102         if %preexisting;
3103
3104
3105     # For each target, check that it's configured with a hash table.
3106     foreach (keys %targets) {
3107         if (ref($targets{$_}) ne "HASH") {
3108             if (ref($targets{$_}) eq "") {
3109                 warn "Deprecated target configuration for $_, ignoring...\n";
3110             } else {
3111                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3112             }
3113             delete $targets{$_};
3114         } else {
3115             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3116         }
3117     }
3118
3119     %table = (%table, %targets);
3120
3121 }
3122
3123 # configuration resolver.  Will only resolve all the lazy evaluation
3124 # codeblocks for the chosen target and all those it inherits from,
3125 # recursively
3126 sub resolve_config {
3127     my $target = shift;
3128     my @breadcrumbs = @_;
3129
3130 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3131
3132     if (grep { $_ eq $target } @breadcrumbs) {
3133         die "inherit_from loop!  target backtrace:\n  "
3134             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3135     }
3136
3137     if (!defined($table{$target})) {
3138         warn "Warning! target $target doesn't exist!\n";
3139         return ();
3140     }
3141     # Recurse through all inheritances.  They will be resolved on the
3142     # fly, so when this operation is done, they will all just be a
3143     # bunch of attributes with string values.
3144     # What we get here, though, are keys with references to lists of
3145     # the combined values of them all.  We will deal with lists after
3146     # this stage is done.
3147     my %combined_inheritance = ();
3148     if ($table{$target}->{inherit_from}) {
3149         my @inherit_from =
3150             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3151         foreach (@inherit_from) {
3152             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3153
3154             # 'template' is a marker that's considered private to
3155             # the config that had it.
3156             delete $inherited_config{template};
3157
3158             foreach (keys %inherited_config) {
3159                 if (!$combined_inheritance{$_}) {
3160                     $combined_inheritance{$_} = [];
3161                 }
3162                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3163             }
3164         }
3165     }
3166
3167     # We won't need inherit_from in this target any more, since we've
3168     # resolved all the inheritances that lead to this
3169     delete $table{$target}->{inherit_from};
3170
3171     # Now is the time to deal with those lists.  Here's the place to
3172     # decide what shall be done with those lists, all based on the
3173     # values of the target we're currently dealing with.
3174     # - If a value is a coderef, it will be executed with the list of
3175     #   inherited values as arguments.
3176     # - If the corresponding key doesn't have a value at all or is the
3177     #   empty string, the inherited value list will be run through the
3178     #   default combiner (below), and the result becomes this target's
3179     #   value.
3180     # - Otherwise, this target's value is assumed to be a string that
3181     #   will simply override the inherited list of values.
3182     my $default_combiner = add();
3183
3184     my %all_keys =
3185         map { $_ => 1 } (keys %combined_inheritance,
3186                          keys %{$table{$target}});
3187
3188     sub process_values {
3189         my $object    = shift;
3190         my $inherited = shift;  # Always a [ list ]
3191         my $target    = shift;
3192         my $entry     = shift;
3193
3194         $add_called = 0;
3195
3196         while(ref($object) eq "CODE") {
3197             $object = $object->(@$inherited);
3198         }
3199         if (!defined($object)) {
3200             return ();
3201         }
3202         elsif (ref($object) eq "ARRAY") {
3203             local $add_called;  # To make sure recursive calls don't affect it
3204             return [ map { process_values($_, $inherited, $target, $entry) }
3205                      @$object ];
3206         } elsif (ref($object) eq "") {
3207             return $object;
3208         } else {
3209             die "cannot handle reference type ",ref($object)
3210                 ," found in target ",$target," -> ",$entry,"\n";
3211         }
3212     }
3213
3214     foreach my $key (sort keys %all_keys) {
3215         my $previous = $combined_inheritance{$key};
3216
3217         # Current target doesn't have a value for the current key?
3218         # Assign it the default combiner, the rest of this loop body
3219         # will handle it just like any other coderef.
3220         if (!exists $table{$target}->{$key}) {
3221             $table{$target}->{$key} = $default_combiner;
3222         }
3223
3224         $table{$target}->{$key} = process_values($table{$target}->{$key},
3225                                                $combined_inheritance{$key},
3226                                                $target, $key);
3227         unless(defined($table{$target}->{$key})) {
3228             delete $table{$target}->{$key};
3229         }
3230 #        if ($extra_checks &&
3231 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$key})) {
3232 #            warn "$key got replaced in $target\n";
3233 #        }
3234     }
3235
3236     # Finally done, return the result.
3237     return %{$table{$target}};
3238 }
3239
3240 sub usage
3241         {
3242         print STDERR $usage;
3243         print STDERR "\npick os/compiler from:\n";
3244         my $j=0;
3245         my $i;
3246         my $k=0;
3247         foreach $i (sort keys %table)
3248                 {
3249                 next if $table{$i}->{template};
3250                 next if $i =~ /^debug/;
3251                 $k += length($i) + 1;
3252                 if ($k > 78)
3253                         {
3254                         print STDERR "\n";
3255                         $k=length($i);
3256                         }
3257                 print STDERR $i . " ";
3258                 }
3259         foreach $i (sort keys %table)
3260                 {
3261                 next if $table{$i}->{template};
3262                 next if $i !~ /^debug/;
3263                 $k += length($i) + 1;
3264                 if ($k > 78)
3265                         {
3266                         print STDERR "\n";
3267                         $k=length($i);
3268                         }
3269                 print STDERR $i . " ";
3270                 }
3271         exit(1);
3272         }
3273
3274 sub compiler_predefined {
3275     state %predefined;
3276     my $cc = shift;
3277
3278     return () if $^O eq 'VMS';
3279
3280     die 'compiler_predefined called without a compiler command'
3281         unless $cc;
3282
3283     if (! $predefined{$cc}) {
3284
3285         $predefined{$cc} = {};
3286
3287         # collect compiler pre-defines from gcc or gcc-alike...
3288         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3289         while (my $l = <PIPE>) {
3290             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3291             $predefined{$cc}->{$1} = $2 // '';
3292         }
3293         close(PIPE);
3294     }
3295
3296     return %{$predefined{$cc}};
3297 }
3298
3299 sub which
3300 {
3301     my ($name)=@_;
3302
3303     if (eval { require IPC::Cmd; 1; }) {
3304         IPC::Cmd->import();
3305         return scalar IPC::Cmd::can_run($name);
3306     } else {
3307         # if there is $directories component in splitpath,
3308         # then it's not something to test with $PATH...
3309         return $name if (File::Spec->splitpath($name))[1];
3310
3311         foreach (File::Spec->path()) {
3312             my $fullpath = catfile($_, "$name$target{exe_extension}");
3313             if (-f $fullpath and -x $fullpath) {
3314                 return $fullpath;
3315             }
3316         }
3317     }
3318 }
3319
3320 sub env
3321 {
3322     my $name = shift;
3323     my %opts = @_;
3324
3325     unless ($opts{cacheonly}) {
3326         # Note that if $ENV{$name} doesn't exist or is undefined,
3327         # $config{perlenv}->{$name} will be created with the value
3328         # undef.  This is intentional.
3329
3330         $config{perlenv}->{$name} = $ENV{$name}
3331             if ! exists $config{perlenv}->{$name};
3332     }
3333     return $config{perlenv}->{$name};
3334 }
3335
3336 # Configuration printer ##############################################
3337
3338 sub print_table_entry
3339 {
3340     local $now_printing = shift;
3341     my %target = resolve_config($now_printing);
3342     my $type = shift;
3343
3344     # Don't print the templates
3345     return if $target{template};
3346
3347     my @sequence = (
3348         "sys_id",
3349         "cpp",
3350         "cppflags",
3351         "defines",
3352         "includes",
3353         "cc",
3354         "cflags",
3355         "ld",
3356         "lflags",
3357         "loutflag",
3358         "ex_libs",
3359         "bn_ops",
3360         "enable",
3361         "disable",
3362         "poly1035_asm_src",
3363         "thread_scheme",
3364         "perlasm_scheme",
3365         "dso_scheme",
3366         "shared_target",
3367         "shared_cflag",
3368         "shared_defines",
3369         "shared_ldflag",
3370         "shared_rcflag",
3371         "shared_extension",
3372         "dso_extension",
3373         "obj_extension",
3374         "exe_extension",
3375         "ranlib",
3376         "ar",
3377         "arflags",
3378         "aroutflag",
3379         "rc",
3380         "rcflags",
3381         "rcoutflag",
3382         "mt",
3383         "mtflags",
3384         "mtinflag",
3385         "mtoutflag",
3386         "multilib",
3387         "build_scheme",
3388         );
3389
3390     if ($type eq "TABLE") {
3391         print "\n";
3392         print "*** $now_printing\n";
3393         foreach (@sequence) {
3394             if (ref($target{$_}) eq "ARRAY") {
3395                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3396             } else {
3397                 printf "\$%-12s = %s\n", $_, $target{$_};
3398             }
3399         }
3400     } elsif ($type eq "HASH") {
3401         my $largest =
3402             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3403         print "    '$now_printing' => {\n";
3404         foreach (@sequence) {
3405             if ($target{$_}) {
3406                 if (ref($target{$_}) eq "ARRAY") {
3407                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3408                 } else {
3409                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3410                 }
3411             }
3412         }
3413         print "    },\n";
3414     }
3415 }
3416
3417 # Utility routines ###################################################
3418
3419 # On VMS, if the given file is a logical name, File::Spec::Functions
3420 # will consider it an absolute path.  There are cases when we want a
3421 # purely syntactic check without checking the environment.
3422 sub isabsolute {
3423     my $file = shift;
3424
3425     # On non-platforms, we just use file_name_is_absolute().
3426     return file_name_is_absolute($file) unless $^O eq "VMS";
3427
3428     # If the file spec includes a device or a directory spec,
3429     # file_name_is_absolute() is perfectly safe.
3430     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3431
3432     # Here, we know the given file spec isn't absolute
3433     return 0;
3434 }
3435
3436 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3437 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3438 # realpath() requires that at least all path components except the last is an
3439 # existing directory.  On VMS, the last component of the directory spec must
3440 # exist.
3441 sub absolutedir {
3442     my $dir = shift;
3443
3444     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3445     # will return the volume name for the device, no matter what.  Also,
3446     # it will return an incorrect directory spec if the argument is a
3447     # directory that doesn't exist.
3448     if ($^O eq "VMS") {
3449         return rel2abs($dir);
3450     }
3451
3452     # We use realpath() on Unix, since no other will properly clean out
3453     # a directory spec.
3454     use Cwd qw/realpath/;
3455
3456     return realpath($dir);
3457 }
3458
3459 # Check if all paths are one and the same, using stat.  They must both exist
3460 # We need this for the cases when File::Spec doesn't detect case insensitivity
3461 # (File::Spec::Unix assumes case sensitivity)
3462 sub samedir {
3463     die "samedir expects two arguments\n" unless scalar @_ == 2;
3464
3465     my @stat0 = stat($_[0]);    # First argument
3466     my @stat1 = stat($_[1]);    # Second argument
3467
3468     die "Couldn't stat $_[0]" unless @stat0;
3469     die "Couldn't stat $_[1]" unless @stat1;
3470
3471     # Compare device number
3472     return 0 unless ($stat0[0] == $stat1[0]);
3473     # Compare "inode".  The perl manual recommends comparing as
3474     # string rather than as number.
3475     return 0 unless ($stat0[1] eq $stat1[1]);
3476
3477     return 1;                   # All the same
3478 }
3479
3480 sub quotify {
3481     my %processors = (
3482         perl    => sub { my $x = shift;
3483                          $x =~ s/([\\\$\@"])/\\$1/g;
3484                          return '"'.$x.'"'; },
3485         maybeshell => sub { my $x = shift;
3486                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3487                             if ($x ne $y || $x =~ m|\s|) {
3488                                 return '"'.$y.'"';
3489                             } else {
3490                                 return $x;
3491                             }
3492                         },
3493         );
3494     my $for = shift;
3495     my $processor =
3496         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3497
3498     return map { $processor->($_); } @_;
3499 }
3500
3501 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3502 # $filename is a file name to read from
3503 # $line_concat_cond_re is a regexp detecting a line continuation ending
3504 # $line_concat is a CODEref that takes care of concatenating two lines
3505 sub collect_from_file {
3506     my $filename = shift;
3507     my $line_concat_cond_re = shift;
3508     my $line_concat = shift;
3509
3510     open my $fh, $filename || die "unable to read $filename: $!\n";
3511     return sub {
3512         my $saved_line = "";
3513         $_ = "";
3514         while (<$fh>) {
3515             s|\R$||;
3516             if (defined $line_concat) {
3517                 $_ = $line_concat->($saved_line, $_);
3518                 $saved_line = "";
3519             }
3520             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3521                 $saved_line = $_;
3522                 next;
3523             }
3524             return $_;
3525         }
3526         die "$filename ending with continuation line\n" if $_;
3527         close $fh;
3528         return undef;
3529     }
3530 }
3531
3532 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3533 # $array is an ARRAYref of lines
3534 # $line_concat_cond_re is a regexp detecting a line continuation ending
3535 # $line_concat is a CODEref that takes care of concatenating two lines
3536 sub collect_from_array {
3537     my $array = shift;
3538     my $line_concat_cond_re = shift;
3539     my $line_concat = shift;
3540     my @array = (@$array);
3541
3542     return sub {
3543         my $saved_line = "";
3544         $_ = "";
3545         while (defined($_ = shift @array)) {
3546             s|\R$||;
3547             if (defined $line_concat) {
3548                 $_ = $line_concat->($saved_line, $_);
3549                 $saved_line = "";
3550             }
3551             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3552                 $saved_line = $_;
3553                 next;
3554             }
3555             return $_;
3556         }
3557         die "input text ending with continuation line\n" if $_;
3558         return undef;
3559     }
3560 }
3561
3562 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3563 # $lineiterator is a CODEref that delivers one line at a time.
3564 # All following arguments are regex/CODEref pairs, where the regexp detects a
3565 # line and the CODEref does something with the result of the regexp.
3566 sub collect_information {
3567     my $lineiterator = shift;
3568     my %collectors = @_;
3569
3570     while(defined($_ = $lineiterator->())) {
3571         s|\R$||;
3572         my $found = 0;
3573         if ($collectors{"BEFORE"}) {
3574             $collectors{"BEFORE"}->($_);
3575         }
3576         foreach my $re (keys %collectors) {
3577             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3578                 $collectors{$re}->($lineiterator);
3579                 $found = 1;
3580             };
3581         }
3582         if ($collectors{"OTHERWISE"}) {
3583             $collectors{"OTHERWISE"}->($lineiterator, $_)
3584                 unless $found || !defined $collectors{"OTHERWISE"};
3585         }
3586         if ($collectors{"AFTER"}) {
3587             $collectors{"AFTER"}->($_);
3588         }
3589     }
3590 }
3591
3592 # tokenize($line)
3593 # tokenize($line,$separator)
3594 # $line is a line of text to split up into tokens
3595 # $separator [optional] is a regular expression that separates the tokens,
3596 # the default being spaces.  Do not use quotes of any kind as separators,
3597 # that will give undefined results.
3598 # Returns a list of tokens.
3599 #
3600 # Tokens are divided by separator (spaces by default).  If the tokens include
3601 # the separators, they have to be quoted with single or double quotes.
3602 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3603 # with backslash.
3604 # Basically, the same quoting rules apply for " and ' as in any
3605 # Unix shell.
3606 sub tokenize {
3607     my $line = my $debug_line = shift;
3608     my $separator = shift // qr|\s+|;
3609     my @result = ();
3610
3611     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3612         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3613     }
3614
3615     while ($line =~ s|^${separator}||, $line ne "") {
3616         my $token = "";
3617     again:
3618         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3619         $token .= $1;
3620         $line = $2.$';
3621
3622         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3623             $token .= $1;
3624             $line = $';
3625             goto again;
3626         } elsif ($line =~ m/^'([^']*)'/) {
3627             $token .= $1;
3628             $line = $';
3629             goto again;
3630         }
3631         push @result, $token;
3632     }
3633
3634     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3635         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3636         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3637     }
3638     return @result;
3639 }