util/check-format.pl

   1 #! /usr/bin/env perl
   2 #
   3 # Copyright 2020-2023 The OpenSSL Project Authors. All Rights Reserved.
   4 # Copyright Siemens AG 2019-2022
   5 #
   6 # Licensed under the Apache License 2.0 (the "License").
   7 # You may not use this file except in compliance with the License.
   8 # You can obtain a copy in the file LICENSE in the source distribution
   9 # or at https://www.openssl.org/source/license.html
  10 #
  11 # check-format.pl
  12 # - check formatting of C source according to OpenSSL coding style
  13 #
  14 # usage:
  15 #   check-format.pl [-l|--sloppy-len] [-l|--sloppy-bodylen]
  16 #                   [-s|--sloppy-space] [-c|--sloppy-comment]
  17 #                   [-m|--sloppy-macro] [-h|--sloppy-hang]
  18 #                   [-e|--eol-comment] [-1|--1-stmt]
  19 #                   <files>
  20 #
  21 # run self-tests:
  22 #   util/check-format.pl util/check-format-test-positives.c
  23 #   util/check-format.pl util/check-format-test-negatives.c
  24 #
  25 # checks adherence to the formatting rules of the OpenSSL coding guidelines
  26 # assuming that the input files contain syntactically correct C code.
  27 # This pragmatic tool is incomplete and yields some false positives.
  28 # Still it should be useful for detecting most typical glitches.
  29 #
  30 # options:
  31 #  -l | --sloppy-len     increase accepted max line length from 80 to 84
  32 #  -l | --sloppy-bodylen do not report function body length > 200
  33 #  -s | --sloppy-space   do not report whitespace nits
  34 #  -c | --sloppy-comment do not report indentation of comments
  35 #                        Otherwise for each multi-line comment the indentation of
  36 #                        its lines is checked for consistency. For each comment
  37 #                        that does not begin to the right of normal code its
  38 #                        indentation must be as for normal code, while in case it
  39 #                        also has no normal code to its right it is considered to
  40 #                        refer to the following line and may be indented equally.
  41 #  -m | --sloppy-macro   allow missing extra indentation of macro bodies
  42 #  -h | --sloppy-hang    when checking hanging indentation, do not report
  43 #                        * same indentation as on line before
  44 #                        * same indentation as non-hanging indent level
  45 #                        * indentation moved left (not beyond non-hanging indent)
  46 #                          just to fit contents within the line length limit
  47 #  -e | --eol-comment    report needless intermediate multiple consecutive spaces also before end-of-line comments
  48 #  -1 | --1-stmt         do more aggressive checks for { 1 stmt } - see below
  49 #
  50 # There are non-trivial false positives and negatives such as the following.
  51 #
  52 # * When a line contains several issues of the same kind only one is reported.
  53 #
  54 # * When a line contains more than one statement this is (correctly) reported
  55 #   but in some situations the indentation checks for subsequent lines go wrong.
  56 #
  57 # * There is the special OpenSSL rule not to unnecessarily use braces around
  58 #   single statements:
  59 #   {
  60 #       stmt;
  61 #   }
  62 #   except within if ... else constructs where some branch contains more than one
  63 #   statement. Since the exception is hard to recognize when such branches occur
  64 #   after the current position (such that false positives would be reported)
  65 #   the tool by checks for this rule by default only for do/while/for bodies.
  66 #   Yet with the --1-stmt option false positives are preferred over negatives.
  67 #   False negatives occur if the braces are more than two non-blank lines apart.
  68 #
  69 # * The presence of multiple consecutive spaces is regarded a coding style nit
  70 #   except when this is before end-of-line comments (unless the --eol-comment is given) and
  71 #   except when done in order to align certain columns over multiple lines, e.g.:
  72 #   # define AB  1
  73 #   # define CDE 22
  74 #   # define F   3333
  75 #   This pattern is recognized - and consequently extra space not reported -
  76 #   for a given line if in the non-blank line before or after (if existing)
  77 #   for each occurrence of "  \S" (where \S means non-space) in the given line
  78 #   there is " \S" in the other line in the respective column position.
  79 #   This may lead to both false negatives (in case of coincidental " \S")
  80 #   and false positives (in case of more complex multi-column alignment).
  81 #
  82 # * When just part of control structures depend on #if(n)(def), which can be
  83 #   considered bad programming style, indentation false positives occur, e.g.:
  84 #   #if X
  85 #       if (1) /* bad style */
  86 #   #else
  87 #       if (2) /* bad style resulting in false positive */
  88 #   #endif
  89 #           c; /* resulting further false positive */
  90
  91 use strict;
  92 # use List::Util qw[min max];
  93 use POSIX;
  94
  95 use constant INDENT_LEVEL => 4;
  96 use constant MAX_LINE_LENGTH => 80;
  97 use constant MAX_BODY_LENGTH => 200;
  98
  99 # global variables @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
 100
 101 # command-line options
 102 my $max_length = MAX_LINE_LENGTH;
 103 my $sloppy_bodylen = 0;
 104 my $sloppy_SPC = 0;
 105 my $sloppy_hang = 0;
 106 my $sloppy_cmt = 0;
 107 my $sloppy_macro = 0;
 108 my $eol_cmt = 0;
 109 my $extended_1_stmt = 0;
 110
 111 while ($ARGV[0] =~ m/^-(\w|-[\w\-]+)$/) {
 112     my $arg = $1; shift;
 113     if ($arg =~ m/^(l|-sloppy-len)$/) {
 114         $max_length += INDENT_LEVEL;
 115     } elsif ($arg =~ m/^(b|-sloppy-bodylen)$/) {
 116         $sloppy_bodylen = 1;
 117     } elsif ($arg =~ m/^(s|-sloppy-space)$/) {
 118         $sloppy_SPC= 1;
 119     } elsif ($arg =~ m/^(c|-sloppy-comment)$/) {
 120         $sloppy_cmt = 1;
 121     } elsif ($arg =~ m/^(m|-sloppy-macro)$/) {
 122         $sloppy_macro = 1;
 123     } elsif ($arg =~ m/^(h|-sloppy-hang)$/) {
 124         $sloppy_hang = 1;
 125     } elsif ($arg =~ m/^(e|-eol-comment)$/) {
 126         $eol_cmt = 1;
 127     } elsif ($arg =~ m/^(1|-1-stmt)$/) {
 128         $extended_1_stmt = 1;
 129     } else {
 130         die("unknown option: -$arg");
 131     }
 132 }
 133
 134 # state variables
 135 my $self_test;             # whether the current input file is regarded to contain (positive/negative) self-tests
 136
 137 my $in_comment;            # number of lines so far within multi-line comment, 0 if no comment, < 0 when end is on current line
 138 my $leading_comment;       # multi-line comment has no code before its beginning delimiter, if $in_comment != 0
 139 my $formatted_comment;     # multi-line comment beginning with "/*-", which indicates/allows special formatting, if $in_comment != 0
 140 my $comment_indent;        # comment indent, if $in_comment != 0
 141
 142 my $ifdef__cplusplus;      # line before contained '#ifdef __cplusplus' (used in header files)
 143 my $preproc_if_nesting;    # currently required indentation of preprocessor directive according to #if(n)(def)
 144 my $in_preproc;            # 0 or number of lines so far within preprocessor directive, e.g., macro definition
 145 my $preproc_directive;     # name of current preprocessor directive, if $in_preproc != 0
 146 my $preproc_offset;        # offset to $block_indent within multi-line preprocessor directive, else 0
 147 my $in_macro_header;       # number of open parentheses + 1 in (multi-line) header of #define, if $in_preproc != 0
 148
 149 my $line;                  # current line number
 150 my $line_before;           # number of previous not essentially blank line (containing at most whitespace and '\')
 151 my $line_before2;          # number of not essentially blank line before previous not essentially blank line
 152
 153 # indentation state
 154 my $contents;              # contents of current line (without blinding)
 155 #  $_                      # current line, where comments etc. get blinded
 156 my $code_contents_before;  # contents of previous non-comment non-preprocessor-directive line (without blinding), initially ""
 157 my $contents_before;       # contents of $line_before (without blinding), if $line_before > 0
 158 my $contents_before_;      # contents of $line_before after blinding comments etc., if $line_before > 0
 159 my $contents_before2;      # contents of $line_before2  (without blinding), if $line_before2 > 0
 160 my $contents_before_2;     # contents of $line_before2 after blinding comments etc., if $line_before2 > 0
 161 my $in_multiline_string;   # line starts within multi-line string literal
 162 my $count;                 # -1 or number of leading whitespace characters (except newline) in current line,
 163                            # which should be $block_indent + $hanging_offset + $local_offset or $expr_indent
 164 my $count_before;          # number of leading whitespace characters (except line ending chars) in $contents_before
 165 my $has_label;             # current line contains label
 166 my $local_offset;          # current extra indent due to label, switch case/default, or leading closing brace(s)
 167 my $line_body_start;       # number of line where last function body started, or 0
 168 my $line_function_start;   # number of line where last function definition started, used for $line_body_start
 169 my $last_function_header;  # header containing name of last function defined, used if $line_body_start != 0
 170 my $line_opening_brace;    # number of previous line with opening brace after do/while/for, optionally for if/else
 171
 172 my $keyword_opening_brace; # name of previous keyword, used if $line_opening_brace != 0
 173 my $block_indent;          # currently required normal indentation at block/statement level
 174 my $hanging_offset;        # extra indent, which may be nested, for just one hanging statement or expr or typedef
 175 my @in_do_hanging_offsets; # stack of hanging offsets for nested 'do' ... 'while'
 176 my @in_if_hanging_offsets; # stack of hanging offsets for nested 'if' (but not its potential 'else' branch)
 177 my $if_maybe_terminated;   # 'if' ends and $hanging_offset should be reset unless the next line starts with 'else'
 178 my @nested_block_indents;  # stack of indentations at block/statement level, needed due to hanging statements
 179 my @nested_hanging_offsets;# stack of nested $hanging_offset values, in parallel to @nested_block_indents
 180 my @nested_in_typedecl;    # stack of nested $in_typedecl values, partly in parallel to @nested_block_indents
 181 my @nested_indents;        # stack of hanging indents due to parentheses, braces, brackets, or conditionals
 182 my @nested_symbols;        # stack of hanging symbols '(', '{', '[', or '?', in parallel to @nested_indents
 183 my @nested_conds_indents;  # stack of hanging indents due to conditionals ('?' ... ':')
 184 my $expr_indent;           # resulting hanging indent within (multi-line) expressions including type exprs, else 0
 185 my $hanging_symbol;        # character ('(', '{', '[', not: '?') responsible for $expr_indent, if $expr_indent != 0
 186 my $in_block_decls;        # number of local declaration lines after block opening before normal statements, or -1 if no block opening
 187 my $in_expr;               # in expression after if/while/for/switch/return/enum/LHS of assignment
 188 my $in_paren_expr;         # in parenthesized if/while/for condition and switch expression, if $expr_indent != 0
 189 my $in_typedecl;           # nesting level of typedef/struct/union/enum
 190
 191 my $num_reports_line = 0;  # number of issues found on current line
 192 my $num_reports = 0;       # total number of issues found
 193 my $num_indent_reports = 0;# total number of indentation issues found
 194 my $num_nesting_issues = 0;# total number of preprocessor #if nesting issues found
 195 my $num_syntax_issues = 0; # total number of syntax issues found during sanity checks
 196 my $num_SPC_reports = 0;   # total number of whitespace issues found
 197 my $num_length_reports = 0;# total number of line length issues found
 198
 199 sub reset_file_state {
 200     $in_comment = 0;
 201     $ifdef__cplusplus = 0;
 202     $preproc_if_nesting = 0;
 203     $in_preproc = 0;
 204     $line = 0;
 205     $line_before = 0;
 206     $line_before2 = 0;
 207     reset_indentation_state();
 208 }
 209 sub reset_indentation_state {
 210     $code_contents_before = "";
 211     @nested_block_indents = ();
 212     @nested_hanging_offsets = ();
 213     @nested_in_typedecl = ();
 214     @nested_symbols = ();
 215     @nested_indents = ();
 216     @nested_conds_indents = ();
 217     $expr_indent = 0;
 218     $in_block_decls = -1;
 219     $in_expr = 0;
 220     $in_paren_expr = 0;
 221     $hanging_offset = 0;
 222     @in_do_hanging_offsets = ();
 223     @in_if_hanging_offsets = ();
 224     $if_maybe_terminated = 0;
 225     $block_indent = 0;
 226     $in_multiline_string = 0;
 227     $line_body_start = 0;
 228     $line_opening_brace = 0;
 229     $in_typedecl = 0;
 230 }
 231 my $bak_line_before;
 232 my $bak_line_before2;
 233 my $bak_code_contents_before;
 234 my @bak_nested_block_indents;
 235 my @bak_nested_hanging_offsets;
 236 my @bak_nested_in_typedecl;
 237 my @bak_nested_symbols;
 238 my @bak_nested_indents;
 239 my @bak_nested_conds_indents;
 240 my $bak_expr_indent;
 241 my $bak_in_block_decls;
 242 my $bak_in_expr;
 243 my $bak_in_paren_expr;
 244 my $bak_hanging_offset;
 245 my @bak_in_do_hanging_offsets;
 246 my @bak_in_if_hanging_offsets;
 247 my $bak_if_maybe_terminated;
 248 my $bak_block_indent;
 249 my $bak_in_multiline_string;
 250 my $bak_line_body_start;
 251 my $bak_line_opening_brace;
 252 my $bak_in_typedecl;
 253 sub backup_indentation_state {
 254     $bak_code_contents_before = $code_contents_before;
 255     @bak_nested_block_indents = @nested_block_indents;
 256     @bak_nested_hanging_offsets = @nested_hanging_offsets;
 257     @bak_nested_in_typedecl = @nested_in_typedecl;
 258     @bak_nested_symbols = @nested_symbols;
 259     @bak_nested_indents = @nested_indents;
 260     @bak_nested_conds_indents = @nested_conds_indents;
 261     $bak_expr_indent = $expr_indent;
 262     $bak_in_block_decls = $in_block_decls;
 263     $bak_in_expr = $in_expr;
 264     $bak_in_paren_expr = $in_paren_expr;
 265     $bak_hanging_offset = $hanging_offset;
 266     @bak_in_do_hanging_offsets = @in_do_hanging_offsets;
 267     @bak_in_if_hanging_offsets = @in_if_hanging_offsets;
 268     $bak_if_maybe_terminated = $if_maybe_terminated;
 269     $bak_block_indent = $block_indent;
 270     $bak_in_multiline_string = $in_multiline_string;
 271     $bak_line_body_start = $line_body_start;
 272     $bak_line_opening_brace = $line_opening_brace;
 273     $bak_in_typedecl = $in_typedecl;
 274 }
 275 sub restore_indentation_state {
 276     $code_contents_before = $bak_code_contents_before;
 277     @nested_block_indents = @bak_nested_block_indents;
 278     @nested_hanging_offsets = @bak_nested_hanging_offsets;
 279     @nested_in_typedecl = @bak_nested_in_typedecl;
 280     @nested_symbols = @bak_nested_symbols;
 281     @nested_indents = @bak_nested_indents;
 282     @nested_conds_indents = @bak_nested_conds_indents;
 283     $expr_indent = $bak_expr_indent;
 284     $in_block_decls = $bak_in_block_decls;
 285     $in_expr = $bak_in_expr;
 286     $in_paren_expr = $bak_in_paren_expr;
 287     $hanging_offset = $bak_hanging_offset;
 288     @in_do_hanging_offsets = @bak_in_do_hanging_offsets;
 289     @in_if_hanging_offsets = @bak_in_if_hanging_offsets;
 290     $if_maybe_terminated = $bak_if_maybe_terminated;
 291     $block_indent = $bak_block_indent;
 292     $in_multiline_string = $bak_in_multiline_string;
 293     $line_body_start = $bak_line_body_start;
 294     $line_opening_brace = $bak_line_opening_brace;
 295     $in_typedecl = $bak_in_typedecl;
 296 }
 297
 298 # auxiliary submodules @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
 299
 300 sub report_flexibly {
 301     my $line = shift;
 302     my $msg = shift;
 303     my $contents = shift;
 304     my $report_SPC = $msg =~ /space|blank/;
 305     return if $report_SPC && $sloppy_SPC;
 306
 307     print "$ARGV:$line:$msg:$contents" unless $self_test;
 308     $num_reports_line++;
 309     $num_reports++;
 310     $num_indent_reports++ if $msg =~ m/:indent /;
 311     $num_nesting_issues++ if $msg =~ m/ nesting indent /;
 312     $num_syntax_issues++  if $msg =~ m/unclosed|unexpected/;
 313     $num_SPC_reports++    if $report_SPC;
 314     $num_length_reports++ if $msg =~ m/length/;
 315 }
 316
 317 sub report {
 318     my $msg = shift;
 319     report_flexibly($line, $msg, $contents);
 320 }
 321
 322 sub parens_balance { # count balance of opening parentheses - closing parentheses
 323     my $str = shift;
 324     return $str =~ tr/\(// - $str =~ tr/\)//;
 325 }
 326
 327 sub blind_nonspace { # blind non-space text of comment as @, preserving length and spaces
 328     # the @ character is used because it cannot occur in normal program code so there is no confusion
 329     # comment text is not blinded to whitespace in order to be able to check extra SPC also in comments
 330     my $comment_text = shift;
 331     $comment_text =~ s/([\.\?\!])\s\s/$1. /g; # in extra SPC checks allow one extra SPC after period '.', '?', or '!' in comments
 332     return $comment_text =~ tr/ /@/cr;
 333 }
 334
 335 # submodule for indentation checking/reporting @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
 336
 337 sub check_indent { # used for lines outside multi-line string literals
 338     my $stmt_indent = $block_indent + $hanging_offset + $local_offset;
 339     # print "DEBUG: expr_indent $expr_indent; stmt_indent $stmt_indent = block_indent $block_indent + hanging_offset $hanging_offset + local_offset $local_offset\n";
 340     $stmt_indent = 0 if $stmt_indent < 0; # TODO maybe give warning/error
 341     my $stmt_desc = $contents =~
 342         m/^\s*\/\*/ ? "intra-line comment" :
 343         $has_label ? "label" :
 344         ($hanging_offset != 0 ? "hanging " : "").
 345         ($hanging_offset != 0 ? "stmt/expr" : "stmt/decl"); # $in_typedecl is not fully to the point here
 346     my ($ref_desc, $ref_indent) = $expr_indent == 0 ? ($stmt_desc, $stmt_indent)
 347                                                     : ("hanging '$hanging_symbol'", $expr_indent);
 348     my ($alt_desc, $alt_indent) = ("", $ref_indent);
 349
 350     # allow indent 1 for labels - this cannot happen for leading ':'
 351     ($alt_desc, $alt_indent) = ("outermost position", 1) if $expr_indent == 0 && $has_label;
 352
 353     if (@nested_conds_indents != 0 && substr($_, $count, 1) eq ":") {
 354         # leading ':' within stmt/expr/decl - this cannot happen for labels, leading '&&', or leading '||'
 355         # allow special indent at level of corresponding "?"
 356         ($alt_desc, $alt_indent) = ("leading ':'", @nested_conds_indents[-1]);
 357     }
 358     # allow extra indent offset leading '&&' or '||' - this cannot happen for leading ":"
 359     ($alt_desc, $alt_indent) = ("leading '$1'", $ref_indent + INDENT_LEVEL) if $contents =~ m/^[\s@]*(\&\&|\|\|)/;
 360
 361     if ($expr_indent < 0) { # implies @nested_symbols != 0 && @nested_symbols[0] eq "{" && @nested_indents[-1] < 0
 362         # allow normal stmt indentation level for hanging initializer/enum expressions after trailing '{'
 363         # this cannot happen for labels and overrides special treatment of ':', '&&' and '||' for this line
 364         ($alt_desc, $alt_indent) = ("lines after '{'", $stmt_indent);
 365         # decide depending on current actual indentation, preventing forth and back
 366         @nested_indents[-1] = $count == $stmt_indent ? $stmt_indent : -@nested_indents[-1]; # allow $stmt_indent
 367         $ref_indent = $expr_indent = @nested_indents[-1];
 368     }
 369
 370     # check consistency of indentation within multi-line comment (i.e., between its first, inner, and last lines)
 371     if ($in_comment != 0 && $in_comment != 1) { # in multi-line comment but not on its first line
 372         if (!$sloppy_cmt) {
 373             if ($in_comment > 0) { # not at its end
 374                 report("indent = $count != $comment_indent within multi-line comment")
 375                     if $count != $comment_indent;
 376             } else {
 377                 my $tweak = $in_comment == -2 ? 1 : 0;
 378                 report("indent = ".($count + $tweak)." != $comment_indent at end of multi-line comment")
 379                     if $count + $tweak != $comment_indent;
 380             }
 381         }
 382         # do not check indentation of last line of non-leading multi-line comment
 383         if ($in_comment < 0 && !$leading_comment) {
 384             s/^(\s*)@/$1*/; # blind first '@' as '*' to prevent below delayed check for the line before
 385             return;
 386         }
 387         return if $in_comment > 0; # not on its last line
 388         # $comment_indent will be checked by the below checks for end of multi-line comment
 389     }
 390
 391     # else check indentation of entire-line comment or entire-line end of multi-line comment
 392     # ... w.r.t. indent of the following line by delayed check for the line before
 393     if (($in_comment == 0 || $in_comment == 1) # no comment, intra-line comment, or begin of multi-line comment
 394         && $line_before > 0 # there is a line before
 395         && $contents_before_ =~ m/^(\s*)@[\s@]*$/) { # line before begins with '@', no code follows (except '\')
 396         report_flexibly($line_before, "entire-line comment indent = $count_before != $count (of following line)",
 397             $contents_before) if !$sloppy_cmt && $count_before != -1 && $count_before != $count;
 398     }
 399     # ... but allow normal indentation for the current line, else above check will be done for the line before
 400     if (($in_comment == 0 || $in_comment < 0) # (no comment,) intra-line comment or end of multi-line comment
 401         && m/^(\s*)@[\s@]*$/) { # line begins with '@', no code follows (except '\')
 402         if ($count == $ref_indent) { # indentation is like for (normal) code in this line
 403             s/^(\s*)@/$1*/; # blind first '@' as '*' to prevent above delayed check for the line before
 404             return;
 405         }
 406         return if !eof; # defer check of entire-line comment to next line
 407     }
 408
 409     # else check indentation of leading intra-line comment or end of multi-line comment
 410     if (m/^(\s*)@/) { # line begins with '@', i.e., any (remaining type of) comment
 411         if (!$sloppy_cmt && $count != $ref_indent) {
 412             report("intra-line comment indent = $count != $ref_indent") if $in_comment == 0;
 413             report("multi-line comment indent = $count != $ref_indent") if $in_comment < 0;
 414         }
 415         return;
 416     }
 417
 418     if ($sloppy_hang && ($hanging_offset != 0 || $expr_indent != 0)) {
 419         # do not report same indentation as on the line before (potentially due to same violations)
 420         return if $line_before > 0 && $count == $count_before;
 421
 422         # do not report indentation at normal indentation level while hanging expression indent would be required
 423         return if $expr_indent != 0 && $count == $stmt_indent;
 424
 425         # do not report if contents have been shifted left of nested expr indent (but not as far as stmt indent)
 426         # apparently aligned to the right in order to fit within line length limit
 427         return if $stmt_indent < $count && $count < $expr_indent &&
 428             length($contents) == MAX_LINE_LENGTH + length("\n");
 429     }
 430
 431     report("indent = $count != $ref_indent for $ref_desc".
 432            ($alt_desc eq ""
 433             || $alt_indent == $ref_indent # prevent showing alternative that happens to have equal value
 434             ? "" : " or $alt_indent for $alt_desc"))
 435         if $count != $ref_indent && $count != $alt_indent;
 436 }
 437
 438 # submodules handling indentation within expressions @@@@@@@@@@@@@@@@@@@@@@@@@@@
 439
 440 sub update_nested_indents { # may reset $in_paren_expr and in this case also resets $in_expr
 441     my $str = shift;
 442     my $start = shift; # defaults to 0
 443     my $terminator_position = -1;
 444     for (my $i = $start; $i < length($str); $i++) {
 445         my $c;
 446         my $curr = substr($str, $i);
 447         if ($curr =~ m/^(.*?)([{}()?:;\[\]])(.*)$/) { # match from position $i the first {}()?:;[]
 448             $c = $2;
 449         } else {
 450             last;
 451         }
 452         my ($head, $tail) = (substr($str, 0, $i).$1, $3);
 453         $i += length($1) + length($2) - 1;
 454
 455         # stop at terminator outside 'for (..;..;..)', assuming that 'for' is followed by '('
 456         return $i if $c eq ";" && (!$in_paren_expr || @nested_indents == 0);
 457
 458         my $in_stmt = $in_expr || @nested_symbols != 0; # not: || $in_typedecl != 0
 459         if ($c =~ m/[{([?]/) { # $c is '{', '(', '[', or '?'
 460             if ($c eq "{") { # '{' in any context
 461                 $in_block_decls = 0 if !$in_expr && $in_typedecl == 0;
 462                 # cancel newly hanging_offset if opening brace '{' is after non-whitespace non-comment:
 463                 $hanging_offset -= INDENT_LEVEL if $hanging_offset > 0 && $head =~ m/[^\s\@]/;
 464                 push @nested_block_indents, $block_indent;
 465                 push @nested_hanging_offsets, $in_expr ? $hanging_offset : 0;
 466                 push @nested_in_typedecl, $in_typedecl if $in_typedecl != 0;
 467                 $block_indent += INDENT_LEVEL + $hanging_offset;
 468                 $hanging_offset = 0;
 469             }
 470             if ($c ne "{" || $in_stmt) { # for '{' inside stmt/expr (not: decl), for '(', '[', or '?' anywhere
 471                 $tail =~ m/^([\s@]*)([^\s\@])/;
 472                 push @nested_indents, defined $2
 473                     ? $i + 1 + length($1) # actual indentation of following non-space non-comment
 474                     : $c ne "{" ? +($i + 1)  # just after '(' or '[' if only whitespace thereafter
 475                                 : -($i + 1); # allow also $stmt_indent if '{' with only whitespace thereafter
 476                 push @nested_symbols, $c; # done also for '?' to be able to check correct nesting
 477                 push @nested_conds_indents, $i if $c eq "?"; # remember special alternative indent for ':'
 478             }
 479         } elsif ($c =~ m/[})\]:]/) { # $c is '}', ')', ']', or ':'
 480             my $opening_c = ($c =~ tr/})]:/{([/r);
 481             if (($c ne ":" || $in_stmt    # ignore ':' outside stmt/expr/decl
 482                 # in the presence of ':', one could add this sanity check:
 483                 # && !(# ':' after initial label/case/default
 484                 #      $head =~ m/^([\s@]*)(case\W.*$|\w+$)/ || # this matching would not work for
 485                 #                                               # multi-line expr after 'case'
 486                 #      # bitfield length within unsigned type decl
 487                 #      $tail =~ m/^[\s@]*\d+/                   # this matching would need improvement
 488                 #     )
 489                 )) {
 490                 if ($c ne "}" || $in_stmt) { # for '}' inside stmt/expr/decl, ')', ']', or ':'
 491                     if (@nested_symbols != 0 &&
 492                         @nested_symbols[-1] == $opening_c) { # for $c there was a corresponding $opening_c
 493                         pop @nested_indents;
 494                         pop @nested_symbols;
 495                         pop @nested_conds_indents if $opening_c eq "?";
 496                     } else {
 497                         report("unexpected '$c' @ ".($in_paren_expr ? "(expr)" : "expr"));
 498                         next;
 499                     }
 500                 }
 501                 if ($c eq "}") { # '}' at block level but also inside stmt/expr/decl
 502                     if (@nested_block_indents == 0) {
 503                         report("unexpected '}'");
 504                     } else {
 505                         $block_indent = pop @nested_block_indents;
 506                         $hanging_offset = pop @nested_hanging_offsets;
 507                         $in_typedecl = pop @nested_in_typedecl if @nested_in_typedecl != 0;
 508                     }
 509                 }
 510                 if ($in_paren_expr && !grep(/\(/, @nested_symbols)) { # end of (expr)
 511                     check_nested_nonblock_indents("(expr)");
 512                     $in_paren_expr = $in_expr = 0;
 513                     report("code after (expr)")
 514                         if $tail =~ m/^([^{]*)/ && $1 =~ m/[^\s\@;]/; # non-space non-';' before any '{'
 515                 }
 516             }
 517         }
 518     }
 519     return -1;
 520 }
 521
 522 sub check_nested_nonblock_indents {
 523     my $position = shift;
 524     while (@nested_symbols != 0) {
 525         my $symbol = pop @nested_symbols;
 526         report("unclosed '$symbol' in $position");
 527         if ($symbol eq "{") { # repair stack of blocks
 528             $block_indent = pop @nested_block_indents;
 529             $hanging_offset = pop @nested_hanging_offsets;
 530             $in_typedecl = pop @nested_in_typedecl if @nested_in_typedecl != 0;
 531         }
 532     }
 533     @nested_indents = ();
 534     @nested_conds_indents = ();
 535 }
 536
 537 # start of main program @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
 538
 539 reset_file_state();
 540
 541 while (<>) { # loop over all lines of all input files
 542     $self_test = $ARGV =~ m/check-format-test/;
 543     $_ = "" if $self_test && m/ blank line within local decls /;
 544     $line++;
 545     s/\r$//; # strip any trailing CR '\r' (which are typical on Windows systems)
 546     $contents = $_;
 547
 548     # check for illegal characters
 549     if (m/(.*?)([\x00-\x09\x0B-\x1F\x7F-\xFF])/) {
 550         my $col = length($1);
 551         report(($2 eq "\x09" ? "TAB" : $2 eq "\x0D" ? "CR " : $2 =~ m/[\x00-\x1F]/ ? "non-printable"
 552                 : "non-7bit char") . " at column $col") ;
 553     }
 554
 555     # check for whitespace at EOL
 556     report("trailing whitespace at EOL") if m/\s\n$/;
 557
 558     # assign to $count the actual indentation level of the current line
 559     chomp; # remove trailing NL '\n'
 560     m/^(\s*)/;
 561     $count = length($1); # actual indentation
 562     $has_label = 0;
 563     $local_offset = 0;
 564
 565     # character/string literals @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
 566
 567     s/\\["']/@@/g; # blind all '"' and "'" escaped by '\' (typically within character literals or string literals)
 568
 569     # handle multi-line string literals to avoid confusion on starting/ending '"' and trailing '\'
 570     if ($in_multiline_string) {
 571         if (s#^([^"]*)"#($1 =~ tr/"/@/cr).'@'#e) { # string literal terminated by '"'
 572             # string contents and its terminating '"' have been blinded as '@'
 573             $count = -1; # do not check indentation
 574         } else {
 575             report("multi-line string literal not terminated by '\"' and trailing '\' is missing")
 576                 unless s#^([^\\]*)\s*\\\s*$#$1#; # strip trailing '\' plus any whitespace around
 577             goto LINE_FINISHED;
 578         }
 579     }
 580
 581     # blind contents of character and string literals as @, preserving length (but not spaces)
 582     # this prevents confusing any of the matching below, e.g., of whitespace and comment delimiters
 583     s#('[^']*')#$1 =~ tr/'/@/cr#eg; # handle all intra-line character literals
 584     s#("[^"]*")#$1 =~ tr/"/@/cr#eg; # handle all intra-line string literals
 585     $in_multiline_string =          # handle trailing string literal terminated by '\'
 586         s#^(([^"]*"[^"]*")*[^"]*)("[^"]*)\\(\s*)$#$1.($3 =~ tr/"/@/cr).'"'.$4#e;
 587         # its contents have been blinded and the trailing '\' replaced by '"'
 588
 589     # strip any other trailing '\' along with any whitespace around it such that it does not interfere with various matching below
 590     my $trailing_backslash = s#^(.*?)\s*\\\s*$#$1#; # trailing '\' possibly preceded or followed by whitespace
 591     my $essentially_blank_line = m/^\s*$/; # just whitespace and maybe a '\'
 592
 593     # comments @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
 594
 595     # do/prepare checks within multi-line comments
 596     my $self_test_exception = $self_test ? "@" : "";
 597     if ($in_comment > 0) { # this still includes the last line of multi-line comment
 598         my ($head, $any_symbol, $cmt_text) = m/^(\s*)(.?)(.*)$/;
 599         if ($any_symbol eq "*") {
 600             report("missing space or '*' after leading '*' in multi-line comment") if $cmt_text =~ m|^[^*\s/$self_test_exception]|;
 601         } else {
 602             report("missing leading '*' in multi-line comment");
 603         }
 604         $in_comment++;
 605     }
 606
 607     # detect end of comment, must be within multi-line comment, check if it is preceded by non-whitespace text
 608     if ((my ($head, $tail) = m|^(.*?)\*/(.*)$|) && $1 ne '/') { # ending comment: '*/'
 609         report("missing space or '*' before '*/'") if $head =~ m/[^*\s]$/;
 610         report("missing space (or ',', ';', ')', '}', ']') after '*/'") if $tail =~ m/^[^\s,;)}\]]/; # no space or ,;)}] after '*/'
 611         if (!($head =~ m|/\*|)) { # not begin of comment '/*', which is is handled below
 612             if ($in_comment == 0) {
 613                 report("unexpected '*/' outside comment");
 614                 $_ = "$head@@".$tail; # blind the "*/"
 615             } else {
 616                 report("text before '*/' in multi-line comment") if ($head =~ m/[^*\s]/); # non-SPC before '*/'
 617                 $in_comment = -1; # indicate that multi-line comment ends on current line
 618                 if ($count > 0) {
 619                     # make indentation of end of multi-line comment appear like of leading intra-line comment
 620                     $head =~ s/^(\s*)\s/$1@/; # replace the last leading space by '@'
 621                     $count--;
 622                     $in_comment = -2; # indicate that multi-line comment ends on current line, with tweak
 623                 }
 624                 my $cmt_text = $head;
 625                 $_ = blind_nonspace($cmt_text)."@@".$tail;
 626             }
 627         }
 628     }
 629
 630     # detect begin of comment, check if it is followed by non-space text
 631   MATCH_COMMENT:
 632     if (my ($head, $opt_minus, $tail) = m|^(.*?)/\*(-?)(.*)$|) { # begin of comment: '/*'
 633         report("missing space before '/*'")
 634             if $head =~ m/[^\s(\*]$/; # not space, '(', or or '*' (needed to allow '*/') before comment delimiter
 635         report("missing space, '*', or '!' after '/*$opt_minus'") if $tail =~ m/^[^\s*!$self_test_exception]/;
 636         my $cmt_text = $opt_minus.$tail; # preliminary
 637         if ($in_comment > 0) {
 638             report("unexpected '/*' inside multi-line comment");
 639         } elsif ($tail =~ m|^(.*?)\*/(.*)$|) { # comment end: */ on same line
 640             report("unexpected '/*' inside intra-line comment") if $1 =~ /\/\*/;
 641             # blind comment text, preserving length and spaces
 642             ($cmt_text, my $rest) = ($opt_minus.$1, $2);
 643             $_ = "$head@@".blind_nonspace($cmt_text)."@@".$rest;
 644             goto MATCH_COMMENT;
 645         } else { # begin of multi-line comment
 646             my $self_test_exception = $self_test ? "(@\d?)?" : "";
 647             report("text after '/*' in multi-line comment")
 648                 unless $tail =~ m/^$self_test_exception.?[*\s]*$/;
 649             # tail not essentially blank, first char already checked
 650             # adapt to actual indentation of first line
 651             $comment_indent = length($head) + 1;
 652             $_ = "$head@@".blind_nonspace($cmt_text);
 653             $in_comment = 1;
 654             $leading_comment = $head =~ m/^\s*$/; # there is code before beginning delimiter
 655             $formatted_comment = $opt_minus eq "-";
 656         }
 657     } elsif (($head, $tail) = m|^\{-(.*)$|) { # begin of Perl pragma: '{-'
 658     }
 659
 660     if ($in_comment > 1) { # still inside multi-line comment (not at its begin or end)
 661         m/^(\s*)\*?(\s*)(.*)$/;
 662         $_ = $1."@".$2.blind_nonspace($3);
 663     }
 664
 665     # handle special case of line after '#ifdef __cplusplus' (which typically appears in header files)
 666     if ($ifdef__cplusplus) {
 667         $ifdef__cplusplus = 0;
 668         $_ = "$1 $2" if $contents =~ m/^(\s*extern\s*"C"\s*)\{(\s*)$/; # ignore opening brace in 'extern "C" {'
 669         goto LINE_FINISHED if m/^\s*\}\s*$/; # ignore closing brace '}'
 670     }
 671
 672     # check for over-long lines,
 673     # while allowing trailing (also multi-line) string literals to go past $max_length
 674     my $len = length; # total line length (without trailing '\n')
 675     if ($len > $max_length &&
 676         !(m/^(.*)"[^"]*"\s*[\)\}\]]*[,;]?\s*$/ # string literal terminated by '"' (or '\'), then maybe )}],;
 677           && length($1) < $max_length)
 678         # this allows over-long trailing string literals with beginning col before $max_length
 679         ) {
 680         report("line length = $len > ".MAX_LINE_LENGTH);
 681     }
 682
 683     # handle C++ / C99 - style end-of-line comments
 684     if (my ($head, $cmt_text) = m|^(.*?)//(.*$)|) {
 685         report("'//' end-of-line comment");  # the '//' comment style is not allowed for C90
 686         # blind comment text, preserving length and spaces
 687         $_ = "$head@@".blind_nonspace($cmt_text);
 688     }
 689
 690     # at this point all non-space portions of any types of comments have been blinded as @
 691
 692     goto LINE_FINISHED if $essentially_blank_line;
 693
 694     # handle preprocessor directives @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
 695
 696     if (s/^(\s*#)(\s*)(\w+)//) { # line beginning with '#' and directive name;
 697         # blank these portions to prevent confusion with C-level 'if', 'else', etc.
 698         my ($lead, $space) = ($1, $2);
 699         $preproc_directive = $3;
 700         $_ = "$lead$space$preproc_directive$_" if $preproc_directive =~ m/^(define|include)$/; # yet do not blank #define or #include to prevent confusing the indentation or whitespace checks, resp.
 701         $_ =  blind_nonspace($_) if $preproc_directive eq "error"; # blind error message
 702         if ($in_preproc != 0) {
 703             report("preprocessor directive within multi-line directive");
 704             reset_indentation_state();
 705         }
 706         $in_preproc++;
 707         report("indent = $count != 0 for '#'") if $count != 0;
 708         report("'#$preproc_directive' with constant condition")
 709             if $preproc_directive =~ m/^(if|elif)$/ && m/^[\W0-9]+$/ && !$trailing_backslash;
 710         $preproc_if_nesting-- if $preproc_directive =~ m/^(else|elif|endif)$/;
 711         if ($preproc_if_nesting < 0) {
 712             $preproc_if_nesting = 0;
 713             report("unexpected '#$preproc_directive' according to '#if' nesting");
 714         }
 715         my $space_count = length($space); # maybe could also use indentation before '#'
 716         report("'#if' nesting indent = $space_count != $preproc_if_nesting") if $space_count != $preproc_if_nesting;
 717         $preproc_if_nesting++ if $preproc_directive =~ m/^(if|ifdef|ifndef|else|elif)$/;
 718         $ifdef__cplusplus = $preproc_directive eq "ifdef" && m/\s+__cplusplus\s*$/;
 719
 720         # handle indentation of preprocessor directive independently of surrounding normal code
 721         $count = -1; # do not check indentation of first line of preprocessor directive
 722         backup_indentation_state();
 723         reset_indentation_state();
 724     }
 725
 726     # intra-line whitespace nits @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
 727
 728     my $in_multiline_comment = ($in_comment > 1 || $in_comment < 0); # $in_multiline_comment refers to line before
 729     if (!$sloppy_SPC && !($in_multiline_comment && $formatted_comment)) {
 730         sub extra_SPC {
 731             my $intra_line = shift;
 732             return "extra space".($intra_line =~ m/@\s\s/ ?
 733                                   $in_comment != 0 ? " in multi-line comment"
 734                                                    : " in intra-line comment" : "");
 735         }
 736         sub split_line_head { # split line contents into header containing leading spaces and the first non-space char, and the rest of the line
 737             my $comment_symbol =
 738                 $in_comment != 0 ? "@" : ""; # '@' will match the blinded leading '*' in multi-line comment
 739                                              # $in_comment may pertain to the following line due to delayed check
 740             # do not check for extra SPC in leading spaces including any '#' (or '*' within multi-line comment)
 741             shift =~ m/^(\s*([#$comment_symbol]\s*)?)(.*?)\s*$/;
 742             return ($1, $3);
 743         }
 744         my ($head , $intra_line ) = split_line_head($_);
 745         my ($head1, $intra_line1) = split_line_head($contents_before_ ) if $line_before > 0;
 746         my ($head2, $intra_line2) = split_line_head($contents_before_2) if $line_before2 > 0;
 747         if ($line_before > 0) { # check with one line delay, such that at least $contents_before is available
 748             sub column_alignments_only { # return 1 if the given line has multiple consecutive spaces only at columns that match the reference line
 749                 # all parameter strings are assumed to contain contents after blinding comments etc.
 750                 my $head = shift;     # leading spaces and the first non-space char
 751                 my $intra = shift;    # the rest of the line contents
 752                 my $contents = shift; # reference line
 753                 # check if all extra SPC in $intra is used only for multi-line column alignment with $contents
 754                 my $offset = length($head);
 755                 for (my $col = 0; $col < length($intra) - 2; $col++) {
 756                     my $substr = substr($intra, $col);
 757                     next unless $substr =~ m/^\s\s\S/; # extra SPC (but not in leading spaces of the line)
 758                     next if !$eol_cmt && $substr =~ m/^[@\s]+$/; # end-of-line comment
 759                     return 0 unless substr($contents, $col + $offset + 1, 2) =~ m/\s\S/; # reference line contents do not match
 760                 }
 761                 return 1;
 762             }
 763             report_flexibly($line_before, extra_SPC($intra_line1), $contents_before) if $intra_line1 =~ m/\s\s\S/ &&
 764                !(    column_alignments_only($head1, $intra_line1, $_                )    # compare with $line
 765                  || ($line_before2 > 0 &&
 766                      column_alignments_only($head1, $intra_line1, $contents_before_2))); # compare w/ $line_before2
 767             report(extra_SPC($intra_line)) if $intra_line  =~ m/\s\s\S/ && eof
 768                 && ! column_alignments_only($head , $intra_line , $contents_before_ )  ; # compare w/ $line_before
 769         } elsif (eof) { # special case: just one line exists
 770             report(extra_SPC($intra_line)) if $intra_line  =~ m/\s\s\S/;
 771         }
 772         # ignore paths in #include
 773         $intra_line =~ s/^(include\s*)(".*?"|<.*?>)/$1/e if $head =~ m/#/;
 774         report("missing space before '$2'")
 775             if $intra_line =~ m/(\S)((<<|>>)=)/ # '<<=' or >>=' without preceding space
 776             || ($intra_line =~ m/(\S)([\+\-\*\/\/%\&\|\^\!<>=]=)/
 777                 && "$1$2" ne "<<=" && "$1$2" ne ">>=") # other <op>= or (in)equality without preceding space
 778             || ($intra_line =~ m/(\S)=/
 779                 && !($1 =~ m/[\+\-\*\/\/%\&\|\^\!<>=]/)
 780                 && $intra_line =~ m/(\S)(=)/); # otherwise, '=' without preceding space
 781         # treat op= and comparison operators as simple '=', simplifying matching below
 782         $intra_line =~ s/(<<|>>|[\+\-\*\/\/%\&\|\^\!<>=])=/=/g;
 783         # treat (type) variables within macro, indicated by trailing '\', as 'int' simplifying matching below
 784         $intra_line =~ s/[A-Z_]+/int/g if $trailing_backslash;
 785         # treat double &&, ||, <<, and >> as single ones, simplifying matching below
 786         $intra_line =~ s/(&&|\|\||<<|>>)/substr($1, 0, 1)/eg;
 787         # remove blinded comments etc. directly after [{(
 788         while ($intra_line =~ s/([\[\{\(])@+\s?/$1/e) {} # /g does not work here
 789         # remove blinded comments etc. directly before ,;)}]
 790         while ($intra_line =~ s/\s?@+([,;\)\}\]])/$1/e) {} # /g does not work here
 791         # treat remaining blinded comments and string literal contents as (single) space during matching below
 792         $intra_line =~ s/@+/ /g;                     # note that extra SPC has already been handled above
 793         $intra_line =~ s/\s+$//;                     # strip any (resulting) space at EOL
 794         # replace ';;' or '; ;' by ';' in "for(;;)" and in "for (...)" unless "..." contains just SPC and ';' characters:
 795         $intra_line =~ s/((^|\W)for\s*\()([^;]*?)(\s*)(;\s?);(\s*)([^;]*)(\))/
 796           "$1$3$4".("$3$4$5$6$7" eq ";" || $3 ne "" || $7 ne "" ? "" : $5).";$6$7$8"/eg;
 797         # strip trailing ';' or '; ' in "for (...)" except in "for (;;)" or "for (;; )":
 798         $intra_line =~ s/((^|\W)for\s*\()([^;]*(;[^;]*)?)(;\s?)(\))/
 799           "$1$3".($3 eq ";" ? $5 : "")."$6"/eg;
 800         $intra_line =~ s/(=\s*)\{ /"$1@ "/eg;        # do not report {SPC in initializers such as ' = { 0, };'
 801         $intra_line =~ s/, \};/, @;/g;               # do not report SPC} in initializers such as ' = { 0, };'
 802         report("space before '$1'") if $intra_line =~ m/[\w)\]]\s+(\+\+|--)/;  # postfix ++/-- with preceding space
 803         report("space after '$1'")  if $intra_line =~ m/(\+\+|--)\s+[a-zA-Z_(]/; # prefix ++/-- with following space
 804         $intra_line =~ s/\.\.\./@/g;                 # blind '...'
 805         report("space before '$1'") if $intra_line =~ m/\s(\.|->)/;            # '.' or '->' with preceding space
 806         report("space after '$1'")  if $intra_line =~ m/(\.|->)\s/;            # '.' or '->' with following space
 807         $intra_line =~ s/\-\>|\+\+|\-\-/@/g;         # blind '->,', '++', and '--'
 808         report("space before '$1'")     if $intra_line =~ m/[^:)]\s+(;)/;      # space before ';' but not after ':' or ')' # note that
 809         # exceptions for "for (;; )" are handled above
 810         report("space before '$1'")     if $intra_line =~ m/\s([,)\]])/;       # space before ,)]
 811         report("space after '$1'")      if $intra_line =~ m/([(\[~!])\s/;      # space after ([~!
 812         report("space after '$1'")      if $intra_line =~ m/(defined)\s/;      # space after 'defined'
 813         report("missing space before '$1'")  if $intra_line =~ m/\S([|\/%<>^\?])/;  # |/%<>^? without preceding space
 814         # TODO ternary ':' without preceding SPC, while allowing no SPC before ':' after 'case'
 815         report("missing space before binary '$2'")  if $intra_line =~ m/([^\s{()\[e])([+\-])/; # '+'/'-' without preceding space or {()[e
 816         # ')' may be used for type casts or before "->", 'e' may be used for numerical literals such as "1e-6"
 817         report("missing space before binary '$1'")  if $intra_line =~ m/[^\s{()\[*!]([*])/; # '*' without preceding space or {()[*!
 818         report("missing space before binary '$1'")  if $intra_line =~ m/[^\s{()\[]([&])/;  # '&' without preceding space or {()[
 819         report("missing space after ternary '$1'") if $intra_line =~ m/(:)[^\s\d]/; # ':' without following space or digit
 820         report("missing space after '$1'")   if $intra_line =~ m/([,;=|\/%<>^\?])\S/; # ,;=|/%<>^? without following space
 821         report("missing space after binary '$1'") if $intra_line=~m/[^{(\[]([*])[^\sa-zA-Z_(),*]/;# '*' w/o space or \w(),* after
 822         # TODO unary '*' must not be followed by SPC
 823         report("missing space after binary '$1'") if $intra_line=~m/([&])[^\sa-zA-Z_(]/;  # '&' w/o following space or \w(
 824         # TODO unary '&' must not be followed by SPC
 825         report("missing space after binary '$1'") if $intra_line=~m/[^{(\[]([+\-])[^\s\d(]/;  # +/- w/o following space or \d(
 826         # TODO unary '+' and '-' must not be followed by SPC
 827         report("missing space after '$2'")   if $intra_line =~ m/(^|\W)(if|while|for|switch|case)[^\w\s]/; # kw w/o SPC
 828         report("missing space after '$2'")   if $intra_line =~ m/(^|\W)(return)[^\w\s;]/;  # return w/o SPC or ';'
 829         report("space after function/macro name")
 830                                       if $intra_line =~ m/(\w+)\s+\(/        # fn/macro name with space before '('
 831        && !($1 =~ m/^(sizeof|if|else|while|do|for|switch|case|default|break|continue|goto|return|void|char|signed|unsigned|int|short|long|float|double|typedef|enum|struct|union|auto|extern|static|const|volatile|register)$/) # not keyword
 832                                     && !(m/^\s*#\s*define\s+\w+\s+\(/); # not a macro without parameters having a body that starts with '('
 833         report("missing space before '{'")   if $intra_line =~ m/[^\s{(\[]\{/;      # '{' without preceding space or {([
 834         report("missing space after '}'")    if $intra_line =~ m/\}[^\s,;\])}]/;    # '}' without following space or ,;])}
 835     }
 836
 837     # adapt required indentation @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
 838
 839     s/(\w*ASN1_[A-Z_]+END\w*([^(]|\(.*?\)|$))/$1;/g; # treat *ASN1_*END*(..) macro calls as if followed by ';'
 840
 841     my $nested_indents_position = 0;
 842
 843     # update indents according to leading closing brace(s) '}' or label or switch case
 844     my $in_stmt = $in_expr || @nested_symbols != 0 || $in_typedecl != 0;
 845     if ($in_stmt) { # expr/stmt/type decl/var def/fn hdr, i.e., not at block level
 846         if (m/^([\s@]*\})/) { # leading '}' within stmt, any preceding blinded comment must not be matched
 847             $in_block_decls = -1;
 848             my $head = $1;
 849             update_nested_indents($head);
 850             $nested_indents_position = length($head);
 851             if (@nested_symbols >= 1) {
 852                 $hanging_symbol = @nested_symbols[-1];
 853                 $expr_indent = @nested_indents[-1];
 854             } else { # typically end of initialiizer expr or enum
 855                 $expr_indent = 0;
 856             }
 857         } elsif (m/^([\s@]*)(static_)?ASN1_ITEM_TEMPLATE_END(\W|$)/) { # workaround for ASN1 macro indented as '}'
 858             $local_offset = -INDENT_LEVEL;
 859             $expr_indent = 0;
 860         } elsif (m/;.*?\}/) { # expr ends with ';' before '}'
 861             report("code before '}'");
 862         }
 863     }
 864     if (@in_do_hanging_offsets != 0 && # note there is nothing like "unexpected 'while'"
 865         m/^[\s@]*while(\W|$)/) { # leading 'while'
 866         $hanging_offset = pop @in_do_hanging_offsets;
 867     }
 868     if ($if_maybe_terminated) {
 869         if (m/(^|\W)else(\W|$)/) { # (not necessarily leading) 'else'
 870             if (@in_if_hanging_offsets == 0) {
 871                 report("unexpected 'else'");
 872             } else {
 873                 $hanging_offset = pop @in_if_hanging_offsets;
 874             }
 875         } else {
 876             @in_if_hanging_offsets = (); # note there is nothing like "unclosed 'if'"
 877             $hanging_offset = 0;
 878         }
 879     }
 880     if (!$in_stmt) { # at block level, i.e., outside expr/stmt/type decl/var def/fn hdr
 881         $if_maybe_terminated = 0;
 882         if (my ($head, $before, $tail) = m/^([\s@]*([^{}]*)\})[\s@]*(.*)$/) { # leading closing '}', but possibly
 883                                                                               # with non-whitespace non-'{' before
 884             report("code after '}'") unless $tail eq "" || $tail =~ m/(else|while|OSSL_TRACE_END)(\W|$)/;
 885             my $outermost_level = @nested_block_indents == 1 && @nested_block_indents[0] == 0;
 886             if (!$sloppy_bodylen && $outermost_level && $line_body_start != 0) {
 887                 my $body_len = $line - $line_body_start - 1;
 888                 report_flexibly($line_function_start, "function body length = $body_len > ".MAX_BODY_LENGTH." lines",
 889                     $last_function_header) if $body_len > MAX_BODY_LENGTH;
 890                 $line_body_start = 0;
 891             }
 892             if ($before ne "") { # non-whitespace non-'{' before '}'
 893                 report("code before '}'");
 894             } else { # leading '}' outside stmt, any preceding blinded comment must not be matched
 895                 $in_block_decls = -1;
 896                 $local_offset = $block_indent + $hanging_offset - INDENT_LEVEL;
 897                 update_nested_indents($head);
 898                 $nested_indents_position = length($head);
 899                 $local_offset -= ($block_indent + $hanging_offset);
 900                 # in effect $local_offset = -INDENT_LEVEL relative to $block_indent + $hanging_offset values before
 901             }
 902         }
 903
 904         # handle opening brace '{' after if/else/while/for/switch/do on line before
 905         if ($hanging_offset > 0 && m/^[\s@]*{/ && # leading opening '{'
 906             $line_before > 0 &&
 907             $contents_before_ =~ m/(^|^.*\W)(if|else|while|for|switch|do)(\W.*$|$)/) {
 908             $keyword_opening_brace = $1;
 909             $hanging_offset -= INDENT_LEVEL; # cancel newly hanging_offset
 910         }
 911
 912         if (m/^[\s@]*(case|default)(\W.*$|$)/) { # leading 'case' or 'default'
 913             my $keyword = $1;
 914             report("code after $keyword: ") if $2 =~ /:.*[^\s@].*$/;
 915             $local_offset = -INDENT_LEVEL;
 916         } else {
 917             if (m/^([\s@]*)(\w+):/) { # (leading) label, cannot be "default"
 918                 $local_offset = -INDENT_LEVEL;
 919                 $has_label = 1;
 920             }
 921         }
 922     }
 923
 924     # potential adaptations of indent in first line of macro body in multi-line macro definition
 925     if ($in_preproc != 0 && $in_macro_header > 0) {
 926         if ($in_macro_header > 1) { # still in macro definition header
 927             $in_macro_header += parens_balance($_);
 928         } else { # begin of macro body
 929             $in_macro_header = 0;
 930             if ($count == $block_indent - $preproc_offset # body began with same indentation as preceding code
 931                 && $sloppy_macro) { # workaround for this situation is enabled
 932                 $block_indent -= $preproc_offset;
 933                 $preproc_offset = 0;
 934             }
 935         }
 936     }
 937
 938     # check required indentation @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
 939
 940     check_indent() if $count >= 0; # not for start of preprocessor directive and not if multi-line string literal is continued
 941
 942     # check for blank lines within/after local decls @@@@@@@@@@@@@@@@@@@@@@@@@@@
 943
 944     if ($in_block_decls >= 0 &&
 945         $in_comment == 0 && !m/^\s*\*?@/ && # not in a multi-line or intra-line comment
 946         !$in_expr && $expr_indent == 0 && $in_typedecl == 0) {
 947         my $blank_line_before = $line > 1 && $code_contents_before =~ m/^\s*(\\\s*)?$/;
 948         # essentially blank line before: just whitespace and maybe a '\'
 949         if (m/^[\s(]*(char|signed|unsigned|int|short|long|float|double|enum|struct|union|auto|extern|static|const|volatile|register)(\W|$)/ # clear start of local decl
 950             || (m/^(\s*(\w+|\[\]|[\*()]))+?\s+[\*\(]*\w+(\s*(\)|\[[^\]]*\]))*\s*[;,=]/ # weak check for decl involving user-defined type
 951                 && !m/^\s*(\}|sizeof|if|else|while|do|for|switch|case|default|break|continue|goto|return)(\W|$)/)) {
 952             $in_block_decls++;
 953             report_flexibly($line - 1, "blank line within local decls, before", $contents) if $blank_line_before;
 954         } else {
 955             report_flexibly($line, "missing blank line after local decls", "\n$contents_before$contents")
 956                 if $in_block_decls > 0 && !$blank_line_before;
 957             $in_block_decls = -1 unless
 958                 m/^\s*(\\\s*)?$/ # essentially blank line: just whitespace (and maybe a trailing '\')
 959             || $in_comment != 0 || m/^\s*\*?@/; # in multi-line comment or an intra-line comment
 960         }
 961     }
 962
 963     $in_comment = 0 if $in_comment < 0; # multi-line comment has ended
 964
 965     # do some further checks @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
 966
 967     my $outermost_level = $block_indent - $preproc_offset == 0;
 968
 969     report("more than one stmt") if !m/(^|\W)for(\W.*|$)/ && # no 'for' - TODO improve matching
 970         m/;.*;/; # two or more terminators ';', so more than one statement
 971
 972     # check for code block containing a single line/statement
 973     if ($line_before2 > 0 && !$outermost_level && # within function body
 974         $in_typedecl == 0 && @nested_indents == 0 && # neither within type declaration nor inside stmt/expr
 975         m/^[\s@]*\}/) { # leading closing brace '}', any preceding blinded comment must not be matched
 976         # TODO extend detection from single-line to potentially multi-line statement
 977         if ($line_opening_brace > 0 &&
 978             ($line_opening_brace == $line_before2 ||
 979              $line_opening_brace == $line_before)
 980             && $contents_before =~ m/;/) { # there is at least one terminator ';', so there is some stmt
 981             # TODO do not report cases where a further else branch
 982             # follows with a block containing more than one line/statement
 983             report_flexibly($line_before, "'$keyword_opening_brace' { 1 stmt }", $contents_before);
 984         }
 985     }
 986
 987     report("single-letter name '$2'") if (m/(^|.*\W)([IO])(\W.*|$)/); # single-letter name 'I' or 'O' # maybe re-add 'l'?
 988     # constant on LHS of comparison or assignment, e.g., NULL != x or 'a' < c, but not a + 1 == b
 989     report("constant on LHS of '$3'")
 990         if (m/(['"]|([\+\-\*\/\/%\&\|\^<>]\s*)?\W[0-9]+L?|\WNULL)\s*([\!<>=]=|[<=>])([<>]?)/ &&
 991             $2 eq "" && (($3 ne "<" && $3 ne "='" && $3 ne ">") || $4 eq ""));
 992
 993     # TODO report needless use of parentheses, while
 994     #      macro parameters should always be in parens (except when passed on), e.g., '#define ID(x) (x)'
 995
 996     # adapt required indentation for following lines @@@@@@@@@@@@@@@@@@@@@@@@@@@
 997
 998     # set $in_expr, $in_paren_expr, and $hanging_offset for if/while/for/switch, return/enum, and assignment RHS
 999     my $paren_expr_start = 0;
1000     my $return_enum_start = 0;
1001     my $assignment_start = 0;
1002     my $tmp = $_;
1003     $tmp =~ s/[\!<>=]=/@@/g; # blind (in-)equality symbols like '<=' as '@@' to prevent matching them as '=' below
1004     if      (m/^((^|.*\W)(if|while|for|switch))(\W.*|$)$/) { # (last) if/for/while/switch
1005         $paren_expr_start = 1;
1006     } elsif (m/^((^|.*\W)(return|enum))(\W.*|$)/             # (last) return/enum
1007         && !$in_expr && @nested_indents == 0 && parens_balance($1) == 0) { # not nested enum
1008         $return_enum_start = 1;
1009     } elsif ($tmp =~ m/^(([^=]*)(=))(.*)$/                   # (last) '=', i.e., assignment
1010         && !$in_expr && @nested_indents == 0 && parens_balance($1) == 0) { # not nested assignment
1011         $assignment_start = 1;
1012     }
1013     if ($paren_expr_start || $return_enum_start || $assignment_start)
1014     {
1015         my ($head, $mid, $tail) = ($1, $3, $4);
1016         $keyword_opening_brace = $mid if $mid ne "=";
1017         # to cope with multi-line expressions, do this also if !($tail =~ m/\{/)
1018         push @in_if_hanging_offsets, $hanging_offset if $mid eq "if";
1019
1020         # already handle $head, i.e., anything before expression
1021         update_nested_indents($head, $nested_indents_position);
1022         $nested_indents_position = length($head);
1023         # now can set $in_expr and $in_paren_expr
1024         $in_expr = 1;
1025         $in_paren_expr = 1 if $paren_expr_start;
1026         if ($mid eq "while" && @in_do_hanging_offsets != 0) {
1027             $hanging_offset = pop @in_do_hanging_offsets;
1028         } else {
1029             $hanging_offset += INDENT_LEVEL; # tentatively set hanging_offset, may be canceled by following '{'
1030         }
1031     }
1032
1033     # set $hanging_offset and $keyword_opening_brace for do/else
1034     if (my ($head, $mid, $tail) = m/(^|^.*\W)(else|do)(\W.*|$)$/) { # last else/do, where 'do' is preferred, but not #else
1035         my $code_before = $head =~ m/[^\s\@}]/; # leading non-whitespace non-comment non-'}'
1036         report("code before '$mid'") if $code_before;
1037         report("code after '$mid'" ) if $tail =~ m/[^\s\@{]/# trailing non-whitespace non-comment non-'{' (non-'\')
1038                                                     && !($mid eq "else" && $tail =~ m/[\s@]*if(\W|$)/);
1039         if ($mid eq "do") { # workarounds for code before 'do'
1040             if ($head =~ m/(^|^.*\W)(else)(\W.*$|$)/) { # 'else' ... 'do'
1041                 $hanging_offset += INDENT_LEVEL; # tentatively set hanging_offset, may be canceled by following '{'
1042             }
1043             if ($head =~ m/;/) { # terminator ';' ... 'do'
1044                 @in_if_hanging_offsets = (); # note there is nothing like "unclosed 'if'"
1045                 $hanging_offset = 0;
1046             }
1047         }
1048         push @in_do_hanging_offsets, $hanging_offset if $mid eq "do";
1049         if ($code_before && $mid eq "do") {
1050             $hanging_offset = length($head) - $block_indent;
1051         }
1052         if (!$in_paren_expr) {
1053             $keyword_opening_brace = $mid if $tail =~ m/\{/;
1054             $hanging_offset += INDENT_LEVEL;
1055         }
1056     }
1057
1058     # set $in_typedecl and potentially $hanging_offset for type declaration
1059     if (!$in_expr && @nested_indents == 0 # not in expression
1060         && m/(^|^.*\W)(typedef|enum|struct|union)(\W.*|$)$/
1061         && parens_balance($1) == 0 # not in newly started expression or function arg list
1062         && ($2 eq "typedef" || !($3 =~ m/\s*\w++\s*(.)/ && $1 ne "{")) # 'struct'/'union'/'enum' <name> not followed by '{'
1063         # not needed: && $keyword_opening_brace = $2 if $3 =~ m/\{/;
1064         ) {
1065         $in_typedecl++;
1066         $hanging_offset += INDENT_LEVEL if m/\*.*\(/; # '*' followed by '(' - seems consistent with Emacs C mode
1067     }
1068
1069     my $local_in_expr = $in_expr;
1070     my $terminator_position = update_nested_indents($_, $nested_indents_position);
1071
1072     if ($local_in_expr) {
1073         # on end of non-if/while/for/switch (multi-line) expression (i.e., return/enum/assignment) and
1074         # on end of statement/type declaration/variable definition/function header
1075         if ($terminator_position >= 0 && ($in_typedecl == 0 || @nested_indents == 0)) {
1076             check_nested_nonblock_indents("expr");
1077             $in_expr = 0;
1078         }
1079     } else {
1080         check_nested_nonblock_indents($in_typedecl == 0 ? "stmt" : "decl") if $terminator_position >= 0;
1081     }
1082
1083     # on ';', which terminates the current statement/type declaration/variable definition/function declaration
1084     if ($terminator_position >= 0) {
1085         my $tail = substr($_, $terminator_position + 1);
1086         if (@in_if_hanging_offsets != 0) {
1087             if ($tail =~ m/\s*else(\W|$)/) {
1088                 pop @in_if_hanging_offsets;
1089                 $hanging_offset -= INDENT_LEVEL;
1090             } elsif ($tail =~ m/[^\s@]/) { # code (not just comment) follows
1091                 @in_if_hanging_offsets = (); # note there is nothing like "unclosed 'if'"
1092                 $hanging_offset = 0;
1093             } else {
1094                 $if_maybe_terminated = 1;
1095             }
1096         } elsif ($tail =~ m/^[\s@]*$/) { # ';' has been trailing, i.e. there is nothing but whitespace and comments
1097             $hanging_offset = 0; # reset in case of terminated assignment ('=') etc.
1098         }
1099         $in_typedecl-- if $in_typedecl != 0 && @nested_in_typedecl == 0; # TODO handle multiple type decls per line
1100         m/(;[^;]*)$/; # match last ';'
1101         $terminator_position = length($_) - length($1) if $1;
1102         # new $terminator_position value may be after the earlier one in case multiple terminators on current line
1103         # TODO check treatment in case of multiple terminators on current line
1104         update_nested_indents($_, $terminator_position + 1);
1105     }
1106
1107     # set hanging expression indent according to nested indents - TODO maybe do better in update_nested_indents()
1108     # also if $in_expr is 0: in statement/type declaration/variable definition/function header
1109     $expr_indent = 0;
1110     for (my $i = -1; $i >= -@nested_symbols; $i--) {
1111         if (@nested_symbols[$i] ne "?") { # conditionals '?' ... ':' are treated specially in check_indent()
1112             $hanging_symbol = @nested_symbols[$i];
1113             $expr_indent = $nested_indents[$i];
1114             # $expr_indent is guaranteed to be != 0 unless @nested_indents contains just outer conditionals
1115             last;
1116         }
1117     }
1118
1119     # remember line number and header containing name of last function defined for reports w.r.t. MAX_BODY_LENGTH
1120     if ($in_preproc == 0 && $outermost_level && m/(\w+)\s*\(/ && $1 ne "STACK_OF") {
1121         $line_function_start = $line;
1122         $last_function_header = $contents;
1123     }
1124
1125     # special checks for last, typically trailing opening brace '{' in line
1126     if (my ($head, $tail) = m/^(.*)\{(.*)$/) { # match last ... '{'
1127         if (!$in_expr && $in_typedecl == 0) {
1128             if ($outermost_level) {
1129                 if (!$assignment_start && !$local_in_expr) {
1130                     # at end of function definition header (or stmt or var definition)
1131                     report("'{' not at line start") if length($head) != $preproc_offset && $head =~ m/\)\s*/; # at end of function definition header
1132                     $line_body_start = $contents =~ m/LONG BODY/ ? 0 : $line if $line_function_start != 0;
1133                 }
1134             } else {
1135                 $line_opening_brace = $line if $keyword_opening_brace =~ m/do|while|for/;
1136                 # using, not assigning, $keyword_opening_brace here because it could be on an earlier line
1137                 $line_opening_brace = $line if $keyword_opening_brace =~ m/if|else/ && $extended_1_stmt &&
1138                 # TODO prevent false positives for if/else where braces around single-statement branches
1139                 # should be avoided but only if all branches have just single statements
1140                 # The following helps detecting the exception when handling multiple 'if ... else' branches:
1141                     !($keyword_opening_brace eq "else" && $line_opening_brace < $line_before2);
1142             }
1143             report("code after '{'") if $tail=~ m/[^\s\@]/ && # trailing non-whitespace non-comment (non-'\')
1144                                       !($tail=~ m/\}/);  # missing '}' after last '{'
1145         }
1146     }
1147
1148     # check for opening brace after if/while/for/switch/do not on same line
1149     # note that "missing '{' on same line after '} else'" is handled further below
1150     if (/^[\s@]*{/ && # leading '{'
1151         $line_before > 0 && !($contents_before_ =~ m/^\s*#/) && # not preprocessor directive '#if
1152         (my ($head, $mid, $tail) = ($contents_before_ =~ m/(^|^.*\W)(if|while|for|switch|do)(\W.*$|$)/))) {
1153         my $brace_after  = $tail =~ /^[\s@]*{/; # any whitespace or comments then '{'
1154         report("'{' not on same line as preceding '$mid'") if !$brace_after;
1155     }
1156     # check for closing brace on line before 'else' not followed by leading '{'
1157     elsif (my ($head, $tail) = m/(^|^.*\W)else(\W.*$|$)/) {
1158         if (parens_balance($tail) == 0 &&  # avoid false positive due to unfinished expr on current line
1159             !($tail =~ m/{/) && # after 'else' missing '{' on same line
1160             !($head =~ m/}[\s@]*$/) && # not: '}' then any whitespace or comments before 'else'
1161             $line_before > 0 && $contents_before_ =~ /}[\s@]*$/) { # trailing '}' on line before
1162             report("missing '{' on same line after '} else'");
1163         }
1164     }
1165
1166     # check for closing brace before 'while' not on same line
1167     if (my ($head, $tail) = m/(^|^.*\W)while(\W.*$|$)/) {
1168         my $brace_before = $head =~ m/}[\s@]*$/; # '}' then any whitespace or comments
1169         # possibly 'if (...)' (with potentially inner '(' and ')') then any whitespace or comments then '{'
1170         if (!$brace_before &&
1171             # does not work here: @in_do_hanging_offsets != 0 && #'while' terminates loop
1172             parens_balance($tail) == 0 &&  # avoid false positive due to unfinished expr on current line
1173             $tail =~ /;/ && # 'while' terminates loop (by ';')
1174             $line_before > 0 &&
1175             $contents_before_ =~ /}[\s@]*$/) { # on line before: '}' then any whitespace or comments
1176                 report("'while' not on same line as preceding '}'");
1177             }
1178     }
1179
1180     # check for missing brace on same line before or after 'else'
1181     if (my ($head, $tail) = m/(^|^.*\W)else(\W.*$|$)/) {
1182         my $brace_before = $head =~ /}[\s@]*$/; # '}' then any whitespace or comments
1183         my $brace_after  = $tail =~ /^[\s@]*if[\s@]*\(.*\)[\s@]*{|[\s@]*{/;
1184         # possibly 'if (...)' (with potentially inner '(' and ')') then any whitespace or comments then '{'
1185         if (!$brace_before) {
1186             if ($line_before > 0 && $contents_before_ =~ /}[\s@]*$/) {
1187                 report("'else' not on same line as preceding '}'");
1188             } elsif (parens_balance($tail) == 0) { # avoid false positive due to unfinished expr on current line
1189                 report("missing '}' on same line before 'else ... {'") if $brace_after;
1190             }
1191         } elsif (parens_balance($tail) == 0) { # avoid false positive due to unfinished expr on current line
1192             report("missing '{' on same line after '} else'") if $brace_before && !$brace_after;
1193         }
1194     }
1195
1196     # on begin of multi-line preprocessor directive, adapt indent
1197     if ($in_comment == 0 && $trailing_backslash) {
1198         # trailing '\'typically used in preprocessor directive like '#define'
1199         if ($in_preproc == 1) { # start of multi-line preprocessor directive
1200             # note that backup+reset_indentation_state() has already been called
1201             $in_macro_header = m/^\s*#\s*define(\W|$)?(.*)/ ? 1 + parens_balance($2) : 0; # '#define' is beginning
1202             $preproc_offset = INDENT_LEVEL;
1203             $block_indent = $preproc_offset;
1204         }
1205         $in_preproc += 1;
1206     }
1207
1208     # post-processing at end of line @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
1209
1210   LINE_FINISHED:
1211     $code_contents_before = $contents if
1212         !m/^\s*#(\s*)(\w+)/ && # not single-line preprocessor directive
1213         $in_comment == 0 && !m/^\s*\*?@/; # not in a multi-line comment nor in an intra-line comment
1214
1215     # on end of (possibly multi-line) preprocessor directive, adapt indent
1216     if ($in_preproc != 0 && !$trailing_backslash) { # no trailing '\'
1217         $in_preproc = 0;
1218         $preproc_offset = 0;
1219         restore_indentation_state();
1220     }
1221
1222     if ($essentially_blank_line) {
1223             report("leading ".($1 eq "" ? "blank" :"whitespace")." line") if $line == 1 && !$sloppy_SPC;
1224     } else {
1225         if ($line_before > 0) {
1226             my $linediff = $line - $line_before - 1;
1227             report("$linediff blank lines before") if $linediff > 1 && !$sloppy_SPC;
1228         }
1229         $line_before2      = $line_before;
1230         $contents_before2  = $contents_before;
1231         $contents_before_2 = $contents_before_;
1232         $line_before       = $line;
1233         $contents_before   = $contents;
1234         $contents_before_  = $_;
1235         $count_before      = $count;
1236     }
1237
1238     if ($self_test) { # debugging
1239         my $should_report = $contents =~ m/\*@(\d)?/ ? 1 : 0;
1240         $should_report = +$1 if $should_report != 0 && defined $1;
1241         print("$ARGV:$line:$num_reports_line reports on:$contents")
1242             if $num_reports_line != $should_report;
1243     }
1244     $num_reports_line = 0;
1245
1246     # post-processing at end of file @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
1247
1248     if (eof) {
1249         # check for essentially blank line (which may include a '\') just before EOF
1250         report(($1 eq "\n" ? "blank line" : $2 ne "" ? "'\\'" : "whitespace")." at EOF")
1251             if $contents =~ m/^(\s*(\\?)\s*)$/ && !$sloppy_SPC;
1252
1253         # report unclosed expression-level nesting
1254         check_nested_nonblock_indents("expr at EOF"); # also adapts @nested_block_indents
1255
1256         # sanity-check balance of block-level { ... } via final $block_indent at end of file
1257         report_flexibly($line, +@nested_block_indents." unclosed '{'", "(EOF)\n") if @nested_block_indents != 0;
1258
1259         # sanity-check balance of #if ... #endif via final preprocessor directive indent at end of file
1260         report_flexibly($line, "$preproc_if_nesting unclosed '#if'", "(EOF)\n") if $preproc_if_nesting != 0;
1261
1262         reset_file_state();
1263     }
1264 }
1265
1266 # final summary report @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
1267
1268 my $num_other_reports = $num_reports - $num_indent_reports - $num_nesting_issues
1269     - $num_syntax_issues - $num_SPC_reports - $num_length_reports;
1270 print "$num_reports ($num_indent_reports indentation, $num_nesting_issues '#if' nesting indent, ".
1271     "$num_syntax_issues syntax, $num_SPC_reports whitespace, $num_length_reports length, $num_other_reports other)".
1272     " issues have been found by $0\n" if $num_reports != 0 && !$self_test;