Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2021 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::fallback "$FindBin::Bin/external/perl/MODULES.txt";
  21 use OpenSSL::Glob;
  22 use OpenSSL::Template;
  23 use OpenSSL::config;
  24
  25 # see INSTALL.md for instructions.
  26
  27 my $orig_death_handler = $SIG{__DIE__};
  28 $SIG{__DIE__} = \&death_handler;
  29
  30 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  31
  32 my $banner = <<"EOF";
  33
  34 **********************************************************************
  35 ***                                                                ***
  36 ***   OpenSSL has been successfully configured                     ***
  37 ***                                                                ***
  38 ***   If you encounter a problem while building, please open an    ***
  39 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
  40 ***   and include the output from the following command:           ***
  41 ***                                                                ***
  42 ***       perl configdata.pm --dump                                ***
  43 ***                                                                ***
  44 ***   (If you are new to OpenSSL, you might want to consult the    ***
  45 ***   'Troubleshooting' section in the INSTALL.md file first)      ***
  46 ***                                                                ***
  47 **********************************************************************
  48 EOF
  49
  50 # Options:
  51 #
  52 # --config      add the given configuration file, which will be read after
  53 #               any "Configurations*" files that are found in the same
  54 #               directory as this script.
  55 # --prefix      prefix for the OpenSSL installation, which includes the
  56 #               directories bin, lib, include, share/man, share/doc/openssl
  57 #               This becomes the value of INSTALLTOP in Makefile
  58 #               (Default: /usr/local)
  59 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  60 #               If it's a relative directory, it will be added on the directory
  61 #               given with --prefix.
  62 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  63 #               (Default: PREFIX/ssl)
  64 # --banner=".." Output specified text instead of default completion banner
  65 #
  66 # --cross-compile-prefix Add specified prefix to binutils components.
  67 #
  68 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0
  69 #               Define the public APIs as they were for that version
  70 #               including patch releases.  If 'no-deprecated' is also
  71 #               given, do not compile support for interfaces deprecated
  72 #               up to and including the specified OpenSSL version.
  73 #
  74 # no-hw-xxx     do not compile support for specific crypto hardware.
  75 #               Generic OpenSSL-style methods relating to this support
  76 #               are always compiled but return NULL if the hardware
  77 #               support isn't compiled.
  78 # no-hw         do not compile support for any crypto hardware.
  79 # [no-]threads  [don't] try to create a library that is suitable for
  80 #               multithreaded applications (default is "threads" if we
  81 #               know how to do it)
  82 # [no-]shared   [don't] try to create shared libraries when supported.
  83 # [no-]pic      [don't] try to build position independent code when supported.
  84 #               If disabled, it also disables shared and dynamic-engine.
  85 # no-asm        do not use assembler
  86 # no-egd        do not compile support for the entropy-gathering daemon APIs
  87 # [no-]zlib     [don't] compile support for zlib compression.
  88 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  89 #               library and will be loaded in run-time by the OpenSSL library.
  90 # sctp          include SCTP support
  91 # no-uplink     Don't build support for UPLINK interface.
  92 # enable-weak-ssl-ciphers
  93 #               Enable weak ciphers that are disabled by default.
  94 # 386           generate 80386 code in assembly modules
  95 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  96 #               mentioned '386' option implies this one
  97 # no-<cipher>   build without specified algorithm (dsa, idea, rc5, ...)
  98 # -<xxx> +<xxx> All options which are unknown to the 'Configure' script are
  99 # /<xxx>        passed through to the compiler. Unix-style options beginning
 100 #               with a '-' or '+' are recognized, as well as Windows-style
 101 #               options beginning with a '/'. If the option contains arguments
 102 #               separated by spaces, then the URL-style notation %20 can be
 103 #               used for the space character in order to avoid having to quote
 104 #               the option. For example, -opt%20arg gets expanded to -opt arg.
 105 #               In fact, any ASCII character can be encoded as %xx using its
 106 #               hexadecimal encoding.
 107 # -static       while -static is also a pass-through compiler option (and
 108 #               as such is limited to environments where it's actually
 109 #               meaningful), it triggers a number configuration options,
 110 #               namely no-pic, no-shared and no-threads. It is
 111 #               argued that the only reason to produce statically linked
 112 #               binaries (and in context it means executables linked with
 113 #               -static flag, and not just executables linked with static
 114 #               libcrypto.a) is to eliminate dependency on specific run-time,
 115 #               a.k.a. libc version. The mentioned config options are meant
 116 #               to achieve just that. Unfortunately on Linux it's impossible
 117 #               to eliminate the dependency completely for openssl executable
 118 #               because of getaddrinfo and gethostbyname calls, which can
 119 #               invoke dynamically loadable library facility anyway to meet
 120 #               the lookup requests. For this reason on Linux statically
 121 #               linked openssl executable has rather debugging value than
 122 #               production quality.
 123 #
 124 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
 125 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
 126 # Following are set automatically by this script
 127 #
 128 # MD5_ASM       use some extra md5 assembler,
 129 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 130 # RMD160_ASM    use some extra ripemd160 assembler,
 131 # SHA256_ASM    sha256_block is implemented in assembler
 132 # SHA512_ASM    sha512_block is implemented in assembler
 133 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 134
 135 # Minimum warning options... any contributions to OpenSSL should at least
 136 # get past these.  Note that we only use these with C compilers, not with
 137 # C++ compilers.
 138
 139 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 140 # -DPEDANTIC complements -pedantic and is meant to mask code that
 141 # is not strictly standard-compliant and/or implementation-specific,
 142 # e.g. inline assembly, disregards to alignment requirements, such
 143 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 144 # to be used even in sanitized builds, because sanitizer too is
 145 # supposed to and does take notice of non-standard behaviour. Then
 146 # -pedantic with pre-C9x compiler would also complain about 'long
 147 # long' not being supported. As 64-bit algorithms are common now,
 148 # it grew impossible to resolve this without sizeable additional
 149 # code, so we just tell compiler to be pedantic about everything
 150 # but 'long long' type.
 151
 152 my @gcc_devteam_warn = qw(
 153     -DDEBUG_UNUSED
 154     -DPEDANTIC -pedantic -Wno-long-long
 155     -Wall
 156     -Wextra
 157     -Wno-unused-parameter
 158     -Wno-missing-field-initializers
 159     -Wswitch
 160     -Wsign-compare
 161     -Wshadow
 162     -Wformat
 163     -Wtype-limits
 164     -Wundef
 165     -Werror
 166     -Wmissing-prototypes
 167     -Wstrict-prototypes
 168 );
 169
 170 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 171 # TODO(openssl-team): fix problems and investigate if (at least) the
 172 # following warnings can also be enabled:
 173 #       -Wcast-align
 174 #       -Wunreachable-code -- no, too ugly/compiler-specific
 175 #       -Wlanguage-extension-token -- no, we use asm()
 176 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 177 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 178 my @clang_devteam_warn = qw(
 179     -Wno-unknown-warning-option
 180     -Wswitch-default
 181     -Wno-parentheses-equality
 182     -Wno-language-extension-token
 183     -Wno-extended-offsetof
 184     -Wconditional-uninitialized
 185     -Wincompatible-pointer-types-discards-qualifiers
 186     -Wmissing-variable-declarations
 187 );
 188
 189 my @cl_devteam_warn = qw(
 190     /WX
 191 );
 192
 193 my $strict_warnings = 0;
 194
 195 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 196 # which would cover all BSD flavors. -pthread applies to them all,
 197 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 198 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 199 # which has to be accompanied by explicit -D_THREAD_SAFE and
 200 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 201 # seems to be sufficient?
 202 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 203
 204 #
 205 # API compatibility name to version number mapping.
 206 #
 207 my $apitable = {
 208     # This table expresses when API additions or changes can occur.
 209     # The numbering used changes from 3.0 and on because we updated
 210     # (solidified) our version numbering scheme at that point.
 211
 212     # From 3.0 and on, we internalise the given version number in decimal
 213     # as MAJOR * 10000 + MINOR * 100 + 0
 214     "3.0.0" => 30000,
 215     "3.0"   => 30000,
 216
 217     # Note that before 3.0, we didn't have the same version number scheme.
 218     # Still, the numbering we use here covers what we need.
 219     "1.1.1" => 10101,
 220     "1.1.0" => 10100,
 221     "1.0.2" => 10002,
 222     "1.0.1" => 10001,
 223     "1.0.0" => 10000,
 224     "0.9.8" =>   908,
 225 };
 226
 227 # For OpenSSL::config::get_platform
 228 my %guess_opts = ();
 229
 230 my $dryrun = 0;
 231
 232 our %table = ();
 233 our %config = ();
 234 our %withargs = ();
 235 our $now_printing;      # set to current entry's name in print_table_entry
 236                         # (todo: right thing would be to encapsulate name
 237                         # into %target [class] and make print_table_entry
 238                         # a method)
 239
 240 # Forward declarations ###############################################
 241
 242 # read_config(filename)
 243 #
 244 # Reads a configuration file and populates %table with the contents
 245 # (which the configuration file places in %targets).
 246 sub read_config;
 247
 248 # resolve_config(target)
 249 #
 250 # Resolves all the late evaluations, inheritances and so on for the
 251 # chosen target and any target it inherits from.
 252 sub resolve_config;
 253
 254
 255 # Information collection #############################################
 256
 257 # Unified build supports separate build dir
 258 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 259 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 260
 261 # File::Spec::Unix doesn't detect case insensitivity, so we make sure to
 262 # check if the source and build directory are really the same, and make
 263 # them so.  This avoids all kinds of confusion later on.
 264 # We must check @File::Spec::ISA rather than using File::Spec->isa() to
 265 # know if File::Spec ended up loading File::Spec::Unix.
 266 $srcdir = $blddir
 267     if (grep(/::Unix$/, @File::Spec::ISA)
 268         && samedir($srcdir, $blddir));
 269
 270 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 271
 272 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 273
 274 $config{sourcedir} = abs2rel($srcdir, $blddir);
 275 $config{builddir} = abs2rel($blddir, $blddir);
 276 # echo -n 'holy hand grenade of antioch' | openssl sha256
 277 $config{FIPSKEY} =
 278     'f4556650ac31d35461610bac4ed81b1a181b2d8a43ea2854cbae22ca74560813';
 279
 280 # Collect reconfiguration information if needed
 281 my @argvcopy=@ARGV;
 282
 283 if (grep /^reconf(igure)?$/, @argvcopy) {
 284     die "reconfiguring with other arguments present isn't supported"
 285         if scalar @argvcopy > 1;
 286     if (-f "./configdata.pm") {
 287         my $file = "./configdata.pm";
 288         unless (my $return = do $file) {
 289             die "couldn't parse $file: $@" if $@;
 290             die "couldn't do $file: $!"    unless defined $return;
 291             die "couldn't run $file"       unless $return;
 292         }
 293
 294         @argvcopy = defined($configdata::config{perlargv}) ?
 295             @{$configdata::config{perlargv}} : ();
 296         die "Incorrect data to reconfigure, please do a normal configuration\n"
 297             if (grep(/^reconf/,@argvcopy));
 298         $config{perlenv} = $configdata::config{perlenv} // {};
 299     } else {
 300         die "Insufficient data to reconfigure, please do a normal configuration\n";
 301     }
 302 }
 303
 304 $config{perlargv} = [ @argvcopy ];
 305
 306 # Historical: if known directories in crypto/ have been removed, it means
 307 # that those sub-systems are disabled.
 308 # (the other option would be to removed them from the SUBDIRS statement in
 309 # crypto/build.info)
 310 # We reverse the input list for cosmetic purely reasons, to compensate that
 311 # 'unshift' adds at the front of the list (i.e. in reverse input order).
 312 foreach ( reverse sort( 'aes', 'aria', 'bf', 'camellia', 'cast', 'des', 'dh',
 313                         'dsa', 'ec', 'hmac', 'idea', 'md2', 'md5', 'mdc2',
 314                         'rc2', 'rc4', 'rc5', 'ripemd', 'seed', 'sha',
 315                         'sm2', 'sm3', 'sm4') ) {
 316     unshift @argvcopy, "no-$_" if ! -d catdir($srcdir, 'crypto', $_);
 317 }
 318
 319 # Collect version numbers
 320 my %version = ();
 321
 322 collect_information(
 323     collect_from_file(catfile($srcdir,'VERSION.dat')),
 324     qr/\s*(\w+)\s*=\s*(.*?)\s*$/ =>
 325         sub {
 326             # Only define it if there is a value at all
 327             if ($2 ne '') {
 328                 my $k = $1;
 329                 my $v = $2;
 330                 # Some values are quoted.  Trim the quotes
 331                 $v = $1 if $v =~ /^"(.*)"$/;
 332                 $version{uc $k} = $v;
 333             }
 334         },
 335     "OTHERWISE" =>
 336         sub { die "Something wrong with this line:\n$_\nin $srcdir/VERSION.dat" },
 337     );
 338
 339 $config{major} = $version{MAJOR} // 'unknown';
 340 $config{minor} = $version{MINOR} // 'unknown';
 341 $config{patch} = $version{PATCH} // 'unknown';
 342 $config{prerelease} =
 343     defined $version{PRE_RELEASE_TAG} ? "-$version{PRE_RELEASE_TAG}" : '';
 344 $config{build_metadata} =
 345     defined $version{BUILD_METADATA} ? "+$version{BUILD_METADATA}" : '';
 346 $config{shlib_version} = $version{SHLIB_VERSION} // 'unknown';
 347 $config{release_date} = $version{RELEASE_DATE} // 'xx XXX xxxx';
 348
 349 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 350 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 351
 352 die "erroneous version information in VERSION.dat: ",
 353     "$config{version}, $config{shlib_version}\n"
 354     unless (defined $version{MAJOR}
 355             && defined $version{MINOR}
 356             && defined $version{PATCH}
 357             && defined $version{SHLIB_VERSION});
 358
 359 # Collect target configurations
 360
 361 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 362 foreach (sort glob($pattern)) {
 363     &read_config($_);
 364 }
 365
 366 if (defined env($local_config_envname)) {
 367     if ($^O eq 'VMS') {
 368         # VMS environment variables are logical names,
 369         # which can be used as is
 370         $pattern = $local_config_envname . ':' . '*.conf';
 371     } else {
 372         $pattern = catfile(env($local_config_envname), '*.conf');
 373     }
 374
 375     foreach (sort glob($pattern)) {
 376         &read_config($_);
 377     }
 378 }
 379
 380 # Save away perl command information
 381 $config{perl_cmd} = $^X;
 382 $config{perl_version} = $Config{version};
 383 $config{perl_archname} = $Config{archname};
 384
 385 $config{prefix}="";
 386 $config{openssldir}="";
 387 $config{processor}="";
 388 $config{libdir}="";
 389 my $auto_threads=1;    # enable threads automatically? true by default
 390 my $default_ranlib;
 391
 392 # Known TLS and DTLS protocols
 393 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 394 my @dtls = qw(dtls1 dtls1_2);
 395
 396 # Explicitly known options that are possible to disable.  They can
 397 # be regexps, and will be used like this: /^no-${option}$/
 398 # For developers: keep it sorted alphabetically
 399
 400 my @disablables = (
 401     "acvp-tests",
 402     "afalgeng",
 403     "aria",
 404     "asan",
 405     "asm",
 406     "async",
 407     "autoalginit",
 408     "autoerrinit",
 409     "autoload-config",
 410     "bf",
 411     "blake2",
 412     "buildtest-c++",
 413     "bulk",
 414     "cached-fetch",
 415     "camellia",
 416     "capieng",
 417     "cast",
 418     "chacha",
 419     "cmac",
 420     "cmp",
 421     "cms",
 422     "comp",
 423     "crypto-mdebug",
 424     "ct",
 425     "deprecated",
 426     "des",
 427     "devcryptoeng",
 428     "dgram",
 429     "dh",
 430     "dsa",
 431     "dso",
 432     "dtls",
 433     "dynamic-engine",
 434     "ec",
 435     "ec2m",
 436     "ec_nistp_64_gcc_128",
 437     "ecdh",
 438     "ecdsa",
 439     "egd",
 440     "engine",
 441     "err",
 442     "external-tests",
 443     "filenames",
 444     "fips",
 445     "fips-securitychecks",
 446     "fuzz-afl",
 447     "fuzz-libfuzzer",
 448     "gost",
 449     "idea",
 450     "ktls",
 451     "legacy",
 452     "makedepend",
 453     "md2",
 454     "md4",
 455     "mdc2",
 456     "module",
 457     "msan",
 458     "multiblock",
 459     "nextprotoneg",
 460     "ocb",
 461     "ocsp",
 462     "padlockeng",
 463     "pic",
 464     "pinshared",
 465     "poly1305",
 466     "posix-io",
 467     "psk",
 468     "rc2",
 469     "rc4",
 470     "rc5",
 471     "rdrand",
 472     "rfc3779",
 473     "rmd160",
 474     "scrypt",
 475     "sctp",
 476     "secure-memory",
 477     "seed",
 478     "shared",
 479     "siphash",
 480     "siv",
 481     "sm2",
 482     "sm3",
 483     "sm4",
 484     "sock",
 485     "srp",
 486     "srtp",
 487     "sse2",
 488     "ssl",
 489     "ssl-trace",
 490     "static-engine",
 491     "stdio",
 492     "tests",
 493     "threads",
 494     "tls",
 495     "trace",
 496     "ts",
 497     "ubsan",
 498     "ui-console",
 499     "unit-test",
 500     "uplink",
 501     "weak-ssl-ciphers",
 502     "whirlpool",
 503     "zlib",
 504     "zlib-dynamic",
 505     );
 506 foreach my $proto ((@tls, @dtls))
 507         {
 508         push(@disablables, $proto);
 509         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 510         }
 511
 512 # Internal disablables, for aliasing purposes.  They serve no special
 513 # purpose here, but allow scripts to get to know them through configdata.pm,
 514 # where these are merged with @disablables.
 515 # The actual aliasing mechanism is done via %disable_cascades
 516 my @disablables_int = qw(
 517     crmf
 518     );
 519
 520 my %deprecated_disablables = (
 521     "ssl2" => undef,
 522     "buf-freelists" => undef,
 523     "crypto-mdebug-backtrace" => undef,
 524     "hw" => "hw",               # causes cascade, but no macro
 525     "hw-padlock" => "padlockeng",
 526     "ripemd" => "rmd160",
 527     "ui" => "ui-console",
 528     "heartbeats" => undef,
 529     );
 530
 531 # All of the following are disabled by default:
 532
 533 our %disabled = ( # "what"         => "comment"
 534                   "fips"                => "default",
 535                   "acvp-tests"          => "default",
 536                   "asan"                => "default",
 537                   "buildtest-c++"       => "default",
 538                   "crypto-mdebug"       => "default",
 539                   "crypto-mdebug-backtrace" => "default",
 540                   "devcryptoeng"        => "default",
 541                   "ec_nistp_64_gcc_128" => "default",
 542                   "egd"                 => "default",
 543                   "external-tests"      => "default",
 544                   "fuzz-afl"            => "default",
 545                   "fuzz-libfuzzer"      => "default",
 546                   "ktls"                => "default",
 547                   "md2"                 => "default",
 548                   "msan"                => "default",
 549                   "rc5"                 => "default",
 550                   "sctp"                => "default",
 551                   "ssl-trace"           => "default",
 552                   "ssl3"                => "default",
 553                   "ssl3-method"         => "default",
 554                   "trace"               => "default",
 555                   "ubsan"               => "default",
 556                   "unit-test"           => "default",
 557                   "weak-ssl-ciphers"    => "default",
 558                   "zlib"                => "default",
 559                   "zlib-dynamic"        => "default",
 560                 );
 561
 562 # Note: => pair form used for aesthetics, not to truly make a hash table
 563 my @disable_cascades = (
 564     # "what"            => [ "cascade", ... ]
 565     "bulk"              => [ "shared", "dso",
 566                              "aria", "async", "autoload-config",
 567                              "blake2", "bf", "camellia", "cast", "chacha",
 568                              "cmac", "cms", "cmp", "comp", "ct",
 569                              "des", "dgram", "dh", "dsa",
 570                              "ec", "engine",
 571                              "filenames",
 572                              "idea", "ktls",
 573                              "md4", "multiblock", "nextprotoneg",
 574                              "ocsp", "ocb", "poly1305", "psk",
 575                              "rc2", "rc4", "rmd160",
 576                              "seed", "siphash", "siv",
 577                              "sm3", "sm4", "srp",
 578                              "srtp", "ssl3-method",
 579                              "ts", "ui-console", "whirlpool",
 580                              "fips-securitychecks" ],
 581     sub { $config{processor} eq "386" }
 582                         => [ "sse2" ],
 583     "ssl"               => [ "ssl3" ],
 584     "ssl3-method"       => [ "ssl3" ],
 585     "zlib"              => [ "zlib-dynamic" ],
 586     "des"               => [ "mdc2" ],
 587     "ec"                => [ "ec2m", "ecdsa", "ecdh", "sm2", "gost" ],
 588     "dgram"             => [ "dtls", "sctp" ],
 589     "sock"              => [ "dgram" ],
 590     "dtls"              => [ @dtls ],
 591     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 592                         => [ "dtls" ],
 593
 594     "tls"               => [ @tls ],
 595     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 596                         => [ "tls" ],
 597
 598     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 599
 600     # If no modules, then no dynamic engines either
 601     "module"            => [ "dynamic-engine" ],
 602
 603     # Without shared libraries, dynamic engines aren't possible.
 604     # This is due to them having to link with libcrypto and register features
 605     # using the ENGINE functionality, and since that relies on global tables,
 606     # those *have* to be exacty the same as the ones accessed from the app,
 607     # which cannot be guaranteed if shared libraries aren't present.
 608     # (note that even with shared libraries, both the app and dynamic engines
 609     # must be linked with the same library)
 610     "shared"            => [ "dynamic-engine", "uplink" ],
 611     "dso"               => [ "dynamic-engine", "module" ],
 612     # Other modules don't necessarily have to link with libcrypto, so shared
 613     # libraries do not have to be a condition to produce those.
 614
 615     # Without position independent code, there can be no shared libraries
 616     # or modules.
 617     "pic"               => [ "shared", "module" ],
 618
 619     "module"            => [ "fips", "dso" ],
 620
 621     "engine"            => [ "dynamic-engine", grep(/eng$/, @disablables) ],
 622     "hw"                => [ "padlockeng" ],
 623
 624     # no-autoalginit is only useful when building non-shared
 625     "autoalginit"       => [ "shared", "apps", "fips" ],
 626
 627     "stdio"             => [ "apps", "capieng", "egd" ],
 628     "apps"              => [ "tests" ],
 629     "tests"             => [ "external-tests" ],
 630     "comp"              => [ "zlib" ],
 631     "sm3"               => [ "sm2" ],
 632     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 633
 634     sub { !$disabled{"msan"} } => [ "asm" ],
 635
 636     "cmac"              => [ "siv" ],
 637     "legacy"            => [ "md2" ],
 638
 639     "cmp"               => [ "crmf" ],
 640
 641     "fips"              => [ "fips-securitychecks" ],
 642
 643     "deprecated-3.0"    => [ "engine", "srp" ]
 644     );
 645
 646 # Avoid protocol support holes.  Also disable all versions below N, if version
 647 # N is disabled while N+1 is enabled.
 648 #
 649 my @list = (reverse @tls);
 650 while ((my $first, my $second) = (shift @list, shift @list)) {
 651     last unless @list;
 652     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 653                               => [ @list ] );
 654     unshift @list, $second;
 655 }
 656 my @list = (reverse @dtls);
 657 while ((my $first, my $second) = (shift @list, shift @list)) {
 658     last unless @list;
 659     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 660                               => [ @list ] );
 661     unshift @list, $second;
 662 }
 663
 664 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 665 # To remove something from %disabled, use "enable-foo".
 666 # For symmetry, "disable-foo" is a synonym for "no-foo".
 667
 668 # For the "make variables" CPPINCLUDES and CPPDEFINES, we support lists with
 669 # platform specific list separators.  Users from those platforms should
 670 # recognise those separators from how you set up the PATH to find executables.
 671 # The default is the Unix like separator, :, but as an exception, we also
 672 # support the space as separator.
 673 my $list_separator_re =
 674     { VMS           => qr/(?<!\^),/,
 675       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 676 # All the "make variables" we support
 677 # Some get pre-populated for the sake of backward compatibility
 678 # (we supported those before the change to "make variable" support.
 679 my %user = (
 680     AR          => env('AR'),
 681     ARFLAGS     => [],
 682     AS          => undef,
 683     ASFLAGS     => [],
 684     CC          => env('CC'),
 685     CFLAGS      => [ env('CFLAGS') || () ],
 686     CXX         => env('CXX'),
 687     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 688     CPP         => undef,
 689     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 690     CPPDEFINES  => [],  # Alternative for -D
 691     CPPINCLUDES => [],  # Alternative for -I
 692     CROSS_COMPILE => env('CROSS_COMPILE'),
 693     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 694     LD          => undef,
 695     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 696     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 697     MT          => undef,
 698     MTFLAGS     => [],
 699     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 700     RANLIB      => env('RANLIB'),
 701     RC          => env('RC') || env('WINDRES'),
 702     RCFLAGS     => [ env('RCFLAGS') || () ],
 703     RM          => undef,
 704    );
 705 # Info about what "make variables" may be prefixed with the cross compiler
 706 # prefix.  This should NEVER mention any such variable with a list for value.
 707 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 708 # The same but for flags given as Configure options.  These are *additional*
 709 # input, as opposed to the VAR=string option that override the corresponding
 710 # config target attributes
 711 my %useradd = (
 712     CPPDEFINES  => [],
 713     CPPINCLUDES => [],
 714     CPPFLAGS    => [],
 715     CFLAGS      => [],
 716     CXXFLAGS    => [],
 717     LDFLAGS     => [],
 718     LDLIBS      => [],
 719     RCFLAGS     => [],
 720    );
 721
 722 my %user_synonyms = (
 723     HASHBANGPERL=> 'PERL',
 724     RC          => 'WINDRES',
 725    );
 726
 727 # Some target attributes have been renamed, this is the translation table
 728 my %target_attr_translate =(
 729     ar          => 'AR',
 730     as          => 'AS',
 731     cc          => 'CC',
 732     cxx         => 'CXX',
 733     cpp         => 'CPP',
 734     hashbangperl => 'HASHBANGPERL',
 735     ld          => 'LD',
 736     mt          => 'MT',
 737     ranlib      => 'RANLIB',
 738     rc          => 'RC',
 739     rm          => 'RM',
 740    );
 741
 742 # Initialisers coming from 'config' scripts
 743 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 744 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 745 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 746 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 747 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 748 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 749 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 750
 751 $config{openssl_api_defines}=[];
 752 $config{openssl_sys_defines}=[];
 753 $config{openssl_feature_defines}=[];
 754 $config{options}="";
 755 $config{build_type} = "release";
 756 my $target="";
 757
 758 my %cmdvars = ();               # Stores FOO='blah' type arguments
 759 my %unsupported_options = ();
 760 my %deprecated_options = ();
 761 # If you change this, update apps/version.c
 762 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 763 my @seed_sources = ();
 764 while (@argvcopy)
 765         {
 766         $_ = shift @argvcopy;
 767
 768         # Support env variable assignments among the options
 769         if (m|^(\w+)=(.+)?$|)
 770                 {
 771                 $cmdvars{$1} = $2;
 772                 # Every time a variable is given as a configuration argument,
 773                 # it acts as a reset if the variable.
 774                 if (exists $user{$1})
 775                         {
 776                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 777                         }
 778                 #if (exists $useradd{$1})
 779                 #       {
 780                 #       $useradd{$1} = [];
 781                 #       }
 782                 next;
 783                 }
 784
 785         # VMS is a case insensitive environment, and depending on settings
 786         # out of our control, we may receive options uppercased.  Let's
 787         # downcase at least the part before any equal sign.
 788         if ($^O eq "VMS")
 789                 {
 790                 s/^([^=]*)/lc($1)/e;
 791                 }
 792
 793         # some people just can't read the instructions, clang people have to...
 794         s/^-no-(?!integrated-as)/no-/;
 795
 796         # rewrite some options in "enable-..." form
 797         s /^-?-?shared$/enable-shared/;
 798         s /^sctp$/enable-sctp/;
 799         s /^threads$/enable-threads/;
 800         s /^zlib$/enable-zlib/;
 801         s /^zlib-dynamic$/enable-zlib-dynamic/;
 802         s /^fips$/enable-fips/;
 803
 804         if (/^(no|disable|enable)-(.+)$/)
 805                 {
 806                 my $word = $2;
 807                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 808                         && !exists $deprecated_disablables{$word}
 809                         && !grep { $word eq $_ } @disablables)
 810                         {
 811                         $unsupported_options{$_} = 1;
 812                         next;
 813                         }
 814                 }
 815         if (/^no-(.+)$/ || /^disable-(.+)$/)
 816                 {
 817                 foreach my $proto ((@tls, @dtls))
 818                         {
 819                         if ($1 eq "$proto-method")
 820                                 {
 821                                 $disabled{"$proto"} = "option($proto-method)";
 822                                 last;
 823                                 }
 824                         }
 825                 if ($1 eq "dtls")
 826                         {
 827                         foreach my $proto (@dtls)
 828                                 {
 829                                 $disabled{$proto} = "option(dtls)";
 830                                 }
 831                         $disabled{"dtls"} = "option(dtls)";
 832                         }
 833                 elsif ($1 eq "ssl")
 834                         {
 835                         # Last one of its kind
 836                         $disabled{"ssl3"} = "option(ssl)";
 837                         }
 838                 elsif ($1 eq "tls")
 839                         {
 840                         # XXX: Tests will fail if all SSL/TLS
 841                         # protocols are disabled.
 842                         foreach my $proto (@tls)
 843                                 {
 844                                 $disabled{$proto} = "option(tls)";
 845                                 }
 846                         }
 847                 elsif ($1 eq "static-engine")
 848                         {
 849                         delete $disabled{"dynamic-engine"};
 850                         }
 851                 elsif ($1 eq "dynamic-engine")
 852                         {
 853                         $disabled{"dynamic-engine"} = "option";
 854                         }
 855                 elsif (exists $deprecated_disablables{$1})
 856                         {
 857                         $deprecated_options{$_} = 1;
 858                         if (defined $deprecated_disablables{$1})
 859                                 {
 860                                 $disabled{$deprecated_disablables{$1}} = "option";
 861                                 }
 862                         }
 863                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 864                         {
 865                         $deprecated_options{$_} = 1;
 866                         }
 867                 else
 868                         {
 869                         $disabled{$1} = "option";
 870                         }
 871                 # No longer an automatic choice
 872                 $auto_threads = 0 if ($1 eq "threads");
 873                 }
 874         elsif (/^enable-(.+)$/)
 875                 {
 876                 if ($1 eq "static-engine")
 877                         {
 878                         $disabled{"dynamic-engine"} = "option";
 879                         }
 880                 elsif ($1 eq "dynamic-engine")
 881                         {
 882                         delete $disabled{"dynamic-engine"};
 883                         }
 884                 elsif ($1 eq "zlib-dynamic")
 885                         {
 886                         delete $disabled{"zlib"};
 887                         }
 888                 my $algo = $1;
 889                 delete $disabled{$algo};
 890
 891                 # No longer an automatic choice
 892                 $auto_threads = 0 if ($1 eq "threads");
 893                 }
 894         elsif (/^-d$/)          # From older 'config'
 895                 {
 896                 $config{build_type} = "debug";
 897                 }
 898         elsif (/^-v$/)          # From older 'config'
 899                 {
 900                 $guess_opts{verbose} = 1;
 901                 }
 902         elsif (/^-w$/)          # From older 'config'
 903                 {
 904                 $guess_opts{nowait} = 1;
 905                 }
 906         elsif (/^-t$/)          # From older 'config'
 907                 {
 908                 $dryrun = 1;
 909                 }
 910         elsif (/^--strict-warnings$/)
 911                 {
 912                 # Pretend that our strict flags is a C flag, and replace it
 913                 # with the proper flags later on
 914                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 915                 $strict_warnings=1;
 916                 }
 917         elsif (/^--debug$/)
 918                 {
 919                 $config{build_type} = "debug";
 920                 }
 921         elsif (/^--release$/)
 922                 {
 923                 $config{build_type} = "release";
 924                 }
 925         elsif (/^386$/)
 926                 { $config{processor}=386; }
 927         elsif (/^rsaref$/)
 928                 {
 929                 # No RSAref support any more since it's not needed.
 930                 # The check for the option is there so scripts aren't
 931                 # broken
 932                 }
 933         elsif (m|^[-+/]|)
 934                 {
 935                 if (/^--prefix=(.*)$/)
 936                         {
 937                         $config{prefix}=$1;
 938                         die "Directory given with --prefix MUST be absolute\n"
 939                                 unless file_name_is_absolute($config{prefix});
 940                         }
 941                 elsif (/^--api=(.*)$/)
 942                         {
 943                         my $api = $1;
 944                         die "Unknown API compatibility level $api"
 945                                 unless defined $apitable->{$api};
 946                         $config{api}=$apitable->{$api};
 947                         }
 948                 elsif (/^--libdir=(.*)$/)
 949                         {
 950                         $config{libdir}=$1;
 951                         }
 952                 elsif (/^--openssldir=(.*)$/)
 953                         {
 954                         $config{openssldir}=$1;
 955                         }
 956                 elsif (/^--with-zlib-lib=(.*)$/)
 957                         {
 958                         $withargs{zlib_lib}=$1;
 959                         }
 960                 elsif (/^--with-zlib-include=(.*)$/)
 961                         {
 962                         $withargs{zlib_include}=$1;
 963                         }
 964                 elsif (/^--with-fuzzer-lib=(.*)$/)
 965                         {
 966                         $withargs{fuzzer_lib}=$1;
 967                         }
 968                 elsif (/^--with-fuzzer-include=(.*)$/)
 969                         {
 970                         $withargs{fuzzer_include}=$1;
 971                         }
 972                 elsif (/^--with-rand-seed=(.*)$/)
 973                         {
 974                         foreach my $x (split(m|,|, $1))
 975                             {
 976                             die "Unknown --with-rand-seed choice $x\n"
 977                                 if ! grep { $x eq $_ } @known_seed_sources;
 978                             push @seed_sources, $x;
 979                             }
 980                         }
 981                 elsif (/^--fips-key=(.*)$/)
 982                         {
 983                         $user{FIPSKEY}=lc($1);
 984                         die "Non-hex character in FIPS key\n"
 985                            if $user{FIPSKEY} =~ /[^a-f0-9]/;
 986                         die "FIPS key must have even number of characters\n"
 987                            if length $1 & 1;
 988                         die "FIPS key too long (64 bytes max)\n"
 989                            if length $1 > 64;
 990                         }
 991                 elsif (/^--banner=(.*)$/)
 992                         {
 993                         $banner = $1 . "\n";
 994                         }
 995                 elsif (/^--cross-compile-prefix=(.*)$/)
 996                         {
 997                         $user{CROSS_COMPILE}=$1;
 998                         }
 999                 elsif (/^--config=(.*)$/)
1000                         {
1001                         read_config $1;
1002                         }
1003                 elsif (/^-l(.*)$/)
1004                         {
1005                         push @{$useradd{LDLIBS}}, $_;
1006                         }
1007                 elsif (/^-framework$/)
1008                         {
1009                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
1010                         }
1011                 elsif (/^-L(.*)$/ or /^-Wl,/)
1012                         {
1013                         push @{$useradd{LDFLAGS}}, $_;
1014                         }
1015                 elsif (/^-rpath$/ or /^-R$/)
1016                         # -rpath is the OSF1 rpath flag
1017                         # -R is the old Solaris rpath flag
1018                         {
1019                         my $rpath = shift(@argvcopy) || "";
1020                         $rpath .= " " if $rpath ne "";
1021                         push @{$useradd{LDFLAGS}}, $_, $rpath;
1022                         }
1023                 elsif (/^-static$/)
1024                         {
1025                         push @{$useradd{LDFLAGS}}, $_;
1026                         }
1027                 elsif (m|^[-/]D(.*)$|)
1028                         {
1029                         push @{$useradd{CPPDEFINES}}, $1;
1030                         }
1031                 elsif (m|^[-/]I(.*)$|)
1032                         {
1033                         push @{$useradd{CPPINCLUDES}}, $1;
1034                         }
1035                 elsif (/^-Wp,$/)
1036                         {
1037                         push @{$useradd{CPPFLAGS}}, $1;
1038                         }
1039                 else    # common if (/^[-+]/), just pass down...
1040                         {
1041                         # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
1042                         # This provides a simple way to pass options with arguments separated
1043                         # by spaces without quoting (e.g. -opt%20arg translates to -opt arg).
1044                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
1045                         push @{$useradd{CFLAGS}}, $_;
1046                         push @{$useradd{CXXFLAGS}}, $_;
1047                         }
1048                 }
1049         elsif (m|^/|)
1050                 {
1051                 # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
1052                 # This provides a simple way to pass options with arguments separated
1053                 # by spaces without quoting (e.g. /opt%20arg translates to /opt arg).
1054                 $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
1055                 push @{$useradd{CFLAGS}}, $_;
1056                 push @{$useradd{CXXFLAGS}}, $_;
1057                 }
1058         else
1059                 {
1060                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
1061                 $target=$_;
1062                 }
1063         unless ($_ eq $target || /^no-/ || /^disable-/)
1064                 {
1065                 # "no-..." follows later after implied deactivations
1066                 # have been derived.  (Don't take this too seriously,
1067                 # we really only write OPTIONS to the Makefile out of
1068                 # nostalgia.)
1069
1070                 if ($config{options} eq "")
1071                         { $config{options} = $_; }
1072                 else
1073                         { $config{options} .= " ".$_; }
1074                 }
1075         }
1076
1077 if (keys %deprecated_options)
1078         {
1079         warn "***** Deprecated options: ",
1080                 join(", ", keys %deprecated_options), "\n";
1081         }
1082 if (keys %unsupported_options)
1083         {
1084         die "***** Unsupported options: ",
1085                 join(", ", keys %unsupported_options), "\n";
1086         }
1087
1088 # If any %useradd entry has been set, we must check that the "make
1089 # variables" haven't been set.  We start by checking of any %useradd entry
1090 # is set.
1091 if (grep { scalar @$_ > 0 } values %useradd) {
1092     # Hash of env / make variables names.  The possible values are:
1093     # 1 - "make vars"
1094     # 2 - %useradd entry set
1095     # 3 - both set
1096     my %detected_vars =
1097         map { my $v = 0;
1098               $v += 1 if $cmdvars{$_};
1099               $v += 2 if @{$useradd{$_}};
1100               $_ => $v }
1101         keys %useradd;
1102
1103     # If any of the corresponding "make variables" is set, we error
1104     if (grep { $_ & 1 } values %detected_vars) {
1105         my $names = join(', ', grep { $detected_vars{$_} > 0 }
1106                                sort keys %detected_vars);
1107         die <<"_____";
1108 ***** Mixing make variables and additional compiler/linker flags as
1109 ***** configure command line option is not permitted.
1110 ***** Affected make variables: $names
1111 _____
1112     }
1113 }
1114
1115 # Check through all supported command line variables to see if any of them
1116 # were set, and canonicalise the values we got.  If no compiler or linker
1117 # flag or anything else that affects %useradd was set, we also check the
1118 # environment for values.
1119 my $anyuseradd =
1120     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
1121 foreach (keys %user) {
1122     my $value = $cmdvars{$_};
1123     $value //= env($_) unless $anyuseradd;
1124     $value //=
1125         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
1126     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
1127         unless $anyuseradd;
1128
1129     if (defined $value) {
1130         if (ref $user{$_} eq 'ARRAY') {
1131             if ($_ eq 'CPPDEFINES' || $_ eq 'CPPINCLUDES') {
1132                 $user{$_} = [ split /$list_separator_re/, $value ];
1133             } else {
1134                 $user{$_} = [ $value ];
1135             }
1136         } elsif (!defined $user{$_}) {
1137             $user{$_} = $value;
1138         }
1139     }
1140 }
1141
1142 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1143     && !$disabled{shared}
1144     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1145     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1146         "***** any of asan, msan or ubsan\n";
1147 }
1148
1149 # If no target was given, try guessing.
1150 unless ($target) {
1151     my %system_config = OpenSSL::config::get_platform(%guess_opts, %user);
1152
1153     # The $system_config{disable} is used to populate %disabled with
1154     # entries that aren't already there.
1155     foreach ( @{$system_config{disable} // []} ) {
1156         $disabled{$_} = 'system' unless defined $disabled{$_};
1157     }
1158     delete $system_config{disable};
1159
1160     # Override config entries with stuff from the guesser.
1161     # It's assumed that this really is nothing new.
1162     %config = ( %config, %system_config );
1163     $target = $system_config{target};
1164 }
1165
1166 sub disable {
1167     my $disable_type = shift;
1168
1169     for (@_) {
1170         $disabled{$_} = $disable_type;
1171     }
1172
1173     my @tocheckfor = (@_ ? @_ : keys %disabled);
1174     while (@tocheckfor) {
1175         my %new_tocheckfor = ();
1176         my @cascade_copy = (@disable_cascades);
1177         while (@cascade_copy) {
1178             my ($test, $descendents) =
1179                 (shift @cascade_copy, shift @cascade_copy);
1180             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1181                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1182                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1183                 }
1184             }
1185         }
1186         @tocheckfor = (keys %new_tocheckfor);
1187     }
1188 }
1189 disable();                     # First cascade run
1190
1191 our $die = sub { die @_; };
1192 if ($target eq "TABLE") {
1193     local $die = sub { warn @_; };
1194     foreach (sort keys %table) {
1195         print_table_entry($_, "TABLE");
1196     }
1197     exit 0;
1198 }
1199
1200 if ($target eq "LIST") {
1201     foreach (sort keys %table) {
1202         print $_,"\n" unless $table{$_}->{template};
1203     }
1204     exit 0;
1205 }
1206
1207 if ($target eq "HASH") {
1208     local $die = sub { warn @_; };
1209     print "%table = (\n";
1210     foreach (sort keys %table) {
1211         print_table_entry($_, "HASH");
1212     }
1213     exit 0;
1214 }
1215
1216 print "Configuring OpenSSL version $config{full_version} ";
1217 print "for target $target\n";
1218
1219 if (scalar(@seed_sources) == 0) {
1220     print "Using os-specific seed configuration\n";
1221     push @seed_sources, 'os';
1222 }
1223 if (scalar(grep { $_ eq 'egd' } @seed_sources) > 0) {
1224     delete $disabled{'egd'};
1225 }
1226 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1227     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1228     warn <<_____ if scalar(@seed_sources) == 1;
1229
1230 ============================== WARNING ===============================
1231 You have selected the --with-rand-seed=none option, which effectively
1232 disables automatic reseeding of the OpenSSL random generator.
1233 All operations depending on the random generator such as creating keys
1234 will not work unless the random generator is seeded manually by the
1235 application.
1236
1237 Please read the 'Note on random number generation' section in the
1238 INSTALL.md instructions and the RAND_DRBG(7) manual page for more
1239 details.
1240 ============================== WARNING ===============================
1241
1242 _____
1243 }
1244 push @{$config{openssl_feature_defines}},
1245      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1246         @seed_sources;
1247
1248 # Backward compatibility?
1249 if ($target =~ m/^CygWin32(-.*)$/) {
1250     $target = "Cygwin".$1;
1251 }
1252
1253 # Support for legacy targets having a name starting with 'debug-'
1254 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1255 if ($d) {
1256     $config{build_type} = "debug";
1257
1258     # If we do not find debug-foo in the table, the target is set to foo.
1259     if (!$table{$target}) {
1260         $target = $t;
1261     }
1262 }
1263
1264 if ($target) {
1265     # It's possible that we have different config targets for specific
1266     # toolchains, so we try to detect them, and go for the plain config
1267     # target if not.
1268     my $found;
1269     foreach ( ( "$target-$user{CC}", "$target", undef ) ) {
1270         $found=$_ if $table{$_} && !$table{$_}->{template};
1271         last if $found;
1272     }
1273     $target = $found;
1274 } else {
1275     # If we don't have a config target now, we try the C compiler as we
1276     # fallback
1277     my $cc = $user{CC} // 'cc';
1278     $target = $cc if $table{$cc} && !$table{$cc}->{template};
1279 }
1280
1281 &usage unless $target;
1282
1283 exit 0 if $dryrun;              # From older 'config'
1284
1285 $config{target} = $target;
1286 my %target = resolve_config($target);
1287
1288 foreach (keys %target_attr_translate) {
1289     $target{$target_attr_translate{$_}} = $target{$_}
1290         if $target{$_};
1291     delete $target{$_};
1292 }
1293
1294 %target = ( %{$table{DEFAULTS}}, %target );
1295
1296 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1297 $config{conf_files} = [ sort keys %conf_files ];
1298
1299 # Using sub disable within these loops may prove fragile, so we run
1300 # a cascade afterwards
1301 foreach my $feature (@{$target{disable}}) {
1302     if (exists $deprecated_disablables{$feature}) {
1303         warn "***** config $target disables deprecated feature $feature\n";
1304     } elsif (!grep { $feature eq $_ } @disablables) {
1305         die "***** config $target disables unknown feature $feature\n";
1306     }
1307     $disabled{$feature} = 'config';
1308 }
1309 foreach my $feature (@{$target{enable}}) {
1310     if ("default" eq ($disabled{$feature} // "")) {
1311         if (exists $deprecated_disablables{$feature}) {
1312             warn "***** config $target enables deprecated feature $feature\n";
1313         } elsif (!grep { $feature eq $_ } @disablables) {
1314             die "***** config $target enables unknown feature $feature\n";
1315         }
1316         delete $disabled{$feature};
1317     }
1318 }
1319
1320 # If uplink_arch isn't defined, disable uplink
1321 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1322 # If asm_arch isn't defined, disable asm
1323 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1324
1325 disable();                      # Run a cascade now
1326
1327 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1328 $target{cxxflags}//=$target{cflags} if $target{CXX};
1329 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1330 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1331
1332 # Fill %config with values from %user, and in case those are undefined or
1333 # empty, use values from %target (acting as a default).
1334 foreach (keys %user) {
1335     my $ref_type = ref $user{$_};
1336
1337     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1338     # and a value that's to be coerced into that type.
1339     my $mkvalue = sub {
1340         my $type = shift;
1341         my $value = shift;
1342         my $undef_p = shift;
1343
1344         die "Too many arguments for \$mkvalue" if @_;
1345
1346         while (ref $value eq 'CODE') {
1347             $value = $value->();
1348         }
1349
1350         if ($type eq 'ARRAY') {
1351             return undef unless defined $value;
1352             return undef if ref $value ne 'ARRAY' && !$value;
1353             return undef if ref $value eq 'ARRAY' && !@$value;
1354             return [ $value ] unless ref $value eq 'ARRAY';
1355         }
1356         return undef unless $value;
1357         return $value;
1358     };
1359
1360     $config{$_} =
1361         $mkvalue->($ref_type, $user{$_})
1362         || $mkvalue->($ref_type, $target{$_});
1363     delete $config{$_} unless defined $config{$_};
1364 }
1365
1366 # Finish up %config by appending things the user gave us on the command line
1367 # apart from "make variables"
1368 foreach (keys %useradd) {
1369     # The must all be lists, so we assert that here
1370     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1371         unless ref $useradd{$_} eq 'ARRAY';
1372
1373     if (defined $config{$_}) {
1374         push @{$config{$_}}, @{$useradd{$_}};
1375     } else {
1376         $config{$_} = [ @{$useradd{$_}} ];
1377     }
1378 }
1379 # At this point, we can forget everything about %user and %useradd,
1380 # because it's now all been merged into the corresponding $config entry
1381
1382 # Allow overriding the build file name
1383 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1384
1385 # Make sure build_scheme is consistent.
1386 $target{build_scheme} = [ $target{build_scheme} ]
1387     if ref($target{build_scheme}) ne "ARRAY";
1388
1389 my ($builder, $builder_platform, @builder_opts) =
1390     @{$target{build_scheme}};
1391
1392 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1393                       $builder_platform."-checker.pm")) {
1394     my $checker_path = catfile($srcdir, "Configurations", $checker);
1395     if (-f $checker_path) {
1396         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1397             ? sub { warn $@; } : sub { die $@; };
1398         if (! do $checker_path) {
1399             if ($@) {
1400                 $fn->($@);
1401             } elsif ($!) {
1402                 $fn->($!);
1403             } else {
1404                 $fn->("The detected tools didn't match the platform\n");
1405             }
1406         }
1407         last;
1408     }
1409 }
1410
1411 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1412
1413 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1414         {
1415         push @{$config{cflags}}, "-mno-cygwin";
1416         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1417         push @{$config{shared_ldflag}}, "-mno-cygwin";
1418         }
1419
1420 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1421         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1422         # minimally required architecture flags for assembly modules
1423         my $value;
1424         $value = '-mips2' if ($target =~ /mips32/);
1425         $value = '-mips3' if ($target =~ /mips64/);
1426         unshift @{$config{cflags}}, $value;
1427         unshift @{$config{cxxflags}}, $value if $config{CXX};
1428 }
1429
1430 # If threads aren't disabled, check how possible they are
1431 unless ($disabled{threads}) {
1432     if ($auto_threads) {
1433         # Enabled by default, disable it forcibly if unavailable
1434         if ($target{thread_scheme} eq "(unknown)") {
1435             disable("unavailable", 'threads');
1436         }
1437     } else {
1438         # The user chose to enable threads explicitly, let's see
1439         # if there's a chance that's possible
1440         if ($target{thread_scheme} eq "(unknown)") {
1441             # If the user asked for "threads" and we don't have internal
1442             # knowledge how to do it, [s]he is expected to provide any
1443             # system-dependent compiler options that are necessary.  We
1444             # can't truly check that the given options are correct, but
1445             # we expect the user to know what [s]He is doing.
1446             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1447                 die "You asked for multi-threading support, but didn't\n"
1448                     ,"provide any system-specific compiler options\n";
1449             }
1450         }
1451     }
1452 }
1453
1454 # Find out if clang's sanitizers have been enabled with -fsanitize
1455 # flags and ensure that the corresponding %disabled elements area
1456 # removed to reflect that the sanitizers are indeed enabled.
1457 my %detected_sanitizers = ();
1458 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1459     (my $checks = $_) =~ s/^-fsanitize=//;
1460     foreach (split /,/, $checks) {
1461         my $d = { address       => 'asan',
1462                   undefined     => 'ubsan',
1463                   memory        => 'msan' } -> {$_};
1464         next unless defined $d;
1465
1466         $detected_sanitizers{$d} = 1;
1467         if (defined $disabled{$d}) {
1468             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1469                 if $disabled{$d} ne "default";
1470             delete $disabled{$d};
1471         }
1472     }
1473 }
1474
1475 # If threads still aren't disabled, add a C macro to ensure the source
1476 # code knows about it.  Any other flag is taken care of by the configs.
1477 unless($disabled{threads}) {
1478     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1479 }
1480
1481 my $no_shared_warn=0;
1482 if (($target{shared_target} // '') eq "")
1483         {
1484         $no_shared_warn = 1
1485             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1486         disable('no-shared-target', 'pic');
1487         }
1488
1489 if ($disabled{"dynamic-engine"}) {
1490         $config{dynamic_engines} = 0;
1491 } else {
1492         $config{dynamic_engines} = 1;
1493 }
1494
1495 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1496     push @{$config{cflags}}, "-fsanitize=address";
1497 }
1498
1499 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1500     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1501     # platforms.
1502     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1503 }
1504
1505 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1506   push @{$config{cflags}}, "-fsanitize=memory";
1507 }
1508
1509 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1510         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1511     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1512     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1513 }
1514 #
1515 # Platform fix-ups
1516 #
1517
1518 # This saves the build files from having to check
1519 if ($disabled{pic})
1520         {
1521         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1522                     shared_defines shared_includes shared_ldflag
1523                     module_cflags module_cxxflags module_cppflags
1524                     module_defines module_includes module_lflags))
1525                 {
1526                 delete $config{$_};
1527                 $target{$_} = "";
1528                 }
1529         }
1530 else
1531         {
1532         push @{$config{lib_defines}}, "OPENSSL_PIC";
1533         }
1534
1535 if ($target{sys_id} ne "")
1536         {
1537         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1538         }
1539
1540 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1541 my %predefined_CXX = $config{CXX}
1542     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1543     : ();
1544
1545 unless ($disabled{asm}) {
1546     # big endian systems can use ELFv2 ABI
1547     if ($target eq "linux-ppc64") {
1548         $target{perlasm_scheme} = "linux64v2" if ($predefined_C{_CALL_ELF} == 2);
1549     }
1550 }
1551
1552 # Check for makedepend capabilities.
1553 if (!$disabled{makedepend}) {
1554     # If the attribute makedep_scheme is defined, then we assume that the
1555     # config target and its associated build file are programmed to deal
1556     # with it.
1557     # If makedep_scheme is undefined, we go looking for GCC compatible
1558     # dependency making, and if that's not available, we try to fall back
1559     # on 'makedepend'.
1560     if ($target{makedep_scheme}) {
1561         $config{makedep_scheme} = $target{makedep_scheme};
1562         # If the makedepcmd attribute is defined, copy it.  If not, the
1563         # build files will have to fend for themselves.
1564         $config{makedepcmd} = $target{makedepcmd} if $target{makedepcmd};
1565     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1566              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1567         # We know that GNU C version 3 and up as well as all clang
1568         # versions support dependency generation, but Xcode did not
1569         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1570         $config{makedep_scheme} = 'gcc';
1571     } else {
1572         # In all other cases, we look for 'makedepend', and set the
1573         # makedep_scheme value if we found it.
1574         $config{makedepcmd} = which('makedepend');
1575         $config{makedep_scheme} = 'makedepend' if $config{makedepcmd};
1576     }
1577
1578     # If no depend scheme is set, we disable makedepend
1579     disable('unavailable', 'makedepend') unless $config{makedep_scheme};
1580 }
1581
1582 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1583     # probe for -Wa,--noexecstack option...
1584     if ($predefined_C{__clang__}) {
1585         # clang has builtin assembler, which doesn't recognize --help,
1586         # but it apparently recognizes the option in question on all
1587         # supported platforms even when it's meaningless. In other words
1588         # probe would fail, but probed option always accepted...
1589         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1590     } else {
1591         my $cc = $config{CROSS_COMPILE}.$config{CC};
1592         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1593         while(<PIPE>) {
1594             if (m/--noexecstack/) {
1595                 push @{$config{cflags}}, "-Wa,--noexecstack";
1596                 last;
1597             }
1598         }
1599         close(PIPE);
1600         unlink("null.$$.o");
1601     }
1602 }
1603
1604 # Deal with bn_ops ###################################################
1605
1606 $config{bn_ll}                  =0;
1607 my $def_int="unsigned int";
1608 $config{rc4_int}                =$def_int;
1609 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1610
1611 my $count = 0;
1612 foreach (sort split(/\s+/,$target{bn_ops})) {
1613     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1614     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1615     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1616     ($config{b64l},$config{b64},$config{b32})
1617         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1618     ($config{b64l},$config{b64},$config{b32})
1619         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1620     ($config{b64l},$config{b64},$config{b32})
1621         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1622 }
1623 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1624     if $count > 1;
1625
1626 $config{api} = $config{major} * 10000 + $config{minor} * 100
1627     unless $config{api};
1628 foreach (keys %$apitable) {
1629     $disabled{"deprecated-$_"} = "deprecation"
1630         if $disabled{deprecated} && $config{api} >= $apitable->{$_};
1631 }
1632
1633 disable();                      # Run a cascade now
1634
1635 # Hack cflags for better warnings (dev option) #######################
1636
1637 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1638 # a string and works as well on command lines.
1639 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1640                         @{$config{cflags}} ];
1641 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1642                           @{$config{cxxflags}} ] if $config{CXX};
1643
1644 $config{openssl_api_defines} = [
1645     "OPENSSL_CONFIGURED_API=".$config{api},
1646 ];
1647
1648 my @strict_warnings_collection=();
1649 if ($strict_warnings)
1650         {
1651         my $wopt;
1652         my $gccver = $predefined_C{__GNUC__} // -1;
1653
1654         if ($gccver >= 4)
1655                 {
1656                 push @strict_warnings_collection, @gcc_devteam_warn;
1657                 push @strict_warnings_collection, @clang_devteam_warn
1658                     if (defined($predefined_C{__clang__}));
1659                 }
1660         elsif ($config{target} =~ /^VC-/)
1661                 {
1662                 push @strict_warnings_collection, @cl_devteam_warn;
1663                 }
1664         else
1665                 {
1666                 warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike, or MSVC"
1667                 }
1668         }
1669
1670 if (grep { $_ =~ /(?:^|\s)-static(?:\s|$)/ } @{$config{LDFLAGS}}) {
1671     disable('static', 'pic', 'threads');
1672 }
1673
1674 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1675                               ? @strict_warnings_collection
1676                               : ( $_ ) }
1677                     @{$config{CFLAGS}} ];
1678
1679 unless ($disabled{afalgeng}) {
1680     $config{afalgeng}="";
1681     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1682         my $minver = 4*10000 + 1*100 + 0;
1683         if ($config{CROSS_COMPILE} eq "") {
1684             my $verstr = `uname -r`;
1685             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1686             ($mi2) = $mi2 =~ /(\d+)/;
1687             my $ver = $ma*10000 + $mi1*100 + $mi2;
1688             if ($ver < $minver) {
1689                 disable('too-old-kernel', 'afalgeng');
1690             } else {
1691                 push @{$config{engdirs}}, "afalg";
1692             }
1693         } else {
1694             disable('cross-compiling', 'afalgeng');
1695         }
1696     } else {
1697         disable('not-linux', 'afalgeng');
1698     }
1699 }
1700
1701 unless ($disabled{devcryptoeng}) {
1702     if ($target =~ m/^BSD/) {
1703         my $maxver = 5*100 + 7;
1704         my $sysstr = `uname -s`;
1705         my $verstr = `uname -r`;
1706         $sysstr =~ s|\R$||;
1707         $verstr =~ s|\R$||;
1708         my ($ma, $mi, @rest) = split m|\.|, $verstr;
1709         my $ver = $ma*100 + $mi;
1710         if ($sysstr eq 'OpenBSD' && $ver >= $maxver) {
1711             disable('too-new-kernel', 'devcryptoeng');
1712         }
1713     }
1714 }
1715
1716 unless ($disabled{ktls}) {
1717     $config{ktls}="";
1718     if ($target =~ m/^linux/) {
1719         my $usr = "/usr/$config{cross_compile_prefix}";
1720         chop($usr);
1721         if ($config{cross_compile_prefix} eq "") {
1722             $usr = "/usr";
1723         }
1724         my $minver = (4 << 16) + (13 << 8) + 0;
1725         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1726
1727         if ($verstr[2] < $minver) {
1728             disable('too-old-kernel', 'ktls');
1729         }
1730     } elsif ($target =~ m/^BSD/) {
1731         my $cc = $config{CROSS_COMPILE}.$config{CC};
1732         system("printf '#include <sys/types.h>\n#include <sys/ktls.h>' | $cc -E - >/dev/null 2>&1");
1733         if ($? != 0) {
1734             disable('too-old-freebsd', 'ktls');
1735         }
1736     } else {
1737         disable('not-linux-or-freebsd', 'ktls');
1738     }
1739 }
1740
1741 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1742
1743 # Get the extra flags used when building shared libraries and modules.  We
1744 # do this late because some of them depend on %disabled.
1745
1746 # Make the flags to build DSOs the same as for shared libraries unless they
1747 # are already defined
1748 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1749 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1750 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1751 {
1752     my $shared_info_pl =
1753         catfile(dirname($0), "Configurations", "shared-info.pl");
1754     my %shared_info = read_eval_file($shared_info_pl);
1755     push @{$target{_conf_fname_int}}, $shared_info_pl;
1756     my $si = $target{shared_target};
1757     while (ref $si ne "HASH") {
1758         last if ! defined $si;
1759         if (ref $si eq "CODE") {
1760             $si = $si->();
1761         } else {
1762             $si = $shared_info{$si};
1763         }
1764     }
1765
1766     # Some of the 'shared_target' values don't have any entries in
1767     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1768     # template knows how to handle this.  That is currently the case for
1769     # Windows and VMS.
1770     if (defined $si) {
1771         # Just as above, copy certain shared_* attributes to the corresponding
1772         # module_ attribute unless the latter is already defined
1773         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1774         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1775         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1776         foreach (sort keys %$si) {
1777             $target{$_} = defined $target{$_}
1778                 ? add($si->{$_})->($target{$_})
1779                 : $si->{$_};
1780         }
1781     }
1782 }
1783
1784 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1785
1786 ######################################################################
1787 # Build up information for skipping certain directories depending on disabled
1788 # features, as well as setting up macros for disabled features.
1789
1790 # This is a tentative database of directories to skip.  Some entries may not
1791 # correspond to anything real, but that's ok, they will simply be ignored.
1792 # The actual processing of these entries is done in the build.info lookup
1793 # loop further down.
1794 #
1795 # The key is a Unix formatted path in the source tree, the value is an index
1796 # into %disabled_info, so any existing path gets added to a corresponding
1797 # 'skipped' entry in there with the list of skipped directories.
1798 my %skipdir = ();
1799 my %disabled_info = ();         # For configdata.pm
1800 foreach my $what (sort keys %disabled) {
1801     # There are deprecated disablables that translate to themselves.
1802     # They cause disabling cascades, but should otherwise not regiter.
1803     next if $deprecated_disablables{$what};
1804     # The generated $disabled{"deprecated-x.y"} entries are special
1805     # and treated properly elsewhere
1806     next if $what =~ m|^deprecated-|;
1807
1808     $config{options} .= " no-$what";
1809
1810     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1811                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1812                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1813         (my $WHAT = uc $what) =~ s|-|_|g;
1814         my $skipdir = $what;
1815
1816         # fix-up crypto/directory name(s)
1817         $skipdir = "ripemd" if $what eq "rmd160";
1818         $skipdir = "whrlpool" if $what eq "whirlpool";
1819
1820         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1821         push @{$config{openssl_feature_defines}}, $macro;
1822
1823         $skipdir{engines} = $what if $what eq 'engine';
1824         $skipdir{"crypto/$skipdir"} = $what
1825             unless $what eq 'async' || $what eq 'err' || $what eq 'dso';
1826     }
1827 }
1828
1829 if ($disabled{"dynamic-engine"}) {
1830     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1831 } else {
1832     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1833 }
1834
1835 # If we use the unified build, collect information from build.info files
1836 my %unified_info = ();
1837
1838 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1839 if ($builder eq "unified") {
1840     use Text::Template 1.46;
1841
1842     sub cleandir {
1843         my $base = shift;
1844         my $dir = shift;
1845         my $relativeto = shift || ".";
1846
1847         $dir = catdir($base,$dir) unless isabsolute($dir);
1848
1849         # Make sure the directories we're building in exists
1850         mkpath($dir);
1851
1852         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1853         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1854         return $res;
1855     }
1856
1857     sub cleanfile {
1858         my $base = shift;
1859         my $file = shift;
1860         my $relativeto = shift || ".";
1861
1862         $file = catfile($base,$file) unless isabsolute($file);
1863
1864         my $d = dirname($file);
1865         my $f = basename($file);
1866
1867         # Make sure the directories we're building in exists
1868         mkpath($d);
1869
1870         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1871         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1872         return $res;
1873     }
1874
1875     # Store the name of the template file we will build the build file from
1876     # in %config.  This may be useful for the build file itself.
1877     my @build_file_template_names =
1878         ( $builder_platform."-".$target{build_file}.".tmpl",
1879           $target{build_file}.".tmpl" );
1880     my @build_file_templates = ();
1881
1882     # First, look in the user provided directory, if given
1883     if (defined env($local_config_envname)) {
1884         @build_file_templates =
1885             map {
1886                 if ($^O eq 'VMS') {
1887                     # VMS environment variables are logical names,
1888                     # which can be used as is
1889                     $local_config_envname . ':' . $_;
1890                 } else {
1891                     catfile(env($local_config_envname), $_);
1892                 }
1893             }
1894             @build_file_template_names;
1895     }
1896     # Then, look in our standard directory
1897     push @build_file_templates,
1898         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1899           @build_file_template_names );
1900
1901     my $build_file_template;
1902     for $_ (@build_file_templates) {
1903         $build_file_template = $_;
1904         last if -f $build_file_template;
1905
1906         $build_file_template = undef;
1907     }
1908     if (!defined $build_file_template) {
1909         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1910     }
1911     $config{build_file_templates}
1912       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1913                     $blddir),
1914            $build_file_template ];
1915
1916     my @build_dirs = ( [ ] );   # current directory
1917
1918     $config{build_infos} = [ ];
1919
1920     # We want to detect configdata.pm in the source tree, so we
1921     # don't use it if the build tree is different.
1922     my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1923
1924     # Any source file that we recognise is placed in this hash table, with
1925     # the list of its intended destinations as value.  When everything has
1926     # been collected, there's a routine that checks that these source files
1927     # exist, or if they are generated, that the generator exists.
1928     my %check_exist = ();
1929     my %check_generate = ();
1930
1931     my %ordinals = ();
1932     while (@build_dirs) {
1933         my @curd = @{shift @build_dirs};
1934         my $sourced = catdir($srcdir, @curd);
1935         my $buildd = catdir($blddir, @curd);
1936
1937         my $unixdir = join('/', @curd);
1938         if (exists $skipdir{$unixdir}) {
1939             my $what = $skipdir{$unixdir};
1940             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1941             next;
1942         }
1943
1944         mkpath($buildd);
1945
1946         my $f = 'build.info';
1947         # The basic things we're trying to build
1948         my @programs = ();
1949         my @libraries = ();
1950         my @modules = ();
1951         my @scripts = ();
1952
1953         my %sources = ();
1954         my %shared_sources = ();
1955         my %includes = ();
1956         my %defines = ();
1957         my %depends = ();
1958         my %generate = ();
1959         my %htmldocs = ();
1960         my %mandocs = ();
1961
1962         # Support for $variablename in build.info files.
1963         # Embedded perl code is the ultimate master, still.  If its output
1964         # contains a dollar sign, it had better be escaped, or it will be
1965         # taken for a variable name prefix.
1966         my %variables = ();
1967         # Variable name syntax
1968         my $variable_name_re = qr/(?P<VARIABLE>[[:alpha:]][[:alnum:]_]*)/;
1969         # Value modifier syntaxes
1970         my $variable_subst_re = qr/\/(?P<RE>(?:\\\/|.)*?)\/(?P<SUBST>.*?)/;
1971         # Variable reference
1972         my $variable_simple_re = qr/(?<!\\)\$${variable_name_re}/;
1973         my $variable_w_mod_re =
1974             qr/(?<!\\)\$\{${variable_name_re}(?P<MOD>(?:\\\/|.)*?)\}/;
1975         # Tie it all together
1976         my $variable_re = qr/${variable_simple_re}|${variable_w_mod_re}/;
1977
1978         my $expand_variables = sub {
1979             my $value = '';
1980             my $value_rest = shift;
1981
1982             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1983                 print STDERR
1984                     "DEBUG[\$expand_variables] Parsed '$value_rest' ...\n"
1985             }
1986
1987             while ($value_rest =~ /${variable_re}/) {
1988                 # We must save important regexp values, because the next
1989                 # regexp clears them
1990                 my $mod = $+{MOD};
1991                 my $variable_value = $variables{$+{VARIABLE}};
1992
1993                 $value_rest = $';
1994                 $value .= $`;
1995
1996                 # Process modifier expressions, if present
1997                 if (defined $mod) {
1998                     if ($mod =~ /^${variable_subst_re}$/) {
1999                         my $re = $+{RE};
2000                         my $subst = $+{SUBST};
2001
2002                         $variable_value =~ s/\Q$re\E/$subst/g;
2003
2004                         if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2005                             print STDERR
2006                                 "DEBUG[\$expand_variables] ... and substituted ",
2007                                 "'$re' with '$subst'\n";
2008                         }
2009                     }
2010                 }
2011
2012                 $value .= $variable_value;
2013             }
2014             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2015                 print STDERR
2016                     "DEBUG[\$expand_variables] ... into: '$value$value_rest'\n";
2017             }
2018             return $value . $value_rest;
2019         };
2020
2021         # Support for attributes in build.info files
2022         my %attributes = ();
2023         my $handle_attributes = sub {
2024             my $attr_str = shift;
2025             my $ref = shift;
2026             my @goals = @_;
2027
2028             return unless defined $attr_str;
2029
2030             my @a = tokenize($attr_str, qr|\s*,\s*|);
2031             foreach my $a (@a) {
2032                 my $ac = 1;
2033                 my $ak = $a;
2034                 my $av = 1;
2035                 if ($a =~ m|^(!)?(.*?)\s* = \s*(.*?)$|x) {
2036                     $ac = ! $1;
2037                     $ak = $2;
2038                     $av = $3;
2039                 }
2040                 foreach my $g (@goals) {
2041                     if ($ac) {
2042                         $$ref->{$g}->{$ak} = $av;
2043                     } else {
2044                         delete $$ref->{$g}->{$ak};
2045                     }
2046                 }
2047             }
2048         };
2049
2050         # Support for pushing values on multiple indexes of a given hash
2051         # array.
2052         my $push_to = sub {
2053             my $valueref = shift;
2054             my $index_str = shift; # May be undef or empty
2055             my $attrref = shift;   # May be undef
2056             my $attr_str = shift;
2057             my @values = @_;
2058
2059             if (defined $index_str) {
2060                 my @indexes = ( '' );
2061                 if ($index_str !~ m|^\s*$|) {
2062                     @indexes = tokenize($index_str);
2063                 }
2064                 foreach (@indexes) {
2065                     push @{$valueref->{$_}}, @values;
2066                     if (defined $attrref) {
2067                         $handle_attributes->($attr_str, \$$attrref->{$_},
2068                                              @values);
2069                     }
2070                 }
2071             } else {
2072                 push @$valueref, @values;
2073                 $handle_attributes->($attr_str, $attrref, @values)
2074                     if defined $attrref;
2075             }
2076         };
2077
2078         if ($buildinfo_debug) {
2079             print STDERR "DEBUG: Reading ",catfile($sourced, $f),"\n";
2080         }
2081         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
2082         my $template =
2083             Text::Template->new(TYPE => 'FILE',
2084                                 SOURCE => catfile($sourced, $f),
2085                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
2086         die "Something went wrong with $sourced/$f: $!\n" unless $template;
2087         my @text =
2088             split /^/m,
2089             $template->fill_in(HASH => { config => \%config,
2090                                          target => \%target,
2091                                          disabled => \%disabled,
2092                                          withargs => \%withargs,
2093                                          builddir => abs2rel($buildd, $blddir),
2094                                          sourcedir => abs2rel($sourced, $blddir),
2095                                          buildtop => abs2rel($blddir, $blddir),
2096                                          sourcetop => abs2rel($srcdir, $blddir) },
2097                                DELIMITERS => [ "{-", "-}" ]);
2098
2099         # The top item of this stack has the following values
2100         # -2 positive already run and we found ELSE (following ELSIF should fail)
2101         # -1 positive already run (skip until ENDIF)
2102         # 0 negatives so far (if we're at a condition, check it)
2103         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
2104         # 2 positive ELSE (following ELSIF should fail)
2105         my @skip = ();
2106
2107         # A few useful generic regexps
2108         my $index_re = qr/\[\s*(?P<INDEX>(?:\\.|.)*?)\s*\]/;
2109         my $cond_re = qr/\[\s*(?P<COND>(?:\\.|.)*?)\s*\]/;
2110         my $attribs_re = qr/(?:\{\s*(?P<ATTRIBS>(?:\\.|.)*?)\s*\})?/;
2111         my $value_re = qr/\s*(?P<VALUE>.*?)\s*/;
2112         collect_information(
2113             collect_from_array([ @text ],
2114                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
2115                                                 $l1 =~ s/\\$//; $l1.$l2 }),
2116             # Info we're looking for
2117             qr/^\s* IF ${cond_re} \s*$/x
2118             => sub {
2119                 if (! @skip || $skip[$#skip] > 0) {
2120                     push @skip, !! $expand_variables->($+{COND});
2121                 } else {
2122                     push @skip, -1;
2123                 }
2124             },
2125             qr/^\s* ELSIF ${cond_re} \s*$/x
2126             => sub { die "ELSIF out of scope" if ! @skip;
2127                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
2128                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
2129                      $skip[$#skip] = !! $expand_variables->($+{COND})
2130                          if $skip[$#skip] == 0; },
2131             qr/^\s* ELSE \s*$/x
2132             => sub { die "ELSE out of scope" if ! @skip;
2133                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
2134                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
2135             qr/^\s* ENDIF \s*$/x
2136             => sub { die "ENDIF out of scope" if ! @skip;
2137                      pop @skip; },
2138             qr/^\s* ${variable_re} \s* = ${value_re} $/x
2139             => sub {
2140                 if (!@skip || $skip[$#skip] > 0) {
2141                     $variables{$+{VARIABLE}} = $expand_variables->($+{VALUE});
2142                 }
2143             },
2144             qr/^\s* SUBDIRS \s* = ${value_re} $/x
2145             => sub {
2146                 if (!@skip || $skip[$#skip] > 0) {
2147                     foreach (tokenize($expand_variables->($+{VALUE}))) {
2148                         push @build_dirs, [ @curd, splitdir($_, 1) ];
2149                     }
2150                 }
2151             },
2152             qr/^\s* PROGRAMS ${attribs_re} \s* =  ${value_re} $/x
2153             => sub { $push_to->(\@programs, undef,
2154                                 \$attributes{programs}, $+{ATTRIBS},
2155                                 tokenize($expand_variables->($+{VALUE})))
2156                          if !@skip || $skip[$#skip] > 0; },
2157             qr/^\s* LIBS ${attribs_re} \s* =  ${value_re} $/x
2158             => sub { $push_to->(\@libraries, undef,
2159                                 \$attributes{libraries}, $+{ATTRIBS},
2160                                 tokenize($expand_variables->($+{VALUE})))
2161                          if !@skip || $skip[$#skip] > 0; },
2162             qr/^\s* MODULES ${attribs_re} \s* =  ${value_re} $/x
2163             => sub { $push_to->(\@modules, undef,
2164                                 \$attributes{modules}, $+{ATTRIBS},
2165                                 tokenize($expand_variables->($+{VALUE})))
2166                          if !@skip || $skip[$#skip] > 0; },
2167             qr/^\s* SCRIPTS ${attribs_re} \s* =  ${value_re} $/x
2168             => sub { $push_to->(\@scripts, undef,
2169                                 \$attributes{scripts}, $+{ATTRIBS},
2170                                 tokenize($expand_variables->($+{VALUE})))
2171                          if !@skip || $skip[$#skip] > 0; },
2172             qr/^\s* HTMLDOCS ${index_re} = ${value_re} $/x
2173             => sub { $push_to->(\%htmldocs, $expand_variables->($+{INDEX}),
2174                                 undef, undef,
2175                                 tokenize($expand_variables->($+{VALUE})))
2176                          if !@skip || $skip[$#skip] > 0; },
2177             qr/^\s* MANDOCS ${index_re} = ${value_re} $/x
2178             => sub { $push_to->(\%mandocs, $expand_variables->($+{INDEX}),
2179                                 undef, undef,
2180                                 tokenize($expand_variables->($+{VALUE})))
2181                          if !@skip || $skip[$#skip] > 0; },
2182             qr/^\s* SOURCE ${index_re} ${attribs_re} = ${value_re} $/x
2183             => sub { $push_to->(\%sources, $expand_variables->($+{INDEX}),
2184                                 \$attributes{sources}, $+{ATTRIBS},
2185                                 tokenize($expand_variables->($+{VALUE})))
2186                          if !@skip || $skip[$#skip] > 0; },
2187             qr/^\s* SHARED_SOURCE ${index_re} ${attribs_re} = ${value_re} $/x
2188             => sub { $push_to->(\%shared_sources, $expand_variables->($+{INDEX}),
2189                                 \$attributes{sources}, $+{ATTRIBS},
2190                                 tokenize($expand_variables->($+{VALUE})))
2191                          if !@skip || $skip[$#skip] > 0; },
2192             qr/^\s* INCLUDE ${index_re} = ${value_re} $/x
2193             => sub { $push_to->(\%includes, $expand_variables->($+{INDEX}),
2194                                 undef, undef,
2195                                 tokenize($expand_variables->($+{VALUE})))
2196                          if !@skip || $skip[$#skip] > 0; },
2197             qr/^\s* DEFINE ${index_re} = ${value_re} $/x
2198             => sub { $push_to->(\%defines, $expand_variables->($+{INDEX}),
2199                                 undef, undef,
2200                                 tokenize($expand_variables->($+{VALUE})))
2201                          if !@skip || $skip[$#skip] > 0; },
2202             qr/^\s* DEPEND ${index_re} ${attribs_re} = ${value_re} $/x
2203             => sub { $push_to->(\%depends, $expand_variables->($+{INDEX}),
2204                                 \$attributes{depends}, $+{ATTRIBS},
2205                                 tokenize($expand_variables->($+{VALUE})))
2206                          if !@skip || $skip[$#skip] > 0; },
2207             qr/^\s* GENERATE ${index_re} = ${value_re} $/x
2208             => sub { $push_to->(\%generate, $expand_variables->($+{INDEX}),
2209                                 undef, undef, $+{VALUE})
2210                          if !@skip || $skip[$#skip] > 0; },
2211             qr/^\s* (?:\#.*)? $/x => sub { },
2212             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
2213             "BEFORE" => sub {
2214                 if ($buildinfo_debug) {
2215                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
2216                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2217                 }
2218             },
2219             "AFTER" => sub {
2220                 if ($buildinfo_debug) {
2221                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2222                 }
2223             },
2224             );
2225         die "runaway IF?" if (@skip);
2226
2227         if (grep { defined $attributes{modules}->{$_}->{engine} } keys %attributes
2228                 and !$config{dynamic_engines}) {
2229             die <<"EOF"
2230 ENGINES can only be used if configured with 'dynamic-engine'.
2231 This is usually a fault in a build.info file.
2232 EOF
2233         }
2234
2235         {
2236             my %infos = ( programs  => [ @programs  ],
2237                           libraries => [ @libraries ],
2238                           modules   => [ @modules   ],
2239                           scripts   => [ @scripts   ] );
2240             foreach my $k (keys %infos) {
2241                 foreach (@{$infos{$k}}) {
2242                     my $item = cleanfile($buildd, $_, $blddir);
2243                     $unified_info{$k}->{$item} = 1;
2244
2245                     # Fix up associated attributes
2246                     $unified_info{attributes}->{$k}->{$item} =
2247                         $attributes{$k}->{$_}
2248                         if defined $attributes{$k}->{$_};
2249                 }
2250             }
2251         }
2252
2253         # Check that we haven't defined any library as both shared and
2254         # explicitly static.  That is forbidden.
2255         my @doubles = ();
2256         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2257             (my $l = $_) =~ s/\.a$//;
2258             push @doubles, $l if defined $unified_info{libraries}->{$l};
2259         }
2260         die "these libraries are both explicitly static and shared:\n  ",
2261             join(" ", @doubles), "\n"
2262             if @doubles;
2263
2264         foreach (keys %sources) {
2265             my $dest = $_;
2266             my $ddest = cleanfile($buildd, $_, $blddir);
2267             foreach (@{$sources{$dest}}) {
2268                 my $s = cleanfile($sourced, $_, $blddir);
2269
2270                 # If it's generated or we simply don't find it in the source
2271                 # tree, we assume it's in the build tree.
2272                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2273                     $s = cleanfile($buildd, $_, $blddir);
2274                 }
2275                 my $o = $_;
2276                 # We recognise C++, C and asm files
2277                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2278                     push @{$check_exist{$s}}, $ddest;
2279                     $o =~ s/\.[csS]$/.o/; # C and assembler
2280                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2281                     $o = cleanfile($buildd, $o, $blddir);
2282                     $unified_info{sources}->{$ddest}->{$o} = -1;
2283                     $unified_info{sources}->{$o}->{$s} = -1;
2284                 } elsif ($s =~ /\.rc$/) {
2285                     # We also recognise resource files
2286                     push @{$check_exist{$s}}, $ddest;
2287                     $o =~ s/\.rc$/.res/; # Resource configuration
2288                     $o = cleanfile($buildd, $o, $blddir);
2289                     $unified_info{sources}->{$ddest}->{$o} = -1;
2290                     $unified_info{sources}->{$o}->{$s} = -1;
2291                 } else {
2292                     push @{$check_exist{$s}}, $ddest;
2293                     $unified_info{sources}->{$ddest}->{$s} = 1;
2294                 }
2295                 # Fix up associated attributes
2296                 if ($o ne $_) {
2297                     $unified_info{attributes}->{sources}->{$ddest}->{$o} =
2298                         $unified_info{attributes}->{sources}->{$o}->{$s} =
2299                         $attributes{sources}->{$dest}->{$_}
2300                         if defined $attributes{sources}->{$dest}->{$_};
2301                 } else {
2302                     $unified_info{attributes}->{sources}->{$ddest}->{$s} =
2303                         $attributes{sources}->{$dest}->{$_}
2304                         if defined $attributes{sources}->{$dest}->{$_};
2305                 }
2306             }
2307         }
2308
2309         foreach (keys %shared_sources) {
2310             my $dest = $_;
2311             my $ddest = cleanfile($buildd, $_, $blddir);
2312             foreach (@{$shared_sources{$dest}}) {
2313                 my $s = cleanfile($sourced, $_, $blddir);
2314
2315                 # If it's generated or we simply don't find it in the source
2316                 # tree, we assume it's in the build tree.
2317                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2318                     $s = cleanfile($buildd, $_, $blddir);
2319                 }
2320
2321                 my $o = $_;
2322                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2323                     # We recognise C++, C and asm files
2324                     push @{$check_exist{$s}}, $ddest;
2325                     $o =~ s/\.[csS]$/.o/; # C and assembler
2326                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2327                     $o = cleanfile($buildd, $o, $blddir);
2328                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2329                     $unified_info{sources}->{$o}->{$s} = -1;
2330                 } elsif ($s =~ /\.rc$/) {
2331                     # We also recognise resource files
2332                     push @{$check_exist{$s}}, $ddest;
2333                     $o =~ s/\.rc$/.res/; # Resource configuration
2334                     $o = cleanfile($buildd, $o, $blddir);
2335                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2336                     $unified_info{sources}->{$o}->{$s} = -1;
2337                 } elsif ($s =~ /\.ld$/) {
2338                     # We also recognise linker scripts (or corresponding)
2339                     # We know they are generated files
2340                     push @{$check_exist{$s}}, $ddest;
2341                     $o = cleanfile($buildd, $_, $blddir);
2342                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
2343                 } else {
2344                     die "unrecognised source file type for shared library: $s\n";
2345                 }
2346                 # Fix up associated attributes
2347                 if ($o ne $_) {
2348                     $unified_info{attributes}->{shared_sources}->{$ddest}->{$o} =
2349                         $unified_info{attributes}->{sources}->{$o}->{$s} =
2350                         $attributes{sources}->{$dest}->{$_}
2351                         if defined $attributes{sources}->{$dest}->{$_};
2352                 } else {
2353                     $unified_info{attributes}->{shared_sources}->{$ddest}->{$o} =
2354                         $attributes{sources}->{$dest}->{$_}
2355                         if defined $attributes{sources}->{$dest}->{$_};
2356                 }
2357             }
2358         }
2359
2360         foreach (keys %generate) {
2361             my $dest = $_;
2362             my $ddest = cleanfile($buildd, $_, $blddir);
2363             die "more than one generator for $dest: "
2364                 ,join(" ", @{$generate{$_}}),"\n"
2365                 if scalar @{$generate{$_}} > 1;
2366             my @generator = split /\s+/, $generate{$dest}->[0];
2367             my $gen = $generator[0];
2368             $generator[0] = cleanfile($sourced, $gen, $blddir);
2369
2370             # If the generator is itself generated, it's in the build tree
2371             if ($generate{$gen} || ! -f $generator[0]) {
2372                 $generator[0] = cleanfile($buildd, $gen, $blddir);
2373             }
2374             $check_generate{$ddest}->{$generator[0]}++;
2375
2376             $unified_info{generate}->{$ddest} = [ @generator ];
2377         }
2378
2379         foreach (keys %depends) {
2380             my $dest = $_;
2381             my $ddest = $dest;
2382
2383             if ($dest =~ /^\|(.*)\|$/) {
2384                 # Collect the raw target
2385                 $unified_info{targets}->{$1} = 1;
2386                 $ddest = $1;
2387             } elsif ($dest eq '') {
2388                 $ddest = '';
2389             } else {
2390                 $ddest = cleanfile($sourced, $_, $blddir);
2391
2392                 # If the destination doesn't exist in source, it can only be
2393                 # a generated file in the build tree.
2394                 if ($ddest eq $src_configdata || ! -f $ddest) {
2395                     $ddest = cleanfile($buildd, $_, $blddir);
2396                 }
2397             }
2398             foreach (@{$depends{$dest}}) {
2399                 my $d = cleanfile($sourced, $_, $blddir);
2400                 my $d2 = cleanfile($buildd, $_, $blddir);
2401
2402                 # If we know it's generated, or assume it is because we can't
2403                 # find it in the source tree, we set file we depend on to be
2404                 # in the build tree rather than the source tree.
2405                 if ($d eq $src_configdata
2406                     || (grep { $d2 eq $_ }
2407                         keys %{$unified_info{generate}})
2408                     || ! -f $d) {
2409                     $d = $d2;
2410                 }
2411                 $unified_info{depends}->{$ddest}->{$d} = 1;
2412
2413                 # Fix up associated attributes
2414                 $unified_info{attributes}->{depends}->{$ddest}->{$d} =
2415                     $attributes{depends}->{$dest}->{$_}
2416                     if defined $attributes{depends}->{$dest}->{$_};
2417             }
2418         }
2419
2420         foreach (keys %includes) {
2421             my $dest = $_;
2422             my $ddest = cleanfile($sourced, $_, $blddir);
2423
2424             # If the destination doesn't exist in source, it can only be
2425             # a generated file in the build tree.
2426             if ($ddest eq $src_configdata || ! -f $ddest) {
2427                 $ddest = cleanfile($buildd, $_, $blddir);
2428             }
2429             foreach (@{$includes{$dest}}) {
2430                 my $is = cleandir($sourced, $_, $blddir);
2431                 my $ib = cleandir($buildd, $_, $blddir);
2432                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2433                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2434                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2435                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2436             }
2437         }
2438
2439         foreach my $dest (keys %defines) {
2440             my $ddest;
2441
2442             if ($dest ne "") {
2443                 $ddest = cleanfile($sourced, $dest, $blddir);
2444
2445                 # If the destination doesn't exist in source, it can only
2446                 # be a generated file in the build tree.
2447                 if (! -f $ddest) {
2448                     $ddest = cleanfile($buildd, $dest, $blddir);
2449                 }
2450             }
2451             foreach my $v (@{$defines{$dest}}) {
2452                 $v =~ m|^([^=]*)(=.*)?$|;
2453                 die "0 length macro name not permitted\n" if $1 eq "";
2454                 if ($dest ne "") {
2455                     die "$1 defined more than once\n"
2456                         if defined $unified_info{defines}->{$ddest}->{$1};
2457                     $unified_info{defines}->{$ddest}->{$1} = $2;
2458                 } else {
2459                     die "$1 defined more than once\n"
2460                         if grep { $v eq $_ } @{$config{defines}};
2461                     push @{$config{defines}}, $v;
2462                 }
2463             }
2464         }
2465
2466         foreach my $section (keys %htmldocs) {
2467             foreach (@{$htmldocs{$section}}) {
2468                 my $htmldocs = cleanfile($buildd, $_, $blddir);
2469                 $unified_info{htmldocs}->{$section}->{$htmldocs} = 1;
2470             }
2471         }
2472
2473         foreach my $section (keys %mandocs) {
2474             foreach (@{$mandocs{$section}}) {
2475                 my $mandocs = cleanfile($buildd, $_, $blddir);
2476                 $unified_info{mandocs}->{$section}->{$mandocs} = 1;
2477             }
2478         }
2479     }
2480
2481     my $ordinals_text = join(', ', sort keys %ordinals);
2482     warn <<"EOF" if $ordinals_text;
2483
2484 WARNING: ORDINALS were specified for $ordinals_text
2485 They are ignored and should be replaced with a combination of GENERATE,
2486 DEPEND and SHARED_SOURCE.
2487 EOF
2488
2489     # Check that each generated file is only generated once
2490     my $ambiguous_generation = 0;
2491     foreach (sort keys %check_generate) {
2492         my @generators = sort keys %{$check_generate{$_}};
2493         my $generators_txt = join(', ', @generators);
2494         if (scalar @generators > 1) {
2495             warn "$_ is GENERATEd by more than one generator ($generators_txt)\n";
2496             $ambiguous_generation++;
2497         }
2498         if ($check_generate{$_}->{$generators[0]} > 1) {
2499             warn "INFO: $_ has more than one GENERATE declaration (same generator)\n"
2500         }
2501     }
2502     die "There are ambiguous source file generations\n"
2503         if $ambiguous_generation > 0;
2504
2505     # All given source files should exist, or if generated, their
2506     # generator should exist.  This loop ensures this is true.
2507     my $missing = 0;
2508     foreach my $orig (sort keys %check_exist) {
2509         foreach my $dest (@{$check_exist{$orig}}) {
2510             if ($orig ne $src_configdata) {
2511                 if ($orig =~ /\.a$/) {
2512                     # Static library names may be used as sources, so we
2513                     # need to detect those and give them special treatment.
2514                     unless (grep { $_ eq $orig }
2515                             keys %{$unified_info{libraries}}) {
2516                         warn "$orig is given as source for $dest, but no such library is built\n";
2517                         $missing++;
2518                     }
2519                 } else {
2520                     # A source may be generated, and its generator may be
2521                     # generated as well.  We therefore loop to dig out the
2522                     # first generator.
2523                     my $gen = $orig;
2524
2525                     while (my @next = keys %{$check_generate{$gen}}) {
2526                         $gen = $next[0];
2527                     }
2528
2529                     if (! -f $gen) {
2530                         if ($gen ne $orig) {
2531                             $missing++;
2532                             warn "$orig is given as source for $dest, but its generator (leading to $gen) is missing\n";
2533                         } else {
2534                             $missing++;
2535                             warn "$orig is given as source for $dest, but is missing\n";
2536                         }
2537                     }
2538                 }
2539             }
2540         }
2541     }
2542     die "There are files missing\n" if $missing > 0;
2543
2544     # Go through the sources of all libraries and check that the same basename
2545     # doesn't appear more than once.  Some static library archivers depend on
2546     # them being unique.
2547     {
2548         my $err = 0;
2549         foreach my $prod (keys %{$unified_info{libraries}}) {
2550             my @prod_sources =
2551                 map { keys %{$unified_info{sources}->{$_}} }
2552                 keys %{$unified_info{sources}->{$prod}};
2553             my %srccnt = ();
2554
2555             # Count how many times a given each source basename
2556             # appears for each product.
2557             foreach my $src (@prod_sources) {
2558                 $srccnt{basename $src}++;
2559             }
2560
2561             foreach my $src (keys %srccnt) {
2562                 if ((my $cnt = $srccnt{$src}) > 1) {
2563                     print STDERR "$src appears $cnt times for the product $prod\n";
2564                     $err++
2565                 }
2566             }
2567         }
2568         die if $err > 0;
2569     }
2570
2571     # Massage the result
2572
2573     # If we depend on a header file or a perl module, add an inclusion of
2574     # its directory to allow smoothe inclusion
2575     foreach my $dest (keys %{$unified_info{depends}}) {
2576         next if $dest eq "";
2577         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2578             next unless $d =~ /\.(h|pm)$/;
2579             my $i = dirname($d);
2580             my $spot =
2581                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2582                 ? 'build' : 'source';
2583             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2584                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2585         }
2586     }
2587
2588     # Go through all intermediary files and change their names to something that
2589     # reflects what they will be built for.  Note that for some source files,
2590     # this leads to duplicate object files because they are used multiple times.
2591     # the goal is to rename all object files according to this scheme:
2592     #    {productname}-{midfix}-{origobjname}.[o|res]
2593     # the {midfix} is a keyword indicating the type of product, which is mostly
2594     # valuable for libraries since they come in two forms.
2595     #
2596     # This also reorganises the {sources} and {shared_sources} so that the
2597     # former only contains ALL object files that are supposed to end up in
2598     # static libraries and programs, while the latter contains ALL object files
2599     # that are supposed to end up in shared libraries and DSOs.
2600     # The main reason for having two different source structures is to allow
2601     # the same name to be used for the static and the shared variants of a
2602     # library.
2603     {
2604         # Take copies so we don't get interference from added stuff
2605         my %unified_copy = ();
2606         foreach (('sources', 'shared_sources')) {
2607             $unified_copy{$_} = { %{$unified_info{$_}} }
2608                 if defined($unified_info{$_});
2609             delete $unified_info{$_};
2610         }
2611         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2612             # $intent serves multi purposes:
2613             # - give a prefix for the new object files names
2614             # - in the case of libraries, rearrange the object files so static
2615             #   libraries use the 'sources' structure exclusively, while shared
2616             #   libraries use the 'shared_sources' structure exclusively.
2617             my $intent = {
2618                 programs  => { bin    => { src => [ 'sources' ],
2619                                            dst => 'sources' } },
2620                 libraries => { lib    => { src => [ 'sources' ],
2621                                            dst => 'sources' },
2622                                shlib  => { prodselect =>
2623                                                sub { grep !/\.a$/, @_ },
2624                                            src => [ 'sources',
2625                                                     'shared_sources' ],
2626                                            dst => 'shared_sources' } },
2627                 modules   => { dso    => { src => [ 'sources' ],
2628                                            dst => 'sources' } },
2629                 scripts   => { script => { src => [ 'sources' ],
2630                                            dst => 'sources' } }
2631                } -> {$prodtype};
2632             foreach my $kind (keys %$intent) {
2633                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2634                              && $disabled{shared});
2635
2636                 my @src = @{$intent->{$kind}->{src}};
2637                 my $dst = $intent->{$kind}->{dst};
2638                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2639                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2640                     # %prod_sources has all applicable objects as keys, and
2641                     # their corresponding sources as values
2642                     my %prod_sources =
2643                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2644                         map { keys %{$unified_copy{$_}->{$prod}} }
2645                         @src;
2646                     foreach (keys %prod_sources) {
2647                         # Only affect object files and resource files,
2648                         # the others simply get a new value
2649                         # (+1 instead of -1)
2650                         if ($_ =~ /\.(o|res)$/) {
2651                             (my $prodname = $prod) =~ s|\.a$||;
2652                             my $newobj =
2653                                 catfile(dirname($_),
2654                                         basename($prodname)
2655                                             . '-' . $kind
2656                                             . '-' . basename($_));
2657                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2658                             foreach my $src (@{$prod_sources{$_}}) {
2659                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2660                                 # Adjust source attributes
2661                                 my $attrs = $unified_info{attributes}->{sources};
2662                                 if (defined $attrs->{$prod}
2663                                     && defined $attrs->{$prod}->{$_}) {
2664                                     $attrs->{$prod}->{$newobj} =
2665                                         $attrs->{$prod}->{$_};
2666                                     delete $attrs->{$prod}->{$_};
2667                                 }
2668                                 foreach my $objsrc (keys %{$attrs->{$_} // {}}) {
2669                                     $attrs->{$newobj}->{$objsrc} =
2670                                         $attrs->{$_}->{$objsrc};
2671                                     delete $attrs->{$_}->{$objsrc};
2672                                 }
2673                             }
2674                             # Adjust dependencies
2675                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2676                                 $unified_info{depends}->{$_}->{$deps} = -1;
2677                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2678                             }
2679                             # Adjust includes
2680                             foreach my $k (('source', 'build')) {
2681                                 next unless
2682                                     defined($unified_info{includes}->{$_}->{$k});
2683                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2684                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2685                             }
2686                         } else {
2687                             $unified_info{$dst}->{$prod}->{$_} = 1;
2688                         }
2689                     }
2690                 }
2691             }
2692         }
2693     }
2694
2695     # At this point, we have a number of sources with the value -1.  They
2696     # aren't part of the local build and are probably meant for a different
2697     # platform, and can therefore be cleaned away.  That happens when making
2698     # %unified_info more efficient below.
2699
2700     ### Make unified_info a bit more efficient
2701     # One level structures
2702     foreach (("programs", "libraries", "modules", "scripts", "targets")) {
2703         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2704     }
2705     # Two level structures
2706     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends",
2707                      "htmldocs", "mandocs")) {
2708         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2709             my @items =
2710                 sort
2711                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2712                 keys %{$unified_info{$l1}->{$l2}};
2713             if (@items) {
2714                 $unified_info{$l1}->{$l2} = [ @items ];
2715             } else {
2716                 delete $unified_info{$l1}->{$l2};
2717             }
2718         }
2719     }
2720     # Defines
2721     foreach my $dest (sort keys %{$unified_info{defines}}) {
2722         $unified_info{defines}->{$dest}
2723             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2724                 sort keys %{$unified_info{defines}->{$dest}} ];
2725     }
2726     # Includes
2727     foreach my $dest (sort keys %{$unified_info{includes}}) {
2728         if (defined($unified_info{includes}->{$dest}->{build})) {
2729             my @source_includes = ();
2730             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2731                 if defined($unified_info{includes}->{$dest}->{source});
2732             $unified_info{includes}->{$dest} =
2733                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2734             foreach my $inc (@source_includes) {
2735                 push @{$unified_info{includes}->{$dest}}, $inc
2736                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2737             }
2738         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2739             $unified_info{includes}->{$dest} =
2740                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2741         } else {
2742             delete $unified_info{includes}->{$dest};
2743         }
2744     }
2745
2746     # For convenience collect information regarding directories where
2747     # files are generated, those generated files and the end product
2748     # they end up in where applicable.  Then, add build rules for those
2749     # directories
2750     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2751                      "dso" => [ @{$unified_info{modules}} ],
2752                      "bin" => [ @{$unified_info{programs}} ],
2753                      "script" => [ @{$unified_info{scripts}} ],
2754                      "docs" => [ (map { @{$unified_info{htmldocs}->{$_} // []} }
2755                                   keys %{$unified_info{htmldocs} // {}}),
2756                                  (map { @{$unified_info{mandocs}->{$_} // []} }
2757                                   keys %{$unified_info{mandocs} // {}}) ] );
2758     foreach my $type (keys %loopinfo) {
2759         foreach my $product (@{$loopinfo{$type}}) {
2760             my %dirs = ();
2761             my $pd = dirname($product);
2762
2763             foreach (@{$unified_info{sources}->{$product} // []},
2764                      @{$unified_info{shared_sources}->{$product} // []}) {
2765                 my $d = dirname($_);
2766
2767                 # We don't want to create targets for source directories
2768                 # when building out of source
2769                 next if ($config{sourcedir} ne $config{builddir}
2770                              && $d =~ m|^\Q$config{sourcedir}\E|);
2771                 # We already have a "test" target, and the current directory
2772                 # is just silly to make a target for
2773                 next if $d eq "test" || $d eq ".";
2774
2775                 $dirs{$d} = 1;
2776                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2777                     if $d ne $pd;
2778             }
2779             foreach (keys %dirs) {
2780                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2781                     $product;
2782             }
2783         }
2784     }
2785 }
2786
2787 # For the schemes that need it, we provide the old *_obj configs
2788 # from the *_asm_obj ones
2789 foreach (grep /_(asm|aux)_src$/, keys %target) {
2790     my $src = $_;
2791     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2792     $target{$obj} = $target{$src};
2793     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2794     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2795 }
2796
2797 # Write down our configuration where it fits #########################
2798
2799 my %template_vars = (
2800     config => \%config,
2801     target => \%target,
2802     disablables => \@disablables,
2803     disablables_int => \@disablables_int,
2804     disabled => \%disabled,
2805     withargs => \%withargs,
2806     unified_info => \%unified_info,
2807     tls => \@tls,
2808     dtls => \@dtls,
2809     makevars => [ sort keys %user ],
2810     disabled_info => \%disabled_info,
2811     user_crossable => \@user_crossable,
2812 );
2813 my $configdata_outname = 'configdata.pm';
2814 print "Creating $configdata_outname\n";
2815 open CONFIGDATA, ">$configdata_outname.new"
2816     or die "Trying to create $configdata_outname.new: $!";
2817 my $configdata_tmplname = cleanfile($srcdir, "configdata.pm.in", $blddir);
2818 my $configdata_tmpl =
2819     OpenSSL::Template->new(TYPE => 'FILE', SOURCE => $configdata_tmplname);
2820 $configdata_tmpl->fill_in(
2821     FILENAME => $configdata_tmplname,
2822     OUTPUT => \*CONFIGDATA,
2823     HASH => { %template_vars,
2824               autowarntext => [
2825                   'WARNING: do not edit!',
2826                   "Generated by Configure from $configdata_tmplname",
2827               ] }
2828 ) or die $Text::Template::ERROR;
2829 close CONFIGDATA;
2830 rename "$configdata_outname.new", $configdata_outname;
2831 if ($builder_platform eq 'unix') {
2832     my $mode = (0755 & ~umask);
2833     chmod $mode, 'configdata.pm'
2834         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2835 }
2836
2837 print "Running $configdata_outname\n";
2838 my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
2839 my $cmd = "$perlcmd $configdata_outname";
2840 #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2841 system($cmd);
2842 exit 1 if $? != 0;
2843
2844 $SIG{__DIE__} = $orig_death_handler;
2845
2846 print <<"EOF" if ($disabled{threads} eq "unavailable");
2847
2848 The library could not be configured for supporting multi-threaded
2849 applications as the compiler options required on this system are not known.
2850 See file INSTALL.md for details if you need multi-threading.
2851 EOF
2852
2853 print <<"EOF" if ($no_shared_warn);
2854
2855 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2856 platform, so we will pretend you gave the option 'no-pic', which also disables
2857 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2858 or position independent code, please let us know (but please first make sure
2859 you have tried with a current version of OpenSSL).
2860 EOF
2861
2862 print $banner;
2863
2864 exit(0);
2865
2866 ######################################################################
2867 #
2868 # Helpers and utility functions
2869 #
2870
2871 # Death handler, to print a helpful message in case of failure #######
2872 #
2873 sub death_handler {
2874     die @_ if $^S;              # To prevent the added message in eval blocks
2875     my $build_file = $target{build_file} // "build file";
2876     my @message = ( <<"_____", @_ );
2877
2878 Failure!  $build_file wasn't produced.
2879 Please read INSTALL.md and associated NOTES-* files.  You may also have to
2880 look over your available compiler tool chain or change your configuration.
2881
2882 _____
2883
2884     # Dying is terminal, so it's ok to reset the signal handler here.
2885     $SIG{__DIE__} = $orig_death_handler;
2886     die @message;
2887 }
2888
2889 # Configuration file reading #########################################
2890
2891 # Note: All of the helper functions are for lazy evaluation.  They all
2892 # return a CODE ref, which will return the intended value when evaluated.
2893 # Thus, whenever there's mention of a returned value, it's about that
2894 # intended value.
2895
2896 # Helper function to implement conditional value variants, with a default
2897 # plus additional values based on the value of $config{build_type}.
2898 # Arguments are given in hash table form:
2899 #
2900 #       picker(default => "Basic string: ",
2901 #              debug   => "debug",
2902 #              release => "release")
2903 #
2904 # When configuring with --debug, the resulting string will be
2905 # "Basic string: debug", and when not, it will be "Basic string: release"
2906 #
2907 # This can be used to create variants of sets of flags according to the
2908 # build type:
2909 #
2910 #       cflags => picker(default => "-Wall",
2911 #                        debug   => "-g -O0",
2912 #                        release => "-O3")
2913 #
2914 sub picker {
2915     my %opts = @_;
2916     return sub { add($opts{default} || (),
2917                      $opts{$config{build_type}} || ())->(); }
2918 }
2919
2920 # Helper function to combine several values of different types into one.
2921 # This is useful if you want to combine a string with the result of a
2922 # lazy function, such as:
2923 #
2924 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2925 #
2926 sub combine {
2927     my @stuff = @_;
2928     return sub { add(@stuff)->(); }
2929 }
2930
2931 # Helper function to implement conditional values depending on the value
2932 # of $disabled{threads}.  Can be used as follows:
2933 #
2934 #       cflags => combine("-Wall", threads("-pthread"))
2935 #
2936 sub threads {
2937     my @flags = @_;
2938     return sub { add($disabled{threads} ? () : @flags)->(); }
2939 }
2940
2941 sub shared {
2942     my @flags = @_;
2943     return sub { add($disabled{shared} ? () : @flags)->(); }
2944 }
2945
2946 our $add_called = 0;
2947 # Helper function to implement adding values to already existing configuration
2948 # values.  It handles elements that are ARRAYs, CODEs and scalars
2949 sub _add {
2950     my $separator = shift;
2951
2952     # If there's any ARRAY in the collection of values OR the separator
2953     # is undef, we will return an ARRAY of combined values, otherwise a
2954     # string of joined values with $separator as the separator.
2955     my $found_array = !defined($separator);
2956
2957     my @values =
2958         map {
2959             my $res = $_;
2960             while (ref($res) eq "CODE") {
2961                 $res = $res->();
2962             }
2963             if (defined($res)) {
2964                 if (ref($res) eq "ARRAY") {
2965                     $found_array = 1;
2966                     @$res;
2967                 } else {
2968                     $res;
2969                 }
2970             } else {
2971                 ();
2972             }
2973     } (@_);
2974
2975     $add_called = 1;
2976
2977     if ($found_array) {
2978         [ @values ];
2979     } else {
2980         join($separator, grep { defined($_) && $_ ne "" } @values);
2981     }
2982 }
2983 sub add_before {
2984     my $separator = " ";
2985     if (ref($_[$#_]) eq "HASH") {
2986         my $opts = pop;
2987         $separator = $opts->{separator};
2988     }
2989     my @x = @_;
2990     sub { _add($separator, @x, @_) };
2991 }
2992 sub add {
2993     my $separator = " ";
2994     if (ref($_[$#_]) eq "HASH") {
2995         my $opts = pop;
2996         $separator = $opts->{separator};
2997     }
2998     my @x = @_;
2999     sub { _add($separator, @_, @x) };
3000 }
3001
3002 sub read_eval_file {
3003     my $fname = shift;
3004     my $content;
3005     my @result;
3006
3007     open F, "< $fname" or die "Can't open '$fname': $!\n";
3008     {
3009         undef local $/;
3010         $content = <F>;
3011     }
3012     close F;
3013     {
3014         local $@;
3015
3016         @result = ( eval $content );
3017         warn $@ if $@;
3018     }
3019     return wantarray ? @result : $result[0];
3020 }
3021
3022 # configuration reader, evaluates the input file as a perl script and expects
3023 # it to fill %targets with target configurations.  Those are then added to
3024 # %table.
3025 sub read_config {
3026     my $fname = shift;
3027     my %targets;
3028
3029     {
3030         # Protect certain tables from tampering
3031         local %table = ();
3032
3033         %targets = read_eval_file($fname);
3034     }
3035     my %preexisting = ();
3036     foreach (sort keys %targets) {
3037         $preexisting{$_} = 1 if $table{$_};
3038     }
3039     die <<"EOF",
3040 The following config targets from $fname
3041 shadow pre-existing config targets with the same name:
3042 EOF
3043         map { "  $_\n" } sort keys %preexisting
3044         if %preexisting;
3045
3046
3047     # For each target, check that it's configured with a hash table.
3048     foreach (keys %targets) {
3049         if (ref($targets{$_}) ne "HASH") {
3050             if (ref($targets{$_}) eq "") {
3051                 warn "Deprecated target configuration for $_, ignoring...\n";
3052             } else {
3053                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3054             }
3055             delete $targets{$_};
3056         } else {
3057             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3058         }
3059     }
3060
3061     %table = (%table, %targets);
3062
3063 }
3064
3065 # configuration resolver.  Will only resolve all the lazy evaluation
3066 # codeblocks for the chosen target and all those it inherits from,
3067 # recursively
3068 sub resolve_config {
3069     my $target = shift;
3070     my @breadcrumbs = @_;
3071
3072 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3073
3074     if (grep { $_ eq $target } @breadcrumbs) {
3075         die "inherit_from loop!  target backtrace:\n  "
3076             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3077     }
3078
3079     if (!defined($table{$target})) {
3080         warn "Warning! target $target doesn't exist!\n";
3081         return ();
3082     }
3083     # Recurse through all inheritances.  They will be resolved on the
3084     # fly, so when this operation is done, they will all just be a
3085     # bunch of attributes with string values.
3086     # What we get here, though, are keys with references to lists of
3087     # the combined values of them all.  We will deal with lists after
3088     # this stage is done.
3089     my %combined_inheritance = ();
3090     if ($table{$target}->{inherit_from}) {
3091         my @inherit_from =
3092             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3093         foreach (@inherit_from) {
3094             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3095
3096             # 'template' is a marker that's considered private to
3097             # the config that had it.
3098             delete $inherited_config{template};
3099
3100             foreach (keys %inherited_config) {
3101                 if (!$combined_inheritance{$_}) {
3102                     $combined_inheritance{$_} = [];
3103                 }
3104                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3105             }
3106         }
3107     }
3108
3109     # We won't need inherit_from in this target any more, since we've
3110     # resolved all the inheritances that lead to this
3111     delete $table{$target}->{inherit_from};
3112
3113     # Now is the time to deal with those lists.  Here's the place to
3114     # decide what shall be done with those lists, all based on the
3115     # values of the target we're currently dealing with.
3116     # - If a value is a coderef, it will be executed with the list of
3117     #   inherited values as arguments.
3118     # - If the corresponding key doesn't have a value at all or is the
3119     #   empty string, the inherited value list will be run through the
3120     #   default combiner (below), and the result becomes this target's
3121     #   value.
3122     # - Otherwise, this target's value is assumed to be a string that
3123     #   will simply override the inherited list of values.
3124     my $default_combiner = add();
3125
3126     my %all_keys =
3127         map { $_ => 1 } (keys %combined_inheritance,
3128                          keys %{$table{$target}});
3129
3130     sub process_values {
3131         my $object    = shift;
3132         my $inherited = shift;  # Always a [ list ]
3133         my $target    = shift;
3134         my $entry     = shift;
3135
3136         $add_called = 0;
3137
3138         while(ref($object) eq "CODE") {
3139             $object = $object->(@$inherited);
3140         }
3141         if (!defined($object)) {
3142             return ();
3143         }
3144         elsif (ref($object) eq "ARRAY") {
3145             local $add_called;  # To make sure recursive calls don't affect it
3146             return [ map { process_values($_, $inherited, $target, $entry) }
3147                      @$object ];
3148         } elsif (ref($object) eq "") {
3149             return $object;
3150         } else {
3151             die "cannot handle reference type ",ref($object)
3152                 ," found in target ",$target," -> ",$entry,"\n";
3153         }
3154     }
3155
3156     foreach (sort keys %all_keys) {
3157         my $previous = $combined_inheritance{$_};
3158
3159         # Current target doesn't have a value for the current key?
3160         # Assign it the default combiner, the rest of this loop body
3161         # will handle it just like any other coderef.
3162         if (!exists $table{$target}->{$_}) {
3163             $table{$target}->{$_} = $default_combiner;
3164         }
3165
3166         $table{$target}->{$_} = process_values($table{$target}->{$_},
3167                                                $combined_inheritance{$_},
3168                                                $target, $_);
3169         unless(defined($table{$target}->{$_})) {
3170             delete $table{$target}->{$_};
3171         }
3172 #        if ($extra_checks &&
3173 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3174 #            warn "$_ got replaced in $target\n";
3175 #        }
3176     }
3177
3178     # Finally done, return the result.
3179     return %{$table{$target}};
3180 }
3181
3182 sub usage
3183         {
3184         print STDERR $usage;
3185         print STDERR "\npick os/compiler from:\n";
3186         my $j=0;
3187         my $i;
3188         my $k=0;
3189         foreach $i (sort keys %table)
3190                 {
3191                 next if $table{$i}->{template};
3192                 next if $i =~ /^debug/;
3193                 $k += length($i) + 1;
3194                 if ($k > 78)
3195                         {
3196                         print STDERR "\n";
3197                         $k=length($i);
3198                         }
3199                 print STDERR $i . " ";
3200                 }
3201         foreach $i (sort keys %table)
3202                 {
3203                 next if $table{$i}->{template};
3204                 next if $i !~ /^debug/;
3205                 $k += length($i) + 1;
3206                 if ($k > 78)
3207                         {
3208                         print STDERR "\n";
3209                         $k=length($i);
3210                         }
3211                 print STDERR $i . " ";
3212                 }
3213         exit(1);
3214         }
3215
3216 sub compiler_predefined {
3217     state %predefined;
3218     my $cc = shift;
3219
3220     return () if $^O eq 'VMS';
3221
3222     die 'compiler_predefined called without a compiler command'
3223         unless $cc;
3224
3225     if (! $predefined{$cc}) {
3226
3227         $predefined{$cc} = {};
3228
3229         # collect compiler pre-defines from gcc or gcc-alike...
3230         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3231         while (my $l = <PIPE>) {
3232             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3233             $predefined{$cc}->{$1} = $2 // '';
3234         }
3235         close(PIPE);
3236     }
3237
3238     return %{$predefined{$cc}};
3239 }
3240
3241 sub which
3242 {
3243     my ($name)=@_;
3244
3245     if (eval { require IPC::Cmd; 1; }) {
3246         IPC::Cmd->import();
3247         return scalar IPC::Cmd::can_run($name);
3248     } else {
3249         # if there is $directories component in splitpath,
3250         # then it's not something to test with $PATH...
3251         return $name if (File::Spec->splitpath($name))[1];
3252
3253         foreach (File::Spec->path()) {
3254             my $fullpath = catfile($_, "$name$target{exe_extension}");
3255             if (-f $fullpath and -x $fullpath) {
3256                 return $fullpath;
3257             }
3258         }
3259     }
3260 }
3261
3262 sub env
3263 {
3264     my $name = shift;
3265     my %opts = @_;
3266
3267     unless ($opts{cacheonly}) {
3268         # Note that if $ENV{$name} doesn't exist or is undefined,
3269         # $config{perlenv}->{$name} will be created with the value
3270         # undef.  This is intentional.
3271
3272         $config{perlenv}->{$name} = $ENV{$name}
3273             if ! exists $config{perlenv}->{$name};
3274     }
3275     return $config{perlenv}->{$name};
3276 }
3277
3278 # Configuration printer ##############################################
3279
3280 sub print_table_entry
3281 {
3282     local $now_printing = shift;
3283     my %target = resolve_config($now_printing);
3284     my $type = shift;
3285
3286     # Don't print the templates
3287     return if $target{template};
3288
3289     my @sequence = (
3290         "sys_id",
3291         "cpp",
3292         "cppflags",
3293         "defines",
3294         "includes",
3295         "cc",
3296         "cflags",
3297         "ld",
3298         "lflags",
3299         "loutflag",
3300         "ex_libs",
3301         "bn_ops",
3302         "enable",
3303         "disable",
3304         "poly1035_asm_src",
3305         "thread_scheme",
3306         "perlasm_scheme",
3307         "dso_scheme",
3308         "shared_target",
3309         "shared_cflag",
3310         "shared_defines",
3311         "shared_ldflag",
3312         "shared_rcflag",
3313         "shared_extension",
3314         "dso_extension",
3315         "obj_extension",
3316         "exe_extension",
3317         "ranlib",
3318         "ar",
3319         "arflags",
3320         "aroutflag",
3321         "rc",
3322         "rcflags",
3323         "rcoutflag",
3324         "mt",
3325         "mtflags",
3326         "mtinflag",
3327         "mtoutflag",
3328         "multilib",
3329         "build_scheme",
3330         );
3331
3332     if ($type eq "TABLE") {
3333         print "\n";
3334         print "*** $now_printing\n";
3335         foreach (@sequence) {
3336             if (ref($target{$_}) eq "ARRAY") {
3337                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3338             } else {
3339                 printf "\$%-12s = %s\n", $_, $target{$_};
3340             }
3341         }
3342     } elsif ($type eq "HASH") {
3343         my $largest =
3344             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3345         print "    '$now_printing' => {\n";
3346         foreach (@sequence) {
3347             if ($target{$_}) {
3348                 if (ref($target{$_}) eq "ARRAY") {
3349                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3350                 } else {
3351                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3352                 }
3353             }
3354         }
3355         print "    },\n";
3356     }
3357 }
3358
3359 # Utility routines ###################################################
3360
3361 # On VMS, if the given file is a logical name, File::Spec::Functions
3362 # will consider it an absolute path.  There are cases when we want a
3363 # purely syntactic check without checking the environment.
3364 sub isabsolute {
3365     my $file = shift;
3366
3367     # On non-platforms, we just use file_name_is_absolute().
3368     return file_name_is_absolute($file) unless $^O eq "VMS";
3369
3370     # If the file spec includes a device or a directory spec,
3371     # file_name_is_absolute() is perfectly safe.
3372     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3373
3374     # Here, we know the given file spec isn't absolute
3375     return 0;
3376 }
3377
3378 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3379 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3380 # realpath() requires that at least all path components except the last is an
3381 # existing directory.  On VMS, the last component of the directory spec must
3382 # exist.
3383 sub absolutedir {
3384     my $dir = shift;
3385
3386     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3387     # will return the volume name for the device, no matter what.  Also,
3388     # it will return an incorrect directory spec if the argument is a
3389     # directory that doesn't exist.
3390     if ($^O eq "VMS") {
3391         return rel2abs($dir);
3392     }
3393
3394     # We use realpath() on Unix, since no other will properly clean out
3395     # a directory spec.
3396     use Cwd qw/realpath/;
3397
3398     return realpath($dir);
3399 }
3400
3401 # Check if all paths are one and the same, using stat.  They must both exist
3402 # We need this for the cases when File::Spec doesn't detect case insensitivity
3403 # (File::Spec::Unix assumes case sensitivity)
3404 sub samedir {
3405     die "samedir expects two arguments\n" unless scalar @_ == 2;
3406
3407     my @stat0 = stat($_[0]);    # First argument
3408     my @stat1 = stat($_[1]);    # Second argument
3409
3410     die "Couldn't stat $_[0]" unless @stat0;
3411     die "Couldn't stat $_[1]" unless @stat1;
3412
3413     # Compare device number
3414     return 0 unless ($stat0[0] == $stat1[0]);
3415     # Compare "inode".  The perl manual recommends comparing as
3416     # string rather than as number.
3417     return 0 unless ($stat0[1] eq $stat1[1]);
3418
3419     return 1;                   # All the same
3420 }
3421
3422 sub quotify {
3423     my %processors = (
3424         perl    => sub { my $x = shift;
3425                          $x =~ s/([\\\$\@"])/\\$1/g;
3426                          return '"'.$x.'"'; },
3427         maybeshell => sub { my $x = shift;
3428                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3429                             if ($x ne $y || $x =~ m|\s|) {
3430                                 return '"'.$y.'"';
3431                             } else {
3432                                 return $x;
3433                             }
3434                         },
3435         );
3436     my $for = shift;
3437     my $processor =
3438         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3439
3440     return map { $processor->($_); } @_;
3441 }
3442
3443 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3444 # $filename is a file name to read from
3445 # $line_concat_cond_re is a regexp detecting a line continuation ending
3446 # $line_concat is a CODEref that takes care of concatenating two lines
3447 sub collect_from_file {
3448     my $filename = shift;
3449     my $line_concat_cond_re = shift;
3450     my $line_concat = shift;
3451
3452     open my $fh, $filename || die "unable to read $filename: $!\n";
3453     return sub {
3454         my $saved_line = "";
3455         $_ = "";
3456         while (<$fh>) {
3457             s|\R$||;
3458             if (defined $line_concat) {
3459                 $_ = $line_concat->($saved_line, $_);
3460                 $saved_line = "";
3461             }
3462             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3463                 $saved_line = $_;
3464                 next;
3465             }
3466             return $_;
3467         }
3468         die "$filename ending with continuation line\n" if $_;
3469         close $fh;
3470         return undef;
3471     }
3472 }
3473
3474 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3475 # $array is an ARRAYref of lines
3476 # $line_concat_cond_re is a regexp detecting a line continuation ending
3477 # $line_concat is a CODEref that takes care of concatenating two lines
3478 sub collect_from_array {
3479     my $array = shift;
3480     my $line_concat_cond_re = shift;
3481     my $line_concat = shift;
3482     my @array = (@$array);
3483
3484     return sub {
3485         my $saved_line = "";
3486         $_ = "";
3487         while (defined($_ = shift @array)) {
3488             s|\R$||;
3489             if (defined $line_concat) {
3490                 $_ = $line_concat->($saved_line, $_);
3491                 $saved_line = "";
3492             }
3493             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3494                 $saved_line = $_;
3495                 next;
3496             }
3497             return $_;
3498         }
3499         die "input text ending with continuation line\n" if $_;
3500         return undef;
3501     }
3502 }
3503
3504 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3505 # $lineiterator is a CODEref that delivers one line at a time.
3506 # All following arguments are regex/CODEref pairs, where the regexp detects a
3507 # line and the CODEref does something with the result of the regexp.
3508 sub collect_information {
3509     my $lineiterator = shift;
3510     my %collectors = @_;
3511
3512     while(defined($_ = $lineiterator->())) {
3513         s|\R$||;
3514         my $found = 0;
3515         if ($collectors{"BEFORE"}) {
3516             $collectors{"BEFORE"}->($_);
3517         }
3518         foreach my $re (keys %collectors) {
3519             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3520                 $collectors{$re}->($lineiterator);
3521                 $found = 1;
3522             };
3523         }
3524         if ($collectors{"OTHERWISE"}) {
3525             $collectors{"OTHERWISE"}->($lineiterator, $_)
3526                 unless $found || !defined $collectors{"OTHERWISE"};
3527         }
3528         if ($collectors{"AFTER"}) {
3529             $collectors{"AFTER"}->($_);
3530         }
3531     }
3532 }
3533
3534 # tokenize($line)
3535 # tokenize($line,$separator)
3536 # $line is a line of text to split up into tokens
3537 # $separator [optional] is a regular expression that separates the tokens,
3538 # the default being spaces.  Do not use quotes of any kind as separators,
3539 # that will give undefined results.
3540 # Returns a list of tokens.
3541 #
3542 # Tokens are divided by separator (spaces by default).  If the tokens include
3543 # the separators, they have to be quoted with single or double quotes.
3544 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3545 # with backslash.
3546 # Basically, the same quoting rules apply for " and ' as in any
3547 # Unix shell.
3548 sub tokenize {
3549     my $line = my $debug_line = shift;
3550     my $separator = shift // qr|\s+|;
3551     my @result = ();
3552
3553     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3554         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3555     }
3556
3557     while ($line =~ s|^${separator}||, $line ne "") {
3558         my $token = "";
3559     again:
3560         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3561         $token .= $1;
3562         $line = $2.$';
3563
3564         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3565             $token .= $1;
3566             $line = $';
3567             goto again;
3568         } elsif ($line =~ m/^'([^']*)'/) {
3569             $token .= $1;
3570             $line = $';
3571             goto again;
3572         }
3573         push @result, $token;
3574     }
3575
3576     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3577         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3578         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3579     }
3580     return @result;
3581 }