Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3
   4 ##
   5 ##  Configure -- OpenSSL source tree configuration script
   6 ##  If editing this file, run this command before committing
   7 ##      make -f Makefile.in TABLE
   8 ##
   9
  10 require 5.000;
  11 use strict;
  12 use File::Basename;
  13 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs/;
  14 use File::Path qw/mkpath/;
  15 use Cwd qw/:DEFAULT realpath/;
  16
  17 # see INSTALL for instructions.
  18
  19 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [experimental-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  20
  21 # Options:
  22 #
  23 # --config      add the given configuration file, which will be read after
  24 #               any "Configurations*" files that are found in the same
  25 #               directory as this script.
  26 # --prefix      prefix for the OpenSSL installation, which includes the
  27 #               directories bin, lib, include, share/man, share/doc/openssl
  28 #               This becomes the value of INSTALLTOP in Makefile
  29 #               (Default: /usr/local)
  30 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  31 #               If it's a relative directory, it will be added on the directory
  32 #               given with --prefix.
  33 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  34 #               (Default: PREFIX/ssl)
  35 #
  36 # --install_prefix  Additional prefix for package builders (empty by
  37 #               default).  This needn't be set in advance, you can
  38 #               just as well use "make INSTALL_PREFIX=/whatever install".
  39 #
  40 # --cross-compile-prefix Add specified prefix to binutils components.
  41 #
  42 # --api         One of 0.9.8, 1.0.0 or 1.1.0.  Do not compile support for
  43 #               interfaces deprecated as of the specified OpenSSL version.
  44 #
  45 # no-hw-xxx     do not compile support for specific crypto hardware.
  46 #               Generic OpenSSL-style methods relating to this support
  47 #               are always compiled but return NULL if the hardware
  48 #               support isn't compiled.
  49 # no-hw         do not compile support for any crypto hardware.
  50 # [no-]threads  [don't] try to create a library that is suitable for
  51 #               multithreaded applications (default is "threads" if we
  52 #               know how to do it)
  53 # [no-]shared   [don't] try to create shared libraries when supported.
  54 # no-asm        do not use assembler
  55 # no-dso        do not compile in any native shared-library methods. This
  56 #               will ensure that all methods just return NULL.
  57 # no-egd        do not compile support for the entropy-gathering daemon APIs
  58 # [no-]zlib     [don't] compile support for zlib compression.
  59 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  60 #               library and will be loaded in run-time by the OpenSSL library.
  61 # sctp          include SCTP support
  62 # 386           generate 80386 code
  63 # no-sse2       disables IA-32 SSE2 code, above option implies no-sse2
  64 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  65 # -<xxx> +<xxx> compiler options are passed through
  66 #
  67 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
  68 #               provided to stack calls. Generates unique stack functions for
  69 #               each possible stack type.
  70 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  71 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  72 # Following are set automatically by this script
  73 #
  74 # MD5_ASM       use some extra md5 assember,
  75 # SHA1_ASM      use some extra sha1 assember, must define L_ENDIAN for x86
  76 # RMD160_ASM    use some extra ripemd160 assember,
  77 # SHA256_ASM    sha256_block is implemented in assembler
  78 # SHA512_ASM    sha512_block is implemented in assembler
  79 # AES_ASM       ASE_[en|de]crypt is implemented in assembler
  80
  81 # Minimum warning options... any contributions to OpenSSL should at least get
  82 # past these.
  83
  84 my $gcc_devteam_warn = "-Wall -pedantic -DPEDANTIC -Wno-long-long -Wsign-compare -Wmissing-prototypes -Wshadow -Wformat -Wtype-limits -Werror -DREF_CHECK -DDEBUG_UNUSED";
  85
  86 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
  87 # TODO(openssl-team): fix problems and investigate if (at least) the
  88 # following warnings can also be enabled:
  89 # -Wswitch-enum, -Wunused-macros, -Wmissing-field-initializers,
  90 # -Wcast-align,
  91 # -Wunreachable-code -Wunused-parameter -Wlanguage-extension-token
  92 # -Wextended-offsetof
  93 my $clang_devteam_warn = "-Wno-unused-parameter -Wno-missing-field-initializers -Wno-language-extension-token -Wno-extended-offsetof -Wconditional-uninitialized -Qunused-arguments -Wincompatible-pointer-types-discards-qualifiers -Wmissing-variable-declarations";
  94
  95 # Warn that "make depend" should be run?
  96 my $warn_make_depend = 0;
  97
  98 # These are used in addition to $gcc_devteam_warn unless this is a mingw build.
  99 # This adds backtrace information to the memory leak info.
 100 my $memleak_devteam_backtrace = "-rdynamic -DCRYPTO_MDEBUG_BACKTRACE";
 101
 102 my $strict_warnings = 0;
 103
 104 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 105 # which would cover all BSD flavors. -pthread applies to them all,
 106 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 107 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 108 # which has to be accompanied by explicit -D_THREAD_SAFE and
 109 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 110 # seems to be sufficient?
 111 my $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 112
 113 #
 114 # API compability name to version number mapping.
 115 #
 116 my $maxapi = "1.1.0";           # API for "no-deprecated" builds
 117 my $apitable = {
 118     "1.1.0" => "0x10100000L",
 119     "1.0.0" => "0x10000000L",
 120     "0.9.8" => "0x00908000L",
 121 };
 122
 123 my $base_target = "BASE";   # The template that all other inherit from
 124 our %table = ();
 125 our %config = ();
 126
 127 # Forward declarations ###############################################
 128
 129 # read_config(filename)
 130 #
 131 # Reads a configuration file and populates %table with the contents
 132 # (which the configuration file places in %targets).
 133 sub read_config;
 134
 135 # resolve_config(target)
 136 #
 137 # Resolves all the late evalutations, inheritances and so on for the
 138 # chosen target and any target it inherits from.
 139 sub resolve_config;
 140
 141
 142 # Information collection #############################################
 143
 144 # Unified build supports separate build dir
 145 my $srcdir = catdir(realpath(dirname($0))); # catdir ensures local syntax
 146 my $blddir = catdir(realpath("."));       # catdir ensures local syntax
 147 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 148
 149 $config{sourcedir} = abs2rel($srcdir);
 150 $config{builddir} = abs2rel($blddir);
 151
 152 # Collect version numbers
 153 $config{version} = "unknown";
 154 $config{version_num} = "unknown";
 155 $config{shlib_version_number} = "unknown";
 156 $config{shlib_version_history} = "unknown";
 157
 158 collect_information(
 159     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 160     qr/OPENSSL.VERSION.TEXT.*OpenSSL (\S+) / => sub { $config{version} = $1; },
 161     qr/OPENSSL.VERSION.NUMBER.*(0x\S+)/      => sub { $config{version_num}=$1 },
 162     qr/SHLIB_VERSION_NUMBER *"([^"]+)"/      => sub { $config{shlib_version_number}=$1 },
 163     qr/SHLIB_VERSION_HISTORY *"([^"]*)"/     => sub { $config{shlib_version_history}=$1 }
 164     );
 165 if ($config{shlib_version_history} ne "") { $config{shlib_version_history} .= ":"; }
 166
 167 ($config{major}, $config{minor})
 168     = ($config{version} =~ /^([0-9]+)\.([0-9\.]+)/);
 169 ($config{shlib_major}, $config{shlib_minor})
 170     = ($config{shlib_version_number} =~ /^([0-9]+)\.([0-9\.]+)/);
 171 die "erroneous version information in opensslv.h: ",
 172     "$config{major}, $config{minor}, $config{shlib_major}, $config{shlib_minor}\n"
 173     if ($config{major} eq "" || $config{minor} eq ""
 174         || $config{shlib_major} eq "" ||  $config{shlib_minor} eq "");
 175
 176 # Collect target configurations
 177
 178 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 179 foreach (sort glob($pattern) ) {
 180     &read_config($_);
 181 }
 182
 183
 184 print "Configuring OpenSSL version $config{version} (0x$config{version_num})\n";
 185
 186 $config{perl};
 187 $config{prefix}="";
 188 $config{openssldir}="";
 189 $config{processor}="";
 190 $config{libdir}="";
 191 $config{install_prefix}= "$ENV{'INSTALL_PREFIX'}";
 192 $config{cross_compile_prefix}="";
 193 $config{fipslibdir}="/usr/local/ssl/fips-2.0/lib/";
 194 my $nofipscanistercheck=0;
 195 $config{baseaddr}="0xFB00000";
 196 my $no_threads=0;
 197 my $threads=0;
 198 $config{no_shared}=0; # but "no-shared" is default
 199 my $zlib=1;      # but "no-zlib" is default
 200 my $no_rfc3779=0;
 201 my $no_asm=0;
 202 my $no_dso=0;
 203 my $default_ranlib;
 204 $config{fips}=0;
 205
 206 # Top level directories to build
 207 $config{dirs} = [ "crypto", "ssl", "engines", "apps", "test", "tools" ];
 208 # crypto/ subdirectories to build
 209 $config{sdirs} = [
 210     "objects",
 211     "md2", "md4", "md5", "sha", "mdc2", "hmac", "ripemd", "whrlpool", "poly1305",
 212     "des", "aes", "rc2", "rc4", "rc5", "idea", "bf", "cast", "camellia", "seed", "chacha", "modes",
 213     "bn", "ec", "rsa", "dsa", "dh", "dso", "engine",
 214     "buffer", "bio", "stack", "lhash", "rand", "err",
 215     "evp", "asn1", "pem", "x509", "x509v3", "conf", "txt_db", "pkcs7", "pkcs12", "comp", "ocsp", "ui",
 216     "cms", "ts", "jpake", "srp", "store", "cmac", "ct", "async", "kdf"
 217     ];
 218
 219 # Known TLS and DTLS protocols
 220 my @tls = qw(ssl3 tls1 tls1_1 tls1_2);
 221 my @dtls = qw(dtls1 dtls1_2);
 222
 223 # Explicitelly known options that are possible to disable.  They can
 224 # be regexps, and will be used like this: /^no-${option}$/
 225 # For developers: keep it sorted alphabetically
 226
 227 my @disablables = (
 228     "aes",
 229     "asm",
 230     "async",
 231     "bf",
 232     "camellia",
 233     "capieng",
 234     "cast",
 235     "chacha",
 236     "cmac",
 237     "cms",
 238     "comp",
 239     "crypto-mdebug",
 240     "ct",
 241     "deprecated",
 242     "des",
 243     "dgram",
 244     "dh",
 245     "dsa",
 246     "dso",
 247     "dtls",
 248     "dynamic[-_]engine",
 249     "ec",
 250     "ec2m",
 251     "ecdh",
 252     "ecdsa",
 253     "ec_nistp_64_gcc_128",
 254     "egd",
 255     "engine",
 256     "err",                      # Really???
 257     "heartbeats",
 258     "hmac",
 259     "hw(-.+)?",
 260     "idea",
 261     "jpake",
 262     "locking",                  # Really???
 263     "md2",
 264     "md4",
 265     "md5",
 266     "mdc2",
 267     "md[-_]ghost94",
 268     "nextprotoneg",
 269     "ocb",
 270     "ocsp",
 271     "poly1305",
 272     "posix-io",
 273     "psk",
 274     "rc2",
 275     "rc4",
 276     "rc5",
 277     "rdrand",
 278     "rfc3779",
 279     "rijndael",                 # Old AES name
 280     "rmd160",
 281     "rsa",
 282     "scrypt",
 283     "sct",
 284     "sctp",
 285     "seed",
 286     "sha",
 287     "shared",
 288     "sock",
 289     "srp",
 290     "srtp",
 291     "sse2",
 292     "ssl",
 293     "ssl-trace",
 294     "static-engine",
 295     "stdio",
 296     "store",
 297     "threads",
 298     "tls",
 299     "unit-test",
 300     "whirlpool",
 301     "zlib",
 302     "zlib-dynamic",
 303     );
 304 foreach my $proto ((@tls, @dtls))
 305         {
 306         push(@disablables, $proto);
 307         push(@disablables, "$proto-method");
 308         }
 309
 310 # All of the following is disabled by default (RC5 was enabled before 0.9.8):
 311
 312 my %disabled = ( # "what"         => "comment" [or special keyword "experimental"]
 313                  "ec_nistp_64_gcc_128" => "default",
 314                  "egd"            => "default",
 315                  "jpake"          => "experimental",
 316                  "md2"            => "default",
 317                  "rc5"            => "default",
 318                  "sctp"           => "default",
 319                  "shared"         => "default",
 320                  "ssl-trace"      => "default",
 321                  "store"          => "experimental",
 322                  "unit-test"      => "default",
 323                  "zlib"           => "default",
 324                  "zlib-dynamic"   => "default",
 325                  "crypto-mdebug"  => "default",
 326                );
 327 my @experimental = ();
 328
 329 # Note: => pair form used for aesthetics, not to truly make a hash table
 330 my @disable_cascades = (
 331     # "what"            => [ "cascade", ... ]
 332     sub { $config{processor} eq "386" }
 333                         => [ "sse2" ],
 334     "ssl"               => [ "ssl3" ],
 335     "ssl3-method"       => [ "ssl3" ],
 336     "zlib"              => [ "zlib-dynamic" ],
 337     "rijndael"          => [ "aes" ],
 338     "des"               => [ "mdc2" ],
 339     "ec"                => [ "ecdsa", "ecdh" ],
 340     "psk"               => [ "jpake" ],
 341
 342     "dgram"             => [ "dtls" ],
 343     "dtls"              => [ @dtls ],
 344
 345     # SSL 3.0, (D)TLS 1.0 and TLS 1.1 require MD5 and SHA
 346     "md5"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
 347     "sha"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
 348
 349     # Additionally, SSL 3.0 requires either RSA or DSA+DH
 350     sub { $disabled{rsa}
 351           && ($disabled{dsa} || $disabled{dh}); }
 352                         => [ "ssl" ],
 353
 354     # (D)TLS 1.0 and TLS 1.1 also require either RSA or DSA+DH
 355     # or ECDSA + ECDH.  (D)TLS 1.2 has this requirement as well.
 356     # (XXX: We don't support PSK-only builds).
 357     sub { $disabled{rsa}
 358           && ($disabled{dsa} || $disabled{dh})
 359           && ($disabled{ecdsa} || $disabled{ecdh}); }
 360                         => [ "tls1", "tls1_1", "tls1_2",
 361                              "dtls1", "dtls1_2" ],
 362
 363     "tls"               => [ @tls ],
 364
 365     # SRP and HEARTBEATS require TLSEXT
 366     "tlsext"            => [ "srp", "heartbeats" ],
 367     );
 368
 369 # Avoid protocol support holes.  Also disable all versions below N, if version
 370 # N is disabled while N+1 is enabled.
 371 #
 372 my @list = (reverse @tls);
 373 while ((my $first, my $second) = (shift @list, shift @list)) {
 374     last unless @list;
 375     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 376                               => [ @list ] );
 377     unshift @list, $second;
 378 }
 379 my @list = (reverse @dtls);
 380 while ((my $first, my $second) = (shift @list, shift @list)) {
 381     last unless @list;
 382     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 383                               => [ @list ] );
 384     unshift @list, $second;
 385 }
 386
 387 # Construct the string of what $config{depflags} should look like with the defaults
 388 # from %disabled above.  (we need this to see if we should advise the user
 389 # to run "make depend"):
 390 my $default_depflags = join(" ",
 391     map { my $x = $_; $x =~ tr{[a-z]-}{[A-Z]_}; "-DOPENSSL_NO_$x"; }
 392     grep { $disabled{$_} !~ /\(no-depflags\)$/ }
 393     sort keys %disabled);
 394
 395 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 396 # To remove something from %disabled, use "enable-foo" (unless it's experimental).
 397 # For symmetry, "disable-foo" is a synonym for "no-foo".
 398
 399 # For features called "experimental" here, a more explicit "experimental-foo" is needed to enable.
 400 # We will collect such requests in @experimental.
 401 # To avoid accidental use of experimental features, applications will have to use -DOPENSSL_EXPERIMENTAL_FOO.
 402
 403
 404 my $no_sse2=0;
 405
 406 &usage if ($#ARGV < 0);
 407
 408 my $flags="";
 409 $config{depflags}="";
 410 $config{openssl_experimental_defines}=[];
 411 $config{openssl_api_defines}=[];
 412 $config{openssl_algorithm_defines}=[];
 413 $config{openssl_thread_defines}=[];
 414 $config{openssl_sys_defines}=[];
 415 $config{openssl_other_defines}=[];
 416 my $libs="";
 417 my $target="";
 418 $config{options}="";
 419 my $make_depend=0;
 420 my %withargs=();
 421 my $build_prefix = "release_";
 422
 423 my @argvcopy=@ARGV;
 424
 425 if (grep /^reconf(igure)?$/, @argvcopy) {
 426     if (-f "./configdata.pm") {
 427         my $file = "./configdata.pm";
 428         unless (my $return = do $file) {
 429             die "couldn't parse $file: $@" if $@;
 430             die "couldn't do $file: $!"    unless defined $return;
 431             die "couldn't run $file"       unless $return;
 432         }
 433
 434         @argvcopy = defined($configdata::config{perlargv}) ?
 435             @{$configdata::config{perlargv}} : ();
 436         die "Incorrect data to reconfigure, please do a normal configuration\n"
 437             if (grep(/^reconf/,@argvcopy));
 438         $ENV{CROSS_COMPILE} = $configdata::config{cross_compile_prefix}
 439             if defined($configdata::config{cross_compile_prefix});
 440         $ENV{CROSS_COMPILE} = $configdata::config{cc}
 441             if defined($configdata::config{cc});
 442
 443         print "Reconfiguring with: ", join(" ",@argvcopy), "\n";
 444         print "    CROSS_COMPILE = ",$ENV{CROSS_COMPILE},"\n"
 445             if $ENV{CROSS_COMPILE};
 446         print "    CC = ",$ENV{CC},"\n" if $ENV{CC};
 447     } elsif (open IN, "<Makefile") {
 448         #
 449         # THIS SECTION IS TEMPORARY, it helps transitioning from Makefile
 450         # centered information gathering the reading configdata.pm
 451         #
 452         while (<IN>) {
 453             chomp;
 454             if (/^CONFIGURE_ARGS=\s*(.*)\s*/) {
 455                 # Older form, we split the string and hope for the best
 456                 @argvcopy = split /\s+/, $_;
 457                 die "Incorrect data to reconfigure, please do a normal configuration\n"
 458                     if (grep(/^reconf/,@argvcopy));
 459             } elsif (/^CROSS_COMPILE=\s*(.*)/) {
 460                 $ENV{CROSS_COMPILE}=$1;
 461             } elsif (/^CC=\s*(?:\$\(CROSS_COMPILE\))?(.*?)$/) {
 462                 $ENV{CC}=$1;
 463             }
 464         }
 465         #
 466         # END OF TEMPORARY SECTION
 467         #
 468     } else {
 469         die "Insufficient data to reconfigure, please do a normal configuration\n";
 470     }
 471 }
 472
 473 $config{perlargv} = [ @argvcopy ];
 474
 475 my %unsupported_options = ();
 476 foreach (@argvcopy)
 477         {
 478         s /^-no-/no-/; # some people just can't read the instructions
 479
 480         # rewrite some options in "enable-..." form
 481         s /^-?-?shared$/enable-shared/;
 482         s /^sctp$/enable-sctp/;
 483         s /^threads$/enable-threads/;
 484         s /^zlib$/enable-zlib/;
 485         s /^zlib-dynamic$/enable-zlib-dynamic/;
 486
 487         if (/^(no|disable|enable|experimental)-(.+)$/)
 488                 {
 489                 my $word = $2;
 490                 if (!grep { $word =~ /^${_}$/ } @disablables)
 491                         {
 492                         $unsupported_options{$_} = 1;
 493                         next;
 494                         }
 495                 }
 496         if (/^no-(.+)$/ || /^disable-(.+)$/)
 497                 {
 498                 if (!($disabled{$1} eq "experimental"))
 499                         {
 500                         foreach my $proto ((@tls, @dtls))
 501                                 {
 502                                 if ($1 eq "$proto-method")
 503                                         {
 504                                         $disabled{"$proto"} = "option($proto-method)";
 505                                         last;
 506                                         }
 507                                 }
 508                         if ($1 eq "dtls")
 509                                 {
 510                                 foreach my $proto (@dtls)
 511                                         {
 512                                         $disabled{$proto} = "option(dtls)";
 513                                         }
 514                                 }
 515                         elsif ($1 eq "ssl")
 516                                 {
 517                                 # Last one of its kind
 518                                 $disabled{"ssl3"} = "option(ssl)";
 519                                 }
 520                         elsif ($1 eq "tls")
 521                                 {
 522                                 # XXX: Tests will fail if all SSL/TLS
 523                                 # protocols are disabled.
 524                                 foreach my $proto (@tls)
 525                                         {
 526                                         $disabled{$proto} = "option(tls)";
 527                                         }
 528                                 }
 529                         else
 530                                 {
 531                                 $disabled{$1} = "option";
 532                                 }
 533                         }
 534                 }
 535         elsif (/^enable-(.+)$/ || /^experimental-(.+)$/)
 536                 {
 537                 my $algo = $1;
 538                 if ($disabled{$algo} eq "experimental")
 539                         {
 540                         die "You are requesting an experimental feature; please say 'experimental-$algo' if you are sure\n"
 541                                 unless (/^experimental-/);
 542                         push @experimental, $algo;
 543                         }
 544                 delete $disabled{$algo};
 545
 546                 $threads = 1 if ($algo eq "threads");
 547                 }
 548         elsif (/^--strict-warnings$/)
 549                 {
 550                 $strict_warnings = 1;
 551                 }
 552         elsif (/^--debug$/)
 553                 {
 554                 $build_prefix = "debug_";
 555                 }
 556         elsif (/^--release$/)
 557                 {
 558                 $build_prefix = "release_";
 559                 }
 560         elsif (/^386$/)
 561                 { $config{processor}=386; }
 562         elsif (/^fips$/)
 563                 {
 564                 $config{fips}=1;
 565                 }
 566         elsif (/^rsaref$/)
 567                 {
 568                 # No RSAref support any more since it's not needed.
 569                 # The check for the option is there so scripts aren't
 570                 # broken
 571                 }
 572         elsif (/^nofipscanistercheck$/)
 573                 {
 574                 $config{fips} = 1;
 575                 $nofipscanistercheck = 1;
 576                 }
 577         elsif (/^[-+]/)
 578                 {
 579                 if (/^--prefix=(.*)$/)
 580                         {
 581                         $config{prefix}=$1;
 582                         }
 583                 elsif (/^--api=(.*)$/)
 584                         {
 585                         $config{api}=$1;
 586                         }
 587                 elsif (/^--libdir=(.*)$/)
 588                         {
 589                         $config{libdir}=$1;
 590                         }
 591                 elsif (/^--openssldir=(.*)$/)
 592                         {
 593                         $config{openssldir}=$1;
 594                         }
 595                 elsif (/^--install.prefix=(.*)$/)
 596                         {
 597                         $config{install_prefix}=$1;
 598                         }
 599                 elsif (/^--with-zlib-lib=(.*)$/)
 600                         {
 601                         $withargs{zlib_lib}=$1;
 602                         }
 603                 elsif (/^--with-zlib-include=(.*)$/)
 604                         {
 605                         $withargs{zlib_include}="-I$1";
 606                         }
 607                 elsif (/^--with-fipslibdir=(.*)$/)
 608                         {
 609                         $config{fipslibdir}="$1/";
 610                         }
 611                 elsif (/^--with-baseaddr=(.*)$/)
 612                         {
 613                         $config{baseaddr}="$1";
 614                         }
 615                 elsif (/^--cross-compile-prefix=(.*)$/)
 616                         {
 617                         $config{cross_compile_prefix}=$1;
 618                         }
 619                 elsif (/^--config=(.*)$/)
 620                         {
 621                         read_config $1;
 622                         }
 623                 elsif (/^-[lL](.*)$/ or /^-Wl,/)
 624                         {
 625                         $libs.=$_." ";
 626                         }
 627                 else    # common if (/^[-+]/), just pass down...
 628                         {
 629                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 630                         $flags.=$_." ";
 631                         }
 632                 }
 633         elsif ($_ =~ /^([^:]+):(.+)$/)
 634                 {
 635                 eval "\$table{\$1} = \"$2\""; # allow $xxx constructs in the string
 636                 $target=$1;
 637                 }
 638         else
 639                 {
 640                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 641                 $target=$_;
 642                 }
 643         unless ($_ eq $target || /^no-/ || /^disable-/)
 644                 {
 645                 # "no-..." follows later after implied disactivations
 646                 # have been derived.  (Don't take this too seroiusly,
 647                 # we really only write OPTIONS to the Makefile out of
 648                 # nostalgia.)
 649
 650                 if ($config{options} eq "")
 651                         { $config{options} = $_; }
 652                 else
 653                         { $config{options} .= " ".$_; }
 654                 }
 655
 656         if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 657                 die "***** Unsupported api compatibility level: $config{api}\n",
 658         }
 659
 660         if (keys %unsupported_options)
 661                 {
 662                 die "***** Unsupported options: ",
 663                         join(", ", keys %unsupported_options), "\n";
 664                 }
 665         }
 666
 667 if ($config{fips})
 668         {
 669         delete $disabled{"shared"} if ($disabled{"shared"} =~ /^default/);
 670         }
 671 else
 672         {
 673         @{$config{dirs}} = grep !/^fips$/, @{$config{dirs}};
 674         }
 675
 676 my @tocheckfor = (keys %disabled);
 677 while (@tocheckfor) {
 678     my %new_tocheckfor = ();
 679     my @cascade_copy = (@disable_cascades);
 680     while (@cascade_copy) {
 681         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
 682         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
 683             map {
 684                 $new_tocheckfor{$_} => 1; $disabled{$_} = "forced";
 685             } grep { !defined($disabled{$_}) } @$descendents;
 686         }
 687     }
 688     @tocheckfor = (keys %new_tocheckfor);
 689 }
 690
 691 if ($target eq "TABLE") {
 692     foreach (sort keys %table) {
 693         print_table_entry($_, "TABLE");
 694     }
 695     exit 0;
 696 }
 697
 698 if ($target eq "LIST") {
 699     foreach (sort keys %table) {
 700         print $_,"\n" unless $table{$_}->{template};
 701     }
 702     exit 0;
 703 }
 704
 705 if ($target eq "HASH") {
 706     print "%table = (\n";
 707     foreach (sort keys %table) {
 708         print_table_entry($_, "HASH");
 709     }
 710     exit 0;
 711 }
 712
 713 # Backward compatibility?
 714 if ($target =~ m/^CygWin32(-.*)$/) {
 715     $target = "Cygwin".$1;
 716 }
 717
 718 foreach (sort (keys %disabled))
 719         {
 720         $config{options} .= " no-$_";
 721
 722         printf "    no-%-12s %-10s", $_, "[$disabled{$_}]";
 723
 724         if (/^dso$/)
 725                 { $no_dso = 1; }
 726         elsif (/^threads$/)
 727                 { $no_threads = 1; }
 728         elsif (/^shared$/)
 729                 { $config{no_shared} = 1; }
 730         elsif (/^zlib$/)
 731                 { $zlib = 0; }
 732         elsif (/^static-engine$/)
 733                 { }
 734         elsif (/^zlib-dynamic$/)
 735                 { }
 736         elsif (/^sse2$/)
 737                 { $no_sse2 = 1; }
 738         elsif (/^engine$/)
 739                 { @{$config{dirs}} = grep !/^engine$/, @{$config{dirs}}; }
 740         else
 741                 {
 742                 my ($ALGO, $algo);
 743                 ($ALGO = $algo = $_) =~ tr/[\-a-z]/[_A-Z]/;
 744
 745                 if (/^asm$/ || /^err$/ || /^hw$/ || /^hw-/ || /^async$/)
 746                         {
 747                         push @{$config{openssl_other_defines}}, "OPENSSL_NO_$ALGO";
 748                         print " OPENSSL_NO_$ALGO";
 749
 750                         if (/^err$/)    { $flags .= "-DOPENSSL_NO_ERR "; }
 751                         elsif (/^asm$/) { $no_asm = 1; }
 752                         }
 753                 else
 754                         {
 755                         ($ALGO,$algo) = ("RMD160","rmd160") if ($algo eq "ripemd");
 756
 757                         push @{$config{openssl_algorithm_defines}}, "OPENSSL_NO_$ALGO";
 758                         $config{depflags} .= " -DOPENSSL_NO_$ALGO";
 759                         print " OPENSSL_NO_$ALGO";
 760
 761                         # fix-up crypto/directory name(s)
 762                         $algo="whrlpool" if $algo eq "whirlpool";
 763                         $algo="ripemd" if $algo eq "rmd160";
 764                         @{$config{sdirs}} = grep { $_ ne $algo} @{$config{sdirs}};
 765
 766                         print " (skip dir)";
 767                         }
 768                 }
 769
 770         print "\n";
 771         }
 772
 773 my $exp_cflags = "";
 774
 775 foreach (sort @experimental)
 776         {
 777         my $ALGO;
 778         ($ALGO = $_) =~ tr/[a-z]/[A-Z]/;
 779
 780         # opensslconf.h will set OPENSSL_NO_... unless OPENSSL_EXPERIMENTAL_... is defined
 781         push @{$config{openssl_experimental_defines}}, "OPENSSL_NO_$ALGO";
 782         $exp_cflags .= " -DOPENSSL_EXPERIMENTAL_$ALGO";
 783         }
 784
 785 print "Configuring for $target\n";
 786
 787 # Support for legacy targets having a name starting with 'debug-'
 788 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
 789 if ($d) {
 790     $build_prefix = "debug_";
 791
 792     # If we do not find debug-foo in the table, the target is set to foo.
 793     if (!$table{$target}) {
 794         $target = $t;
 795     }
 796 }
 797 $config{target} = $target;
 798 delete $table{$base_target}->{template}; # or the next test will fail.
 799 my %target = ( %{$table{$base_target}}, resolve_config($target) );
 800
 801 &usage if (!%target || $target{template});
 802
 803 $target{exe_extension}="";
 804 $target{exe_extension}=".exe" if ($config{target} eq "Cygwin" || $config{target} eq "DJGPP" || $config{target} =~ /^mingw/);
 805 $target{exe_extension}=".nlm" if ($config{target} =~ /netware/);
 806 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
 807
 808 $default_ranlib = which("ranlib") || "true";
 809 $config{perl}   = $ENV{'PERL'} || which("perl5") || which("perl") || "perl";
 810 my $make        = $ENV{'MAKE'} || "make";
 811
 812 $config{cross_compile_prefix} = $ENV{'CROSS_COMPILE'}
 813     if $config{cross_compile_prefix} eq "";
 814
 815 $config{prefix} = "/usr/local" if !$config{prefix};
 816 $config{openssldir} = "ssl" if !$config{openssldir};
 817 $config{openssldir} = catdir($config{prefix}, $config{openssldir})
 818     unless file_name_is_absolute($config{openssldir});
 819
 820 # Allow environment CC to override compiler...
 821 $target{cc} = $ENV{CC} || $target{cc};
 822
 823 # For cflags, lflags, plib_lflags and ex_libs, add the debug_ or release_
 824 # attributes.
 825 # Do it in such a way that no spurious space is appended (hence the grep).
 826 $config{cflags} = join(" ",
 827                        grep { $_ ne "" } ($target{cflags},
 828                                           $target{$build_prefix."cflags"}));
 829 $config{lflags} = join(" ",
 830                        grep { $_ ne "" } ($target{lflags},
 831                                           $target{$build_prefix."lflags"}));
 832 $config{plib_lflags} = join(" ",
 833                             grep { $_  ne "" } ($target{plib_lflags},
 834                                                 $target{$build_prefix."plib_lflags"}));
 835 $config{ex_libs} = join(" ",
 836                         grep { $_  ne "" } ($target{ex_libs},
 837                                             $target{$build_prefix."ex_libs"}));
 838
 839 $target{ranlib} = $ENV{'RANLIB'} || $target{ranlib} || $default_ranlib;
 840 $target{ar} = $ENV{'AR'} || "ar";
 841 $target{arflags} = "" if !defined($target{arflags});
 842 $target{nm} = "nm";
 843 # Make sure build_scheme is consistent.
 844 $target{build_scheme} = [ $target{build_scheme} ]
 845     if ref($target{build_scheme}) ne "ARRAY";
 846
 847 my ($builder, $builder_platform, @builder_opts) =
 848     @{$target{build_scheme}};
 849
 850 # if $config{prefix}/lib$target{multilib} is not an existing directory, then
 851 # assume that it's not searched by linker automatically, in
 852 # which case adding $target{multilib} suffix causes more grief than
 853 # we're ready to tolerate, so don't...
 854 $target{multilib}="" if !-d "$config{prefix}/lib$target{multilib}";
 855
 856 $config{libdir}="lib$target{multilib}" if $config{libdir} eq "";
 857 $config{enginesdir}=$config{prefix} . "/" . $config{libdir}  . "/engines";
 858
 859 $config{cflags} .= "$exp_cflags";
 860
 861 if ($target =~ /^mingw/ && `$target{cc} --target-help 2>&1` !~ m/-mno-cygwin/m)
 862         {
 863         $config{cflags} =~ s/-mno-cygwin\s*//;
 864         $target{shared_ldflag} =~ s/-mno-cygwin\s*//;
 865         }
 866
 867 if ($target =~ /linux.*-mips/ && !$no_asm && $flags !~ /-m(ips|arch=)/) {
 868         # minimally required architecture flags for assembly modules
 869         $config{cflags}="-mips2 $config{cflags}" if ($target =~ /mips32/);
 870         $config{cflags}="-mips3 $config{cflags}" if ($target =~ /mips64/);
 871 }
 872
 873 my $no_shared_warn=0;
 874 my $no_user_cflags=0;
 875
 876 if ($flags ne "")       { $config{cflags}="$flags$config{cflags}"; }
 877 else                    { $no_user_cflags=1;       }
 878
 879 # The DSO code currently always implements all functions so that no
 880 # applications will have to worry about that from a compilation point
 881 # of view. However, the "method"s may return zero unless that platform
 882 # has support compiled in for them. Currently each method is enabled
 883 # by a define "DSO_<name>" ... we translate the "dso_scheme" config
 884 # string entry into using the following logic;
 885 my $dso_cflags;
 886 if (!$no_dso && $target{dso_scheme} ne "")
 887         {
 888         $target{dso_scheme} =~ tr/[a-z]/[A-Z]/;
 889         if ($target{dso_scheme} eq "DLFCN")
 890                 {
 891                 $dso_cflags = "-DDSO_DLFCN -DHAVE_DLFCN_H";
 892                 }
 893         elsif ($target{dso_scheme} eq "DLFCN_NO_H")
 894                 {
 895                 $dso_cflags = "-DDSO_DLFCN";
 896                 }
 897         else
 898                 {
 899                 $dso_cflags = "-DDSO_$target{dso_scheme}";
 900                 }
 901         $config{cflags} = "$dso_cflags $config{cflags}";
 902         }
 903
 904 my $thread_cflags = "";
 905 my @thread_defines;
 906 if ($target{thread_cflag} ne "(unknown)" && !$no_threads)
 907         {
 908         # If we know how to do it, support threads by default.
 909         $threads = 1;
 910         }
 911 if ($target{thread_cflag} eq "(unknown)" && $threads)
 912         {
 913         # If the user asked for "threads", [s]he is also expected to
 914         # provide any system-dependent compiler options that are
 915         # necessary.
 916         if ($no_user_cflags)
 917                 {
 918                 print "You asked for multi-threading support, but didn't\n";
 919                 print "provide any system-specific compiler options\n";
 920                 exit(1);
 921                 }
 922         $thread_cflags="-DOPENSSL_THREADS" ;
 923         push @thread_defines, "OPENSSL_THREADS";
 924         }
 925 else
 926         {
 927         $thread_cflags="-DOPENSSL_THREADS $target{thread_cflag}";
 928         push @thread_defines, "OPENSSL_THREADS";
 929         }
 930
 931 $config{ex_libs}="$libs$config{ex_libs}" if ($libs ne "");
 932
 933 if ($no_asm)
 934         {
 935         $config{cflags}=~s/-D[BL]_ENDIAN//              if ($config{fips});
 936         }
 937
 938 if ($threads)
 939         {
 940         $config{cflags} = "$thread_cflags $config{cflags}" if $thread_cflags;
 941         push @{$config{openssl_thread_defines}}, @thread_defines;
 942         }
 943
 944 if ($zlib)
 945         {
 946         $config{cflags} = "-DZLIB $config{cflags}";
 947         if (defined($disabled{"zlib-dynamic"}))
 948                 {
 949                 if (defined($withargs{zlib_lib}))
 950                         {
 951                         $config{ex_libs} .= " -L" . $withargs{zlib_lib} . " -lz";
 952                         }
 953                 else
 954                         {
 955                         $config{ex_libs} .= " -lz";
 956                         }
 957                 }
 958         else
 959                 {
 960                 $config{cflags} = "-DZLIB_SHARED $config{cflags}";
 961                 }
 962         }
 963
 964 # With "deprecated" disable all deprecated features.
 965 if (defined($disabled{"deprecated"})) {
 966         $config{api} = $maxapi;
 967 }
 968
 969 if ($target{shared_target} eq "")
 970         {
 971         $no_shared_warn = 1 if !$config{no_shared} && !$config{fips};
 972         $config{no_shared} = 1;
 973         }
 974 if (!$config{no_shared})
 975         {
 976         if ($target{shared_cflag} ne "")
 977                 {
 978                 $config{cflags} = "$target{shared_cflag} -DOPENSSL_PIC $config{cflags}";
 979                 }
 980         }
 981
 982 if ($builder ne "mk1mf")
 983         {
 984         # add {no-}static-engine to options to allow mkdef.pl to work without extra arguments
 985         if ($config{no_shared})
 986                 {
 987                 push @{$config{openssl_other_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
 988                 $config{options}.=" static-engine";
 989                 }
 990         else
 991                 {
 992                 push @{$config{openssl_other_defines}}, "OPENSSL_NO_STATIC_ENGINE";
 993                 $config{options}.=" no-static-engine";
 994                 }
 995         }
 996
 997 #
 998 # Platform fix-ups
 999 #
1000 # Unlike other OSes (like Solaris, Linux, Tru64, IRIX) BSD run-time
1001 # linkers (tested OpenBSD, NetBSD and FreeBSD) "demand" RPATH set on
1002 # .so objects. Apparently application RPATH is not global and does
1003 # not apply to .so linked with other .so. Problem manifests itself
1004 # when libssl.so fails to load libcrypto.so. One can argue that we
1005 # should engrave this into Makefile.shared rules or into BSD-* config
1006 # lines above. Meanwhile let's try to be cautious and pass -rpath to
1007 # linker only when --prefix is not /usr.
1008 if ($target =~ /^BSD-/)
1009         {
1010         $target{shared_ldflag}.=" -Wl,-rpath,\$\$(LIBRPATH)" if ($config{prefix} !~ m|^/usr[/]*$|);
1011         }
1012
1013 if ($target{sys_id} ne "")
1014         {
1015         #$config{cflags}="-DOPENSSL_SYS_$target{sys_id} $config{cflags}";
1016         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1017         }
1018
1019 if ($target{ranlib} eq "")
1020         {
1021         $target{ranlib} = $default_ranlib;
1022         }
1023
1024 if (!$no_asm) {
1025     $target{cpuid_asm_src}=$table{BASE}->{cpuid_asm_src} if ($config{processor} eq "386");
1026     $target{cpuid_asm_src}.=" uplink.c uplink-x86.s" if ($config{cflags} =~ /-DOPENSSL_USE_APPLINK/);
1027
1028     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1029
1030     # bn-586 is the only one implementing bn_*_part_words
1031     $config{cflags}.=" -DOPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1032     $config{cflags}.=" -DOPENSSL_IA32_SSE2" if (!$no_sse2 && $target{bn_asm_src} =~ /86/);
1033
1034     $config{cflags}.=" -DOPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1035     $config{cflags}.=" -DOPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1036     $config{cflags}.=" -DOPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1037
1038     if ($config{fips}) {
1039         push @{$config{openssl_other_defines}}, "OPENSSL_FIPS";
1040     }
1041
1042     if ($target{sha1_asm_src}) {
1043         $config{cflags}.=" -DSHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1044         $config{cflags}.=" -DSHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1045         $config{cflags}.=" -DSHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1046     }
1047     if ($target{md5_asm_src}) {
1048         $config{cflags}.=" -DMD5_ASM";
1049     }
1050     $target{cast_asm_src}=$table{BASE}->{cast_asm_src} if (!$config{no_shared}); # CAST assembler is not PIC
1051     if ($target{rmd160_asm_src}) {
1052         $config{cflags}.=" -DRMD160_ASM";
1053     }
1054     if ($target{aes_asm_src}) {
1055         $config{cflags}.=" -DAES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1056         # aes-ctr.fake is not a real file, only indication that assembler
1057         # module implements AES_ctr32_encrypt...
1058         $config{cflags}.=" -DAES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1059         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1060         $config{cflags}.=" -DAES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1061         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($no_sse2);
1062         $config{cflags}.=" -DVPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1063         $config{cflags}.=" -DBSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1064     }
1065     if ($target{wp_asm_src} =~ /mmx/) {
1066         if ($config{processor} eq "386") {
1067             $target{wp_asm_src}=$table{BASE}->{wp_asm_src};
1068         } elsif (!$disabled{"whirlpool"}) {
1069             $config{cflags}.=" -DWHIRLPOOL_ASM";
1070         }
1071     }
1072     if ($target{modes_asm_src} =~ /ghash-/) {
1073         $config{cflags}.=" -DGHASH_ASM";
1074     }
1075     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1076         $config{cflags}.=" -DECP_NISTZ256_ASM";
1077     }
1078     if ($target{poly1305_asm_src} ne "") {
1079         $config{cflags}.=" -DPOLY1305_ASM";
1080     }
1081 }
1082
1083 # Is the compiler gcc or clang?  $ecc is used below to see if error-checking
1084 # can be turned on.
1085 my $ecc = $target{cc};
1086 my $ccpcc = "$config{cross_compile_prefix}$target{cc}";
1087 $config{makedepprog} = 'makedepend';
1088 open(PIPE, "$ccpcc --version 2>&1 | head -2 |");
1089 while ( <PIPE> ) {
1090     $config{makedepprog} = $ccpcc if /clang|gcc/;
1091     $ecc = "clang" if /clang/;
1092     $ecc = "gcc" if /gcc/;
1093 }
1094 close(PIPE);
1095
1096 $config{depflags} =~ s/^\s*//;
1097
1098
1099 # Deal with bn_ops ###################################################
1100
1101 $config{bn_ll}                  =0;
1102 $config{export_var_as_fn}       =0;
1103 my $def_int="unsigned int";
1104 $config{rc4_int}                =$def_int;
1105 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1106
1107 my $count = 0;
1108 foreach (sort split(/\s+/,$target{bn_ops})) {
1109     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1110     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1111     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1112     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1113     ($config{b64l},$config{b64},$config{b32})
1114         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1115     ($config{b64l},$config{b64},$config{b32})
1116         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1117     ($config{b64l},$config{b64},$config{b32})
1118         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1119 }
1120 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1121     if $count > 1;
1122
1123
1124 # Hack cflags for better warnings (dev option) #######################
1125
1126 # "Stringify" the C flags string.  This permits it to be made part of a string
1127 # and works as well on command lines.
1128 $config{cflags} =~ s/([\\\"])/\\\1/g;
1129
1130 if (defined($config{api})) {
1131     $config{openssl_api_defines} = [ "OPENSSL_MIN_API=".$apitable->{$config{api}} ];
1132     my $apiflag = sprintf("-DOPENSSL_API_COMPAT=%s", $apitable->{$config{api}});
1133     $default_depflags .= " $apiflag";
1134     $config{cflags} .= " $apiflag";
1135 }
1136
1137 if ($strict_warnings)
1138         {
1139         my $wopt;
1140         die "ERROR --strict-warnings requires gcc or clang"
1141             unless $ecc eq 'gcc' || $ecc eq 'clang';
1142         foreach $wopt (split /\s+/, $gcc_devteam_warn)
1143                 {
1144                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(^|\s)$wopt(\s|$)/)
1145                 }
1146         if ($ecc eq "clang")
1147                 {
1148                 foreach $wopt (split /\s+/, $clang_devteam_warn)
1149                         {
1150                         $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(^|\s)$wopt(\s|$)/)
1151                         }
1152                 }
1153         if ($target !~ /^mingw/)
1154                 {
1155                 foreach $wopt (split /\s+/, $memleak_devteam_backtrace)
1156                         {
1157                         $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(^|\s)$wopt(\s|$)/)
1158                         }
1159                 if ($target =~ /^BSD-/)
1160                         {
1161                         $config{ex_libs} .= " -lexecinfo";
1162                         }
1163                 }
1164         }
1165
1166 # If we use the unified build, collect information from build.info files
1167 my %unified_info = ();
1168
1169 if ($builder eq "unified") {
1170     # Store the name of the template file we will build the build file from
1171     # in %config.  This may be useful for the build file itself.
1172     my $build_file_template =
1173         catfile($srcdir, "Configurations",
1174                 $builder_platform."-".$target{build_file}.".tmpl");
1175     $build_file_template =
1176         catfile($srcdir, "Configurations", $target{build_file}.".tmpl")
1177         if (! -f $build_file_template);
1178     $config{build_file_template} = $build_file_template;
1179
1180     use lib catdir(dirname(__FILE__),"util");
1181     use with_fallback qw(Text::Template);
1182
1183     # Helpers to produce clean paths with no /../ in the middle and so on.
1184     sub int_absolutedir {
1185         my $dir = shift;
1186
1187         # Required, because realpath only works properly with existing dirs
1188         mkpath($dir);
1189
1190         my $res = realpath($dir);
1191         return $res;
1192     }
1193
1194     sub cleandir {
1195         my $dir = shift;
1196         my $base = shift || ".";
1197
1198         my $res = abs2rel(int_absolutedir($dir), rel2abs($base));
1199         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1200         return $res;
1201     }
1202
1203     sub cleanfile {
1204         my $file = shift;
1205         my $base = shift || ".";
1206         my $d = dirname($file);
1207         my $f = basename($file);
1208
1209         my $res = abs2rel(catfile(int_absolutedir($d), $f), rel2abs($base));
1210         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1211         return $res;
1212     }
1213
1214     my @build_infos = ( [ ".", "build.info" ] );
1215     foreach (@{$config{dirs}}) {
1216         push @build_infos, [ $_, "build.info" ]
1217             if (-f catfile($srcdir, $_, "build.info"));
1218     }
1219     foreach (@{$config{sdirs}}) {
1220         push @build_infos, [ catdir("crypto", $_), "build.info" ]
1221             if (-f catfile($srcdir, "crypto", $_, "build.info"));
1222     }
1223     foreach (@{$config{engdirs}}) {
1224         push @build_infos, [ catdir("engines", $_), "build.info" ]
1225             if (-f catfile($srcdir, "engines", $_, "build.info"));
1226     }
1227
1228     foreach (@build_infos) {
1229         my $sourced = catdir($srcdir, $_->[0]);
1230         my $buildd = catdir($blddir, $_->[0]);
1231
1232         mkpath($buildd);
1233
1234         my $f = $_->[1];
1235         # The basic things we're trying to build
1236         my @programs = ();
1237         my @libraries = ();
1238         my @engines = ();
1239         my @scripts = ();
1240         my @extra = ();
1241         my @intermediates = ();
1242         my @rawlines = ();
1243
1244         my %ordinals = ();
1245         my %sources = ();
1246         my %includes = ();
1247         my %depends = ();
1248         my %renames = ();
1249         my %sharednames = ();
1250
1251         my $template = Text::Template->new(TYPE => 'FILE',
1252                                            SOURCE => catfile($sourced, $f));
1253         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1254         my @text =
1255             split /^/m,
1256             $template->fill_in(HASH => { config => \%config,
1257                                          target => \%target,
1258                                          builddir => abs2rel($buildd, $blddir),
1259                                          sourcedir => abs2rel($sourced, $blddir),
1260                                          buildtop => abs2rel($blddir, $blddir),
1261                                          sourcetop => abs2rel($srcdir, $blddir) },
1262                                DELIMITERS => [ "{-", "-}" ]);
1263
1264         # The top item of this stack has the following values
1265         # -2 positive already run and we found ELSE (following ELSIF should fail)
1266         # -1 positive already run (skip until ENDIF)
1267         # 0 negatives so far (if we're at a condition, check it)
1268         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1269         # 2 positive ELSE (following ELSIF should fail)
1270         my @skip = ();
1271         collect_information(
1272             collect_from_array([ @text ],
1273                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1274                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1275             # Info we're looking for
1276             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1277             => sub { push @skip, !! $1; },
1278             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1279             => sub { die "ELSIF out of scope" if ! @skip;
1280                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1281                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1282                      $skip[$#skip] = !! $1
1283                          if $skip[$#skip] == 0; },
1284             qr/^\s*ELSE\s*$/
1285             => sub { die "ELSE out of scope" if ! @skip;
1286                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1287                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1288             qr/^\s*ENDIF\s*$/
1289             => sub { die "ENDIF out of scope" if ! @skip;
1290                      pop @skip; },
1291             qr/^\s*PROGRAMS\s*=\s*(.*)\s*$/
1292             => sub { push @programs, split(/\s+/, $1)
1293                          if !@skip || $skip[$#skip] > 0 },
1294             qr/^\s*LIBS\s*=\s*(.*)\s*$/
1295             => sub { push @libraries, split(/\s+/, $1)
1296                          if !@skip || $skip[$#skip] > 0 },
1297             qr/^\s*ENGINES\s*=\s*(.*)\s*$/
1298             => sub { push @engines, split(/\s+/, $1)
1299                          if !@skip || $skip[$#skip] > 0 },
1300             qr/^\s*SCRIPTS\s*=\s*(.*)\s*$/
1301             => sub { push @scripts, split(/\s+/, $1)
1302                          if !@skip || $skip[$#skip] > 0 },
1303             qr/^\s*EXTRA\s*=\s*(.*)\s*$/
1304             => sub { push @extra, split(/\s+/, $1)
1305                          if !@skip || $skip[$#skip] > 0 },
1306
1307             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1308             => sub { push @{$ordinals{$1}}, split(/\s+/, $2)
1309                          if !@skip || $skip[$#skip] > 0 },
1310             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1311             => sub { push @{$sources{$1}}, split(/\s+/, $2)
1312                          if !@skip || $skip[$#skip] > 0 },
1313             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1314             => sub { push @{$includes{$1}}, split(/\s+/, $2)
1315                          if !@skip || $skip[$#skip] > 0 },
1316             qr/^\s*DEPEND\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1317             => sub { push @{$depends{$1}}, split(/\s+/, $2)
1318                          if !@skip || $skip[$#skip] > 0 },
1319             qr/^\s*RENAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1320             => sub { push @{$renames{$1}}, split(/\s+/, $2)
1321                          if !@skip || $skip[$#skip] > 0 },
1322             qr/^\s*SHARED_NAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1323             => sub { push @{$sharednames{$1}}, split(/\s+/, $2)
1324                          if !@skip || $skip[$#skip] > 0 },
1325             qr/^\s*BEGINRAW\[((?:\\.|[^\\\]])+)\]\s*$/
1326             => sub {
1327                 my $lineiterator = shift;
1328                 my $target_kind = $1;
1329                 while (defined $lineiterator->()) {
1330                     chomp;
1331                     if (/^\s*ENDRAW\[((?:\\.|[^\\\]])+)\]\s*$/) {
1332                         die "ENDRAW doesn't match BEGINRAW"
1333                             if $1 ne $target_kind;
1334                         last;
1335                     }
1336                     next if @skip && $skip[$#skip] <= 0;
1337                     push @rawlines,  $_
1338                         if ($target_kind eq $target{build_file}
1339                             || $target_kind eq $target{build_file}."(".$builder_platform.")");
1340                 }
1341             },
1342             qr/^(?:#.*|\s*)$/ => sub { },
1343             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" }
1344             );
1345         die "runaway IF?" if (@skip);
1346
1347         foreach (keys %renames) {
1348             die "$_ renamed to more than one thing: "
1349                 ,join(" ", @{$renames{$_}}),"\n"
1350                 if scalar @{$renames{$_}} > 1;
1351             my $dest = cleanfile(catfile($buildd, $_), $blddir);
1352             my $to = cleanfile(catfile($buildd, $renames{$_}->[0]), $blddir);
1353             die "$dest renamed to more than one thing: "
1354                 ,$unified_info{rename}->{$dest}, $to
1355                 unless !defined($unified_info{rename}->{$dest})
1356                 or $unified_info{rename}->{$dest} eq $to;
1357             $unified_info{rename}->{$dest} = $to;
1358         }
1359
1360         foreach (@programs) {
1361             my $program = cleanfile(catfile($buildd, $_), $blddir);
1362             if ($unified_info{rename}->{$program}) {
1363                 $program = $unified_info{rename}->{$program};
1364             }
1365             $unified_info{programs}->{$program} = 1;
1366         }
1367
1368         foreach (@libraries) {
1369             my $library = cleanfile(catfile($buildd, $_), $blddir);
1370             if ($unified_info{rename}->{$library}) {
1371                 $library = $unified_info{rename}->{$library};
1372             }
1373             $unified_info{libraries}->{$library} = 1;
1374         }
1375
1376         die <<"EOF" if $config{no_shared} && scalar @engines;
1377 ENGINES can only be used if configured with 'shared'.
1378 This is usually a fault in a build.info file.
1379 EOF
1380         foreach (@engines) {
1381             my $library = cleanfile(catfile($buildd, $_), $blddir);
1382             if ($unified_info{rename}->{$library}) {
1383                 $library = $unified_info{rename}->{$library};
1384             }
1385             $unified_info{engines}->{$library} = 1;
1386         }
1387
1388         foreach (@scripts) {
1389             my $script = cleanfile(catfile($buildd, $_), $blddir);
1390             if ($unified_info{rename}->{$script}) {
1391                 $script = $unified_info{rename}->{$script};
1392             }
1393             $unified_info{scripts}->{$script} = 1;
1394         }
1395
1396         foreach (@extra) {
1397             my $extra = cleanfile(catfile($buildd, $_), $blddir);
1398             $unified_info{extra}->{$extra} = 1;
1399         }
1400
1401         push @{$unified_info{rawlines}}, @rawlines;
1402
1403         if (!$config{no_shared}) {
1404             # Check sharednames.
1405             foreach (keys %sharednames) {
1406                 my $dest = cleanfile(catfile($buildd, $_), $blddir);
1407                 if ($unified_info{rename}->{$dest}) {
1408                     $dest = $unified_info{rename}->{$dest};
1409                 }
1410                 die "shared_name for $dest with multiple values: "
1411                     ,join(" ", @{$sharednames{$_}}),"\n"
1412                     if scalar @{$sharednames{$_}} > 1;
1413                 my $to = cleanfile(catfile($buildd, $sharednames{$_}->[0]),
1414                                    $blddir);
1415                 die "shared_name found for a library $dest that isn't defined\n"
1416                     unless $unified_info{libraries}->{$dest};
1417                 die "shared_name for $dest with multiple values: "
1418                     ,$unified_info{sharednames}->{$dest}, ", ", $to
1419                     unless !defined($unified_info{sharednames}->{$dest})
1420                     or $unified_info{sharednames}->{$dest} eq $to;
1421                 $unified_info{sharednames}->{$dest} = $to;
1422             }
1423
1424             # Additionally, we set up sharednames for libraries that don't
1425             # have any, as themselves.
1426             foreach (keys %{$unified_info{libraries}}) {
1427                 if (!defined $unified_info{sharednames}->{$_}) {
1428                     $unified_info{sharednames}->{$_} = $_
1429                 }
1430             }
1431         }
1432
1433         foreach (keys %ordinals) {
1434             my $dest = $_;
1435             my $ddest = cleanfile(catfile($buildd, $_), $blddir);
1436             if ($unified_info{rename}->{$ddest}) {
1437                 $ddest = $unified_info{rename}->{$ddest};
1438             }
1439             foreach (@{$ordinals{$dest}}) {
1440                 my %known_ordinals =
1441                     (
1442                      crypto =>
1443                      cleanfile(catfile($sourced, "util", "libeay.num"), $blddir),
1444                      ssl =>
1445                      cleanfile(catfile($sourced, "util", "ssleay.num"), $blddir)
1446                     );
1447                 my $o = $known_ordinals{$_};
1448                 die "Ordinals for $ddest defined more than once\n"
1449                     if $unified_info{ordinals}->{$ddest};
1450                 $unified_info{ordinals}->{$ddest} = [ $_, $o ];
1451             }
1452         }
1453
1454         foreach (keys %sources) {
1455             my $dest = $_;
1456             my $ddest = cleanfile(catfile($buildd, $_), $blddir);
1457             if ($unified_info{rename}->{$ddest}) {
1458                 $ddest = $unified_info{rename}->{$ddest};
1459             }
1460             foreach (@{$sources{$dest}}) {
1461                 my $s = cleanfile(catfile($sourced, $_), $blddir);
1462
1463                 # If it isn't in the source tree, we assume it's generated
1464                 # in the build tree
1465                 if (! -f $s) {
1466                     $s = cleanfile(catfile($buildd, $_), $blddir);
1467                 }
1468                 # We recognise C and asm files
1469                 if ($s =~ /\.[csS]\b$/) {
1470                     (my $o = $_) =~ s/\.[csS]\b$/.o/;
1471                     $o = cleanfile(catfile($buildd, $o), $blddir);
1472                     $unified_info{sources}->{$ddest}->{$o} = 1;
1473                     $unified_info{sources}->{$o}->{$s} = 1;
1474                 } else {
1475                     $unified_info{sources}->{$ddest}->{$s} = 1;
1476                 }
1477             }
1478         }
1479
1480         foreach (keys %depends) {
1481             my $dest = $_;
1482             my $ddest = cleanfile(catfile($buildd, $_), $blddir);
1483             if ($unified_info{rename}->{$ddest}) {
1484                 $ddest = $unified_info{rename}->{$ddest};
1485             }
1486             foreach (@{$depends{$dest}}) {
1487                 my $d = cleanfile(catfile($sourced, $_), $blddir);
1488
1489                 # If it isn't found in the source, let's assume it's generated
1490                 # and that the Makefile template has the lines
1491                 if (! -f $d) {
1492                     $d = cleanfile(catfile($buildd, $_), $blddir);
1493                 }
1494                 # Take note if the file to depend on is being renamed
1495                 if ($unified_info{rename}->{$d}) {
1496                     $d = $unified_info{rename}->{$d};
1497                 }
1498                 $unified_info{depends}->{$ddest}->{$d} = 1;
1499                 # If we depend on a header file, let's make sure it
1500                 # can get included
1501                 if ($d =~ /\.h$/) {
1502                     my $i = dirname($d);
1503                     push @{$unified_info{includes}->{$ddest}}, $i
1504                         unless grep { $_ eq $i } @{$unified_info{includes}->{$ddest}};
1505                 }
1506             }
1507         }
1508
1509         foreach (keys %includes) {
1510             my $dest = $_;
1511             my $ddest = cleanfile(catfile($buildd, $_), $blddir);
1512             if ($unified_info{rename}->{$ddest}) {
1513                 $ddest = $unified_info{rename}->{$ddest};
1514             }
1515             foreach (@{$includes{$dest}}) {
1516                 my $i = cleandir(catdir($sourced, $_), $blddir);
1517                 push @{$unified_info{includes}->{$ddest}}, $i
1518                     unless grep { $_ eq $i } @{$unified_info{includes}->{$ddest}};
1519             }
1520         }
1521     }
1522
1523     ### Make unified_info a bit more efficient
1524     # One level structures
1525     foreach (("programs", "libraries", "engines", "scripts", "extra")) {
1526         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
1527     }
1528     # Two level structures
1529     foreach my $l1 (("sources", "ldadd", "depends")) {
1530         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
1531             $unified_info{$l1}->{$l2} =
1532                 [ sort keys %{$unified_info{$l1}->{$l2}} ];
1533         }
1534     }
1535 }
1536
1537 # For the schemes that need it, we provide the old *_obj configs
1538 # from the *_asm_obj ones
1539 foreach (grep /_asm_src$/, keys %target) {
1540     my $src = $_;
1541     (my $obj = $_) =~ s/_asm_src$/_obj/;
1542     ($target{$obj} = $target{$src}) =~ s/\.[csS]\b/.o/g;
1543 }
1544
1545 # Write down our configuration where it fits #########################
1546
1547 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
1548 print OUT <<"EOF";
1549 package configdata;
1550
1551 use strict;
1552 use warnings;
1553
1554 use Exporter;
1555 #use vars qw(\@ISA \@EXPORT);
1556 our \@ISA = qw(Exporter);
1557 our \@EXPORT = qw(\%config \%target %withargs %unified_info);
1558
1559 EOF
1560 print OUT "our %config = (\n";
1561 foreach (sort keys %config) {
1562     if (ref($config{$_}) eq "ARRAY") {
1563         print OUT "  ", $_, " => [ ", join(", ",
1564                                            map { quotify("perl", $_) }
1565                                            @{$config{$_}}), " ],\n";
1566     } else {
1567         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
1568     }
1569 }
1570 print OUT <<"EOF";
1571 );
1572
1573 EOF
1574 print OUT "our %target = (\n";
1575 foreach (sort keys %target) {
1576     if (ref($target{$_}) eq "ARRAY") {
1577         print OUT "  ", $_, " => [ ", join(", ",
1578                                            map { quotify("perl", $_) }
1579                                            @{$target{$_}}), " ],\n";
1580     } else {
1581         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
1582     }
1583 }
1584 print OUT <<"EOF";
1585 );
1586
1587 EOF
1588 print OUT "our \%available_protocols = (\n";
1589 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
1590 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
1591 print OUT <<"EOF";
1592 );
1593
1594 EOF
1595 print OUT "our \%disabled = (\n";
1596 foreach (sort keys %disabled) {
1597     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
1598 }
1599 print OUT <<"EOF";
1600 );
1601
1602 EOF
1603 print OUT "our %withargs = (\n";
1604 foreach (sort keys %withargs) {
1605     if (ref($withargs{$_}) eq "ARRAY") {
1606         print OUT "  ", $_, " => [ ", join(", ",
1607                                            map { quotify("perl", $_) }
1608                                            @{$withargs{$_}}), " ],\n";
1609     } else {
1610         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
1611     }
1612 }
1613 print OUT <<"EOF";
1614 );
1615
1616 EOF
1617 if ($builder eq "unified") {
1618     my $recurse;
1619     $recurse = sub {
1620         my $indent = shift;
1621         foreach (@_) {
1622             if (ref $_ eq "ARRAY") {
1623                 print OUT " "x$indent, "[\n";
1624                 foreach (@$_) {
1625                     $recurse->($indent + 4, $_);
1626                 }
1627                 print OUT " "x$indent, "],\n";
1628             } elsif (ref $_ eq "HASH") {
1629                 my %h = %$_;
1630                 print OUT " "x$indent, "{\n";
1631                 foreach (sort keys %h) {
1632                     if (ref $h{$_} eq "") {
1633                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
1634                     } else {
1635                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
1636                         $recurse->($indent + 8, $h{$_});
1637                     }
1638                 }
1639                 print OUT " "x$indent, "},\n";
1640             } else {
1641                 print OUT " "x$indent, quotify("perl", $_), ",\n";
1642             }
1643         }
1644     };
1645     print OUT "our %unified_info = (\n";
1646     foreach (sort keys %unified_info) {
1647         if (ref $unified_info{$_} eq "") {
1648             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
1649         } else {
1650             print OUT " "x4, quotify("perl", $_), " =>\n";
1651             $recurse->(8, $unified_info{$_});
1652         }
1653     }
1654     print OUT <<"EOF";
1655 );
1656
1657 EOF
1658 }
1659 print OUT "1;\n";
1660 close(OUT);
1661
1662 die <<"EOF" if $builder ne "unified" && $srcdir ne $blddir;
1663
1664 ***** Trying building anywhere else than in the source tree will not
1665 ***** work for target $config{target}.  To make it possible, it needs
1666 ***** to use the "unified" build scheme.
1667
1668 EOF
1669
1670 print "IsMK1MF       =", ($builder eq "mk1mf" ? "yes" : "no"), "\n";
1671 print "CC            =$target{cc}\n";
1672 print "CFLAG         =$config{cflags}\n";
1673 print "LFLAG         =$config{lflags}\n";
1674 print "PLIB_LFLAG    =$config{plib_lflags}\n";
1675 print "EX_LIBS       =$config{ex_libs}\n";
1676 print "CPUID_OBJ     =$target{cpuid_obj}\n";
1677 print "BN_ASM        =$target{bn_obj}\n";
1678 print "EC_ASM        =$target{ec_obj}\n";
1679 print "DES_ENC       =$target{des_obj}\n";
1680 print "AES_ENC       =$target{aes_obj}\n";
1681 print "BF_ENC        =$target{bf_obj}\n";
1682 print "CAST_ENC      =$target{cast_obj}\n";
1683 print "RC4_ENC       =$target{rc4_obj}\n";
1684 print "RC5_ENC       =$target{rc5_obj}\n";
1685 print "MD5_OBJ_ASM   =$target{md5_obj}\n";
1686 print "SHA1_OBJ_ASM  =$target{sha1_obj}\n";
1687 print "RMD160_OBJ_ASM=$target{rmd160_obj}\n";
1688 print "CMLL_ENC      =$target{cmll_obj}\n";
1689 print "MODES_OBJ     =$target{modes_obj}\n";
1690 print "PADLOCK_OBJ   =$target{padlock_obj}\n";
1691 print "CHACHA_ENC    =$target{chacha_obj}\n";
1692 print "POLY1305_OBJ  =$target{poly1305_obj}\n";
1693 print "PROCESSOR     =$config{processor}\n";
1694 print "RANLIB        =$target{ranlib}\n";
1695 print "ARFLAGS       =$target{arflags}\n";
1696 print "PERL          =$config{perl}\n";
1697 print "\n";
1698 print "SIXTY_FOUR_BIT_LONG mode\n" if $config{b64l};
1699 print "SIXTY_FOUR_BIT mode\n" if $config{b64};
1700 print "THIRTY_TWO_BIT mode\n" if $config{b32};
1701 print "BN_LLONG mode\n" if $config{bn_ll};
1702 print "RC4 uses $config{rc4_int}\n" if $config{rc4_int} != $def_int;
1703
1704 mkpath(catdir($blddir, "include/openssl"));
1705 run_dofile(catfile($blddir, "include/openssl/opensslconf.h"),
1706            catfile($srcdir, "include/openssl/opensslconf.h.in"));
1707
1708 mkpath(catdir($blddir, "crypto/include/internal"));
1709 foreach my $alg ( 'bn' ) {
1710     run_dofile(catfile($blddir, "crypto/include/internal/${alg}_conf.h"),
1711                catfile($srcdir, "crypto/include/internal/${alg}_conf.h.in"));
1712 }
1713
1714 ###
1715 ### When the old "unixmake" scheme goes away, so does this function
1716 ###
1717 sub build_Makefile {
1718     run_dofile("Makefile","Makefile.in");
1719
1720     # Copy all Makefile.in to Makefile (except top-level)
1721     use File::Find;
1722     use IO::File;
1723     find(
1724         {
1725             preprocess => sub {
1726                 grep(!/^\./, @_);
1727             },
1728             wanted => sub {
1729                 return if ($_ ne "Makefile.in" || $File::Find::dir eq ".");
1730                 my $in = IO::File->new($_, "r") or
1731                     die sprintf "Error reading Makefile.in in %s: !$\n",
1732                     $File::Find::dir;
1733                 my $out = IO::File->new("Makefile", "w") or
1734                     die sprintf "Error writing Makefile in %s: !$\n",
1735                     $File::Find::dir;
1736                 print $out "# Generated from $_, do not edit\n";
1737                 while (my $line = <$in>) { print $out $line }
1738                 $in->close() or
1739                     die sprintf "Error reading Makefile.in in %s: !$\n",
1740                     $File::Find::dir;
1741                 $out->close() or
1742                     die sprintf "Error writing Makefile in %s: !$\n",
1743                     $File::Find::dir;
1744             },
1745         },
1746         ".");
1747 }
1748
1749 my %builders = (
1750     unified => sub {
1751         run_dofile(catfile($blddir, $target{build_file}),
1752                    $config{build_file_template},
1753                    catfile($srcdir, "Configurations", "common.tmpl"));
1754
1755         my $make_command = "$make PERL=\'$config{perl}\'";
1756         my $make_targets = "";
1757         $make_targets .= " depend"
1758             if $config{depflags} ne $default_depflags && $make_depend;
1759         (system $make_command.$make_targets) == 0
1760             or die "make $make_targets failed"
1761             if $make_targets ne "";
1762         if ($config{depflags} ne $default_depflags && !$make_depend) {
1763             $warn_make_depend++;
1764         }
1765     },
1766     unixmake => sub {
1767         build_Makefile();
1768
1769         run_dofile("util/domd", "util/domd.in");
1770         chmod 0755, "util/domd";
1771
1772         my $make_command = "$make PERL=\'$config{perl}\'";
1773         my $make_targets = "";
1774         $make_targets .= " depend"
1775             if $config{depflags} ne $default_depflags && $make_depend;
1776         (system $make_command.$make_targets) == 0
1777             or die "make $make_targets failed"
1778             if $make_targets ne "";
1779
1780         if ($config{depflags} ne $default_depflags && !$make_depend) {
1781             $warn_make_depend++;
1782         }
1783     },
1784     mk1mf => sub {
1785         my $platform = shift;
1786         # The only reason we do this is to have something to build MINFO from
1787         build_Makefile();
1788
1789         open (OUT,">crypto/buildinf.h") || die "Can't open buildinf.h";
1790         printf OUT <<"EOF";
1791 #ifndef MK1MF_BUILD
1792   /* auto-generated by Configure for crypto/cversion.c:
1793    * for Unix builds, crypto/Makefile.ssl generates functional definitions;
1794    * Windows builds (and other mk1mf builds) compile cversion.c with
1795    * -DMK1MF_BUILD and use definitions added to this file by util/mk1mf.pl. */
1796   #error "Windows builds (PLATFORM=$target) use mk1mf.pl-created Makefiles"
1797 #endif
1798 EOF
1799         close(OUT);
1800
1801         # create the ms/version32.rc file if needed
1802         if ($platform eq "netware") {
1803             my ($v1, $v2, $v3, $v4);
1804             if ($config{version_num} =~ /^0x([0-9a-f]{1})([0-9a-f]{2})([0-9a-f]{2})([0-9a-f]{2})([0-9a-f]{1})L$/i) {
1805                 $v1=hex $1;
1806                 $v2=hex $2;
1807                 $v3=hex $3;
1808                 $v4=hex $4;
1809             }
1810             open (OUT,">ms/version32.rc") || die "Can't open ms/version32.rc";
1811             print OUT <<"EOF";
1812 #include <winver.h>
1813
1814 LANGUAGE 0x09,0x01
1815
1816 1 VERSIONINFO
1817   FILEVERSION $v1,$v2,$v3,$v4
1818   PRODUCTVERSION $v1,$v2,$v3,$v4
1819   FILEFLAGSMASK 0x3fL
1820 #ifdef _DEBUG
1821   FILEFLAGS 0x01L
1822 #else
1823   FILEFLAGS 0x00L
1824 #endif
1825   FILEOS VOS__WINDOWS32
1826   FILETYPE VFT_DLL
1827   FILESUBTYPE 0x0L
1828 BEGIN
1829     BLOCK "StringFileInfo"
1830     BEGIN
1831         BLOCK "040904b0"
1832         BEGIN
1833             // Required:
1834             VALUE "CompanyName", "The OpenSSL Project, http://www.openssl.org/\\0"
1835             VALUE "FileDescription", "OpenSSL Shared Library\\0"
1836             VALUE "FileVersion", "$config{version}\\0"
1837 #if defined(CRYPTO)
1838             VALUE "InternalName", "libeay32\\0"
1839             VALUE "OriginalFilename", "libeay32.dll\\0"
1840 #elif defined(SSL)
1841             VALUE "InternalName", "ssleay32\\0"
1842             VALUE "OriginalFilename", "ssleay32.dll\\0"
1843 #endif
1844             VALUE "ProductName", "The OpenSSL Toolkit\\0"
1845             VALUE "ProductVersion", "$config{version}\\0"
1846             // Optional:
1847             //VALUE "Comments", "\\0"
1848             VALUE "LegalCopyright", "Copyright © 1998-2015 The OpenSSL Project. Copyright © 1995-1998 Eric A. Young, Tim J. Hudson. All rights reserved.\\0"
1849             //VALUE "LegalTrademarks", "\\0"
1850             //VALUE "PrivateBuild", "\\0"
1851             //VALUE "SpecialBuild", "\\0"
1852         END
1853     END
1854     BLOCK "VarFileInfo"
1855     BEGIN
1856         VALUE "Translation", 0x409, 0x4b0
1857     END
1858 END
1859 EOF
1860             close(OUT);
1861         }
1862     },
1863     );
1864
1865 $builders{$builder}->($builder_platform, @builder_opts);
1866
1867 print <<"EOF";
1868
1869 Configured for $target.
1870 EOF
1871
1872 print <<"EOF" if (!$no_threads && !$threads);
1873
1874 The library could not be configured for supporting multi-threaded
1875 applications as the compiler options required on this system are not known.
1876 See file INSTALL for details if you need multi-threading.
1877 EOF
1878
1879 print <<"EOF" if ($no_shared_warn);
1880
1881 You gave the option 'shared', which is not supported on this platform, so
1882 we will pretend you gave the option 'no-shared'.  If you know how to implement
1883 shared libraries, please let us know (but please first make sure you have
1884 tried with a current version of OpenSSL).
1885 EOF
1886
1887 print <<"EOF" if ($warn_make_depend);
1888
1889 *** Because of configuration changes, you MUST do the following before
1890 *** building:
1891
1892         make depend
1893 EOF
1894
1895 exit(0);
1896
1897 ######################################################################
1898 #
1899 # Helpers and utility functions
1900 #
1901
1902 # Configuration file reading #########################################
1903
1904 # Helper function to implement conditional inheritance depending on the
1905 # value of $no_asm.  Used in inherit_from values as follows:
1906 #
1907 #      inherit_from => [ "template", asm("asm_tmpl") ]
1908 #
1909 sub asm {
1910     my @x = @_;
1911     sub {
1912         $no_asm ? () : @x;
1913     }
1914 }
1915
1916 # Helper function to implement adding values to already existing configuration
1917 # values.  It handles elements that are ARRAYs, CODEs and scalars
1918 sub _add {
1919     my $separator = shift;
1920
1921     # If there's any ARRAY in the collection of values, we will return
1922     # an ARRAY of combined values, otherwise a string of joined values
1923     # with $separator as the separator.
1924     my $found_array = 0;
1925
1926     my @values =
1927         map {
1928             if (ref($_) eq "ARRAY") {
1929                 $found_array = 1;
1930                 @$_;
1931             } else {
1932                 $_;
1933             }
1934     } (@_);
1935
1936     if ($found_array) {
1937         [ @values ];
1938     } else {
1939         join($separator, @values);
1940     }
1941 }
1942 sub add_before {
1943     my $separator = shift;
1944     my @x = @_;
1945     sub { _add($separator, @x, @_) };
1946 }
1947 sub add {
1948     my $separator = shift;
1949     my @x = @_;
1950     sub { _add($separator, @_, @x) };
1951 }
1952
1953 # configuration reader, evaluates the input file as a perl script and expects
1954 # it to fill %targets with target configurations.  Those are then added to
1955 # %table.
1956 sub read_config {
1957     my $fname = shift;
1958     open(CONFFILE, "< $fname")
1959         or die "Can't open configuration file '$fname'!\n";
1960     my $x = $/;
1961     undef $/;
1962     my $content = <CONFFILE>;
1963     $/ = $x;
1964     close(CONFFILE);
1965     my %targets = ();
1966     {
1967         local %table = %::table;    # Protect %table from tampering
1968
1969         eval $content;
1970         warn $@ if $@;
1971     }
1972
1973     # For each target, check that it's configured with a hash table.
1974     foreach (keys %targets) {
1975         if (ref($targets{$_}) ne "HASH") {
1976             if (ref($targets{$_}) eq "") {
1977                 warn "Deprecated target configuration for $_, ignoring...\n";
1978             } else {
1979                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
1980             }
1981             delete $targets{$_};
1982         }
1983     }
1984
1985     %table = (%table, %targets);
1986
1987 }
1988
1989 # configuration resolver.  Will only resolve all the lazy evalutation
1990 # codeblocks for the chozen target and all those it inherits from,
1991 # recursively
1992 sub resolve_config {
1993     my $target = shift;
1994     my @breadcrumbs = @_;
1995
1996     if (grep { $_ eq $target } @breadcrumbs) {
1997         die "inherit_from loop!  target backtrace:\n  "
1998             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
1999     }
2000
2001     if (!defined($table{$target})) {
2002         warn "Warning! target $target doesn't exist!\n";
2003         return ();
2004     }
2005     # Recurse through all inheritances.  They will be resolved on the
2006     # fly, so when this operation is done, they will all just be a
2007     # bunch of attributes with string values.
2008     # What we get here, though, are keys with references to lists of
2009     # the combined values of them all.  We will deal with lists after
2010     # this stage is done.
2011     my %combined_inheritance = ();
2012     if ($table{$target}->{inherit_from}) {
2013         my @inherit_from =
2014             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2015         foreach (@inherit_from) {
2016             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2017
2018             # 'template' is a marker that's considered private to
2019             # the config that had it.
2020             delete $inherited_config{template};
2021
2022             map {
2023                 if (!$combined_inheritance{$_}) {
2024                     $combined_inheritance{$_} = [];
2025                 }
2026                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2027             } keys %inherited_config;
2028         }
2029     }
2030
2031     # We won't need inherit_from in this target any more, since we've
2032     # resolved all the inheritances that lead to this
2033     delete $table{$target}->{inherit_from};
2034
2035     # Now is the time to deal with those lists.  Here's the place to
2036     # decide what shall be done with those lists, all based on the
2037     # values of the target we're currently dealing with.
2038     # - If a value is a coderef, it will be executed with the list of
2039     #   inherited values as arguments.
2040     # - If the corresponding key doesn't have a value at all or is the
2041     #   emoty string, the inherited value list will be run through the
2042     #   default combiner (below), and the result becomes this target's
2043     #   value.
2044     # - Otherwise, this target's value is assumed to be a string that
2045     #   will simply override the inherited list of values.
2046     my $default_combiner = add(" ");
2047
2048     my %all_keys =
2049         map { $_ => 1 } (keys %combined_inheritance,
2050                          keys %{$table{$target}});
2051     foreach (sort keys %all_keys) {
2052
2053         # Current target doesn't have a value for the current key?
2054         # Assign it the default combiner, the rest of this loop body
2055         # will handle it just like any other coderef.
2056         if (!exists $table{$target}->{$_}) {
2057             $table{$target}->{$_} = $default_combiner;
2058         }
2059
2060         my $valuetype = ref($table{$target}->{$_});
2061         if ($valuetype eq "CODE") {
2062             # CODE reference, execute it with the inherited values as
2063             # arguments.
2064             $table{$target}->{$_} =
2065                 $table{$target}->{$_}->(@{$combined_inheritance{$_}});
2066         } elsif ($valuetype eq "ARRAY" || $valuetype eq "") {
2067             # ARRAY or Scalar, just leave it as is.
2068         } else {
2069             # Some other type of reference that we don't handle.
2070             # Better to abort at this point.
2071             die "cannot handle reference type $valuetype,"
2072                 ," found in target $target -> $_\n";
2073         }
2074     }
2075
2076     # Finally done, return the result.
2077     return %{$table{$target}};
2078 }
2079
2080 sub usage
2081         {
2082         print STDERR $usage;
2083         print STDERR "\npick os/compiler from:\n";
2084         my $j=0;
2085         my $i;
2086         my $k=0;
2087         foreach $i (sort keys %table)
2088                 {
2089                 next if $table{$i}->{template};
2090                 next if $i =~ /^debug/;
2091                 $k += length($i) + 1;
2092                 if ($k > 78)
2093                         {
2094                         print STDERR "\n";
2095                         $k=length($i);
2096                         }
2097                 print STDERR $i . " ";
2098                 }
2099         foreach $i (sort keys %table)
2100                 {
2101                 next if $table{$i}->{template};
2102                 next if $i !~ /^debug/;
2103                 $k += length($i) + 1;
2104                 if ($k > 78)
2105                         {
2106                         print STDERR "\n";
2107                         $k=length($i);
2108                         }
2109                 print STDERR $i . " ";
2110                 }
2111         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2112         exit(1);
2113         }
2114
2115 sub run_dofile()
2116 {
2117     my $out = shift;
2118     my @templates = @_;
2119
2120     unlink $out || warn "Can't remove $out, $!"
2121         if -f $out;
2122     foreach (@templates) {
2123         die "Can't open $_, $!" unless -f $_;
2124     }
2125     my $cmd = "$config{perl} \"-I.\" \"-Mconfigdata\" $dofile -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
2126     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2127     system($cmd);
2128     exit 1 if $? != 0;
2129     rename("$out.new", $out) || die "Can't rename $out.new, $!";
2130 }
2131
2132 # Configuration printer ##############################################
2133
2134 sub print_table_entry
2135 {
2136     my $target = shift;
2137     my %target = resolve_config($target);
2138     my $type = shift;
2139
2140     # Don't print the templates
2141     return if $target{template};
2142
2143     my @sequence = (
2144         "sys_id",
2145         "cc",
2146         "cflags",
2147         "debug_cflags",
2148         "release_cflags",
2149         "thread_cflag",
2150         "unistd",
2151         "ld",
2152         "lflags",
2153         "plib_lflags",
2154         "ex_libs",
2155         "debug_lflags",
2156         "debug_plib_lflags",
2157         "debug_ex_libs",
2158         "release_lflags",
2159         "release_plib_lflags",
2160         "release_ex_libs",
2161         "bn_ops",
2162         "cpuid_obj",
2163         "bn_obj",
2164         "ec_obj",
2165         "des_obj",
2166         "aes_obj",
2167         "bf_obj",
2168         "md5_obj",
2169         "sha1_obj",
2170         "cast_obj",
2171         "rc4_obj",
2172         "rmd160_obj",
2173         "rc5_obj",
2174         "wp_obj",
2175         "cmll_obj",
2176         "modes_obj",
2177         "padlock_obj",
2178         "perlasm_scheme",
2179         "dso_scheme",
2180         "shared_target",
2181         "shared_cflag",
2182         "shared_ldflag",
2183         "shared_extension",
2184         "obj_extension",
2185         "exe_extension",
2186         "ranlib",
2187         "ar",
2188         "arflags",
2189         "multilib",
2190         "build_scheme",
2191         );
2192
2193     if ($type eq "TABLE") {
2194         print "\n";
2195         print "*** $target\n";
2196         printf "\$%-12s = %s\n", $_, $target{$_} foreach (@sequence);
2197     } elsif ($type eq "HASH") {
2198         my $largest =
2199             length((sort { length($a) <=> length($b) } @sequence)[-1]);
2200         print "    '$target' => {\n";
2201         foreach (@sequence) {
2202             if ($target{$_}) {
2203                 print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
2204             }
2205         }
2206         print "    },\n";
2207     }
2208 }
2209
2210 # Utility routines ###################################################
2211
2212 sub which
2213         {
2214         my($name)=@_;
2215         my $path;
2216         foreach $path (split /:/, $ENV{PATH})
2217                 {
2218                 if (-f "$path/$name$target{exe_extension}" and -x _)
2219                         {
2220                         return "$path/$name$target{exe_extension}" unless ($name eq "perl" and
2221                          system("$path/$name$target{exe_extension} -e " . '\'exit($]<5.0);\''));
2222                         }
2223                 }
2224         }
2225
2226 sub quotify {
2227     my %processors = (
2228         perl    => sub { my $x = shift;
2229                          $x =~ s/([\\\$\@"])/\\$1/g;
2230                          return '"'.$x.'"'; },
2231         );
2232     my $for = shift;
2233     my $processor =
2234         defined($processors{$for}) ? $processors{$for} : sub { shift; };
2235
2236     map { $processor->($_); } @_;
2237 }
2238
2239 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
2240 # $filename is a file name to read from
2241 # $line_concat_cond_re is a regexp detecting a line continuation ending
2242 # $line_concat is a CODEref that takes care of concatenating two lines
2243 sub collect_from_file {
2244     my $filename = shift;
2245     my $line_concat_cond_re = shift;
2246     my $line_concat = shift;
2247
2248     open my $fh, $filename || die "unable to read $filename: $!\n";
2249     return sub {
2250         my $saved_line = "";
2251         $_ = "";
2252         while (<$fh>) {
2253             chomp;
2254             if (defined $line_concat) {
2255                 $_ = $line_concat->($saved_line, $_);
2256                 $saved_line = "";
2257             }
2258             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2259                 $saved_line = $_;
2260                 next;
2261             }
2262             return $_;
2263         }
2264         die "$filename ending with continuation line\n" if $_;
2265         close $fh;
2266         return undef;
2267     }
2268 }
2269
2270 # collect_from_array($array, $line_concat_cond_re, $line_concat)
2271 # $array is an ARRAYref of lines
2272 # $line_concat_cond_re is a regexp detecting a line continuation ending
2273 # $line_concat is a CODEref that takes care of concatenating two lines
2274 sub collect_from_array {
2275     my $array = shift;
2276     my $line_concat_cond_re = shift;
2277     my $line_concat = shift;
2278     my @array = (@$array);
2279
2280     return sub {
2281         my $saved_line = "";
2282         $_ = "";
2283         while (defined($_ = shift @array)) {
2284             chomp;
2285             if (defined $line_concat) {
2286                 $_ = $line_concat->($saved_line, $_);
2287                 $saved_line = "";
2288             }
2289             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2290                 $saved_line = $_;
2291                 next;
2292             }
2293             return $_;
2294         }
2295         die "input text ending with continuation line\n" if $_;
2296         return undef;
2297     }
2298 }
2299
2300 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
2301 # $lineiterator is a CODEref that delivers one line at a time.
2302 # All following arguments are regex/CODEref pairs, where the regexp detects a
2303 # line and the CODEref does something with the result of the regexp.
2304 sub collect_information {
2305     my $lineiterator = shift;
2306     my %collectors = @_;
2307
2308     while(defined($_ = $lineiterator->())) {
2309         chomp;
2310         my $found = 0;
2311         foreach my $re (keys %collectors) {
2312             if ($re ne "OTHERWISE" && /$re/) {
2313                 $collectors{$re}->($lineiterator);
2314                 $found = 1;
2315             };
2316         }
2317         if ($collectors{"OTHERWISE"}) {
2318             $collectors{"OTHERWISE"}->($lineiterator, $_)
2319                 unless $found || !defined $collectors{"OTHERWISE"};
2320         }
2321     }
2322 }