Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2022 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::fallback "$FindBin::Bin/external/perl/MODULES.txt";
  21 use OpenSSL::Glob;
  22 use OpenSSL::Template;
  23 use OpenSSL::config;
  24
  25 # see INSTALL.md for instructions.
  26
  27 my $orig_death_handler = $SIG{__DIE__};
  28 $SIG{__DIE__} = \&death_handler;
  29
  30 my $usage="Usage: Configure [no-<feature> ...] [enable-<feature> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]thread-pool] [[no-]default-thread-pool] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  31
  32 my $banner = <<"EOF";
  33
  34 **********************************************************************
  35 ***                                                                ***
  36 ***   OpenSSL has been successfully configured                     ***
  37 ***                                                                ***
  38 ***   If you encounter a problem while building, please open an    ***
  39 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
  40 ***   and include the output from the following command:           ***
  41 ***                                                                ***
  42 ***       perl configdata.pm --dump                                ***
  43 ***                                                                ***
  44 ***   (If you are new to OpenSSL, you might want to consult the    ***
  45 ***   'Troubleshooting' section in the INSTALL.md file first)      ***
  46 ***                                                                ***
  47 **********************************************************************
  48 EOF
  49
  50 # Options:
  51 #
  52 # --config      add the given configuration file, which will be read after
  53 #               any "Configurations*" files that are found in the same
  54 #               directory as this script.
  55 # --prefix      prefix for the OpenSSL installation, which includes the
  56 #               directories bin, lib, include, share/man, share/doc/openssl
  57 #               This becomes the value of INSTALLTOP in Makefile
  58 #               (Default: /usr/local)
  59 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  60 #               If it's a relative directory, it will be added on the directory
  61 #               given with --prefix.
  62 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  63 #               (Default: PREFIX/ssl)
  64 # --banner=".." Output specified text instead of default completion banner
  65 #
  66 # -w            Don't wait after showing a Configure warning
  67 #
  68 # --cross-compile-prefix Add specified prefix to binutils components.
  69 #
  70 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0
  71 #               Define the public APIs as they were for that version
  72 #               including patch releases.  If 'no-deprecated' is also
  73 #               given, do not compile support for interfaces deprecated
  74 #               up to and including the specified OpenSSL version.
  75 #
  76 # no-hw-xxx     do not compile support for specific crypto hardware.
  77 #               Generic OpenSSL-style methods relating to this support
  78 #               are always compiled but return NULL if the hardware
  79 #               support isn't compiled.
  80 # no-hw         do not compile support for any crypto hardware.
  81 # [no-]threads  [don't] try to create a library that is suitable for
  82 #               multithreaded applications (default is "threads" if we
  83 #               know how to do it)
  84 # [no-]thread-pool
  85 #               [don't] allow thread pool functionality
  86 # [no-]default-thread-pool
  87 #               [don't] allow default thread pool functionality
  88 # [no-]shared   [don't] try to create shared libraries when supported.
  89 # [no-]pic      [don't] try to build position independent code when supported.
  90 #               If disabled, it also disables shared and dynamic-engine.
  91 # no-asm        do not use assembler
  92 # no-egd        do not compile support for the entropy-gathering daemon APIs
  93 # [no-]zlib     [don't] compile support for zlib compression.
  94 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  95 #               library and will be loaded at run-time by the OpenSSL library.
  96 # sctp          include SCTP support
  97 # no-quic       disable QUIC support
  98 # no-uplink     Don't build support for UPLINK interface.
  99 # enable-weak-ssl-ciphers
 100 #               Enable weak ciphers that are disabled by default.
 101 # 386           generate 80386 code in assembly modules
 102 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
 103 #               mentioned '386' option implies this one
 104 # no-<cipher>   build without specified algorithm (dsa, idea, rc5, ...)
 105 # -<xxx> +<xxx> All options which are unknown to the 'Configure' script are
 106 # /<xxx>        passed through to the compiler. Unix-style options beginning
 107 #               with a '-' or '+' are recognized, as well as Windows-style
 108 #               options beginning with a '/'. If the option contains arguments
 109 #               separated by spaces, then the URL-style notation %20 can be
 110 #               used for the space character in order to avoid having to quote
 111 #               the option. For example, -opt%20arg gets expanded to -opt arg.
 112 #               In fact, any ASCII character can be encoded as %xx using its
 113 #               hexadecimal encoding.
 114 # -static       while -static is also a pass-through compiler option (and
 115 #               as such is limited to environments where it's actually
 116 #               meaningful), it triggers a number configuration options,
 117 #               namely no-pic, no-shared and no-threads. It is
 118 #               argued that the only reason to produce statically linked
 119 #               binaries (and in context it means executables linked with
 120 #               -static flag, and not just executables linked with static
 121 #               libcrypto.a) is to eliminate dependency on specific run-time,
 122 #               a.k.a. libc version. The mentioned config options are meant
 123 #               to achieve just that. Unfortunately on Linux it's impossible
 124 #               to eliminate the dependency completely for openssl executable
 125 #               because of getaddrinfo and gethostbyname calls, which can
 126 #               invoke dynamically loadable library facility anyway to meet
 127 #               the lookup requests. For this reason on Linux statically
 128 #               linked openssl executable has rather debugging value than
 129 #               production quality.
 130 #
 131 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
 132 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
 133 # Following are set automatically by this script
 134 #
 135 # MD5_ASM       use some extra md5 assembler,
 136 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 137 # RMD160_ASM    use some extra ripemd160 assembler,
 138 # SHA256_ASM    sha256_block is implemented in assembler
 139 # SHA512_ASM    sha512_block is implemented in assembler
 140 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 141
 142 # Minimum warning options... any contributions to OpenSSL should at least
 143 # get past these.  Note that we only use these with C compilers, not with
 144 # C++ compilers.
 145
 146 # -DPEDANTIC complements -pedantic and is meant to mask code that
 147 # is not strictly standard-compliant and/or implementation-specific,
 148 # e.g. inline assembly, disregards to alignment requirements, such
 149 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 150 # to be used even in sanitized builds, because sanitizer too is
 151 # supposed to and does take notice of non-standard behaviour. Then
 152 # -pedantic with pre-C9x compiler would also complain about 'long
 153 # long' not being supported. As 64-bit algorithms are common now,
 154 # it grew impossible to resolve this without sizeable additional
 155 # code, so we just tell compiler to be pedantic about everything
 156 # but 'long long' type.
 157
 158 my @gcc_devteam_warn = qw(
 159     -DPEDANTIC -pedantic -Wno-long-long -DUNUSEDRESULT_DEBUG
 160     -Wall
 161     -Wmissing-declarations
 162     -Wextra
 163     -Wno-unused-parameter
 164     -Wno-missing-field-initializers
 165     -Wswitch
 166     -Wsign-compare
 167     -Wshadow
 168     -Wformat
 169     -Wno-type-limits
 170     -Wno-tautological-constant-out-of-range-compare
 171     -Wundef
 172     -Werror
 173     -Wmissing-prototypes
 174     -Wstrict-prototypes
 175 );
 176
 177 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 178 # TODO(openssl-team): fix problems and investigate if (at least) the
 179 # following warnings can also be enabled:
 180 #       -Wcast-align
 181 #       -Wunreachable-code -- no, too ugly/compiler-specific
 182 #       -Wlanguage-extension-token -- no, we use asm()
 183 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 184 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 185 my @clang_devteam_warn = qw(
 186     -Wno-unknown-warning-option
 187     -Wswitch-default
 188     -Wno-parentheses-equality
 189     -Wno-language-extension-token
 190     -Wno-extended-offsetof
 191     -Wconditional-uninitialized
 192     -Wincompatible-pointer-types-discards-qualifiers
 193     -Wmissing-variable-declarations
 194 );
 195
 196 my @cl_devteam_warn = qw(
 197     /WX
 198 );
 199
 200 my $strict_warnings = 0;
 201
 202 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 203 # which would cover all BSD flavors. -pthread applies to them all,
 204 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 205 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 206 # which has to be accompanied by explicit -D_THREAD_SAFE and
 207 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 208 # seems to be sufficient?
 209 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 210
 211 #
 212 # API compatibility name to version number mapping.
 213 #
 214 my $apitable = {
 215     # This table expresses when API additions or changes can occur.
 216     # The numbering used changes from 3.0 and on because we updated
 217     # (solidified) our version numbering scheme at that point.
 218
 219     # From 3.0 and on, we internalise the given version number in decimal
 220     # as MAJOR * 10000 + MINOR * 100 + 0
 221     "3.0.0" => 30000,
 222     "3.0"   => 30000,
 223
 224     # Note that before 3.0, we didn't have the same version number scheme.
 225     # Still, the numbering we use here covers what we need.
 226     "1.1.1" => 10101,
 227     "1.1.0" => 10100,
 228     "1.0.2" => 10002,
 229     "1.0.1" => 10001,
 230     "1.0.0" => 10000,
 231     "0.9.8" =>   908,
 232 };
 233
 234 # For OpenSSL::config::get_platform
 235 my %guess_opts = ();
 236
 237 my $dryrun = 0;
 238
 239 our %table = ();
 240 our %config = ();
 241 our %withargs = ();
 242 our $now_printing;      # set to current entry's name in print_table_entry
 243                         # (todo: right thing would be to encapsulate name
 244                         # into %target [class] and make print_table_entry
 245                         # a method)
 246
 247 # Forward declarations ###############################################
 248
 249 # read_config(filename)
 250 #
 251 # Reads a configuration file and populates %table with the contents
 252 # (which the configuration file places in %targets).
 253 sub read_config;
 254
 255 # resolve_config(target)
 256 #
 257 # Resolves all the late evaluations, inheritances and so on for the
 258 # chosen target and any target it inherits from.
 259 sub resolve_config;
 260
 261
 262 # Information collection #############################################
 263
 264 # Unified build supports separate build dir
 265 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 266 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 267
 268 # File::Spec::Unix doesn't detect case insensitivity, so we make sure to
 269 # check if the source and build directory are really the same, and make
 270 # them so.  This avoids all kinds of confusion later on.
 271 # We must check @File::Spec::ISA rather than using File::Spec->isa() to
 272 # know if File::Spec ended up loading File::Spec::Unix.
 273 $srcdir = $blddir
 274     if (grep(/::Unix$/, @File::Spec::ISA)
 275         && samedir($srcdir, $blddir));
 276
 277 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 278
 279 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 280
 281 $config{sourcedir} = abs2rel($srcdir, $blddir);
 282 $config{builddir} = abs2rel($blddir, $blddir);
 283 # echo -n 'holy hand grenade of antioch' | openssl sha256
 284 $config{FIPSKEY} =
 285     'f4556650ac31d35461610bac4ed81b1a181b2d8a43ea2854cbae22ca74560813';
 286
 287 # Collect reconfiguration information if needed
 288 my @argvcopy=@ARGV;
 289
 290 if (grep /^reconf(igure)?$/, @argvcopy) {
 291     die "reconfiguring with other arguments present isn't supported"
 292         if scalar @argvcopy > 1;
 293     if (-f "./configdata.pm") {
 294         my $file = "./configdata.pm";
 295         unless (my $return = do $file) {
 296             die "couldn't parse $file: $@" if $@;
 297             die "couldn't do $file: $!"    unless defined $return;
 298             die "couldn't run $file"       unless $return;
 299         }
 300
 301         @argvcopy = defined($configdata::config{perlargv}) ?
 302             @{$configdata::config{perlargv}} : ();
 303         die "Incorrect data to reconfigure, please do a normal configuration\n"
 304             if (grep(/^reconf/,@argvcopy));
 305         $config{perlenv} = $configdata::config{perlenv} // {};
 306     } else {
 307         die "Insufficient data to reconfigure, please do a normal configuration\n";
 308     }
 309 }
 310
 311 $config{perlargv} = [ @argvcopy ];
 312
 313 # Historical: if known directories in crypto/ have been removed, it means
 314 # that those sub-systems are disabled.
 315 # (the other option would be to removed them from the SUBDIRS statement in
 316 # crypto/build.info)
 317 # We reverse the input list for cosmetic purely reasons, to compensate that
 318 # 'unshift' adds at the front of the list (i.e. in reverse input order).
 319 foreach ( reverse sort( 'aes', 'aria', 'bf', 'camellia', 'cast', 'des', 'dh',
 320                         'dsa', 'ec', 'hmac', 'idea', 'md2', 'md5', 'mdc2',
 321                         'rc2', 'rc4', 'rc5', 'ripemd', 'seed', 'sha',
 322                         'sm2', 'sm3', 'sm4') ) {
 323     unshift @argvcopy, "no-$_" if ! -d catdir($srcdir, 'crypto', $_);
 324 }
 325
 326 # Collect version numbers
 327 my %version = ();
 328
 329 collect_information(
 330     collect_from_file(catfile($srcdir,'VERSION.dat')),
 331     qr/\s*(\w+)\s*=\s*(.*?)\s*$/ =>
 332         sub {
 333             # Only define it if there is a value at all
 334             if ($2 ne '') {
 335                 my $k = $1;
 336                 my $v = $2;
 337                 # Some values are quoted.  Trim the quotes
 338                 $v = $1 if $v =~ /^"(.*)"$/;
 339                 $version{uc $k} = $v;
 340             }
 341         },
 342     "OTHERWISE" =>
 343         sub { die "Something wrong with this line:\n$_\nin $srcdir/VERSION.dat" },
 344     );
 345
 346 $config{major} = $version{MAJOR} // 'unknown';
 347 $config{minor} = $version{MINOR} // 'unknown';
 348 $config{patch} = $version{PATCH} // 'unknown';
 349 $config{prerelease} =
 350     defined $version{PRE_RELEASE_TAG} ? "-$version{PRE_RELEASE_TAG}" : '';
 351 $config{build_metadata} =
 352     defined $version{BUILD_METADATA} ? "+$version{BUILD_METADATA}" : '';
 353 $config{shlib_version} = $version{SHLIB_VERSION} // 'unknown';
 354 $config{release_date} = $version{RELEASE_DATE} // 'xx XXX xxxx';
 355
 356 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 357 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 358
 359 die "erroneous version information in VERSION.dat: ",
 360     "$config{version}, $config{shlib_version}\n"
 361     unless (defined $version{MAJOR}
 362             && defined $version{MINOR}
 363             && defined $version{PATCH}
 364             && defined $version{SHLIB_VERSION});
 365
 366 # Collect target configurations
 367
 368 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 369 foreach (sort glob($pattern)) {
 370     &read_config($_);
 371 }
 372
 373 if (defined env($local_config_envname)) {
 374     if ($^O eq 'VMS') {
 375         # VMS environment variables are logical names,
 376         # which can be used as is
 377         $pattern = $local_config_envname . ':' . '*.conf';
 378     } else {
 379         $pattern = catfile(env($local_config_envname), '*.conf');
 380     }
 381
 382     foreach (sort glob($pattern)) {
 383         &read_config($_);
 384     }
 385 }
 386
 387 # Save away perl command information
 388 $config{perl_cmd} = $^X;
 389 $config{perl_version} = $Config{version};
 390 $config{perl_archname} = $Config{archname};
 391
 392 $config{prefix}="";
 393 $config{openssldir}="";
 394 $config{processor}="";
 395 $config{libdir}="";
 396 my $auto_threads=1;    # enable threads automatically? true by default
 397 my $default_ranlib;
 398
 399 # Known TLS and DTLS protocols
 400 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 401 my @dtls = qw(dtls1 dtls1_2);
 402
 403 # Explicitly known options that are possible to disable.  They can
 404 # be regexps, and will be used like this: /^no-${option}$/
 405 # For developers: keep it sorted alphabetically
 406
 407 my @disablables = (
 408     "acvp-tests",
 409     "afalgeng",
 410     "apps",
 411     "argon2",
 412     "aria",
 413     "asan",
 414     "asm",
 415     "async",
 416     "autoalginit",
 417     "autoerrinit",
 418     "autoload-config",
 419     "bf",
 420     "blake2",
 421     "brotli",
 422     "brotli-dynamic",
 423     "buildtest-c++",
 424     "bulk",
 425     "cached-fetch",
 426     "camellia",
 427     "capieng",
 428     "winstore",
 429     "cast",
 430     "chacha",
 431     "cmac",
 432     "cmp",
 433     "cms",
 434     "comp",
 435     "crypto-mdebug",
 436     "ct",
 437     "default-thread-pool",
 438     "deprecated",
 439     "des",
 440     "devcryptoeng",
 441     "dgram",
 442     "dh",
 443     "docs",
 444     "dsa",
 445     "dso",
 446     "dtls",
 447     "dynamic-engine",
 448     "ec",
 449     "ec2m",
 450     "ec_nistp_64_gcc_128",
 451     "ecdh",
 452     "ecdsa",
 453     "ecx",
 454     "egd",
 455     "engine",
 456     "err",
 457     "external-tests",
 458     "filenames",
 459     "fips",
 460     "fips-securitychecks",
 461     "fuzz-afl",
 462     "fuzz-libfuzzer",
 463     "gost",
 464     "http",
 465     "idea",
 466     "ktls",
 467     "legacy",
 468     "loadereng",
 469     "makedepend",
 470     "md2",
 471     "md4",
 472     "mdc2",
 473     "module",
 474     "msan",
 475     "multiblock",
 476     "nextprotoneg",
 477     "ocb",
 478     "ocsp",
 479     "padlockeng",
 480     "pic",
 481     "pinshared",
 482     "poly1305",
 483     "posix-io",
 484     "psk",
 485     "quic",
 486     "rc2",
 487     "rc4",
 488     "rc5",
 489     "rdrand",
 490     "rfc3779",
 491     "rmd160",
 492     "scrypt",
 493     "sctp",
 494     "secure-memory",
 495     "seed",
 496     "shared",
 497     "siphash",
 498     "siv",
 499     "sm2",
 500     "sm3",
 501     "sm4",
 502     "sock",
 503     "srp",
 504     "srtp",
 505     "sse2",
 506     "ssl",
 507     "ssl-trace",
 508     "static-engine",
 509     "stdio",
 510     "tests",
 511     "tfo",
 512     "thread-pool",
 513     "threads",
 514     "tls",
 515     "trace",
 516     "ts",
 517     "ubsan",
 518     "ui-console",
 519     "unit-test",
 520     "uplink",
 521     "weak-ssl-ciphers",
 522     "whirlpool",
 523     "zlib",
 524     "zlib-dynamic",
 525     "zstd",
 526     "zstd-dynamic",
 527     );
 528 foreach my $proto ((@tls, @dtls))
 529         {
 530         push(@disablables, $proto);
 531         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 532         }
 533
 534 # Internal disablables, for aliasing purposes.  They serve no special
 535 # purpose here, but allow scripts to get to know them through configdata.pm,
 536 # where these are merged with @disablables.
 537 # The actual aliasing mechanism is done via %disable_cascades
 538 my @disablables_int = qw(
 539     crmf
 540     );
 541
 542 my %deprecated_disablables = (
 543     "ssl2" => undef,
 544     "buf-freelists" => undef,
 545     "crypto-mdebug-backtrace" => undef,
 546     "hw" => "hw",               # causes cascade, but no macro
 547     "hw-padlock" => "padlockeng",
 548     "ripemd" => "rmd160",
 549     "ui" => "ui-console",
 550     "heartbeats" => undef,
 551     );
 552
 553 # All of the following are disabled by default:
 554
 555 our %disabled = ( # "what"         => "comment"
 556                   "fips"                => "default",
 557                   "asan"                => "default",
 558                   "brotli"              => "default",
 559                   "brotli-dynamic"      => "default",
 560                   "buildtest-c++"       => "default",
 561                   "crypto-mdebug"       => "default",
 562                   "crypto-mdebug-backtrace" => "default",
 563                   "devcryptoeng"        => "default",
 564                   "ec_nistp_64_gcc_128" => "default",
 565                   "egd"                 => "default",
 566                   "external-tests"      => "default",
 567                   "fuzz-afl"            => "default",
 568                   "fuzz-libfuzzer"      => "default",
 569                   "ktls"                => "default",
 570                   "md2"                 => "default",
 571                   "msan"                => "default",
 572                   "rc5"                 => "default",
 573                   "sctp"                => "default",
 574                   "ssl3"                => "default",
 575                   "ssl3-method"         => "default",
 576                   "tfo"                 => "default",
 577                   "trace"               => "default",
 578                   "ubsan"               => "default",
 579                   "unit-test"           => "default",
 580                   "weak-ssl-ciphers"    => "default",
 581                   "zlib"                => "default",
 582                   "zlib-dynamic"        => "default",
 583                   "zstd"                => "default",
 584                   "zstd-dynamic"        => "default",
 585                 );
 586
 587 # Note: => pair form used for aesthetics, not to truly make a hash table
 588 my @disable_cascades = (
 589     # "what"            => [ "cascade", ... ]
 590     "bulk"              => [ "shared", "dso",
 591                              "aria", "async", "autoload-config",
 592                              "blake2", "bf", "camellia", "cast", "chacha",
 593                              "cmac", "cms", "cmp", "comp", "ct",
 594                              "des", "dgram", "dh", "dsa",
 595                              "ec", "engine",
 596                              "filenames",
 597                              "idea", "ktls",
 598                              "md4", "multiblock", "nextprotoneg",
 599                              "ocsp", "ocb", "poly1305", "psk",
 600                              "rc2", "rc4", "rmd160",
 601                              "seed", "siphash", "siv",
 602                              "sm3", "sm4", "srp",
 603                              "srtp", "ssl3-method", "ssl-trace",
 604                              "tfo",
 605                              "ts", "ui-console", "whirlpool",
 606                              "fips-securitychecks" ],
 607     sub { $config{processor} eq "386" }
 608                         => [ "sse2" ],
 609     "ssl"               => [ "ssl3" ],
 610     "ssl3-method"       => [ "ssl3" ],
 611     "zlib"              => [ "zlib-dynamic" ],
 612     "brotli"            => [ "brotli-dynamic" ],
 613     "zstd"              => [ "zstd-dynamic" ],
 614     "des"               => [ "mdc2" ],
 615     "ec"                => [ "ec2m", "ecdsa", "ecdh", "sm2", "gost", "ecx" ],
 616     "dgram"             => [ "dtls", "quic", "sctp" ],
 617     "sock"              => [ "dgram", "tfo" ],
 618     "dtls"              => [ @dtls ],
 619     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 620                         => [ "dtls" ],
 621
 622     "tls"               => [ @tls ],
 623     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 624                         => [ "tls" ],
 625     "tls1_3"            => [ "quic" ],
 626
 627     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 628
 629     "module"            => [ "dynamic-engine", "fips" ],
 630
 631     # Without shared libraries, dynamic engines aren't possible.
 632     # This is due to them having to link with libcrypto and register features
 633     # using the ENGINE functionality, and since that relies on global tables,
 634     # those *have* to be exactly the same as the ones accessed from the app,
 635     # which cannot be guaranteed if shared libraries aren't present.
 636     # (note that even with shared libraries, both the app and dynamic engines
 637     # must be linked with the same library)
 638     "shared"            => [ "dynamic-engine", "uplink" ],
 639     "dso"               => [ "dynamic-engine", "module" ],
 640     # Other modules don't necessarily have to link with libcrypto, so shared
 641     # libraries do not have to be a condition to produce those.
 642
 643     # Without position independent code, there can be no shared libraries
 644     # or modules.
 645     "pic"               => [ "shared", "module" ],
 646
 647     "engine"            => [ "dynamic-engine", grep(/eng$/, @disablables) ],
 648     "dynamic-engine"    => [ "loadereng" ],
 649     "hw"                => [ "padlockeng" ],
 650
 651     # no-autoalginit is only useful when building non-shared
 652     "autoalginit"       => [ "shared", "apps", "fips" ],
 653
 654     "stdio"             => [ "apps", "capieng", "egd" ],
 655     "apps"              => [ "tests" ],
 656     "tests"             => [ "external-tests" ],
 657     "comp"              => [ "zlib", "brotli", "zstd" ],
 658     "sm3"               => [ "sm2" ],
 659     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 660
 661     sub { !$disabled{"msan"} } => [ "asm" ],
 662
 663     "cmac"              => [ "siv" ],
 664     "legacy"            => [ "md2" ],
 665
 666     "cmp"               => [ "crmf" ],
 667
 668     "fips"              => [ "fips-securitychecks", "acvp-tests" ],
 669
 670     "threads"           => [ "thread-pool" ],
 671     "thread-pool"       => [ "default-thread-pool" ],
 672
 673     "blake2"            => [ "argon2" ],
 674
 675     "deprecated-3.0"    => [ "engine", "srp" ],
 676
 677     "http"              => [ "ocsp" ]
 678     );
 679
 680 # Avoid protocol support holes.  Also disable all versions below N, if version
 681 # N is disabled while N+1 is enabled.
 682 #
 683 my @list = (reverse @tls);
 684 while ((my $first, my $second) = (shift @list, shift @list)) {
 685     last unless @list;
 686     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 687                               => [ @list ] );
 688     unshift @list, $second;
 689 }
 690 my @list = (reverse @dtls);
 691 while ((my $first, my $second) = (shift @list, shift @list)) {
 692     last unless @list;
 693     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 694                               => [ @list ] );
 695     unshift @list, $second;
 696 }
 697
 698 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 699 # To remove something from %disabled, use "enable-foo".
 700 # For symmetry, "disable-foo" is a synonym for "no-foo".
 701
 702 # For the "make variables" CPPINCLUDES and CPPDEFINES, we support lists with
 703 # platform specific list separators.  Users from those platforms should
 704 # recognise those separators from how you set up the PATH to find executables.
 705 # The default is the Unix like separator, :, but as an exception, we also
 706 # support the space as separator.
 707 my $list_separator_re =
 708     { VMS           => qr/(?<!\^),/,
 709       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 710 # All the "make variables" we support
 711 # Some get pre-populated for the sake of backward compatibility
 712 # (we supported those before the change to "make variable" support.
 713 my %user = (
 714     AR          => env('AR'),
 715     ARFLAGS     => [],
 716     AS          => undef,
 717     ASFLAGS     => [],
 718     CC          => env('CC'),
 719     CFLAGS      => [ env('CFLAGS') || () ],
 720     CXX         => env('CXX'),
 721     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 722     CPP         => undef,
 723     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 724     CPPDEFINES  => [],  # Alternative for -D
 725     CPPINCLUDES => [],  # Alternative for -I
 726     CROSS_COMPILE => env('CROSS_COMPILE'),
 727     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 728     LD          => undef,
 729     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 730     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 731     MT          => undef,
 732     MTFLAGS     => [],
 733     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 734     RANLIB      => env('RANLIB'),
 735     RC          => env('RC') || env('WINDRES'),
 736     RCFLAGS     => [ env('RCFLAGS') || () ],
 737     RM          => undef,
 738    );
 739 # Info about what "make variables" may be prefixed with the cross compiler
 740 # prefix.  This should NEVER mention any such variable with a list for value.
 741 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 742 # The same but for flags given as Configure options.  These are *additional*
 743 # input, as opposed to the VAR=string option that override the corresponding
 744 # config target attributes
 745 my %useradd = (
 746     ASFLAGS     => [],
 747     CPPDEFINES  => [],
 748     CPPINCLUDES => [],
 749     CPPFLAGS    => [],
 750     CFLAGS      => [],
 751     CXXFLAGS    => [],
 752     LDFLAGS     => [],
 753     LDLIBS      => [],
 754     RCFLAGS     => [],
 755    );
 756
 757 my %user_synonyms = (
 758     HASHBANGPERL=> 'PERL',
 759     RC          => 'WINDRES',
 760    );
 761
 762 # Some target attributes have been renamed, this is the translation table
 763 my %target_attr_translate =(
 764     ar          => 'AR',
 765     as          => 'AS',
 766     cc          => 'CC',
 767     cxx         => 'CXX',
 768     cpp         => 'CPP',
 769     hashbangperl => 'HASHBANGPERL',
 770     ld          => 'LD',
 771     mt          => 'MT',
 772     ranlib      => 'RANLIB',
 773     rc          => 'RC',
 774     rm          => 'RM',
 775    );
 776
 777 # Initialisers coming from 'config' scripts
 778 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 779 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 780 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 781 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 782 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 783 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 784 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 785
 786 $config{openssl_api_defines}=[];
 787 $config{openssl_sys_defines}=[];
 788 $config{openssl_feature_defines}=[];
 789 $config{options}="";
 790 $config{build_type} = "release";
 791 my $target="";
 792
 793 my %cmdvars = ();               # Stores FOO='blah' type arguments
 794 my %unsupported_options = ();
 795 my %deprecated_options = ();
 796 # If you change this, update apps/version.c
 797 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 798 my @seed_sources = ();
 799 while (@argvcopy)
 800         {
 801         $_ = shift @argvcopy;
 802
 803         # Support env variable assignments among the options
 804         if (m|^(\w+)=(.+)?$|)
 805                 {
 806                 $cmdvars{$1} = $2;
 807                 # Every time a variable is given as a configuration argument,
 808                 # it acts as a reset if the variable.
 809                 if (exists $user{$1})
 810                         {
 811                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 812                         }
 813                 #if (exists $useradd{$1})
 814                 #       {
 815                 #       $useradd{$1} = [];
 816                 #       }
 817                 next;
 818                 }
 819
 820         # VMS is a case insensitive environment, and depending on settings
 821         # out of our control, we may receive options uppercased.  Let's
 822         # downcase at least the part before any equal sign.
 823         if ($^O eq "VMS")
 824                 {
 825                 s/^([^=]*)/lc($1)/e;
 826                 }
 827
 828         # some people just can't read the instructions, clang people have to...
 829         s/^-no-(?!integrated-as)/no-/;
 830
 831         # rewrite some options in "enable-..." form
 832         s /^-?-?shared$/enable-shared/;
 833         s /^sctp$/enable-sctp/;
 834         s /^threads$/enable-threads/;
 835         s /^zlib$/enable-zlib/;
 836         s /^zlib-dynamic$/enable-zlib-dynamic/;
 837         s /^fips$/enable-fips/;
 838
 839         if (/^(no|disable|enable)-(.+)$/)
 840                 {
 841                 my $word = $2;
 842                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 843                         && !exists $deprecated_disablables{$word}
 844                         && !grep { $word eq $_ } @disablables)
 845                         {
 846                         $unsupported_options{$_} = 1;
 847                         next;
 848                         }
 849                 }
 850         if (/^no-(.+)$/ || /^disable-(.+)$/)
 851                 {
 852                 foreach my $proto ((@tls, @dtls))
 853                         {
 854                         if ($1 eq "$proto-method")
 855                                 {
 856                                 $disabled{"$proto"} = "option($proto-method)";
 857                                 last;
 858                                 }
 859                         }
 860                 if ($1 eq "dtls")
 861                         {
 862                         foreach my $proto (@dtls)
 863                                 {
 864                                 $disabled{$proto} = "option(dtls)";
 865                                 }
 866                         $disabled{"dtls"} = "option(dtls)";
 867                         }
 868                 elsif ($1 eq "ssl")
 869                         {
 870                         # Last one of its kind
 871                         $disabled{"ssl3"} = "option(ssl)";
 872                         }
 873                 elsif ($1 eq "tls")
 874                         {
 875                         # XXX: Tests will fail if all SSL/TLS
 876                         # protocols are disabled.
 877                         foreach my $proto (@tls)
 878                                 {
 879                                 $disabled{$proto} = "option(tls)";
 880                                 }
 881                         }
 882                 elsif ($1 eq "static-engine")
 883                         {
 884                         delete $disabled{"dynamic-engine"};
 885                         }
 886                 elsif ($1 eq "dynamic-engine")
 887                         {
 888                         $disabled{"dynamic-engine"} = "option";
 889                         }
 890                 elsif (exists $deprecated_disablables{$1})
 891                         {
 892                         $deprecated_options{$_} = 1;
 893                         if (defined $deprecated_disablables{$1})
 894                                 {
 895                                 $disabled{$deprecated_disablables{$1}} = "option";
 896                                 }
 897                         }
 898                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 899                         {
 900                         $deprecated_options{$_} = 1;
 901                         }
 902                 else
 903                         {
 904                         $disabled{$1} = "option";
 905                         }
 906                 # No longer an automatic choice
 907                 $auto_threads = 0 if ($1 eq "threads");
 908                 }
 909         elsif (/^enable-(.+)$/)
 910                 {
 911                 if ($1 eq "static-engine")
 912                         {
 913                         $disabled{"dynamic-engine"} = "option";
 914                         }
 915                 elsif ($1 eq "dynamic-engine")
 916                         {
 917                         delete $disabled{"dynamic-engine"};
 918                         }
 919                 elsif ($1 eq "zlib-dynamic")
 920                         {
 921                         delete $disabled{"zlib"};
 922                         }
 923                 elsif ($1 eq "brotli-dynamic")
 924                         {
 925                         delete $disabled{"brotli"};
 926                         }
 927                 elsif ($1 eq "zstd-dynamic")
 928                         {
 929                         delete $disabled{"zstd"};
 930                         }
 931                 my $algo = $1;
 932                 delete $disabled{$algo};
 933
 934                 # No longer an automatic choice
 935                 $auto_threads = 0 if ($1 eq "threads");
 936                 }
 937         elsif (/^-d$/)          # From older 'config'
 938                 {
 939                 $config{build_type} = "debug";
 940                 }
 941         elsif (/^-v$/)          # From older 'config'
 942                 {
 943                 $guess_opts{verbose} = 1;
 944                 }
 945         elsif (/^-w$/)
 946                 {
 947                 $guess_opts{nowait} = 1;
 948                 }
 949         elsif (/^-t$/)          # From older 'config'
 950                 {
 951                 $dryrun = 1;
 952                 }
 953         elsif (/^--strict-warnings$/)
 954                 {
 955                 # Pretend that our strict flags is a C flag, and replace it
 956                 # with the proper flags later on
 957                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 958                 $strict_warnings=1;
 959                 }
 960         elsif (/^--debug$/)
 961                 {
 962                 $config{build_type} = "debug";
 963                 }
 964         elsif (/^--release$/)
 965                 {
 966                 $config{build_type} = "release";
 967                 }
 968         elsif (/^386$/)
 969                 { $config{processor}=386; }
 970         elsif (/^rsaref$/)
 971                 {
 972                 # No RSAref support any more since it's not needed.
 973                 # The check for the option is there so scripts aren't
 974                 # broken
 975                 }
 976         elsif (m|^[-+/]|)
 977                 {
 978                 if (/^--prefix=(.*)$/)
 979                         {
 980                         $config{prefix}=$1;
 981                         die "Directory given with --prefix MUST be absolute\n"
 982                                 unless file_name_is_absolute($config{prefix});
 983                         }
 984                 elsif (/^--api=(.*)$/)
 985                         {
 986                         my $api = $1;
 987                         die "Unknown API compatibility level $api"
 988                                 unless defined $apitable->{$api};
 989                         $config{api}=$apitable->{$api};
 990                         }
 991                 elsif (/^--libdir=(.*)$/)
 992                         {
 993                         $config{libdir}=$1;
 994                         }
 995                 elsif (/^--openssldir=(.*)$/)
 996                         {
 997                         $config{openssldir}=$1;
 998                         }
 999                 elsif (/^--with-zlib-lib=(.*)$/)
1000                         {
1001                         $withargs{zlib_lib}=$1;
1002                         }
1003                 elsif (/^--with-zlib-include=(.*)$/)
1004                         {
1005                         $withargs{zlib_include}=$1;
1006                         }
1007                 elsif (/^--with-brotli-lib=(.*)$/)
1008                         {
1009                         $withargs{brotli_lib}=$1;
1010                         }
1011                 elsif (/^--with-brotli-include=(.*)$/)
1012                         {
1013                         $withargs{brotli_include}=$1;
1014                         }
1015                 elsif (/^--with-zstd-lib=(.*)$/)
1016                         {
1017                         $withargs{zstd_lib}=$1;
1018                         }
1019                 elsif (/^--with-zstd-include=(.*)$/)
1020                         {
1021                         $withargs{zstd_include}=$1;
1022                         }
1023                 elsif (/^--with-fuzzer-lib=(.*)$/)
1024                         {
1025                         $withargs{fuzzer_lib}=$1;
1026                         }
1027                 elsif (/^--with-fuzzer-include=(.*)$/)
1028                         {
1029                         $withargs{fuzzer_include}=$1;
1030                         }
1031                 elsif (/^--with-rand-seed=(.*)$/)
1032                         {
1033                         foreach my $x (split(m|,|, $1))
1034                             {
1035                             die "Unknown --with-rand-seed choice $x\n"
1036                                 if ! grep { $x eq $_ } @known_seed_sources;
1037                             push @seed_sources, $x;
1038                             }
1039                         }
1040                 elsif (/^--fips-key=(.*)$/)
1041                         {
1042                         $user{FIPSKEY}=lc($1);
1043                         die "Non-hex character in FIPS key\n"
1044                            if $user{FIPSKEY} =~ /[^a-f0-9]/;
1045                         die "FIPS key must have even number of characters\n"
1046                            if length $1 & 1;
1047                         die "FIPS key too long (64 bytes max)\n"
1048                            if length $1 > 64;
1049                         }
1050                 elsif (/^--banner=(.*)$/)
1051                         {
1052                         $banner = $1 . "\n";
1053                         }
1054                 elsif (/^--cross-compile-prefix=(.*)$/)
1055                         {
1056                         $user{CROSS_COMPILE}=$1;
1057                         }
1058                 elsif (/^--config=(.*)$/)
1059                         {
1060                         read_config $1;
1061                         }
1062                 elsif (/^-l(.*)$/)
1063                         {
1064                         push @{$useradd{LDLIBS}}, $_;
1065                         }
1066                 elsif (/^-framework$/)
1067                         {
1068                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
1069                         }
1070                 elsif (/^-L(.*)$/ or /^-Wl,/)
1071                         {
1072                         push @{$useradd{LDFLAGS}}, $_;
1073                         }
1074                 elsif (/^-rpath$/ or /^-R$/)
1075                         # -rpath is the OSF1 rpath flag
1076                         # -R is the old Solaris rpath flag
1077                         {
1078                         my $rpath = shift(@argvcopy) || "";
1079                         $rpath .= " " if $rpath ne "";
1080                         push @{$useradd{LDFLAGS}}, $_, $rpath;
1081                         }
1082                 elsif (/^-static$/)
1083                         {
1084                         push @{$useradd{LDFLAGS}}, $_;
1085                         }
1086                 elsif (m|^[-/]D(.*)$|)
1087                         {
1088                         push @{$useradd{CPPDEFINES}}, $1;
1089                         }
1090                 elsif (m|^[-/]I(.*)$|)
1091                         {
1092                         push @{$useradd{CPPINCLUDES}}, $1;
1093                         }
1094                 elsif (/^-Wp,$/)
1095                         {
1096                         push @{$useradd{CPPFLAGS}}, $1;
1097                         }
1098                 else    # common if (/^[-+]/), just pass down...
1099                         {
1100                         # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
1101                         # This provides a simple way to pass options with arguments separated
1102                         # by spaces without quoting (e.g. -opt%20arg translates to -opt arg).
1103                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
1104                         push @{$useradd{CFLAGS}}, $_;
1105                         push @{$useradd{CXXFLAGS}}, $_;
1106                         }
1107                 }
1108         elsif (m|^/|)
1109                 {
1110                 # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
1111                 # This provides a simple way to pass options with arguments separated
1112                 # by spaces without quoting (e.g. /opt%20arg translates to /opt arg).
1113                 $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
1114                 push @{$useradd{CFLAGS}}, $_;
1115                 push @{$useradd{CXXFLAGS}}, $_;
1116                 }
1117         else
1118                 {
1119                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
1120                 $target=$_;
1121                 }
1122         unless ($_ eq $target || /^no-/ || /^disable-/)
1123                 {
1124                 # "no-..." follows later after implied deactivations
1125                 # have been derived.  (Don't take this too seriously,
1126                 # we really only write OPTIONS to the Makefile out of
1127                 # nostalgia.)
1128
1129                 if ($config{options} eq "")
1130                         { $config{options} = $_; }
1131                 else
1132                         { $config{options} .= " ".$_; }
1133                 }
1134         }
1135
1136 if (keys %deprecated_options)
1137         {
1138         warn "***** Deprecated options: ",
1139                 join(", ", keys %deprecated_options), "\n";
1140         }
1141 if (keys %unsupported_options)
1142         {
1143         die "***** Unsupported options: ",
1144                 join(", ", keys %unsupported_options), "\n";
1145         }
1146
1147 # If any %useradd entry has been set, we must check that the "make
1148 # variables" haven't been set.  We start by checking of any %useradd entry
1149 # is set.
1150 if (grep { scalar @$_ > 0 } values %useradd) {
1151     # Hash of env / make variables names.  The possible values are:
1152     # 1 - "make vars"
1153     # 2 - %useradd entry set
1154     # 3 - both set
1155     my %detected_vars =
1156         map { my $v = 0;
1157               $v += 1 if $cmdvars{$_};
1158               $v += 2 if @{$useradd{$_}};
1159               $_ => $v }
1160         keys %useradd;
1161
1162     # If any of the corresponding "make variables" is set, we error
1163     if (grep { $_ & 1 } values %detected_vars) {
1164         my $names = join(', ', grep { $detected_vars{$_} > 0 }
1165                                sort keys %detected_vars);
1166         die <<"_____";
1167 ***** Mixing make variables and additional compiler/linker flags as
1168 ***** configure command line option is not permitted.
1169 ***** Affected make variables: $names
1170 _____
1171     }
1172 }
1173
1174 # Check through all supported command line variables to see if any of them
1175 # were set, and canonicalise the values we got.  If no compiler or linker
1176 # flag or anything else that affects %useradd was set, we also check the
1177 # environment for values.
1178 my $anyuseradd =
1179     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
1180 foreach (keys %user) {
1181     my $value = $cmdvars{$_};
1182     $value //= env($_) unless $anyuseradd;
1183     $value //=
1184         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
1185     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
1186         unless $anyuseradd;
1187
1188     if (defined $value) {
1189         if (ref $user{$_} eq 'ARRAY') {
1190             if ($_ eq 'CPPDEFINES' || $_ eq 'CPPINCLUDES') {
1191                 $user{$_} = [ split /$list_separator_re/, $value ];
1192             } else {
1193                 $user{$_} = [ $value ];
1194             }
1195         } elsif (!defined $user{$_}) {
1196             $user{$_} = $value;
1197         }
1198     }
1199 }
1200
1201 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1202     && !$disabled{shared}
1203     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1204     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1205         "***** any of asan, msan or ubsan\n";
1206 }
1207
1208 # If no target was given, try guessing.
1209 unless ($target) {
1210     my %system_config = OpenSSL::config::get_platform(%guess_opts, %user);
1211
1212     # The $system_config{disable} is used to populate %disabled with
1213     # entries that aren't already there.
1214     foreach ( @{$system_config{disable} // []} ) {
1215         $disabled{$_} = 'system' unless defined $disabled{$_};
1216     }
1217     delete $system_config{disable};
1218
1219     # Override config entries with stuff from the guesser.
1220     # It's assumed that this really is nothing new.
1221     %config = ( %config, %system_config );
1222     $target = $system_config{target};
1223 }
1224
1225 sub disable {
1226     my $disable_type = shift;
1227
1228     for (@_) {
1229         $disabled{$_} = $disable_type;
1230     }
1231
1232     my @tocheckfor = (@_ ? @_ : keys %disabled);
1233     while (@tocheckfor) {
1234         my %new_tocheckfor = ();
1235         my @cascade_copy = (@disable_cascades);
1236         while (@cascade_copy) {
1237             my ($test, $descendents) =
1238                 (shift @cascade_copy, shift @cascade_copy);
1239             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1240                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1241                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1242                 }
1243             }
1244         }
1245         @tocheckfor = (keys %new_tocheckfor);
1246     }
1247 }
1248 disable();                     # First cascade run
1249
1250 our $die = sub { die @_; };
1251 if ($target eq "TABLE") {
1252     local $die = sub { warn @_; };
1253     foreach (sort keys %table) {
1254         print_table_entry($_, "TABLE");
1255     }
1256     exit 0;
1257 }
1258
1259 if ($target eq "LIST") {
1260     foreach (sort keys %table) {
1261         print $_,"\n" unless $table{$_}->{template};
1262     }
1263     exit 0;
1264 }
1265
1266 if ($target eq "HASH") {
1267     local $die = sub { warn @_; };
1268     print "%table = (\n";
1269     foreach (sort keys %table) {
1270         print_table_entry($_, "HASH");
1271     }
1272     exit 0;
1273 }
1274
1275 print "Configuring OpenSSL version $config{full_version} ";
1276 print "for target $target\n";
1277
1278 if (scalar(@seed_sources) == 0) {
1279     print "Using os-specific seed configuration\n";
1280     push @seed_sources, 'os';
1281 }
1282 if (scalar(grep { $_ eq 'egd' } @seed_sources) > 0) {
1283     delete $disabled{'egd'};
1284 }
1285 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1286     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1287     warn <<_____ if scalar(@seed_sources) == 1;
1288
1289 ============================== WARNING ===============================
1290 You have selected the --with-rand-seed=none option, which effectively
1291 disables automatic reseeding of the OpenSSL random generator.
1292 All operations depending on the random generator such as creating keys
1293 will not work unless the random generator is seeded manually by the
1294 application.
1295
1296 Please read the 'Note on random number generation' section in the
1297 INSTALL.md instructions and the RAND_DRBG(7) manual page for more
1298 details.
1299 ============================== WARNING ===============================
1300
1301 _____
1302 }
1303 push @{$config{openssl_feature_defines}},
1304      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1305         @seed_sources;
1306
1307 # Backward compatibility?
1308 if ($target =~ m/^CygWin32(-.*)$/) {
1309     $target = "Cygwin".$1;
1310 }
1311
1312 # Support for legacy targets having a name starting with 'debug-'
1313 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1314 if ($d) {
1315     $config{build_type} = "debug";
1316
1317     # If we do not find debug-foo in the table, the target is set to foo.
1318     if (!$table{$target}) {
1319         $target = $t;
1320     }
1321 }
1322
1323 if ($target) {
1324     # It's possible that we have different config targets for specific
1325     # toolchains, so we try to detect them, and go for the plain config
1326     # target if not.
1327     my $found;
1328     foreach ( ( "$target-$user{CC}", "$target", undef ) ) {
1329         $found=$_ if $table{$_} && !$table{$_}->{template};
1330         last if $found;
1331     }
1332     $target = $found;
1333 } else {
1334     # If we don't have a config target now, we try the C compiler as we
1335     # fallback
1336     my $cc = $user{CC} // 'cc';
1337     $target = $cc if $table{$cc} && !$table{$cc}->{template};
1338 }
1339
1340 &usage unless $target;
1341
1342 exit 0 if $dryrun;              # From older 'config'
1343
1344 $config{target} = $target;
1345 my %target = resolve_config($target);
1346
1347 foreach (keys %target_attr_translate) {
1348     $target{$target_attr_translate{$_}} = $target{$_}
1349         if $target{$_};
1350     delete $target{$_};
1351 }
1352
1353 %target = ( %{$table{DEFAULTS}}, %target );
1354
1355 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1356 $config{conf_files} = [ sort keys %conf_files ];
1357
1358 # Using sub disable within these loops may prove fragile, so we run
1359 # a cascade afterwards
1360 foreach my $feature (@{$target{disable}}) {
1361     if (exists $deprecated_disablables{$feature}) {
1362         warn "***** config $target disables deprecated feature $feature\n";
1363     } elsif (!grep { $feature eq $_ } @disablables) {
1364         die "***** config $target disables unknown feature $feature\n";
1365     }
1366     $disabled{$feature} = 'config';
1367 }
1368 foreach my $feature (@{$target{enable}}) {
1369     if ("default" eq ($disabled{$feature} // "")) {
1370         if (exists $deprecated_disablables{$feature}) {
1371             warn "***** config $target enables deprecated feature $feature\n";
1372         } elsif (!grep { $feature eq $_ } @disablables) {
1373             die "***** config $target enables unknown feature $feature\n";
1374         }
1375         delete $disabled{$feature};
1376     }
1377 }
1378
1379 # If uplink_arch isn't defined, disable uplink
1380 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1381 # If asm_arch isn't defined, disable asm
1382 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1383
1384 disable();                      # Run a cascade now
1385
1386 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1387 $target{cxxflags}//=$target{cflags} if $target{CXX};
1388 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1389 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1390
1391 # Fill %config with values from %user, and in case those are undefined or
1392 # empty, use values from %target (acting as a default).
1393 foreach (keys %user) {
1394     my $ref_type = ref $user{$_};
1395
1396     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1397     # and a value that's to be coerced into that type.
1398     my $mkvalue = sub {
1399         my $type = shift;
1400         my $value = shift;
1401         my $undef_p = shift;
1402
1403         die "Too many arguments for \$mkvalue" if @_;
1404
1405         while (ref $value eq 'CODE') {
1406             $value = $value->();
1407         }
1408
1409         if ($type eq 'ARRAY') {
1410             return undef unless defined $value;
1411             return undef if ref $value ne 'ARRAY' && !$value;
1412             return undef if ref $value eq 'ARRAY' && !@$value;
1413             return [ $value ] unless ref $value eq 'ARRAY';
1414         }
1415         return undef unless $value;
1416         return $value;
1417     };
1418
1419     $config{$_} =
1420         $mkvalue->($ref_type, $user{$_})
1421         || $mkvalue->($ref_type, $target{$_});
1422     delete $config{$_} unless defined $config{$_};
1423 }
1424
1425 # Finish up %config by appending things the user gave us on the command line
1426 # apart from "make variables"
1427 foreach (keys %useradd) {
1428     # The must all be lists, so we assert that here
1429     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1430         unless ref $useradd{$_} eq 'ARRAY';
1431
1432     if (defined $config{$_}) {
1433         push @{$config{$_}}, @{$useradd{$_}};
1434     } else {
1435         $config{$_} = [ @{$useradd{$_}} ];
1436     }
1437 }
1438 # At this point, we can forget everything about %user and %useradd,
1439 # because it's now all been merged into the corresponding $config entry
1440
1441 if (grep { $_ =~ /(?:^|\s)-static(?:\s|$)/ } @{$config{LDFLAGS}}) {
1442     disable('static', 'pic', 'threads');
1443 }
1444
1445 # Allow overriding the build file name
1446 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1447
1448 # Make sure build_scheme is consistent.
1449 $target{build_scheme} = [ $target{build_scheme} ]
1450     if ref($target{build_scheme}) ne "ARRAY";
1451
1452 my ($builder, $builder_platform, @builder_opts) =
1453     @{$target{build_scheme}};
1454
1455 foreach my $checker (($builder_platform."-".$config{build_file}."-checker.pm",
1456                       $builder_platform."-checker.pm")) {
1457     my $checker_path = catfile($srcdir, "Configurations", $checker);
1458     if (-f $checker_path) {
1459         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1460             ? sub { warn $@; } : sub { die $@; };
1461         if (! do $checker_path) {
1462             if ($@) {
1463                 $fn->($@);
1464             } elsif ($!) {
1465                 $fn->($!);
1466             } else {
1467                 $fn->("The detected tools didn't match the platform\n");
1468             }
1469         }
1470         last;
1471     }
1472 }
1473
1474 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1475
1476 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1477         {
1478         push @{$config{cflags}}, "-mno-cygwin";
1479         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1480         push @{$config{shared_ldflag}}, "-mno-cygwin";
1481         }
1482
1483 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1484         && !grep { $_ =~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1485         # minimally required architecture flags for assembly modules
1486         my $value;
1487         $value = '-mips2' if ($target =~ /mips32/);
1488         $value = '-mips3' if ($target =~ /mips64/);
1489         unshift @{$config{cflags}}, $value;
1490         unshift @{$config{cxxflags}}, $value if $config{CXX};
1491 }
1492
1493 # If threads aren't disabled, check how possible they are
1494 unless ($disabled{threads}) {
1495     if ($auto_threads) {
1496         # Enabled by default, disable it forcibly if unavailable
1497         if ($target{thread_scheme} eq "(unknown)") {
1498             disable("unavailable", 'threads');
1499         }
1500     } else {
1501         # The user chose to enable threads explicitly, let's see
1502         # if there's a chance that's possible
1503         if ($target{thread_scheme} eq "(unknown)") {
1504             # If the user asked for "threads" and we don't have internal
1505             # knowledge how to do it, [s]he is expected to provide any
1506             # system-dependent compiler options that are necessary.  We
1507             # can't truly check that the given options are correct, but
1508             # we expect the user to know what [s]He is doing.
1509             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1510                 die "You asked for multi-threading support, but didn't\n"
1511                     ,"provide any system-specific compiler options\n";
1512             }
1513         }
1514     }
1515 }
1516
1517 # Find out if clang's sanitizers have been enabled with -fsanitize
1518 # flags and ensure that the corresponding %disabled elements area
1519 # removed to reflect that the sanitizers are indeed enabled.
1520 my %detected_sanitizers = ();
1521 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1522     (my $checks = $_) =~ s/^-fsanitize=//;
1523     foreach (split /,/, $checks) {
1524         my $d = { address       => 'asan',
1525                   undefined     => 'ubsan',
1526                   memory        => 'msan' } -> {$_};
1527         next unless defined $d;
1528
1529         $detected_sanitizers{$d} = 1;
1530         if (defined $disabled{$d}) {
1531             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1532                 if $disabled{$d} ne "default";
1533             delete $disabled{$d};
1534         }
1535     }
1536 }
1537
1538 # If threads still aren't disabled, add a C macro to ensure the source
1539 # code knows about it.  Any other flag is taken care of by the configs.
1540 unless($disabled{threads}) {
1541     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1542 }
1543
1544 my $no_shared_warn=0;
1545 if (($target{shared_target} // '') eq "")
1546         {
1547         $no_shared_warn = 1
1548             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1549         disable('no-shared-target', 'pic');
1550         }
1551
1552 if ($disabled{"dynamic-engine"}) {
1553         $config{dynamic_engines} = 0;
1554 } else {
1555         $config{dynamic_engines} = 1;
1556 }
1557
1558 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1559     push @{$config{cflags}}, "-fsanitize=address";
1560 }
1561
1562 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1563     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all", "-DPEDANTIC";
1564 }
1565
1566 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1567   push @{$config{cflags}}, "-fsanitize=memory";
1568 }
1569
1570 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1571         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1572     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1573     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1574 }
1575 #
1576 # Platform fix-ups
1577 #
1578
1579 # This saves the build files from having to check
1580 if ($disabled{pic})
1581         {
1582         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1583                     shared_defines shared_includes shared_ldflag
1584                     module_cflags module_cxxflags module_cppflags
1585                     module_defines module_includes module_lflags))
1586                 {
1587                 delete $config{$_};
1588                 $target{$_} = "";
1589                 }
1590         }
1591 else
1592         {
1593         push @{$config{lib_defines}}, "OPENSSL_PIC";
1594         }
1595
1596 if ($target{sys_id} ne "")
1597         {
1598         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1599         }
1600
1601 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1602 my %predefined_CXX = $config{CXX}
1603     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1604     : ();
1605
1606 unless ($disabled{asm}) {
1607     # big endian systems can use ELFv2 ABI
1608     if ($target eq "linux-ppc64" || $target eq "BSD-ppc64") {
1609         $target{perlasm_scheme} = "linux64v2" if ($predefined_C{_CALL_ELF} == 2);
1610     }
1611 }
1612
1613 # Check for makedepend capabilities.
1614 if (!$disabled{makedepend}) {
1615     # If the attribute makedep_scheme is defined, then we assume that the
1616     # config target and its associated build file are programmed to deal
1617     # with it.
1618     # If makedep_scheme is undefined, we go looking for GCC compatible
1619     # dependency making, and if that's not available, we try to fall back
1620     # on 'makedepend'.
1621     if ($target{makedep_scheme}) {
1622         $config{makedep_scheme} = $target{makedep_scheme};
1623         # If the makedepcmd attribute is defined, copy it.  If not, the
1624         # build files will have to fend for themselves.
1625         $config{makedepcmd} = $target{makedepcmd} if $target{makedepcmd};
1626     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1627              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1628         # We know that GNU C version 3 and up as well as all clang
1629         # versions support dependency generation, but Xcode did not
1630         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1631         $config{makedep_scheme} = 'gcc';
1632     } else {
1633         # In all other cases, we look for 'makedepend', and set the
1634         # makedep_scheme value if we found it.
1635         $config{makedepcmd} = which('makedepend');
1636         $config{makedep_scheme} = 'makedepend' if $config{makedepcmd};
1637     }
1638
1639     # If no depend scheme is set, we disable makedepend
1640     disable('unavailable', 'makedepend') unless $config{makedep_scheme};
1641 }
1642
1643 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1644     # probe for -Wa,--noexecstack option...
1645     if ($predefined_C{__clang__}) {
1646         # clang has builtin assembler, which doesn't recognize --help,
1647         # but it apparently recognizes the option in question on all
1648         # supported platforms even when it's meaningless. In other words
1649         # probe would fail, but probed option always accepted...
1650         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1651     } else {
1652         my $cc = $config{CROSS_COMPILE}.$config{CC};
1653         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1654         while(<PIPE>) {
1655             if (m/--noexecstack/) {
1656                 push @{$config{cflags}}, "-Wa,--noexecstack";
1657                 last;
1658             }
1659         }
1660         close(PIPE);
1661         unlink("null.$$.o");
1662     }
1663 }
1664
1665 # Deal with bn_ops ###################################################
1666
1667 $config{bn_ll}                  =0;
1668 my $def_int="unsigned int";
1669 $config{rc4_int}                =$def_int;
1670 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1671
1672 my $count = 0;
1673 foreach (sort split(/\s+/,$target{bn_ops})) {
1674     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1675     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1676     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1677     ($config{b64l},$config{b64},$config{b32})
1678         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1679     ($config{b64l},$config{b64},$config{b32})
1680         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1681     ($config{b64l},$config{b64},$config{b32})
1682         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1683 }
1684 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1685     if $count > 1;
1686
1687 $config{api} = $config{major} * 10000 + $config{minor} * 100
1688     unless $config{api};
1689 foreach (keys %$apitable) {
1690     $disabled{"deprecated-$_"} = "deprecation"
1691         if $disabled{deprecated} && $config{api} >= $apitable->{$_};
1692 }
1693
1694 disable();                      # Run a cascade now
1695
1696 # Hack cflags for better warnings (dev option) #######################
1697
1698 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1699 # a string and works as well on command lines.
1700 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1701                         @{$config{cflags}} ];
1702 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1703                           @{$config{cxxflags}} ] if $config{CXX};
1704
1705 $config{openssl_api_defines} = [
1706     "OPENSSL_CONFIGURED_API=".$config{api},
1707 ];
1708
1709 my @strict_warnings_collection=();
1710 if ($strict_warnings)
1711         {
1712         my $wopt;
1713         my $gccver = $predefined_C{__GNUC__} // -1;
1714
1715         if ($gccver >= 4)
1716                 {
1717                 push @strict_warnings_collection, @gcc_devteam_warn;
1718                 push @strict_warnings_collection, @clang_devteam_warn
1719                     if (defined($predefined_C{__clang__}));
1720                 }
1721         elsif ($config{target} =~ /^VC-/)
1722                 {
1723                 push @strict_warnings_collection, @cl_devteam_warn;
1724                 }
1725         else
1726                 {
1727                 warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike, or MSVC"
1728                 }
1729         }
1730
1731 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1732                               ? @strict_warnings_collection
1733                               : ( $_ ) }
1734                     @{$config{CFLAGS}} ];
1735
1736 unless ($disabled{afalgeng}) {
1737     $config{afalgeng}="";
1738     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1739         push @{$config{engdirs}}, "afalg";
1740     } else {
1741         disable('not-linux', 'afalgeng');
1742     }
1743 }
1744
1745 unless ($disabled{devcryptoeng}) {
1746     if ($target =~ m/^BSD/) {
1747         my $maxver = 5*100 + 7;
1748         my $sysstr = `uname -s`;
1749         my $verstr = `uname -r`;
1750         $sysstr =~ s|\R$||;
1751         $verstr =~ s|\R$||;
1752         my ($ma, $mi, @rest) = split m|\.|, $verstr;
1753         my $ver = $ma*100 + $mi;
1754         if ($sysstr eq 'OpenBSD' && $ver >= $maxver) {
1755             disable('too-new-kernel', 'devcryptoeng');
1756         }
1757     }
1758 }
1759
1760 unless ($disabled{ktls}) {
1761     $config{ktls}="";
1762     my $cc = $config{CROSS_COMPILE}.$config{CC};
1763     if ($target =~ m/^linux/) {
1764         system("printf '#include <sys/types.h>\n#include <linux/tls.h>' | $cc -E - >/dev/null 2>&1");
1765         if ($? != 0) {
1766             disable('too-old-kernel', 'ktls');
1767         }
1768     } elsif ($target =~ m/^BSD/) {
1769         system("printf '#include <sys/types.h>\n#include <sys/ktls.h>' | $cc -E - >/dev/null 2>&1");
1770         if ($? != 0) {
1771             disable('too-old-freebsd', 'ktls');
1772         }
1773     } else {
1774         disable('not-linux-or-freebsd', 'ktls');
1775     }
1776 }
1777
1778 unless ($disabled{winstore}) {
1779     unless ($target =~ /^(?:Cygwin|mingw|VC-|BC-)/) {
1780         disable('not-windows', 'winstore');
1781     }
1782 }
1783
1784 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1785
1786 # Get the extra flags used when building shared libraries and modules.  We
1787 # do this late because some of them depend on %disabled.
1788
1789 # Make the flags to build DSOs the same as for shared libraries unless they
1790 # are already defined
1791 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1792 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1793 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1794 {
1795     my $shared_info_pl =
1796         catfile(dirname($0), "Configurations", "shared-info.pl");
1797     my %shared_info = read_eval_file($shared_info_pl);
1798     push @{$target{_conf_fname_int}}, $shared_info_pl;
1799     my $si = $target{shared_target};
1800     while (ref $si ne "HASH") {
1801         last if ! defined $si;
1802         if (ref $si eq "CODE") {
1803             $si = $si->();
1804         } else {
1805             $si = $shared_info{$si};
1806         }
1807     }
1808
1809     # Some of the 'shared_target' values don't have any entries in
1810     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1811     # template knows how to handle this.  That is currently the case for
1812     # Windows and VMS.
1813     if (defined $si) {
1814         # Just as above, copy certain shared_* attributes to the corresponding
1815         # module_ attribute unless the latter is already defined
1816         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1817         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1818         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1819         foreach (sort keys %$si) {
1820             $target{$_} = defined $target{$_}
1821                 ? add($si->{$_})->($target{$_})
1822                 : $si->{$_};
1823         }
1824     }
1825 }
1826
1827 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1828
1829 ######################################################################
1830 # Build up information for skipping certain directories depending on disabled
1831 # features, as well as setting up macros for disabled features.
1832
1833 # This is a tentative database of directories to skip.  Some entries may not
1834 # correspond to anything real, but that's ok, they will simply be ignored.
1835 # The actual processing of these entries is done in the build.info lookup
1836 # loop further down.
1837 #
1838 # The key is a Unix formatted path in the source tree, the value is an index
1839 # into %disabled_info, so any existing path gets added to a corresponding
1840 # 'skipped' entry in there with the list of skipped directories.
1841 my %skipdir = ();
1842 my %disabled_info = ();         # For configdata.pm
1843 foreach my $what (sort keys %disabled) {
1844     # There are deprecated disablables that translate to themselves.
1845     # They cause disabling cascades, but should otherwise not register.
1846     next if $deprecated_disablables{$what};
1847     # The generated $disabled{"deprecated-x.y"} entries are special
1848     # and treated properly elsewhere
1849     next if $what =~ m|^deprecated-|;
1850
1851     $config{options} .= " no-$what";
1852
1853     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1854                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1855                                 'sse2', 'legacy' )) {
1856         (my $WHAT = uc $what) =~ s|-|_|g;
1857         my $skipdir = $what;
1858
1859         # fix-up crypto/directory name(s)
1860         $skipdir = "ripemd" if $what eq "rmd160";
1861         $skipdir = "whrlpool" if $what eq "whirlpool";
1862
1863         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1864         push @{$config{openssl_feature_defines}}, $macro;
1865
1866         $skipdir{engines} = $what if $what eq 'engine';
1867         $skipdir{"crypto/$skipdir"} = $what
1868             unless $what eq 'async' || $what eq 'err' || $what eq 'dso';
1869     }
1870 }
1871
1872 if ($disabled{"dynamic-engine"}) {
1873     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1874 } else {
1875     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1876 }
1877
1878 # If we use the unified build, collect information from build.info files
1879 my %unified_info = ();
1880
1881 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1882 if ($builder eq "unified") {
1883     use Text::Template 1.46;
1884
1885     sub cleandir {
1886         my $base = shift;
1887         my $dir = shift;
1888         my $relativeto = shift || ".";
1889
1890         $dir = catdir($base,$dir) unless isabsolute($dir);
1891
1892         # Make sure the directories we're building in exists
1893         mkpath($dir);
1894
1895         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1896         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1897         return $res;
1898     }
1899
1900     sub cleanfile {
1901         my $base = shift;
1902         my $file = shift;
1903         my $relativeto = shift || ".";
1904
1905         $file = catfile($base,$file) unless isabsolute($file);
1906
1907         my $d = dirname($file);
1908         my $f = basename($file);
1909
1910         # Make sure the directories we're building in exists
1911         mkpath($d);
1912
1913         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1914         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1915         return $res;
1916     }
1917
1918     # Store the name of the template file we will build the build file from
1919     # in %config.  This may be useful for the build file itself.
1920     my @build_file_template_names =
1921         ( $builder_platform."-".$config{build_file}.".tmpl",
1922           $config{build_file}.".tmpl" );
1923     my @build_file_templates = ();
1924
1925     # First, look in the user provided directory, if given
1926     if (defined env($local_config_envname)) {
1927         @build_file_templates =
1928             map {
1929                 if ($^O eq 'VMS') {
1930                     # VMS environment variables are logical names,
1931                     # which can be used as is
1932                     $local_config_envname . ':' . $_;
1933                 } else {
1934                     catfile(env($local_config_envname), $_);
1935                 }
1936             }
1937             @build_file_template_names;
1938     }
1939     # Then, look in our standard directory
1940     push @build_file_templates,
1941         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1942           @build_file_template_names );
1943
1944     my $build_file_template;
1945     for $_ (@build_file_templates) {
1946         $build_file_template = $_;
1947         last if -f $build_file_template;
1948
1949         $build_file_template = undef;
1950     }
1951     if (!defined $build_file_template) {
1952         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1953     }
1954     $config{build_file_templates}
1955       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1956                     $blddir),
1957            $build_file_template ];
1958
1959     my @build_dirs = ( [ ] );   # current directory
1960
1961     $config{build_infos} = [ ];
1962
1963     # We want to detect configdata.pm in the source tree, so we
1964     # don't use it if the build tree is different.
1965     my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1966
1967     # Any source file that we recognise is placed in this hash table, with
1968     # the list of its intended destinations as value.  When everything has
1969     # been collected, there's a routine that checks that these source files
1970     # exist, or if they are generated, that the generator exists.
1971     my %check_exist = ();
1972     my %check_generate = ();
1973
1974     my %ordinals = ();
1975     while (@build_dirs) {
1976         my @curd = @{shift @build_dirs};
1977         my $sourced = catdir($srcdir, @curd);
1978         my $buildd = catdir($blddir, @curd);
1979
1980         my $unixdir = join('/', @curd);
1981         if (exists $skipdir{$unixdir}) {
1982             my $what = $skipdir{$unixdir};
1983             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1984             next;
1985         }
1986
1987         mkpath($buildd);
1988
1989         my $f = 'build.info';
1990         # The basic things we're trying to build
1991         my @programs = ();
1992         my @libraries = ();
1993         my @modules = ();
1994         my @scripts = ();
1995
1996         my %sources = ();
1997         my %shared_sources = ();
1998         my %includes = ();
1999         my %defines = ();
2000         my %depends = ();
2001         my %generate = ();
2002         my %imagedocs = ();
2003         my %htmldocs = ();
2004         my %mandocs = ();
2005
2006         # Support for $variablename in build.info files.
2007         # Embedded perl code is the ultimate master, still.  If its output
2008         # contains a dollar sign, it had better be escaped, or it will be
2009         # taken for a variable name prefix.
2010         my %variables = ();
2011         # Variable name syntax
2012         my $variable_name_re = qr/(?P<VARIABLE>[[:alpha:]][[:alnum:]_]*)/;
2013         # Value modifier syntaxes
2014         my $variable_subst_re = qr/\/(?P<RE>(?:\\\/|.)*?)\/(?P<SUBST>.*?)/;
2015         # Variable reference
2016         my $variable_simple_re = qr/(?<!\\)\$${variable_name_re}/;
2017         my $variable_w_mod_re =
2018             qr/(?<!\\)\$\{${variable_name_re}(?P<MOD>(?:\\\/|.)*?)\}/;
2019         # Tie it all together
2020         my $variable_re = qr/${variable_simple_re}|${variable_w_mod_re}/;
2021
2022         my $expand_variables = sub {
2023             my $value = '';
2024             my $value_rest = shift;
2025
2026             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2027                 print STDERR
2028                     "DEBUG[\$expand_variables] Parsed '$value_rest' ...\n"
2029             }
2030
2031             while ($value_rest =~ /${variable_re}/) {
2032                 # We must save important regexp values, because the next
2033                 # regexp clears them
2034                 my $mod = $+{MOD};
2035                 my $variable_value = $variables{$+{VARIABLE}};
2036
2037                 $value_rest = $';
2038                 $value .= $`;
2039
2040                 # Process modifier expressions, if present
2041                 if (defined $mod) {
2042                     if ($mod =~ /^${variable_subst_re}$/) {
2043                         my $re = $+{RE};
2044                         my $subst = $+{SUBST};
2045
2046                         $variable_value =~ s/\Q$re\E/$subst/g;
2047
2048                         if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2049                             print STDERR
2050                                 "DEBUG[\$expand_variables] ... and substituted ",
2051                                 "'$re' with '$subst'\n";
2052                         }
2053                     }
2054                 }
2055
2056                 $value .= $variable_value;
2057             }
2058             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2059                 print STDERR
2060                     "DEBUG[\$expand_variables] ... into: '$value$value_rest'\n";
2061             }
2062             return $value . $value_rest;
2063         };
2064
2065         # Support for attributes in build.info files
2066         my %attributes = ();
2067         my $handle_attributes = sub {
2068             my $attr_str = shift;
2069             my $ref = shift;
2070             my @goals = @_;
2071
2072             return unless defined $attr_str;
2073
2074             my @a = tokenize($attr_str, qr|\s*,\s*|);
2075             foreach my $a (@a) {
2076                 my $ac = 1;
2077                 my $ak = $a;
2078                 my $av = 1;
2079                 if ($a =~ m|^(!)?(.*?)\s* = \s*(.*?)$|x) {
2080                     $ac = ! $1;
2081                     $ak = $2;
2082                     $av = $3;
2083                 }
2084                 foreach my $g (@goals) {
2085                     if ($ac) {
2086                         $$ref->{$g}->{$ak} = $av;
2087                     } else {
2088                         delete $$ref->{$g}->{$ak};
2089                     }
2090                 }
2091             }
2092         };
2093
2094         # Support for pushing values on multiple indexes of a given hash
2095         # array.
2096         my $push_to = sub {
2097             my $valueref = shift;
2098             my $index_str = shift; # May be undef or empty
2099             my $attrref = shift;   # May be undef
2100             my $attr_str = shift;
2101             my @values = @_;
2102
2103             if (defined $index_str) {
2104                 my @indexes = ( '' );
2105                 if ($index_str !~ m|^\s*$|) {
2106                     @indexes = tokenize($index_str);
2107                 }
2108                 foreach (@indexes) {
2109                     push @{$valueref->{$_}}, @values;
2110                     if (defined $attrref) {
2111                         $handle_attributes->($attr_str, \$$attrref->{$_},
2112                                              @values);
2113                     }
2114                 }
2115             } else {
2116                 push @$valueref, @values;
2117                 $handle_attributes->($attr_str, $attrref, @values)
2118                     if defined $attrref;
2119             }
2120         };
2121
2122         if ($buildinfo_debug) {
2123             print STDERR "DEBUG: Reading ",catfile($sourced, $f),"\n";
2124         }
2125         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
2126         my $template =
2127             Text::Template->new(TYPE => 'FILE',
2128                                 SOURCE => catfile($sourced, $f),
2129                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
2130         die "Something went wrong with $sourced/$f: $!\n" unless $template;
2131         my @text =
2132             split /^/m,
2133             $template->fill_in(HASH => { config => \%config,
2134                                          target => \%target,
2135                                          disabled => \%disabled,
2136                                          withargs => \%withargs,
2137                                          builddir => abs2rel($buildd, $blddir),
2138                                          sourcedir => abs2rel($sourced, $blddir),
2139                                          buildtop => abs2rel($blddir, $blddir),
2140                                          sourcetop => abs2rel($srcdir, $blddir) },
2141                                DELIMITERS => [ "{-", "-}" ]);
2142
2143         # The top item of this stack has the following values
2144         # -2 positive already run and we found ELSE (following ELSIF should fail)
2145         # -1 positive already run (skip until ENDIF)
2146         # 0 negatives so far (if we're at a condition, check it)
2147         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
2148         # 2 positive ELSE (following ELSIF should fail)
2149         my @skip = ();
2150
2151         # A few useful generic regexps
2152         my $index_re = qr/\[\s*(?P<INDEX>(?:\\.|.)*?)\s*\]/;
2153         my $cond_re = qr/\[\s*(?P<COND>(?:\\.|.)*?)\s*\]/;
2154         my $attribs_re = qr/(?:\{\s*(?P<ATTRIBS>(?:\\.|.)*?)\s*\})?/;
2155         my $value_re = qr/(?P<VALUE>.*?)/;
2156         collect_information(
2157             collect_from_array([ @text ],
2158                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
2159                                                 $l1 =~ s/\\$//; $l1.$l2 }),
2160             # Info we're looking for
2161             qr/^\s* IF ${cond_re} \s*$/x
2162             => sub {
2163                 if (! @skip || $skip[$#skip] > 0) {
2164                     push @skip, !! $expand_variables->($+{COND});
2165                 } else {
2166                     push @skip, -1;
2167                 }
2168             },
2169             qr/^\s* ELSIF ${cond_re} \s*$/x
2170             => sub { die "ELSIF out of scope" if ! @skip;
2171                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
2172                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
2173                      $skip[$#skip] = !! $expand_variables->($+{COND})
2174                          if $skip[$#skip] == 0; },
2175             qr/^\s* ELSE \s*$/x
2176             => sub { die "ELSE out of scope" if ! @skip;
2177                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
2178                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
2179             qr/^\s* ENDIF \s*$/x
2180             => sub { die "ENDIF out of scope" if ! @skip;
2181                      pop @skip; },
2182             qr/^\s* ${variable_re} \s* = \s* ${value_re} \s* $/x
2183             => sub {
2184                 if (!@skip || $skip[$#skip] > 0) {
2185                     $variables{$+{VARIABLE}} = $expand_variables->($+{VALUE});
2186                 }
2187             },
2188             qr/^\s* SUBDIRS \s* = \s* ${value_re} \s* $/x
2189             => sub {
2190                 if (!@skip || $skip[$#skip] > 0) {
2191                     foreach (tokenize($expand_variables->($+{VALUE}))) {
2192                         push @build_dirs, [ @curd, splitdir($_, 1) ];
2193                     }
2194                 }
2195             },
2196             qr/^\s* PROGRAMS ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2197             => sub { $push_to->(\@programs, undef,
2198                                 \$attributes{programs}, $+{ATTRIBS},
2199                                 tokenize($expand_variables->($+{VALUE})))
2200                          if !@skip || $skip[$#skip] > 0; },
2201             qr/^\s* LIBS ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2202             => sub { $push_to->(\@libraries, undef,
2203                                 \$attributes{libraries}, $+{ATTRIBS},
2204                                 tokenize($expand_variables->($+{VALUE})))
2205                          if !@skip || $skip[$#skip] > 0; },
2206             qr/^\s* MODULES ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2207             => sub { $push_to->(\@modules, undef,
2208                                 \$attributes{modules}, $+{ATTRIBS},
2209                                 tokenize($expand_variables->($+{VALUE})))
2210                          if !@skip || $skip[$#skip] > 0; },
2211             qr/^\s* SCRIPTS ${attribs_re} \s* = \s* ${value_re} \s* $/x
2212             => sub { $push_to->(\@scripts, undef,
2213                                 \$attributes{scripts}, $+{ATTRIBS},
2214                                 tokenize($expand_variables->($+{VALUE})))
2215                          if !@skip || $skip[$#skip] > 0; },
2216             qr/^\s* IMAGEDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2217             => sub { $push_to->(\%imagedocs, $expand_variables->($+{INDEX}),
2218                                 undef, undef,
2219                                 tokenize($expand_variables->($+{VALUE})))
2220                          if !@skip || $skip[$#skip] > 0; },
2221             qr/^\s* HTMLDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2222             => sub { $push_to->(\%htmldocs, $expand_variables->($+{INDEX}),
2223                                 undef, undef,
2224                                 tokenize($expand_variables->($+{VALUE})))
2225                          if !@skip || $skip[$#skip] > 0; },
2226             qr/^\s* MANDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2227             => sub { $push_to->(\%mandocs, $expand_variables->($+{INDEX}),
2228                                 undef, undef,
2229                                 tokenize($expand_variables->($+{VALUE})))
2230                          if !@skip || $skip[$#skip] > 0; },
2231             qr/^\s* SOURCE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2232             => sub { $push_to->(\%sources, $expand_variables->($+{INDEX}),
2233                                 \$attributes{sources}, $+{ATTRIBS},
2234                                 tokenize($expand_variables->($+{VALUE})))
2235                          if !@skip || $skip[$#skip] > 0; },
2236             qr/^\s* SHARED_SOURCE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2237             => sub { $push_to->(\%shared_sources, $expand_variables->($+{INDEX}),
2238                                 \$attributes{sources}, $+{ATTRIBS},
2239                                 tokenize($expand_variables->($+{VALUE})))
2240                          if !@skip || $skip[$#skip] > 0; },
2241             qr/^\s* INCLUDE ${index_re} \s* = \s* ${value_re} \s* $/x
2242             => sub { $push_to->(\%includes, $expand_variables->($+{INDEX}),
2243                                 undef, undef,
2244                                 tokenize($expand_variables->($+{VALUE})))
2245                          if !@skip || $skip[$#skip] > 0; },
2246             qr/^\s* DEFINE ${index_re} \s* = \s* ${value_re} \s* $/x
2247             => sub { $push_to->(\%defines, $expand_variables->($+{INDEX}),
2248                                 undef, undef,
2249                                 tokenize($expand_variables->($+{VALUE})))
2250                          if !@skip || $skip[$#skip] > 0; },
2251             qr/^\s* DEPEND ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2252             => sub { $push_to->(\%depends, $expand_variables->($+{INDEX}),
2253                                 \$attributes{depends}, $+{ATTRIBS},
2254                                 tokenize($expand_variables->($+{VALUE})))
2255                          if !@skip || $skip[$#skip] > 0; },
2256             qr/^\s* GENERATE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2257             => sub { $push_to->(\%generate, $expand_variables->($+{INDEX}),
2258                                 \$attributes{generate}, $+{ATTRIBS},
2259                                 $expand_variables->($+{VALUE}))
2260                          if !@skip || $skip[$#skip] > 0; },
2261             qr/^\s* (?:\#.*)? $/x => sub { },
2262             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
2263             "BEFORE" => sub {
2264                 if ($buildinfo_debug) {
2265                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
2266                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2267                 }
2268             },
2269             "AFTER" => sub {
2270                 if ($buildinfo_debug) {
2271                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2272                 }
2273             },
2274             );
2275         die "runaway IF?" if (@skip);
2276
2277         if (grep { defined $attributes{modules}->{$_}->{engine} } keys %attributes
2278                 and !$config{dynamic_engines}) {
2279             die <<"EOF"
2280 ENGINES can only be used if configured with 'dynamic-engine'.
2281 This is usually a fault in a build.info file.
2282 EOF
2283         }
2284
2285         {
2286             my %infos = ( programs  => [ @programs  ],
2287                           libraries => [ @libraries ],
2288                           modules   => [ @modules   ],
2289                           scripts   => [ @scripts   ] );
2290             foreach my $k (keys %infos) {
2291                 foreach (@{$infos{$k}}) {
2292                     my $item = cleanfile($buildd, $_, $blddir);
2293                     $unified_info{$k}->{$item} = 1;
2294
2295                     # Fix up associated attributes
2296                     $unified_info{attributes}->{$k}->{$item} =
2297                         $attributes{$k}->{$_}
2298                         if defined $attributes{$k}->{$_};
2299                 }
2300             }
2301         }
2302
2303         # Check that we haven't defined any library as both shared and
2304         # explicitly static.  That is forbidden.
2305         my @doubles = ();
2306         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2307             (my $l = $_) =~ s/\.a$//;
2308             push @doubles, $l if defined $unified_info{libraries}->{$l};
2309         }
2310         die "these libraries are both explicitly static and shared:\n  ",
2311             join(" ", @doubles), "\n"
2312             if @doubles;
2313
2314         foreach (keys %sources) {
2315             my $dest = $_;
2316             my $ddest = cleanfile($buildd, $_, $blddir);
2317             foreach (@{$sources{$dest}}) {
2318                 my $s = cleanfile($sourced, $_, $blddir);
2319
2320                 # If it's generated or we simply don't find it in the source
2321                 # tree, we assume it's in the build tree.
2322                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2323                     $s = cleanfile($buildd, $_, $blddir);
2324                 }
2325                 my $o = $_;
2326                 # We recognise C++, C and asm files
2327                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2328                     push @{$check_exist{$s}}, $ddest;
2329                     $o =~ s/\.[csS]$/.o/; # C and assembler
2330                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2331                     $o = cleanfile($buildd, $o, $blddir);
2332                     $unified_info{sources}->{$ddest}->{$o} = -1;
2333                     $unified_info{sources}->{$o}->{$s} = -1;
2334                 } elsif ($s =~ /\.rc$/) {
2335                     # We also recognise resource files
2336                     push @{$check_exist{$s}}, $ddest;
2337                     $o =~ s/\.rc$/.res/; # Resource configuration
2338                     $o = cleanfile($buildd, $o, $blddir);
2339                     $unified_info{sources}->{$ddest}->{$o} = -1;
2340                     $unified_info{sources}->{$o}->{$s} = -1;
2341                 } else {
2342                     push @{$check_exist{$s}}, $ddest;
2343                     $unified_info{sources}->{$ddest}->{$s} = 1;
2344                 }
2345                 # Fix up associated attributes
2346                 if ($o ne $_) {
2347                     $unified_info{attributes}->{sources}->{$ddest}->{$o} =
2348                         $unified_info{attributes}->{sources}->{$o}->{$s} =
2349                         $attributes{sources}->{$dest}->{$_}
2350                         if defined $attributes{sources}->{$dest}->{$_};
2351                 } else {
2352                     $unified_info{attributes}->{sources}->{$ddest}->{$s} =
2353                         $attributes{sources}->{$dest}->{$_}
2354                         if defined $attributes{sources}->{$dest}->{$_};
2355                 }
2356             }
2357         }
2358
2359         foreach (keys %shared_sources) {
2360             my $dest = $_;
2361             my $ddest = cleanfile($buildd, $_, $blddir);
2362             foreach (@{$shared_sources{$dest}}) {
2363                 my $s = cleanfile($sourced, $_, $blddir);
2364
2365                 # If it's generated or we simply don't find it in the source
2366                 # tree, we assume it's in the build tree.
2367                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2368                     $s = cleanfile($buildd, $_, $blddir);
2369                 }
2370
2371                 my $o = $_;
2372                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2373                     # We recognise C++, C and asm files
2374                     push @{$check_exist{$s}}, $ddest;
2375                     $o =~ s/\.[csS]$/.o/; # C and assembler
2376                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2377                     $o = cleanfile($buildd, $o, $blddir);
2378                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2379                     $unified_info{sources}->{$o}->{$s} = -1;
2380                 } elsif ($s =~ /\.rc$/) {
2381                     # We also recognise resource files
2382                     push @{$check_exist{$s}}, $ddest;
2383                     $o =~ s/\.rc$/.res/; # Resource configuration
2384                     $o = cleanfile($buildd, $o, $blddir);
2385                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2386                     $unified_info{sources}->{$o}->{$s} = -1;
2387                 } elsif ($s =~ /\.ld$/) {
2388                     # We also recognise linker scripts (or corresponding)
2389                     # We know they are generated files
2390                     push @{$check_exist{$s}}, $ddest;
2391                     $o = cleanfile($buildd, $_, $blddir);
2392                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
2393                 } else {
2394                     die "unrecognised source file type for shared library: $s\n";
2395                 }
2396                 # Fix up associated attributes
2397                 if ($o ne $_) {
2398                     $unified_info{attributes}->{shared_sources}->{$ddest}->{$o} =
2399                         $unified_info{attributes}->{sources}->{$o}->{$s} =
2400                         $attributes{sources}->{$dest}->{$_}
2401                         if defined $attributes{sources}->{$dest}->{$_};
2402                 } else {
2403                     $unified_info{attributes}->{shared_sources}->{$ddest}->{$o} =
2404                         $attributes{sources}->{$dest}->{$_}
2405                         if defined $attributes{sources}->{$dest}->{$_};
2406                 }
2407             }
2408         }
2409
2410         foreach (keys %generate) {
2411             my $dest = $_;
2412             my $ddest = cleanfile($buildd, $_, $blddir);
2413             die "more than one generator for $dest: "
2414                 ,join(" ", @{$generate{$_}}),"\n"
2415                 if scalar @{$generate{$_}} > 1;
2416             my @generator = split /\s+/, $generate{$dest}->[0];
2417             my $gen = $generator[0];
2418             $generator[0] = cleanfile($sourced, $gen, $blddir);
2419
2420             # If the generator is itself generated, it's in the build tree
2421             if ($generate{$gen} || ! -f $generator[0]) {
2422                 $generator[0] = cleanfile($buildd, $gen, $blddir);
2423             }
2424             $check_generate{$ddest}->{$generator[0]}++;
2425
2426             $unified_info{generate}->{$ddest} = [ @generator ];
2427             # Fix up associated attributes
2428             $unified_info{attributes}->{generate}->{$ddest} =
2429                 $attributes{generate}->{$dest}->{$gen}
2430                 if defined $attributes{generate}->{$dest}->{$gen};
2431         }
2432
2433         foreach (keys %depends) {
2434             my $dest = $_;
2435             my $ddest = $dest;
2436
2437             if ($dest =~ /^\|(.*)\|$/) {
2438                 # Collect the raw target
2439                 $unified_info{targets}->{$1} = 1;
2440                 $ddest = $1;
2441             } elsif ($dest eq '') {
2442                 $ddest = '';
2443             } else {
2444                 $ddest = cleanfile($sourced, $dest, $blddir);
2445
2446                 # If the destination doesn't exist in source, it can only be
2447                 # a generated file in the build tree.
2448                 if ($ddest eq $src_configdata || ! -f $ddest) {
2449                     $ddest = cleanfile($buildd, $dest, $blddir);
2450                 }
2451             }
2452             foreach my $f (@{$depends{$dest}}) {
2453                 # If the dependency destination is generated, dependencies
2454                 # may have an extra syntax to separate the intended inclusion
2455                 # directory from the module to be loaded: a | instead of a
2456                 # / as directory separator.
2457                 # Do note that this has to be handled in the build file
2458                 # template as well.
2459                 # $i = inclusion path in source directory
2460                 # $i2 = inclusion path in build directory
2461                 # $m = module path (within the inclusion path)
2462                 # $i = full module path in source directory
2463                 # $i2 = full module path in build directory
2464                 my $i; my $i2; my $m; my $d; my $d2;
2465                 if ($unified_info{generate}->{$ddest}
2466                     && $f =~ m/^(.*?)\|(.*)$/) {
2467                     $i = $1;
2468                     $m = $2;
2469                     $i = cleanfile($sourced, $i, $blddir);
2470                     $i2 = cleanfile($buildd, $i, $blddir);
2471                     $d = cleanfile($sourced, "$i/$m", $blddir);
2472                     $d2 = cleanfile($buildd, "$i/$m", $blddir);
2473                 } else {
2474                     $d = cleanfile($sourced, $f, $blddir);
2475                     $d2 = cleanfile($buildd, $f, $blddir);
2476                 }
2477
2478                 # If we know it's generated, or assume it is because we can't
2479                 # find it in the source tree, we set file we depend on to be
2480                 # in the build tree rather than the source tree.
2481                 if ($d eq $src_configdata
2482                     || (grep { $d2 eq $_ }
2483                         keys %{$unified_info{generate}})
2484                     || ! -f $d) {
2485                     $d = $d2;
2486                     $i = $i2;
2487                 }
2488                 if ($i) {
2489                     # Put together the computed inclusion dir with the
2490                     # original module name.  Do note that we conserve the
2491                     # Unixly path syntax for the module path.
2492                     $d = "$i|$m";
2493                 }
2494                 $unified_info{depends}->{$ddest}->{$d} = 1;
2495
2496                 # Fix up associated attributes
2497                 $unified_info{attributes}->{depends}->{$ddest}->{$d} =
2498                     $attributes{depends}->{$dest}->{$f}
2499                     if defined $attributes{depends}->{$dest}->{$f};
2500             }
2501         }
2502
2503         foreach (keys %includes) {
2504             my $dest = $_;
2505             my $ddest = cleanfile($sourced, $_, $blddir);
2506
2507             # If the destination doesn't exist in source, it can only be
2508             # a generated file in the build tree.
2509             if ($ddest eq $src_configdata || ! -f $ddest) {
2510                 $ddest = cleanfile($buildd, $_, $blddir);
2511             }
2512             foreach (@{$includes{$dest}}) {
2513                 my $is = cleandir($sourced, $_, $blddir);
2514                 my $ib = cleandir($buildd, $_, $blddir);
2515                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2516                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2517                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2518                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2519             }
2520         }
2521
2522         foreach my $dest (keys %defines) {
2523             my $ddest;
2524
2525             if ($dest ne "") {
2526                 $ddest = cleanfile($sourced, $dest, $blddir);
2527
2528                 # If the destination doesn't exist in source, it can only
2529                 # be a generated file in the build tree.
2530                 if (! -f $ddest) {
2531                     $ddest = cleanfile($buildd, $dest, $blddir);
2532                 }
2533             }
2534             foreach my $v (@{$defines{$dest}}) {
2535                 $v =~ m|^([^=]*)(=.*)?$|;
2536                 die "0 length macro name not permitted\n" if $1 eq "";
2537                 if ($dest ne "") {
2538                     die "$1 defined more than once\n"
2539                         if defined $unified_info{defines}->{$ddest}->{$1};
2540                     $unified_info{defines}->{$ddest}->{$1} = $2;
2541                 } else {
2542                     die "$1 defined more than once\n"
2543                         if grep { $v eq $_ } @{$config{defines}};
2544                     push @{$config{defines}}, $v;
2545                 }
2546             }
2547         }
2548
2549         foreach my $section (keys %imagedocs) {
2550             foreach (@{$imagedocs{$section}}) {
2551                 my $imagedocs = cleanfile($buildd, $_, $blddir);
2552                 $unified_info{imagedocs}->{$section}->{$imagedocs} = 1;
2553             }
2554         }
2555
2556         foreach my $section (keys %htmldocs) {
2557             foreach (@{$htmldocs{$section}}) {
2558                 my $htmldocs = cleanfile($buildd, $_, $blddir);
2559                 $unified_info{htmldocs}->{$section}->{$htmldocs} = 1;
2560             }
2561         }
2562
2563         foreach my $section (keys %mandocs) {
2564             foreach (@{$mandocs{$section}}) {
2565                 my $mandocs = cleanfile($buildd, $_, $blddir);
2566                 $unified_info{mandocs}->{$section}->{$mandocs} = 1;
2567             }
2568         }
2569     }
2570
2571     my $ordinals_text = join(', ', sort keys %ordinals);
2572     warn <<"EOF" if $ordinals_text;
2573
2574 WARNING: ORDINALS were specified for $ordinals_text
2575 They are ignored and should be replaced with a combination of GENERATE,
2576 DEPEND and SHARED_SOURCE.
2577 EOF
2578
2579     # Check that each generated file is only generated once
2580     my $ambiguous_generation = 0;
2581     foreach (sort keys %check_generate) {
2582         my @generators = sort keys %{$check_generate{$_}};
2583         my $generators_txt = join(', ', @generators);
2584         if (scalar @generators > 1) {
2585             warn "$_ is GENERATEd by more than one generator ($generators_txt)\n";
2586             $ambiguous_generation++;
2587         }
2588         if ($check_generate{$_}->{$generators[0]} > 1) {
2589             warn "INFO: $_ has more than one GENERATE declaration (same generator)\n"
2590         }
2591     }
2592     die "There are ambiguous source file generations\n"
2593         if $ambiguous_generation > 0;
2594
2595     # All given source files should exist, or if generated, their
2596     # generator should exist.  This loop ensures this is true.
2597     my $missing = 0;
2598     foreach my $orig (sort keys %check_exist) {
2599         foreach my $dest (@{$check_exist{$orig}}) {
2600             if ($orig ne $src_configdata) {
2601                 if ($orig =~ /\.a$/) {
2602                     # Static library names may be used as sources, so we
2603                     # need to detect those and give them special treatment.
2604                     unless (grep { $_ eq $orig }
2605                             keys %{$unified_info{libraries}}) {
2606                         warn "$orig is given as source for $dest, but no such library is built\n";
2607                         $missing++;
2608                     }
2609                 } else {
2610                     # A source may be generated, and its generator may be
2611                     # generated as well.  We therefore loop to dig out the
2612                     # first generator.
2613                     my $gen = $orig;
2614
2615                     while (my @next = keys %{$check_generate{$gen}}) {
2616                         $gen = $next[0];
2617                     }
2618
2619                     if (! -f $gen) {
2620                         if ($gen ne $orig) {
2621                             $missing++;
2622                             warn "$orig is given as source for $dest, but its generator (leading to $gen) is missing\n";
2623                         } else {
2624                             $missing++;
2625                             warn "$orig is given as source for $dest, but is missing\n";
2626                         }
2627                     }
2628                 }
2629             }
2630         }
2631     }
2632     die "There are files missing\n" if $missing > 0;
2633
2634     # Go through the sources of all libraries and check that the same basename
2635     # doesn't appear more than once.  Some static library archivers depend on
2636     # them being unique.
2637     {
2638         my $err = 0;
2639         foreach my $prod (keys %{$unified_info{libraries}}) {
2640             my @prod_sources =
2641                 map { keys %{$unified_info{sources}->{$_}} }
2642                 keys %{$unified_info{sources}->{$prod}};
2643             my %srccnt = ();
2644
2645             # Count how many times a given each source basename
2646             # appears for each product.
2647             foreach my $src (@prod_sources) {
2648                 $srccnt{basename $src}++;
2649             }
2650
2651             foreach my $src (keys %srccnt) {
2652                 if ((my $cnt = $srccnt{$src}) > 1) {
2653                     print STDERR "$src appears $cnt times for the product $prod\n";
2654                     $err++
2655                 }
2656             }
2657         }
2658         die if $err > 0;
2659     }
2660
2661     # Massage the result
2662
2663     # If we depend on a header file or a perl module, add an inclusion of
2664     # its directory to allow smoothe inclusion
2665     foreach my $dest (keys %{$unified_info{depends}}) {
2666         next if $dest eq "";
2667         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2668             next unless $d =~ /\.(h|pm)$/;
2669             # Take into account when a dependency uses the inclusion|module
2670             # syntax
2671             my $i = $d =~ m/\|/ ? $` : dirname($d);
2672             my $spot =
2673                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2674                 ? 'build' : 'source';
2675             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2676                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2677         }
2678     }
2679
2680     # Go through all intermediary files and change their names to something that
2681     # reflects what they will be built for.  Note that for some source files,
2682     # this leads to duplicate object files because they are used multiple times.
2683     # the goal is to rename all object files according to this scheme:
2684     #    {productname}-{midfix}-{origobjname}.[o|res]
2685     # the {midfix} is a keyword indicating the type of product, which is mostly
2686     # valuable for libraries since they come in two forms.
2687     #
2688     # This also reorganises the {sources} and {shared_sources} so that the
2689     # former only contains ALL object files that are supposed to end up in
2690     # static libraries and programs, while the latter contains ALL object files
2691     # that are supposed to end up in shared libraries and DSOs.
2692     # The main reason for having two different source structures is to allow
2693     # the same name to be used for the static and the shared variants of a
2694     # library.
2695     {
2696         # Take copies so we don't get interference from added stuff
2697         my %unified_copy = ();
2698         foreach (('sources', 'shared_sources')) {
2699             $unified_copy{$_} = { %{$unified_info{$_}} }
2700                 if defined($unified_info{$_});
2701             delete $unified_info{$_};
2702         }
2703         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2704             # $intent serves multi purposes:
2705             # - give a prefix for the new object files names
2706             # - in the case of libraries, rearrange the object files so static
2707             #   libraries use the 'sources' structure exclusively, while shared
2708             #   libraries use the 'shared_sources' structure exclusively.
2709             my $intent = {
2710                 programs  => { bin    => { src => [ 'sources' ],
2711                                            dst => 'sources' } },
2712                 libraries => { lib    => { src => [ 'sources' ],
2713                                            dst => 'sources' },
2714                                shlib  => { prodselect =>
2715                                                sub { grep !/\.a$/, @_ },
2716                                            src => [ 'sources',
2717                                                     'shared_sources' ],
2718                                            dst => 'shared_sources' } },
2719                 modules   => { dso    => { src => [ 'sources' ],
2720                                            dst => 'sources' } },
2721                 scripts   => { script => { src => [ 'sources' ],
2722                                            dst => 'sources' } }
2723                } -> {$prodtype};
2724             foreach my $kind (keys %$intent) {
2725                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2726                              && $disabled{shared});
2727
2728                 my @src = @{$intent->{$kind}->{src}};
2729                 my $dst = $intent->{$kind}->{dst};
2730                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2731                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2732                     # %prod_sources has all applicable objects as keys, and
2733                     # their corresponding sources as values
2734                     my %prod_sources =
2735                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2736                         map { keys %{$unified_copy{$_}->{$prod}} }
2737                         @src;
2738                     foreach (keys %prod_sources) {
2739                         # Only affect object files and resource files,
2740                         # the others simply get a new value
2741                         # (+1 instead of -1)
2742                         if ($_ =~ /\.(o|res)$/) {
2743                             (my $prodname = $prod) =~ s|\.a$||;
2744                             my $newobj =
2745                                 catfile(dirname($_),
2746                                         basename($prodname)
2747                                             . '-' . $kind
2748                                             . '-' . basename($_));
2749                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2750                             foreach my $src (@{$prod_sources{$_}}) {
2751                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2752                                 # Adjust source attributes
2753                                 my $attrs = $unified_info{attributes}->{sources};
2754                                 if (defined $attrs->{$prod}
2755                                     && defined $attrs->{$prod}->{$_}) {
2756                                     $attrs->{$prod}->{$newobj} =
2757                                         $attrs->{$prod}->{$_};
2758                                     delete $attrs->{$prod}->{$_};
2759                                 }
2760                                 foreach my $objsrc (keys %{$attrs->{$_} // {}}) {
2761                                     $attrs->{$newobj}->{$objsrc} =
2762                                         $attrs->{$_}->{$objsrc};
2763                                     delete $attrs->{$_}->{$objsrc};
2764                                 }
2765                             }
2766                             # Adjust dependencies
2767                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2768                                 $unified_info{depends}->{$_}->{$deps} = -1;
2769                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2770                             }
2771                             # Adjust includes
2772                             foreach my $k (('source', 'build')) {
2773                                 next unless
2774                                     defined($unified_info{includes}->{$_}->{$k});
2775                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2776                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2777                             }
2778                         } else {
2779                             $unified_info{$dst}->{$prod}->{$_} = 1;
2780                         }
2781                     }
2782                 }
2783             }
2784         }
2785     }
2786
2787     # At this point, we have a number of sources with the value -1.  They
2788     # aren't part of the local build and are probably meant for a different
2789     # platform, and can therefore be cleaned away.  That happens when making
2790     # %unified_info more efficient below.
2791
2792     ### Make unified_info a bit more efficient
2793     # One level structures
2794     foreach (("programs", "libraries", "modules", "scripts", "targets")) {
2795         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2796     }
2797     # Two level structures
2798     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends",
2799                      "imagedocs", "htmldocs", "mandocs")) {
2800         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2801             my @items =
2802                 sort
2803                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2804                 keys %{$unified_info{$l1}->{$l2}};
2805             if (@items) {
2806                 $unified_info{$l1}->{$l2} = [ @items ];
2807             } else {
2808                 delete $unified_info{$l1}->{$l2};
2809             }
2810         }
2811     }
2812     # Defines
2813     foreach my $dest (sort keys %{$unified_info{defines}}) {
2814         $unified_info{defines}->{$dest}
2815             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2816                 sort keys %{$unified_info{defines}->{$dest}} ];
2817     }
2818     # Includes
2819     foreach my $dest (sort keys %{$unified_info{includes}}) {
2820         if (defined($unified_info{includes}->{$dest}->{build})) {
2821             my @source_includes = ();
2822             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2823                 if defined($unified_info{includes}->{$dest}->{source});
2824             $unified_info{includes}->{$dest} =
2825                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2826             foreach my $inc (@source_includes) {
2827                 push @{$unified_info{includes}->{$dest}}, $inc
2828                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2829             }
2830         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2831             $unified_info{includes}->{$dest} =
2832                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2833         } else {
2834             delete $unified_info{includes}->{$dest};
2835         }
2836     }
2837
2838     # For convenience collect information regarding directories where
2839     # files are generated, those generated files and the end product
2840     # they end up in where applicable.  Then, add build rules for those
2841     # directories
2842     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2843                      "dso" => [ @{$unified_info{modules}} ],
2844                      "bin" => [ @{$unified_info{programs}} ],
2845                      "script" => [ @{$unified_info{scripts}} ],
2846                      "docs" => [ (map { @{$unified_info{imagedocs}->{$_} // []} }
2847                                   keys %{$unified_info{imagedocs} // {}}),
2848                                  (map { @{$unified_info{htmldocs}->{$_} // []} }
2849                                   keys %{$unified_info{htmldocs} // {}}),
2850                                  (map { @{$unified_info{mandocs}->{$_} // []} }
2851                                   keys %{$unified_info{mandocs} // {}}) ] );
2852     foreach my $type (sort keys %loopinfo) {
2853         foreach my $product (@{$loopinfo{$type}}) {
2854             my %dirs = ();
2855             my $pd = dirname($product);
2856
2857             foreach (@{$unified_info{sources}->{$product} // []},
2858                      @{$unified_info{shared_sources}->{$product} // []}) {
2859                 my $d = dirname($_);
2860
2861                 # We don't want to create targets for source directories
2862                 # when building out of source
2863                 next if ($config{sourcedir} ne $config{builddir}
2864                              && $d =~ m|^\Q$config{sourcedir}\E|);
2865                 # We already have a "test" target, and the current directory
2866                 # is just silly to make a target for
2867                 next if $d eq "test" || $d eq ".";
2868
2869                 $dirs{$d} = 1;
2870                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2871                     if $d ne $pd;
2872             }
2873             foreach (sort keys %dirs) {
2874                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2875                     $product;
2876             }
2877         }
2878     }
2879 }
2880
2881 # For the schemes that need it, we provide the old *_obj configs
2882 # from the *_asm_obj ones
2883 foreach (grep /_(asm|aux)_src$/, keys %target) {
2884     my $src = $_;
2885     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2886     $target{$obj} = $target{$src};
2887     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2888     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2889 }
2890
2891 # Write down our configuration where it fits #########################
2892
2893 my %template_vars = (
2894     config => \%config,
2895     target => \%target,
2896     disablables => \@disablables,
2897     disablables_int => \@disablables_int,
2898     disabled => \%disabled,
2899     withargs => \%withargs,
2900     unified_info => \%unified_info,
2901     tls => \@tls,
2902     dtls => \@dtls,
2903     makevars => [ sort keys %user ],
2904     disabled_info => \%disabled_info,
2905     user_crossable => \@user_crossable,
2906 );
2907 my $configdata_outname = 'configdata.pm';
2908 open CONFIGDATA, ">$configdata_outname.new"
2909     or die "Trying to create $configdata_outname.new: $!";
2910 my $configdata_tmplname = cleanfile($srcdir, "configdata.pm.in", $blddir);
2911 my $configdata_tmpl =
2912     OpenSSL::Template->new(TYPE => 'FILE', SOURCE => $configdata_tmplname);
2913 $configdata_tmpl->fill_in(
2914     FILENAME => $configdata_tmplname,
2915     OUTPUT => \*CONFIGDATA,
2916     HASH => { %template_vars,
2917               autowarntext => [
2918                   'WARNING: do not edit!',
2919                   "Generated by Configure from $configdata_tmplname",
2920               ] }
2921 ) or die $Text::Template::ERROR;
2922 close CONFIGDATA;
2923
2924 rename "$configdata_outname.new", $configdata_outname;
2925 if ($builder_platform eq 'unix') {
2926     my $mode = (0755 & ~umask);
2927     chmod $mode, 'configdata.pm'
2928         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2929 }
2930 print "Created $configdata_outname\n";
2931
2932 print "Running $configdata_outname\n";
2933 my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
2934 my $cmd = "$perlcmd $configdata_outname";
2935 #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2936 system($cmd);
2937 exit 1 if $? != 0;
2938
2939 $SIG{__DIE__} = $orig_death_handler;
2940
2941 print <<"EOF" if ($disabled{threads} eq "unavailable");
2942
2943 The library could not be configured for supporting multi-threaded
2944 applications as the compiler options required on this system are not known.
2945 See file INSTALL.md for details if you need multi-threading.
2946 EOF
2947
2948 print <<"EOF" if ($no_shared_warn);
2949
2950 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2951 platform, so we will pretend you gave the option 'no-pic', which also disables
2952 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2953 or position independent code, please let us know (but please first make sure
2954 you have tried with a current version of OpenSSL).
2955 EOF
2956
2957 print $banner;
2958
2959 exit(0);
2960
2961 ######################################################################
2962 #
2963 # Helpers and utility functions
2964 #
2965
2966 # Death handler, to print a helpful message in case of failure #######
2967 #
2968 sub death_handler {
2969     die @_ if $^S;              # To prevent the added message in eval blocks
2970     my $build_file = $config{build_file} // "build file";
2971     my @message = ( <<"_____", @_ );
2972
2973 Failure!  $build_file wasn't produced.
2974 Please read INSTALL.md and associated NOTES-* files.  You may also have to
2975 look over your available compiler tool chain or change your configuration.
2976
2977 _____
2978
2979     # Dying is terminal, so it's ok to reset the signal handler here.
2980     $SIG{__DIE__} = $orig_death_handler;
2981     die @message;
2982 }
2983
2984 # Configuration file reading #########################################
2985
2986 # Note: All of the helper functions are for lazy evaluation.  They all
2987 # return a CODE ref, which will return the intended value when evaluated.
2988 # Thus, whenever there's mention of a returned value, it's about that
2989 # intended value.
2990
2991 # Helper function to implement conditional value variants, with a default
2992 # plus additional values based on the value of $config{build_type}.
2993 # Arguments are given in hash table form:
2994 #
2995 #       picker(default => "Basic string: ",
2996 #              debug   => "debug",
2997 #              release => "release")
2998 #
2999 # When configuring with --debug, the resulting string will be
3000 # "Basic string: debug", and when not, it will be "Basic string: release"
3001 #
3002 # This can be used to create variants of sets of flags according to the
3003 # build type:
3004 #
3005 #       cflags => picker(default => "-Wall",
3006 #                        debug   => "-g -O0",
3007 #                        release => "-O3")
3008 #
3009 sub picker {
3010     my %opts = @_;
3011     return sub { add($opts{default} || (),
3012                      $opts{$config{build_type}} || ())->(); }
3013 }
3014
3015 # Helper function to combine several values of different types into one.
3016 # This is useful if you want to combine a string with the result of a
3017 # lazy function, such as:
3018 #
3019 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
3020 #
3021 sub combine {
3022     my @stuff = @_;
3023     return sub { add(@stuff)->(); }
3024 }
3025
3026 # Helper function to implement conditional values depending on the value
3027 # of $disabled{threads}.  Can be used as follows:
3028 #
3029 #       cflags => combine("-Wall", threads("-pthread"))
3030 #
3031 sub threads {
3032     my @flags = @_;
3033     return sub { add($disabled{threads} ? () : @flags)->(); }
3034 }
3035
3036 sub shared {
3037     my @flags = @_;
3038     return sub { add($disabled{shared} ? () : @flags)->(); }
3039 }
3040
3041 our $add_called = 0;
3042 # Helper function to implement adding values to already existing configuration
3043 # values.  It handles elements that are ARRAYs, CODEs and scalars
3044 sub _add {
3045     my $separator = shift;
3046
3047     # If there's any ARRAY in the collection of values OR the separator
3048     # is undef, we will return an ARRAY of combined values, otherwise a
3049     # string of joined values with $separator as the separator.
3050     my $found_array = !defined($separator);
3051
3052     my @values =
3053         map {
3054             my $res = $_;
3055             while (ref($res) eq "CODE") {
3056                 $res = $res->();
3057             }
3058             if (defined($res)) {
3059                 if (ref($res) eq "ARRAY") {
3060                     $found_array = 1;
3061                     @$res;
3062                 } else {
3063                     $res;
3064                 }
3065             } else {
3066                 ();
3067             }
3068     } (@_);
3069
3070     $add_called = 1;
3071
3072     if ($found_array) {
3073         [ @values ];
3074     } else {
3075         join($separator, grep { defined($_) && $_ ne "" } @values);
3076     }
3077 }
3078 sub add_before {
3079     my $separator = " ";
3080     if (ref($_[$#_]) eq "HASH") {
3081         my $opts = pop;
3082         $separator = $opts->{separator};
3083     }
3084     my @x = @_;
3085     sub { _add($separator, @x, @_) };
3086 }
3087 sub add {
3088     my $separator = " ";
3089     if (ref($_[$#_]) eq "HASH") {
3090         my $opts = pop;
3091         $separator = $opts->{separator};
3092     }
3093     my @x = @_;
3094     sub { _add($separator, @_, @x) };
3095 }
3096
3097 sub read_eval_file {
3098     my $fname = shift;
3099     my $content;
3100     my @result;
3101
3102     open F, "< $fname" or die "Can't open '$fname': $!\n";
3103     {
3104         undef local $/;
3105         $content = <F>;
3106     }
3107     close F;
3108     {
3109         local $@;
3110
3111         @result = ( eval $content );
3112         warn $@ if $@;
3113     }
3114     return wantarray ? @result : $result[0];
3115 }
3116
3117 # configuration reader, evaluates the input file as a perl script and expects
3118 # it to fill %targets with target configurations.  Those are then added to
3119 # %table.
3120 sub read_config {
3121     my $fname = shift;
3122     my %targets;
3123
3124     {
3125         # Protect certain tables from tampering
3126         local %table = ();
3127
3128         %targets = read_eval_file($fname);
3129     }
3130     my %preexisting = ();
3131     foreach (sort keys %targets) {
3132         $preexisting{$_} = 1 if $table{$_};
3133     }
3134     die <<"EOF",
3135 The following config targets from $fname
3136 shadow pre-existing config targets with the same name:
3137 EOF
3138         map { "  $_\n" } sort keys %preexisting
3139         if %preexisting;
3140
3141
3142     # For each target, check that it's configured with a hash table.
3143     foreach (keys %targets) {
3144         if (ref($targets{$_}) ne "HASH") {
3145             if (ref($targets{$_}) eq "") {
3146                 warn "Deprecated target configuration for $_, ignoring...\n";
3147             } else {
3148                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3149             }
3150             delete $targets{$_};
3151         } else {
3152             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3153         }
3154     }
3155
3156     %table = (%table, %targets);
3157
3158 }
3159
3160 # configuration resolver.  Will only resolve all the lazy evaluation
3161 # codeblocks for the chosen target and all those it inherits from,
3162 # recursively
3163 sub resolve_config {
3164     my $target = shift;
3165     my @breadcrumbs = @_;
3166
3167 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3168
3169     if (grep { $_ eq $target } @breadcrumbs) {
3170         die "inherit_from loop!  target backtrace:\n  "
3171             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3172     }
3173
3174     if (!defined($table{$target})) {
3175         warn "Warning! target $target doesn't exist!\n";
3176         return ();
3177     }
3178     # Recurse through all inheritances.  They will be resolved on the
3179     # fly, so when this operation is done, they will all just be a
3180     # bunch of attributes with string values.
3181     # What we get here, though, are keys with references to lists of
3182     # the combined values of them all.  We will deal with lists after
3183     # this stage is done.
3184     my %combined_inheritance = ();
3185     if ($table{$target}->{inherit_from}) {
3186         my @inherit_from =
3187             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3188         foreach (@inherit_from) {
3189             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3190
3191             # 'template' is a marker that's considered private to
3192             # the config that had it.
3193             delete $inherited_config{template};
3194
3195             foreach (keys %inherited_config) {
3196                 if (!$combined_inheritance{$_}) {
3197                     $combined_inheritance{$_} = [];
3198                 }
3199                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3200             }
3201         }
3202     }
3203
3204     # We won't need inherit_from in this target any more, since we've
3205     # resolved all the inheritances that lead to this
3206     delete $table{$target}->{inherit_from};
3207
3208     # Now is the time to deal with those lists.  Here's the place to
3209     # decide what shall be done with those lists, all based on the
3210     # values of the target we're currently dealing with.
3211     # - If a value is a coderef, it will be executed with the list of
3212     #   inherited values as arguments.
3213     # - If the corresponding key doesn't have a value at all or is the
3214     #   empty string, the inherited value list will be run through the
3215     #   default combiner (below), and the result becomes this target's
3216     #   value.
3217     # - Otherwise, this target's value is assumed to be a string that
3218     #   will simply override the inherited list of values.
3219     my $default_combiner = add();
3220
3221     my %all_keys =
3222         map { $_ => 1 } (keys %combined_inheritance,
3223                          keys %{$table{$target}});
3224
3225     sub process_values {
3226         my $object    = shift;
3227         my $inherited = shift;  # Always a [ list ]
3228         my $target    = shift;
3229         my $entry     = shift;
3230
3231         $add_called = 0;
3232
3233         while(ref($object) eq "CODE") {
3234             $object = $object->(@$inherited);
3235         }
3236         if (!defined($object)) {
3237             return ();
3238         }
3239         elsif (ref($object) eq "ARRAY") {
3240             local $add_called;  # To make sure recursive calls don't affect it
3241             return [ map { process_values($_, $inherited, $target, $entry) }
3242                      @$object ];
3243         } elsif (ref($object) eq "") {
3244             return $object;
3245         } else {
3246             die "cannot handle reference type ",ref($object)
3247                 ," found in target ",$target," -> ",$entry,"\n";
3248         }
3249     }
3250
3251     foreach my $key (sort keys %all_keys) {
3252         my $previous = $combined_inheritance{$key};
3253
3254         # Current target doesn't have a value for the current key?
3255         # Assign it the default combiner, the rest of this loop body
3256         # will handle it just like any other coderef.
3257         if (!exists $table{$target}->{$key}) {
3258             $table{$target}->{$key} = $default_combiner;
3259         }
3260
3261         $table{$target}->{$key} = process_values($table{$target}->{$key},
3262                                                $combined_inheritance{$key},
3263                                                $target, $key);
3264         unless(defined($table{$target}->{$key})) {
3265             delete $table{$target}->{$key};
3266         }
3267 #        if ($extra_checks &&
3268 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$key})) {
3269 #            warn "$key got replaced in $target\n";
3270 #        }
3271     }
3272
3273     # Finally done, return the result.
3274     return %{$table{$target}};
3275 }
3276
3277 sub usage
3278         {
3279         print STDERR $usage;
3280         print STDERR "\npick os/compiler from:\n";
3281         my $j=0;
3282         my $i;
3283         my $k=0;
3284         foreach $i (sort keys %table)
3285                 {
3286                 next if $table{$i}->{template};
3287                 next if $i =~ /^debug/;
3288                 $k += length($i) + 1;
3289                 if ($k > 78)
3290                         {
3291                         print STDERR "\n";
3292                         $k=length($i);
3293                         }
3294                 print STDERR $i . " ";
3295                 }
3296         foreach $i (sort keys %table)
3297                 {
3298                 next if $table{$i}->{template};
3299                 next if $i !~ /^debug/;
3300                 $k += length($i) + 1;
3301                 if ($k > 78)
3302                         {
3303                         print STDERR "\n";
3304                         $k=length($i);
3305                         }
3306                 print STDERR $i . " ";
3307                 }
3308         exit(1);
3309         }
3310
3311 sub compiler_predefined {
3312     state %predefined;
3313     my $cc = shift;
3314
3315     return () if $^O eq 'VMS';
3316
3317     die 'compiler_predefined called without a compiler command'
3318         unless $cc;
3319
3320     if (! $predefined{$cc}) {
3321
3322         $predefined{$cc} = {};
3323
3324         # collect compiler pre-defines from gcc or gcc-alike...
3325         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3326         while (my $l = <PIPE>) {
3327             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3328             $predefined{$cc}->{$1} = $2 // '';
3329         }
3330         close(PIPE);
3331     }
3332
3333     return %{$predefined{$cc}};
3334 }
3335
3336 sub which
3337 {
3338     my ($name)=@_;
3339
3340     if (eval { require IPC::Cmd; 1; }) {
3341         IPC::Cmd->import();
3342         return scalar IPC::Cmd::can_run($name);
3343     } else {
3344         # if there is $directories component in splitpath,
3345         # then it's not something to test with $PATH...
3346         return $name if (File::Spec->splitpath($name))[1];
3347
3348         foreach (File::Spec->path()) {
3349             my $fullpath = catfile($_, "$name$target{exe_extension}");
3350             if (-f $fullpath and -x $fullpath) {
3351                 return $fullpath;
3352             }
3353         }
3354     }
3355 }
3356
3357 sub env
3358 {
3359     my $name = shift;
3360     my %opts = @_;
3361
3362     unless ($opts{cacheonly}) {
3363         # Note that if $ENV{$name} doesn't exist or is undefined,
3364         # $config{perlenv}->{$name} will be created with the value
3365         # undef.  This is intentional.
3366
3367         $config{perlenv}->{$name} = $ENV{$name}
3368             if ! exists $config{perlenv}->{$name};
3369     }
3370     return $config{perlenv}->{$name};
3371 }
3372
3373 # Configuration printer ##############################################
3374
3375 sub print_table_entry
3376 {
3377     local $now_printing = shift;
3378     my %target = resolve_config($now_printing);
3379     my $type = shift;
3380
3381     # Don't print the templates
3382     return if $target{template};
3383
3384     my @sequence = (
3385         "sys_id",
3386         "cpp",
3387         "cppflags",
3388         "defines",
3389         "includes",
3390         "cc",
3391         "cflags",
3392         "ld",
3393         "lflags",
3394         "loutflag",
3395         "ex_libs",
3396         "bn_ops",
3397         "enable",
3398         "disable",
3399         "poly1035_asm_src",
3400         "thread_scheme",
3401         "perlasm_scheme",
3402         "dso_scheme",
3403         "shared_target",
3404         "shared_cflag",
3405         "shared_defines",
3406         "shared_ldflag",
3407         "shared_rcflag",
3408         "shared_extension",
3409         "dso_extension",
3410         "obj_extension",
3411         "exe_extension",
3412         "ranlib",
3413         "ar",
3414         "arflags",
3415         "aroutflag",
3416         "rc",
3417         "rcflags",
3418         "rcoutflag",
3419         "mt",
3420         "mtflags",
3421         "mtinflag",
3422         "mtoutflag",
3423         "multilib",
3424         "build_scheme",
3425         );
3426
3427     if ($type eq "TABLE") {
3428         print "\n";
3429         print "*** $now_printing\n";
3430         foreach (@sequence) {
3431             if (ref($target{$_}) eq "ARRAY") {
3432                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3433             } else {
3434                 printf "\$%-12s = %s\n", $_, $target{$_};
3435             }
3436         }
3437     } elsif ($type eq "HASH") {
3438         my $largest =
3439             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3440         print "    '$now_printing' => {\n";
3441         foreach (@sequence) {
3442             if ($target{$_}) {
3443                 if (ref($target{$_}) eq "ARRAY") {
3444                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3445                 } else {
3446                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3447                 }
3448             }
3449         }
3450         print "    },\n";
3451     }
3452 }
3453
3454 # Utility routines ###################################################
3455
3456 # On VMS, if the given file is a logical name, File::Spec::Functions
3457 # will consider it an absolute path.  There are cases when we want a
3458 # purely syntactic check without checking the environment.
3459 sub isabsolute {
3460     my $file = shift;
3461
3462     # On non-platforms, we just use file_name_is_absolute().
3463     return file_name_is_absolute($file) unless $^O eq "VMS";
3464
3465     # If the file spec includes a device or a directory spec,
3466     # file_name_is_absolute() is perfectly safe.
3467     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3468
3469     # Here, we know the given file spec isn't absolute
3470     return 0;
3471 }
3472
3473 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3474 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3475 # realpath() requires that at least all path components except the last is an
3476 # existing directory.  On VMS, the last component of the directory spec must
3477 # exist.
3478 sub absolutedir {
3479     my $dir = shift;
3480
3481     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3482     # will return the volume name for the device, no matter what.  Also,
3483     # it will return an incorrect directory spec if the argument is a
3484     # directory that doesn't exist.
3485     if ($^O eq "VMS") {
3486         return rel2abs($dir);
3487     }
3488
3489     # We use realpath() on Unix, since no other will properly clean out
3490     # a directory spec.
3491     use Cwd qw/realpath/;
3492
3493     return realpath($dir);
3494 }
3495
3496 # Check if all paths are one and the same, using stat.  They must both exist
3497 # We need this for the cases when File::Spec doesn't detect case insensitivity
3498 # (File::Spec::Unix assumes case sensitivity)
3499 sub samedir {
3500     die "samedir expects two arguments\n" unless scalar @_ == 2;
3501
3502     my @stat0 = stat($_[0]);    # First argument
3503     my @stat1 = stat($_[1]);    # Second argument
3504
3505     die "Couldn't stat $_[0]" unless @stat0;
3506     die "Couldn't stat $_[1]" unless @stat1;
3507
3508     # Compare device number
3509     return 0 unless ($stat0[0] == $stat1[0]);
3510     # Compare "inode".  The perl manual recommends comparing as
3511     # string rather than as number.
3512     return 0 unless ($stat0[1] eq $stat1[1]);
3513
3514     return 1;                   # All the same
3515 }
3516
3517 sub quotify {
3518     my %processors = (
3519         perl    => sub { my $x = shift;
3520                          $x =~ s/([\\\$\@"])/\\$1/g;
3521                          return '"'.$x.'"'; },
3522         maybeshell => sub { my $x = shift;
3523                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3524                             if ($x ne $y || $x =~ m|\s|) {
3525                                 return '"'.$y.'"';
3526                             } else {
3527                                 return $x;
3528                             }
3529                         },
3530         );
3531     my $for = shift;
3532     my $processor =
3533         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3534
3535     return map { $processor->($_); } @_;
3536 }
3537
3538 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3539 # $filename is a file name to read from
3540 # $line_concat_cond_re is a regexp detecting a line continuation ending
3541 # $line_concat is a CODEref that takes care of concatenating two lines
3542 sub collect_from_file {
3543     my $filename = shift;
3544     my $line_concat_cond_re = shift;
3545     my $line_concat = shift;
3546
3547     open my $fh, $filename || die "unable to read $filename: $!\n";
3548     return sub {
3549         my $saved_line = "";
3550         $_ = "";
3551         while (<$fh>) {
3552             s|\R$||;
3553             if (defined $line_concat) {
3554                 $_ = $line_concat->($saved_line, $_);
3555                 $saved_line = "";
3556             }
3557             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3558                 $saved_line = $_;
3559                 next;
3560             }
3561             return $_;
3562         }
3563         die "$filename ending with continuation line\n" if $_;
3564         close $fh;
3565         return undef;
3566     }
3567 }
3568
3569 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3570 # $array is an ARRAYref of lines
3571 # $line_concat_cond_re is a regexp detecting a line continuation ending
3572 # $line_concat is a CODEref that takes care of concatenating two lines
3573 sub collect_from_array {
3574     my $array = shift;
3575     my $line_concat_cond_re = shift;
3576     my $line_concat = shift;
3577     my @array = (@$array);
3578
3579     return sub {
3580         my $saved_line = "";
3581         $_ = "";
3582         while (defined($_ = shift @array)) {
3583             s|\R$||;
3584             if (defined $line_concat) {
3585                 $_ = $line_concat->($saved_line, $_);
3586                 $saved_line = "";
3587             }
3588             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3589                 $saved_line = $_;
3590                 next;
3591             }
3592             return $_;
3593         }
3594         die "input text ending with continuation line\n" if $_;
3595         return undef;
3596     }
3597 }
3598
3599 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3600 # $lineiterator is a CODEref that delivers one line at a time.
3601 # All following arguments are regex/CODEref pairs, where the regexp detects a
3602 # line and the CODEref does something with the result of the regexp.
3603 sub collect_information {
3604     my $lineiterator = shift;
3605     my %collectors = @_;
3606
3607     while(defined($_ = $lineiterator->())) {
3608         s|\R$||;
3609         my $found = 0;
3610         if ($collectors{"BEFORE"}) {
3611             $collectors{"BEFORE"}->($_);
3612         }
3613         foreach my $re (keys %collectors) {
3614             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3615                 $collectors{$re}->($lineiterator);
3616                 $found = 1;
3617             };
3618         }
3619         if ($collectors{"OTHERWISE"}) {
3620             $collectors{"OTHERWISE"}->($lineiterator, $_)
3621                 unless $found || !defined $collectors{"OTHERWISE"};
3622         }
3623         if ($collectors{"AFTER"}) {
3624             $collectors{"AFTER"}->($_);
3625         }
3626     }
3627 }
3628
3629 # tokenize($line)
3630 # tokenize($line,$separator)
3631 # $line is a line of text to split up into tokens
3632 # $separator [optional] is a regular expression that separates the tokens,
3633 # the default being spaces.  Do not use quotes of any kind as separators,
3634 # that will give undefined results.
3635 # Returns a list of tokens.
3636 #
3637 # Tokens are divided by separator (spaces by default).  If the tokens include
3638 # the separators, they have to be quoted with single or double quotes.
3639 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3640 # with backslash.
3641 # Basically, the same quoting rules apply for " and ' as in any
3642 # Unix shell.
3643 sub tokenize {
3644     my $line = my $debug_line = shift;
3645     my $separator = shift // qr|\s+|;
3646     my @result = ();
3647
3648     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3649         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3650     }
3651
3652     while ($line =~ s|^${separator}||, $line ne "") {
3653         my $token = "";
3654     again:
3655         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3656         $token .= $1;
3657         $line = $2.$';
3658
3659         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3660             $token .= $1;
3661             $line = $';
3662             goto again;
3663         } elsif ($line =~ m/^'([^']*)'/) {
3664             $token .= $1;
3665             $line = $';
3666             goto again;
3667         }
3668         push @result, $token;
3669     }
3670
3671     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3672         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3673         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3674     }
3675     return @result;
3676 }