Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2022 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::fallback "$FindBin::Bin/external/perl/MODULES.txt";
  21 use OpenSSL::Glob;
  22 use OpenSSL::Template;
  23 use OpenSSL::config;
  24
  25 # see INSTALL.md for instructions.
  26
  27 my $orig_death_handler = $SIG{__DIE__};
  28 $SIG{__DIE__} = \&death_handler;
  29
  30 my $usage="Usage: Configure [no-<feature> ...] [enable-<feature> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]thread-pool] [[no-]default-thread-pool] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  31
  32 my $banner = <<"EOF";
  33
  34 **********************************************************************
  35 ***                                                                ***
  36 ***   OpenSSL has been successfully configured                     ***
  37 ***                                                                ***
  38 ***   If you encounter a problem while building, please open an    ***
  39 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
  40 ***   and include the output from the following command:           ***
  41 ***                                                                ***
  42 ***       perl configdata.pm --dump                                ***
  43 ***                                                                ***
  44 ***   (If you are new to OpenSSL, you might want to consult the    ***
  45 ***   'Troubleshooting' section in the INSTALL.md file first)      ***
  46 ***                                                                ***
  47 **********************************************************************
  48 EOF
  49
  50 # Options:
  51 #
  52 # --config      add the given configuration file, which will be read after
  53 #               any "Configurations*" files that are found in the same
  54 #               directory as this script.
  55 # --prefix      prefix for the OpenSSL installation, which includes the
  56 #               directories bin, lib, include, share/man, share/doc/openssl
  57 #               This becomes the value of INSTALLTOP in Makefile
  58 #               (Default: /usr/local)
  59 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  60 #               If it's a relative directory, it will be added on the directory
  61 #               given with --prefix.
  62 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  63 #               (Default: PREFIX/ssl)
  64 # --banner=".." Output specified text instead of default completion banner
  65 #
  66 # -w            Don't wait after showing a Configure warning
  67 #
  68 # --cross-compile-prefix Add specified prefix to binutils components.
  69 #
  70 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0
  71 #               Define the public APIs as they were for that version
  72 #               including patch releases.  If 'no-deprecated' is also
  73 #               given, do not compile support for interfaces deprecated
  74 #               up to and including the specified OpenSSL version.
  75 #
  76 # no-hw-xxx     do not compile support for specific crypto hardware.
  77 #               Generic OpenSSL-style methods relating to this support
  78 #               are always compiled but return NULL if the hardware
  79 #               support isn't compiled.
  80 # no-hw         do not compile support for any crypto hardware.
  81 # [no-]threads  [don't] try to create a library that is suitable for
  82 #               multithreaded applications (default is "threads" if we
  83 #               know how to do it)
  84 # [no-]thread-pool
  85 #               [don't] allow thread pool functionality
  86 # [no-]default-thread-pool
  87 #               [don't] allow default thread pool functionality
  88 # [no-]shared   [don't] try to create shared libraries when supported.
  89 # [no-]pic      [don't] try to build position independent code when supported.
  90 #               If disabled, it also disables shared and dynamic-engine.
  91 # no-asm        do not use assembler
  92 # no-egd        do not compile support for the entropy-gathering daemon APIs
  93 # [no-]zlib     [don't] compile support for zlib compression.
  94 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  95 #               library and will be loaded at run-time by the OpenSSL library.
  96 # sctp          include SCTP support
  97 # enable-quic   include QUIC support (currently just for developers as the
  98 #               implementation is by no means complete and usable)
  99 # no-uplink     Don't build support for UPLINK interface.
 100 # enable-weak-ssl-ciphers
 101 #               Enable weak ciphers that are disabled by default.
 102 # 386           generate 80386 code in assembly modules
 103 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
 104 #               mentioned '386' option implies this one
 105 # no-<cipher>   build without specified algorithm (dsa, idea, rc5, ...)
 106 # -<xxx> +<xxx> All options which are unknown to the 'Configure' script are
 107 # /<xxx>        passed through to the compiler. Unix-style options beginning
 108 #               with a '-' or '+' are recognized, as well as Windows-style
 109 #               options beginning with a '/'. If the option contains arguments
 110 #               separated by spaces, then the URL-style notation %20 can be
 111 #               used for the space character in order to avoid having to quote
 112 #               the option. For example, -opt%20arg gets expanded to -opt arg.
 113 #               In fact, any ASCII character can be encoded as %xx using its
 114 #               hexadecimal encoding.
 115 # -static       while -static is also a pass-through compiler option (and
 116 #               as such is limited to environments where it's actually
 117 #               meaningful), it triggers a number configuration options,
 118 #               namely no-pic, no-shared and no-threads. It is
 119 #               argued that the only reason to produce statically linked
 120 #               binaries (and in context it means executables linked with
 121 #               -static flag, and not just executables linked with static
 122 #               libcrypto.a) is to eliminate dependency on specific run-time,
 123 #               a.k.a. libc version. The mentioned config options are meant
 124 #               to achieve just that. Unfortunately on Linux it's impossible
 125 #               to eliminate the dependency completely for openssl executable
 126 #               because of getaddrinfo and gethostbyname calls, which can
 127 #               invoke dynamically loadable library facility anyway to meet
 128 #               the lookup requests. For this reason on Linux statically
 129 #               linked openssl executable has rather debugging value than
 130 #               production quality.
 131 #
 132 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
 133 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
 134 # Following are set automatically by this script
 135 #
 136 # MD5_ASM       use some extra md5 assembler,
 137 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 138 # RMD160_ASM    use some extra ripemd160 assembler,
 139 # SHA256_ASM    sha256_block is implemented in assembler
 140 # SHA512_ASM    sha512_block is implemented in assembler
 141 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 142
 143 # Minimum warning options... any contributions to OpenSSL should at least
 144 # get past these.  Note that we only use these with C compilers, not with
 145 # C++ compilers.
 146
 147 # -DPEDANTIC complements -pedantic and is meant to mask code that
 148 # is not strictly standard-compliant and/or implementation-specific,
 149 # e.g. inline assembly, disregards to alignment requirements, such
 150 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 151 # to be used even in sanitized builds, because sanitizer too is
 152 # supposed to and does take notice of non-standard behaviour. Then
 153 # -pedantic with pre-C9x compiler would also complain about 'long
 154 # long' not being supported. As 64-bit algorithms are common now,
 155 # it grew impossible to resolve this without sizeable additional
 156 # code, so we just tell compiler to be pedantic about everything
 157 # but 'long long' type.
 158
 159 my @gcc_devteam_warn = qw(
 160     -DPEDANTIC -pedantic -Wno-long-long -DUNUSEDRESULT_DEBUG
 161     -Wall
 162     -Wmissing-declarations
 163     -Wextra
 164     -Wno-unused-parameter
 165     -Wno-missing-field-initializers
 166     -Wswitch
 167     -Wsign-compare
 168     -Wshadow
 169     -Wformat
 170     -Wno-type-limits
 171     -Wno-tautological-constant-out-of-range-compare
 172     -Wundef
 173     -Werror
 174     -Wmissing-prototypes
 175     -Wstrict-prototypes
 176 );
 177
 178 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 179 # TODO(openssl-team): fix problems and investigate if (at least) the
 180 # following warnings can also be enabled:
 181 #       -Wcast-align
 182 #       -Wunreachable-code -- no, too ugly/compiler-specific
 183 #       -Wlanguage-extension-token -- no, we use asm()
 184 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 185 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 186 my @clang_devteam_warn = qw(
 187     -Wno-unknown-warning-option
 188     -Wswitch-default
 189     -Wno-parentheses-equality
 190     -Wno-language-extension-token
 191     -Wno-extended-offsetof
 192     -Wconditional-uninitialized
 193     -Wincompatible-pointer-types-discards-qualifiers
 194     -Wmissing-variable-declarations
 195 );
 196
 197 my @cl_devteam_warn = qw(
 198     /WX
 199 );
 200
 201 my $strict_warnings = 0;
 202
 203 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 204 # which would cover all BSD flavors. -pthread applies to them all,
 205 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 206 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 207 # which has to be accompanied by explicit -D_THREAD_SAFE and
 208 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 209 # seems to be sufficient?
 210 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 211
 212 #
 213 # API compatibility name to version number mapping.
 214 #
 215 my $apitable = {
 216     # This table expresses when API additions or changes can occur.
 217     # The numbering used changes from 3.0 and on because we updated
 218     # (solidified) our version numbering scheme at that point.
 219
 220     # From 3.0 and on, we internalise the given version number in decimal
 221     # as MAJOR * 10000 + MINOR * 100 + 0
 222     "3.0.0" => 30000,
 223     "3.0"   => 30000,
 224
 225     # Note that before 3.0, we didn't have the same version number scheme.
 226     # Still, the numbering we use here covers what we need.
 227     "1.1.1" => 10101,
 228     "1.1.0" => 10100,
 229     "1.0.2" => 10002,
 230     "1.0.1" => 10001,
 231     "1.0.0" => 10000,
 232     "0.9.8" =>   908,
 233 };
 234
 235 # For OpenSSL::config::get_platform
 236 my %guess_opts = ();
 237
 238 my $dryrun = 0;
 239
 240 our %table = ();
 241 our %config = ();
 242 our %withargs = ();
 243 our $now_printing;      # set to current entry's name in print_table_entry
 244                         # (todo: right thing would be to encapsulate name
 245                         # into %target [class] and make print_table_entry
 246                         # a method)
 247
 248 # Forward declarations ###############################################
 249
 250 # read_config(filename)
 251 #
 252 # Reads a configuration file and populates %table with the contents
 253 # (which the configuration file places in %targets).
 254 sub read_config;
 255
 256 # resolve_config(target)
 257 #
 258 # Resolves all the late evaluations, inheritances and so on for the
 259 # chosen target and any target it inherits from.
 260 sub resolve_config;
 261
 262
 263 # Information collection #############################################
 264
 265 # Unified build supports separate build dir
 266 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 267 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 268
 269 # File::Spec::Unix doesn't detect case insensitivity, so we make sure to
 270 # check if the source and build directory are really the same, and make
 271 # them so.  This avoids all kinds of confusion later on.
 272 # We must check @File::Spec::ISA rather than using File::Spec->isa() to
 273 # know if File::Spec ended up loading File::Spec::Unix.
 274 $srcdir = $blddir
 275     if (grep(/::Unix$/, @File::Spec::ISA)
 276         && samedir($srcdir, $blddir));
 277
 278 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 279
 280 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 281
 282 $config{sourcedir} = abs2rel($srcdir, $blddir);
 283 $config{builddir} = abs2rel($blddir, $blddir);
 284 # echo -n 'holy hand grenade of antioch' | openssl sha256
 285 $config{FIPSKEY} =
 286     'f4556650ac31d35461610bac4ed81b1a181b2d8a43ea2854cbae22ca74560813';
 287
 288 # Collect reconfiguration information if needed
 289 my @argvcopy=@ARGV;
 290
 291 if (grep /^reconf(igure)?$/, @argvcopy) {
 292     die "reconfiguring with other arguments present isn't supported"
 293         if scalar @argvcopy > 1;
 294     if (-f "./configdata.pm") {
 295         my $file = "./configdata.pm";
 296         unless (my $return = do $file) {
 297             die "couldn't parse $file: $@" if $@;
 298             die "couldn't do $file: $!"    unless defined $return;
 299             die "couldn't run $file"       unless $return;
 300         }
 301
 302         @argvcopy = defined($configdata::config{perlargv}) ?
 303             @{$configdata::config{perlargv}} : ();
 304         die "Incorrect data to reconfigure, please do a normal configuration\n"
 305             if (grep(/^reconf/,@argvcopy));
 306         $config{perlenv} = $configdata::config{perlenv} // {};
 307     } else {
 308         die "Insufficient data to reconfigure, please do a normal configuration\n";
 309     }
 310 }
 311
 312 $config{perlargv} = [ @argvcopy ];
 313
 314 # Historical: if known directories in crypto/ have been removed, it means
 315 # that those sub-systems are disabled.
 316 # (the other option would be to removed them from the SUBDIRS statement in
 317 # crypto/build.info)
 318 # We reverse the input list for cosmetic purely reasons, to compensate that
 319 # 'unshift' adds at the front of the list (i.e. in reverse input order).
 320 foreach ( reverse sort( 'aes', 'aria', 'bf', 'camellia', 'cast', 'des', 'dh',
 321                         'dsa', 'ec', 'hmac', 'idea', 'md2', 'md5', 'mdc2',
 322                         'rc2', 'rc4', 'rc5', 'ripemd', 'seed', 'sha',
 323                         'sm2', 'sm3', 'sm4') ) {
 324     unshift @argvcopy, "no-$_" if ! -d catdir($srcdir, 'crypto', $_);
 325 }
 326
 327 # Collect version numbers
 328 my %version = ();
 329
 330 collect_information(
 331     collect_from_file(catfile($srcdir,'VERSION.dat')),
 332     qr/\s*(\w+)\s*=\s*(.*?)\s*$/ =>
 333         sub {
 334             # Only define it if there is a value at all
 335             if ($2 ne '') {
 336                 my $k = $1;
 337                 my $v = $2;
 338                 # Some values are quoted.  Trim the quotes
 339                 $v = $1 if $v =~ /^"(.*)"$/;
 340                 $version{uc $k} = $v;
 341             }
 342         },
 343     "OTHERWISE" =>
 344         sub { die "Something wrong with this line:\n$_\nin $srcdir/VERSION.dat" },
 345     );
 346
 347 $config{major} = $version{MAJOR} // 'unknown';
 348 $config{minor} = $version{MINOR} // 'unknown';
 349 $config{patch} = $version{PATCH} // 'unknown';
 350 $config{prerelease} =
 351     defined $version{PRE_RELEASE_TAG} ? "-$version{PRE_RELEASE_TAG}" : '';
 352 $config{build_metadata} =
 353     defined $version{BUILD_METADATA} ? "+$version{BUILD_METADATA}" : '';
 354 $config{shlib_version} = $version{SHLIB_VERSION} // 'unknown';
 355 $config{release_date} = $version{RELEASE_DATE} // 'xx XXX xxxx';
 356
 357 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 358 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 359
 360 die "erroneous version information in VERSION.dat: ",
 361     "$config{version}, $config{shlib_version}\n"
 362     unless (defined $version{MAJOR}
 363             && defined $version{MINOR}
 364             && defined $version{PATCH}
 365             && defined $version{SHLIB_VERSION});
 366
 367 # Collect target configurations
 368
 369 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 370 foreach (sort glob($pattern)) {
 371     &read_config($_);
 372 }
 373
 374 if (defined env($local_config_envname)) {
 375     if ($^O eq 'VMS') {
 376         # VMS environment variables are logical names,
 377         # which can be used as is
 378         $pattern = $local_config_envname . ':' . '*.conf';
 379     } else {
 380         $pattern = catfile(env($local_config_envname), '*.conf');
 381     }
 382
 383     foreach (sort glob($pattern)) {
 384         &read_config($_);
 385     }
 386 }
 387
 388 # Save away perl command information
 389 $config{perl_cmd} = $^X;
 390 $config{perl_version} = $Config{version};
 391 $config{perl_archname} = $Config{archname};
 392
 393 $config{prefix}="";
 394 $config{openssldir}="";
 395 $config{processor}="";
 396 $config{libdir}="";
 397 my $auto_threads=1;    # enable threads automatically? true by default
 398 my $default_ranlib;
 399
 400 # Known TLS and DTLS protocols
 401 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 402 my @dtls = qw(dtls1 dtls1_2);
 403
 404 # Explicitly known options that are possible to disable.  They can
 405 # be regexps, and will be used like this: /^no-${option}$/
 406 # For developers: keep it sorted alphabetically
 407
 408 my @disablables = (
 409     "acvp-tests",
 410     "afalgeng",
 411     "argon2",
 412     "aria",
 413     "asan",
 414     "asm",
 415     "async",
 416     "autoalginit",
 417     "autoerrinit",
 418     "autoload-config",
 419     "bf",
 420     "blake2",
 421     "brotli",
 422     "brotli-dynamic",
 423     "buildtest-c++",
 424     "bulk",
 425     "cached-fetch",
 426     "camellia",
 427     "capieng",
 428     "winstore",
 429     "cast",
 430     "chacha",
 431     "cmac",
 432     "cmp",
 433     "cms",
 434     "comp",
 435     "crypto-mdebug",
 436     "ct",
 437     "default-thread-pool",
 438     "deprecated",
 439     "des",
 440     "devcryptoeng",
 441     "dgram",
 442     "dh",
 443     "dsa",
 444     "dso",
 445     "dtls",
 446     "dynamic-engine",
 447     "ec",
 448     "ec2m",
 449     "ec_nistp_64_gcc_128",
 450     "ecdh",
 451     "ecdsa",
 452     "egd",
 453     "engine",
 454     "err",
 455     "external-tests",
 456     "filenames",
 457     "fips",
 458     "fips-securitychecks",
 459     "fuzz-afl",
 460     "fuzz-libfuzzer",
 461     "gost",
 462     "idea",
 463     "ktls",
 464     "legacy",
 465     "loadereng",
 466     "makedepend",
 467     "md2",
 468     "md4",
 469     "mdc2",
 470     "module",
 471     "msan",
 472     "multiblock",
 473     "nextprotoneg",
 474     "ocb",
 475     "ocsp",
 476     "padlockeng",
 477     "pic",
 478     "pinshared",
 479     "poly1305",
 480     "posix-io",
 481     "psk",
 482     "quic",
 483     "rc2",
 484     "rc4",
 485     "rc5",
 486     "rdrand",
 487     "rfc3779",
 488     "rmd160",
 489     "scrypt",
 490     "sctp",
 491     "secure-memory",
 492     "seed",
 493     "shared",
 494     "siphash",
 495     "siv",
 496     "sm2",
 497     "sm3",
 498     "sm4",
 499     "sock",
 500     "srp",
 501     "srtp",
 502     "sse2",
 503     "ssl",
 504     "ssl-trace",
 505     "static-engine",
 506     "stdio",
 507     "tests",
 508     "tfo",
 509     "thread-pool",
 510     "threads",
 511     "tls",
 512     "trace",
 513     "ts",
 514     "ubsan",
 515     "ui-console",
 516     "unit-test",
 517     "uplink",
 518     "weak-ssl-ciphers",
 519     "whirlpool",
 520     "zlib",
 521     "zlib-dynamic",
 522     "zstd",
 523     "zstd-dynamic",
 524     );
 525 foreach my $proto ((@tls, @dtls))
 526         {
 527         push(@disablables, $proto);
 528         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 529         }
 530
 531 # Internal disablables, for aliasing purposes.  They serve no special
 532 # purpose here, but allow scripts to get to know them through configdata.pm,
 533 # where these are merged with @disablables.
 534 # The actual aliasing mechanism is done via %disable_cascades
 535 my @disablables_int = qw(
 536     crmf
 537     );
 538
 539 my %deprecated_disablables = (
 540     "ssl2" => undef,
 541     "buf-freelists" => undef,
 542     "crypto-mdebug-backtrace" => undef,
 543     "hw" => "hw",               # causes cascade, but no macro
 544     "hw-padlock" => "padlockeng",
 545     "ripemd" => "rmd160",
 546     "ui" => "ui-console",
 547     "heartbeats" => undef,
 548     );
 549
 550 # All of the following are disabled by default:
 551
 552 our %disabled = ( # "what"         => "comment"
 553                   "fips"                => "default",
 554                   "asan"                => "default",
 555                   "brotli"              => "default",
 556                   "brotli-dynamic"      => "default",
 557                   "buildtest-c++"       => "default",
 558                   "crypto-mdebug"       => "default",
 559                   "crypto-mdebug-backtrace" => "default",
 560                   "devcryptoeng"        => "default",
 561                   "ec_nistp_64_gcc_128" => "default",
 562                   "egd"                 => "default",
 563                   "external-tests"      => "default",
 564                   "fuzz-afl"            => "default",
 565                   "fuzz-libfuzzer"      => "default",
 566                   "ktls"                => "default",
 567                   "md2"                 => "default",
 568                   "msan"                => "default",
 569                   "quic"                => "default",
 570                   "rc5"                 => "default",
 571                   "sctp"                => "default",
 572                   "ssl3"                => "default",
 573                   "ssl3-method"         => "default",
 574                   "tfo"                 => "default",
 575                   "trace"               => "default",
 576                   "ubsan"               => "default",
 577                   "unit-test"           => "default",
 578                   "weak-ssl-ciphers"    => "default",
 579                   "zlib"                => "default",
 580                   "zlib-dynamic"        => "default",
 581                   "zstd"                => "default",
 582                   "zstd-dynamic"        => "default",
 583                 );
 584
 585 # Note: => pair form used for aesthetics, not to truly make a hash table
 586 my @disable_cascades = (
 587     # "what"            => [ "cascade", ... ]
 588     "bulk"              => [ "shared", "dso",
 589                              "aria", "async", "autoload-config",
 590                              "blake2", "bf", "camellia", "cast", "chacha",
 591                              "cmac", "cms", "cmp", "comp", "ct",
 592                              "des", "dgram", "dh", "dsa",
 593                              "ec", "engine",
 594                              "filenames",
 595                              "idea", "ktls",
 596                              "md4", "multiblock", "nextprotoneg",
 597                              "ocsp", "ocb", "poly1305", "psk",
 598                              "rc2", "rc4", "rmd160",
 599                              "seed", "siphash", "siv",
 600                              "sm3", "sm4", "srp",
 601                              "srtp", "ssl3-method", "ssl-trace",
 602                              "tfo",
 603                              "ts", "ui-console", "whirlpool",
 604                              "fips-securitychecks" ],
 605     sub { $config{processor} eq "386" }
 606                         => [ "sse2" ],
 607     "ssl"               => [ "ssl3" ],
 608     "ssl3-method"       => [ "ssl3" ],
 609     "zlib"              => [ "zlib-dynamic" ],
 610     "brotli"            => [ "brotli-dynamic" ],
 611     "zstd"              => [ "zstd-dynamic" ],
 612     "des"               => [ "mdc2" ],
 613     "ec"                => [ "ec2m", "ecdsa", "ecdh", "sm2", "gost" ],
 614     "dgram"             => [ "dtls", "quic", "sctp" ],
 615     "sock"              => [ "dgram", "tfo" ],
 616     "dtls"              => [ @dtls ],
 617     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 618                         => [ "dtls" ],
 619
 620     "tls"               => [ @tls ],
 621     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 622                         => [ "tls" ],
 623
 624     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 625
 626     # If no modules, then no dynamic engines either
 627     "module"            => [ "dynamic-engine" ],
 628
 629     # Without shared libraries, dynamic engines aren't possible.
 630     # This is due to them having to link with libcrypto and register features
 631     # using the ENGINE functionality, and since that relies on global tables,
 632     # those *have* to be exactly the same as the ones accessed from the app,
 633     # which cannot be guaranteed if shared libraries aren't present.
 634     # (note that even with shared libraries, both the app and dynamic engines
 635     # must be linked with the same library)
 636     "shared"            => [ "dynamic-engine", "uplink" ],
 637     "dso"               => [ "dynamic-engine", "module" ],
 638     # Other modules don't necessarily have to link with libcrypto, so shared
 639     # libraries do not have to be a condition to produce those.
 640
 641     # Without position independent code, there can be no shared libraries
 642     # or modules.
 643     "pic"               => [ "shared", "module" ],
 644
 645     "module"            => [ "fips", "dso" ],
 646
 647     "engine"            => [ "dynamic-engine", grep(/eng$/, @disablables) ],
 648     "dynamic-engine"    => [ "loadereng" ],
 649     "hw"                => [ "padlockeng" ],
 650
 651     # no-autoalginit is only useful when building non-shared
 652     "autoalginit"       => [ "shared", "apps", "fips" ],
 653
 654     "stdio"             => [ "apps", "capieng", "egd" ],
 655     "apps"              => [ "tests" ],
 656     "tests"             => [ "external-tests" ],
 657     "comp"              => [ "zlib", "brotli", "zstd" ],
 658     "sm3"               => [ "sm2" ],
 659     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 660
 661     sub { !$disabled{"msan"} } => [ "asm" ],
 662
 663     "cmac"              => [ "siv" ],
 664     "legacy"            => [ "md2" ],
 665
 666     "cmp"               => [ "crmf" ],
 667
 668     "fips"              => [ "fips-securitychecks", "acvp-tests" ],
 669
 670     "threads"           => [ "thread-pool" ],
 671     "thread-pool"       => [ "default-thread-pool" ],
 672
 673     "blake2"            => [ "argon2" ],
 674
 675     "deprecated-3.0"    => [ "engine", "srp" ]
 676     );
 677
 678 # Avoid protocol support holes.  Also disable all versions below N, if version
 679 # N is disabled while N+1 is enabled.
 680 #
 681 my @list = (reverse @tls);
 682 while ((my $first, my $second) = (shift @list, shift @list)) {
 683     last unless @list;
 684     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 685                               => [ @list ] );
 686     unshift @list, $second;
 687 }
 688 my @list = (reverse @dtls);
 689 while ((my $first, my $second) = (shift @list, shift @list)) {
 690     last unless @list;
 691     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 692                               => [ @list ] );
 693     unshift @list, $second;
 694 }
 695
 696 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 697 # To remove something from %disabled, use "enable-foo".
 698 # For symmetry, "disable-foo" is a synonym for "no-foo".
 699
 700 # For the "make variables" CPPINCLUDES and CPPDEFINES, we support lists with
 701 # platform specific list separators.  Users from those platforms should
 702 # recognise those separators from how you set up the PATH to find executables.
 703 # The default is the Unix like separator, :, but as an exception, we also
 704 # support the space as separator.
 705 my $list_separator_re =
 706     { VMS           => qr/(?<!\^),/,
 707       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 708 # All the "make variables" we support
 709 # Some get pre-populated for the sake of backward compatibility
 710 # (we supported those before the change to "make variable" support.
 711 my %user = (
 712     AR          => env('AR'),
 713     ARFLAGS     => [],
 714     AS          => undef,
 715     ASFLAGS     => [],
 716     CC          => env('CC'),
 717     CFLAGS      => [ env('CFLAGS') || () ],
 718     CXX         => env('CXX'),
 719     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 720     CPP         => undef,
 721     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 722     CPPDEFINES  => [],  # Alternative for -D
 723     CPPINCLUDES => [],  # Alternative for -I
 724     CROSS_COMPILE => env('CROSS_COMPILE'),
 725     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 726     LD          => undef,
 727     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 728     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 729     MT          => undef,
 730     MTFLAGS     => [],
 731     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 732     RANLIB      => env('RANLIB'),
 733     RC          => env('RC') || env('WINDRES'),
 734     RCFLAGS     => [ env('RCFLAGS') || () ],
 735     RM          => undef,
 736    );
 737 # Info about what "make variables" may be prefixed with the cross compiler
 738 # prefix.  This should NEVER mention any such variable with a list for value.
 739 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 740 # The same but for flags given as Configure options.  These are *additional*
 741 # input, as opposed to the VAR=string option that override the corresponding
 742 # config target attributes
 743 my %useradd = (
 744     ASFLAGS     => [],
 745     CPPDEFINES  => [],
 746     CPPINCLUDES => [],
 747     CPPFLAGS    => [],
 748     CFLAGS      => [],
 749     CXXFLAGS    => [],
 750     LDFLAGS     => [],
 751     LDLIBS      => [],
 752     RCFLAGS     => [],
 753    );
 754
 755 my %user_synonyms = (
 756     HASHBANGPERL=> 'PERL',
 757     RC          => 'WINDRES',
 758    );
 759
 760 # Some target attributes have been renamed, this is the translation table
 761 my %target_attr_translate =(
 762     ar          => 'AR',
 763     as          => 'AS',
 764     cc          => 'CC',
 765     cxx         => 'CXX',
 766     cpp         => 'CPP',
 767     hashbangperl => 'HASHBANGPERL',
 768     ld          => 'LD',
 769     mt          => 'MT',
 770     ranlib      => 'RANLIB',
 771     rc          => 'RC',
 772     rm          => 'RM',
 773    );
 774
 775 # Initialisers coming from 'config' scripts
 776 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 777 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 778 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 779 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 780 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 781 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 782 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 783
 784 $config{openssl_api_defines}=[];
 785 $config{openssl_sys_defines}=[];
 786 $config{openssl_feature_defines}=[];
 787 $config{options}="";
 788 $config{build_type} = "release";
 789 my $target="";
 790
 791 my %cmdvars = ();               # Stores FOO='blah' type arguments
 792 my %unsupported_options = ();
 793 my %deprecated_options = ();
 794 # If you change this, update apps/version.c
 795 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 796 my @seed_sources = ();
 797 while (@argvcopy)
 798         {
 799         $_ = shift @argvcopy;
 800
 801         # Support env variable assignments among the options
 802         if (m|^(\w+)=(.+)?$|)
 803                 {
 804                 $cmdvars{$1} = $2;
 805                 # Every time a variable is given as a configuration argument,
 806                 # it acts as a reset if the variable.
 807                 if (exists $user{$1})
 808                         {
 809                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 810                         }
 811                 #if (exists $useradd{$1})
 812                 #       {
 813                 #       $useradd{$1} = [];
 814                 #       }
 815                 next;
 816                 }
 817
 818         # VMS is a case insensitive environment, and depending on settings
 819         # out of our control, we may receive options uppercased.  Let's
 820         # downcase at least the part before any equal sign.
 821         if ($^O eq "VMS")
 822                 {
 823                 s/^([^=]*)/lc($1)/e;
 824                 }
 825
 826         # some people just can't read the instructions, clang people have to...
 827         s/^-no-(?!integrated-as)/no-/;
 828
 829         # rewrite some options in "enable-..." form
 830         s /^-?-?shared$/enable-shared/;
 831         s /^sctp$/enable-sctp/;
 832         s /^threads$/enable-threads/;
 833         s /^zlib$/enable-zlib/;
 834         s /^zlib-dynamic$/enable-zlib-dynamic/;
 835         s /^fips$/enable-fips/;
 836
 837         if (/^(no|disable|enable)-(.+)$/)
 838                 {
 839                 my $word = $2;
 840                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 841                         && !exists $deprecated_disablables{$word}
 842                         && !grep { $word eq $_ } @disablables)
 843                         {
 844                         $unsupported_options{$_} = 1;
 845                         next;
 846                         }
 847                 }
 848         if (/^no-(.+)$/ || /^disable-(.+)$/)
 849                 {
 850                 foreach my $proto ((@tls, @dtls))
 851                         {
 852                         if ($1 eq "$proto-method")
 853                                 {
 854                                 $disabled{"$proto"} = "option($proto-method)";
 855                                 last;
 856                                 }
 857                         }
 858                 if ($1 eq "dtls")
 859                         {
 860                         foreach my $proto (@dtls)
 861                                 {
 862                                 $disabled{$proto} = "option(dtls)";
 863                                 }
 864                         $disabled{"dtls"} = "option(dtls)";
 865                         }
 866                 elsif ($1 eq "ssl")
 867                         {
 868                         # Last one of its kind
 869                         $disabled{"ssl3"} = "option(ssl)";
 870                         }
 871                 elsif ($1 eq "tls")
 872                         {
 873                         # XXX: Tests will fail if all SSL/TLS
 874                         # protocols are disabled.
 875                         foreach my $proto (@tls)
 876                                 {
 877                                 $disabled{$proto} = "option(tls)";
 878                                 }
 879                         }
 880                 elsif ($1 eq "static-engine")
 881                         {
 882                         delete $disabled{"dynamic-engine"};
 883                         }
 884                 elsif ($1 eq "dynamic-engine")
 885                         {
 886                         $disabled{"dynamic-engine"} = "option";
 887                         }
 888                 elsif (exists $deprecated_disablables{$1})
 889                         {
 890                         $deprecated_options{$_} = 1;
 891                         if (defined $deprecated_disablables{$1})
 892                                 {
 893                                 $disabled{$deprecated_disablables{$1}} = "option";
 894                                 }
 895                         }
 896                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 897                         {
 898                         $deprecated_options{$_} = 1;
 899                         }
 900                 else
 901                         {
 902                         $disabled{$1} = "option";
 903                         }
 904                 # No longer an automatic choice
 905                 $auto_threads = 0 if ($1 eq "threads");
 906                 }
 907         elsif (/^enable-(.+)$/)
 908                 {
 909                 if ($1 eq "static-engine")
 910                         {
 911                         $disabled{"dynamic-engine"} = "option";
 912                         }
 913                 elsif ($1 eq "dynamic-engine")
 914                         {
 915                         delete $disabled{"dynamic-engine"};
 916                         }
 917                 elsif ($1 eq "zlib-dynamic")
 918                         {
 919                         delete $disabled{"zlib"};
 920                         }
 921                 elsif ($1 eq "brotli-dynamic")
 922                         {
 923                         delete $disabled{"brotli"};
 924                         }
 925                 elsif ($1 eq "zstd-dynamic")
 926                         {
 927                         delete $disabled{"zstd"};
 928                         }
 929                 my $algo = $1;
 930                 delete $disabled{$algo};
 931
 932                 # No longer an automatic choice
 933                 $auto_threads = 0 if ($1 eq "threads");
 934                 }
 935         elsif (/^-d$/)          # From older 'config'
 936                 {
 937                 $config{build_type} = "debug";
 938                 }
 939         elsif (/^-v$/)          # From older 'config'
 940                 {
 941                 $guess_opts{verbose} = 1;
 942                 }
 943         elsif (/^-w$/)
 944                 {
 945                 $guess_opts{nowait} = 1;
 946                 }
 947         elsif (/^-t$/)          # From older 'config'
 948                 {
 949                 $dryrun = 1;
 950                 }
 951         elsif (/^--strict-warnings$/)
 952                 {
 953                 # Pretend that our strict flags is a C flag, and replace it
 954                 # with the proper flags later on
 955                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 956                 $strict_warnings=1;
 957                 }
 958         elsif (/^--debug$/)
 959                 {
 960                 $config{build_type} = "debug";
 961                 }
 962         elsif (/^--release$/)
 963                 {
 964                 $config{build_type} = "release";
 965                 }
 966         elsif (/^386$/)
 967                 { $config{processor}=386; }
 968         elsif (/^rsaref$/)
 969                 {
 970                 # No RSAref support any more since it's not needed.
 971                 # The check for the option is there so scripts aren't
 972                 # broken
 973                 }
 974         elsif (m|^[-+/]|)
 975                 {
 976                 if (/^--prefix=(.*)$/)
 977                         {
 978                         $config{prefix}=$1;
 979                         die "Directory given with --prefix MUST be absolute\n"
 980                                 unless file_name_is_absolute($config{prefix});
 981                         }
 982                 elsif (/^--api=(.*)$/)
 983                         {
 984                         my $api = $1;
 985                         die "Unknown API compatibility level $api"
 986                                 unless defined $apitable->{$api};
 987                         $config{api}=$apitable->{$api};
 988                         }
 989                 elsif (/^--libdir=(.*)$/)
 990                         {
 991                         $config{libdir}=$1;
 992                         }
 993                 elsif (/^--openssldir=(.*)$/)
 994                         {
 995                         $config{openssldir}=$1;
 996                         }
 997                 elsif (/^--with-zlib-lib=(.*)$/)
 998                         {
 999                         $withargs{zlib_lib}=$1;
1000                         }
1001                 elsif (/^--with-zlib-include=(.*)$/)
1002                         {
1003                         $withargs{zlib_include}=$1;
1004                         }
1005                 elsif (/^--with-brotli-lib=(.*)$/)
1006                         {
1007                         $withargs{brotli_lib}=$1;
1008                         }
1009                 elsif (/^--with-brotli-include=(.*)$/)
1010                         {
1011                         $withargs{brotli_include}=$1;
1012                         }
1013                 elsif (/^--with-zstd-lib=(.*)$/)
1014                         {
1015                         $withargs{zstd_lib}=$1;
1016                         }
1017                 elsif (/^--with-zstd-include=(.*)$/)
1018                         {
1019                         $withargs{zstd_include}=$1;
1020                         }
1021                 elsif (/^--with-fuzzer-lib=(.*)$/)
1022                         {
1023                         $withargs{fuzzer_lib}=$1;
1024                         }
1025                 elsif (/^--with-fuzzer-include=(.*)$/)
1026                         {
1027                         $withargs{fuzzer_include}=$1;
1028                         }
1029                 elsif (/^--with-rand-seed=(.*)$/)
1030                         {
1031                         foreach my $x (split(m|,|, $1))
1032                             {
1033                             die "Unknown --with-rand-seed choice $x\n"
1034                                 if ! grep { $x eq $_ } @known_seed_sources;
1035                             push @seed_sources, $x;
1036                             }
1037                         }
1038                 elsif (/^--fips-key=(.*)$/)
1039                         {
1040                         $user{FIPSKEY}=lc($1);
1041                         die "Non-hex character in FIPS key\n"
1042                            if $user{FIPSKEY} =~ /[^a-f0-9]/;
1043                         die "FIPS key must have even number of characters\n"
1044                            if length $1 & 1;
1045                         die "FIPS key too long (64 bytes max)\n"
1046                            if length $1 > 64;
1047                         }
1048                 elsif (/^--banner=(.*)$/)
1049                         {
1050                         $banner = $1 . "\n";
1051                         }
1052                 elsif (/^--cross-compile-prefix=(.*)$/)
1053                         {
1054                         $user{CROSS_COMPILE}=$1;
1055                         }
1056                 elsif (/^--config=(.*)$/)
1057                         {
1058                         read_config $1;
1059                         }
1060                 elsif (/^-l(.*)$/)
1061                         {
1062                         push @{$useradd{LDLIBS}}, $_;
1063                         }
1064                 elsif (/^-framework$/)
1065                         {
1066                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
1067                         }
1068                 elsif (/^-L(.*)$/ or /^-Wl,/)
1069                         {
1070                         push @{$useradd{LDFLAGS}}, $_;
1071                         }
1072                 elsif (/^-rpath$/ or /^-R$/)
1073                         # -rpath is the OSF1 rpath flag
1074                         # -R is the old Solaris rpath flag
1075                         {
1076                         my $rpath = shift(@argvcopy) || "";
1077                         $rpath .= " " if $rpath ne "";
1078                         push @{$useradd{LDFLAGS}}, $_, $rpath;
1079                         }
1080                 elsif (/^-static$/)
1081                         {
1082                         push @{$useradd{LDFLAGS}}, $_;
1083                         }
1084                 elsif (m|^[-/]D(.*)$|)
1085                         {
1086                         push @{$useradd{CPPDEFINES}}, $1;
1087                         }
1088                 elsif (m|^[-/]I(.*)$|)
1089                         {
1090                         push @{$useradd{CPPINCLUDES}}, $1;
1091                         }
1092                 elsif (/^-Wp,$/)
1093                         {
1094                         push @{$useradd{CPPFLAGS}}, $1;
1095                         }
1096                 else    # common if (/^[-+]/), just pass down...
1097                         {
1098                         # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
1099                         # This provides a simple way to pass options with arguments separated
1100                         # by spaces without quoting (e.g. -opt%20arg translates to -opt arg).
1101                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
1102                         push @{$useradd{CFLAGS}}, $_;
1103                         push @{$useradd{CXXFLAGS}}, $_;
1104                         }
1105                 }
1106         elsif (m|^/|)
1107                 {
1108                 # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
1109                 # This provides a simple way to pass options with arguments separated
1110                 # by spaces without quoting (e.g. /opt%20arg translates to /opt arg).
1111                 $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
1112                 push @{$useradd{CFLAGS}}, $_;
1113                 push @{$useradd{CXXFLAGS}}, $_;
1114                 }
1115         else
1116                 {
1117                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
1118                 $target=$_;
1119                 }
1120         unless ($_ eq $target || /^no-/ || /^disable-/)
1121                 {
1122                 # "no-..." follows later after implied deactivations
1123                 # have been derived.  (Don't take this too seriously,
1124                 # we really only write OPTIONS to the Makefile out of
1125                 # nostalgia.)
1126
1127                 if ($config{options} eq "")
1128                         { $config{options} = $_; }
1129                 else
1130                         { $config{options} .= " ".$_; }
1131                 }
1132         }
1133
1134 if (keys %deprecated_options)
1135         {
1136         warn "***** Deprecated options: ",
1137                 join(", ", keys %deprecated_options), "\n";
1138         }
1139 if (keys %unsupported_options)
1140         {
1141         die "***** Unsupported options: ",
1142                 join(", ", keys %unsupported_options), "\n";
1143         }
1144
1145 # If any %useradd entry has been set, we must check that the "make
1146 # variables" haven't been set.  We start by checking of any %useradd entry
1147 # is set.
1148 if (grep { scalar @$_ > 0 } values %useradd) {
1149     # Hash of env / make variables names.  The possible values are:
1150     # 1 - "make vars"
1151     # 2 - %useradd entry set
1152     # 3 - both set
1153     my %detected_vars =
1154         map { my $v = 0;
1155               $v += 1 if $cmdvars{$_};
1156               $v += 2 if @{$useradd{$_}};
1157               $_ => $v }
1158         keys %useradd;
1159
1160     # If any of the corresponding "make variables" is set, we error
1161     if (grep { $_ & 1 } values %detected_vars) {
1162         my $names = join(', ', grep { $detected_vars{$_} > 0 }
1163                                sort keys %detected_vars);
1164         die <<"_____";
1165 ***** Mixing make variables and additional compiler/linker flags as
1166 ***** configure command line option is not permitted.
1167 ***** Affected make variables: $names
1168 _____
1169     }
1170 }
1171
1172 # Check through all supported command line variables to see if any of them
1173 # were set, and canonicalise the values we got.  If no compiler or linker
1174 # flag or anything else that affects %useradd was set, we also check the
1175 # environment for values.
1176 my $anyuseradd =
1177     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
1178 foreach (keys %user) {
1179     my $value = $cmdvars{$_};
1180     $value //= env($_) unless $anyuseradd;
1181     $value //=
1182         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
1183     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
1184         unless $anyuseradd;
1185
1186     if (defined $value) {
1187         if (ref $user{$_} eq 'ARRAY') {
1188             if ($_ eq 'CPPDEFINES' || $_ eq 'CPPINCLUDES') {
1189                 $user{$_} = [ split /$list_separator_re/, $value ];
1190             } else {
1191                 $user{$_} = [ $value ];
1192             }
1193         } elsif (!defined $user{$_}) {
1194             $user{$_} = $value;
1195         }
1196     }
1197 }
1198
1199 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1200     && !$disabled{shared}
1201     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1202     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1203         "***** any of asan, msan or ubsan\n";
1204 }
1205
1206 # If no target was given, try guessing.
1207 unless ($target) {
1208     my %system_config = OpenSSL::config::get_platform(%guess_opts, %user);
1209
1210     # The $system_config{disable} is used to populate %disabled with
1211     # entries that aren't already there.
1212     foreach ( @{$system_config{disable} // []} ) {
1213         $disabled{$_} = 'system' unless defined $disabled{$_};
1214     }
1215     delete $system_config{disable};
1216
1217     # Override config entries with stuff from the guesser.
1218     # It's assumed that this really is nothing new.
1219     %config = ( %config, %system_config );
1220     $target = $system_config{target};
1221 }
1222
1223 sub disable {
1224     my $disable_type = shift;
1225
1226     for (@_) {
1227         $disabled{$_} = $disable_type;
1228     }
1229
1230     my @tocheckfor = (@_ ? @_ : keys %disabled);
1231     while (@tocheckfor) {
1232         my %new_tocheckfor = ();
1233         my @cascade_copy = (@disable_cascades);
1234         while (@cascade_copy) {
1235             my ($test, $descendents) =
1236                 (shift @cascade_copy, shift @cascade_copy);
1237             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1238                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1239                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1240                 }
1241             }
1242         }
1243         @tocheckfor = (keys %new_tocheckfor);
1244     }
1245 }
1246 disable();                     # First cascade run
1247
1248 our $die = sub { die @_; };
1249 if ($target eq "TABLE") {
1250     local $die = sub { warn @_; };
1251     foreach (sort keys %table) {
1252         print_table_entry($_, "TABLE");
1253     }
1254     exit 0;
1255 }
1256
1257 if ($target eq "LIST") {
1258     foreach (sort keys %table) {
1259         print $_,"\n" unless $table{$_}->{template};
1260     }
1261     exit 0;
1262 }
1263
1264 if ($target eq "HASH") {
1265     local $die = sub { warn @_; };
1266     print "%table = (\n";
1267     foreach (sort keys %table) {
1268         print_table_entry($_, "HASH");
1269     }
1270     exit 0;
1271 }
1272
1273 print "Configuring OpenSSL version $config{full_version} ";
1274 print "for target $target\n";
1275
1276 if (scalar(@seed_sources) == 0) {
1277     print "Using os-specific seed configuration\n";
1278     push @seed_sources, 'os';
1279 }
1280 if (scalar(grep { $_ eq 'egd' } @seed_sources) > 0) {
1281     delete $disabled{'egd'};
1282 }
1283 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1284     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1285     warn <<_____ if scalar(@seed_sources) == 1;
1286
1287 ============================== WARNING ===============================
1288 You have selected the --with-rand-seed=none option, which effectively
1289 disables automatic reseeding of the OpenSSL random generator.
1290 All operations depending on the random generator such as creating keys
1291 will not work unless the random generator is seeded manually by the
1292 application.
1293
1294 Please read the 'Note on random number generation' section in the
1295 INSTALL.md instructions and the RAND_DRBG(7) manual page for more
1296 details.
1297 ============================== WARNING ===============================
1298
1299 _____
1300 }
1301 push @{$config{openssl_feature_defines}},
1302      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1303         @seed_sources;
1304
1305 # Backward compatibility?
1306 if ($target =~ m/^CygWin32(-.*)$/) {
1307     $target = "Cygwin".$1;
1308 }
1309
1310 # Support for legacy targets having a name starting with 'debug-'
1311 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1312 if ($d) {
1313     $config{build_type} = "debug";
1314
1315     # If we do not find debug-foo in the table, the target is set to foo.
1316     if (!$table{$target}) {
1317         $target = $t;
1318     }
1319 }
1320
1321 if ($target) {
1322     # It's possible that we have different config targets for specific
1323     # toolchains, so we try to detect them, and go for the plain config
1324     # target if not.
1325     my $found;
1326     foreach ( ( "$target-$user{CC}", "$target", undef ) ) {
1327         $found=$_ if $table{$_} && !$table{$_}->{template};
1328         last if $found;
1329     }
1330     $target = $found;
1331 } else {
1332     # If we don't have a config target now, we try the C compiler as we
1333     # fallback
1334     my $cc = $user{CC} // 'cc';
1335     $target = $cc if $table{$cc} && !$table{$cc}->{template};
1336 }
1337
1338 &usage unless $target;
1339
1340 exit 0 if $dryrun;              # From older 'config'
1341
1342 $config{target} = $target;
1343 my %target = resolve_config($target);
1344
1345 foreach (keys %target_attr_translate) {
1346     $target{$target_attr_translate{$_}} = $target{$_}
1347         if $target{$_};
1348     delete $target{$_};
1349 }
1350
1351 %target = ( %{$table{DEFAULTS}}, %target );
1352
1353 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1354 $config{conf_files} = [ sort keys %conf_files ];
1355
1356 # Using sub disable within these loops may prove fragile, so we run
1357 # a cascade afterwards
1358 foreach my $feature (@{$target{disable}}) {
1359     if (exists $deprecated_disablables{$feature}) {
1360         warn "***** config $target disables deprecated feature $feature\n";
1361     } elsif (!grep { $feature eq $_ } @disablables) {
1362         die "***** config $target disables unknown feature $feature\n";
1363     }
1364     $disabled{$feature} = 'config';
1365 }
1366 foreach my $feature (@{$target{enable}}) {
1367     if ("default" eq ($disabled{$feature} // "")) {
1368         if (exists $deprecated_disablables{$feature}) {
1369             warn "***** config $target enables deprecated feature $feature\n";
1370         } elsif (!grep { $feature eq $_ } @disablables) {
1371             die "***** config $target enables unknown feature $feature\n";
1372         }
1373         delete $disabled{$feature};
1374     }
1375 }
1376
1377 # If uplink_arch isn't defined, disable uplink
1378 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1379 # If asm_arch isn't defined, disable asm
1380 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1381
1382 disable();                      # Run a cascade now
1383
1384 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1385 $target{cxxflags}//=$target{cflags} if $target{CXX};
1386 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1387 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1388
1389 # Fill %config with values from %user, and in case those are undefined or
1390 # empty, use values from %target (acting as a default).
1391 foreach (keys %user) {
1392     my $ref_type = ref $user{$_};
1393
1394     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1395     # and a value that's to be coerced into that type.
1396     my $mkvalue = sub {
1397         my $type = shift;
1398         my $value = shift;
1399         my $undef_p = shift;
1400
1401         die "Too many arguments for \$mkvalue" if @_;
1402
1403         while (ref $value eq 'CODE') {
1404             $value = $value->();
1405         }
1406
1407         if ($type eq 'ARRAY') {
1408             return undef unless defined $value;
1409             return undef if ref $value ne 'ARRAY' && !$value;
1410             return undef if ref $value eq 'ARRAY' && !@$value;
1411             return [ $value ] unless ref $value eq 'ARRAY';
1412         }
1413         return undef unless $value;
1414         return $value;
1415     };
1416
1417     $config{$_} =
1418         $mkvalue->($ref_type, $user{$_})
1419         || $mkvalue->($ref_type, $target{$_});
1420     delete $config{$_} unless defined $config{$_};
1421 }
1422
1423 # Finish up %config by appending things the user gave us on the command line
1424 # apart from "make variables"
1425 foreach (keys %useradd) {
1426     # The must all be lists, so we assert that here
1427     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1428         unless ref $useradd{$_} eq 'ARRAY';
1429
1430     if (defined $config{$_}) {
1431         push @{$config{$_}}, @{$useradd{$_}};
1432     } else {
1433         $config{$_} = [ @{$useradd{$_}} ];
1434     }
1435 }
1436 # At this point, we can forget everything about %user and %useradd,
1437 # because it's now all been merged into the corresponding $config entry
1438
1439 if (grep { $_ =~ /(?:^|\s)-static(?:\s|$)/ } @{$config{LDFLAGS}}) {
1440     disable('static', 'pic', 'threads');
1441 }
1442
1443 # Allow overriding the build file name
1444 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1445
1446 # Make sure build_scheme is consistent.
1447 $target{build_scheme} = [ $target{build_scheme} ]
1448     if ref($target{build_scheme}) ne "ARRAY";
1449
1450 my ($builder, $builder_platform, @builder_opts) =
1451     @{$target{build_scheme}};
1452
1453 foreach my $checker (($builder_platform."-".$config{build_file}."-checker.pm",
1454                       $builder_platform."-checker.pm")) {
1455     my $checker_path = catfile($srcdir, "Configurations", $checker);
1456     if (-f $checker_path) {
1457         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1458             ? sub { warn $@; } : sub { die $@; };
1459         if (! do $checker_path) {
1460             if ($@) {
1461                 $fn->($@);
1462             } elsif ($!) {
1463                 $fn->($!);
1464             } else {
1465                 $fn->("The detected tools didn't match the platform\n");
1466             }
1467         }
1468         last;
1469     }
1470 }
1471
1472 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1473
1474 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1475         {
1476         push @{$config{cflags}}, "-mno-cygwin";
1477         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1478         push @{$config{shared_ldflag}}, "-mno-cygwin";
1479         }
1480
1481 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1482         && !grep { $_ =~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1483         # minimally required architecture flags for assembly modules
1484         my $value;
1485         $value = '-mips2' if ($target =~ /mips32/);
1486         $value = '-mips3' if ($target =~ /mips64/);
1487         unshift @{$config{cflags}}, $value;
1488         unshift @{$config{cxxflags}}, $value if $config{CXX};
1489 }
1490
1491 # If threads aren't disabled, check how possible they are
1492 unless ($disabled{threads}) {
1493     if ($auto_threads) {
1494         # Enabled by default, disable it forcibly if unavailable
1495         if ($target{thread_scheme} eq "(unknown)") {
1496             disable("unavailable", 'threads');
1497         }
1498     } else {
1499         # The user chose to enable threads explicitly, let's see
1500         # if there's a chance that's possible
1501         if ($target{thread_scheme} eq "(unknown)") {
1502             # If the user asked for "threads" and we don't have internal
1503             # knowledge how to do it, [s]he is expected to provide any
1504             # system-dependent compiler options that are necessary.  We
1505             # can't truly check that the given options are correct, but
1506             # we expect the user to know what [s]He is doing.
1507             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1508                 die "You asked for multi-threading support, but didn't\n"
1509                     ,"provide any system-specific compiler options\n";
1510             }
1511         }
1512     }
1513 }
1514
1515 # Find out if clang's sanitizers have been enabled with -fsanitize
1516 # flags and ensure that the corresponding %disabled elements area
1517 # removed to reflect that the sanitizers are indeed enabled.
1518 my %detected_sanitizers = ();
1519 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1520     (my $checks = $_) =~ s/^-fsanitize=//;
1521     foreach (split /,/, $checks) {
1522         my $d = { address       => 'asan',
1523                   undefined     => 'ubsan',
1524                   memory        => 'msan' } -> {$_};
1525         next unless defined $d;
1526
1527         $detected_sanitizers{$d} = 1;
1528         if (defined $disabled{$d}) {
1529             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1530                 if $disabled{$d} ne "default";
1531             delete $disabled{$d};
1532         }
1533     }
1534 }
1535
1536 # If threads still aren't disabled, add a C macro to ensure the source
1537 # code knows about it.  Any other flag is taken care of by the configs.
1538 unless($disabled{threads}) {
1539     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1540 }
1541
1542 my $no_shared_warn=0;
1543 if (($target{shared_target} // '') eq "")
1544         {
1545         $no_shared_warn = 1
1546             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1547         disable('no-shared-target', 'pic');
1548         }
1549
1550 if ($disabled{"dynamic-engine"}) {
1551         $config{dynamic_engines} = 0;
1552 } else {
1553         $config{dynamic_engines} = 1;
1554 }
1555
1556 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1557     push @{$config{cflags}}, "-fsanitize=address";
1558 }
1559
1560 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1561     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all", "-DPEDANTIC";
1562 }
1563
1564 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1565   push @{$config{cflags}}, "-fsanitize=memory";
1566 }
1567
1568 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1569         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1570     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1571     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1572 }
1573 #
1574 # Platform fix-ups
1575 #
1576
1577 # This saves the build files from having to check
1578 if ($disabled{pic})
1579         {
1580         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1581                     shared_defines shared_includes shared_ldflag
1582                     module_cflags module_cxxflags module_cppflags
1583                     module_defines module_includes module_lflags))
1584                 {
1585                 delete $config{$_};
1586                 $target{$_} = "";
1587                 }
1588         }
1589 else
1590         {
1591         push @{$config{lib_defines}}, "OPENSSL_PIC";
1592         }
1593
1594 if ($target{sys_id} ne "")
1595         {
1596         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1597         }
1598
1599 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1600 my %predefined_CXX = $config{CXX}
1601     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1602     : ();
1603
1604 unless ($disabled{asm}) {
1605     # big endian systems can use ELFv2 ABI
1606     if ($target eq "linux-ppc64" || $target eq "BSD-ppc64") {
1607         $target{perlasm_scheme} = "linux64v2" if ($predefined_C{_CALL_ELF} == 2);
1608     }
1609 }
1610
1611 # Check for makedepend capabilities.
1612 if (!$disabled{makedepend}) {
1613     # If the attribute makedep_scheme is defined, then we assume that the
1614     # config target and its associated build file are programmed to deal
1615     # with it.
1616     # If makedep_scheme is undefined, we go looking for GCC compatible
1617     # dependency making, and if that's not available, we try to fall back
1618     # on 'makedepend'.
1619     if ($target{makedep_scheme}) {
1620         $config{makedep_scheme} = $target{makedep_scheme};
1621         # If the makedepcmd attribute is defined, copy it.  If not, the
1622         # build files will have to fend for themselves.
1623         $config{makedepcmd} = $target{makedepcmd} if $target{makedepcmd};
1624     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1625              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1626         # We know that GNU C version 3 and up as well as all clang
1627         # versions support dependency generation, but Xcode did not
1628         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1629         $config{makedep_scheme} = 'gcc';
1630     } else {
1631         # In all other cases, we look for 'makedepend', and set the
1632         # makedep_scheme value if we found it.
1633         $config{makedepcmd} = which('makedepend');
1634         $config{makedep_scheme} = 'makedepend' if $config{makedepcmd};
1635     }
1636
1637     # If no depend scheme is set, we disable makedepend
1638     disable('unavailable', 'makedepend') unless $config{makedep_scheme};
1639 }
1640
1641 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1642     # probe for -Wa,--noexecstack option...
1643     if ($predefined_C{__clang__}) {
1644         # clang has builtin assembler, which doesn't recognize --help,
1645         # but it apparently recognizes the option in question on all
1646         # supported platforms even when it's meaningless. In other words
1647         # probe would fail, but probed option always accepted...
1648         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1649     } else {
1650         my $cc = $config{CROSS_COMPILE}.$config{CC};
1651         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1652         while(<PIPE>) {
1653             if (m/--noexecstack/) {
1654                 push @{$config{cflags}}, "-Wa,--noexecstack";
1655                 last;
1656             }
1657         }
1658         close(PIPE);
1659         unlink("null.$$.o");
1660     }
1661 }
1662
1663 # Deal with bn_ops ###################################################
1664
1665 $config{bn_ll}                  =0;
1666 my $def_int="unsigned int";
1667 $config{rc4_int}                =$def_int;
1668 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1669
1670 my $count = 0;
1671 foreach (sort split(/\s+/,$target{bn_ops})) {
1672     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1673     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1674     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1675     ($config{b64l},$config{b64},$config{b32})
1676         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1677     ($config{b64l},$config{b64},$config{b32})
1678         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1679     ($config{b64l},$config{b64},$config{b32})
1680         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1681 }
1682 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1683     if $count > 1;
1684
1685 $config{api} = $config{major} * 10000 + $config{minor} * 100
1686     unless $config{api};
1687 foreach (keys %$apitable) {
1688     $disabled{"deprecated-$_"} = "deprecation"
1689         if $disabled{deprecated} && $config{api} >= $apitable->{$_};
1690 }
1691
1692 disable();                      # Run a cascade now
1693
1694 # Hack cflags for better warnings (dev option) #######################
1695
1696 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1697 # a string and works as well on command lines.
1698 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1699                         @{$config{cflags}} ];
1700 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1701                           @{$config{cxxflags}} ] if $config{CXX};
1702
1703 $config{openssl_api_defines} = [
1704     "OPENSSL_CONFIGURED_API=".$config{api},
1705 ];
1706
1707 my @strict_warnings_collection=();
1708 if ($strict_warnings)
1709         {
1710         my $wopt;
1711         my $gccver = $predefined_C{__GNUC__} // -1;
1712
1713         if ($gccver >= 4)
1714                 {
1715                 push @strict_warnings_collection, @gcc_devteam_warn;
1716                 push @strict_warnings_collection, @clang_devteam_warn
1717                     if (defined($predefined_C{__clang__}));
1718                 }
1719         elsif ($config{target} =~ /^VC-/)
1720                 {
1721                 push @strict_warnings_collection, @cl_devteam_warn;
1722                 }
1723         else
1724                 {
1725                 warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike, or MSVC"
1726                 }
1727         }
1728
1729 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1730                               ? @strict_warnings_collection
1731                               : ( $_ ) }
1732                     @{$config{CFLAGS}} ];
1733
1734 unless ($disabled{afalgeng}) {
1735     $config{afalgeng}="";
1736     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1737         push @{$config{engdirs}}, "afalg";
1738     } else {
1739         disable('not-linux', 'afalgeng');
1740     }
1741 }
1742
1743 unless ($disabled{devcryptoeng}) {
1744     if ($target =~ m/^BSD/) {
1745         my $maxver = 5*100 + 7;
1746         my $sysstr = `uname -s`;
1747         my $verstr = `uname -r`;
1748         $sysstr =~ s|\R$||;
1749         $verstr =~ s|\R$||;
1750         my ($ma, $mi, @rest) = split m|\.|, $verstr;
1751         my $ver = $ma*100 + $mi;
1752         if ($sysstr eq 'OpenBSD' && $ver >= $maxver) {
1753             disable('too-new-kernel', 'devcryptoeng');
1754         }
1755     }
1756 }
1757
1758 unless ($disabled{ktls}) {
1759     $config{ktls}="";
1760     my $cc = $config{CROSS_COMPILE}.$config{CC};
1761     if ($target =~ m/^linux/) {
1762         system("printf '#include <sys/types.h>\n#include <linux/tls.h>' | $cc -E - >/dev/null 2>&1");
1763         if ($? != 0) {
1764             disable('too-old-kernel', 'ktls');
1765         }
1766     } elsif ($target =~ m/^BSD/) {
1767         system("printf '#include <sys/types.h>\n#include <sys/ktls.h>' | $cc -E - >/dev/null 2>&1");
1768         if ($? != 0) {
1769             disable('too-old-freebsd', 'ktls');
1770         }
1771     } else {
1772         disable('not-linux-or-freebsd', 'ktls');
1773     }
1774 }
1775
1776 unless ($disabled{winstore}) {
1777     unless ($target =~ /^(?:Cygwin|mingw|VC-|BC-)/) {
1778         disable('not-windows', 'winstore');
1779     }
1780 }
1781
1782 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1783
1784 # Get the extra flags used when building shared libraries and modules.  We
1785 # do this late because some of them depend on %disabled.
1786
1787 # Make the flags to build DSOs the same as for shared libraries unless they
1788 # are already defined
1789 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1790 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1791 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1792 {
1793     my $shared_info_pl =
1794         catfile(dirname($0), "Configurations", "shared-info.pl");
1795     my %shared_info = read_eval_file($shared_info_pl);
1796     push @{$target{_conf_fname_int}}, $shared_info_pl;
1797     my $si = $target{shared_target};
1798     while (ref $si ne "HASH") {
1799         last if ! defined $si;
1800         if (ref $si eq "CODE") {
1801             $si = $si->();
1802         } else {
1803             $si = $shared_info{$si};
1804         }
1805     }
1806
1807     # Some of the 'shared_target' values don't have any entries in
1808     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1809     # template knows how to handle this.  That is currently the case for
1810     # Windows and VMS.
1811     if (defined $si) {
1812         # Just as above, copy certain shared_* attributes to the corresponding
1813         # module_ attribute unless the latter is already defined
1814         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1815         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1816         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1817         foreach (sort keys %$si) {
1818             $target{$_} = defined $target{$_}
1819                 ? add($si->{$_})->($target{$_})
1820                 : $si->{$_};
1821         }
1822     }
1823 }
1824
1825 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1826
1827 ######################################################################
1828 # Build up information for skipping certain directories depending on disabled
1829 # features, as well as setting up macros for disabled features.
1830
1831 # This is a tentative database of directories to skip.  Some entries may not
1832 # correspond to anything real, but that's ok, they will simply be ignored.
1833 # The actual processing of these entries is done in the build.info lookup
1834 # loop further down.
1835 #
1836 # The key is a Unix formatted path in the source tree, the value is an index
1837 # into %disabled_info, so any existing path gets added to a corresponding
1838 # 'skipped' entry in there with the list of skipped directories.
1839 my %skipdir = ();
1840 my %disabled_info = ();         # For configdata.pm
1841 foreach my $what (sort keys %disabled) {
1842     # There are deprecated disablables that translate to themselves.
1843     # They cause disabling cascades, but should otherwise not register.
1844     next if $deprecated_disablables{$what};
1845     # The generated $disabled{"deprecated-x.y"} entries are special
1846     # and treated properly elsewhere
1847     next if $what =~ m|^deprecated-|;
1848
1849     $config{options} .= " no-$what";
1850
1851     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1852                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1853                                 'sse2', 'legacy' )) {
1854         (my $WHAT = uc $what) =~ s|-|_|g;
1855         my $skipdir = $what;
1856
1857         # fix-up crypto/directory name(s)
1858         $skipdir = "ripemd" if $what eq "rmd160";
1859         $skipdir = "whrlpool" if $what eq "whirlpool";
1860
1861         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1862         push @{$config{openssl_feature_defines}}, $macro;
1863
1864         $skipdir{engines} = $what if $what eq 'engine';
1865         $skipdir{"crypto/$skipdir"} = $what
1866             unless $what eq 'async' || $what eq 'err' || $what eq 'dso';
1867     }
1868 }
1869
1870 if ($disabled{"dynamic-engine"}) {
1871     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1872 } else {
1873     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1874 }
1875
1876 # If we use the unified build, collect information from build.info files
1877 my %unified_info = ();
1878
1879 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1880 if ($builder eq "unified") {
1881     use Text::Template 1.46;
1882
1883     sub cleandir {
1884         my $base = shift;
1885         my $dir = shift;
1886         my $relativeto = shift || ".";
1887
1888         $dir = catdir($base,$dir) unless isabsolute($dir);
1889
1890         # Make sure the directories we're building in exists
1891         mkpath($dir);
1892
1893         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1894         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1895         return $res;
1896     }
1897
1898     sub cleanfile {
1899         my $base = shift;
1900         my $file = shift;
1901         my $relativeto = shift || ".";
1902
1903         $file = catfile($base,$file) unless isabsolute($file);
1904
1905         my $d = dirname($file);
1906         my $f = basename($file);
1907
1908         # Make sure the directories we're building in exists
1909         mkpath($d);
1910
1911         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1912         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1913         return $res;
1914     }
1915
1916     # Store the name of the template file we will build the build file from
1917     # in %config.  This may be useful for the build file itself.
1918     my @build_file_template_names =
1919         ( $builder_platform."-".$config{build_file}.".tmpl",
1920           $config{build_file}.".tmpl" );
1921     my @build_file_templates = ();
1922
1923     # First, look in the user provided directory, if given
1924     if (defined env($local_config_envname)) {
1925         @build_file_templates =
1926             map {
1927                 if ($^O eq 'VMS') {
1928                     # VMS environment variables are logical names,
1929                     # which can be used as is
1930                     $local_config_envname . ':' . $_;
1931                 } else {
1932                     catfile(env($local_config_envname), $_);
1933                 }
1934             }
1935             @build_file_template_names;
1936     }
1937     # Then, look in our standard directory
1938     push @build_file_templates,
1939         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1940           @build_file_template_names );
1941
1942     my $build_file_template;
1943     for $_ (@build_file_templates) {
1944         $build_file_template = $_;
1945         last if -f $build_file_template;
1946
1947         $build_file_template = undef;
1948     }
1949     if (!defined $build_file_template) {
1950         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1951     }
1952     $config{build_file_templates}
1953       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1954                     $blddir),
1955            $build_file_template ];
1956
1957     my @build_dirs = ( [ ] );   # current directory
1958
1959     $config{build_infos} = [ ];
1960
1961     # We want to detect configdata.pm in the source tree, so we
1962     # don't use it if the build tree is different.
1963     my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1964
1965     # Any source file that we recognise is placed in this hash table, with
1966     # the list of its intended destinations as value.  When everything has
1967     # been collected, there's a routine that checks that these source files
1968     # exist, or if they are generated, that the generator exists.
1969     my %check_exist = ();
1970     my %check_generate = ();
1971
1972     my %ordinals = ();
1973     while (@build_dirs) {
1974         my @curd = @{shift @build_dirs};
1975         my $sourced = catdir($srcdir, @curd);
1976         my $buildd = catdir($blddir, @curd);
1977
1978         my $unixdir = join('/', @curd);
1979         if (exists $skipdir{$unixdir}) {
1980             my $what = $skipdir{$unixdir};
1981             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1982             next;
1983         }
1984
1985         mkpath($buildd);
1986
1987         my $f = 'build.info';
1988         # The basic things we're trying to build
1989         my @programs = ();
1990         my @libraries = ();
1991         my @modules = ();
1992         my @scripts = ();
1993
1994         my %sources = ();
1995         my %shared_sources = ();
1996         my %includes = ();
1997         my %defines = ();
1998         my %depends = ();
1999         my %generate = ();
2000         my %imagedocs = ();
2001         my %htmldocs = ();
2002         my %mandocs = ();
2003
2004         # Support for $variablename in build.info files.
2005         # Embedded perl code is the ultimate master, still.  If its output
2006         # contains a dollar sign, it had better be escaped, or it will be
2007         # taken for a variable name prefix.
2008         my %variables = ();
2009         # Variable name syntax
2010         my $variable_name_re = qr/(?P<VARIABLE>[[:alpha:]][[:alnum:]_]*)/;
2011         # Value modifier syntaxes
2012         my $variable_subst_re = qr/\/(?P<RE>(?:\\\/|.)*?)\/(?P<SUBST>.*?)/;
2013         # Variable reference
2014         my $variable_simple_re = qr/(?<!\\)\$${variable_name_re}/;
2015         my $variable_w_mod_re =
2016             qr/(?<!\\)\$\{${variable_name_re}(?P<MOD>(?:\\\/|.)*?)\}/;
2017         # Tie it all together
2018         my $variable_re = qr/${variable_simple_re}|${variable_w_mod_re}/;
2019
2020         my $expand_variables = sub {
2021             my $value = '';
2022             my $value_rest = shift;
2023
2024             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2025                 print STDERR
2026                     "DEBUG[\$expand_variables] Parsed '$value_rest' ...\n"
2027             }
2028
2029             while ($value_rest =~ /${variable_re}/) {
2030                 # We must save important regexp values, because the next
2031                 # regexp clears them
2032                 my $mod = $+{MOD};
2033                 my $variable_value = $variables{$+{VARIABLE}};
2034
2035                 $value_rest = $';
2036                 $value .= $`;
2037
2038                 # Process modifier expressions, if present
2039                 if (defined $mod) {
2040                     if ($mod =~ /^${variable_subst_re}$/) {
2041                         my $re = $+{RE};
2042                         my $subst = $+{SUBST};
2043
2044                         $variable_value =~ s/\Q$re\E/$subst/g;
2045
2046                         if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2047                             print STDERR
2048                                 "DEBUG[\$expand_variables] ... and substituted ",
2049                                 "'$re' with '$subst'\n";
2050                         }
2051                     }
2052                 }
2053
2054                 $value .= $variable_value;
2055             }
2056             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2057                 print STDERR
2058                     "DEBUG[\$expand_variables] ... into: '$value$value_rest'\n";
2059             }
2060             return $value . $value_rest;
2061         };
2062
2063         # Support for attributes in build.info files
2064         my %attributes = ();
2065         my $handle_attributes = sub {
2066             my $attr_str = shift;
2067             my $ref = shift;
2068             my @goals = @_;
2069
2070             return unless defined $attr_str;
2071
2072             my @a = tokenize($attr_str, qr|\s*,\s*|);
2073             foreach my $a (@a) {
2074                 my $ac = 1;
2075                 my $ak = $a;
2076                 my $av = 1;
2077                 if ($a =~ m|^(!)?(.*?)\s* = \s*(.*?)$|x) {
2078                     $ac = ! $1;
2079                     $ak = $2;
2080                     $av = $3;
2081                 }
2082                 foreach my $g (@goals) {
2083                     if ($ac) {
2084                         $$ref->{$g}->{$ak} = $av;
2085                     } else {
2086                         delete $$ref->{$g}->{$ak};
2087                     }
2088                 }
2089             }
2090         };
2091
2092         # Support for pushing values on multiple indexes of a given hash
2093         # array.
2094         my $push_to = sub {
2095             my $valueref = shift;
2096             my $index_str = shift; # May be undef or empty
2097             my $attrref = shift;   # May be undef
2098             my $attr_str = shift;
2099             my @values = @_;
2100
2101             if (defined $index_str) {
2102                 my @indexes = ( '' );
2103                 if ($index_str !~ m|^\s*$|) {
2104                     @indexes = tokenize($index_str);
2105                 }
2106                 foreach (@indexes) {
2107                     push @{$valueref->{$_}}, @values;
2108                     if (defined $attrref) {
2109                         $handle_attributes->($attr_str, \$$attrref->{$_},
2110                                              @values);
2111                     }
2112                 }
2113             } else {
2114                 push @$valueref, @values;
2115                 $handle_attributes->($attr_str, $attrref, @values)
2116                     if defined $attrref;
2117             }
2118         };
2119
2120         if ($buildinfo_debug) {
2121             print STDERR "DEBUG: Reading ",catfile($sourced, $f),"\n";
2122         }
2123         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
2124         my $template =
2125             Text::Template->new(TYPE => 'FILE',
2126                                 SOURCE => catfile($sourced, $f),
2127                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
2128         die "Something went wrong with $sourced/$f: $!\n" unless $template;
2129         my @text =
2130             split /^/m,
2131             $template->fill_in(HASH => { config => \%config,
2132                                          target => \%target,
2133                                          disabled => \%disabled,
2134                                          withargs => \%withargs,
2135                                          builddir => abs2rel($buildd, $blddir),
2136                                          sourcedir => abs2rel($sourced, $blddir),
2137                                          buildtop => abs2rel($blddir, $blddir),
2138                                          sourcetop => abs2rel($srcdir, $blddir) },
2139                                DELIMITERS => [ "{-", "-}" ]);
2140
2141         # The top item of this stack has the following values
2142         # -2 positive already run and we found ELSE (following ELSIF should fail)
2143         # -1 positive already run (skip until ENDIF)
2144         # 0 negatives so far (if we're at a condition, check it)
2145         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
2146         # 2 positive ELSE (following ELSIF should fail)
2147         my @skip = ();
2148
2149         # A few useful generic regexps
2150         my $index_re = qr/\[\s*(?P<INDEX>(?:\\.|.)*?)\s*\]/;
2151         my $cond_re = qr/\[\s*(?P<COND>(?:\\.|.)*?)\s*\]/;
2152         my $attribs_re = qr/(?:\{\s*(?P<ATTRIBS>(?:\\.|.)*?)\s*\})?/;
2153         my $value_re = qr/(?P<VALUE>.*?)/;
2154         collect_information(
2155             collect_from_array([ @text ],
2156                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
2157                                                 $l1 =~ s/\\$//; $l1.$l2 }),
2158             # Info we're looking for
2159             qr/^\s* IF ${cond_re} \s*$/x
2160             => sub {
2161                 if (! @skip || $skip[$#skip] > 0) {
2162                     push @skip, !! $expand_variables->($+{COND});
2163                 } else {
2164                     push @skip, -1;
2165                 }
2166             },
2167             qr/^\s* ELSIF ${cond_re} \s*$/x
2168             => sub { die "ELSIF out of scope" if ! @skip;
2169                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
2170                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
2171                      $skip[$#skip] = !! $expand_variables->($+{COND})
2172                          if $skip[$#skip] == 0; },
2173             qr/^\s* ELSE \s*$/x
2174             => sub { die "ELSE out of scope" if ! @skip;
2175                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
2176                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
2177             qr/^\s* ENDIF \s*$/x
2178             => sub { die "ENDIF out of scope" if ! @skip;
2179                      pop @skip; },
2180             qr/^\s* ${variable_re} \s* = \s* ${value_re} \s* $/x
2181             => sub {
2182                 if (!@skip || $skip[$#skip] > 0) {
2183                     $variables{$+{VARIABLE}} = $expand_variables->($+{VALUE});
2184                 }
2185             },
2186             qr/^\s* SUBDIRS \s* = \s* ${value_re} \s* $/x
2187             => sub {
2188                 if (!@skip || $skip[$#skip] > 0) {
2189                     foreach (tokenize($expand_variables->($+{VALUE}))) {
2190                         push @build_dirs, [ @curd, splitdir($_, 1) ];
2191                     }
2192                 }
2193             },
2194             qr/^\s* PROGRAMS ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2195             => sub { $push_to->(\@programs, undef,
2196                                 \$attributes{programs}, $+{ATTRIBS},
2197                                 tokenize($expand_variables->($+{VALUE})))
2198                          if !@skip || $skip[$#skip] > 0; },
2199             qr/^\s* LIBS ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2200             => sub { $push_to->(\@libraries, undef,
2201                                 \$attributes{libraries}, $+{ATTRIBS},
2202                                 tokenize($expand_variables->($+{VALUE})))
2203                          if !@skip || $skip[$#skip] > 0; },
2204             qr/^\s* MODULES ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2205             => sub { $push_to->(\@modules, undef,
2206                                 \$attributes{modules}, $+{ATTRIBS},
2207                                 tokenize($expand_variables->($+{VALUE})))
2208                          if !@skip || $skip[$#skip] > 0; },
2209             qr/^\s* SCRIPTS ${attribs_re} \s* = \s* ${value_re} \s* $/x
2210             => sub { $push_to->(\@scripts, undef,
2211                                 \$attributes{scripts}, $+{ATTRIBS},
2212                                 tokenize($expand_variables->($+{VALUE})))
2213                          if !@skip || $skip[$#skip] > 0; },
2214             qr/^\s* IMAGEDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2215             => sub { $push_to->(\%imagedocs, $expand_variables->($+{INDEX}),
2216                                 undef, undef,
2217                                 tokenize($expand_variables->($+{VALUE})))
2218                          if !@skip || $skip[$#skip] > 0; },
2219             qr/^\s* HTMLDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2220             => sub { $push_to->(\%htmldocs, $expand_variables->($+{INDEX}),
2221                                 undef, undef,
2222                                 tokenize($expand_variables->($+{VALUE})))
2223                          if !@skip || $skip[$#skip] > 0; },
2224             qr/^\s* MANDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2225             => sub { $push_to->(\%mandocs, $expand_variables->($+{INDEX}),
2226                                 undef, undef,
2227                                 tokenize($expand_variables->($+{VALUE})))
2228                          if !@skip || $skip[$#skip] > 0; },
2229             qr/^\s* SOURCE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2230             => sub { $push_to->(\%sources, $expand_variables->($+{INDEX}),
2231                                 \$attributes{sources}, $+{ATTRIBS},
2232                                 tokenize($expand_variables->($+{VALUE})))
2233                          if !@skip || $skip[$#skip] > 0; },
2234             qr/^\s* SHARED_SOURCE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2235             => sub { $push_to->(\%shared_sources, $expand_variables->($+{INDEX}),
2236                                 \$attributes{sources}, $+{ATTRIBS},
2237                                 tokenize($expand_variables->($+{VALUE})))
2238                          if !@skip || $skip[$#skip] > 0; },
2239             qr/^\s* INCLUDE ${index_re} \s* = \s* ${value_re} \s* $/x
2240             => sub { $push_to->(\%includes, $expand_variables->($+{INDEX}),
2241                                 undef, undef,
2242                                 tokenize($expand_variables->($+{VALUE})))
2243                          if !@skip || $skip[$#skip] > 0; },
2244             qr/^\s* DEFINE ${index_re} \s* = \s* ${value_re} \s* $/x
2245             => sub { $push_to->(\%defines, $expand_variables->($+{INDEX}),
2246                                 undef, undef,
2247                                 tokenize($expand_variables->($+{VALUE})))
2248                          if !@skip || $skip[$#skip] > 0; },
2249             qr/^\s* DEPEND ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2250             => sub { $push_to->(\%depends, $expand_variables->($+{INDEX}),
2251                                 \$attributes{depends}, $+{ATTRIBS},
2252                                 tokenize($expand_variables->($+{VALUE})))
2253                          if !@skip || $skip[$#skip] > 0; },
2254             qr/^\s* GENERATE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2255             => sub { $push_to->(\%generate, $expand_variables->($+{INDEX}),
2256                                 \$attributes{generate}, $+{ATTRIBS},
2257                                 $expand_variables->($+{VALUE}))
2258                          if !@skip || $skip[$#skip] > 0; },
2259             qr/^\s* (?:\#.*)? $/x => sub { },
2260             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
2261             "BEFORE" => sub {
2262                 if ($buildinfo_debug) {
2263                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
2264                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2265                 }
2266             },
2267             "AFTER" => sub {
2268                 if ($buildinfo_debug) {
2269                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2270                 }
2271             },
2272             );
2273         die "runaway IF?" if (@skip);
2274
2275         if (grep { defined $attributes{modules}->{$_}->{engine} } keys %attributes
2276                 and !$config{dynamic_engines}) {
2277             die <<"EOF"
2278 ENGINES can only be used if configured with 'dynamic-engine'.
2279 This is usually a fault in a build.info file.
2280 EOF
2281         }
2282
2283         {
2284             my %infos = ( programs  => [ @programs  ],
2285                           libraries => [ @libraries ],
2286                           modules   => [ @modules   ],
2287                           scripts   => [ @scripts   ] );
2288             foreach my $k (keys %infos) {
2289                 foreach (@{$infos{$k}}) {
2290                     my $item = cleanfile($buildd, $_, $blddir);
2291                     $unified_info{$k}->{$item} = 1;
2292
2293                     # Fix up associated attributes
2294                     $unified_info{attributes}->{$k}->{$item} =
2295                         $attributes{$k}->{$_}
2296                         if defined $attributes{$k}->{$_};
2297                 }
2298             }
2299         }
2300
2301         # Check that we haven't defined any library as both shared and
2302         # explicitly static.  That is forbidden.
2303         my @doubles = ();
2304         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2305             (my $l = $_) =~ s/\.a$//;
2306             push @doubles, $l if defined $unified_info{libraries}->{$l};
2307         }
2308         die "these libraries are both explicitly static and shared:\n  ",
2309             join(" ", @doubles), "\n"
2310             if @doubles;
2311
2312         foreach (keys %sources) {
2313             my $dest = $_;
2314             my $ddest = cleanfile($buildd, $_, $blddir);
2315             foreach (@{$sources{$dest}}) {
2316                 my $s = cleanfile($sourced, $_, $blddir);
2317
2318                 # If it's generated or we simply don't find it in the source
2319                 # tree, we assume it's in the build tree.
2320                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2321                     $s = cleanfile($buildd, $_, $blddir);
2322                 }
2323                 my $o = $_;
2324                 # We recognise C++, C and asm files
2325                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2326                     push @{$check_exist{$s}}, $ddest;
2327                     $o =~ s/\.[csS]$/.o/; # C and assembler
2328                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2329                     $o = cleanfile($buildd, $o, $blddir);
2330                     $unified_info{sources}->{$ddest}->{$o} = -1;
2331                     $unified_info{sources}->{$o}->{$s} = -1;
2332                 } elsif ($s =~ /\.rc$/) {
2333                     # We also recognise resource files
2334                     push @{$check_exist{$s}}, $ddest;
2335                     $o =~ s/\.rc$/.res/; # Resource configuration
2336                     $o = cleanfile($buildd, $o, $blddir);
2337                     $unified_info{sources}->{$ddest}->{$o} = -1;
2338                     $unified_info{sources}->{$o}->{$s} = -1;
2339                 } else {
2340                     push @{$check_exist{$s}}, $ddest;
2341                     $unified_info{sources}->{$ddest}->{$s} = 1;
2342                 }
2343                 # Fix up associated attributes
2344                 if ($o ne $_) {
2345                     $unified_info{attributes}->{sources}->{$ddest}->{$o} =
2346                         $unified_info{attributes}->{sources}->{$o}->{$s} =
2347                         $attributes{sources}->{$dest}->{$_}
2348                         if defined $attributes{sources}->{$dest}->{$_};
2349                 } else {
2350                     $unified_info{attributes}->{sources}->{$ddest}->{$s} =
2351                         $attributes{sources}->{$dest}->{$_}
2352                         if defined $attributes{sources}->{$dest}->{$_};
2353                 }
2354             }
2355         }
2356
2357         foreach (keys %shared_sources) {
2358             my $dest = $_;
2359             my $ddest = cleanfile($buildd, $_, $blddir);
2360             foreach (@{$shared_sources{$dest}}) {
2361                 my $s = cleanfile($sourced, $_, $blddir);
2362
2363                 # If it's generated or we simply don't find it in the source
2364                 # tree, we assume it's in the build tree.
2365                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2366                     $s = cleanfile($buildd, $_, $blddir);
2367                 }
2368
2369                 my $o = $_;
2370                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2371                     # We recognise C++, C and asm files
2372                     push @{$check_exist{$s}}, $ddest;
2373                     $o =~ s/\.[csS]$/.o/; # C and assembler
2374                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2375                     $o = cleanfile($buildd, $o, $blddir);
2376                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2377                     $unified_info{sources}->{$o}->{$s} = -1;
2378                 } elsif ($s =~ /\.rc$/) {
2379                     # We also recognise resource files
2380                     push @{$check_exist{$s}}, $ddest;
2381                     $o =~ s/\.rc$/.res/; # Resource configuration
2382                     $o = cleanfile($buildd, $o, $blddir);
2383                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2384                     $unified_info{sources}->{$o}->{$s} = -1;
2385                 } elsif ($s =~ /\.ld$/) {
2386                     # We also recognise linker scripts (or corresponding)
2387                     # We know they are generated files
2388                     push @{$check_exist{$s}}, $ddest;
2389                     $o = cleanfile($buildd, $_, $blddir);
2390                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
2391                 } else {
2392                     die "unrecognised source file type for shared library: $s\n";
2393                 }
2394                 # Fix up associated attributes
2395                 if ($o ne $_) {
2396                     $unified_info{attributes}->{shared_sources}->{$ddest}->{$o} =
2397                         $unified_info{attributes}->{sources}->{$o}->{$s} =
2398                         $attributes{sources}->{$dest}->{$_}
2399                         if defined $attributes{sources}->{$dest}->{$_};
2400                 } else {
2401                     $unified_info{attributes}->{shared_sources}->{$ddest}->{$o} =
2402                         $attributes{sources}->{$dest}->{$_}
2403                         if defined $attributes{sources}->{$dest}->{$_};
2404                 }
2405             }
2406         }
2407
2408         foreach (keys %generate) {
2409             my $dest = $_;
2410             my $ddest = cleanfile($buildd, $_, $blddir);
2411             die "more than one generator for $dest: "
2412                 ,join(" ", @{$generate{$_}}),"\n"
2413                 if scalar @{$generate{$_}} > 1;
2414             my @generator = split /\s+/, $generate{$dest}->[0];
2415             my $gen = $generator[0];
2416             $generator[0] = cleanfile($sourced, $gen, $blddir);
2417
2418             # If the generator is itself generated, it's in the build tree
2419             if ($generate{$gen} || ! -f $generator[0]) {
2420                 $generator[0] = cleanfile($buildd, $gen, $blddir);
2421             }
2422             $check_generate{$ddest}->{$generator[0]}++;
2423
2424             $unified_info{generate}->{$ddest} = [ @generator ];
2425             # Fix up associated attributes
2426             $unified_info{attributes}->{generate}->{$ddest} =
2427                 $attributes{generate}->{$dest}->{$gen}
2428                 if defined $attributes{generate}->{$dest}->{$gen};
2429         }
2430
2431         foreach (keys %depends) {
2432             my $dest = $_;
2433             my $ddest = $dest;
2434
2435             if ($dest =~ /^\|(.*)\|$/) {
2436                 # Collect the raw target
2437                 $unified_info{targets}->{$1} = 1;
2438                 $ddest = $1;
2439             } elsif ($dest eq '') {
2440                 $ddest = '';
2441             } else {
2442                 $ddest = cleanfile($sourced, $_, $blddir);
2443
2444                 # If the destination doesn't exist in source, it can only be
2445                 # a generated file in the build tree.
2446                 if ($ddest eq $src_configdata || ! -f $ddest) {
2447                     $ddest = cleanfile($buildd, $_, $blddir);
2448                 }
2449             }
2450             foreach (@{$depends{$dest}}) {
2451                 my $d = cleanfile($sourced, $_, $blddir);
2452                 my $d2 = cleanfile($buildd, $_, $blddir);
2453
2454                 # If we know it's generated, or assume it is because we can't
2455                 # find it in the source tree, we set file we depend on to be
2456                 # in the build tree rather than the source tree.
2457                 if ($d eq $src_configdata
2458                     || (grep { $d2 eq $_ }
2459                         keys %{$unified_info{generate}})
2460                     || ! -f $d) {
2461                     $d = $d2;
2462                 }
2463                 $unified_info{depends}->{$ddest}->{$d} = 1;
2464
2465                 # Fix up associated attributes
2466                 $unified_info{attributes}->{depends}->{$ddest}->{$d} =
2467                     $attributes{depends}->{$dest}->{$_}
2468                     if defined $attributes{depends}->{$dest}->{$_};
2469             }
2470         }
2471
2472         foreach (keys %includes) {
2473             my $dest = $_;
2474             my $ddest = cleanfile($sourced, $_, $blddir);
2475
2476             # If the destination doesn't exist in source, it can only be
2477             # a generated file in the build tree.
2478             if ($ddest eq $src_configdata || ! -f $ddest) {
2479                 $ddest = cleanfile($buildd, $_, $blddir);
2480             }
2481             foreach (@{$includes{$dest}}) {
2482                 my $is = cleandir($sourced, $_, $blddir);
2483                 my $ib = cleandir($buildd, $_, $blddir);
2484                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2485                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2486                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2487                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2488             }
2489         }
2490
2491         foreach my $dest (keys %defines) {
2492             my $ddest;
2493
2494             if ($dest ne "") {
2495                 $ddest = cleanfile($sourced, $dest, $blddir);
2496
2497                 # If the destination doesn't exist in source, it can only
2498                 # be a generated file in the build tree.
2499                 if (! -f $ddest) {
2500                     $ddest = cleanfile($buildd, $dest, $blddir);
2501                 }
2502             }
2503             foreach my $v (@{$defines{$dest}}) {
2504                 $v =~ m|^([^=]*)(=.*)?$|;
2505                 die "0 length macro name not permitted\n" if $1 eq "";
2506                 if ($dest ne "") {
2507                     die "$1 defined more than once\n"
2508                         if defined $unified_info{defines}->{$ddest}->{$1};
2509                     $unified_info{defines}->{$ddest}->{$1} = $2;
2510                 } else {
2511                     die "$1 defined more than once\n"
2512                         if grep { $v eq $_ } @{$config{defines}};
2513                     push @{$config{defines}}, $v;
2514                 }
2515             }
2516         }
2517
2518         foreach my $section (keys %imagedocs) {
2519             foreach (@{$imagedocs{$section}}) {
2520                 my $imagedocs = cleanfile($buildd, $_, $blddir);
2521                 $unified_info{imagedocs}->{$section}->{$imagedocs} = 1;
2522             }
2523         }
2524
2525         foreach my $section (keys %htmldocs) {
2526             foreach (@{$htmldocs{$section}}) {
2527                 my $htmldocs = cleanfile($buildd, $_, $blddir);
2528                 $unified_info{htmldocs}->{$section}->{$htmldocs} = 1;
2529             }
2530         }
2531
2532         foreach my $section (keys %mandocs) {
2533             foreach (@{$mandocs{$section}}) {
2534                 my $mandocs = cleanfile($buildd, $_, $blddir);
2535                 $unified_info{mandocs}->{$section}->{$mandocs} = 1;
2536             }
2537         }
2538     }
2539
2540     my $ordinals_text = join(', ', sort keys %ordinals);
2541     warn <<"EOF" if $ordinals_text;
2542
2543 WARNING: ORDINALS were specified for $ordinals_text
2544 They are ignored and should be replaced with a combination of GENERATE,
2545 DEPEND and SHARED_SOURCE.
2546 EOF
2547
2548     # Check that each generated file is only generated once
2549     my $ambiguous_generation = 0;
2550     foreach (sort keys %check_generate) {
2551         my @generators = sort keys %{$check_generate{$_}};
2552         my $generators_txt = join(', ', @generators);
2553         if (scalar @generators > 1) {
2554             warn "$_ is GENERATEd by more than one generator ($generators_txt)\n";
2555             $ambiguous_generation++;
2556         }
2557         if ($check_generate{$_}->{$generators[0]} > 1) {
2558             warn "INFO: $_ has more than one GENERATE declaration (same generator)\n"
2559         }
2560     }
2561     die "There are ambiguous source file generations\n"
2562         if $ambiguous_generation > 0;
2563
2564     # All given source files should exist, or if generated, their
2565     # generator should exist.  This loop ensures this is true.
2566     my $missing = 0;
2567     foreach my $orig (sort keys %check_exist) {
2568         foreach my $dest (@{$check_exist{$orig}}) {
2569             if ($orig ne $src_configdata) {
2570                 if ($orig =~ /\.a$/) {
2571                     # Static library names may be used as sources, so we
2572                     # need to detect those and give them special treatment.
2573                     unless (grep { $_ eq $orig }
2574                             keys %{$unified_info{libraries}}) {
2575                         warn "$orig is given as source for $dest, but no such library is built\n";
2576                         $missing++;
2577                     }
2578                 } else {
2579                     # A source may be generated, and its generator may be
2580                     # generated as well.  We therefore loop to dig out the
2581                     # first generator.
2582                     my $gen = $orig;
2583
2584                     while (my @next = keys %{$check_generate{$gen}}) {
2585                         $gen = $next[0];
2586                     }
2587
2588                     if (! -f $gen) {
2589                         if ($gen ne $orig) {
2590                             $missing++;
2591                             warn "$orig is given as source for $dest, but its generator (leading to $gen) is missing\n";
2592                         } else {
2593                             $missing++;
2594                             warn "$orig is given as source for $dest, but is missing\n";
2595                         }
2596                     }
2597                 }
2598             }
2599         }
2600     }
2601     die "There are files missing\n" if $missing > 0;
2602
2603     # Go through the sources of all libraries and check that the same basename
2604     # doesn't appear more than once.  Some static library archivers depend on
2605     # them being unique.
2606     {
2607         my $err = 0;
2608         foreach my $prod (keys %{$unified_info{libraries}}) {
2609             my @prod_sources =
2610                 map { keys %{$unified_info{sources}->{$_}} }
2611                 keys %{$unified_info{sources}->{$prod}};
2612             my %srccnt = ();
2613
2614             # Count how many times a given each source basename
2615             # appears for each product.
2616             foreach my $src (@prod_sources) {
2617                 $srccnt{basename $src}++;
2618             }
2619
2620             foreach my $src (keys %srccnt) {
2621                 if ((my $cnt = $srccnt{$src}) > 1) {
2622                     print STDERR "$src appears $cnt times for the product $prod\n";
2623                     $err++
2624                 }
2625             }
2626         }
2627         die if $err > 0;
2628     }
2629
2630     # Massage the result
2631
2632     # If we depend on a header file or a perl module, add an inclusion of
2633     # its directory to allow smoothe inclusion
2634     foreach my $dest (keys %{$unified_info{depends}}) {
2635         next if $dest eq "";
2636         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2637             next unless $d =~ /\.(h|pm)$/;
2638             my $i = dirname($d);
2639             my $spot =
2640                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2641                 ? 'build' : 'source';
2642             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2643                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2644         }
2645     }
2646
2647     # Go through all intermediary files and change their names to something that
2648     # reflects what they will be built for.  Note that for some source files,
2649     # this leads to duplicate object files because they are used multiple times.
2650     # the goal is to rename all object files according to this scheme:
2651     #    {productname}-{midfix}-{origobjname}.[o|res]
2652     # the {midfix} is a keyword indicating the type of product, which is mostly
2653     # valuable for libraries since they come in two forms.
2654     #
2655     # This also reorganises the {sources} and {shared_sources} so that the
2656     # former only contains ALL object files that are supposed to end up in
2657     # static libraries and programs, while the latter contains ALL object files
2658     # that are supposed to end up in shared libraries and DSOs.
2659     # The main reason for having two different source structures is to allow
2660     # the same name to be used for the static and the shared variants of a
2661     # library.
2662     {
2663         # Take copies so we don't get interference from added stuff
2664         my %unified_copy = ();
2665         foreach (('sources', 'shared_sources')) {
2666             $unified_copy{$_} = { %{$unified_info{$_}} }
2667                 if defined($unified_info{$_});
2668             delete $unified_info{$_};
2669         }
2670         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2671             # $intent serves multi purposes:
2672             # - give a prefix for the new object files names
2673             # - in the case of libraries, rearrange the object files so static
2674             #   libraries use the 'sources' structure exclusively, while shared
2675             #   libraries use the 'shared_sources' structure exclusively.
2676             my $intent = {
2677                 programs  => { bin    => { src => [ 'sources' ],
2678                                            dst => 'sources' } },
2679                 libraries => { lib    => { src => [ 'sources' ],
2680                                            dst => 'sources' },
2681                                shlib  => { prodselect =>
2682                                                sub { grep !/\.a$/, @_ },
2683                                            src => [ 'sources',
2684                                                     'shared_sources' ],
2685                                            dst => 'shared_sources' } },
2686                 modules   => { dso    => { src => [ 'sources' ],
2687                                            dst => 'sources' } },
2688                 scripts   => { script => { src => [ 'sources' ],
2689                                            dst => 'sources' } }
2690                } -> {$prodtype};
2691             foreach my $kind (keys %$intent) {
2692                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2693                              && $disabled{shared});
2694
2695                 my @src = @{$intent->{$kind}->{src}};
2696                 my $dst = $intent->{$kind}->{dst};
2697                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2698                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2699                     # %prod_sources has all applicable objects as keys, and
2700                     # their corresponding sources as values
2701                     my %prod_sources =
2702                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2703                         map { keys %{$unified_copy{$_}->{$prod}} }
2704                         @src;
2705                     foreach (keys %prod_sources) {
2706                         # Only affect object files and resource files,
2707                         # the others simply get a new value
2708                         # (+1 instead of -1)
2709                         if ($_ =~ /\.(o|res)$/) {
2710                             (my $prodname = $prod) =~ s|\.a$||;
2711                             my $newobj =
2712                                 catfile(dirname($_),
2713                                         basename($prodname)
2714                                             . '-' . $kind
2715                                             . '-' . basename($_));
2716                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2717                             foreach my $src (@{$prod_sources{$_}}) {
2718                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2719                                 # Adjust source attributes
2720                                 my $attrs = $unified_info{attributes}->{sources};
2721                                 if (defined $attrs->{$prod}
2722                                     && defined $attrs->{$prod}->{$_}) {
2723                                     $attrs->{$prod}->{$newobj} =
2724                                         $attrs->{$prod}->{$_};
2725                                     delete $attrs->{$prod}->{$_};
2726                                 }
2727                                 foreach my $objsrc (keys %{$attrs->{$_} // {}}) {
2728                                     $attrs->{$newobj}->{$objsrc} =
2729                                         $attrs->{$_}->{$objsrc};
2730                                     delete $attrs->{$_}->{$objsrc};
2731                                 }
2732                             }
2733                             # Adjust dependencies
2734                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2735                                 $unified_info{depends}->{$_}->{$deps} = -1;
2736                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2737                             }
2738                             # Adjust includes
2739                             foreach my $k (('source', 'build')) {
2740                                 next unless
2741                                     defined($unified_info{includes}->{$_}->{$k});
2742                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2743                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2744                             }
2745                         } else {
2746                             $unified_info{$dst}->{$prod}->{$_} = 1;
2747                         }
2748                     }
2749                 }
2750             }
2751         }
2752     }
2753
2754     # At this point, we have a number of sources with the value -1.  They
2755     # aren't part of the local build and are probably meant for a different
2756     # platform, and can therefore be cleaned away.  That happens when making
2757     # %unified_info more efficient below.
2758
2759     ### Make unified_info a bit more efficient
2760     # One level structures
2761     foreach (("programs", "libraries", "modules", "scripts", "targets")) {
2762         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2763     }
2764     # Two level structures
2765     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends",
2766                      "imagedocs", "htmldocs", "mandocs")) {
2767         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2768             my @items =
2769                 sort
2770                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2771                 keys %{$unified_info{$l1}->{$l2}};
2772             if (@items) {
2773                 $unified_info{$l1}->{$l2} = [ @items ];
2774             } else {
2775                 delete $unified_info{$l1}->{$l2};
2776             }
2777         }
2778     }
2779     # Defines
2780     foreach my $dest (sort keys %{$unified_info{defines}}) {
2781         $unified_info{defines}->{$dest}
2782             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2783                 sort keys %{$unified_info{defines}->{$dest}} ];
2784     }
2785     # Includes
2786     foreach my $dest (sort keys %{$unified_info{includes}}) {
2787         if (defined($unified_info{includes}->{$dest}->{build})) {
2788             my @source_includes = ();
2789             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2790                 if defined($unified_info{includes}->{$dest}->{source});
2791             $unified_info{includes}->{$dest} =
2792                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2793             foreach my $inc (@source_includes) {
2794                 push @{$unified_info{includes}->{$dest}}, $inc
2795                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2796             }
2797         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2798             $unified_info{includes}->{$dest} =
2799                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2800         } else {
2801             delete $unified_info{includes}->{$dest};
2802         }
2803     }
2804
2805     # For convenience collect information regarding directories where
2806     # files are generated, those generated files and the end product
2807     # they end up in where applicable.  Then, add build rules for those
2808     # directories
2809     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2810                      "dso" => [ @{$unified_info{modules}} ],
2811                      "bin" => [ @{$unified_info{programs}} ],
2812                      "script" => [ @{$unified_info{scripts}} ],
2813                      "docs" => [ (map { @{$unified_info{imagedocs}->{$_} // []} }
2814                                   keys %{$unified_info{imagedocs} // {}}),
2815                                  (map { @{$unified_info{htmldocs}->{$_} // []} }
2816                                   keys %{$unified_info{htmldocs} // {}}),
2817                                  (map { @{$unified_info{mandocs}->{$_} // []} }
2818                                   keys %{$unified_info{mandocs} // {}}) ] );
2819     foreach my $type (sort keys %loopinfo) {
2820         foreach my $product (@{$loopinfo{$type}}) {
2821             my %dirs = ();
2822             my $pd = dirname($product);
2823
2824             foreach (@{$unified_info{sources}->{$product} // []},
2825                      @{$unified_info{shared_sources}->{$product} // []}) {
2826                 my $d = dirname($_);
2827
2828                 # We don't want to create targets for source directories
2829                 # when building out of source
2830                 next if ($config{sourcedir} ne $config{builddir}
2831                              && $d =~ m|^\Q$config{sourcedir}\E|);
2832                 # We already have a "test" target, and the current directory
2833                 # is just silly to make a target for
2834                 next if $d eq "test" || $d eq ".";
2835
2836                 $dirs{$d} = 1;
2837                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2838                     if $d ne $pd;
2839             }
2840             foreach (sort keys %dirs) {
2841                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2842                     $product;
2843             }
2844         }
2845     }
2846 }
2847
2848 # For the schemes that need it, we provide the old *_obj configs
2849 # from the *_asm_obj ones
2850 foreach (grep /_(asm|aux)_src$/, keys %target) {
2851     my $src = $_;
2852     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2853     $target{$obj} = $target{$src};
2854     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2855     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2856 }
2857
2858 # Write down our configuration where it fits #########################
2859
2860 my %template_vars = (
2861     config => \%config,
2862     target => \%target,
2863     disablables => \@disablables,
2864     disablables_int => \@disablables_int,
2865     disabled => \%disabled,
2866     withargs => \%withargs,
2867     unified_info => \%unified_info,
2868     tls => \@tls,
2869     dtls => \@dtls,
2870     makevars => [ sort keys %user ],
2871     disabled_info => \%disabled_info,
2872     user_crossable => \@user_crossable,
2873 );
2874 my $configdata_outname = 'configdata.pm';
2875 open CONFIGDATA, ">$configdata_outname.new"
2876     or die "Trying to create $configdata_outname.new: $!";
2877 my $configdata_tmplname = cleanfile($srcdir, "configdata.pm.in", $blddir);
2878 my $configdata_tmpl =
2879     OpenSSL::Template->new(TYPE => 'FILE', SOURCE => $configdata_tmplname);
2880 $configdata_tmpl->fill_in(
2881     FILENAME => $configdata_tmplname,
2882     OUTPUT => \*CONFIGDATA,
2883     HASH => { %template_vars,
2884               autowarntext => [
2885                   'WARNING: do not edit!',
2886                   "Generated by Configure from $configdata_tmplname",
2887               ] }
2888 ) or die $Text::Template::ERROR;
2889 close CONFIGDATA;
2890
2891 rename "$configdata_outname.new", $configdata_outname;
2892 if ($builder_platform eq 'unix') {
2893     my $mode = (0755 & ~umask);
2894     chmod $mode, 'configdata.pm'
2895         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2896 }
2897 print "Created $configdata_outname\n";
2898
2899 print "Running $configdata_outname\n";
2900 my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
2901 my $cmd = "$perlcmd $configdata_outname";
2902 #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2903 system($cmd);
2904 exit 1 if $? != 0;
2905
2906 $SIG{__DIE__} = $orig_death_handler;
2907
2908 print <<"EOF" if ($disabled{threads} eq "unavailable");
2909
2910 The library could not be configured for supporting multi-threaded
2911 applications as the compiler options required on this system are not known.
2912 See file INSTALL.md for details if you need multi-threading.
2913 EOF
2914
2915 print <<"EOF" if ($no_shared_warn);
2916
2917 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2918 platform, so we will pretend you gave the option 'no-pic', which also disables
2919 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2920 or position independent code, please let us know (but please first make sure
2921 you have tried with a current version of OpenSSL).
2922 EOF
2923
2924 print $banner;
2925
2926 exit(0);
2927
2928 ######################################################################
2929 #
2930 # Helpers and utility functions
2931 #
2932
2933 # Death handler, to print a helpful message in case of failure #######
2934 #
2935 sub death_handler {
2936     die @_ if $^S;              # To prevent the added message in eval blocks
2937     my $build_file = $config{build_file} // "build file";
2938     my @message = ( <<"_____", @_ );
2939
2940 Failure!  $build_file wasn't produced.
2941 Please read INSTALL.md and associated NOTES-* files.  You may also have to
2942 look over your available compiler tool chain or change your configuration.
2943
2944 _____
2945
2946     # Dying is terminal, so it's ok to reset the signal handler here.
2947     $SIG{__DIE__} = $orig_death_handler;
2948     die @message;
2949 }
2950
2951 # Configuration file reading #########################################
2952
2953 # Note: All of the helper functions are for lazy evaluation.  They all
2954 # return a CODE ref, which will return the intended value when evaluated.
2955 # Thus, whenever there's mention of a returned value, it's about that
2956 # intended value.
2957
2958 # Helper function to implement conditional value variants, with a default
2959 # plus additional values based on the value of $config{build_type}.
2960 # Arguments are given in hash table form:
2961 #
2962 #       picker(default => "Basic string: ",
2963 #              debug   => "debug",
2964 #              release => "release")
2965 #
2966 # When configuring with --debug, the resulting string will be
2967 # "Basic string: debug", and when not, it will be "Basic string: release"
2968 #
2969 # This can be used to create variants of sets of flags according to the
2970 # build type:
2971 #
2972 #       cflags => picker(default => "-Wall",
2973 #                        debug   => "-g -O0",
2974 #                        release => "-O3")
2975 #
2976 sub picker {
2977     my %opts = @_;
2978     return sub { add($opts{default} || (),
2979                      $opts{$config{build_type}} || ())->(); }
2980 }
2981
2982 # Helper function to combine several values of different types into one.
2983 # This is useful if you want to combine a string with the result of a
2984 # lazy function, such as:
2985 #
2986 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2987 #
2988 sub combine {
2989     my @stuff = @_;
2990     return sub { add(@stuff)->(); }
2991 }
2992
2993 # Helper function to implement conditional values depending on the value
2994 # of $disabled{threads}.  Can be used as follows:
2995 #
2996 #       cflags => combine("-Wall", threads("-pthread"))
2997 #
2998 sub threads {
2999     my @flags = @_;
3000     return sub { add($disabled{threads} ? () : @flags)->(); }
3001 }
3002
3003 sub shared {
3004     my @flags = @_;
3005     return sub { add($disabled{shared} ? () : @flags)->(); }
3006 }
3007
3008 our $add_called = 0;
3009 # Helper function to implement adding values to already existing configuration
3010 # values.  It handles elements that are ARRAYs, CODEs and scalars
3011 sub _add {
3012     my $separator = shift;
3013
3014     # If there's any ARRAY in the collection of values OR the separator
3015     # is undef, we will return an ARRAY of combined values, otherwise a
3016     # string of joined values with $separator as the separator.
3017     my $found_array = !defined($separator);
3018
3019     my @values =
3020         map {
3021             my $res = $_;
3022             while (ref($res) eq "CODE") {
3023                 $res = $res->();
3024             }
3025             if (defined($res)) {
3026                 if (ref($res) eq "ARRAY") {
3027                     $found_array = 1;
3028                     @$res;
3029                 } else {
3030                     $res;
3031                 }
3032             } else {
3033                 ();
3034             }
3035     } (@_);
3036
3037     $add_called = 1;
3038
3039     if ($found_array) {
3040         [ @values ];
3041     } else {
3042         join($separator, grep { defined($_) && $_ ne "" } @values);
3043     }
3044 }
3045 sub add_before {
3046     my $separator = " ";
3047     if (ref($_[$#_]) eq "HASH") {
3048         my $opts = pop;
3049         $separator = $opts->{separator};
3050     }
3051     my @x = @_;
3052     sub { _add($separator, @x, @_) };
3053 }
3054 sub add {
3055     my $separator = " ";
3056     if (ref($_[$#_]) eq "HASH") {
3057         my $opts = pop;
3058         $separator = $opts->{separator};
3059     }
3060     my @x = @_;
3061     sub { _add($separator, @_, @x) };
3062 }
3063
3064 sub read_eval_file {
3065     my $fname = shift;
3066     my $content;
3067     my @result;
3068
3069     open F, "< $fname" or die "Can't open '$fname': $!\n";
3070     {
3071         undef local $/;
3072         $content = <F>;
3073     }
3074     close F;
3075     {
3076         local $@;
3077
3078         @result = ( eval $content );
3079         warn $@ if $@;
3080     }
3081     return wantarray ? @result : $result[0];
3082 }
3083
3084 # configuration reader, evaluates the input file as a perl script and expects
3085 # it to fill %targets with target configurations.  Those are then added to
3086 # %table.
3087 sub read_config {
3088     my $fname = shift;
3089     my %targets;
3090
3091     {
3092         # Protect certain tables from tampering
3093         local %table = ();
3094
3095         %targets = read_eval_file($fname);
3096     }
3097     my %preexisting = ();
3098     foreach (sort keys %targets) {
3099         $preexisting{$_} = 1 if $table{$_};
3100     }
3101     die <<"EOF",
3102 The following config targets from $fname
3103 shadow pre-existing config targets with the same name:
3104 EOF
3105         map { "  $_\n" } sort keys %preexisting
3106         if %preexisting;
3107
3108
3109     # For each target, check that it's configured with a hash table.
3110     foreach (keys %targets) {
3111         if (ref($targets{$_}) ne "HASH") {
3112             if (ref($targets{$_}) eq "") {
3113                 warn "Deprecated target configuration for $_, ignoring...\n";
3114             } else {
3115                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3116             }
3117             delete $targets{$_};
3118         } else {
3119             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3120         }
3121     }
3122
3123     %table = (%table, %targets);
3124
3125 }
3126
3127 # configuration resolver.  Will only resolve all the lazy evaluation
3128 # codeblocks for the chosen target and all those it inherits from,
3129 # recursively
3130 sub resolve_config {
3131     my $target = shift;
3132     my @breadcrumbs = @_;
3133
3134 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3135
3136     if (grep { $_ eq $target } @breadcrumbs) {
3137         die "inherit_from loop!  target backtrace:\n  "
3138             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3139     }
3140
3141     if (!defined($table{$target})) {
3142         warn "Warning! target $target doesn't exist!\n";
3143         return ();
3144     }
3145     # Recurse through all inheritances.  They will be resolved on the
3146     # fly, so when this operation is done, they will all just be a
3147     # bunch of attributes with string values.
3148     # What we get here, though, are keys with references to lists of
3149     # the combined values of them all.  We will deal with lists after
3150     # this stage is done.
3151     my %combined_inheritance = ();
3152     if ($table{$target}->{inherit_from}) {
3153         my @inherit_from =
3154             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3155         foreach (@inherit_from) {
3156             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3157
3158             # 'template' is a marker that's considered private to
3159             # the config that had it.
3160             delete $inherited_config{template};
3161
3162             foreach (keys %inherited_config) {
3163                 if (!$combined_inheritance{$_}) {
3164                     $combined_inheritance{$_} = [];
3165                 }
3166                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3167             }
3168         }
3169     }
3170
3171     # We won't need inherit_from in this target any more, since we've
3172     # resolved all the inheritances that lead to this
3173     delete $table{$target}->{inherit_from};
3174
3175     # Now is the time to deal with those lists.  Here's the place to
3176     # decide what shall be done with those lists, all based on the
3177     # values of the target we're currently dealing with.
3178     # - If a value is a coderef, it will be executed with the list of
3179     #   inherited values as arguments.
3180     # - If the corresponding key doesn't have a value at all or is the
3181     #   empty string, the inherited value list will be run through the
3182     #   default combiner (below), and the result becomes this target's
3183     #   value.
3184     # - Otherwise, this target's value is assumed to be a string that
3185     #   will simply override the inherited list of values.
3186     my $default_combiner = add();
3187
3188     my %all_keys =
3189         map { $_ => 1 } (keys %combined_inheritance,
3190                          keys %{$table{$target}});
3191
3192     sub process_values {
3193         my $object    = shift;
3194         my $inherited = shift;  # Always a [ list ]
3195         my $target    = shift;
3196         my $entry     = shift;
3197
3198         $add_called = 0;
3199
3200         while(ref($object) eq "CODE") {
3201             $object = $object->(@$inherited);
3202         }
3203         if (!defined($object)) {
3204             return ();
3205         }
3206         elsif (ref($object) eq "ARRAY") {
3207             local $add_called;  # To make sure recursive calls don't affect it
3208             return [ map { process_values($_, $inherited, $target, $entry) }
3209                      @$object ];
3210         } elsif (ref($object) eq "") {
3211             return $object;
3212         } else {
3213             die "cannot handle reference type ",ref($object)
3214                 ," found in target ",$target," -> ",$entry,"\n";
3215         }
3216     }
3217
3218     foreach my $key (sort keys %all_keys) {
3219         my $previous = $combined_inheritance{$key};
3220
3221         # Current target doesn't have a value for the current key?
3222         # Assign it the default combiner, the rest of this loop body
3223         # will handle it just like any other coderef.
3224         if (!exists $table{$target}->{$key}) {
3225             $table{$target}->{$key} = $default_combiner;
3226         }
3227
3228         $table{$target}->{$key} = process_values($table{$target}->{$key},
3229                                                $combined_inheritance{$key},
3230                                                $target, $key);
3231         unless(defined($table{$target}->{$key})) {
3232             delete $table{$target}->{$key};
3233         }
3234 #        if ($extra_checks &&
3235 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$key})) {
3236 #            warn "$key got replaced in $target\n";
3237 #        }
3238     }
3239
3240     # Finally done, return the result.
3241     return %{$table{$target}};
3242 }
3243
3244 sub usage
3245         {
3246         print STDERR $usage;
3247         print STDERR "\npick os/compiler from:\n";
3248         my $j=0;
3249         my $i;
3250         my $k=0;
3251         foreach $i (sort keys %table)
3252                 {
3253                 next if $table{$i}->{template};
3254                 next if $i =~ /^debug/;
3255                 $k += length($i) + 1;
3256                 if ($k > 78)
3257                         {
3258                         print STDERR "\n";
3259                         $k=length($i);
3260                         }
3261                 print STDERR $i . " ";
3262                 }
3263         foreach $i (sort keys %table)
3264                 {
3265                 next if $table{$i}->{template};
3266                 next if $i !~ /^debug/;
3267                 $k += length($i) + 1;
3268                 if ($k > 78)
3269                         {
3270                         print STDERR "\n";
3271                         $k=length($i);
3272                         }
3273                 print STDERR $i . " ";
3274                 }
3275         exit(1);
3276         }
3277
3278 sub compiler_predefined {
3279     state %predefined;
3280     my $cc = shift;
3281
3282     return () if $^O eq 'VMS';
3283
3284     die 'compiler_predefined called without a compiler command'
3285         unless $cc;
3286
3287     if (! $predefined{$cc}) {
3288
3289         $predefined{$cc} = {};
3290
3291         # collect compiler pre-defines from gcc or gcc-alike...
3292         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3293         while (my $l = <PIPE>) {
3294             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3295             $predefined{$cc}->{$1} = $2 // '';
3296         }
3297         close(PIPE);
3298     }
3299
3300     return %{$predefined{$cc}};
3301 }
3302
3303 sub which
3304 {
3305     my ($name)=@_;
3306
3307     if (eval { require IPC::Cmd; 1; }) {
3308         IPC::Cmd->import();
3309         return scalar IPC::Cmd::can_run($name);
3310     } else {
3311         # if there is $directories component in splitpath,
3312         # then it's not something to test with $PATH...
3313         return $name if (File::Spec->splitpath($name))[1];
3314
3315         foreach (File::Spec->path()) {
3316             my $fullpath = catfile($_, "$name$target{exe_extension}");
3317             if (-f $fullpath and -x $fullpath) {
3318                 return $fullpath;
3319             }
3320         }
3321     }
3322 }
3323
3324 sub env
3325 {
3326     my $name = shift;
3327     my %opts = @_;
3328
3329     unless ($opts{cacheonly}) {
3330         # Note that if $ENV{$name} doesn't exist or is undefined,
3331         # $config{perlenv}->{$name} will be created with the value
3332         # undef.  This is intentional.
3333
3334         $config{perlenv}->{$name} = $ENV{$name}
3335             if ! exists $config{perlenv}->{$name};
3336     }
3337     return $config{perlenv}->{$name};
3338 }
3339
3340 # Configuration printer ##############################################
3341
3342 sub print_table_entry
3343 {
3344     local $now_printing = shift;
3345     my %target = resolve_config($now_printing);
3346     my $type = shift;
3347
3348     # Don't print the templates
3349     return if $target{template};
3350
3351     my @sequence = (
3352         "sys_id",
3353         "cpp",
3354         "cppflags",
3355         "defines",
3356         "includes",
3357         "cc",
3358         "cflags",
3359         "ld",
3360         "lflags",
3361         "loutflag",
3362         "ex_libs",
3363         "bn_ops",
3364         "enable",
3365         "disable",
3366         "poly1035_asm_src",
3367         "thread_scheme",
3368         "perlasm_scheme",
3369         "dso_scheme",
3370         "shared_target",
3371         "shared_cflag",
3372         "shared_defines",
3373         "shared_ldflag",
3374         "shared_rcflag",
3375         "shared_extension",
3376         "dso_extension",
3377         "obj_extension",
3378         "exe_extension",
3379         "ranlib",
3380         "ar",
3381         "arflags",
3382         "aroutflag",
3383         "rc",
3384         "rcflags",
3385         "rcoutflag",
3386         "mt",
3387         "mtflags",
3388         "mtinflag",
3389         "mtoutflag",
3390         "multilib",
3391         "build_scheme",
3392         );
3393
3394     if ($type eq "TABLE") {
3395         print "\n";
3396         print "*** $now_printing\n";
3397         foreach (@sequence) {
3398             if (ref($target{$_}) eq "ARRAY") {
3399                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3400             } else {
3401                 printf "\$%-12s = %s\n", $_, $target{$_};
3402             }
3403         }
3404     } elsif ($type eq "HASH") {
3405         my $largest =
3406             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3407         print "    '$now_printing' => {\n";
3408         foreach (@sequence) {
3409             if ($target{$_}) {
3410                 if (ref($target{$_}) eq "ARRAY") {
3411                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3412                 } else {
3413                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3414                 }
3415             }
3416         }
3417         print "    },\n";
3418     }
3419 }
3420
3421 # Utility routines ###################################################
3422
3423 # On VMS, if the given file is a logical name, File::Spec::Functions
3424 # will consider it an absolute path.  There are cases when we want a
3425 # purely syntactic check without checking the environment.
3426 sub isabsolute {
3427     my $file = shift;
3428
3429     # On non-platforms, we just use file_name_is_absolute().
3430     return file_name_is_absolute($file) unless $^O eq "VMS";
3431
3432     # If the file spec includes a device or a directory spec,
3433     # file_name_is_absolute() is perfectly safe.
3434     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3435
3436     # Here, we know the given file spec isn't absolute
3437     return 0;
3438 }
3439
3440 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3441 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3442 # realpath() requires that at least all path components except the last is an
3443 # existing directory.  On VMS, the last component of the directory spec must
3444 # exist.
3445 sub absolutedir {
3446     my $dir = shift;
3447
3448     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3449     # will return the volume name for the device, no matter what.  Also,
3450     # it will return an incorrect directory spec if the argument is a
3451     # directory that doesn't exist.
3452     if ($^O eq "VMS") {
3453         return rel2abs($dir);
3454     }
3455
3456     # We use realpath() on Unix, since no other will properly clean out
3457     # a directory spec.
3458     use Cwd qw/realpath/;
3459
3460     return realpath($dir);
3461 }
3462
3463 # Check if all paths are one and the same, using stat.  They must both exist
3464 # We need this for the cases when File::Spec doesn't detect case insensitivity
3465 # (File::Spec::Unix assumes case sensitivity)
3466 sub samedir {
3467     die "samedir expects two arguments\n" unless scalar @_ == 2;
3468
3469     my @stat0 = stat($_[0]);    # First argument
3470     my @stat1 = stat($_[1]);    # Second argument
3471
3472     die "Couldn't stat $_[0]" unless @stat0;
3473     die "Couldn't stat $_[1]" unless @stat1;
3474
3475     # Compare device number
3476     return 0 unless ($stat0[0] == $stat1[0]);
3477     # Compare "inode".  The perl manual recommends comparing as
3478     # string rather than as number.
3479     return 0 unless ($stat0[1] eq $stat1[1]);
3480
3481     return 1;                   # All the same
3482 }
3483
3484 sub quotify {
3485     my %processors = (
3486         perl    => sub { my $x = shift;
3487                          $x =~ s/([\\\$\@"])/\\$1/g;
3488                          return '"'.$x.'"'; },
3489         maybeshell => sub { my $x = shift;
3490                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3491                             if ($x ne $y || $x =~ m|\s|) {
3492                                 return '"'.$y.'"';
3493                             } else {
3494                                 return $x;
3495                             }
3496                         },
3497         );
3498     my $for = shift;
3499     my $processor =
3500         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3501
3502     return map { $processor->($_); } @_;
3503 }
3504
3505 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3506 # $filename is a file name to read from
3507 # $line_concat_cond_re is a regexp detecting a line continuation ending
3508 # $line_concat is a CODEref that takes care of concatenating two lines
3509 sub collect_from_file {
3510     my $filename = shift;
3511     my $line_concat_cond_re = shift;
3512     my $line_concat = shift;
3513
3514     open my $fh, $filename || die "unable to read $filename: $!\n";
3515     return sub {
3516         my $saved_line = "";
3517         $_ = "";
3518         while (<$fh>) {
3519             s|\R$||;
3520             if (defined $line_concat) {
3521                 $_ = $line_concat->($saved_line, $_);
3522                 $saved_line = "";
3523             }
3524             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3525                 $saved_line = $_;
3526                 next;
3527             }
3528             return $_;
3529         }
3530         die "$filename ending with continuation line\n" if $_;
3531         close $fh;
3532         return undef;
3533     }
3534 }
3535
3536 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3537 # $array is an ARRAYref of lines
3538 # $line_concat_cond_re is a regexp detecting a line continuation ending
3539 # $line_concat is a CODEref that takes care of concatenating two lines
3540 sub collect_from_array {
3541     my $array = shift;
3542     my $line_concat_cond_re = shift;
3543     my $line_concat = shift;
3544     my @array = (@$array);
3545
3546     return sub {
3547         my $saved_line = "";
3548         $_ = "";
3549         while (defined($_ = shift @array)) {
3550             s|\R$||;
3551             if (defined $line_concat) {
3552                 $_ = $line_concat->($saved_line, $_);
3553                 $saved_line = "";
3554             }
3555             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3556                 $saved_line = $_;
3557                 next;
3558             }
3559             return $_;
3560         }
3561         die "input text ending with continuation line\n" if $_;
3562         return undef;
3563     }
3564 }
3565
3566 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3567 # $lineiterator is a CODEref that delivers one line at a time.
3568 # All following arguments are regex/CODEref pairs, where the regexp detects a
3569 # line and the CODEref does something with the result of the regexp.
3570 sub collect_information {
3571     my $lineiterator = shift;
3572     my %collectors = @_;
3573
3574     while(defined($_ = $lineiterator->())) {
3575         s|\R$||;
3576         my $found = 0;
3577         if ($collectors{"BEFORE"}) {
3578             $collectors{"BEFORE"}->($_);
3579         }
3580         foreach my $re (keys %collectors) {
3581             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3582                 $collectors{$re}->($lineiterator);
3583                 $found = 1;
3584             };
3585         }
3586         if ($collectors{"OTHERWISE"}) {
3587             $collectors{"OTHERWISE"}->($lineiterator, $_)
3588                 unless $found || !defined $collectors{"OTHERWISE"};
3589         }
3590         if ($collectors{"AFTER"}) {
3591             $collectors{"AFTER"}->($_);
3592         }
3593     }
3594 }
3595
3596 # tokenize($line)
3597 # tokenize($line,$separator)
3598 # $line is a line of text to split up into tokens
3599 # $separator [optional] is a regular expression that separates the tokens,
3600 # the default being spaces.  Do not use quotes of any kind as separators,
3601 # that will give undefined results.
3602 # Returns a list of tokens.
3603 #
3604 # Tokens are divided by separator (spaces by default).  If the tokens include
3605 # the separators, they have to be quoted with single or double quotes.
3606 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3607 # with backslash.
3608 # Basically, the same quoting rules apply for " and ' as in any
3609 # Unix shell.
3610 sub tokenize {
3611     my $line = my $debug_line = shift;
3612     my $separator = shift // qr|\s+|;
3613     my @result = ();
3614
3615     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3616         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3617     }
3618
3619     while ($line =~ s|^${separator}||, $line ne "") {
3620         my $token = "";
3621     again:
3622         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3623         $token .= $1;
3624         $line = $2.$';
3625
3626         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3627             $token .= $1;
3628             $line = $';
3629             goto again;
3630         } elsif ($line =~ m/^'([^']*)'/) {
3631             $token .= $1;
3632             $line = $';
3633             goto again;
3634         }
3635         push @result, $token;
3636     }
3637
3638     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3639         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3640         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3641     }
3642     return @result;
3643 }