Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2022 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::fallback "$FindBin::Bin/external/perl/MODULES.txt";
  21 use OpenSSL::Glob;
  22 use OpenSSL::Template;
  23 use OpenSSL::config;
  24
  25 # see INSTALL.md for instructions.
  26
  27 my $orig_death_handler = $SIG{__DIE__};
  28 $SIG{__DIE__} = \&death_handler;
  29
  30 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  31
  32 my $banner = <<"EOF";
  33
  34 **********************************************************************
  35 ***                                                                ***
  36 ***   OpenSSL has been successfully configured                     ***
  37 ***                                                                ***
  38 ***   If you encounter a problem while building, please open an    ***
  39 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
  40 ***   and include the output from the following command:           ***
  41 ***                                                                ***
  42 ***       perl configdata.pm --dump                                ***
  43 ***                                                                ***
  44 ***   (If you are new to OpenSSL, you might want to consult the    ***
  45 ***   'Troubleshooting' section in the INSTALL.md file first)      ***
  46 ***                                                                ***
  47 **********************************************************************
  48 EOF
  49
  50 # Options:
  51 #
  52 # --config      add the given configuration file, which will be read after
  53 #               any "Configurations*" files that are found in the same
  54 #               directory as this script.
  55 # --prefix      prefix for the OpenSSL installation, which includes the
  56 #               directories bin, lib, include, share/man, share/doc/openssl
  57 #               This becomes the value of INSTALLTOP in Makefile
  58 #               (Default: /usr/local)
  59 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  60 #               If it's a relative directory, it will be added on the directory
  61 #               given with --prefix.
  62 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  63 #               (Default: PREFIX/ssl)
  64 # --banner=".." Output specified text instead of default completion banner
  65 #
  66 # -w            Don't wait after showing a Configure warning
  67 #
  68 # --cross-compile-prefix Add specified prefix to binutils components.
  69 #
  70 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0
  71 #               Define the public APIs as they were for that version
  72 #               including patch releases.  If 'no-deprecated' is also
  73 #               given, do not compile support for interfaces deprecated
  74 #               up to and including the specified OpenSSL version.
  75 #
  76 # no-hw-xxx     do not compile support for specific crypto hardware.
  77 #               Generic OpenSSL-style methods relating to this support
  78 #               are always compiled but return NULL if the hardware
  79 #               support isn't compiled.
  80 # no-hw         do not compile support for any crypto hardware.
  81 # [no-]threads  [don't] try to create a library that is suitable for
  82 #               multithreaded applications (default is "threads" if we
  83 #               know how to do it)
  84 # [no-]shared   [don't] try to create shared libraries when supported.
  85 # [no-]pic      [don't] try to build position independent code when supported.
  86 #               If disabled, it also disables shared and dynamic-engine.
  87 # no-asm        do not use assembler
  88 # no-egd        do not compile support for the entropy-gathering daemon APIs
  89 # [no-]zlib     [don't] compile support for zlib compression.
  90 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  91 #               library and will be loaded in run-time by the OpenSSL library.
  92 # sctp          include SCTP support
  93 # enable-quic   include QUIC support (currently just for developers as the
  94 #               implementation is by no means complete and usable)
  95 # no-uplink     Don't build support for UPLINK interface.
  96 # enable-weak-ssl-ciphers
  97 #               Enable weak ciphers that are disabled by default.
  98 # 386           generate 80386 code in assembly modules
  99 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
 100 #               mentioned '386' option implies this one
 101 # no-<cipher>   build without specified algorithm (dsa, idea, rc5, ...)
 102 # -<xxx> +<xxx> All options which are unknown to the 'Configure' script are
 103 # /<xxx>        passed through to the compiler. Unix-style options beginning
 104 #               with a '-' or '+' are recognized, as well as Windows-style
 105 #               options beginning with a '/'. If the option contains arguments
 106 #               separated by spaces, then the URL-style notation %20 can be
 107 #               used for the space character in order to avoid having to quote
 108 #               the option. For example, -opt%20arg gets expanded to -opt arg.
 109 #               In fact, any ASCII character can be encoded as %xx using its
 110 #               hexadecimal encoding.
 111 # -static       while -static is also a pass-through compiler option (and
 112 #               as such is limited to environments where it's actually
 113 #               meaningful), it triggers a number configuration options,
 114 #               namely no-pic, no-shared and no-threads. It is
 115 #               argued that the only reason to produce statically linked
 116 #               binaries (and in context it means executables linked with
 117 #               -static flag, and not just executables linked with static
 118 #               libcrypto.a) is to eliminate dependency on specific run-time,
 119 #               a.k.a. libc version. The mentioned config options are meant
 120 #               to achieve just that. Unfortunately on Linux it's impossible
 121 #               to eliminate the dependency completely for openssl executable
 122 #               because of getaddrinfo and gethostbyname calls, which can
 123 #               invoke dynamically loadable library facility anyway to meet
 124 #               the lookup requests. For this reason on Linux statically
 125 #               linked openssl executable has rather debugging value than
 126 #               production quality.
 127 #
 128 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
 129 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
 130 # Following are set automatically by this script
 131 #
 132 # MD5_ASM       use some extra md5 assembler,
 133 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 134 # RMD160_ASM    use some extra ripemd160 assembler,
 135 # SHA256_ASM    sha256_block is implemented in assembler
 136 # SHA512_ASM    sha512_block is implemented in assembler
 137 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 138
 139 # Minimum warning options... any contributions to OpenSSL should at least
 140 # get past these.  Note that we only use these with C compilers, not with
 141 # C++ compilers.
 142
 143 # -DPEDANTIC complements -pedantic and is meant to mask code that
 144 # is not strictly standard-compliant and/or implementation-specific,
 145 # e.g. inline assembly, disregards to alignment requirements, such
 146 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 147 # to be used even in sanitized builds, because sanitizer too is
 148 # supposed to and does take notice of non-standard behaviour. Then
 149 # -pedantic with pre-C9x compiler would also complain about 'long
 150 # long' not being supported. As 64-bit algorithms are common now,
 151 # it grew impossible to resolve this without sizeable additional
 152 # code, so we just tell compiler to be pedantic about everything
 153 # but 'long long' type.
 154
 155 my @gcc_devteam_warn = qw(
 156     -DPEDANTIC -pedantic -Wno-long-long -DUNUSEDRESULT_DEBUG
 157     -Wall
 158     -Wmissing-declarations
 159     -Wextra
 160     -Wno-unused-parameter
 161     -Wno-missing-field-initializers
 162     -Wswitch
 163     -Wsign-compare
 164     -Wshadow
 165     -Wformat
 166     -Wtype-limits
 167     -Wundef
 168     -Werror
 169     -Wmissing-prototypes
 170     -Wstrict-prototypes
 171 );
 172
 173 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 174 # TODO(openssl-team): fix problems and investigate if (at least) the
 175 # following warnings can also be enabled:
 176 #       -Wcast-align
 177 #       -Wunreachable-code -- no, too ugly/compiler-specific
 178 #       -Wlanguage-extension-token -- no, we use asm()
 179 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 180 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 181 my @clang_devteam_warn = qw(
 182     -Wno-unknown-warning-option
 183     -Wswitch-default
 184     -Wno-parentheses-equality
 185     -Wno-language-extension-token
 186     -Wno-extended-offsetof
 187     -Wconditional-uninitialized
 188     -Wincompatible-pointer-types-discards-qualifiers
 189     -Wmissing-variable-declarations
 190 );
 191
 192 my @cl_devteam_warn = qw(
 193     /WX
 194 );
 195
 196 my $strict_warnings = 0;
 197
 198 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 199 # which would cover all BSD flavors. -pthread applies to them all,
 200 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 201 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 202 # which has to be accompanied by explicit -D_THREAD_SAFE and
 203 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 204 # seems to be sufficient?
 205 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 206
 207 #
 208 # API compatibility name to version number mapping.
 209 #
 210 my $apitable = {
 211     # This table expresses when API additions or changes can occur.
 212     # The numbering used changes from 3.0 and on because we updated
 213     # (solidified) our version numbering scheme at that point.
 214
 215     # From 3.0 and on, we internalise the given version number in decimal
 216     # as MAJOR * 10000 + MINOR * 100 + 0
 217     "3.0.0" => 30000,
 218     "3.0"   => 30000,
 219
 220     # Note that before 3.0, we didn't have the same version number scheme.
 221     # Still, the numbering we use here covers what we need.
 222     "1.1.1" => 10101,
 223     "1.1.0" => 10100,
 224     "1.0.2" => 10002,
 225     "1.0.1" => 10001,
 226     "1.0.0" => 10000,
 227     "0.9.8" =>   908,
 228 };
 229
 230 # For OpenSSL::config::get_platform
 231 my %guess_opts = ();
 232
 233 my $dryrun = 0;
 234
 235 our %table = ();
 236 our %config = ();
 237 our %withargs = ();
 238 our $now_printing;      # set to current entry's name in print_table_entry
 239                         # (todo: right thing would be to encapsulate name
 240                         # into %target [class] and make print_table_entry
 241                         # a method)
 242
 243 # Forward declarations ###############################################
 244
 245 # read_config(filename)
 246 #
 247 # Reads a configuration file and populates %table with the contents
 248 # (which the configuration file places in %targets).
 249 sub read_config;
 250
 251 # resolve_config(target)
 252 #
 253 # Resolves all the late evaluations, inheritances and so on for the
 254 # chosen target and any target it inherits from.
 255 sub resolve_config;
 256
 257
 258 # Information collection #############################################
 259
 260 # Unified build supports separate build dir
 261 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 262 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 263
 264 # File::Spec::Unix doesn't detect case insensitivity, so we make sure to
 265 # check if the source and build directory are really the same, and make
 266 # them so.  This avoids all kinds of confusion later on.
 267 # We must check @File::Spec::ISA rather than using File::Spec->isa() to
 268 # know if File::Spec ended up loading File::Spec::Unix.
 269 $srcdir = $blddir
 270     if (grep(/::Unix$/, @File::Spec::ISA)
 271         && samedir($srcdir, $blddir));
 272
 273 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 274
 275 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 276
 277 $config{sourcedir} = abs2rel($srcdir, $blddir);
 278 $config{builddir} = abs2rel($blddir, $blddir);
 279 # echo -n 'holy hand grenade of antioch' | openssl sha256
 280 $config{FIPSKEY} =
 281     'f4556650ac31d35461610bac4ed81b1a181b2d8a43ea2854cbae22ca74560813';
 282
 283 # Collect reconfiguration information if needed
 284 my @argvcopy=@ARGV;
 285
 286 if (grep /^reconf(igure)?$/, @argvcopy) {
 287     die "reconfiguring with other arguments present isn't supported"
 288         if scalar @argvcopy > 1;
 289     if (-f "./configdata.pm") {
 290         my $file = "./configdata.pm";
 291         unless (my $return = do $file) {
 292             die "couldn't parse $file: $@" if $@;
 293             die "couldn't do $file: $!"    unless defined $return;
 294             die "couldn't run $file"       unless $return;
 295         }
 296
 297         @argvcopy = defined($configdata::config{perlargv}) ?
 298             @{$configdata::config{perlargv}} : ();
 299         die "Incorrect data to reconfigure, please do a normal configuration\n"
 300             if (grep(/^reconf/,@argvcopy));
 301         $config{perlenv} = $configdata::config{perlenv} // {};
 302     } else {
 303         die "Insufficient data to reconfigure, please do a normal configuration\n";
 304     }
 305 }
 306
 307 $config{perlargv} = [ @argvcopy ];
 308
 309 # Historical: if known directories in crypto/ have been removed, it means
 310 # that those sub-systems are disabled.
 311 # (the other option would be to removed them from the SUBDIRS statement in
 312 # crypto/build.info)
 313 # We reverse the input list for cosmetic purely reasons, to compensate that
 314 # 'unshift' adds at the front of the list (i.e. in reverse input order).
 315 foreach ( reverse sort( 'aes', 'aria', 'bf', 'camellia', 'cast', 'des', 'dh',
 316                         'dsa', 'ec', 'hmac', 'idea', 'md2', 'md5', 'mdc2',
 317                         'rc2', 'rc4', 'rc5', 'ripemd', 'seed', 'sha',
 318                         'sm2', 'sm3', 'sm4') ) {
 319     unshift @argvcopy, "no-$_" if ! -d catdir($srcdir, 'crypto', $_);
 320 }
 321
 322 # Collect version numbers
 323 my %version = ();
 324
 325 collect_information(
 326     collect_from_file(catfile($srcdir,'VERSION.dat')),
 327     qr/\s*(\w+)\s*=\s*(.*?)\s*$/ =>
 328         sub {
 329             # Only define it if there is a value at all
 330             if ($2 ne '') {
 331                 my $k = $1;
 332                 my $v = $2;
 333                 # Some values are quoted.  Trim the quotes
 334                 $v = $1 if $v =~ /^"(.*)"$/;
 335                 $version{uc $k} = $v;
 336             }
 337         },
 338     "OTHERWISE" =>
 339         sub { die "Something wrong with this line:\n$_\nin $srcdir/VERSION.dat" },
 340     );
 341
 342 $config{major} = $version{MAJOR} // 'unknown';
 343 $config{minor} = $version{MINOR} // 'unknown';
 344 $config{patch} = $version{PATCH} // 'unknown';
 345 $config{prerelease} =
 346     defined $version{PRE_RELEASE_TAG} ? "-$version{PRE_RELEASE_TAG}" : '';
 347 $config{build_metadata} =
 348     defined $version{BUILD_METADATA} ? "+$version{BUILD_METADATA}" : '';
 349 $config{shlib_version} = $version{SHLIB_VERSION} // 'unknown';
 350 $config{release_date} = $version{RELEASE_DATE} // 'xx XXX xxxx';
 351
 352 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 353 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 354
 355 die "erroneous version information in VERSION.dat: ",
 356     "$config{version}, $config{shlib_version}\n"
 357     unless (defined $version{MAJOR}
 358             && defined $version{MINOR}
 359             && defined $version{PATCH}
 360             && defined $version{SHLIB_VERSION});
 361
 362 # Collect target configurations
 363
 364 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 365 foreach (sort glob($pattern)) {
 366     &read_config($_);
 367 }
 368
 369 if (defined env($local_config_envname)) {
 370     if ($^O eq 'VMS') {
 371         # VMS environment variables are logical names,
 372         # which can be used as is
 373         $pattern = $local_config_envname . ':' . '*.conf';
 374     } else {
 375         $pattern = catfile(env($local_config_envname), '*.conf');
 376     }
 377
 378     foreach (sort glob($pattern)) {
 379         &read_config($_);
 380     }
 381 }
 382
 383 # Save away perl command information
 384 $config{perl_cmd} = $^X;
 385 $config{perl_version} = $Config{version};
 386 $config{perl_archname} = $Config{archname};
 387
 388 $config{prefix}="";
 389 $config{openssldir}="";
 390 $config{processor}="";
 391 $config{libdir}="";
 392 my $auto_threads=1;    # enable threads automatically? true by default
 393 my $default_ranlib;
 394
 395 # Known TLS and DTLS protocols
 396 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 397 my @dtls = qw(dtls1 dtls1_2);
 398
 399 # Explicitly known options that are possible to disable.  They can
 400 # be regexps, and will be used like this: /^no-${option}$/
 401 # For developers: keep it sorted alphabetically
 402
 403 my @disablables = (
 404     "acvp-tests",
 405     "afalgeng",
 406     "aria",
 407     "asan",
 408     "asm",
 409     "async",
 410     "autoalginit",
 411     "autoerrinit",
 412     "autoload-config",
 413     "bf",
 414     "blake2",
 415     "buildtest-c++",
 416     "bulk",
 417     "cached-fetch",
 418     "camellia",
 419     "capieng",
 420     "winstore",
 421     "cast",
 422     "chacha",
 423     "cmac",
 424     "cmp",
 425     "cms",
 426     "comp",
 427     "crypto-mdebug",
 428     "ct",
 429     "deprecated",
 430     "des",
 431     "devcryptoeng",
 432     "dgram",
 433     "dh",
 434     "dsa",
 435     "dso",
 436     "dtls",
 437     "dynamic-engine",
 438     "ec",
 439     "ec2m",
 440     "ec_nistp_64_gcc_128",
 441     "ecdh",
 442     "ecdsa",
 443     "egd",
 444     "engine",
 445     "err",
 446     "external-tests",
 447     "filenames",
 448     "fips",
 449     "fips-securitychecks",
 450     "fuzz-afl",
 451     "fuzz-libfuzzer",
 452     "gost",
 453     "idea",
 454     "ktls",
 455     "legacy",
 456     "loadereng",
 457     "makedepend",
 458     "md2",
 459     "md4",
 460     "mdc2",
 461     "module",
 462     "msan",
 463     "multiblock",
 464     "nextprotoneg",
 465     "ocb",
 466     "ocsp",
 467     "padlockeng",
 468     "pic",
 469     "pinshared",
 470     "poly1305",
 471     "posix-io",
 472     "psk",
 473     "quic",
 474     "rc2",
 475     "rc4",
 476     "rc5",
 477     "rdrand",
 478     "rfc3779",
 479     "rmd160",
 480     "scrypt",
 481     "sctp",
 482     "secure-memory",
 483     "seed",
 484     "shared",
 485     "siphash",
 486     "siv",
 487     "sm2",
 488     "sm3",
 489     "sm4",
 490     "sock",
 491     "srp",
 492     "srtp",
 493     "sse2",
 494     "ssl",
 495     "ssl-trace",
 496     "static-engine",
 497     "stdio",
 498     "tests",
 499     "tfo",
 500     "threads",
 501     "tls",
 502     "trace",
 503     "ts",
 504     "ubsan",
 505     "ui-console",
 506     "unit-test",
 507     "uplink",
 508     "weak-ssl-ciphers",
 509     "whirlpool",
 510     "zlib",
 511     "zlib-dynamic",
 512     );
 513 foreach my $proto ((@tls, @dtls))
 514         {
 515         push(@disablables, $proto);
 516         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 517         }
 518
 519 # Internal disablables, for aliasing purposes.  They serve no special
 520 # purpose here, but allow scripts to get to know them through configdata.pm,
 521 # where these are merged with @disablables.
 522 # The actual aliasing mechanism is done via %disable_cascades
 523 my @disablables_int = qw(
 524     crmf
 525     );
 526
 527 my %deprecated_disablables = (
 528     "ssl2" => undef,
 529     "buf-freelists" => undef,
 530     "crypto-mdebug-backtrace" => undef,
 531     "hw" => "hw",               # causes cascade, but no macro
 532     "hw-padlock" => "padlockeng",
 533     "ripemd" => "rmd160",
 534     "ui" => "ui-console",
 535     "heartbeats" => undef,
 536     );
 537
 538 # All of the following are disabled by default:
 539
 540 our %disabled = ( # "what"         => "comment"
 541                   "fips"                => "default",
 542                   "asan"                => "default",
 543                   "buildtest-c++"       => "default",
 544                   "crypto-mdebug"       => "default",
 545                   "crypto-mdebug-backtrace" => "default",
 546                   "devcryptoeng"        => "default",
 547                   "ec_nistp_64_gcc_128" => "default",
 548                   "egd"                 => "default",
 549                   "external-tests"      => "default",
 550                   "fuzz-afl"            => "default",
 551                   "fuzz-libfuzzer"      => "default",
 552                   "ktls"                => "default",
 553                   "md2"                 => "default",
 554                   "msan"                => "default",
 555                   "quic"                => "default",
 556                   "rc5"                 => "default",
 557                   "sctp"                => "default",
 558                   "ssl3"                => "default",
 559                   "ssl3-method"         => "default",
 560                   "tfo"                 => "default",
 561                   "trace"               => "default",
 562                   "ubsan"               => "default",
 563                   "unit-test"           => "default",
 564                   "weak-ssl-ciphers"    => "default",
 565                   "zlib"                => "default",
 566                   "zlib-dynamic"        => "default",
 567                 );
 568
 569 # Note: => pair form used for aesthetics, not to truly make a hash table
 570 my @disable_cascades = (
 571     # "what"            => [ "cascade", ... ]
 572     "bulk"              => [ "shared", "dso",
 573                              "aria", "async", "autoload-config",
 574                              "blake2", "bf", "camellia", "cast", "chacha",
 575                              "cmac", "cms", "cmp", "comp", "ct",
 576                              "des", "dgram", "dh", "dsa",
 577                              "ec", "engine",
 578                              "filenames",
 579                              "idea", "ktls",
 580                              "md4", "multiblock", "nextprotoneg",
 581                              "ocsp", "ocb", "poly1305", "psk",
 582                              "rc2", "rc4", "rmd160",
 583                              "seed", "siphash", "siv",
 584                              "sm3", "sm4", "srp",
 585                              "srtp", "ssl3-method", "ssl-trace",
 586                              "tfo",
 587                              "ts", "ui-console", "whirlpool",
 588                              "fips-securitychecks" ],
 589     sub { $config{processor} eq "386" }
 590                         => [ "sse2" ],
 591     "ssl"               => [ "ssl3" ],
 592     "ssl3-method"       => [ "ssl3" ],
 593     "zlib"              => [ "zlib-dynamic" ],
 594     "des"               => [ "mdc2" ],
 595     "ec"                => [ "ec2m", "ecdsa", "ecdh", "sm2", "gost" ],
 596     "dgram"             => [ "dtls", "quic", "sctp" ],
 597     "sock"              => [ "dgram", "tfo" ],
 598     "dtls"              => [ @dtls ],
 599     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 600                         => [ "dtls" ],
 601
 602     "tls"               => [ @tls ],
 603     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 604                         => [ "tls" ],
 605
 606     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 607
 608     # If no modules, then no dynamic engines either
 609     "module"            => [ "dynamic-engine" ],
 610
 611     # Without shared libraries, dynamic engines aren't possible.
 612     # This is due to them having to link with libcrypto and register features
 613     # using the ENGINE functionality, and since that relies on global tables,
 614     # those *have* to be exactly the same as the ones accessed from the app,
 615     # which cannot be guaranteed if shared libraries aren't present.
 616     # (note that even with shared libraries, both the app and dynamic engines
 617     # must be linked with the same library)
 618     "shared"            => [ "dynamic-engine", "uplink" ],
 619     "dso"               => [ "dynamic-engine", "module" ],
 620     # Other modules don't necessarily have to link with libcrypto, so shared
 621     # libraries do not have to be a condition to produce those.
 622
 623     # Without position independent code, there can be no shared libraries
 624     # or modules.
 625     "pic"               => [ "shared", "module" ],
 626
 627     "module"            => [ "fips", "dso" ],
 628
 629     "engine"            => [ "dynamic-engine", grep(/eng$/, @disablables) ],
 630     "dynamic-engine"    => [ "loadereng" ],
 631     "hw"                => [ "padlockeng" ],
 632
 633     # no-autoalginit is only useful when building non-shared
 634     "autoalginit"       => [ "shared", "apps", "fips" ],
 635
 636     "stdio"             => [ "apps", "capieng", "egd" ],
 637     "apps"              => [ "tests" ],
 638     "tests"             => [ "external-tests" ],
 639     "comp"              => [ "zlib" ],
 640     "sm3"               => [ "sm2" ],
 641     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 642
 643     sub { !$disabled{"msan"} } => [ "asm" ],
 644
 645     "cmac"              => [ "siv" ],
 646     "legacy"            => [ "md2" ],
 647
 648     "cmp"               => [ "crmf" ],
 649
 650     "fips"              => [ "fips-securitychecks", "acvp-tests" ],
 651
 652     "deprecated-3.0"    => [ "engine", "srp" ]
 653     );
 654
 655 # Avoid protocol support holes.  Also disable all versions below N, if version
 656 # N is disabled while N+1 is enabled.
 657 #
 658 my @list = (reverse @tls);
 659 while ((my $first, my $second) = (shift @list, shift @list)) {
 660     last unless @list;
 661     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 662                               => [ @list ] );
 663     unshift @list, $second;
 664 }
 665 my @list = (reverse @dtls);
 666 while ((my $first, my $second) = (shift @list, shift @list)) {
 667     last unless @list;
 668     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 669                               => [ @list ] );
 670     unshift @list, $second;
 671 }
 672
 673 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 674 # To remove something from %disabled, use "enable-foo".
 675 # For symmetry, "disable-foo" is a synonym for "no-foo".
 676
 677 # For the "make variables" CPPINCLUDES and CPPDEFINES, we support lists with
 678 # platform specific list separators.  Users from those platforms should
 679 # recognise those separators from how you set up the PATH to find executables.
 680 # The default is the Unix like separator, :, but as an exception, we also
 681 # support the space as separator.
 682 my $list_separator_re =
 683     { VMS           => qr/(?<!\^),/,
 684       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 685 # All the "make variables" we support
 686 # Some get pre-populated for the sake of backward compatibility
 687 # (we supported those before the change to "make variable" support.
 688 my %user = (
 689     AR          => env('AR'),
 690     ARFLAGS     => [],
 691     AS          => undef,
 692     ASFLAGS     => [],
 693     CC          => env('CC'),
 694     CFLAGS      => [ env('CFLAGS') || () ],
 695     CXX         => env('CXX'),
 696     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 697     CPP         => undef,
 698     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 699     CPPDEFINES  => [],  # Alternative for -D
 700     CPPINCLUDES => [],  # Alternative for -I
 701     CROSS_COMPILE => env('CROSS_COMPILE'),
 702     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 703     LD          => undef,
 704     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 705     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 706     MT          => undef,
 707     MTFLAGS     => [],
 708     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 709     RANLIB      => env('RANLIB'),
 710     RC          => env('RC') || env('WINDRES'),
 711     RCFLAGS     => [ env('RCFLAGS') || () ],
 712     RM          => undef,
 713    );
 714 # Info about what "make variables" may be prefixed with the cross compiler
 715 # prefix.  This should NEVER mention any such variable with a list for value.
 716 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 717 # The same but for flags given as Configure options.  These are *additional*
 718 # input, as opposed to the VAR=string option that override the corresponding
 719 # config target attributes
 720 my %useradd = (
 721     CPPDEFINES  => [],
 722     CPPINCLUDES => [],
 723     CPPFLAGS    => [],
 724     CFLAGS      => [],
 725     CXXFLAGS    => [],
 726     LDFLAGS     => [],
 727     LDLIBS      => [],
 728     RCFLAGS     => [],
 729    );
 730
 731 my %user_synonyms = (
 732     HASHBANGPERL=> 'PERL',
 733     RC          => 'WINDRES',
 734    );
 735
 736 # Some target attributes have been renamed, this is the translation table
 737 my %target_attr_translate =(
 738     ar          => 'AR',
 739     as          => 'AS',
 740     cc          => 'CC',
 741     cxx         => 'CXX',
 742     cpp         => 'CPP',
 743     hashbangperl => 'HASHBANGPERL',
 744     ld          => 'LD',
 745     mt          => 'MT',
 746     ranlib      => 'RANLIB',
 747     rc          => 'RC',
 748     rm          => 'RM',
 749    );
 750
 751 # Initialisers coming from 'config' scripts
 752 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 753 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 754 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 755 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 756 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 757 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 758 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 759
 760 $config{openssl_api_defines}=[];
 761 $config{openssl_sys_defines}=[];
 762 $config{openssl_feature_defines}=[];
 763 $config{options}="";
 764 $config{build_type} = "release";
 765 my $target="";
 766
 767 my %cmdvars = ();               # Stores FOO='blah' type arguments
 768 my %unsupported_options = ();
 769 my %deprecated_options = ();
 770 # If you change this, update apps/version.c
 771 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 772 my @seed_sources = ();
 773 while (@argvcopy)
 774         {
 775         $_ = shift @argvcopy;
 776
 777         # Support env variable assignments among the options
 778         if (m|^(\w+)=(.+)?$|)
 779                 {
 780                 $cmdvars{$1} = $2;
 781                 # Every time a variable is given as a configuration argument,
 782                 # it acts as a reset if the variable.
 783                 if (exists $user{$1})
 784                         {
 785                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 786                         }
 787                 #if (exists $useradd{$1})
 788                 #       {
 789                 #       $useradd{$1} = [];
 790                 #       }
 791                 next;
 792                 }
 793
 794         # VMS is a case insensitive environment, and depending on settings
 795         # out of our control, we may receive options uppercased.  Let's
 796         # downcase at least the part before any equal sign.
 797         if ($^O eq "VMS")
 798                 {
 799                 s/^([^=]*)/lc($1)/e;
 800                 }
 801
 802         # some people just can't read the instructions, clang people have to...
 803         s/^-no-(?!integrated-as)/no-/;
 804
 805         # rewrite some options in "enable-..." form
 806         s /^-?-?shared$/enable-shared/;
 807         s /^sctp$/enable-sctp/;
 808         s /^threads$/enable-threads/;
 809         s /^zlib$/enable-zlib/;
 810         s /^zlib-dynamic$/enable-zlib-dynamic/;
 811         s /^fips$/enable-fips/;
 812
 813         if (/^(no|disable|enable)-(.+)$/)
 814                 {
 815                 my $word = $2;
 816                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 817                         && !exists $deprecated_disablables{$word}
 818                         && !grep { $word eq $_ } @disablables)
 819                         {
 820                         $unsupported_options{$_} = 1;
 821                         next;
 822                         }
 823                 }
 824         if (/^no-(.+)$/ || /^disable-(.+)$/)
 825                 {
 826                 foreach my $proto ((@tls, @dtls))
 827                         {
 828                         if ($1 eq "$proto-method")
 829                                 {
 830                                 $disabled{"$proto"} = "option($proto-method)";
 831                                 last;
 832                                 }
 833                         }
 834                 if ($1 eq "dtls")
 835                         {
 836                         foreach my $proto (@dtls)
 837                                 {
 838                                 $disabled{$proto} = "option(dtls)";
 839                                 }
 840                         $disabled{"dtls"} = "option(dtls)";
 841                         }
 842                 elsif ($1 eq "ssl")
 843                         {
 844                         # Last one of its kind
 845                         $disabled{"ssl3"} = "option(ssl)";
 846                         }
 847                 elsif ($1 eq "tls")
 848                         {
 849                         # XXX: Tests will fail if all SSL/TLS
 850                         # protocols are disabled.
 851                         foreach my $proto (@tls)
 852                                 {
 853                                 $disabled{$proto} = "option(tls)";
 854                                 }
 855                         }
 856                 elsif ($1 eq "static-engine")
 857                         {
 858                         delete $disabled{"dynamic-engine"};
 859                         }
 860                 elsif ($1 eq "dynamic-engine")
 861                         {
 862                         $disabled{"dynamic-engine"} = "option";
 863                         }
 864                 elsif (exists $deprecated_disablables{$1})
 865                         {
 866                         $deprecated_options{$_} = 1;
 867                         if (defined $deprecated_disablables{$1})
 868                                 {
 869                                 $disabled{$deprecated_disablables{$1}} = "option";
 870                                 }
 871                         }
 872                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 873                         {
 874                         $deprecated_options{$_} = 1;
 875                         }
 876                 else
 877                         {
 878                         $disabled{$1} = "option";
 879                         }
 880                 # No longer an automatic choice
 881                 $auto_threads = 0 if ($1 eq "threads");
 882                 }
 883         elsif (/^enable-(.+)$/)
 884                 {
 885                 if ($1 eq "static-engine")
 886                         {
 887                         $disabled{"dynamic-engine"} = "option";
 888                         }
 889                 elsif ($1 eq "dynamic-engine")
 890                         {
 891                         delete $disabled{"dynamic-engine"};
 892                         }
 893                 elsif ($1 eq "zlib-dynamic")
 894                         {
 895                         delete $disabled{"zlib"};
 896                         }
 897                 my $algo = $1;
 898                 delete $disabled{$algo};
 899
 900                 # No longer an automatic choice
 901                 $auto_threads = 0 if ($1 eq "threads");
 902                 }
 903         elsif (/^-d$/)          # From older 'config'
 904                 {
 905                 $config{build_type} = "debug";
 906                 }
 907         elsif (/^-v$/)          # From older 'config'
 908                 {
 909                 $guess_opts{verbose} = 1;
 910                 }
 911         elsif (/^-w$/)
 912                 {
 913                 $guess_opts{nowait} = 1;
 914                 }
 915         elsif (/^-t$/)          # From older 'config'
 916                 {
 917                 $dryrun = 1;
 918                 }
 919         elsif (/^--strict-warnings$/)
 920                 {
 921                 # Pretend that our strict flags is a C flag, and replace it
 922                 # with the proper flags later on
 923                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 924                 $strict_warnings=1;
 925                 }
 926         elsif (/^--debug$/)
 927                 {
 928                 $config{build_type} = "debug";
 929                 }
 930         elsif (/^--release$/)
 931                 {
 932                 $config{build_type} = "release";
 933                 }
 934         elsif (/^386$/)
 935                 { $config{processor}=386; }
 936         elsif (/^rsaref$/)
 937                 {
 938                 # No RSAref support any more since it's not needed.
 939                 # The check for the option is there so scripts aren't
 940                 # broken
 941                 }
 942         elsif (m|^[-+/]|)
 943                 {
 944                 if (/^--prefix=(.*)$/)
 945                         {
 946                         $config{prefix}=$1;
 947                         die "Directory given with --prefix MUST be absolute\n"
 948                                 unless file_name_is_absolute($config{prefix});
 949                         }
 950                 elsif (/^--api=(.*)$/)
 951                         {
 952                         my $api = $1;
 953                         die "Unknown API compatibility level $api"
 954                                 unless defined $apitable->{$api};
 955                         $config{api}=$apitable->{$api};
 956                         }
 957                 elsif (/^--libdir=(.*)$/)
 958                         {
 959                         $config{libdir}=$1;
 960                         }
 961                 elsif (/^--openssldir=(.*)$/)
 962                         {
 963                         $config{openssldir}=$1;
 964                         }
 965                 elsif (/^--with-zlib-lib=(.*)$/)
 966                         {
 967                         $withargs{zlib_lib}=$1;
 968                         }
 969                 elsif (/^--with-zlib-include=(.*)$/)
 970                         {
 971                         $withargs{zlib_include}=$1;
 972                         }
 973                 elsif (/^--with-fuzzer-lib=(.*)$/)
 974                         {
 975                         $withargs{fuzzer_lib}=$1;
 976                         }
 977                 elsif (/^--with-fuzzer-include=(.*)$/)
 978                         {
 979                         $withargs{fuzzer_include}=$1;
 980                         }
 981                 elsif (/^--with-rand-seed=(.*)$/)
 982                         {
 983                         foreach my $x (split(m|,|, $1))
 984                             {
 985                             die "Unknown --with-rand-seed choice $x\n"
 986                                 if ! grep { $x eq $_ } @known_seed_sources;
 987                             push @seed_sources, $x;
 988                             }
 989                         }
 990                 elsif (/^--fips-key=(.*)$/)
 991                         {
 992                         $user{FIPSKEY}=lc($1);
 993                         die "Non-hex character in FIPS key\n"
 994                            if $user{FIPSKEY} =~ /[^a-f0-9]/;
 995                         die "FIPS key must have even number of characters\n"
 996                            if length $1 & 1;
 997                         die "FIPS key too long (64 bytes max)\n"
 998                            if length $1 > 64;
 999                         }
1000                 elsif (/^--banner=(.*)$/)
1001                         {
1002                         $banner = $1 . "\n";
1003                         }
1004                 elsif (/^--cross-compile-prefix=(.*)$/)
1005                         {
1006                         $user{CROSS_COMPILE}=$1;
1007                         }
1008                 elsif (/^--config=(.*)$/)
1009                         {
1010                         read_config $1;
1011                         }
1012                 elsif (/^-l(.*)$/)
1013                         {
1014                         push @{$useradd{LDLIBS}}, $_;
1015                         }
1016                 elsif (/^-framework$/)
1017                         {
1018                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
1019                         }
1020                 elsif (/^-L(.*)$/ or /^-Wl,/)
1021                         {
1022                         push @{$useradd{LDFLAGS}}, $_;
1023                         }
1024                 elsif (/^-rpath$/ or /^-R$/)
1025                         # -rpath is the OSF1 rpath flag
1026                         # -R is the old Solaris rpath flag
1027                         {
1028                         my $rpath = shift(@argvcopy) || "";
1029                         $rpath .= " " if $rpath ne "";
1030                         push @{$useradd{LDFLAGS}}, $_, $rpath;
1031                         }
1032                 elsif (/^-static$/)
1033                         {
1034                         push @{$useradd{LDFLAGS}}, $_;
1035                         }
1036                 elsif (m|^[-/]D(.*)$|)
1037                         {
1038                         push @{$useradd{CPPDEFINES}}, $1;
1039                         }
1040                 elsif (m|^[-/]I(.*)$|)
1041                         {
1042                         push @{$useradd{CPPINCLUDES}}, $1;
1043                         }
1044                 elsif (/^-Wp,$/)
1045                         {
1046                         push @{$useradd{CPPFLAGS}}, $1;
1047                         }
1048                 else    # common if (/^[-+]/), just pass down...
1049                         {
1050                         # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
1051                         # This provides a simple way to pass options with arguments separated
1052                         # by spaces without quoting (e.g. -opt%20arg translates to -opt arg).
1053                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
1054                         push @{$useradd{CFLAGS}}, $_;
1055                         push @{$useradd{CXXFLAGS}}, $_;
1056                         }
1057                 }
1058         elsif (m|^/|)
1059                 {
1060                 # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
1061                 # This provides a simple way to pass options with arguments separated
1062                 # by spaces without quoting (e.g. /opt%20arg translates to /opt arg).
1063                 $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
1064                 push @{$useradd{CFLAGS}}, $_;
1065                 push @{$useradd{CXXFLAGS}}, $_;
1066                 }
1067         else
1068                 {
1069                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
1070                 $target=$_;
1071                 }
1072         unless ($_ eq $target || /^no-/ || /^disable-/)
1073                 {
1074                 # "no-..." follows later after implied deactivations
1075                 # have been derived.  (Don't take this too seriously,
1076                 # we really only write OPTIONS to the Makefile out of
1077                 # nostalgia.)
1078
1079                 if ($config{options} eq "")
1080                         { $config{options} = $_; }
1081                 else
1082                         { $config{options} .= " ".$_; }
1083                 }
1084         }
1085
1086 if (keys %deprecated_options)
1087         {
1088         warn "***** Deprecated options: ",
1089                 join(", ", keys %deprecated_options), "\n";
1090         }
1091 if (keys %unsupported_options)
1092         {
1093         die "***** Unsupported options: ",
1094                 join(", ", keys %unsupported_options), "\n";
1095         }
1096
1097 # If any %useradd entry has been set, we must check that the "make
1098 # variables" haven't been set.  We start by checking of any %useradd entry
1099 # is set.
1100 if (grep { scalar @$_ > 0 } values %useradd) {
1101     # Hash of env / make variables names.  The possible values are:
1102     # 1 - "make vars"
1103     # 2 - %useradd entry set
1104     # 3 - both set
1105     my %detected_vars =
1106         map { my $v = 0;
1107               $v += 1 if $cmdvars{$_};
1108               $v += 2 if @{$useradd{$_}};
1109               $_ => $v }
1110         keys %useradd;
1111
1112     # If any of the corresponding "make variables" is set, we error
1113     if (grep { $_ & 1 } values %detected_vars) {
1114         my $names = join(', ', grep { $detected_vars{$_} > 0 }
1115                                sort keys %detected_vars);
1116         die <<"_____";
1117 ***** Mixing make variables and additional compiler/linker flags as
1118 ***** configure command line option is not permitted.
1119 ***** Affected make variables: $names
1120 _____
1121     }
1122 }
1123
1124 # Check through all supported command line variables to see if any of them
1125 # were set, and canonicalise the values we got.  If no compiler or linker
1126 # flag or anything else that affects %useradd was set, we also check the
1127 # environment for values.
1128 my $anyuseradd =
1129     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
1130 foreach (keys %user) {
1131     my $value = $cmdvars{$_};
1132     $value //= env($_) unless $anyuseradd;
1133     $value //=
1134         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
1135     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
1136         unless $anyuseradd;
1137
1138     if (defined $value) {
1139         if (ref $user{$_} eq 'ARRAY') {
1140             if ($_ eq 'CPPDEFINES' || $_ eq 'CPPINCLUDES') {
1141                 $user{$_} = [ split /$list_separator_re/, $value ];
1142             } else {
1143                 $user{$_} = [ $value ];
1144             }
1145         } elsif (!defined $user{$_}) {
1146             $user{$_} = $value;
1147         }
1148     }
1149 }
1150
1151 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1152     && !$disabled{shared}
1153     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1154     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1155         "***** any of asan, msan or ubsan\n";
1156 }
1157
1158 # If no target was given, try guessing.
1159 unless ($target) {
1160     my %system_config = OpenSSL::config::get_platform(%guess_opts, %user);
1161
1162     # The $system_config{disable} is used to populate %disabled with
1163     # entries that aren't already there.
1164     foreach ( @{$system_config{disable} // []} ) {
1165         $disabled{$_} = 'system' unless defined $disabled{$_};
1166     }
1167     delete $system_config{disable};
1168
1169     # Override config entries with stuff from the guesser.
1170     # It's assumed that this really is nothing new.
1171     %config = ( %config, %system_config );
1172     $target = $system_config{target};
1173 }
1174
1175 sub disable {
1176     my $disable_type = shift;
1177
1178     for (@_) {
1179         $disabled{$_} = $disable_type;
1180     }
1181
1182     my @tocheckfor = (@_ ? @_ : keys %disabled);
1183     while (@tocheckfor) {
1184         my %new_tocheckfor = ();
1185         my @cascade_copy = (@disable_cascades);
1186         while (@cascade_copy) {
1187             my ($test, $descendents) =
1188                 (shift @cascade_copy, shift @cascade_copy);
1189             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1190                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1191                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1192                 }
1193             }
1194         }
1195         @tocheckfor = (keys %new_tocheckfor);
1196     }
1197 }
1198 disable();                     # First cascade run
1199
1200 our $die = sub { die @_; };
1201 if ($target eq "TABLE") {
1202     local $die = sub { warn @_; };
1203     foreach (sort keys %table) {
1204         print_table_entry($_, "TABLE");
1205     }
1206     exit 0;
1207 }
1208
1209 if ($target eq "LIST") {
1210     foreach (sort keys %table) {
1211         print $_,"\n" unless $table{$_}->{template};
1212     }
1213     exit 0;
1214 }
1215
1216 if ($target eq "HASH") {
1217     local $die = sub { warn @_; };
1218     print "%table = (\n";
1219     foreach (sort keys %table) {
1220         print_table_entry($_, "HASH");
1221     }
1222     exit 0;
1223 }
1224
1225 print "Configuring OpenSSL version $config{full_version} ";
1226 print "for target $target\n";
1227
1228 if (scalar(@seed_sources) == 0) {
1229     print "Using os-specific seed configuration\n";
1230     push @seed_sources, 'os';
1231 }
1232 if (scalar(grep { $_ eq 'egd' } @seed_sources) > 0) {
1233     delete $disabled{'egd'};
1234 }
1235 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1236     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1237     warn <<_____ if scalar(@seed_sources) == 1;
1238
1239 ============================== WARNING ===============================
1240 You have selected the --with-rand-seed=none option, which effectively
1241 disables automatic reseeding of the OpenSSL random generator.
1242 All operations depending on the random generator such as creating keys
1243 will not work unless the random generator is seeded manually by the
1244 application.
1245
1246 Please read the 'Note on random number generation' section in the
1247 INSTALL.md instructions and the RAND_DRBG(7) manual page for more
1248 details.
1249 ============================== WARNING ===============================
1250
1251 _____
1252 }
1253 push @{$config{openssl_feature_defines}},
1254      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1255         @seed_sources;
1256
1257 # Backward compatibility?
1258 if ($target =~ m/^CygWin32(-.*)$/) {
1259     $target = "Cygwin".$1;
1260 }
1261
1262 # Support for legacy targets having a name starting with 'debug-'
1263 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1264 if ($d) {
1265     $config{build_type} = "debug";
1266
1267     # If we do not find debug-foo in the table, the target is set to foo.
1268     if (!$table{$target}) {
1269         $target = $t;
1270     }
1271 }
1272
1273 if ($target) {
1274     # It's possible that we have different config targets for specific
1275     # toolchains, so we try to detect them, and go for the plain config
1276     # target if not.
1277     my $found;
1278     foreach ( ( "$target-$user{CC}", "$target", undef ) ) {
1279         $found=$_ if $table{$_} && !$table{$_}->{template};
1280         last if $found;
1281     }
1282     $target = $found;
1283 } else {
1284     # If we don't have a config target now, we try the C compiler as we
1285     # fallback
1286     my $cc = $user{CC} // 'cc';
1287     $target = $cc if $table{$cc} && !$table{$cc}->{template};
1288 }
1289
1290 &usage unless $target;
1291
1292 exit 0 if $dryrun;              # From older 'config'
1293
1294 $config{target} = $target;
1295 my %target = resolve_config($target);
1296
1297 foreach (keys %target_attr_translate) {
1298     $target{$target_attr_translate{$_}} = $target{$_}
1299         if $target{$_};
1300     delete $target{$_};
1301 }
1302
1303 %target = ( %{$table{DEFAULTS}}, %target );
1304
1305 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1306 $config{conf_files} = [ sort keys %conf_files ];
1307
1308 # Using sub disable within these loops may prove fragile, so we run
1309 # a cascade afterwards
1310 foreach my $feature (@{$target{disable}}) {
1311     if (exists $deprecated_disablables{$feature}) {
1312         warn "***** config $target disables deprecated feature $feature\n";
1313     } elsif (!grep { $feature eq $_ } @disablables) {
1314         die "***** config $target disables unknown feature $feature\n";
1315     }
1316     $disabled{$feature} = 'config';
1317 }
1318 foreach my $feature (@{$target{enable}}) {
1319     if ("default" eq ($disabled{$feature} // "")) {
1320         if (exists $deprecated_disablables{$feature}) {
1321             warn "***** config $target enables deprecated feature $feature\n";
1322         } elsif (!grep { $feature eq $_ } @disablables) {
1323             die "***** config $target enables unknown feature $feature\n";
1324         }
1325         delete $disabled{$feature};
1326     }
1327 }
1328
1329 # If uplink_arch isn't defined, disable uplink
1330 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1331 # If asm_arch isn't defined, disable asm
1332 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1333
1334 disable();                      # Run a cascade now
1335
1336 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1337 $target{cxxflags}//=$target{cflags} if $target{CXX};
1338 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1339 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1340
1341 # Fill %config with values from %user, and in case those are undefined or
1342 # empty, use values from %target (acting as a default).
1343 foreach (keys %user) {
1344     my $ref_type = ref $user{$_};
1345
1346     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1347     # and a value that's to be coerced into that type.
1348     my $mkvalue = sub {
1349         my $type = shift;
1350         my $value = shift;
1351         my $undef_p = shift;
1352
1353         die "Too many arguments for \$mkvalue" if @_;
1354
1355         while (ref $value eq 'CODE') {
1356             $value = $value->();
1357         }
1358
1359         if ($type eq 'ARRAY') {
1360             return undef unless defined $value;
1361             return undef if ref $value ne 'ARRAY' && !$value;
1362             return undef if ref $value eq 'ARRAY' && !@$value;
1363             return [ $value ] unless ref $value eq 'ARRAY';
1364         }
1365         return undef unless $value;
1366         return $value;
1367     };
1368
1369     $config{$_} =
1370         $mkvalue->($ref_type, $user{$_})
1371         || $mkvalue->($ref_type, $target{$_});
1372     delete $config{$_} unless defined $config{$_};
1373 }
1374
1375 # Finish up %config by appending things the user gave us on the command line
1376 # apart from "make variables"
1377 foreach (keys %useradd) {
1378     # The must all be lists, so we assert that here
1379     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1380         unless ref $useradd{$_} eq 'ARRAY';
1381
1382     if (defined $config{$_}) {
1383         push @{$config{$_}}, @{$useradd{$_}};
1384     } else {
1385         $config{$_} = [ @{$useradd{$_}} ];
1386     }
1387 }
1388 # At this point, we can forget everything about %user and %useradd,
1389 # because it's now all been merged into the corresponding $config entry
1390
1391 if (grep { $_ =~ /(?:^|\s)-static(?:\s|$)/ } @{$config{LDFLAGS}}) {
1392     disable('static', 'pic', 'threads');
1393 }
1394
1395 # Allow overriding the build file name
1396 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1397
1398 # Make sure build_scheme is consistent.
1399 $target{build_scheme} = [ $target{build_scheme} ]
1400     if ref($target{build_scheme}) ne "ARRAY";
1401
1402 my ($builder, $builder_platform, @builder_opts) =
1403     @{$target{build_scheme}};
1404
1405 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1406                       $builder_platform."-checker.pm")) {
1407     my $checker_path = catfile($srcdir, "Configurations", $checker);
1408     if (-f $checker_path) {
1409         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1410             ? sub { warn $@; } : sub { die $@; };
1411         if (! do $checker_path) {
1412             if ($@) {
1413                 $fn->($@);
1414             } elsif ($!) {
1415                 $fn->($!);
1416             } else {
1417                 $fn->("The detected tools didn't match the platform\n");
1418             }
1419         }
1420         last;
1421     }
1422 }
1423
1424 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1425
1426 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1427         {
1428         push @{$config{cflags}}, "-mno-cygwin";
1429         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1430         push @{$config{shared_ldflag}}, "-mno-cygwin";
1431         }
1432
1433 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1434         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1435         # minimally required architecture flags for assembly modules
1436         my $value;
1437         $value = '-mips2' if ($target =~ /mips32/);
1438         $value = '-mips3' if ($target =~ /mips64/);
1439         unshift @{$config{cflags}}, $value;
1440         unshift @{$config{cxxflags}}, $value if $config{CXX};
1441 }
1442
1443 # If threads aren't disabled, check how possible they are
1444 unless ($disabled{threads}) {
1445     if ($auto_threads) {
1446         # Enabled by default, disable it forcibly if unavailable
1447         if ($target{thread_scheme} eq "(unknown)") {
1448             disable("unavailable", 'threads');
1449         }
1450     } else {
1451         # The user chose to enable threads explicitly, let's see
1452         # if there's a chance that's possible
1453         if ($target{thread_scheme} eq "(unknown)") {
1454             # If the user asked for "threads" and we don't have internal
1455             # knowledge how to do it, [s]he is expected to provide any
1456             # system-dependent compiler options that are necessary.  We
1457             # can't truly check that the given options are correct, but
1458             # we expect the user to know what [s]He is doing.
1459             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1460                 die "You asked for multi-threading support, but didn't\n"
1461                     ,"provide any system-specific compiler options\n";
1462             }
1463         }
1464     }
1465 }
1466
1467 # Find out if clang's sanitizers have been enabled with -fsanitize
1468 # flags and ensure that the corresponding %disabled elements area
1469 # removed to reflect that the sanitizers are indeed enabled.
1470 my %detected_sanitizers = ();
1471 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1472     (my $checks = $_) =~ s/^-fsanitize=//;
1473     foreach (split /,/, $checks) {
1474         my $d = { address       => 'asan',
1475                   undefined     => 'ubsan',
1476                   memory        => 'msan' } -> {$_};
1477         next unless defined $d;
1478
1479         $detected_sanitizers{$d} = 1;
1480         if (defined $disabled{$d}) {
1481             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1482                 if $disabled{$d} ne "default";
1483             delete $disabled{$d};
1484         }
1485     }
1486 }
1487
1488 # If threads still aren't disabled, add a C macro to ensure the source
1489 # code knows about it.  Any other flag is taken care of by the configs.
1490 unless($disabled{threads}) {
1491     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1492 }
1493
1494 my $no_shared_warn=0;
1495 if (($target{shared_target} // '') eq "")
1496         {
1497         $no_shared_warn = 1
1498             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1499         disable('no-shared-target', 'pic');
1500         }
1501
1502 if ($disabled{"dynamic-engine"}) {
1503         $config{dynamic_engines} = 0;
1504 } else {
1505         $config{dynamic_engines} = 1;
1506 }
1507
1508 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1509     push @{$config{cflags}}, "-fsanitize=address";
1510 }
1511
1512 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1513     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all", "-DPEDANTIC";
1514 }
1515
1516 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1517   push @{$config{cflags}}, "-fsanitize=memory";
1518 }
1519
1520 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1521         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1522     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1523     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1524 }
1525 #
1526 # Platform fix-ups
1527 #
1528
1529 # This saves the build files from having to check
1530 if ($disabled{pic})
1531         {
1532         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1533                     shared_defines shared_includes shared_ldflag
1534                     module_cflags module_cxxflags module_cppflags
1535                     module_defines module_includes module_lflags))
1536                 {
1537                 delete $config{$_};
1538                 $target{$_} = "";
1539                 }
1540         }
1541 else
1542         {
1543         push @{$config{lib_defines}}, "OPENSSL_PIC";
1544         }
1545
1546 if ($target{sys_id} ne "")
1547         {
1548         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1549         }
1550
1551 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1552 my %predefined_CXX = $config{CXX}
1553     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1554     : ();
1555
1556 unless ($disabled{asm}) {
1557     # big endian systems can use ELFv2 ABI
1558     if ($target eq "linux-ppc64" || $target eq "BSD-ppc64") {
1559         $target{perlasm_scheme} = "linux64v2" if ($predefined_C{_CALL_ELF} == 2);
1560     }
1561 }
1562
1563 # Check for makedepend capabilities.
1564 if (!$disabled{makedepend}) {
1565     # If the attribute makedep_scheme is defined, then we assume that the
1566     # config target and its associated build file are programmed to deal
1567     # with it.
1568     # If makedep_scheme is undefined, we go looking for GCC compatible
1569     # dependency making, and if that's not available, we try to fall back
1570     # on 'makedepend'.
1571     if ($target{makedep_scheme}) {
1572         $config{makedep_scheme} = $target{makedep_scheme};
1573         # If the makedepcmd attribute is defined, copy it.  If not, the
1574         # build files will have to fend for themselves.
1575         $config{makedepcmd} = $target{makedepcmd} if $target{makedepcmd};
1576     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1577              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1578         # We know that GNU C version 3 and up as well as all clang
1579         # versions support dependency generation, but Xcode did not
1580         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1581         $config{makedep_scheme} = 'gcc';
1582     } else {
1583         # In all other cases, we look for 'makedepend', and set the
1584         # makedep_scheme value if we found it.
1585         $config{makedepcmd} = which('makedepend');
1586         $config{makedep_scheme} = 'makedepend' if $config{makedepcmd};
1587     }
1588
1589     # If no depend scheme is set, we disable makedepend
1590     disable('unavailable', 'makedepend') unless $config{makedep_scheme};
1591 }
1592
1593 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1594     # probe for -Wa,--noexecstack option...
1595     if ($predefined_C{__clang__}) {
1596         # clang has builtin assembler, which doesn't recognize --help,
1597         # but it apparently recognizes the option in question on all
1598         # supported platforms even when it's meaningless. In other words
1599         # probe would fail, but probed option always accepted...
1600         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1601     } else {
1602         my $cc = $config{CROSS_COMPILE}.$config{CC};
1603         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1604         while(<PIPE>) {
1605             if (m/--noexecstack/) {
1606                 push @{$config{cflags}}, "-Wa,--noexecstack";
1607                 last;
1608             }
1609         }
1610         close(PIPE);
1611         unlink("null.$$.o");
1612     }
1613 }
1614
1615 # Deal with bn_ops ###################################################
1616
1617 $config{bn_ll}                  =0;
1618 my $def_int="unsigned int";
1619 $config{rc4_int}                =$def_int;
1620 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1621
1622 my $count = 0;
1623 foreach (sort split(/\s+/,$target{bn_ops})) {
1624     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1625     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1626     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1627     ($config{b64l},$config{b64},$config{b32})
1628         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1629     ($config{b64l},$config{b64},$config{b32})
1630         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1631     ($config{b64l},$config{b64},$config{b32})
1632         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1633 }
1634 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1635     if $count > 1;
1636
1637 $config{api} = $config{major} * 10000 + $config{minor} * 100
1638     unless $config{api};
1639 foreach (keys %$apitable) {
1640     $disabled{"deprecated-$_"} = "deprecation"
1641         if $disabled{deprecated} && $config{api} >= $apitable->{$_};
1642 }
1643
1644 disable();                      # Run a cascade now
1645
1646 # Hack cflags for better warnings (dev option) #######################
1647
1648 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1649 # a string and works as well on command lines.
1650 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1651                         @{$config{cflags}} ];
1652 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1653                           @{$config{cxxflags}} ] if $config{CXX};
1654
1655 $config{openssl_api_defines} = [
1656     "OPENSSL_CONFIGURED_API=".$config{api},
1657 ];
1658
1659 my @strict_warnings_collection=();
1660 if ($strict_warnings)
1661         {
1662         my $wopt;
1663         my $gccver = $predefined_C{__GNUC__} // -1;
1664
1665         if ($gccver >= 4)
1666                 {
1667                 push @strict_warnings_collection, @gcc_devteam_warn;
1668                 push @strict_warnings_collection, @clang_devteam_warn
1669                     if (defined($predefined_C{__clang__}));
1670                 }
1671         elsif ($config{target} =~ /^VC-/)
1672                 {
1673                 push @strict_warnings_collection, @cl_devteam_warn;
1674                 }
1675         else
1676                 {
1677                 warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike, or MSVC"
1678                 }
1679         }
1680
1681 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1682                               ? @strict_warnings_collection
1683                               : ( $_ ) }
1684                     @{$config{CFLAGS}} ];
1685
1686 unless ($disabled{afalgeng}) {
1687     $config{afalgeng}="";
1688     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1689         push @{$config{engdirs}}, "afalg";
1690     } else {
1691         disable('not-linux', 'afalgeng');
1692     }
1693 }
1694
1695 unless ($disabled{devcryptoeng}) {
1696     if ($target =~ m/^BSD/) {
1697         my $maxver = 5*100 + 7;
1698         my $sysstr = `uname -s`;
1699         my $verstr = `uname -r`;
1700         $sysstr =~ s|\R$||;
1701         $verstr =~ s|\R$||;
1702         my ($ma, $mi, @rest) = split m|\.|, $verstr;
1703         my $ver = $ma*100 + $mi;
1704         if ($sysstr eq 'OpenBSD' && $ver >= $maxver) {
1705             disable('too-new-kernel', 'devcryptoeng');
1706         }
1707     }
1708 }
1709
1710 unless ($disabled{ktls}) {
1711     $config{ktls}="";
1712     if ($target =~ m/^linux/) {
1713         my $usr = "/usr/$config{cross_compile_prefix}";
1714         chop($usr);
1715         if ($config{cross_compile_prefix} eq "") {
1716             $usr = "/usr";
1717         }
1718         my $minver = (4 << 16) + (13 << 8) + 0;
1719         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1720
1721         if ($verstr[2] < $minver) {
1722             disable('too-old-kernel', 'ktls');
1723         }
1724     } elsif ($target =~ m/^BSD/) {
1725         my $cc = $config{CROSS_COMPILE}.$config{CC};
1726         system("printf '#include <sys/types.h>\n#include <sys/ktls.h>' | $cc -E - >/dev/null 2>&1");
1727         if ($? != 0) {
1728             disable('too-old-freebsd', 'ktls');
1729         }
1730     } else {
1731         disable('not-linux-or-freebsd', 'ktls');
1732     }
1733 }
1734
1735 unless ($disabled{winstore}) {
1736     unless ($target =~ /^(?:Cygwin|mingw|VC-|BC-)/) {
1737         disable('not-windows', 'winstore');
1738     }
1739 }
1740
1741 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1742
1743 # Get the extra flags used when building shared libraries and modules.  We
1744 # do this late because some of them depend on %disabled.
1745
1746 # Make the flags to build DSOs the same as for shared libraries unless they
1747 # are already defined
1748 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1749 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1750 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1751 {
1752     my $shared_info_pl =
1753         catfile(dirname($0), "Configurations", "shared-info.pl");
1754     my %shared_info = read_eval_file($shared_info_pl);
1755     push @{$target{_conf_fname_int}}, $shared_info_pl;
1756     my $si = $target{shared_target};
1757     while (ref $si ne "HASH") {
1758         last if ! defined $si;
1759         if (ref $si eq "CODE") {
1760             $si = $si->();
1761         } else {
1762             $si = $shared_info{$si};
1763         }
1764     }
1765
1766     # Some of the 'shared_target' values don't have any entries in
1767     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1768     # template knows how to handle this.  That is currently the case for
1769     # Windows and VMS.
1770     if (defined $si) {
1771         # Just as above, copy certain shared_* attributes to the corresponding
1772         # module_ attribute unless the latter is already defined
1773         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1774         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1775         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1776         foreach (sort keys %$si) {
1777             $target{$_} = defined $target{$_}
1778                 ? add($si->{$_})->($target{$_})
1779                 : $si->{$_};
1780         }
1781     }
1782 }
1783
1784 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1785
1786 ######################################################################
1787 # Build up information for skipping certain directories depending on disabled
1788 # features, as well as setting up macros for disabled features.
1789
1790 # This is a tentative database of directories to skip.  Some entries may not
1791 # correspond to anything real, but that's ok, they will simply be ignored.
1792 # The actual processing of these entries is done in the build.info lookup
1793 # loop further down.
1794 #
1795 # The key is a Unix formatted path in the source tree, the value is an index
1796 # into %disabled_info, so any existing path gets added to a corresponding
1797 # 'skipped' entry in there with the list of skipped directories.
1798 my %skipdir = ();
1799 my %disabled_info = ();         # For configdata.pm
1800 foreach my $what (sort keys %disabled) {
1801     # There are deprecated disablables that translate to themselves.
1802     # They cause disabling cascades, but should otherwise not register.
1803     next if $deprecated_disablables{$what};
1804     # The generated $disabled{"deprecated-x.y"} entries are special
1805     # and treated properly elsewhere
1806     next if $what =~ m|^deprecated-|;
1807
1808     $config{options} .= " no-$what";
1809
1810     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1811                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1812                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1813         (my $WHAT = uc $what) =~ s|-|_|g;
1814         my $skipdir = $what;
1815
1816         # fix-up crypto/directory name(s)
1817         $skipdir = "ripemd" if $what eq "rmd160";
1818         $skipdir = "whrlpool" if $what eq "whirlpool";
1819
1820         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1821         push @{$config{openssl_feature_defines}}, $macro;
1822
1823         $skipdir{engines} = $what if $what eq 'engine';
1824         $skipdir{"crypto/$skipdir"} = $what
1825             unless $what eq 'async' || $what eq 'err' || $what eq 'dso';
1826     }
1827 }
1828
1829 if ($disabled{"dynamic-engine"}) {
1830     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1831 } else {
1832     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1833 }
1834
1835 # If we use the unified build, collect information from build.info files
1836 my %unified_info = ();
1837
1838 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1839 if ($builder eq "unified") {
1840     use Text::Template 1.46;
1841
1842     sub cleandir {
1843         my $base = shift;
1844         my $dir = shift;
1845         my $relativeto = shift || ".";
1846
1847         $dir = catdir($base,$dir) unless isabsolute($dir);
1848
1849         # Make sure the directories we're building in exists
1850         mkpath($dir);
1851
1852         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1853         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1854         return $res;
1855     }
1856
1857     sub cleanfile {
1858         my $base = shift;
1859         my $file = shift;
1860         my $relativeto = shift || ".";
1861
1862         $file = catfile($base,$file) unless isabsolute($file);
1863
1864         my $d = dirname($file);
1865         my $f = basename($file);
1866
1867         # Make sure the directories we're building in exists
1868         mkpath($d);
1869
1870         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1871         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1872         return $res;
1873     }
1874
1875     # Store the name of the template file we will build the build file from
1876     # in %config.  This may be useful for the build file itself.
1877     my @build_file_template_names =
1878         ( $builder_platform."-".$target{build_file}.".tmpl",
1879           $target{build_file}.".tmpl" );
1880     my @build_file_templates = ();
1881
1882     # First, look in the user provided directory, if given
1883     if (defined env($local_config_envname)) {
1884         @build_file_templates =
1885             map {
1886                 if ($^O eq 'VMS') {
1887                     # VMS environment variables are logical names,
1888                     # which can be used as is
1889                     $local_config_envname . ':' . $_;
1890                 } else {
1891                     catfile(env($local_config_envname), $_);
1892                 }
1893             }
1894             @build_file_template_names;
1895     }
1896     # Then, look in our standard directory
1897     push @build_file_templates,
1898         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1899           @build_file_template_names );
1900
1901     my $build_file_template;
1902     for $_ (@build_file_templates) {
1903         $build_file_template = $_;
1904         last if -f $build_file_template;
1905
1906         $build_file_template = undef;
1907     }
1908     if (!defined $build_file_template) {
1909         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1910     }
1911     $config{build_file_templates}
1912       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1913                     $blddir),
1914            $build_file_template ];
1915
1916     my @build_dirs = ( [ ] );   # current directory
1917
1918     $config{build_infos} = [ ];
1919
1920     # We want to detect configdata.pm in the source tree, so we
1921     # don't use it if the build tree is different.
1922     my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1923
1924     # Any source file that we recognise is placed in this hash table, with
1925     # the list of its intended destinations as value.  When everything has
1926     # been collected, there's a routine that checks that these source files
1927     # exist, or if they are generated, that the generator exists.
1928     my %check_exist = ();
1929     my %check_generate = ();
1930
1931     my %ordinals = ();
1932     while (@build_dirs) {
1933         my @curd = @{shift @build_dirs};
1934         my $sourced = catdir($srcdir, @curd);
1935         my $buildd = catdir($blddir, @curd);
1936
1937         my $unixdir = join('/', @curd);
1938         if (exists $skipdir{$unixdir}) {
1939             my $what = $skipdir{$unixdir};
1940             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1941             next;
1942         }
1943
1944         mkpath($buildd);
1945
1946         my $f = 'build.info';
1947         # The basic things we're trying to build
1948         my @programs = ();
1949         my @libraries = ();
1950         my @modules = ();
1951         my @scripts = ();
1952
1953         my %sources = ();
1954         my %shared_sources = ();
1955         my %includes = ();
1956         my %defines = ();
1957         my %depends = ();
1958         my %generate = ();
1959         my %imagedocs = ();
1960         my %htmldocs = ();
1961         my %mandocs = ();
1962
1963         # Support for $variablename in build.info files.
1964         # Embedded perl code is the ultimate master, still.  If its output
1965         # contains a dollar sign, it had better be escaped, or it will be
1966         # taken for a variable name prefix.
1967         my %variables = ();
1968         # Variable name syntax
1969         my $variable_name_re = qr/(?P<VARIABLE>[[:alpha:]][[:alnum:]_]*)/;
1970         # Value modifier syntaxes
1971         my $variable_subst_re = qr/\/(?P<RE>(?:\\\/|.)*?)\/(?P<SUBST>.*?)/;
1972         # Variable reference
1973         my $variable_simple_re = qr/(?<!\\)\$${variable_name_re}/;
1974         my $variable_w_mod_re =
1975             qr/(?<!\\)\$\{${variable_name_re}(?P<MOD>(?:\\\/|.)*?)\}/;
1976         # Tie it all together
1977         my $variable_re = qr/${variable_simple_re}|${variable_w_mod_re}/;
1978
1979         my $expand_variables = sub {
1980             my $value = '';
1981             my $value_rest = shift;
1982
1983             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1984                 print STDERR
1985                     "DEBUG[\$expand_variables] Parsed '$value_rest' ...\n"
1986             }
1987
1988             while ($value_rest =~ /${variable_re}/) {
1989                 # We must save important regexp values, because the next
1990                 # regexp clears them
1991                 my $mod = $+{MOD};
1992                 my $variable_value = $variables{$+{VARIABLE}};
1993
1994                 $value_rest = $';
1995                 $value .= $`;
1996
1997                 # Process modifier expressions, if present
1998                 if (defined $mod) {
1999                     if ($mod =~ /^${variable_subst_re}$/) {
2000                         my $re = $+{RE};
2001                         my $subst = $+{SUBST};
2002
2003                         $variable_value =~ s/\Q$re\E/$subst/g;
2004
2005                         if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2006                             print STDERR
2007                                 "DEBUG[\$expand_variables] ... and substituted ",
2008                                 "'$re' with '$subst'\n";
2009                         }
2010                     }
2011                 }
2012
2013                 $value .= $variable_value;
2014             }
2015             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2016                 print STDERR
2017                     "DEBUG[\$expand_variables] ... into: '$value$value_rest'\n";
2018             }
2019             return $value . $value_rest;
2020         };
2021
2022         # Support for attributes in build.info files
2023         my %attributes = ();
2024         my $handle_attributes = sub {
2025             my $attr_str = shift;
2026             my $ref = shift;
2027             my @goals = @_;
2028
2029             return unless defined $attr_str;
2030
2031             my @a = tokenize($attr_str, qr|\s*,\s*|);
2032             foreach my $a (@a) {
2033                 my $ac = 1;
2034                 my $ak = $a;
2035                 my $av = 1;
2036                 if ($a =~ m|^(!)?(.*?)\s* = \s*(.*?)$|x) {
2037                     $ac = ! $1;
2038                     $ak = $2;
2039                     $av = $3;
2040                 }
2041                 foreach my $g (@goals) {
2042                     if ($ac) {
2043                         $$ref->{$g}->{$ak} = $av;
2044                     } else {
2045                         delete $$ref->{$g}->{$ak};
2046                     }
2047                 }
2048             }
2049         };
2050
2051         # Support for pushing values on multiple indexes of a given hash
2052         # array.
2053         my $push_to = sub {
2054             my $valueref = shift;
2055             my $index_str = shift; # May be undef or empty
2056             my $attrref = shift;   # May be undef
2057             my $attr_str = shift;
2058             my @values = @_;
2059
2060             if (defined $index_str) {
2061                 my @indexes = ( '' );
2062                 if ($index_str !~ m|^\s*$|) {
2063                     @indexes = tokenize($index_str);
2064                 }
2065                 foreach (@indexes) {
2066                     push @{$valueref->{$_}}, @values;
2067                     if (defined $attrref) {
2068                         $handle_attributes->($attr_str, \$$attrref->{$_},
2069                                              @values);
2070                     }
2071                 }
2072             } else {
2073                 push @$valueref, @values;
2074                 $handle_attributes->($attr_str, $attrref, @values)
2075                     if defined $attrref;
2076             }
2077         };
2078
2079         if ($buildinfo_debug) {
2080             print STDERR "DEBUG: Reading ",catfile($sourced, $f),"\n";
2081         }
2082         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
2083         my $template =
2084             Text::Template->new(TYPE => 'FILE',
2085                                 SOURCE => catfile($sourced, $f),
2086                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
2087         die "Something went wrong with $sourced/$f: $!\n" unless $template;
2088         my @text =
2089             split /^/m,
2090             $template->fill_in(HASH => { config => \%config,
2091                                          target => \%target,
2092                                          disabled => \%disabled,
2093                                          withargs => \%withargs,
2094                                          builddir => abs2rel($buildd, $blddir),
2095                                          sourcedir => abs2rel($sourced, $blddir),
2096                                          buildtop => abs2rel($blddir, $blddir),
2097                                          sourcetop => abs2rel($srcdir, $blddir) },
2098                                DELIMITERS => [ "{-", "-}" ]);
2099
2100         # The top item of this stack has the following values
2101         # -2 positive already run and we found ELSE (following ELSIF should fail)
2102         # -1 positive already run (skip until ENDIF)
2103         # 0 negatives so far (if we're at a condition, check it)
2104         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
2105         # 2 positive ELSE (following ELSIF should fail)
2106         my @skip = ();
2107
2108         # A few useful generic regexps
2109         my $index_re = qr/\[\s*(?P<INDEX>(?:\\.|.)*?)\s*\]/;
2110         my $cond_re = qr/\[\s*(?P<COND>(?:\\.|.)*?)\s*\]/;
2111         my $attribs_re = qr/(?:\{\s*(?P<ATTRIBS>(?:\\.|.)*?)\s*\})?/;
2112         my $value_re = qr/(?P<VALUE>.*?)/;
2113         collect_information(
2114             collect_from_array([ @text ],
2115                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
2116                                                 $l1 =~ s/\\$//; $l1.$l2 }),
2117             # Info we're looking for
2118             qr/^\s* IF ${cond_re} \s*$/x
2119             => sub {
2120                 if (! @skip || $skip[$#skip] > 0) {
2121                     push @skip, !! $expand_variables->($+{COND});
2122                 } else {
2123                     push @skip, -1;
2124                 }
2125             },
2126             qr/^\s* ELSIF ${cond_re} \s*$/x
2127             => sub { die "ELSIF out of scope" if ! @skip;
2128                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
2129                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
2130                      $skip[$#skip] = !! $expand_variables->($+{COND})
2131                          if $skip[$#skip] == 0; },
2132             qr/^\s* ELSE \s*$/x
2133             => sub { die "ELSE out of scope" if ! @skip;
2134                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
2135                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
2136             qr/^\s* ENDIF \s*$/x
2137             => sub { die "ENDIF out of scope" if ! @skip;
2138                      pop @skip; },
2139             qr/^\s* ${variable_re} \s* = \s* ${value_re} \s* $/x
2140             => sub {
2141                 if (!@skip || $skip[$#skip] > 0) {
2142                     $variables{$+{VARIABLE}} = $expand_variables->($+{VALUE});
2143                 }
2144             },
2145             qr/^\s* SUBDIRS \s* = \s* ${value_re} \s* $/x
2146             => sub {
2147                 if (!@skip || $skip[$#skip] > 0) {
2148                     foreach (tokenize($expand_variables->($+{VALUE}))) {
2149                         push @build_dirs, [ @curd, splitdir($_, 1) ];
2150                     }
2151                 }
2152             },
2153             qr/^\s* PROGRAMS ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2154             => sub { $push_to->(\@programs, undef,
2155                                 \$attributes{programs}, $+{ATTRIBS},
2156                                 tokenize($expand_variables->($+{VALUE})))
2157                          if !@skip || $skip[$#skip] > 0; },
2158             qr/^\s* LIBS ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2159             => sub { $push_to->(\@libraries, undef,
2160                                 \$attributes{libraries}, $+{ATTRIBS},
2161                                 tokenize($expand_variables->($+{VALUE})))
2162                          if !@skip || $skip[$#skip] > 0; },
2163             qr/^\s* MODULES ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2164             => sub { $push_to->(\@modules, undef,
2165                                 \$attributes{modules}, $+{ATTRIBS},
2166                                 tokenize($expand_variables->($+{VALUE})))
2167                          if !@skip || $skip[$#skip] > 0; },
2168             qr/^\s* SCRIPTS ${attribs_re} \s* = \s* ${value_re} \s* $/x
2169             => sub { $push_to->(\@scripts, undef,
2170                                 \$attributes{scripts}, $+{ATTRIBS},
2171                                 tokenize($expand_variables->($+{VALUE})))
2172                          if !@skip || $skip[$#skip] > 0; },
2173             qr/^\s* IMAGEDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2174             => sub { $push_to->(\%imagedocs, $expand_variables->($+{INDEX}),
2175                                 undef, undef,
2176                                 tokenize($expand_variables->($+{VALUE})))
2177                          if !@skip || $skip[$#skip] > 0; },
2178             qr/^\s* HTMLDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2179             => sub { $push_to->(\%htmldocs, $expand_variables->($+{INDEX}),
2180                                 undef, undef,
2181                                 tokenize($expand_variables->($+{VALUE})))
2182                          if !@skip || $skip[$#skip] > 0; },
2183             qr/^\s* MANDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2184             => sub { $push_to->(\%mandocs, $expand_variables->($+{INDEX}),
2185                                 undef, undef,
2186                                 tokenize($expand_variables->($+{VALUE})))
2187                          if !@skip || $skip[$#skip] > 0; },
2188             qr/^\s* SOURCE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2189             => sub { $push_to->(\%sources, $expand_variables->($+{INDEX}),
2190                                 \$attributes{sources}, $+{ATTRIBS},
2191                                 tokenize($expand_variables->($+{VALUE})))
2192                          if !@skip || $skip[$#skip] > 0; },
2193             qr/^\s* SHARED_SOURCE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2194             => sub { $push_to->(\%shared_sources, $expand_variables->($+{INDEX}),
2195                                 \$attributes{sources}, $+{ATTRIBS},
2196                                 tokenize($expand_variables->($+{VALUE})))
2197                          if !@skip || $skip[$#skip] > 0; },
2198             qr/^\s* INCLUDE ${index_re} \s* = \s* ${value_re} \s* $/x
2199             => sub { $push_to->(\%includes, $expand_variables->($+{INDEX}),
2200                                 undef, undef,
2201                                 tokenize($expand_variables->($+{VALUE})))
2202                          if !@skip || $skip[$#skip] > 0; },
2203             qr/^\s* DEFINE ${index_re} \s* = \s* ${value_re} \s* $/x
2204             => sub { $push_to->(\%defines, $expand_variables->($+{INDEX}),
2205                                 undef, undef,
2206                                 tokenize($expand_variables->($+{VALUE})))
2207                          if !@skip || $skip[$#skip] > 0; },
2208             qr/^\s* DEPEND ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2209             => sub { $push_to->(\%depends, $expand_variables->($+{INDEX}),
2210                                 \$attributes{depends}, $+{ATTRIBS},
2211                                 tokenize($expand_variables->($+{VALUE})))
2212                          if !@skip || $skip[$#skip] > 0; },
2213             qr/^\s* GENERATE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2214             => sub { $push_to->(\%generate, $expand_variables->($+{INDEX}),
2215                                 \$attributes{generate}, $+{ATTRIBS},
2216                                 $expand_variables->($+{VALUE}))
2217                          if !@skip || $skip[$#skip] > 0; },
2218             qr/^\s* (?:\#.*)? $/x => sub { },
2219             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
2220             "BEFORE" => sub {
2221                 if ($buildinfo_debug) {
2222                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
2223                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2224                 }
2225             },
2226             "AFTER" => sub {
2227                 if ($buildinfo_debug) {
2228                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2229                 }
2230             },
2231             );
2232         die "runaway IF?" if (@skip);
2233
2234         if (grep { defined $attributes{modules}->{$_}->{engine} } keys %attributes
2235                 and !$config{dynamic_engines}) {
2236             die <<"EOF"
2237 ENGINES can only be used if configured with 'dynamic-engine'.
2238 This is usually a fault in a build.info file.
2239 EOF
2240         }
2241
2242         {
2243             my %infos = ( programs  => [ @programs  ],
2244                           libraries => [ @libraries ],
2245                           modules   => [ @modules   ],
2246                           scripts   => [ @scripts   ] );
2247             foreach my $k (keys %infos) {
2248                 foreach (@{$infos{$k}}) {
2249                     my $item = cleanfile($buildd, $_, $blddir);
2250                     $unified_info{$k}->{$item} = 1;
2251
2252                     # Fix up associated attributes
2253                     $unified_info{attributes}->{$k}->{$item} =
2254                         $attributes{$k}->{$_}
2255                         if defined $attributes{$k}->{$_};
2256                 }
2257             }
2258         }
2259
2260         # Check that we haven't defined any library as both shared and
2261         # explicitly static.  That is forbidden.
2262         my @doubles = ();
2263         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2264             (my $l = $_) =~ s/\.a$//;
2265             push @doubles, $l if defined $unified_info{libraries}->{$l};
2266         }
2267         die "these libraries are both explicitly static and shared:\n  ",
2268             join(" ", @doubles), "\n"
2269             if @doubles;
2270
2271         foreach (keys %sources) {
2272             my $dest = $_;
2273             my $ddest = cleanfile($buildd, $_, $blddir);
2274             foreach (@{$sources{$dest}}) {
2275                 my $s = cleanfile($sourced, $_, $blddir);
2276
2277                 # If it's generated or we simply don't find it in the source
2278                 # tree, we assume it's in the build tree.
2279                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2280                     $s = cleanfile($buildd, $_, $blddir);
2281                 }
2282                 my $o = $_;
2283                 # We recognise C++, C and asm files
2284                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2285                     push @{$check_exist{$s}}, $ddest;
2286                     $o =~ s/\.[csS]$/.o/; # C and assembler
2287                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2288                     $o = cleanfile($buildd, $o, $blddir);
2289                     $unified_info{sources}->{$ddest}->{$o} = -1;
2290                     $unified_info{sources}->{$o}->{$s} = -1;
2291                 } elsif ($s =~ /\.rc$/) {
2292                     # We also recognise resource files
2293                     push @{$check_exist{$s}}, $ddest;
2294                     $o =~ s/\.rc$/.res/; # Resource configuration
2295                     $o = cleanfile($buildd, $o, $blddir);
2296                     $unified_info{sources}->{$ddest}->{$o} = -1;
2297                     $unified_info{sources}->{$o}->{$s} = -1;
2298                 } else {
2299                     push @{$check_exist{$s}}, $ddest;
2300                     $unified_info{sources}->{$ddest}->{$s} = 1;
2301                 }
2302                 # Fix up associated attributes
2303                 if ($o ne $_) {
2304                     $unified_info{attributes}->{sources}->{$ddest}->{$o} =
2305                         $unified_info{attributes}->{sources}->{$o}->{$s} =
2306                         $attributes{sources}->{$dest}->{$_}
2307                         if defined $attributes{sources}->{$dest}->{$_};
2308                 } else {
2309                     $unified_info{attributes}->{sources}->{$ddest}->{$s} =
2310                         $attributes{sources}->{$dest}->{$_}
2311                         if defined $attributes{sources}->{$dest}->{$_};
2312                 }
2313             }
2314         }
2315
2316         foreach (keys %shared_sources) {
2317             my $dest = $_;
2318             my $ddest = cleanfile($buildd, $_, $blddir);
2319             foreach (@{$shared_sources{$dest}}) {
2320                 my $s = cleanfile($sourced, $_, $blddir);
2321
2322                 # If it's generated or we simply don't find it in the source
2323                 # tree, we assume it's in the build tree.
2324                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2325                     $s = cleanfile($buildd, $_, $blddir);
2326                 }
2327
2328                 my $o = $_;
2329                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2330                     # We recognise C++, C and asm files
2331                     push @{$check_exist{$s}}, $ddest;
2332                     $o =~ s/\.[csS]$/.o/; # C and assembler
2333                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2334                     $o = cleanfile($buildd, $o, $blddir);
2335                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2336                     $unified_info{sources}->{$o}->{$s} = -1;
2337                 } elsif ($s =~ /\.rc$/) {
2338                     # We also recognise resource files
2339                     push @{$check_exist{$s}}, $ddest;
2340                     $o =~ s/\.rc$/.res/; # Resource configuration
2341                     $o = cleanfile($buildd, $o, $blddir);
2342                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2343                     $unified_info{sources}->{$o}->{$s} = -1;
2344                 } elsif ($s =~ /\.ld$/) {
2345                     # We also recognise linker scripts (or corresponding)
2346                     # We know they are generated files
2347                     push @{$check_exist{$s}}, $ddest;
2348                     $o = cleanfile($buildd, $_, $blddir);
2349                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
2350                 } else {
2351                     die "unrecognised source file type for shared library: $s\n";
2352                 }
2353                 # Fix up associated attributes
2354                 if ($o ne $_) {
2355                     $unified_info{attributes}->{shared_sources}->{$ddest}->{$o} =
2356                         $unified_info{attributes}->{sources}->{$o}->{$s} =
2357                         $attributes{sources}->{$dest}->{$_}
2358                         if defined $attributes{sources}->{$dest}->{$_};
2359                 } else {
2360                     $unified_info{attributes}->{shared_sources}->{$ddest}->{$o} =
2361                         $attributes{sources}->{$dest}->{$_}
2362                         if defined $attributes{sources}->{$dest}->{$_};
2363                 }
2364             }
2365         }
2366
2367         foreach (keys %generate) {
2368             my $dest = $_;
2369             my $ddest = cleanfile($buildd, $_, $blddir);
2370             die "more than one generator for $dest: "
2371                 ,join(" ", @{$generate{$_}}),"\n"
2372                 if scalar @{$generate{$_}} > 1;
2373             my @generator = split /\s+/, $generate{$dest}->[0];
2374             my $gen = $generator[0];
2375             $generator[0] = cleanfile($sourced, $gen, $blddir);
2376
2377             # If the generator is itself generated, it's in the build tree
2378             if ($generate{$gen} || ! -f $generator[0]) {
2379                 $generator[0] = cleanfile($buildd, $gen, $blddir);
2380             }
2381             $check_generate{$ddest}->{$generator[0]}++;
2382
2383             $unified_info{generate}->{$ddest} = [ @generator ];
2384             # Fix up associated attributes
2385             $unified_info{attributes}->{generate}->{$ddest} =
2386                 $attributes{generate}->{$dest}->{$gen}
2387                 if defined $attributes{generate}->{$dest}->{$gen};
2388         }
2389
2390         foreach (keys %depends) {
2391             my $dest = $_;
2392             my $ddest = $dest;
2393
2394             if ($dest =~ /^\|(.*)\|$/) {
2395                 # Collect the raw target
2396                 $unified_info{targets}->{$1} = 1;
2397                 $ddest = $1;
2398             } elsif ($dest eq '') {
2399                 $ddest = '';
2400             } else {
2401                 $ddest = cleanfile($sourced, $_, $blddir);
2402
2403                 # If the destination doesn't exist in source, it can only be
2404                 # a generated file in the build tree.
2405                 if ($ddest eq $src_configdata || ! -f $ddest) {
2406                     $ddest = cleanfile($buildd, $_, $blddir);
2407                 }
2408             }
2409             foreach (@{$depends{$dest}}) {
2410                 my $d = cleanfile($sourced, $_, $blddir);
2411                 my $d2 = cleanfile($buildd, $_, $blddir);
2412
2413                 # If we know it's generated, or assume it is because we can't
2414                 # find it in the source tree, we set file we depend on to be
2415                 # in the build tree rather than the source tree.
2416                 if ($d eq $src_configdata
2417                     || (grep { $d2 eq $_ }
2418                         keys %{$unified_info{generate}})
2419                     || ! -f $d) {
2420                     $d = $d2;
2421                 }
2422                 $unified_info{depends}->{$ddest}->{$d} = 1;
2423
2424                 # Fix up associated attributes
2425                 $unified_info{attributes}->{depends}->{$ddest}->{$d} =
2426                     $attributes{depends}->{$dest}->{$_}
2427                     if defined $attributes{depends}->{$dest}->{$_};
2428             }
2429         }
2430
2431         foreach (keys %includes) {
2432             my $dest = $_;
2433             my $ddest = cleanfile($sourced, $_, $blddir);
2434
2435             # If the destination doesn't exist in source, it can only be
2436             # a generated file in the build tree.
2437             if ($ddest eq $src_configdata || ! -f $ddest) {
2438                 $ddest = cleanfile($buildd, $_, $blddir);
2439             }
2440             foreach (@{$includes{$dest}}) {
2441                 my $is = cleandir($sourced, $_, $blddir);
2442                 my $ib = cleandir($buildd, $_, $blddir);
2443                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2444                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2445                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2446                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2447             }
2448         }
2449
2450         foreach my $dest (keys %defines) {
2451             my $ddest;
2452
2453             if ($dest ne "") {
2454                 $ddest = cleanfile($sourced, $dest, $blddir);
2455
2456                 # If the destination doesn't exist in source, it can only
2457                 # be a generated file in the build tree.
2458                 if (! -f $ddest) {
2459                     $ddest = cleanfile($buildd, $dest, $blddir);
2460                 }
2461             }
2462             foreach my $v (@{$defines{$dest}}) {
2463                 $v =~ m|^([^=]*)(=.*)?$|;
2464                 die "0 length macro name not permitted\n" if $1 eq "";
2465                 if ($dest ne "") {
2466                     die "$1 defined more than once\n"
2467                         if defined $unified_info{defines}->{$ddest}->{$1};
2468                     $unified_info{defines}->{$ddest}->{$1} = $2;
2469                 } else {
2470                     die "$1 defined more than once\n"
2471                         if grep { $v eq $_ } @{$config{defines}};
2472                     push @{$config{defines}}, $v;
2473                 }
2474             }
2475         }
2476
2477         foreach my $section (keys %imagedocs) {
2478             foreach (@{$imagedocs{$section}}) {
2479                 my $imagedocs = cleanfile($buildd, $_, $blddir);
2480                 $unified_info{imagedocs}->{$section}->{$imagedocs} = 1;
2481             }
2482         }
2483
2484         foreach my $section (keys %htmldocs) {
2485             foreach (@{$htmldocs{$section}}) {
2486                 my $htmldocs = cleanfile($buildd, $_, $blddir);
2487                 $unified_info{htmldocs}->{$section}->{$htmldocs} = 1;
2488             }
2489         }
2490
2491         foreach my $section (keys %mandocs) {
2492             foreach (@{$mandocs{$section}}) {
2493                 my $mandocs = cleanfile($buildd, $_, $blddir);
2494                 $unified_info{mandocs}->{$section}->{$mandocs} = 1;
2495             }
2496         }
2497     }
2498
2499     my $ordinals_text = join(', ', sort keys %ordinals);
2500     warn <<"EOF" if $ordinals_text;
2501
2502 WARNING: ORDINALS were specified for $ordinals_text
2503 They are ignored and should be replaced with a combination of GENERATE,
2504 DEPEND and SHARED_SOURCE.
2505 EOF
2506
2507     # Check that each generated file is only generated once
2508     my $ambiguous_generation = 0;
2509     foreach (sort keys %check_generate) {
2510         my @generators = sort keys %{$check_generate{$_}};
2511         my $generators_txt = join(', ', @generators);
2512         if (scalar @generators > 1) {
2513             warn "$_ is GENERATEd by more than one generator ($generators_txt)\n";
2514             $ambiguous_generation++;
2515         }
2516         if ($check_generate{$_}->{$generators[0]} > 1) {
2517             warn "INFO: $_ has more than one GENERATE declaration (same generator)\n"
2518         }
2519     }
2520     die "There are ambiguous source file generations\n"
2521         if $ambiguous_generation > 0;
2522
2523     # All given source files should exist, or if generated, their
2524     # generator should exist.  This loop ensures this is true.
2525     my $missing = 0;
2526     foreach my $orig (sort keys %check_exist) {
2527         foreach my $dest (@{$check_exist{$orig}}) {
2528             if ($orig ne $src_configdata) {
2529                 if ($orig =~ /\.a$/) {
2530                     # Static library names may be used as sources, so we
2531                     # need to detect those and give them special treatment.
2532                     unless (grep { $_ eq $orig }
2533                             keys %{$unified_info{libraries}}) {
2534                         warn "$orig is given as source for $dest, but no such library is built\n";
2535                         $missing++;
2536                     }
2537                 } else {
2538                     # A source may be generated, and its generator may be
2539                     # generated as well.  We therefore loop to dig out the
2540                     # first generator.
2541                     my $gen = $orig;
2542
2543                     while (my @next = keys %{$check_generate{$gen}}) {
2544                         $gen = $next[0];
2545                     }
2546
2547                     if (! -f $gen) {
2548                         if ($gen ne $orig) {
2549                             $missing++;
2550                             warn "$orig is given as source for $dest, but its generator (leading to $gen) is missing\n";
2551                         } else {
2552                             $missing++;
2553                             warn "$orig is given as source for $dest, but is missing\n";
2554                         }
2555                     }
2556                 }
2557             }
2558         }
2559     }
2560     die "There are files missing\n" if $missing > 0;
2561
2562     # Go through the sources of all libraries and check that the same basename
2563     # doesn't appear more than once.  Some static library archivers depend on
2564     # them being unique.
2565     {
2566         my $err = 0;
2567         foreach my $prod (keys %{$unified_info{libraries}}) {
2568             my @prod_sources =
2569                 map { keys %{$unified_info{sources}->{$_}} }
2570                 keys %{$unified_info{sources}->{$prod}};
2571             my %srccnt = ();
2572
2573             # Count how many times a given each source basename
2574             # appears for each product.
2575             foreach my $src (@prod_sources) {
2576                 $srccnt{basename $src}++;
2577             }
2578
2579             foreach my $src (keys %srccnt) {
2580                 if ((my $cnt = $srccnt{$src}) > 1) {
2581                     print STDERR "$src appears $cnt times for the product $prod\n";
2582                     $err++
2583                 }
2584             }
2585         }
2586         die if $err > 0;
2587     }
2588
2589     # Massage the result
2590
2591     # If we depend on a header file or a perl module, add an inclusion of
2592     # its directory to allow smoothe inclusion
2593     foreach my $dest (keys %{$unified_info{depends}}) {
2594         next if $dest eq "";
2595         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2596             next unless $d =~ /\.(h|pm)$/;
2597             my $i = dirname($d);
2598             my $spot =
2599                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2600                 ? 'build' : 'source';
2601             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2602                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2603         }
2604     }
2605
2606     # Go through all intermediary files and change their names to something that
2607     # reflects what they will be built for.  Note that for some source files,
2608     # this leads to duplicate object files because they are used multiple times.
2609     # the goal is to rename all object files according to this scheme:
2610     #    {productname}-{midfix}-{origobjname}.[o|res]
2611     # the {midfix} is a keyword indicating the type of product, which is mostly
2612     # valuable for libraries since they come in two forms.
2613     #
2614     # This also reorganises the {sources} and {shared_sources} so that the
2615     # former only contains ALL object files that are supposed to end up in
2616     # static libraries and programs, while the latter contains ALL object files
2617     # that are supposed to end up in shared libraries and DSOs.
2618     # The main reason for having two different source structures is to allow
2619     # the same name to be used for the static and the shared variants of a
2620     # library.
2621     {
2622         # Take copies so we don't get interference from added stuff
2623         my %unified_copy = ();
2624         foreach (('sources', 'shared_sources')) {
2625             $unified_copy{$_} = { %{$unified_info{$_}} }
2626                 if defined($unified_info{$_});
2627             delete $unified_info{$_};
2628         }
2629         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2630             # $intent serves multi purposes:
2631             # - give a prefix for the new object files names
2632             # - in the case of libraries, rearrange the object files so static
2633             #   libraries use the 'sources' structure exclusively, while shared
2634             #   libraries use the 'shared_sources' structure exclusively.
2635             my $intent = {
2636                 programs  => { bin    => { src => [ 'sources' ],
2637                                            dst => 'sources' } },
2638                 libraries => { lib    => { src => [ 'sources' ],
2639                                            dst => 'sources' },
2640                                shlib  => { prodselect =>
2641                                                sub { grep !/\.a$/, @_ },
2642                                            src => [ 'sources',
2643                                                     'shared_sources' ],
2644                                            dst => 'shared_sources' } },
2645                 modules   => { dso    => { src => [ 'sources' ],
2646                                            dst => 'sources' } },
2647                 scripts   => { script => { src => [ 'sources' ],
2648                                            dst => 'sources' } }
2649                } -> {$prodtype};
2650             foreach my $kind (keys %$intent) {
2651                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2652                              && $disabled{shared});
2653
2654                 my @src = @{$intent->{$kind}->{src}};
2655                 my $dst = $intent->{$kind}->{dst};
2656                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2657                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2658                     # %prod_sources has all applicable objects as keys, and
2659                     # their corresponding sources as values
2660                     my %prod_sources =
2661                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2662                         map { keys %{$unified_copy{$_}->{$prod}} }
2663                         @src;
2664                     foreach (keys %prod_sources) {
2665                         # Only affect object files and resource files,
2666                         # the others simply get a new value
2667                         # (+1 instead of -1)
2668                         if ($_ =~ /\.(o|res)$/) {
2669                             (my $prodname = $prod) =~ s|\.a$||;
2670                             my $newobj =
2671                                 catfile(dirname($_),
2672                                         basename($prodname)
2673                                             . '-' . $kind
2674                                             . '-' . basename($_));
2675                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2676                             foreach my $src (@{$prod_sources{$_}}) {
2677                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2678                                 # Adjust source attributes
2679                                 my $attrs = $unified_info{attributes}->{sources};
2680                                 if (defined $attrs->{$prod}
2681                                     && defined $attrs->{$prod}->{$_}) {
2682                                     $attrs->{$prod}->{$newobj} =
2683                                         $attrs->{$prod}->{$_};
2684                                     delete $attrs->{$prod}->{$_};
2685                                 }
2686                                 foreach my $objsrc (keys %{$attrs->{$_} // {}}) {
2687                                     $attrs->{$newobj}->{$objsrc} =
2688                                         $attrs->{$_}->{$objsrc};
2689                                     delete $attrs->{$_}->{$objsrc};
2690                                 }
2691                             }
2692                             # Adjust dependencies
2693                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2694                                 $unified_info{depends}->{$_}->{$deps} = -1;
2695                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2696                             }
2697                             # Adjust includes
2698                             foreach my $k (('source', 'build')) {
2699                                 next unless
2700                                     defined($unified_info{includes}->{$_}->{$k});
2701                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2702                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2703                             }
2704                         } else {
2705                             $unified_info{$dst}->{$prod}->{$_} = 1;
2706                         }
2707                     }
2708                 }
2709             }
2710         }
2711     }
2712
2713     # At this point, we have a number of sources with the value -1.  They
2714     # aren't part of the local build and are probably meant for a different
2715     # platform, and can therefore be cleaned away.  That happens when making
2716     # %unified_info more efficient below.
2717
2718     ### Make unified_info a bit more efficient
2719     # One level structures
2720     foreach (("programs", "libraries", "modules", "scripts", "targets")) {
2721         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2722     }
2723     # Two level structures
2724     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends",
2725                      "imagedocs", "htmldocs", "mandocs")) {
2726         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2727             my @items =
2728                 sort
2729                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2730                 keys %{$unified_info{$l1}->{$l2}};
2731             if (@items) {
2732                 $unified_info{$l1}->{$l2} = [ @items ];
2733             } else {
2734                 delete $unified_info{$l1}->{$l2};
2735             }
2736         }
2737     }
2738     # Defines
2739     foreach my $dest (sort keys %{$unified_info{defines}}) {
2740         $unified_info{defines}->{$dest}
2741             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2742                 sort keys %{$unified_info{defines}->{$dest}} ];
2743     }
2744     # Includes
2745     foreach my $dest (sort keys %{$unified_info{includes}}) {
2746         if (defined($unified_info{includes}->{$dest}->{build})) {
2747             my @source_includes = ();
2748             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2749                 if defined($unified_info{includes}->{$dest}->{source});
2750             $unified_info{includes}->{$dest} =
2751                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2752             foreach my $inc (@source_includes) {
2753                 push @{$unified_info{includes}->{$dest}}, $inc
2754                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2755             }
2756         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2757             $unified_info{includes}->{$dest} =
2758                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2759         } else {
2760             delete $unified_info{includes}->{$dest};
2761         }
2762     }
2763
2764     # For convenience collect information regarding directories where
2765     # files are generated, those generated files and the end product
2766     # they end up in where applicable.  Then, add build rules for those
2767     # directories
2768     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2769                      "dso" => [ @{$unified_info{modules}} ],
2770                      "bin" => [ @{$unified_info{programs}} ],
2771                      "script" => [ @{$unified_info{scripts}} ],
2772                      "docs" => [ (map { @{$unified_info{imagedocs}->{$_} // []} }
2773                                   keys %{$unified_info{imagedocs} // {}}),
2774                                  (map { @{$unified_info{htmldocs}->{$_} // []} }
2775                                   keys %{$unified_info{htmldocs} // {}}),
2776                                  (map { @{$unified_info{mandocs}->{$_} // []} }
2777                                   keys %{$unified_info{mandocs} // {}}) ] );
2778     foreach my $type (sort keys %loopinfo) {
2779         foreach my $product (@{$loopinfo{$type}}) {
2780             my %dirs = ();
2781             my $pd = dirname($product);
2782
2783             foreach (@{$unified_info{sources}->{$product} // []},
2784                      @{$unified_info{shared_sources}->{$product} // []}) {
2785                 my $d = dirname($_);
2786
2787                 # We don't want to create targets for source directories
2788                 # when building out of source
2789                 next if ($config{sourcedir} ne $config{builddir}
2790                              && $d =~ m|^\Q$config{sourcedir}\E|);
2791                 # We already have a "test" target, and the current directory
2792                 # is just silly to make a target for
2793                 next if $d eq "test" || $d eq ".";
2794
2795                 $dirs{$d} = 1;
2796                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2797                     if $d ne $pd;
2798             }
2799             foreach (sort keys %dirs) {
2800                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2801                     $product;
2802             }
2803         }
2804     }
2805 }
2806
2807 # For the schemes that need it, we provide the old *_obj configs
2808 # from the *_asm_obj ones
2809 foreach (grep /_(asm|aux)_src$/, keys %target) {
2810     my $src = $_;
2811     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2812     $target{$obj} = $target{$src};
2813     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2814     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2815 }
2816
2817 # Write down our configuration where it fits #########################
2818
2819 my %template_vars = (
2820     config => \%config,
2821     target => \%target,
2822     disablables => \@disablables,
2823     disablables_int => \@disablables_int,
2824     disabled => \%disabled,
2825     withargs => \%withargs,
2826     unified_info => \%unified_info,
2827     tls => \@tls,
2828     dtls => \@dtls,
2829     makevars => [ sort keys %user ],
2830     disabled_info => \%disabled_info,
2831     user_crossable => \@user_crossable,
2832 );
2833 my $configdata_outname = 'configdata.pm';
2834 open CONFIGDATA, ">$configdata_outname.new"
2835     or die "Trying to create $configdata_outname.new: $!";
2836 my $configdata_tmplname = cleanfile($srcdir, "configdata.pm.in", $blddir);
2837 my $configdata_tmpl =
2838     OpenSSL::Template->new(TYPE => 'FILE', SOURCE => $configdata_tmplname);
2839 $configdata_tmpl->fill_in(
2840     FILENAME => $configdata_tmplname,
2841     OUTPUT => \*CONFIGDATA,
2842     HASH => { %template_vars,
2843               autowarntext => [
2844                   'WARNING: do not edit!',
2845                   "Generated by Configure from $configdata_tmplname",
2846               ] }
2847 ) or die $Text::Template::ERROR;
2848 close CONFIGDATA;
2849
2850 rename "$configdata_outname.new", $configdata_outname;
2851 if ($builder_platform eq 'unix') {
2852     my $mode = (0755 & ~umask);
2853     chmod $mode, 'configdata.pm'
2854         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2855 }
2856 print "Created $configdata_outname\n";
2857
2858 print "Running $configdata_outname\n";
2859 my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
2860 my $cmd = "$perlcmd $configdata_outname";
2861 #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2862 system($cmd);
2863 exit 1 if $? != 0;
2864
2865 $SIG{__DIE__} = $orig_death_handler;
2866
2867 print <<"EOF" if ($disabled{threads} eq "unavailable");
2868
2869 The library could not be configured for supporting multi-threaded
2870 applications as the compiler options required on this system are not known.
2871 See file INSTALL.md for details if you need multi-threading.
2872 EOF
2873
2874 print <<"EOF" if ($no_shared_warn);
2875
2876 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2877 platform, so we will pretend you gave the option 'no-pic', which also disables
2878 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2879 or position independent code, please let us know (but please first make sure
2880 you have tried with a current version of OpenSSL).
2881 EOF
2882
2883 print $banner;
2884
2885 exit(0);
2886
2887 ######################################################################
2888 #
2889 # Helpers and utility functions
2890 #
2891
2892 # Death handler, to print a helpful message in case of failure #######
2893 #
2894 sub death_handler {
2895     die @_ if $^S;              # To prevent the added message in eval blocks
2896     my $build_file = $target{build_file} // "build file";
2897     my @message = ( <<"_____", @_ );
2898
2899 Failure!  $build_file wasn't produced.
2900 Please read INSTALL.md and associated NOTES-* files.  You may also have to
2901 look over your available compiler tool chain or change your configuration.
2902
2903 _____
2904
2905     # Dying is terminal, so it's ok to reset the signal handler here.
2906     $SIG{__DIE__} = $orig_death_handler;
2907     die @message;
2908 }
2909
2910 # Configuration file reading #########################################
2911
2912 # Note: All of the helper functions are for lazy evaluation.  They all
2913 # return a CODE ref, which will return the intended value when evaluated.
2914 # Thus, whenever there's mention of a returned value, it's about that
2915 # intended value.
2916
2917 # Helper function to implement conditional value variants, with a default
2918 # plus additional values based on the value of $config{build_type}.
2919 # Arguments are given in hash table form:
2920 #
2921 #       picker(default => "Basic string: ",
2922 #              debug   => "debug",
2923 #              release => "release")
2924 #
2925 # When configuring with --debug, the resulting string will be
2926 # "Basic string: debug", and when not, it will be "Basic string: release"
2927 #
2928 # This can be used to create variants of sets of flags according to the
2929 # build type:
2930 #
2931 #       cflags => picker(default => "-Wall",
2932 #                        debug   => "-g -O0",
2933 #                        release => "-O3")
2934 #
2935 sub picker {
2936     my %opts = @_;
2937     return sub { add($opts{default} || (),
2938                      $opts{$config{build_type}} || ())->(); }
2939 }
2940
2941 # Helper function to combine several values of different types into one.
2942 # This is useful if you want to combine a string with the result of a
2943 # lazy function, such as:
2944 #
2945 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2946 #
2947 sub combine {
2948     my @stuff = @_;
2949     return sub { add(@stuff)->(); }
2950 }
2951
2952 # Helper function to implement conditional values depending on the value
2953 # of $disabled{threads}.  Can be used as follows:
2954 #
2955 #       cflags => combine("-Wall", threads("-pthread"))
2956 #
2957 sub threads {
2958     my @flags = @_;
2959     return sub { add($disabled{threads} ? () : @flags)->(); }
2960 }
2961
2962 sub shared {
2963     my @flags = @_;
2964     return sub { add($disabled{shared} ? () : @flags)->(); }
2965 }
2966
2967 our $add_called = 0;
2968 # Helper function to implement adding values to already existing configuration
2969 # values.  It handles elements that are ARRAYs, CODEs and scalars
2970 sub _add {
2971     my $separator = shift;
2972
2973     # If there's any ARRAY in the collection of values OR the separator
2974     # is undef, we will return an ARRAY of combined values, otherwise a
2975     # string of joined values with $separator as the separator.
2976     my $found_array = !defined($separator);
2977
2978     my @values =
2979         map {
2980             my $res = $_;
2981             while (ref($res) eq "CODE") {
2982                 $res = $res->();
2983             }
2984             if (defined($res)) {
2985                 if (ref($res) eq "ARRAY") {
2986                     $found_array = 1;
2987                     @$res;
2988                 } else {
2989                     $res;
2990                 }
2991             } else {
2992                 ();
2993             }
2994     } (@_);
2995
2996     $add_called = 1;
2997
2998     if ($found_array) {
2999         [ @values ];
3000     } else {
3001         join($separator, grep { defined($_) && $_ ne "" } @values);
3002     }
3003 }
3004 sub add_before {
3005     my $separator = " ";
3006     if (ref($_[$#_]) eq "HASH") {
3007         my $opts = pop;
3008         $separator = $opts->{separator};
3009     }
3010     my @x = @_;
3011     sub { _add($separator, @x, @_) };
3012 }
3013 sub add {
3014     my $separator = " ";
3015     if (ref($_[$#_]) eq "HASH") {
3016         my $opts = pop;
3017         $separator = $opts->{separator};
3018     }
3019     my @x = @_;
3020     sub { _add($separator, @_, @x) };
3021 }
3022
3023 sub read_eval_file {
3024     my $fname = shift;
3025     my $content;
3026     my @result;
3027
3028     open F, "< $fname" or die "Can't open '$fname': $!\n";
3029     {
3030         undef local $/;
3031         $content = <F>;
3032     }
3033     close F;
3034     {
3035         local $@;
3036
3037         @result = ( eval $content );
3038         warn $@ if $@;
3039     }
3040     return wantarray ? @result : $result[0];
3041 }
3042
3043 # configuration reader, evaluates the input file as a perl script and expects
3044 # it to fill %targets with target configurations.  Those are then added to
3045 # %table.
3046 sub read_config {
3047     my $fname = shift;
3048     my %targets;
3049
3050     {
3051         # Protect certain tables from tampering
3052         local %table = ();
3053
3054         %targets = read_eval_file($fname);
3055     }
3056     my %preexisting = ();
3057     foreach (sort keys %targets) {
3058         $preexisting{$_} = 1 if $table{$_};
3059     }
3060     die <<"EOF",
3061 The following config targets from $fname
3062 shadow pre-existing config targets with the same name:
3063 EOF
3064         map { "  $_\n" } sort keys %preexisting
3065         if %preexisting;
3066
3067
3068     # For each target, check that it's configured with a hash table.
3069     foreach (keys %targets) {
3070         if (ref($targets{$_}) ne "HASH") {
3071             if (ref($targets{$_}) eq "") {
3072                 warn "Deprecated target configuration for $_, ignoring...\n";
3073             } else {
3074                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3075             }
3076             delete $targets{$_};
3077         } else {
3078             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3079         }
3080     }
3081
3082     %table = (%table, %targets);
3083
3084 }
3085
3086 # configuration resolver.  Will only resolve all the lazy evaluation
3087 # codeblocks for the chosen target and all those it inherits from,
3088 # recursively
3089 sub resolve_config {
3090     my $target = shift;
3091     my @breadcrumbs = @_;
3092
3093 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3094
3095     if (grep { $_ eq $target } @breadcrumbs) {
3096         die "inherit_from loop!  target backtrace:\n  "
3097             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3098     }
3099
3100     if (!defined($table{$target})) {
3101         warn "Warning! target $target doesn't exist!\n";
3102         return ();
3103     }
3104     # Recurse through all inheritances.  They will be resolved on the
3105     # fly, so when this operation is done, they will all just be a
3106     # bunch of attributes with string values.
3107     # What we get here, though, are keys with references to lists of
3108     # the combined values of them all.  We will deal with lists after
3109     # this stage is done.
3110     my %combined_inheritance = ();
3111     if ($table{$target}->{inherit_from}) {
3112         my @inherit_from =
3113             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3114         foreach (@inherit_from) {
3115             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3116
3117             # 'template' is a marker that's considered private to
3118             # the config that had it.
3119             delete $inherited_config{template};
3120
3121             foreach (keys %inherited_config) {
3122                 if (!$combined_inheritance{$_}) {
3123                     $combined_inheritance{$_} = [];
3124                 }
3125                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3126             }
3127         }
3128     }
3129
3130     # We won't need inherit_from in this target any more, since we've
3131     # resolved all the inheritances that lead to this
3132     delete $table{$target}->{inherit_from};
3133
3134     # Now is the time to deal with those lists.  Here's the place to
3135     # decide what shall be done with those lists, all based on the
3136     # values of the target we're currently dealing with.
3137     # - If a value is a coderef, it will be executed with the list of
3138     #   inherited values as arguments.
3139     # - If the corresponding key doesn't have a value at all or is the
3140     #   empty string, the inherited value list will be run through the
3141     #   default combiner (below), and the result becomes this target's
3142     #   value.
3143     # - Otherwise, this target's value is assumed to be a string that
3144     #   will simply override the inherited list of values.
3145     my $default_combiner = add();
3146
3147     my %all_keys =
3148         map { $_ => 1 } (keys %combined_inheritance,
3149                          keys %{$table{$target}});
3150
3151     sub process_values {
3152         my $object    = shift;
3153         my $inherited = shift;  # Always a [ list ]
3154         my $target    = shift;
3155         my $entry     = shift;
3156
3157         $add_called = 0;
3158
3159         while(ref($object) eq "CODE") {
3160             $object = $object->(@$inherited);
3161         }
3162         if (!defined($object)) {
3163             return ();
3164         }
3165         elsif (ref($object) eq "ARRAY") {
3166             local $add_called;  # To make sure recursive calls don't affect it
3167             return [ map { process_values($_, $inherited, $target, $entry) }
3168                      @$object ];
3169         } elsif (ref($object) eq "") {
3170             return $object;
3171         } else {
3172             die "cannot handle reference type ",ref($object)
3173                 ," found in target ",$target," -> ",$entry,"\n";
3174         }
3175     }
3176
3177     foreach my $key (sort keys %all_keys) {
3178         my $previous = $combined_inheritance{$key};
3179
3180         # Current target doesn't have a value for the current key?
3181         # Assign it the default combiner, the rest of this loop body
3182         # will handle it just like any other coderef.
3183         if (!exists $table{$target}->{$key}) {
3184             $table{$target}->{$key} = $default_combiner;
3185         }
3186
3187         $table{$target}->{$key} = process_values($table{$target}->{$key},
3188                                                $combined_inheritance{$key},
3189                                                $target, $key);
3190         unless(defined($table{$target}->{$key})) {
3191             delete $table{$target}->{$key};
3192         }
3193 #        if ($extra_checks &&
3194 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$key})) {
3195 #            warn "$key got replaced in $target\n";
3196 #        }
3197     }
3198
3199     # Finally done, return the result.
3200     return %{$table{$target}};
3201 }
3202
3203 sub usage
3204         {
3205         print STDERR $usage;
3206         print STDERR "\npick os/compiler from:\n";
3207         my $j=0;
3208         my $i;
3209         my $k=0;
3210         foreach $i (sort keys %table)
3211                 {
3212                 next if $table{$i}->{template};
3213                 next if $i =~ /^debug/;
3214                 $k += length($i) + 1;
3215                 if ($k > 78)
3216                         {
3217                         print STDERR "\n";
3218                         $k=length($i);
3219                         }
3220                 print STDERR $i . " ";
3221                 }
3222         foreach $i (sort keys %table)
3223                 {
3224                 next if $table{$i}->{template};
3225                 next if $i !~ /^debug/;
3226                 $k += length($i) + 1;
3227                 if ($k > 78)
3228                         {
3229                         print STDERR "\n";
3230                         $k=length($i);
3231                         }
3232                 print STDERR $i . " ";
3233                 }
3234         exit(1);
3235         }
3236
3237 sub compiler_predefined {
3238     state %predefined;
3239     my $cc = shift;
3240
3241     return () if $^O eq 'VMS';
3242
3243     die 'compiler_predefined called without a compiler command'
3244         unless $cc;
3245
3246     if (! $predefined{$cc}) {
3247
3248         $predefined{$cc} = {};
3249
3250         # collect compiler pre-defines from gcc or gcc-alike...
3251         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3252         while (my $l = <PIPE>) {
3253             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3254             $predefined{$cc}->{$1} = $2 // '';
3255         }
3256         close(PIPE);
3257     }
3258
3259     return %{$predefined{$cc}};
3260 }
3261
3262 sub which
3263 {
3264     my ($name)=@_;
3265
3266     if (eval { require IPC::Cmd; 1; }) {
3267         IPC::Cmd->import();
3268         return scalar IPC::Cmd::can_run($name);
3269     } else {
3270         # if there is $directories component in splitpath,
3271         # then it's not something to test with $PATH...
3272         return $name if (File::Spec->splitpath($name))[1];
3273
3274         foreach (File::Spec->path()) {
3275             my $fullpath = catfile($_, "$name$target{exe_extension}");
3276             if (-f $fullpath and -x $fullpath) {
3277                 return $fullpath;
3278             }
3279         }
3280     }
3281 }
3282
3283 sub env
3284 {
3285     my $name = shift;
3286     my %opts = @_;
3287
3288     unless ($opts{cacheonly}) {
3289         # Note that if $ENV{$name} doesn't exist or is undefined,
3290         # $config{perlenv}->{$name} will be created with the value
3291         # undef.  This is intentional.
3292
3293         $config{perlenv}->{$name} = $ENV{$name}
3294             if ! exists $config{perlenv}->{$name};
3295     }
3296     return $config{perlenv}->{$name};
3297 }
3298
3299 # Configuration printer ##############################################
3300
3301 sub print_table_entry
3302 {
3303     local $now_printing = shift;
3304     my %target = resolve_config($now_printing);
3305     my $type = shift;
3306
3307     # Don't print the templates
3308     return if $target{template};
3309
3310     my @sequence = (
3311         "sys_id",
3312         "cpp",
3313         "cppflags",
3314         "defines",
3315         "includes",
3316         "cc",
3317         "cflags",
3318         "ld",
3319         "lflags",
3320         "loutflag",
3321         "ex_libs",
3322         "bn_ops",
3323         "enable",
3324         "disable",
3325         "poly1035_asm_src",
3326         "thread_scheme",
3327         "perlasm_scheme",
3328         "dso_scheme",
3329         "shared_target",
3330         "shared_cflag",
3331         "shared_defines",
3332         "shared_ldflag",
3333         "shared_rcflag",
3334         "shared_extension",
3335         "dso_extension",
3336         "obj_extension",
3337         "exe_extension",
3338         "ranlib",
3339         "ar",
3340         "arflags",
3341         "aroutflag",
3342         "rc",
3343         "rcflags",
3344         "rcoutflag",
3345         "mt",
3346         "mtflags",
3347         "mtinflag",
3348         "mtoutflag",
3349         "multilib",
3350         "build_scheme",
3351         );
3352
3353     if ($type eq "TABLE") {
3354         print "\n";
3355         print "*** $now_printing\n";
3356         foreach (@sequence) {
3357             if (ref($target{$_}) eq "ARRAY") {
3358                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3359             } else {
3360                 printf "\$%-12s = %s\n", $_, $target{$_};
3361             }
3362         }
3363     } elsif ($type eq "HASH") {
3364         my $largest =
3365             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3366         print "    '$now_printing' => {\n";
3367         foreach (@sequence) {
3368             if ($target{$_}) {
3369                 if (ref($target{$_}) eq "ARRAY") {
3370                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3371                 } else {
3372                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3373                 }
3374             }
3375         }
3376         print "    },\n";
3377     }
3378 }
3379
3380 # Utility routines ###################################################
3381
3382 # On VMS, if the given file is a logical name, File::Spec::Functions
3383 # will consider it an absolute path.  There are cases when we want a
3384 # purely syntactic check without checking the environment.
3385 sub isabsolute {
3386     my $file = shift;
3387
3388     # On non-platforms, we just use file_name_is_absolute().
3389     return file_name_is_absolute($file) unless $^O eq "VMS";
3390
3391     # If the file spec includes a device or a directory spec,
3392     # file_name_is_absolute() is perfectly safe.
3393     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3394
3395     # Here, we know the given file spec isn't absolute
3396     return 0;
3397 }
3398
3399 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3400 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3401 # realpath() requires that at least all path components except the last is an
3402 # existing directory.  On VMS, the last component of the directory spec must
3403 # exist.
3404 sub absolutedir {
3405     my $dir = shift;
3406
3407     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3408     # will return the volume name for the device, no matter what.  Also,
3409     # it will return an incorrect directory spec if the argument is a
3410     # directory that doesn't exist.
3411     if ($^O eq "VMS") {
3412         return rel2abs($dir);
3413     }
3414
3415     # We use realpath() on Unix, since no other will properly clean out
3416     # a directory spec.
3417     use Cwd qw/realpath/;
3418
3419     return realpath($dir);
3420 }
3421
3422 # Check if all paths are one and the same, using stat.  They must both exist
3423 # We need this for the cases when File::Spec doesn't detect case insensitivity
3424 # (File::Spec::Unix assumes case sensitivity)
3425 sub samedir {
3426     die "samedir expects two arguments\n" unless scalar @_ == 2;
3427
3428     my @stat0 = stat($_[0]);    # First argument
3429     my @stat1 = stat($_[1]);    # Second argument
3430
3431     die "Couldn't stat $_[0]" unless @stat0;
3432     die "Couldn't stat $_[1]" unless @stat1;
3433
3434     # Compare device number
3435     return 0 unless ($stat0[0] == $stat1[0]);
3436     # Compare "inode".  The perl manual recommends comparing as
3437     # string rather than as number.
3438     return 0 unless ($stat0[1] eq $stat1[1]);
3439
3440     return 1;                   # All the same
3441 }
3442
3443 sub quotify {
3444     my %processors = (
3445         perl    => sub { my $x = shift;
3446                          $x =~ s/([\\\$\@"])/\\$1/g;
3447                          return '"'.$x.'"'; },
3448         maybeshell => sub { my $x = shift;
3449                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3450                             if ($x ne $y || $x =~ m|\s|) {
3451                                 return '"'.$y.'"';
3452                             } else {
3453                                 return $x;
3454                             }
3455                         },
3456         );
3457     my $for = shift;
3458     my $processor =
3459         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3460
3461     return map { $processor->($_); } @_;
3462 }
3463
3464 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3465 # $filename is a file name to read from
3466 # $line_concat_cond_re is a regexp detecting a line continuation ending
3467 # $line_concat is a CODEref that takes care of concatenating two lines
3468 sub collect_from_file {
3469     my $filename = shift;
3470     my $line_concat_cond_re = shift;
3471     my $line_concat = shift;
3472
3473     open my $fh, $filename || die "unable to read $filename: $!\n";
3474     return sub {
3475         my $saved_line = "";
3476         $_ = "";
3477         while (<$fh>) {
3478             s|\R$||;
3479             if (defined $line_concat) {
3480                 $_ = $line_concat->($saved_line, $_);
3481                 $saved_line = "";
3482             }
3483             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3484                 $saved_line = $_;
3485                 next;
3486             }
3487             return $_;
3488         }
3489         die "$filename ending with continuation line\n" if $_;
3490         close $fh;
3491         return undef;
3492     }
3493 }
3494
3495 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3496 # $array is an ARRAYref of lines
3497 # $line_concat_cond_re is a regexp detecting a line continuation ending
3498 # $line_concat is a CODEref that takes care of concatenating two lines
3499 sub collect_from_array {
3500     my $array = shift;
3501     my $line_concat_cond_re = shift;
3502     my $line_concat = shift;
3503     my @array = (@$array);
3504
3505     return sub {
3506         my $saved_line = "";
3507         $_ = "";
3508         while (defined($_ = shift @array)) {
3509             s|\R$||;
3510             if (defined $line_concat) {
3511                 $_ = $line_concat->($saved_line, $_);
3512                 $saved_line = "";
3513             }
3514             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3515                 $saved_line = $_;
3516                 next;
3517             }
3518             return $_;
3519         }
3520         die "input text ending with continuation line\n" if $_;
3521         return undef;
3522     }
3523 }
3524
3525 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3526 # $lineiterator is a CODEref that delivers one line at a time.
3527 # All following arguments are regex/CODEref pairs, where the regexp detects a
3528 # line and the CODEref does something with the result of the regexp.
3529 sub collect_information {
3530     my $lineiterator = shift;
3531     my %collectors = @_;
3532
3533     while(defined($_ = $lineiterator->())) {
3534         s|\R$||;
3535         my $found = 0;
3536         if ($collectors{"BEFORE"}) {
3537             $collectors{"BEFORE"}->($_);
3538         }
3539         foreach my $re (keys %collectors) {
3540             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3541                 $collectors{$re}->($lineiterator);
3542                 $found = 1;
3543             };
3544         }
3545         if ($collectors{"OTHERWISE"}) {
3546             $collectors{"OTHERWISE"}->($lineiterator, $_)
3547                 unless $found || !defined $collectors{"OTHERWISE"};
3548         }
3549         if ($collectors{"AFTER"}) {
3550             $collectors{"AFTER"}->($_);
3551         }
3552     }
3553 }
3554
3555 # tokenize($line)
3556 # tokenize($line,$separator)
3557 # $line is a line of text to split up into tokens
3558 # $separator [optional] is a regular expression that separates the tokens,
3559 # the default being spaces.  Do not use quotes of any kind as separators,
3560 # that will give undefined results.
3561 # Returns a list of tokens.
3562 #
3563 # Tokens are divided by separator (spaces by default).  If the tokens include
3564 # the separators, they have to be quoted with single or double quotes.
3565 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3566 # with backslash.
3567 # Basically, the same quoting rules apply for " and ' as in any
3568 # Unix shell.
3569 sub tokenize {
3570     my $line = my $debug_line = shift;
3571     my $separator = shift // qr|\s+|;
3572     my @result = ();
3573
3574     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3575         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3576     }
3577
3578     while ($line =~ s|^${separator}||, $line ne "") {
3579         my $token = "";
3580     again:
3581         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3582         $token .= $1;
3583         $line = $2.$';
3584
3585         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3586             $token .= $1;
3587             $line = $';
3588             goto again;
3589         } elsif ($line =~ m/^'([^']*)'/) {
3590             $token .= $1;
3591             $line = $';
3592             goto again;
3593         }
3594         push @result, $token;
3595     }
3596
3597     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3598         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3599         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3600     }
3601     return @result;
3602 }