Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the OpenSSL license (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::Glob;
  21
  22 # see INSTALL for instructions.
  23
  24 my $orig_death_handler = $SIG{__DIE__};
  25 $SIG{__DIE__} = \&death_handler;
  26
  27 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  28
  29 # Options:
  30 #
  31 # --config      add the given configuration file, which will be read after
  32 #               any "Configurations*" files that are found in the same
  33 #               directory as this script.
  34 # --prefix      prefix for the OpenSSL installation, which includes the
  35 #               directories bin, lib, include, share/man, share/doc/openssl
  36 #               This becomes the value of INSTALLTOP in Makefile
  37 #               (Default: /usr/local)
  38 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  39 #               If it's a relative directory, it will be added on the directory
  40 #               given with --prefix.
  41 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  42 #               (Default: PREFIX/ssl)
  43 #
  44 # --cross-compile-prefix Add specified prefix to binutils components.
  45 #
  46 # --api         One of 0.9.8, 1.0.0 or 1.1.0.  Do not compile support for
  47 #               interfaces deprecated as of the specified OpenSSL version.
  48 #
  49 # no-hw-xxx     do not compile support for specific crypto hardware.
  50 #               Generic OpenSSL-style methods relating to this support
  51 #               are always compiled but return NULL if the hardware
  52 #               support isn't compiled.
  53 # no-hw         do not compile support for any crypto hardware.
  54 # [no-]threads  [don't] try to create a library that is suitable for
  55 #               multithreaded applications (default is "threads" if we
  56 #               know how to do it)
  57 # [no-]shared   [don't] try to create shared libraries when supported.
  58 # [no-]pic      [don't] try to build position independent code when supported.
  59 #               If disabled, it also disables shared and dynamic-engine.
  60 # no-asm        do not use assembler
  61 # no-dso        do not compile in any native shared-library methods. This
  62 #               will ensure that all methods just return NULL.
  63 # no-egd        do not compile support for the entropy-gathering daemon APIs
  64 # [no-]zlib     [don't] compile support for zlib compression.
  65 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  66 #               library and will be loaded in run-time by the OpenSSL library.
  67 # sctp          include SCTP support
  68 # enable-weak-ssl-ciphers
  69 #               Enable weak ciphers that are disabled by default.
  70 # 386           generate 80386 code in assembly modules
  71 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  72 #               mentioned '386' option implies this one
  73 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  74 # -<xxx> +<xxx> compiler options are passed through
  75 # -static       while -static is also a pass-through compiler option (and
  76 #               as such is limited to environments where it's actually
  77 #               meaningful), it triggers a number configuration options,
  78 #               namely no-dso, no-pic, no-shared and no-threads. It is
  79 #               argued that the only reason to produce statically linked
  80 #               binaries (and in context it means executables linked with
  81 #               -static flag, and not just executables linked with static
  82 #               libcrypto.a) is to eliminate dependency on specific run-time,
  83 #               a.k.a. libc version. The mentioned config options are meant
  84 #               to achieve just that. Unfortunately on Linux it's impossible
  85 #               to eliminate the dependency completely for openssl executable
  86 #               because of getaddrinfo and gethostbyname calls, which can
  87 #               invoke dynamically loadable library facility anyway to meet
  88 #               the lookup requests. For this reason on Linux statically
  89 #               linked openssl executable has rather debugging value than
  90 #               production quality.
  91 #
  92 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
  93 #               provided to stack calls. Generates unique stack functions for
  94 #               each possible stack type.
  95 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  96 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  97 # Following are set automatically by this script
  98 #
  99 # MD5_ASM       use some extra md5 assembler,
 100 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 101 # RMD160_ASM    use some extra ripemd160 assembler,
 102 # SHA256_ASM    sha256_block is implemented in assembler
 103 # SHA512_ASM    sha512_block is implemented in assembler
 104 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 105
 106 # Minimum warning options... any contributions to OpenSSL should at least get
 107 # past these.
 108
 109 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 110 # -DPEDANTIC complements -pedantic and is meant to mask code that
 111 # is not strictly standard-compliant and/or implementation-specific,
 112 # e.g. inline assembly, disregards to alignment requirements, such
 113 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 114 # to be used even in sanitized builds, because sanitizer too is
 115 # supposed to and does take notice of non-standard behaviour. Then
 116 # -pedantic with pre-C9x compiler would also complain about 'long
 117 # long' not being supported. As 64-bit algorithms are common now,
 118 # it grew impossible to resolve this without sizeable additional
 119 # code, so we just tell compiler to be pedantic about everything
 120 # but 'long long' type.
 121
 122 my $gcc_devteam_warn = "-DDEBUG_UNUSED"
 123         . " -DPEDANTIC -pedantic -Wno-long-long"
 124         . " -Wall"
 125         . " -Wextra"
 126         . " -Wno-unused-parameter"
 127         . " -Wno-missing-field-initializers"
 128         . " -Wswitch"
 129         . " -Wsign-compare"
 130         . " -Wmissing-prototypes"
 131         . " -Wstrict-prototypes"
 132         . " -Wshadow"
 133         . " -Wformat"
 134         . " -Wtype-limits"
 135         . " -Wundef"
 136         . " -Werror"
 137         ;
 138
 139 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 140 # TODO(openssl-team): fix problems and investigate if (at least) the
 141 # following warnings can also be enabled:
 142 #       -Wcast-align
 143 #       -Wunreachable-code -- no, too ugly/compiler-specific
 144 #       -Wlanguage-extension-token -- no, we use asm()
 145 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 146 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 147 my $clang_devteam_warn = ""
 148         . " -Wswitch-default"
 149         . " -Wno-parentheses-equality"
 150         . " -Wno-language-extension-token"
 151         . " -Wno-extended-offsetof"
 152         . " -Wconditional-uninitialized"
 153         . " -Wincompatible-pointer-types-discards-qualifiers"
 154         . " -Wmissing-variable-declarations"
 155         . " -Wno-unknown-warning-option"
 156         ;
 157
 158 # This adds backtrace information to the memory leak info.  Is only used
 159 # when crypto-mdebug-backtrace is enabled.
 160 my $memleak_devteam_backtrace = "-rdynamic";
 161
 162 my $strict_warnings = 0;
 163
 164 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 165 # which would cover all BSD flavors. -pthread applies to them all,
 166 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 167 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 168 # which has to be accompanied by explicit -D_THREAD_SAFE and
 169 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 170 # seems to be sufficient?
 171 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 172
 173 #
 174 # API compatibility name to version number mapping.
 175 #
 176 my $maxapi = "1.1.0";           # API for "no-deprecated" builds
 177 my $apitable = {
 178     "1.1.0" => "0x10100000L",
 179     "1.0.0" => "0x10000000L",
 180     "0.9.8" => "0x00908000L",
 181 };
 182
 183 our %table = ();
 184 our %config = ();
 185 our %withargs = ();
 186 our $now_printing;      # set to current entry's name in print_table_entry
 187                         # (todo: right thing would be to encapsulate name
 188                         # into %target [class] and make print_table_entry
 189                         # a method)
 190
 191 # Forward declarations ###############################################
 192
 193 # read_config(filename)
 194 #
 195 # Reads a configuration file and populates %table with the contents
 196 # (which the configuration file places in %targets).
 197 sub read_config;
 198
 199 # resolve_config(target)
 200 #
 201 # Resolves all the late evaluations, inheritances and so on for the
 202 # chosen target and any target it inherits from.
 203 sub resolve_config;
 204
 205
 206 # Information collection #############################################
 207
 208 # Unified build supports separate build dir
 209 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 210 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 211 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 212
 213 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 214
 215 $config{sourcedir} = abs2rel($srcdir);
 216 $config{builddir} = abs2rel($blddir);
 217
 218 # Collect reconfiguration information if needed
 219 my @argvcopy=@ARGV;
 220
 221 if (grep /^reconf(igure)?$/, @argvcopy) {
 222     die "reconfiguring with other arguments present isn't supported"
 223         if scalar @argvcopy > 1;
 224     if (-f "./configdata.pm") {
 225         my $file = "./configdata.pm";
 226         unless (my $return = do $file) {
 227             die "couldn't parse $file: $@" if $@;
 228             die "couldn't do $file: $!"    unless defined $return;
 229             die "couldn't run $file"       unless $return;
 230         }
 231
 232         @argvcopy = defined($configdata::config{perlargv}) ?
 233             @{$configdata::config{perlargv}} : ();
 234         die "Incorrect data to reconfigure, please do a normal configuration\n"
 235             if (grep(/^reconf/,@argvcopy));
 236         $config{perlenv} = $configdata::config{perlenv} // {};
 237     } else {
 238         die "Insufficient data to reconfigure, please do a normal configuration\n";
 239     }
 240 }
 241
 242 $config{perlargv} = [ @argvcopy ];
 243
 244 # Collect version numbers
 245 $config{version} = "unknown";
 246 $config{version_num} = "unknown";
 247 $config{shlib_version_number} = "unknown";
 248 $config{shlib_version_history} = "unknown";
 249
 250 collect_information(
 251     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 252     qr/OPENSSL.VERSION.TEXT.*OpenSSL (\S+) / => sub { $config{version} = $1; },
 253     qr/OPENSSL.VERSION.NUMBER.*(0x\S+)/      => sub { $config{version_num}=$1 },
 254     qr/SHLIB_VERSION_NUMBER *"([^"]+)"/      => sub { $config{shlib_version_number}=$1 },
 255     qr/SHLIB_VERSION_HISTORY *"([^"]*)"/     => sub { $config{shlib_version_history}=$1 }
 256     );
 257 if ($config{shlib_version_history} ne "") { $config{shlib_version_history} .= ":"; }
 258
 259 ($config{major}, $config{minor})
 260     = ($config{version} =~ /^([0-9]+)\.([0-9\.]+)/);
 261 ($config{shlib_major}, $config{shlib_minor})
 262     = ($config{shlib_version_number} =~ /^([0-9]+)\.([0-9\.]+)/);
 263 die "erroneous version information in opensslv.h: ",
 264     "$config{major}, $config{minor}, $config{shlib_major}, $config{shlib_minor}\n"
 265     if ($config{major} eq "" || $config{minor} eq ""
 266         || $config{shlib_major} eq "" ||  $config{shlib_minor} eq "");
 267
 268 # Collect target configurations
 269
 270 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 271 foreach (sort glob($pattern)) {
 272     &read_config($_);
 273 }
 274
 275 if (defined env($local_config_envname)) {
 276     if ($^O eq 'VMS') {
 277         # VMS environment variables are logical names,
 278         # which can be used as is
 279         $pattern = $local_config_envname . ':' . '*.conf';
 280     } else {
 281         $pattern = catfile(env($local_config_envname), '*.conf');
 282     }
 283
 284     foreach (sort glob($pattern)) {
 285         &read_config($_);
 286     }
 287 }
 288
 289 # Save away perl command information
 290 $config{perl_cmd} = $^X;
 291 $config{perl_version} = $Config{version};
 292 $config{perl_archname} = $Config{archname};
 293
 294 $config{prefix}="";
 295 $config{openssldir}="";
 296 $config{processor}="";
 297 $config{libdir}="";
 298 my $auto_threads=1;    # enable threads automatically? true by default
 299 my $default_ranlib;
 300
 301 # Known TLS and DTLS protocols
 302 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 303 my @dtls = qw(dtls1 dtls1_2);
 304
 305 # Explicitly known options that are possible to disable.  They can
 306 # be regexps, and will be used like this: /^no-${option}$/
 307 # For developers: keep it sorted alphabetically
 308
 309 my @disablables = (
 310     "afalgeng",
 311     "aria",
 312     "asan",
 313     "asm",
 314     "async",
 315     "autoalginit",
 316     "autoerrinit",
 317     "autoload-config",
 318     "bf",
 319     "blake2",
 320     "camellia",
 321     "capieng",
 322     "cast",
 323     "chacha",
 324     "cmac",
 325     "cms",
 326     "comp",
 327     "crypto-mdebug",
 328     "crypto-mdebug-backtrace",
 329     "ct",
 330     "deprecated",
 331     "des",
 332     "devcryptoeng",
 333     "dgram",
 334     "dh",
 335     "dsa",
 336     "dso",
 337     "dtls",
 338     "dynamic-engine",
 339     "ec",
 340     "ec2m",
 341     "ecdh",
 342     "ecdsa",
 343     "ec_nistp_64_gcc_128",
 344     "egd",
 345     "engine",
 346     "err",
 347     "external-tests",
 348     "filenames",
 349     "fuzz-libfuzzer",
 350     "fuzz-afl",
 351     "gost",
 352     "heartbeats",
 353     "hw(-.+)?",
 354     "idea",
 355     "makedepend",
 356     "md2",
 357     "md4",
 358     "mdc2",
 359     "msan",
 360     "multiblock",
 361     "nextprotoneg",
 362     "ocb",
 363     "ocsp",
 364     "pic",
 365     "poly1305",
 366     "posix-io",
 367     "psk",
 368     "rc2",
 369     "rc4",
 370     "rc5",
 371     "rdrand",
 372     "rfc3779",
 373     "rmd160",
 374     "scrypt",
 375     "sctp",
 376     "seed",
 377     "shared",
 378     "siphash",
 379     "sm2",
 380     "sm3",
 381     "sm4",
 382     "sock",
 383     "srp",
 384     "srtp",
 385     "sse2",
 386     "ssl",
 387     "ssl-trace",
 388     "static-engine",
 389     "stdio",
 390     "tests",
 391     "threads",
 392     "tls",
 393     "ts",
 394     "ubsan",
 395     "ui-console",
 396     "unit-test",
 397     "whirlpool",
 398     "weak-ssl-ciphers",
 399     "zlib",
 400     "zlib-dynamic",
 401     );
 402 foreach my $proto ((@tls, @dtls))
 403         {
 404         push(@disablables, $proto);
 405         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 406         }
 407
 408 my %deprecated_disablables = (
 409     "ssl2" => undef,
 410     "buf-freelists" => undef,
 411     "ripemd" => "rmd160",
 412     "ui" => "ui-console",
 413     );
 414
 415 # All of the following are disabled by default:
 416
 417 our %disabled = ( # "what"         => "comment"
 418                   "asan"                => "default",
 419                   "crypto-mdebug"       => "default",
 420                   "crypto-mdebug-backtrace" => "default",
 421                   "devcryptoeng"        => "default",
 422                   "ec_nistp_64_gcc_128" => "default",
 423                   "egd"                 => "default",
 424                   "external-tests"      => "default",
 425                   "fuzz-libfuzzer"      => "default",
 426                   "fuzz-afl"            => "default",
 427                   "heartbeats"          => "default",
 428                   "md2"                 => "default",
 429                   "msan"                => "default",
 430                   "rc5"                 => "default",
 431                   "sctp"                => "default",
 432                   "ssl-trace"           => "default",
 433                   "ssl3"                => "default",
 434                   "ssl3-method"         => "default",
 435                   "ubsan"               => "default",
 436                   "unit-test"           => "default",
 437                   "weak-ssl-ciphers"    => "default",
 438                   "zlib"                => "default",
 439                   "zlib-dynamic"        => "default",
 440                 );
 441
 442 # Note: => pair form used for aesthetics, not to truly make a hash table
 443 my @disable_cascades = (
 444     # "what"            => [ "cascade", ... ]
 445     sub { $config{processor} eq "386" }
 446                         => [ "sse2" ],
 447     "ssl"               => [ "ssl3" ],
 448     "ssl3-method"       => [ "ssl3" ],
 449     "zlib"              => [ "zlib-dynamic" ],
 450     "des"               => [ "mdc2" ],
 451     "ec"                => [ "ecdsa", "ecdh" ],
 452
 453     "dgram"             => [ "dtls", "sctp" ],
 454     "sock"              => [ "dgram" ],
 455     "dtls"              => [ @dtls ],
 456     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 457                         => [ "dtls" ],
 458
 459     "tls"               => [ @tls ],
 460     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 461                         => [ "tls" ],
 462
 463     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 464
 465     # Without DSO, we can't load dynamic engines, so don't build them dynamic
 466     "dso"               => [ "dynamic-engine" ],
 467
 468     # Without position independent code, there can be no shared libraries or DSOs
 469     "pic"               => [ "shared" ],
 470     "shared"            => [ "dynamic-engine" ],
 471     "engine"            => [ "afalgeng", "devcryptoeng" ],
 472
 473     # no-autoalginit is only useful when building non-shared
 474     "autoalginit"       => [ "shared", "apps" ],
 475
 476     "stdio"             => [ "apps", "capieng", "egd" ],
 477     "apps"              => [ "tests" ],
 478     "tests"             => [ "external-tests" ],
 479     "comp"              => [ "zlib" ],
 480     "ec"                => [ "tls1_3", "sm2" ],
 481     "sm3"               => [ "sm2" ],
 482     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 483
 484     sub { !$disabled{"msan"} } => [ "asm" ],
 485     );
 486
 487 # Avoid protocol support holes.  Also disable all versions below N, if version
 488 # N is disabled while N+1 is enabled.
 489 #
 490 my @list = (reverse @tls);
 491 while ((my $first, my $second) = (shift @list, shift @list)) {
 492     last unless @list;
 493     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 494                               => [ @list ] );
 495     unshift @list, $second;
 496 }
 497 my @list = (reverse @dtls);
 498 while ((my $first, my $second) = (shift @list, shift @list)) {
 499     last unless @list;
 500     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 501                               => [ @list ] );
 502     unshift @list, $second;
 503 }
 504
 505 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 506 # To remove something from %disabled, use "enable-foo".
 507 # For symmetry, "disable-foo" is a synonym for "no-foo".
 508
 509 &usage if ($#ARGV < 0);
 510
 511 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 512 # platform specific list separators.  Users from those platforms should
 513 # recognise those separators from how you set up the PATH to find executables.
 514 # The default is the Unix like separator, :, but as an exception, we also
 515 # support the space as separator.
 516 my $list_separator_re =
 517     { VMS           => qr/(?<!\^),/,
 518       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 519 # All the "make variables" we support
 520 # Some get pre-populated for the sake of backward compatibility
 521 # (we supported those before the change to "make variable" support.
 522 my %user = (
 523     AR          => env('AR'),
 524     ARFLAGS     => [],
 525     AS          => undef,
 526     ASFLAGS     => [],
 527     CC          => env('CC'),
 528     CFLAGS      => [],
 529     CXX         => env('CXX'),
 530     CXXFLAGS    => [],
 531     CPP         => undef,
 532     CPPFLAGS    => [],  # -D, -I, -Wp,
 533     CPPDEFINES  => [],  # Alternative for -D
 534     CPPINCLUDES => [],  # Alternative for -I
 535     CROSS_COMPILE => env('CROSS_COMPILE'),
 536     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 537     LD          => undef,
 538     LDFLAGS     => [],  # -L, -Wl,
 539     LDLIBS      => [],  # -l
 540     MT          => undef,
 541     MTFLAGS     => [],
 542     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 543     RANLIB      => env('RANLIB'),
 544     RC          => env('RC') || env('WINDRES'),
 545     RCFLAGS     => [],
 546     RM          => undef,
 547    );
 548 # Info about what "make variables" may be prefixed with the cross compiler
 549 # prefix.  This should NEVER mention any such variable with a list for value.
 550 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 551 # The same but for flags given as Configure options.  These are *additional*
 552 # input, as opposed to the VAR=string option that override the corresponding
 553 # config target attributes
 554 my %useradd = (
 555     CPPDEFINES  => [],
 556     CPPINCLUDES => [],
 557     CPPFLAGS    => [],
 558     CFLAGS      => [],
 559     CXXFLAGS    => [],
 560     LDFLAGS     => [],
 561     LDLIBS      => [],
 562    );
 563
 564 my %user_synonyms = (
 565     HASHBANGPERL=> 'PERL',
 566     RC          => 'WINDRES',
 567    );
 568
 569 # Some target attributes have been renamed, this is the translation table
 570 my %target_attr_translate =(
 571     ar          => 'AR',
 572     as          => 'AS',
 573     cc          => 'CC',
 574     cxx         => 'CXX',
 575     cpp         => 'CPP',
 576     hashbangperl => 'HASHBANGPERL',
 577     ld          => 'LD',
 578     mt          => 'MT',
 579     ranlib      => 'RANLIB',
 580     rc          => 'RC',
 581     rm          => 'RM',
 582    );
 583
 584 # Initialisers coming from 'config' scripts
 585 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 586 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 587 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 588 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 589 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 590 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 591 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 592
 593 $config{openssl_api_defines}=[];
 594 $config{openssl_sys_defines}=[];
 595 $config{openssl_feature_defines}=[];
 596 $config{options}="";
 597 $config{build_type} = "release";
 598 my $target="";
 599
 600 my %cmdvars = ();               # Stores FOO='blah' type arguments
 601 my %unsupported_options = ();
 602 my %deprecated_options = ();
 603 # If you change this, update apps/version.c
 604 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 605 my @seed_sources = ();
 606 while (@argvcopy)
 607         {
 608         $_ = shift @argvcopy;
 609
 610         # Support env variable assignments among the options
 611         if (m|^(\w+)=(.+)?$|)
 612                 {
 613                 $cmdvars{$1} = $2;
 614                 # Every time a variable is given as a configuration argument,
 615                 # it acts as a reset if the variable.
 616                 if (exists $user{$1})
 617                         {
 618                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 619                         }
 620                 #if (exists $useradd{$1})
 621                 #       {
 622                 #       $useradd{$1} = [];
 623                 #       }
 624                 next;
 625                 }
 626
 627         # VMS is a case insensitive environment, and depending on settings
 628         # out of our control, we may receive options uppercased.  Let's
 629         # downcase at least the part before any equal sign.
 630         if ($^O eq "VMS")
 631                 {
 632                 s/^([^=]*)/lc($1)/e;
 633                 }
 634
 635         # some people just can't read the instructions, clang people have to...
 636         s/^-no-(?!integrated-as)/no-/;
 637
 638         # rewrite some options in "enable-..." form
 639         s /^-?-?shared$/enable-shared/;
 640         s /^sctp$/enable-sctp/;
 641         s /^threads$/enable-threads/;
 642         s /^zlib$/enable-zlib/;
 643         s /^zlib-dynamic$/enable-zlib-dynamic/;
 644
 645         if (/^(no|disable|enable)-(.+)$/)
 646                 {
 647                 my $word = $2;
 648                 if (!exists $deprecated_disablables{$word}
 649                         && !grep { $word =~ /^${_}$/ } @disablables)
 650                         {
 651                         $unsupported_options{$_} = 1;
 652                         next;
 653                         }
 654                 }
 655         if (/^no-(.+)$/ || /^disable-(.+)$/)
 656                 {
 657                 foreach my $proto ((@tls, @dtls))
 658                         {
 659                         if ($1 eq "$proto-method")
 660                                 {
 661                                 $disabled{"$proto"} = "option($proto-method)";
 662                                 last;
 663                                 }
 664                         }
 665                 if ($1 eq "dtls")
 666                         {
 667                         foreach my $proto (@dtls)
 668                                 {
 669                                 $disabled{$proto} = "option(dtls)";
 670                                 }
 671                         $disabled{"dtls"} = "option(dtls)";
 672                         }
 673                 elsif ($1 eq "ssl")
 674                         {
 675                         # Last one of its kind
 676                         $disabled{"ssl3"} = "option(ssl)";
 677                         }
 678                 elsif ($1 eq "tls")
 679                         {
 680                         # XXX: Tests will fail if all SSL/TLS
 681                         # protocols are disabled.
 682                         foreach my $proto (@tls)
 683                                 {
 684                                 $disabled{$proto} = "option(tls)";
 685                                 }
 686                         }
 687                 elsif ($1 eq "static-engine")
 688                         {
 689                         delete $disabled{"dynamic-engine"};
 690                         }
 691                 elsif ($1 eq "dynamic-engine")
 692                         {
 693                         $disabled{"dynamic-engine"} = "option";
 694                         }
 695                 elsif (exists $deprecated_disablables{$1})
 696                         {
 697                         $deprecated_options{$_} = 1;
 698                         if (defined $deprecated_disablables{$1})
 699                                 {
 700                                 $disabled{$deprecated_disablables{$1}} = "option";
 701                                 }
 702                         }
 703                 else
 704                         {
 705                         $disabled{$1} = "option";
 706                         }
 707                 # No longer an automatic choice
 708                 $auto_threads = 0 if ($1 eq "threads");
 709                 }
 710         elsif (/^enable-(.+)$/)
 711                 {
 712                 if ($1 eq "static-engine")
 713                         {
 714                         $disabled{"dynamic-engine"} = "option";
 715                         }
 716                 elsif ($1 eq "dynamic-engine")
 717                         {
 718                         delete $disabled{"dynamic-engine"};
 719                         }
 720                 elsif ($1 eq "zlib-dynamic")
 721                         {
 722                         delete $disabled{"zlib"};
 723                         }
 724                 my $algo = $1;
 725                 delete $disabled{$algo};
 726
 727                 # No longer an automatic choice
 728                 $auto_threads = 0 if ($1 eq "threads");
 729                 }
 730         elsif (/^--strict-warnings$/)
 731                 {
 732                 $strict_warnings = 1;
 733                 }
 734         elsif (/^--debug$/)
 735                 {
 736                 $config{build_type} = "debug";
 737                 }
 738         elsif (/^--release$/)
 739                 {
 740                 $config{build_type} = "release";
 741                 }
 742         elsif (/^386$/)
 743                 { $config{processor}=386; }
 744         elsif (/^fips$/)
 745                 {
 746                 die "FIPS mode not supported\n";
 747                 }
 748         elsif (/^rsaref$/)
 749                 {
 750                 # No RSAref support any more since it's not needed.
 751                 # The check for the option is there so scripts aren't
 752                 # broken
 753                 }
 754         elsif (/^nofipscanistercheck$/)
 755                 {
 756                 die "FIPS mode not supported\n";
 757                 }
 758         elsif (/^[-+]/)
 759                 {
 760                 if (/^--prefix=(.*)$/)
 761                         {
 762                         $config{prefix}=$1;
 763                         die "Directory given with --prefix MUST be absolute\n"
 764                                 unless file_name_is_absolute($config{prefix});
 765                         }
 766                 elsif (/^--api=(.*)$/)
 767                         {
 768                         $config{api}=$1;
 769                         }
 770                 elsif (/^--libdir=(.*)$/)
 771                         {
 772                         $config{libdir}=$1;
 773                         }
 774                 elsif (/^--openssldir=(.*)$/)
 775                         {
 776                         $config{openssldir}=$1;
 777                         }
 778                 elsif (/^--with-zlib-lib=(.*)$/)
 779                         {
 780                         $withargs{zlib_lib}=$1;
 781                         }
 782                 elsif (/^--with-zlib-include=(.*)$/)
 783                         {
 784                         $withargs{zlib_include}=$1;
 785                         }
 786                 elsif (/^--with-fuzzer-lib=(.*)$/)
 787                         {
 788                         $withargs{fuzzer_lib}=$1;
 789                         }
 790                 elsif (/^--with-fuzzer-include=(.*)$/)
 791                         {
 792                         $withargs{fuzzer_include}=$1;
 793                         }
 794                 elsif (/^--with-rand-seed=(.*)$/)
 795                         {
 796                         foreach my $x (split(m|,|, $1))
 797                             {
 798                             die "Unknown --with-rand-seed choice $x\n"
 799                                 if ! grep { $x eq $_ } @known_seed_sources;
 800                             push @seed_sources, $x;
 801                             }
 802                         }
 803                 elsif (/^--cross-compile-prefix=(.*)$/)
 804                         {
 805                         $user{CROSS_COMPILE}=$1;
 806                         }
 807                 elsif (/^--config=(.*)$/)
 808                         {
 809                         read_config $1;
 810                         }
 811                 elsif (/^-l(.*)$/)
 812                         {
 813                         push @{$useradd{LDLIBS}}, $_;
 814                         }
 815                 elsif (/^-framework$/)
 816                         {
 817                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 818                         }
 819                 elsif (/^-L(.*)$/ or /^-Wl,/)
 820                         {
 821                         push @{$useradd{LDFLAGS}}, $_;
 822                         }
 823                 elsif (/^-rpath$/ or /^-R$/)
 824                         # -rpath is the OSF1 rpath flag
 825                         # -R is the old Solaris rpath flag
 826                         {
 827                         my $rpath = shift(@argvcopy) || "";
 828                         $rpath .= " " if $rpath ne "";
 829                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 830                         }
 831                 elsif (/^-static$/)
 832                         {
 833                         push @{$useradd{LDFLAGS}}, $_;
 834                         $disabled{"dso"} = "forced";
 835                         $disabled{"pic"} = "forced";
 836                         $disabled{"shared"} = "forced";
 837                         $disabled{"threads"} = "forced";
 838                         }
 839                 elsif (/^-D(.*)$/)
 840                         {
 841                         push @{$useradd{CPPDEFINES}}, $1;
 842                         }
 843                 elsif (/^-I(.*)$/)
 844                         {
 845                         push @{$useradd{CPPINCLUDES}}, $1;
 846                         }
 847                 elsif (/^-Wp,$/)
 848                         {
 849                         push @{$useradd{CPPFLAGS}}, $1;
 850                         }
 851                 else    # common if (/^[-+]/), just pass down...
 852                         {
 853                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 854                         push @{$useradd{CFLAGS}}, $_;
 855                         push @{$useradd{CXXFLAGS}}, $_;
 856                         }
 857                 }
 858         else
 859                 {
 860                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 861                 $target=$_;
 862                 }
 863         unless ($_ eq $target || /^no-/ || /^disable-/)
 864                 {
 865                 # "no-..." follows later after implied deactivations
 866                 # have been derived.  (Don't take this too seriously,
 867                 # we really only write OPTIONS to the Makefile out of
 868                 # nostalgia.)
 869
 870                 if ($config{options} eq "")
 871                         { $config{options} = $_; }
 872                 else
 873                         { $config{options} .= " ".$_; }
 874                 }
 875         }
 876
 877 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 878         die "***** Unsupported api compatibility level: $config{api}\n",
 879 }
 880
 881 if (keys %deprecated_options)
 882         {
 883         warn "***** Deprecated options: ",
 884                 join(", ", keys %deprecated_options), "\n";
 885         }
 886 if (keys %unsupported_options)
 887         {
 888         die "***** Unsupported options: ",
 889                 join(", ", keys %unsupported_options), "\n";
 890         }
 891
 892 # If any %useradd entry has been set, we must check that the "make
 893 # variables" haven't been set.  We start by checking of any %useradd entry
 894 # is set.
 895 if (grep { scalar @$_ > 0 } values %useradd) {
 896     # Hash of env / make variables names.  The possible values are:
 897     # 1 - "make vars"
 898     # 2 - %useradd entry set
 899     # 3 - both set
 900     my %detected_vars =
 901         map { my $v = 0;
 902               $v += 1 if $cmdvars{$_};
 903               $v += 2 if @{$useradd{$_}};
 904               $_ => $v }
 905         keys %useradd;
 906
 907     # If any of the corresponding "make variables" is set, we error
 908     if (grep { $_ & 1 } values %detected_vars) {
 909         my $names = join(', ', grep { $detected_vars{$_} > 0 }
 910                                sort keys %detected_vars);
 911         die <<"_____";
 912 ***** Mixing make variables and additional compiler/linker flags as
 913 ***** configure command line option is not permitted.
 914 ***** Affected make variables: $names
 915 _____
 916     }
 917 }
 918
 919 # Check through all supported command line variables to see if any of them
 920 # were set, and canonicalise the values we got.  If no compiler or linker
 921 # flag or anything else that affects %useradd was set, we also check the
 922 # environment for values.
 923 my $anyuseradd =
 924     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
 925 foreach (keys %user) {
 926     my $value = $cmdvars{$_};
 927     $value //= env($_) unless $anyuseradd;
 928     $value //=
 929         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
 930     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
 931         unless $anyuseradd;
 932
 933     if (defined $value) {
 934         if (ref $user{$_} eq 'ARRAY') {
 935             $user{$_} = [ split /$list_separator_re/, $value ];
 936         } elsif (!defined $user{$_}) {
 937             $user{$_} = $value;
 938         }
 939     }
 940 }
 941
 942 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
 943     && !$disabled{shared}
 944     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
 945     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
 946         "***** any of asan, msan or ubsan\n";
 947 }
 948
 949 my @tocheckfor = (keys %disabled);
 950 while (@tocheckfor) {
 951     my %new_tocheckfor = ();
 952     my @cascade_copy = (@disable_cascades);
 953     while (@cascade_copy) {
 954         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
 955         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
 956             foreach(grep { !defined($disabled{$_}) } @$descendents) {
 957                 $new_tocheckfor{$_} = 1; $disabled{$_} = "forced";
 958             }
 959         }
 960     }
 961     @tocheckfor = (keys %new_tocheckfor);
 962 }
 963
 964 our $die = sub { die @_; };
 965 if ($target eq "TABLE") {
 966     local $die = sub { warn @_; };
 967     foreach (sort keys %table) {
 968         print_table_entry($_, "TABLE");
 969     }
 970     exit 0;
 971 }
 972
 973 if ($target eq "LIST") {
 974     foreach (sort keys %table) {
 975         print $_,"\n" unless $table{$_}->{template};
 976     }
 977     exit 0;
 978 }
 979
 980 if ($target eq "HASH") {
 981     local $die = sub { warn @_; };
 982     print "%table = (\n";
 983     foreach (sort keys %table) {
 984         print_table_entry($_, "HASH");
 985     }
 986     exit 0;
 987 }
 988
 989 print "Configuring OpenSSL version $config{version} ($config{version_num}) ";
 990 print "for $target\n";
 991
 992 if (scalar(@seed_sources) == 0) {
 993     print "Using os-specific seed configuration\n";
 994     push @seed_sources, 'os';
 995 }
 996 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
 997     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
 998     warn <<_____ if scalar(@seed_sources) == 1;
 999
1000 ============================== WARNING ===============================
1001 You have selected the --with-rand-seed=none option, which effectively
1002 disables automatic reseeding of the OpenSSL random generator.
1003 All operations depending on the random generator such as creating keys
1004 will not work unless the random generator is seeded manually by the
1005 application.
1006
1007 Please read the 'Note on random number generation' section in the
1008 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1009 ============================== WARNING ===============================
1010
1011 _____
1012 }
1013 push @{$config{openssl_feature_defines}},
1014      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1015         @seed_sources;
1016
1017 # Backward compatibility?
1018 if ($target =~ m/^CygWin32(-.*)$/) {
1019     $target = "Cygwin".$1;
1020 }
1021
1022 # Support for legacy targets having a name starting with 'debug-'
1023 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1024 if ($d) {
1025     $config{build_type} = "debug";
1026
1027     # If we do not find debug-foo in the table, the target is set to foo.
1028     if (!$table{$target}) {
1029         $target = $t;
1030     }
1031 }
1032
1033 &usage if !$table{$target} || $table{$target}->{template};
1034
1035 $config{target} = $target;
1036 my %target = resolve_config($target);
1037
1038 foreach (keys %target_attr_translate) {
1039     $target{$target_attr_translate{$_}} = $target{$_}
1040         if $target{$_};
1041     delete $target{$_};
1042 }
1043
1044 %target = ( %{$table{DEFAULTS}}, %target );
1045
1046 # Make the flags to build DSOs the same as for shared libraries unless they
1047 # are already defined
1048 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1049 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1050 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1051 {
1052     my $shared_info_pl =
1053         catfile(dirname($0), "Configurations", "shared-info.pl");
1054     my %shared_info = read_eval_file($shared_info_pl);
1055     push @{$target{_conf_fname_int}}, $shared_info_pl;
1056     my $si = $target{shared_target};
1057     while (ref $si ne "HASH") {
1058         last if ! defined $si;
1059         if (ref $si eq "CODE") {
1060             $si = $si->();
1061         } else {
1062             $si = $shared_info{$si};
1063         }
1064     }
1065
1066     # Some of the 'shared_target' values don't have any entried in
1067     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1068     # template knows how to handle this.  That is currently the case for
1069     # Windows and VMS.
1070     if (defined $si) {
1071         # Just as above, copy certain shared_* attributes to the corresponding
1072         # module_ attribute unless the latter is already defined
1073         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1074         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1075         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1076         foreach (sort keys %$si) {
1077             $target{$_} = defined $target{$_}
1078                 ? add($si->{$_})->($target{$_})
1079                 : $si->{$_};
1080         }
1081     }
1082 }
1083
1084 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1085 $config{conf_files} = [ sort keys %conf_files ];
1086
1087 foreach my $feature (@{$target{disable}}) {
1088     if (exists $deprecated_disablables{$feature}) {
1089         warn "***** config $target disables deprecated feature $feature\n";
1090     } elsif (!grep { $feature eq $_ } @disablables) {
1091         die "***** config $target disables unknown feature $feature\n";
1092     }
1093     $disabled{$feature} = 'config';
1094 }
1095 foreach my $feature (@{$target{enable}}) {
1096     if ("default" eq ($disabled{$_} // "")) {
1097         if (exists $deprecated_disablables{$feature}) {
1098             warn "***** config $target enables deprecated feature $feature\n";
1099         } elsif (!grep { $feature eq $_ } @disablables) {
1100             die "***** config $target enables unknown feature $feature\n";
1101         }
1102         delete $disabled{$_};
1103     }
1104 }
1105
1106 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1107 $target{cxxflags}//=$target{cflags} if $target{CXX};
1108 $target{exe_extension}="";
1109 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP"
1110                                   || $config{target} =~ /^(?:Cygwin|mingw)/);
1111 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1112 $target{def_extension}=".ld";
1113 $target{def_extension}=".def" if $config{target} =~ /^mingw|VC-/;
1114 $target{def_extension}=".opt" if $config{target} =~ /^vms/;
1115 ($target{shared_extension_simple}=$target{shared_extension})
1116     =~ s|\.\$\(SHLIB_VERSION_NUMBER\)||
1117     unless defined($target{shared_extension_simple});
1118 $target{dso_extension}//=$target{shared_extension_simple};
1119 ($target{shared_import_extension}=$target{shared_extension_simple}.".a")
1120     if ($config{target} =~ /^(?:Cygwin|mingw)/);
1121
1122 # Fill %config with values from %user, and in case those are undefined or
1123 # empty, use values from %target (acting as a default).
1124 foreach (keys %user) {
1125     my $ref_type = ref $user{$_};
1126
1127     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1128     # and a value that's to be coerced into that type.
1129     my $mkvalue = sub {
1130         my $type = shift;
1131         my $value = shift;
1132         my $undef_p = shift;
1133
1134         die "Too many arguments for \$mkvalue" if @_;
1135
1136         while (ref $value eq 'CODE') {
1137             $value = $value->();
1138         }
1139
1140         if ($type eq 'ARRAY') {
1141             return undef unless defined $value;
1142             return undef if ref $value ne 'ARRAY' && !$value;
1143             return undef if ref $value eq 'ARRAY' && !@$value;
1144             return [ $value ] unless ref $value eq 'ARRAY';
1145         }
1146         return undef unless $value;
1147         return $value;
1148     };
1149
1150     $config{$_} =
1151         $mkvalue->($ref_type, $user{$_})
1152         || $mkvalue->($ref_type, $target{$_});
1153     delete $config{$_} unless defined $config{$_};
1154 }
1155
1156 # Allow overriding the build file name
1157 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1158
1159 ######################################################################
1160 # Build up information for skipping certain directories depending on disabled
1161 # features, as well as setting up macros for disabled features.
1162
1163 # This is a tentative database of directories to skip.  Some entries may not
1164 # correspond to anything real, but that's ok, they will simply be ignored.
1165 # The actual processing of these entries is done in the build.info lookup
1166 # loop further down.
1167 #
1168 # The key is a Unix formated path in the source tree, the value is an index
1169 # into %disabled_info, so any existing path gets added to a corresponding
1170 # 'skipped' entry in there with the list of skipped directories.
1171 my %skipdir = ();
1172 my %disabled_info = ();         # For configdata.pm
1173 foreach my $what (sort keys %disabled) {
1174     $config{options} .= " no-$what";
1175
1176     if (!grep { $what eq $_ } ( 'dso', 'threads', 'shared', 'pic',
1177                                 'dynamic-engine', 'makedepend',
1178                                 'zlib-dynamic', 'zlib', 'sse2' )) {
1179         (my $WHAT = uc $what) =~ s|-|_|g;
1180         my $skipdir = $what;
1181
1182         # fix-up crypto/directory name(s)
1183         $skipdir = "ripemd" if $what eq "rmd160";
1184         $skipdir = "whrlpool" if $what eq "whirlpool";
1185
1186         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1187         push @{$config{openssl_feature_defines}}, $macro;
1188
1189         $skipdir{engines} = $what if $what eq 'engine';
1190         $skipdir{"crypto/$skipdir"} = $what
1191             unless $what eq 'async' || $what eq 'err';
1192     }
1193 }
1194
1195 # Make sure build_scheme is consistent.
1196 $target{build_scheme} = [ $target{build_scheme} ]
1197     if ref($target{build_scheme}) ne "ARRAY";
1198
1199 my ($builder, $builder_platform, @builder_opts) =
1200     @{$target{build_scheme}};
1201
1202 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1203                       $builder_platform."-checker.pm")) {
1204     my $checker_path = catfile($srcdir, "Configurations", $checker);
1205     if (-f $checker_path) {
1206         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1207             ? sub { warn $@; } : sub { die $@; };
1208         if (! do $checker_path) {
1209             if ($@) {
1210                 $fn->($@);
1211             } elsif ($!) {
1212                 $fn->($!);
1213             } else {
1214                 $fn->("The detected tools didn't match the platform\n");
1215             }
1216         }
1217         last;
1218     }
1219 }
1220
1221 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1222
1223 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1224         {
1225         push @{$config{cflags}}, "-mno-cygwin";
1226         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1227         push @{$config{shared_ldflag}}, "-mno-cygwin";
1228         }
1229
1230 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1231         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$user{CFLAGS}},
1232                                             @{$useradd{CFLAGS}})) {
1233         # minimally required architecture flags for assembly modules
1234         my $value;
1235         $value = '-mips2' if ($target =~ /mips32/);
1236         $value = '-mips3' if ($target =~ /mips64/);
1237         unshift @{$config{cflags}}, $value;
1238         unshift @{$config{cxxflags}}, $value if $config{CXX};
1239 }
1240
1241 # If threads aren't disabled, check how possible they are
1242 unless ($disabled{threads}) {
1243     if ($auto_threads) {
1244         # Enabled by default, disable it forcibly if unavailable
1245         if ($target{thread_scheme} eq "(unknown)") {
1246             $disabled{threads} = "unavailable";
1247         }
1248     } else {
1249         # The user chose to enable threads explicitly, let's see
1250         # if there's a chance that's possible
1251         if ($target{thread_scheme} eq "(unknown)") {
1252             # If the user asked for "threads" and we don't have internal
1253             # knowledge how to do it, [s]he is expected to provide any
1254             # system-dependent compiler options that are necessary.  We
1255             # can't truly check that the given options are correct, but
1256             # we expect the user to know what [s]He is doing.
1257             if (!@{$user{CFLAGS}} && !@{$useradd{CFLAGS}}
1258                     && !@{$user{CPPDEFINES}} && !@{$useradd{CPPDEFINES}}) {
1259                 die "You asked for multi-threading support, but didn't\n"
1260                     ,"provide any system-specific compiler options\n";
1261             }
1262         }
1263     }
1264 }
1265
1266 # If threads still aren't disabled, add a C macro to ensure the source
1267 # code knows about it.  Any other flag is taken care of by the configs.
1268 unless($disabled{threads}) {
1269     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1270 }
1271
1272 # With "deprecated" disable all deprecated features.
1273 if (defined($disabled{"deprecated"})) {
1274         $config{api} = $maxapi;
1275 }
1276
1277 my $no_shared_warn=0;
1278 if ($target{shared_target} eq "")
1279         {
1280         $no_shared_warn = 1
1281             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1282         $disabled{shared} = "no-shared-target";
1283         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
1284             "no-shared-target";
1285         }
1286
1287 if ($disabled{"dynamic-engine"}) {
1288         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1289         $config{dynamic_engines} = 0;
1290 } else {
1291         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1292         $config{dynamic_engines} = 1;
1293 }
1294
1295 unless ($disabled{asan}) {
1296     push @{$config{cflags}}, "-fsanitize=address";
1297     push @{$config{cxxflags}}, "-fsanitize=address" if $config{CXX};
1298 }
1299
1300 unless ($disabled{ubsan}) {
1301     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1302     # platforms.
1303     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1304     push @{$config{cxxflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all"
1305         if $config{CXX};
1306 }
1307
1308 unless ($disabled{msan}) {
1309   push @{$config{cflags}}, "-fsanitize=memory";
1310   push @{$config{cxxflags}}, "-fsanitize=memory" if $config{CXX};
1311 }
1312
1313 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1314         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1315     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1316     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1317 }
1318 #
1319 # Platform fix-ups
1320 #
1321
1322 # This saves the build files from having to check
1323 if ($disabled{pic})
1324         {
1325         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1326                     shared_defines shared_includes shared_ldflag
1327                     module_cflags module_cxxflags module_cppflags
1328                     module_defines module_includes module_lflags))
1329                 {
1330                 delete $config{$_};
1331                 $target{$_} = "";
1332                 }
1333         }
1334 else
1335         {
1336         push @{$config{lib_defines}}, "OPENSSL_PIC";
1337         }
1338
1339 if ($target{sys_id} ne "")
1340         {
1341         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1342         }
1343
1344 unless ($disabled{asm}) {
1345     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1346     push @{$config{lib_defines}}, "OPENSSL_CPUID_OBJ" if ($target{cpuid_asm_src} ne "mem_clr.c");
1347
1348     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1349
1350     # bn-586 is the only one implementing bn_*_part_words
1351     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1352     push @{$config{lib_defines}}, "OPENSSL_IA32_SSE2" if (!$disabled{sse2} && $target{bn_asm_src} =~ /86/);
1353
1354     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1355     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1356     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1357     push @{$config{lib_defines}}, "BN_DIV3W" if ($target{bn_asm_src} =~ /-div3w/);
1358
1359     if ($target{sha1_asm_src}) {
1360         push @{$config{lib_defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1361         push @{$config{lib_defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1362         push @{$config{lib_defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1363     }
1364     if ($target{keccak1600_asm_src} ne $table{DEFAULTS}->{keccak1600_asm_src}) {
1365         push @{$config{lib_defines}}, "KECCAK1600_ASM";
1366     }
1367     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1368         push @{$config{lib_defines}}, "RC4_ASM";
1369     }
1370     if ($target{md5_asm_src}) {
1371         push @{$config{lib_defines}}, "MD5_ASM";
1372     }
1373     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1374     if ($target{rmd160_asm_src}) {
1375         push @{$config{lib_defines}}, "RMD160_ASM";
1376     }
1377     if ($target{aes_asm_src}) {
1378         push @{$config{lib_defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1379         # aes-ctr.fake is not a real file, only indication that assembler
1380         # module implements AES_ctr32_encrypt...
1381         push @{$config{lib_defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1382         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1383         push @{$config{lib_defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1384         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($disabled{sse2});
1385         push @{$config{lib_defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1386         push @{$config{lib_defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1387     }
1388     if ($target{wp_asm_src} =~ /mmx/) {
1389         if ($config{processor} eq "386") {
1390             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1391         } elsif (!$disabled{"whirlpool"}) {
1392             push @{$config{lib_defines}}, "WHIRLPOOL_ASM";
1393         }
1394     }
1395     if ($target{modes_asm_src} =~ /ghash-/) {
1396         push @{$config{lib_defines}}, "GHASH_ASM";
1397     }
1398     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1399         push @{$config{lib_defines}}, "ECP_NISTZ256_ASM";
1400     }
1401     if ($target{ec_asm_src} =~ /x25519/) {
1402         push @{$config{lib_defines}}, "X25519_ASM";
1403     }
1404     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1405         push @{$config{lib_defines}}, "PADLOCK_ASM";
1406     }
1407     if ($target{poly1305_asm_src} ne "") {
1408         push @{$config{lib_defines}}, "POLY1305_ASM";
1409     }
1410 }
1411
1412 my %predefined = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1413
1414 # Check for makedepend capabilities.
1415 if (!$disabled{makedepend}) {
1416     if ($config{target} =~ /^(VC|vms)-/) {
1417         # For VC- and vms- targets, there's nothing more to do here.  The
1418         # functionality is hard coded in the corresponding build files for
1419         # cl (Windows) and CC/DECC (VMS).
1420     } elsif (($predefined{__GNUC__} // -1) >= 3
1421              && !($predefined{__APPLE_CC__} && !$predefined{__clang__})) {
1422         # We know that GNU C version 3 and up as well as all clang
1423         # versions support dependency generation, but Xcode did not
1424         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1425         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1426     } else {
1427         # In all other cases, we look for 'makedepend', and disable the
1428         # capability if not found.
1429         $config{makedepprog} = which('makedepend');
1430         $disabled{makedepend} = "unavailable" unless $config{makedepprog};
1431     }
1432 }
1433
1434 if (!$disabled{asm} && !$predefined{__MACH__} && $^O ne 'VMS') {
1435     # probe for -Wa,--noexecstack option...
1436     if ($predefined{__clang__}) {
1437         # clang has builtin assembler, which doesn't recognize --help,
1438         # but it apparently recognizes the option in question on all
1439         # supported platforms even when it's meaningless. In other words
1440         # probe would fail, but probed option always accepted...
1441         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1442     } else {
1443         my $cc = $config{CROSS_COMPILE}.$config{CC};
1444         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1445         while(<PIPE>) {
1446             if (m/--noexecstack/) {
1447                 push @{$config{cflags}}, "-Wa,--noexecstack";
1448                 last;
1449             }
1450         }
1451         close(PIPE);
1452         unlink("null.$$.o");
1453     }
1454 }
1455
1456 # Deal with bn_ops ###################################################
1457
1458 $config{bn_ll}                  =0;
1459 $config{export_var_as_fn}       =0;
1460 my $def_int="unsigned int";
1461 $config{rc4_int}                =$def_int;
1462 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1463
1464 my $count = 0;
1465 foreach (sort split(/\s+/,$target{bn_ops})) {
1466     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1467     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1468     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1469     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1470     ($config{b64l},$config{b64},$config{b32})
1471         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1472     ($config{b64l},$config{b64},$config{b32})
1473         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1474     ($config{b64l},$config{b64},$config{b32})
1475         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1476 }
1477 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1478     if $count > 1;
1479
1480
1481 # Hack cflags for better warnings (dev option) #######################
1482
1483 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1484 # a string and works as well on command lines.
1485 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1486                         @{$config{cflags}} ];
1487 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1488                           @{$config{cxxflags}} ] if $config{CXX};
1489
1490 if (defined($config{api})) {
1491     $config{openssl_api_defines} = [ "OPENSSL_MIN_API=".$apitable->{$config{api}} ];
1492     my $apiflag = sprintf("OPENSSL_API_COMPAT=%s", $apitable->{$config{api}});
1493     push @{$config{defines}}, $apiflag;
1494 }
1495
1496 if ($strict_warnings)
1497         {
1498         my $wopt;
1499         my $gccver = $predefined{__GNUC__} // -1;
1500
1501         die "ERROR --strict-warnings requires gcc[>=4] or gcc-alike"
1502             unless $gccver >= 4;
1503         foreach $wopt (split /\s+/, $gcc_devteam_warn)
1504                 {
1505                 push @{$config{cflags}}, $wopt
1506                         unless grep { $_ eq $wopt } @{$config{cflags}};
1507                 push @{$config{cxxflags}}, $wopt
1508                         if ($config{CXX}
1509                             && !grep { $_ eq $wopt } @{$config{cxxflags}});
1510                 }
1511         if (defined($predefined{__clang__}))
1512                 {
1513                 foreach $wopt (split /\s+/, $clang_devteam_warn)
1514                         {
1515                         push @{$config{cflags}}, $wopt
1516                                 unless grep { $_ eq $wopt } @{$config{cflags}};
1517                         push @{$config{cxxflags}}, $wopt
1518                                 if ($config{CXX}
1519                                     && !grep { $_ eq $wopt } @{$config{cxxflags}});
1520                         }
1521                 }
1522         }
1523
1524 unless ($disabled{"crypto-mdebug-backtrace"})
1525         {
1526         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1527                 {
1528                 push @{$config{cflags}}, $wopt
1529                         unless grep { $_ eq $wopt } @{$config{cflags}};
1530                 push @{$config{cxxflags}}, $wopt
1531                         if ($config{CXX}
1532                             && !grep { $_ eq $wopt } @{$config{cxxflags}});
1533                 }
1534         if ($target =~ /^BSD-/)
1535                 {
1536                 push @{$config{ex_libs}}, "-lexecinfo";
1537                 }
1538         }
1539
1540 unless ($disabled{afalgeng}) {
1541     $config{afalgeng}="";
1542     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1543         my $minver = 4*10000 + 1*100 + 0;
1544         if ($config{CROSS_COMPILE} eq "") {
1545             my $verstr = `uname -r`;
1546             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1547             ($mi2) = $mi2 =~ /(\d+)/;
1548             my $ver = $ma*10000 + $mi1*100 + $mi2;
1549             if ($ver < $minver) {
1550                 $disabled{afalgeng} = "too-old-kernel";
1551             } else {
1552                 push @{$config{engdirs}}, "afalg";
1553             }
1554         } else {
1555             $disabled{afalgeng} = "cross-compiling";
1556         }
1557     } else {
1558         $disabled{afalgeng}  = "not-linux";
1559     }
1560 }
1561
1562 push @{$config{openssl_feature_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1563
1564 # Finish up %config by appending things the user gave us on the command line
1565 # apart from "make variables"
1566 foreach (keys %useradd) {
1567     # The must all be lists, so we assert that here
1568     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1569         unless ref $useradd{$_} eq 'ARRAY';
1570
1571     if (defined $config{$_}) {
1572         push @{$config{$_}}, @{$useradd{$_}};
1573     } else {
1574         $config{$_} = [ @{$useradd{$_}} ];
1575     }
1576 }
1577
1578 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1579
1580 # If we use the unified build, collect information from build.info files
1581 my %unified_info = ();
1582
1583 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1584 if ($builder eq "unified") {
1585     use with_fallback qw(Text::Template);
1586
1587     sub cleandir {
1588         my $base = shift;
1589         my $dir = shift;
1590         my $relativeto = shift || ".";
1591
1592         $dir = catdir($base,$dir) unless isabsolute($dir);
1593
1594         # Make sure the directories we're building in exists
1595         mkpath($dir);
1596
1597         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1598         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1599         return $res;
1600     }
1601
1602     sub cleanfile {
1603         my $base = shift;
1604         my $file = shift;
1605         my $relativeto = shift || ".";
1606
1607         $file = catfile($base,$file) unless isabsolute($file);
1608
1609         my $d = dirname($file);
1610         my $f = basename($file);
1611
1612         # Make sure the directories we're building in exists
1613         mkpath($d);
1614
1615         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1616         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1617         return $res;
1618     }
1619
1620     # Store the name of the template file we will build the build file from
1621     # in %config.  This may be useful for the build file itself.
1622     my @build_file_template_names =
1623         ( $builder_platform."-".$target{build_file}.".tmpl",
1624           $target{build_file}.".tmpl" );
1625     my @build_file_templates = ();
1626
1627     # First, look in the user provided directory, if given
1628     if (defined env($local_config_envname)) {
1629         @build_file_templates =
1630             map {
1631                 if ($^O eq 'VMS') {
1632                     # VMS environment variables are logical names,
1633                     # which can be used as is
1634                     $local_config_envname . ':' . $_;
1635                 } else {
1636                     catfile(env($local_config_envname), $_);
1637                 }
1638             }
1639             @build_file_template_names;
1640     }
1641     # Then, look in our standard directory
1642     push @build_file_templates,
1643         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1644           @build_file_template_names );
1645
1646     my $build_file_template;
1647     for $_ (@build_file_templates) {
1648         $build_file_template = $_;
1649         last if -f $build_file_template;
1650
1651         $build_file_template = undef;
1652     }
1653     if (!defined $build_file_template) {
1654         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1655     }
1656     $config{build_file_templates}
1657       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1658                     $blddir),
1659           $build_file_template,
1660           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1661                     $blddir) ];
1662
1663     my @build_dirs = ( [ ] );   # current directory
1664
1665     $config{build_infos} = [ ];
1666
1667     my %ordinals = ();
1668     while (@build_dirs) {
1669         my @curd = @{shift @build_dirs};
1670         my $sourced = catdir($srcdir, @curd);
1671         my $buildd = catdir($blddir, @curd);
1672
1673         my $unixdir = join('/', @curd);
1674         if (exists $skipdir{$unixdir}) {
1675             my $what = $skipdir{$unixdir};
1676             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1677             next;
1678         }
1679
1680         mkpath($buildd);
1681
1682         my $f = 'build.info';
1683         # The basic things we're trying to build
1684         my @programs = ();
1685         my @programs_install = ();
1686         my @libraries = ();
1687         my @libraries_install = ();
1688         my @engines = ();
1689         my @engines_install = ();
1690         my @scripts = ();
1691         my @scripts_install = ();
1692         my @extra = ();
1693         my @overrides = ();
1694         my @intermediates = ();
1695         my @rawlines = ();
1696
1697         my %sources = ();
1698         my %shared_sources = ();
1699         my %includes = ();
1700         my %defines = ();
1701         my %depends = ();
1702         my %renames = ();
1703         my %sharednames = ();
1704         my %generate = ();
1705
1706         # We want to detect configdata.pm in the source tree, so we
1707         # don't use it if the build tree is different.
1708         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1709
1710         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1711         my $template =
1712             Text::Template->new(TYPE => 'FILE',
1713                                 SOURCE => catfile($sourced, $f),
1714                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1715         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1716         my @text =
1717             split /^/m,
1718             $template->fill_in(HASH => { config => \%config,
1719                                          target => \%target,
1720                                          disabled => \%disabled,
1721                                          withargs => \%withargs,
1722                                          builddir => abs2rel($buildd, $blddir),
1723                                          sourcedir => abs2rel($sourced, $blddir),
1724                                          buildtop => abs2rel($blddir, $blddir),
1725                                          sourcetop => abs2rel($srcdir, $blddir) },
1726                                DELIMITERS => [ "{-", "-}" ]);
1727
1728         # The top item of this stack has the following values
1729         # -2 positive already run and we found ELSE (following ELSIF should fail)
1730         # -1 positive already run (skip until ENDIF)
1731         # 0 negatives so far (if we're at a condition, check it)
1732         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1733         # 2 positive ELSE (following ELSIF should fail)
1734         my @skip = ();
1735         collect_information(
1736             collect_from_array([ @text ],
1737                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1738                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1739             # Info we're looking for
1740             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1741             => sub {
1742                 if (! @skip || $skip[$#skip] > 0) {
1743                     push @skip, !! $1;
1744                 } else {
1745                     push @skip, -1;
1746                 }
1747             },
1748             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1749             => sub { die "ELSIF out of scope" if ! @skip;
1750                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1751                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1752                      $skip[$#skip] = !! $1
1753                          if $skip[$#skip] == 0; },
1754             qr/^\s*ELSE\s*$/
1755             => sub { die "ELSE out of scope" if ! @skip;
1756                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1757                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1758             qr/^\s*ENDIF\s*$/
1759             => sub { die "ENDIF out of scope" if ! @skip;
1760                      pop @skip; },
1761             qr/^\s*SUBDIRS\s*=\s*(.*)\s*$/
1762             => sub {
1763                 if (!@skip || $skip[$#skip] > 0) {
1764                     foreach (tokenize($1)) {
1765                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1766                     }
1767                 }
1768             },
1769             qr/^\s*PROGRAMS(_NO_INST)?\s*=\s*(.*)\s*$/
1770             => sub {
1771                 if (!@skip || $skip[$#skip] > 0) {
1772                     my $install = $1;
1773                     my @x = tokenize($2);
1774                     push @programs, @x;
1775                     push @programs_install, @x unless $install;
1776                 }
1777             },
1778             qr/^\s*LIBS(_NO_INST)?\s*=\s*(.*)\s*$/
1779             => sub {
1780                 if (!@skip || $skip[$#skip] > 0) {
1781                     my $install = $1;
1782                     my @x = tokenize($2);
1783                     push @libraries, @x;
1784                     push @libraries_install, @x unless $install;
1785                 }
1786             },
1787             qr/^\s*ENGINES(_NO_INST)?\s*=\s*(.*)\s*$/
1788             => sub {
1789                 if (!@skip || $skip[$#skip] > 0) {
1790                     my $install = $1;
1791                     my @x = tokenize($2);
1792                     push @engines, @x;
1793                     push @engines_install, @x unless $install;
1794                 }
1795             },
1796             qr/^\s*SCRIPTS(_NO_INST)?\s*=\s*(.*)\s*$/
1797             => sub {
1798                 if (!@skip || $skip[$#skip] > 0) {
1799                     my $install = $1;
1800                     my @x = tokenize($2);
1801                     push @scripts, @x;
1802                     push @scripts_install, @x unless $install;
1803                 }
1804             },
1805             qr/^\s*EXTRA\s*=\s*(.*)\s*$/
1806             => sub { push @extra, tokenize($1)
1807                          if !@skip || $skip[$#skip] > 0 },
1808             qr/^\s*OVERRIDES\s*=\s*(.*)\s*$/
1809             => sub { push @overrides, tokenize($1)
1810                          if !@skip || $skip[$#skip] > 0 },
1811
1812             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1813             => sub { push @{$ordinals{$1}}, tokenize($2)
1814                          if !@skip || $skip[$#skip] > 0 },
1815             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1816             => sub { push @{$sources{$1}}, tokenize($2)
1817                          if !@skip || $skip[$#skip] > 0 },
1818             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1819             => sub { push @{$shared_sources{$1}}, tokenize($2)
1820                          if !@skip || $skip[$#skip] > 0 },
1821             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1822             => sub { push @{$includes{$1}}, tokenize($2)
1823                          if !@skip || $skip[$#skip] > 0 },
1824             qr/^\s*DEFINE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1825             => sub { push @{$defines{$1}}, tokenize($2)
1826                          if !@skip || $skip[$#skip] > 0 },
1827             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1828             => sub { push @{$depends{$1}}, tokenize($2)
1829                          if !@skip || $skip[$#skip] > 0 },
1830             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1831             => sub { push @{$generate{$1}}, $2
1832                          if !@skip || $skip[$#skip] > 0 },
1833             qr/^\s*RENAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1834             => sub { push @{$renames{$1}}, tokenize($2)
1835                          if !@skip || $skip[$#skip] > 0 },
1836             qr/^\s*SHARED_NAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1837             => sub { push @{$sharednames{$1}}, tokenize($2)
1838                          if !@skip || $skip[$#skip] > 0 },
1839             qr/^\s*BEGINRAW\[((?:\\.|[^\\\]])+)\]\s*$/
1840             => sub {
1841                 my $lineiterator = shift;
1842                 my $target_kind = $1;
1843                 while (defined $lineiterator->()) {
1844                     s|\R$||;
1845                     if (/^\s*ENDRAW\[((?:\\.|[^\\\]])+)\]\s*$/) {
1846                         die "ENDRAW doesn't match BEGINRAW"
1847                             if $1 ne $target_kind;
1848                         last;
1849                     }
1850                     next if @skip && $skip[$#skip] <= 0;
1851                     push @rawlines,  $_
1852                         if ($target_kind eq $target{build_file}
1853                             || $target_kind eq $target{build_file}."(".$builder_platform.")");
1854                 }
1855             },
1856             qr/^\s*(?:#.*)?$/ => sub { },
1857             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1858             "BEFORE" => sub {
1859                 if ($buildinfo_debug) {
1860                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1861                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1862                 }
1863             },
1864             "AFTER" => sub {
1865                 if ($buildinfo_debug) {
1866                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1867                 }
1868             },
1869             );
1870         die "runaway IF?" if (@skip);
1871
1872         foreach (keys %renames) {
1873             die "$_ renamed to more than one thing: "
1874                 ,join(" ", @{$renames{$_}}),"\n"
1875                 if scalar @{$renames{$_}} > 1;
1876             my $dest = cleanfile($buildd, $_, $blddir);
1877             my $to = cleanfile($buildd, $renames{$_}->[0], $blddir);
1878             die "$dest renamed to more than one thing: "
1879                 ,$unified_info{rename}->{$dest}, $to
1880                 unless !defined($unified_info{rename}->{$dest})
1881                 or $unified_info{rename}->{$dest} eq $to;
1882             $unified_info{rename}->{$dest} = $to;
1883         }
1884
1885         foreach (@programs) {
1886             my $program = cleanfile($buildd, $_, $blddir);
1887             if ($unified_info{rename}->{$program}) {
1888                 $program = $unified_info{rename}->{$program};
1889             }
1890             $unified_info{programs}->{$program} = 1;
1891         }
1892
1893         foreach (@programs_install) {
1894             my $program = cleanfile($buildd, $_, $blddir);
1895             if ($unified_info{rename}->{$program}) {
1896                 $program = $unified_info{rename}->{$program};
1897             }
1898             $unified_info{install}->{programs}->{$program} = 1;
1899         }
1900
1901         foreach (@libraries) {
1902             my $library = cleanfile($buildd, $_, $blddir);
1903             if ($unified_info{rename}->{$library}) {
1904                 $library = $unified_info{rename}->{$library};
1905             }
1906             $unified_info{libraries}->{$library} = 1;
1907         }
1908
1909         foreach (@libraries_install) {
1910             my $library = cleanfile($buildd, $_, $blddir);
1911             if ($unified_info{rename}->{$library}) {
1912                 $library = $unified_info{rename}->{$library};
1913             }
1914             $unified_info{install}->{libraries}->{$library} = 1;
1915         }
1916
1917         die <<"EOF" if scalar @engines and !$config{dynamic_engines};
1918 ENGINES can only be used if configured with 'dynamic-engine'.
1919 This is usually a fault in a build.info file.
1920 EOF
1921         foreach (@engines) {
1922             my $library = cleanfile($buildd, $_, $blddir);
1923             if ($unified_info{rename}->{$library}) {
1924                 $library = $unified_info{rename}->{$library};
1925             }
1926             $unified_info{engines}->{$library} = 1;
1927         }
1928
1929         foreach (@engines_install) {
1930             my $library = cleanfile($buildd, $_, $blddir);
1931             if ($unified_info{rename}->{$library}) {
1932                 $library = $unified_info{rename}->{$library};
1933             }
1934             $unified_info{install}->{engines}->{$library} = 1;
1935         }
1936
1937         foreach (@scripts) {
1938             my $script = cleanfile($buildd, $_, $blddir);
1939             if ($unified_info{rename}->{$script}) {
1940                 $script = $unified_info{rename}->{$script};
1941             }
1942             $unified_info{scripts}->{$script} = 1;
1943         }
1944
1945         foreach (@scripts_install) {
1946             my $script = cleanfile($buildd, $_, $blddir);
1947             if ($unified_info{rename}->{$script}) {
1948                 $script = $unified_info{rename}->{$script};
1949             }
1950             $unified_info{install}->{scripts}->{$script} = 1;
1951         }
1952
1953         foreach (@extra) {
1954             my $extra = cleanfile($buildd, $_, $blddir);
1955             $unified_info{extra}->{$extra} = 1;
1956         }
1957
1958         foreach (@overrides) {
1959             my $override = cleanfile($buildd, $_, $blddir);
1960             $unified_info{overrides}->{$override} = 1;
1961         }
1962
1963         push @{$unified_info{rawlines}}, @rawlines;
1964
1965         unless ($disabled{shared}) {
1966             # Check sharednames.
1967             foreach (keys %sharednames) {
1968                 my $dest = cleanfile($buildd, $_, $blddir);
1969                 if ($unified_info{rename}->{$dest}) {
1970                     $dest = $unified_info{rename}->{$dest};
1971                 }
1972                 die "shared_name for $dest with multiple values: "
1973                     ,join(" ", @{$sharednames{$_}}),"\n"
1974                     if scalar @{$sharednames{$_}} > 1;
1975                 my $to = cleanfile($buildd, $sharednames{$_}->[0], $blddir);
1976                 die "shared_name found for a library $dest that isn't defined\n"
1977                     unless $unified_info{libraries}->{$dest};
1978                 die "shared_name for $dest with multiple values: "
1979                     ,$unified_info{sharednames}->{$dest}, ", ", $to
1980                     unless !defined($unified_info{sharednames}->{$dest})
1981                     or $unified_info{sharednames}->{$dest} eq $to;
1982                 $unified_info{sharednames}->{$dest} = $to;
1983             }
1984
1985             # Additionally, we set up sharednames for libraries that don't
1986             # have any, as themselves.  Only for libraries that aren't
1987             # explicitly static.
1988             foreach (grep !/\.a$/, keys %{$unified_info{libraries}}) {
1989                 if (!defined $unified_info{sharednames}->{$_}) {
1990                     $unified_info{sharednames}->{$_} = $_
1991                 }
1992             }
1993
1994             # Check that we haven't defined any library as both shared and
1995             # explicitly static.  That is forbidden.
1996             my @doubles = ();
1997             foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
1998                 (my $l = $_) =~ s/\.a$//;
1999                 push @doubles, $l if defined $unified_info{sharednames}->{$l};
2000             }
2001             die "these libraries are both explicitly static and shared:\n  ",
2002                 join(" ", @doubles), "\n"
2003                 if @doubles;
2004         }
2005
2006         foreach (keys %sources) {
2007             my $dest = $_;
2008             my $ddest = cleanfile($buildd, $_, $blddir);
2009             if ($unified_info{rename}->{$ddest}) {
2010                 $ddest = $unified_info{rename}->{$ddest};
2011             }
2012             foreach (@{$sources{$dest}}) {
2013                 my $s = cleanfile($sourced, $_, $blddir);
2014
2015                 # If it isn't in the source tree, we assume it's generated
2016                 # in the build tree
2017                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2018                     $s = cleanfile($buildd, $_, $blddir);
2019                 }
2020                 # We recognise C++, C and asm files
2021                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2022                     my $o = $_;
2023                     $o =~ s/\.[csS]$/.o/; # C and assembler
2024                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2025                     $o = cleanfile($buildd, $o, $blddir);
2026                     $unified_info{sources}->{$ddest}->{$o} = -1;
2027                     $unified_info{sources}->{$o}->{$s} = -1;
2028                 } elsif ($s =~ /\.rc$/) {
2029                     # We also recognise resource files
2030                     my $o = $_;
2031                     $o =~ s/\.rc$/.res/; # Resource configuration
2032                     my $o = cleanfile($buildd, $o, $blddir);
2033                     $unified_info{sources}->{$ddest}->{$o} = -1;
2034                     $unified_info{sources}->{$o}->{$s} = -1;
2035                 } else {
2036                     $unified_info{sources}->{$ddest}->{$s} = 1;
2037                 }
2038             }
2039         }
2040
2041         foreach (keys %shared_sources) {
2042             my $dest = $_;
2043             my $ddest = cleanfile($buildd, $_, $blddir);
2044             if ($unified_info{rename}->{$ddest}) {
2045                 $ddest = $unified_info{rename}->{$ddest};
2046             }
2047             foreach (@{$shared_sources{$dest}}) {
2048                 my $s = cleanfile($sourced, $_, $blddir);
2049
2050                 # If it isn't in the source tree, we assume it's generated
2051                 # in the build tree
2052                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2053                     $s = cleanfile($buildd, $_, $blddir);
2054                 }
2055
2056                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2057                     # We recognise C++, C and asm files
2058                     my $o = $_;
2059                     $o =~ s/\.[csS]$/.o/; # C and assembler
2060                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2061                     $o = cleanfile($buildd, $o, $blddir);
2062                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2063                     $unified_info{sources}->{$o}->{$s} = -1;
2064                 } elsif ($s =~ /\.rc$/) {
2065                     # We also recognise resource files
2066                     my $o = $_;
2067                     $o =~ s/\.rc$/.res/; # Resource configuration
2068                     my $o = cleanfile($buildd, $o, $blddir);
2069                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2070                     $unified_info{sources}->{$o}->{$s} = -1;
2071                 } elsif ($s =~ /\.ld$/) {
2072                     # We also recognise linker scripts (or corresponding)
2073                     # We know they are generated files
2074                     my $ld = cleanfile($buildd, $_, $blddir);
2075                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2076                 } else {
2077                     die "unrecognised source file type for shared library: $s\n";
2078                 }
2079             }
2080         }
2081
2082         foreach (keys %generate) {
2083             my $dest = $_;
2084             my $ddest = cleanfile($buildd, $_, $blddir);
2085             if ($unified_info{rename}->{$ddest}) {
2086                 $ddest = $unified_info{rename}->{$ddest};
2087             }
2088             die "more than one generator for $dest: "
2089                     ,join(" ", @{$generate{$_}}),"\n"
2090                     if scalar @{$generate{$_}} > 1;
2091             my @generator = split /\s+/, $generate{$dest}->[0];
2092             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2093             $unified_info{generate}->{$ddest} = [ @generator ];
2094         }
2095
2096         foreach (keys %depends) {
2097             my $dest = $_;
2098             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2099
2100             # If the destination doesn't exist in source, it can only be
2101             # a generated file in the build tree.
2102             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2103                 $ddest = cleanfile($buildd, $_, $blddir);
2104                 if ($unified_info{rename}->{$ddest}) {
2105                     $ddest = $unified_info{rename}->{$ddest};
2106                 }
2107             }
2108             foreach (@{$depends{$dest}}) {
2109                 my $d = cleanfile($sourced, $_, $blddir);
2110
2111                 # If we know it's generated, or assume it is because we can't
2112                 # find it in the source tree, we set file we depend on to be
2113                 # in the build tree rather than the source tree, and assume
2114                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2115                 # section or in the Makefile template.
2116                 if ($d eq $src_configdata
2117                     || ! -f $d
2118                     || (grep { $d eq $_ }
2119                         map { cleanfile($srcdir, $_, $blddir) }
2120                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2121                     $d = cleanfile($buildd, $_, $blddir);
2122                 }
2123                 # Take note if the file to depend on is being renamed
2124                 # Take extra care with files ending with .a, they should
2125                 # be treated without that extension, and the extension
2126                 # should be added back after treatment.
2127                 $d =~ /(\.a)?$/;
2128                 my $e = $1 // "";
2129                 $d = $`;
2130                 if ($unified_info{rename}->{$d}) {
2131                     $d = $unified_info{rename}->{$d};
2132                 }
2133                 $d .= $e;
2134                 $unified_info{depends}->{$ddest}->{$d} = 1;
2135             }
2136         }
2137
2138         foreach (keys %includes) {
2139             my $dest = $_;
2140             my $ddest = cleanfile($sourced, $_, $blddir);
2141
2142             # If the destination doesn't exist in source, it can only be
2143             # a generated file in the build tree.
2144             if ($ddest eq $src_configdata || ! -f $ddest) {
2145                 $ddest = cleanfile($buildd, $_, $blddir);
2146                 if ($unified_info{rename}->{$ddest}) {
2147                     $ddest = $unified_info{rename}->{$ddest};
2148                 }
2149             }
2150             foreach (@{$includes{$dest}}) {
2151                 my $is = cleandir($sourced, $_, $blddir);
2152                 my $ib = cleandir($buildd, $_, $blddir);
2153                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2154                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2155                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2156                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2157             }
2158         }
2159
2160         foreach (keys %defines) {
2161             my $dest = $_;
2162             my $ddest = cleanfile($sourced, $_, $blddir);
2163
2164             # If the destination doesn't exist in source, it can only be
2165             # a generated file in the build tree.
2166             if (! -f $ddest) {
2167                 $ddest = cleanfile($buildd, $_, $blddir);
2168                 if ($unified_info{rename}->{$ddest}) {
2169                     $ddest = $unified_info{rename}->{$ddest};
2170                 }
2171             }
2172             foreach (@{$defines{$dest}}) {
2173                 m|^([^=]*)(=.*)?$|;
2174                 die "0 length macro name not permitted\n" if $1 eq "";
2175                 die "$1 defined more than once\n"
2176                     if defined $unified_info{defines}->{$ddest}->{$1};
2177                 $unified_info{defines}->{$ddest}->{$1} = $2;
2178             }
2179         }
2180     }
2181
2182     my $ordinals_text = join(', ', sort keys %ordinals);
2183     warn <<"EOF" if $ordinals_text;
2184
2185 WARNING: ORDINALS were specified for $ordinals_text
2186 They are ignored and should be replaced with a combination of GENERATE,
2187 DEPEND and SHARED_SOURCE.
2188 EOF
2189
2190     # Massage the result
2191
2192     # If we depend on a header file or a perl module, add an inclusion of
2193     # its directory to allow smoothe inclusion
2194     foreach my $dest (keys %{$unified_info{depends}}) {
2195         next if $dest eq "";
2196         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2197             next unless $d =~ /\.(h|pm)$/;
2198             my $i = dirname($d);
2199             my $spot =
2200                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2201                 ? 'build' : 'source';
2202             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2203                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2204         }
2205     }
2206
2207     # Go through all intermediary files and change their names to something that
2208     # reflects what they will be built for.  Note that for some source files,
2209     # this leads to duplicate object files because they are used multiple times.
2210     # the goal is to rename all object files according to this scheme:
2211     #    {productname}-{midfix}-{origobjname}.[o|res]
2212     # the {midfix} is a keyword indicating the type of product, which is mostly
2213     # valuable for libraries since they come in two forms.
2214     #
2215     # This also reorganises the {sources} and {shared_sources} so that the
2216     # former only contains ALL object files that are supposed to end up in
2217     # static libraries and programs, while the latter contains ALL object files
2218     # that are supposed to end up in shared libraries and DSOs.
2219     # The main reason for having two different source structures is to allow
2220     # the same name to be used for the static and the shared variants of a
2221     # library.
2222     {
2223         # Take copies so we don't get interference from added stuff
2224         my %unified_copy = ();
2225         foreach (('sources', 'shared_sources')) {
2226             $unified_copy{$_} = { %{$unified_info{$_}} }
2227                 if defined($unified_info{$_});
2228             delete $unified_info{$_};
2229         }
2230         foreach my $prodtype (('programs', 'libraries', 'engines', 'scripts')) {
2231             # $intent serves multi purposes:
2232             # - give a prefix for the new object files names
2233             # - in the case of libraries, rearrange the object files so static
2234             #   libraries use the 'sources' structure exclusively, while shared
2235             #   libraries use the 'shared_sources' structure exclusively.
2236             my $intent = {
2237                 programs  => { bin    => { src => [ 'sources' ],
2238                                            dst => 'sources' } },
2239                 libraries => { lib    => { src => [ 'sources' ],
2240                                            dst => 'sources' },
2241                                shlib  => { prodselect =>
2242                                                sub { grep !/\.a$/, @_ },
2243                                            src => [ 'sources',
2244                                                     'shared_sources' ],
2245                                            dst => 'shared_sources' } },
2246                 engines   => { dso    => { src => [ 'sources',
2247                                                     'shared_sources' ],
2248                                            dst => 'shared_sources' } },
2249                 scripts   => { script => { src => [ 'sources' ],
2250                                            dst => 'sources' } }
2251                } -> {$prodtype};
2252             foreach my $kind (keys %$intent) {
2253                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2254                              && $disabled{shared});
2255
2256                 my @src = @{$intent->{$kind}->{src}};
2257                 my $dst = $intent->{$kind}->{dst};
2258                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2259                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2260                     # %prod_sources has all applicable objects as keys, and
2261                     # their corresponding sources as values
2262                     my %prod_sources =
2263                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2264                         map { keys %{$unified_copy{$_}->{$prod}} }
2265                         @src;
2266                     foreach (keys %prod_sources) {
2267                         # Only affect object files and resource files,
2268                         # the others simply get a new value
2269                         # (+1 instead of -1)
2270                         if ($_ =~ /\.(o|res)$/) {
2271                             (my $prodname = $prod) =~ s|\.a$||;
2272                             my $newobj =
2273                                 catfile(dirname($_),
2274                                         basename($prodname)
2275                                             . '-' . $kind
2276                                             . '-' . basename($_));
2277                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2278                             foreach my $src (@{$prod_sources{$_}}) {
2279                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2280                             }
2281                             # Adjust dependencies
2282                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2283                                 $unified_info{depends}->{$_}->{$deps} = -1;
2284                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2285                             }
2286                             # Adjust includes
2287                             foreach my $k (('source', 'build')) {
2288                                 next unless
2289                                     defined($unified_info{includes}->{$_}->{$k});
2290                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2291                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2292                             }
2293                         } else {
2294                             $unified_info{$dst}->{$prod}->{$_} = 1;
2295                         }
2296                     }
2297                 }
2298             }
2299         }
2300     }
2301     # At this point, we have a number of sources with the value -1.  They
2302     # aren't part of the local build and are probably meant for a different
2303     # platform, and can therefore be cleaned away.  That happens when making
2304     # %unified_info more efficient below.
2305
2306     ### Make unified_info a bit more efficient
2307     # One level structures
2308     foreach (("programs", "libraries", "engines", "scripts", "extra", "overrides")) {
2309         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2310     }
2311     # Two level structures
2312     foreach my $l1 (("install", "sources", "shared_sources", "ldadd", "depends")) {
2313         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2314             my @items =
2315                 sort
2316                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2317                 keys %{$unified_info{$l1}->{$l2}};
2318             if (@items) {
2319                 $unified_info{$l1}->{$l2} = [ @items ];
2320             } else {
2321                 delete $unified_info{$l1}->{$l2};
2322             }
2323         }
2324     }
2325     # Defines
2326     foreach my $dest (sort keys %{$unified_info{defines}}) {
2327         $unified_info{defines}->{$dest}
2328             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2329                 sort keys %{$unified_info{defines}->{$dest}} ];
2330     }
2331     # Includes
2332     foreach my $dest (sort keys %{$unified_info{includes}}) {
2333         if (defined($unified_info{includes}->{$dest}->{build})) {
2334             my @source_includes = ();
2335             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2336                 if defined($unified_info{includes}->{$dest}->{source});
2337             $unified_info{includes}->{$dest} =
2338                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2339             foreach my $inc (@source_includes) {
2340                 push @{$unified_info{includes}->{$dest}}, $inc
2341                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2342             }
2343         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2344             $unified_info{includes}->{$dest} =
2345                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2346         } else {
2347             delete $unified_info{includes}->{$dest};
2348         }
2349     }
2350
2351     # For convenience collect information regarding directories where
2352     # files are generated, those generated files and the end product
2353     # they end up in where applicable.  Then, add build rules for those
2354     # directories
2355     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2356                      "dso" => [ @{$unified_info{engines}} ],
2357                      "bin" => [ @{$unified_info{programs}} ],
2358                      "script" => [ @{$unified_info{scripts}} ] );
2359     foreach my $type (keys %loopinfo) {
2360         foreach my $product (@{$loopinfo{$type}}) {
2361             my %dirs = ();
2362             my $pd = dirname($product);
2363
2364             foreach (@{$unified_info{sources}->{$product} // []},
2365                      @{$unified_info{shared_sources}->{$product} // []}) {
2366                 my $d = dirname($_);
2367
2368                 # We don't want to create targets for source directories
2369                 # when building out of source
2370                 next if ($config{sourcedir} ne $config{builddir}
2371                              && $d =~ m|^\Q$config{sourcedir}\E|);
2372                 # We already have a "test" target, and the current directory
2373                 # is just silly to make a target for
2374                 next if $d eq "test" || $d eq ".";
2375
2376                 $dirs{$d} = 1;
2377                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2378                     if $d ne $pd;
2379             }
2380             foreach (keys %dirs) {
2381                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2382                     $product;
2383             }
2384         }
2385     }
2386 }
2387
2388 # For the schemes that need it, we provide the old *_obj configs
2389 # from the *_asm_obj ones
2390 foreach (grep /_(asm|aux)_src$/, keys %target) {
2391     my $src = $_;
2392     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2393     $target{$obj} = $target{$src};
2394     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2395     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2396 }
2397
2398 # Write down our configuration where it fits #########################
2399
2400 print "Creating configdata.pm\n";
2401 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2402 print OUT <<"EOF";
2403 #! $config{HASHBANGPERL}
2404
2405 package configdata;
2406
2407 use strict;
2408 use warnings;
2409
2410 use Exporter;
2411 #use vars qw(\@ISA \@EXPORT);
2412 our \@ISA = qw(Exporter);
2413 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables);
2414
2415 EOF
2416 print OUT "our %config = (\n";
2417 foreach (sort keys %config) {
2418     if (ref($config{$_}) eq "ARRAY") {
2419         print OUT "  ", $_, " => [ ", join(", ",
2420                                            map { quotify("perl", $_) }
2421                                            @{$config{$_}}), " ],\n";
2422     } elsif (ref($config{$_}) eq "HASH") {
2423         print OUT "  ", $_, " => {";
2424         if (scalar keys %{$config{$_}} > 0) {
2425             print OUT "\n";
2426             foreach my $key (sort keys %{$config{$_}}) {
2427                 print OUT "      ",
2428                     join(" => ",
2429                          quotify("perl", $key),
2430                          defined $config{$_}->{$key}
2431                              ? quotify("perl", $config{$_}->{$key})
2432                              : "undef");
2433                 print OUT ",\n";
2434             }
2435             print OUT "  ";
2436         }
2437         print OUT "},\n";
2438     } else {
2439         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2440     }
2441 }
2442 print OUT <<"EOF";
2443 );
2444
2445 EOF
2446 print OUT "our %target = (\n";
2447 foreach (sort keys %target) {
2448     if (ref($target{$_}) eq "ARRAY") {
2449         print OUT "  ", $_, " => [ ", join(", ",
2450                                            map { quotify("perl", $_) }
2451                                            @{$target{$_}}), " ],\n";
2452     } else {
2453         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2454     }
2455 }
2456 print OUT <<"EOF";
2457 );
2458
2459 EOF
2460 print OUT "our \%available_protocols = (\n";
2461 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2462 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2463 print OUT <<"EOF";
2464 );
2465
2466 EOF
2467 print OUT "our \@disablables = (\n";
2468 foreach (@disablables) {
2469     print OUT "  ", quotify("perl", $_), ",\n";
2470 }
2471 print OUT <<"EOF";
2472 );
2473
2474 EOF
2475 print OUT "our \%disabled = (\n";
2476 foreach (sort keys %disabled) {
2477     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2478 }
2479 print OUT <<"EOF";
2480 );
2481
2482 EOF
2483 print OUT "our %withargs = (\n";
2484 foreach (sort keys %withargs) {
2485     if (ref($withargs{$_}) eq "ARRAY") {
2486         print OUT "  ", $_, " => [ ", join(", ",
2487                                            map { quotify("perl", $_) }
2488                                            @{$withargs{$_}}), " ],\n";
2489     } else {
2490         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2491     }
2492 }
2493 print OUT <<"EOF";
2494 );
2495
2496 EOF
2497 if ($builder eq "unified") {
2498     my $recurse;
2499     $recurse = sub {
2500         my $indent = shift;
2501         foreach (@_) {
2502             if (ref $_ eq "ARRAY") {
2503                 print OUT " "x$indent, "[\n";
2504                 foreach (@$_) {
2505                     $recurse->($indent + 4, $_);
2506                 }
2507                 print OUT " "x$indent, "],\n";
2508             } elsif (ref $_ eq "HASH") {
2509                 my %h = %$_;
2510                 print OUT " "x$indent, "{\n";
2511                 foreach (sort keys %h) {
2512                     if (ref $h{$_} eq "") {
2513                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2514                     } else {
2515                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2516                         $recurse->($indent + 8, $h{$_});
2517                     }
2518                 }
2519                 print OUT " "x$indent, "},\n";
2520             } else {
2521                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2522             }
2523         }
2524     };
2525     print OUT "our %unified_info = (\n";
2526     foreach (sort keys %unified_info) {
2527         if (ref $unified_info{$_} eq "") {
2528             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2529         } else {
2530             print OUT " "x4, quotify("perl", $_), " =>\n";
2531             $recurse->(8, $unified_info{$_});
2532         }
2533     }
2534     print OUT <<"EOF";
2535 );
2536
2537 EOF
2538 }
2539 print OUT
2540     "# The following data is only used when this files is use as a script\n";
2541 print OUT "my \@makevars = (\n";
2542 foreach (sort keys %user) {
2543     print OUT "    '",$_,"',\n";
2544 }
2545 print OUT ");\n";
2546 print OUT "my \%disabled_info = (\n";
2547 foreach my $what (sort keys %disabled_info) {
2548     print OUT "    '$what' => {\n";
2549     foreach my $info (sort keys %{$disabled_info{$what}}) {
2550         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2551             print OUT "        $info => [ ",
2552                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2553                 " ],\n";
2554         } else {
2555             print OUT "        $info => '", $disabled_info{$what}->{$info},
2556                 "',\n";
2557         }
2558     }
2559     print OUT "    },\n";
2560 }
2561 print OUT ");\n";
2562 print OUT 'my @user_crossable = qw( ', join (' ', @user_crossable), " );\n";
2563 print OUT << 'EOF';
2564 # If run directly, we can give some answers, and even reconfigure
2565 unless (caller) {
2566     use Getopt::Long;
2567     use File::Spec::Functions;
2568     use File::Basename;
2569     use Pod::Usage;
2570
2571     my $here = dirname($0);
2572
2573     my $dump = undef;
2574     my $cmdline = undef;
2575     my $options = undef;
2576     my $target = undef;
2577     my $envvars = undef;
2578     my $makevars = undef;
2579     my $buildparams = undef;
2580     my $reconf = undef;
2581     my $verbose = undef;
2582     my $help = undef;
2583     my $man = undef;
2584     GetOptions('dump|d'                 => \$dump,
2585                'command-line|c'         => \$cmdline,
2586                'options|o'              => \$options,
2587                'target|t'               => \$target,
2588                'environment|e'          => \$envvars,
2589                'make-variables|m'       => \$makevars,
2590                'build-parameters|b'     => \$buildparams,
2591                'reconfigure|reconf|r'   => \$reconf,
2592                'verbose|v'              => \$verbose,
2593                'help'                   => \$help,
2594                'man'                    => \$man)
2595         or die "Errors in command line arguments\n";
2596
2597     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2598             || $buildparams || $reconf || $verbose || $help || $man) {
2599         print STDERR <<"_____";
2600 You must give at least one option.
2601 For more information, do '$0 --help'
2602 _____
2603         exit(2);
2604     }
2605
2606     if ($help) {
2607         pod2usage(-exitval => 0,
2608                   -verbose => 1);
2609     }
2610     if ($man) {
2611         pod2usage(-exitval => 0,
2612                   -verbose => 2);
2613     }
2614     if ($dump || $cmdline) {
2615         print "\nCommand line (with current working directory = $here):\n\n";
2616         print '    ',join(' ',
2617                           $config{PERL},
2618                           catfile($config{sourcedir}, 'Configure'),
2619                           @{$config{perlargv}}), "\n";
2620         print "\nPerl information:\n\n";
2621         print '    ',$config{perl_cmd},"\n";
2622         print '    ',$config{perl_version},' for ',$config{perl_archname},"\n";
2623     }
2624     if ($dump || $options) {
2625         my $longest = 0;
2626         my $longest2 = 0;
2627         foreach my $what (@disablables) {
2628             $longest = length($what) if $longest < length($what);
2629             $longest2 = length($disabled{$what})
2630                 if $disabled{$what} && $longest2 < length($disabled{$what});
2631         }
2632         print "\nEnabled features:\n\n";
2633         foreach my $what (@disablables) {
2634             print "    $what\n" unless $disabled{$what};
2635         }
2636         print "\nDisabled features:\n\n";
2637         foreach my $what (@disablables) {
2638             if ($disabled{$what}) {
2639                 print "    $what", ' ' x ($longest - length($what) + 1),
2640                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2641                 print $disabled_info{$what}->{macro}
2642                     if $disabled_info{$what}->{macro};
2643                 print ' (skip ',
2644                     join(', ', @{$disabled_info{$what}->{skipped}}),
2645                     ')'
2646                     if $disabled_info{$what}->{skipped};
2647                 print "\n";
2648             }
2649         }
2650     }
2651     if ($dump || $target) {
2652         print "\nConfig target attributes:\n\n";
2653         foreach (sort keys %target) {
2654             next if $_ =~ m|^_| || $_ eq 'template';
2655             my $quotify = sub {
2656                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2657             };
2658             print '    ', $_, ' => ';
2659             if (ref($target{$_}) eq "ARRAY") {
2660                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2661             } else {
2662                 print $quotify->($target{$_}), ",\n"
2663             }
2664         }
2665     }
2666     if ($dump || $envvars) {
2667         print "\nRecorded environment:\n\n";
2668         foreach (sort keys %{$config{perlenv}}) {
2669             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2670         }
2671     }
2672     if ($dump || $makevars) {
2673         print "\nMakevars:\n\n";
2674         foreach my $var (@makevars) {
2675             my $prefix = '';
2676             $prefix = $config{CROSS_COMPILE}
2677                 if grep { $var eq $_ } @user_crossable;
2678             $prefix //= '';
2679             print '    ',$var,' ' x (16 - length $var),'= ',
2680                 (ref $config{$var} eq 'ARRAY'
2681                  ? join(' ', @{$config{$var}})
2682                  : $prefix.$config{$var}),
2683                 "\n"
2684                 if defined $config{$var};
2685         }
2686
2687         my @buildfile = ($config{builddir}, $config{build_file});
2688         unshift @buildfile, $here
2689             unless file_name_is_absolute($config{builddir});
2690         my $buildfile = canonpath(catdir(@buildfile));
2691         print <<"_____";
2692
2693 NOTE: These variables only represent the configuration view.  The build file
2694 template may have processed these variables further, please have a look at the
2695 build file for more exact data:
2696     $buildfile
2697 _____
2698     }
2699     if ($dump || $buildparams) {
2700         my @buildfile = ($config{builddir}, $config{build_file});
2701         unshift @buildfile, $here
2702             unless file_name_is_absolute($config{builddir});
2703         print "\nbuild file:\n\n";
2704         print "    ", canonpath(catfile(@buildfile)),"\n";
2705
2706         print "\nbuild file templates:\n\n";
2707         foreach (@{$config{build_file_templates}}) {
2708             my @tmpl = ($_);
2709             unshift @tmpl, $here
2710                 unless file_name_is_absolute($config{sourcedir});
2711             print '    ',canonpath(catfile(@tmpl)),"\n";
2712         }
2713     }
2714     if ($reconf) {
2715         if ($verbose) {
2716             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2717             foreach (sort keys %{$config{perlenv}}) {
2718                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2719             }
2720         }
2721
2722         chdir $here;
2723         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2724     }
2725 }
2726
2727 1;
2728
2729 __END__
2730
2731 =head1 NAME
2732
2733 configdata.pm - configuration data for OpenSSL builds
2734
2735 =head1 SYNOPSIS
2736
2737 Interactive:
2738
2739   perl configdata.pm [options]
2740
2741 As data bank module:
2742
2743   use configdata;
2744
2745 =head1 DESCRIPTION
2746
2747 This module can be used in two modes, interactively and as a module containing
2748 all the data recorded by OpenSSL's Configure script.
2749
2750 When used interactively, simply run it as any perl script, with at least one
2751 option, and you will get the information you ask for.  See L</OPTIONS> below.
2752
2753 When loaded as a module, you get a few databanks with useful information to
2754 perform build related tasks.  The databanks are:
2755
2756     %config             Configured things.
2757     %target             The OpenSSL config target with all inheritances
2758                         resolved.
2759     %disabled           The features that are disabled.
2760     @disablables        The list of features that can be disabled.
2761     %withargs           All data given through --with-THING options.
2762     %unified_info       All information that was computed from the build.info
2763                         files.
2764
2765 =head1 OPTIONS
2766
2767 =over 4
2768
2769 =item B<--help>
2770
2771 Print a brief help message and exit.
2772
2773 =item B<--man>
2774
2775 Print the manual page and exit.
2776
2777 =item B<--dump> | B<-d>
2778
2779 Print all relevant configuration data.  This is equivalent to B<--command-line>
2780 B<--options> B<--target> B<--environment> B<--make-variables>
2781 B<--build-parameters>.
2782
2783 =item B<--command-line> | B<-c>
2784
2785 Print the current configuration command line.
2786
2787 =item B<--options> | B<-o>
2788
2789 Print the features, both enabled and disabled, and display defined macro and
2790 skipped directories where applicable.
2791
2792 =item B<--target> | B<-t>
2793
2794 Print the config attributes for this config target.
2795
2796 =item B<--environment> | B<-e>
2797
2798 Print the environment variables and their values at the time of configuration.
2799
2800 =item B<--make-variables> | B<-m>
2801
2802 Print the main make variables generated in the current configuration
2803
2804 =item B<--build-parameters> | B<-b>
2805
2806 Print the build parameters, i.e. build file and build file templates.
2807
2808 =item B<--reconfigure> | B<--reconf> | B<-r>
2809
2810 Redo the configuration.
2811
2812 =item B<--verbose> | B<-v>
2813
2814 Verbose output.
2815
2816 =back
2817
2818 =cut
2819
2820 EOF
2821 close(OUT);
2822 if ($builder_platform eq 'unix') {
2823     my $mode = (0755 & ~umask);
2824     chmod $mode, 'configdata.pm'
2825         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2826 }
2827
2828 my %builders = (
2829     unified => sub {
2830         print 'Creating ',$target{build_file},"\n";
2831         run_dofile(catfile($blddir, $target{build_file}),
2832                    @{$config{build_file_templates}});
2833     },
2834     );
2835
2836 $builders{$builder}->($builder_platform, @builder_opts);
2837
2838 $SIG{__DIE__} = $orig_death_handler;
2839
2840 print <<"EOF" if ($disabled{threads} eq "unavailable");
2841
2842 The library could not be configured for supporting multi-threaded
2843 applications as the compiler options required on this system are not known.
2844 See file INSTALL for details if you need multi-threading.
2845 EOF
2846
2847 print <<"EOF" if ($no_shared_warn);
2848
2849 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2850 platform, so we will pretend you gave the option 'no-pic', which also disables
2851 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2852 or position independent code, please let us know (but please first make sure
2853 you have tried with a current version of OpenSSL).
2854 EOF
2855
2856 print <<"EOF";
2857
2858 **********************************************************************
2859 ***                                                                ***
2860 ***   OpenSSL has been successfully configured                     ***
2861 ***                                                                ***
2862 ***   If you encounter a problem while building, please open an    ***
2863 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2864 ***   and include the output from the following command:           ***
2865 ***                                                                ***
2866 ***       perl configdata.pm --dump                                ***
2867 ***                                                                ***
2868 ***   (If you are new to OpenSSL, you might want to consult the    ***
2869 ***   'Troubleshooting' section in the INSTALL file first)         ***
2870 ***                                                                ***
2871 **********************************************************************
2872 EOF
2873
2874 exit(0);
2875
2876 ######################################################################
2877 #
2878 # Helpers and utility functions
2879 #
2880
2881 # Death handler, to print a helpful message in case of failure #######
2882 #
2883 sub death_handler {
2884     die @_ if $^S;              # To prevent the added message in eval blocks
2885     my $build_file = $target{build_file} // "build file";
2886     my @message = ( <<"_____", @_ );
2887
2888 Failure!  $build_file wasn't produced.
2889 Please read INSTALL and associated NOTES files.  You may also have to look over
2890 your available compiler tool chain or change your configuration.
2891
2892 _____
2893
2894     # Dying is terminal, so it's ok to reset the signal handler here.
2895     $SIG{__DIE__} = $orig_death_handler;
2896     die @message;
2897 }
2898
2899 # Configuration file reading #########################################
2900
2901 # Note: All of the helper functions are for lazy evaluation.  They all
2902 # return a CODE ref, which will return the intended value when evaluated.
2903 # Thus, whenever there's mention of a returned value, it's about that
2904 # intended value.
2905
2906 # Helper function to implement conditional inheritance depending on the
2907 # value of $disabled{asm}.  Used in inherit_from values as follows:
2908 #
2909 #      inherit_from => [ "template", asm("asm_tmpl") ]
2910 #
2911 sub asm {
2912     my @x = @_;
2913     sub {
2914         $disabled{asm} ? () : @x;
2915     }
2916 }
2917
2918 # Helper function to implement conditional value variants, with a default
2919 # plus additional values based on the value of $config{build_type}.
2920 # Arguments are given in hash table form:
2921 #
2922 #       picker(default => "Basic string: ",
2923 #              debug   => "debug",
2924 #              release => "release")
2925 #
2926 # When configuring with --debug, the resulting string will be
2927 # "Basic string: debug", and when not, it will be "Basic string: release"
2928 #
2929 # This can be used to create variants of sets of flags according to the
2930 # build type:
2931 #
2932 #       cflags => picker(default => "-Wall",
2933 #                        debug   => "-g -O0",
2934 #                        release => "-O3")
2935 #
2936 sub picker {
2937     my %opts = @_;
2938     return sub { add($opts{default} || (),
2939                      $opts{$config{build_type}} || ())->(); }
2940 }
2941
2942 # Helper function to combine several values of different types into one.
2943 # This is useful if you want to combine a string with the result of a
2944 # lazy function, such as:
2945 #
2946 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2947 #
2948 sub combine {
2949     my @stuff = @_;
2950     return sub { add(@stuff)->(); }
2951 }
2952
2953 # Helper function to implement conditional values depending on the value
2954 # of $disabled{threads}.  Can be used as follows:
2955 #
2956 #       cflags => combine("-Wall", threads("-pthread"))
2957 #
2958 sub threads {
2959     my @flags = @_;
2960     return sub { add($disabled{threads} ? () : @flags)->(); }
2961 }
2962
2963 sub shared {
2964     my @flags = @_;
2965     return sub { add($disabled{shared} ? () : @flags)->(); }
2966 }
2967
2968 our $add_called = 0;
2969 # Helper function to implement adding values to already existing configuration
2970 # values.  It handles elements that are ARRAYs, CODEs and scalars
2971 sub _add {
2972     my $separator = shift;
2973
2974     # If there's any ARRAY in the collection of values OR the separator
2975     # is undef, we will return an ARRAY of combined values, otherwise a
2976     # string of joined values with $separator as the separator.
2977     my $found_array = !defined($separator);
2978
2979     my @values =
2980         map {
2981             my $res = $_;
2982             while (ref($res) eq "CODE") {
2983                 $res = $res->();
2984             }
2985             if (defined($res)) {
2986                 if (ref($res) eq "ARRAY") {
2987                     $found_array = 1;
2988                     @$res;
2989                 } else {
2990                     $res;
2991                 }
2992             } else {
2993                 ();
2994             }
2995     } (@_);
2996
2997     $add_called = 1;
2998
2999     if ($found_array) {
3000         [ @values ];
3001     } else {
3002         join($separator, grep { defined($_) && $_ ne "" } @values);
3003     }
3004 }
3005 sub add_before {
3006     my $separator = " ";
3007     if (ref($_[$#_]) eq "HASH") {
3008         my $opts = pop;
3009         $separator = $opts->{separator};
3010     }
3011     my @x = @_;
3012     sub { _add($separator, @x, @_) };
3013 }
3014 sub add {
3015     my $separator = " ";
3016     if (ref($_[$#_]) eq "HASH") {
3017         my $opts = pop;
3018         $separator = $opts->{separator};
3019     }
3020     my @x = @_;
3021     sub { _add($separator, @_, @x) };
3022 }
3023
3024 sub read_eval_file {
3025     my $fname = shift;
3026     my $content;
3027     my @result;
3028
3029     open F, "< $fname" or die "Can't open '$fname': $!\n";
3030     {
3031         undef local $/;
3032         $content = <F>;
3033     }
3034     close F;
3035     {
3036         local $@;
3037
3038         @result = ( eval $content );
3039         warn $@ if $@;
3040     }
3041     return wantarray ? @result : $result[0];
3042 }
3043
3044 # configuration reader, evaluates the input file as a perl script and expects
3045 # it to fill %targets with target configurations.  Those are then added to
3046 # %table.
3047 sub read_config {
3048     my $fname = shift;
3049     my %targets;
3050
3051     {
3052         # Protect certain tables from tampering
3053         local %table = ();
3054
3055         %targets = read_eval_file($fname);
3056     }
3057     my %preexisting = ();
3058     foreach (sort keys %targets) {
3059         $preexisting{$_} = 1 if $table{$_};
3060     }
3061     die <<"EOF",
3062 The following config targets from $fname
3063 shadow pre-existing config targets with the same name:
3064 EOF
3065         map { "  $_\n" } sort keys %preexisting
3066         if %preexisting;
3067
3068
3069     # For each target, check that it's configured with a hash table.
3070     foreach (keys %targets) {
3071         if (ref($targets{$_}) ne "HASH") {
3072             if (ref($targets{$_}) eq "") {
3073                 warn "Deprecated target configuration for $_, ignoring...\n";
3074             } else {
3075                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3076             }
3077             delete $targets{$_};
3078         } else {
3079             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3080         }
3081     }
3082
3083     %table = (%table, %targets);
3084
3085 }
3086
3087 # configuration resolver.  Will only resolve all the lazy evaluation
3088 # codeblocks for the chosen target and all those it inherits from,
3089 # recursively
3090 sub resolve_config {
3091     my $target = shift;
3092     my @breadcrumbs = @_;
3093
3094 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3095
3096     if (grep { $_ eq $target } @breadcrumbs) {
3097         die "inherit_from loop!  target backtrace:\n  "
3098             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3099     }
3100
3101     if (!defined($table{$target})) {
3102         warn "Warning! target $target doesn't exist!\n";
3103         return ();
3104     }
3105     # Recurse through all inheritances.  They will be resolved on the
3106     # fly, so when this operation is done, they will all just be a
3107     # bunch of attributes with string values.
3108     # What we get here, though, are keys with references to lists of
3109     # the combined values of them all.  We will deal with lists after
3110     # this stage is done.
3111     my %combined_inheritance = ();
3112     if ($table{$target}->{inherit_from}) {
3113         my @inherit_from =
3114             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3115         foreach (@inherit_from) {
3116             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3117
3118             # 'template' is a marker that's considered private to
3119             # the config that had it.
3120             delete $inherited_config{template};
3121
3122             foreach (keys %inherited_config) {
3123                 if (!$combined_inheritance{$_}) {
3124                     $combined_inheritance{$_} = [];
3125                 }
3126                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3127             }
3128         }
3129     }
3130
3131     # We won't need inherit_from in this target any more, since we've
3132     # resolved all the inheritances that lead to this
3133     delete $table{$target}->{inherit_from};
3134
3135     # Now is the time to deal with those lists.  Here's the place to
3136     # decide what shall be done with those lists, all based on the
3137     # values of the target we're currently dealing with.
3138     # - If a value is a coderef, it will be executed with the list of
3139     #   inherited values as arguments.
3140     # - If the corresponding key doesn't have a value at all or is the
3141     #   empty string, the inherited value list will be run through the
3142     #   default combiner (below), and the result becomes this target's
3143     #   value.
3144     # - Otherwise, this target's value is assumed to be a string that
3145     #   will simply override the inherited list of values.
3146     my $default_combiner = add();
3147
3148     my %all_keys =
3149         map { $_ => 1 } (keys %combined_inheritance,
3150                          keys %{$table{$target}});
3151
3152     sub process_values {
3153         my $object    = shift;
3154         my $inherited = shift;  # Always a [ list ]
3155         my $target    = shift;
3156         my $entry     = shift;
3157
3158         $add_called = 0;
3159
3160         while(ref($object) eq "CODE") {
3161             $object = $object->(@$inherited);
3162         }
3163         if (!defined($object)) {
3164             return ();
3165         }
3166         elsif (ref($object) eq "ARRAY") {
3167             local $add_called;  # To make sure recursive calls don't affect it
3168             return [ map { process_values($_, $inherited, $target, $entry) }
3169                      @$object ];
3170         } elsif (ref($object) eq "") {
3171             return $object;
3172         } else {
3173             die "cannot handle reference type ",ref($object)
3174                 ," found in target ",$target," -> ",$entry,"\n";
3175         }
3176     }
3177
3178     foreach (sort keys %all_keys) {
3179         my $previous = $combined_inheritance{$_};
3180
3181         # Current target doesn't have a value for the current key?
3182         # Assign it the default combiner, the rest of this loop body
3183         # will handle it just like any other coderef.
3184         if (!exists $table{$target}->{$_}) {
3185             $table{$target}->{$_} = $default_combiner;
3186         }
3187
3188         $table{$target}->{$_} = process_values($table{$target}->{$_},
3189                                                $combined_inheritance{$_},
3190                                                $target, $_);
3191         unless(defined($table{$target}->{$_})) {
3192             delete $table{$target}->{$_};
3193         }
3194 #        if ($extra_checks &&
3195 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3196 #            warn "$_ got replaced in $target\n";
3197 #        }
3198     }
3199
3200     # Finally done, return the result.
3201     return %{$table{$target}};
3202 }
3203
3204 sub usage
3205         {
3206         print STDERR $usage;
3207         print STDERR "\npick os/compiler from:\n";
3208         my $j=0;
3209         my $i;
3210         my $k=0;
3211         foreach $i (sort keys %table)
3212                 {
3213                 next if $table{$i}->{template};
3214                 next if $i =~ /^debug/;
3215                 $k += length($i) + 1;
3216                 if ($k > 78)
3217                         {
3218                         print STDERR "\n";
3219                         $k=length($i);
3220                         }
3221                 print STDERR $i . " ";
3222                 }
3223         foreach $i (sort keys %table)
3224                 {
3225                 next if $table{$i}->{template};
3226                 next if $i !~ /^debug/;
3227                 $k += length($i) + 1;
3228                 if ($k > 78)
3229                         {
3230                         print STDERR "\n";
3231                         $k=length($i);
3232                         }
3233                 print STDERR $i . " ";
3234                 }
3235         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3236         exit(1);
3237         }
3238
3239 sub run_dofile
3240 {
3241     my $out = shift;
3242     my @templates = @_;
3243
3244     unlink $out || warn "Can't remove $out, $!"
3245         if -f $out;
3246     foreach (@templates) {
3247         die "Can't open $_, $!" unless -f $_;
3248     }
3249     my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
3250     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
3251     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
3252     system($cmd);
3253     exit 1 if $? != 0;
3254     rename("$out.new", $out) || die "Can't rename $out.new, $!";
3255 }
3256
3257 sub compiler_predefined {
3258     state %predefined;
3259     my $cc = shift;
3260
3261     return () if $^O eq 'VMS';
3262
3263     die 'compiler_predefined called without a compiler command'
3264         unless $cc;
3265
3266     if (! $predefined{$cc}) {
3267
3268         $predefined{$cc} = {};
3269
3270         # collect compiler pre-defines from gcc or gcc-alike...
3271         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3272         while (my $l = <PIPE>) {
3273             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3274             $predefined{$cc}->{$1} = $2 // '';
3275         }
3276         close(PIPE);
3277     }
3278
3279     return %{$predefined{$cc}};
3280 }
3281
3282 sub which
3283 {
3284     my ($name)=@_;
3285
3286     if (eval { require IPC::Cmd; 1; }) {
3287         IPC::Cmd->import();
3288         return scalar IPC::Cmd::can_run($name);
3289     } else {
3290         # if there is $directories component in splitpath,
3291         # then it's not something to test with $PATH...
3292         return $name if (File::Spec->splitpath($name))[1];
3293
3294         foreach (File::Spec->path()) {
3295             my $fullpath = catfile($_, "$name$target{exe_extension}");
3296             if (-f $fullpath and -x $fullpath) {
3297                 return $fullpath;
3298             }
3299         }
3300     }
3301 }
3302
3303 sub env
3304 {
3305     my $name = shift;
3306     my %opts = @_;
3307
3308     unless ($opts{cacheonly}) {
3309         # Note that if $ENV{$name} doesn't exist or is undefined,
3310         # $config{perlenv}->{$name} will be created with the value
3311         # undef.  This is intentional.
3312
3313         $config{perlenv}->{$name} = $ENV{$name}
3314             if ! exists $config{perlenv}->{$name};
3315     }
3316     return $config{perlenv}->{$name};
3317 }
3318
3319 # Configuration printer ##############################################
3320
3321 sub print_table_entry
3322 {
3323     local $now_printing = shift;
3324     my %target = resolve_config($now_printing);
3325     my $type = shift;
3326
3327     # Don't print the templates
3328     return if $target{template};
3329
3330     my @sequence = (
3331         "sys_id",
3332         "cpp",
3333         "cppflags",
3334         "defines",
3335         "includes",
3336         "cc",
3337         "cflags",
3338         "unistd",
3339         "ld",
3340         "lflags",
3341         "loutflag",
3342         "ex_libs",
3343         "bn_ops",
3344         "apps_aux_src",
3345         "cpuid_asm_src",
3346         "uplink_aux_src",
3347         "bn_asm_src",
3348         "ec_asm_src",
3349         "des_asm_src",
3350         "aes_asm_src",
3351         "bf_asm_src",
3352         "md5_asm_src",
3353         "cast_asm_src",
3354         "sha1_asm_src",
3355         "rc4_asm_src",
3356         "rmd160_asm_src",
3357         "rc5_asm_src",
3358         "wp_asm_src",
3359         "cmll_asm_src",
3360         "modes_asm_src",
3361         "padlock_asm_src",
3362         "chacha_asm_src",
3363         "poly1035_asm_src",
3364         "thread_scheme",
3365         "perlasm_scheme",
3366         "dso_scheme",
3367         "shared_target",
3368         "shared_cflag",
3369         "shared_defines",
3370         "shared_ldflag",
3371         "shared_rcflag",
3372         "shared_extension",
3373         "dso_extension",
3374         "obj_extension",
3375         "exe_extension",
3376         "ranlib",
3377         "ar",
3378         "arflags",
3379         "aroutflag",
3380         "rc",
3381         "rcflags",
3382         "rcoutflag",
3383         "mt",
3384         "mtflags",
3385         "mtinflag",
3386         "mtoutflag",
3387         "multilib",
3388         "build_scheme",
3389         );
3390
3391     if ($type eq "TABLE") {
3392         print "\n";
3393         print "*** $now_printing\n";
3394         foreach (@sequence) {
3395             if (ref($target{$_}) eq "ARRAY") {
3396                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3397             } else {
3398                 printf "\$%-12s = %s\n", $_, $target{$_};
3399             }
3400         }
3401     } elsif ($type eq "HASH") {
3402         my $largest =
3403             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3404         print "    '$now_printing' => {\n";
3405         foreach (@sequence) {
3406             if ($target{$_}) {
3407                 if (ref($target{$_}) eq "ARRAY") {
3408                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3409                 } else {
3410                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3411                 }
3412             }
3413         }
3414         print "    },\n";
3415     }
3416 }
3417
3418 # Utility routines ###################################################
3419
3420 # On VMS, if the given file is a logical name, File::Spec::Functions
3421 # will consider it an absolute path.  There are cases when we want a
3422 # purely syntactic check without checking the environment.
3423 sub isabsolute {
3424     my $file = shift;
3425
3426     # On non-platforms, we just use file_name_is_absolute().
3427     return file_name_is_absolute($file) unless $^O eq "VMS";
3428
3429     # If the file spec includes a device or a directory spec,
3430     # file_name_is_absolute() is perfectly safe.
3431     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3432
3433     # Here, we know the given file spec isn't absolute
3434     return 0;
3435 }
3436
3437 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3438 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3439 # realpath() requires that at least all path components except the last is an
3440 # existing directory.  On VMS, the last component of the directory spec must
3441 # exist.
3442 sub absolutedir {
3443     my $dir = shift;
3444
3445     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3446     # will return the volume name for the device, no matter what.  Also,
3447     # it will return an incorrect directory spec if the argument is a
3448     # directory that doesn't exist.
3449     if ($^O eq "VMS") {
3450         return rel2abs($dir);
3451     }
3452
3453     # We use realpath() on Unix, since no other will properly clean out
3454     # a directory spec.
3455     use Cwd qw/realpath/;
3456
3457     return realpath($dir);
3458 }
3459
3460 sub quotify {
3461     my %processors = (
3462         perl    => sub { my $x = shift;
3463                          $x =~ s/([\\\$\@"])/\\$1/g;
3464                          return '"'.$x.'"'; },
3465         maybeshell => sub { my $x = shift;
3466                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3467                             if ($x ne $y || $x =~ m|\s|) {
3468                                 return '"'.$y.'"';
3469                             } else {
3470                                 return $x;
3471                             }
3472                         },
3473         );
3474     my $for = shift;
3475     my $processor =
3476         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3477
3478     return map { $processor->($_); } @_;
3479 }
3480
3481 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3482 # $filename is a file name to read from
3483 # $line_concat_cond_re is a regexp detecting a line continuation ending
3484 # $line_concat is a CODEref that takes care of concatenating two lines
3485 sub collect_from_file {
3486     my $filename = shift;
3487     my $line_concat_cond_re = shift;
3488     my $line_concat = shift;
3489
3490     open my $fh, $filename || die "unable to read $filename: $!\n";
3491     return sub {
3492         my $saved_line = "";
3493         $_ = "";
3494         while (<$fh>) {
3495             s|\R$||;
3496             if (defined $line_concat) {
3497                 $_ = $line_concat->($saved_line, $_);
3498                 $saved_line = "";
3499             }
3500             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3501                 $saved_line = $_;
3502                 next;
3503             }
3504             return $_;
3505         }
3506         die "$filename ending with continuation line\n" if $_;
3507         close $fh;
3508         return undef;
3509     }
3510 }
3511
3512 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3513 # $array is an ARRAYref of lines
3514 # $line_concat_cond_re is a regexp detecting a line continuation ending
3515 # $line_concat is a CODEref that takes care of concatenating two lines
3516 sub collect_from_array {
3517     my $array = shift;
3518     my $line_concat_cond_re = shift;
3519     my $line_concat = shift;
3520     my @array = (@$array);
3521
3522     return sub {
3523         my $saved_line = "";
3524         $_ = "";
3525         while (defined($_ = shift @array)) {
3526             s|\R$||;
3527             if (defined $line_concat) {
3528                 $_ = $line_concat->($saved_line, $_);
3529                 $saved_line = "";
3530             }
3531             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3532                 $saved_line = $_;
3533                 next;
3534             }
3535             return $_;
3536         }
3537         die "input text ending with continuation line\n" if $_;
3538         return undef;
3539     }
3540 }
3541
3542 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3543 # $lineiterator is a CODEref that delivers one line at a time.
3544 # All following arguments are regex/CODEref pairs, where the regexp detects a
3545 # line and the CODEref does something with the result of the regexp.
3546 sub collect_information {
3547     my $lineiterator = shift;
3548     my %collectors = @_;
3549
3550     while(defined($_ = $lineiterator->())) {
3551         s|\R$||;
3552         my $found = 0;
3553         if ($collectors{"BEFORE"}) {
3554             $collectors{"BEFORE"}->($_);
3555         }
3556         foreach my $re (keys %collectors) {
3557             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3558                 $collectors{$re}->($lineiterator);
3559                 $found = 1;
3560             };
3561         }
3562         if ($collectors{"OTHERWISE"}) {
3563             $collectors{"OTHERWISE"}->($lineiterator, $_)
3564                 unless $found || !defined $collectors{"OTHERWISE"};
3565         }
3566         if ($collectors{"AFTER"}) {
3567             $collectors{"AFTER"}->($_);
3568         }
3569     }
3570 }
3571
3572 # tokenize($line)
3573 # $line is a line of text to split up into tokens
3574 # returns a list of tokens
3575 #
3576 # Tokens are divided by spaces.  If the tokens include spaces, they
3577 # have to be quoted with single or double quotes.  Double quotes
3578 # inside a double quoted token must be escaped.  Escaping is done
3579 # with backslash.
3580 # Basically, the same quoting rules apply for " and ' as in any
3581 # Unix shell.
3582 sub tokenize {
3583     my $line = my $debug_line = shift;
3584     my @result = ();
3585
3586     while ($line =~ s|^\s+||, $line ne "") {
3587         my $token = "";
3588         while ($line ne "" && $line !~ m|^\s|) {
3589             if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3590                 $token .= $1;
3591                 $line = $';
3592             } elsif ($line =~ m/^'([^']*)'/) {
3593                 $token .= $1;
3594                 $line = $';
3595             } elsif ($line =~ m/^(\S+)/) {
3596                 $token .= $1;
3597                 $line = $';
3598             }
3599         }
3600         push @result, $token;
3601     }
3602
3603     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3604         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3605         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3606     }
3607     return @result;
3608 }