test/recipes/80-test_ssl_new.t

   1 #! /usr/bin/env perl
   2 # Copyright 2015-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9
  10 use strict;
  11 use warnings;
  12
  13 use File::Basename;
  14 use File::Compare qw/compare_text/;
  15
  16 use OpenSSL::Test qw/:DEFAULT srctop_dir srctop_file/;
  17 use OpenSSL::Test::Utils qw/disabled alldisabled available_protocols/;
  18
  19 setup("test_ssl_new");
  20
  21 $ENV{TEST_CERTS_DIR} = srctop_dir("test", "certs");
  22
  23 my @conf_srcs =  glob(srctop_file("test", "ssl-tests", "*.conf"));
  24 my @conf_files = map {basename($_)} @conf_srcs;
  25
  26 # 02-protocol-version.conf test results depend on the configuration of enabled
  27 # protocols. We only verify generated sources in the default configuration.
  28 my $is_default = (disabled("ssl3") && !disabled("tls1") &&
  29                   !disabled("tls1_1") && !disabled("tls1_2"));
  30
  31 my %conf_dependent_tests = ("02-protocol-version.conf" => 1);
  32
  33 foreach my $conf (@conf_files) {
  34     subtest "Test configuration $conf" => sub {
  35         test_conf($conf,
  36                   $conf_dependent_tests{$conf} || $^O eq "VMS" ?  0 : 1);
  37     }
  38 }
  39
  40 # We hard-code the number of tests to double-check that the globbing above
  41 # finds all files as expected.
  42 plan tests => 2;  # = scalar @conf_files
  43
  44 sub test_conf {
  45     plan tests => 3;
  46
  47     my ($conf, $check_source) = @_;
  48
  49     my $conf_file = srctop_file("test", "ssl-tests", $conf);
  50     my $tmp_file = "${conf}.$$.tmp";
  51     my $run_test = 1;
  52
  53   SKIP: {
  54       # "Test" 1. Generate the source.
  55       my $input_file = $conf_file . ".in";
  56
  57       skip 'failure', 2 unless
  58         ok(run(perltest(["generate_ssl_tests.pl", $input_file],
  59                         interpreter_args => [ "-I", srctop_dir("test", "testlib")],
  60                         stdout => $tmp_file)),
  61            "Getting output from generate_ssl_tests.pl.");
  62
  63     SKIP: {
  64         # Test 2. Compare against existing output in test/ssl_tests.conf.
  65         skip "Skipping generated source test for $conf", 1
  66           if !$check_source;
  67
  68         $run_test = is(cmp_text($tmp_file, $conf_file), 0,
  69                        "Comparing generated sources.");
  70       }
  71
  72       # Test 3. Run the test.
  73       my $no_tls = alldisabled(available_protocols("tls"));
  74       skip "No TLS tests available; skipping tests", 1 if $no_tls;
  75       skip "Stale sources; skipping tests", 1 if !$run_test;
  76
  77       ok(run(test(["ssl_test", $tmp_file])), "running ssl_test $conf");
  78     }
  79
  80     unlink glob $tmp_file;
  81 }
  82
  83 sub cmp_text {
  84     return compare_text(@_, sub {
  85         $_[0] =~ s/\R//g;
  86         $_[1] =~ s/\R//g;
  87         return $_[0] ne $_[1];
  88     });
  89 }