test/recipes/70-test_sslextension.t

   1 #! /usr/bin/env perl
   2 # Copyright 2015-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9 use strict;
  10 use OpenSSL::Test qw/:DEFAULT cmdstr srctop_file bldtop_dir/;
  11 use OpenSSL::Test::Utils;
  12 use TLSProxy::Proxy;
  13
  14 my $test_name = "test_sslextension";
  15 setup($test_name);
  16
  17 plan skip_all => "TLSProxy isn't usable on $^O"
  18     if $^O =~ /^(VMS|MSWin32)$/;
  19
  20 plan skip_all => "$test_name needs the dynamic engine feature enabled"
  21     if disabled("engine") || disabled("dynamic-engine");
  22
  23 plan skip_all => "$test_name needs the sock feature enabled"
  24     if disabled("sock");
  25
  26 plan skip_all => "$test_name needs TLS enabled"
  27     if alldisabled(available_protocols("tls"));
  28
  29 $ENV{OPENSSL_ia32cap} = '~0x200000200000000';
  30 my $proxy = TLSProxy::Proxy->new(
  31     \&extension_filter,
  32     cmdstr(app(["openssl"]), display => 1),
  33     srctop_file("apps", "server.pem"),
  34     (!$ENV{HARNESS_ACTIVE} || $ENV{HARNESS_VERBOSE})
  35 );
  36
  37 plan tests => 3;
  38
  39 # Test 1: Sending a zero length extension block should pass
  40 $proxy->start();
  41 ok(TLSProxy::Message->success, "Zero extension length test");
  42
  43 sub extension_filter
  44 {
  45     my $proxy = shift;
  46
  47     # We're only interested in the initial ClientHello
  48     if ($proxy->flight != 0) {
  49         return;
  50     }
  51
  52     foreach my $message (@{$proxy->message_list}) {
  53         if ($message->mt == TLSProxy::Message::MT_CLIENT_HELLO) {
  54             # Remove all extensions and set the extension len to zero
  55             $message->extension_data({});
  56             $message->extensions_len(0);
  57             # Extensions have been removed so make sure we don't try to use them
  58             $message->process_extensions();
  59
  60             $message->repack();
  61         }
  62     }
  63 }
  64
  65 # Test 2-3: Sending a duplicate extension should fail.
  66 sub inject_duplicate_extension
  67 {
  68   my ($proxy, $message_type) = @_;
  69
  70     foreach my $message (@{$proxy->message_list}) {
  71         if ($message->mt == $message_type) {
  72           my %extensions = %{$message->extension_data};
  73             # Add a duplicate (unknown) extension.
  74             $message->set_extension(TLSProxy::Message::EXT_DUPLICATE_EXTENSION, "");
  75             $message->set_extension(TLSProxy::Message::EXT_DUPLICATE_EXTENSION, "");
  76             $message->repack();
  77         }
  78     }
  79 }
  80
  81 sub inject_duplicate_extension_clienthello
  82 {
  83     my $proxy = shift;
  84
  85     # We're only interested in the initial ClientHello
  86     if ($proxy->flight != 0) {
  87         return;
  88     }
  89
  90     inject_duplicate_extension($proxy, TLSProxy::Message::MT_CLIENT_HELLO);
  91 }
  92
  93 sub inject_duplicate_extension_serverhello
  94 {
  95     my $proxy = shift;
  96
  97     # We're only interested in the initial ServerHello
  98     if ($proxy->flight != 1) {
  99         return;
 100     }
 101
 102     inject_duplicate_extension($proxy, TLSProxy::Message::MT_SERVER_HELLO);
 103 }
 104
 105 $proxy->clear();
 106 $proxy->filter(\&inject_duplicate_extension_clienthello);
 107 $proxy->start();
 108 ok(TLSProxy::Message->fail(), "Duplicate ClientHello extension");
 109
 110 $proxy->clear();
 111 $proxy->filter(\&inject_duplicate_extension_serverhello);
 112 $proxy->start();
 113 ok(TLSProxy::Message->fail(), "Duplicate ServerHello extension");
 114