util/perl/TLSProxy/Message.pm

   1 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   2 #
   3 # Licensed under the OpenSSL license (the "License").  You may not use
   4 # this file except in compliance with the License.  You can obtain a copy
   5 # in the file LICENSE in the source distribution or at
   6 # https://www.openssl.org/source/license.html
   7
   8 use strict;
   9
  10 package TLSProxy::Message;
  11
  12 use constant TLS_MESSAGE_HEADER_LENGTH => 4;
  13
  14 #Message types
  15 use constant {
  16     MT_HELLO_REQUEST => 0,
  17     MT_CLIENT_HELLO => 1,
  18     MT_SERVER_HELLO => 2,
  19     MT_NEW_SESSION_TICKET => 4,
  20     MT_ENCRYPTED_EXTENSIONS => 8,
  21     MT_CERTIFICATE => 11,
  22     MT_SERVER_KEY_EXCHANGE => 12,
  23     MT_CERTIFICATE_REQUEST => 13,
  24     MT_SERVER_HELLO_DONE => 14,
  25     MT_CERTIFICATE_VERIFY => 15,
  26     MT_CLIENT_KEY_EXCHANGE => 16,
  27     MT_FINISHED => 20,
  28     MT_CERTIFICATE_STATUS => 22,
  29     MT_NEXT_PROTO => 67
  30 };
  31
  32 #Alert levels
  33 use constant {
  34     AL_LEVEL_WARN => 1,
  35     AL_LEVEL_FATAL => 2
  36 };
  37
  38 #Alert descriptions
  39 use constant {
  40     AL_DESC_CLOSE_NOTIFY => 0,
  41     AL_DESC_UNEXPECTED_MESSAGE => 10,
  42     AL_DESC_NO_RENEGOTIATION => 100
  43 };
  44
  45 my %message_type = (
  46     MT_HELLO_REQUEST, "HelloRequest",
  47     MT_CLIENT_HELLO, "ClientHello",
  48     MT_SERVER_HELLO, "ServerHello",
  49     MT_NEW_SESSION_TICKET, "NewSessionTicket",
  50     MT_ENCRYPTED_EXTENSIONS, "EncryptedExtensions",
  51     MT_CERTIFICATE, "Certificate",
  52     MT_SERVER_KEY_EXCHANGE, "ServerKeyExchange",
  53     MT_CERTIFICATE_REQUEST, "CertificateRequest",
  54     MT_SERVER_HELLO_DONE, "ServerHelloDone",
  55     MT_CERTIFICATE_VERIFY, "CertificateVerify",
  56     MT_CLIENT_KEY_EXCHANGE, "ClientKeyExchange",
  57     MT_FINISHED, "Finished",
  58     MT_CERTIFICATE_STATUS, "CertificateStatus",
  59     MT_NEXT_PROTO, "NextProto"
  60 );
  61
  62 use constant {
  63     EXT_SERVER_NAME => 0,
  64     EXT_MAX_FRAGMENT_LENGTH => 1,
  65     EXT_STATUS_REQUEST => 5,
  66     EXT_SUPPORTED_GROUPS => 10,
  67     EXT_EC_POINT_FORMATS => 11,
  68     EXT_SRP => 12,
  69     EXT_SIG_ALGS => 13,
  70     EXT_USE_SRTP => 14,
  71     EXT_ALPN => 16,
  72     EXT_SCT => 18,
  73     EXT_PADDING => 21,
  74     EXT_ENCRYPT_THEN_MAC => 22,
  75     EXT_EXTENDED_MASTER_SECRET => 23,
  76     EXT_SESSION_TICKET => 35,
  77     EXT_KEY_SHARE => 51,
  78     EXT_PSK => 41,
  79     EXT_SUPPORTED_VERSIONS => 43,
  80     EXT_COOKIE => 44,
  81     EXT_PSK_KEX_MODES => 45,
  82     EXT_POST_HANDSHAKE_AUTH => 49,
  83     EXT_SIG_ALGS_CERT => 50,
  84     EXT_RENEGOTIATE => 65281,
  85     EXT_NPN => 13172,
  86     # This extension is an unofficial extension only ever written by OpenSSL
  87     # (i.e. not read), and even then only when enabled. We use it to test
  88     # handling of duplicate extensions.
  89     EXT_DUPLICATE_EXTENSION => 0xfde8,
  90     EXT_UNKNOWN => 0xfffe,
  91     #Unknown extension that should appear last
  92     EXT_FORCE_LAST => 0xffff
  93 };
  94
  95 # SignatureScheme of TLS 1.3, from
  96 # https://tools.ietf.org/html/draft-ietf-tls-tls13-20#appendix-B.3.1.3
  97 # TODO(TLS1.3) update link to IANA registry after publication
  98 # We have to manually grab the SHA224 equivalents from the old registry
  99 use constant {
 100     SIG_ALG_RSA_PKCS1_SHA256 => 0x0401,
 101     SIG_ALG_RSA_PKCS1_SHA384 => 0x0501,
 102     SIG_ALG_RSA_PKCS1_SHA512 => 0x0601,
 103     SIG_ALG_ECDSA_SECP256R1_SHA256 => 0x0403,
 104     SIG_ALG_ECDSA_SECP384R1_SHA384 => 0x0503,
 105     SIG_ALG_ECDSA_SECP521R1_SHA512 => 0x0603,
 106     SIG_ALG_RSA_PSS_SHA256 => 0x0804,
 107     SIG_ALG_RSA_PSS_SHA384 => 0x0805,
 108     SIG_ALG_RSA_PSS_SHA512 => 0x0806,
 109     SIG_ALG_ED25519 => 0x0807,
 110     SIG_ALG_ED448 => 0x0808,
 111     SIG_ALG_RSA_PKCS1_SHA1 => 0x0201,
 112     SIG_ALG_ECDSA_SHA1 => 0x0203,
 113     SIG_ALG_DSA_SHA1 => 0x0202,
 114     SIG_ALG_DSA_SHA256 => 0x0402,
 115     SIG_ALG_DSA_SHA384 => 0x0502,
 116     SIG_ALG_DSA_SHA512 => 0x0602,
 117     OSSL_SIG_ALG_RSA_PKCS1_SHA224 => 0x0301,
 118     OSSL_SIG_ALG_DSA_SHA224 => 0x0302,
 119     OSSL_SIG_ALG_ECDSA_SHA224 => 0x0303
 120 };
 121
 122 use constant {
 123     CIPHER_DHE_RSA_AES_128_SHA => 0x0033,
 124     CIPHER_ADH_AES_128_SHA => 0x0034,
 125     CIPHER_TLS13_AES_128_GCM_SHA256 => 0x1301,
 126     CIPHER_TLS13_AES_256_GCM_SHA384 => 0x1302
 127 };
 128
 129 my $payload = "";
 130 my $messlen = -1;
 131 my $mt;
 132 my $startoffset = -1;
 133 my $server = 0;
 134 my $success = 0;
 135 my $end = 0;
 136 my @message_rec_list = ();
 137 my @message_frag_lens = ();
 138 my $ciphersuite = 0;
 139 my $successondata = 0;
 140
 141 sub clear
 142 {
 143     $payload = "";
 144     $messlen = -1;
 145     $startoffset = -1;
 146     $server = 0;
 147     $success = 0;
 148     $end = 0;
 149     $successondata = 0;
 150     @message_rec_list = ();
 151     @message_frag_lens = ();
 152 }
 153
 154 #Class method to extract messages from a record
 155 sub get_messages
 156 {
 157     my $class = shift;
 158     my $serverin = shift;
 159     my $record = shift;
 160     my @messages = ();
 161     my $message;
 162
 163     @message_frag_lens = ();
 164
 165     if ($serverin != $server && length($payload) != 0) {
 166         die "Changed peer, but we still have fragment data\n";
 167     }
 168     $server = $serverin;
 169
 170     if ($record->content_type == TLSProxy::Record::RT_CCS) {
 171         if ($payload ne "") {
 172             #We can't handle this yet
 173             die "CCS received before message data complete\n";
 174         }
 175         if (!TLSProxy::Proxy->is_tls13()) {
 176             if ($server) {
 177                 TLSProxy::Record->server_encrypting(1);
 178             } else {
 179                 TLSProxy::Record->client_encrypting(1);
 180             }
 181         }
 182     } elsif ($record->content_type == TLSProxy::Record::RT_HANDSHAKE) {
 183         if ($record->len == 0 || $record->len_real == 0) {
 184             print "  Message truncated\n";
 185         } else {
 186             my $recoffset = 0;
 187
 188             if (length $payload > 0) {
 189                 #We are continuing processing a message started in a previous
 190                 #record. Add this record to the list associated with this
 191                 #message
 192                 push @message_rec_list, $record;
 193
 194                 if ($messlen <= length($payload)) {
 195                     #Shouldn't happen
 196                     die "Internal error: invalid messlen: ".$messlen
 197                         ." payload length:".length($payload)."\n";
 198                 }
 199                 if (length($payload) + $record->decrypt_len >= $messlen) {
 200                     #We can complete the message with this record
 201                     $recoffset = $messlen - length($payload);
 202                     $payload .= substr($record->decrypt_data, 0, $recoffset);
 203                     push @message_frag_lens, $recoffset;
 204                     $message = create_message($server, $mt, $payload,
 205                                               $startoffset);
 206                     push @messages, $message;
 207
 208                     $payload = "";
 209                 } else {
 210                     #This is just part of the total message
 211                     $payload .= $record->decrypt_data;
 212                     $recoffset = $record->decrypt_len;
 213                     push @message_frag_lens, $record->decrypt_len;
 214                 }
 215                 print "  Partial message data read: ".$recoffset." bytes\n";
 216             }
 217
 218             while ($record->decrypt_len > $recoffset) {
 219                 #We are at the start of a new message
 220                 if ($record->decrypt_len - $recoffset < 4) {
 221                     #Whilst technically probably valid we can't cope with this
 222                     die "End of record in the middle of a message header\n";
 223                 }
 224                 @message_rec_list = ($record);
 225                 my $lenhi;
 226                 my $lenlo;
 227                 ($mt, $lenhi, $lenlo) = unpack('CnC',
 228                                                substr($record->decrypt_data,
 229                                                       $recoffset));
 230                 $messlen = ($lenhi << 8) | $lenlo;
 231                 print "  Message type: $message_type{$mt}\n";
 232                 print "  Message Length: $messlen\n";
 233                 $startoffset = $recoffset;
 234                 $recoffset += 4;
 235                 $payload = "";
 236
 237                 if ($recoffset <= $record->decrypt_len) {
 238                     #Some payload data is present in this record
 239                     if ($record->decrypt_len - $recoffset >= $messlen) {
 240                         #We can complete the message with this record
 241                         $payload .= substr($record->decrypt_data, $recoffset,
 242                                            $messlen);
 243                         $recoffset += $messlen;
 244                         push @message_frag_lens, $messlen;
 245                         $message = create_message($server, $mt, $payload,
 246                                                   $startoffset);
 247                         push @messages, $message;
 248
 249                         $payload = "";
 250                     } else {
 251                         #This is just part of the total message
 252                         $payload .= substr($record->decrypt_data, $recoffset,
 253                                            $record->decrypt_len - $recoffset);
 254                         $recoffset = $record->decrypt_len;
 255                         push @message_frag_lens, $recoffset;
 256                     }
 257                 }
 258             }
 259         }
 260     } elsif ($record->content_type == TLSProxy::Record::RT_APPLICATION_DATA) {
 261         print "  [ENCRYPTED APPLICATION DATA]\n";
 262         print "  [".$record->decrypt_data."]\n";
 263
 264         if ($successondata) {
 265             $success = 1;
 266             $end = 1;
 267         }
 268     } elsif ($record->content_type == TLSProxy::Record::RT_ALERT) {
 269         my ($alertlev, $alertdesc) = unpack('CC', $record->decrypt_data);
 270         print "  [$alertlev, $alertdesc]\n";
 271         #A CloseNotify from the client indicates we have finished successfully
 272         #(we assume)
 273         if (!$end && !$server && $alertlev == AL_LEVEL_WARN
 274             && $alertdesc == AL_DESC_CLOSE_NOTIFY) {
 275             $success = 1;
 276         }
 277         #Fatal or close notify alerts end the test
 278         if ($alertlev == AL_LEVEL_FATAL || $alertdesc == AL_DESC_CLOSE_NOTIFY) {
 279             $end = 1;
 280         }
 281     }
 282
 283     return @messages;
 284 }
 285
 286 #Function to work out which sub-class we need to create and then
 287 #construct it
 288 sub create_message
 289 {
 290     my ($server, $mt, $data, $startoffset) = @_;
 291     my $message;
 292
 293     #We only support ClientHello in this version...needs to be extended for
 294     #others
 295     if ($mt == MT_CLIENT_HELLO) {
 296         $message = TLSProxy::ClientHello->new(
 297             $server,
 298             $data,
 299             [@message_rec_list],
 300             $startoffset,
 301             [@message_frag_lens]
 302         );
 303         $message->parse();
 304     } elsif ($mt == MT_SERVER_HELLO) {
 305         $message = TLSProxy::ServerHello->new(
 306             $server,
 307             $data,
 308             [@message_rec_list],
 309             $startoffset,
 310             [@message_frag_lens]
 311         );
 312         $message->parse();
 313     } elsif ($mt == MT_ENCRYPTED_EXTENSIONS) {
 314         $message = TLSProxy::EncryptedExtensions->new(
 315             $server,
 316             $data,
 317             [@message_rec_list],
 318             $startoffset,
 319             [@message_frag_lens]
 320         );
 321         $message->parse();
 322     } elsif ($mt == MT_CERTIFICATE) {
 323         $message = TLSProxy::Certificate->new(
 324             $server,
 325             $data,
 326             [@message_rec_list],
 327             $startoffset,
 328             [@message_frag_lens]
 329         );
 330         $message->parse();
 331     } elsif ($mt == MT_CERTIFICATE_VERIFY) {
 332         $message = TLSProxy::CertificateVerify->new(
 333             $server,
 334             $data,
 335             [@message_rec_list],
 336             $startoffset,
 337             [@message_frag_lens]
 338         );
 339         $message->parse();
 340     } elsif ($mt == MT_SERVER_KEY_EXCHANGE) {
 341         $message = TLSProxy::ServerKeyExchange->new(
 342             $server,
 343             $data,
 344             [@message_rec_list],
 345             $startoffset,
 346             [@message_frag_lens]
 347         );
 348         $message->parse();
 349     } elsif ($mt == MT_NEW_SESSION_TICKET) {
 350         $message = TLSProxy::NewSessionTicket->new(
 351             $server,
 352             $data,
 353             [@message_rec_list],
 354             $startoffset,
 355             [@message_frag_lens]
 356         );
 357         $message->parse();
 358     } else {
 359         #Unknown message type
 360         $message = TLSProxy::Message->new(
 361             $server,
 362             $mt,
 363             $data,
 364             [@message_rec_list],
 365             $startoffset,
 366             [@message_frag_lens]
 367         );
 368     }
 369
 370     return $message;
 371 }
 372
 373 sub end
 374 {
 375     my $class = shift;
 376     return $end;
 377 }
 378 sub success
 379 {
 380     my $class = shift;
 381     return $success;
 382 }
 383 sub fail
 384 {
 385     my $class = shift;
 386     return !$success && $end;
 387 }
 388 sub new
 389 {
 390     my $class = shift;
 391     my ($server,
 392         $mt,
 393         $data,
 394         $records,
 395         $startoffset,
 396         $message_frag_lens) = @_;
 397
 398     my $self = {
 399         server => $server,
 400         data => $data,
 401         records => $records,
 402         mt => $mt,
 403         startoffset => $startoffset,
 404         message_frag_lens => $message_frag_lens
 405     };
 406
 407     return bless $self, $class;
 408 }
 409
 410 sub ciphersuite
 411 {
 412     my $class = shift;
 413     if (@_) {
 414       $ciphersuite = shift;
 415     }
 416     return $ciphersuite;
 417 }
 418
 419 #Update all the underlying records with the modified data from this message
 420 #Note: Only supports re-encrypting for TLSv1.3
 421 sub repack
 422 {
 423     my $self = shift;
 424     my $msgdata;
 425
 426     my $numrecs = $#{$self->records};
 427
 428     $self->set_message_contents();
 429
 430     my $lenhi;
 431     my $lenlo;
 432
 433     $lenlo = length($self->data) & 0xff;
 434     $lenhi = length($self->data) >> 8;
 435     $msgdata = pack('CnC', $self->mt, $lenhi, $lenlo).$self->data;
 436
 437     if ($numrecs == 0) {
 438         #The message is fully contained within one record
 439         my ($rec) = @{$self->records};
 440         my $recdata = $rec->decrypt_data;
 441
 442         my $old_length;
 443
 444         # We use empty message_frag_lens to indicates that pre-repacking,
 445         # the message wasn't present. The first fragment length doesn't include
 446         # the TLS header, so we need to check and compute the right length.
 447         if (@{$self->message_frag_lens}) {
 448             $old_length = ${$self->message_frag_lens}[0] +
 449               TLS_MESSAGE_HEADER_LENGTH;
 450         } else {
 451             $old_length = 0;
 452         }
 453
 454         my $prefix = substr($recdata, 0, $self->startoffset);
 455         my $suffix = substr($recdata, $self->startoffset + $old_length);
 456
 457         $rec->decrypt_data($prefix.($msgdata).($suffix));
 458         # TODO(openssl-team): don't keep explicit lengths.
 459         # (If a length override is ever needed to construct invalid packets,
 460         #  use an explicit override field instead.)
 461         $rec->decrypt_len(length($rec->decrypt_data));
 462         $rec->len($rec->len + length($msgdata) - $old_length);
 463         # Only support re-encryption for TLSv1.3.
 464         if (TLSProxy::Proxy->is_tls13() && $rec->encrypted()) {
 465             #Add content type (1 byte) and 16 tag bytes
 466             $rec->data($rec->decrypt_data
 467                 .pack("C", TLSProxy::Record::RT_HANDSHAKE).("\0"x16));
 468         } else {
 469             $rec->data($rec->decrypt_data);
 470         }
 471
 472         #Update the fragment len in case we changed it above
 473         ${$self->message_frag_lens}[0] = length($msgdata)
 474                                          - TLS_MESSAGE_HEADER_LENGTH;
 475         return;
 476     }
 477
 478     #Note we don't currently support changing a fragmented message length
 479     my $recctr = 0;
 480     my $datadone = 0;
 481     foreach my $rec (@{$self->records}) {
 482         my $recdata = $rec->decrypt_data;
 483         if ($recctr == 0) {
 484             #This is the first record
 485             my $remainlen = length($recdata) - $self->startoffset;
 486             $rec->data(substr($recdata, 0, $self->startoffset)
 487                        .substr(($msgdata), 0, $remainlen));
 488             $datadone += $remainlen;
 489         } elsif ($recctr + 1 == $numrecs) {
 490             #This is the last record
 491             $rec->data(substr($msgdata, $datadone));
 492         } else {
 493             #This is a middle record
 494             $rec->data(substr($msgdata, $datadone, length($rec->data)));
 495             $datadone += length($rec->data);
 496         }
 497         $recctr++;
 498     }
 499 }
 500
 501 #To be overridden by sub-classes
 502 sub set_message_contents
 503 {
 504 }
 505
 506 #Read only accessors
 507 sub server
 508 {
 509     my $self = shift;
 510     return $self->{server};
 511 }
 512
 513 #Read/write accessors
 514 sub mt
 515 {
 516     my $self = shift;
 517     if (@_) {
 518       $self->{mt} = shift;
 519     }
 520     return $self->{mt};
 521 }
 522 sub data
 523 {
 524     my $self = shift;
 525     if (@_) {
 526       $self->{data} = shift;
 527     }
 528     return $self->{data};
 529 }
 530 sub records
 531 {
 532     my $self = shift;
 533     if (@_) {
 534       $self->{records} = shift;
 535     }
 536     return $self->{records};
 537 }
 538 sub startoffset
 539 {
 540     my $self = shift;
 541     if (@_) {
 542       $self->{startoffset} = shift;
 543     }
 544     return $self->{startoffset};
 545 }
 546 sub message_frag_lens
 547 {
 548     my $self = shift;
 549     if (@_) {
 550       $self->{message_frag_lens} = shift;
 551     }
 552     return $self->{message_frag_lens};
 553 }
 554 sub encoded_length
 555 {
 556     my $self = shift;
 557     return TLS_MESSAGE_HEADER_LENGTH + length($self->data);
 558 }
 559 sub successondata
 560 {
 561     my $class = shift;
 562     if (@_) {
 563         $successondata = shift;
 564     }
 565     return $successondata;
 566 }
 567 1;