Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::Glob;
  21
  22 # see INSTALL for instructions.
  23
  24 my $orig_death_handler = $SIG{__DIE__};
  25 $SIG{__DIE__} = \&death_handler;
  26
  27 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  28
  29 # Options:
  30 #
  31 # --config      add the given configuration file, which will be read after
  32 #               any "Configurations*" files that are found in the same
  33 #               directory as this script.
  34 # --prefix      prefix for the OpenSSL installation, which includes the
  35 #               directories bin, lib, include, share/man, share/doc/openssl
  36 #               This becomes the value of INSTALLTOP in Makefile
  37 #               (Default: /usr/local)
  38 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  39 #               If it's a relative directory, it will be added on the directory
  40 #               given with --prefix.
  41 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  42 #               (Default: PREFIX/ssl)
  43 #
  44 # --cross-compile-prefix Add specified prefix to binutils components.
  45 #
  46 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0.0 / 3.
  47 #               Do not compile support for interfaces deprecated as of the
  48 #               specified OpenSSL version.
  49 #
  50 # no-hw-xxx     do not compile support for specific crypto hardware.
  51 #               Generic OpenSSL-style methods relating to this support
  52 #               are always compiled but return NULL if the hardware
  53 #               support isn't compiled.
  54 # no-hw         do not compile support for any crypto hardware.
  55 # [no-]threads  [don't] try to create a library that is suitable for
  56 #               multithreaded applications (default is "threads" if we
  57 #               know how to do it)
  58 # [no-]shared   [don't] try to create shared libraries when supported.
  59 # [no-]pic      [don't] try to build position independent code when supported.
  60 #               If disabled, it also disables shared and dynamic-engine.
  61 # no-asm        do not use assembler
  62 # no-egd        do not compile support for the entropy-gathering daemon APIs
  63 # [no-]zlib     [don't] compile support for zlib compression.
  64 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  65 #               library and will be loaded in run-time by the OpenSSL library.
  66 # sctp          include SCTP support
  67 # no-uplink     Don't build support for UPLINK interface.
  68 # enable-weak-ssl-ciphers
  69 #               Enable weak ciphers that are disabled by default.
  70 # 386           generate 80386 code in assembly modules
  71 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  72 #               mentioned '386' option implies this one
  73 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  74 # -<xxx> +<xxx> compiler options are passed through
  75 # -static       while -static is also a pass-through compiler option (and
  76 #               as such is limited to environments where it's actually
  77 #               meaningful), it triggers a number configuration options,
  78 #               namely no-pic, no-shared and no-threads. It is
  79 #               argued that the only reason to produce statically linked
  80 #               binaries (and in context it means executables linked with
  81 #               -static flag, and not just executables linked with static
  82 #               libcrypto.a) is to eliminate dependency on specific run-time,
  83 #               a.k.a. libc version. The mentioned config options are meant
  84 #               to achieve just that. Unfortunately on Linux it's impossible
  85 #               to eliminate the dependency completely for openssl executable
  86 #               because of getaddrinfo and gethostbyname calls, which can
  87 #               invoke dynamically loadable library facility anyway to meet
  88 #               the lookup requests. For this reason on Linux statically
  89 #               linked openssl executable has rather debugging value than
  90 #               production quality.
  91 #
  92 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  93 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  94 # Following are set automatically by this script
  95 #
  96 # MD5_ASM       use some extra md5 assembler,
  97 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
  98 # RMD160_ASM    use some extra ripemd160 assembler,
  99 # SHA256_ASM    sha256_block is implemented in assembler
 100 # SHA512_ASM    sha512_block is implemented in assembler
 101 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 102
 103 # Minimum warning options... any contributions to OpenSSL should at least
 104 # get past these.  Note that we only use these with C compilers, not with
 105 # C++ compilers.
 106
 107 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 108 # -DPEDANTIC complements -pedantic and is meant to mask code that
 109 # is not strictly standard-compliant and/or implementation-specific,
 110 # e.g. inline assembly, disregards to alignment requirements, such
 111 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 112 # to be used even in sanitized builds, because sanitizer too is
 113 # supposed to and does take notice of non-standard behaviour. Then
 114 # -pedantic with pre-C9x compiler would also complain about 'long
 115 # long' not being supported. As 64-bit algorithms are common now,
 116 # it grew impossible to resolve this without sizeable additional
 117 # code, so we just tell compiler to be pedantic about everything
 118 # but 'long long' type.
 119
 120 my @gcc_devteam_warn = qw(
 121     -DDEBUG_UNUSED
 122     -DPEDANTIC -pedantic -Wno-long-long
 123     -Wall
 124     -Wextra
 125     -Wno-unused-parameter
 126     -Wno-missing-field-initializers
 127     -Wswitch
 128     -Wsign-compare
 129     -Wshadow
 130     -Wformat
 131     -Wtype-limits
 132     -Wundef
 133     -Werror
 134     -Wmissing-prototypes
 135     -Wstrict-prototypes
 136 );
 137
 138 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 139 # TODO(openssl-team): fix problems and investigate if (at least) the
 140 # following warnings can also be enabled:
 141 #       -Wcast-align
 142 #       -Wunreachable-code -- no, too ugly/compiler-specific
 143 #       -Wlanguage-extension-token -- no, we use asm()
 144 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 145 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 146 my @clang_devteam_warn = qw(
 147     -Wswitch-default
 148     -Wno-parentheses-equality
 149     -Wno-language-extension-token
 150     -Wno-extended-offsetof
 151     -Wconditional-uninitialized
 152     -Wincompatible-pointer-types-discards-qualifiers
 153     -Wno-unknown-warning-option
 154     -Wmissing-variable-declarations
 155 );
 156
 157 # This adds backtrace information to the memory leak info.  Is only used
 158 # when crypto-mdebug-backtrace is enabled.
 159 my $memleak_devteam_backtrace = "-rdynamic";
 160
 161 my $strict_warnings = 0;
 162
 163 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 164 # which would cover all BSD flavors. -pthread applies to them all,
 165 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 166 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 167 # which has to be accompanied by explicit -D_THREAD_SAFE and
 168 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 169 # seems to be sufficient?
 170 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 171
 172 #
 173 # API compatibility name to version number mapping.
 174 #
 175 my $maxapi = "3.0.0";           # API for "no-deprecated" builds
 176 my $apitable = {
 177     "3.0.0" => 3,
 178     "1.1.1" => 2,
 179     "1.1.0" => 2,
 180     "1.0.2" => 1,
 181     "1.0.1" => 1,
 182     "1.0.0" => 1,
 183     "0.9.8" => 0,
 184 };
 185
 186 our %table = ();
 187 our %config = ();
 188 our %withargs = ();
 189 our $now_printing;      # set to current entry's name in print_table_entry
 190                         # (todo: right thing would be to encapsulate name
 191                         # into %target [class] and make print_table_entry
 192                         # a method)
 193
 194 # Forward declarations ###############################################
 195
 196 # read_config(filename)
 197 #
 198 # Reads a configuration file and populates %table with the contents
 199 # (which the configuration file places in %targets).
 200 sub read_config;
 201
 202 # resolve_config(target)
 203 #
 204 # Resolves all the late evaluations, inheritances and so on for the
 205 # chosen target and any target it inherits from.
 206 sub resolve_config;
 207
 208
 209 # Information collection #############################################
 210
 211 # Unified build supports separate build dir
 212 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 213 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 214 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 215
 216 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 217
 218 $config{sourcedir} = abs2rel($srcdir);
 219 $config{builddir} = abs2rel($blddir);
 220
 221 # Collect reconfiguration information if needed
 222 my @argvcopy=@ARGV;
 223
 224 if (grep /^reconf(igure)?$/, @argvcopy) {
 225     die "reconfiguring with other arguments present isn't supported"
 226         if scalar @argvcopy > 1;
 227     if (-f "./configdata.pm") {
 228         my $file = "./configdata.pm";
 229         unless (my $return = do $file) {
 230             die "couldn't parse $file: $@" if $@;
 231             die "couldn't do $file: $!"    unless defined $return;
 232             die "couldn't run $file"       unless $return;
 233         }
 234
 235         @argvcopy = defined($configdata::config{perlargv}) ?
 236             @{$configdata::config{perlargv}} : ();
 237         die "Incorrect data to reconfigure, please do a normal configuration\n"
 238             if (grep(/^reconf/,@argvcopy));
 239         $config{perlenv} = $configdata::config{perlenv} // {};
 240     } else {
 241         die "Insufficient data to reconfigure, please do a normal configuration\n";
 242     }
 243 }
 244
 245 $config{perlargv} = [ @argvcopy ];
 246
 247 # Collect version numbers
 248 $config{major} = "unknown";
 249 $config{minor} = "unknown";
 250 $config{patch} = "unknown";
 251 $config{prerelease} = "";
 252 $config{build_metadata} = "";
 253 $config{shlib_version} = "unknown";
 254
 255 collect_information(
 256     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 257     qr/#\s+define\s+OPENSSL_VERSION_MAJOR\s+(\d+)/ =>
 258         sub { $config{major} = $1; },
 259     qr/#\s+define\s+OPENSSL_VERSION_MINOR\s+(\d+)/ =>
 260         sub { $config{minor} = $1; },
 261     qr/#\s+define\s+OPENSSL_VERSION_PATCH\s+(\d+)/ =>
 262         sub { $config{patch} = $1; },
 263     qr/#\s+define\s+OPENSSL_VERSION_PRE_RELEASE\s+"((?:\\.|[^"])*)"/ =>
 264         sub { $config{prerelease} = $1; },
 265     qr/#\s+define\s+OPENSSL_VERSION_BUILD_METADATA\s+"((?:\\.|[^"])*)"/ =>
 266         sub { $config{build_metadata} = $1; },
 267     qr/#\s+define\s+OPENSSL_SHLIB_VERSION\s+([\d\.]+)/ =>
 268         sub { $config{shlib_version} = $1; },
 269     );
 270 die "erroneous version information in opensslv.h: ",
 271     "$config{major}.$config{minor}.$config{patch}, $config{shlib_version}\n"
 272     if ($config{major} eq "unknown"
 273             || $config{minor} eq "unknown"
 274             || $config{patch} eq "unknown"
 275             || $config{shlib_version} eq "unknown");
 276
 277 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 278 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 279
 280 # Collect target configurations
 281
 282 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 283 foreach (sort glob($pattern)) {
 284     &read_config($_);
 285 }
 286
 287 if (defined env($local_config_envname)) {
 288     if ($^O eq 'VMS') {
 289         # VMS environment variables are logical names,
 290         # which can be used as is
 291         $pattern = $local_config_envname . ':' . '*.conf';
 292     } else {
 293         $pattern = catfile(env($local_config_envname), '*.conf');
 294     }
 295
 296     foreach (sort glob($pattern)) {
 297         &read_config($_);
 298     }
 299 }
 300
 301 # Save away perl command information
 302 $config{perl_cmd} = $^X;
 303 $config{perl_version} = $Config{version};
 304 $config{perl_archname} = $Config{archname};
 305
 306 $config{prefix}="";
 307 $config{openssldir}="";
 308 $config{processor}="";
 309 $config{libdir}="";
 310 my $auto_threads=1;    # enable threads automatically? true by default
 311 my $default_ranlib;
 312
 313 # Known TLS and DTLS protocols
 314 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 315 my @dtls = qw(dtls1 dtls1_2);
 316
 317 # Explicitly known options that are possible to disable.  They can
 318 # be regexps, and will be used like this: /^no-${option}$/
 319 # For developers: keep it sorted alphabetically
 320
 321 my @disablables = (
 322     "ktls",
 323     "afalgeng",
 324     "aria",
 325     "asan",
 326     "asm",
 327     "async",
 328     "autoalginit",
 329     "autoerrinit",
 330     "autoload-config",
 331     "bf",
 332     "blake2",
 333     "buildtest-c++",
 334     "camellia",
 335     "capieng",
 336     "cast",
 337     "chacha",
 338     "cmac",
 339     "cmp",
 340     "cms",
 341     "comp",
 342     "crypto-mdebug",
 343     "crypto-mdebug-backtrace",
 344     "ct",
 345     "deprecated",
 346     "des",
 347     "devcryptoeng",
 348     "dgram",
 349     "dh",
 350     "dsa",
 351     "dtls",
 352     "dynamic-engine",
 353     "ec",
 354     "ec2m",
 355     "ecdh",
 356     "ecdsa",
 357     "ec_nistp_64_gcc_128",
 358     "egd",
 359     "engine",
 360     "err",
 361     "external-tests",
 362     "filenames",
 363     "fips",
 364     "fuzz-libfuzzer",
 365     "fuzz-afl",
 366     "gost",
 367     "idea",
 368     "legacy",
 369     "makedepend",
 370     "md2",
 371     "md4",
 372     "mdc2",
 373     "module",
 374     "msan",
 375     "multiblock",
 376     "nextprotoneg",
 377     "pinshared",
 378     "ocb",
 379     "ocsp",
 380     "padlockeng",
 381     "pic",
 382     "poly1305",
 383     "posix-io",
 384     "psk",
 385     "rc2",
 386     "rc4",
 387     "rc5",
 388     "rdrand",
 389     "rfc3779",
 390     "rmd160",
 391     "scrypt",
 392     "sctp",
 393     "seed",
 394     "shared",
 395     "siphash",
 396     "siv",
 397     "sm2",
 398     "sm3",
 399     "sm4",
 400     "sock",
 401     "srp",
 402     "srtp",
 403     "sse2",
 404     "ssl",
 405     "ssl-trace",
 406     "static-engine",
 407     "stdio",
 408     "tests",
 409     "threads",
 410     "tls",
 411     "trace",
 412     "ts",
 413     "ubsan",
 414     "ui-console",
 415     "unit-test",
 416     "uplink",
 417     "whirlpool",
 418     "weak-ssl-ciphers",
 419     "zlib",
 420     "zlib-dynamic",
 421     );
 422 foreach my $proto ((@tls, @dtls))
 423         {
 424         push(@disablables, $proto);
 425         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 426         }
 427
 428 # Internal disablables, for aliasing purposes.  They serve no special
 429 # purpose here, but allow scripts to get to know them through configdata.pm,
 430 # where these are merged with @disablables.
 431 # The actual aliasing mechanism is done via %disable_cascades
 432 my @disablables_int = qw(
 433     crmf
 434     );
 435
 436 my %deprecated_disablables = (
 437     "ssl2" => undef,
 438     "buf-freelists" => undef,
 439     "hw" => "hw",               # causes cascade, but no macro
 440     "hw-padlock" => "padlockeng",
 441     "ripemd" => "rmd160",
 442     "ui" => "ui-console",
 443     "dso" => undef,
 444     "heartbeats" => undef,
 445     );
 446
 447 # All of the following are disabled by default:
 448
 449 our %disabled = ( # "what"         => "comment"
 450                   "asan"                => "default",
 451                   "buildtest-c++"       => "default",
 452                   "crypto-mdebug"       => "default",
 453                   "crypto-mdebug-backtrace" => "default",
 454                   "devcryptoeng"        => "default",
 455                   "ec_nistp_64_gcc_128" => "default",
 456                   "egd"                 => "default",
 457                   "external-tests"      => "default",
 458                   "fuzz-libfuzzer"      => "default",
 459                   "fuzz-afl"            => "default",
 460                   "md2"                 => "default",
 461                   "msan"                => "default",
 462                   "rc5"                 => "default",
 463                   "sctp"                => "default",
 464                   "ssl-trace"           => "default",
 465                   "ssl3"                => "default",
 466                   "ssl3-method"         => "default",
 467                   "trace"               => "default",
 468                   "ubsan"               => "default",
 469                   "unit-test"           => "default",
 470                   "weak-ssl-ciphers"    => "default",
 471                   "zlib"                => "default",
 472                   "zlib-dynamic"        => "default",
 473                   "ktls"                => "default",
 474                 );
 475
 476 # Note: => pair form used for aesthetics, not to truly make a hash table
 477 my @disable_cascades = (
 478     # "what"            => [ "cascade", ... ]
 479     sub { $config{processor} eq "386" }
 480                         => [ "sse2" ],
 481     "ssl"               => [ "ssl3" ],
 482     "ssl3-method"       => [ "ssl3" ],
 483     "zlib"              => [ "zlib-dynamic" ],
 484     "des"               => [ "mdc2" ],
 485     "ec"                => [ "ecdsa", "ecdh", "sm2" ],
 486     sub { $disabled{"ec"} && $disabled{"dh"} }
 487                         => [ "tls1_3" ],
 488     "dgram"             => [ "dtls", "sctp" ],
 489     "sock"              => [ "dgram" ],
 490     "dtls"              => [ @dtls ],
 491     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 492                         => [ "dtls" ],
 493
 494     "tls"               => [ @tls ],
 495     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 496                         => [ "tls" ],
 497
 498     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 499
 500     # If no modules, then no dynamic engines either
 501     "module"            => [ "dynamic-engine" ],
 502
 503     # Without shared libraries, dynamic engines aren't possible.
 504     # This is due to them having to link with libcrypto and register features
 505     # using the ENGINE functionality, and since that relies on global tables,
 506     # those *have* to be exacty the same as the ones accessed from the app,
 507     # which cannot be guaranteed if shared libraries aren't present.
 508     # (note that even with shared libraries, both the app and dynamic engines
 509     # must be linked with the same library)
 510     "shared"            => [ "dynamic-engine", "uplink" ],
 511     # Other modules don't necessarily have to link with libcrypto, so shared
 512     # libraries do not have to be a condition to produce those.
 513
 514     # Without position independent code, there can be no shared libraries
 515     # or modules.
 516     "pic"               => [ "shared", "module" ],
 517
 518     "module"            => [ "fips", "legacy" ],
 519
 520     "engine"            => [ grep /eng$/, @disablables ],
 521     "hw"                => [ "padlockeng" ],
 522
 523     # no-autoalginit is only useful when building non-shared
 524     "autoalginit"       => [ "shared", "apps" ],
 525
 526     "stdio"             => [ "apps", "capieng", "egd" ],
 527     "apps"              => [ "tests" ],
 528     "tests"             => [ "external-tests" ],
 529     "comp"              => [ "zlib" ],
 530     "sm3"               => [ "sm2" ],
 531     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 532
 533     sub { !$disabled{"msan"} } => [ "asm" ],
 534
 535     sub { $disabled{cmac}; } => [ "siv" ],
 536     "legacy"                 => [ "md2" ],
 537
 538     "cmp"               => [ "crmf" ],
 539     );
 540
 541 # Avoid protocol support holes.  Also disable all versions below N, if version
 542 # N is disabled while N+1 is enabled.
 543 #
 544 my @list = (reverse @tls);
 545 while ((my $first, my $second) = (shift @list, shift @list)) {
 546     last unless @list;
 547     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 548                               => [ @list ] );
 549     unshift @list, $second;
 550 }
 551 my @list = (reverse @dtls);
 552 while ((my $first, my $second) = (shift @list, shift @list)) {
 553     last unless @list;
 554     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 555                               => [ @list ] );
 556     unshift @list, $second;
 557 }
 558
 559 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 560 # To remove something from %disabled, use "enable-foo".
 561 # For symmetry, "disable-foo" is a synonym for "no-foo".
 562
 563 &usage if ($#ARGV < 0);
 564
 565 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 566 # platform specific list separators.  Users from those platforms should
 567 # recognise those separators from how you set up the PATH to find executables.
 568 # The default is the Unix like separator, :, but as an exception, we also
 569 # support the space as separator.
 570 my $list_separator_re =
 571     { VMS           => qr/(?<!\^),/,
 572       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 573 # All the "make variables" we support
 574 # Some get pre-populated for the sake of backward compatibility
 575 # (we supported those before the change to "make variable" support.
 576 my %user = (
 577     AR          => env('AR'),
 578     ARFLAGS     => [],
 579     AS          => undef,
 580     ASFLAGS     => [],
 581     CC          => env('CC'),
 582     CFLAGS      => [ env('CFLAGS') || () ],
 583     CXX         => env('CXX'),
 584     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 585     CPP         => undef,
 586     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 587     CPPDEFINES  => [],  # Alternative for -D
 588     CPPINCLUDES => [],  # Alternative for -I
 589     CROSS_COMPILE => env('CROSS_COMPILE'),
 590     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 591     LD          => undef,
 592     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 593     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 594     MT          => undef,
 595     MTFLAGS     => [],
 596     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 597     RANLIB      => env('RANLIB'),
 598     RC          => env('RC') || env('WINDRES'),
 599     RCFLAGS     => [ env('RCFLAGS') || () ],
 600     RM          => undef,
 601    );
 602 # Info about what "make variables" may be prefixed with the cross compiler
 603 # prefix.  This should NEVER mention any such variable with a list for value.
 604 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 605 # The same but for flags given as Configure options.  These are *additional*
 606 # input, as opposed to the VAR=string option that override the corresponding
 607 # config target attributes
 608 my %useradd = (
 609     CPPDEFINES  => [],
 610     CPPINCLUDES => [],
 611     CPPFLAGS    => [],
 612     CFLAGS      => [],
 613     CXXFLAGS    => [],
 614     LDFLAGS     => [],
 615     LDLIBS      => [],
 616     RCFLAGS     => [],
 617    );
 618
 619 my %user_synonyms = (
 620     HASHBANGPERL=> 'PERL',
 621     RC          => 'WINDRES',
 622    );
 623
 624 # Some target attributes have been renamed, this is the translation table
 625 my %target_attr_translate =(
 626     ar          => 'AR',
 627     as          => 'AS',
 628     cc          => 'CC',
 629     cxx         => 'CXX',
 630     cpp         => 'CPP',
 631     hashbangperl => 'HASHBANGPERL',
 632     ld          => 'LD',
 633     mt          => 'MT',
 634     ranlib      => 'RANLIB',
 635     rc          => 'RC',
 636     rm          => 'RM',
 637    );
 638
 639 # Initialisers coming from 'config' scripts
 640 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 641 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 642 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 643 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 644 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 645 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 646 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 647
 648 $config{openssl_api_defines}=[];
 649 $config{openssl_sys_defines}=[];
 650 $config{openssl_feature_defines}=[];
 651 $config{options}="";
 652 $config{build_type} = "release";
 653 my $target="";
 654
 655 my %cmdvars = ();               # Stores FOO='blah' type arguments
 656 my %unsupported_options = ();
 657 my %deprecated_options = ();
 658 # If you change this, update apps/version.c
 659 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 660 my @seed_sources = ();
 661 while (@argvcopy)
 662         {
 663         $_ = shift @argvcopy;
 664
 665         # Support env variable assignments among the options
 666         if (m|^(\w+)=(.+)?$|)
 667                 {
 668                 $cmdvars{$1} = $2;
 669                 # Every time a variable is given as a configuration argument,
 670                 # it acts as a reset if the variable.
 671                 if (exists $user{$1})
 672                         {
 673                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 674                         }
 675                 #if (exists $useradd{$1})
 676                 #       {
 677                 #       $useradd{$1} = [];
 678                 #       }
 679                 next;
 680                 }
 681
 682         # VMS is a case insensitive environment, and depending on settings
 683         # out of our control, we may receive options uppercased.  Let's
 684         # downcase at least the part before any equal sign.
 685         if ($^O eq "VMS")
 686                 {
 687                 s/^([^=]*)/lc($1)/e;
 688                 }
 689
 690         # some people just can't read the instructions, clang people have to...
 691         s/^-no-(?!integrated-as)/no-/;
 692
 693         # rewrite some options in "enable-..." form
 694         s /^-?-?shared$/enable-shared/;
 695         s /^sctp$/enable-sctp/;
 696         s /^threads$/enable-threads/;
 697         s /^zlib$/enable-zlib/;
 698         s /^zlib-dynamic$/enable-zlib-dynamic/;
 699
 700         if (/^(no|disable|enable)-(.+)$/)
 701                 {
 702                 my $word = $2;
 703                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 704                         && !exists $deprecated_disablables{$word}
 705                         && !grep { $word eq $_ } @disablables)
 706                         {
 707                         $unsupported_options{$_} = 1;
 708                         next;
 709                         }
 710                 }
 711         if (/^no-(.+)$/ || /^disable-(.+)$/)
 712                 {
 713                 foreach my $proto ((@tls, @dtls))
 714                         {
 715                         if ($1 eq "$proto-method")
 716                                 {
 717                                 $disabled{"$proto"} = "option($proto-method)";
 718                                 last;
 719                                 }
 720                         }
 721                 if ($1 eq "dtls")
 722                         {
 723                         foreach my $proto (@dtls)
 724                                 {
 725                                 $disabled{$proto} = "option(dtls)";
 726                                 }
 727                         $disabled{"dtls"} = "option(dtls)";
 728                         }
 729                 elsif ($1 eq "ssl")
 730                         {
 731                         # Last one of its kind
 732                         $disabled{"ssl3"} = "option(ssl)";
 733                         }
 734                 elsif ($1 eq "tls")
 735                         {
 736                         # XXX: Tests will fail if all SSL/TLS
 737                         # protocols are disabled.
 738                         foreach my $proto (@tls)
 739                                 {
 740                                 $disabled{$proto} = "option(tls)";
 741                                 }
 742                         }
 743                 elsif ($1 eq "static-engine")
 744                         {
 745                         delete $disabled{"dynamic-engine"};
 746                         }
 747                 elsif ($1 eq "dynamic-engine")
 748                         {
 749                         $disabled{"dynamic-engine"} = "option";
 750                         }
 751                 elsif (exists $deprecated_disablables{$1})
 752                         {
 753                         $deprecated_options{$_} = 1;
 754                         if (defined $deprecated_disablables{$1})
 755                                 {
 756                                 $disabled{$deprecated_disablables{$1}} = "option";
 757                                 }
 758                         }
 759                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 760                         {
 761                         $deprecated_options{$_} = 1;
 762                         }
 763                 else
 764                         {
 765                         $disabled{$1} = "option";
 766                         }
 767                 # No longer an automatic choice
 768                 $auto_threads = 0 if ($1 eq "threads");
 769                 }
 770         elsif (/^enable-(.+)$/)
 771                 {
 772                 if ($1 eq "static-engine")
 773                         {
 774                         $disabled{"dynamic-engine"} = "option";
 775                         }
 776                 elsif ($1 eq "dynamic-engine")
 777                         {
 778                         delete $disabled{"dynamic-engine"};
 779                         }
 780                 elsif ($1 eq "zlib-dynamic")
 781                         {
 782                         delete $disabled{"zlib"};
 783                         }
 784                 my $algo = $1;
 785                 delete $disabled{$algo};
 786
 787                 # No longer an automatic choice
 788                 $auto_threads = 0 if ($1 eq "threads");
 789                 }
 790         elsif (/^--strict-warnings$/)
 791                 {
 792                 # Pretend that our strict flags is a C flag, and replace it
 793                 # with the proper flags later on
 794                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 795                 $strict_warnings=1;
 796                 }
 797         elsif (/^--debug$/)
 798                 {
 799                 $config{build_type} = "debug";
 800                 }
 801         elsif (/^--release$/)
 802                 {
 803                 $config{build_type} = "release";
 804                 }
 805         elsif (/^386$/)
 806                 { $config{processor}=386; }
 807         elsif (/^fips$/)
 808                 {
 809                 die "FIPS mode not supported\n";
 810                 }
 811         elsif (/^rsaref$/)
 812                 {
 813                 # No RSAref support any more since it's not needed.
 814                 # The check for the option is there so scripts aren't
 815                 # broken
 816                 }
 817         elsif (/^nofipscanistercheck$/)
 818                 {
 819                 die "FIPS mode not supported\n";
 820                 }
 821         elsif (/^[-+]/)
 822                 {
 823                 if (/^--prefix=(.*)$/)
 824                         {
 825                         $config{prefix}=$1;
 826                         die "Directory given with --prefix MUST be absolute\n"
 827                                 unless file_name_is_absolute($config{prefix});
 828                         }
 829                 elsif (/^--api=(.*)$/)
 830                         {
 831                         $config{api}=$1;
 832                         }
 833                 elsif (/^--libdir=(.*)$/)
 834                         {
 835                         $config{libdir}=$1;
 836                         }
 837                 elsif (/^--openssldir=(.*)$/)
 838                         {
 839                         $config{openssldir}=$1;
 840                         }
 841                 elsif (/^--with-zlib-lib=(.*)$/)
 842                         {
 843                         $withargs{zlib_lib}=$1;
 844                         }
 845                 elsif (/^--with-zlib-include=(.*)$/)
 846                         {
 847                         $withargs{zlib_include}=$1;
 848                         }
 849                 elsif (/^--with-fuzzer-lib=(.*)$/)
 850                         {
 851                         $withargs{fuzzer_lib}=$1;
 852                         }
 853                 elsif (/^--with-fuzzer-include=(.*)$/)
 854                         {
 855                         $withargs{fuzzer_include}=$1;
 856                         }
 857                 elsif (/^--with-rand-seed=(.*)$/)
 858                         {
 859                         foreach my $x (split(m|,|, $1))
 860                             {
 861                             die "Unknown --with-rand-seed choice $x\n"
 862                                 if ! grep { $x eq $_ } @known_seed_sources;
 863                             push @seed_sources, $x;
 864                             }
 865                         }
 866                 elsif (/^--cross-compile-prefix=(.*)$/)
 867                         {
 868                         $user{CROSS_COMPILE}=$1;
 869                         }
 870                 elsif (/^--config=(.*)$/)
 871                         {
 872                         read_config $1;
 873                         }
 874                 elsif (/^-l(.*)$/)
 875                         {
 876                         push @{$useradd{LDLIBS}}, $_;
 877                         }
 878                 elsif (/^-framework$/)
 879                         {
 880                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 881                         }
 882                 elsif (/^-L(.*)$/ or /^-Wl,/)
 883                         {
 884                         push @{$useradd{LDFLAGS}}, $_;
 885                         }
 886                 elsif (/^-rpath$/ or /^-R$/)
 887                         # -rpath is the OSF1 rpath flag
 888                         # -R is the old Solaris rpath flag
 889                         {
 890                         my $rpath = shift(@argvcopy) || "";
 891                         $rpath .= " " if $rpath ne "";
 892                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 893                         }
 894                 elsif (/^-static$/)
 895                         {
 896                         push @{$useradd{LDFLAGS}}, $_;
 897                         }
 898                 elsif (/^-D(.*)$/)
 899                         {
 900                         push @{$useradd{CPPDEFINES}}, $1;
 901                         }
 902                 elsif (/^-I(.*)$/)
 903                         {
 904                         push @{$useradd{CPPINCLUDES}}, $1;
 905                         }
 906                 elsif (/^-Wp,$/)
 907                         {
 908                         push @{$useradd{CPPFLAGS}}, $1;
 909                         }
 910                 else    # common if (/^[-+]/), just pass down...
 911                         {
 912                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 913                         push @{$useradd{CFLAGS}}, $_;
 914                         push @{$useradd{CXXFLAGS}}, $_;
 915                         }
 916                 }
 917         else
 918                 {
 919                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 920                 $target=$_;
 921                 }
 922         unless ($_ eq $target || /^no-/ || /^disable-/)
 923                 {
 924                 # "no-..." follows later after implied deactivations
 925                 # have been derived.  (Don't take this too seriously,
 926                 # we really only write OPTIONS to the Makefile out of
 927                 # nostalgia.)
 928
 929                 if ($config{options} eq "")
 930                         { $config{options} = $_; }
 931                 else
 932                         { $config{options} .= " ".$_; }
 933                 }
 934         }
 935
 936 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 937         die "***** Unsupported api compatibility level: $config{api}\n",
 938 }
 939
 940 if (keys %deprecated_options)
 941         {
 942         warn "***** Deprecated options: ",
 943                 join(", ", keys %deprecated_options), "\n";
 944         }
 945 if (keys %unsupported_options)
 946         {
 947         die "***** Unsupported options: ",
 948                 join(", ", keys %unsupported_options), "\n";
 949         }
 950
 951 # If any %useradd entry has been set, we must check that the "make
 952 # variables" haven't been set.  We start by checking of any %useradd entry
 953 # is set.
 954 if (grep { scalar @$_ > 0 } values %useradd) {
 955     # Hash of env / make variables names.  The possible values are:
 956     # 1 - "make vars"
 957     # 2 - %useradd entry set
 958     # 3 - both set
 959     my %detected_vars =
 960         map { my $v = 0;
 961               $v += 1 if $cmdvars{$_};
 962               $v += 2 if @{$useradd{$_}};
 963               $_ => $v }
 964         keys %useradd;
 965
 966     # If any of the corresponding "make variables" is set, we error
 967     if (grep { $_ & 1 } values %detected_vars) {
 968         my $names = join(', ', grep { $detected_vars{$_} > 0 }
 969                                sort keys %detected_vars);
 970         die <<"_____";
 971 ***** Mixing make variables and additional compiler/linker flags as
 972 ***** configure command line option is not permitted.
 973 ***** Affected make variables: $names
 974 _____
 975     }
 976 }
 977
 978 # Check through all supported command line variables to see if any of them
 979 # were set, and canonicalise the values we got.  If no compiler or linker
 980 # flag or anything else that affects %useradd was set, we also check the
 981 # environment for values.
 982 my $anyuseradd =
 983     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
 984 foreach (keys %user) {
 985     my $value = $cmdvars{$_};
 986     $value //= env($_) unless $anyuseradd;
 987     $value //=
 988         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
 989     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
 990         unless $anyuseradd;
 991
 992     if (defined $value) {
 993         if (ref $user{$_} eq 'ARRAY') {
 994             $user{$_} = [ split /$list_separator_re/, $value ];
 995         } elsif (!defined $user{$_}) {
 996             $user{$_} = $value;
 997         }
 998     }
 999 }
1000
1001 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1002     && !$disabled{shared}
1003     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1004     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1005         "***** any of asan, msan or ubsan\n";
1006 }
1007
1008 sub disable {
1009     my $disable_type = shift;
1010
1011     for (@_) {
1012         $disabled{$_} = $disable_type;
1013     }
1014
1015     my @tocheckfor = (@_ ? @_ : keys %disabled);
1016     while (@tocheckfor) {
1017         my %new_tocheckfor = ();
1018         my @cascade_copy = (@disable_cascades);
1019         while (@cascade_copy) {
1020             my ($test, $descendents) =
1021                 (shift @cascade_copy, shift @cascade_copy);
1022             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1023                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1024                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1025                 }
1026             }
1027         }
1028         @tocheckfor = (keys %new_tocheckfor);
1029     }
1030 }
1031 disable();                     # First cascade run
1032
1033 our $die = sub { die @_; };
1034 if ($target eq "TABLE") {
1035     local $die = sub { warn @_; };
1036     foreach (sort keys %table) {
1037         print_table_entry($_, "TABLE");
1038     }
1039     exit 0;
1040 }
1041
1042 if ($target eq "LIST") {
1043     foreach (sort keys %table) {
1044         print $_,"\n" unless $table{$_}->{template};
1045     }
1046     exit 0;
1047 }
1048
1049 if ($target eq "HASH") {
1050     local $die = sub { warn @_; };
1051     print "%table = (\n";
1052     foreach (sort keys %table) {
1053         print_table_entry($_, "HASH");
1054     }
1055     exit 0;
1056 }
1057
1058 print "Configuring OpenSSL version $config{full_version} ";
1059 print "for target $target\n";
1060
1061 if (scalar(@seed_sources) == 0) {
1062     print "Using os-specific seed configuration\n";
1063     push @seed_sources, 'os';
1064 }
1065 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1066     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1067     warn <<_____ if scalar(@seed_sources) == 1;
1068
1069 ============================== WARNING ===============================
1070 You have selected the --with-rand-seed=none option, which effectively
1071 disables automatic reseeding of the OpenSSL random generator.
1072 All operations depending on the random generator such as creating keys
1073 will not work unless the random generator is seeded manually by the
1074 application.
1075
1076 Please read the 'Note on random number generation' section in the
1077 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1078 ============================== WARNING ===============================
1079
1080 _____
1081 }
1082 push @{$config{openssl_feature_defines}},
1083      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1084         @seed_sources;
1085
1086 # Backward compatibility?
1087 if ($target =~ m/^CygWin32(-.*)$/) {
1088     $target = "Cygwin".$1;
1089 }
1090
1091 # Support for legacy targets having a name starting with 'debug-'
1092 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1093 if ($d) {
1094     $config{build_type} = "debug";
1095
1096     # If we do not find debug-foo in the table, the target is set to foo.
1097     if (!$table{$target}) {
1098         $target = $t;
1099     }
1100 }
1101
1102 &usage if !$table{$target} || $table{$target}->{template};
1103
1104 $config{target} = $target;
1105 my %target = resolve_config($target);
1106
1107 foreach (keys %target_attr_translate) {
1108     $target{$target_attr_translate{$_}} = $target{$_}
1109         if $target{$_};
1110     delete $target{$_};
1111 }
1112
1113 %target = ( %{$table{DEFAULTS}}, %target );
1114
1115 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1116 $config{conf_files} = [ sort keys %conf_files ];
1117
1118 # Using sub disable within these loops may prove fragile, so we run
1119 # a cascade afterwards
1120 foreach my $feature (@{$target{disable}}) {
1121     if (exists $deprecated_disablables{$feature}) {
1122         warn "***** config $target disables deprecated feature $feature\n";
1123     } elsif (!grep { $feature eq $_ } @disablables) {
1124         die "***** config $target disables unknown feature $feature\n";
1125     }
1126     $disabled{$feature} = 'config';
1127 }
1128 foreach my $feature (@{$target{enable}}) {
1129     if ("default" eq ($disabled{$feature} // "")) {
1130         if (exists $deprecated_disablables{$feature}) {
1131             warn "***** config $target enables deprecated feature $feature\n";
1132         } elsif (!grep { $feature eq $_ } @disablables) {
1133             die "***** config $target enables unknown feature $feature\n";
1134         }
1135         delete $disabled{$feature};
1136     }
1137 }
1138
1139 # If uplink_arch isn't defined, disable uplink
1140 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1141 # If asm_arch isn't defined, disable asm
1142 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1143
1144 disable();                      # Run a cascade now
1145
1146 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1147 $target{cxxflags}//=$target{cflags} if $target{CXX};
1148 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1149 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1150
1151 # Fill %config with values from %user, and in case those are undefined or
1152 # empty, use values from %target (acting as a default).
1153 foreach (keys %user) {
1154     my $ref_type = ref $user{$_};
1155
1156     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1157     # and a value that's to be coerced into that type.
1158     my $mkvalue = sub {
1159         my $type = shift;
1160         my $value = shift;
1161         my $undef_p = shift;
1162
1163         die "Too many arguments for \$mkvalue" if @_;
1164
1165         while (ref $value eq 'CODE') {
1166             $value = $value->();
1167         }
1168
1169         if ($type eq 'ARRAY') {
1170             return undef unless defined $value;
1171             return undef if ref $value ne 'ARRAY' && !$value;
1172             return undef if ref $value eq 'ARRAY' && !@$value;
1173             return [ $value ] unless ref $value eq 'ARRAY';
1174         }
1175         return undef unless $value;
1176         return $value;
1177     };
1178
1179     $config{$_} =
1180         $mkvalue->($ref_type, $user{$_})
1181         || $mkvalue->($ref_type, $target{$_});
1182     delete $config{$_} unless defined $config{$_};
1183 }
1184
1185 # Finish up %config by appending things the user gave us on the command line
1186 # apart from "make variables"
1187 foreach (keys %useradd) {
1188     # The must all be lists, so we assert that here
1189     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1190         unless ref $useradd{$_} eq 'ARRAY';
1191
1192     if (defined $config{$_}) {
1193         push @{$config{$_}}, @{$useradd{$_}};
1194     } else {
1195         $config{$_} = [ @{$useradd{$_}} ];
1196     }
1197 }
1198 # At this point, we can forget everything about %user and %useradd,
1199 # because it's now all been merged into the corresponding $config entry
1200
1201 # Allow overriding the build file name
1202 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1203
1204 ######################################################################
1205 # Build up information for skipping certain directories depending on disabled
1206 # features, as well as setting up macros for disabled features.
1207
1208 # This is a tentative database of directories to skip.  Some entries may not
1209 # correspond to anything real, but that's ok, they will simply be ignored.
1210 # The actual processing of these entries is done in the build.info lookup
1211 # loop further down.
1212 #
1213 # The key is a Unix formated path in the source tree, the value is an index
1214 # into %disabled_info, so any existing path gets added to a corresponding
1215 # 'skipped' entry in there with the list of skipped directories.
1216 my %skipdir = ();
1217 my %disabled_info = ();         # For configdata.pm
1218 foreach my $what (sort keys %disabled) {
1219     # There are deprecated disablables that translate to themselves.
1220     # They cause disabling cascades, but should otherwise not regiter.
1221     next if $deprecated_disablables{$what};
1222
1223     $config{options} .= " no-$what";
1224
1225     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1226                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1227                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1228         (my $WHAT = uc $what) =~ s|-|_|g;
1229         my $skipdir = $what;
1230
1231         # fix-up crypto/directory name(s)
1232         $skipdir = "ripemd" if $what eq "rmd160";
1233         $skipdir = "whrlpool" if $what eq "whirlpool";
1234
1235         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1236         push @{$config{openssl_feature_defines}}, $macro;
1237
1238         $skipdir{engines} = $what if $what eq 'engine';
1239         $skipdir{"crypto/$skipdir"} = $what
1240             unless $what eq 'async' || $what eq 'err';
1241     }
1242 }
1243
1244 # Make sure build_scheme is consistent.
1245 $target{build_scheme} = [ $target{build_scheme} ]
1246     if ref($target{build_scheme}) ne "ARRAY";
1247
1248 my ($builder, $builder_platform, @builder_opts) =
1249     @{$target{build_scheme}};
1250
1251 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1252                       $builder_platform."-checker.pm")) {
1253     my $checker_path = catfile($srcdir, "Configurations", $checker);
1254     if (-f $checker_path) {
1255         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1256             ? sub { warn $@; } : sub { die $@; };
1257         if (! do $checker_path) {
1258             if ($@) {
1259                 $fn->($@);
1260             } elsif ($!) {
1261                 $fn->($!);
1262             } else {
1263                 $fn->("The detected tools didn't match the platform\n");
1264             }
1265         }
1266         last;
1267     }
1268 }
1269
1270 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1271
1272 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1273         {
1274         push @{$config{cflags}}, "-mno-cygwin";
1275         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1276         push @{$config{shared_ldflag}}, "-mno-cygwin";
1277         }
1278
1279 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1280         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1281         # minimally required architecture flags for assembly modules
1282         my $value;
1283         $value = '-mips2' if ($target =~ /mips32/);
1284         $value = '-mips3' if ($target =~ /mips64/);
1285         unshift @{$config{cflags}}, $value;
1286         unshift @{$config{cxxflags}}, $value if $config{CXX};
1287 }
1288
1289 # If threads aren't disabled, check how possible they are
1290 unless ($disabled{threads}) {
1291     if ($auto_threads) {
1292         # Enabled by default, disable it forcibly if unavailable
1293         if ($target{thread_scheme} eq "(unknown)") {
1294             disable("unavailable", 'threads');
1295         }
1296     } else {
1297         # The user chose to enable threads explicitly, let's see
1298         # if there's a chance that's possible
1299         if ($target{thread_scheme} eq "(unknown)") {
1300             # If the user asked for "threads" and we don't have internal
1301             # knowledge how to do it, [s]he is expected to provide any
1302             # system-dependent compiler options that are necessary.  We
1303             # can't truly check that the given options are correct, but
1304             # we expect the user to know what [s]He is doing.
1305             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1306                 die "You asked for multi-threading support, but didn't\n"
1307                     ,"provide any system-specific compiler options\n";
1308             }
1309         }
1310     }
1311 }
1312
1313 # Find out if clang's sanitizers have been enabled with -fsanitize
1314 # flags and ensure that the corresponding %disabled elements area
1315 # removed to reflect that the sanitizers are indeed enabled.
1316 my %detected_sanitizers = ();
1317 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1318     (my $checks = $_) =~ s/^-fsanitize=//;
1319     foreach (split /,/, $checks) {
1320         my $d = { address       => 'asan',
1321                   undefined     => 'ubsan',
1322                   memory        => 'msan' } -> {$_};
1323         next unless defined $d;
1324
1325         $detected_sanitizers{$d} = 1;
1326         if (defined $disabled{$d}) {
1327             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1328                 if $disabled{$d} ne "default";
1329             delete $disabled{$d};
1330         }
1331     }
1332 }
1333
1334 # If threads still aren't disabled, add a C macro to ensure the source
1335 # code knows about it.  Any other flag is taken care of by the configs.
1336 unless($disabled{threads}) {
1337     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1338 }
1339
1340 # With "deprecated" disable all deprecated features.
1341 if (defined($disabled{"deprecated"})) {
1342         $config{api} = $maxapi;
1343 }
1344
1345 my $no_shared_warn=0;
1346 if ($target{shared_target} eq "")
1347         {
1348         $no_shared_warn = 1
1349             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1350         disable('no-shared-target', 'pic');
1351         }
1352
1353 if ($disabled{"dynamic-engine"}) {
1354         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1355         $config{dynamic_engines} = 0;
1356 } else {
1357         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1358         $config{dynamic_engines} = 1;
1359 }
1360
1361 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1362     push @{$config{cflags}}, "-fsanitize=address";
1363 }
1364
1365 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1366     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1367     # platforms.
1368     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1369 }
1370
1371 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1372   push @{$config{cflags}}, "-fsanitize=memory";
1373 }
1374
1375 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1376         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1377     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1378     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1379 }
1380 #
1381 # Platform fix-ups
1382 #
1383
1384 # This saves the build files from having to check
1385 if ($disabled{pic})
1386         {
1387         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1388                     shared_defines shared_includes shared_ldflag
1389                     module_cflags module_cxxflags module_cppflags
1390                     module_defines module_includes module_lflags))
1391                 {
1392                 delete $config{$_};
1393                 $target{$_} = "";
1394                 }
1395         }
1396 else
1397         {
1398         push @{$config{lib_defines}}, "OPENSSL_PIC";
1399         }
1400
1401 if ($target{sys_id} ne "")
1402         {
1403         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1404         }
1405
1406 unless ($disabled{asm}) {
1407     if ($target{keccak1600_asm_src} ne $table{DEFAULTS}->{keccak1600_asm_src}) {
1408         push @{$config{lib_defines}}, "KECCAK1600_ASM";
1409     }
1410     if ($target{wp_asm_src} =~ /mmx/) {
1411         if ($config{processor} eq "386") {
1412             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1413         } elsif (!$disabled{"whirlpool"}) {
1414             push @{$config{lib_defines}}, "WHIRLPOOL_ASM";
1415         }
1416     }
1417     if ($target{modes_asm_src} =~ /ghash-/) {
1418         push @{$config{lib_defines}}, "GHASH_ASM";
1419     }
1420     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1421         push @{$config{dso_defines}}, "PADLOCK_ASM";
1422     }
1423     if ($target{poly1305_asm_src} ne "") {
1424         push @{$config{lib_defines}}, "POLY1305_ASM";
1425     }
1426 }
1427
1428 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1429 my %predefined_CXX = $config{CXX}
1430     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1431     : ();
1432
1433 # Check for makedepend capabilities.
1434 if (!$disabled{makedepend}) {
1435     if ($config{target} =~ /^(VC|vms)-/) {
1436         # For VC- and vms- targets, there's nothing more to do here.  The
1437         # functionality is hard coded in the corresponding build files for
1438         # cl (Windows) and CC/DECC (VMS).
1439     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1440              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1441         # We know that GNU C version 3 and up as well as all clang
1442         # versions support dependency generation, but Xcode did not
1443         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1444         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1445     } else {
1446         # In all other cases, we look for 'makedepend', and disable the
1447         # capability if not found.
1448         $config{makedepprog} = which('makedepend');
1449         disable('unavailable', 'makedepend') unless $config{makedepprog};
1450     }
1451 }
1452
1453 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1454     # probe for -Wa,--noexecstack option...
1455     if ($predefined_C{__clang__}) {
1456         # clang has builtin assembler, which doesn't recognize --help,
1457         # but it apparently recognizes the option in question on all
1458         # supported platforms even when it's meaningless. In other words
1459         # probe would fail, but probed option always accepted...
1460         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1461     } else {
1462         my $cc = $config{CROSS_COMPILE}.$config{CC};
1463         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1464         while(<PIPE>) {
1465             if (m/--noexecstack/) {
1466                 push @{$config{cflags}}, "-Wa,--noexecstack";
1467                 last;
1468             }
1469         }
1470         close(PIPE);
1471         unlink("null.$$.o");
1472     }
1473 }
1474
1475 # Deal with bn_ops ###################################################
1476
1477 $config{bn_ll}                  =0;
1478 $config{export_var_as_fn}       =0;
1479 my $def_int="unsigned int";
1480 $config{rc4_int}                =$def_int;
1481 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1482
1483 my $count = 0;
1484 foreach (sort split(/\s+/,$target{bn_ops})) {
1485     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1486     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1487     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1488     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1489     ($config{b64l},$config{b64},$config{b32})
1490         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1491     ($config{b64l},$config{b64},$config{b32})
1492         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1493     ($config{b64l},$config{b64},$config{b32})
1494         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1495 }
1496 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1497     if $count > 1;
1498
1499
1500 # Hack cflags for better warnings (dev option) #######################
1501
1502 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1503 # a string and works as well on command lines.
1504 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1505                         @{$config{cflags}} ];
1506 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1507                           @{$config{cxxflags}} ] if $config{CXX};
1508
1509 $config{openssl_api_defines} = [
1510     "OPENSSL_MIN_API=".($apitable->{$config{api} // ""} // -1)
1511 ];
1512
1513 my @strict_warnings_collection=();
1514 if ($strict_warnings)
1515         {
1516         my $wopt;
1517         my $gccver = $predefined_C{__GNUC__} // -1;
1518
1519         warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike"
1520             unless $gccver >= 4;
1521         push @strict_warnings_collection, @gcc_devteam_warn;
1522         push @strict_warnings_collection, @clang_devteam_warn
1523             if (defined($predefined_C{__clang__}));
1524         }
1525
1526 if (grep { $_ eq '-static' } @{$config{LDFLAGS}}) {
1527     disable('static', 'pic', 'threads');
1528 }
1529
1530 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1531                               ? @strict_warnings_collection
1532                               : ( $_ ) }
1533                     @{$config{CFLAGS}} ];
1534
1535 unless ($disabled{"crypto-mdebug-backtrace"})
1536         {
1537         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1538                 {
1539                 push @{$config{cflags}}, $wopt
1540                         unless grep { $_ eq $wopt } @{$config{cflags}};
1541                 }
1542         if ($target =~ /^BSD-/)
1543                 {
1544                 push @{$config{ex_libs}}, "-lexecinfo";
1545                 }
1546         }
1547
1548 unless ($disabled{afalgeng}) {
1549     $config{afalgeng}="";
1550     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1551         my $minver = 4*10000 + 1*100 + 0;
1552         if ($config{CROSS_COMPILE} eq "") {
1553             my $verstr = `uname -r`;
1554             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1555             ($mi2) = $mi2 =~ /(\d+)/;
1556             my $ver = $ma*10000 + $mi1*100 + $mi2;
1557             if ($ver < $minver) {
1558                 disable('too-old-kernel', 'afalgeng');
1559             } else {
1560                 push @{$config{engdirs}}, "afalg";
1561             }
1562         } else {
1563             disable('cross-compiling', 'afalgeng');
1564         }
1565     } else {
1566         disable('not-linux', 'afalgeng');
1567     }
1568 }
1569
1570 push @{$config{openssl_feature_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1571
1572 unless ($disabled{ktls}) {
1573     $config{ktls}="";
1574     if ($target =~ m/^linux/) {
1575         my $usr = "/usr/$config{cross_compile_prefix}";
1576         chop($usr);
1577         if ($config{cross_compile_prefix} eq "") {
1578             $usr = "/usr";
1579         }
1580         my $minver = (4 << 16) + (13 << 8) + 0;
1581         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1582
1583         if ($verstr[2] < $minver) {
1584             disable('too-old-kernel', 'ktls');
1585         }
1586     } else {
1587         disable('not-linux', 'ktls');
1588     }
1589 }
1590
1591 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1592
1593 # Get the extra flags used when building shared libraries and modules.  We
1594 # do this late because some of them depend on %disabled.
1595
1596 # Make the flags to build DSOs the same as for shared libraries unless they
1597 # are already defined
1598 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1599 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1600 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1601 {
1602     my $shared_info_pl =
1603         catfile(dirname($0), "Configurations", "shared-info.pl");
1604     my %shared_info = read_eval_file($shared_info_pl);
1605     push @{$target{_conf_fname_int}}, $shared_info_pl;
1606     my $si = $target{shared_target};
1607     while (ref $si ne "HASH") {
1608         last if ! defined $si;
1609         if (ref $si eq "CODE") {
1610             $si = $si->();
1611         } else {
1612             $si = $shared_info{$si};
1613         }
1614     }
1615
1616     # Some of the 'shared_target' values don't have any entries in
1617     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1618     # template knows how to handle this.  That is currently the case for
1619     # Windows and VMS.
1620     if (defined $si) {
1621         # Just as above, copy certain shared_* attributes to the corresponding
1622         # module_ attribute unless the latter is already defined
1623         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1624         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1625         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1626         foreach (sort keys %$si) {
1627             $target{$_} = defined $target{$_}
1628                 ? add($si->{$_})->($target{$_})
1629                 : $si->{$_};
1630         }
1631     }
1632 }
1633
1634 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1635
1636 # If we use the unified build, collect information from build.info files
1637 my %unified_info = ();
1638
1639 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1640 if ($builder eq "unified") {
1641     use with_fallback qw(Text::Template);
1642
1643     sub cleandir {
1644         my $base = shift;
1645         my $dir = shift;
1646         my $relativeto = shift || ".";
1647
1648         $dir = catdir($base,$dir) unless isabsolute($dir);
1649
1650         # Make sure the directories we're building in exists
1651         mkpath($dir);
1652
1653         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1654         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1655         return $res;
1656     }
1657
1658     sub cleanfile {
1659         my $base = shift;
1660         my $file = shift;
1661         my $relativeto = shift || ".";
1662
1663         $file = catfile($base,$file) unless isabsolute($file);
1664
1665         my $d = dirname($file);
1666         my $f = basename($file);
1667
1668         # Make sure the directories we're building in exists
1669         mkpath($d);
1670
1671         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1672         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1673         return $res;
1674     }
1675
1676     # Store the name of the template file we will build the build file from
1677     # in %config.  This may be useful for the build file itself.
1678     my @build_file_template_names =
1679         ( $builder_platform."-".$target{build_file}.".tmpl",
1680           $target{build_file}.".tmpl" );
1681     my @build_file_templates = ();
1682
1683     # First, look in the user provided directory, if given
1684     if (defined env($local_config_envname)) {
1685         @build_file_templates =
1686             map {
1687                 if ($^O eq 'VMS') {
1688                     # VMS environment variables are logical names,
1689                     # which can be used as is
1690                     $local_config_envname . ':' . $_;
1691                 } else {
1692                     catfile(env($local_config_envname), $_);
1693                 }
1694             }
1695             @build_file_template_names;
1696     }
1697     # Then, look in our standard directory
1698     push @build_file_templates,
1699         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1700           @build_file_template_names );
1701
1702     my $build_file_template;
1703     for $_ (@build_file_templates) {
1704         $build_file_template = $_;
1705         last if -f $build_file_template;
1706
1707         $build_file_template = undef;
1708     }
1709     if (!defined $build_file_template) {
1710         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1711     }
1712     $config{build_file_templates}
1713       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1714                     $blddir),
1715           $build_file_template,
1716           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1717                     $blddir) ];
1718
1719     my @build_dirs = ( [ ] );   # current directory
1720
1721     $config{build_infos} = [ ];
1722
1723     my %ordinals = ();
1724     while (@build_dirs) {
1725         my @curd = @{shift @build_dirs};
1726         my $sourced = catdir($srcdir, @curd);
1727         my $buildd = catdir($blddir, @curd);
1728
1729         my $unixdir = join('/', @curd);
1730         if (exists $skipdir{$unixdir}) {
1731             my $what = $skipdir{$unixdir};
1732             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1733             next;
1734         }
1735
1736         mkpath($buildd);
1737
1738         my $f = 'build.info';
1739         # The basic things we're trying to build
1740         my @programs = ();
1741         my @libraries = ();
1742         my @modules = ();
1743         my @scripts = ();
1744
1745         my %attributes = ();
1746         my %sources = ();
1747         my %shared_sources = ();
1748         my %includes = ();
1749         my %defines = ();
1750         my %depends = ();
1751         my %generate = ();
1752
1753         # Support for $variablename in build.info files.
1754         # Embedded perl code is the ultimate master, still.  If its output
1755         # contains a dollar sign, it had better be escaped, or it will be
1756         # taken for a variable name prefix.
1757         my %variables = ();
1758         my $variable_re = qr/\$([[:alpha:]][[:alnum:]_]*)/;
1759         my $expand_variables = sub {
1760             my $value = '';
1761             my $value_rest = shift;
1762
1763             while ($value_rest =~ /(?<!\\)${variable_re}/) {
1764                 $value .= $`;
1765                 $value .= $variables{$1};
1766                 $value_rest = $';
1767             }
1768             return $value . $value_rest;
1769         };
1770
1771         # We want to detect configdata.pm in the source tree, so we
1772         # don't use it if the build tree is different.
1773         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1774
1775         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1776         my $template =
1777             Text::Template->new(TYPE => 'FILE',
1778                                 SOURCE => catfile($sourced, $f),
1779                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1780         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1781         my @text =
1782             split /^/m,
1783             $template->fill_in(HASH => { config => \%config,
1784                                          target => \%target,
1785                                          disabled => \%disabled,
1786                                          withargs => \%withargs,
1787                                          builddir => abs2rel($buildd, $blddir),
1788                                          sourcedir => abs2rel($sourced, $blddir),
1789                                          buildtop => abs2rel($blddir, $blddir),
1790                                          sourcetop => abs2rel($srcdir, $blddir) },
1791                                DELIMITERS => [ "{-", "-}" ]);
1792
1793         # The top item of this stack has the following values
1794         # -2 positive already run and we found ELSE (following ELSIF should fail)
1795         # -1 positive already run (skip until ENDIF)
1796         # 0 negatives so far (if we're at a condition, check it)
1797         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1798         # 2 positive ELSE (following ELSIF should fail)
1799         my @skip = ();
1800         collect_information(
1801             collect_from_array([ @text ],
1802                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1803                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1804             # Info we're looking for
1805             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1806             => sub {
1807                 if (! @skip || $skip[$#skip] > 0) {
1808                     push @skip, !! $expand_variables->($1);
1809                 } else {
1810                     push @skip, -1;
1811                 }
1812             },
1813             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1814             => sub { die "ELSIF out of scope" if ! @skip;
1815                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1816                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1817                      $skip[$#skip] = !! $expand_variables->($1)
1818                          if $skip[$#skip] == 0; },
1819             qr/^\s*ELSE\s*$/
1820             => sub { die "ELSE out of scope" if ! @skip;
1821                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1822                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1823             qr/^\s*ENDIF\s*$/
1824             => sub { die "ENDIF out of scope" if ! @skip;
1825                      pop @skip; },
1826             qr/^\s*${variable_re}\s*=\s*(.*?)\s*$/
1827             => sub {
1828                 if (!@skip || $skip[$#skip] > 0) {
1829                     my $n = $1;
1830                     my $v = $2;
1831                     $variables{$n} = $expand_variables->($v);
1832                 }
1833             },
1834             qr/^\s*SUBDIRS\s*=\s*(.*)\s*$/
1835             => sub {
1836                 if (!@skip || $skip[$#skip] > 0) {
1837                     foreach (tokenize($expand_variables->($1))) {
1838                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1839                     }
1840                 }
1841             },
1842             qr/^\s*PROGRAMS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1843             => sub {
1844                 if (!@skip || $skip[$#skip] > 0) {
1845                     my @a = tokenize($1, qr|\s*,\s*|);
1846                     my @p = tokenize($expand_variables->($2));
1847                     push @programs, @p;
1848                     foreach my $a (@a) {
1849                         my $ak = $a;
1850                         my $av = 1;
1851                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1852                             $ak = $1;
1853                             $av = $2;
1854                         }
1855                         foreach my $p (@p) {
1856                             $attributes{$p}->{$ak} = $av;
1857                         }
1858                     }
1859                 }
1860             },
1861             qr/^\s*LIBS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1862             => sub {
1863                 if (!@skip || $skip[$#skip] > 0) {
1864                     my @a = tokenize($1, qr|\s*,\s*|);
1865                     my @l = tokenize($expand_variables->($2));
1866                     push @libraries, @l;
1867                     foreach my $a (@a) {
1868                         my $ak = $a;
1869                         my $av = 1;
1870                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1871                             $ak = $1;
1872                             $av = $2;
1873                         }
1874                         foreach my $l (@l) {
1875                             $attributes{$l}->{$ak} = $av;
1876                         }
1877                     }
1878                 }
1879             },
1880             qr/^\s*MODULES(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1881             => sub {
1882                 if (!@skip || $skip[$#skip] > 0) {
1883                     my @a = tokenize($1, qr|\s*,\s*|);
1884                     my @m = tokenize($expand_variables->($2));
1885                     push @modules, @m;
1886                     foreach my $a (@a) {
1887                         my $ak = $a;
1888                         my $av = 1;
1889                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1890                             $ak = $1;
1891                             $av = $2;
1892                         }
1893                         foreach my $m (@m) {
1894                             $attributes{$m}->{$ak} = $av;
1895                         }
1896                     }
1897                 }
1898             },
1899             qr/^\s*SCRIPTS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1900             => sub {
1901                 if (!@skip || $skip[$#skip] > 0) {
1902                     my @a = tokenize($1, qr|\s*,\s*|);
1903                     my @s = tokenize($expand_variables->($2));
1904                     push @scripts, @s;
1905                     foreach my $a (@a) {
1906                         my $ak = $a;
1907                         my $av = 1;
1908                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1909                             $ak = $1;
1910                             $av = $2;
1911                         }
1912                         foreach my $s (@s) {
1913                             $attributes{$s}->{$ak} = $av;
1914                         }
1915                     }
1916                 }
1917             },
1918
1919             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1920             => sub { push @{$ordinals{$1}}, tokenize($expand_variables->($2))
1921                          if !@skip || $skip[$#skip] > 0 },
1922             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1923             => sub { push @{$sources{$1}}, tokenize($expand_variables->($2))
1924                          if !@skip || $skip[$#skip] > 0 },
1925             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1926             => sub { push @{$shared_sources{$1}},
1927                          tokenize($expand_variables->($2))
1928                          if !@skip || $skip[$#skip] > 0 },
1929             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1930             => sub { push @{$includes{$1}}, tokenize($expand_variables->($2))
1931                          if !@skip || $skip[$#skip] > 0 },
1932             qr/^\s*DEFINE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1933             => sub { push @{$defines{$1}}, tokenize($expand_variables->($2))
1934                          if !@skip || $skip[$#skip] > 0 },
1935             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1936             => sub { push @{$depends{$1}}, tokenize($expand_variables->($2))
1937                          if !@skip || $skip[$#skip] > 0 },
1938             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1939             => sub { push @{$generate{$1}}, $2
1940                          if !@skip || $skip[$#skip] > 0 },
1941             qr/^\s*(?:#.*)?$/ => sub { },
1942             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1943             "BEFORE" => sub {
1944                 if ($buildinfo_debug) {
1945                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1946                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1947                 }
1948             },
1949             "AFTER" => sub {
1950                 if ($buildinfo_debug) {
1951                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1952                 }
1953             },
1954             );
1955         die "runaway IF?" if (@skip);
1956
1957         if (grep { defined $attributes{$_}->{engine} } keys %attributes
1958                 and !$config{dynamic_engines}) {
1959             die <<"EOF"
1960 ENGINES can only be used if configured with 'dynamic-engine'.
1961 This is usually a fault in a build.info file.
1962 EOF
1963         }
1964
1965         foreach (keys %attributes) {
1966             my $dest = $_;
1967             my $ddest = cleanfile($buildd, $_, $blddir);
1968             foreach (keys %{$attributes{$dest} // {}}) {
1969                 $unified_info{attributes}->{$ddest}->{$_} =
1970                     $attributes{$dest}->{$_};
1971             }
1972         }
1973
1974         {
1975             my %infos = ( programs  => [ @programs  ],
1976                           libraries => [ @libraries ],
1977                           modules   => [ @modules   ],
1978                           scripts   => [ @scripts   ] );
1979             foreach my $k (keys %infos) {
1980                 foreach (@{$infos{$k}}) {
1981                     my $item = cleanfile($buildd, $_, $blddir);
1982                     $unified_info{$k}->{$item} = 1;
1983                 }
1984             }
1985         }
1986
1987         # Check that we haven't defined any library as both shared and
1988         # explicitly static.  That is forbidden.
1989         my @doubles = ();
1990         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
1991             (my $l = $_) =~ s/\.a$//;
1992             push @doubles, $l if defined $unified_info{libraries}->{$l};
1993         }
1994         die "these libraries are both explicitly static and shared:\n  ",
1995             join(" ", @doubles), "\n"
1996             if @doubles;
1997
1998         foreach (keys %sources) {
1999             my $dest = $_;
2000             my $ddest = cleanfile($buildd, $_, $blddir);
2001             foreach (@{$sources{$dest}}) {
2002                 my $s = cleanfile($sourced, $_, $blddir);
2003
2004                 # If it isn't in the source tree, we assume it's generated
2005                 # in the build tree
2006                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2007                     $s = cleanfile($buildd, $_, $blddir);
2008                 }
2009                 # We recognise C++, C and asm files
2010                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2011                     my $o = $_;
2012                     $o =~ s/\.[csS]$/.o/; # C and assembler
2013                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2014                     $o = cleanfile($buildd, $o, $blddir);
2015                     $unified_info{sources}->{$ddest}->{$o} = -1;
2016                     $unified_info{sources}->{$o}->{$s} = -1;
2017                 } elsif ($s =~ /\.rc$/) {
2018                     # We also recognise resource files
2019                     my $o = $_;
2020                     $o =~ s/\.rc$/.res/; # Resource configuration
2021                     my $o = cleanfile($buildd, $o, $blddir);
2022                     $unified_info{sources}->{$ddest}->{$o} = -1;
2023                     $unified_info{sources}->{$o}->{$s} = -1;
2024                 } else {
2025                     $unified_info{sources}->{$ddest}->{$s} = 1;
2026                 }
2027             }
2028         }
2029
2030         foreach (keys %shared_sources) {
2031             my $dest = $_;
2032             my $ddest = cleanfile($buildd, $_, $blddir);
2033             foreach (@{$shared_sources{$dest}}) {
2034                 my $s = cleanfile($sourced, $_, $blddir);
2035
2036                 # If it isn't in the source tree, we assume it's generated
2037                 # in the build tree
2038                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2039                     $s = cleanfile($buildd, $_, $blddir);
2040                 }
2041
2042                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2043                     # We recognise C++, C and asm files
2044                     my $o = $_;
2045                     $o =~ s/\.[csS]$/.o/; # C and assembler
2046                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2047                     $o = cleanfile($buildd, $o, $blddir);
2048                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2049                     $unified_info{sources}->{$o}->{$s} = -1;
2050                 } elsif ($s =~ /\.rc$/) {
2051                     # We also recognise resource files
2052                     my $o = $_;
2053                     $o =~ s/\.rc$/.res/; # Resource configuration
2054                     my $o = cleanfile($buildd, $o, $blddir);
2055                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2056                     $unified_info{sources}->{$o}->{$s} = -1;
2057                 } elsif ($s =~ /\.ld$/) {
2058                     # We also recognise linker scripts (or corresponding)
2059                     # We know they are generated files
2060                     my $ld = cleanfile($buildd, $_, $blddir);
2061                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2062                 } else {
2063                     die "unrecognised source file type for shared library: $s\n";
2064                 }
2065             }
2066         }
2067
2068         foreach (keys %generate) {
2069             my $dest = $_;
2070             my $ddest = cleanfile($buildd, $_, $blddir);
2071             die "more than one generator for $dest: "
2072                     ,join(" ", @{$generate{$_}}),"\n"
2073                     if scalar @{$generate{$_}} > 1;
2074             my @generator = split /\s+/, $generate{$dest}->[0];
2075             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2076             $unified_info{generate}->{$ddest} = [ @generator ];
2077         }
2078
2079         foreach (keys %depends) {
2080             my $dest = $_;
2081             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2082
2083             # If the destination doesn't exist in source, it can only be
2084             # a generated file in the build tree.
2085             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2086                 $ddest = cleanfile($buildd, $_, $blddir);
2087             }
2088             foreach (@{$depends{$dest}}) {
2089                 my $d = cleanfile($sourced, $_, $blddir);
2090
2091                 # If we know it's generated, or assume it is because we can't
2092                 # find it in the source tree, we set file we depend on to be
2093                 # in the build tree rather than the source tree, and assume
2094                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2095                 # section or in the Makefile template.
2096                 if ($d eq $src_configdata
2097                     || ! -f $d
2098                     || (grep { $d eq $_ }
2099                         map { cleanfile($srcdir, $_, $blddir) }
2100                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2101                     $d = cleanfile($buildd, $_, $blddir);
2102                 }
2103                 # Take note if the file to depend on is being renamed
2104                 # Take extra care with files ending with .a, they should
2105                 # be treated without that extension, and the extension
2106                 # should be added back after treatment.
2107                 $d =~ /(\.a)?$/;
2108                 my $e = $1 // "";
2109                 $d = $`.$e;
2110                 $unified_info{depends}->{$ddest}->{$d} = 1;
2111             }
2112         }
2113
2114         foreach (keys %includes) {
2115             my $dest = $_;
2116             my $ddest = cleanfile($sourced, $_, $blddir);
2117
2118             # If the destination doesn't exist in source, it can only be
2119             # a generated file in the build tree.
2120             if ($ddest eq $src_configdata || ! -f $ddest) {
2121                 $ddest = cleanfile($buildd, $_, $blddir);
2122             }
2123             foreach (@{$includes{$dest}}) {
2124                 my $is = cleandir($sourced, $_, $blddir);
2125                 my $ib = cleandir($buildd, $_, $blddir);
2126                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2127                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2128                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2129                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2130             }
2131         }
2132
2133         foreach (keys %defines) {
2134             my $dest = $_;
2135             my $ddest = cleanfile($sourced, $_, $blddir);
2136
2137             # If the destination doesn't exist in source, it can only be
2138             # a generated file in the build tree.
2139             if (! -f $ddest) {
2140                 $ddest = cleanfile($buildd, $_, $blddir);
2141                 if ($unified_info{rename}->{$ddest}) {
2142                     $ddest = $unified_info{rename}->{$ddest};
2143                 }
2144             }
2145             foreach (@{$defines{$dest}}) {
2146                 m|^([^=]*)(=.*)?$|;
2147                 die "0 length macro name not permitted\n" if $1 eq "";
2148                 die "$1 defined more than once\n"
2149                     if defined $unified_info{defines}->{$ddest}->{$1};
2150                 $unified_info{defines}->{$ddest}->{$1} = $2;
2151             }
2152         }
2153     }
2154
2155     my $ordinals_text = join(', ', sort keys %ordinals);
2156     warn <<"EOF" if $ordinals_text;
2157
2158 WARNING: ORDINALS were specified for $ordinals_text
2159 They are ignored and should be replaced with a combination of GENERATE,
2160 DEPEND and SHARED_SOURCE.
2161 EOF
2162
2163
2164     # Go through the sources of all libraries and check that the same basename
2165     # doesn't appear more than once.  Some static library archivers depend on
2166     # them being unique.
2167     {
2168         my $err = 0;
2169         foreach my $prod (keys %{$unified_info{libraries}}) {
2170             my @prod_sources =
2171                 map { keys %{$unified_info{sources}->{$_}} }
2172                 keys %{$unified_info{sources}->{$prod}};
2173             my %srccnt = ();
2174
2175             # Count how many times a given each source basename
2176             # appears for each product.
2177             foreach my $src (@prod_sources) {
2178                 $srccnt{basename $src}++;
2179             }
2180
2181             foreach my $src (keys %srccnt) {
2182                 if ((my $cnt = $srccnt{$src}) > 1) {
2183                     print STDERR "$src appears $cnt times for the product $prod\n";
2184                     $err++
2185                 }
2186             }
2187         }
2188         die if $err > 0;
2189     }
2190
2191     # Massage the result
2192
2193     # If we depend on a header file or a perl module, add an inclusion of
2194     # its directory to allow smoothe inclusion
2195     foreach my $dest (keys %{$unified_info{depends}}) {
2196         next if $dest eq "";
2197         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2198             next unless $d =~ /\.(h|pm)$/;
2199             my $i = dirname($d);
2200             my $spot =
2201                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2202                 ? 'build' : 'source';
2203             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2204                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2205         }
2206     }
2207
2208     # Go through all intermediary files and change their names to something that
2209     # reflects what they will be built for.  Note that for some source files,
2210     # this leads to duplicate object files because they are used multiple times.
2211     # the goal is to rename all object files according to this scheme:
2212     #    {productname}-{midfix}-{origobjname}.[o|res]
2213     # the {midfix} is a keyword indicating the type of product, which is mostly
2214     # valuable for libraries since they come in two forms.
2215     #
2216     # This also reorganises the {sources} and {shared_sources} so that the
2217     # former only contains ALL object files that are supposed to end up in
2218     # static libraries and programs, while the latter contains ALL object files
2219     # that are supposed to end up in shared libraries and DSOs.
2220     # The main reason for having two different source structures is to allow
2221     # the same name to be used for the static and the shared variants of a
2222     # library.
2223     {
2224         # Take copies so we don't get interference from added stuff
2225         my %unified_copy = ();
2226         foreach (('sources', 'shared_sources')) {
2227             $unified_copy{$_} = { %{$unified_info{$_}} }
2228                 if defined($unified_info{$_});
2229             delete $unified_info{$_};
2230         }
2231         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2232             # $intent serves multi purposes:
2233             # - give a prefix for the new object files names
2234             # - in the case of libraries, rearrange the object files so static
2235             #   libraries use the 'sources' structure exclusively, while shared
2236             #   libraries use the 'shared_sources' structure exclusively.
2237             my $intent = {
2238                 programs  => { bin    => { src => [ 'sources' ],
2239                                            dst => 'sources' } },
2240                 libraries => { lib    => { src => [ 'sources' ],
2241                                            dst => 'sources' },
2242                                shlib  => { prodselect =>
2243                                                sub { grep !/\.a$/, @_ },
2244                                            src => [ 'sources',
2245                                                     'shared_sources' ],
2246                                            dst => 'shared_sources' } },
2247                 modules   => { dso    => { src => [ 'sources' ],
2248                                            dst => 'sources' } },
2249                 scripts   => { script => { src => [ 'sources' ],
2250                                            dst => 'sources' } }
2251                } -> {$prodtype};
2252             foreach my $kind (keys %$intent) {
2253                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2254                              && $disabled{shared});
2255
2256                 my @src = @{$intent->{$kind}->{src}};
2257                 my $dst = $intent->{$kind}->{dst};
2258                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2259                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2260                     # %prod_sources has all applicable objects as keys, and
2261                     # their corresponding sources as values
2262                     my %prod_sources =
2263                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2264                         map { keys %{$unified_copy{$_}->{$prod}} }
2265                         @src;
2266                     foreach (keys %prod_sources) {
2267                         # Only affect object files and resource files,
2268                         # the others simply get a new value
2269                         # (+1 instead of -1)
2270                         if ($_ =~ /\.(o|res)$/) {
2271                             (my $prodname = $prod) =~ s|\.a$||;
2272                             my $newobj =
2273                                 catfile(dirname($_),
2274                                         basename($prodname)
2275                                             . '-' . $kind
2276                                             . '-' . basename($_));
2277                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2278                             foreach my $src (@{$prod_sources{$_}}) {
2279                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2280                             }
2281                             # Adjust dependencies
2282                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2283                                 $unified_info{depends}->{$_}->{$deps} = -1;
2284                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2285                             }
2286                             # Adjust includes
2287                             foreach my $k (('source', 'build')) {
2288                                 next unless
2289                                     defined($unified_info{includes}->{$_}->{$k});
2290                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2291                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2292                             }
2293                         } else {
2294                             $unified_info{$dst}->{$prod}->{$_} = 1;
2295                         }
2296                     }
2297                 }
2298             }
2299         }
2300     }
2301
2302     # At this point, we have a number of sources with the value -1.  They
2303     # aren't part of the local build and are probably meant for a different
2304     # platform, and can therefore be cleaned away.  That happens when making
2305     # %unified_info more efficient below.
2306
2307     ### Make unified_info a bit more efficient
2308     # One level structures
2309     foreach (("programs", "libraries", "modules", "scripts")) {
2310         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2311     }
2312     # Two level structures
2313     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends")) {
2314         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2315             my @items =
2316                 sort
2317                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2318                 keys %{$unified_info{$l1}->{$l2}};
2319             if (@items) {
2320                 $unified_info{$l1}->{$l2} = [ @items ];
2321             } else {
2322                 delete $unified_info{$l1}->{$l2};
2323             }
2324         }
2325     }
2326     # Defines
2327     foreach my $dest (sort keys %{$unified_info{defines}}) {
2328         $unified_info{defines}->{$dest}
2329             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2330                 sort keys %{$unified_info{defines}->{$dest}} ];
2331     }
2332     # Includes
2333     foreach my $dest (sort keys %{$unified_info{includes}}) {
2334         if (defined($unified_info{includes}->{$dest}->{build})) {
2335             my @source_includes = ();
2336             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2337                 if defined($unified_info{includes}->{$dest}->{source});
2338             $unified_info{includes}->{$dest} =
2339                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2340             foreach my $inc (@source_includes) {
2341                 push @{$unified_info{includes}->{$dest}}, $inc
2342                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2343             }
2344         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2345             $unified_info{includes}->{$dest} =
2346                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2347         } else {
2348             delete $unified_info{includes}->{$dest};
2349         }
2350     }
2351
2352     # For convenience collect information regarding directories where
2353     # files are generated, those generated files and the end product
2354     # they end up in where applicable.  Then, add build rules for those
2355     # directories
2356     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2357                      "dso" => [ @{$unified_info{modules}} ],
2358                      "bin" => [ @{$unified_info{programs}} ],
2359                      "script" => [ @{$unified_info{scripts}} ] );
2360     foreach my $type (keys %loopinfo) {
2361         foreach my $product (@{$loopinfo{$type}}) {
2362             my %dirs = ();
2363             my $pd = dirname($product);
2364
2365             foreach (@{$unified_info{sources}->{$product} // []},
2366                      @{$unified_info{shared_sources}->{$product} // []}) {
2367                 my $d = dirname($_);
2368
2369                 # We don't want to create targets for source directories
2370                 # when building out of source
2371                 next if ($config{sourcedir} ne $config{builddir}
2372                              && $d =~ m|^\Q$config{sourcedir}\E|);
2373                 # We already have a "test" target, and the current directory
2374                 # is just silly to make a target for
2375                 next if $d eq "test" || $d eq ".";
2376
2377                 $dirs{$d} = 1;
2378                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2379                     if $d ne $pd;
2380             }
2381             foreach (keys %dirs) {
2382                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2383                     $product;
2384             }
2385         }
2386     }
2387 }
2388
2389 # For the schemes that need it, we provide the old *_obj configs
2390 # from the *_asm_obj ones
2391 foreach (grep /_(asm|aux)_src$/, keys %target) {
2392     my $src = $_;
2393     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2394     $target{$obj} = $target{$src};
2395     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2396     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2397 }
2398
2399 # Write down our configuration where it fits #########################
2400
2401 print "Creating configdata.pm\n";
2402 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2403 print OUT <<"EOF";
2404 #! $config{HASHBANGPERL}
2405
2406 package configdata;
2407
2408 use strict;
2409 use warnings;
2410
2411 use Exporter;
2412 #use vars qw(\@ISA \@EXPORT);
2413 our \@ISA = qw(Exporter);
2414 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables \@disablables_int);
2415
2416 EOF
2417 print OUT "our %config = (\n";
2418 foreach (sort keys %config) {
2419     if (ref($config{$_}) eq "ARRAY") {
2420         print OUT "  ", $_, " => [ ", join(", ",
2421                                            map { quotify("perl", $_) }
2422                                            @{$config{$_}}), " ],\n";
2423     } elsif (ref($config{$_}) eq "HASH") {
2424         print OUT "  ", $_, " => {";
2425         if (scalar keys %{$config{$_}} > 0) {
2426             print OUT "\n";
2427             foreach my $key (sort keys %{$config{$_}}) {
2428                 print OUT "      ",
2429                     join(" => ",
2430                          quotify("perl", $key),
2431                          defined $config{$_}->{$key}
2432                              ? quotify("perl", $config{$_}->{$key})
2433                              : "undef");
2434                 print OUT ",\n";
2435             }
2436             print OUT "  ";
2437         }
2438         print OUT "},\n";
2439     } else {
2440         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2441     }
2442 }
2443 print OUT <<"EOF";
2444 );
2445
2446 EOF
2447 print OUT "our %target = (\n";
2448 foreach (sort keys %target) {
2449     if (ref($target{$_}) eq "ARRAY") {
2450         print OUT "  ", $_, " => [ ", join(", ",
2451                                            map { quotify("perl", $_) }
2452                                            @{$target{$_}}), " ],\n";
2453     } else {
2454         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2455     }
2456 }
2457 print OUT <<"EOF";
2458 );
2459
2460 EOF
2461 print OUT "our \%available_protocols = (\n";
2462 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2463 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2464 print OUT <<"EOF";
2465 );
2466
2467 EOF
2468 print OUT "our \@disablables = (\n";
2469 foreach (@disablables) {
2470     print OUT "  ", quotify("perl", $_), ",\n";
2471 }
2472 print OUT <<"EOF";
2473 );
2474
2475 EOF
2476 print OUT "# The following come from Configure's @disablables_int\n";
2477 print OUT "our \@disablables_int = (\n";
2478 foreach (@disablables_int) {
2479     print OUT "  ", quotify("perl", $_), ",\n";
2480 }
2481 print OUT <<"EOF";
2482 );
2483
2484 EOF
2485 print OUT "our \%disabled = (\n";
2486 foreach (sort keys %disabled) {
2487     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2488 }
2489 print OUT <<"EOF";
2490 );
2491
2492 EOF
2493 print OUT "our %withargs = (\n";
2494 foreach (sort keys %withargs) {
2495     if (ref($withargs{$_}) eq "ARRAY") {
2496         print OUT "  ", $_, " => [ ", join(", ",
2497                                            map { quotify("perl", $_) }
2498                                            @{$withargs{$_}}), " ],\n";
2499     } else {
2500         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2501     }
2502 }
2503 print OUT <<"EOF";
2504 );
2505
2506 EOF
2507 if ($builder eq "unified") {
2508     my $recurse;
2509     $recurse = sub {
2510         my $indent = shift;
2511         foreach (@_) {
2512             if (ref $_ eq "ARRAY") {
2513                 print OUT " "x$indent, "[\n";
2514                 foreach (@$_) {
2515                     $recurse->($indent + 4, $_);
2516                 }
2517                 print OUT " "x$indent, "],\n";
2518             } elsif (ref $_ eq "HASH") {
2519                 my %h = %$_;
2520                 print OUT " "x$indent, "{\n";
2521                 foreach (sort keys %h) {
2522                     if (ref $h{$_} eq "") {
2523                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2524                     } else {
2525                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2526                         $recurse->($indent + 8, $h{$_});
2527                     }
2528                 }
2529                 print OUT " "x$indent, "},\n";
2530             } else {
2531                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2532             }
2533         }
2534     };
2535     print OUT "our %unified_info = (\n";
2536     foreach (sort keys %unified_info) {
2537         if (ref $unified_info{$_} eq "") {
2538             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2539         } else {
2540             print OUT " "x4, quotify("perl", $_), " =>\n";
2541             $recurse->(8, $unified_info{$_});
2542         }
2543     }
2544     print OUT <<"EOF";
2545 );
2546
2547 EOF
2548 }
2549 print OUT
2550     "# The following data is only used when this files is use as a script\n";
2551 print OUT "my \@makevars = (\n";
2552 foreach (sort keys %user) {
2553     print OUT "    '",$_,"',\n";
2554 }
2555 print OUT ");\n";
2556 print OUT "my \%disabled_info = (\n";
2557 foreach my $what (sort keys %disabled_info) {
2558     print OUT "    '$what' => {\n";
2559     foreach my $info (sort keys %{$disabled_info{$what}}) {
2560         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2561             print OUT "        $info => [ ",
2562                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2563                 " ],\n";
2564         } else {
2565             print OUT "        $info => '", $disabled_info{$what}->{$info},
2566                 "',\n";
2567         }
2568     }
2569     print OUT "    },\n";
2570 }
2571 print OUT ");\n";
2572 print OUT 'my @user_crossable = qw( ', join (' ', @user_crossable), " );\n";
2573 print OUT << 'EOF';
2574 # If run directly, we can give some answers, and even reconfigure
2575 unless (caller) {
2576     use Getopt::Long;
2577     use File::Spec::Functions;
2578     use File::Basename;
2579     use Pod::Usage;
2580
2581     my $here = dirname($0);
2582
2583     my $dump = undef;
2584     my $cmdline = undef;
2585     my $options = undef;
2586     my $target = undef;
2587     my $envvars = undef;
2588     my $makevars = undef;
2589     my $buildparams = undef;
2590     my $reconf = undef;
2591     my $verbose = undef;
2592     my $help = undef;
2593     my $man = undef;
2594     GetOptions('dump|d'                 => \$dump,
2595                'command-line|c'         => \$cmdline,
2596                'options|o'              => \$options,
2597                'target|t'               => \$target,
2598                'environment|e'          => \$envvars,
2599                'make-variables|m'       => \$makevars,
2600                'build-parameters|b'     => \$buildparams,
2601                'reconfigure|reconf|r'   => \$reconf,
2602                'verbose|v'              => \$verbose,
2603                'help'                   => \$help,
2604                'man'                    => \$man)
2605         or die "Errors in command line arguments\n";
2606
2607     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2608             || $buildparams || $reconf || $verbose || $help || $man) {
2609         print STDERR <<"_____";
2610 You must give at least one option.
2611 For more information, do '$0 --help'
2612 _____
2613         exit(2);
2614     }
2615
2616     if ($help) {
2617         pod2usage(-exitval => 0,
2618                   -verbose => 1);
2619     }
2620     if ($man) {
2621         pod2usage(-exitval => 0,
2622                   -verbose => 2);
2623     }
2624     if ($dump || $cmdline) {
2625         print "\nCommand line (with current working directory = $here):\n\n";
2626         print '    ',join(' ',
2627                           $config{PERL},
2628                           catfile($config{sourcedir}, 'Configure'),
2629                           @{$config{perlargv}}), "\n";
2630         print "\nPerl information:\n\n";
2631         print '    ',$config{perl_cmd},"\n";
2632         print '    ',$config{perl_version},' for ',$config{perl_archname},"\n";
2633     }
2634     if ($dump || $options) {
2635         my $longest = 0;
2636         my $longest2 = 0;
2637         foreach my $what (@disablables) {
2638             $longest = length($what) if $longest < length($what);
2639             $longest2 = length($disabled{$what})
2640                 if $disabled{$what} && $longest2 < length($disabled{$what});
2641         }
2642         print "\nEnabled features:\n\n";
2643         foreach my $what (@disablables) {
2644             print "    $what\n" unless $disabled{$what};
2645         }
2646         print "\nDisabled features:\n\n";
2647         foreach my $what (@disablables) {
2648             if ($disabled{$what}) {
2649                 print "    $what", ' ' x ($longest - length($what) + 1),
2650                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2651                 print $disabled_info{$what}->{macro}
2652                     if $disabled_info{$what}->{macro};
2653                 print ' (skip ',
2654                     join(', ', @{$disabled_info{$what}->{skipped}}),
2655                     ')'
2656                     if $disabled_info{$what}->{skipped};
2657                 print "\n";
2658             }
2659         }
2660     }
2661     if ($dump || $target) {
2662         print "\nConfig target attributes:\n\n";
2663         foreach (sort keys %target) {
2664             next if $_ =~ m|^_| || $_ eq 'template';
2665             my $quotify = sub {
2666                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2667             };
2668             print '    ', $_, ' => ';
2669             if (ref($target{$_}) eq "ARRAY") {
2670                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2671             } else {
2672                 print $quotify->($target{$_}), ",\n"
2673             }
2674         }
2675     }
2676     if ($dump || $envvars) {
2677         print "\nRecorded environment:\n\n";
2678         foreach (sort keys %{$config{perlenv}}) {
2679             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2680         }
2681     }
2682     if ($dump || $makevars) {
2683         print "\nMakevars:\n\n";
2684         foreach my $var (@makevars) {
2685             my $prefix = '';
2686             $prefix = $config{CROSS_COMPILE}
2687                 if grep { $var eq $_ } @user_crossable;
2688             $prefix //= '';
2689             print '    ',$var,' ' x (16 - length $var),'= ',
2690                 (ref $config{$var} eq 'ARRAY'
2691                  ? join(' ', @{$config{$var}})
2692                  : $prefix.$config{$var}),
2693                 "\n"
2694                 if defined $config{$var};
2695         }
2696
2697         my @buildfile = ($config{builddir}, $config{build_file});
2698         unshift @buildfile, $here
2699             unless file_name_is_absolute($config{builddir});
2700         my $buildfile = canonpath(catdir(@buildfile));
2701         print <<"_____";
2702
2703 NOTE: These variables only represent the configuration view.  The build file
2704 template may have processed these variables further, please have a look at the
2705 build file for more exact data:
2706     $buildfile
2707 _____
2708     }
2709     if ($dump || $buildparams) {
2710         my @buildfile = ($config{builddir}, $config{build_file});
2711         unshift @buildfile, $here
2712             unless file_name_is_absolute($config{builddir});
2713         print "\nbuild file:\n\n";
2714         print "    ", canonpath(catfile(@buildfile)),"\n";
2715
2716         print "\nbuild file templates:\n\n";
2717         foreach (@{$config{build_file_templates}}) {
2718             my @tmpl = ($_);
2719             unshift @tmpl, $here
2720                 unless file_name_is_absolute($config{sourcedir});
2721             print '    ',canonpath(catfile(@tmpl)),"\n";
2722         }
2723     }
2724     if ($reconf) {
2725         if ($verbose) {
2726             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2727             foreach (sort keys %{$config{perlenv}}) {
2728                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2729             }
2730         }
2731
2732         chdir $here;
2733         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2734     }
2735 }
2736
2737 1;
2738
2739 __END__
2740
2741 =head1 NAME
2742
2743 configdata.pm - configuration data for OpenSSL builds
2744
2745 =head1 SYNOPSIS
2746
2747 Interactive:
2748
2749   perl configdata.pm [options]
2750
2751 As data bank module:
2752
2753   use configdata;
2754
2755 =head1 DESCRIPTION
2756
2757 This module can be used in two modes, interactively and as a module containing
2758 all the data recorded by OpenSSL's Configure script.
2759
2760 When used interactively, simply run it as any perl script, with at least one
2761 option, and you will get the information you ask for.  See L</OPTIONS> below.
2762
2763 When loaded as a module, you get a few databanks with useful information to
2764 perform build related tasks.  The databanks are:
2765
2766     %config             Configured things.
2767     %target             The OpenSSL config target with all inheritances
2768                         resolved.
2769     %disabled           The features that are disabled.
2770     @disablables        The list of features that can be disabled.
2771     %withargs           All data given through --with-THING options.
2772     %unified_info       All information that was computed from the build.info
2773                         files.
2774
2775 =head1 OPTIONS
2776
2777 =over 4
2778
2779 =item B<--help>
2780
2781 Print a brief help message and exit.
2782
2783 =item B<--man>
2784
2785 Print the manual page and exit.
2786
2787 =item B<--dump> | B<-d>
2788
2789 Print all relevant configuration data.  This is equivalent to B<--command-line>
2790 B<--options> B<--target> B<--environment> B<--make-variables>
2791 B<--build-parameters>.
2792
2793 =item B<--command-line> | B<-c>
2794
2795 Print the current configuration command line.
2796
2797 =item B<--options> | B<-o>
2798
2799 Print the features, both enabled and disabled, and display defined macro and
2800 skipped directories where applicable.
2801
2802 =item B<--target> | B<-t>
2803
2804 Print the config attributes for this config target.
2805
2806 =item B<--environment> | B<-e>
2807
2808 Print the environment variables and their values at the time of configuration.
2809
2810 =item B<--make-variables> | B<-m>
2811
2812 Print the main make variables generated in the current configuration
2813
2814 =item B<--build-parameters> | B<-b>
2815
2816 Print the build parameters, i.e. build file and build file templates.
2817
2818 =item B<--reconfigure> | B<--reconf> | B<-r>
2819
2820 Redo the configuration.
2821
2822 =item B<--verbose> | B<-v>
2823
2824 Verbose output.
2825
2826 =back
2827
2828 =cut
2829
2830 EOF
2831 close(OUT);
2832 if ($builder_platform eq 'unix') {
2833     my $mode = (0755 & ~umask);
2834     chmod $mode, 'configdata.pm'
2835         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2836 }
2837
2838 my %builders = (
2839     unified => sub {
2840         print 'Creating ',$target{build_file},"\n";
2841         run_dofile(catfile($blddir, $target{build_file}),
2842                    @{$config{build_file_templates}});
2843     },
2844     );
2845
2846 $builders{$builder}->($builder_platform, @builder_opts);
2847
2848 $SIG{__DIE__} = $orig_death_handler;
2849
2850 print <<"EOF" if ($disabled{threads} eq "unavailable");
2851
2852 The library could not be configured for supporting multi-threaded
2853 applications as the compiler options required on this system are not known.
2854 See file INSTALL for details if you need multi-threading.
2855 EOF
2856
2857 print <<"EOF" if ($no_shared_warn);
2858
2859 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2860 platform, so we will pretend you gave the option 'no-pic', which also disables
2861 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2862 or position independent code, please let us know (but please first make sure
2863 you have tried with a current version of OpenSSL).
2864 EOF
2865
2866 print <<"EOF";
2867
2868 **********************************************************************
2869 ***                                                                ***
2870 ***   OpenSSL has been successfully configured                     ***
2871 ***                                                                ***
2872 ***   If you encounter a problem while building, please open an    ***
2873 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2874 ***   and include the output from the following command:           ***
2875 ***                                                                ***
2876 ***       perl configdata.pm --dump                                ***
2877 ***                                                                ***
2878 ***   (If you are new to OpenSSL, you might want to consult the    ***
2879 ***   'Troubleshooting' section in the INSTALL file first)         ***
2880 ***                                                                ***
2881 **********************************************************************
2882 EOF
2883
2884 exit(0);
2885
2886 ######################################################################
2887 #
2888 # Helpers and utility functions
2889 #
2890
2891 # Death handler, to print a helpful message in case of failure #######
2892 #
2893 sub death_handler {
2894     die @_ if $^S;              # To prevent the added message in eval blocks
2895     my $build_file = $target{build_file} // "build file";
2896     my @message = ( <<"_____", @_ );
2897
2898 Failure!  $build_file wasn't produced.
2899 Please read INSTALL and associated NOTES files.  You may also have to look over
2900 your available compiler tool chain or change your configuration.
2901
2902 _____
2903
2904     # Dying is terminal, so it's ok to reset the signal handler here.
2905     $SIG{__DIE__} = $orig_death_handler;
2906     die @message;
2907 }
2908
2909 # Configuration file reading #########################################
2910
2911 # Note: All of the helper functions are for lazy evaluation.  They all
2912 # return a CODE ref, which will return the intended value when evaluated.
2913 # Thus, whenever there's mention of a returned value, it's about that
2914 # intended value.
2915
2916 # Helper function to implement conditional inheritance depending on the
2917 # value of $disabled{asm}.  Used in inherit_from values as follows:
2918 #
2919 #      inherit_from => [ "template", asm("asm_tmpl") ]
2920 #
2921 sub asm {
2922     my @x = @_;
2923     sub {
2924         $disabled{asm} ? () : @x;
2925     }
2926 }
2927
2928 # Helper function to implement conditional value variants, with a default
2929 # plus additional values based on the value of $config{build_type}.
2930 # Arguments are given in hash table form:
2931 #
2932 #       picker(default => "Basic string: ",
2933 #              debug   => "debug",
2934 #              release => "release")
2935 #
2936 # When configuring with --debug, the resulting string will be
2937 # "Basic string: debug", and when not, it will be "Basic string: release"
2938 #
2939 # This can be used to create variants of sets of flags according to the
2940 # build type:
2941 #
2942 #       cflags => picker(default => "-Wall",
2943 #                        debug   => "-g -O0",
2944 #                        release => "-O3")
2945 #
2946 sub picker {
2947     my %opts = @_;
2948     return sub { add($opts{default} || (),
2949                      $opts{$config{build_type}} || ())->(); }
2950 }
2951
2952 # Helper function to combine several values of different types into one.
2953 # This is useful if you want to combine a string with the result of a
2954 # lazy function, such as:
2955 #
2956 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2957 #
2958 sub combine {
2959     my @stuff = @_;
2960     return sub { add(@stuff)->(); }
2961 }
2962
2963 # Helper function to implement conditional values depending on the value
2964 # of $disabled{threads}.  Can be used as follows:
2965 #
2966 #       cflags => combine("-Wall", threads("-pthread"))
2967 #
2968 sub threads {
2969     my @flags = @_;
2970     return sub { add($disabled{threads} ? () : @flags)->(); }
2971 }
2972
2973 sub shared {
2974     my @flags = @_;
2975     return sub { add($disabled{shared} ? () : @flags)->(); }
2976 }
2977
2978 our $add_called = 0;
2979 # Helper function to implement adding values to already existing configuration
2980 # values.  It handles elements that are ARRAYs, CODEs and scalars
2981 sub _add {
2982     my $separator = shift;
2983
2984     # If there's any ARRAY in the collection of values OR the separator
2985     # is undef, we will return an ARRAY of combined values, otherwise a
2986     # string of joined values with $separator as the separator.
2987     my $found_array = !defined($separator);
2988
2989     my @values =
2990         map {
2991             my $res = $_;
2992             while (ref($res) eq "CODE") {
2993                 $res = $res->();
2994             }
2995             if (defined($res)) {
2996                 if (ref($res) eq "ARRAY") {
2997                     $found_array = 1;
2998                     @$res;
2999                 } else {
3000                     $res;
3001                 }
3002             } else {
3003                 ();
3004             }
3005     } (@_);
3006
3007     $add_called = 1;
3008
3009     if ($found_array) {
3010         [ @values ];
3011     } else {
3012         join($separator, grep { defined($_) && $_ ne "" } @values);
3013     }
3014 }
3015 sub add_before {
3016     my $separator = " ";
3017     if (ref($_[$#_]) eq "HASH") {
3018         my $opts = pop;
3019         $separator = $opts->{separator};
3020     }
3021     my @x = @_;
3022     sub { _add($separator, @x, @_) };
3023 }
3024 sub add {
3025     my $separator = " ";
3026     if (ref($_[$#_]) eq "HASH") {
3027         my $opts = pop;
3028         $separator = $opts->{separator};
3029     }
3030     my @x = @_;
3031     sub { _add($separator, @_, @x) };
3032 }
3033
3034 sub read_eval_file {
3035     my $fname = shift;
3036     my $content;
3037     my @result;
3038
3039     open F, "< $fname" or die "Can't open '$fname': $!\n";
3040     {
3041         undef local $/;
3042         $content = <F>;
3043     }
3044     close F;
3045     {
3046         local $@;
3047
3048         @result = ( eval $content );
3049         warn $@ if $@;
3050     }
3051     return wantarray ? @result : $result[0];
3052 }
3053
3054 # configuration reader, evaluates the input file as a perl script and expects
3055 # it to fill %targets with target configurations.  Those are then added to
3056 # %table.
3057 sub read_config {
3058     my $fname = shift;
3059     my %targets;
3060
3061     {
3062         # Protect certain tables from tampering
3063         local %table = ();
3064
3065         %targets = read_eval_file($fname);
3066     }
3067     my %preexisting = ();
3068     foreach (sort keys %targets) {
3069         $preexisting{$_} = 1 if $table{$_};
3070     }
3071     die <<"EOF",
3072 The following config targets from $fname
3073 shadow pre-existing config targets with the same name:
3074 EOF
3075         map { "  $_\n" } sort keys %preexisting
3076         if %preexisting;
3077
3078
3079     # For each target, check that it's configured with a hash table.
3080     foreach (keys %targets) {
3081         if (ref($targets{$_}) ne "HASH") {
3082             if (ref($targets{$_}) eq "") {
3083                 warn "Deprecated target configuration for $_, ignoring...\n";
3084             } else {
3085                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3086             }
3087             delete $targets{$_};
3088         } else {
3089             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3090         }
3091     }
3092
3093     %table = (%table, %targets);
3094
3095 }
3096
3097 # configuration resolver.  Will only resolve all the lazy evaluation
3098 # codeblocks for the chosen target and all those it inherits from,
3099 # recursively
3100 sub resolve_config {
3101     my $target = shift;
3102     my @breadcrumbs = @_;
3103
3104 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3105
3106     if (grep { $_ eq $target } @breadcrumbs) {
3107         die "inherit_from loop!  target backtrace:\n  "
3108             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3109     }
3110
3111     if (!defined($table{$target})) {
3112         warn "Warning! target $target doesn't exist!\n";
3113         return ();
3114     }
3115     # Recurse through all inheritances.  They will be resolved on the
3116     # fly, so when this operation is done, they will all just be a
3117     # bunch of attributes with string values.
3118     # What we get here, though, are keys with references to lists of
3119     # the combined values of them all.  We will deal with lists after
3120     # this stage is done.
3121     my %combined_inheritance = ();
3122     if ($table{$target}->{inherit_from}) {
3123         my @inherit_from =
3124             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3125         foreach (@inherit_from) {
3126             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3127
3128             # 'template' is a marker that's considered private to
3129             # the config that had it.
3130             delete $inherited_config{template};
3131
3132             foreach (keys %inherited_config) {
3133                 if (!$combined_inheritance{$_}) {
3134                     $combined_inheritance{$_} = [];
3135                 }
3136                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3137             }
3138         }
3139     }
3140
3141     # We won't need inherit_from in this target any more, since we've
3142     # resolved all the inheritances that lead to this
3143     delete $table{$target}->{inherit_from};
3144
3145     # Now is the time to deal with those lists.  Here's the place to
3146     # decide what shall be done with those lists, all based on the
3147     # values of the target we're currently dealing with.
3148     # - If a value is a coderef, it will be executed with the list of
3149     #   inherited values as arguments.
3150     # - If the corresponding key doesn't have a value at all or is the
3151     #   empty string, the inherited value list will be run through the
3152     #   default combiner (below), and the result becomes this target's
3153     #   value.
3154     # - Otherwise, this target's value is assumed to be a string that
3155     #   will simply override the inherited list of values.
3156     my $default_combiner = add();
3157
3158     my %all_keys =
3159         map { $_ => 1 } (keys %combined_inheritance,
3160                          keys %{$table{$target}});
3161
3162     sub process_values {
3163         my $object    = shift;
3164         my $inherited = shift;  # Always a [ list ]
3165         my $target    = shift;
3166         my $entry     = shift;
3167
3168         $add_called = 0;
3169
3170         while(ref($object) eq "CODE") {
3171             $object = $object->(@$inherited);
3172         }
3173         if (!defined($object)) {
3174             return ();
3175         }
3176         elsif (ref($object) eq "ARRAY") {
3177             local $add_called;  # To make sure recursive calls don't affect it
3178             return [ map { process_values($_, $inherited, $target, $entry) }
3179                      @$object ];
3180         } elsif (ref($object) eq "") {
3181             return $object;
3182         } else {
3183             die "cannot handle reference type ",ref($object)
3184                 ," found in target ",$target," -> ",$entry,"\n";
3185         }
3186     }
3187
3188     foreach (sort keys %all_keys) {
3189         my $previous = $combined_inheritance{$_};
3190
3191         # Current target doesn't have a value for the current key?
3192         # Assign it the default combiner, the rest of this loop body
3193         # will handle it just like any other coderef.
3194         if (!exists $table{$target}->{$_}) {
3195             $table{$target}->{$_} = $default_combiner;
3196         }
3197
3198         $table{$target}->{$_} = process_values($table{$target}->{$_},
3199                                                $combined_inheritance{$_},
3200                                                $target, $_);
3201         unless(defined($table{$target}->{$_})) {
3202             delete $table{$target}->{$_};
3203         }
3204 #        if ($extra_checks &&
3205 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3206 #            warn "$_ got replaced in $target\n";
3207 #        }
3208     }
3209
3210     # Finally done, return the result.
3211     return %{$table{$target}};
3212 }
3213
3214 sub usage
3215         {
3216         print STDERR $usage;
3217         print STDERR "\npick os/compiler from:\n";
3218         my $j=0;
3219         my $i;
3220         my $k=0;
3221         foreach $i (sort keys %table)
3222                 {
3223                 next if $table{$i}->{template};
3224                 next if $i =~ /^debug/;
3225                 $k += length($i) + 1;
3226                 if ($k > 78)
3227                         {
3228                         print STDERR "\n";
3229                         $k=length($i);
3230                         }
3231                 print STDERR $i . " ";
3232                 }
3233         foreach $i (sort keys %table)
3234                 {
3235                 next if $table{$i}->{template};
3236                 next if $i !~ /^debug/;
3237                 $k += length($i) + 1;
3238                 if ($k > 78)
3239                         {
3240                         print STDERR "\n";
3241                         $k=length($i);
3242                         }
3243                 print STDERR $i . " ";
3244                 }
3245         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3246         exit(1);
3247         }
3248
3249 sub run_dofile
3250 {
3251     my $out = shift;
3252     my @templates = @_;
3253
3254     unlink $out || warn "Can't remove $out, $!"
3255         if -f $out;
3256     foreach (@templates) {
3257         die "Can't open $_, $!" unless -f $_;
3258     }
3259     my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
3260     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
3261     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
3262     system($cmd);
3263     exit 1 if $? != 0;
3264     rename("$out.new", $out) || die "Can't rename $out.new, $!";
3265 }
3266
3267 sub compiler_predefined {
3268     state %predefined;
3269     my $cc = shift;
3270
3271     return () if $^O eq 'VMS';
3272
3273     die 'compiler_predefined called without a compiler command'
3274         unless $cc;
3275
3276     if (! $predefined{$cc}) {
3277
3278         $predefined{$cc} = {};
3279
3280         # collect compiler pre-defines from gcc or gcc-alike...
3281         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3282         while (my $l = <PIPE>) {
3283             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3284             $predefined{$cc}->{$1} = $2 // '';
3285         }
3286         close(PIPE);
3287     }
3288
3289     return %{$predefined{$cc}};
3290 }
3291
3292 sub which
3293 {
3294     my ($name)=@_;
3295
3296     if (eval { require IPC::Cmd; 1; }) {
3297         IPC::Cmd->import();
3298         return scalar IPC::Cmd::can_run($name);
3299     } else {
3300         # if there is $directories component in splitpath,
3301         # then it's not something to test with $PATH...
3302         return $name if (File::Spec->splitpath($name))[1];
3303
3304         foreach (File::Spec->path()) {
3305             my $fullpath = catfile($_, "$name$target{exe_extension}");
3306             if (-f $fullpath and -x $fullpath) {
3307                 return $fullpath;
3308             }
3309         }
3310     }
3311 }
3312
3313 sub env
3314 {
3315     my $name = shift;
3316     my %opts = @_;
3317
3318     unless ($opts{cacheonly}) {
3319         # Note that if $ENV{$name} doesn't exist or is undefined,
3320         # $config{perlenv}->{$name} will be created with the value
3321         # undef.  This is intentional.
3322
3323         $config{perlenv}->{$name} = $ENV{$name}
3324             if ! exists $config{perlenv}->{$name};
3325     }
3326     return $config{perlenv}->{$name};
3327 }
3328
3329 # Configuration printer ##############################################
3330
3331 sub print_table_entry
3332 {
3333     local $now_printing = shift;
3334     my %target = resolve_config($now_printing);
3335     my $type = shift;
3336
3337     # Don't print the templates
3338     return if $target{template};
3339
3340     my @sequence = (
3341         "sys_id",
3342         "cpp",
3343         "cppflags",
3344         "defines",
3345         "includes",
3346         "cc",
3347         "cflags",
3348         "unistd",
3349         "ld",
3350         "lflags",
3351         "loutflag",
3352         "ex_libs",
3353         "bn_ops",
3354         "rc5_asm_src",
3355         "wp_asm_src",
3356         "cmll_asm_src",
3357         "modes_asm_src",
3358         "padlock_asm_src",
3359         "chacha_asm_src",
3360         "poly1035_asm_src",
3361         "thread_scheme",
3362         "perlasm_scheme",
3363         "dso_scheme",
3364         "shared_target",
3365         "shared_cflag",
3366         "shared_defines",
3367         "shared_ldflag",
3368         "shared_rcflag",
3369         "shared_extension",
3370         "dso_extension",
3371         "obj_extension",
3372         "exe_extension",
3373         "ranlib",
3374         "ar",
3375         "arflags",
3376         "aroutflag",
3377         "rc",
3378         "rcflags",
3379         "rcoutflag",
3380         "mt",
3381         "mtflags",
3382         "mtinflag",
3383         "mtoutflag",
3384         "multilib",
3385         "build_scheme",
3386         );
3387
3388     if ($type eq "TABLE") {
3389         print "\n";
3390         print "*** $now_printing\n";
3391         foreach (@sequence) {
3392             if (ref($target{$_}) eq "ARRAY") {
3393                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3394             } else {
3395                 printf "\$%-12s = %s\n", $_, $target{$_};
3396             }
3397         }
3398     } elsif ($type eq "HASH") {
3399         my $largest =
3400             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3401         print "    '$now_printing' => {\n";
3402         foreach (@sequence) {
3403             if ($target{$_}) {
3404                 if (ref($target{$_}) eq "ARRAY") {
3405                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3406                 } else {
3407                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3408                 }
3409             }
3410         }
3411         print "    },\n";
3412     }
3413 }
3414
3415 # Utility routines ###################################################
3416
3417 # On VMS, if the given file is a logical name, File::Spec::Functions
3418 # will consider it an absolute path.  There are cases when we want a
3419 # purely syntactic check without checking the environment.
3420 sub isabsolute {
3421     my $file = shift;
3422
3423     # On non-platforms, we just use file_name_is_absolute().
3424     return file_name_is_absolute($file) unless $^O eq "VMS";
3425
3426     # If the file spec includes a device or a directory spec,
3427     # file_name_is_absolute() is perfectly safe.
3428     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3429
3430     # Here, we know the given file spec isn't absolute
3431     return 0;
3432 }
3433
3434 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3435 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3436 # realpath() requires that at least all path components except the last is an
3437 # existing directory.  On VMS, the last component of the directory spec must
3438 # exist.
3439 sub absolutedir {
3440     my $dir = shift;
3441
3442     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3443     # will return the volume name for the device, no matter what.  Also,
3444     # it will return an incorrect directory spec if the argument is a
3445     # directory that doesn't exist.
3446     if ($^O eq "VMS") {
3447         return rel2abs($dir);
3448     }
3449
3450     # We use realpath() on Unix, since no other will properly clean out
3451     # a directory spec.
3452     use Cwd qw/realpath/;
3453
3454     return realpath($dir);
3455 }
3456
3457 sub quotify {
3458     my %processors = (
3459         perl    => sub { my $x = shift;
3460                          $x =~ s/([\\\$\@"])/\\$1/g;
3461                          return '"'.$x.'"'; },
3462         maybeshell => sub { my $x = shift;
3463                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3464                             if ($x ne $y || $x =~ m|\s|) {
3465                                 return '"'.$y.'"';
3466                             } else {
3467                                 return $x;
3468                             }
3469                         },
3470         );
3471     my $for = shift;
3472     my $processor =
3473         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3474
3475     return map { $processor->($_); } @_;
3476 }
3477
3478 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3479 # $filename is a file name to read from
3480 # $line_concat_cond_re is a regexp detecting a line continuation ending
3481 # $line_concat is a CODEref that takes care of concatenating two lines
3482 sub collect_from_file {
3483     my $filename = shift;
3484     my $line_concat_cond_re = shift;
3485     my $line_concat = shift;
3486
3487     open my $fh, $filename || die "unable to read $filename: $!\n";
3488     return sub {
3489         my $saved_line = "";
3490         $_ = "";
3491         while (<$fh>) {
3492             s|\R$||;
3493             if (defined $line_concat) {
3494                 $_ = $line_concat->($saved_line, $_);
3495                 $saved_line = "";
3496             }
3497             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3498                 $saved_line = $_;
3499                 next;
3500             }
3501             return $_;
3502         }
3503         die "$filename ending with continuation line\n" if $_;
3504         close $fh;
3505         return undef;
3506     }
3507 }
3508
3509 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3510 # $array is an ARRAYref of lines
3511 # $line_concat_cond_re is a regexp detecting a line continuation ending
3512 # $line_concat is a CODEref that takes care of concatenating two lines
3513 sub collect_from_array {
3514     my $array = shift;
3515     my $line_concat_cond_re = shift;
3516     my $line_concat = shift;
3517     my @array = (@$array);
3518
3519     return sub {
3520         my $saved_line = "";
3521         $_ = "";
3522         while (defined($_ = shift @array)) {
3523             s|\R$||;
3524             if (defined $line_concat) {
3525                 $_ = $line_concat->($saved_line, $_);
3526                 $saved_line = "";
3527             }
3528             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3529                 $saved_line = $_;
3530                 next;
3531             }
3532             return $_;
3533         }
3534         die "input text ending with continuation line\n" if $_;
3535         return undef;
3536     }
3537 }
3538
3539 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3540 # $lineiterator is a CODEref that delivers one line at a time.
3541 # All following arguments are regex/CODEref pairs, where the regexp detects a
3542 # line and the CODEref does something with the result of the regexp.
3543 sub collect_information {
3544     my $lineiterator = shift;
3545     my %collectors = @_;
3546
3547     while(defined($_ = $lineiterator->())) {
3548         s|\R$||;
3549         my $found = 0;
3550         if ($collectors{"BEFORE"}) {
3551             $collectors{"BEFORE"}->($_);
3552         }
3553         foreach my $re (keys %collectors) {
3554             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3555                 $collectors{$re}->($lineiterator);
3556                 $found = 1;
3557             };
3558         }
3559         if ($collectors{"OTHERWISE"}) {
3560             $collectors{"OTHERWISE"}->($lineiterator, $_)
3561                 unless $found || !defined $collectors{"OTHERWISE"};
3562         }
3563         if ($collectors{"AFTER"}) {
3564             $collectors{"AFTER"}->($_);
3565         }
3566     }
3567 }
3568
3569 # tokenize($line)
3570 # tokenize($line,$separator)
3571 # $line is a line of text to split up into tokens
3572 # $separator [optional] is a regular expression that separates the tokens,
3573 # the default being spaces.  Do not use quotes of any kind as separators,
3574 # that will give undefined results.
3575 # Returns a list of tokens.
3576 #
3577 # Tokens are divided by separator (spaces by default).  If the tokens include
3578 # the separators, they have to be quoted with single or double quotes.
3579 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3580 # with backslash.
3581 # Basically, the same quoting rules apply for " and ' as in any
3582 # Unix shell.
3583 sub tokenize {
3584     my $line = my $debug_line = shift;
3585     my $separator = shift // qr|\s+|;
3586     my @result = ();
3587
3588     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3589         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3590     }
3591
3592     while ($line =~ s|^${separator}||, $line ne "") {
3593         my $token = "";
3594     again:
3595         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3596         $token .= $1;
3597         $line = $2.$';
3598
3599         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3600             $token .= $1;
3601             $line = $';
3602             goto again;
3603         } elsif ($line =~ m/^'([^']*)'/) {
3604             $token .= $1;
3605             $line = $';
3606             goto again;
3607         }
3608         push @result, $token;
3609     }
3610
3611     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3612         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3613         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3614     }
3615     return @result;
3616 }