Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2021 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::fallback "$FindBin::Bin/external/perl/MODULES.txt";
  21 use OpenSSL::Glob;
  22 use OpenSSL::Template;
  23 use OpenSSL::config;
  24
  25 # see INSTALL.md for instructions.
  26
  27 my $orig_death_handler = $SIG{__DIE__};
  28 $SIG{__DIE__} = \&death_handler;
  29
  30 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  31
  32 my $banner = <<"EOF";
  33
  34 **********************************************************************
  35 ***                                                                ***
  36 ***   OpenSSL has been successfully configured                     ***
  37 ***                                                                ***
  38 ***   If you encounter a problem while building, please open an    ***
  39 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
  40 ***   and include the output from the following command:           ***
  41 ***                                                                ***
  42 ***       perl configdata.pm --dump                                ***
  43 ***                                                                ***
  44 ***   (If you are new to OpenSSL, you might want to consult the    ***
  45 ***   'Troubleshooting' section in the INSTALL.md file first)      ***
  46 ***                                                                ***
  47 **********************************************************************
  48 EOF
  49
  50 # Options:
  51 #
  52 # --config      add the given configuration file, which will be read after
  53 #               any "Configurations*" files that are found in the same
  54 #               directory as this script.
  55 # --prefix      prefix for the OpenSSL installation, which includes the
  56 #               directories bin, lib, include, share/man, share/doc/openssl
  57 #               This becomes the value of INSTALLTOP in Makefile
  58 #               (Default: /usr/local)
  59 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  60 #               If it's a relative directory, it will be added on the directory
  61 #               given with --prefix.
  62 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  63 #               (Default: PREFIX/ssl)
  64 # --banner=".." Output specified text instead of default completion banner
  65 #
  66 # --cross-compile-prefix Add specified prefix to binutils components.
  67 #
  68 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0
  69 #               Define the public APIs as they were for that version
  70 #               including patch releases.  If 'no-deprecated' is also
  71 #               given, do not compile support for interfaces deprecated
  72 #               up to and including the specified OpenSSL version.
  73 #
  74 # no-hw-xxx     do not compile support for specific crypto hardware.
  75 #               Generic OpenSSL-style methods relating to this support
  76 #               are always compiled but return NULL if the hardware
  77 #               support isn't compiled.
  78 # no-hw         do not compile support for any crypto hardware.
  79 # [no-]threads  [don't] try to create a library that is suitable for
  80 #               multithreaded applications (default is "threads" if we
  81 #               know how to do it)
  82 # [no-]shared   [don't] try to create shared libraries when supported.
  83 # [no-]pic      [don't] try to build position independent code when supported.
  84 #               If disabled, it also disables shared and dynamic-engine.
  85 # no-asm        do not use assembler
  86 # no-egd        do not compile support for the entropy-gathering daemon APIs
  87 # [no-]zlib     [don't] compile support for zlib compression.
  88 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  89 #               library and will be loaded in run-time by the OpenSSL library.
  90 # sctp          include SCTP support
  91 # no-uplink     Don't build support for UPLINK interface.
  92 # enable-weak-ssl-ciphers
  93 #               Enable weak ciphers that are disabled by default.
  94 # 386           generate 80386 code in assembly modules
  95 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  96 #               mentioned '386' option implies this one
  97 # no-<cipher>   build without specified algorithm (dsa, idea, rc5, ...)
  98 # -<xxx> +<xxx> All options which are unknown to the 'Configure' script are
  99 # /<xxx>        passed through to the compiler. Unix-style options beginning
 100 #               with a '-' or '+' are recognized, as well as Windows-style
 101 #               options beginning with a '/'. If the option contains arguments
 102 #               separated by spaces, then the URL-style notation %20 can be
 103 #               used for the space character in order to avoid having to quote
 104 #               the option. For example, -opt%20arg gets expanded to -opt arg.
 105 #               In fact, any ASCII character can be encoded as %xx using its
 106 #               hexadecimal encoding.
 107 # -static       while -static is also a pass-through compiler option (and
 108 #               as such is limited to environments where it's actually
 109 #               meaningful), it triggers a number configuration options,
 110 #               namely no-pic, no-shared and no-threads. It is
 111 #               argued that the only reason to produce statically linked
 112 #               binaries (and in context it means executables linked with
 113 #               -static flag, and not just executables linked with static
 114 #               libcrypto.a) is to eliminate dependency on specific run-time,
 115 #               a.k.a. libc version. The mentioned config options are meant
 116 #               to achieve just that. Unfortunately on Linux it's impossible
 117 #               to eliminate the dependency completely for openssl executable
 118 #               because of getaddrinfo and gethostbyname calls, which can
 119 #               invoke dynamically loadable library facility anyway to meet
 120 #               the lookup requests. For this reason on Linux statically
 121 #               linked openssl executable has rather debugging value than
 122 #               production quality.
 123 #
 124 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
 125 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
 126 # Following are set automatically by this script
 127 #
 128 # MD5_ASM       use some extra md5 assembler,
 129 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 130 # RMD160_ASM    use some extra ripemd160 assembler,
 131 # SHA256_ASM    sha256_block is implemented in assembler
 132 # SHA512_ASM    sha512_block is implemented in assembler
 133 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 134
 135 # Minimum warning options... any contributions to OpenSSL should at least
 136 # get past these.  Note that we only use these with C compilers, not with
 137 # C++ compilers.
 138
 139 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 140 # -DPEDANTIC complements -pedantic and is meant to mask code that
 141 # is not strictly standard-compliant and/or implementation-specific,
 142 # e.g. inline assembly, disregards to alignment requirements, such
 143 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 144 # to be used even in sanitized builds, because sanitizer too is
 145 # supposed to and does take notice of non-standard behaviour. Then
 146 # -pedantic with pre-C9x compiler would also complain about 'long
 147 # long' not being supported. As 64-bit algorithms are common now,
 148 # it grew impossible to resolve this without sizeable additional
 149 # code, so we just tell compiler to be pedantic about everything
 150 # but 'long long' type.
 151
 152 my @gcc_devteam_warn = qw(
 153     -DDEBUG_UNUSED
 154     -DPEDANTIC -pedantic -Wno-long-long
 155     -Wall
 156     -Wextra
 157     -Wno-unused-parameter
 158     -Wno-missing-field-initializers
 159     -Wswitch
 160     -Wsign-compare
 161     -Wshadow
 162     -Wformat
 163     -Wtype-limits
 164     -Wundef
 165     -Werror
 166     -Wmissing-prototypes
 167     -Wstrict-prototypes
 168 );
 169
 170 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 171 # TODO(openssl-team): fix problems and investigate if (at least) the
 172 # following warnings can also be enabled:
 173 #       -Wcast-align
 174 #       -Wunreachable-code -- no, too ugly/compiler-specific
 175 #       -Wlanguage-extension-token -- no, we use asm()
 176 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 177 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 178 my @clang_devteam_warn = qw(
 179     -Wno-unknown-warning-option
 180     -Wswitch-default
 181     -Wno-parentheses-equality
 182     -Wno-language-extension-token
 183     -Wno-extended-offsetof
 184     -Wconditional-uninitialized
 185     -Wincompatible-pointer-types-discards-qualifiers
 186     -Wmissing-variable-declarations
 187 );
 188
 189 my @cl_devteam_warn = qw(
 190     /WX
 191 );
 192
 193 my $strict_warnings = 0;
 194
 195 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 196 # which would cover all BSD flavors. -pthread applies to them all,
 197 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 198 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 199 # which has to be accompanied by explicit -D_THREAD_SAFE and
 200 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 201 # seems to be sufficient?
 202 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 203
 204 #
 205 # API compatibility name to version number mapping.
 206 #
 207 my $apitable = {
 208     # This table expresses when API additions or changes can occur.
 209     # The numbering used changes from 3.0 and on because we updated
 210     # (solidified) our version numbering scheme at that point.
 211
 212     # From 3.0 and on, we internalise the given version number in decimal
 213     # as MAJOR * 10000 + MINOR * 100 + 0
 214     "3.0.0" => 30000,
 215     "3.0"   => 30000,
 216
 217     # Note that before 3.0, we didn't have the same version number scheme.
 218     # Still, the numbering we use here covers what we need.
 219     "1.1.1" => 10101,
 220     "1.1.0" => 10100,
 221     "1.0.2" => 10002,
 222     "1.0.1" => 10001,
 223     "1.0.0" => 10000,
 224     "0.9.8" =>   908,
 225 };
 226
 227 # For OpenSSL::config::get_platform
 228 my %guess_opts = ();
 229
 230 my $dryrun = 0;
 231
 232 our %table = ();
 233 our %config = ();
 234 our %withargs = ();
 235 our $now_printing;      # set to current entry's name in print_table_entry
 236                         # (todo: right thing would be to encapsulate name
 237                         # into %target [class] and make print_table_entry
 238                         # a method)
 239
 240 # Forward declarations ###############################################
 241
 242 # read_config(filename)
 243 #
 244 # Reads a configuration file and populates %table with the contents
 245 # (which the configuration file places in %targets).
 246 sub read_config;
 247
 248 # resolve_config(target)
 249 #
 250 # Resolves all the late evaluations, inheritances and so on for the
 251 # chosen target and any target it inherits from.
 252 sub resolve_config;
 253
 254
 255 # Information collection #############################################
 256
 257 # Unified build supports separate build dir
 258 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 259 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 260
 261 # File::Spec::Unix doesn't detect case insensitivity, so we make sure to
 262 # check if the source and build directory are really the same, and make
 263 # them so.  This avoids all kinds of confusion later on.
 264 # We must check @File::Spec::ISA rather than using File::Spec->isa() to
 265 # know if File::Spec ended up loading File::Spec::Unix.
 266 $srcdir = $blddir
 267     if (grep(/::Unix$/, @File::Spec::ISA)
 268         && samedir($srcdir, $blddir));
 269
 270 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 271
 272 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 273
 274 $config{sourcedir} = abs2rel($srcdir, $blddir);
 275 $config{builddir} = abs2rel($blddir, $blddir);
 276 # echo -n 'holy hand grenade of antioch' | openssl sha256
 277 $config{FIPSKEY} =
 278     'f4556650ac31d35461610bac4ed81b1a181b2d8a43ea2854cbae22ca74560813';
 279
 280 # Collect reconfiguration information if needed
 281 my @argvcopy=@ARGV;
 282
 283 if (grep /^reconf(igure)?$/, @argvcopy) {
 284     die "reconfiguring with other arguments present isn't supported"
 285         if scalar @argvcopy > 1;
 286     if (-f "./configdata.pm") {
 287         my $file = "./configdata.pm";
 288         unless (my $return = do $file) {
 289             die "couldn't parse $file: $@" if $@;
 290             die "couldn't do $file: $!"    unless defined $return;
 291             die "couldn't run $file"       unless $return;
 292         }
 293
 294         @argvcopy = defined($configdata::config{perlargv}) ?
 295             @{$configdata::config{perlargv}} : ();
 296         die "Incorrect data to reconfigure, please do a normal configuration\n"
 297             if (grep(/^reconf/,@argvcopy));
 298         $config{perlenv} = $configdata::config{perlenv} // {};
 299     } else {
 300         die "Insufficient data to reconfigure, please do a normal configuration\n";
 301     }
 302 }
 303
 304 $config{perlargv} = [ @argvcopy ];
 305
 306 # Historical: if known directories in crypto/ have been removed, it means
 307 # that those sub-systems are disabled.
 308 # (the other option would be to removed them from the SUBDIRS statement in
 309 # crypto/build.info)
 310 # We reverse the input list for cosmetic purely reasons, to compensate that
 311 # 'unshift' adds at the front of the list (i.e. in reverse input order).
 312 foreach ( reverse sort( 'aes', 'aria', 'bf', 'camellia', 'cast', 'des', 'dh',
 313                         'dsa', 'ec', 'hmac', 'idea', 'md2', 'md5', 'mdc2',
 314                         'rc2', 'rc4', 'rc5', 'ripemd', 'seed', 'sha',
 315                         'sm2', 'sm3', 'sm4') ) {
 316     unshift @argvcopy, "no-$_" if ! -d catdir($srcdir, 'crypto', $_);
 317 }
 318
 319 # Collect version numbers
 320 my %version = ();
 321
 322 collect_information(
 323     collect_from_file(catfile($srcdir,'VERSION.dat')),
 324     qr/\s*(\w+)\s*=\s*(.*?)\s*$/ =>
 325         sub {
 326             # Only define it if there is a value at all
 327             if ($2 ne '') {
 328                 my $k = $1;
 329                 my $v = $2;
 330                 # Some values are quoted.  Trim the quotes
 331                 $v = $1 if $v =~ /^"(.*)"$/;
 332                 $version{uc $k} = $v;
 333             }
 334         },
 335     "OTHERWISE" =>
 336         sub { die "Something wrong with this line:\n$_\nin $srcdir/VERSION.dat" },
 337     );
 338
 339 $config{major} = $version{MAJOR} // 'unknown';
 340 $config{minor} = $version{MINOR} // 'unknown';
 341 $config{patch} = $version{PATCH} // 'unknown';
 342 $config{prerelease} =
 343     defined $version{PRE_RELEASE_TAG} ? "-$version{PRE_RELEASE_TAG}" : '';
 344 $config{build_metadata} =
 345     defined $version{BUILD_METADATA} ? "+$version{BUILD_METADATA}" : '';
 346 $config{shlib_version} = $version{SHLIB_VERSION} // 'unknown';
 347 $config{release_date} = $version{RELEASE_DATE} // 'xx XXX xxxx';
 348
 349 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 350 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 351
 352 die "erroneous version information in VERSION.dat: ",
 353     "$config{version}, $config{shlib_version}\n"
 354     unless (defined $version{MAJOR}
 355             && defined $version{MINOR}
 356             && defined $version{PATCH}
 357             && defined $version{SHLIB_VERSION});
 358
 359 # Collect target configurations
 360
 361 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 362 foreach (sort glob($pattern)) {
 363     &read_config($_);
 364 }
 365
 366 if (defined env($local_config_envname)) {
 367     if ($^O eq 'VMS') {
 368         # VMS environment variables are logical names,
 369         # which can be used as is
 370         $pattern = $local_config_envname . ':' . '*.conf';
 371     } else {
 372         $pattern = catfile(env($local_config_envname), '*.conf');
 373     }
 374
 375     foreach (sort glob($pattern)) {
 376         &read_config($_);
 377     }
 378 }
 379
 380 # Save away perl command information
 381 $config{perl_cmd} = $^X;
 382 $config{perl_version} = $Config{version};
 383 $config{perl_archname} = $Config{archname};
 384
 385 $config{prefix}="";
 386 $config{openssldir}="";
 387 $config{processor}="";
 388 $config{libdir}="";
 389 my $auto_threads=1;    # enable threads automatically? true by default
 390 my $default_ranlib;
 391
 392 # Known TLS and DTLS protocols
 393 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 394 my @dtls = qw(dtls1 dtls1_2);
 395
 396 # Explicitly known options that are possible to disable.  They can
 397 # be regexps, and will be used like this: /^no-${option}$/
 398 # For developers: keep it sorted alphabetically
 399
 400 my @disablables = (
 401     "acvp-tests",
 402     "afalgeng",
 403     "aria",
 404     "asan",
 405     "asm",
 406     "async",
 407     "autoalginit",
 408     "autoerrinit",
 409     "autoload-config",
 410     "bf",
 411     "blake2",
 412     "buildtest-c++",
 413     "bulk",
 414     "cached-fetch",
 415     "camellia",
 416     "capieng",
 417     "cast",
 418     "chacha",
 419     "cmac",
 420     "cmp",
 421     "cms",
 422     "comp",
 423     "crypto-mdebug",
 424     "ct",
 425     "deprecated",
 426     "des",
 427     "devcryptoeng",
 428     "dgram",
 429     "dh",
 430     "dsa",
 431     "dso",
 432     "dtls",
 433     "dynamic-engine",
 434     "ec",
 435     "ec2m",
 436     "ec_nistp_64_gcc_128",
 437     "ecdh",
 438     "ecdsa",
 439     "egd",
 440     "engine",
 441     "err",
 442     "external-tests",
 443     "filenames",
 444     "fips",
 445     "fips-securitychecks",
 446     "fuzz-afl",
 447     "fuzz-libfuzzer",
 448     "gost",
 449     "idea",
 450     "ktls",
 451     "legacy",
 452     "makedepend",
 453     "md2",
 454     "md4",
 455     "mdc2",
 456     "module",
 457     "msan",
 458     "multiblock",
 459     "nextprotoneg",
 460     "ocb",
 461     "ocsp",
 462     "padlockeng",
 463     "pic",
 464     "pinshared",
 465     "poly1305",
 466     "posix-io",
 467     "psk",
 468     "rc2",
 469     "rc4",
 470     "rc5",
 471     "rdrand",
 472     "rfc3779",
 473     "rmd160",
 474     "scrypt",
 475     "sctp",
 476     "secure-memory",
 477     "seed",
 478     "shared",
 479     "siphash",
 480     "siv",
 481     "sm2",
 482     "sm3",
 483     "sm4",
 484     "sock",
 485     "srp",
 486     "srtp",
 487     "sse2",
 488     "ssl",
 489     "ssl-trace",
 490     "static-engine",
 491     "stdio",
 492     "tests",
 493     "threads",
 494     "tls",
 495     "trace",
 496     "ts",
 497     "ubsan",
 498     "ui-console",
 499     "unit-test",
 500     "uplink",
 501     "weak-ssl-ciphers",
 502     "whirlpool",
 503     "zlib",
 504     "zlib-dynamic",
 505     );
 506 foreach my $proto ((@tls, @dtls))
 507         {
 508         push(@disablables, $proto);
 509         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 510         }
 511
 512 # Internal disablables, for aliasing purposes.  They serve no special
 513 # purpose here, but allow scripts to get to know them through configdata.pm,
 514 # where these are merged with @disablables.
 515 # The actual aliasing mechanism is done via %disable_cascades
 516 my @disablables_int = qw(
 517     crmf
 518     );
 519
 520 my %deprecated_disablables = (
 521     "ssl2" => undef,
 522     "buf-freelists" => undef,
 523     "crypto-mdebug-backtrace" => undef,
 524     "hw" => "hw",               # causes cascade, but no macro
 525     "hw-padlock" => "padlockeng",
 526     "ripemd" => "rmd160",
 527     "ui" => "ui-console",
 528     "heartbeats" => undef,
 529     );
 530
 531 # All of the following are disabled by default:
 532
 533 our %disabled = ( # "what"         => "comment"
 534                   "fips"                => "default",
 535                   "acvp-tests"          => "default",
 536                   "asan"                => "default",
 537                   "buildtest-c++"       => "default",
 538                   "crypto-mdebug"       => "default",
 539                   "crypto-mdebug-backtrace" => "default",
 540                   "devcryptoeng"        => "default",
 541                   "ec_nistp_64_gcc_128" => "default",
 542                   "egd"                 => "default",
 543                   "external-tests"      => "default",
 544                   "fuzz-afl"            => "default",
 545                   "fuzz-libfuzzer"      => "default",
 546                   "ktls"                => "default",
 547                   "md2"                 => "default",
 548                   "msan"                => "default",
 549                   "rc5"                 => "default",
 550                   "sctp"                => "default",
 551                   "ssl-trace"           => "default",
 552                   "ssl3"                => "default",
 553                   "ssl3-method"         => "default",
 554                   "trace"               => "default",
 555                   "ubsan"               => "default",
 556                   "unit-test"           => "default",
 557                   "weak-ssl-ciphers"    => "default",
 558                   "zlib"                => "default",
 559                   "zlib-dynamic"        => "default",
 560                 );
 561
 562 # Note: => pair form used for aesthetics, not to truly make a hash table
 563 my @disable_cascades = (
 564     # "what"            => [ "cascade", ... ]
 565     "bulk"              => [ "shared", "dso",
 566                              "aria", "async", "autoload-config",
 567                              "blake2", "bf", "camellia", "cast", "chacha",
 568                              "cmac", "cms", "cmp", "comp", "ct",
 569                              "des", "dgram", "dh", "dsa",
 570                              "ec", "engine",
 571                              "filenames",
 572                              "idea", "ktls",
 573                              "md4", "multiblock", "nextprotoneg",
 574                              "ocsp", "ocb", "poly1305", "psk",
 575                              "rc2", "rc4", "rmd160",
 576                              "seed", "siphash", "siv",
 577                              "sm3", "sm4", "srp",
 578                              "srtp", "ssl3-method",
 579                              "ts", "ui-console", "whirlpool",
 580                              "fips-securitychecks" ],
 581     sub { $config{processor} eq "386" }
 582                         => [ "sse2" ],
 583     "ssl"               => [ "ssl3" ],
 584     "ssl3-method"       => [ "ssl3" ],
 585     "zlib"              => [ "zlib-dynamic" ],
 586     "des"               => [ "mdc2" ],
 587     "ec"                => [ "ec2m", "ecdsa", "ecdh", "sm2", "gost" ],
 588     "dgram"             => [ "dtls", "sctp" ],
 589     "sock"              => [ "dgram" ],
 590     "dtls"              => [ @dtls ],
 591     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 592                         => [ "dtls" ],
 593
 594     "tls"               => [ @tls ],
 595     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 596                         => [ "tls" ],
 597
 598     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 599
 600     # If no modules, then no dynamic engines either
 601     "module"            => [ "dynamic-engine" ],
 602
 603     # Without shared libraries, dynamic engines aren't possible.
 604     # This is due to them having to link with libcrypto and register features
 605     # using the ENGINE functionality, and since that relies on global tables,
 606     # those *have* to be exacty the same as the ones accessed from the app,
 607     # which cannot be guaranteed if shared libraries aren't present.
 608     # (note that even with shared libraries, both the app and dynamic engines
 609     # must be linked with the same library)
 610     "shared"            => [ "dynamic-engine", "uplink" ],
 611     "dso"               => [ "dynamic-engine", "module" ],
 612     # Other modules don't necessarily have to link with libcrypto, so shared
 613     # libraries do not have to be a condition to produce those.
 614
 615     # Without position independent code, there can be no shared libraries
 616     # or modules.
 617     "pic"               => [ "shared", "module" ],
 618
 619     "module"            => [ "fips", "dso" ],
 620
 621     "engine"            => [ "dynamic-engine", grep(/eng$/, @disablables) ],
 622     "hw"                => [ "padlockeng" ],
 623
 624     # no-autoalginit is only useful when building non-shared
 625     "autoalginit"       => [ "shared", "apps", "fips" ],
 626
 627     "stdio"             => [ "apps", "capieng", "egd" ],
 628     "apps"              => [ "tests" ],
 629     "tests"             => [ "external-tests" ],
 630     "comp"              => [ "zlib" ],
 631     "sm3"               => [ "sm2" ],
 632     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 633
 634     sub { !$disabled{"msan"} } => [ "asm" ],
 635
 636     "cmac"              => [ "siv" ],
 637     "legacy"            => [ "md2" ],
 638
 639     "cmp"               => [ "crmf" ],
 640
 641     "fips"              => [ "fips-securitychecks" ],
 642
 643     "deprecated-3.0"    => [ "engine", "srp" ]
 644     );
 645
 646 # Avoid protocol support holes.  Also disable all versions below N, if version
 647 # N is disabled while N+1 is enabled.
 648 #
 649 my @list = (reverse @tls);
 650 while ((my $first, my $second) = (shift @list, shift @list)) {
 651     last unless @list;
 652     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 653                               => [ @list ] );
 654     unshift @list, $second;
 655 }
 656 my @list = (reverse @dtls);
 657 while ((my $first, my $second) = (shift @list, shift @list)) {
 658     last unless @list;
 659     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 660                               => [ @list ] );
 661     unshift @list, $second;
 662 }
 663
 664 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 665 # To remove something from %disabled, use "enable-foo".
 666 # For symmetry, "disable-foo" is a synonym for "no-foo".
 667
 668 # For the "make variables" CPPINCLUDES and CPPDEFINES, we support lists with
 669 # platform specific list separators.  Users from those platforms should
 670 # recognise those separators from how you set up the PATH to find executables.
 671 # The default is the Unix like separator, :, but as an exception, we also
 672 # support the space as separator.
 673 my $list_separator_re =
 674     { VMS           => qr/(?<!\^),/,
 675       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 676 # All the "make variables" we support
 677 # Some get pre-populated for the sake of backward compatibility
 678 # (we supported those before the change to "make variable" support.
 679 my %user = (
 680     AR          => env('AR'),
 681     ARFLAGS     => [],
 682     AS          => undef,
 683     ASFLAGS     => [],
 684     CC          => env('CC'),
 685     CFLAGS      => [ env('CFLAGS') || () ],
 686     CXX         => env('CXX'),
 687     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 688     CPP         => undef,
 689     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 690     CPPDEFINES  => [],  # Alternative for -D
 691     CPPINCLUDES => [],  # Alternative for -I
 692     CROSS_COMPILE => env('CROSS_COMPILE'),
 693     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 694     LD          => undef,
 695     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 696     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 697     MT          => undef,
 698     MTFLAGS     => [],
 699     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 700     RANLIB      => env('RANLIB'),
 701     RC          => env('RC') || env('WINDRES'),
 702     RCFLAGS     => [ env('RCFLAGS') || () ],
 703     RM          => undef,
 704    );
 705 # Info about what "make variables" may be prefixed with the cross compiler
 706 # prefix.  This should NEVER mention any such variable with a list for value.
 707 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 708 # The same but for flags given as Configure options.  These are *additional*
 709 # input, as opposed to the VAR=string option that override the corresponding
 710 # config target attributes
 711 my %useradd = (
 712     CPPDEFINES  => [],
 713     CPPINCLUDES => [],
 714     CPPFLAGS    => [],
 715     CFLAGS      => [],
 716     CXXFLAGS    => [],
 717     LDFLAGS     => [],
 718     LDLIBS      => [],
 719     RCFLAGS     => [],
 720    );
 721
 722 my %user_synonyms = (
 723     HASHBANGPERL=> 'PERL',
 724     RC          => 'WINDRES',
 725    );
 726
 727 # Some target attributes have been renamed, this is the translation table
 728 my %target_attr_translate =(
 729     ar          => 'AR',
 730     as          => 'AS',
 731     cc          => 'CC',
 732     cxx         => 'CXX',
 733     cpp         => 'CPP',
 734     hashbangperl => 'HASHBANGPERL',
 735     ld          => 'LD',
 736     mt          => 'MT',
 737     ranlib      => 'RANLIB',
 738     rc          => 'RC',
 739     rm          => 'RM',
 740    );
 741
 742 # Initialisers coming from 'config' scripts
 743 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 744 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 745 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 746 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 747 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 748 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 749 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 750
 751 $config{openssl_api_defines}=[];
 752 $config{openssl_sys_defines}=[];
 753 $config{openssl_feature_defines}=[];
 754 $config{options}="";
 755 $config{build_type} = "release";
 756 my $target="";
 757
 758 my %cmdvars = ();               # Stores FOO='blah' type arguments
 759 my %unsupported_options = ();
 760 my %deprecated_options = ();
 761 # If you change this, update apps/version.c
 762 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 763 my @seed_sources = ();
 764 while (@argvcopy)
 765         {
 766         $_ = shift @argvcopy;
 767
 768         # Support env variable assignments among the options
 769         if (m|^(\w+)=(.+)?$|)
 770                 {
 771                 $cmdvars{$1} = $2;
 772                 # Every time a variable is given as a configuration argument,
 773                 # it acts as a reset if the variable.
 774                 if (exists $user{$1})
 775                         {
 776                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 777                         }
 778                 #if (exists $useradd{$1})
 779                 #       {
 780                 #       $useradd{$1} = [];
 781                 #       }
 782                 next;
 783                 }
 784
 785         # VMS is a case insensitive environment, and depending on settings
 786         # out of our control, we may receive options uppercased.  Let's
 787         # downcase at least the part before any equal sign.
 788         if ($^O eq "VMS")
 789                 {
 790                 s/^([^=]*)/lc($1)/e;
 791                 }
 792
 793         # some people just can't read the instructions, clang people have to...
 794         s/^-no-(?!integrated-as)/no-/;
 795
 796         # rewrite some options in "enable-..." form
 797         s /^-?-?shared$/enable-shared/;
 798         s /^sctp$/enable-sctp/;
 799         s /^threads$/enable-threads/;
 800         s /^zlib$/enable-zlib/;
 801         s /^zlib-dynamic$/enable-zlib-dynamic/;
 802
 803         if (/^(no|disable|enable)-(.+)$/)
 804                 {
 805                 my $word = $2;
 806                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 807                         && !exists $deprecated_disablables{$word}
 808                         && !grep { $word eq $_ } @disablables)
 809                         {
 810                         $unsupported_options{$_} = 1;
 811                         next;
 812                         }
 813                 }
 814         if (/^no-(.+)$/ || /^disable-(.+)$/)
 815                 {
 816                 foreach my $proto ((@tls, @dtls))
 817                         {
 818                         if ($1 eq "$proto-method")
 819                                 {
 820                                 $disabled{"$proto"} = "option($proto-method)";
 821                                 last;
 822                                 }
 823                         }
 824                 if ($1 eq "dtls")
 825                         {
 826                         foreach my $proto (@dtls)
 827                                 {
 828                                 $disabled{$proto} = "option(dtls)";
 829                                 }
 830                         $disabled{"dtls"} = "option(dtls)";
 831                         }
 832                 elsif ($1 eq "ssl")
 833                         {
 834                         # Last one of its kind
 835                         $disabled{"ssl3"} = "option(ssl)";
 836                         }
 837                 elsif ($1 eq "tls")
 838                         {
 839                         # XXX: Tests will fail if all SSL/TLS
 840                         # protocols are disabled.
 841                         foreach my $proto (@tls)
 842                                 {
 843                                 $disabled{$proto} = "option(tls)";
 844                                 }
 845                         }
 846                 elsif ($1 eq "static-engine")
 847                         {
 848                         delete $disabled{"dynamic-engine"};
 849                         }
 850                 elsif ($1 eq "dynamic-engine")
 851                         {
 852                         $disabled{"dynamic-engine"} = "option";
 853                         }
 854                 elsif (exists $deprecated_disablables{$1})
 855                         {
 856                         $deprecated_options{$_} = 1;
 857                         if (defined $deprecated_disablables{$1})
 858                                 {
 859                                 $disabled{$deprecated_disablables{$1}} = "option";
 860                                 }
 861                         }
 862                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 863                         {
 864                         $deprecated_options{$_} = 1;
 865                         }
 866                 else
 867                         {
 868                         $disabled{$1} = "option";
 869                         }
 870                 # No longer an automatic choice
 871                 $auto_threads = 0 if ($1 eq "threads");
 872                 }
 873         elsif (/^enable-(.+)$/)
 874                 {
 875                 if ($1 eq "static-engine")
 876                         {
 877                         $disabled{"dynamic-engine"} = "option";
 878                         }
 879                 elsif ($1 eq "dynamic-engine")
 880                         {
 881                         delete $disabled{"dynamic-engine"};
 882                         }
 883                 elsif ($1 eq "zlib-dynamic")
 884                         {
 885                         delete $disabled{"zlib"};
 886                         }
 887                 my $algo = $1;
 888                 delete $disabled{$algo};
 889
 890                 # No longer an automatic choice
 891                 $auto_threads = 0 if ($1 eq "threads");
 892                 }
 893         elsif (/^-d$/)          # From older 'config'
 894                 {
 895                 $config{build_type} = "debug";
 896                 }
 897         elsif (/^-v$/)          # From older 'config'
 898                 {
 899                 $guess_opts{verbose} = 1;
 900                 }
 901         elsif (/^-w$/)          # From older 'config'
 902                 {
 903                 $guess_opts{nowait} = 1;
 904                 }
 905         elsif (/^-t$/)          # From older 'config'
 906                 {
 907                 $dryrun = 1;
 908                 }
 909         elsif (/^--strict-warnings$/)
 910                 {
 911                 # Pretend that our strict flags is a C flag, and replace it
 912                 # with the proper flags later on
 913                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 914                 $strict_warnings=1;
 915                 }
 916         elsif (/^--debug$/)
 917                 {
 918                 $config{build_type} = "debug";
 919                 }
 920         elsif (/^--release$/)
 921                 {
 922                 $config{build_type} = "release";
 923                 }
 924         elsif (/^386$/)
 925                 { $config{processor}=386; }
 926         elsif (/^fips$/)
 927                 {
 928                 die "FIPS mode not supported\n";
 929                 }
 930         elsif (/^rsaref$/)
 931                 {
 932                 # No RSAref support any more since it's not needed.
 933                 # The check for the option is there so scripts aren't
 934                 # broken
 935                 }
 936         elsif (/^nofipscanistercheck$/)
 937                 {
 938                 die "FIPS mode not supported\n";
 939                 }
 940         elsif (m|^[-+/]|)
 941                 {
 942                 if (/^--prefix=(.*)$/)
 943                         {
 944                         $config{prefix}=$1;
 945                         die "Directory given with --prefix MUST be absolute\n"
 946                                 unless file_name_is_absolute($config{prefix});
 947                         }
 948                 elsif (/^--api=(.*)$/)
 949                         {
 950                         my $api = $1;
 951                         die "Unknown API compatibility level $api"
 952                                 unless defined $apitable->{$api};
 953                         $config{api}=$apitable->{$api};
 954                         }
 955                 elsif (/^--libdir=(.*)$/)
 956                         {
 957                         $config{libdir}=$1;
 958                         }
 959                 elsif (/^--openssldir=(.*)$/)
 960                         {
 961                         $config{openssldir}=$1;
 962                         }
 963                 elsif (/^--with-zlib-lib=(.*)$/)
 964                         {
 965                         $withargs{zlib_lib}=$1;
 966                         }
 967                 elsif (/^--with-zlib-include=(.*)$/)
 968                         {
 969                         $withargs{zlib_include}=$1;
 970                         }
 971                 elsif (/^--with-fuzzer-lib=(.*)$/)
 972                         {
 973                         $withargs{fuzzer_lib}=$1;
 974                         }
 975                 elsif (/^--with-fuzzer-include=(.*)$/)
 976                         {
 977                         $withargs{fuzzer_include}=$1;
 978                         }
 979                 elsif (/^--with-rand-seed=(.*)$/)
 980                         {
 981                         foreach my $x (split(m|,|, $1))
 982                             {
 983                             die "Unknown --with-rand-seed choice $x\n"
 984                                 if ! grep { $x eq $_ } @known_seed_sources;
 985                             push @seed_sources, $x;
 986                             }
 987                         }
 988                 elsif (/^--fips-key=(.*)$/)
 989                         {
 990                         $user{FIPSKEY}=lc($1);
 991                         die "Non-hex character in FIPS key\n"
 992                            if $user{FIPSKEY} =~ /[^a-f0-9]/;
 993                         die "FIPS key must have even number of characters\n"
 994                            if length $1 & 1;
 995                         die "FIPS key too long (64 bytes max)\n"
 996                            if length $1 > 64;
 997                         }
 998                 elsif (/^--banner=(.*)$/)
 999                         {
1000                         $banner = $1 . "\n";
1001                         }
1002                 elsif (/^--cross-compile-prefix=(.*)$/)
1003                         {
1004                         $user{CROSS_COMPILE}=$1;
1005                         }
1006                 elsif (/^--config=(.*)$/)
1007                         {
1008                         read_config $1;
1009                         }
1010                 elsif (/^-l(.*)$/)
1011                         {
1012                         push @{$useradd{LDLIBS}}, $_;
1013                         }
1014                 elsif (/^-framework$/)
1015                         {
1016                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
1017                         }
1018                 elsif (/^-L(.*)$/ or /^-Wl,/)
1019                         {
1020                         push @{$useradd{LDFLAGS}}, $_;
1021                         }
1022                 elsif (/^-rpath$/ or /^-R$/)
1023                         # -rpath is the OSF1 rpath flag
1024                         # -R is the old Solaris rpath flag
1025                         {
1026                         my $rpath = shift(@argvcopy) || "";
1027                         $rpath .= " " if $rpath ne "";
1028                         push @{$useradd{LDFLAGS}}, $_, $rpath;
1029                         }
1030                 elsif (/^-static$/)
1031                         {
1032                         push @{$useradd{LDFLAGS}}, $_;
1033                         }
1034                 elsif (m|^[-/]D(.*)$|)
1035                         {
1036                         push @{$useradd{CPPDEFINES}}, $1;
1037                         }
1038                 elsif (m|^[-/]I(.*)$|)
1039                         {
1040                         push @{$useradd{CPPINCLUDES}}, $1;
1041                         }
1042                 elsif (/^-Wp,$/)
1043                         {
1044                         push @{$useradd{CPPFLAGS}}, $1;
1045                         }
1046                 else    # common if (/^[-+]/), just pass down...
1047                         {
1048                         # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
1049                         # This provides a simple way to pass options with arguments separated
1050                         # by spaces without quoting (e.g. -opt%20arg translates to -opt arg).
1051                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
1052                         push @{$useradd{CFLAGS}}, $_;
1053                         push @{$useradd{CXXFLAGS}}, $_;
1054                         }
1055                 }
1056         elsif (m|^/|)
1057                 {
1058                 # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
1059                 # This provides a simple way to pass options with arguments separated
1060                 # by spaces without quoting (e.g. /opt%20arg translates to /opt arg).
1061                 $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
1062                 push @{$useradd{CFLAGS}}, $_;
1063                 push @{$useradd{CXXFLAGS}}, $_;
1064                 }
1065         else
1066                 {
1067                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
1068                 $target=$_;
1069                 }
1070         unless ($_ eq $target || /^no-/ || /^disable-/)
1071                 {
1072                 # "no-..." follows later after implied deactivations
1073                 # have been derived.  (Don't take this too seriously,
1074                 # we really only write OPTIONS to the Makefile out of
1075                 # nostalgia.)
1076
1077                 if ($config{options} eq "")
1078                         { $config{options} = $_; }
1079                 else
1080                         { $config{options} .= " ".$_; }
1081                 }
1082         }
1083
1084 if (keys %deprecated_options)
1085         {
1086         warn "***** Deprecated options: ",
1087                 join(", ", keys %deprecated_options), "\n";
1088         }
1089 if (keys %unsupported_options)
1090         {
1091         die "***** Unsupported options: ",
1092                 join(", ", keys %unsupported_options), "\n";
1093         }
1094
1095 # If any %useradd entry has been set, we must check that the "make
1096 # variables" haven't been set.  We start by checking of any %useradd entry
1097 # is set.
1098 if (grep { scalar @$_ > 0 } values %useradd) {
1099     # Hash of env / make variables names.  The possible values are:
1100     # 1 - "make vars"
1101     # 2 - %useradd entry set
1102     # 3 - both set
1103     my %detected_vars =
1104         map { my $v = 0;
1105               $v += 1 if $cmdvars{$_};
1106               $v += 2 if @{$useradd{$_}};
1107               $_ => $v }
1108         keys %useradd;
1109
1110     # If any of the corresponding "make variables" is set, we error
1111     if (grep { $_ & 1 } values %detected_vars) {
1112         my $names = join(', ', grep { $detected_vars{$_} > 0 }
1113                                sort keys %detected_vars);
1114         die <<"_____";
1115 ***** Mixing make variables and additional compiler/linker flags as
1116 ***** configure command line option is not permitted.
1117 ***** Affected make variables: $names
1118 _____
1119     }
1120 }
1121
1122 # Check through all supported command line variables to see if any of them
1123 # were set, and canonicalise the values we got.  If no compiler or linker
1124 # flag or anything else that affects %useradd was set, we also check the
1125 # environment for values.
1126 my $anyuseradd =
1127     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
1128 foreach (keys %user) {
1129     my $value = $cmdvars{$_};
1130     $value //= env($_) unless $anyuseradd;
1131     $value //=
1132         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
1133     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
1134         unless $anyuseradd;
1135
1136     if (defined $value) {
1137         if (ref $user{$_} eq 'ARRAY') {
1138             if ($_ eq 'CPPDEFINES' || $_ eq 'CPPINCLUDES') {
1139                 $user{$_} = [ split /$list_separator_re/, $value ];
1140             } else {
1141                 $user{$_} = [ $value ];
1142             }
1143         } elsif (!defined $user{$_}) {
1144             $user{$_} = $value;
1145         }
1146     }
1147 }
1148
1149 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1150     && !$disabled{shared}
1151     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1152     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1153         "***** any of asan, msan or ubsan\n";
1154 }
1155
1156 # If no target was given, try guessing.
1157 unless ($target) {
1158     my %system_config = OpenSSL::config::get_platform(%guess_opts, %user);
1159
1160     # The $system_config{disable} is used to populate %disabled with
1161     # entries that aren't already there.
1162     foreach ( @{$system_config{disable} // []} ) {
1163         $disabled{$_} = 'system' unless defined $disabled{$_};
1164     }
1165     delete $system_config{disable};
1166
1167     # Override config entries with stuff from the guesser.
1168     # It's assumed that this really is nothing new.
1169     %config = ( %config, %system_config );
1170     $target = $system_config{target};
1171 }
1172
1173 sub disable {
1174     my $disable_type = shift;
1175
1176     for (@_) {
1177         $disabled{$_} = $disable_type;
1178     }
1179
1180     my @tocheckfor = (@_ ? @_ : keys %disabled);
1181     while (@tocheckfor) {
1182         my %new_tocheckfor = ();
1183         my @cascade_copy = (@disable_cascades);
1184         while (@cascade_copy) {
1185             my ($test, $descendents) =
1186                 (shift @cascade_copy, shift @cascade_copy);
1187             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1188                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1189                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1190                 }
1191             }
1192         }
1193         @tocheckfor = (keys %new_tocheckfor);
1194     }
1195 }
1196 disable();                     # First cascade run
1197
1198 our $die = sub { die @_; };
1199 if ($target eq "TABLE") {
1200     local $die = sub { warn @_; };
1201     foreach (sort keys %table) {
1202         print_table_entry($_, "TABLE");
1203     }
1204     exit 0;
1205 }
1206
1207 if ($target eq "LIST") {
1208     foreach (sort keys %table) {
1209         print $_,"\n" unless $table{$_}->{template};
1210     }
1211     exit 0;
1212 }
1213
1214 if ($target eq "HASH") {
1215     local $die = sub { warn @_; };
1216     print "%table = (\n";
1217     foreach (sort keys %table) {
1218         print_table_entry($_, "HASH");
1219     }
1220     exit 0;
1221 }
1222
1223 print "Configuring OpenSSL version $config{full_version} ";
1224 print "for target $target\n";
1225
1226 if (scalar(@seed_sources) == 0) {
1227     print "Using os-specific seed configuration\n";
1228     push @seed_sources, 'os';
1229 }
1230 if (scalar(grep { $_ eq 'egd' } @seed_sources) > 0) {
1231     delete $disabled{'egd'};
1232 }
1233 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1234     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1235     warn <<_____ if scalar(@seed_sources) == 1;
1236
1237 ============================== WARNING ===============================
1238 You have selected the --with-rand-seed=none option, which effectively
1239 disables automatic reseeding of the OpenSSL random generator.
1240 All operations depending on the random generator such as creating keys
1241 will not work unless the random generator is seeded manually by the
1242 application.
1243
1244 Please read the 'Note on random number generation' section in the
1245 INSTALL.md instructions and the RAND_DRBG(7) manual page for more
1246 details.
1247 ============================== WARNING ===============================
1248
1249 _____
1250 }
1251 push @{$config{openssl_feature_defines}},
1252      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1253         @seed_sources;
1254
1255 # Backward compatibility?
1256 if ($target =~ m/^CygWin32(-.*)$/) {
1257     $target = "Cygwin".$1;
1258 }
1259
1260 # Support for legacy targets having a name starting with 'debug-'
1261 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1262 if ($d) {
1263     $config{build_type} = "debug";
1264
1265     # If we do not find debug-foo in the table, the target is set to foo.
1266     if (!$table{$target}) {
1267         $target = $t;
1268     }
1269 }
1270
1271 if ($target) {
1272     # It's possible that we have different config targets for specific
1273     # toolchains, so we try to detect them, and go for the plain config
1274     # target if not.
1275     my $found;
1276     foreach ( ( "$target-$user{CC}", "$target", undef ) ) {
1277         $found=$_ if $table{$_} && !$table{$_}->{template};
1278         last if $found;
1279     }
1280     $target = $found;
1281 } else {
1282     # If we don't have a config target now, we try the C compiler as we
1283     # fallback
1284     my $cc = $user{CC} // 'cc';
1285     $target = $cc if $table{$cc} && !$table{$cc}->{template};
1286 }
1287
1288 &usage unless $target;
1289
1290 exit 0 if $dryrun;              # From older 'config'
1291
1292 $config{target} = $target;
1293 my %target = resolve_config($target);
1294
1295 foreach (keys %target_attr_translate) {
1296     $target{$target_attr_translate{$_}} = $target{$_}
1297         if $target{$_};
1298     delete $target{$_};
1299 }
1300
1301 %target = ( %{$table{DEFAULTS}}, %target );
1302
1303 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1304 $config{conf_files} = [ sort keys %conf_files ];
1305
1306 # Using sub disable within these loops may prove fragile, so we run
1307 # a cascade afterwards
1308 foreach my $feature (@{$target{disable}}) {
1309     if (exists $deprecated_disablables{$feature}) {
1310         warn "***** config $target disables deprecated feature $feature\n";
1311     } elsif (!grep { $feature eq $_ } @disablables) {
1312         die "***** config $target disables unknown feature $feature\n";
1313     }
1314     $disabled{$feature} = 'config';
1315 }
1316 foreach my $feature (@{$target{enable}}) {
1317     if ("default" eq ($disabled{$feature} // "")) {
1318         if (exists $deprecated_disablables{$feature}) {
1319             warn "***** config $target enables deprecated feature $feature\n";
1320         } elsif (!grep { $feature eq $_ } @disablables) {
1321             die "***** config $target enables unknown feature $feature\n";
1322         }
1323         delete $disabled{$feature};
1324     }
1325 }
1326
1327 # If uplink_arch isn't defined, disable uplink
1328 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1329 # If asm_arch isn't defined, disable asm
1330 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1331
1332 disable();                      # Run a cascade now
1333
1334 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1335 $target{cxxflags}//=$target{cflags} if $target{CXX};
1336 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1337 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1338
1339 # Fill %config with values from %user, and in case those are undefined or
1340 # empty, use values from %target (acting as a default).
1341 foreach (keys %user) {
1342     my $ref_type = ref $user{$_};
1343
1344     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1345     # and a value that's to be coerced into that type.
1346     my $mkvalue = sub {
1347         my $type = shift;
1348         my $value = shift;
1349         my $undef_p = shift;
1350
1351         die "Too many arguments for \$mkvalue" if @_;
1352
1353         while (ref $value eq 'CODE') {
1354             $value = $value->();
1355         }
1356
1357         if ($type eq 'ARRAY') {
1358             return undef unless defined $value;
1359             return undef if ref $value ne 'ARRAY' && !$value;
1360             return undef if ref $value eq 'ARRAY' && !@$value;
1361             return [ $value ] unless ref $value eq 'ARRAY';
1362         }
1363         return undef unless $value;
1364         return $value;
1365     };
1366
1367     $config{$_} =
1368         $mkvalue->($ref_type, $user{$_})
1369         || $mkvalue->($ref_type, $target{$_});
1370     delete $config{$_} unless defined $config{$_};
1371 }
1372
1373 # Finish up %config by appending things the user gave us on the command line
1374 # apart from "make variables"
1375 foreach (keys %useradd) {
1376     # The must all be lists, so we assert that here
1377     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1378         unless ref $useradd{$_} eq 'ARRAY';
1379
1380     if (defined $config{$_}) {
1381         push @{$config{$_}}, @{$useradd{$_}};
1382     } else {
1383         $config{$_} = [ @{$useradd{$_}} ];
1384     }
1385 }
1386 # At this point, we can forget everything about %user and %useradd,
1387 # because it's now all been merged into the corresponding $config entry
1388
1389 # Allow overriding the build file name
1390 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1391
1392 # Make sure build_scheme is consistent.
1393 $target{build_scheme} = [ $target{build_scheme} ]
1394     if ref($target{build_scheme}) ne "ARRAY";
1395
1396 my ($builder, $builder_platform, @builder_opts) =
1397     @{$target{build_scheme}};
1398
1399 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1400                       $builder_platform."-checker.pm")) {
1401     my $checker_path = catfile($srcdir, "Configurations", $checker);
1402     if (-f $checker_path) {
1403         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1404             ? sub { warn $@; } : sub { die $@; };
1405         if (! do $checker_path) {
1406             if ($@) {
1407                 $fn->($@);
1408             } elsif ($!) {
1409                 $fn->($!);
1410             } else {
1411                 $fn->("The detected tools didn't match the platform\n");
1412             }
1413         }
1414         last;
1415     }
1416 }
1417
1418 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1419
1420 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1421         {
1422         push @{$config{cflags}}, "-mno-cygwin";
1423         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1424         push @{$config{shared_ldflag}}, "-mno-cygwin";
1425         }
1426
1427 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1428         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1429         # minimally required architecture flags for assembly modules
1430         my $value;
1431         $value = '-mips2' if ($target =~ /mips32/);
1432         $value = '-mips3' if ($target =~ /mips64/);
1433         unshift @{$config{cflags}}, $value;
1434         unshift @{$config{cxxflags}}, $value if $config{CXX};
1435 }
1436
1437 # If threads aren't disabled, check how possible they are
1438 unless ($disabled{threads}) {
1439     if ($auto_threads) {
1440         # Enabled by default, disable it forcibly if unavailable
1441         if ($target{thread_scheme} eq "(unknown)") {
1442             disable("unavailable", 'threads');
1443         }
1444     } else {
1445         # The user chose to enable threads explicitly, let's see
1446         # if there's a chance that's possible
1447         if ($target{thread_scheme} eq "(unknown)") {
1448             # If the user asked for "threads" and we don't have internal
1449             # knowledge how to do it, [s]he is expected to provide any
1450             # system-dependent compiler options that are necessary.  We
1451             # can't truly check that the given options are correct, but
1452             # we expect the user to know what [s]He is doing.
1453             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1454                 die "You asked for multi-threading support, but didn't\n"
1455                     ,"provide any system-specific compiler options\n";
1456             }
1457         }
1458     }
1459 }
1460
1461 # Find out if clang's sanitizers have been enabled with -fsanitize
1462 # flags and ensure that the corresponding %disabled elements area
1463 # removed to reflect that the sanitizers are indeed enabled.
1464 my %detected_sanitizers = ();
1465 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1466     (my $checks = $_) =~ s/^-fsanitize=//;
1467     foreach (split /,/, $checks) {
1468         my $d = { address       => 'asan',
1469                   undefined     => 'ubsan',
1470                   memory        => 'msan' } -> {$_};
1471         next unless defined $d;
1472
1473         $detected_sanitizers{$d} = 1;
1474         if (defined $disabled{$d}) {
1475             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1476                 if $disabled{$d} ne "default";
1477             delete $disabled{$d};
1478         }
1479     }
1480 }
1481
1482 # If threads still aren't disabled, add a C macro to ensure the source
1483 # code knows about it.  Any other flag is taken care of by the configs.
1484 unless($disabled{threads}) {
1485     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1486 }
1487
1488 my $no_shared_warn=0;
1489 if (($target{shared_target} // '') eq "")
1490         {
1491         $no_shared_warn = 1
1492             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1493         disable('no-shared-target', 'pic');
1494         }
1495
1496 if ($disabled{"dynamic-engine"}) {
1497         $config{dynamic_engines} = 0;
1498 } else {
1499         $config{dynamic_engines} = 1;
1500 }
1501
1502 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1503     push @{$config{cflags}}, "-fsanitize=address";
1504 }
1505
1506 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1507     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1508     # platforms.
1509     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1510 }
1511
1512 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1513   push @{$config{cflags}}, "-fsanitize=memory";
1514 }
1515
1516 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1517         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1518     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1519     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1520 }
1521 #
1522 # Platform fix-ups
1523 #
1524
1525 # This saves the build files from having to check
1526 if ($disabled{pic})
1527         {
1528         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1529                     shared_defines shared_includes shared_ldflag
1530                     module_cflags module_cxxflags module_cppflags
1531                     module_defines module_includes module_lflags))
1532                 {
1533                 delete $config{$_};
1534                 $target{$_} = "";
1535                 }
1536         }
1537 else
1538         {
1539         push @{$config{lib_defines}}, "OPENSSL_PIC";
1540         }
1541
1542 if ($target{sys_id} ne "")
1543         {
1544         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1545         }
1546
1547 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1548 my %predefined_CXX = $config{CXX}
1549     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1550     : ();
1551
1552 unless ($disabled{asm}) {
1553     # big endian systems can use ELFv2 ABI
1554     if ($target eq "linux-ppc64") {
1555         $target{perlasm_scheme} = "linux64v2" if ($predefined_C{_CALL_ELF} == 2);
1556     }
1557 }
1558
1559 # Check for makedepend capabilities.
1560 if (!$disabled{makedepend}) {
1561     # If the attribute makedep_scheme is defined, then we assume that the
1562     # config target and its associated build file are programmed to deal
1563     # with it.
1564     # If makedep_scheme is undefined, we go looking for GCC compatible
1565     # dependency making, and if that's not available, we try to fall back
1566     # on 'makedepend'.
1567     if ($target{makedep_scheme}) {
1568         $config{makedep_scheme} = $target{makedep_scheme};
1569         # If the makedepcmd attribute is defined, copy it.  If not, the
1570         # build files will have to fend for themselves.
1571         $config{makedepcmd} = $target{makedepcmd} if $target{makedepcmd};
1572     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1573              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1574         # We know that GNU C version 3 and up as well as all clang
1575         # versions support dependency generation, but Xcode did not
1576         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1577         $config{makedep_scheme} = 'gcc';
1578     } else {
1579         # In all other cases, we look for 'makedepend', and set the
1580         # makedep_scheme value if we found it.
1581         $config{makedepcmd} = which('makedepend');
1582         $config{makedep_scheme} = 'makedepend' if $config{makedepcmd};
1583     }
1584
1585     # If no depend scheme is set, we disable makedepend
1586     disable('unavailable', 'makedepend') unless $config{makedep_scheme};
1587 }
1588
1589 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1590     # probe for -Wa,--noexecstack option...
1591     if ($predefined_C{__clang__}) {
1592         # clang has builtin assembler, which doesn't recognize --help,
1593         # but it apparently recognizes the option in question on all
1594         # supported platforms even when it's meaningless. In other words
1595         # probe would fail, but probed option always accepted...
1596         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1597     } else {
1598         my $cc = $config{CROSS_COMPILE}.$config{CC};
1599         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1600         while(<PIPE>) {
1601             if (m/--noexecstack/) {
1602                 push @{$config{cflags}}, "-Wa,--noexecstack";
1603                 last;
1604             }
1605         }
1606         close(PIPE);
1607         unlink("null.$$.o");
1608     }
1609 }
1610
1611 # Deal with bn_ops ###################################################
1612
1613 $config{bn_ll}                  =0;
1614 my $def_int="unsigned int";
1615 $config{rc4_int}                =$def_int;
1616 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1617
1618 my $count = 0;
1619 foreach (sort split(/\s+/,$target{bn_ops})) {
1620     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1621     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1622     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1623     ($config{b64l},$config{b64},$config{b32})
1624         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1625     ($config{b64l},$config{b64},$config{b32})
1626         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1627     ($config{b64l},$config{b64},$config{b32})
1628         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1629 }
1630 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1631     if $count > 1;
1632
1633 $config{api} = $config{major} * 10000 + $config{minor} * 100
1634     unless $config{api};
1635 foreach (keys %$apitable) {
1636     $disabled{"deprecated-$_"} = "deprecation"
1637         if $disabled{deprecated} && $config{api} >= $apitable->{$_};
1638 }
1639
1640 disable();                      # Run a cascade now
1641
1642 # Hack cflags for better warnings (dev option) #######################
1643
1644 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1645 # a string and works as well on command lines.
1646 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1647                         @{$config{cflags}} ];
1648 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1649                           @{$config{cxxflags}} ] if $config{CXX};
1650
1651 $config{openssl_api_defines} = [
1652     "OPENSSL_CONFIGURED_API=".$config{api},
1653 ];
1654
1655 my @strict_warnings_collection=();
1656 if ($strict_warnings)
1657         {
1658         my $wopt;
1659         my $gccver = $predefined_C{__GNUC__} // -1;
1660
1661         if ($gccver >= 4)
1662                 {
1663                 push @strict_warnings_collection, @gcc_devteam_warn;
1664                 push @strict_warnings_collection, @clang_devteam_warn
1665                     if (defined($predefined_C{__clang__}));
1666                 }
1667         elsif ($config{target} =~ /^VC-/)
1668                 {
1669                 push @strict_warnings_collection, @cl_devteam_warn;
1670                 }
1671         else
1672                 {
1673                 warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike, or MSVC"
1674                 }
1675         }
1676
1677 if (grep { $_ =~ /(?:^|\s)-static(?:\s|$)/ } @{$config{LDFLAGS}}) {
1678     disable('static', 'pic', 'threads');
1679 }
1680
1681 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1682                               ? @strict_warnings_collection
1683                               : ( $_ ) }
1684                     @{$config{CFLAGS}} ];
1685
1686 unless ($disabled{afalgeng}) {
1687     $config{afalgeng}="";
1688     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1689         my $minver = 4*10000 + 1*100 + 0;
1690         if ($config{CROSS_COMPILE} eq "") {
1691             my $verstr = `uname -r`;
1692             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1693             ($mi2) = $mi2 =~ /(\d+)/;
1694             my $ver = $ma*10000 + $mi1*100 + $mi2;
1695             if ($ver < $minver) {
1696                 disable('too-old-kernel', 'afalgeng');
1697             } else {
1698                 push @{$config{engdirs}}, "afalg";
1699             }
1700         } else {
1701             disable('cross-compiling', 'afalgeng');
1702         }
1703     } else {
1704         disable('not-linux', 'afalgeng');
1705     }
1706 }
1707
1708 unless ($disabled{devcryptoeng}) {
1709     if ($target =~ m/^BSD/) {
1710         my $maxver = 5*100 + 7;
1711         my $sysstr = `uname -s`;
1712         my $verstr = `uname -r`;
1713         $sysstr =~ s|\R$||;
1714         $verstr =~ s|\R$||;
1715         my ($ma, $mi, @rest) = split m|\.|, $verstr;
1716         my $ver = $ma*100 + $mi;
1717         if ($sysstr eq 'OpenBSD' && $ver >= $maxver) {
1718             disable('too-new-kernel', 'devcryptoeng');
1719         }
1720     }
1721 }
1722
1723 unless ($disabled{ktls}) {
1724     $config{ktls}="";
1725     if ($target =~ m/^linux/) {
1726         my $usr = "/usr/$config{cross_compile_prefix}";
1727         chop($usr);
1728         if ($config{cross_compile_prefix} eq "") {
1729             $usr = "/usr";
1730         }
1731         my $minver = (4 << 16) + (13 << 8) + 0;
1732         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1733
1734         if ($verstr[2] < $minver) {
1735             disable('too-old-kernel', 'ktls');
1736         }
1737     } elsif ($target =~ m/^BSD/) {
1738         my $cc = $config{CROSS_COMPILE}.$config{CC};
1739         system("printf '#include <sys/types.h>\n#include <sys/ktls.h>' | $cc -E - >/dev/null 2>&1");
1740         if ($? != 0) {
1741             disable('too-old-freebsd', 'ktls');
1742         }
1743     } else {
1744         disable('not-linux-or-freebsd', 'ktls');
1745     }
1746 }
1747
1748 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1749
1750 # Get the extra flags used when building shared libraries and modules.  We
1751 # do this late because some of them depend on %disabled.
1752
1753 # Make the flags to build DSOs the same as for shared libraries unless they
1754 # are already defined
1755 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1756 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1757 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1758 {
1759     my $shared_info_pl =
1760         catfile(dirname($0), "Configurations", "shared-info.pl");
1761     my %shared_info = read_eval_file($shared_info_pl);
1762     push @{$target{_conf_fname_int}}, $shared_info_pl;
1763     my $si = $target{shared_target};
1764     while (ref $si ne "HASH") {
1765         last if ! defined $si;
1766         if (ref $si eq "CODE") {
1767             $si = $si->();
1768         } else {
1769             $si = $shared_info{$si};
1770         }
1771     }
1772
1773     # Some of the 'shared_target' values don't have any entries in
1774     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1775     # template knows how to handle this.  That is currently the case for
1776     # Windows and VMS.
1777     if (defined $si) {
1778         # Just as above, copy certain shared_* attributes to the corresponding
1779         # module_ attribute unless the latter is already defined
1780         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1781         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1782         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1783         foreach (sort keys %$si) {
1784             $target{$_} = defined $target{$_}
1785                 ? add($si->{$_})->($target{$_})
1786                 : $si->{$_};
1787         }
1788     }
1789 }
1790
1791 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1792
1793 ######################################################################
1794 # Build up information for skipping certain directories depending on disabled
1795 # features, as well as setting up macros for disabled features.
1796
1797 # This is a tentative database of directories to skip.  Some entries may not
1798 # correspond to anything real, but that's ok, they will simply be ignored.
1799 # The actual processing of these entries is done in the build.info lookup
1800 # loop further down.
1801 #
1802 # The key is a Unix formatted path in the source tree, the value is an index
1803 # into %disabled_info, so any existing path gets added to a corresponding
1804 # 'skipped' entry in there with the list of skipped directories.
1805 my %skipdir = ();
1806 my %disabled_info = ();         # For configdata.pm
1807 foreach my $what (sort keys %disabled) {
1808     # There are deprecated disablables that translate to themselves.
1809     # They cause disabling cascades, but should otherwise not regiter.
1810     next if $deprecated_disablables{$what};
1811     # The generated $disabled{"deprecated-x.y"} entries are special
1812     # and treated properly elsewhere
1813     next if $what =~ m|^deprecated-|;
1814
1815     $config{options} .= " no-$what";
1816
1817     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1818                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1819                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1820         (my $WHAT = uc $what) =~ s|-|_|g;
1821         my $skipdir = $what;
1822
1823         # fix-up crypto/directory name(s)
1824         $skipdir = "ripemd" if $what eq "rmd160";
1825         $skipdir = "whrlpool" if $what eq "whirlpool";
1826
1827         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1828         push @{$config{openssl_feature_defines}}, $macro;
1829
1830         $skipdir{engines} = $what if $what eq 'engine';
1831         $skipdir{"crypto/$skipdir"} = $what
1832             unless $what eq 'async' || $what eq 'err' || $what eq 'dso';
1833     }
1834 }
1835
1836 if ($disabled{"dynamic-engine"}) {
1837     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1838 } else {
1839     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1840 }
1841
1842 # If we use the unified build, collect information from build.info files
1843 my %unified_info = ();
1844
1845 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1846 if ($builder eq "unified") {
1847     use Text::Template 1.46;
1848
1849     sub cleandir {
1850         my $base = shift;
1851         my $dir = shift;
1852         my $relativeto = shift || ".";
1853
1854         $dir = catdir($base,$dir) unless isabsolute($dir);
1855
1856         # Make sure the directories we're building in exists
1857         mkpath($dir);
1858
1859         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1860         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1861         return $res;
1862     }
1863
1864     sub cleanfile {
1865         my $base = shift;
1866         my $file = shift;
1867         my $relativeto = shift || ".";
1868
1869         $file = catfile($base,$file) unless isabsolute($file);
1870
1871         my $d = dirname($file);
1872         my $f = basename($file);
1873
1874         # Make sure the directories we're building in exists
1875         mkpath($d);
1876
1877         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1878         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1879         return $res;
1880     }
1881
1882     # Store the name of the template file we will build the build file from
1883     # in %config.  This may be useful for the build file itself.
1884     my @build_file_template_names =
1885         ( $builder_platform."-".$target{build_file}.".tmpl",
1886           $target{build_file}.".tmpl" );
1887     my @build_file_templates = ();
1888
1889     # First, look in the user provided directory, if given
1890     if (defined env($local_config_envname)) {
1891         @build_file_templates =
1892             map {
1893                 if ($^O eq 'VMS') {
1894                     # VMS environment variables are logical names,
1895                     # which can be used as is
1896                     $local_config_envname . ':' . $_;
1897                 } else {
1898                     catfile(env($local_config_envname), $_);
1899                 }
1900             }
1901             @build_file_template_names;
1902     }
1903     # Then, look in our standard directory
1904     push @build_file_templates,
1905         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1906           @build_file_template_names );
1907
1908     my $build_file_template;
1909     for $_ (@build_file_templates) {
1910         $build_file_template = $_;
1911         last if -f $build_file_template;
1912
1913         $build_file_template = undef;
1914     }
1915     if (!defined $build_file_template) {
1916         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1917     }
1918     $config{build_file_templates}
1919       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1920                     $blddir),
1921            $build_file_template ];
1922
1923     my @build_dirs = ( [ ] );   # current directory
1924
1925     $config{build_infos} = [ ];
1926
1927     # We want to detect configdata.pm in the source tree, so we
1928     # don't use it if the build tree is different.
1929     my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1930
1931     # Any source file that we recognise is placed in this hash table, with
1932     # the list of its intended destinations as value.  When everything has
1933     # been collected, there's a routine that checks that these source files
1934     # exist, or if they are generated, that the generator exists.
1935     my %check_exist = ();
1936     my %check_generate = ();
1937
1938     my %ordinals = ();
1939     while (@build_dirs) {
1940         my @curd = @{shift @build_dirs};
1941         my $sourced = catdir($srcdir, @curd);
1942         my $buildd = catdir($blddir, @curd);
1943
1944         my $unixdir = join('/', @curd);
1945         if (exists $skipdir{$unixdir}) {
1946             my $what = $skipdir{$unixdir};
1947             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1948             next;
1949         }
1950
1951         mkpath($buildd);
1952
1953         my $f = 'build.info';
1954         # The basic things we're trying to build
1955         my @programs = ();
1956         my @libraries = ();
1957         my @modules = ();
1958         my @scripts = ();
1959
1960         my %sources = ();
1961         my %shared_sources = ();
1962         my %includes = ();
1963         my %defines = ();
1964         my %depends = ();
1965         my %generate = ();
1966         my %htmldocs = ();
1967         my %mandocs = ();
1968
1969         # Support for $variablename in build.info files.
1970         # Embedded perl code is the ultimate master, still.  If its output
1971         # contains a dollar sign, it had better be escaped, or it will be
1972         # taken for a variable name prefix.
1973         my %variables = ();
1974         # Variable name syntax
1975         my $variable_name_re = qr/(?P<VARIABLE>[[:alpha:]][[:alnum:]_]*)/;
1976         # Value modifier syntaxes
1977         my $variable_subst_re = qr/\/(?P<RE>(?:\\\/|.)*?)\/(?P<SUBST>.*?)/;
1978         # Variable reference
1979         my $variable_simple_re = qr/(?<!\\)\$${variable_name_re}/;
1980         my $variable_w_mod_re =
1981             qr/(?<!\\)\$\{${variable_name_re}(?P<MOD>(?:\\\/|.)*?)\}/;
1982         # Tie it all together
1983         my $variable_re = qr/${variable_simple_re}|${variable_w_mod_re}/;
1984
1985         my $expand_variables = sub {
1986             my $value = '';
1987             my $value_rest = shift;
1988
1989             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1990                 print STDERR
1991                     "DEBUG[\$expand_variables] Parsed '$value_rest' ...\n"
1992             }
1993
1994             while ($value_rest =~ /${variable_re}/) {
1995                 # We must save important regexp values, because the next
1996                 # regexp clears them
1997                 my $mod = $+{MOD};
1998                 my $variable_value = $variables{$+{VARIABLE}};
1999
2000                 $value_rest = $';
2001                 $value .= $`;
2002
2003                 # Process modifier expressions, if present
2004                 if (defined $mod) {
2005                     if ($mod =~ /^${variable_subst_re}$/) {
2006                         my $re = $+{RE};
2007                         my $subst = $+{SUBST};
2008
2009                         $variable_value =~ s/\Q$re\E/$subst/g;
2010
2011                         if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2012                             print STDERR
2013                                 "DEBUG[\$expand_variables] ... and substituted ",
2014                                 "'$re' with '$subst'\n";
2015                         }
2016                     }
2017                 }
2018
2019                 $value .= $variable_value;
2020             }
2021             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2022                 print STDERR
2023                     "DEBUG[\$expand_variables] ... into: '$value$value_rest'\n";
2024             }
2025             return $value . $value_rest;
2026         };
2027
2028         # Support for attributes in build.info files
2029         my %attributes = ();
2030         my $handle_attributes = sub {
2031             my $attr_str = shift;
2032             my $ref = shift;
2033             my @goals = @_;
2034
2035             return unless defined $attr_str;
2036
2037             my @a = tokenize($attr_str, qr|\s*,\s*|);
2038             foreach my $a (@a) {
2039                 my $ac = 1;
2040                 my $ak = $a;
2041                 my $av = 1;
2042                 if ($a =~ m|^(!)?(.*?)\s* = \s*(.*?)$|x) {
2043                     $ac = ! $1;
2044                     $ak = $2;
2045                     $av = $3;
2046                 }
2047                 foreach my $g (@goals) {
2048                     if ($ac) {
2049                         $$ref->{$g}->{$ak} = $av;
2050                     } else {
2051                         delete $$ref->{$g}->{$ak};
2052                     }
2053                 }
2054             }
2055         };
2056
2057         # Support for pushing values on multiple indexes of a given hash
2058         # array.
2059         my $push_to = sub {
2060             my $valueref = shift;
2061             my $index_str = shift; # May be undef or empty
2062             my $attrref = shift;   # May be undef
2063             my $attr_str = shift;
2064             my @values = @_;
2065
2066             if (defined $index_str) {
2067                 my @indexes = ( '' );
2068                 if ($index_str !~ m|^\s*$|) {
2069                     @indexes = tokenize($index_str);
2070                 }
2071                 foreach (@indexes) {
2072                     push @{$valueref->{$_}}, @values;
2073                     if (defined $attrref) {
2074                         $handle_attributes->($attr_str, \$$attrref->{$_},
2075                                              @values);
2076                     }
2077                 }
2078             } else {
2079                 push @$valueref, @values;
2080                 $handle_attributes->($attr_str, $attrref, @values)
2081                     if defined $attrref;
2082             }
2083         };
2084
2085         if ($buildinfo_debug) {
2086             print STDERR "DEBUG: Reading ",catfile($sourced, $f),"\n";
2087         }
2088         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
2089         my $template =
2090             Text::Template->new(TYPE => 'FILE',
2091                                 SOURCE => catfile($sourced, $f),
2092                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
2093         die "Something went wrong with $sourced/$f: $!\n" unless $template;
2094         my @text =
2095             split /^/m,
2096             $template->fill_in(HASH => { config => \%config,
2097                                          target => \%target,
2098                                          disabled => \%disabled,
2099                                          withargs => \%withargs,
2100                                          builddir => abs2rel($buildd, $blddir),
2101                                          sourcedir => abs2rel($sourced, $blddir),
2102                                          buildtop => abs2rel($blddir, $blddir),
2103                                          sourcetop => abs2rel($srcdir, $blddir) },
2104                                DELIMITERS => [ "{-", "-}" ]);
2105
2106         # The top item of this stack has the following values
2107         # -2 positive already run and we found ELSE (following ELSIF should fail)
2108         # -1 positive already run (skip until ENDIF)
2109         # 0 negatives so far (if we're at a condition, check it)
2110         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
2111         # 2 positive ELSE (following ELSIF should fail)
2112         my @skip = ();
2113
2114         # A few useful generic regexps
2115         my $index_re = qr/\[\s*(?P<INDEX>(?:\\.|.)*?)\s*\]/;
2116         my $cond_re = qr/\[\s*(?P<COND>(?:\\.|.)*?)\s*\]/;
2117         my $attribs_re = qr/(?:\{\s*(?P<ATTRIBS>(?:\\.|.)*?)\s*\})?/;
2118         my $value_re = qr/\s*(?P<VALUE>.*?)\s*/;
2119         collect_information(
2120             collect_from_array([ @text ],
2121                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
2122                                                 $l1 =~ s/\\$//; $l1.$l2 }),
2123             # Info we're looking for
2124             qr/^\s* IF ${cond_re} \s*$/x
2125             => sub {
2126                 if (! @skip || $skip[$#skip] > 0) {
2127                     push @skip, !! $expand_variables->($+{COND});
2128                 } else {
2129                     push @skip, -1;
2130                 }
2131             },
2132             qr/^\s* ELSIF ${cond_re} \s*$/x
2133             => sub { die "ELSIF out of scope" if ! @skip;
2134                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
2135                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
2136                      $skip[$#skip] = !! $expand_variables->($+{COND})
2137                          if $skip[$#skip] == 0; },
2138             qr/^\s* ELSE \s*$/x
2139             => sub { die "ELSE out of scope" if ! @skip;
2140                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
2141                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
2142             qr/^\s* ENDIF \s*$/x
2143             => sub { die "ENDIF out of scope" if ! @skip;
2144                      pop @skip; },
2145             qr/^\s* ${variable_re} \s* = ${value_re} $/x
2146             => sub {
2147                 if (!@skip || $skip[$#skip] > 0) {
2148                     $variables{$+{VARIABLE}} = $expand_variables->($+{VALUE});
2149                 }
2150             },
2151             qr/^\s* SUBDIRS \s* = ${value_re} $/x
2152             => sub {
2153                 if (!@skip || $skip[$#skip] > 0) {
2154                     foreach (tokenize($expand_variables->($+{VALUE}))) {
2155                         push @build_dirs, [ @curd, splitdir($_, 1) ];
2156                     }
2157                 }
2158             },
2159             qr/^\s* PROGRAMS ${attribs_re} \s* =  ${value_re} $/x
2160             => sub { $push_to->(\@programs, undef,
2161                                 \$attributes{programs}, $+{ATTRIBS},
2162                                 tokenize($expand_variables->($+{VALUE})))
2163                          if !@skip || $skip[$#skip] > 0; },
2164             qr/^\s* LIBS ${attribs_re} \s* =  ${value_re} $/x
2165             => sub { $push_to->(\@libraries, undef,
2166                                 \$attributes{libraries}, $+{ATTRIBS},
2167                                 tokenize($expand_variables->($+{VALUE})))
2168                          if !@skip || $skip[$#skip] > 0; },
2169             qr/^\s* MODULES ${attribs_re} \s* =  ${value_re} $/x
2170             => sub { $push_to->(\@modules, undef,
2171                                 \$attributes{modules}, $+{ATTRIBS},
2172                                 tokenize($expand_variables->($+{VALUE})))
2173                          if !@skip || $skip[$#skip] > 0; },
2174             qr/^\s* SCRIPTS ${attribs_re} \s* =  ${value_re} $/x
2175             => sub { $push_to->(\@scripts, undef,
2176                                 \$attributes{scripts}, $+{ATTRIBS},
2177                                 tokenize($expand_variables->($+{VALUE})))
2178                          if !@skip || $skip[$#skip] > 0; },
2179             qr/^\s* HTMLDOCS ${index_re} = ${value_re} $/x
2180             => sub { $push_to->(\%htmldocs, $expand_variables->($+{INDEX}),
2181                                 undef, undef,
2182                                 tokenize($expand_variables->($+{VALUE})))
2183                          if !@skip || $skip[$#skip] > 0; },
2184             qr/^\s* MANDOCS ${index_re} = ${value_re} $/x
2185             => sub { $push_to->(\%mandocs, $expand_variables->($+{INDEX}),
2186                                 undef, undef,
2187                                 tokenize($expand_variables->($+{VALUE})))
2188                          if !@skip || $skip[$#skip] > 0; },
2189             qr/^\s* SOURCE ${index_re} = ${value_re} $/x
2190             => sub { $push_to->(\%sources, $expand_variables->($+{INDEX}),
2191                                 undef, undef,
2192                                 tokenize($expand_variables->($+{VALUE})))
2193                          if !@skip || $skip[$#skip] > 0; },
2194             qr/^\s* SHARED_SOURCE ${index_re} = ${value_re} $/x
2195             => sub { $push_to->(\%shared_sources, $expand_variables->($+{INDEX}),
2196                                 undef, undef,
2197                                 tokenize($expand_variables->($+{VALUE})))
2198                          if !@skip || $skip[$#skip] > 0; },
2199             qr/^\s* INCLUDE ${index_re} = ${value_re} $/x
2200             => sub { $push_to->(\%includes, $expand_variables->($+{INDEX}),
2201                                 undef, undef,
2202                                 tokenize($expand_variables->($+{VALUE})))
2203                          if !@skip || $skip[$#skip] > 0; },
2204             qr/^\s* DEFINE ${index_re} = ${value_re} $/x
2205             => sub { $push_to->(\%defines, $expand_variables->($+{INDEX}),
2206                                 undef, undef,
2207                                 tokenize($expand_variables->($+{VALUE})))
2208                          if !@skip || $skip[$#skip] > 0; },
2209             qr/^\s* DEPEND ${index_re} ${attribs_re} = ${value_re} $/x
2210             => sub { $push_to->(\%depends, $expand_variables->($+{INDEX}),
2211                                 \$attributes{depends}, $+{ATTRIBS},
2212                                 tokenize($expand_variables->($+{VALUE})))
2213                          if !@skip || $skip[$#skip] > 0; },
2214             qr/^\s* GENERATE ${index_re} = ${value_re} $/x
2215             => sub { $push_to->(\%generate, $expand_variables->($+{INDEX}),
2216                                 undef, undef, $+{VALUE})
2217                          if !@skip || $skip[$#skip] > 0; },
2218             qr/^\s* (?:\#.*)? $/x => sub { },
2219             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
2220             "BEFORE" => sub {
2221                 if ($buildinfo_debug) {
2222                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
2223                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2224                 }
2225             },
2226             "AFTER" => sub {
2227                 if ($buildinfo_debug) {
2228                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2229                 }
2230             },
2231             );
2232         die "runaway IF?" if (@skip);
2233
2234         if (grep { defined $attributes{modules}->{$_}->{engine} } keys %attributes
2235                 and !$config{dynamic_engines}) {
2236             die <<"EOF"
2237 ENGINES can only be used if configured with 'dynamic-engine'.
2238 This is usually a fault in a build.info file.
2239 EOF
2240         }
2241
2242         {
2243             my %infos = ( programs  => [ @programs  ],
2244                           libraries => [ @libraries ],
2245                           modules   => [ @modules   ],
2246                           scripts   => [ @scripts   ] );
2247             foreach my $k (keys %infos) {
2248                 foreach (@{$infos{$k}}) {
2249                     my $item = cleanfile($buildd, $_, $blddir);
2250                     $unified_info{$k}->{$item} = 1;
2251
2252                     # Fix up associated attributes
2253                     $unified_info{attributes}->{$k}->{$item} =
2254                         $attributes{$k}->{$_}
2255                         if defined $attributes{$k}->{$_};
2256                 }
2257             }
2258         }
2259
2260         # Check that we haven't defined any library as both shared and
2261         # explicitly static.  That is forbidden.
2262         my @doubles = ();
2263         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2264             (my $l = $_) =~ s/\.a$//;
2265             push @doubles, $l if defined $unified_info{libraries}->{$l};
2266         }
2267         die "these libraries are both explicitly static and shared:\n  ",
2268             join(" ", @doubles), "\n"
2269             if @doubles;
2270
2271         foreach (keys %sources) {
2272             my $dest = $_;
2273             my $ddest = cleanfile($buildd, $_, $blddir);
2274             foreach (@{$sources{$dest}}) {
2275                 my $s = cleanfile($sourced, $_, $blddir);
2276
2277                 # If it's generated or we simply don't find it in the source
2278                 # tree, we assume it's in the build tree.
2279                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2280                     $s = cleanfile($buildd, $_, $blddir);
2281                 }
2282                 # We recognise C++, C and asm files
2283                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2284                     push @{$check_exist{$s}}, $ddest;
2285                     my $o = $_;
2286                     $o =~ s/\.[csS]$/.o/; # C and assembler
2287                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2288                     $o = cleanfile($buildd, $o, $blddir);
2289                     $unified_info{sources}->{$ddest}->{$o} = -1;
2290                     $unified_info{sources}->{$o}->{$s} = -1;
2291                 } elsif ($s =~ /\.rc$/) {
2292                     # We also recognise resource files
2293                     push @{$check_exist{$s}}, $ddest;
2294                     my $o = $_;
2295                     $o =~ s/\.rc$/.res/; # Resource configuration
2296                     $o = cleanfile($buildd, $o, $blddir);
2297                     $unified_info{sources}->{$ddest}->{$o} = -1;
2298                     $unified_info{sources}->{$o}->{$s} = -1;
2299                 } else {
2300                     push @{$check_exist{$s}}, $ddest;
2301                     $unified_info{sources}->{$ddest}->{$s} = 1;
2302                 }
2303             }
2304         }
2305
2306         foreach (keys %shared_sources) {
2307             my $dest = $_;
2308             my $ddest = cleanfile($buildd, $_, $blddir);
2309             foreach (@{$shared_sources{$dest}}) {
2310                 my $s = cleanfile($sourced, $_, $blddir);
2311
2312                 # If it's generated or we simply don't find it in the source
2313                 # tree, we assume it's in the build tree.
2314                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2315                     $s = cleanfile($buildd, $_, $blddir);
2316                 }
2317
2318                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2319                     # We recognise C++, C and asm files
2320                     push @{$check_exist{$s}}, $ddest;
2321                     my $o = $_;
2322                     $o =~ s/\.[csS]$/.o/; # C and assembler
2323                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2324                     $o = cleanfile($buildd, $o, $blddir);
2325                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2326                     $unified_info{sources}->{$o}->{$s} = -1;
2327                 } elsif ($s =~ /\.rc$/) {
2328                     # We also recognise resource files
2329                     push @{$check_exist{$s}}, $ddest;
2330                     my $o = $_;
2331                     $o =~ s/\.rc$/.res/; # Resource configuration
2332                     $o = cleanfile($buildd, $o, $blddir);
2333                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2334                     $unified_info{sources}->{$o}->{$s} = -1;
2335                 } elsif ($s =~ /\.ld$/) {
2336                     # We also recognise linker scripts (or corresponding)
2337                     # We know they are generated files
2338                     push @{$check_exist{$s}}, $ddest;
2339                     my $ld = cleanfile($buildd, $_, $blddir);
2340                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2341                 } else {
2342                     die "unrecognised source file type for shared library: $s\n";
2343                 }
2344             }
2345         }
2346
2347         foreach (keys %generate) {
2348             my $dest = $_;
2349             my $ddest = cleanfile($buildd, $_, $blddir);
2350             die "more than one generator for $dest: "
2351                 ,join(" ", @{$generate{$_}}),"\n"
2352                 if scalar @{$generate{$_}} > 1;
2353             my @generator = split /\s+/, $generate{$dest}->[0];
2354             my $gen = $generator[0];
2355             $generator[0] = cleanfile($sourced, $gen, $blddir);
2356
2357             # If the generator is itself generated, it's in the build tree
2358             if ($generate{$gen} || ! -f $generator[0]) {
2359                 $generator[0] = cleanfile($buildd, $gen, $blddir);
2360             }
2361             $check_generate{$ddest}->{$generator[0]}++;
2362
2363             $unified_info{generate}->{$ddest} = [ @generator ];
2364         }
2365
2366         foreach (keys %depends) {
2367             my $dest = $_;
2368             my $ddest = $dest;
2369
2370             if ($dest =~ /^\|(.*)\|$/) {
2371                 # Collect the raw target
2372                 $unified_info{targets}->{$1} = 1;
2373                 $ddest = $1;
2374             } elsif ($dest eq '') {
2375                 $ddest = '';
2376             } else {
2377                 $ddest = cleanfile($sourced, $_, $blddir);
2378
2379                 # If the destination doesn't exist in source, it can only be
2380                 # a generated file in the build tree.
2381                 if ($ddest eq $src_configdata || ! -f $ddest) {
2382                     $ddest = cleanfile($buildd, $_, $blddir);
2383                 }
2384             }
2385             foreach (@{$depends{$dest}}) {
2386                 my $d = cleanfile($sourced, $_, $blddir);
2387                 my $d2 = cleanfile($buildd, $_, $blddir);
2388
2389                 # If we know it's generated, or assume it is because we can't
2390                 # find it in the source tree, we set file we depend on to be
2391                 # in the build tree rather than the source tree.
2392                 if ($d eq $src_configdata
2393                     || (grep { $d2 eq $_ }
2394                         keys %{$unified_info{generate}})
2395                     || ! -f $d) {
2396                     $d = $d2;
2397                 }
2398                 $unified_info{depends}->{$ddest}->{$d} = 1;
2399
2400                 # Fix up associated attributes
2401                 $unified_info{attributes}->{depends}->{$ddest}->{$d} =
2402                     $attributes{depends}->{$dest}->{$_}
2403                     if defined $attributes{depends}->{$dest}->{$_};
2404             }
2405         }
2406
2407         foreach (keys %includes) {
2408             my $dest = $_;
2409             my $ddest = cleanfile($sourced, $_, $blddir);
2410
2411             # If the destination doesn't exist in source, it can only be
2412             # a generated file in the build tree.
2413             if ($ddest eq $src_configdata || ! -f $ddest) {
2414                 $ddest = cleanfile($buildd, $_, $blddir);
2415             }
2416             foreach (@{$includes{$dest}}) {
2417                 my $is = cleandir($sourced, $_, $blddir);
2418                 my $ib = cleandir($buildd, $_, $blddir);
2419                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2420                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2421                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2422                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2423             }
2424         }
2425
2426         foreach my $dest (keys %defines) {
2427             my $ddest;
2428
2429             if ($dest ne "") {
2430                 $ddest = cleanfile($sourced, $dest, $blddir);
2431
2432                 # If the destination doesn't exist in source, it can only
2433                 # be a generated file in the build tree.
2434                 if (! -f $ddest) {
2435                     $ddest = cleanfile($buildd, $dest, $blddir);
2436                 }
2437             }
2438             foreach my $v (@{$defines{$dest}}) {
2439                 $v =~ m|^([^=]*)(=.*)?$|;
2440                 die "0 length macro name not permitted\n" if $1 eq "";
2441                 if ($dest ne "") {
2442                     die "$1 defined more than once\n"
2443                         if defined $unified_info{defines}->{$ddest}->{$1};
2444                     $unified_info{defines}->{$ddest}->{$1} = $2;
2445                 } else {
2446                     die "$1 defined more than once\n"
2447                         if grep { $v eq $_ } @{$config{defines}};
2448                     push @{$config{defines}}, $v;
2449                 }
2450             }
2451         }
2452
2453         foreach my $section (keys %htmldocs) {
2454             foreach (@{$htmldocs{$section}}) {
2455                 my $htmldocs = cleanfile($buildd, $_, $blddir);
2456                 $unified_info{htmldocs}->{$section}->{$htmldocs} = 1;
2457             }
2458         }
2459
2460         foreach my $section (keys %mandocs) {
2461             foreach (@{$mandocs{$section}}) {
2462                 my $mandocs = cleanfile($buildd, $_, $blddir);
2463                 $unified_info{mandocs}->{$section}->{$mandocs} = 1;
2464             }
2465         }
2466     }
2467
2468     my $ordinals_text = join(', ', sort keys %ordinals);
2469     warn <<"EOF" if $ordinals_text;
2470
2471 WARNING: ORDINALS were specified for $ordinals_text
2472 They are ignored and should be replaced with a combination of GENERATE,
2473 DEPEND and SHARED_SOURCE.
2474 EOF
2475
2476     # Check that each generated file is only generated once
2477     my $ambiguous_generation = 0;
2478     foreach (sort keys %check_generate) {
2479         my @generators = sort keys %{$check_generate{$_}};
2480         my $generators_txt = join(', ', @generators);
2481         if (scalar @generators > 1) {
2482             warn "$_ is GENERATEd by more than one generator ($generators_txt)\n";
2483             $ambiguous_generation++;
2484         }
2485         if ($check_generate{$_}->{$generators[0]} > 1) {
2486             warn "INFO: $_ has more than one GENERATE declaration (same generator)\n"
2487         }
2488     }
2489     die "There are ambiguous source file generations\n"
2490         if $ambiguous_generation > 0;
2491
2492     # All given source files should exist, or if generated, their
2493     # generator should exist.  This loop ensures this is true.
2494     my $missing = 0;
2495     foreach my $orig (sort keys %check_exist) {
2496         foreach my $dest (@{$check_exist{$orig}}) {
2497             if ($orig ne $src_configdata) {
2498                 if ($orig =~ /\.a$/) {
2499                     # Static library names may be used as sources, so we
2500                     # need to detect those and give them special treatment.
2501                     unless (grep { $_ eq $orig }
2502                             keys %{$unified_info{libraries}}) {
2503                         warn "$orig is given as source for $dest, but no such library is built\n";
2504                         $missing++;
2505                     }
2506                 } else {
2507                     # A source may be generated, and its generator may be
2508                     # generated as well.  We therefore loop to dig out the
2509                     # first generator.
2510                     my $gen = $orig;
2511
2512                     while (my @next = keys %{$check_generate{$gen}}) {
2513                         $gen = $next[0];
2514                     }
2515
2516                     if (! -f $gen) {
2517                         if ($gen ne $orig) {
2518                             $missing++;
2519                             warn "$orig is given as source for $dest, but its generator (leading to $gen) is missing\n";
2520                         } else {
2521                             $missing++;
2522                             warn "$orig is given as source for $dest, but is missing\n";
2523                         }
2524                     }
2525                 }
2526             }
2527         }
2528     }
2529     die "There are files missing\n" if $missing > 0;
2530
2531     # Go through the sources of all libraries and check that the same basename
2532     # doesn't appear more than once.  Some static library archivers depend on
2533     # them being unique.
2534     {
2535         my $err = 0;
2536         foreach my $prod (keys %{$unified_info{libraries}}) {
2537             my @prod_sources =
2538                 map { keys %{$unified_info{sources}->{$_}} }
2539                 keys %{$unified_info{sources}->{$prod}};
2540             my %srccnt = ();
2541
2542             # Count how many times a given each source basename
2543             # appears for each product.
2544             foreach my $src (@prod_sources) {
2545                 $srccnt{basename $src}++;
2546             }
2547
2548             foreach my $src (keys %srccnt) {
2549                 if ((my $cnt = $srccnt{$src}) > 1) {
2550                     print STDERR "$src appears $cnt times for the product $prod\n";
2551                     $err++
2552                 }
2553             }
2554         }
2555         die if $err > 0;
2556     }
2557
2558     # Massage the result
2559
2560     # If we depend on a header file or a perl module, add an inclusion of
2561     # its directory to allow smoothe inclusion
2562     foreach my $dest (keys %{$unified_info{depends}}) {
2563         next if $dest eq "";
2564         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2565             next unless $d =~ /\.(h|pm)$/;
2566             my $i = dirname($d);
2567             my $spot =
2568                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2569                 ? 'build' : 'source';
2570             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2571                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2572         }
2573     }
2574
2575     # Go through all intermediary files and change their names to something that
2576     # reflects what they will be built for.  Note that for some source files,
2577     # this leads to duplicate object files because they are used multiple times.
2578     # the goal is to rename all object files according to this scheme:
2579     #    {productname}-{midfix}-{origobjname}.[o|res]
2580     # the {midfix} is a keyword indicating the type of product, which is mostly
2581     # valuable for libraries since they come in two forms.
2582     #
2583     # This also reorganises the {sources} and {shared_sources} so that the
2584     # former only contains ALL object files that are supposed to end up in
2585     # static libraries and programs, while the latter contains ALL object files
2586     # that are supposed to end up in shared libraries and DSOs.
2587     # The main reason for having two different source structures is to allow
2588     # the same name to be used for the static and the shared variants of a
2589     # library.
2590     {
2591         # Take copies so we don't get interference from added stuff
2592         my %unified_copy = ();
2593         foreach (('sources', 'shared_sources')) {
2594             $unified_copy{$_} = { %{$unified_info{$_}} }
2595                 if defined($unified_info{$_});
2596             delete $unified_info{$_};
2597         }
2598         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2599             # $intent serves multi purposes:
2600             # - give a prefix for the new object files names
2601             # - in the case of libraries, rearrange the object files so static
2602             #   libraries use the 'sources' structure exclusively, while shared
2603             #   libraries use the 'shared_sources' structure exclusively.
2604             my $intent = {
2605                 programs  => { bin    => { src => [ 'sources' ],
2606                                            dst => 'sources' } },
2607                 libraries => { lib    => { src => [ 'sources' ],
2608                                            dst => 'sources' },
2609                                shlib  => { prodselect =>
2610                                                sub { grep !/\.a$/, @_ },
2611                                            src => [ 'sources',
2612                                                     'shared_sources' ],
2613                                            dst => 'shared_sources' } },
2614                 modules   => { dso    => { src => [ 'sources' ],
2615                                            dst => 'sources' } },
2616                 scripts   => { script => { src => [ 'sources' ],
2617                                            dst => 'sources' } }
2618                } -> {$prodtype};
2619             foreach my $kind (keys %$intent) {
2620                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2621                              && $disabled{shared});
2622
2623                 my @src = @{$intent->{$kind}->{src}};
2624                 my $dst = $intent->{$kind}->{dst};
2625                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2626                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2627                     # %prod_sources has all applicable objects as keys, and
2628                     # their corresponding sources as values
2629                     my %prod_sources =
2630                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2631                         map { keys %{$unified_copy{$_}->{$prod}} }
2632                         @src;
2633                     foreach (keys %prod_sources) {
2634                         # Only affect object files and resource files,
2635                         # the others simply get a new value
2636                         # (+1 instead of -1)
2637                         if ($_ =~ /\.(o|res)$/) {
2638                             (my $prodname = $prod) =~ s|\.a$||;
2639                             my $newobj =
2640                                 catfile(dirname($_),
2641                                         basename($prodname)
2642                                             . '-' . $kind
2643                                             . '-' . basename($_));
2644                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2645                             foreach my $src (@{$prod_sources{$_}}) {
2646                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2647                             }
2648                             # Adjust dependencies
2649                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2650                                 $unified_info{depends}->{$_}->{$deps} = -1;
2651                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2652                             }
2653                             # Adjust includes
2654                             foreach my $k (('source', 'build')) {
2655                                 next unless
2656                                     defined($unified_info{includes}->{$_}->{$k});
2657                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2658                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2659                             }
2660                         } else {
2661                             $unified_info{$dst}->{$prod}->{$_} = 1;
2662                         }
2663                     }
2664                 }
2665             }
2666         }
2667     }
2668
2669     # At this point, we have a number of sources with the value -1.  They
2670     # aren't part of the local build and are probably meant for a different
2671     # platform, and can therefore be cleaned away.  That happens when making
2672     # %unified_info more efficient below.
2673
2674     ### Make unified_info a bit more efficient
2675     # One level structures
2676     foreach (("programs", "libraries", "modules", "scripts", "targets")) {
2677         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2678     }
2679     # Two level structures
2680     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends",
2681                      "htmldocs", "mandocs")) {
2682         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2683             my @items =
2684                 sort
2685                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2686                 keys %{$unified_info{$l1}->{$l2}};
2687             if (@items) {
2688                 $unified_info{$l1}->{$l2} = [ @items ];
2689             } else {
2690                 delete $unified_info{$l1}->{$l2};
2691             }
2692         }
2693     }
2694     # Defines
2695     foreach my $dest (sort keys %{$unified_info{defines}}) {
2696         $unified_info{defines}->{$dest}
2697             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2698                 sort keys %{$unified_info{defines}->{$dest}} ];
2699     }
2700     # Includes
2701     foreach my $dest (sort keys %{$unified_info{includes}}) {
2702         if (defined($unified_info{includes}->{$dest}->{build})) {
2703             my @source_includes = ();
2704             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2705                 if defined($unified_info{includes}->{$dest}->{source});
2706             $unified_info{includes}->{$dest} =
2707                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2708             foreach my $inc (@source_includes) {
2709                 push @{$unified_info{includes}->{$dest}}, $inc
2710                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2711             }
2712         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2713             $unified_info{includes}->{$dest} =
2714                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2715         } else {
2716             delete $unified_info{includes}->{$dest};
2717         }
2718     }
2719
2720     # For convenience collect information regarding directories where
2721     # files are generated, those generated files and the end product
2722     # they end up in where applicable.  Then, add build rules for those
2723     # directories
2724     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2725                      "dso" => [ @{$unified_info{modules}} ],
2726                      "bin" => [ @{$unified_info{programs}} ],
2727                      "script" => [ @{$unified_info{scripts}} ],
2728                      "docs" => [ (map { @{$unified_info{htmldocs}->{$_} // []} }
2729                                   keys %{$unified_info{htmldocs} // {}}),
2730                                  (map { @{$unified_info{mandocs}->{$_} // []} }
2731                                   keys %{$unified_info{mandocs} // {}}) ] );
2732     foreach my $type (keys %loopinfo) {
2733         foreach my $product (@{$loopinfo{$type}}) {
2734             my %dirs = ();
2735             my $pd = dirname($product);
2736
2737             foreach (@{$unified_info{sources}->{$product} // []},
2738                      @{$unified_info{shared_sources}->{$product} // []}) {
2739                 my $d = dirname($_);
2740
2741                 # We don't want to create targets for source directories
2742                 # when building out of source
2743                 next if ($config{sourcedir} ne $config{builddir}
2744                              && $d =~ m|^\Q$config{sourcedir}\E|);
2745                 # We already have a "test" target, and the current directory
2746                 # is just silly to make a target for
2747                 next if $d eq "test" || $d eq ".";
2748
2749                 $dirs{$d} = 1;
2750                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2751                     if $d ne $pd;
2752             }
2753             foreach (keys %dirs) {
2754                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2755                     $product;
2756             }
2757         }
2758     }
2759 }
2760
2761 # For the schemes that need it, we provide the old *_obj configs
2762 # from the *_asm_obj ones
2763 foreach (grep /_(asm|aux)_src$/, keys %target) {
2764     my $src = $_;
2765     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2766     $target{$obj} = $target{$src};
2767     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2768     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2769 }
2770
2771 # Write down our configuration where it fits #########################
2772
2773 my %template_vars = (
2774     config => \%config,
2775     target => \%target,
2776     disablables => \@disablables,
2777     disablables_int => \@disablables_int,
2778     disabled => \%disabled,
2779     withargs => \%withargs,
2780     unified_info => \%unified_info,
2781     tls => \@tls,
2782     dtls => \@dtls,
2783     makevars => [ sort keys %user ],
2784     disabled_info => \%disabled_info,
2785     user_crossable => \@user_crossable,
2786 );
2787 my $configdata_outname = 'configdata.pm';
2788 print "Creating $configdata_outname\n";
2789 open CONFIGDATA, ">$configdata_outname.new"
2790     or die "Trying to create $configdata_outname.new: $!";
2791 my $configdata_tmplname = cleanfile($srcdir, "configdata.pm.in", $blddir);
2792 my $configdata_tmpl =
2793     OpenSSL::Template->new(TYPE => 'FILE', SOURCE => $configdata_tmplname);
2794 $configdata_tmpl->fill_in(
2795     FILENAME => $configdata_tmplname,
2796     OUTPUT => \*CONFIGDATA,
2797     HASH => { %template_vars,
2798               autowarntext => [
2799                   'WARNING: do not edit!',
2800                   "Generated by Configure from $configdata_tmplname",
2801               ] }
2802 ) or die $Text::Template::ERROR;
2803 close CONFIGDATA;
2804 rename "$configdata_outname.new", $configdata_outname;
2805 if ($builder_platform eq 'unix') {
2806     my $mode = (0755 & ~umask);
2807     chmod $mode, 'configdata.pm'
2808         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2809 }
2810
2811 print "Running $configdata_outname\n";
2812 my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
2813 my $cmd = "$perlcmd $configdata_outname";
2814 #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2815 system($cmd);
2816 exit 1 if $? != 0;
2817
2818 $SIG{__DIE__} = $orig_death_handler;
2819
2820 print <<"EOF" if ($disabled{threads} eq "unavailable");
2821
2822 The library could not be configured for supporting multi-threaded
2823 applications as the compiler options required on this system are not known.
2824 See file INSTALL.md for details if you need multi-threading.
2825 EOF
2826
2827 print <<"EOF" if ($no_shared_warn);
2828
2829 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2830 platform, so we will pretend you gave the option 'no-pic', which also disables
2831 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2832 or position independent code, please let us know (but please first make sure
2833 you have tried with a current version of OpenSSL).
2834 EOF
2835
2836 print $banner;
2837
2838 exit(0);
2839
2840 ######################################################################
2841 #
2842 # Helpers and utility functions
2843 #
2844
2845 # Death handler, to print a helpful message in case of failure #######
2846 #
2847 sub death_handler {
2848     die @_ if $^S;              # To prevent the added message in eval blocks
2849     my $build_file = $target{build_file} // "build file";
2850     my @message = ( <<"_____", @_ );
2851
2852 Failure!  $build_file wasn't produced.
2853 Please read INSTALL.md and associated NOTES-* files.  You may also have to
2854 look over your available compiler tool chain or change your configuration.
2855
2856 _____
2857
2858     # Dying is terminal, so it's ok to reset the signal handler here.
2859     $SIG{__DIE__} = $orig_death_handler;
2860     die @message;
2861 }
2862
2863 # Configuration file reading #########################################
2864
2865 # Note: All of the helper functions are for lazy evaluation.  They all
2866 # return a CODE ref, which will return the intended value when evaluated.
2867 # Thus, whenever there's mention of a returned value, it's about that
2868 # intended value.
2869
2870 # Helper function to implement conditional value variants, with a default
2871 # plus additional values based on the value of $config{build_type}.
2872 # Arguments are given in hash table form:
2873 #
2874 #       picker(default => "Basic string: ",
2875 #              debug   => "debug",
2876 #              release => "release")
2877 #
2878 # When configuring with --debug, the resulting string will be
2879 # "Basic string: debug", and when not, it will be "Basic string: release"
2880 #
2881 # This can be used to create variants of sets of flags according to the
2882 # build type:
2883 #
2884 #       cflags => picker(default => "-Wall",
2885 #                        debug   => "-g -O0",
2886 #                        release => "-O3")
2887 #
2888 sub picker {
2889     my %opts = @_;
2890     return sub { add($opts{default} || (),
2891                      $opts{$config{build_type}} || ())->(); }
2892 }
2893
2894 # Helper function to combine several values of different types into one.
2895 # This is useful if you want to combine a string with the result of a
2896 # lazy function, such as:
2897 #
2898 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2899 #
2900 sub combine {
2901     my @stuff = @_;
2902     return sub { add(@stuff)->(); }
2903 }
2904
2905 # Helper function to implement conditional values depending on the value
2906 # of $disabled{threads}.  Can be used as follows:
2907 #
2908 #       cflags => combine("-Wall", threads("-pthread"))
2909 #
2910 sub threads {
2911     my @flags = @_;
2912     return sub { add($disabled{threads} ? () : @flags)->(); }
2913 }
2914
2915 sub shared {
2916     my @flags = @_;
2917     return sub { add($disabled{shared} ? () : @flags)->(); }
2918 }
2919
2920 our $add_called = 0;
2921 # Helper function to implement adding values to already existing configuration
2922 # values.  It handles elements that are ARRAYs, CODEs and scalars
2923 sub _add {
2924     my $separator = shift;
2925
2926     # If there's any ARRAY in the collection of values OR the separator
2927     # is undef, we will return an ARRAY of combined values, otherwise a
2928     # string of joined values with $separator as the separator.
2929     my $found_array = !defined($separator);
2930
2931     my @values =
2932         map {
2933             my $res = $_;
2934             while (ref($res) eq "CODE") {
2935                 $res = $res->();
2936             }
2937             if (defined($res)) {
2938                 if (ref($res) eq "ARRAY") {
2939                     $found_array = 1;
2940                     @$res;
2941                 } else {
2942                     $res;
2943                 }
2944             } else {
2945                 ();
2946             }
2947     } (@_);
2948
2949     $add_called = 1;
2950
2951     if ($found_array) {
2952         [ @values ];
2953     } else {
2954         join($separator, grep { defined($_) && $_ ne "" } @values);
2955     }
2956 }
2957 sub add_before {
2958     my $separator = " ";
2959     if (ref($_[$#_]) eq "HASH") {
2960         my $opts = pop;
2961         $separator = $opts->{separator};
2962     }
2963     my @x = @_;
2964     sub { _add($separator, @x, @_) };
2965 }
2966 sub add {
2967     my $separator = " ";
2968     if (ref($_[$#_]) eq "HASH") {
2969         my $opts = pop;
2970         $separator = $opts->{separator};
2971     }
2972     my @x = @_;
2973     sub { _add($separator, @_, @x) };
2974 }
2975
2976 sub read_eval_file {
2977     my $fname = shift;
2978     my $content;
2979     my @result;
2980
2981     open F, "< $fname" or die "Can't open '$fname': $!\n";
2982     {
2983         undef local $/;
2984         $content = <F>;
2985     }
2986     close F;
2987     {
2988         local $@;
2989
2990         @result = ( eval $content );
2991         warn $@ if $@;
2992     }
2993     return wantarray ? @result : $result[0];
2994 }
2995
2996 # configuration reader, evaluates the input file as a perl script and expects
2997 # it to fill %targets with target configurations.  Those are then added to
2998 # %table.
2999 sub read_config {
3000     my $fname = shift;
3001     my %targets;
3002
3003     {
3004         # Protect certain tables from tampering
3005         local %table = ();
3006
3007         %targets = read_eval_file($fname);
3008     }
3009     my %preexisting = ();
3010     foreach (sort keys %targets) {
3011         $preexisting{$_} = 1 if $table{$_};
3012     }
3013     die <<"EOF",
3014 The following config targets from $fname
3015 shadow pre-existing config targets with the same name:
3016 EOF
3017         map { "  $_\n" } sort keys %preexisting
3018         if %preexisting;
3019
3020
3021     # For each target, check that it's configured with a hash table.
3022     foreach (keys %targets) {
3023         if (ref($targets{$_}) ne "HASH") {
3024             if (ref($targets{$_}) eq "") {
3025                 warn "Deprecated target configuration for $_, ignoring...\n";
3026             } else {
3027                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3028             }
3029             delete $targets{$_};
3030         } else {
3031             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3032         }
3033     }
3034
3035     %table = (%table, %targets);
3036
3037 }
3038
3039 # configuration resolver.  Will only resolve all the lazy evaluation
3040 # codeblocks for the chosen target and all those it inherits from,
3041 # recursively
3042 sub resolve_config {
3043     my $target = shift;
3044     my @breadcrumbs = @_;
3045
3046 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3047
3048     if (grep { $_ eq $target } @breadcrumbs) {
3049         die "inherit_from loop!  target backtrace:\n  "
3050             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3051     }
3052
3053     if (!defined($table{$target})) {
3054         warn "Warning! target $target doesn't exist!\n";
3055         return ();
3056     }
3057     # Recurse through all inheritances.  They will be resolved on the
3058     # fly, so when this operation is done, they will all just be a
3059     # bunch of attributes with string values.
3060     # What we get here, though, are keys with references to lists of
3061     # the combined values of them all.  We will deal with lists after
3062     # this stage is done.
3063     my %combined_inheritance = ();
3064     if ($table{$target}->{inherit_from}) {
3065         my @inherit_from =
3066             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3067         foreach (@inherit_from) {
3068             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3069
3070             # 'template' is a marker that's considered private to
3071             # the config that had it.
3072             delete $inherited_config{template};
3073
3074             foreach (keys %inherited_config) {
3075                 if (!$combined_inheritance{$_}) {
3076                     $combined_inheritance{$_} = [];
3077                 }
3078                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3079             }
3080         }
3081     }
3082
3083     # We won't need inherit_from in this target any more, since we've
3084     # resolved all the inheritances that lead to this
3085     delete $table{$target}->{inherit_from};
3086
3087     # Now is the time to deal with those lists.  Here's the place to
3088     # decide what shall be done with those lists, all based on the
3089     # values of the target we're currently dealing with.
3090     # - If a value is a coderef, it will be executed with the list of
3091     #   inherited values as arguments.
3092     # - If the corresponding key doesn't have a value at all or is the
3093     #   empty string, the inherited value list will be run through the
3094     #   default combiner (below), and the result becomes this target's
3095     #   value.
3096     # - Otherwise, this target's value is assumed to be a string that
3097     #   will simply override the inherited list of values.
3098     my $default_combiner = add();
3099
3100     my %all_keys =
3101         map { $_ => 1 } (keys %combined_inheritance,
3102                          keys %{$table{$target}});
3103
3104     sub process_values {
3105         my $object    = shift;
3106         my $inherited = shift;  # Always a [ list ]
3107         my $target    = shift;
3108         my $entry     = shift;
3109
3110         $add_called = 0;
3111
3112         while(ref($object) eq "CODE") {
3113             $object = $object->(@$inherited);
3114         }
3115         if (!defined($object)) {
3116             return ();
3117         }
3118         elsif (ref($object) eq "ARRAY") {
3119             local $add_called;  # To make sure recursive calls don't affect it
3120             return [ map { process_values($_, $inherited, $target, $entry) }
3121                      @$object ];
3122         } elsif (ref($object) eq "") {
3123             return $object;
3124         } else {
3125             die "cannot handle reference type ",ref($object)
3126                 ," found in target ",$target," -> ",$entry,"\n";
3127         }
3128     }
3129
3130     foreach (sort keys %all_keys) {
3131         my $previous = $combined_inheritance{$_};
3132
3133         # Current target doesn't have a value for the current key?
3134         # Assign it the default combiner, the rest of this loop body
3135         # will handle it just like any other coderef.
3136         if (!exists $table{$target}->{$_}) {
3137             $table{$target}->{$_} = $default_combiner;
3138         }
3139
3140         $table{$target}->{$_} = process_values($table{$target}->{$_},
3141                                                $combined_inheritance{$_},
3142                                                $target, $_);
3143         unless(defined($table{$target}->{$_})) {
3144             delete $table{$target}->{$_};
3145         }
3146 #        if ($extra_checks &&
3147 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3148 #            warn "$_ got replaced in $target\n";
3149 #        }
3150     }
3151
3152     # Finally done, return the result.
3153     return %{$table{$target}};
3154 }
3155
3156 sub usage
3157         {
3158         print STDERR $usage;
3159         print STDERR "\npick os/compiler from:\n";
3160         my $j=0;
3161         my $i;
3162         my $k=0;
3163         foreach $i (sort keys %table)
3164                 {
3165                 next if $table{$i}->{template};
3166                 next if $i =~ /^debug/;
3167                 $k += length($i) + 1;
3168                 if ($k > 78)
3169                         {
3170                         print STDERR "\n";
3171                         $k=length($i);
3172                         }
3173                 print STDERR $i . " ";
3174                 }
3175         foreach $i (sort keys %table)
3176                 {
3177                 next if $table{$i}->{template};
3178                 next if $i !~ /^debug/;
3179                 $k += length($i) + 1;
3180                 if ($k > 78)
3181                         {
3182                         print STDERR "\n";
3183                         $k=length($i);
3184                         }
3185                 print STDERR $i . " ";
3186                 }
3187         exit(1);
3188         }
3189
3190 sub compiler_predefined {
3191     state %predefined;
3192     my $cc = shift;
3193
3194     return () if $^O eq 'VMS';
3195
3196     die 'compiler_predefined called without a compiler command'
3197         unless $cc;
3198
3199     if (! $predefined{$cc}) {
3200
3201         $predefined{$cc} = {};
3202
3203         # collect compiler pre-defines from gcc or gcc-alike...
3204         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3205         while (my $l = <PIPE>) {
3206             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3207             $predefined{$cc}->{$1} = $2 // '';
3208         }
3209         close(PIPE);
3210     }
3211
3212     return %{$predefined{$cc}};
3213 }
3214
3215 sub which
3216 {
3217     my ($name)=@_;
3218
3219     if (eval { require IPC::Cmd; 1; }) {
3220         IPC::Cmd->import();
3221         return scalar IPC::Cmd::can_run($name);
3222     } else {
3223         # if there is $directories component in splitpath,
3224         # then it's not something to test with $PATH...
3225         return $name if (File::Spec->splitpath($name))[1];
3226
3227         foreach (File::Spec->path()) {
3228             my $fullpath = catfile($_, "$name$target{exe_extension}");
3229             if (-f $fullpath and -x $fullpath) {
3230                 return $fullpath;
3231             }
3232         }
3233     }
3234 }
3235
3236 sub env
3237 {
3238     my $name = shift;
3239     my %opts = @_;
3240
3241     unless ($opts{cacheonly}) {
3242         # Note that if $ENV{$name} doesn't exist or is undefined,
3243         # $config{perlenv}->{$name} will be created with the value
3244         # undef.  This is intentional.
3245
3246         $config{perlenv}->{$name} = $ENV{$name}
3247             if ! exists $config{perlenv}->{$name};
3248     }
3249     return $config{perlenv}->{$name};
3250 }
3251
3252 # Configuration printer ##############################################
3253
3254 sub print_table_entry
3255 {
3256     local $now_printing = shift;
3257     my %target = resolve_config($now_printing);
3258     my $type = shift;
3259
3260     # Don't print the templates
3261     return if $target{template};
3262
3263     my @sequence = (
3264         "sys_id",
3265         "cpp",
3266         "cppflags",
3267         "defines",
3268         "includes",
3269         "cc",
3270         "cflags",
3271         "ld",
3272         "lflags",
3273         "loutflag",
3274         "ex_libs",
3275         "bn_ops",
3276         "enable",
3277         "disable",
3278         "poly1035_asm_src",
3279         "thread_scheme",
3280         "perlasm_scheme",
3281         "dso_scheme",
3282         "shared_target",
3283         "shared_cflag",
3284         "shared_defines",
3285         "shared_ldflag",
3286         "shared_rcflag",
3287         "shared_extension",
3288         "dso_extension",
3289         "obj_extension",
3290         "exe_extension",
3291         "ranlib",
3292         "ar",
3293         "arflags",
3294         "aroutflag",
3295         "rc",
3296         "rcflags",
3297         "rcoutflag",
3298         "mt",
3299         "mtflags",
3300         "mtinflag",
3301         "mtoutflag",
3302         "multilib",
3303         "build_scheme",
3304         );
3305
3306     if ($type eq "TABLE") {
3307         print "\n";
3308         print "*** $now_printing\n";
3309         foreach (@sequence) {
3310             if (ref($target{$_}) eq "ARRAY") {
3311                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3312             } else {
3313                 printf "\$%-12s = %s\n", $_, $target{$_};
3314             }
3315         }
3316     } elsif ($type eq "HASH") {
3317         my $largest =
3318             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3319         print "    '$now_printing' => {\n";
3320         foreach (@sequence) {
3321             if ($target{$_}) {
3322                 if (ref($target{$_}) eq "ARRAY") {
3323                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3324                 } else {
3325                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3326                 }
3327             }
3328         }
3329         print "    },\n";
3330     }
3331 }
3332
3333 # Utility routines ###################################################
3334
3335 # On VMS, if the given file is a logical name, File::Spec::Functions
3336 # will consider it an absolute path.  There are cases when we want a
3337 # purely syntactic check without checking the environment.
3338 sub isabsolute {
3339     my $file = shift;
3340
3341     # On non-platforms, we just use file_name_is_absolute().
3342     return file_name_is_absolute($file) unless $^O eq "VMS";
3343
3344     # If the file spec includes a device or a directory spec,
3345     # file_name_is_absolute() is perfectly safe.
3346     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3347
3348     # Here, we know the given file spec isn't absolute
3349     return 0;
3350 }
3351
3352 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3353 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3354 # realpath() requires that at least all path components except the last is an
3355 # existing directory.  On VMS, the last component of the directory spec must
3356 # exist.
3357 sub absolutedir {
3358     my $dir = shift;
3359
3360     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3361     # will return the volume name for the device, no matter what.  Also,
3362     # it will return an incorrect directory spec if the argument is a
3363     # directory that doesn't exist.
3364     if ($^O eq "VMS") {
3365         return rel2abs($dir);
3366     }
3367
3368     # We use realpath() on Unix, since no other will properly clean out
3369     # a directory spec.
3370     use Cwd qw/realpath/;
3371
3372     return realpath($dir);
3373 }
3374
3375 # Check if all paths are one and the same, using stat.  They must both exist
3376 # We need this for the cases when File::Spec doesn't detect case insensitivity
3377 # (File::Spec::Unix assumes case sensitivity)
3378 sub samedir {
3379     die "samedir expects two arguments\n" unless scalar @_ == 2;
3380
3381     my @stat0 = stat($_[0]);    # First argument
3382     my @stat1 = stat($_[1]);    # Second argument
3383
3384     die "Couldn't stat $_[0]" unless @stat0;
3385     die "Couldn't stat $_[1]" unless @stat1;
3386
3387     # Compare device number
3388     return 0 unless ($stat0[0] == $stat1[0]);
3389     # Compare "inode".  The perl manual recommends comparing as
3390     # string rather than as number.
3391     return 0 unless ($stat0[1] eq $stat1[1]);
3392
3393     return 1;                   # All the same
3394 }
3395
3396 sub quotify {
3397     my %processors = (
3398         perl    => sub { my $x = shift;
3399                          $x =~ s/([\\\$\@"])/\\$1/g;
3400                          return '"'.$x.'"'; },
3401         maybeshell => sub { my $x = shift;
3402                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3403                             if ($x ne $y || $x =~ m|\s|) {
3404                                 return '"'.$y.'"';
3405                             } else {
3406                                 return $x;
3407                             }
3408                         },
3409         );
3410     my $for = shift;
3411     my $processor =
3412         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3413
3414     return map { $processor->($_); } @_;
3415 }
3416
3417 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3418 # $filename is a file name to read from
3419 # $line_concat_cond_re is a regexp detecting a line continuation ending
3420 # $line_concat is a CODEref that takes care of concatenating two lines
3421 sub collect_from_file {
3422     my $filename = shift;
3423     my $line_concat_cond_re = shift;
3424     my $line_concat = shift;
3425
3426     open my $fh, $filename || die "unable to read $filename: $!\n";
3427     return sub {
3428         my $saved_line = "";
3429         $_ = "";
3430         while (<$fh>) {
3431             s|\R$||;
3432             if (defined $line_concat) {
3433                 $_ = $line_concat->($saved_line, $_);
3434                 $saved_line = "";
3435             }
3436             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3437                 $saved_line = $_;
3438                 next;
3439             }
3440             return $_;
3441         }
3442         die "$filename ending with continuation line\n" if $_;
3443         close $fh;
3444         return undef;
3445     }
3446 }
3447
3448 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3449 # $array is an ARRAYref of lines
3450 # $line_concat_cond_re is a regexp detecting a line continuation ending
3451 # $line_concat is a CODEref that takes care of concatenating two lines
3452 sub collect_from_array {
3453     my $array = shift;
3454     my $line_concat_cond_re = shift;
3455     my $line_concat = shift;
3456     my @array = (@$array);
3457
3458     return sub {
3459         my $saved_line = "";
3460         $_ = "";
3461         while (defined($_ = shift @array)) {
3462             s|\R$||;
3463             if (defined $line_concat) {
3464                 $_ = $line_concat->($saved_line, $_);
3465                 $saved_line = "";
3466             }
3467             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3468                 $saved_line = $_;
3469                 next;
3470             }
3471             return $_;
3472         }
3473         die "input text ending with continuation line\n" if $_;
3474         return undef;
3475     }
3476 }
3477
3478 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3479 # $lineiterator is a CODEref that delivers one line at a time.
3480 # All following arguments are regex/CODEref pairs, where the regexp detects a
3481 # line and the CODEref does something with the result of the regexp.
3482 sub collect_information {
3483     my $lineiterator = shift;
3484     my %collectors = @_;
3485
3486     while(defined($_ = $lineiterator->())) {
3487         s|\R$||;
3488         my $found = 0;
3489         if ($collectors{"BEFORE"}) {
3490             $collectors{"BEFORE"}->($_);
3491         }
3492         foreach my $re (keys %collectors) {
3493             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3494                 $collectors{$re}->($lineiterator);
3495                 $found = 1;
3496             };
3497         }
3498         if ($collectors{"OTHERWISE"}) {
3499             $collectors{"OTHERWISE"}->($lineiterator, $_)
3500                 unless $found || !defined $collectors{"OTHERWISE"};
3501         }
3502         if ($collectors{"AFTER"}) {
3503             $collectors{"AFTER"}->($_);
3504         }
3505     }
3506 }
3507
3508 # tokenize($line)
3509 # tokenize($line,$separator)
3510 # $line is a line of text to split up into tokens
3511 # $separator [optional] is a regular expression that separates the tokens,
3512 # the default being spaces.  Do not use quotes of any kind as separators,
3513 # that will give undefined results.
3514 # Returns a list of tokens.
3515 #
3516 # Tokens are divided by separator (spaces by default).  If the tokens include
3517 # the separators, they have to be quoted with single or double quotes.
3518 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3519 # with backslash.
3520 # Basically, the same quoting rules apply for " and ' as in any
3521 # Unix shell.
3522 sub tokenize {
3523     my $line = my $debug_line = shift;
3524     my $separator = shift // qr|\s+|;
3525     my @result = ();
3526
3527     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3528         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3529     }
3530
3531     while ($line =~ s|^${separator}||, $line ne "") {
3532         my $token = "";
3533     again:
3534         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3535         $token .= $1;
3536         $line = $2.$';
3537
3538         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3539             $token .= $1;
3540             $line = $';
3541             goto again;
3542         } elsif ($line =~ m/^'([^']*)'/) {
3543             $token .= $1;
3544             $line = $';
3545             goto again;
3546         }
3547         push @result, $token;
3548     }
3549
3550     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3551         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3552         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3553     }
3554     return @result;
3555 }