Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2022 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::fallback "$FindBin::Bin/external/perl/MODULES.txt";
  21 use OpenSSL::Glob;
  22 use OpenSSL::Template;
  23 use OpenSSL::config;
  24
  25 # see INSTALL.md for instructions.
  26
  27 my $orig_death_handler = $SIG{__DIE__};
  28 $SIG{__DIE__} = \&death_handler;
  29
  30 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]thread-pool] [[no-]default-thread-pool] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  31
  32 my $banner = <<"EOF";
  33
  34 **********************************************************************
  35 ***                                                                ***
  36 ***   OpenSSL has been successfully configured                     ***
  37 ***                                                                ***
  38 ***   If you encounter a problem while building, please open an    ***
  39 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
  40 ***   and include the output from the following command:           ***
  41 ***                                                                ***
  42 ***       perl configdata.pm --dump                                ***
  43 ***                                                                ***
  44 ***   (If you are new to OpenSSL, you might want to consult the    ***
  45 ***   'Troubleshooting' section in the INSTALL.md file first)      ***
  46 ***                                                                ***
  47 **********************************************************************
  48 EOF
  49
  50 # Options:
  51 #
  52 # --config      add the given configuration file, which will be read after
  53 #               any "Configurations*" files that are found in the same
  54 #               directory as this script.
  55 # --prefix      prefix for the OpenSSL installation, which includes the
  56 #               directories bin, lib, include, share/man, share/doc/openssl
  57 #               This becomes the value of INSTALLTOP in Makefile
  58 #               (Default: /usr/local)
  59 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  60 #               If it's a relative directory, it will be added on the directory
  61 #               given with --prefix.
  62 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  63 #               (Default: PREFIX/ssl)
  64 # --banner=".." Output specified text instead of default completion banner
  65 #
  66 # -w            Don't wait after showing a Configure warning
  67 #
  68 # --cross-compile-prefix Add specified prefix to binutils components.
  69 #
  70 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0
  71 #               Define the public APIs as they were for that version
  72 #               including patch releases.  If 'no-deprecated' is also
  73 #               given, do not compile support for interfaces deprecated
  74 #               up to and including the specified OpenSSL version.
  75 #
  76 # no-hw-xxx     do not compile support for specific crypto hardware.
  77 #               Generic OpenSSL-style methods relating to this support
  78 #               are always compiled but return NULL if the hardware
  79 #               support isn't compiled.
  80 # no-hw         do not compile support for any crypto hardware.
  81 # [no-]threads  [don't] try to create a library that is suitable for
  82 #               multithreaded applications (default is "threads" if we
  83 #               know how to do it)
  84 # [no-]thread-pool
  85 #               [don't] allow thread pool functionality
  86 # [no-]default-thread-pool
  87 #               [don't] allow default thread pool functionality
  88 # [no-]shared   [don't] try to create shared libraries when supported.
  89 # [no-]pic      [don't] try to build position independent code when supported.
  90 #               If disabled, it also disables shared and dynamic-engine.
  91 # no-asm        do not use assembler
  92 # no-egd        do not compile support for the entropy-gathering daemon APIs
  93 # [no-]zlib     [don't] compile support for zlib compression.
  94 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  95 #               library and will be loaded in run-time by the OpenSSL library.
  96 # sctp          include SCTP support
  97 # enable-quic   include QUIC support (currently just for developers as the
  98 #               implementation is by no means complete and usable)
  99 # no-uplink     Don't build support for UPLINK interface.
 100 # enable-weak-ssl-ciphers
 101 #               Enable weak ciphers that are disabled by default.
 102 # 386           generate 80386 code in assembly modules
 103 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
 104 #               mentioned '386' option implies this one
 105 # no-<cipher>   build without specified algorithm (dsa, idea, rc5, ...)
 106 # -<xxx> +<xxx> All options which are unknown to the 'Configure' script are
 107 # /<xxx>        passed through to the compiler. Unix-style options beginning
 108 #               with a '-' or '+' are recognized, as well as Windows-style
 109 #               options beginning with a '/'. If the option contains arguments
 110 #               separated by spaces, then the URL-style notation %20 can be
 111 #               used for the space character in order to avoid having to quote
 112 #               the option. For example, -opt%20arg gets expanded to -opt arg.
 113 #               In fact, any ASCII character can be encoded as %xx using its
 114 #               hexadecimal encoding.
 115 # -static       while -static is also a pass-through compiler option (and
 116 #               as such is limited to environments where it's actually
 117 #               meaningful), it triggers a number configuration options,
 118 #               namely no-pic, no-shared and no-threads. It is
 119 #               argued that the only reason to produce statically linked
 120 #               binaries (and in context it means executables linked with
 121 #               -static flag, and not just executables linked with static
 122 #               libcrypto.a) is to eliminate dependency on specific run-time,
 123 #               a.k.a. libc version. The mentioned config options are meant
 124 #               to achieve just that. Unfortunately on Linux it's impossible
 125 #               to eliminate the dependency completely for openssl executable
 126 #               because of getaddrinfo and gethostbyname calls, which can
 127 #               invoke dynamically loadable library facility anyway to meet
 128 #               the lookup requests. For this reason on Linux statically
 129 #               linked openssl executable has rather debugging value than
 130 #               production quality.
 131 #
 132 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
 133 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
 134 # Following are set automatically by this script
 135 #
 136 # MD5_ASM       use some extra md5 assembler,
 137 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 138 # RMD160_ASM    use some extra ripemd160 assembler,
 139 # SHA256_ASM    sha256_block is implemented in assembler
 140 # SHA512_ASM    sha512_block is implemented in assembler
 141 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 142
 143 # Minimum warning options... any contributions to OpenSSL should at least
 144 # get past these.  Note that we only use these with C compilers, not with
 145 # C++ compilers.
 146
 147 # -DPEDANTIC complements -pedantic and is meant to mask code that
 148 # is not strictly standard-compliant and/or implementation-specific,
 149 # e.g. inline assembly, disregards to alignment requirements, such
 150 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 151 # to be used even in sanitized builds, because sanitizer too is
 152 # supposed to and does take notice of non-standard behaviour. Then
 153 # -pedantic with pre-C9x compiler would also complain about 'long
 154 # long' not being supported. As 64-bit algorithms are common now,
 155 # it grew impossible to resolve this without sizeable additional
 156 # code, so we just tell compiler to be pedantic about everything
 157 # but 'long long' type.
 158
 159 my @gcc_devteam_warn = qw(
 160     -DPEDANTIC -pedantic -Wno-long-long -DUNUSEDRESULT_DEBUG
 161     -Wall
 162     -Wmissing-declarations
 163     -Wextra
 164     -Wno-unused-parameter
 165     -Wno-missing-field-initializers
 166     -Wswitch
 167     -Wsign-compare
 168     -Wshadow
 169     -Wformat
 170     -Wtype-limits
 171     -Wundef
 172     -Werror
 173     -Wmissing-prototypes
 174     -Wstrict-prototypes
 175 );
 176
 177 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 178 # TODO(openssl-team): fix problems and investigate if (at least) the
 179 # following warnings can also be enabled:
 180 #       -Wcast-align
 181 #       -Wunreachable-code -- no, too ugly/compiler-specific
 182 #       -Wlanguage-extension-token -- no, we use asm()
 183 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 184 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 185 my @clang_devteam_warn = qw(
 186     -Wno-unknown-warning-option
 187     -Wswitch-default
 188     -Wno-parentheses-equality
 189     -Wno-language-extension-token
 190     -Wno-extended-offsetof
 191     -Wconditional-uninitialized
 192     -Wincompatible-pointer-types-discards-qualifiers
 193     -Wmissing-variable-declarations
 194 );
 195
 196 my @cl_devteam_warn = qw(
 197     /WX
 198 );
 199
 200 my $strict_warnings = 0;
 201
 202 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 203 # which would cover all BSD flavors. -pthread applies to them all,
 204 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 205 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 206 # which has to be accompanied by explicit -D_THREAD_SAFE and
 207 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 208 # seems to be sufficient?
 209 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 210
 211 #
 212 # API compatibility name to version number mapping.
 213 #
 214 my $apitable = {
 215     # This table expresses when API additions or changes can occur.
 216     # The numbering used changes from 3.0 and on because we updated
 217     # (solidified) our version numbering scheme at that point.
 218
 219     # From 3.0 and on, we internalise the given version number in decimal
 220     # as MAJOR * 10000 + MINOR * 100 + 0
 221     "3.0.0" => 30000,
 222     "3.0"   => 30000,
 223
 224     # Note that before 3.0, we didn't have the same version number scheme.
 225     # Still, the numbering we use here covers what we need.
 226     "1.1.1" => 10101,
 227     "1.1.0" => 10100,
 228     "1.0.2" => 10002,
 229     "1.0.1" => 10001,
 230     "1.0.0" => 10000,
 231     "0.9.8" =>   908,
 232 };
 233
 234 # For OpenSSL::config::get_platform
 235 my %guess_opts = ();
 236
 237 my $dryrun = 0;
 238
 239 our %table = ();
 240 our %config = ();
 241 our %withargs = ();
 242 our $now_printing;      # set to current entry's name in print_table_entry
 243                         # (todo: right thing would be to encapsulate name
 244                         # into %target [class] and make print_table_entry
 245                         # a method)
 246
 247 # Forward declarations ###############################################
 248
 249 # read_config(filename)
 250 #
 251 # Reads a configuration file and populates %table with the contents
 252 # (which the configuration file places in %targets).
 253 sub read_config;
 254
 255 # resolve_config(target)
 256 #
 257 # Resolves all the late evaluations, inheritances and so on for the
 258 # chosen target and any target it inherits from.
 259 sub resolve_config;
 260
 261
 262 # Information collection #############################################
 263
 264 # Unified build supports separate build dir
 265 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 266 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 267
 268 # File::Spec::Unix doesn't detect case insensitivity, so we make sure to
 269 # check if the source and build directory are really the same, and make
 270 # them so.  This avoids all kinds of confusion later on.
 271 # We must check @File::Spec::ISA rather than using File::Spec->isa() to
 272 # know if File::Spec ended up loading File::Spec::Unix.
 273 $srcdir = $blddir
 274     if (grep(/::Unix$/, @File::Spec::ISA)
 275         && samedir($srcdir, $blddir));
 276
 277 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 278
 279 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 280
 281 $config{sourcedir} = abs2rel($srcdir, $blddir);
 282 $config{builddir} = abs2rel($blddir, $blddir);
 283 # echo -n 'holy hand grenade of antioch' | openssl sha256
 284 $config{FIPSKEY} =
 285     'f4556650ac31d35461610bac4ed81b1a181b2d8a43ea2854cbae22ca74560813';
 286
 287 # Collect reconfiguration information if needed
 288 my @argvcopy=@ARGV;
 289
 290 if (grep /^reconf(igure)?$/, @argvcopy) {
 291     die "reconfiguring with other arguments present isn't supported"
 292         if scalar @argvcopy > 1;
 293     if (-f "./configdata.pm") {
 294         my $file = "./configdata.pm";
 295         unless (my $return = do $file) {
 296             die "couldn't parse $file: $@" if $@;
 297             die "couldn't do $file: $!"    unless defined $return;
 298             die "couldn't run $file"       unless $return;
 299         }
 300
 301         @argvcopy = defined($configdata::config{perlargv}) ?
 302             @{$configdata::config{perlargv}} : ();
 303         die "Incorrect data to reconfigure, please do a normal configuration\n"
 304             if (grep(/^reconf/,@argvcopy));
 305         $config{perlenv} = $configdata::config{perlenv} // {};
 306     } else {
 307         die "Insufficient data to reconfigure, please do a normal configuration\n";
 308     }
 309 }
 310
 311 $config{perlargv} = [ @argvcopy ];
 312
 313 # Historical: if known directories in crypto/ have been removed, it means
 314 # that those sub-systems are disabled.
 315 # (the other option would be to removed them from the SUBDIRS statement in
 316 # crypto/build.info)
 317 # We reverse the input list for cosmetic purely reasons, to compensate that
 318 # 'unshift' adds at the front of the list (i.e. in reverse input order).
 319 foreach ( reverse sort( 'aes', 'aria', 'bf', 'camellia', 'cast', 'des', 'dh',
 320                         'dsa', 'ec', 'hmac', 'idea', 'md2', 'md5', 'mdc2',
 321                         'rc2', 'rc4', 'rc5', 'ripemd', 'seed', 'sha',
 322                         'sm2', 'sm3', 'sm4') ) {
 323     unshift @argvcopy, "no-$_" if ! -d catdir($srcdir, 'crypto', $_);
 324 }
 325
 326 # Collect version numbers
 327 my %version = ();
 328
 329 collect_information(
 330     collect_from_file(catfile($srcdir,'VERSION.dat')),
 331     qr/\s*(\w+)\s*=\s*(.*?)\s*$/ =>
 332         sub {
 333             # Only define it if there is a value at all
 334             if ($2 ne '') {
 335                 my $k = $1;
 336                 my $v = $2;
 337                 # Some values are quoted.  Trim the quotes
 338                 $v = $1 if $v =~ /^"(.*)"$/;
 339                 $version{uc $k} = $v;
 340             }
 341         },
 342     "OTHERWISE" =>
 343         sub { die "Something wrong with this line:\n$_\nin $srcdir/VERSION.dat" },
 344     );
 345
 346 $config{major} = $version{MAJOR} // 'unknown';
 347 $config{minor} = $version{MINOR} // 'unknown';
 348 $config{patch} = $version{PATCH} // 'unknown';
 349 $config{prerelease} =
 350     defined $version{PRE_RELEASE_TAG} ? "-$version{PRE_RELEASE_TAG}" : '';
 351 $config{build_metadata} =
 352     defined $version{BUILD_METADATA} ? "+$version{BUILD_METADATA}" : '';
 353 $config{shlib_version} = $version{SHLIB_VERSION} // 'unknown';
 354 $config{release_date} = $version{RELEASE_DATE} // 'xx XXX xxxx';
 355
 356 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 357 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 358
 359 die "erroneous version information in VERSION.dat: ",
 360     "$config{version}, $config{shlib_version}\n"
 361     unless (defined $version{MAJOR}
 362             && defined $version{MINOR}
 363             && defined $version{PATCH}
 364             && defined $version{SHLIB_VERSION});
 365
 366 # Collect target configurations
 367
 368 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 369 foreach (sort glob($pattern)) {
 370     &read_config($_);
 371 }
 372
 373 if (defined env($local_config_envname)) {
 374     if ($^O eq 'VMS') {
 375         # VMS environment variables are logical names,
 376         # which can be used as is
 377         $pattern = $local_config_envname . ':' . '*.conf';
 378     } else {
 379         $pattern = catfile(env($local_config_envname), '*.conf');
 380     }
 381
 382     foreach (sort glob($pattern)) {
 383         &read_config($_);
 384     }
 385 }
 386
 387 # Save away perl command information
 388 $config{perl_cmd} = $^X;
 389 $config{perl_version} = $Config{version};
 390 $config{perl_archname} = $Config{archname};
 391
 392 $config{prefix}="";
 393 $config{openssldir}="";
 394 $config{processor}="";
 395 $config{libdir}="";
 396 my $auto_threads=1;    # enable threads automatically? true by default
 397 my $default_ranlib;
 398
 399 # Known TLS and DTLS protocols
 400 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 401 my @dtls = qw(dtls1 dtls1_2);
 402
 403 # Explicitly known options that are possible to disable.  They can
 404 # be regexps, and will be used like this: /^no-${option}$/
 405 # For developers: keep it sorted alphabetically
 406
 407 my @disablables = (
 408     "acvp-tests",
 409     "afalgeng",
 410     "aria",
 411     "asan",
 412     "asm",
 413     "async",
 414     "autoalginit",
 415     "autoerrinit",
 416     "autoload-config",
 417     "bf",
 418     "blake2",
 419     "buildtest-c++",
 420     "bulk",
 421     "cached-fetch",
 422     "camellia",
 423     "capieng",
 424     "winstore",
 425     "cast",
 426     "chacha",
 427     "cmac",
 428     "cmp",
 429     "cms",
 430     "comp",
 431     "crypto-mdebug",
 432     "ct",
 433     "default-thread-pool",
 434     "deprecated",
 435     "des",
 436     "devcryptoeng",
 437     "dgram",
 438     "dh",
 439     "dsa",
 440     "dso",
 441     "dtls",
 442     "dynamic-engine",
 443     "ec",
 444     "ec2m",
 445     "ec_nistp_64_gcc_128",
 446     "ecdh",
 447     "ecdsa",
 448     "egd",
 449     "engine",
 450     "err",
 451     "external-tests",
 452     "filenames",
 453     "fips",
 454     "fips-securitychecks",
 455     "fuzz-afl",
 456     "fuzz-libfuzzer",
 457     "gost",
 458     "idea",
 459     "ktls",
 460     "legacy",
 461     "loadereng",
 462     "makedepend",
 463     "md2",
 464     "md4",
 465     "mdc2",
 466     "module",
 467     "msan",
 468     "multiblock",
 469     "nextprotoneg",
 470     "ocb",
 471     "ocsp",
 472     "padlockeng",
 473     "pic",
 474     "pinshared",
 475     "poly1305",
 476     "posix-io",
 477     "psk",
 478     "quic",
 479     "rc2",
 480     "rc4",
 481     "rc5",
 482     "rdrand",
 483     "rfc3779",
 484     "rmd160",
 485     "scrypt",
 486     "sctp",
 487     "secure-memory",
 488     "seed",
 489     "shared",
 490     "siphash",
 491     "siv",
 492     "sm2",
 493     "sm3",
 494     "sm4",
 495     "sock",
 496     "srp",
 497     "srtp",
 498     "sse2",
 499     "ssl",
 500     "ssl-trace",
 501     "static-engine",
 502     "stdio",
 503     "tests",
 504     "tfo",
 505     "thread-pool",
 506     "threads",
 507     "tls",
 508     "trace",
 509     "ts",
 510     "ubsan",
 511     "ui-console",
 512     "unit-test",
 513     "uplink",
 514     "weak-ssl-ciphers",
 515     "whirlpool",
 516     "zlib",
 517     "zlib-dynamic",
 518     );
 519 foreach my $proto ((@tls, @dtls))
 520         {
 521         push(@disablables, $proto);
 522         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 523         }
 524
 525 # Internal disablables, for aliasing purposes.  They serve no special
 526 # purpose here, but allow scripts to get to know them through configdata.pm,
 527 # where these are merged with @disablables.
 528 # The actual aliasing mechanism is done via %disable_cascades
 529 my @disablables_int = qw(
 530     crmf
 531     );
 532
 533 my %deprecated_disablables = (
 534     "ssl2" => undef,
 535     "buf-freelists" => undef,
 536     "crypto-mdebug-backtrace" => undef,
 537     "hw" => "hw",               # causes cascade, but no macro
 538     "hw-padlock" => "padlockeng",
 539     "ripemd" => "rmd160",
 540     "ui" => "ui-console",
 541     "heartbeats" => undef,
 542     );
 543
 544 # All of the following are disabled by default:
 545
 546 our %disabled = ( # "what"         => "comment"
 547                   "fips"                => "default",
 548                   "asan"                => "default",
 549                   "buildtest-c++"       => "default",
 550                   "crypto-mdebug"       => "default",
 551                   "crypto-mdebug-backtrace" => "default",
 552                   "devcryptoeng"        => "default",
 553                   "ec_nistp_64_gcc_128" => "default",
 554                   "egd"                 => "default",
 555                   "external-tests"      => "default",
 556                   "fuzz-afl"            => "default",
 557                   "fuzz-libfuzzer"      => "default",
 558                   "ktls"                => "default",
 559                   "md2"                 => "default",
 560                   "msan"                => "default",
 561                   "quic"                => "default",
 562                   "rc5"                 => "default",
 563                   "sctp"                => "default",
 564                   "ssl3"                => "default",
 565                   "ssl3-method"         => "default",
 566                   "tfo"                 => "default",
 567                   "trace"               => "default",
 568                   "ubsan"               => "default",
 569                   "unit-test"           => "default",
 570                   "weak-ssl-ciphers"    => "default",
 571                   "zlib"                => "default",
 572                   "zlib-dynamic"        => "default",
 573                 );
 574
 575 # Note: => pair form used for aesthetics, not to truly make a hash table
 576 my @disable_cascades = (
 577     # "what"            => [ "cascade", ... ]
 578     "bulk"              => [ "shared", "dso",
 579                              "aria", "async", "autoload-config",
 580                              "blake2", "bf", "camellia", "cast", "chacha",
 581                              "cmac", "cms", "cmp", "comp", "ct",
 582                              "des", "dgram", "dh", "dsa",
 583                              "ec", "engine",
 584                              "filenames",
 585                              "idea", "ktls",
 586                              "md4", "multiblock", "nextprotoneg",
 587                              "ocsp", "ocb", "poly1305", "psk",
 588                              "rc2", "rc4", "rmd160",
 589                              "seed", "siphash", "siv",
 590                              "sm3", "sm4", "srp",
 591                              "srtp", "ssl3-method", "ssl-trace",
 592                              "tfo",
 593                              "ts", "ui-console", "whirlpool",
 594                              "fips-securitychecks" ],
 595     sub { $config{processor} eq "386" }
 596                         => [ "sse2" ],
 597     "ssl"               => [ "ssl3" ],
 598     "ssl3-method"       => [ "ssl3" ],
 599     "zlib"              => [ "zlib-dynamic" ],
 600     "des"               => [ "mdc2" ],
 601     "ec"                => [ "ec2m", "ecdsa", "ecdh", "sm2", "gost" ],
 602     "dgram"             => [ "dtls", "quic", "sctp" ],
 603     "sock"              => [ "dgram", "tfo" ],
 604     "dtls"              => [ @dtls ],
 605     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 606                         => [ "dtls" ],
 607
 608     "tls"               => [ @tls ],
 609     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 610                         => [ "tls" ],
 611
 612     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 613
 614     # If no modules, then no dynamic engines either
 615     "module"            => [ "dynamic-engine" ],
 616
 617     # Without shared libraries, dynamic engines aren't possible.
 618     # This is due to them having to link with libcrypto and register features
 619     # using the ENGINE functionality, and since that relies on global tables,
 620     # those *have* to be exactly the same as the ones accessed from the app,
 621     # which cannot be guaranteed if shared libraries aren't present.
 622     # (note that even with shared libraries, both the app and dynamic engines
 623     # must be linked with the same library)
 624     "shared"            => [ "dynamic-engine", "uplink" ],
 625     "dso"               => [ "dynamic-engine", "module" ],
 626     # Other modules don't necessarily have to link with libcrypto, so shared
 627     # libraries do not have to be a condition to produce those.
 628
 629     # Without position independent code, there can be no shared libraries
 630     # or modules.
 631     "pic"               => [ "shared", "module" ],
 632
 633     "module"            => [ "fips", "dso" ],
 634
 635     "engine"            => [ "dynamic-engine", grep(/eng$/, @disablables) ],
 636     "dynamic-engine"    => [ "loadereng" ],
 637     "hw"                => [ "padlockeng" ],
 638
 639     # no-autoalginit is only useful when building non-shared
 640     "autoalginit"       => [ "shared", "apps", "fips" ],
 641
 642     "stdio"             => [ "apps", "capieng", "egd" ],
 643     "apps"              => [ "tests" ],
 644     "tests"             => [ "external-tests" ],
 645     "comp"              => [ "zlib" ],
 646     "sm3"               => [ "sm2" ],
 647     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 648
 649     sub { !$disabled{"msan"} } => [ "asm" ],
 650
 651     "cmac"              => [ "siv" ],
 652     "legacy"            => [ "md2" ],
 653
 654     "cmp"               => [ "crmf" ],
 655
 656     "fips"              => [ "fips-securitychecks", "acvp-tests" ],
 657
 658     "deprecated-3.0"    => [ "engine", "srp" ]
 659     );
 660
 661 # Avoid protocol support holes.  Also disable all versions below N, if version
 662 # N is disabled while N+1 is enabled.
 663 #
 664 my @list = (reverse @tls);
 665 while ((my $first, my $second) = (shift @list, shift @list)) {
 666     last unless @list;
 667     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 668                               => [ @list ] );
 669     unshift @list, $second;
 670 }
 671 my @list = (reverse @dtls);
 672 while ((my $first, my $second) = (shift @list, shift @list)) {
 673     last unless @list;
 674     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 675                               => [ @list ] );
 676     unshift @list, $second;
 677 }
 678
 679 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 680 # To remove something from %disabled, use "enable-foo".
 681 # For symmetry, "disable-foo" is a synonym for "no-foo".
 682
 683 # For the "make variables" CPPINCLUDES and CPPDEFINES, we support lists with
 684 # platform specific list separators.  Users from those platforms should
 685 # recognise those separators from how you set up the PATH to find executables.
 686 # The default is the Unix like separator, :, but as an exception, we also
 687 # support the space as separator.
 688 my $list_separator_re =
 689     { VMS           => qr/(?<!\^),/,
 690       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 691 # All the "make variables" we support
 692 # Some get pre-populated for the sake of backward compatibility
 693 # (we supported those before the change to "make variable" support.
 694 my %user = (
 695     AR          => env('AR'),
 696     ARFLAGS     => [],
 697     AS          => undef,
 698     ASFLAGS     => [],
 699     CC          => env('CC'),
 700     CFLAGS      => [ env('CFLAGS') || () ],
 701     CXX         => env('CXX'),
 702     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 703     CPP         => undef,
 704     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 705     CPPDEFINES  => [],  # Alternative for -D
 706     CPPINCLUDES => [],  # Alternative for -I
 707     CROSS_COMPILE => env('CROSS_COMPILE'),
 708     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 709     LD          => undef,
 710     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 711     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 712     MT          => undef,
 713     MTFLAGS     => [],
 714     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 715     RANLIB      => env('RANLIB'),
 716     RC          => env('RC') || env('WINDRES'),
 717     RCFLAGS     => [ env('RCFLAGS') || () ],
 718     RM          => undef,
 719    );
 720 # Info about what "make variables" may be prefixed with the cross compiler
 721 # prefix.  This should NEVER mention any such variable with a list for value.
 722 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 723 # The same but for flags given as Configure options.  These are *additional*
 724 # input, as opposed to the VAR=string option that override the corresponding
 725 # config target attributes
 726 my %useradd = (
 727     CPPDEFINES  => [],
 728     CPPINCLUDES => [],
 729     CPPFLAGS    => [],
 730     CFLAGS      => [],
 731     CXXFLAGS    => [],
 732     LDFLAGS     => [],
 733     LDLIBS      => [],
 734     RCFLAGS     => [],
 735    );
 736
 737 my %user_synonyms = (
 738     HASHBANGPERL=> 'PERL',
 739     RC          => 'WINDRES',
 740    );
 741
 742 # Some target attributes have been renamed, this is the translation table
 743 my %target_attr_translate =(
 744     ar          => 'AR',
 745     as          => 'AS',
 746     cc          => 'CC',
 747     cxx         => 'CXX',
 748     cpp         => 'CPP',
 749     hashbangperl => 'HASHBANGPERL',
 750     ld          => 'LD',
 751     mt          => 'MT',
 752     ranlib      => 'RANLIB',
 753     rc          => 'RC',
 754     rm          => 'RM',
 755    );
 756
 757 # Initialisers coming from 'config' scripts
 758 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 759 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 760 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 761 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 762 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 763 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 764 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 765
 766 $config{openssl_api_defines}=[];
 767 $config{openssl_sys_defines}=[];
 768 $config{openssl_feature_defines}=[];
 769 $config{options}="";
 770 $config{build_type} = "release";
 771 my $target="";
 772
 773 my %cmdvars = ();               # Stores FOO='blah' type arguments
 774 my %unsupported_options = ();
 775 my %deprecated_options = ();
 776 # If you change this, update apps/version.c
 777 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 778 my @seed_sources = ();
 779 while (@argvcopy)
 780         {
 781         $_ = shift @argvcopy;
 782
 783         # Support env variable assignments among the options
 784         if (m|^(\w+)=(.+)?$|)
 785                 {
 786                 $cmdvars{$1} = $2;
 787                 # Every time a variable is given as a configuration argument,
 788                 # it acts as a reset if the variable.
 789                 if (exists $user{$1})
 790                         {
 791                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 792                         }
 793                 #if (exists $useradd{$1})
 794                 #       {
 795                 #       $useradd{$1} = [];
 796                 #       }
 797                 next;
 798                 }
 799
 800         # VMS is a case insensitive environment, and depending on settings
 801         # out of our control, we may receive options uppercased.  Let's
 802         # downcase at least the part before any equal sign.
 803         if ($^O eq "VMS")
 804                 {
 805                 s/^([^=]*)/lc($1)/e;
 806                 }
 807
 808         # some people just can't read the instructions, clang people have to...
 809         s/^-no-(?!integrated-as)/no-/;
 810
 811         # rewrite some options in "enable-..." form
 812         s /^-?-?shared$/enable-shared/;
 813         s /^sctp$/enable-sctp/;
 814         s /^threads$/enable-threads/;
 815         s /^thread-pool$/enable-thread-pool/;
 816         s /^default-thread-pool$/enable-default-thread-pool/;
 817         s /^zlib$/enable-zlib/;
 818         s /^zlib-dynamic$/enable-zlib-dynamic/;
 819         s /^fips$/enable-fips/;
 820
 821         if (/^(no|disable|enable)-(.+)$/)
 822                 {
 823                 my $word = $2;
 824                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 825                         && !exists $deprecated_disablables{$word}
 826                         && !grep { $word eq $_ } @disablables)
 827                         {
 828                         $unsupported_options{$_} = 1;
 829                         next;
 830                         }
 831                 }
 832         if (/^no-(.+)$/ || /^disable-(.+)$/)
 833                 {
 834                 foreach my $proto ((@tls, @dtls))
 835                         {
 836                         if ($1 eq "$proto-method")
 837                                 {
 838                                 $disabled{"$proto"} = "option($proto-method)";
 839                                 last;
 840                                 }
 841                         }
 842                 if ($1 eq "dtls")
 843                         {
 844                         foreach my $proto (@dtls)
 845                                 {
 846                                 $disabled{$proto} = "option(dtls)";
 847                                 }
 848                         $disabled{"dtls"} = "option(dtls)";
 849                         }
 850                 elsif ($1 eq "ssl")
 851                         {
 852                         # Last one of its kind
 853                         $disabled{"ssl3"} = "option(ssl)";
 854                         }
 855                 elsif ($1 eq "tls")
 856                         {
 857                         # XXX: Tests will fail if all SSL/TLS
 858                         # protocols are disabled.
 859                         foreach my $proto (@tls)
 860                                 {
 861                                 $disabled{$proto} = "option(tls)";
 862                                 }
 863                         }
 864                 elsif ($1 eq "static-engine")
 865                         {
 866                         delete $disabled{"dynamic-engine"};
 867                         }
 868                 elsif ($1 eq "dynamic-engine")
 869                         {
 870                         $disabled{"dynamic-engine"} = "option";
 871                         }
 872                 elsif (exists $deprecated_disablables{$1})
 873                         {
 874                         $deprecated_options{$_} = 1;
 875                         if (defined $deprecated_disablables{$1})
 876                                 {
 877                                 $disabled{$deprecated_disablables{$1}} = "option";
 878                                 }
 879                         }
 880                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 881                         {
 882                         $deprecated_options{$_} = 1;
 883                         }
 884                 else
 885                         {
 886                         $disabled{$1} = "option";
 887                         }
 888                 # No longer an automatic choice
 889                 $auto_threads = 0 if ($1 eq "threads");
 890                 }
 891         elsif (/^enable-(.+)$/)
 892                 {
 893                 if ($1 eq "static-engine")
 894                         {
 895                         $disabled{"dynamic-engine"} = "option";
 896                         }
 897                 elsif ($1 eq "dynamic-engine")
 898                         {
 899                         delete $disabled{"dynamic-engine"};
 900                         }
 901                 elsif ($1 eq "zlib-dynamic")
 902                         {
 903                         delete $disabled{"zlib"};
 904                         }
 905                 my $algo = $1;
 906                 delete $disabled{$algo};
 907
 908                 # No longer an automatic choice
 909                 $auto_threads = 0 if ($1 eq "threads");
 910                 }
 911         elsif (/^-d$/)          # From older 'config'
 912                 {
 913                 $config{build_type} = "debug";
 914                 }
 915         elsif (/^-v$/)          # From older 'config'
 916                 {
 917                 $guess_opts{verbose} = 1;
 918                 }
 919         elsif (/^-w$/)
 920                 {
 921                 $guess_opts{nowait} = 1;
 922                 }
 923         elsif (/^-t$/)          # From older 'config'
 924                 {
 925                 $dryrun = 1;
 926                 }
 927         elsif (/^--strict-warnings$/)
 928                 {
 929                 # Pretend that our strict flags is a C flag, and replace it
 930                 # with the proper flags later on
 931                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 932                 $strict_warnings=1;
 933                 }
 934         elsif (/^--debug$/)
 935                 {
 936                 $config{build_type} = "debug";
 937                 }
 938         elsif (/^--release$/)
 939                 {
 940                 $config{build_type} = "release";
 941                 }
 942         elsif (/^386$/)
 943                 { $config{processor}=386; }
 944         elsif (/^rsaref$/)
 945                 {
 946                 # No RSAref support any more since it's not needed.
 947                 # The check for the option is there so scripts aren't
 948                 # broken
 949                 }
 950         elsif (m|^[-+/]|)
 951                 {
 952                 if (/^--prefix=(.*)$/)
 953                         {
 954                         $config{prefix}=$1;
 955                         die "Directory given with --prefix MUST be absolute\n"
 956                                 unless file_name_is_absolute($config{prefix});
 957                         }
 958                 elsif (/^--api=(.*)$/)
 959                         {
 960                         my $api = $1;
 961                         die "Unknown API compatibility level $api"
 962                                 unless defined $apitable->{$api};
 963                         $config{api}=$apitable->{$api};
 964                         }
 965                 elsif (/^--libdir=(.*)$/)
 966                         {
 967                         $config{libdir}=$1;
 968                         }
 969                 elsif (/^--openssldir=(.*)$/)
 970                         {
 971                         $config{openssldir}=$1;
 972                         }
 973                 elsif (/^--with-zlib-lib=(.*)$/)
 974                         {
 975                         $withargs{zlib_lib}=$1;
 976                         }
 977                 elsif (/^--with-zlib-include=(.*)$/)
 978                         {
 979                         $withargs{zlib_include}=$1;
 980                         }
 981                 elsif (/^--with-fuzzer-lib=(.*)$/)
 982                         {
 983                         $withargs{fuzzer_lib}=$1;
 984                         }
 985                 elsif (/^--with-fuzzer-include=(.*)$/)
 986                         {
 987                         $withargs{fuzzer_include}=$1;
 988                         }
 989                 elsif (/^--with-rand-seed=(.*)$/)
 990                         {
 991                         foreach my $x (split(m|,|, $1))
 992                             {
 993                             die "Unknown --with-rand-seed choice $x\n"
 994                                 if ! grep { $x eq $_ } @known_seed_sources;
 995                             push @seed_sources, $x;
 996                             }
 997                         }
 998                 elsif (/^--fips-key=(.*)$/)
 999                         {
1000                         $user{FIPSKEY}=lc($1);
1001                         die "Non-hex character in FIPS key\n"
1002                            if $user{FIPSKEY} =~ /[^a-f0-9]/;
1003                         die "FIPS key must have even number of characters\n"
1004                            if length $1 & 1;
1005                         die "FIPS key too long (64 bytes max)\n"
1006                            if length $1 > 64;
1007                         }
1008                 elsif (/^--banner=(.*)$/)
1009                         {
1010                         $banner = $1 . "\n";
1011                         }
1012                 elsif (/^--cross-compile-prefix=(.*)$/)
1013                         {
1014                         $user{CROSS_COMPILE}=$1;
1015                         }
1016                 elsif (/^--config=(.*)$/)
1017                         {
1018                         read_config $1;
1019                         }
1020                 elsif (/^-l(.*)$/)
1021                         {
1022                         push @{$useradd{LDLIBS}}, $_;
1023                         }
1024                 elsif (/^-framework$/)
1025                         {
1026                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
1027                         }
1028                 elsif (/^-L(.*)$/ or /^-Wl,/)
1029                         {
1030                         push @{$useradd{LDFLAGS}}, $_;
1031                         }
1032                 elsif (/^-rpath$/ or /^-R$/)
1033                         # -rpath is the OSF1 rpath flag
1034                         # -R is the old Solaris rpath flag
1035                         {
1036                         my $rpath = shift(@argvcopy) || "";
1037                         $rpath .= " " if $rpath ne "";
1038                         push @{$useradd{LDFLAGS}}, $_, $rpath;
1039                         }
1040                 elsif (/^-static$/)
1041                         {
1042                         push @{$useradd{LDFLAGS}}, $_;
1043                         }
1044                 elsif (m|^[-/]D(.*)$|)
1045                         {
1046                         push @{$useradd{CPPDEFINES}}, $1;
1047                         }
1048                 elsif (m|^[-/]I(.*)$|)
1049                         {
1050                         push @{$useradd{CPPINCLUDES}}, $1;
1051                         }
1052                 elsif (/^-Wp,$/)
1053                         {
1054                         push @{$useradd{CPPFLAGS}}, $1;
1055                         }
1056                 else    # common if (/^[-+]/), just pass down...
1057                         {
1058                         # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
1059                         # This provides a simple way to pass options with arguments separated
1060                         # by spaces without quoting (e.g. -opt%20arg translates to -opt arg).
1061                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
1062                         push @{$useradd{CFLAGS}}, $_;
1063                         push @{$useradd{CXXFLAGS}}, $_;
1064                         }
1065                 }
1066         elsif (m|^/|)
1067                 {
1068                 # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
1069                 # This provides a simple way to pass options with arguments separated
1070                 # by spaces without quoting (e.g. /opt%20arg translates to /opt arg).
1071                 $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
1072                 push @{$useradd{CFLAGS}}, $_;
1073                 push @{$useradd{CXXFLAGS}}, $_;
1074                 }
1075         else
1076                 {
1077                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
1078                 $target=$_;
1079                 }
1080         unless ($_ eq $target || /^no-/ || /^disable-/)
1081                 {
1082                 # "no-..." follows later after implied deactivations
1083                 # have been derived.  (Don't take this too seriously,
1084                 # we really only write OPTIONS to the Makefile out of
1085                 # nostalgia.)
1086
1087                 if ($config{options} eq "")
1088                         { $config{options} = $_; }
1089                 else
1090                         { $config{options} .= " ".$_; }
1091                 }
1092         }
1093
1094 if (keys %deprecated_options)
1095         {
1096         warn "***** Deprecated options: ",
1097                 join(", ", keys %deprecated_options), "\n";
1098         }
1099 if (keys %unsupported_options)
1100         {
1101         die "***** Unsupported options: ",
1102                 join(", ", keys %unsupported_options), "\n";
1103         }
1104
1105 # If any %useradd entry has been set, we must check that the "make
1106 # variables" haven't been set.  We start by checking of any %useradd entry
1107 # is set.
1108 if (grep { scalar @$_ > 0 } values %useradd) {
1109     # Hash of env / make variables names.  The possible values are:
1110     # 1 - "make vars"
1111     # 2 - %useradd entry set
1112     # 3 - both set
1113     my %detected_vars =
1114         map { my $v = 0;
1115               $v += 1 if $cmdvars{$_};
1116               $v += 2 if @{$useradd{$_}};
1117               $_ => $v }
1118         keys %useradd;
1119
1120     # If any of the corresponding "make variables" is set, we error
1121     if (grep { $_ & 1 } values %detected_vars) {
1122         my $names = join(', ', grep { $detected_vars{$_} > 0 }
1123                                sort keys %detected_vars);
1124         die <<"_____";
1125 ***** Mixing make variables and additional compiler/linker flags as
1126 ***** configure command line option is not permitted.
1127 ***** Affected make variables: $names
1128 _____
1129     }
1130 }
1131
1132 # Check through all supported command line variables to see if any of them
1133 # were set, and canonicalise the values we got.  If no compiler or linker
1134 # flag or anything else that affects %useradd was set, we also check the
1135 # environment for values.
1136 my $anyuseradd =
1137     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
1138 foreach (keys %user) {
1139     my $value = $cmdvars{$_};
1140     $value //= env($_) unless $anyuseradd;
1141     $value //=
1142         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
1143     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
1144         unless $anyuseradd;
1145
1146     if (defined $value) {
1147         if (ref $user{$_} eq 'ARRAY') {
1148             if ($_ eq 'CPPDEFINES' || $_ eq 'CPPINCLUDES') {
1149                 $user{$_} = [ split /$list_separator_re/, $value ];
1150             } else {
1151                 $user{$_} = [ $value ];
1152             }
1153         } elsif (!defined $user{$_}) {
1154             $user{$_} = $value;
1155         }
1156     }
1157 }
1158
1159 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1160     && !$disabled{shared}
1161     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1162     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1163         "***** any of asan, msan or ubsan\n";
1164 }
1165
1166 # If no target was given, try guessing.
1167 unless ($target) {
1168     my %system_config = OpenSSL::config::get_platform(%guess_opts, %user);
1169
1170     # The $system_config{disable} is used to populate %disabled with
1171     # entries that aren't already there.
1172     foreach ( @{$system_config{disable} // []} ) {
1173         $disabled{$_} = 'system' unless defined $disabled{$_};
1174     }
1175     delete $system_config{disable};
1176
1177     # Override config entries with stuff from the guesser.
1178     # It's assumed that this really is nothing new.
1179     %config = ( %config, %system_config );
1180     $target = $system_config{target};
1181 }
1182
1183 sub disable {
1184     my $disable_type = shift;
1185
1186     for (@_) {
1187         $disabled{$_} = $disable_type;
1188     }
1189
1190     my @tocheckfor = (@_ ? @_ : keys %disabled);
1191     while (@tocheckfor) {
1192         my %new_tocheckfor = ();
1193         my @cascade_copy = (@disable_cascades);
1194         while (@cascade_copy) {
1195             my ($test, $descendents) =
1196                 (shift @cascade_copy, shift @cascade_copy);
1197             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1198                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1199                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1200                 }
1201             }
1202         }
1203         @tocheckfor = (keys %new_tocheckfor);
1204     }
1205 }
1206 disable();                     # First cascade run
1207
1208 our $die = sub { die @_; };
1209 if ($target eq "TABLE") {
1210     local $die = sub { warn @_; };
1211     foreach (sort keys %table) {
1212         print_table_entry($_, "TABLE");
1213     }
1214     exit 0;
1215 }
1216
1217 if ($target eq "LIST") {
1218     foreach (sort keys %table) {
1219         print $_,"\n" unless $table{$_}->{template};
1220     }
1221     exit 0;
1222 }
1223
1224 if ($target eq "HASH") {
1225     local $die = sub { warn @_; };
1226     print "%table = (\n";
1227     foreach (sort keys %table) {
1228         print_table_entry($_, "HASH");
1229     }
1230     exit 0;
1231 }
1232
1233 print "Configuring OpenSSL version $config{full_version} ";
1234 print "for target $target\n";
1235
1236 if (scalar(@seed_sources) == 0) {
1237     print "Using os-specific seed configuration\n";
1238     push @seed_sources, 'os';
1239 }
1240 if (scalar(grep { $_ eq 'egd' } @seed_sources) > 0) {
1241     delete $disabled{'egd'};
1242 }
1243 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1244     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1245     warn <<_____ if scalar(@seed_sources) == 1;
1246
1247 ============================== WARNING ===============================
1248 You have selected the --with-rand-seed=none option, which effectively
1249 disables automatic reseeding of the OpenSSL random generator.
1250 All operations depending on the random generator such as creating keys
1251 will not work unless the random generator is seeded manually by the
1252 application.
1253
1254 Please read the 'Note on random number generation' section in the
1255 INSTALL.md instructions and the RAND_DRBG(7) manual page for more
1256 details.
1257 ============================== WARNING ===============================
1258
1259 _____
1260 }
1261 push @{$config{openssl_feature_defines}},
1262      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1263         @seed_sources;
1264
1265 # Backward compatibility?
1266 if ($target =~ m/^CygWin32(-.*)$/) {
1267     $target = "Cygwin".$1;
1268 }
1269
1270 # Support for legacy targets having a name starting with 'debug-'
1271 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1272 if ($d) {
1273     $config{build_type} = "debug";
1274
1275     # If we do not find debug-foo in the table, the target is set to foo.
1276     if (!$table{$target}) {
1277         $target = $t;
1278     }
1279 }
1280
1281 if ($target) {
1282     # It's possible that we have different config targets for specific
1283     # toolchains, so we try to detect them, and go for the plain config
1284     # target if not.
1285     my $found;
1286     foreach ( ( "$target-$user{CC}", "$target", undef ) ) {
1287         $found=$_ if $table{$_} && !$table{$_}->{template};
1288         last if $found;
1289     }
1290     $target = $found;
1291 } else {
1292     # If we don't have a config target now, we try the C compiler as we
1293     # fallback
1294     my $cc = $user{CC} // 'cc';
1295     $target = $cc if $table{$cc} && !$table{$cc}->{template};
1296 }
1297
1298 &usage unless $target;
1299
1300 exit 0 if $dryrun;              # From older 'config'
1301
1302 $config{target} = $target;
1303 my %target = resolve_config($target);
1304
1305 foreach (keys %target_attr_translate) {
1306     $target{$target_attr_translate{$_}} = $target{$_}
1307         if $target{$_};
1308     delete $target{$_};
1309 }
1310
1311 %target = ( %{$table{DEFAULTS}}, %target );
1312
1313 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1314 $config{conf_files} = [ sort keys %conf_files ];
1315
1316 # Using sub disable within these loops may prove fragile, so we run
1317 # a cascade afterwards
1318 foreach my $feature (@{$target{disable}}) {
1319     if (exists $deprecated_disablables{$feature}) {
1320         warn "***** config $target disables deprecated feature $feature\n";
1321     } elsif (!grep { $feature eq $_ } @disablables) {
1322         die "***** config $target disables unknown feature $feature\n";
1323     }
1324     $disabled{$feature} = 'config';
1325 }
1326 foreach my $feature (@{$target{enable}}) {
1327     if ("default" eq ($disabled{$feature} // "")) {
1328         if (exists $deprecated_disablables{$feature}) {
1329             warn "***** config $target enables deprecated feature $feature\n";
1330         } elsif (!grep { $feature eq $_ } @disablables) {
1331             die "***** config $target enables unknown feature $feature\n";
1332         }
1333         delete $disabled{$feature};
1334     }
1335 }
1336
1337 # If uplink_arch isn't defined, disable uplink
1338 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1339 # If asm_arch isn't defined, disable asm
1340 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1341
1342 disable();                      # Run a cascade now
1343
1344 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1345 $target{cxxflags}//=$target{cflags} if $target{CXX};
1346 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1347 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1348
1349 # Fill %config with values from %user, and in case those are undefined or
1350 # empty, use values from %target (acting as a default).
1351 foreach (keys %user) {
1352     my $ref_type = ref $user{$_};
1353
1354     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1355     # and a value that's to be coerced into that type.
1356     my $mkvalue = sub {
1357         my $type = shift;
1358         my $value = shift;
1359         my $undef_p = shift;
1360
1361         die "Too many arguments for \$mkvalue" if @_;
1362
1363         while (ref $value eq 'CODE') {
1364             $value = $value->();
1365         }
1366
1367         if ($type eq 'ARRAY') {
1368             return undef unless defined $value;
1369             return undef if ref $value ne 'ARRAY' && !$value;
1370             return undef if ref $value eq 'ARRAY' && !@$value;
1371             return [ $value ] unless ref $value eq 'ARRAY';
1372         }
1373         return undef unless $value;
1374         return $value;
1375     };
1376
1377     $config{$_} =
1378         $mkvalue->($ref_type, $user{$_})
1379         || $mkvalue->($ref_type, $target{$_});
1380     delete $config{$_} unless defined $config{$_};
1381 }
1382
1383 # Finish up %config by appending things the user gave us on the command line
1384 # apart from "make variables"
1385 foreach (keys %useradd) {
1386     # The must all be lists, so we assert that here
1387     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1388         unless ref $useradd{$_} eq 'ARRAY';
1389
1390     if (defined $config{$_}) {
1391         push @{$config{$_}}, @{$useradd{$_}};
1392     } else {
1393         $config{$_} = [ @{$useradd{$_}} ];
1394     }
1395 }
1396 # At this point, we can forget everything about %user and %useradd,
1397 # because it's now all been merged into the corresponding $config entry
1398
1399 if (grep { $_ =~ /(?:^|\s)-static(?:\s|$)/ } @{$config{LDFLAGS}}) {
1400     disable('static', 'pic', 'threads');
1401 }
1402
1403 if ($disabled{threads}) {
1404     disable('unavailable', 'thread-pool');
1405 }
1406
1407 if ($disabled{"thread-pool"}) {
1408     disable('unavailable', 'default-thread-pool');
1409 }
1410
1411 # Allow overriding the build file name
1412 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1413
1414 # Make sure build_scheme is consistent.
1415 $target{build_scheme} = [ $target{build_scheme} ]
1416     if ref($target{build_scheme}) ne "ARRAY";
1417
1418 my ($builder, $builder_platform, @builder_opts) =
1419     @{$target{build_scheme}};
1420
1421 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1422                       $builder_platform."-checker.pm")) {
1423     my $checker_path = catfile($srcdir, "Configurations", $checker);
1424     if (-f $checker_path) {
1425         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1426             ? sub { warn $@; } : sub { die $@; };
1427         if (! do $checker_path) {
1428             if ($@) {
1429                 $fn->($@);
1430             } elsif ($!) {
1431                 $fn->($!);
1432             } else {
1433                 $fn->("The detected tools didn't match the platform\n");
1434             }
1435         }
1436         last;
1437     }
1438 }
1439
1440 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1441
1442 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1443         {
1444         push @{$config{cflags}}, "-mno-cygwin";
1445         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1446         push @{$config{shared_ldflag}}, "-mno-cygwin";
1447         }
1448
1449 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1450         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1451         # minimally required architecture flags for assembly modules
1452         my $value;
1453         $value = '-mips2' if ($target =~ /mips32/);
1454         $value = '-mips3' if ($target =~ /mips64/);
1455         unshift @{$config{cflags}}, $value;
1456         unshift @{$config{cxxflags}}, $value if $config{CXX};
1457 }
1458
1459 # If threads aren't disabled, check how possible they are
1460 unless ($disabled{threads}) {
1461     if ($auto_threads) {
1462         # Enabled by default, disable it forcibly if unavailable
1463         if ($target{thread_scheme} eq "(unknown)") {
1464             disable("unavailable", 'threads');
1465         }
1466     } else {
1467         # The user chose to enable threads explicitly, let's see
1468         # if there's a chance that's possible
1469         if ($target{thread_scheme} eq "(unknown)") {
1470             # If the user asked for "threads" and we don't have internal
1471             # knowledge how to do it, [s]he is expected to provide any
1472             # system-dependent compiler options that are necessary.  We
1473             # can't truly check that the given options are correct, but
1474             # we expect the user to know what [s]He is doing.
1475             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1476                 die "You asked for multi-threading support, but didn't\n"
1477                     ,"provide any system-specific compiler options\n";
1478             }
1479         }
1480     }
1481 }
1482
1483 # Find out if clang's sanitizers have been enabled with -fsanitize
1484 # flags and ensure that the corresponding %disabled elements area
1485 # removed to reflect that the sanitizers are indeed enabled.
1486 my %detected_sanitizers = ();
1487 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1488     (my $checks = $_) =~ s/^-fsanitize=//;
1489     foreach (split /,/, $checks) {
1490         my $d = { address       => 'asan',
1491                   undefined     => 'ubsan',
1492                   memory        => 'msan' } -> {$_};
1493         next unless defined $d;
1494
1495         $detected_sanitizers{$d} = 1;
1496         if (defined $disabled{$d}) {
1497             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1498                 if $disabled{$d} ne "default";
1499             delete $disabled{$d};
1500         }
1501     }
1502 }
1503
1504 # If threads still aren't disabled, add a C macro to ensure the source
1505 # code knows about it.  Any other flag is taken care of by the configs.
1506 unless($disabled{threads}) {
1507     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1508 }
1509 unless($disabled{"thread-pool"}) {
1510     push @{$config{openssl_feature_defines}}, "OPENSSL_THREAD_POOL";
1511 }
1512 unless($disabled{"default-thread-pool"}) {
1513     push @{$config{openssl_feature_defines}}, "OPENSSL_DEFAULT_THREAD_POOL";
1514 }
1515
1516 my $no_shared_warn=0;
1517 if (($target{shared_target} // '') eq "")
1518         {
1519         $no_shared_warn = 1
1520             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1521         disable('no-shared-target', 'pic');
1522         }
1523
1524 if ($disabled{"dynamic-engine"}) {
1525         $config{dynamic_engines} = 0;
1526 } else {
1527         $config{dynamic_engines} = 1;
1528 }
1529
1530 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1531     push @{$config{cflags}}, "-fsanitize=address";
1532 }
1533
1534 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1535     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all", "-DPEDANTIC";
1536 }
1537
1538 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1539   push @{$config{cflags}}, "-fsanitize=memory";
1540 }
1541
1542 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1543         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1544     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1545     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1546 }
1547 #
1548 # Platform fix-ups
1549 #
1550
1551 # This saves the build files from having to check
1552 if ($disabled{pic})
1553         {
1554         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1555                     shared_defines shared_includes shared_ldflag
1556                     module_cflags module_cxxflags module_cppflags
1557                     module_defines module_includes module_lflags))
1558                 {
1559                 delete $config{$_};
1560                 $target{$_} = "";
1561                 }
1562         }
1563 else
1564         {
1565         push @{$config{lib_defines}}, "OPENSSL_PIC";
1566         }
1567
1568 if ($target{sys_id} ne "")
1569         {
1570         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1571         }
1572
1573 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1574 my %predefined_CXX = $config{CXX}
1575     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1576     : ();
1577
1578 unless ($disabled{asm}) {
1579     # big endian systems can use ELFv2 ABI
1580     if ($target eq "linux-ppc64" || $target eq "BSD-ppc64") {
1581         $target{perlasm_scheme} = "linux64v2" if ($predefined_C{_CALL_ELF} == 2);
1582     }
1583 }
1584
1585 # Check for makedepend capabilities.
1586 if (!$disabled{makedepend}) {
1587     # If the attribute makedep_scheme is defined, then we assume that the
1588     # config target and its associated build file are programmed to deal
1589     # with it.
1590     # If makedep_scheme is undefined, we go looking for GCC compatible
1591     # dependency making, and if that's not available, we try to fall back
1592     # on 'makedepend'.
1593     if ($target{makedep_scheme}) {
1594         $config{makedep_scheme} = $target{makedep_scheme};
1595         # If the makedepcmd attribute is defined, copy it.  If not, the
1596         # build files will have to fend for themselves.
1597         $config{makedepcmd} = $target{makedepcmd} if $target{makedepcmd};
1598     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1599              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1600         # We know that GNU C version 3 and up as well as all clang
1601         # versions support dependency generation, but Xcode did not
1602         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1603         $config{makedep_scheme} = 'gcc';
1604     } else {
1605         # In all other cases, we look for 'makedepend', and set the
1606         # makedep_scheme value if we found it.
1607         $config{makedepcmd} = which('makedepend');
1608         $config{makedep_scheme} = 'makedepend' if $config{makedepcmd};
1609     }
1610
1611     # If no depend scheme is set, we disable makedepend
1612     disable('unavailable', 'makedepend') unless $config{makedep_scheme};
1613 }
1614
1615 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1616     # probe for -Wa,--noexecstack option...
1617     if ($predefined_C{__clang__}) {
1618         # clang has builtin assembler, which doesn't recognize --help,
1619         # but it apparently recognizes the option in question on all
1620         # supported platforms even when it's meaningless. In other words
1621         # probe would fail, but probed option always accepted...
1622         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1623     } else {
1624         my $cc = $config{CROSS_COMPILE}.$config{CC};
1625         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1626         while(<PIPE>) {
1627             if (m/--noexecstack/) {
1628                 push @{$config{cflags}}, "-Wa,--noexecstack";
1629                 last;
1630             }
1631         }
1632         close(PIPE);
1633         unlink("null.$$.o");
1634     }
1635 }
1636
1637 # Deal with bn_ops ###################################################
1638
1639 $config{bn_ll}                  =0;
1640 my $def_int="unsigned int";
1641 $config{rc4_int}                =$def_int;
1642 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1643
1644 my $count = 0;
1645 foreach (sort split(/\s+/,$target{bn_ops})) {
1646     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1647     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1648     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1649     ($config{b64l},$config{b64},$config{b32})
1650         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1651     ($config{b64l},$config{b64},$config{b32})
1652         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1653     ($config{b64l},$config{b64},$config{b32})
1654         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1655 }
1656 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1657     if $count > 1;
1658
1659 $config{api} = $config{major} * 10000 + $config{minor} * 100
1660     unless $config{api};
1661 foreach (keys %$apitable) {
1662     $disabled{"deprecated-$_"} = "deprecation"
1663         if $disabled{deprecated} && $config{api} >= $apitable->{$_};
1664 }
1665
1666 disable();                      # Run a cascade now
1667
1668 # Hack cflags for better warnings (dev option) #######################
1669
1670 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1671 # a string and works as well on command lines.
1672 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1673                         @{$config{cflags}} ];
1674 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1675                           @{$config{cxxflags}} ] if $config{CXX};
1676
1677 $config{openssl_api_defines} = [
1678     "OPENSSL_CONFIGURED_API=".$config{api},
1679 ];
1680
1681 my @strict_warnings_collection=();
1682 if ($strict_warnings)
1683         {
1684         my $wopt;
1685         my $gccver = $predefined_C{__GNUC__} // -1;
1686
1687         if ($gccver >= 4)
1688                 {
1689                 push @strict_warnings_collection, @gcc_devteam_warn;
1690                 push @strict_warnings_collection, @clang_devteam_warn
1691                     if (defined($predefined_C{__clang__}));
1692                 }
1693         elsif ($config{target} =~ /^VC-/)
1694                 {
1695                 push @strict_warnings_collection, @cl_devteam_warn;
1696                 }
1697         else
1698                 {
1699                 warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike, or MSVC"
1700                 }
1701         }
1702
1703 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1704                               ? @strict_warnings_collection
1705                               : ( $_ ) }
1706                     @{$config{CFLAGS}} ];
1707
1708 unless ($disabled{afalgeng}) {
1709     $config{afalgeng}="";
1710     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1711         push @{$config{engdirs}}, "afalg";
1712     } else {
1713         disable('not-linux', 'afalgeng');
1714     }
1715 }
1716
1717 unless ($disabled{devcryptoeng}) {
1718     if ($target =~ m/^BSD/) {
1719         my $maxver = 5*100 + 7;
1720         my $sysstr = `uname -s`;
1721         my $verstr = `uname -r`;
1722         $sysstr =~ s|\R$||;
1723         $verstr =~ s|\R$||;
1724         my ($ma, $mi, @rest) = split m|\.|, $verstr;
1725         my $ver = $ma*100 + $mi;
1726         if ($sysstr eq 'OpenBSD' && $ver >= $maxver) {
1727             disable('too-new-kernel', 'devcryptoeng');
1728         }
1729     }
1730 }
1731
1732 unless ($disabled{ktls}) {
1733     $config{ktls}="";
1734     my $cc = $config{CROSS_COMPILE}.$config{CC};
1735     if ($target =~ m/^linux/) {
1736         system("printf '#include <sys/types.h>\n#include <linux/tls.h>' | $cc -E - >/dev/null 2>&1");
1737         if ($? != 0) {
1738             disable('too-old-kernel', 'ktls');
1739         }
1740     } elsif ($target =~ m/^BSD/) {
1741         system("printf '#include <sys/types.h>\n#include <sys/ktls.h>' | $cc -E - >/dev/null 2>&1");
1742         if ($? != 0) {
1743             disable('too-old-freebsd', 'ktls');
1744         }
1745     } else {
1746         disable('not-linux-or-freebsd', 'ktls');
1747     }
1748 }
1749
1750 unless ($disabled{winstore}) {
1751     unless ($target =~ /^(?:Cygwin|mingw|VC-|BC-)/) {
1752         disable('not-windows', 'winstore');
1753     }
1754 }
1755
1756 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1757
1758 # Get the extra flags used when building shared libraries and modules.  We
1759 # do this late because some of them depend on %disabled.
1760
1761 # Make the flags to build DSOs the same as for shared libraries unless they
1762 # are already defined
1763 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1764 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1765 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1766 {
1767     my $shared_info_pl =
1768         catfile(dirname($0), "Configurations", "shared-info.pl");
1769     my %shared_info = read_eval_file($shared_info_pl);
1770     push @{$target{_conf_fname_int}}, $shared_info_pl;
1771     my $si = $target{shared_target};
1772     while (ref $si ne "HASH") {
1773         last if ! defined $si;
1774         if (ref $si eq "CODE") {
1775             $si = $si->();
1776         } else {
1777             $si = $shared_info{$si};
1778         }
1779     }
1780
1781     # Some of the 'shared_target' values don't have any entries in
1782     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1783     # template knows how to handle this.  That is currently the case for
1784     # Windows and VMS.
1785     if (defined $si) {
1786         # Just as above, copy certain shared_* attributes to the corresponding
1787         # module_ attribute unless the latter is already defined
1788         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1789         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1790         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1791         foreach (sort keys %$si) {
1792             $target{$_} = defined $target{$_}
1793                 ? add($si->{$_})->($target{$_})
1794                 : $si->{$_};
1795         }
1796     }
1797 }
1798
1799 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1800
1801 ######################################################################
1802 # Build up information for skipping certain directories depending on disabled
1803 # features, as well as setting up macros for disabled features.
1804
1805 # This is a tentative database of directories to skip.  Some entries may not
1806 # correspond to anything real, but that's ok, they will simply be ignored.
1807 # The actual processing of these entries is done in the build.info lookup
1808 # loop further down.
1809 #
1810 # The key is a Unix formatted path in the source tree, the value is an index
1811 # into %disabled_info, so any existing path gets added to a corresponding
1812 # 'skipped' entry in there with the list of skipped directories.
1813 my %skipdir = ();
1814 my %disabled_info = ();         # For configdata.pm
1815 foreach my $what (sort keys %disabled) {
1816     # There are deprecated disablables that translate to themselves.
1817     # They cause disabling cascades, but should otherwise not register.
1818     next if $deprecated_disablables{$what};
1819     # The generated $disabled{"deprecated-x.y"} entries are special
1820     # and treated properly elsewhere
1821     next if $what =~ m|^deprecated-|;
1822
1823     $config{options} .= " no-$what";
1824
1825     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1826                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1827                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1828         (my $WHAT = uc $what) =~ s|-|_|g;
1829         my $skipdir = $what;
1830
1831         # fix-up crypto/directory name(s)
1832         $skipdir = "ripemd" if $what eq "rmd160";
1833         $skipdir = "whrlpool" if $what eq "whirlpool";
1834
1835         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1836         push @{$config{openssl_feature_defines}}, $macro;
1837
1838         $skipdir{engines} = $what if $what eq 'engine';
1839         $skipdir{"crypto/$skipdir"} = $what
1840             unless $what eq 'async' || $what eq 'err' || $what eq 'dso';
1841     }
1842 }
1843
1844 if ($disabled{"dynamic-engine"}) {
1845     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1846 } else {
1847     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1848 }
1849
1850 # If we use the unified build, collect information from build.info files
1851 my %unified_info = ();
1852
1853 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1854 if ($builder eq "unified") {
1855     use Text::Template 1.46;
1856
1857     sub cleandir {
1858         my $base = shift;
1859         my $dir = shift;
1860         my $relativeto = shift || ".";
1861
1862         $dir = catdir($base,$dir) unless isabsolute($dir);
1863
1864         # Make sure the directories we're building in exists
1865         mkpath($dir);
1866
1867         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1868         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1869         return $res;
1870     }
1871
1872     sub cleanfile {
1873         my $base = shift;
1874         my $file = shift;
1875         my $relativeto = shift || ".";
1876
1877         $file = catfile($base,$file) unless isabsolute($file);
1878
1879         my $d = dirname($file);
1880         my $f = basename($file);
1881
1882         # Make sure the directories we're building in exists
1883         mkpath($d);
1884
1885         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1886         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1887         return $res;
1888     }
1889
1890     # Store the name of the template file we will build the build file from
1891     # in %config.  This may be useful for the build file itself.
1892     my @build_file_template_names =
1893         ( $builder_platform."-".$target{build_file}.".tmpl",
1894           $target{build_file}.".tmpl" );
1895     my @build_file_templates = ();
1896
1897     # First, look in the user provided directory, if given
1898     if (defined env($local_config_envname)) {
1899         @build_file_templates =
1900             map {
1901                 if ($^O eq 'VMS') {
1902                     # VMS environment variables are logical names,
1903                     # which can be used as is
1904                     $local_config_envname . ':' . $_;
1905                 } else {
1906                     catfile(env($local_config_envname), $_);
1907                 }
1908             }
1909             @build_file_template_names;
1910     }
1911     # Then, look in our standard directory
1912     push @build_file_templates,
1913         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1914           @build_file_template_names );
1915
1916     my $build_file_template;
1917     for $_ (@build_file_templates) {
1918         $build_file_template = $_;
1919         last if -f $build_file_template;
1920
1921         $build_file_template = undef;
1922     }
1923     if (!defined $build_file_template) {
1924         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1925     }
1926     $config{build_file_templates}
1927       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1928                     $blddir),
1929            $build_file_template ];
1930
1931     my @build_dirs = ( [ ] );   # current directory
1932
1933     $config{build_infos} = [ ];
1934
1935     # We want to detect configdata.pm in the source tree, so we
1936     # don't use it if the build tree is different.
1937     my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1938
1939     # Any source file that we recognise is placed in this hash table, with
1940     # the list of its intended destinations as value.  When everything has
1941     # been collected, there's a routine that checks that these source files
1942     # exist, or if they are generated, that the generator exists.
1943     my %check_exist = ();
1944     my %check_generate = ();
1945
1946     my %ordinals = ();
1947     while (@build_dirs) {
1948         my @curd = @{shift @build_dirs};
1949         my $sourced = catdir($srcdir, @curd);
1950         my $buildd = catdir($blddir, @curd);
1951
1952         my $unixdir = join('/', @curd);
1953         if (exists $skipdir{$unixdir}) {
1954             my $what = $skipdir{$unixdir};
1955             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1956             next;
1957         }
1958
1959         mkpath($buildd);
1960
1961         my $f = 'build.info';
1962         # The basic things we're trying to build
1963         my @programs = ();
1964         my @libraries = ();
1965         my @modules = ();
1966         my @scripts = ();
1967
1968         my %sources = ();
1969         my %shared_sources = ();
1970         my %includes = ();
1971         my %defines = ();
1972         my %depends = ();
1973         my %generate = ();
1974         my %imagedocs = ();
1975         my %htmldocs = ();
1976         my %mandocs = ();
1977
1978         # Support for $variablename in build.info files.
1979         # Embedded perl code is the ultimate master, still.  If its output
1980         # contains a dollar sign, it had better be escaped, or it will be
1981         # taken for a variable name prefix.
1982         my %variables = ();
1983         # Variable name syntax
1984         my $variable_name_re = qr/(?P<VARIABLE>[[:alpha:]][[:alnum:]_]*)/;
1985         # Value modifier syntaxes
1986         my $variable_subst_re = qr/\/(?P<RE>(?:\\\/|.)*?)\/(?P<SUBST>.*?)/;
1987         # Variable reference
1988         my $variable_simple_re = qr/(?<!\\)\$${variable_name_re}/;
1989         my $variable_w_mod_re =
1990             qr/(?<!\\)\$\{${variable_name_re}(?P<MOD>(?:\\\/|.)*?)\}/;
1991         # Tie it all together
1992         my $variable_re = qr/${variable_simple_re}|${variable_w_mod_re}/;
1993
1994         my $expand_variables = sub {
1995             my $value = '';
1996             my $value_rest = shift;
1997
1998             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1999                 print STDERR
2000                     "DEBUG[\$expand_variables] Parsed '$value_rest' ...\n"
2001             }
2002
2003             while ($value_rest =~ /${variable_re}/) {
2004                 # We must save important regexp values, because the next
2005                 # regexp clears them
2006                 my $mod = $+{MOD};
2007                 my $variable_value = $variables{$+{VARIABLE}};
2008
2009                 $value_rest = $';
2010                 $value .= $`;
2011
2012                 # Process modifier expressions, if present
2013                 if (defined $mod) {
2014                     if ($mod =~ /^${variable_subst_re}$/) {
2015                         my $re = $+{RE};
2016                         my $subst = $+{SUBST};
2017
2018                         $variable_value =~ s/\Q$re\E/$subst/g;
2019
2020                         if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2021                             print STDERR
2022                                 "DEBUG[\$expand_variables] ... and substituted ",
2023                                 "'$re' with '$subst'\n";
2024                         }
2025                     }
2026                 }
2027
2028                 $value .= $variable_value;
2029             }
2030             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2031                 print STDERR
2032                     "DEBUG[\$expand_variables] ... into: '$value$value_rest'\n";
2033             }
2034             return $value . $value_rest;
2035         };
2036
2037         # Support for attributes in build.info files
2038         my %attributes = ();
2039         my $handle_attributes = sub {
2040             my $attr_str = shift;
2041             my $ref = shift;
2042             my @goals = @_;
2043
2044             return unless defined $attr_str;
2045
2046             my @a = tokenize($attr_str, qr|\s*,\s*|);
2047             foreach my $a (@a) {
2048                 my $ac = 1;
2049                 my $ak = $a;
2050                 my $av = 1;
2051                 if ($a =~ m|^(!)?(.*?)\s* = \s*(.*?)$|x) {
2052                     $ac = ! $1;
2053                     $ak = $2;
2054                     $av = $3;
2055                 }
2056                 foreach my $g (@goals) {
2057                     if ($ac) {
2058                         $$ref->{$g}->{$ak} = $av;
2059                     } else {
2060                         delete $$ref->{$g}->{$ak};
2061                     }
2062                 }
2063             }
2064         };
2065
2066         # Support for pushing values on multiple indexes of a given hash
2067         # array.
2068         my $push_to = sub {
2069             my $valueref = shift;
2070             my $index_str = shift; # May be undef or empty
2071             my $attrref = shift;   # May be undef
2072             my $attr_str = shift;
2073             my @values = @_;
2074
2075             if (defined $index_str) {
2076                 my @indexes = ( '' );
2077                 if ($index_str !~ m|^\s*$|) {
2078                     @indexes = tokenize($index_str);
2079                 }
2080                 foreach (@indexes) {
2081                     push @{$valueref->{$_}}, @values;
2082                     if (defined $attrref) {
2083                         $handle_attributes->($attr_str, \$$attrref->{$_},
2084                                              @values);
2085                     }
2086                 }
2087             } else {
2088                 push @$valueref, @values;
2089                 $handle_attributes->($attr_str, $attrref, @values)
2090                     if defined $attrref;
2091             }
2092         };
2093
2094         if ($buildinfo_debug) {
2095             print STDERR "DEBUG: Reading ",catfile($sourced, $f),"\n";
2096         }
2097         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
2098         my $template =
2099             Text::Template->new(TYPE => 'FILE',
2100                                 SOURCE => catfile($sourced, $f),
2101                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
2102         die "Something went wrong with $sourced/$f: $!\n" unless $template;
2103         my @text =
2104             split /^/m,
2105             $template->fill_in(HASH => { config => \%config,
2106                                          target => \%target,
2107                                          disabled => \%disabled,
2108                                          withargs => \%withargs,
2109                                          builddir => abs2rel($buildd, $blddir),
2110                                          sourcedir => abs2rel($sourced, $blddir),
2111                                          buildtop => abs2rel($blddir, $blddir),
2112                                          sourcetop => abs2rel($srcdir, $blddir) },
2113                                DELIMITERS => [ "{-", "-}" ]);
2114
2115         # The top item of this stack has the following values
2116         # -2 positive already run and we found ELSE (following ELSIF should fail)
2117         # -1 positive already run (skip until ENDIF)
2118         # 0 negatives so far (if we're at a condition, check it)
2119         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
2120         # 2 positive ELSE (following ELSIF should fail)
2121         my @skip = ();
2122
2123         # A few useful generic regexps
2124         my $index_re = qr/\[\s*(?P<INDEX>(?:\\.|.)*?)\s*\]/;
2125         my $cond_re = qr/\[\s*(?P<COND>(?:\\.|.)*?)\s*\]/;
2126         my $attribs_re = qr/(?:\{\s*(?P<ATTRIBS>(?:\\.|.)*?)\s*\})?/;
2127         my $value_re = qr/(?P<VALUE>.*?)/;
2128         collect_information(
2129             collect_from_array([ @text ],
2130                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
2131                                                 $l1 =~ s/\\$//; $l1.$l2 }),
2132             # Info we're looking for
2133             qr/^\s* IF ${cond_re} \s*$/x
2134             => sub {
2135                 if (! @skip || $skip[$#skip] > 0) {
2136                     push @skip, !! $expand_variables->($+{COND});
2137                 } else {
2138                     push @skip, -1;
2139                 }
2140             },
2141             qr/^\s* ELSIF ${cond_re} \s*$/x
2142             => sub { die "ELSIF out of scope" if ! @skip;
2143                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
2144                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
2145                      $skip[$#skip] = !! $expand_variables->($+{COND})
2146                          if $skip[$#skip] == 0; },
2147             qr/^\s* ELSE \s*$/x
2148             => sub { die "ELSE out of scope" if ! @skip;
2149                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
2150                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
2151             qr/^\s* ENDIF \s*$/x
2152             => sub { die "ENDIF out of scope" if ! @skip;
2153                      pop @skip; },
2154             qr/^\s* ${variable_re} \s* = \s* ${value_re} \s* $/x
2155             => sub {
2156                 if (!@skip || $skip[$#skip] > 0) {
2157                     $variables{$+{VARIABLE}} = $expand_variables->($+{VALUE});
2158                 }
2159             },
2160             qr/^\s* SUBDIRS \s* = \s* ${value_re} \s* $/x
2161             => sub {
2162                 if (!@skip || $skip[$#skip] > 0) {
2163                     foreach (tokenize($expand_variables->($+{VALUE}))) {
2164                         push @build_dirs, [ @curd, splitdir($_, 1) ];
2165                     }
2166                 }
2167             },
2168             qr/^\s* PROGRAMS ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2169             => sub { $push_to->(\@programs, undef,
2170                                 \$attributes{programs}, $+{ATTRIBS},
2171                                 tokenize($expand_variables->($+{VALUE})))
2172                          if !@skip || $skip[$#skip] > 0; },
2173             qr/^\s* LIBS ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2174             => sub { $push_to->(\@libraries, undef,
2175                                 \$attributes{libraries}, $+{ATTRIBS},
2176                                 tokenize($expand_variables->($+{VALUE})))
2177                          if !@skip || $skip[$#skip] > 0; },
2178             qr/^\s* MODULES ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2179             => sub { $push_to->(\@modules, undef,
2180                                 \$attributes{modules}, $+{ATTRIBS},
2181                                 tokenize($expand_variables->($+{VALUE})))
2182                          if !@skip || $skip[$#skip] > 0; },
2183             qr/^\s* SCRIPTS ${attribs_re} \s* = \s* ${value_re} \s* $/x
2184             => sub { $push_to->(\@scripts, undef,
2185                                 \$attributes{scripts}, $+{ATTRIBS},
2186                                 tokenize($expand_variables->($+{VALUE})))
2187                          if !@skip || $skip[$#skip] > 0; },
2188             qr/^\s* IMAGEDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2189             => sub { $push_to->(\%imagedocs, $expand_variables->($+{INDEX}),
2190                                 undef, undef,
2191                                 tokenize($expand_variables->($+{VALUE})))
2192                          if !@skip || $skip[$#skip] > 0; },
2193             qr/^\s* HTMLDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2194             => sub { $push_to->(\%htmldocs, $expand_variables->($+{INDEX}),
2195                                 undef, undef,
2196                                 tokenize($expand_variables->($+{VALUE})))
2197                          if !@skip || $skip[$#skip] > 0; },
2198             qr/^\s* MANDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2199             => sub { $push_to->(\%mandocs, $expand_variables->($+{INDEX}),
2200                                 undef, undef,
2201                                 tokenize($expand_variables->($+{VALUE})))
2202                          if !@skip || $skip[$#skip] > 0; },
2203             qr/^\s* SOURCE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2204             => sub { $push_to->(\%sources, $expand_variables->($+{INDEX}),
2205                                 \$attributes{sources}, $+{ATTRIBS},
2206                                 tokenize($expand_variables->($+{VALUE})))
2207                          if !@skip || $skip[$#skip] > 0; },
2208             qr/^\s* SHARED_SOURCE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2209             => sub { $push_to->(\%shared_sources, $expand_variables->($+{INDEX}),
2210                                 \$attributes{sources}, $+{ATTRIBS},
2211                                 tokenize($expand_variables->($+{VALUE})))
2212                          if !@skip || $skip[$#skip] > 0; },
2213             qr/^\s* INCLUDE ${index_re} \s* = \s* ${value_re} \s* $/x
2214             => sub { $push_to->(\%includes, $expand_variables->($+{INDEX}),
2215                                 undef, undef,
2216                                 tokenize($expand_variables->($+{VALUE})))
2217                          if !@skip || $skip[$#skip] > 0; },
2218             qr/^\s* DEFINE ${index_re} \s* = \s* ${value_re} \s* $/x
2219             => sub { $push_to->(\%defines, $expand_variables->($+{INDEX}),
2220                                 undef, undef,
2221                                 tokenize($expand_variables->($+{VALUE})))
2222                          if !@skip || $skip[$#skip] > 0; },
2223             qr/^\s* DEPEND ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2224             => sub { $push_to->(\%depends, $expand_variables->($+{INDEX}),
2225                                 \$attributes{depends}, $+{ATTRIBS},
2226                                 tokenize($expand_variables->($+{VALUE})))
2227                          if !@skip || $skip[$#skip] > 0; },
2228             qr/^\s* GENERATE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2229             => sub { $push_to->(\%generate, $expand_variables->($+{INDEX}),
2230                                 \$attributes{generate}, $+{ATTRIBS},
2231                                 $expand_variables->($+{VALUE}))
2232                          if !@skip || $skip[$#skip] > 0; },
2233             qr/^\s* (?:\#.*)? $/x => sub { },
2234             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
2235             "BEFORE" => sub {
2236                 if ($buildinfo_debug) {
2237                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
2238                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2239                 }
2240             },
2241             "AFTER" => sub {
2242                 if ($buildinfo_debug) {
2243                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2244                 }
2245             },
2246             );
2247         die "runaway IF?" if (@skip);
2248
2249         if (grep { defined $attributes{modules}->{$_}->{engine} } keys %attributes
2250                 and !$config{dynamic_engines}) {
2251             die <<"EOF"
2252 ENGINES can only be used if configured with 'dynamic-engine'.
2253 This is usually a fault in a build.info file.
2254 EOF
2255         }
2256
2257         {
2258             my %infos = ( programs  => [ @programs  ],
2259                           libraries => [ @libraries ],
2260                           modules   => [ @modules   ],
2261                           scripts   => [ @scripts   ] );
2262             foreach my $k (keys %infos) {
2263                 foreach (@{$infos{$k}}) {
2264                     my $item = cleanfile($buildd, $_, $blddir);
2265                     $unified_info{$k}->{$item} = 1;
2266
2267                     # Fix up associated attributes
2268                     $unified_info{attributes}->{$k}->{$item} =
2269                         $attributes{$k}->{$_}
2270                         if defined $attributes{$k}->{$_};
2271                 }
2272             }
2273         }
2274
2275         # Check that we haven't defined any library as both shared and
2276         # explicitly static.  That is forbidden.
2277         my @doubles = ();
2278         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2279             (my $l = $_) =~ s/\.a$//;
2280             push @doubles, $l if defined $unified_info{libraries}->{$l};
2281         }
2282         die "these libraries are both explicitly static and shared:\n  ",
2283             join(" ", @doubles), "\n"
2284             if @doubles;
2285
2286         foreach (keys %sources) {
2287             my $dest = $_;
2288             my $ddest = cleanfile($buildd, $_, $blddir);
2289             foreach (@{$sources{$dest}}) {
2290                 my $s = cleanfile($sourced, $_, $blddir);
2291
2292                 # If it's generated or we simply don't find it in the source
2293                 # tree, we assume it's in the build tree.
2294                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2295                     $s = cleanfile($buildd, $_, $blddir);
2296                 }
2297                 my $o = $_;
2298                 # We recognise C++, C and asm files
2299                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2300                     push @{$check_exist{$s}}, $ddest;
2301                     $o =~ s/\.[csS]$/.o/; # C and assembler
2302                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2303                     $o = cleanfile($buildd, $o, $blddir);
2304                     $unified_info{sources}->{$ddest}->{$o} = -1;
2305                     $unified_info{sources}->{$o}->{$s} = -1;
2306                 } elsif ($s =~ /\.rc$/) {
2307                     # We also recognise resource files
2308                     push @{$check_exist{$s}}, $ddest;
2309                     $o =~ s/\.rc$/.res/; # Resource configuration
2310                     $o = cleanfile($buildd, $o, $blddir);
2311                     $unified_info{sources}->{$ddest}->{$o} = -1;
2312                     $unified_info{sources}->{$o}->{$s} = -1;
2313                 } else {
2314                     push @{$check_exist{$s}}, $ddest;
2315                     $unified_info{sources}->{$ddest}->{$s} = 1;
2316                 }
2317                 # Fix up associated attributes
2318                 if ($o ne $_) {
2319                     $unified_info{attributes}->{sources}->{$ddest}->{$o} =
2320                         $unified_info{attributes}->{sources}->{$o}->{$s} =
2321                         $attributes{sources}->{$dest}->{$_}
2322                         if defined $attributes{sources}->{$dest}->{$_};
2323                 } else {
2324                     $unified_info{attributes}->{sources}->{$ddest}->{$s} =
2325                         $attributes{sources}->{$dest}->{$_}
2326                         if defined $attributes{sources}->{$dest}->{$_};
2327                 }
2328             }
2329         }
2330
2331         foreach (keys %shared_sources) {
2332             my $dest = $_;
2333             my $ddest = cleanfile($buildd, $_, $blddir);
2334             foreach (@{$shared_sources{$dest}}) {
2335                 my $s = cleanfile($sourced, $_, $blddir);
2336
2337                 # If it's generated or we simply don't find it in the source
2338                 # tree, we assume it's in the build tree.
2339                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2340                     $s = cleanfile($buildd, $_, $blddir);
2341                 }
2342
2343                 my $o = $_;
2344                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2345                     # We recognise C++, C and asm files
2346                     push @{$check_exist{$s}}, $ddest;
2347                     $o =~ s/\.[csS]$/.o/; # C and assembler
2348                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2349                     $o = cleanfile($buildd, $o, $blddir);
2350                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2351                     $unified_info{sources}->{$o}->{$s} = -1;
2352                 } elsif ($s =~ /\.rc$/) {
2353                     # We also recognise resource files
2354                     push @{$check_exist{$s}}, $ddest;
2355                     $o =~ s/\.rc$/.res/; # Resource configuration
2356                     $o = cleanfile($buildd, $o, $blddir);
2357                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2358                     $unified_info{sources}->{$o}->{$s} = -1;
2359                 } elsif ($s =~ /\.ld$/) {
2360                     # We also recognise linker scripts (or corresponding)
2361                     # We know they are generated files
2362                     push @{$check_exist{$s}}, $ddest;
2363                     $o = cleanfile($buildd, $_, $blddir);
2364                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
2365                 } else {
2366                     die "unrecognised source file type for shared library: $s\n";
2367                 }
2368                 # Fix up associated attributes
2369                 if ($o ne $_) {
2370                     $unified_info{attributes}->{shared_sources}->{$ddest}->{$o} =
2371                         $unified_info{attributes}->{sources}->{$o}->{$s} =
2372                         $attributes{sources}->{$dest}->{$_}
2373                         if defined $attributes{sources}->{$dest}->{$_};
2374                 } else {
2375                     $unified_info{attributes}->{shared_sources}->{$ddest}->{$o} =
2376                         $attributes{sources}->{$dest}->{$_}
2377                         if defined $attributes{sources}->{$dest}->{$_};
2378                 }
2379             }
2380         }
2381
2382         foreach (keys %generate) {
2383             my $dest = $_;
2384             my $ddest = cleanfile($buildd, $_, $blddir);
2385             die "more than one generator for $dest: "
2386                 ,join(" ", @{$generate{$_}}),"\n"
2387                 if scalar @{$generate{$_}} > 1;
2388             my @generator = split /\s+/, $generate{$dest}->[0];
2389             my $gen = $generator[0];
2390             $generator[0] = cleanfile($sourced, $gen, $blddir);
2391
2392             # If the generator is itself generated, it's in the build tree
2393             if ($generate{$gen} || ! -f $generator[0]) {
2394                 $generator[0] = cleanfile($buildd, $gen, $blddir);
2395             }
2396             $check_generate{$ddest}->{$generator[0]}++;
2397
2398             $unified_info{generate}->{$ddest} = [ @generator ];
2399             # Fix up associated attributes
2400             $unified_info{attributes}->{generate}->{$ddest} =
2401                 $attributes{generate}->{$dest}->{$gen}
2402                 if defined $attributes{generate}->{$dest}->{$gen};
2403         }
2404
2405         foreach (keys %depends) {
2406             my $dest = $_;
2407             my $ddest = $dest;
2408
2409             if ($dest =~ /^\|(.*)\|$/) {
2410                 # Collect the raw target
2411                 $unified_info{targets}->{$1} = 1;
2412                 $ddest = $1;
2413             } elsif ($dest eq '') {
2414                 $ddest = '';
2415             } else {
2416                 $ddest = cleanfile($sourced, $_, $blddir);
2417
2418                 # If the destination doesn't exist in source, it can only be
2419                 # a generated file in the build tree.
2420                 if ($ddest eq $src_configdata || ! -f $ddest) {
2421                     $ddest = cleanfile($buildd, $_, $blddir);
2422                 }
2423             }
2424             foreach (@{$depends{$dest}}) {
2425                 my $d = cleanfile($sourced, $_, $blddir);
2426                 my $d2 = cleanfile($buildd, $_, $blddir);
2427
2428                 # If we know it's generated, or assume it is because we can't
2429                 # find it in the source tree, we set file we depend on to be
2430                 # in the build tree rather than the source tree.
2431                 if ($d eq $src_configdata
2432                     || (grep { $d2 eq $_ }
2433                         keys %{$unified_info{generate}})
2434                     || ! -f $d) {
2435                     $d = $d2;
2436                 }
2437                 $unified_info{depends}->{$ddest}->{$d} = 1;
2438
2439                 # Fix up associated attributes
2440                 $unified_info{attributes}->{depends}->{$ddest}->{$d} =
2441                     $attributes{depends}->{$dest}->{$_}
2442                     if defined $attributes{depends}->{$dest}->{$_};
2443             }
2444         }
2445
2446         foreach (keys %includes) {
2447             my $dest = $_;
2448             my $ddest = cleanfile($sourced, $_, $blddir);
2449
2450             # If the destination doesn't exist in source, it can only be
2451             # a generated file in the build tree.
2452             if ($ddest eq $src_configdata || ! -f $ddest) {
2453                 $ddest = cleanfile($buildd, $_, $blddir);
2454             }
2455             foreach (@{$includes{$dest}}) {
2456                 my $is = cleandir($sourced, $_, $blddir);
2457                 my $ib = cleandir($buildd, $_, $blddir);
2458                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2459                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2460                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2461                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2462             }
2463         }
2464
2465         foreach my $dest (keys %defines) {
2466             my $ddest;
2467
2468             if ($dest ne "") {
2469                 $ddest = cleanfile($sourced, $dest, $blddir);
2470
2471                 # If the destination doesn't exist in source, it can only
2472                 # be a generated file in the build tree.
2473                 if (! -f $ddest) {
2474                     $ddest = cleanfile($buildd, $dest, $blddir);
2475                 }
2476             }
2477             foreach my $v (@{$defines{$dest}}) {
2478                 $v =~ m|^([^=]*)(=.*)?$|;
2479                 die "0 length macro name not permitted\n" if $1 eq "";
2480                 if ($dest ne "") {
2481                     die "$1 defined more than once\n"
2482                         if defined $unified_info{defines}->{$ddest}->{$1};
2483                     $unified_info{defines}->{$ddest}->{$1} = $2;
2484                 } else {
2485                     die "$1 defined more than once\n"
2486                         if grep { $v eq $_ } @{$config{defines}};
2487                     push @{$config{defines}}, $v;
2488                 }
2489             }
2490         }
2491
2492         foreach my $section (keys %imagedocs) {
2493             foreach (@{$imagedocs{$section}}) {
2494                 my $imagedocs = cleanfile($buildd, $_, $blddir);
2495                 $unified_info{imagedocs}->{$section}->{$imagedocs} = 1;
2496             }
2497         }
2498
2499         foreach my $section (keys %htmldocs) {
2500             foreach (@{$htmldocs{$section}}) {
2501                 my $htmldocs = cleanfile($buildd, $_, $blddir);
2502                 $unified_info{htmldocs}->{$section}->{$htmldocs} = 1;
2503             }
2504         }
2505
2506         foreach my $section (keys %mandocs) {
2507             foreach (@{$mandocs{$section}}) {
2508                 my $mandocs = cleanfile($buildd, $_, $blddir);
2509                 $unified_info{mandocs}->{$section}->{$mandocs} = 1;
2510             }
2511         }
2512     }
2513
2514     my $ordinals_text = join(', ', sort keys %ordinals);
2515     warn <<"EOF" if $ordinals_text;
2516
2517 WARNING: ORDINALS were specified for $ordinals_text
2518 They are ignored and should be replaced with a combination of GENERATE,
2519 DEPEND and SHARED_SOURCE.
2520 EOF
2521
2522     # Check that each generated file is only generated once
2523     my $ambiguous_generation = 0;
2524     foreach (sort keys %check_generate) {
2525         my @generators = sort keys %{$check_generate{$_}};
2526         my $generators_txt = join(', ', @generators);
2527         if (scalar @generators > 1) {
2528             warn "$_ is GENERATEd by more than one generator ($generators_txt)\n";
2529             $ambiguous_generation++;
2530         }
2531         if ($check_generate{$_}->{$generators[0]} > 1) {
2532             warn "INFO: $_ has more than one GENERATE declaration (same generator)\n"
2533         }
2534     }
2535     die "There are ambiguous source file generations\n"
2536         if $ambiguous_generation > 0;
2537
2538     # All given source files should exist, or if generated, their
2539     # generator should exist.  This loop ensures this is true.
2540     my $missing = 0;
2541     foreach my $orig (sort keys %check_exist) {
2542         foreach my $dest (@{$check_exist{$orig}}) {
2543             if ($orig ne $src_configdata) {
2544                 if ($orig =~ /\.a$/) {
2545                     # Static library names may be used as sources, so we
2546                     # need to detect those and give them special treatment.
2547                     unless (grep { $_ eq $orig }
2548                             keys %{$unified_info{libraries}}) {
2549                         warn "$orig is given as source for $dest, but no such library is built\n";
2550                         $missing++;
2551                     }
2552                 } else {
2553                     # A source may be generated, and its generator may be
2554                     # generated as well.  We therefore loop to dig out the
2555                     # first generator.
2556                     my $gen = $orig;
2557
2558                     while (my @next = keys %{$check_generate{$gen}}) {
2559                         $gen = $next[0];
2560                     }
2561
2562                     if (! -f $gen) {
2563                         if ($gen ne $orig) {
2564                             $missing++;
2565                             warn "$orig is given as source for $dest, but its generator (leading to $gen) is missing\n";
2566                         } else {
2567                             $missing++;
2568                             warn "$orig is given as source for $dest, but is missing\n";
2569                         }
2570                     }
2571                 }
2572             }
2573         }
2574     }
2575     die "There are files missing\n" if $missing > 0;
2576
2577     # Go through the sources of all libraries and check that the same basename
2578     # doesn't appear more than once.  Some static library archivers depend on
2579     # them being unique.
2580     {
2581         my $err = 0;
2582         foreach my $prod (keys %{$unified_info{libraries}}) {
2583             my @prod_sources =
2584                 map { keys %{$unified_info{sources}->{$_}} }
2585                 keys %{$unified_info{sources}->{$prod}};
2586             my %srccnt = ();
2587
2588             # Count how many times a given each source basename
2589             # appears for each product.
2590             foreach my $src (@prod_sources) {
2591                 $srccnt{basename $src}++;
2592             }
2593
2594             foreach my $src (keys %srccnt) {
2595                 if ((my $cnt = $srccnt{$src}) > 1) {
2596                     print STDERR "$src appears $cnt times for the product $prod\n";
2597                     $err++
2598                 }
2599             }
2600         }
2601         die if $err > 0;
2602     }
2603
2604     # Massage the result
2605
2606     # If we depend on a header file or a perl module, add an inclusion of
2607     # its directory to allow smoothe inclusion
2608     foreach my $dest (keys %{$unified_info{depends}}) {
2609         next if $dest eq "";
2610         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2611             next unless $d =~ /\.(h|pm)$/;
2612             my $i = dirname($d);
2613             my $spot =
2614                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2615                 ? 'build' : 'source';
2616             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2617                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2618         }
2619     }
2620
2621     # Go through all intermediary files and change their names to something that
2622     # reflects what they will be built for.  Note that for some source files,
2623     # this leads to duplicate object files because they are used multiple times.
2624     # the goal is to rename all object files according to this scheme:
2625     #    {productname}-{midfix}-{origobjname}.[o|res]
2626     # the {midfix} is a keyword indicating the type of product, which is mostly
2627     # valuable for libraries since they come in two forms.
2628     #
2629     # This also reorganises the {sources} and {shared_sources} so that the
2630     # former only contains ALL object files that are supposed to end up in
2631     # static libraries and programs, while the latter contains ALL object files
2632     # that are supposed to end up in shared libraries and DSOs.
2633     # The main reason for having two different source structures is to allow
2634     # the same name to be used for the static and the shared variants of a
2635     # library.
2636     {
2637         # Take copies so we don't get interference from added stuff
2638         my %unified_copy = ();
2639         foreach (('sources', 'shared_sources')) {
2640             $unified_copy{$_} = { %{$unified_info{$_}} }
2641                 if defined($unified_info{$_});
2642             delete $unified_info{$_};
2643         }
2644         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2645             # $intent serves multi purposes:
2646             # - give a prefix for the new object files names
2647             # - in the case of libraries, rearrange the object files so static
2648             #   libraries use the 'sources' structure exclusively, while shared
2649             #   libraries use the 'shared_sources' structure exclusively.
2650             my $intent = {
2651                 programs  => { bin    => { src => [ 'sources' ],
2652                                            dst => 'sources' } },
2653                 libraries => { lib    => { src => [ 'sources' ],
2654                                            dst => 'sources' },
2655                                shlib  => { prodselect =>
2656                                                sub { grep !/\.a$/, @_ },
2657                                            src => [ 'sources',
2658                                                     'shared_sources' ],
2659                                            dst => 'shared_sources' } },
2660                 modules   => { dso    => { src => [ 'sources' ],
2661                                            dst => 'sources' } },
2662                 scripts   => { script => { src => [ 'sources' ],
2663                                            dst => 'sources' } }
2664                } -> {$prodtype};
2665             foreach my $kind (keys %$intent) {
2666                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2667                              && $disabled{shared});
2668
2669                 my @src = @{$intent->{$kind}->{src}};
2670                 my $dst = $intent->{$kind}->{dst};
2671                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2672                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2673                     # %prod_sources has all applicable objects as keys, and
2674                     # their corresponding sources as values
2675                     my %prod_sources =
2676                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2677                         map { keys %{$unified_copy{$_}->{$prod}} }
2678                         @src;
2679                     foreach (keys %prod_sources) {
2680                         # Only affect object files and resource files,
2681                         # the others simply get a new value
2682                         # (+1 instead of -1)
2683                         if ($_ =~ /\.(o|res)$/) {
2684                             (my $prodname = $prod) =~ s|\.a$||;
2685                             my $newobj =
2686                                 catfile(dirname($_),
2687                                         basename($prodname)
2688                                             . '-' . $kind
2689                                             . '-' . basename($_));
2690                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2691                             foreach my $src (@{$prod_sources{$_}}) {
2692                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2693                                 # Adjust source attributes
2694                                 my $attrs = $unified_info{attributes}->{sources};
2695                                 if (defined $attrs->{$prod}
2696                                     && defined $attrs->{$prod}->{$_}) {
2697                                     $attrs->{$prod}->{$newobj} =
2698                                         $attrs->{$prod}->{$_};
2699                                     delete $attrs->{$prod}->{$_};
2700                                 }
2701                                 foreach my $objsrc (keys %{$attrs->{$_} // {}}) {
2702                                     $attrs->{$newobj}->{$objsrc} =
2703                                         $attrs->{$_}->{$objsrc};
2704                                     delete $attrs->{$_}->{$objsrc};
2705                                 }
2706                             }
2707                             # Adjust dependencies
2708                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2709                                 $unified_info{depends}->{$_}->{$deps} = -1;
2710                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2711                             }
2712                             # Adjust includes
2713                             foreach my $k (('source', 'build')) {
2714                                 next unless
2715                                     defined($unified_info{includes}->{$_}->{$k});
2716                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2717                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2718                             }
2719                         } else {
2720                             $unified_info{$dst}->{$prod}->{$_} = 1;
2721                         }
2722                     }
2723                 }
2724             }
2725         }
2726     }
2727
2728     # At this point, we have a number of sources with the value -1.  They
2729     # aren't part of the local build and are probably meant for a different
2730     # platform, and can therefore be cleaned away.  That happens when making
2731     # %unified_info more efficient below.
2732
2733     ### Make unified_info a bit more efficient
2734     # One level structures
2735     foreach (("programs", "libraries", "modules", "scripts", "targets")) {
2736         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2737     }
2738     # Two level structures
2739     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends",
2740                      "imagedocs", "htmldocs", "mandocs")) {
2741         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2742             my @items =
2743                 sort
2744                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2745                 keys %{$unified_info{$l1}->{$l2}};
2746             if (@items) {
2747                 $unified_info{$l1}->{$l2} = [ @items ];
2748             } else {
2749                 delete $unified_info{$l1}->{$l2};
2750             }
2751         }
2752     }
2753     # Defines
2754     foreach my $dest (sort keys %{$unified_info{defines}}) {
2755         $unified_info{defines}->{$dest}
2756             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2757                 sort keys %{$unified_info{defines}->{$dest}} ];
2758     }
2759     # Includes
2760     foreach my $dest (sort keys %{$unified_info{includes}}) {
2761         if (defined($unified_info{includes}->{$dest}->{build})) {
2762             my @source_includes = ();
2763             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2764                 if defined($unified_info{includes}->{$dest}->{source});
2765             $unified_info{includes}->{$dest} =
2766                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2767             foreach my $inc (@source_includes) {
2768                 push @{$unified_info{includes}->{$dest}}, $inc
2769                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2770             }
2771         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2772             $unified_info{includes}->{$dest} =
2773                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2774         } else {
2775             delete $unified_info{includes}->{$dest};
2776         }
2777     }
2778
2779     # For convenience collect information regarding directories where
2780     # files are generated, those generated files and the end product
2781     # they end up in where applicable.  Then, add build rules for those
2782     # directories
2783     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2784                      "dso" => [ @{$unified_info{modules}} ],
2785                      "bin" => [ @{$unified_info{programs}} ],
2786                      "script" => [ @{$unified_info{scripts}} ],
2787                      "docs" => [ (map { @{$unified_info{imagedocs}->{$_} // []} }
2788                                   keys %{$unified_info{imagedocs} // {}}),
2789                                  (map { @{$unified_info{htmldocs}->{$_} // []} }
2790                                   keys %{$unified_info{htmldocs} // {}}),
2791                                  (map { @{$unified_info{mandocs}->{$_} // []} }
2792                                   keys %{$unified_info{mandocs} // {}}) ] );
2793     foreach my $type (sort keys %loopinfo) {
2794         foreach my $product (@{$loopinfo{$type}}) {
2795             my %dirs = ();
2796             my $pd = dirname($product);
2797
2798             foreach (@{$unified_info{sources}->{$product} // []},
2799                      @{$unified_info{shared_sources}->{$product} // []}) {
2800                 my $d = dirname($_);
2801
2802                 # We don't want to create targets for source directories
2803                 # when building out of source
2804                 next if ($config{sourcedir} ne $config{builddir}
2805                              && $d =~ m|^\Q$config{sourcedir}\E|);
2806                 # We already have a "test" target, and the current directory
2807                 # is just silly to make a target for
2808                 next if $d eq "test" || $d eq ".";
2809
2810                 $dirs{$d} = 1;
2811                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2812                     if $d ne $pd;
2813             }
2814             foreach (sort keys %dirs) {
2815                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2816                     $product;
2817             }
2818         }
2819     }
2820 }
2821
2822 # For the schemes that need it, we provide the old *_obj configs
2823 # from the *_asm_obj ones
2824 foreach (grep /_(asm|aux)_src$/, keys %target) {
2825     my $src = $_;
2826     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2827     $target{$obj} = $target{$src};
2828     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2829     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2830 }
2831
2832 # Write down our configuration where it fits #########################
2833
2834 my %template_vars = (
2835     config => \%config,
2836     target => \%target,
2837     disablables => \@disablables,
2838     disablables_int => \@disablables_int,
2839     disabled => \%disabled,
2840     withargs => \%withargs,
2841     unified_info => \%unified_info,
2842     tls => \@tls,
2843     dtls => \@dtls,
2844     makevars => [ sort keys %user ],
2845     disabled_info => \%disabled_info,
2846     user_crossable => \@user_crossable,
2847 );
2848 my $configdata_outname = 'configdata.pm';
2849 open CONFIGDATA, ">$configdata_outname.new"
2850     or die "Trying to create $configdata_outname.new: $!";
2851 my $configdata_tmplname = cleanfile($srcdir, "configdata.pm.in", $blddir);
2852 my $configdata_tmpl =
2853     OpenSSL::Template->new(TYPE => 'FILE', SOURCE => $configdata_tmplname);
2854 $configdata_tmpl->fill_in(
2855     FILENAME => $configdata_tmplname,
2856     OUTPUT => \*CONFIGDATA,
2857     HASH => { %template_vars,
2858               autowarntext => [
2859                   'WARNING: do not edit!',
2860                   "Generated by Configure from $configdata_tmplname",
2861               ] }
2862 ) or die $Text::Template::ERROR;
2863 close CONFIGDATA;
2864
2865 rename "$configdata_outname.new", $configdata_outname;
2866 if ($builder_platform eq 'unix') {
2867     my $mode = (0755 & ~umask);
2868     chmod $mode, 'configdata.pm'
2869         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2870 }
2871 print "Created $configdata_outname\n";
2872
2873 print "Running $configdata_outname\n";
2874 my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
2875 my $cmd = "$perlcmd $configdata_outname";
2876 #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2877 system($cmd);
2878 exit 1 if $? != 0;
2879
2880 $SIG{__DIE__} = $orig_death_handler;
2881
2882 print <<"EOF" if ($disabled{threads} eq "unavailable");
2883
2884 The library could not be configured for supporting multi-threaded
2885 applications as the compiler options required on this system are not known.
2886 See file INSTALL.md for details if you need multi-threading.
2887 EOF
2888
2889 print <<"EOF" if ($no_shared_warn);
2890
2891 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2892 platform, so we will pretend you gave the option 'no-pic', which also disables
2893 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2894 or position independent code, please let us know (but please first make sure
2895 you have tried with a current version of OpenSSL).
2896 EOF
2897
2898 print $banner;
2899
2900 exit(0);
2901
2902 ######################################################################
2903 #
2904 # Helpers and utility functions
2905 #
2906
2907 # Death handler, to print a helpful message in case of failure #######
2908 #
2909 sub death_handler {
2910     die @_ if $^S;              # To prevent the added message in eval blocks
2911     my $build_file = $target{build_file} // "build file";
2912     my @message = ( <<"_____", @_ );
2913
2914 Failure!  $build_file wasn't produced.
2915 Please read INSTALL.md and associated NOTES-* files.  You may also have to
2916 look over your available compiler tool chain or change your configuration.
2917
2918 _____
2919
2920     # Dying is terminal, so it's ok to reset the signal handler here.
2921     $SIG{__DIE__} = $orig_death_handler;
2922     die @message;
2923 }
2924
2925 # Configuration file reading #########################################
2926
2927 # Note: All of the helper functions are for lazy evaluation.  They all
2928 # return a CODE ref, which will return the intended value when evaluated.
2929 # Thus, whenever there's mention of a returned value, it's about that
2930 # intended value.
2931
2932 # Helper function to implement conditional value variants, with a default
2933 # plus additional values based on the value of $config{build_type}.
2934 # Arguments are given in hash table form:
2935 #
2936 #       picker(default => "Basic string: ",
2937 #              debug   => "debug",
2938 #              release => "release")
2939 #
2940 # When configuring with --debug, the resulting string will be
2941 # "Basic string: debug", and when not, it will be "Basic string: release"
2942 #
2943 # This can be used to create variants of sets of flags according to the
2944 # build type:
2945 #
2946 #       cflags => picker(default => "-Wall",
2947 #                        debug   => "-g -O0",
2948 #                        release => "-O3")
2949 #
2950 sub picker {
2951     my %opts = @_;
2952     return sub { add($opts{default} || (),
2953                      $opts{$config{build_type}} || ())->(); }
2954 }
2955
2956 # Helper function to combine several values of different types into one.
2957 # This is useful if you want to combine a string with the result of a
2958 # lazy function, such as:
2959 #
2960 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2961 #
2962 sub combine {
2963     my @stuff = @_;
2964     return sub { add(@stuff)->(); }
2965 }
2966
2967 # Helper function to implement conditional values depending on the value
2968 # of $disabled{threads}.  Can be used as follows:
2969 #
2970 #       cflags => combine("-Wall", threads("-pthread"))
2971 #
2972 sub threads {
2973     my @flags = @_;
2974     return sub { add($disabled{threads} ? () : @flags)->(); }
2975 }
2976
2977 sub shared {
2978     my @flags = @_;
2979     return sub { add($disabled{shared} ? () : @flags)->(); }
2980 }
2981
2982 our $add_called = 0;
2983 # Helper function to implement adding values to already existing configuration
2984 # values.  It handles elements that are ARRAYs, CODEs and scalars
2985 sub _add {
2986     my $separator = shift;
2987
2988     # If there's any ARRAY in the collection of values OR the separator
2989     # is undef, we will return an ARRAY of combined values, otherwise a
2990     # string of joined values with $separator as the separator.
2991     my $found_array = !defined($separator);
2992
2993     my @values =
2994         map {
2995             my $res = $_;
2996             while (ref($res) eq "CODE") {
2997                 $res = $res->();
2998             }
2999             if (defined($res)) {
3000                 if (ref($res) eq "ARRAY") {
3001                     $found_array = 1;
3002                     @$res;
3003                 } else {
3004                     $res;
3005                 }
3006             } else {
3007                 ();
3008             }
3009     } (@_);
3010
3011     $add_called = 1;
3012
3013     if ($found_array) {
3014         [ @values ];
3015     } else {
3016         join($separator, grep { defined($_) && $_ ne "" } @values);
3017     }
3018 }
3019 sub add_before {
3020     my $separator = " ";
3021     if (ref($_[$#_]) eq "HASH") {
3022         my $opts = pop;
3023         $separator = $opts->{separator};
3024     }
3025     my @x = @_;
3026     sub { _add($separator, @x, @_) };
3027 }
3028 sub add {
3029     my $separator = " ";
3030     if (ref($_[$#_]) eq "HASH") {
3031         my $opts = pop;
3032         $separator = $opts->{separator};
3033     }
3034     my @x = @_;
3035     sub { _add($separator, @_, @x) };
3036 }
3037
3038 sub read_eval_file {
3039     my $fname = shift;
3040     my $content;
3041     my @result;
3042
3043     open F, "< $fname" or die "Can't open '$fname': $!\n";
3044     {
3045         undef local $/;
3046         $content = <F>;
3047     }
3048     close F;
3049     {
3050         local $@;
3051
3052         @result = ( eval $content );
3053         warn $@ if $@;
3054     }
3055     return wantarray ? @result : $result[0];
3056 }
3057
3058 # configuration reader, evaluates the input file as a perl script and expects
3059 # it to fill %targets with target configurations.  Those are then added to
3060 # %table.
3061 sub read_config {
3062     my $fname = shift;
3063     my %targets;
3064
3065     {
3066         # Protect certain tables from tampering
3067         local %table = ();
3068
3069         %targets = read_eval_file($fname);
3070     }
3071     my %preexisting = ();
3072     foreach (sort keys %targets) {
3073         $preexisting{$_} = 1 if $table{$_};
3074     }
3075     die <<"EOF",
3076 The following config targets from $fname
3077 shadow pre-existing config targets with the same name:
3078 EOF
3079         map { "  $_\n" } sort keys %preexisting
3080         if %preexisting;
3081
3082
3083     # For each target, check that it's configured with a hash table.
3084     foreach (keys %targets) {
3085         if (ref($targets{$_}) ne "HASH") {
3086             if (ref($targets{$_}) eq "") {
3087                 warn "Deprecated target configuration for $_, ignoring...\n";
3088             } else {
3089                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3090             }
3091             delete $targets{$_};
3092         } else {
3093             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3094         }
3095     }
3096
3097     %table = (%table, %targets);
3098
3099 }
3100
3101 # configuration resolver.  Will only resolve all the lazy evaluation
3102 # codeblocks for the chosen target and all those it inherits from,
3103 # recursively
3104 sub resolve_config {
3105     my $target = shift;
3106     my @breadcrumbs = @_;
3107
3108 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3109
3110     if (grep { $_ eq $target } @breadcrumbs) {
3111         die "inherit_from loop!  target backtrace:\n  "
3112             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3113     }
3114
3115     if (!defined($table{$target})) {
3116         warn "Warning! target $target doesn't exist!\n";
3117         return ();
3118     }
3119     # Recurse through all inheritances.  They will be resolved on the
3120     # fly, so when this operation is done, they will all just be a
3121     # bunch of attributes with string values.
3122     # What we get here, though, are keys with references to lists of
3123     # the combined values of them all.  We will deal with lists after
3124     # this stage is done.
3125     my %combined_inheritance = ();
3126     if ($table{$target}->{inherit_from}) {
3127         my @inherit_from =
3128             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3129         foreach (@inherit_from) {
3130             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3131
3132             # 'template' is a marker that's considered private to
3133             # the config that had it.
3134             delete $inherited_config{template};
3135
3136             foreach (keys %inherited_config) {
3137                 if (!$combined_inheritance{$_}) {
3138                     $combined_inheritance{$_} = [];
3139                 }
3140                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3141             }
3142         }
3143     }
3144
3145     # We won't need inherit_from in this target any more, since we've
3146     # resolved all the inheritances that lead to this
3147     delete $table{$target}->{inherit_from};
3148
3149     # Now is the time to deal with those lists.  Here's the place to
3150     # decide what shall be done with those lists, all based on the
3151     # values of the target we're currently dealing with.
3152     # - If a value is a coderef, it will be executed with the list of
3153     #   inherited values as arguments.
3154     # - If the corresponding key doesn't have a value at all or is the
3155     #   empty string, the inherited value list will be run through the
3156     #   default combiner (below), and the result becomes this target's
3157     #   value.
3158     # - Otherwise, this target's value is assumed to be a string that
3159     #   will simply override the inherited list of values.
3160     my $default_combiner = add();
3161
3162     my %all_keys =
3163         map { $_ => 1 } (keys %combined_inheritance,
3164                          keys %{$table{$target}});
3165
3166     sub process_values {
3167         my $object    = shift;
3168         my $inherited = shift;  # Always a [ list ]
3169         my $target    = shift;
3170         my $entry     = shift;
3171
3172         $add_called = 0;
3173
3174         while(ref($object) eq "CODE") {
3175             $object = $object->(@$inherited);
3176         }
3177         if (!defined($object)) {
3178             return ();
3179         }
3180         elsif (ref($object) eq "ARRAY") {
3181             local $add_called;  # To make sure recursive calls don't affect it
3182             return [ map { process_values($_, $inherited, $target, $entry) }
3183                      @$object ];
3184         } elsif (ref($object) eq "") {
3185             return $object;
3186         } else {
3187             die "cannot handle reference type ",ref($object)
3188                 ," found in target ",$target," -> ",$entry,"\n";
3189         }
3190     }
3191
3192     foreach my $key (sort keys %all_keys) {
3193         my $previous = $combined_inheritance{$key};
3194
3195         # Current target doesn't have a value for the current key?
3196         # Assign it the default combiner, the rest of this loop body
3197         # will handle it just like any other coderef.
3198         if (!exists $table{$target}->{$key}) {
3199             $table{$target}->{$key} = $default_combiner;
3200         }
3201
3202         $table{$target}->{$key} = process_values($table{$target}->{$key},
3203                                                $combined_inheritance{$key},
3204                                                $target, $key);
3205         unless(defined($table{$target}->{$key})) {
3206             delete $table{$target}->{$key};
3207         }
3208 #        if ($extra_checks &&
3209 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$key})) {
3210 #            warn "$key got replaced in $target\n";
3211 #        }
3212     }
3213
3214     # Finally done, return the result.
3215     return %{$table{$target}};
3216 }
3217
3218 sub usage
3219         {
3220         print STDERR $usage;
3221         print STDERR "\npick os/compiler from:\n";
3222         my $j=0;
3223         my $i;
3224         my $k=0;
3225         foreach $i (sort keys %table)
3226                 {
3227                 next if $table{$i}->{template};
3228                 next if $i =~ /^debug/;
3229                 $k += length($i) + 1;
3230                 if ($k > 78)
3231                         {
3232                         print STDERR "\n";
3233                         $k=length($i);
3234                         }
3235                 print STDERR $i . " ";
3236                 }
3237         foreach $i (sort keys %table)
3238                 {
3239                 next if $table{$i}->{template};
3240                 next if $i !~ /^debug/;
3241                 $k += length($i) + 1;
3242                 if ($k > 78)
3243                         {
3244                         print STDERR "\n";
3245                         $k=length($i);
3246                         }
3247                 print STDERR $i . " ";
3248                 }
3249         exit(1);
3250         }
3251
3252 sub compiler_predefined {
3253     state %predefined;
3254     my $cc = shift;
3255
3256     return () if $^O eq 'VMS';
3257
3258     die 'compiler_predefined called without a compiler command'
3259         unless $cc;
3260
3261     if (! $predefined{$cc}) {
3262
3263         $predefined{$cc} = {};
3264
3265         # collect compiler pre-defines from gcc or gcc-alike...
3266         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3267         while (my $l = <PIPE>) {
3268             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3269             $predefined{$cc}->{$1} = $2 // '';
3270         }
3271         close(PIPE);
3272     }
3273
3274     return %{$predefined{$cc}};
3275 }
3276
3277 sub which
3278 {
3279     my ($name)=@_;
3280
3281     if (eval { require IPC::Cmd; 1; }) {
3282         IPC::Cmd->import();
3283         return scalar IPC::Cmd::can_run($name);
3284     } else {
3285         # if there is $directories component in splitpath,
3286         # then it's not something to test with $PATH...
3287         return $name if (File::Spec->splitpath($name))[1];
3288
3289         foreach (File::Spec->path()) {
3290             my $fullpath = catfile($_, "$name$target{exe_extension}");
3291             if (-f $fullpath and -x $fullpath) {
3292                 return $fullpath;
3293             }
3294         }
3295     }
3296 }
3297
3298 sub env
3299 {
3300     my $name = shift;
3301     my %opts = @_;
3302
3303     unless ($opts{cacheonly}) {
3304         # Note that if $ENV{$name} doesn't exist or is undefined,
3305         # $config{perlenv}->{$name} will be created with the value
3306         # undef.  This is intentional.
3307
3308         $config{perlenv}->{$name} = $ENV{$name}
3309             if ! exists $config{perlenv}->{$name};
3310     }
3311     return $config{perlenv}->{$name};
3312 }
3313
3314 # Configuration printer ##############################################
3315
3316 sub print_table_entry
3317 {
3318     local $now_printing = shift;
3319     my %target = resolve_config($now_printing);
3320     my $type = shift;
3321
3322     # Don't print the templates
3323     return if $target{template};
3324
3325     my @sequence = (
3326         "sys_id",
3327         "cpp",
3328         "cppflags",
3329         "defines",
3330         "includes",
3331         "cc",
3332         "cflags",
3333         "ld",
3334         "lflags",
3335         "loutflag",
3336         "ex_libs",
3337         "bn_ops",
3338         "enable",
3339         "disable",
3340         "poly1035_asm_src",
3341         "thread_scheme",
3342         "perlasm_scheme",
3343         "dso_scheme",
3344         "shared_target",
3345         "shared_cflag",
3346         "shared_defines",
3347         "shared_ldflag",
3348         "shared_rcflag",
3349         "shared_extension",
3350         "dso_extension",
3351         "obj_extension",
3352         "exe_extension",
3353         "ranlib",
3354         "ar",
3355         "arflags",
3356         "aroutflag",
3357         "rc",
3358         "rcflags",
3359         "rcoutflag",
3360         "mt",
3361         "mtflags",
3362         "mtinflag",
3363         "mtoutflag",
3364         "multilib",
3365         "build_scheme",
3366         );
3367
3368     if ($type eq "TABLE") {
3369         print "\n";
3370         print "*** $now_printing\n";
3371         foreach (@sequence) {
3372             if (ref($target{$_}) eq "ARRAY") {
3373                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3374             } else {
3375                 printf "\$%-12s = %s\n", $_, $target{$_};
3376             }
3377         }
3378     } elsif ($type eq "HASH") {
3379         my $largest =
3380             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3381         print "    '$now_printing' => {\n";
3382         foreach (@sequence) {
3383             if ($target{$_}) {
3384                 if (ref($target{$_}) eq "ARRAY") {
3385                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3386                 } else {
3387                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3388                 }
3389             }
3390         }
3391         print "    },\n";
3392     }
3393 }
3394
3395 # Utility routines ###################################################
3396
3397 # On VMS, if the given file is a logical name, File::Spec::Functions
3398 # will consider it an absolute path.  There are cases when we want a
3399 # purely syntactic check without checking the environment.
3400 sub isabsolute {
3401     my $file = shift;
3402
3403     # On non-platforms, we just use file_name_is_absolute().
3404     return file_name_is_absolute($file) unless $^O eq "VMS";
3405
3406     # If the file spec includes a device or a directory spec,
3407     # file_name_is_absolute() is perfectly safe.
3408     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3409
3410     # Here, we know the given file spec isn't absolute
3411     return 0;
3412 }
3413
3414 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3415 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3416 # realpath() requires that at least all path components except the last is an
3417 # existing directory.  On VMS, the last component of the directory spec must
3418 # exist.
3419 sub absolutedir {
3420     my $dir = shift;
3421
3422     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3423     # will return the volume name for the device, no matter what.  Also,
3424     # it will return an incorrect directory spec if the argument is a
3425     # directory that doesn't exist.
3426     if ($^O eq "VMS") {
3427         return rel2abs($dir);
3428     }
3429
3430     # We use realpath() on Unix, since no other will properly clean out
3431     # a directory spec.
3432     use Cwd qw/realpath/;
3433
3434     return realpath($dir);
3435 }
3436
3437 # Check if all paths are one and the same, using stat.  They must both exist
3438 # We need this for the cases when File::Spec doesn't detect case insensitivity
3439 # (File::Spec::Unix assumes case sensitivity)
3440 sub samedir {
3441     die "samedir expects two arguments\n" unless scalar @_ == 2;
3442
3443     my @stat0 = stat($_[0]);    # First argument
3444     my @stat1 = stat($_[1]);    # Second argument
3445
3446     die "Couldn't stat $_[0]" unless @stat0;
3447     die "Couldn't stat $_[1]" unless @stat1;
3448
3449     # Compare device number
3450     return 0 unless ($stat0[0] == $stat1[0]);
3451     # Compare "inode".  The perl manual recommends comparing as
3452     # string rather than as number.
3453     return 0 unless ($stat0[1] eq $stat1[1]);
3454
3455     return 1;                   # All the same
3456 }
3457
3458 sub quotify {
3459     my %processors = (
3460         perl    => sub { my $x = shift;
3461                          $x =~ s/([\\\$\@"])/\\$1/g;
3462                          return '"'.$x.'"'; },
3463         maybeshell => sub { my $x = shift;
3464                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3465                             if ($x ne $y || $x =~ m|\s|) {
3466                                 return '"'.$y.'"';
3467                             } else {
3468                                 return $x;
3469                             }
3470                         },
3471         );
3472     my $for = shift;
3473     my $processor =
3474         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3475
3476     return map { $processor->($_); } @_;
3477 }
3478
3479 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3480 # $filename is a file name to read from
3481 # $line_concat_cond_re is a regexp detecting a line continuation ending
3482 # $line_concat is a CODEref that takes care of concatenating two lines
3483 sub collect_from_file {
3484     my $filename = shift;
3485     my $line_concat_cond_re = shift;
3486     my $line_concat = shift;
3487
3488     open my $fh, $filename || die "unable to read $filename: $!\n";
3489     return sub {
3490         my $saved_line = "";
3491         $_ = "";
3492         while (<$fh>) {
3493             s|\R$||;
3494             if (defined $line_concat) {
3495                 $_ = $line_concat->($saved_line, $_);
3496                 $saved_line = "";
3497             }
3498             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3499                 $saved_line = $_;
3500                 next;
3501             }
3502             return $_;
3503         }
3504         die "$filename ending with continuation line\n" if $_;
3505         close $fh;
3506         return undef;
3507     }
3508 }
3509
3510 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3511 # $array is an ARRAYref of lines
3512 # $line_concat_cond_re is a regexp detecting a line continuation ending
3513 # $line_concat is a CODEref that takes care of concatenating two lines
3514 sub collect_from_array {
3515     my $array = shift;
3516     my $line_concat_cond_re = shift;
3517     my $line_concat = shift;
3518     my @array = (@$array);
3519
3520     return sub {
3521         my $saved_line = "";
3522         $_ = "";
3523         while (defined($_ = shift @array)) {
3524             s|\R$||;
3525             if (defined $line_concat) {
3526                 $_ = $line_concat->($saved_line, $_);
3527                 $saved_line = "";
3528             }
3529             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3530                 $saved_line = $_;
3531                 next;
3532             }
3533             return $_;
3534         }
3535         die "input text ending with continuation line\n" if $_;
3536         return undef;
3537     }
3538 }
3539
3540 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3541 # $lineiterator is a CODEref that delivers one line at a time.
3542 # All following arguments are regex/CODEref pairs, where the regexp detects a
3543 # line and the CODEref does something with the result of the regexp.
3544 sub collect_information {
3545     my $lineiterator = shift;
3546     my %collectors = @_;
3547
3548     while(defined($_ = $lineiterator->())) {
3549         s|\R$||;
3550         my $found = 0;
3551         if ($collectors{"BEFORE"}) {
3552             $collectors{"BEFORE"}->($_);
3553         }
3554         foreach my $re (keys %collectors) {
3555             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3556                 $collectors{$re}->($lineiterator);
3557                 $found = 1;
3558             };
3559         }
3560         if ($collectors{"OTHERWISE"}) {
3561             $collectors{"OTHERWISE"}->($lineiterator, $_)
3562                 unless $found || !defined $collectors{"OTHERWISE"};
3563         }
3564         if ($collectors{"AFTER"}) {
3565             $collectors{"AFTER"}->($_);
3566         }
3567     }
3568 }
3569
3570 # tokenize($line)
3571 # tokenize($line,$separator)
3572 # $line is a line of text to split up into tokens
3573 # $separator [optional] is a regular expression that separates the tokens,
3574 # the default being spaces.  Do not use quotes of any kind as separators,
3575 # that will give undefined results.
3576 # Returns a list of tokens.
3577 #
3578 # Tokens are divided by separator (spaces by default).  If the tokens include
3579 # the separators, they have to be quoted with single or double quotes.
3580 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3581 # with backslash.
3582 # Basically, the same quoting rules apply for " and ' as in any
3583 # Unix shell.
3584 sub tokenize {
3585     my $line = my $debug_line = shift;
3586     my $separator = shift // qr|\s+|;
3587     my @result = ();
3588
3589     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3590         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3591     }
3592
3593     while ($line =~ s|^${separator}||, $line ne "") {
3594         my $token = "";
3595     again:
3596         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3597         $token .= $1;
3598         $line = $2.$';
3599
3600         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3601             $token .= $1;
3602             $line = $';
3603             goto again;
3604         } elsif ($line =~ m/^'([^']*)'/) {
3605             $token .= $1;
3606             $line = $';
3607             goto again;
3608         }
3609         push @result, $token;
3610     }
3611
3612     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3613         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3614         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3615     }
3616     return @result;
3617 }