Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2024 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::fallback "$FindBin::Bin/external/perl/MODULES.txt";
  21 use OpenSSL::Glob;
  22 use OpenSSL::Template;
  23 use OpenSSL::config;
  24
  25 # see INSTALL.md for instructions.
  26
  27 my $orig_death_handler = $SIG{__DIE__};
  28 $SIG{__DIE__} = \&death_handler;
  29
  30 my $usage="Usage: Configure [no-<feature> ...] [enable-<feature> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]thread-pool] [[no-]default-thread-pool] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  31
  32 my $banner = <<"EOF";
  33
  34 **********************************************************************
  35 ***                                                                ***
  36 ***   OpenSSL has been successfully configured                     ***
  37 ***                                                                ***
  38 ***   If you encounter a problem while building, please open an    ***
  39 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
  40 ***   and include the output from the following command:           ***
  41 ***                                                                ***
  42 ***       perl configdata.pm --dump                                ***
  43 ***                                                                ***
  44 ***   (If you are new to OpenSSL, you might want to consult the    ***
  45 ***   'Troubleshooting' section in the INSTALL.md file first)      ***
  46 ***                                                                ***
  47 **********************************************************************
  48 EOF
  49
  50 # Options:
  51 #
  52 # --config      add the given configuration file, which will be read after
  53 #               any "Configurations*" files that are found in the same
  54 #               directory as this script.
  55 # --prefix      prefix for the OpenSSL installation, which includes the
  56 #               directories bin, lib, include, share/man, share/doc/openssl
  57 #               This becomes the value of INSTALLTOP in Makefile
  58 #               (Default: /usr/local)
  59 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  60 #               If it's a relative directory, it will be added on the directory
  61 #               given with --prefix.
  62 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  63 #               (Default: PREFIX/ssl)
  64 # --banner=".." Output specified text instead of default completion banner
  65 #
  66 # -w            Don't wait after showing a Configure warning
  67 #
  68 # --cross-compile-prefix Add specified prefix to binutils components.
  69 #
  70 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0
  71 #               Define the public APIs as they were for that version
  72 #               including patch releases.  If 'no-deprecated' is also
  73 #               given, do not compile support for interfaces deprecated
  74 #               up to and including the specified OpenSSL version.
  75 #
  76 # no-hw-xxx     do not compile support for specific crypto hardware.
  77 #               Generic OpenSSL-style methods relating to this support
  78 #               are always compiled but return NULL if the hardware
  79 #               support isn't compiled.
  80 #
  81 # enable-demos  Enable the building of the example code in the demos directory
  82 # no-hw         do not compile support for any crypto hardware.
  83 # [no-]threads  [don't] try to create a library that is suitable for
  84 #               multithreaded applications (default is "threads" if we
  85 #               know how to do it)
  86 # [no-]thread-pool
  87 #               [don't] allow thread pool functionality
  88 # [no-]default-thread-pool
  89 #               [don't] allow default thread pool functionality
  90 # [no-]shared   [don't] try to create shared libraries when supported.
  91 # [no-]pic      [don't] try to build position independent code when supported.
  92 #               If disabled, it also disables shared and dynamic-engine.
  93 # no-asm        do not use assembler
  94 # no-egd        do not compile support for the entropy-gathering daemon APIs
  95 # [no-]zlib     [don't] compile support for zlib compression.
  96 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  97 #               library and will be loaded at run-time by the OpenSSL library.
  98 # sctp          include SCTP support
  99 # no-quic       disable QUIC support
 100 # no-uplink     Don't build support for UPLINK interface.
 101 # enable-weak-ssl-ciphers
 102 #               Enable weak ciphers that are disabled by default.
 103 # 386           generate 80386 code in assembly modules
 104 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
 105 #               mentioned '386' option implies this one
 106 # no-<cipher>   build without specified algorithm (dsa, idea, rc5, ...)
 107 # -<xxx> +<xxx> All options which are unknown to the 'Configure' script are
 108 # /<xxx>        passed through to the compiler. Unix-style options beginning
 109 #               with a '-' or '+' are recognized, as well as Windows-style
 110 #               options beginning with a '/'. If the option contains arguments
 111 #               separated by spaces, then the URL-style notation %20 can be
 112 #               used for the space character in order to avoid having to quote
 113 #               the option. For example, -opt%20arg gets expanded to -opt arg.
 114 #               In fact, any ASCII character can be encoded as %xx using its
 115 #               hexadecimal encoding.
 116 # -static       while -static is also a pass-through compiler option (and
 117 #               as such is limited to environments where it's actually
 118 #               meaningful), it triggers a number configuration options,
 119 #               namely no-pic, no-shared and no-threads. It is
 120 #               argued that the only reason to produce statically linked
 121 #               binaries (and in context it means executables linked with
 122 #               -static flag, and not just executables linked with static
 123 #               libcrypto.a) is to eliminate dependency on specific run-time,
 124 #               a.k.a. libc version. The mentioned config options are meant
 125 #               to achieve just that. Unfortunately on Linux it's impossible
 126 #               to eliminate the dependency completely for openssl executable
 127 #               because of getaddrinfo and gethostbyname calls, which can
 128 #               invoke dynamically loadable library facility anyway to meet
 129 #               the lookup requests. For this reason on Linux statically
 130 #               linked openssl executable has rather debugging value than
 131 #               production quality.
 132 #
 133 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
 134 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
 135 # Following are set automatically by this script
 136 #
 137 # MD5_ASM       use some extra md5 assembler,
 138 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 139 # RMD160_ASM    use some extra ripemd160 assembler,
 140 # SHA256_ASM    sha256_block is implemented in assembler
 141 # SHA512_ASM    sha512_block is implemented in assembler
 142 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 143
 144 # Minimum warning options... any contributions to OpenSSL should at least
 145 # get past these.  Note that we only use these with C compilers, not with
 146 # C++ compilers.
 147
 148 # -DPEDANTIC complements -pedantic and is meant to mask code that
 149 # is not strictly standard-compliant and/or implementation-specific,
 150 # e.g. inline assembly, disregards to alignment requirements, such
 151 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 152 # to be used even in sanitized builds, because sanitizer too is
 153 # supposed to and does take notice of non-standard behaviour. Then
 154 # -pedantic with pre-C9x compiler would also complain about 'long
 155 # long' not being supported. As 64-bit algorithms are common now,
 156 # it grew impossible to resolve this without sizeable additional
 157 # code, so we just tell compiler to be pedantic about everything
 158 # but 'long long' type.
 159
 160 my @gcc_devteam_warn = qw(
 161     -DPEDANTIC -pedantic -Wno-long-long -DUNUSEDRESULT_DEBUG
 162     -Wall
 163     -Wmissing-declarations
 164     -Wextra
 165     -Wno-unused-parameter
 166     -Wno-missing-field-initializers
 167     -Wswitch
 168     -Wsign-compare
 169     -Wshadow
 170     -Wformat
 171     -Wno-type-limits
 172     -Wno-tautological-constant-out-of-range-compare
 173     -Wundef
 174     -Werror
 175     -Wmissing-prototypes
 176     -Wstrict-prototypes
 177 );
 178
 179 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 180 # TODO(openssl-team): fix problems and investigate if (at least) the
 181 # following warnings can also be enabled:
 182 #       -Wcast-align
 183 #       -Wunreachable-code -- no, too ugly/compiler-specific
 184 #       -Wlanguage-extension-token -- no, we use asm()
 185 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 186 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 187 my @clang_devteam_warn = qw(
 188     -Wno-unknown-warning-option
 189     -Wswitch-default
 190     -Wno-parentheses-equality
 191     -Wno-language-extension-token
 192     -Wno-extended-offsetof
 193     -Wno-missing-braces
 194     -Wconditional-uninitialized
 195     -Wincompatible-pointer-types-discards-qualifiers
 196     -Wmissing-variable-declarations
 197 );
 198
 199 my @cl_devteam_warn = qw(
 200     /WX
 201 );
 202
 203 my $strict_warnings = 0;
 204
 205 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 206 # which would cover all BSD flavors. -pthread applies to them all,
 207 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 208 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 209 # which has to be accompanied by explicit -D_THREAD_SAFE and
 210 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 211 # seems to be sufficient?
 212 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 213
 214 #
 215 # API compatibility name to version number mapping.
 216 #
 217 my $apitable = {
 218     # This table expresses when API additions or changes can occur.
 219     # The numbering used changes from 3.0 and on because we updated
 220     # (solidified) our version numbering scheme at that point.
 221
 222     # From 3.0 and on, we internalise the given version number in decimal
 223     # as MAJOR * 10000 + MINOR * 100 + 0
 224     "3.0.0" => 30000,
 225     "3.0"   => 30000,
 226
 227     # Note that before 3.0, we didn't have the same version number scheme.
 228     # Still, the numbering we use here covers what we need.
 229     "1.1.1" => 10101,
 230     "1.1.0" => 10100,
 231     "1.0.2" => 10002,
 232     "1.0.1" => 10001,
 233     "1.0.0" => 10000,
 234     "0.9.8" =>   908,
 235 };
 236
 237 # For OpenSSL::config::get_platform
 238 my %guess_opts = ();
 239
 240 my $dryrun = 0;
 241
 242 our %table = ();
 243 our %config = ();
 244 our %withargs = ();
 245 our $now_printing;      # set to current entry's name in print_table_entry
 246                         # (todo: right thing would be to encapsulate name
 247                         # into %target [class] and make print_table_entry
 248                         # a method)
 249
 250 # Forward declarations ###############################################
 251
 252 # read_config(filename)
 253 #
 254 # Reads a configuration file and populates %table with the contents
 255 # (which the configuration file places in %targets).
 256 sub read_config;
 257
 258 # resolve_config(target)
 259 #
 260 # Resolves all the late evaluations, inheritances and so on for the
 261 # chosen target and any target it inherits from.
 262 sub resolve_config;
 263
 264
 265 # Information collection #############################################
 266
 267 # Unified build supports separate build dir
 268 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 269 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 270
 271 # File::Spec::Unix doesn't detect case insensitivity, so we make sure to
 272 # check if the source and build directory are really the same, and make
 273 # them so.  This avoids all kinds of confusion later on.
 274 # We must check @File::Spec::ISA rather than using File::Spec->isa() to
 275 # know if File::Spec ended up loading File::Spec::Unix.
 276 $srcdir = $blddir
 277     if (grep(/::Unix$/, @File::Spec::ISA)
 278         && samedir($srcdir, $blddir));
 279
 280 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 281
 282 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 283
 284 $config{sourcedir} = abs2rel($srcdir, $blddir);
 285 $config{builddir} = abs2rel($blddir, $blddir);
 286 # echo -n 'holy hand grenade of antioch' | openssl sha256
 287 $config{FIPSKEY} =
 288     'f4556650ac31d35461610bac4ed81b1a181b2d8a43ea2854cbae22ca74560813';
 289
 290 # Collect reconfiguration information if needed
 291 my @argvcopy=@ARGV;
 292
 293 if (grep /^reconf(igure)?$/, @argvcopy) {
 294     die "reconfiguring with other arguments present isn't supported"
 295         if scalar @argvcopy > 1;
 296     if (-f "./configdata.pm") {
 297         my $file = "./configdata.pm";
 298         unless (my $return = do $file) {
 299             die "couldn't parse $file: $@" if $@;
 300             die "couldn't do $file: $!"    unless defined $return;
 301             die "couldn't run $file"       unless $return;
 302         }
 303
 304         @argvcopy = defined($configdata::config{perlargv}) ?
 305             @{$configdata::config{perlargv}} : ();
 306         die "Incorrect data to reconfigure, please do a normal configuration\n"
 307             if (grep(/^reconf/,@argvcopy));
 308         $config{perlenv} = $configdata::config{perlenv} // {};
 309     } else {
 310         die "Insufficient data to reconfigure, please do a normal configuration\n";
 311     }
 312 }
 313
 314 $config{perlargv} = [ @argvcopy ];
 315
 316 # Historical: if known directories in crypto/ have been removed, it means
 317 # that those sub-systems are disabled.
 318 # (the other option would be to removed them from the SUBDIRS statement in
 319 # crypto/build.info)
 320 # We reverse the input list for cosmetic purely reasons, to compensate that
 321 # 'unshift' adds at the front of the list (i.e. in reverse input order).
 322 foreach ( reverse sort( 'aes', 'aria', 'bf', 'camellia', 'cast', 'des', 'dh',
 323                         'dsa', 'ec', 'hmac', 'idea', 'md2', 'md5', 'mdc2',
 324                         'rc2', 'rc4', 'rc5', 'ripemd', 'seed', 'sha',
 325                         'sm2', 'sm3', 'sm4') ) {
 326     unshift @argvcopy, "no-$_" if ! -d catdir($srcdir, 'crypto', $_);
 327 }
 328
 329 # Collect version numbers
 330 my %version = ();
 331
 332 collect_information(
 333     collect_from_file(catfile($srcdir,'VERSION.dat')),
 334     qr/\s*(\w+)\s*=\s*(.*?)\s*$/ =>
 335         sub {
 336             # Only define it if there is a value at all
 337             if ($2 ne '') {
 338                 my $k = $1;
 339                 my $v = $2;
 340                 # Some values are quoted.  Trim the quotes
 341                 $v = $1 if $v =~ /^"(.*)"$/;
 342                 $version{uc $k} = $v;
 343             }
 344         },
 345     "OTHERWISE" =>
 346         sub { die "Something wrong with this line:\n$_\nin $srcdir/VERSION.dat" },
 347     );
 348
 349 $config{major} = $version{MAJOR} // 'unknown';
 350 $config{minor} = $version{MINOR} // 'unknown';
 351 $config{patch} = $version{PATCH} // 'unknown';
 352 $config{prerelease} =
 353     defined $version{PRE_RELEASE_TAG} ? "-$version{PRE_RELEASE_TAG}" : '';
 354 $config{build_metadata} =
 355     defined $version{BUILD_METADATA} ? "+$version{BUILD_METADATA}" : '';
 356 $config{shlib_version} = $version{SHLIB_VERSION} // 'unknown';
 357 $config{release_date} = $version{RELEASE_DATE} // 'xx XXX xxxx';
 358
 359 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 360 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 361
 362 die "erroneous version information in VERSION.dat: ",
 363     "$config{version}, $config{shlib_version}\n"
 364     unless (defined $version{MAJOR}
 365             && defined $version{MINOR}
 366             && defined $version{PATCH}
 367             && defined $version{SHLIB_VERSION});
 368
 369 # Collect target configurations
 370
 371 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 372 foreach (sort glob($pattern)) {
 373     &read_config($_);
 374 }
 375
 376 if (defined env($local_config_envname)) {
 377     if ($^O eq 'VMS') {
 378         # VMS environment variables are logical names,
 379         # which can be used as is
 380         $pattern = $local_config_envname . ':' . '*.conf';
 381     } else {
 382         $pattern = catfile(env($local_config_envname), '*.conf');
 383     }
 384
 385     foreach (sort glob($pattern)) {
 386         &read_config($_);
 387     }
 388 }
 389
 390 # Fail if no configuration is apparent
 391 if (!%table) {
 392     print "Failed to find any os/compiler configurations. Please make sure the Configurations directory is included.\n";
 393     &usage;
 394 }
 395
 396 # Save away perl command information
 397 $config{perl_cmd} = $^X;
 398 $config{perl_version} = $Config{version};
 399 $config{perl_archname} = $Config{archname};
 400
 401 $config{prefix}="";
 402 $config{openssldir}="";
 403 $config{processor}="";
 404 $config{libdir}="";
 405 my $auto_threads=1;    # enable threads automatically? true by default
 406 my $default_ranlib;
 407
 408 # Known TLS and DTLS protocols
 409 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 410 my @dtls = qw(dtls1 dtls1_2);
 411
 412 # Explicitly known options that are possible to disable.  They can
 413 # be regexps, and will be used like this: /^no-${option}$/
 414 # For developers: keep it sorted alphabetically
 415
 416 my @disablables = (
 417     "acvp-tests",
 418     "afalgeng",
 419     "apps",
 420     "argon2",
 421     "aria",
 422     "asan",
 423     "asm",
 424     "async",
 425     "atexit",
 426     "autoalginit",
 427     "autoerrinit",
 428     "autoload-config",
 429     "bf",
 430     "blake2",
 431     "brotli",
 432     "brotli-dynamic",
 433     "buildtest-c++",
 434     "bulk",
 435     "cached-fetch",
 436     "camellia",
 437     "capieng",
 438     "winstore",
 439     "cast",
 440     "chacha",
 441     "cmac",
 442     "cmp",
 443     "cms",
 444     "comp",
 445     "crypto-mdebug",
 446     "ct",
 447     "default-thread-pool",
 448     "demos",
 449     "deprecated",
 450     "des",
 451     "devcryptoeng",
 452     "dgram",
 453     "dh",
 454     "docs",
 455     "dsa",
 456     "dso",
 457     "dtls",
 458     "dynamic-engine",
 459     "ec",
 460     "ec2m",
 461     "ec_nistp_64_gcc_128",
 462     "ecdh",
 463     "ecdsa",
 464     "ecx",
 465     "egd",
 466     "engine",
 467     "err",
 468     "external-tests",
 469     "filenames",
 470     "fips",
 471     "fips-securitychecks",
 472     "fuzz-afl",
 473     "fuzz-libfuzzer",
 474     "gost",
 475     "http",
 476     "idea",
 477     "ktls",
 478     "legacy",
 479     "loadereng",
 480     "makedepend",
 481     "md2",
 482     "md4",
 483     "mdc2",
 484     "module",
 485     "msan",
 486     "multiblock",
 487     "nextprotoneg",
 488     "ocb",
 489     "ocsp",
 490     "padlockeng",
 491     "pic",
 492     "pinshared",
 493     "poly1305",
 494     "posix-io",
 495     "psk",
 496     "quic",
 497     "unstable-qlog",
 498     "rc2",
 499     "rc4",
 500     "rc5",
 501     "rdrand",
 502     "rfc3779",
 503     "rmd160",
 504     "scrypt",
 505     "sctp",
 506     "secure-memory",
 507     "seed",
 508     "shared",
 509     "siphash",
 510     "siv",
 511     "sm2",
 512     "sm2-precomp",
 513     "sm3",
 514     "sm4",
 515     "sock",
 516     "srp",
 517     "srtp",
 518     "sse2",
 519     "ssl",
 520     "ssl-trace",
 521     "static-engine",
 522     "stdio",
 523     "tests",
 524     "tfo",
 525     "thread-pool",
 526     "threads",
 527     "tls",
 528     "trace",
 529     "ts",
 530     "ubsan",
 531     "ui-console",
 532     "unit-test",
 533     "uplink",
 534     "weak-ssl-ciphers",
 535     "whirlpool",
 536     "zlib",
 537     "zlib-dynamic",
 538     "zstd",
 539     "zstd-dynamic",
 540     );
 541 foreach my $proto ((@tls, @dtls))
 542         {
 543         push(@disablables, $proto);
 544         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 545         }
 546
 547 # Internal disablables, for aliasing purposes.  They serve no special
 548 # purpose here, but allow scripts to get to know them through configdata.pm,
 549 # where these are merged with @disablables.
 550 # The actual aliasing mechanism is done via %disable_cascades
 551 my @disablables_int = qw(
 552     crmf
 553     );
 554
 555 my %deprecated_disablables = (
 556     "ssl2" => undef,
 557     "buf-freelists" => undef,
 558     "crypto-mdebug-backtrace" => undef,
 559     "hw" => "hw",               # causes cascade, but no macro
 560     "hw-padlock" => "padlockeng",
 561     "ripemd" => "rmd160",
 562     "ui" => "ui-console",
 563     "heartbeats" => undef,
 564     );
 565
 566 # All of the following are disabled by default:
 567
 568 our %disabled = ( # "what"         => "comment"
 569                   "fips"                => "default",
 570                   "asan"                => "default",
 571                   "brotli"              => "default",
 572                   "brotli-dynamic"      => "default",
 573                   "buildtest-c++"       => "default",
 574                   "crypto-mdebug"       => "default",
 575                   "crypto-mdebug-backtrace" => "default",
 576                   "demos"               => "default",
 577                   "devcryptoeng"        => "default",
 578                   "ec_nistp_64_gcc_128" => "default",
 579                   "egd"                 => "default",
 580                   "external-tests"      => "default",
 581                   "fuzz-afl"            => "default",
 582                   "fuzz-libfuzzer"      => "default",
 583                   "ktls"                => "default",
 584                   "md2"                 => "default",
 585                   "msan"                => "default",
 586                   "rc5"                 => "default",
 587                   "sctp"                => "default",
 588                   "ssl3"                => "default",
 589                   "ssl3-method"         => "default",
 590                   "tfo"                 => "default",
 591                   "trace"               => "default",
 592                   "ubsan"               => "default",
 593                   "unit-test"           => "default",
 594                   "weak-ssl-ciphers"    => "default",
 595                   "zlib"                => "default",
 596                   "zlib-dynamic"        => "default",
 597                   "zstd"                => "default",
 598                   "zstd-dynamic"        => "default",
 599                 );
 600
 601 # Note: => pair form used for aesthetics, not to truly make a hash table
 602 my @disable_cascades = (
 603     # "what"            => [ "cascade", ... ]
 604     "bulk"              => [ "shared", "dso",
 605                              "aria", "async", "atexit", "autoload-config",
 606                              "blake2", "bf", "camellia", "cast", "chacha",
 607                              "cmac", "cms", "cmp", "comp", "ct",
 608                              "des", "dgram", "dh", "dsa",
 609                              "ec", "engine",
 610                              "filenames",
 611                              "idea", "ktls",
 612                              "md4", "multiblock", "nextprotoneg",
 613                              "ocsp", "ocb", "poly1305", "psk",
 614                              "rc2", "rc4", "rmd160",
 615                              "seed", "siphash", "siv",
 616                              "sm3", "sm4", "srp",
 617                              "srtp", "ssl3-method", "ssl-trace",
 618                              "tfo",
 619                              "ts", "ui-console", "whirlpool",
 620                              "fips-securitychecks" ],
 621     sub { $config{processor} eq "386" }
 622                         => [ "sse2" ],
 623     "ssl"               => [ "ssl3" ],
 624     "ssl3-method"       => [ "ssl3" ],
 625     "zlib"              => [ "zlib-dynamic" ],
 626     "brotli"            => [ "brotli-dynamic" ],
 627     "zstd"              => [ "zstd-dynamic" ],
 628     "des"               => [ "mdc2" ],
 629     "ec"                => [ "ec2m", "ecdsa", "ecdh", "sm2", "gost", "ecx" ],
 630     "dgram"             => [ "dtls", "quic", "sctp" ],
 631     "sock"              => [ "dgram", "tfo" ],
 632     "dtls"              => [ @dtls ],
 633     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 634                         => [ "dtls" ],
 635
 636     "tls"               => [ @tls ],
 637     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 638                         => [ "tls" ],
 639     "tls1_3"            => [ "quic" ],
 640     "quic"              => [ "unstable-qlog" ],
 641
 642     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 643
 644     "module"            => [ "dynamic-engine", "fips" ],
 645
 646     # Without shared libraries, dynamic engines aren't possible.
 647     # This is due to them having to link with libcrypto and register features
 648     # using the ENGINE functionality, and since that relies on global tables,
 649     # those *have* to be exactly the same as the ones accessed from the app,
 650     # which cannot be guaranteed if shared libraries aren't present.
 651     # (note that even with shared libraries, both the app and dynamic engines
 652     # must be linked with the same library)
 653     "shared"            => [ "dynamic-engine", "uplink" ],
 654     "dso"               => [ "dynamic-engine", "module" ],
 655     # Other modules don't necessarily have to link with libcrypto, so shared
 656     # libraries do not have to be a condition to produce those.
 657
 658     # Without position independent code, there can be no shared libraries
 659     # or modules.
 660     "pic"               => [ "shared", "module" ],
 661
 662     "engine"            => [ "dynamic-engine", grep(/eng$/, @disablables) ],
 663     "dynamic-engine"    => [ "loadereng" ],
 664     "hw"                => [ "padlockeng" ],
 665
 666     # no-autoalginit is only useful when building non-shared
 667     "autoalginit"       => [ "shared", "apps", "fips" ],
 668
 669     "stdio"             => [ "apps", "capieng", "egd" ],
 670     "apps"              => [ "tests" ],
 671     "tests"             => [ "external-tests" ],
 672     "comp"              => [ "zlib", "brotli", "zstd" ],
 673     "sm3"               => [ "sm2" ],
 674     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 675
 676     sub { !$disabled{"msan"} } => [ "asm" ],
 677
 678     "cmac"              => [ "siv" ],
 679     "legacy"            => [ "md2" ],
 680
 681     "cmp"               => [ "crmf" ],
 682
 683     "fips"              => [ "fips-securitychecks", "acvp-tests" ],
 684
 685     "threads"           => [ "thread-pool" ],
 686     "thread-pool"       => [ "default-thread-pool" ],
 687
 688     "blake2"            => [ "argon2" ],
 689
 690     "deprecated-3.0"    => [ "engine", "srp" ],
 691
 692     "http"              => [ "ocsp" ]
 693     );
 694
 695 # Avoid protocol support holes.  Also disable all versions below N, if version
 696 # N is disabled while N+1 is enabled.
 697 #
 698 my @list = (reverse @tls);
 699 while ((my $first, my $second) = (shift @list, shift @list)) {
 700     last unless @list;
 701     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 702                               => [ @list ] );
 703     unshift @list, $second;
 704 }
 705 my @list = (reverse @dtls);
 706 while ((my $first, my $second) = (shift @list, shift @list)) {
 707     last unless @list;
 708     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 709                               => [ @list ] );
 710     unshift @list, $second;
 711 }
 712
 713 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 714 # To remove something from %disabled, use "enable-foo".
 715 # For symmetry, "disable-foo" is a synonym for "no-foo".
 716
 717 # For the "make variables" CPPINCLUDES and CPPDEFINES, we support lists with
 718 # platform specific list separators.  Users from those platforms should
 719 # recognise those separators from how you set up the PATH to find executables.
 720 # The default is the Unix like separator, :, but as an exception, we also
 721 # support the space as separator.
 722 my $list_separator_re =
 723     { VMS           => qr/(?<!\^),/,
 724       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 725 # All the "make variables" we support
 726 # Some get pre-populated for the sake of backward compatibility
 727 # (we supported those before the change to "make variable" support.
 728 my %user = (
 729     AR          => env('AR'),
 730     ARFLAGS     => [],
 731     AS          => undef,
 732     ASFLAGS     => [],
 733     CC          => env('CC'),
 734     CFLAGS      => [ env('CFLAGS') || () ],
 735     CXX         => env('CXX'),
 736     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 737     CPP         => undef,
 738     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 739     CPPDEFINES  => [],  # Alternative for -D
 740     CPPINCLUDES => [],  # Alternative for -I
 741     CROSS_COMPILE => env('CROSS_COMPILE'),
 742     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 743     LD          => undef,
 744     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 745     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 746     MT          => undef,
 747     MTFLAGS     => [],
 748     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 749     RANLIB      => env('RANLIB'),
 750     RC          => env('RC') || env('WINDRES'),
 751     RCFLAGS     => [ env('RCFLAGS') || () ],
 752     RM          => undef,
 753    );
 754 # Info about what "make variables" may be prefixed with the cross compiler
 755 # prefix.  This should NEVER mention any such variable with a list for value.
 756 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 757 # The same but for flags given as Configure options.  These are *additional*
 758 # input, as opposed to the VAR=string option that override the corresponding
 759 # config target attributes
 760 my %useradd = (
 761     ASFLAGS     => [],
 762     CPPDEFINES  => [],
 763     CPPINCLUDES => [],
 764     CPPFLAGS    => [],
 765     CFLAGS      => [],
 766     CXXFLAGS    => [],
 767     LDFLAGS     => [],
 768     LDLIBS      => [],
 769     RCFLAGS     => [],
 770    );
 771
 772 my %user_synonyms = (
 773     HASHBANGPERL=> 'PERL',
 774     RC          => 'WINDRES',
 775    );
 776
 777 # Some target attributes have been renamed, this is the translation table
 778 my %target_attr_translate =(
 779     ar          => 'AR',
 780     as          => 'AS',
 781     cc          => 'CC',
 782     cxx         => 'CXX',
 783     cpp         => 'CPP',
 784     hashbangperl => 'HASHBANGPERL',
 785     ld          => 'LD',
 786     mt          => 'MT',
 787     ranlib      => 'RANLIB',
 788     rc          => 'RC',
 789     rm          => 'RM',
 790    );
 791
 792 # Initialisers coming from 'config' scripts
 793 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 794 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 795 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 796 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 797 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 798 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 799 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 800
 801 $config{openssl_api_defines}=[];
 802 $config{openssl_sys_defines}=[];
 803 $config{openssl_feature_defines}=[];
 804 $config{options}="";
 805 $config{build_type} = "release";
 806 my $target="";
 807
 808 my %cmdvars = ();               # Stores FOO='blah' type arguments
 809 my %unsupported_options = ();
 810 my %deprecated_options = ();
 811 # If you change this, update apps/version.c
 812 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 813 my @seed_sources = ();
 814 while (@argvcopy)
 815         {
 816         $_ = shift @argvcopy;
 817
 818         # Support env variable assignments among the options
 819         if (m|^(\w+)=(.+)?$|)
 820                 {
 821                 $cmdvars{$1} = $2;
 822                 # Every time a variable is given as a configuration argument,
 823                 # it acts as a reset if the variable.
 824                 if (exists $user{$1})
 825                         {
 826                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 827                         }
 828                 #if (exists $useradd{$1})
 829                 #       {
 830                 #       $useradd{$1} = [];
 831                 #       }
 832                 next;
 833                 }
 834
 835         # VMS is a case insensitive environment, and depending on settings
 836         # out of our control, we may receive options uppercased.  Let's
 837         # downcase at least the part before any equal sign.
 838         if ($^O eq "VMS")
 839                 {
 840                 s/^([^=]*)/lc($1)/e;
 841                 }
 842
 843         # some people just can't read the instructions, clang people have to...
 844         s/^-no-(?!integrated-as)/no-/;
 845
 846         # rewrite some options in "enable-..." form
 847         s /^-?-?shared$/enable-shared/;
 848         s /^sctp$/enable-sctp/;
 849         s /^threads$/enable-threads/;
 850         s /^zlib$/enable-zlib/;
 851         s /^zlib-dynamic$/enable-zlib-dynamic/;
 852         s /^fips$/enable-fips/;
 853
 854         if (/^(no|disable|enable)-(.+)$/)
 855                 {
 856                 my $word = $2;
 857                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 858                         && !exists $deprecated_disablables{$word}
 859                         && !grep { $word eq $_ } @disablables)
 860                         {
 861                         $unsupported_options{$_} = 1;
 862                         next;
 863                         }
 864                 }
 865         if (/^no-(.+)$/ || /^disable-(.+)$/)
 866                 {
 867                 foreach my $proto ((@tls, @dtls))
 868                         {
 869                         if ($1 eq "$proto-method")
 870                                 {
 871                                 $disabled{"$proto"} = "option($proto-method)";
 872                                 last;
 873                                 }
 874                         }
 875                 if ($1 eq "dtls")
 876                         {
 877                         foreach my $proto (@dtls)
 878                                 {
 879                                 $disabled{$proto} = "option(dtls)";
 880                                 }
 881                         $disabled{"dtls"} = "option(dtls)";
 882                         }
 883                 elsif ($1 eq "ssl")
 884                         {
 885                         # Last one of its kind
 886                         $disabled{"ssl3"} = "option(ssl)";
 887                         }
 888                 elsif ($1 eq "tls")
 889                         {
 890                         # XXX: Tests will fail if all SSL/TLS
 891                         # protocols are disabled.
 892                         foreach my $proto (@tls)
 893                                 {
 894                                 $disabled{$proto} = "option(tls)";
 895                                 }
 896                         }
 897                 elsif ($1 eq "static-engine")
 898                         {
 899                         delete $disabled{"dynamic-engine"};
 900                         }
 901                 elsif ($1 eq "dynamic-engine")
 902                         {
 903                         $disabled{"dynamic-engine"} = "option";
 904                         }
 905                 elsif (exists $deprecated_disablables{$1})
 906                         {
 907                         $deprecated_options{$_} = 1;
 908                         if (defined $deprecated_disablables{$1})
 909                                 {
 910                                 $disabled{$deprecated_disablables{$1}} = "option";
 911                                 }
 912                         }
 913                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 914                         {
 915                         $deprecated_options{$_} = 1;
 916                         }
 917                 else
 918                         {
 919                         $disabled{$1} = "option";
 920                         }
 921                 # No longer an automatic choice
 922                 $auto_threads = 0 if ($1 eq "threads");
 923                 }
 924         elsif (/^enable-(.+)$/)
 925                 {
 926                 if ($1 eq "static-engine")
 927                         {
 928                         $disabled{"dynamic-engine"} = "option";
 929                         }
 930                 elsif ($1 eq "dynamic-engine")
 931                         {
 932                         delete $disabled{"dynamic-engine"};
 933                         }
 934                 elsif ($1 eq "zlib-dynamic")
 935                         {
 936                         delete $disabled{"zlib"};
 937                         }
 938                 elsif ($1 eq "brotli-dynamic")
 939                         {
 940                         delete $disabled{"brotli"};
 941                         }
 942                 elsif ($1 eq "zstd-dynamic")
 943                         {
 944                         delete $disabled{"zstd"};
 945                         }
 946                 my $algo = $1;
 947                 delete $disabled{$algo};
 948
 949                 # No longer an automatic choice
 950                 $auto_threads = 0 if ($1 eq "threads");
 951                 }
 952         elsif (/^-d$/)          # From older 'config'
 953                 {
 954                 $config{build_type} = "debug";
 955                 }
 956         elsif (/^-v$/)          # From older 'config'
 957                 {
 958                 $guess_opts{verbose} = 1;
 959                 }
 960         elsif (/^-w$/)
 961                 {
 962                 $guess_opts{nowait} = 1;
 963                 }
 964         elsif (/^-t$/)          # From older 'config'
 965                 {
 966                 $dryrun = 1;
 967                 }
 968         elsif (/^--strict-warnings$/)
 969                 {
 970                 # Pretend that our strict flags is a C flag, and replace it
 971                 # with the proper flags later on
 972                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 973                 $strict_warnings=1;
 974                 }
 975         elsif (/^--debug$/)
 976                 {
 977                 $config{build_type} = "debug";
 978                 }
 979         elsif (/^--release$/)
 980                 {
 981                 $config{build_type} = "release";
 982                 }
 983         elsif (/^386$/)
 984                 { $config{processor}=386; }
 985         elsif (/^rsaref$/)
 986                 {
 987                 # No RSAref support any more since it's not needed.
 988                 # The check for the option is there so scripts aren't
 989                 # broken
 990                 }
 991         elsif (m|^[-+/]|)
 992                 {
 993                 if (/^--prefix=(.*)$/)
 994                         {
 995                         $config{prefix}=$1;
 996                         }
 997                 elsif (/^--api=(.*)$/)
 998                         {
 999                         my $api = $1;
1000                         die "Unknown API compatibility level $api"
1001                                 unless defined $apitable->{$api};
1002                         $config{api}=$apitable->{$api};
1003                         }
1004                 elsif (/^--libdir=(.*)$/)
1005                         {
1006                         $config{libdir}=$1;
1007                         }
1008                 elsif (/^--openssldir=(.*)$/)
1009                         {
1010                         $config{openssldir}=$1;
1011                         }
1012                 elsif (/^--with-zlib-lib=(.*)$/)
1013                         {
1014                         $withargs{zlib_lib}=$1;
1015                         }
1016                 elsif (/^--with-zlib-include=(.*)$/)
1017                         {
1018                         $withargs{zlib_include}=$1;
1019                         }
1020                 elsif (/^--with-brotli-lib=(.*)$/)
1021                         {
1022                         $withargs{brotli_lib}=$1;
1023                         }
1024                 elsif (/^--with-brotli-include=(.*)$/)
1025                         {
1026                         $withargs{brotli_include}=$1;
1027                         }
1028                 elsif (/^--with-zstd-lib=(.*)$/)
1029                         {
1030                         $withargs{zstd_lib}=$1;
1031                         }
1032                 elsif (/^--with-zstd-include=(.*)$/)
1033                         {
1034                         $withargs{zstd_include}=$1;
1035                         }
1036                 elsif (/^--with-fuzzer-lib=(.*)$/)
1037                         {
1038                         $withargs{fuzzer_lib}=$1;
1039                         }
1040                 elsif (/^--with-fuzzer-include=(.*)$/)
1041                         {
1042                         $withargs{fuzzer_include}=$1;
1043                         }
1044                 elsif (/^--with-rand-seed=(.*)$/)
1045                         {
1046                         foreach my $x (split(m|,|, $1))
1047                             {
1048                             die "Unknown --with-rand-seed choice $x\n"
1049                                 if ! grep { $x eq $_ } @known_seed_sources;
1050                             push @seed_sources, $x;
1051                             }
1052                         }
1053                 elsif (/^--fips-key=(.*)$/)
1054                         {
1055                         $user{FIPSKEY}=lc($1);
1056                         die "Non-hex character in FIPS key\n"
1057                            if $user{FIPSKEY} =~ /[^a-f0-9]/;
1058                         die "FIPS key must have even number of characters\n"
1059                            if length $1 & 1;
1060                         die "FIPS key too long (64 bytes max)\n"
1061                            if length $1 > 64;
1062                         }
1063                 elsif (/^--banner=(.*)$/)
1064                         {
1065                         $banner = $1 . "\n";
1066                         }
1067                 elsif (/^--cross-compile-prefix=(.*)$/)
1068                         {
1069                         $user{CROSS_COMPILE}=$1;
1070                         }
1071                 elsif (/^--config=(.*)$/)
1072                         {
1073                         read_config $1;
1074                         }
1075                 elsif (/^-l(.*)$/)
1076                         {
1077                         push @{$useradd{LDLIBS}}, $_;
1078                         }
1079                 elsif (/^-framework$/)
1080                         {
1081                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
1082                         }
1083                 elsif (/^-L(.*)$/ or /^-Wl,/)
1084                         {
1085                         push @{$useradd{LDFLAGS}}, $_;
1086                         }
1087                 elsif (/^-rpath$/ or /^-R$/)
1088                         # -rpath is the OSF1 rpath flag
1089                         # -R is the old Solaris rpath flag
1090                         {
1091                         my $rpath = shift(@argvcopy) || "";
1092                         $rpath .= " " if $rpath ne "";
1093                         push @{$useradd{LDFLAGS}}, $_, $rpath;
1094                         }
1095                 elsif (/^-static$/)
1096                         {
1097                         push @{$useradd{LDFLAGS}}, $_;
1098                         }
1099                 elsif (m|^[-/]D(.*)$|)
1100                         {
1101                         push @{$useradd{CPPDEFINES}}, $1;
1102                         }
1103                 elsif (m|^[-/]I(.*)$|)
1104                         {
1105                         push @{$useradd{CPPINCLUDES}}, $1;
1106                         }
1107                 elsif (/^-Wp,$/)
1108                         {
1109                         push @{$useradd{CPPFLAGS}}, $1;
1110                         }
1111                 else    # common if (/^[-+]/), just pass down...
1112                         {
1113                         # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
1114                         # This provides a simple way to pass options with arguments separated
1115                         # by spaces without quoting (e.g. -opt%20arg translates to -opt arg).
1116                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
1117                         push @{$useradd{CFLAGS}}, $_;
1118                         push @{$useradd{CXXFLAGS}}, $_;
1119                         }
1120                 }
1121         elsif (m|^/|)
1122                 {
1123                 # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
1124                 # This provides a simple way to pass options with arguments separated
1125                 # by spaces without quoting (e.g. /opt%20arg translates to /opt arg).
1126                 $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
1127                 push @{$useradd{CFLAGS}}, $_;
1128                 push @{$useradd{CXXFLAGS}}, $_;
1129                 }
1130         else
1131                 {
1132                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
1133                 $target=$_;
1134                 }
1135         unless ($_ eq $target || /^no-/ || /^disable-/)
1136                 {
1137                 # "no-..." follows later after implied deactivations
1138                 # have been derived.  (Don't take this too seriously,
1139                 # we really only write OPTIONS to the Makefile out of
1140                 # nostalgia.)
1141
1142                 if ($config{options} eq "")
1143                         { $config{options} = $_; }
1144                 else
1145                         { $config{options} .= " ".$_; }
1146                 }
1147         }
1148
1149 if (keys %deprecated_options)
1150         {
1151         warn "***** Deprecated options: ",
1152                 join(", ", keys %deprecated_options), "\n";
1153         }
1154 if (keys %unsupported_options)
1155         {
1156         die "***** Unsupported options: ",
1157                 join(", ", keys %unsupported_options), "\n";
1158         }
1159
1160 # If any %useradd entry has been set, we must check that the "make
1161 # variables" haven't been set.  We start by checking of any %useradd entry
1162 # is set.
1163 if (grep { scalar @$_ > 0 } values %useradd) {
1164     # Hash of env / make variables names.  The possible values are:
1165     # 1 - "make vars"
1166     # 2 - %useradd entry set
1167     # 3 - both set
1168     my %detected_vars =
1169         map { my $v = 0;
1170               $v += 1 if $cmdvars{$_};
1171               $v += 2 if @{$useradd{$_}};
1172               $_ => $v }
1173         keys %useradd;
1174
1175     # If any of the corresponding "make variables" is set, we error
1176     if (grep { $_ & 1 } values %detected_vars) {
1177         my $names = join(', ', grep { $detected_vars{$_} > 0 }
1178                                sort keys %detected_vars);
1179         die <<"_____";
1180 ***** Mixing make variables and additional compiler/linker flags as
1181 ***** configure command line option is not permitted.
1182 ***** Affected make variables: $names
1183 _____
1184     }
1185 }
1186
1187 # Check through all supported command line variables to see if any of them
1188 # were set, and canonicalise the values we got.  If no compiler or linker
1189 # flag or anything else that affects %useradd was set, we also check the
1190 # environment for values.
1191 my $anyuseradd =
1192     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
1193 foreach (keys %user) {
1194     my $value = $cmdvars{$_};
1195     $value //= env($_) unless $anyuseradd;
1196     $value //=
1197         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
1198     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
1199         unless $anyuseradd;
1200
1201     if (defined $value) {
1202         if (ref $user{$_} eq 'ARRAY') {
1203             if ($_ eq 'CPPDEFINES' || $_ eq 'CPPINCLUDES') {
1204                 $user{$_} = [ split /$list_separator_re/, $value ];
1205             } else {
1206                 $user{$_} = [ $value ];
1207             }
1208         } elsif (!defined $user{$_}) {
1209             $user{$_} = $value;
1210         }
1211     }
1212 }
1213
1214 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1215     && !$disabled{shared}
1216     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1217     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1218         "***** any of asan, msan or ubsan\n";
1219 }
1220
1221 # If no target was given, try guessing.
1222 unless ($target) {
1223     my %system_config = OpenSSL::config::get_platform(%guess_opts, %user);
1224
1225     # The $system_config{disable} is used to populate %disabled with
1226     # entries that aren't already there.
1227     foreach ( @{$system_config{disable} // []} ) {
1228         $disabled{$_} = 'system' unless defined $disabled{$_};
1229     }
1230     delete $system_config{disable};
1231
1232     # Override config entries with stuff from the guesser.
1233     # It's assumed that this really is nothing new.
1234     %config = ( %config, %system_config );
1235     $target = $system_config{target};
1236 }
1237
1238 sub disable {
1239     my $disable_type = shift;
1240
1241     for (@_) {
1242         $disabled{$_} = $disable_type;
1243     }
1244
1245     my @tocheckfor = (@_ ? @_ : keys %disabled);
1246     while (@tocheckfor) {
1247         my %new_tocheckfor = ();
1248         my @cascade_copy = (@disable_cascades);
1249         while (@cascade_copy) {
1250             my ($test, $descendents) =
1251                 (shift @cascade_copy, shift @cascade_copy);
1252             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1253                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1254                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1255                 }
1256             }
1257         }
1258         @tocheckfor = (keys %new_tocheckfor);
1259     }
1260 }
1261 disable();                     # First cascade run
1262
1263 our $die = sub { die @_; };
1264 if ($target eq "TABLE") {
1265     local $die = sub { warn @_; };
1266     foreach (sort keys %table) {
1267         print_table_entry($_, "TABLE");
1268     }
1269     exit 0;
1270 }
1271
1272 if ($target eq "LIST") {
1273     foreach (sort keys %table) {
1274         print $_,"\n" unless $table{$_}->{template};
1275     }
1276     exit 0;
1277 }
1278
1279 if ($target eq "HASH") {
1280     local $die = sub { warn @_; };
1281     print "%table = (\n";
1282     foreach (sort keys %table) {
1283         print_table_entry($_, "HASH");
1284     }
1285     exit 0;
1286 }
1287
1288 print "Configuring OpenSSL version $config{full_version} ";
1289 print "for target $target\n";
1290
1291 if (scalar(@seed_sources) == 0) {
1292     print "Using os-specific seed configuration\n";
1293     push @seed_sources, 'os';
1294 }
1295 if (scalar(grep { $_ eq 'egd' } @seed_sources) > 0) {
1296     delete $disabled{'egd'};
1297 }
1298 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1299     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1300     warn <<_____ if scalar(@seed_sources) == 1;
1301
1302 ============================== WARNING ===============================
1303 You have selected the --with-rand-seed=none option, which effectively
1304 disables automatic reseeding of the OpenSSL random generator.
1305 All operations depending on the random generator such as creating keys
1306 will not work unless the random generator is seeded manually by the
1307 application.
1308
1309 Please read the 'Note on random number generation' section in the
1310 INSTALL.md instructions and the RAND_DRBG(7) manual page for more
1311 details.
1312 ============================== WARNING ===============================
1313
1314 _____
1315 }
1316 push @{$config{openssl_feature_defines}},
1317      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1318         @seed_sources;
1319
1320 # Backward compatibility?
1321 if ($target =~ m/^CygWin32(-.*)$/) {
1322     $target = "Cygwin".$1;
1323 }
1324
1325 # Support for legacy targets having a name starting with 'debug-'
1326 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1327 if ($d) {
1328     $config{build_type} = "debug";
1329
1330     # If we do not find debug-foo in the table, the target is set to foo.
1331     if (!$table{$target}) {
1332         $target = $t;
1333     }
1334 }
1335
1336 if ($target) {
1337     # It's possible that we have different config targets for specific
1338     # toolchains, so we try to detect them, and go for the plain config
1339     # target if not.
1340     my $found;
1341     foreach ( ( "$target-$user{CC}", "$target", undef ) ) {
1342         $found=$_ if $table{$_} && !$table{$_}->{template};
1343         last if $found;
1344     }
1345     $target = $found;
1346 } else {
1347     # If we don't have a config target now, we try the C compiler as we
1348     # fallback
1349     my $cc = $user{CC} // 'cc';
1350     $target = $cc if $table{$cc} && !$table{$cc}->{template};
1351 }
1352
1353 &usage unless $target;
1354
1355 exit 0 if $dryrun;              # From older 'config'
1356
1357 $config{target} = $target;
1358 my %target = resolve_config($target);
1359
1360 foreach (keys %target_attr_translate) {
1361     $target{$target_attr_translate{$_}} = $target{$_}
1362         if $target{$_};
1363     delete $target{$_};
1364 }
1365
1366 %target = ( %{$table{DEFAULTS}}, %target );
1367
1368 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1369 $config{conf_files} = [ sort keys %conf_files ];
1370
1371 # Using sub disable within these loops may prove fragile, so we run
1372 # a cascade afterwards
1373 foreach my $feature (@{$target{disable}}) {
1374     if (exists $deprecated_disablables{$feature}) {
1375         warn "***** config $target disables deprecated feature $feature\n";
1376     } elsif (!grep { $feature eq $_ } @disablables) {
1377         die "***** config $target disables unknown feature $feature\n";
1378     }
1379     $disabled{$feature} = 'config';
1380 }
1381 foreach my $feature (@{$target{enable}}) {
1382     if ("default" eq ($disabled{$feature} // "")) {
1383         if (exists $deprecated_disablables{$feature}) {
1384             warn "***** config $target enables deprecated feature $feature\n";
1385         } elsif (!grep { $feature eq $_ } @disablables) {
1386             die "***** config $target enables unknown feature $feature\n";
1387         }
1388         delete $disabled{$feature};
1389     }
1390 }
1391
1392 # If uplink_arch isn't defined, disable uplink
1393 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1394 # If asm_arch isn't defined, disable asm
1395 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1396
1397 disable();                      # Run a cascade now
1398
1399 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1400 $target{cxxflags}//=$target{cflags} if $target{CXX};
1401 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1402 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1403
1404 # Fill %config with values from %user, and in case those are undefined or
1405 # empty, use values from %target (acting as a default).
1406 foreach (keys %user) {
1407     my $ref_type = ref $user{$_};
1408
1409     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1410     # and a value that's to be coerced into that type.
1411     my $mkvalue = sub {
1412         my $type = shift;
1413         my $value = shift;
1414         my $undef_p = shift;
1415
1416         die "Too many arguments for \$mkvalue" if @_;
1417
1418         while (ref $value eq 'CODE') {
1419             $value = $value->();
1420         }
1421
1422         if ($type eq 'ARRAY') {
1423             return undef unless defined $value;
1424             return undef if ref $value ne 'ARRAY' && !$value;
1425             return undef if ref $value eq 'ARRAY' && !@$value;
1426             return [ $value ] unless ref $value eq 'ARRAY';
1427         }
1428         return undef unless $value;
1429         return $value;
1430     };
1431
1432     $config{$_} =
1433         $mkvalue->($ref_type, $user{$_})
1434         || $mkvalue->($ref_type, $target{$_});
1435     delete $config{$_} unless defined $config{$_};
1436 }
1437
1438 # Finish up %config by appending things the user gave us on the command line
1439 # apart from "make variables"
1440 foreach (keys %useradd) {
1441     # The must all be lists, so we assert that here
1442     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1443         unless ref $useradd{$_} eq 'ARRAY';
1444
1445     if (defined $config{$_}) {
1446         push @{$config{$_}}, @{$useradd{$_}};
1447     } else {
1448         $config{$_} = [ @{$useradd{$_}} ];
1449     }
1450 }
1451 # At this point, we can forget everything about %user and %useradd,
1452 # because it's now all been merged into the corresponding $config entry
1453
1454 if ($config{prefix} && !$config{CROSS_COMPILE}) {
1455     die "Directory given with --prefix MUST be absolute\n"
1456         unless file_name_is_absolute($config{prefix});
1457 }
1458
1459 if (grep { $_ =~ /(?:^|\s)-static(?:\s|$)/ } @{$config{LDFLAGS}}) {
1460     disable('static', 'pic', 'threads');
1461 }
1462
1463 # Allow overriding the build file name
1464 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1465
1466 # Make sure build_scheme is consistent.
1467 $target{build_scheme} = [ $target{build_scheme} ]
1468     if ref($target{build_scheme}) ne "ARRAY";
1469
1470 my ($builder, $builder_platform, @builder_opts) =
1471     @{$target{build_scheme}};
1472
1473 foreach my $checker (($builder_platform."-".$config{build_file}."-checker.pm",
1474                       $builder_platform."-checker.pm")) {
1475     my $checker_path = catfile($srcdir, "Configurations", $checker);
1476     if (-f $checker_path) {
1477         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1478             ? sub { warn $@; } : sub { die $@; };
1479         if (! do $checker_path) {
1480             if ($@) {
1481                 $fn->($@);
1482             } elsif ($!) {
1483                 $fn->($!);
1484             } else {
1485                 $fn->("The detected tools didn't match the platform\n");
1486             }
1487         }
1488         last;
1489     }
1490 }
1491
1492 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1493
1494 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1495         {
1496         push @{$config{cflags}}, "-mno-cygwin";
1497         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1498         push @{$config{shared_ldflag}}, "-mno-cygwin";
1499         }
1500
1501 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1502         && !grep { $_ =~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1503         # minimally required architecture flags for assembly modules
1504         my $value;
1505         $value = '-mips2' if ($target =~ /mips32/);
1506         $value = '-mips3' if ($target =~ /mips64/);
1507         unshift @{$config{cflags}}, $value;
1508         unshift @{$config{cxxflags}}, $value if $config{CXX};
1509 }
1510
1511 # If threads aren't disabled, check how possible they are
1512 unless ($disabled{threads}) {
1513     if ($auto_threads) {
1514         # Enabled by default, disable it forcibly if unavailable
1515         if ($target{thread_scheme} eq "(unknown)") {
1516             disable("unavailable", 'threads');
1517         }
1518     } else {
1519         # The user chose to enable threads explicitly, let's see
1520         # if there's a chance that's possible
1521         if ($target{thread_scheme} eq "(unknown)") {
1522             # If the user asked for "threads" and we don't have internal
1523             # knowledge how to do it, [s]he is expected to provide any
1524             # system-dependent compiler options that are necessary.  We
1525             # can't truly check that the given options are correct, but
1526             # we expect the user to know what [s]He is doing.
1527             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1528                 die "You asked for multi-threading support, but didn't\n"
1529                     ,"provide any system-specific compiler options\n";
1530             }
1531         }
1532     }
1533 }
1534
1535 # Find out if clang's sanitizers have been enabled with -fsanitize
1536 # flags and ensure that the corresponding %disabled elements area
1537 # removed to reflect that the sanitizers are indeed enabled.
1538 my %detected_sanitizers = ();
1539 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1540     (my $checks = $_) =~ s/^-fsanitize=//;
1541     foreach (split /,/, $checks) {
1542         my $d = { address       => 'asan',
1543                   undefined     => 'ubsan',
1544                   memory        => 'msan' } -> {$_};
1545         next unless defined $d;
1546
1547         $detected_sanitizers{$d} = 1;
1548         if (defined $disabled{$d}) {
1549             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1550                 if $disabled{$d} ne "default";
1551             delete $disabled{$d};
1552         }
1553     }
1554 }
1555
1556 # If threads still aren't disabled, add a C macro to ensure the source
1557 # code knows about it.  Any other flag is taken care of by the configs.
1558 unless($disabled{threads}) {
1559     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1560 }
1561
1562 if ($disabled{"unstable-qlog"}) {
1563     $disabled{"qlog"} = 1;
1564 }
1565
1566 my $no_shared_warn=0;
1567 if (($target{shared_target} // '') eq "")
1568         {
1569         $no_shared_warn = 1
1570             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1571         disable('no-shared-target', 'pic');
1572         }
1573
1574 if ($disabled{"dynamic-engine"}) {
1575         $config{dynamic_engines} = 0;
1576 } else {
1577         $config{dynamic_engines} = 1;
1578 }
1579
1580 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1581     push @{$config{cflags}}, "-fsanitize=address";
1582 }
1583
1584 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1585     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all", "-DPEDANTIC";
1586 }
1587
1588 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1589   push @{$config{cflags}}, "-fsanitize=memory";
1590 }
1591
1592 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1593         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1594     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1595     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1596 }
1597 #
1598 # Platform fix-ups
1599 #
1600
1601 # This saves the build files from having to check
1602 if ($disabled{pic})
1603         {
1604         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1605                     shared_defines shared_includes shared_ldflag
1606                     module_cflags module_cxxflags module_cppflags
1607                     module_defines module_includes module_lflags))
1608                 {
1609                 delete $config{$_};
1610                 $target{$_} = "";
1611                 }
1612         }
1613 else
1614         {
1615         push @{$config{lib_defines}}, "OPENSSL_PIC";
1616         }
1617
1618 if ($target{sys_id} ne "")
1619         {
1620         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1621         }
1622
1623 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1624 my %predefined_CXX = $config{CXX}
1625     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1626     : ();
1627
1628 unless ($disabled{asm}) {
1629     # big endian systems can use ELFv2 ABI
1630     if ($target eq "linux-ppc64" || $target eq "BSD-ppc64") {
1631         $target{perlasm_scheme} = "linux64v2" if ($predefined_C{_CALL_ELF} == 2);
1632     }
1633 }
1634
1635 # Check for makedepend capabilities.
1636 if (!$disabled{makedepend}) {
1637     # If the attribute makedep_scheme is defined, then we assume that the
1638     # config target and its associated build file are programmed to deal
1639     # with it.
1640     # If makedep_scheme is undefined, we go looking for GCC compatible
1641     # dependency making, and if that's not available, we try to fall back
1642     # on 'makedepend'.
1643     if ($target{makedep_scheme}) {
1644         $config{makedep_scheme} = $target{makedep_scheme};
1645         # If the makedepcmd attribute is defined, copy it.  If not, the
1646         # build files will have to fend for themselves.
1647         $config{makedepcmd} = $target{makedepcmd} if $target{makedepcmd};
1648     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1649              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1650         # We know that GNU C version 3 and up as well as all clang
1651         # versions support dependency generation, but Xcode did not
1652         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1653         $config{makedep_scheme} = 'gcc';
1654     } else {
1655         # In all other cases, we look for 'makedepend', and set the
1656         # makedep_scheme value if we found it.
1657         $config{makedepcmd} = which('makedepend');
1658         $config{makedep_scheme} = 'makedepend' if $config{makedepcmd};
1659     }
1660
1661     # If no depend scheme is set, we disable makedepend
1662     disable('unavailable', 'makedepend') unless $config{makedep_scheme};
1663 }
1664
1665 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1666     # probe for -Wa,--noexecstack option...
1667     if ($predefined_C{__clang__}) {
1668         # clang has builtin assembler, which doesn't recognize --help,
1669         # but it apparently recognizes the option in question on all
1670         # supported platforms even when it's meaningless. In other words
1671         # probe would fail, but probed option always accepted...
1672         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1673     } else {
1674         my $cc = $config{CROSS_COMPILE}.$config{CC};
1675         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1676         while(<PIPE>) {
1677             if (m/--noexecstack/) {
1678                 push @{$config{cflags}}, "-Wa,--noexecstack";
1679                 last;
1680             }
1681         }
1682         close(PIPE);
1683         unlink("null.$$.o");
1684     }
1685 }
1686
1687 # Deal with bn_ops ###################################################
1688
1689 $config{bn_ll}                  =0;
1690 my $def_int="unsigned int";
1691 $config{rc4_int}                =$def_int;
1692 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1693
1694 my $count = 0;
1695 foreach (sort split(/\s+/,$target{bn_ops})) {
1696     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1697     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1698     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1699     ($config{b64l},$config{b64},$config{b32})
1700         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1701     ($config{b64l},$config{b64},$config{b32})
1702         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1703     ($config{b64l},$config{b64},$config{b32})
1704         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1705 }
1706 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1707     if $count > 1;
1708
1709 $config{api} = $config{major} * 10000 + $config{minor} * 100
1710     unless $config{api};
1711 foreach (keys %$apitable) {
1712     $disabled{"deprecated-$_"} = "deprecation"
1713         if $disabled{deprecated} && $config{api} >= $apitable->{$_};
1714 }
1715
1716 disable();                      # Run a cascade now
1717
1718 # Hack cflags for better warnings (dev option) #######################
1719
1720 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1721 # a string and works as well on command lines.
1722 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1723                         @{$config{cflags}} ];
1724 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1725                           @{$config{cxxflags}} ] if $config{CXX};
1726
1727 $config{openssl_api_defines} = [
1728     "OPENSSL_CONFIGURED_API=".$config{api},
1729 ];
1730
1731 my @strict_warnings_collection=();
1732 if ($strict_warnings)
1733         {
1734         my $wopt;
1735         my $gccver = $predefined_C{__GNUC__} // -1;
1736
1737         if ($gccver >= 4)
1738                 {
1739                 push @strict_warnings_collection, @gcc_devteam_warn;
1740                 push @strict_warnings_collection, @clang_devteam_warn
1741                     if (defined($predefined_C{__clang__}));
1742                 }
1743         elsif ($config{target} =~ /^VC-/)
1744                 {
1745                 push @strict_warnings_collection, @cl_devteam_warn;
1746                 }
1747         else
1748                 {
1749                 warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike, or MSVC"
1750                 }
1751         }
1752
1753 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1754                               ? @strict_warnings_collection
1755                               : ( $_ ) }
1756                     @{$config{CFLAGS}} ];
1757
1758 unless ($disabled{afalgeng}) {
1759     $config{afalgeng}="";
1760     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1761         push @{$config{engdirs}}, "afalg";
1762     } else {
1763         disable('not-linux', 'afalgeng');
1764     }
1765 }
1766
1767 unless ($disabled{devcryptoeng}) {
1768     if ($target =~ m/^BSD/) {
1769         my $maxver = 5*100 + 7;
1770         my $sysstr = `uname -s`;
1771         my $verstr = `uname -r`;
1772         $sysstr =~ s|\R$||;
1773         $verstr =~ s|\R$||;
1774         my ($ma, $mi, @rest) = split m|\.|, $verstr;
1775         my $ver = $ma*100 + $mi;
1776         if ($sysstr eq 'OpenBSD' && $ver >= $maxver) {
1777             disable('too-new-kernel', 'devcryptoeng');
1778         }
1779     }
1780 }
1781
1782 unless ($disabled{ktls}) {
1783     $config{ktls}="";
1784     my $cc = $config{CROSS_COMPILE}.$config{CC};
1785     if ($target =~ m/^linux/) {
1786         system("printf '#include <sys/types.h>\n#include <linux/tls.h>' | $cc -E - >/dev/null 2>&1");
1787         if ($? != 0) {
1788             disable('too-old-kernel', 'ktls');
1789         }
1790     } elsif ($target =~ m/^BSD/) {
1791         system("printf '#include <sys/types.h>\n#include <sys/ktls.h>' | $cc -E - >/dev/null 2>&1");
1792         if ($? != 0) {
1793             disable('too-old-freebsd', 'ktls');
1794         }
1795     } else {
1796         disable('not-linux-or-freebsd', 'ktls');
1797     }
1798 }
1799
1800 unless ($disabled{winstore}) {
1801     unless ($target =~ /^(?:Cygwin|mingw|VC-|BC-)/) {
1802         disable('not-windows', 'winstore');
1803     }
1804 }
1805
1806 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1807
1808 # Get the extra flags used when building shared libraries and modules.  We
1809 # do this late because some of them depend on %disabled.
1810
1811 # Make the flags to build DSOs the same as for shared libraries unless they
1812 # are already defined
1813 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1814 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1815 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1816 {
1817     my $shared_info_pl =
1818         catfile(dirname($0), "Configurations", "shared-info.pl");
1819     my %shared_info = read_eval_file($shared_info_pl);
1820     push @{$target{_conf_fname_int}}, $shared_info_pl;
1821     my $si = $target{shared_target};
1822     while (ref $si ne "HASH") {
1823         last if ! defined $si;
1824         if (ref $si eq "CODE") {
1825             $si = $si->();
1826         } else {
1827             $si = $shared_info{$si};
1828         }
1829     }
1830
1831     # Some of the 'shared_target' values don't have any entries in
1832     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1833     # template knows how to handle this.  That is currently the case for
1834     # Windows and VMS.
1835     if (defined $si) {
1836         # Just as above, copy certain shared_* attributes to the corresponding
1837         # module_ attribute unless the latter is already defined
1838         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1839         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1840         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1841         foreach (sort keys %$si) {
1842             $target{$_} = defined $target{$_}
1843                 ? add($si->{$_})->($target{$_})
1844                 : $si->{$_};
1845         }
1846     }
1847 }
1848
1849 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1850
1851 ######################################################################
1852 # Build up information for skipping certain directories depending on disabled
1853 # features, as well as setting up macros for disabled features.
1854
1855 # This is a tentative database of directories to skip.  Some entries may not
1856 # correspond to anything real, but that's ok, they will simply be ignored.
1857 # The actual processing of these entries is done in the build.info lookup
1858 # loop further down.
1859 #
1860 # The key is a Unix formatted path in the source tree, the value is an index
1861 # into %disabled_info, so any existing path gets added to a corresponding
1862 # 'skipped' entry in there with the list of skipped directories.
1863 my %skipdir = ();
1864 my %disabled_info = ();         # For configdata.pm
1865 foreach my $what (sort keys %disabled) {
1866     # There are deprecated disablables that translate to themselves.
1867     # They cause disabling cascades, but should otherwise not register.
1868     next if $deprecated_disablables{$what};
1869     # The generated $disabled{"deprecated-x.y"} entries are special
1870     # and treated properly elsewhere
1871     next if $what =~ m|^deprecated-|;
1872
1873     $config{options} .= " no-$what";
1874
1875     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1876                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1877                                 'sse2', 'legacy' )) {
1878         (my $WHAT = uc $what) =~ s|-|_|g;
1879         my $skipdir = $what;
1880
1881         # fix-up crypto/directory name(s)
1882         $skipdir = "ripemd" if $what eq "rmd160";
1883         $skipdir = "whrlpool" if $what eq "whirlpool";
1884
1885         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1886         push @{$config{openssl_feature_defines}}, $macro;
1887
1888         $skipdir{engines} = $what if $what eq 'engine';
1889         $skipdir{"crypto/$skipdir"} = $what
1890             unless $what eq 'async' || $what eq 'err' || $what eq 'dso';
1891     }
1892 }
1893
1894 if ($disabled{"dynamic-engine"}) {
1895     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1896 } else {
1897     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1898 }
1899
1900 # If we use the unified build, collect information from build.info files
1901 my %unified_info = ();
1902
1903 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1904 if ($builder eq "unified") {
1905     use Text::Template 1.46;
1906
1907     sub cleandir {
1908         my $base = shift;
1909         my $dir = shift;
1910         my $relativeto = shift || ".";
1911         my $no_mkpath = shift // 0;
1912
1913         $dir = catdir($base,$dir) unless isabsolute($dir);
1914
1915         # Make sure the directories we're building in exists
1916         mkpath($dir) unless $no_mkpath;
1917
1918         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1919         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1920         return $res;
1921     }
1922
1923     sub cleanfile {
1924         my $base = shift;
1925         my $file = shift;
1926         my $relativeto = shift || ".";
1927         my $no_mkpath = shift // 0;
1928
1929         $file = catfile($base,$file) unless isabsolute($file);
1930
1931         my $d = dirname($file);
1932         my $f = basename($file);
1933
1934         # Make sure the directories we're building in exists
1935         mkpath($d) unless $no_mkpath;
1936
1937         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1938         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1939         return $res;
1940     }
1941
1942     # Store the name of the template file we will build the build file from
1943     # in %config.  This may be useful for the build file itself.
1944     my @build_file_template_names =
1945         ( $builder_platform."-".$config{build_file}.".tmpl",
1946           $config{build_file}.".tmpl" );
1947     my @build_file_templates = ();
1948
1949     # First, look in the user provided directory, if given
1950     if (defined env($local_config_envname)) {
1951         @build_file_templates =
1952             map {
1953                 if ($^O eq 'VMS') {
1954                     # VMS environment variables are logical names,
1955                     # which can be used as is
1956                     $local_config_envname . ':' . $_;
1957                 } else {
1958                     catfile(env($local_config_envname), $_);
1959                 }
1960             }
1961             @build_file_template_names;
1962     }
1963     # Then, look in our standard directory
1964     push @build_file_templates,
1965         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir, 1) }
1966           @build_file_template_names );
1967
1968     my $build_file_template;
1969     for $_ (@build_file_templates) {
1970         $build_file_template = $_;
1971         last if -f $build_file_template;
1972
1973         $build_file_template = undef;
1974     }
1975     if (!defined $build_file_template) {
1976         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1977     }
1978     $config{build_file_templates}
1979       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1980                     $blddir, 1),
1981            $build_file_template ];
1982
1983     my @build_dirs = ( [ ] );   # current directory
1984
1985     $config{build_infos} = [ ];
1986
1987     # We want to detect configdata.pm in the source tree, so we
1988     # don't use it if the build tree is different.
1989     my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir, 1);
1990
1991     # Any source file that we recognise is placed in this hash table, with
1992     # the list of its intended destinations as value.  When everything has
1993     # been collected, there's a routine that checks that these source files
1994     # exist, or if they are generated, that the generator exists.
1995     my %check_exist = ();
1996     my %check_generate = ();
1997
1998     my %ordinals = ();
1999     while (@build_dirs) {
2000         my @curd = @{shift @build_dirs};
2001         my $sourced = catdir($srcdir, @curd);
2002         my $buildd = catdir($blddir, @curd);
2003
2004         my $unixdir = join('/', @curd);
2005         if (exists $skipdir{$unixdir}) {
2006             my $what = $skipdir{$unixdir};
2007             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
2008             next;
2009         }
2010
2011         mkpath($buildd);
2012
2013         my $f = 'build.info';
2014         # The basic things we're trying to build
2015         my @programs = ();
2016         my @libraries = ();
2017         my @modules = ();
2018         my @scripts = ();
2019
2020         my %sources = ();
2021         my %shared_sources = ();
2022         my %includes = ();
2023         my %defines = ();
2024         my %depends = ();
2025         my %generate = ();
2026         my %imagedocs = ();
2027         my %htmldocs = ();
2028         my %mandocs = ();
2029
2030         # Support for $variablename in build.info files.
2031         # Embedded perl code is the ultimate master, still.  If its output
2032         # contains a dollar sign, it had better be escaped, or it will be
2033         # taken for a variable name prefix.
2034         my %variables = ();
2035         # Variable name syntax
2036         my $variable_name_re = qr/(?P<VARIABLE>[[:alpha:]][[:alnum:]_]*)/;
2037         # Value modifier syntaxes
2038         my $variable_subst_re = qr/\/(?P<RE>(?:\\\/|.)*?)\/(?P<SUBST>.*?)/;
2039         # Variable reference
2040         my $variable_simple_re = qr/(?<!\\)\$${variable_name_re}/;
2041         my $variable_w_mod_re =
2042             qr/(?<!\\)\$\{${variable_name_re}(?P<MOD>(?:\\\/|.)*?)\}/;
2043         # Tie it all together
2044         my $variable_re = qr/${variable_simple_re}|${variable_w_mod_re}/;
2045
2046         my $expand_variables = sub {
2047             my $value = '';
2048             my $value_rest = shift;
2049
2050             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2051                 print STDERR
2052                     "DEBUG[\$expand_variables] Parsed '$value_rest' ...\n"
2053             }
2054
2055             while ($value_rest =~ /${variable_re}/) {
2056                 # We must save important regexp values, because the next
2057                 # regexp clears them
2058                 my $mod = $+{MOD};
2059                 my $variable_value = $variables{$+{VARIABLE}};
2060
2061                 $value_rest = $';
2062                 $value .= $`;
2063
2064                 # Process modifier expressions, if present
2065                 if (defined $mod) {
2066                     if ($mod =~ /^${variable_subst_re}$/) {
2067                         my $re = $+{RE};
2068                         my $subst = $+{SUBST};
2069
2070                         $variable_value =~ s/\Q$re\E/$subst/g;
2071
2072                         if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2073                             print STDERR
2074                                 "DEBUG[\$expand_variables] ... and substituted ",
2075                                 "'$re' with '$subst'\n";
2076                         }
2077                     }
2078                 }
2079
2080                 $value .= $variable_value;
2081             }
2082             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2083                 print STDERR
2084                     "DEBUG[\$expand_variables] ... into: '$value$value_rest'\n";
2085             }
2086             return $value . $value_rest;
2087         };
2088
2089         # Support for attributes in build.info files
2090         my %attributes = ();
2091         my $handle_attributes = sub {
2092             my $attr_str = shift;
2093             my $ref = shift;
2094             my @goals = @_;
2095
2096             return unless defined $attr_str;
2097
2098             my @a = tokenize($attr_str, qr|\s*,\s*|);
2099             foreach my $a (@a) {
2100                 my $ac = 1;
2101                 my $ak = $a;
2102                 my $av = 1;
2103                 if ($a =~ m|^(!)?(.*?)\s* = \s*(.*?)$|x) {
2104                     $ac = ! $1;
2105                     $ak = $2;
2106                     $av = $3;
2107                 }
2108                 foreach my $g (@goals) {
2109                     if ($ac) {
2110                         $$ref->{$g}->{$ak} = $av;
2111                     } else {
2112                         delete $$ref->{$g}->{$ak};
2113                     }
2114                 }
2115             }
2116         };
2117
2118         # Support for pushing values on multiple indexes of a given hash
2119         # array.
2120         my $push_to = sub {
2121             my $valueref = shift;
2122             my $index_str = shift; # May be undef or empty
2123             my $attrref = shift;   # May be undef
2124             my $attr_str = shift;
2125             my @values = @_;
2126
2127             if (defined $index_str) {
2128                 my @indexes = ( '' );
2129                 if ($index_str !~ m|^\s*$|) {
2130                     @indexes = tokenize($index_str);
2131                 }
2132                 foreach (@indexes) {
2133                     push @{$valueref->{$_}}, @values;
2134                     if (defined $attrref) {
2135                         $handle_attributes->($attr_str, \$$attrref->{$_},
2136                                              @values);
2137                     }
2138                 }
2139             } else {
2140                 push @$valueref, @values;
2141                 $handle_attributes->($attr_str, $attrref, @values)
2142                     if defined $attrref;
2143             }
2144         };
2145
2146         if ($buildinfo_debug) {
2147             print STDERR "DEBUG: Reading ",catfile($sourced, $f),"\n";
2148         }
2149         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
2150         my $template =
2151             Text::Template->new(TYPE => 'FILE',
2152                                 SOURCE => catfile($sourced, $f),
2153                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
2154         die "Something went wrong with $sourced/$f: $!\n" unless $template;
2155         my @text =
2156             split /^/m,
2157             $template->fill_in(HASH => { config => \%config,
2158                                          target => \%target,
2159                                          disabled => \%disabled,
2160                                          withargs => \%withargs,
2161                                          builddir => abs2rel($buildd, $blddir),
2162                                          sourcedir => abs2rel($sourced, $blddir),
2163                                          buildtop => abs2rel($blddir, $blddir),
2164                                          sourcetop => abs2rel($srcdir, $blddir) },
2165                                DELIMITERS => [ "{-", "-}" ]);
2166
2167         # The top item of this stack has the following values
2168         # -2 positive already run and we found ELSE (following ELSIF should fail)
2169         # -1 positive already run (skip until ENDIF)
2170         # 0 negatives so far (if we're at a condition, check it)
2171         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
2172         # 2 positive ELSE (following ELSIF should fail)
2173         my @skip = ();
2174
2175         # A few useful generic regexps
2176         my $index_re = qr/\[\s*(?P<INDEX>(?:\\.|.)*?)\s*\]/;
2177         my $cond_re = qr/\[\s*(?P<COND>(?:\\.|.)*?)\s*\]/;
2178         my $attribs_re = qr/(?:\{\s*(?P<ATTRIBS>(?:\\.|.)*?)\s*\})?/;
2179         my $value_re = qr/(?P<VALUE>.*?)/;
2180         collect_information(
2181             collect_from_array([ @text ],
2182                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
2183                                                 $l1 =~ s/\\$//; $l1.$l2 }),
2184             # Info we're looking for
2185             qr/^\s* IF ${cond_re} \s*$/x
2186             => sub {
2187                 if (! @skip || $skip[$#skip] > 0) {
2188                     push @skip, !! $expand_variables->($+{COND});
2189                 } else {
2190                     push @skip, -1;
2191                 }
2192             },
2193             qr/^\s* ELSIF ${cond_re} \s*$/x
2194             => sub { die "ELSIF out of scope" if ! @skip;
2195                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
2196                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
2197                      $skip[$#skip] = !! $expand_variables->($+{COND})
2198                          if $skip[$#skip] == 0; },
2199             qr/^\s* ELSE \s*$/x
2200             => sub { die "ELSE out of scope" if ! @skip;
2201                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
2202                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
2203             qr/^\s* ENDIF \s*$/x
2204             => sub { die "ENDIF out of scope" if ! @skip;
2205                      pop @skip; },
2206             qr/^\s* ${variable_re} \s* = \s* ${value_re} \s* $/x
2207             => sub {
2208                 if (!@skip || $skip[$#skip] > 0) {
2209                     $variables{$+{VARIABLE}} = $expand_variables->($+{VALUE});
2210                 }
2211             },
2212             qr/^\s* SUBDIRS \s* = \s* ${value_re} \s* $/x
2213             => sub {
2214                 if (!@skip || $skip[$#skip] > 0) {
2215                     foreach (tokenize($expand_variables->($+{VALUE}))) {
2216                         push @build_dirs, [ @curd, splitdir($_, 1) ];
2217                     }
2218                 }
2219             },
2220             qr/^\s* PROGRAMS ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2221             => sub { $push_to->(\@programs, undef,
2222                                 \$attributes{programs}, $+{ATTRIBS},
2223                                 tokenize($expand_variables->($+{VALUE})))
2224                          if !@skip || $skip[$#skip] > 0; },
2225             qr/^\s* LIBS ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2226             => sub { $push_to->(\@libraries, undef,
2227                                 \$attributes{libraries}, $+{ATTRIBS},
2228                                 tokenize($expand_variables->($+{VALUE})))
2229                          if !@skip || $skip[$#skip] > 0; },
2230             qr/^\s* MODULES ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2231             => sub { $push_to->(\@modules, undef,
2232                                 \$attributes{modules}, $+{ATTRIBS},
2233                                 tokenize($expand_variables->($+{VALUE})))
2234                          if !@skip || $skip[$#skip] > 0; },
2235             qr/^\s* SCRIPTS ${attribs_re} \s* = \s* ${value_re} \s* $/x
2236             => sub { $push_to->(\@scripts, undef,
2237                                 \$attributes{scripts}, $+{ATTRIBS},
2238                                 tokenize($expand_variables->($+{VALUE})))
2239                          if !@skip || $skip[$#skip] > 0; },
2240             qr/^\s* IMAGEDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2241             => sub { $push_to->(\%imagedocs, $expand_variables->($+{INDEX}),
2242                                 undef, undef,
2243                                 tokenize($expand_variables->($+{VALUE})))
2244                          if !@skip || $skip[$#skip] > 0; },
2245             qr/^\s* HTMLDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2246             => sub { $push_to->(\%htmldocs, $expand_variables->($+{INDEX}),
2247                                 undef, undef,
2248                                 tokenize($expand_variables->($+{VALUE})))
2249                          if !@skip || $skip[$#skip] > 0; },
2250             qr/^\s* MANDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2251             => sub { $push_to->(\%mandocs, $expand_variables->($+{INDEX}),
2252                                 undef, undef,
2253                                 tokenize($expand_variables->($+{VALUE})))
2254                          if !@skip || $skip[$#skip] > 0; },
2255             qr/^\s* SOURCE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2256             => sub { $push_to->(\%sources, $expand_variables->($+{INDEX}),
2257                                 \$attributes{sources}, $+{ATTRIBS},
2258                                 tokenize($expand_variables->($+{VALUE})))
2259                          if !@skip || $skip[$#skip] > 0; },
2260             qr/^\s* SHARED_SOURCE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2261             => sub { $push_to->(\%shared_sources, $expand_variables->($+{INDEX}),
2262                                 \$attributes{sources}, $+{ATTRIBS},
2263                                 tokenize($expand_variables->($+{VALUE})))
2264                          if !@skip || $skip[$#skip] > 0; },
2265             qr/^\s* INCLUDE ${index_re} \s* = \s* ${value_re} \s* $/x
2266             => sub { $push_to->(\%includes, $expand_variables->($+{INDEX}),
2267                                 undef, undef,
2268                                 tokenize($expand_variables->($+{VALUE})))
2269                          if !@skip || $skip[$#skip] > 0; },
2270             qr/^\s* DEFINE ${index_re} \s* = \s* ${value_re} \s* $/x
2271             => sub { $push_to->(\%defines, $expand_variables->($+{INDEX}),
2272                                 undef, undef,
2273                                 tokenize($expand_variables->($+{VALUE})))
2274                          if !@skip || $skip[$#skip] > 0; },
2275             qr/^\s* DEPEND ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2276             => sub { $push_to->(\%depends, $expand_variables->($+{INDEX}),
2277                                 \$attributes{depends}, $+{ATTRIBS},
2278                                 tokenize($expand_variables->($+{VALUE})))
2279                          if !@skip || $skip[$#skip] > 0; },
2280             qr/^\s* GENERATE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2281             => sub { $push_to->(\%generate, $expand_variables->($+{INDEX}),
2282                                 \$attributes{generate}, $+{ATTRIBS},
2283                                 $expand_variables->($+{VALUE}))
2284                          if !@skip || $skip[$#skip] > 0; },
2285             qr/^\s* (?:\#.*)? $/x => sub { },
2286             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
2287             "BEFORE" => sub {
2288                 if ($buildinfo_debug) {
2289                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
2290                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2291                 }
2292             },
2293             "AFTER" => sub {
2294                 if ($buildinfo_debug) {
2295                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2296                 }
2297             },
2298             );
2299         die "runaway IF?" if (@skip);
2300
2301         if (grep { defined $attributes{modules}->{$_}->{engine} } keys %attributes
2302                 and !$config{dynamic_engines}) {
2303             die <<"EOF"
2304 ENGINES can only be used if configured with 'dynamic-engine'.
2305 This is usually a fault in a build.info file.
2306 EOF
2307         }
2308
2309         {
2310             my %infos = ( programs  => [ @programs  ],
2311                           libraries => [ @libraries ],
2312                           modules   => [ @modules   ],
2313                           scripts   => [ @scripts   ] );
2314             foreach my $k (keys %infos) {
2315                 foreach (@{$infos{$k}}) {
2316                     my $item = cleanfile($buildd, $_, $blddir);
2317                     $unified_info{$k}->{$item} = 1;
2318
2319                     # Fix up associated attributes
2320                     $unified_info{attributes}->{$k}->{$item} =
2321                         $attributes{$k}->{$_}
2322                         if defined $attributes{$k}->{$_};
2323                 }
2324             }
2325         }
2326
2327         # Check that we haven't defined any library as both shared and
2328         # explicitly static.  That is forbidden.
2329         my @doubles = ();
2330         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2331             (my $l = $_) =~ s/\.a$//;
2332             push @doubles, $l if defined $unified_info{libraries}->{$l};
2333         }
2334         die "these libraries are both explicitly static and shared:\n  ",
2335             join(" ", @doubles), "\n"
2336             if @doubles;
2337
2338         foreach (keys %sources) {
2339             my $dest = $_;
2340             my $ddest = cleanfile($buildd, $_, $blddir);
2341             foreach (@{$sources{$dest}}) {
2342                 my $s = cleanfile($sourced, $_, $blddir, 1);
2343
2344                 # If it's generated or we simply don't find it in the source
2345                 # tree, we assume it's in the build tree.
2346                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2347                     $s = cleanfile($buildd, $_, $blddir);
2348                 }
2349                 my $o = $_;
2350                 # We recognise C++, C and asm files
2351                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2352                     push @{$check_exist{$s}}, $ddest;
2353                     $o =~ s/\.[csS]$/.o/; # C and assembler
2354                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2355                     $o = cleanfile($buildd, $o, $blddir);
2356                     $unified_info{sources}->{$ddest}->{$o} = -1;
2357                     $unified_info{sources}->{$o}->{$s} = -1;
2358                 } elsif ($s =~ /\.rc$/) {
2359                     # We also recognise resource files
2360                     push @{$check_exist{$s}}, $ddest;
2361                     $o =~ s/\.rc$/.res/; # Resource configuration
2362                     $o = cleanfile($buildd, $o, $blddir);
2363                     $unified_info{sources}->{$ddest}->{$o} = -1;
2364                     $unified_info{sources}->{$o}->{$s} = -1;
2365                 } else {
2366                     push @{$check_exist{$s}}, $ddest;
2367                     $unified_info{sources}->{$ddest}->{$s} = 1;
2368                 }
2369                 # Fix up associated attributes
2370                 if ($o ne $_) {
2371                     $unified_info{attributes}->{sources}->{$ddest}->{$o} =
2372                         $unified_info{attributes}->{sources}->{$o}->{$s} =
2373                         $attributes{sources}->{$dest}->{$_}
2374                         if defined $attributes{sources}->{$dest}->{$_};
2375                 } else {
2376                     $unified_info{attributes}->{sources}->{$ddest}->{$s} =
2377                         $attributes{sources}->{$dest}->{$_}
2378                         if defined $attributes{sources}->{$dest}->{$_};
2379                 }
2380             }
2381         }
2382
2383         foreach (keys %shared_sources) {
2384             my $dest = $_;
2385             my $ddest = cleanfile($buildd, $_, $blddir);
2386             foreach (@{$shared_sources{$dest}}) {
2387                 my $s = cleanfile($sourced, $_, $blddir, 1);
2388
2389                 # If it's generated or we simply don't find it in the source
2390                 # tree, we assume it's in the build tree.
2391                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2392                     $s = cleanfile($buildd, $_, $blddir);
2393                 }
2394
2395                 my $o = $_;
2396                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2397                     # We recognise C++, C and asm files
2398                     push @{$check_exist{$s}}, $ddest;
2399                     $o =~ s/\.[csS]$/.o/; # C and assembler
2400                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2401                     $o = cleanfile($buildd, $o, $blddir);
2402                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2403                     $unified_info{sources}->{$o}->{$s} = -1;
2404                 } elsif ($s =~ /\.rc$/) {
2405                     # We also recognise resource files
2406                     push @{$check_exist{$s}}, $ddest;
2407                     $o =~ s/\.rc$/.res/; # Resource configuration
2408                     $o = cleanfile($buildd, $o, $blddir);
2409                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2410                     $unified_info{sources}->{$o}->{$s} = -1;
2411                 } elsif ($s =~ /\.ld$/) {
2412                     # We also recognise linker scripts (or corresponding)
2413                     # We know they are generated files
2414                     push @{$check_exist{$s}}, $ddest;
2415                     $o = cleanfile($buildd, $_, $blddir);
2416                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
2417                 } else {
2418                     die "unrecognised source file type for shared library: $s\n";
2419                 }
2420                 # Fix up associated attributes
2421                 if ($o ne $_) {
2422                     $unified_info{attributes}->{shared_sources}->{$ddest}->{$o} =
2423                         $unified_info{attributes}->{sources}->{$o}->{$s} =
2424                         $attributes{sources}->{$dest}->{$_}
2425                         if defined $attributes{sources}->{$dest}->{$_};
2426                 } else {
2427                     $unified_info{attributes}->{shared_sources}->{$ddest}->{$o} =
2428                         $attributes{sources}->{$dest}->{$_}
2429                         if defined $attributes{sources}->{$dest}->{$_};
2430                 }
2431             }
2432         }
2433
2434         foreach (keys %generate) {
2435             my $dest = $_;
2436             my $ddest = cleanfile($buildd, $_, $blddir);
2437             die "more than one generator for $dest: "
2438                 ,join(" ", @{$generate{$_}}),"\n"
2439                 if scalar @{$generate{$_}} > 1;
2440             my @generator = split /\s+/, $generate{$dest}->[0];
2441             my $gen = $generator[0];
2442             $generator[0] = cleanfile($sourced, $gen, $blddir, 1);
2443
2444             # If the generator is itself generated, it's in the build tree
2445             if ($generate{$gen} || ! -f $generator[0]) {
2446                 $generator[0] = cleanfile($buildd, $gen, $blddir);
2447             }
2448             $check_generate{$ddest}->{$generator[0]}++;
2449
2450             $unified_info{generate}->{$ddest} = [ @generator ];
2451             # Fix up associated attributes
2452             $unified_info{attributes}->{generate}->{$ddest} =
2453                 $attributes{generate}->{$dest}->{$gen}
2454                 if defined $attributes{generate}->{$dest}->{$gen};
2455         }
2456
2457         foreach (keys %depends) {
2458             my $dest = $_;
2459             my $ddest = $dest;
2460
2461             if ($dest =~ /^\|(.*)\|$/) {
2462                 # Collect the raw target
2463                 $unified_info{targets}->{$1} = 1;
2464                 $ddest = $1;
2465             } elsif ($dest eq '') {
2466                 $ddest = '';
2467             } else {
2468                 $ddest = cleanfile($sourced, $dest, $blddir, 1);
2469
2470                 # If the destination doesn't exist in source, it can only be
2471                 # a generated file in the build tree.
2472                 if ($ddest eq $src_configdata || ! -f $ddest) {
2473                     $ddest = cleanfile($buildd, $dest, $blddir);
2474                 }
2475             }
2476             foreach my $f (@{$depends{$dest}}) {
2477                 # If the dependency destination is generated, dependencies
2478                 # may have an extra syntax to separate the intended inclusion
2479                 # directory from the module to be loaded: a | instead of a
2480                 # / as directory separator.
2481                 # Do note that this has to be handled in the build file
2482                 # template as well.
2483                 # $i = inclusion path in source directory
2484                 # $i2 = inclusion path in build directory
2485                 # $m = module path (within the inclusion path)
2486                 # $i = full module path in source directory
2487                 # $i2 = full module path in build directory
2488                 my $i; my $i2; my $m; my $d; my $d2;
2489                 if ($unified_info{generate}->{$ddest}
2490                     && $f =~ m/^(.*?)\|(.*)$/) {
2491                     $i = $1;
2492                     $m = $2;
2493                     # We must be very careful to modify $i last
2494                     $d = cleanfile($sourced, "$i/$m", $blddir, 1);
2495                     $d2 = cleanfile($buildd, "$i/$m", $blddir);
2496                     $i2 = cleandir($buildd, $i, $blddir);
2497                     $i = cleandir($sourced, $i, $blddir, 1);
2498                 } else {
2499                     $d = cleanfile($sourced, $f, $blddir, 1);
2500                     $d2 = cleanfile($buildd, $f, $blddir);
2501                 }
2502
2503                 # If we know it's generated, or assume it is because we can't
2504                 # find it in the source tree, we set file we depend on to be
2505                 # in the build tree rather than the source tree.
2506                 if ($d eq $src_configdata
2507                     || (grep { $d2 eq $_ }
2508                         keys %{$unified_info{generate}})
2509                     || ! -f $d) {
2510                     $d = $d2;
2511                     $i = $i2;
2512                 }
2513                 if ($i) {
2514                     # Put together the computed inclusion dir with the
2515                     # original module name.  Do note that we conserve the
2516                     # Unixly path syntax for the module path.
2517                     $d = "$i|$m";
2518                 }
2519                 $unified_info{depends}->{$ddest}->{$d} = 1;
2520
2521                 # Fix up associated attributes
2522                 $unified_info{attributes}->{depends}->{$ddest}->{$d} =
2523                     $attributes{depends}->{$dest}->{$f}
2524                     if defined $attributes{depends}->{$dest}->{$f};
2525             }
2526         }
2527
2528         foreach (keys %includes) {
2529             my $dest = $_;
2530             my $ddest = cleanfile($sourced, $_, $blddir, 1);
2531
2532             # If the destination doesn't exist in source, it can only be
2533             # a generated file in the build tree.
2534             if ($ddest eq $src_configdata || ! -f $ddest) {
2535                 $ddest = cleanfile($buildd, $_, $blddir);
2536             }
2537             foreach (@{$includes{$dest}}) {
2538                 my $is = cleandir($sourced, $_, $blddir, 1);
2539                 my $ib = cleandir($buildd, $_, $blddir);
2540                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2541                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2542                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2543                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2544             }
2545         }
2546
2547         foreach my $dest (keys %defines) {
2548             my $ddest;
2549
2550             if ($dest ne "") {
2551                 $ddest = cleanfile($sourced, $dest, $blddir, 1);
2552
2553                 # If the destination doesn't exist in source, it can only
2554                 # be a generated file in the build tree.
2555                 if (! -f $ddest) {
2556                     $ddest = cleanfile($buildd, $dest, $blddir);
2557                 }
2558             }
2559             foreach my $v (@{$defines{$dest}}) {
2560                 $v =~ m|^([^=]*)(=.*)?$|;
2561                 die "0 length macro name not permitted\n" if $1 eq "";
2562                 if ($dest ne "") {
2563                     die "$1 defined more than once\n"
2564                         if defined $unified_info{defines}->{$ddest}->{$1};
2565                     $unified_info{defines}->{$ddest}->{$1} = $2;
2566                 } else {
2567                     die "$1 defined more than once\n"
2568                         if grep { $v eq $_ } @{$config{defines}};
2569                     push @{$config{defines}}, $v;
2570                 }
2571             }
2572         }
2573
2574         foreach my $section (keys %imagedocs) {
2575             foreach (@{$imagedocs{$section}}) {
2576                 my $imagedocs = cleanfile($buildd, $_, $blddir);
2577                 $unified_info{imagedocs}->{$section}->{$imagedocs} = 1;
2578             }
2579         }
2580
2581         foreach my $section (keys %htmldocs) {
2582             foreach (@{$htmldocs{$section}}) {
2583                 my $htmldocs = cleanfile($buildd, $_, $blddir);
2584                 $unified_info{htmldocs}->{$section}->{$htmldocs} = 1;
2585             }
2586         }
2587
2588         foreach my $section (keys %mandocs) {
2589             foreach (@{$mandocs{$section}}) {
2590                 my $mandocs = cleanfile($buildd, $_, $blddir);
2591                 $unified_info{mandocs}->{$section}->{$mandocs} = 1;
2592             }
2593         }
2594     }
2595
2596     my $ordinals_text = join(', ', sort keys %ordinals);
2597     warn <<"EOF" if $ordinals_text;
2598
2599 WARNING: ORDINALS were specified for $ordinals_text
2600 They are ignored and should be replaced with a combination of GENERATE,
2601 DEPEND and SHARED_SOURCE.
2602 EOF
2603
2604     # Check that each generated file is only generated once
2605     my $ambiguous_generation = 0;
2606     foreach (sort keys %check_generate) {
2607         my @generators = sort keys %{$check_generate{$_}};
2608         my $generators_txt = join(', ', @generators);
2609         if (scalar @generators > 1) {
2610             warn "$_ is GENERATEd by more than one generator ($generators_txt)\n";
2611             $ambiguous_generation++;
2612         }
2613         if ($check_generate{$_}->{$generators[0]} > 1) {
2614             warn "INFO: $_ has more than one GENERATE declaration (same generator)\n"
2615         }
2616     }
2617     die "There are ambiguous source file generations\n"
2618         if $ambiguous_generation > 0;
2619
2620     # All given source files should exist, or if generated, their
2621     # generator should exist.  This loop ensures this is true.
2622     my $missing = 0;
2623     foreach my $orig (sort keys %check_exist) {
2624         foreach my $dest (@{$check_exist{$orig}}) {
2625             if ($orig ne $src_configdata) {
2626                 if ($orig =~ /\.a$/) {
2627                     # Static library names may be used as sources, so we
2628                     # need to detect those and give them special treatment.
2629                     unless (grep { $_ eq $orig }
2630                             keys %{$unified_info{libraries}}) {
2631                         warn "$orig is given as source for $dest, but no such library is built\n";
2632                         $missing++;
2633                     }
2634                 } else {
2635                     # A source may be generated, and its generator may be
2636                     # generated as well.  We therefore loop to dig out the
2637                     # first generator.
2638                     my $gen = $orig;
2639
2640                     while (my @next = keys %{$check_generate{$gen}}) {
2641                         $gen = $next[0];
2642                     }
2643
2644                     if (! -f $gen) {
2645                         if ($gen ne $orig) {
2646                             $missing++;
2647                             warn "$orig is given as source for $dest, but its generator (leading to $gen) is missing\n";
2648                         } else {
2649                             $missing++;
2650                             warn "$orig is given as source for $dest, but is missing\n";
2651                         }
2652                     }
2653                 }
2654             }
2655         }
2656     }
2657     die "There are files missing\n" if $missing > 0;
2658
2659     # Go through the sources of all libraries and check that the same basename
2660     # doesn't appear more than once.  Some static library archivers depend on
2661     # them being unique.
2662     {
2663         my $err = 0;
2664         foreach my $prod (keys %{$unified_info{libraries}}) {
2665             my @prod_sources =
2666                 map { keys %{$unified_info{sources}->{$_}} }
2667                 keys %{$unified_info{sources}->{$prod}};
2668             my %srccnt = ();
2669
2670             # Count how many times a given each source basename
2671             # appears for each product.
2672             foreach my $src (@prod_sources) {
2673                 $srccnt{basename $src}++;
2674             }
2675
2676             foreach my $src (keys %srccnt) {
2677                 if ((my $cnt = $srccnt{$src}) > 1) {
2678                     print STDERR "$src appears $cnt times for the product $prod\n";
2679                     $err++
2680                 }
2681             }
2682         }
2683         die if $err > 0;
2684     }
2685
2686     # Massage the result
2687
2688     # If we depend on a header file or a perl module, add an inclusion of
2689     # its directory to allow smoothe inclusion
2690     foreach my $dest (keys %{$unified_info{depends}}) {
2691         next if $dest eq "";
2692         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2693             next unless $d =~ /\.(h|pm)$/;
2694             # Take into account when a dependency uses the inclusion|module
2695             # syntax
2696             my $i = $d =~ m/\|/ ? $` : dirname($d);
2697             my $spot =
2698                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2699                 ? 'build' : 'source';
2700             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2701                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2702         }
2703     }
2704
2705     # Go through all intermediary files and change their names to something that
2706     # reflects what they will be built for.  Note that for some source files,
2707     # this leads to duplicate object files because they are used multiple times.
2708     # the goal is to rename all object files according to this scheme:
2709     #    {productname}-{midfix}-{origobjname}.[o|res]
2710     # the {midfix} is a keyword indicating the type of product, which is mostly
2711     # valuable for libraries since they come in two forms.
2712     #
2713     # This also reorganises the {sources} and {shared_sources} so that the
2714     # former only contains ALL object files that are supposed to end up in
2715     # static libraries and programs, while the latter contains ALL object files
2716     # that are supposed to end up in shared libraries and DSOs.
2717     # The main reason for having two different source structures is to allow
2718     # the same name to be used for the static and the shared variants of a
2719     # library.
2720     {
2721         # Take copies so we don't get interference from added stuff
2722         my %unified_copy = ();
2723         foreach (('sources', 'shared_sources')) {
2724             $unified_copy{$_} = { %{$unified_info{$_}} }
2725                 if defined($unified_info{$_});
2726             delete $unified_info{$_};
2727         }
2728         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2729             # $intent serves multi purposes:
2730             # - give a prefix for the new object files names
2731             # - in the case of libraries, rearrange the object files so static
2732             #   libraries use the 'sources' structure exclusively, while shared
2733             #   libraries use the 'shared_sources' structure exclusively.
2734             my $intent = {
2735                 programs  => { bin    => { src => [ 'sources' ],
2736                                            dst => 'sources' } },
2737                 libraries => { lib    => { src => [ 'sources' ],
2738                                            dst => 'sources' },
2739                                shlib  => { prodselect =>
2740                                                sub { grep !/\.a$/, @_ },
2741                                            src => [ 'sources',
2742                                                     'shared_sources' ],
2743                                            dst => 'shared_sources' } },
2744                 modules   => { dso    => { src => [ 'sources' ],
2745                                            dst => 'sources' } },
2746                 scripts   => { script => { src => [ 'sources' ],
2747                                            dst => 'sources' } }
2748                } -> {$prodtype};
2749             foreach my $kind (keys %$intent) {
2750                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2751                              && $disabled{shared});
2752
2753                 my @src = @{$intent->{$kind}->{src}};
2754                 my $dst = $intent->{$kind}->{dst};
2755                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2756                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2757                     # %prod_sources has all applicable objects as keys, and
2758                     # their corresponding sources as values
2759                     my %prod_sources =
2760                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2761                         map { keys %{$unified_copy{$_}->{$prod}} }
2762                         @src;
2763                     foreach (keys %prod_sources) {
2764                         # Only affect object files and resource files,
2765                         # the others simply get a new value
2766                         # (+1 instead of -1)
2767                         if ($_ =~ /\.(o|res)$/) {
2768                             (my $prodname = $prod) =~ s|\.a$||;
2769                             my $newobj =
2770                                 catfile(dirname($_),
2771                                         basename($prodname)
2772                                             . '-' . $kind
2773                                             . '-' . basename($_));
2774                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2775                             foreach my $src (@{$prod_sources{$_}}) {
2776                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2777                                 # Adjust source attributes
2778                                 my $attrs = $unified_info{attributes}->{sources};
2779                                 if (defined $attrs->{$prod}
2780                                     && defined $attrs->{$prod}->{$_}) {
2781                                     $attrs->{$prod}->{$newobj} =
2782                                         $attrs->{$prod}->{$_};
2783                                     delete $attrs->{$prod}->{$_};
2784                                 }
2785                                 foreach my $objsrc (keys %{$attrs->{$_} // {}}) {
2786                                     $attrs->{$newobj}->{$objsrc} =
2787                                         $attrs->{$_}->{$objsrc};
2788                                     delete $attrs->{$_}->{$objsrc};
2789                                 }
2790                             }
2791                             # Adjust dependencies
2792                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2793                                 $unified_info{depends}->{$_}->{$deps} = -1;
2794                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2795                             }
2796                             # Adjust includes
2797                             foreach my $k (('source', 'build')) {
2798                                 next unless
2799                                     defined($unified_info{includes}->{$_}->{$k});
2800                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2801                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2802                             }
2803                         } else {
2804                             $unified_info{$dst}->{$prod}->{$_} = 1;
2805                         }
2806                     }
2807                 }
2808             }
2809         }
2810     }
2811
2812     # At this point, we have a number of sources with the value -1.  They
2813     # aren't part of the local build and are probably meant for a different
2814     # platform, and can therefore be cleaned away.  That happens when making
2815     # %unified_info more efficient below.
2816
2817     ### Make unified_info a bit more efficient
2818     # One level structures
2819     foreach (("programs", "libraries", "modules", "scripts", "targets")) {
2820         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2821     }
2822     # Two level structures
2823     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends",
2824                      "imagedocs", "htmldocs", "mandocs")) {
2825         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2826             my @items =
2827                 sort
2828                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2829                 keys %{$unified_info{$l1}->{$l2}};
2830             if (@items) {
2831                 $unified_info{$l1}->{$l2} = [ @items ];
2832             } else {
2833                 delete $unified_info{$l1}->{$l2};
2834             }
2835         }
2836     }
2837     # Defines
2838     foreach my $dest (sort keys %{$unified_info{defines}}) {
2839         $unified_info{defines}->{$dest}
2840             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2841                 sort keys %{$unified_info{defines}->{$dest}} ];
2842     }
2843     # Includes
2844     foreach my $dest (sort keys %{$unified_info{includes}}) {
2845         if (defined($unified_info{includes}->{$dest}->{build})) {
2846             my @source_includes = ();
2847             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2848                 if defined($unified_info{includes}->{$dest}->{source});
2849             $unified_info{includes}->{$dest} =
2850                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2851             foreach my $inc (@source_includes) {
2852                 push @{$unified_info{includes}->{$dest}}, $inc
2853                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2854             }
2855         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2856             $unified_info{includes}->{$dest} =
2857                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2858         } else {
2859             delete $unified_info{includes}->{$dest};
2860         }
2861     }
2862
2863     # For convenience collect information regarding directories where
2864     # files are generated, those generated files and the end product
2865     # they end up in where applicable.  Then, add build rules for those
2866     # directories
2867     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2868                      "dso" => [ @{$unified_info{modules}} ],
2869                      "bin" => [ @{$unified_info{programs}} ],
2870                      "script" => [ @{$unified_info{scripts}} ],
2871                      "docs" => [ (map { @{$unified_info{imagedocs}->{$_} // []} }
2872                                   keys %{$unified_info{imagedocs} // {}}),
2873                                  (map { @{$unified_info{htmldocs}->{$_} // []} }
2874                                   keys %{$unified_info{htmldocs} // {}}),
2875                                  (map { @{$unified_info{mandocs}->{$_} // []} }
2876                                   keys %{$unified_info{mandocs} // {}}) ] );
2877     foreach my $type (sort keys %loopinfo) {
2878         foreach my $product (@{$loopinfo{$type}}) {
2879             my %dirs = ();
2880             my $pd = dirname($product);
2881
2882             foreach (@{$unified_info{sources}->{$product} // []},
2883                      @{$unified_info{shared_sources}->{$product} // []}) {
2884                 my $d = dirname($_);
2885
2886                 # We don't want to create targets for source directories
2887                 # when building out of source
2888                 next if ($config{sourcedir} ne $config{builddir}
2889                              && $d =~ m|^\Q$config{sourcedir}\E|);
2890                 # We already have a "test" target, and the current directory
2891                 # is just silly to make a target for
2892                 next if $d eq "test" || $d eq ".";
2893
2894                 $dirs{$d} = 1;
2895                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2896                     if $d ne $pd;
2897             }
2898             foreach (sort keys %dirs) {
2899                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2900                     $product;
2901             }
2902         }
2903     }
2904 }
2905
2906 # For the schemes that need it, we provide the old *_obj configs
2907 # from the *_asm_obj ones
2908 foreach (grep /_(asm|aux)_src$/, keys %target) {
2909     my $src = $_;
2910     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2911     $target{$obj} = $target{$src};
2912     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2913     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2914 }
2915
2916 # Write down our configuration where it fits #########################
2917
2918 my %template_vars = (
2919     config => \%config,
2920     target => \%target,
2921     disablables => \@disablables,
2922     disablables_int => \@disablables_int,
2923     disabled => \%disabled,
2924     withargs => \%withargs,
2925     unified_info => \%unified_info,
2926     tls => \@tls,
2927     dtls => \@dtls,
2928     makevars => [ sort keys %user ],
2929     disabled_info => \%disabled_info,
2930     user_crossable => \@user_crossable,
2931 );
2932 my $configdata_outname = 'configdata.pm';
2933 open CONFIGDATA, ">$configdata_outname.new"
2934     or die "Trying to create $configdata_outname.new: $!";
2935 my $configdata_tmplname = cleanfile($srcdir, "configdata.pm.in", $blddir, 1);
2936 my $configdata_tmpl =
2937     OpenSSL::Template->new(TYPE => 'FILE', SOURCE => $configdata_tmplname);
2938 $configdata_tmpl->fill_in(
2939     FILENAME => $configdata_tmplname,
2940     OUTPUT => \*CONFIGDATA,
2941     HASH => { %template_vars,
2942               autowarntext => [
2943                   'WARNING: do not edit!',
2944                   "Generated by Configure from $configdata_tmplname",
2945               ] }
2946 ) or die $Text::Template::ERROR;
2947 close CONFIGDATA;
2948
2949 rename "$configdata_outname.new", $configdata_outname;
2950 if ($builder_platform eq 'unix') {
2951     my $mode = (0755 & ~umask);
2952     chmod $mode, 'configdata.pm'
2953         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2954 }
2955 print "Created $configdata_outname\n";
2956
2957 print "Running $configdata_outname\n";
2958 my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
2959 my $cmd = "$perlcmd $configdata_outname";
2960 #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2961 system($cmd);
2962 exit 1 if $? != 0;
2963
2964 $SIG{__DIE__} = $orig_death_handler;
2965
2966 print <<"EOF" if ($disabled{threads} eq "unavailable");
2967
2968 The library could not be configured for supporting multi-threaded
2969 applications as the compiler options required on this system are not known.
2970 See file INSTALL.md for details if you need multi-threading.
2971 EOF
2972
2973 print <<"EOF" if ($no_shared_warn);
2974
2975 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2976 platform, so we will pretend you gave the option 'no-pic', which also disables
2977 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2978 or position independent code, please let us know (but please first make sure
2979 you have tried with a current version of OpenSSL).
2980 EOF
2981
2982 print $banner;
2983
2984 exit(0);
2985
2986 ######################################################################
2987 #
2988 # Helpers and utility functions
2989 #
2990
2991 # Death handler, to print a helpful message in case of failure #######
2992 #
2993 sub death_handler {
2994     die @_ if $^S;              # To prevent the added message in eval blocks
2995     my $build_file = $config{build_file} // "build file";
2996     my @message = ( <<"_____", @_ );
2997
2998 Failure!  $build_file wasn't produced.
2999 Please read INSTALL.md and associated NOTES-* files.  You may also have to
3000 look over your available compiler tool chain or change your configuration.
3001
3002 _____
3003
3004     # Dying is terminal, so it's ok to reset the signal handler here.
3005     $SIG{__DIE__} = $orig_death_handler;
3006     die @message;
3007 }
3008
3009 # Configuration file reading #########################################
3010
3011 # Note: All of the helper functions are for lazy evaluation.  They all
3012 # return a CODE ref, which will return the intended value when evaluated.
3013 # Thus, whenever there's mention of a returned value, it's about that
3014 # intended value.
3015
3016 # Helper function to implement conditional value variants, with a default
3017 # plus additional values based on the value of $config{build_type}.
3018 # Arguments are given in hash table form:
3019 #
3020 #       picker(default => "Basic string: ",
3021 #              debug   => "debug",
3022 #              release => "release")
3023 #
3024 # When configuring with --debug, the resulting string will be
3025 # "Basic string: debug", and when not, it will be "Basic string: release"
3026 #
3027 # This can be used to create variants of sets of flags according to the
3028 # build type:
3029 #
3030 #       cflags => picker(default => "-Wall",
3031 #                        debug   => "-g -O0",
3032 #                        release => "-O3")
3033 #
3034 sub picker {
3035     my %opts = @_;
3036     return sub { add($opts{default} || (),
3037                      $opts{$config{build_type}} || ())->(); }
3038 }
3039
3040 # Helper function to combine several values of different types into one.
3041 # This is useful if you want to combine a string with the result of a
3042 # lazy function, such as:
3043 #
3044 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
3045 #
3046 sub combine {
3047     my @stuff = @_;
3048     return sub { add(@stuff)->(); }
3049 }
3050
3051 # Helper function to implement conditional values depending on the value
3052 # of $disabled{threads}.  Can be used as follows:
3053 #
3054 #       cflags => combine("-Wall", threads("-pthread"))
3055 #
3056 sub threads {
3057     my @flags = @_;
3058     return sub { add($disabled{threads} ? () : @flags)->(); }
3059 }
3060
3061 sub shared {
3062     my @flags = @_;
3063     return sub { add($disabled{shared} ? () : @flags)->(); }
3064 }
3065
3066 our $add_called = 0;
3067 # Helper function to implement adding values to already existing configuration
3068 # values.  It handles elements that are ARRAYs, CODEs and scalars
3069 sub _add {
3070     my $separator = shift;
3071
3072     # If there's any ARRAY in the collection of values OR the separator
3073     # is undef, we will return an ARRAY of combined values, otherwise a
3074     # string of joined values with $separator as the separator.
3075     my $found_array = !defined($separator);
3076
3077     my @values =
3078         map {
3079             my $res = $_;
3080             while (ref($res) eq "CODE") {
3081                 $res = $res->();
3082             }
3083             if (defined($res)) {
3084                 if (ref($res) eq "ARRAY") {
3085                     $found_array = 1;
3086                     @$res;
3087                 } else {
3088                     $res;
3089                 }
3090             } else {
3091                 ();
3092             }
3093     } (@_);
3094
3095     $add_called = 1;
3096
3097     if ($found_array) {
3098         [ @values ];
3099     } else {
3100         join($separator, grep { defined($_) && $_ ne "" } @values);
3101     }
3102 }
3103 sub add_before {
3104     my $separator = " ";
3105     if (ref($_[$#_]) eq "HASH") {
3106         my $opts = pop;
3107         $separator = $opts->{separator};
3108     }
3109     my @x = @_;
3110     sub { _add($separator, @x, @_) };
3111 }
3112 sub add {
3113     my $separator = " ";
3114     if (ref($_[$#_]) eq "HASH") {
3115         my $opts = pop;
3116         $separator = $opts->{separator};
3117     }
3118     my @x = @_;
3119     sub { _add($separator, @_, @x) };
3120 }
3121
3122 sub read_eval_file {
3123     my $fname = shift;
3124     my $content;
3125     my @result;
3126
3127     open F, "< $fname" or die "Can't open '$fname': $!\n";
3128     {
3129         undef local $/;
3130         $content = <F>;
3131     }
3132     close F;
3133     {
3134         local $@;
3135
3136         @result = ( eval $content );
3137         warn $@ if $@;
3138     }
3139     return wantarray ? @result : $result[0];
3140 }
3141
3142 # configuration reader, evaluates the input file as a perl script and expects
3143 # it to fill %targets with target configurations.  Those are then added to
3144 # %table.
3145 sub read_config {
3146     my $fname = shift;
3147     my %targets;
3148
3149     {
3150         # Protect certain tables from tampering
3151         local %table = ();
3152
3153         %targets = read_eval_file($fname);
3154     }
3155     my %preexisting = ();
3156     foreach (sort keys %targets) {
3157         $preexisting{$_} = 1 if $table{$_};
3158     }
3159     die <<"EOF",
3160 The following config targets from $fname
3161 shadow pre-existing config targets with the same name:
3162 EOF
3163         map { "  $_\n" } sort keys %preexisting
3164         if %preexisting;
3165
3166
3167     # For each target, check that it's configured with a hash table.
3168     foreach (keys %targets) {
3169         if (ref($targets{$_}) ne "HASH") {
3170             if (ref($targets{$_}) eq "") {
3171                 warn "Deprecated target configuration for $_, ignoring...\n";
3172             } else {
3173                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3174             }
3175             delete $targets{$_};
3176         } else {
3177             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3178         }
3179     }
3180
3181     %table = (%table, %targets);
3182
3183 }
3184
3185 # configuration resolver.  Will only resolve all the lazy evaluation
3186 # codeblocks for the chosen target and all those it inherits from,
3187 # recursively
3188 sub resolve_config {
3189     my $target = shift;
3190     my @breadcrumbs = @_;
3191
3192 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3193
3194     if (grep { $_ eq $target } @breadcrumbs) {
3195         die "inherit_from loop!  target backtrace:\n  "
3196             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3197     }
3198
3199     if (!defined($table{$target})) {
3200         warn "Warning! target $target doesn't exist!\n";
3201         return ();
3202     }
3203     # Recurse through all inheritances.  They will be resolved on the
3204     # fly, so when this operation is done, they will all just be a
3205     # bunch of attributes with string values.
3206     # What we get here, though, are keys with references to lists of
3207     # the combined values of them all.  We will deal with lists after
3208     # this stage is done.
3209     my %combined_inheritance = ();
3210     if ($table{$target}->{inherit_from}) {
3211         my @inherit_from =
3212             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3213         foreach (@inherit_from) {
3214             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3215
3216             # 'template' is a marker that's considered private to
3217             # the config that had it.
3218             delete $inherited_config{template};
3219
3220             foreach (keys %inherited_config) {
3221                 if (!$combined_inheritance{$_}) {
3222                     $combined_inheritance{$_} = [];
3223                 }
3224                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3225             }
3226         }
3227     }
3228
3229     # We won't need inherit_from in this target any more, since we've
3230     # resolved all the inheritances that lead to this
3231     delete $table{$target}->{inherit_from};
3232
3233     # Now is the time to deal with those lists.  Here's the place to
3234     # decide what shall be done with those lists, all based on the
3235     # values of the target we're currently dealing with.
3236     # - If a value is a coderef, it will be executed with the list of
3237     #   inherited values as arguments.
3238     # - If the corresponding key doesn't have a value at all or is the
3239     #   empty string, the inherited value list will be run through the
3240     #   default combiner (below), and the result becomes this target's
3241     #   value.
3242     # - Otherwise, this target's value is assumed to be a string that
3243     #   will simply override the inherited list of values.
3244     my $default_combiner = add();
3245
3246     my %all_keys =
3247         map { $_ => 1 } (keys %combined_inheritance,
3248                          keys %{$table{$target}});
3249
3250     sub process_values {
3251         my $object    = shift;
3252         my $inherited = shift;  # Always a [ list ]
3253         my $target    = shift;
3254         my $entry     = shift;
3255
3256         $add_called = 0;
3257
3258         while(ref($object) eq "CODE") {
3259             $object = $object->(@$inherited);
3260         }
3261         if (!defined($object)) {
3262             return ();
3263         }
3264         elsif (ref($object) eq "ARRAY") {
3265             local $add_called;  # To make sure recursive calls don't affect it
3266             return [ map { process_values($_, $inherited, $target, $entry) }
3267                      @$object ];
3268         } elsif (ref($object) eq "") {
3269             return $object;
3270         } else {
3271             die "cannot handle reference type ",ref($object)
3272                 ," found in target ",$target," -> ",$entry,"\n";
3273         }
3274     }
3275
3276     foreach my $key (sort keys %all_keys) {
3277         my $previous = $combined_inheritance{$key};
3278
3279         # Current target doesn't have a value for the current key?
3280         # Assign it the default combiner, the rest of this loop body
3281         # will handle it just like any other coderef.
3282         if (!exists $table{$target}->{$key}) {
3283             $table{$target}->{$key} = $default_combiner;
3284         }
3285
3286         $table{$target}->{$key} = process_values($table{$target}->{$key},
3287                                                $combined_inheritance{$key},
3288                                                $target, $key);
3289         unless(defined($table{$target}->{$key})) {
3290             delete $table{$target}->{$key};
3291         }
3292 #        if ($extra_checks &&
3293 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$key})) {
3294 #            warn "$key got replaced in $target\n";
3295 #        }
3296     }
3297
3298     # Finally done, return the result.
3299     return %{$table{$target}};
3300 }
3301
3302 sub usage
3303         {
3304         print STDERR $usage;
3305         print STDERR "\npick os/compiler from:\n";
3306         my $j=0;
3307         my $i;
3308         my $k=0;
3309         foreach $i (sort keys %table)
3310                 {
3311                 next if $table{$i}->{template};
3312                 next if $i =~ /^debug/;
3313                 $k += length($i) + 1;
3314                 if ($k > 78)
3315                         {
3316                         print STDERR "\n";
3317                         $k=length($i);
3318                         }
3319                 print STDERR $i . " ";
3320                 }
3321         foreach $i (sort keys %table)
3322                 {
3323                 next if $table{$i}->{template};
3324                 next if $i !~ /^debug/;
3325                 $k += length($i) + 1;
3326                 if ($k > 78)
3327                         {
3328                         print STDERR "\n";
3329                         $k=length($i);
3330                         }
3331                 print STDERR $i . " ";
3332                 }
3333         exit(1);
3334         }
3335
3336 sub compiler_predefined {
3337     state %predefined;
3338     my $cc = shift;
3339
3340     return () if $^O eq 'VMS';
3341
3342     die 'compiler_predefined called without a compiler command'
3343         unless $cc;
3344
3345     if (! $predefined{$cc}) {
3346
3347         $predefined{$cc} = {};
3348
3349         # collect compiler pre-defines from gcc or gcc-alike...
3350         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3351         while (my $l = <PIPE>) {
3352             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3353             $predefined{$cc}->{$1} = $2 // '';
3354         }
3355         close(PIPE);
3356     }
3357
3358     return %{$predefined{$cc}};
3359 }
3360
3361 sub which
3362 {
3363     my ($name)=@_;
3364
3365     if (eval { require IPC::Cmd; 1; }) {
3366         IPC::Cmd->import();
3367         return scalar IPC::Cmd::can_run($name);
3368     } else {
3369         # if there is $directories component in splitpath,
3370         # then it's not something to test with $PATH...
3371         return $name if (File::Spec->splitpath($name))[1];
3372
3373         foreach (File::Spec->path()) {
3374             my $fullpath = catfile($_, "$name$target{exe_extension}");
3375             if (-f $fullpath and -x $fullpath) {
3376                 return $fullpath;
3377             }
3378         }
3379     }
3380 }
3381
3382 sub env
3383 {
3384     my $name = shift;
3385     my %opts = @_;
3386
3387     unless ($opts{cacheonly}) {
3388         # Note that if $ENV{$name} doesn't exist or is undefined,
3389         # $config{perlenv}->{$name} will be created with the value
3390         # undef.  This is intentional.
3391
3392         $config{perlenv}->{$name} = $ENV{$name}
3393             if ! exists $config{perlenv}->{$name};
3394     }
3395     return $config{perlenv}->{$name};
3396 }
3397
3398 # Configuration printer ##############################################
3399
3400 sub print_table_entry
3401 {
3402     local $now_printing = shift;
3403     my %target = resolve_config($now_printing);
3404     my $type = shift;
3405
3406     # Don't print the templates
3407     return if $target{template};
3408
3409     my @sequence = (
3410         "sys_id",
3411         "cpp",
3412         "cppflags",
3413         "defines",
3414         "includes",
3415         "cc",
3416         "cflags",
3417         "ld",
3418         "lflags",
3419         "loutflag",
3420         "ex_libs",
3421         "bn_ops",
3422         "enable",
3423         "disable",
3424         "poly1035_asm_src",
3425         "thread_scheme",
3426         "perlasm_scheme",
3427         "dso_scheme",
3428         "shared_target",
3429         "shared_cflag",
3430         "shared_defines",
3431         "shared_ldflag",
3432         "shared_rcflag",
3433         "shared_extension",
3434         "dso_extension",
3435         "obj_extension",
3436         "exe_extension",
3437         "ranlib",
3438         "ar",
3439         "arflags",
3440         "aroutflag",
3441         "rc",
3442         "rcflags",
3443         "rcoutflag",
3444         "mt",
3445         "mtflags",
3446         "mtinflag",
3447         "mtoutflag",
3448         "multilib",
3449         "build_scheme",
3450         );
3451
3452     if ($type eq "TABLE") {
3453         print "\n";
3454         print "*** $now_printing\n";
3455         foreach (@sequence) {
3456             if (ref($target{$_}) eq "ARRAY") {
3457                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3458             } else {
3459                 printf "\$%-12s = %s\n", $_, $target{$_};
3460             }
3461         }
3462     } elsif ($type eq "HASH") {
3463         my $largest =
3464             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3465         print "    '$now_printing' => {\n";
3466         foreach (@sequence) {
3467             if ($target{$_}) {
3468                 if (ref($target{$_}) eq "ARRAY") {
3469                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3470                 } else {
3471                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3472                 }
3473             }
3474         }
3475         print "    },\n";
3476     }
3477 }
3478
3479 # Utility routines ###################################################
3480
3481 # On VMS, if the given file is a logical name, File::Spec::Functions
3482 # will consider it an absolute path.  There are cases when we want a
3483 # purely syntactic check without checking the environment.
3484 sub isabsolute {
3485     my $file = shift;
3486
3487     # On non-platforms, we just use file_name_is_absolute().
3488     return file_name_is_absolute($file) unless $^O eq "VMS";
3489
3490     # If the file spec includes a device or a directory spec,
3491     # file_name_is_absolute() is perfectly safe.
3492     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3493
3494     # Here, we know the given file spec isn't absolute
3495     return 0;
3496 }
3497
3498 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3499 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3500 # realpath() requires that at least all path components except the last is an
3501 # existing directory.  On VMS, the last component of the directory spec must
3502 # exist.
3503 sub absolutedir {
3504     my $dir = shift;
3505
3506     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3507     # will return the volume name for the device, no matter what.  Also,
3508     # it will return an incorrect directory spec if the argument is a
3509     # directory that doesn't exist.
3510     if ($^O eq "VMS") {
3511         return rel2abs($dir);
3512     }
3513
3514     # We use realpath() on Unix, since no other will properly clean out
3515     # a directory spec.
3516     use Cwd qw/realpath/;
3517
3518     return realpath($dir);
3519 }
3520
3521 # Check if all paths are one and the same, using stat.  They must both exist
3522 # We need this for the cases when File::Spec doesn't detect case insensitivity
3523 # (File::Spec::Unix assumes case sensitivity)
3524 sub samedir {
3525     die "samedir expects two arguments\n" unless scalar @_ == 2;
3526
3527     my @stat0 = stat($_[0]);    # First argument
3528     my @stat1 = stat($_[1]);    # Second argument
3529
3530     die "Couldn't stat $_[0]" unless @stat0;
3531     die "Couldn't stat $_[1]" unless @stat1;
3532
3533     # Compare device number
3534     return 0 unless ($stat0[0] == $stat1[0]);
3535     # Compare "inode".  The perl manual recommends comparing as
3536     # string rather than as number.
3537     return 0 unless ($stat0[1] eq $stat1[1]);
3538
3539     return 1;                   # All the same
3540 }
3541
3542 sub quotify {
3543     my %processors = (
3544         perl    => sub { my $x = shift;
3545                          $x =~ s/([\\\$\@"])/\\$1/g;
3546                          return '"'.$x.'"'; },
3547         maybeshell => sub { my $x = shift;
3548                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3549                             if ($x ne $y || $x =~ m|\s|) {
3550                                 return '"'.$y.'"';
3551                             } else {
3552                                 return $x;
3553                             }
3554                         },
3555         );
3556     my $for = shift;
3557     my $processor =
3558         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3559
3560     return map { $processor->($_); } @_;
3561 }
3562
3563 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3564 # $filename is a file name to read from
3565 # $line_concat_cond_re is a regexp detecting a line continuation ending
3566 # $line_concat is a CODEref that takes care of concatenating two lines
3567 sub collect_from_file {
3568     my $filename = shift;
3569     my $line_concat_cond_re = shift;
3570     my $line_concat = shift;
3571
3572     open my $fh, $filename || die "unable to read $filename: $!\n";
3573     return sub {
3574         my $saved_line = "";
3575         $_ = "";
3576         while (<$fh>) {
3577             s|\R$||;
3578             if (defined $line_concat) {
3579                 $_ = $line_concat->($saved_line, $_);
3580                 $saved_line = "";
3581             }
3582             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3583                 $saved_line = $_;
3584                 next;
3585             }
3586             return $_;
3587         }
3588         die "$filename ending with continuation line\n" if $_;
3589         close $fh;
3590         return undef;
3591     }
3592 }
3593
3594 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3595 # $array is an ARRAYref of lines
3596 # $line_concat_cond_re is a regexp detecting a line continuation ending
3597 # $line_concat is a CODEref that takes care of concatenating two lines
3598 sub collect_from_array {
3599     my $array = shift;
3600     my $line_concat_cond_re = shift;
3601     my $line_concat = shift;
3602     my @array = (@$array);
3603
3604     return sub {
3605         my $saved_line = "";
3606         $_ = "";
3607         while (defined($_ = shift @array)) {
3608             s|\R$||;
3609             if (defined $line_concat) {
3610                 $_ = $line_concat->($saved_line, $_);
3611                 $saved_line = "";
3612             }
3613             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3614                 $saved_line = $_;
3615                 next;
3616             }
3617             return $_;
3618         }
3619         die "input text ending with continuation line\n" if $_;
3620         return undef;
3621     }
3622 }
3623
3624 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3625 # $lineiterator is a CODEref that delivers one line at a time.
3626 # All following arguments are regex/CODEref pairs, where the regexp detects a
3627 # line and the CODEref does something with the result of the regexp.
3628 sub collect_information {
3629     my $lineiterator = shift;
3630     my %collectors = @_;
3631
3632     while(defined($_ = $lineiterator->())) {
3633         s|\R$||;
3634         my $found = 0;
3635         if ($collectors{"BEFORE"}) {
3636             $collectors{"BEFORE"}->($_);
3637         }
3638         foreach my $re (keys %collectors) {
3639             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3640                 $collectors{$re}->($lineiterator);
3641                 $found = 1;
3642             };
3643         }
3644         if ($collectors{"OTHERWISE"}) {
3645             $collectors{"OTHERWISE"}->($lineiterator, $_)
3646                 unless $found || !defined $collectors{"OTHERWISE"};
3647         }
3648         if ($collectors{"AFTER"}) {
3649             $collectors{"AFTER"}->($_);
3650         }
3651     }
3652 }
3653
3654 # tokenize($line)
3655 # tokenize($line,$separator)
3656 # $line is a line of text to split up into tokens
3657 # $separator [optional] is a regular expression that separates the tokens,
3658 # the default being spaces.  Do not use quotes of any kind as separators,
3659 # that will give undefined results.
3660 # Returns a list of tokens.
3661 #
3662 # Tokens are divided by separator (spaces by default).  If the tokens include
3663 # the separators, they have to be quoted with single or double quotes.
3664 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3665 # with backslash.
3666 # Basically, the same quoting rules apply for " and ' as in any
3667 # Unix shell.
3668 sub tokenize {
3669     my $line = my $debug_line = shift;
3670     my $separator = shift // qr|\s+|;
3671     my @result = ();
3672
3673     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3674         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3675     }
3676
3677     while ($line =~ s|^${separator}||, $line ne "") {
3678         my $token = "";
3679     again:
3680         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3681         $token .= $1;
3682         $line = $2.$';
3683
3684         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3685             $token .= $1;
3686             $line = $';
3687             goto again;
3688         } elsif ($line =~ m/^'([^']*)'/) {
3689             $token .= $1;
3690             $line = $';
3691             goto again;
3692         }
3693         push @result, $token;
3694     }
3695
3696     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3697         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3698         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3699     }
3700     return @result;
3701 }