util/find-doc-nits

   1 #! /usr/bin/env perl
   2 # Copyright 2002-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9
  10 require 5.10.0;
  11 use warnings;
  12 use strict;
  13 use Pod::Checker;
  14 use File::Find;
  15 use File::Basename;
  16 use File::Spec::Functions;
  17 use Getopt::Std;
  18 use lib catdir(dirname($0), "perl");
  19 use OpenSSL::Util::Pod;
  20
  21 # Options.
  22 our($opt_s);
  23 our($opt_u);
  24 our($opt_h);
  25 our($opt_n);
  26 our($opt_l);
  27 our($opt_p);
  28
  29 sub help()
  30 {
  31     print <<EOF;
  32 Find small errors (nits) in documentation.  Options:
  33     -l Print bogus links
  34     -n Print nits in POD pages
  35     -s Also print missing sections in POD pages (implies -n)
  36     -p Warn if non-public name documented (implies -n)
  37     -u List undocumented functions
  38     -h Print this help message
  39 EOF
  40     exit;
  41 }
  42
  43 my $temp = '/tmp/docnits.txt';
  44 my $OUT;
  45 my %public;
  46
  47 my %mandatory_sections =
  48     ( '*'    => [ 'NAME', 'DESCRIPTION', 'COPYRIGHT' ],
  49       1      => [ 'SYNOPSIS', 'OPTIONS' ],
  50       3      => [ 'SYNOPSIS', 'RETURN VALUES' ],
  51       5      => [ ],
  52       7      => [ ] );
  53
  54 # Cross-check functions in the NAME and SYNOPSIS section.
  55 sub name_synopsis()
  56 {
  57     my $id = shift;
  58     my $filename = shift;
  59     my $contents = shift;
  60
  61     # Get NAME section and all words in it.
  62     return unless $contents =~ /=head1 NAME(.*)=head1 SYNOPSIS/ms;
  63     my $tmp = $1;
  64     $tmp =~ tr/\n/ /;
  65     print "$id trailing comma before - in NAME\n" if $tmp =~ /, *-/;
  66     $tmp =~ s/ -.*//g;
  67     $tmp =~ s/  */ /g;
  68     print "$id missing comma in NAME\n" if $tmp =~ /[^,] /;
  69     $tmp =~ s/,//g;
  70
  71     my $dirname = dirname($filename);
  72     my $simplename = basename($filename);
  73     $simplename =~ s/.pod$//;
  74     my $foundfilename = 0;
  75     my %foundfilenames = ();
  76     my %names;
  77     foreach my $n ( split ' ', $tmp ) {
  78         $names{$n} = 1;
  79         $foundfilename++ if $n eq $simplename;
  80         $foundfilenames{$n} = 1
  81             if -f "$dirname/$n.pod" && $n ne $simplename;
  82     }
  83     print "$id the following exist as other .pod files:\n",
  84         join(" ", sort keys %foundfilenames), "\n"
  85         if %foundfilenames;
  86     print "$id $simplename (filename) missing from NAME section\n"
  87         unless $foundfilename;
  88     foreach my $n ( keys %names ) {
  89         print "$id $n is not public\n"
  90             if $opt_p and !defined $public{$n};
  91     }
  92
  93     # Find all functions in SYNOPSIS
  94     return unless $contents =~ /=head1 SYNOPSIS(.*)=head1 DESCRIPTION/ms;
  95     my $syn = $1;
  96     foreach my $line ( split /\n+/, $syn ) {
  97         my $sym;
  98         $line =~ s/STACK_OF\([^)]+\)/int/g;
  99         $line =~ s/__declspec\([^)]+\)//;
 100         if ( $line =~ /env (\S*)=/ ) {
 101             # environment variable env NAME=...
 102             $sym = $1;
 103         } elsif ( $line =~ /typedef.*\(\*(\S+)\)\(.*/ ) {
 104             # a callback function: typedef ... (*NAME)(...
 105             $sym = $1;
 106         } elsif ( $line =~ /typedef.* (\S+);/ ) {
 107             # a simple typedef: typedef ... NAME;
 108             $sym = $1;
 109         } elsif ( $line =~ /enum (\S*) \{/ ) {
 110             # an enumeration: enum ... {
 111             $sym = $1;
 112         } elsif ( $line =~ /#define ([A-Za-z0-9_]+)/ ) {
 113             $sym = $1;
 114         } elsif ( $line =~ /([A-Za-z0-9_]+)\(/ ) {
 115             $sym = $1;
 116         }
 117         else {
 118             next;
 119         }
 120         print "$id $sym missing from NAME section\n"
 121             unless defined $names{$sym};
 122         $names{$sym} = 2;
 123
 124         # Do some sanity checks on the prototype.
 125         print "$id prototype missing spaces around commas: $line\n"
 126             if ( $line =~ /[a-z0-9],[^ ]/ );
 127     }
 128
 129     foreach my $n ( keys %names ) {
 130         next if $names{$n} == 2;
 131         print "$id $n missing from SYNOPSIS\n";
 132     }
 133 }
 134
 135 sub check()
 136 {
 137     my $filename = shift;
 138     my $dirname = basename(dirname($filename));
 139
 140     my $contents = '';
 141     {
 142         local $/ = undef;
 143         open POD, $filename or die "Couldn't open $filename, $!";
 144         $contents = <POD>;
 145         close POD;
 146     }
 147
 148     my $id = "${filename}:1:";
 149
 150     &name_synopsis($id, $filename, $contents)
 151         unless $contents =~ /=for comment generic/
 152             or $filename =~ m@man[157]/@;
 153
 154     print "$id doesn't start with =pod\n"
 155         if $contents !~ /^=pod/;
 156     print "$id doesn't end with =cut\n"
 157         if $contents !~ /=cut\n$/;
 158     print "$id more than one cut line.\n"
 159         if $contents =~ /=cut.*=cut/ms;
 160     print "$id missing copyright\n"
 161         if $contents !~ /Copyright .* The OpenSSL Project Authors/;
 162     print "$id copyright not last\n"
 163         if $contents =~ /head1 COPYRIGHT.*=head/ms;
 164     print "$id head2 in All uppercase\n"
 165         if $contents =~ /head2\s+[A-Z ]+\n/;
 166     print "$id extra space after head\n"
 167         if $contents =~ /=head\d\s\s+/;
 168     print "$id period in NAME section\n"
 169         if $contents =~ /=head1 NAME.*\.\n.*=head1 SYNOPSIS/ms;
 170     print "$id POD markup in NAME section\n"
 171         if $contents =~ /=head1 NAME.*[<>].*=head1 SYNOPSIS/ms;
 172     print "$id Duplicate $1 in L<>\n"
 173         if $contents =~ /L<([^>]*)\|([^>]*)>/ && $1 eq $2;
 174     print "$id Bad =over $1\n"
 175         if $contents =~ /=over([^ ][^24])/;
 176
 177     if ( $contents !~ /=for comment multiple includes/ ) {
 178         # Look for multiple consecutive openssl #include lines
 179         # (non-consecutive lines are okay; see man3/MD5.pod).
 180         if ( $contents =~ /=head1 SYNOPSIS(.*)=head1 DESCRIPTION/ms ) {
 181             my $count = 0;
 182             foreach my $line ( split /\n+/, $1 ) {
 183                 if ( $line =~ m@include <openssl/@ ) {
 184                     print "$id has multiple includes\n" if ++$count == 2;
 185                 } else {
 186                     $count = 0;
 187                 }
 188             }
 189         }
 190     }
 191
 192     open my $OUT, '>', $temp
 193         or die "Can't open $temp, $!";
 194     podchecker($filename, $OUT);
 195     close $OUT;
 196     open $OUT, '<', $temp
 197         or die "Can't read $temp, $!";
 198     while ( <$OUT> ) {
 199         next if /\(section\) in.*deprecated/;
 200         print;
 201     }
 202     close $OUT;
 203     unlink $temp || warn "Can't remove $temp, $!";
 204
 205     # Find what section this page is in; assume 3.
 206     my $section = 3;
 207     $section = $1 if $dirname =~ /man([1-9])/;
 208
 209     foreach ((@{$mandatory_sections{'*'}}, @{$mandatory_sections{$section}})) {
 210         # Skip "return values" if not -s
 211         next if $_ eq 'RETURN VALUES' and not $opt_s;
 212         print "$id: missing $_ head1 section\n"
 213             if $contents !~ /^=head1\s+${_}\s*$/m;
 214     }
 215 }
 216
 217 my %dups;
 218
 219 sub parsenum()
 220 {
 221     my $file = shift;
 222     my @apis;
 223
 224     open my $IN, '<', $file
 225         or die "Can't open $file, $!, stopped";
 226
 227     while ( <$IN> ) {
 228         next if /^#/;
 229         next if /\bNOEXIST\b/;
 230         next if /\bEXPORT_VAR_AS_FUNC\b/;
 231         my @fields = split();
 232         die "Malformed line $_"
 233             if scalar @fields != 2 && scalar @fields != 4;
 234         push @apis, $fields[0];
 235     }
 236
 237     close $IN;
 238
 239     print "# Found ", scalar(@apis), " in $file\n" unless $opt_p;
 240     return sort @apis;
 241 }
 242
 243 sub getdocced()
 244 {
 245     my $dir = shift;
 246     my %return;
 247
 248     foreach my $pod ( glob("$dir/*.pod") ) {
 249         my %podinfo = extract_pod_info($pod);
 250         foreach my $n ( @{$podinfo{names}} ) {
 251             $return{$n} = $pod;
 252             print "# Duplicate $n in $pod and $dups{$n}\n"
 253                 if defined $dups{$n} && $dups{$n} ne $pod;
 254             $dups{$n} = $pod;
 255         }
 256     }
 257
 258     return %return;
 259 }
 260
 261 my %docced;
 262
 263 sub checkmacros()
 264 {
 265     my $count = 0;
 266
 267     print "# Checking macros (approximate)\n";
 268     foreach my $f ( glob('include/openssl/*.h') ) {
 269         # Skip some internals we don't want to document yet.
 270         next if $f eq 'include/openssl/asn1.h';
 271         next if $f eq 'include/openssl/asn1t.h';
 272         next if $f eq 'include/openssl/err.h';
 273         open(IN, $f) || die "Can't open $f, $!";
 274         while ( <IN> ) {
 275             next unless /^#\s*define\s*(\S+)\(/;
 276             my $macro = $1;
 277             next if $docced{$macro};
 278             next if $macro =~ /i2d_/
 279                 || $macro =~ /d2i_/
 280                 || $macro =~ /DEPRECATEDIN/
 281                 || $macro =~ /IMPLEMENT_/
 282                 || $macro =~ /DECLARE_/;
 283             print "$f:$macro\n";
 284             $count++;
 285         }
 286         close(IN);
 287     }
 288     print "# Found $count macros missing (not all should be documnted)\n"
 289 }
 290
 291 sub printem()
 292 {
 293     my $libname = shift;
 294     my $numfile = shift;
 295     my $count = 0;
 296
 297     foreach my $func ( &parsenum($numfile) ) {
 298         next if $docced{$func};
 299
 300         # Skip ASN1 utilities
 301         next if $func =~ /^ASN1_/;
 302
 303         print "$libname:$func\n";
 304         $count++;
 305     }
 306     print "# Found $count missing from $numfile\n\n";
 307 }
 308
 309
 310 # Collection of links in each POD file.
 311 # filename => [ "foo(1)", "bar(3)", ... ]
 312 my %link_collection = ();
 313 # Collection of names in each POD file.
 314 # "name(s)" => filename
 315 my %name_collection = ();
 316
 317 sub collectnames {
 318     my $filename = shift;
 319     $filename =~ m|man(\d)/|;
 320     my $section = $1;
 321     my $simplename = basename($filename, ".pod");
 322     my $id = "${filename}:1:";
 323
 324     my $contents = '';
 325     {
 326         local $/ = undef;
 327         open POD, $filename or die "Couldn't open $filename, $!";
 328         $contents = <POD>;
 329         close POD;
 330     }
 331
 332     $contents =~ /=head1 NAME([^=]*)=head1 /ms;
 333     my $tmp = $1;
 334     unless (defined $tmp) {
 335         print "$id weird name section\n";
 336         return;
 337     }
 338     $tmp =~ tr/\n/ /;
 339     $tmp =~ s/-.*//g;
 340
 341     my @names = map { s/\s+//g; $_ } split(/,/, $tmp);
 342     unless (grep { $simplename eq $_ } @names) {
 343         print "$id missing $simplename\n";
 344         push @names, $simplename;
 345     }
 346     foreach my $name (@names) {
 347         next if $name eq "";
 348         my $name_sec = "$name($section)";
 349         if (! exists $name_collection{$name_sec}) {
 350             $name_collection{$name_sec} = $filename;
 351         } else { #elsif ($filename ne $name_collection{$name_sec}) {
 352             print "$id $name_sec also in $name_collection{$name_sec}\n";
 353         }
 354     }
 355
 356     my @foreign_names =
 357         map { map { s/\s+//g; $_ } split(/,/, $_) }
 358         $contents =~ /=for\s+comment\s+foreign\s+manuals:\s*(.*)\n\n/;
 359     foreach (@foreign_names) {
 360         $name_collection{$_} = undef; # It still exists!
 361     }
 362
 363     my @links = $contents =~ /L<
 364                               # if the link is of the form L<something|name(s)>,
 365                               # then remove 'something'.  Note that 'something'
 366                               # may contain POD codes as well...
 367                               (?:(?:[^\|]|<[^>]*>)*\|)?
 368                               # we're only interested in referenses that have
 369                               # a one digit section number
 370                               ([^\/>\(]+\(\d\))
 371                              /gx;
 372     $link_collection{$filename} = [ @links ];
 373 }
 374
 375 sub checklinks {
 376     foreach my $filename (sort keys %link_collection) {
 377         foreach my $link (@{$link_collection{$filename}}) {
 378             print "${filename}:1: reference to non-existing $link\n"
 379                 unless exists $name_collection{$link};
 380         }
 381     }
 382 }
 383
 384 sub publicize() {
 385     foreach my $name ( &parsenum('util/libcrypto.num') ) {
 386         $public{$name} = 1;
 387     }
 388     foreach my $name ( &parsenum('util/libssl.num') ) {
 389         $public{$name} = 1;
 390     }
 391     foreach my $name ( &parsenum('util/private.num') ) {
 392         $public{$name} = 1;
 393     }
 394 }
 395
 396 getopts('lnsphu');
 397
 398 &help() if $opt_h;
 399
 400 die "Need one of -l -n -s -p or -u flags.\n"
 401     unless $opt_l or $opt_n or $opt_s or $opt_p or $opt_u;
 402
 403 $opt_n = 1 if $opt_s or $opt_p;
 404
 405 if ( $opt_n ) {
 406     &publicize() if $opt_p;
 407     foreach (@ARGV ? @ARGV : glob('doc/*/*.pod')) {
 408         &check($_);
 409     }
 410 }
 411
 412 if ( $opt_l ) {
 413     foreach (@ARGV ? @ARGV : glob('doc/*/*.pod')) {
 414         collectnames($_);
 415     }
 416     checklinks();
 417 }
 418
 419 if ( $opt_u ) {
 420     my %temp = &getdocced('doc/man3');
 421     foreach ( keys %temp ) {
 422         $docced{$_} = $temp{$_};
 423     }
 424     &printem('crypto', 'util/libcrypto.num');
 425     &printem('ssl', 'util/libssl.num');
 426     &checkmacros();
 427 }
 428
 429 exit;