test/ssl-tests/protocol_version.pm

   1 # -*- mode: perl; -*-
   2 # Copyright 2016-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9
  10 ## Test version negotiation
  11
  12 package ssltests;
  13
  14 use strict;
  15 use warnings;
  16
  17 use List::Util qw/max min/;
  18
  19 use OpenSSL::Test;
  20 use OpenSSL::Test::Utils qw/anydisabled alldisabled disabled/;
  21 setup("no_test_here");
  22
  23 my @tls_protocols = ("SSLv3", "TLSv1", "TLSv1.1", "TLSv1.2", "TLSv1.3");
  24 # undef stands for "no limit".
  25 my @min_tls_protocols = (undef, "SSLv3", "TLSv1", "TLSv1.1", "TLSv1.2", "TLSv1.3");
  26 my @max_tls_protocols = ("SSLv3", "TLSv1", "TLSv1.1", "TLSv1.2", "TLSv1.3", undef);
  27
  28 my @is_tls_disabled = anydisabled("ssl3", "tls1", "tls1_1", "tls1_2", "tls1_3");
  29
  30 my $min_tls_enabled; my $max_tls_enabled;
  31
  32 # Protocol configuration works in cascades, i.e.,
  33 # $no_tls1_1 disables TLSv1.1 and below.
  34 #
  35 # $min_enabled and $max_enabled will be correct if there is at least one
  36 # protocol enabled.
  37 foreach my $i (0..$#tls_protocols) {
  38     if (!$is_tls_disabled[$i]) {
  39         $min_tls_enabled = $i;
  40         last;
  41     }
  42 }
  43
  44 foreach my $i (0..$#tls_protocols) {
  45     if (!$is_tls_disabled[$i]) {
  46         $max_tls_enabled = $i;
  47     }
  48 }
  49
  50 my @dtls_protocols = ("DTLSv1", "DTLSv1.2");
  51 # undef stands for "no limit".
  52 my @min_dtls_protocols = (undef, "DTLSv1", "DTLSv1.2");
  53 my @max_dtls_protocols = ("DTLSv1", "DTLSv1.2", undef);
  54
  55 my @is_dtls_disabled = anydisabled("dtls1", "dtls1_2");
  56
  57 my $min_dtls_enabled; my $max_dtls_enabled;
  58
  59 # $min_enabled and $max_enabled will be correct if there is at least one
  60 # protocol enabled.
  61 foreach my $i (0..$#dtls_protocols) {
  62     if (!$is_dtls_disabled[$i]) {
  63         $min_dtls_enabled = $i;
  64         last;
  65     }
  66 }
  67
  68 foreach my $i (0..$#dtls_protocols) {
  69     if (!$is_dtls_disabled[$i]) {
  70         $max_dtls_enabled = $i;
  71     }
  72 }
  73
  74 sub no_tests {
  75     my ($dtls) = @_;
  76     return $dtls ? alldisabled("dtls1", "dtls1_2") :
  77       alldisabled("ssl3", "tls1", "tls1_1", "tls1_2", "tls1_3");
  78 }
  79
  80 sub generate_version_tests {
  81     my ($method) = @_;
  82
  83     my $dtls = $method eq "DTLS";
  84     # Don't write the redundant "Method = TLS" into the configuration.
  85     undef $method if !$dtls;
  86
  87     my @protocols = $dtls ? @dtls_protocols : @tls_protocols;
  88     my @min_protocols = $dtls ? @min_dtls_protocols : @min_tls_protocols;
  89     my @max_protocols = $dtls ? @max_dtls_protocols : @max_tls_protocols;
  90     my $min_enabled  = $dtls ? $min_dtls_enabled : $min_tls_enabled;
  91     my $max_enabled  = $dtls ? $max_dtls_enabled : $max_tls_enabled;
  92
  93     if (no_tests($dtls)) {
  94         return;
  95     }
  96
  97     my @tests = ();
  98
  99     for (my $sctp = 0; $sctp < ($dtls && !disabled("sctp") ? 2 : 1); $sctp++) {
 100         foreach my $c_min (0..$#min_protocols) {
 101             my $c_max_min = $c_min == 0 ? 0 : $c_min - 1;
 102             foreach my $c_max ($c_max_min..$#max_protocols) {
 103                 foreach my $s_min (0..$#min_protocols) {
 104                     my $s_max_min = $s_min == 0 ? 0 : $s_min - 1;
 105                     foreach my $s_max ($s_max_min..$#max_protocols) {
 106                         my ($result, $protocol) =
 107                             expected_result($c_min, $c_max, $s_min, $s_max,
 108                                             $min_enabled, $max_enabled,
 109                                             \@protocols);
 110                         push @tests, {
 111                             "name" => "version-negotiation",
 112                             "client" => {
 113                                 "MinProtocol" => $min_protocols[$c_min],
 114                                 "MaxProtocol" => $max_protocols[$c_max],
 115                             },
 116                             "server" => {
 117                                 "MinProtocol" => $min_protocols[$s_min],
 118                                 "MaxProtocol" => $max_protocols[$s_max],
 119                             },
 120                             "test" => {
 121                                 "ExpectedResult" => $result,
 122                                 "ExpectedProtocol" => $protocol,
 123                                 "Method" => $method,
 124                             }
 125                         };
 126                         $tests[-1]{"test"}{"UseSCTP"} = "Yes" if $sctp;
 127                     }
 128                 }
 129             }
 130         }
 131     }
 132     return @tests;
 133 }
 134
 135 sub generate_resumption_tests {
 136     my ($method) = @_;
 137
 138     my $dtls = $method eq "DTLS";
 139     # Don't write the redundant "Method = TLS" into the configuration.
 140     undef $method if !$dtls;
 141
 142     my @protocols = $dtls ? @dtls_protocols : @tls_protocols;
 143     my $min_enabled  = $dtls ? $min_dtls_enabled : $min_tls_enabled;
 144     my $max_enabled = $dtls ? $max_dtls_enabled : $max_tls_enabled;
 145
 146     if (no_tests($dtls)) {
 147         return;
 148     }
 149
 150     my @server_tests = ();
 151     my @client_tests = ();
 152
 153     # Obtain the first session against a fixed-version server/client.
 154     foreach my $original_protocol($min_enabled..$max_enabled) {
 155         # Upgrade or downgrade the server/client max version support and test
 156         # that it upgrades, downgrades or resumes the session as well.
 157         foreach my $resume_protocol($min_enabled..$max_enabled) {
 158             my $resumption_expected;
 159             # We should only resume on exact version match.
 160             if ($original_protocol eq $resume_protocol) {
 161                 $resumption_expected = "Yes";
 162             } else {
 163                 $resumption_expected = "No";
 164             }
 165
 166             for (my $sctp = 0; $sctp < ($dtls && !disabled("sctp") ? 2 : 1);
 167                  $sctp++) {
 168                 foreach my $ticket ("SessionTicket", "-SessionTicket") {
 169                     # Client is flexible, server upgrades/downgrades.
 170                     push @server_tests, {
 171                         "name" => "resumption",
 172                         "client" => { },
 173                         "server" => {
 174                             "MinProtocol" => $protocols[$original_protocol],
 175                             "MaxProtocol" => $protocols[$original_protocol],
 176                             "Options" => $ticket,
 177                         },
 178                         "resume_server" => {
 179                             "MaxProtocol" => $protocols[$resume_protocol],
 180                         },
 181                         "test" => {
 182                             "ExpectedProtocol" => $protocols[$resume_protocol],
 183                             "Method" => $method,
 184                             "HandshakeMode" => "Resume",
 185                             "ResumptionExpected" => $resumption_expected,
 186                         }
 187                     };
 188                     $server_tests[-1]{"test"}{"UseSCTP"} = "Yes" if $sctp;
 189                     # Server is flexible, client upgrades/downgrades.
 190                     push @client_tests, {
 191                         "name" => "resumption",
 192                         "client" => {
 193                             "MinProtocol" => $protocols[$original_protocol],
 194                             "MaxProtocol" => $protocols[$original_protocol],
 195                         },
 196                         "server" => {
 197                             "Options" => $ticket,
 198                         },
 199                         "resume_client" => {
 200                             "MaxProtocol" => $protocols[$resume_protocol],
 201                         },
 202                         "test" => {
 203                             "ExpectedProtocol" => $protocols[$resume_protocol],
 204                             "Method" => $method,
 205                             "HandshakeMode" => "Resume",
 206                             "ResumptionExpected" => $resumption_expected,
 207                         }
 208                     };
 209                     $client_tests[-1]{"test"}{"UseSCTP"} = "Yes" if $sctp;
 210                 }
 211             }
 212         }
 213     }
 214
 215     if (!disabled("tls1_3") && !$dtls) {
 216         push @client_tests, {
 217             "name" => "resumption-with-hrr",
 218             "client" => {
 219             },
 220             "server" => {
 221                 "Curves" => "P-256"
 222             },
 223             "resume_client" => {
 224             },
 225             "test" => {
 226                 "ExpectedProtocol" => "TLSv1.3",
 227                 "Method" => "TLS",
 228                 "HandshakeMode" => "Resume",
 229                 "ResumptionExpected" => "Yes",
 230             }
 231         };
 232     }
 233
 234     return (@server_tests, @client_tests);
 235 }
 236
 237 sub expected_result {
 238     my ($c_min, $c_max, $s_min, $s_max, $min_enabled, $max_enabled,
 239         $protocols) = @_;
 240
 241     # Adjust for "undef" (no limit).
 242     $c_min = $c_min == 0 ? 0 : $c_min - 1;
 243     $c_max = $c_max == scalar @$protocols ? $c_max - 1 : $c_max;
 244     $s_min = $s_min == 0 ? 0 : $s_min - 1;
 245     $s_max = $s_max == scalar @$protocols ? $s_max - 1 : $s_max;
 246
 247     # We now have at least one protocol enabled, so $min_enabled and
 248     # $max_enabled are well-defined.
 249     $c_min = max $c_min, $min_enabled;
 250     $s_min = max $s_min, $min_enabled;
 251     $c_max = min $c_max, $max_enabled;
 252     $s_max = min $s_max, $max_enabled;
 253
 254     if ($c_min > $c_max) {
 255         # Client should fail to even send a hello.
 256         return ("ClientFail", undef);
 257     } elsif ($s_min > $s_max) {
 258         # Server has no protocols, should always fail.
 259         return ("ServerFail", undef);
 260     } elsif ($s_min > $c_max) {
 261         # Server doesn't support the client range.
 262         return ("ServerFail", undef);
 263     } elsif ($c_min > $s_max) {
 264         my @prots = @$protocols;
 265         if ($prots[$c_max] eq "TLSv1.3") {
 266             # Client will have sent supported_versions, so server will know
 267             # that there are no overlapping versions.
 268             return ("ServerFail", undef);
 269         } else {
 270             # Server will try with a version that is lower than the lowest
 271             # supported client version.
 272             return ("ClientFail", undef);
 273         }
 274     } else {
 275         # Server and client ranges overlap.
 276         my $max_common = $s_max < $c_max ? $s_max : $c_max;
 277         return ("Success", $protocols->[$max_common]);
 278     }
 279 }
 280
 281 1;