Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3
   4 ##
   5 ##  Configure -- OpenSSL source tree configuration script
   6 ##  If editing this file, run this command before committing
   7 ##      make -f Makefile.in TABLE
   8 ##
   9
  10 require 5.000;
  11 use strict;
  12 use File::Basename;
  13 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs/;
  14 use File::Path qw/mkpath/;
  15
  16 # see INSTALL for instructions.
  17
  18 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  19
  20 # Options:
  21 #
  22 # --config      add the given configuration file, which will be read after
  23 #               any "Configurations*" files that are found in the same
  24 #               directory as this script.
  25 # --prefix      prefix for the OpenSSL installation, which includes the
  26 #               directories bin, lib, include, share/man, share/doc/openssl
  27 #               This becomes the value of INSTALLTOP in Makefile
  28 #               (Default: /usr/local)
  29 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  30 #               If it's a relative directory, it will be added on the directory
  31 #               given with --prefix.
  32 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  33 #               (Default: PREFIX/ssl)
  34 #
  35 # --cross-compile-prefix Add specified prefix to binutils components.
  36 #
  37 # --api         One of 0.9.8, 1.0.0 or 1.1.0.  Do not compile support for
  38 #               interfaces deprecated as of the specified OpenSSL version.
  39 #
  40 # no-hw-xxx     do not compile support for specific crypto hardware.
  41 #               Generic OpenSSL-style methods relating to this support
  42 #               are always compiled but return NULL if the hardware
  43 #               support isn't compiled.
  44 # no-hw         do not compile support for any crypto hardware.
  45 # [no-]threads  [don't] try to create a library that is suitable for
  46 #               multithreaded applications (default is "threads" if we
  47 #               know how to do it)
  48 # [no-]shared   [don't] try to create shared libraries when supported.
  49 # [no-]pic      [don't] try to build position independent code when supported.
  50 #               If disabled, it also disables shared and dynamic-engine.
  51 # no-asm        do not use assembler
  52 # no-dso        do not compile in any native shared-library methods. This
  53 #               will ensure that all methods just return NULL.
  54 # no-egd        do not compile support for the entropy-gathering daemon APIs
  55 # [no-]zlib     [don't] compile support for zlib compression.
  56 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  57 #               library and will be loaded in run-time by the OpenSSL library.
  58 # sctp          include SCTP support
  59 # 386           generate 80386 code
  60 # enable-weak-ssl-ciphers
  61 #               Enable weak ciphers that are disabled by default. This currently
  62 #               only includes RC4 based ciphers.
  63 # no-sse2       disables IA-32 SSE2 code, above option implies no-sse2
  64 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  65 # -<xxx> +<xxx> compiler options are passed through
  66 #
  67 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
  68 #               provided to stack calls. Generates unique stack functions for
  69 #               each possible stack type.
  70 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  71 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  72 # Following are set automatically by this script
  73 #
  74 # MD5_ASM       use some extra md5 assember,
  75 # SHA1_ASM      use some extra sha1 assember, must define L_ENDIAN for x86
  76 # RMD160_ASM    use some extra ripemd160 assember,
  77 # SHA256_ASM    sha256_block is implemented in assembler
  78 # SHA512_ASM    sha512_block is implemented in assembler
  79 # AES_ASM       ASE_[en|de]crypt is implemented in assembler
  80
  81 # Minimum warning options... any contributions to OpenSSL should at least get
  82 # past these.
  83
  84 my $gcc_devteam_warn = "-DPEDANTIC -DREF_DEBUG -DDEBUG_UNUSED -DBIO_DEBUG"
  85         . " -pedantic"
  86         . " -Wall"
  87         . " -Wno-long-long"
  88         . " -Wsign-compare"
  89         . " -Wmissing-prototypes"
  90         . " -Wshadow"
  91         . " -Wformat"
  92         . " -Wtype-limits"
  93         . " -Werror"
  94         ;
  95
  96 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
  97 # TODO(openssl-team): fix problems and investigate if (at least) the
  98 # following warnings can also be enabled:
  99 #       -Wswitch-enum
 100 #       -Wcast-align
 101 #       -Wunreachable-code
 102 #       -Wlanguage-extension-token -- no, we use asm()
 103 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 104 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 105 my $clang_devteam_warn = ""
 106         . " -Qunused-arguments"
 107         . " -Wextra"
 108         . " -Wno-unused-parameter"
 109         . " -Wno-missing-field-initializers"
 110         . " -Wno-language-extension-token"
 111         . " -Wno-extended-offsetof"
 112         . " -Wconditional-uninitialized"
 113         . " -Wincompatible-pointer-types-discards-qualifiers"
 114         . " -Wmissing-variable-declarations"
 115         ;
 116
 117 # This adds backtrace information to the memory leak info.  Is only used
 118 # when crypto-mdebug-backtrace is enabled.
 119 my $memleak_devteam_backtrace = "-rdynamic";
 120
 121 my $strict_warnings = 0;
 122
 123 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 124 # which would cover all BSD flavors. -pthread applies to them all,
 125 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 126 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 127 # which has to be accompanied by explicit -D_THREAD_SAFE and
 128 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 129 # seems to be sufficient?
 130 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 131
 132 #
 133 # API compability name to version number mapping.
 134 #
 135 my $maxapi = "1.1.0";           # API for "no-deprecated" builds
 136 my $apitable = {
 137     "1.1.0" => "0x10100000L",
 138     "1.0.0" => "0x10000000L",
 139     "0.9.8" => "0x00908000L",
 140 };
 141
 142 our %table = ();
 143 our %config = ();
 144 our %withargs = ();
 145
 146 # Forward declarations ###############################################
 147
 148 # read_config(filename)
 149 #
 150 # Reads a configuration file and populates %table with the contents
 151 # (which the configuration file places in %targets).
 152 sub read_config;
 153
 154 # resolve_config(target)
 155 #
 156 # Resolves all the late evalutations, inheritances and so on for the
 157 # chosen target and any target it inherits from.
 158 sub resolve_config;
 159
 160
 161 # Information collection #############################################
 162
 163 # Unified build supports separate build dir
 164 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 165 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 166 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 167
 168 $config{sourcedir} = abs2rel($srcdir);
 169 $config{builddir} = abs2rel($blddir);
 170
 171 # Collect version numbers
 172 $config{version} = "unknown";
 173 $config{version_num} = "unknown";
 174 $config{shlib_version_number} = "unknown";
 175 $config{shlib_version_history} = "unknown";
 176
 177 collect_information(
 178     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 179     qr/OPENSSL.VERSION.TEXT.*OpenSSL (\S+) / => sub { $config{version} = $1; },
 180     qr/OPENSSL.VERSION.NUMBER.*(0x\S+)/      => sub { $config{version_num}=$1 },
 181     qr/SHLIB_VERSION_NUMBER *"([^"]+)"/      => sub { $config{shlib_version_number}=$1 },
 182     qr/SHLIB_VERSION_HISTORY *"([^"]*)"/     => sub { $config{shlib_version_history}=$1 }
 183     );
 184 if ($config{shlib_version_history} ne "") { $config{shlib_version_history} .= ":"; }
 185
 186 ($config{major}, $config{minor})
 187     = ($config{version} =~ /^([0-9]+)\.([0-9\.]+)/);
 188 ($config{shlib_major}, $config{shlib_minor})
 189     = ($config{shlib_version_number} =~ /^([0-9]+)\.([0-9\.]+)/);
 190 die "erroneous version information in opensslv.h: ",
 191     "$config{major}, $config{minor}, $config{shlib_major}, $config{shlib_minor}\n"
 192     if ($config{major} eq "" || $config{minor} eq ""
 193         || $config{shlib_major} eq "" ||  $config{shlib_minor} eq "");
 194
 195 # Collect target configurations
 196
 197 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 198 foreach (sort glob($pattern) ) {
 199     &read_config($_);
 200 }
 201
 202
 203 print "Configuring OpenSSL version $config{version} (0x$config{version_num})\n";
 204
 205 $config{perl};
 206 $config{prefix}="";
 207 $config{openssldir}="";
 208 $config{processor}="";
 209 $config{libdir}="";
 210 $config{cross_compile_prefix}="";
 211 $config{fipslibdir}="/usr/local/ssl/fips-2.0/lib/";
 212 my $nofipscanistercheck=0;
 213 $config{baseaddr}="0xFB00000";
 214 my $auto_threads=1;    # enable threads automatically? true by default
 215 my $default_ranlib;
 216 $config{fips}=0;
 217
 218 # Top level directories to build
 219 $config{dirs} = [ "crypto", "ssl", "engines", "apps", "test", "tools" ];
 220 # crypto/ subdirectories to build
 221 $config{sdirs} = [
 222     "objects",
 223     "md2", "md4", "md5", "sha", "mdc2", "hmac", "ripemd", "whrlpool", "poly1305",
 224     "des", "aes", "rc2", "rc4", "rc5", "idea", "bf", "cast", "camellia", "seed", "chacha", "modes",
 225     "bn", "ec", "rsa", "dsa", "dh", "dso", "engine",
 226     "buffer", "bio", "stack", "lhash", "rand", "err",
 227     "evp", "asn1", "pem", "x509", "x509v3", "conf", "txt_db", "pkcs7", "pkcs12", "comp", "ocsp", "ui",
 228     "cms", "ts", "srp", "cmac", "ct", "async", "kdf"
 229     ];
 230
 231 # Known TLS and DTLS protocols
 232 my @tls = qw(ssl3 tls1 tls1_1 tls1_2);
 233 my @dtls = qw(dtls1 dtls1_2);
 234
 235 # Explicitelly known options that are possible to disable.  They can
 236 # be regexps, and will be used like this: /^no-${option}$/
 237 # For developers: keep it sorted alphabetically
 238
 239 my @disablables = (
 240     "aes",
 241     "asm",
 242     "async",
 243     "autoalginit",
 244     "autoerrinit",
 245     "bf",
 246     "camellia",
 247     "capieng",
 248     "cast",
 249     "chacha",
 250     "cmac",
 251     "cms",
 252     "comp",
 253     "crypto-mdebug",
 254     "crypto-mdebug-backtrace",
 255     "ct",
 256     "deprecated",
 257     "des",
 258     "dgram",
 259     "dh",
 260     "dsa",
 261     "dso",
 262     "dtls",
 263     "dynamic-engine",
 264     "ec",
 265     "ec2m",
 266     "ecdh",
 267     "ecdsa",
 268     "ec_nistp_64_gcc_128",
 269     "egd",
 270     "engine",
 271     "err",
 272     "filenames",
 273     "heartbeats",
 274     "hmac",
 275     "hw(-.+)?",
 276     "idea",
 277     "locking",
 278     "makedepend",
 279     "md2",
 280     "md4",
 281     "md5",
 282     "mdc2",
 283     "md[-_]ghost94",
 284     "multiblock",
 285     "nextprotoneg",
 286     "ocb",
 287     "ocsp",
 288     "pic",
 289     "poly1305",
 290     "posix-io",
 291     "psk",
 292     "rc2",
 293     "rc4",
 294     "rc5",
 295     "rdrand",
 296     "rfc3779",
 297     "rijndael",                 # Old AES name
 298     "ripemd",
 299     "rmd160",
 300     "rsa",
 301     "scrypt",
 302     "sct",
 303     "sctp",
 304     "seed",
 305     "sha",
 306     "shared",
 307     "sock",
 308     "srp",
 309     "srtp",
 310     "sse2",
 311     "ssl",
 312     "ssl-trace",
 313     "static-engine",
 314     "stdio",
 315     "threads",
 316     "tls",
 317     "ts",
 318     "ui",
 319     "unit-test",
 320     "whirlpool",
 321     "weak-ssl-ciphers",
 322     "zlib",
 323     "zlib-dynamic",
 324     );
 325 foreach my $proto ((@tls, @dtls))
 326         {
 327         push(@disablables, $proto);
 328         push(@disablables, "$proto-method");
 329         }
 330
 331 my @deprecated_disablables = (
 332     "ssl2",
 333     );
 334
 335 # All of the following is disabled by default (RC5 was enabled before 0.9.8):
 336
 337 our %disabled = ( # "what"         => "comment"
 338                   "ec_nistp_64_gcc_128" => "default",
 339                   "egd"                 => "default",
 340                   "md2"                 => "default",
 341                   "rc5"                 => "default",
 342                   "sctp"                => "default",
 343                   "shared"              => "default",
 344                   "ssl-trace"           => "default",
 345                   "ssl3"                => "default",
 346                   "ssl3-method"         => "default",
 347                   "static-engine"       => "default",
 348                   "unit-test"           => "default",
 349                   "weak-ssl-ciphers"    => "default",
 350                   "zlib"                => "default",
 351                   "zlib-dynamic"        => "default",
 352                   "crypto-mdebug"       => "default",
 353                   "heartbeats"          => "default",
 354                 );
 355
 356 # Note: => pair form used for aesthetics, not to truly make a hash table
 357 my @disable_cascades = (
 358     # "what"            => [ "cascade", ... ]
 359     sub { $config{processor} eq "386" }
 360                         => [ "sse2" ],
 361     "ssl"               => [ "ssl3" ],
 362     "ssl3-method"       => [ "ssl3" ],
 363     "zlib"              => [ "zlib-dynamic" ],
 364     "rijndael"          => [ "aes" ],
 365     "des"               => [ "mdc2" ],
 366     "ec"                => [ "ecdsa", "ecdh" ],
 367
 368     "dgram"             => [ "dtls" ],
 369     "dtls"              => [ @dtls ],
 370
 371     # SSL 3.0, (D)TLS 1.0 and TLS 1.1 require MD5 and SHA
 372     "md5"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
 373     "sha"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
 374
 375     # Additionally, SSL 3.0 requires either RSA or DSA+DH
 376     sub { $disabled{rsa}
 377           && ($disabled{dsa} || $disabled{dh}); }
 378                         => [ "ssl" ],
 379
 380     # (D)TLS 1.0 and TLS 1.1 also require either RSA or DSA+DH
 381     # or ECDSA + ECDH.  (D)TLS 1.2 has this requirement as well.
 382     # (XXX: We don't support PSK-only builds).
 383     sub { $disabled{rsa}
 384           && ($disabled{dsa} || $disabled{dh})
 385           && ($disabled{ecdsa} || $disabled{ecdh}); }
 386                         => [ "tls1", "tls1_1", "tls1_2",
 387                              "dtls1", "dtls1_2" ],
 388
 389     "tls"               => [ @tls ],
 390
 391     # SRP and HEARTBEATS require TLSEXT
 392     "tlsext"            => [ "srp", "heartbeats" ],
 393
 394     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 395
 396     # Without DSO, we can't load dynamic engines, so don't build them dynamic
 397     "dso"               => [ "dynamic-engine" ],
 398
 399     # Without position independent code, there can be no shared libraries or DSOs
 400     "pic"               => [ "shared", "dynamic-engine" ],
 401     );
 402
 403 # Avoid protocol support holes.  Also disable all versions below N, if version
 404 # N is disabled while N+1 is enabled.
 405 #
 406 my @list = (reverse @tls);
 407 while ((my $first, my $second) = (shift @list, shift @list)) {
 408     last unless @list;
 409     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 410                               => [ @list ] );
 411     unshift @list, $second;
 412 }
 413 my @list = (reverse @dtls);
 414 while ((my $first, my $second) = (shift @list, shift @list)) {
 415     last unless @list;
 416     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 417                               => [ @list ] );
 418     unshift @list, $second;
 419 }
 420
 421 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 422 # To remove something from %disabled, use "enable-foo".
 423 # For symmetry, "disable-foo" is a synonym for "no-foo".
 424
 425 my @generated_headers = (
 426     "include/openssl/opensslconf.h",
 427     "crypto/include/internal/bn_conf.h",
 428     "crypto/include/internal/dso_conf.h"
 429     );
 430
 431 my @generated_by_make_headers = (
 432     "crypto/buildinf.h"
 433     );
 434
 435
 436 my $no_sse2=0;
 437
 438 &usage if ($#ARGV < 0);
 439
 440 my $user_cflags="";
 441 my @user_defines=();
 442 $config{openssl_api_defines}=[];
 443 $config{openssl_algorithm_defines}=[];
 444 $config{openssl_thread_defines}=[];
 445 $config{openssl_sys_defines}=[];
 446 $config{openssl_other_defines}=[];
 447 my $libs="";
 448 my $target="";
 449 $config{options}="";
 450 $config{build_type} = "release";
 451
 452 my $classic = 0;
 453
 454 my @argvcopy=@ARGV;
 455
 456 if (grep /^reconf(igure)?$/, @argvcopy) {
 457     if (-f "./configdata.pm") {
 458         my $file = "./configdata.pm";
 459         unless (my $return = do $file) {
 460             die "couldn't parse $file: $@" if $@;
 461             die "couldn't do $file: $!"    unless defined $return;
 462             die "couldn't run $file"       unless $return;
 463         }
 464
 465         @argvcopy = defined($configdata::config{perlargv}) ?
 466             @{$configdata::config{perlargv}} : ();
 467         die "Incorrect data to reconfigure, please do a normal configuration\n"
 468             if (grep(/^reconf/,@argvcopy));
 469         $ENV{CROSS_COMPILE} = $configdata::config{cross_compile_prefix}
 470             if defined($configdata::config{cross_compile_prefix});
 471         $ENV{CROSS_COMPILE} = $configdata::config{cc}
 472             if defined($configdata::config{cc});
 473
 474         print "Reconfiguring with: ", join(" ",@argvcopy), "\n";
 475         print "    CROSS_COMPILE = ",$ENV{CROSS_COMPILE},"\n"
 476             if $ENV{CROSS_COMPILE};
 477         print "    CC = ",$ENV{CC},"\n" if $ENV{CC};
 478     } elsif (open IN, "<Makefile") {
 479         #
 480         # THIS SECTION IS TEMPORARY, it helps transitioning from Makefile
 481         # centered information gathering the reading configdata.pm
 482         #
 483         while (<IN>) {
 484             s|\R$||;
 485             if (/^CONFIGURE_ARGS=\s*(.*)\s*/) {
 486                 # Older form, we split the string and hope for the best
 487                 @argvcopy = split /\s+/, $_;
 488                 die "Incorrect data to reconfigure, please do a normal configuration\n"
 489                     if (grep(/^reconf/,@argvcopy));
 490             } elsif (/^CROSS_COMPILE=\s*(.*)/) {
 491                 $ENV{CROSS_COMPILE}=$1;
 492             } elsif (/^CC=\s*(?:\$\(CROSS_COMPILE\))?(.*?)$/) {
 493                 $ENV{CC}=$1;
 494             }
 495         }
 496         #
 497         # END OF TEMPORARY SECTION
 498         #
 499     } else {
 500         die "Insufficient data to reconfigure, please do a normal configuration\n";
 501     }
 502 }
 503
 504 $config{perlargv} = [ @argvcopy ];
 505
 506 my %unsupported_options = ();
 507 my %deprecated_options = ();
 508 foreach (@argvcopy)
 509         {
 510         # VMS is a case insensitive environment, and depending on settings
 511         # out of our control, we may receive options uppercased.  Let's
 512         # downcase at least the part before any equal sign.
 513         if ($^O eq "VMS")
 514                 {
 515                 s/^([^=]*)/lc($1)/e;
 516                 }
 517         s /^-no-/no-/; # some people just can't read the instructions
 518
 519         # rewrite some options in "enable-..." form
 520         s /^-?-?shared$/enable-shared/;
 521         s /^sctp$/enable-sctp/;
 522         s /^threads$/enable-threads/;
 523         s /^zlib$/enable-zlib/;
 524         s /^zlib-dynamic$/enable-zlib-dynamic/;
 525
 526         if (/^(no|disable|enable)-(.+)$/)
 527                 {
 528                 my $word = $2;
 529                 if (grep { $word =~ /^${_}$/ } @deprecated_disablables)
 530                         {
 531                         $deprecated_options{$_} = 1;
 532                         next;
 533                         }
 534                 elsif (!grep { $word =~ /^${_}$/ } @disablables)
 535                         {
 536                         $unsupported_options{$_} = 1;
 537                         next;
 538                         }
 539                 }
 540         if (/^no-(.+)$/ || /^disable-(.+)$/)
 541                 {
 542                 foreach my $proto ((@tls, @dtls))
 543                         {
 544                         if ($1 eq "$proto-method")
 545                                 {
 546                                 $disabled{"$proto"} = "option($proto-method)";
 547                                 last;
 548                                 }
 549                         }
 550                 if ($1 eq "dtls")
 551                         {
 552                         foreach my $proto (@dtls)
 553                                 {
 554                                 $disabled{$proto} = "option(dtls)";
 555                                 }
 556                         }
 557                 elsif ($1 eq "ssl")
 558                         {
 559                         # Last one of its kind
 560                         $disabled{"ssl3"} = "option(ssl)";
 561                         }
 562                 elsif ($1 eq "tls")
 563                         {
 564                         # XXX: Tests will fail if all SSL/TLS
 565                         # protocols are disabled.
 566                         foreach my $proto (@tls)
 567                                 {
 568                                 $disabled{$proto} = "option(tls)";
 569                                 }
 570                         }
 571                 elsif ($1 eq "static-engine")
 572                         {
 573                         delete $disabled{"dynamic-engine"};
 574                         }
 575                 elsif ($1 eq "dynamic-engine")
 576                         {
 577                         $disabled{"dynamic-engine"} = "option";
 578                         }
 579                 else
 580                         {
 581                         $disabled{$1} = "option";
 582                         }
 583                 # No longer an automatic choice
 584                 $auto_threads = 0 if ($1 eq "threads");
 585                 }
 586         elsif (/^enable-(.+)$/)
 587                 {
 588                 if ($1 eq "static-engine")
 589                         {
 590                         $disabled{"dynamic-engine"} = "option";
 591                         }
 592                 elsif ($1 eq "dynamic-engine")
 593                         {
 594                         delete $disabled{"dynamic-engine"};
 595                         }
 596                 elsif ($1 eq "zlib-dynamic")
 597                         {
 598                         delete $disabled{"zlib"};
 599                         }
 600                 my $algo = $1;
 601                 delete $disabled{$algo};
 602
 603                 # No longer an automatic choice
 604                 $auto_threads = 0 if ($1 eq "threads");
 605                 }
 606         elsif (/^--strict-warnings$/)
 607                 {
 608                 $strict_warnings = 1;
 609                 }
 610         elsif (/^--debug$/)
 611                 {
 612                 $config{build_type} = "debug";
 613                 }
 614         elsif (/^--release$/)
 615                 {
 616                 $config{build_type} = "release";
 617                 }
 618         elsif (/^386$/)
 619                 { $config{processor}=386; }
 620         elsif (/^fips$/)
 621                 {
 622                 $config{fips}=1;
 623                 }
 624         elsif (/^rsaref$/)
 625                 {
 626                 # No RSAref support any more since it's not needed.
 627                 # The check for the option is there so scripts aren't
 628                 # broken
 629                 }
 630         elsif (/^nofipscanistercheck$/)
 631                 {
 632                 $config{fips} = 1;
 633                 $nofipscanistercheck = 1;
 634                 }
 635         elsif (/^[-+]/)
 636                 {
 637                 if (/^--classic$/)
 638                         {
 639                         $classic=1;
 640                         }
 641                 elsif (/^--prefix=(.*)$/)
 642                         {
 643                         $config{prefix}=$1;
 644                         die "Directory given with --prefix MUST be absolute\n"
 645                                 unless file_name_is_absolute($config{prefix});
 646                         }
 647                 elsif (/^--api=(.*)$/)
 648                         {
 649                         $config{api}=$1;
 650                         }
 651                 elsif (/^--libdir=(.*)$/)
 652                         {
 653                         $config{libdir}=$1;
 654                         }
 655                 elsif (/^--openssldir=(.*)$/)
 656                         {
 657                         $config{openssldir}=$1;
 658                         }
 659                 elsif (/^--with-zlib-lib=(.*)$/)
 660                         {
 661                         $withargs{zlib_lib}=$1;
 662                         }
 663                 elsif (/^--with-zlib-include=(.*)$/)
 664                         {
 665                         $withargs{zlib_include}="-I$1";
 666                         }
 667                 elsif (/^--with-fipslibdir=(.*)$/)
 668                         {
 669                         $config{fipslibdir}="$1/";
 670                         }
 671                 elsif (/^--with-baseaddr=(.*)$/)
 672                         {
 673                         $config{baseaddr}="$1";
 674                         }
 675                 elsif (/^--cross-compile-prefix=(.*)$/)
 676                         {
 677                         $config{cross_compile_prefix}=$1;
 678                         }
 679                 elsif (/^--config=(.*)$/)
 680                         {
 681                         read_config $1;
 682                         }
 683                 elsif (/^-[lL](.*)$/ or /^-Wl,/)
 684                         {
 685                         $libs.=$_." ";
 686                         }
 687                 elsif (/^-D(.*)$/)
 688                         {
 689                         push @user_defines, $1;
 690                         }
 691                 else    # common if (/^[-+]/), just pass down...
 692                         {
 693                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 694                         $user_cflags.=" ".$_;
 695                         }
 696                 }
 697         else
 698                 {
 699                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 700                 $target=$_;
 701                 }
 702         unless ($_ eq $target || /^no-/ || /^disable-/)
 703                 {
 704                 # "no-..." follows later after implied disactivations
 705                 # have been derived.  (Don't take this too seroiusly,
 706                 # we really only write OPTIONS to the Makefile out of
 707                 # nostalgia.)
 708
 709                 if ($config{options} eq "")
 710                         { $config{options} = $_; }
 711                 else
 712                         { $config{options} .= " ".$_; }
 713                 }
 714
 715         if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 716                 die "***** Unsupported api compatibility level: $config{api}\n",
 717         }
 718
 719         if (keys %deprecated_options)
 720                 {
 721                 warn "***** Deprecated options: ",
 722                         join(", ", keys %deprecated_options), "\n";
 723                 }
 724         if (keys %unsupported_options)
 725                 {
 726                 die "***** Unsupported options: ",
 727                         join(", ", keys %unsupported_options), "\n";
 728                 }
 729         }
 730
 731 if ($config{fips})
 732         {
 733         delete $disabled{"shared"} if ($disabled{"shared"} =~ /^default/);
 734         }
 735 else
 736         {
 737         @{$config{dirs}} = grep !/^fips$/, @{$config{dirs}};
 738         }
 739
 740 my @tocheckfor = (keys %disabled);
 741 while (@tocheckfor) {
 742     my %new_tocheckfor = ();
 743     my @cascade_copy = (@disable_cascades);
 744     while (@cascade_copy) {
 745         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
 746         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
 747             map {
 748                 $new_tocheckfor{$_} => 1; $disabled{$_} = "forced";
 749             } grep { !defined($disabled{$_}) } @$descendents;
 750         }
 751     }
 752     @tocheckfor = (keys %new_tocheckfor);
 753 }
 754
 755 if ($target eq "TABLE") {
 756     foreach (sort keys %table) {
 757         print_table_entry($_, "TABLE");
 758     }
 759     exit 0;
 760 }
 761
 762 if ($target eq "LIST") {
 763     foreach (sort keys %table) {
 764         print $_,"\n" unless $table{$_}->{template};
 765     }
 766     exit 0;
 767 }
 768
 769 if ($target eq "HASH") {
 770     print "%table = (\n";
 771     foreach (sort keys %table) {
 772         print_table_entry($_, "HASH");
 773     }
 774     exit 0;
 775 }
 776
 777 # Backward compatibility?
 778 if ($target =~ m/^CygWin32(-.*)$/) {
 779     $target = "Cygwin".$1;
 780 }
 781
 782 foreach (sort (keys %disabled))
 783         {
 784         $config{options} .= " no-$_";
 785
 786         printf "    no-%-12s %-10s", $_, "[$disabled{$_}]";
 787
 788         if (/^dso$/)
 789                 { }
 790         elsif (/^threads$/)
 791                 { }
 792         elsif (/^shared$/)
 793                 { }
 794         elsif (/^pic$/)
 795                 { }
 796         elsif (/^zlib$/)
 797                 { }
 798         elsif (/^dynamic-engine$/)
 799                 { }
 800         elsif (/^makedepend$/)
 801                 { }
 802         elsif (/^zlib-dynamic$/)
 803                 { }
 804         elsif (/^sse2$/)
 805                 { $no_sse2 = 1; }
 806         elsif (/^engine$/)
 807                 {
 808                 @{$config{dirs}} = grep !/^engines$/, @{$config{dirs}};
 809                 @{$config{sdirs}} = grep !/^engine$/, @{$config{sdirs}};
 810                 push @{$config{openssl_other_defines}}, "OPENSSL_NO_ENGINE";
 811                 }
 812         else
 813                 {
 814                 my ($ALGO, $algo);
 815                 ($ALGO = $algo = $_) =~ tr/[\-a-z]/[_A-Z]/;
 816
 817                 if (/^asm$/ || /^err$/ || /^hw$/ || /^hw-/ || /^async$/
 818                                 || /^autoalginit/ || /^autoerrinit/)
 819                         {
 820                         push @{$config{openssl_other_defines}}, "OPENSSL_NO_$ALGO";
 821                         print " OPENSSL_NO_$ALGO";
 822
 823                         if (/^err$/)    { push @user_defines, "OPENSSL_NO_ERR"; }
 824                         }
 825                 else
 826                         {
 827                         ($ALGO,$algo) = ("RMD160","rmd160") if ($algo eq "ripemd");
 828
 829                         push @{$config{openssl_algorithm_defines}}, "OPENSSL_NO_$ALGO";
 830                         print " OPENSSL_NO_$ALGO";
 831
 832                         # fix-up crypto/directory name(s)
 833                         $algo="whrlpool" if $algo eq "whirlpool";
 834                         $algo="ripemd" if $algo eq "rmd160";
 835                         @{$config{sdirs}} = grep { $_ ne $algo} @{$config{sdirs}};
 836
 837                         print " (skip dir)";
 838                         }
 839                 }
 840
 841         print "\n";
 842         }
 843
 844 print "Configuring for $target\n";
 845
 846 # Support for legacy targets having a name starting with 'debug-'
 847 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
 848 if ($d) {
 849     $config{build_type} = "debug";
 850
 851     # If we do not find debug-foo in the table, the target is set to foo.
 852     if (!$table{$target}) {
 853         $target = $t;
 854     }
 855 }
 856 $config{target} = $target;
 857 my %target = resolve_config($target);
 858
 859 &usage if (!%target || $target{template});
 860
 861 %target = ( %{$table{DEFAULTS}}, %target );
 862
 863 $target{exe_extension}="";
 864 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP"
 865                                   || $config{target} =~ /^(?:Cygwin|mingw)/);
 866 $target{exe_extension}=".nlm" if ($config{target} =~ /netware/);
 867 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
 868
 869 ($target{shared_extension_simple}=$target{shared_extension})
 870     =~ s|\.\$\(SHLIB_MAJOR\)\.\$\(SHLIB_MINOR\)||;
 871 $target{dso_extension}=$target{shared_extension_simple};
 872 ($target{shared_import_extension}=$target{shared_extension_simple}.".a")
 873     if ($config{target} =~ /^(?:Cygwin|mingw)/);
 874
 875
 876 $config{cross_compile_prefix} = $ENV{'CROSS_COMPILE'}
 877     if $config{cross_compile_prefix} eq "";
 878
 879 # Allow overriding the names of some tools.  USE WITH CARE
 880 $config{perl} =    $ENV{'PERL'}    || which("perl5") || which("perl") || "perl";
 881 $target{cc} =      $ENV{'CC'}      || $target{cc}      || "cc";
 882 $target{ranlib} =  $ENV{'RANLIB'}  || $target{ranlib}  || which("ranlib") || "true";
 883 $target{ar} =      $ENV{'AR'}      || $target{ar}      || "ar";
 884 $target{nm} =      $ENV{'NM'}      || $target{nm}      || "nm";
 885
 886 # For cflags, lflags, plib_lflags, ex_libs and defines, add the debug_
 887 # or release_ attributes.
 888 # Do it in such a way that no spurious space is appended (hence the grep).
 889 $config{defines} = [];
 890 $config{cflags} = "";
 891 $config{ex_libs} = "";
 892 $config{shared_ldflag} = "";
 893
 894 # Make sure build_scheme is consistent.
 895 $target{build_scheme} = [ $target{build_scheme} ]
 896     if ref($target{build_scheme}) ne "ARRAY";
 897
 898 ###### TO BE REMOVED WHEN CLASSIC BUILD IS REMOVED
 899 ######
 900 ###### If the user has chosen --classic, we give it to them.
 901 ###### If they try that with an out-of-source config, we complain.
 902 if ($target{build_scheme}->[0] eq "unified" && $classic) {
 903     die "Can't perform a classic build out of source tree\n"
 904         if $srcdir ne $blddir;
 905
 906     $target{build_scheme} = { unix    => [ "unixmake" ],
 907                               windows => [ "mk1mf", $target{build_scheme}->[2] ],
 908                               VMS     => undef } -> {$target{build_scheme}->[1]};
 909
 910     die "Classic mode unavailable on this platform\n"
 911         unless defined($target{build_scheme});
 912 }
 913
 914 my ($builder, $builder_platform, @builder_opts) =
 915     @{$target{build_scheme}};
 916
 917 if ($target =~ /^mingw/ && `$target{cc} --target-help 2>&1` =~ m/-mno-cygwin/m)
 918         {
 919         $config{cflags} .= " -mno-cygwin";
 920         $config{shared_ldflag} .= " -mno-cygwin";
 921         }
 922
 923 if ($target =~ /linux.*-mips/ && !$disabled{asm} && $user_cflags !~ /-m(ips|arch=)/) {
 924         # minimally required architecture flags for assembly modules
 925         $config{cflags}="-mips2 $config{cflags}" if ($target =~ /mips32/);
 926         $config{cflags}="-mips3 $config{cflags}" if ($target =~ /mips64/);
 927 }
 928
 929 my $no_shared_warn=0;
 930 my $no_user_cflags=0;
 931 my $no_user_defines=0;
 932
 933 # The DSO code currently always implements all functions so that no
 934 # applications will have to worry about that from a compilation point
 935 # of view. However, the "method"s may return zero unless that platform
 936 # has support compiled in for them. Currently each method is enabled
 937 # by a define "DSO_<name>" ... we translate the "dso_scheme" config
 938 # string entry into using the following logic;
 939 if (!$disabled{dso} && $target{dso_scheme} ne "")
 940         {
 941         $target{dso_scheme} =~ tr/[a-z]/[A-Z]/;
 942         if ($target{dso_scheme} eq "DLFCN")
 943                 {
 944                 unshift @{$config{defines}}, "DSO_DLFCN", "HAVE_DLFCN_H";
 945                 }
 946         elsif ($target{dso_scheme} eq "DLFCN_NO_H")
 947                 {
 948                 unshift @{$config{defines}}, "DSO_DLFCN";
 949                 }
 950         else
 951                 {
 952                 unshift @{$config{defines}}, "DSO_$target{dso_scheme}";
 953                 }
 954         }
 955
 956 $config{ex_libs}="$libs$config{ex_libs}" if ($libs ne "");
 957
 958 if ($disabled{asm})
 959         {
 960         if ($config{fips})
 961                 {
 962                 @{$config{defines}} = grep !/^[BL]_ENDIAN$/, @{$config{defines}};
 963                 @{$target{defines}} = grep !/^[BL]_ENDIAN$/, @{$target{defines}};
 964                 }
 965         }
 966
 967 # If threads aren't disabled, check how possible they are
 968 unless ($disabled{threads}) {
 969     if ($auto_threads) {
 970         # Enabled by default, disable it forcibly if unavailable
 971         if ($target{thread_scheme} eq "(unknown)") {
 972             $disabled{threads} = "unavailable";
 973         }
 974     } else {
 975         # The user chose to enable threads explicitely, let's see
 976         # if there's a chance that's possible
 977         if ($target{thread_scheme} eq "(unknown)") {
 978             # If the user asked for "threads" and we don't have internal
 979             # knowledge how to do it, [s]he is expected to provide any
 980             # system-dependent compiler options that are necessary.  We
 981             # can't truly check that the given options are correct, but
 982             # we expect the user to know what [s]He is doing.
 983             if ($no_user_cflags && $no_user_defines) {
 984                 die "You asked for multi-threading support, but didn't\n"
 985                     ,"provide any system-specific compiler options\n";
 986             }
 987         }
 988     }
 989 }
 990
 991 # If threads still aren't disabled, add a C macro to ensure the source
 992 # code knows about it.  Any other flag is taken care of by the configs.
 993 unless($disabled{threads}) {
 994     foreach (("defines", "openssl_thread_defines")) {
 995         push @{$config{$_}}, "OPENSSL_THREADS";
 996     }
 997 }
 998
 999 # With "deprecated" disable all deprecated features.
1000 if (defined($disabled{"deprecated"})) {
1001         $config{api} = $maxapi;
1002 }
1003
1004 if ($target{shared_target} eq "")
1005         {
1006         $no_shared_warn = 1
1007             if ((!$disabled{shared} || !$disabled{"dynamic-engine"})
1008                 && !$config{fips});
1009         $disabled{shared} = "no-shared-target";
1010         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
1011             "no-shared-target";
1012         }
1013
1014 if ($disabled{"dynamic-engine"}) {
1015         push @{$config{defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1016         $config{dynamic_engines} = 0;
1017 } else {
1018         push @{$config{defines}}, "OPENSSL_NO_STATIC_ENGINE";
1019         $config{dynamic_engines} = 1;
1020 }
1021
1022 #
1023 # Platform fix-ups
1024 #
1025
1026 # This saves the build files from having to check
1027 if ($disabled{pic})
1028         {
1029         $target{shared_cflag} = $target{shared_ldflag} =
1030                 $target{shared_rcflag} = "";
1031         }
1032 else
1033         {
1034         push @{$config{defines}}, "OPENSSL_PIC";
1035         }
1036
1037 if ($target{sys_id} ne "")
1038         {
1039         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1040         }
1041
1042 unless ($disabled{asm}) {
1043     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1044     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1045
1046     # bn-586 is the only one implementing bn_*_part_words
1047     push @{$config{defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1048     push @{$config{defines}}, "OPENSSL_IA32_SSE2" if (!$no_sse2 && $target{bn_asm_src} =~ /86/);
1049
1050     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1051     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1052     push @{$config{defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1053
1054     if ($config{fips}) {
1055         push @{$config{openssl_other_defines}}, "OPENSSL_FIPS";
1056     }
1057
1058     if ($target{sha1_asm_src}) {
1059         push @{$config{defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1060         push @{$config{defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1061         push @{$config{defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1062     }
1063     if ($target{md5_asm_src}) {
1064         push @{$config{defines}}, "MD5_ASM";
1065     }
1066     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1067     if ($target{rmd160_asm_src}) {
1068         push @{$config{defines}}, "RMD160_ASM";
1069     }
1070     if ($target{aes_asm_src}) {
1071         push @{$config{defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1072         # aes-ctr.fake is not a real file, only indication that assembler
1073         # module implements AES_ctr32_encrypt...
1074         push @{$config{defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1075         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1076         push @{$config{defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1077         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($no_sse2);
1078         push @{$config{defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1079         push @{$config{defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1080     }
1081     if ($target{wp_asm_src} =~ /mmx/) {
1082         if ($config{processor} eq "386") {
1083             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1084         } elsif (!$disabled{"whirlpool"}) {
1085             push @{$config{defines}}, "WHIRLPOOL_ASM";
1086         }
1087     }
1088     if ($target{modes_asm_src} =~ /ghash-/) {
1089         push @{$config{defines}}, "GHASH_ASM";
1090     }
1091     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1092         push @{$config{defines}}, "ECP_NISTZ256_ASM";
1093     }
1094     if ($target{poly1305_asm_src} ne "") {
1095         push @{$config{defines}}, "POLY1305_ASM";
1096     }
1097 }
1098
1099 my $ecc = $target{cc};
1100 if ($^O ne "VMS" && !$disabled{makedepend}) {
1101     # Is the compiler gcc or clang?  $ecc is used below to see if
1102     # error-checking can be turned on.
1103     my $ccpcc = "$config{cross_compile_prefix}$target{cc}";
1104     $config{makedepprog} = which('makedepend');
1105     open(PIPE, "$ccpcc --version 2>&1 | head -2 |");
1106     while ( <PIPE> ) {
1107         # Find the version number and save the major.
1108         m|(?:.*)\b(\d+)\.\d+\.\d+\b(?:.*)|;
1109         # We know that GNU C version 3 and up as well as all clang
1110         # versions support dependency generation
1111         $config{makedepprog} = $ccpcc if /clang/ || (/gcc/ && $1 > 3);
1112         $ecc = "clang" if /clang/;
1113         $ecc = "gcc" if /gcc/;
1114     }
1115     close(PIPE);
1116
1117     $disabled{makedepend} = "unavailable" unless $config{makedepprog};
1118 }
1119
1120
1121
1122 # Deal with bn_ops ###################################################
1123
1124 $config{bn_ll}                  =0;
1125 $config{export_var_as_fn}       =0;
1126 my $def_int="unsigned int";
1127 $config{rc4_int}                =$def_int;
1128 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1129
1130 my $count = 0;
1131 foreach (sort split(/\s+/,$target{bn_ops})) {
1132     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1133     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1134     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1135     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1136     ($config{b64l},$config{b64},$config{b32})
1137         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1138     ($config{b64l},$config{b64},$config{b32})
1139         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1140     ($config{b64l},$config{b64},$config{b32})
1141         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1142 }
1143 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1144     if $count > 1;
1145
1146
1147 # Hack cflags for better warnings (dev option) #######################
1148
1149 # "Stringify" the C flags string.  This permits it to be made part of a string
1150 # and works as well on command lines.
1151 $config{cflags} =~ s/([\\\"])/\\\1/g;
1152
1153 if (defined($config{api})) {
1154     $config{openssl_api_defines} = [ "OPENSSL_MIN_API=".$apitable->{$config{api}} ];
1155     my $apiflag = sprintf("OPENSSL_API_COMPAT=%s", $apitable->{$config{api}});
1156     push @{$config{defines}}, $apiflag;
1157 }
1158
1159 if ($strict_warnings)
1160         {
1161         my $wopt;
1162         die "ERROR --strict-warnings requires gcc or clang"
1163             unless $ecc eq 'gcc' || $ecc eq 'clang';
1164         foreach $wopt (split /\s+/, $gcc_devteam_warn)
1165                 {
1166                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1167                 }
1168         if ($ecc eq "clang")
1169                 {
1170                 foreach $wopt (split /\s+/, $clang_devteam_warn)
1171                         {
1172                         $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1173                         }
1174                 }
1175         }
1176
1177 unless ($disabled{"crypto-mdebug-backtrace"})
1178         {
1179         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1180                 {
1181                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1182                 }
1183         if ($target =~ /^BSD-/)
1184                 {
1185                 $config{ex_libs} .= " -lexecinfo";
1186                 }
1187         }
1188
1189 if ($user_cflags ne "") { $config{cflags}="$config{cflags}$user_cflags"; }
1190 else                    { $no_user_cflags=1;  }
1191 if (@user_defines) { $config{defines}=[ @{$config{defines}}, @user_defines ]; }
1192 else               { $no_user_defines=1;    }
1193
1194 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1195
1196 $config{afalg}="";
1197 if ($target =~ m/^linux/) {
1198     my $minver = 4*10000 + 1*100 + 0;
1199     if ($config{cross_compile_prefix} eq "") {
1200         my $verstr = `uname -r`;
1201         my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1202         ($mi2) = $mi2 =~ /(\d+)/;
1203         my $ver = $ma*10000 + $mi1*100 + $mi2;
1204         if ($ver < $minver) {
1205             $disabled{afalg} = "too-old-kernel";
1206         } else {
1207             push @{$config{engdirs}}, "afalg";
1208         }
1209     }
1210 } else {
1211     $disabled{afalg}  = "not-linux";
1212 }
1213
1214 push @{$config{openssl_other_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalg});
1215
1216 # If we use the unified build, collect information from build.info files
1217 my %unified_info = ();
1218
1219 if ($builder eq "unified") {
1220     # Store the name of the template file we will build the build file from
1221     # in %config.  This may be useful for the build file itself.
1222     my $build_file_template =
1223         catfile($srcdir, "Configurations",
1224                 $builder_platform."-".$target{build_file}.".tmpl");
1225     $build_file_template =
1226         catfile($srcdir, "Configurations", $target{build_file}.".tmpl")
1227         if (! -f $build_file_template);
1228     $config{build_file_template} = $build_file_template;
1229
1230     use lib catdir(dirname(__FILE__),"util");
1231     use with_fallback qw(Text::Template);
1232
1233     sub cleandir {
1234         my $base = shift;
1235         my $dir = shift;
1236         my $relativeto = shift || ".";
1237
1238         $dir = catdir($base,$dir) unless isabsolute($dir);
1239
1240         # Make sure the directories we're building in exists
1241         mkpath($dir);
1242
1243         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1244         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1245         return $res;
1246     }
1247
1248     sub cleanfile {
1249         my $base = shift;
1250         my $file = shift;
1251         my $relativeto = shift || ".";
1252
1253         $file = catfile($base,$file) unless isabsolute($file);
1254
1255         my $d = dirname($file);
1256         my $f = basename($file);
1257
1258         # Make sure the directories we're building in exists
1259         mkpath($d);
1260
1261         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1262         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1263         return $res;
1264     }
1265
1266     my @build_infos = ( [ ".", "build.info" ] );
1267     foreach (@{$config{dirs}}) {
1268         push @build_infos, [ $_, "build.info" ]
1269             if (-f catfile($srcdir, $_, "build.info"));
1270     }
1271     foreach (@{$config{sdirs}}) {
1272         push @build_infos, [ catdir("crypto", $_), "build.info" ]
1273             if (-f catfile($srcdir, "crypto", $_, "build.info"));
1274     }
1275     foreach (@{$config{engdirs}}) {
1276         push @build_infos, [ catdir("engines", $_), "build.info" ]
1277             if (-f catfile($srcdir, "engines", $_, "build.info"));
1278     }
1279
1280     $config{build_infos} = [ ];
1281
1282     foreach (@build_infos) {
1283         my $sourced = catdir($srcdir, $_->[0]);
1284         my $buildd = catdir($blddir, $_->[0]);
1285
1286         mkpath($buildd);
1287
1288         my $f = $_->[1];
1289         # The basic things we're trying to build
1290         my @programs = ();
1291         my @libraries = ();
1292         my @engines = ();
1293         my @scripts = ();
1294         my @extra = ();
1295         my @overrides = ();
1296         my @intermediates = ();
1297         my @rawlines = ();
1298
1299         my %ordinals = ();
1300         my %sources = ();
1301         my %includes = ();
1302         my %depends = ();
1303         my %renames = ();
1304         my %sharednames = ();
1305         my %generate = ();
1306
1307         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1308         my $template = Text::Template->new(TYPE => 'FILE',
1309                                            SOURCE => catfile($sourced, $f));
1310         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1311         my @text =
1312             split /^/m,
1313             $template->fill_in(HASH => { config => \%config,
1314                                          target => \%target,
1315                                          disabled => \%disabled,
1316                                          builddir => abs2rel($buildd, $blddir),
1317                                          sourcedir => abs2rel($sourced, $blddir),
1318                                          buildtop => abs2rel($blddir, $blddir),
1319                                          sourcetop => abs2rel($srcdir, $blddir) },
1320                                DELIMITERS => [ "{-", "-}" ]);
1321
1322         # The top item of this stack has the following values
1323         # -2 positive already run and we found ELSE (following ELSIF should fail)
1324         # -1 positive already run (skip until ENDIF)
1325         # 0 negatives so far (if we're at a condition, check it)
1326         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1327         # 2 positive ELSE (following ELSIF should fail)
1328         my @skip = ();
1329         collect_information(
1330             collect_from_array([ @text ],
1331                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1332                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1333             # Info we're looking for
1334             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1335             => sub { push @skip, !! $1; },
1336             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1337             => sub { die "ELSIF out of scope" if ! @skip;
1338                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1339                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1340                      $skip[$#skip] = !! $1
1341                          if $skip[$#skip] == 0; },
1342             qr/^\s*ELSE\s*$/
1343             => sub { die "ELSE out of scope" if ! @skip;
1344                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1345                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1346             qr/^\s*ENDIF\s*$/
1347             => sub { die "ENDIF out of scope" if ! @skip;
1348                      pop @skip; },
1349             qr/^\s*PROGRAMS\s*=\s*(.*)\s*$/
1350             => sub { push @programs, split(/\s+/, $1)
1351                          if !@skip || $skip[$#skip] > 0 },
1352             qr/^\s*LIBS\s*=\s*(.*)\s*$/
1353             => sub { push @libraries, split(/\s+/, $1)
1354                          if !@skip || $skip[$#skip] > 0 },
1355             qr/^\s*ENGINES\s*=\s*(.*)\s*$/
1356             => sub { push @engines, split(/\s+/, $1)
1357                          if !@skip || $skip[$#skip] > 0 },
1358             qr/^\s*SCRIPTS\s*=\s*(.*)\s*$/
1359             => sub { push @scripts, split(/\s+/, $1)
1360                          if !@skip || $skip[$#skip] > 0 },
1361             qr/^\s*EXTRA\s*=\s*(.*)\s*$/
1362             => sub { push @extra, split(/\s+/, $1)
1363                          if !@skip || $skip[$#skip] > 0 },
1364             qr/^\s*OVERRIDES\s*=\s*(.*)\s*$/
1365             => sub { push @overrides, split(/\s+/, $1)
1366                          if !@skip || $skip[$#skip] > 0 },
1367
1368             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1369             => sub { push @{$ordinals{$1}}, split(/\s+/, $2)
1370                          if !@skip || $skip[$#skip] > 0 },
1371             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1372             => sub { push @{$sources{$1}}, split(/\s+/, $2)
1373                          if !@skip || $skip[$#skip] > 0 },
1374             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1375             => sub { push @{$includes{$1}}, split(/\s+/, $2)
1376                          if !@skip || $skip[$#skip] > 0 },
1377             qr/^\s*DEPEND\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1378             => sub { push @{$depends{$1}}, split(/\s+/, $2)
1379                          if !@skip || $skip[$#skip] > 0 },
1380             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1381             => sub { push @{$generate{$1}}, $2
1382                          if !@skip || $skip[$#skip] > 0 },
1383             qr/^\s*RENAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1384             => sub { push @{$renames{$1}}, split(/\s+/, $2)
1385                          if !@skip || $skip[$#skip] > 0 },
1386             qr/^\s*SHARED_NAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1387             => sub { push @{$sharednames{$1}}, split(/\s+/, $2)
1388                          if !@skip || $skip[$#skip] > 0 },
1389             qr/^\s*BEGINRAW\[((?:\\.|[^\\\]])+)\]\s*$/
1390             => sub {
1391                 my $lineiterator = shift;
1392                 my $target_kind = $1;
1393                 while (defined $lineiterator->()) {
1394                     s|\R$||;
1395                     if (/^\s*ENDRAW\[((?:\\.|[^\\\]])+)\]\s*$/) {
1396                         die "ENDRAW doesn't match BEGINRAW"
1397                             if $1 ne $target_kind;
1398                         last;
1399                     }
1400                     next if @skip && $skip[$#skip] <= 0;
1401                     push @rawlines,  $_
1402                         if ($target_kind eq $target{build_file}
1403                             || $target_kind eq $target{build_file}."(".$builder_platform.")");
1404                 }
1405             },
1406             qr/^(?:#.*|\s*)$/ => sub { },
1407             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" }
1408             );
1409         die "runaway IF?" if (@skip);
1410
1411         foreach (keys %renames) {
1412             die "$_ renamed to more than one thing: "
1413                 ,join(" ", @{$renames{$_}}),"\n"
1414                 if scalar @{$renames{$_}} > 1;
1415             my $dest = cleanfile($buildd, $_, $blddir);
1416             my $to = cleanfile($buildd, $renames{$_}->[0], $blddir);
1417             die "$dest renamed to more than one thing: "
1418                 ,$unified_info{rename}->{$dest}, $to
1419                 unless !defined($unified_info{rename}->{$dest})
1420                 or $unified_info{rename}->{$dest} eq $to;
1421             $unified_info{rename}->{$dest} = $to;
1422         }
1423
1424         foreach (@programs) {
1425             my $program = cleanfile($buildd, $_, $blddir);
1426             if ($unified_info{rename}->{$program}) {
1427                 $program = $unified_info{rename}->{$program};
1428             }
1429             $unified_info{programs}->{$program} = 1;
1430         }
1431
1432         foreach (@libraries) {
1433             my $library = cleanfile($buildd, $_, $blddir);
1434             if ($unified_info{rename}->{$library}) {
1435                 $library = $unified_info{rename}->{$library};
1436             }
1437             $unified_info{libraries}->{$library} = 1;
1438         }
1439
1440         die <<"EOF" if scalar @engines and !$config{dynamic_engines};
1441 ENGINES can only be used if configured with 'dynamic-engine'.
1442 This is usually a fault in a build.info file.
1443 EOF
1444         foreach (@engines) {
1445             my $library = cleanfile($buildd, $_, $blddir);
1446             if ($unified_info{rename}->{$library}) {
1447                 $library = $unified_info{rename}->{$library};
1448             }
1449             $unified_info{engines}->{$library} = 1;
1450         }
1451
1452         foreach (@scripts) {
1453             my $script = cleanfile($buildd, $_, $blddir);
1454             if ($unified_info{rename}->{$script}) {
1455                 $script = $unified_info{rename}->{$script};
1456             }
1457             $unified_info{scripts}->{$script} = 1;
1458         }
1459
1460         foreach (@extra) {
1461             my $extra = cleanfile($buildd, $_, $blddir);
1462             $unified_info{extra}->{$extra} = 1;
1463         }
1464
1465         foreach (@overrides) {
1466             my $override = cleanfile($buildd, $_, $blddir);
1467             $unified_info{overrides}->{$override} = 1;
1468         }
1469
1470         push @{$unified_info{rawlines}}, @rawlines;
1471
1472         unless ($disabled{shared}) {
1473             # Check sharednames.
1474             foreach (keys %sharednames) {
1475                 my $dest = cleanfile($buildd, $_, $blddir);
1476                 if ($unified_info{rename}->{$dest}) {
1477                     $dest = $unified_info{rename}->{$dest};
1478                 }
1479                 die "shared_name for $dest with multiple values: "
1480                     ,join(" ", @{$sharednames{$_}}),"\n"
1481                     if scalar @{$sharednames{$_}} > 1;
1482                 my $to = cleanfile($buildd, $sharednames{$_}->[0], $blddir);
1483                 die "shared_name found for a library $dest that isn't defined\n"
1484                     unless $unified_info{libraries}->{$dest};
1485                 die "shared_name for $dest with multiple values: "
1486                     ,$unified_info{sharednames}->{$dest}, ", ", $to
1487                     unless !defined($unified_info{sharednames}->{$dest})
1488                     or $unified_info{sharednames}->{$dest} eq $to;
1489                 $unified_info{sharednames}->{$dest} = $to;
1490             }
1491
1492             # Additionally, we set up sharednames for libraries that don't
1493             # have any, as themselves.
1494             foreach (keys %{$unified_info{libraries}}) {
1495                 if (!defined $unified_info{sharednames}->{$_}) {
1496                     $unified_info{sharednames}->{$_} = $_
1497                 }
1498             }
1499         }
1500
1501         foreach (keys %ordinals) {
1502             my $dest = $_;
1503             my $ddest = cleanfile($buildd, $_, $blddir);
1504             if ($unified_info{rename}->{$ddest}) {
1505                 $ddest = $unified_info{rename}->{$ddest};
1506             }
1507             foreach (@{$ordinals{$dest}}) {
1508                 my %known_ordinals =
1509                     (
1510                      crypto =>
1511                      cleanfile($sourced, catfile("util", "libcrypto.num"), $blddir),
1512                      ssl =>
1513                      cleanfile($sourced, catfile("util", "libssl.num"), $blddir)
1514                     );
1515                 my $o = $known_ordinals{$_};
1516                 die "Ordinals for $ddest defined more than once\n"
1517                     if $unified_info{ordinals}->{$ddest};
1518                 $unified_info{ordinals}->{$ddest} = [ $_, $o ];
1519             }
1520         }
1521
1522         foreach (keys %sources) {
1523             my $dest = $_;
1524             my $ddest = cleanfile($buildd, $_, $blddir);
1525             if ($unified_info{rename}->{$ddest}) {
1526                 $ddest = $unified_info{rename}->{$ddest};
1527             }
1528             foreach (@{$sources{$dest}}) {
1529                 my $s = cleanfile($sourced, $_, $blddir);
1530
1531                 # If it isn't in the source tree, we assume it's generated
1532                 # in the build tree
1533                 if (! -f $s) {
1534                     $s = cleanfile($buildd, $_, $blddir);
1535                 }
1536                 # We recognise C and asm files
1537                 if ($s =~ /\.[csS]\b$/) {
1538                     (my $o = $_) =~ s/\.[csS]\b$/.o/;
1539                     $o = cleanfile($buildd, $o, $blddir);
1540                     $unified_info{sources}->{$ddest}->{$o} = 1;
1541                     $unified_info{sources}->{$o}->{$s} = 1;
1542                 } else {
1543                     $unified_info{sources}->{$ddest}->{$s} = 1;
1544                 }
1545             }
1546         }
1547
1548         foreach (keys %generate) {
1549             my $dest = $_;
1550             my $ddest = cleanfile($buildd, $_, $blddir);
1551             if ($unified_info{rename}->{$ddest}) {
1552                 $ddest = $unified_info{rename}->{$ddest};
1553             }
1554             die "more than one generator for $dest: "
1555                     ,join(" ", @{$generate{$_}}),"\n"
1556                     if scalar @{$generate{$_}} > 1;
1557             my @generator = split /\s+/, $generate{$dest}->[0];
1558             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
1559             $unified_info{generate}->{$ddest} = [ @generator ];
1560         }
1561
1562         foreach (keys %depends) {
1563             my $dest = $_;
1564             my $ddest = cleanfile($buildd, $_, $blddir);
1565             if ($unified_info{rename}->{$ddest}) {
1566                 $ddest = $unified_info{rename}->{$ddest};
1567             }
1568             foreach (@{$depends{$dest}}) {
1569                 my $d = cleanfile($sourced, $_, $blddir);
1570
1571                 # If we know it's generated, or assume it is because we can't
1572                 # find it in the source tree, we set file we depend on to be
1573                 # in the build tree rather than the source tree, and assume
1574                 # and that there are lines to build it in a BEGINRAW..ENDRAW
1575                 # section or in the Makefile template.
1576                 if (! -f $d
1577                     || !(grep { $d eq $_ }
1578                          map { cleanfile($srcdir, $_, $blddir) }
1579                          (@generated_headers, @generated_by_make_headers))) {
1580                     $d = cleanfile($buildd, $_, $blddir);
1581                 }
1582                 # Take note if the file to depend on is being renamed
1583                 if ($unified_info{rename}->{$d}) {
1584                     $d = $unified_info{rename}->{$d};
1585                 }
1586                 $unified_info{depends}->{$ddest}->{$d} = 1;
1587                 # If we depend on a header file, let's make sure it
1588                 # can get included
1589                 if ($d =~ /\.h$/) {
1590                     my $i = dirname($d);
1591                     push @{$unified_info{includes}->{$ddest}}, $i
1592                         unless grep { $_ eq $i } @{$unified_info{includes}->{$ddest}};
1593                 }
1594             }
1595         }
1596
1597         foreach (keys %includes) {
1598             my $dest = $_;
1599             my $ddest = cleanfile($buildd, $_, $blddir);
1600             if ($unified_info{rename}->{$ddest}) {
1601                 $ddest = $unified_info{rename}->{$ddest};
1602             }
1603             foreach (@{$includes{$dest}}) {
1604                 my $i = cleandir($sourced, $_, $blddir);
1605                 push @{$unified_info{includes}->{$ddest}}, $i
1606                     unless grep { $_ eq $i } @{$unified_info{includes}->{$ddest}};
1607             }
1608         }
1609     }
1610
1611     ### Make unified_info a bit more efficient
1612     # One level structures
1613     foreach (("programs", "libraries", "engines", "scripts", "extra", "overrides")) {
1614         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
1615     }
1616     # Two level structures
1617     foreach my $l1 (("sources", "ldadd", "depends")) {
1618         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
1619             $unified_info{$l1}->{$l2} =
1620                 [ sort keys %{$unified_info{$l1}->{$l2}} ];
1621         }
1622     }
1623 }
1624
1625 # For the schemes that need it, we provide the old *_obj configs
1626 # from the *_asm_obj ones
1627 foreach (grep /_(asm|aux)_src$/, keys %target) {
1628     my $src = $_;
1629     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
1630     ($target{$obj} = $target{$src}) =~ s/\.[csS]\b/.o/g;
1631 }
1632
1633 # Write down our configuration where it fits #########################
1634
1635 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
1636 print OUT <<"EOF";
1637 package configdata;
1638
1639 use strict;
1640 use warnings;
1641
1642 use Exporter;
1643 #use vars qw(\@ISA \@EXPORT);
1644 our \@ISA = qw(Exporter);
1645 our \@EXPORT = qw(\%config \%target %disabled %withargs %unified_info);
1646
1647 EOF
1648 print OUT "our %config = (\n";
1649 foreach (sort keys %config) {
1650     if (ref($config{$_}) eq "ARRAY") {
1651         print OUT "  ", $_, " => [ ", join(", ",
1652                                            map { quotify("perl", $_) }
1653                                            @{$config{$_}}), " ],\n";
1654     } else {
1655         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
1656     }
1657 }
1658 print OUT <<"EOF";
1659 );
1660
1661 EOF
1662 print OUT "our %target = (\n";
1663 foreach (sort keys %target) {
1664     if (ref($target{$_}) eq "ARRAY") {
1665         print OUT "  ", $_, " => [ ", join(", ",
1666                                            map { quotify("perl", $_) }
1667                                            @{$target{$_}}), " ],\n";
1668     } else {
1669         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
1670     }
1671 }
1672 print OUT <<"EOF";
1673 );
1674
1675 EOF
1676 print OUT "our \%available_protocols = (\n";
1677 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
1678 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
1679 print OUT <<"EOF";
1680 );
1681
1682 EOF
1683 print OUT "our \%disabled = (\n";
1684 foreach (sort keys %disabled) {
1685     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
1686 }
1687 print OUT <<"EOF";
1688 );
1689
1690 EOF
1691 print OUT "our %withargs = (\n";
1692 foreach (sort keys %withargs) {
1693     if (ref($withargs{$_}) eq "ARRAY") {
1694         print OUT "  ", $_, " => [ ", join(", ",
1695                                            map { quotify("perl", $_) }
1696                                            @{$withargs{$_}}), " ],\n";
1697     } else {
1698         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
1699     }
1700 }
1701 print OUT <<"EOF";
1702 );
1703
1704 EOF
1705 if ($builder eq "unified") {
1706     my $recurse;
1707     $recurse = sub {
1708         my $indent = shift;
1709         foreach (@_) {
1710             if (ref $_ eq "ARRAY") {
1711                 print OUT " "x$indent, "[\n";
1712                 foreach (@$_) {
1713                     $recurse->($indent + 4, $_);
1714                 }
1715                 print OUT " "x$indent, "],\n";
1716             } elsif (ref $_ eq "HASH") {
1717                 my %h = %$_;
1718                 print OUT " "x$indent, "{\n";
1719                 foreach (sort keys %h) {
1720                     if (ref $h{$_} eq "") {
1721                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
1722                     } else {
1723                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
1724                         $recurse->($indent + 8, $h{$_});
1725                     }
1726                 }
1727                 print OUT " "x$indent, "},\n";
1728             } else {
1729                 print OUT " "x$indent, quotify("perl", $_), ",\n";
1730             }
1731         }
1732     };
1733     print OUT "our %unified_info = (\n";
1734     foreach (sort keys %unified_info) {
1735         if (ref $unified_info{$_} eq "") {
1736             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
1737         } else {
1738             print OUT " "x4, quotify("perl", $_), " =>\n";
1739             $recurse->(8, $unified_info{$_});
1740         }
1741     }
1742     print OUT <<"EOF";
1743 );
1744
1745 EOF
1746 }
1747 print OUT "1;\n";
1748 close(OUT);
1749
1750
1751 print "IsMK1MF       =", ($builder eq "mk1mf" ? "yes" : "no"), "\n";
1752 print "CC            =$target{cc}\n";
1753 print "CFLAG         =$target{cflags} $config{cflags}\n";
1754 print "DEFINES       =",join(" ", @{$target{defines}}, @{$config{defines}}),"\n";
1755 print "LFLAG         =$target{lflags}\n";
1756 print "PLIB_LFLAG    =$target{plib_lflags}\n";
1757 print "EX_LIBS       =$target{ex_libs} $config{ex_libs}\n";
1758 print "APPS_OBJ      =$target{apps_obj}\n";
1759 print "CPUID_OBJ     =$target{cpuid_obj}\n";
1760 print "UPLINK_OBJ    =$target{uplink_obj}\n";
1761 print "BN_ASM        =$target{bn_obj}\n";
1762 print "EC_ASM        =$target{ec_obj}\n";
1763 print "DES_ENC       =$target{des_obj}\n";
1764 print "AES_ENC       =$target{aes_obj}\n";
1765 print "BF_ENC        =$target{bf_obj}\n";
1766 print "CAST_ENC      =$target{cast_obj}\n";
1767 print "RC4_ENC       =$target{rc4_obj}\n";
1768 print "RC5_ENC       =$target{rc5_obj}\n";
1769 print "MD5_OBJ_ASM   =$target{md5_obj}\n";
1770 print "SHA1_OBJ_ASM  =$target{sha1_obj}\n";
1771 print "RMD160_OBJ_ASM=$target{rmd160_obj}\n";
1772 print "CMLL_ENC      =$target{cmll_obj}\n";
1773 print "MODES_OBJ     =$target{modes_obj}\n";
1774 print "PADLOCK_OBJ   =$target{padlock_obj}\n";
1775 print "CHACHA_ENC    =$target{chacha_obj}\n";
1776 print "POLY1305_OBJ  =$target{poly1305_obj}\n";
1777 print "PROCESSOR     =$config{processor}\n";
1778 print "RANLIB        =$target{ranlib}\n";
1779 print "ARFLAGS       =$target{arflags}\n";
1780 print "PERL          =$config{perl}\n";
1781 print "\n";
1782 print "SIXTY_FOUR_BIT_LONG mode\n" if $config{b64l};
1783 print "SIXTY_FOUR_BIT mode\n" if $config{b64};
1784 print "THIRTY_TWO_BIT mode\n" if $config{b32};
1785 print "BN_LLONG mode\n" if $config{bn_ll};
1786 print "RC4 uses $config{rc4_int}\n" if $config{rc4_int} != $def_int;
1787
1788 for (@generated_headers) {
1789     mkpath(catdir($blddir, dirname($_)));
1790     run_dofile(catfile($blddir, $_),
1791                catfile($srcdir, $_.".in"));
1792 }
1793
1794 ###
1795 ### When the old "unixmake" scheme goes away, so does this function
1796 ###
1797 sub build_Makefile {
1798     run_dofile("Makefile","Makefile.in");
1799
1800     # Copy all Makefile.in to Makefile (except top-level)
1801     use File::Find;
1802     use IO::File;
1803     find(
1804         {
1805             preprocess => sub {
1806                 grep(!/^\./, @_);
1807             },
1808             wanted => sub {
1809                 return if ($_ ne "Makefile.in" || $File::Find::dir eq ".");
1810                 my $in = IO::File->new($_, "r") or
1811                     die sprintf "Error reading Makefile.in in %s: !$\n",
1812                     $File::Find::dir;
1813                 my $out = IO::File->new("Makefile", "w") or
1814                     die sprintf "Error writing Makefile in %s: !$\n",
1815                     $File::Find::dir;
1816                 print $out "# Generated from $_, do not edit\n";
1817                 while (my $line = <$in>) { print $out $line }
1818                 $in->close() or
1819                     die sprintf "Error reading Makefile.in in %s: !$\n",
1820                     $File::Find::dir;
1821                 $out->close() or
1822                     die sprintf "Error writing Makefile in %s: !$\n",
1823                     $File::Find::dir;
1824             },
1825         },
1826         ".");
1827 }
1828
1829 my %builders = (
1830     unified => sub {
1831         run_dofile(catfile($blddir, $target{build_file}),
1832                    $config{build_file_template},
1833                    catfile($srcdir, "Configurations", "common.tmpl"));
1834     },
1835     unixmake => sub {
1836         build_Makefile();
1837
1838         run_dofile("util/domd", "util/domd.in");
1839         chmod 0755, "util/domd";
1840     },
1841     mk1mf => sub {
1842         my $platform = shift;
1843         # The only reason we do this is to have something to build MINFO from
1844         build_Makefile();
1845
1846         # create the ms/version32.rc file if needed
1847         if ($platform ne "netware") {
1848             my ($v1, $v2, $v3, $v4);
1849             if ($config{version_num} =~ /^0x([0-9a-f]{1})([0-9a-f]{2})([0-9a-f]{2})([0-9a-f]{2})([0-9a-f]{1})L$/i) {
1850                 $v1=hex $1;
1851                 $v2=hex $2;
1852                 $v3=hex $3;
1853                 $v4=hex $4;
1854             }
1855             open (OUT,">ms/version32.rc") || die "Can't open ms/version32.rc";
1856             print OUT <<"EOF";
1857 #include <winver.h>
1858
1859 LANGUAGE 0x09,0x01
1860
1861 1 VERSIONINFO
1862   FILEVERSION $v1,$v2,$v3,$v4
1863   PRODUCTVERSION $v1,$v2,$v3,$v4
1864   FILEFLAGSMASK 0x3fL
1865 #ifdef _DEBUG
1866   FILEFLAGS 0x01L
1867 #else
1868   FILEFLAGS 0x00L
1869 #endif
1870   FILEOS VOS__WINDOWS32
1871   FILETYPE VFT_DLL
1872   FILESUBTYPE 0x0L
1873 BEGIN
1874     BLOCK "StringFileInfo"
1875     BEGIN
1876         BLOCK "040904b0"
1877         BEGIN
1878             // Required:
1879             VALUE "CompanyName", "The OpenSSL Project, http://www.openssl.org/\\0"
1880             VALUE "FileDescription", "OpenSSL Shared Library\\0"
1881             VALUE "FileVersion", "$config{version}\\0"
1882 #if defined(CRYPTO)
1883             VALUE "InternalName", "libcrypto32\\0"
1884             VALUE "OriginalFilename", "libcrypto32.dll\\0"
1885 #elif defined(SSL)
1886             VALUE "InternalName", "libssl32\\0"
1887             VALUE "OriginalFilename", "libssl32.dll\\0"
1888 #endif
1889             VALUE "ProductName", "The OpenSSL Toolkit\\0"
1890             VALUE "ProductVersion", "$config{version}\\0"
1891             // Optional:
1892             //VALUE "Comments", "\\0"
1893             VALUE "LegalCopyright", "Copyright © 1998-2015 The OpenSSL Project. Copyright © 1995-1998 Eric A. Young, Tim J. Hudson. All rights reserved.\\0"
1894             //VALUE "LegalTrademarks", "\\0"
1895             //VALUE "PrivateBuild", "\\0"
1896             //VALUE "SpecialBuild", "\\0"
1897         END
1898     END
1899     BLOCK "VarFileInfo"
1900     BEGIN
1901         VALUE "Translation", 0x409, 0x4b0
1902     END
1903 END
1904 EOF
1905             close(OUT);
1906         }
1907     },
1908     );
1909
1910 $builders{$builder}->($builder_platform, @builder_opts);
1911
1912 print <<"EOF";
1913
1914 Configured for $target.
1915 EOF
1916
1917 print <<"EOF" if ($disabled{threads} eq "unavailable");
1918
1919 The library could not be configured for supporting multi-threaded
1920 applications as the compiler options required on this system are not known.
1921 See file INSTALL for details if you need multi-threading.
1922 EOF
1923
1924 print <<"EOF" if ($no_shared_warn);
1925
1926 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
1927 platform, so we will pretend you gave the option 'no-pic', which also disables
1928 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
1929 or position independent code, please let us know (but please first make sure
1930 you have tried with a current version of OpenSSL).
1931 EOF
1932
1933 exit(0);
1934
1935 ######################################################################
1936 #
1937 # Helpers and utility functions
1938 #
1939
1940 # Configuration file reading #########################################
1941
1942 # Helper function to implement conditional inheritance depending on the
1943 # value of $disabled{asm}.  Used in inherit_from values as follows:
1944 #
1945 #      inherit_from => [ "template", asm("asm_tmpl") ]
1946 #
1947 sub asm {
1948     my @x = @_;
1949     sub {
1950         $disabled{asm} ? () : @x;
1951     }
1952 }
1953
1954 our $add_called = 0;
1955 # Helper function to implement adding values to already existing configuration
1956 # values.  It handles elements that are ARRAYs, CODEs and scalars
1957 sub _add {
1958     my $separator = shift;
1959
1960     # If there's any ARRAY in the collection of values OR the separator
1961     # is undef, we will return an ARRAY of combined values, otherwise a
1962     # string of joined values with $separator as the separator.
1963     my $found_array = !defined($separator);
1964
1965     my @values =
1966         map {
1967             my $res = $_;
1968             while (ref($res) eq "CODE") {
1969                 $res = $res->();
1970             }
1971             if (defined($res)) {
1972                 if (ref($res) eq "ARRAY") {
1973                     $found_array = 1;
1974                     @$res;
1975                 } else {
1976                     $res;
1977                 }
1978             } else {
1979                 ();
1980             }
1981     } (@_);
1982
1983     $add_called = 1;
1984
1985     if ($found_array) {
1986         [ @values ];
1987     } else {
1988         join($separator, grep { defined($_) && $_ ne "" } @values);
1989     }
1990 }
1991 sub add_before {
1992     my $separator = " ";
1993     if (ref($_[$#_]) eq "HASH") {
1994         my $opts = pop;
1995         $separator = $opts->{separator};
1996     }
1997     my @x = @_;
1998     sub { _add($separator, @x, @_) };
1999 }
2000 sub add {
2001     my $separator = " ";
2002     if (ref($_[$#_]) eq "HASH") {
2003         my $opts = pop;
2004         $separator = $opts->{separator};
2005     }
2006     my @x = @_;
2007     sub { _add($separator, @_, @x) };
2008 }
2009
2010 # configuration reader, evaluates the input file as a perl script and expects
2011 # it to fill %targets with target configurations.  Those are then added to
2012 # %table.
2013 sub read_config {
2014     my $fname = shift;
2015     open(CONFFILE, "< $fname")
2016         or die "Can't open configuration file '$fname'!\n";
2017     my $x = $/;
2018     undef $/;
2019     my $content = <CONFFILE>;
2020     $/ = $x;
2021     close(CONFFILE);
2022     my %targets = ();
2023     {
2024         local %table = %::table;    # Protect %table from tampering
2025
2026         eval $content;
2027         warn $@ if $@;
2028     }
2029
2030     # For each target, check that it's configured with a hash table.
2031     foreach (keys %targets) {
2032         if (ref($targets{$_}) ne "HASH") {
2033             if (ref($targets{$_}) eq "") {
2034                 warn "Deprecated target configuration for $_, ignoring...\n";
2035             } else {
2036                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2037             }
2038             delete $targets{$_};
2039         }
2040     }
2041
2042     %table = (%table, %targets);
2043
2044 }
2045
2046 # configuration resolver.  Will only resolve all the lazy evalutation
2047 # codeblocks for the chozen target and all those it inherits from,
2048 # recursively
2049 sub resolve_config {
2050     my $target = shift;
2051     my @breadcrumbs = @_;
2052
2053     my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2054
2055     if (grep { $_ eq $target } @breadcrumbs) {
2056         die "inherit_from loop!  target backtrace:\n  "
2057             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2058     }
2059
2060     if (!defined($table{$target})) {
2061         warn "Warning! target $target doesn't exist!\n";
2062         return ();
2063     }
2064     # Recurse through all inheritances.  They will be resolved on the
2065     # fly, so when this operation is done, they will all just be a
2066     # bunch of attributes with string values.
2067     # What we get here, though, are keys with references to lists of
2068     # the combined values of them all.  We will deal with lists after
2069     # this stage is done.
2070     my %combined_inheritance = ();
2071     if ($table{$target}->{inherit_from}) {
2072         my @inherit_from =
2073             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2074         foreach (@inherit_from) {
2075             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2076
2077             # 'template' is a marker that's considered private to
2078             # the config that had it.
2079             delete $inherited_config{template};
2080
2081             map {
2082                 if (!$combined_inheritance{$_}) {
2083                     $combined_inheritance{$_} = [];
2084                 }
2085                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2086             } keys %inherited_config;
2087         }
2088     }
2089
2090     # We won't need inherit_from in this target any more, since we've
2091     # resolved all the inheritances that lead to this
2092     delete $table{$target}->{inherit_from};
2093
2094     # Now is the time to deal with those lists.  Here's the place to
2095     # decide what shall be done with those lists, all based on the
2096     # values of the target we're currently dealing with.
2097     # - If a value is a coderef, it will be executed with the list of
2098     #   inherited values as arguments.
2099     # - If the corresponding key doesn't have a value at all or is the
2100     #   emoty string, the inherited value list will be run through the
2101     #   default combiner (below), and the result becomes this target's
2102     #   value.
2103     # - Otherwise, this target's value is assumed to be a string that
2104     #   will simply override the inherited list of values.
2105     my $default_combiner = add();
2106
2107     my %all_keys =
2108         map { $_ => 1 } (keys %combined_inheritance,
2109                          keys %{$table{$target}});
2110
2111     sub process_values {
2112         my $object    = shift;
2113         my $inherited = shift;  # Always a [ list ]
2114         my $target    = shift;
2115         my $entry     = shift;
2116
2117         $add_called = 0;
2118
2119         while(ref($object) eq "CODE") {
2120             $object = $object->(@$inherited);
2121         }
2122         if (!defined($object)) {
2123             return ();
2124         }
2125         elsif (ref($object) eq "ARRAY") {
2126             local $add_called;  # To make sure recursive calls don't affect it
2127             return [ map { process_values($_, $inherited, $target, $entry) }
2128                      @$object ];
2129         } elsif (ref($object) eq "") {
2130             return $object;
2131         } else {
2132             die "cannot handle reference type ",ref($object)
2133                 ," found in target ",$target," -> ",$entry,"\n";
2134         }
2135     }
2136
2137     foreach (sort keys %all_keys) {
2138         my $previous = $combined_inheritance{$_};
2139
2140         # Current target doesn't have a value for the current key?
2141         # Assign it the default combiner, the rest of this loop body
2142         # will handle it just like any other coderef.
2143         if (!exists $table{$target}->{$_}) {
2144             $table{$target}->{$_} = $default_combiner;
2145         }
2146
2147         $table{$target}->{$_} = process_values($table{$target}->{$_},
2148                                                $combined_inheritance{$_},
2149                                                $target, $_);
2150         unless(defined($table{$target}->{$_})) {
2151             delete $table{$target}->{$_};
2152         }
2153         if ($extra_checks &&
2154             $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2155             warn "$_ got replaced in $target\n";
2156         }
2157     }
2158
2159     # Finally done, return the result.
2160     return %{$table{$target}};
2161 }
2162
2163 sub usage
2164         {
2165         print STDERR $usage;
2166         print STDERR "\npick os/compiler from:\n";
2167         my $j=0;
2168         my $i;
2169         my $k=0;
2170         foreach $i (sort keys %table)
2171                 {
2172                 next if $table{$i}->{template};
2173                 next if $i =~ /^debug/;
2174                 $k += length($i) + 1;
2175                 if ($k > 78)
2176                         {
2177                         print STDERR "\n";
2178                         $k=length($i);
2179                         }
2180                 print STDERR $i . " ";
2181                 }
2182         foreach $i (sort keys %table)
2183                 {
2184                 next if $table{$i}->{template};
2185                 next if $i !~ /^debug/;
2186                 $k += length($i) + 1;
2187                 if ($k > 78)
2188                         {
2189                         print STDERR "\n";
2190                         $k=length($i);
2191                         }
2192                 print STDERR $i . " ";
2193                 }
2194         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2195         exit(1);
2196         }
2197
2198 sub run_dofile()
2199 {
2200     my $out = shift;
2201     my @templates = @_;
2202
2203     unlink $out || warn "Can't remove $out, $!"
2204         if -f $out;
2205     foreach (@templates) {
2206         die "Can't open $_, $!" unless -f $_;
2207     }
2208     my $cmd = "$config{perl} \"-I.\" \"-Mconfigdata\" $dofile -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
2209     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2210     system($cmd);
2211     exit 1 if $? != 0;
2212     rename("$out.new", $out) || die "Can't rename $out.new, $!";
2213 }
2214
2215 # Configuration printer ##############################################
2216
2217 sub print_table_entry
2218 {
2219     my $target = shift;
2220     my %target = resolve_config($target);
2221     my $type = shift;
2222
2223     # Don't print the templates
2224     return if $target{template};
2225
2226     my @sequence = (
2227         "sys_id",
2228         "cc",
2229         "cflags",
2230         "defines",
2231         "unistd",
2232         "ld",
2233         "lflags",
2234         "plib_lflags",
2235         "ex_libs",
2236         "bn_ops",
2237         "cpuid_obj",
2238         "bn_obj",
2239         "ec_obj",
2240         "des_obj",
2241         "aes_obj",
2242         "bf_obj",
2243         "md5_obj",
2244         "sha1_obj",
2245         "cast_obj",
2246         "rc4_obj",
2247         "rmd160_obj",
2248         "rc5_obj",
2249         "wp_obj",
2250         "cmll_obj",
2251         "modes_obj",
2252         "padlock_obj",
2253         "thread_scheme",
2254         "perlasm_scheme",
2255         "dso_scheme",
2256         "shared_target",
2257         "shared_cflag",
2258         "shared_ldflag",
2259         "shared_rcflag",
2260         "shared_extension",
2261         "shared_extension_simple",
2262         "shared_import_extension",
2263         "dso_extension",
2264         "obj_extension",
2265         "exe_extension",
2266         "ranlib",
2267         "ar",
2268         "arflags",
2269         "multilib",
2270         "build_scheme",
2271         );
2272
2273     if ($type eq "TABLE") {
2274         print "\n";
2275         print "*** $target\n";
2276         foreach (@sequence) {
2277             if (ref($target{$_}) eq "ARRAY") {
2278                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
2279             } else {
2280                 printf "\$%-12s = %s\n", $_, $target{$_};
2281             }
2282         }
2283     } elsif ($type eq "HASH") {
2284         my $largest =
2285             length((sort { length($a) <=> length($b) } @sequence)[-1]);
2286         print "    '$target' => {\n";
2287         foreach (@sequence) {
2288             if ($target{$_}) {
2289                 if (ref($target{$_}) eq "ARRAY") {
2290                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
2291                 } else {
2292                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
2293                 }
2294             }
2295         }
2296         print "    },\n";
2297     }
2298 }
2299
2300 # Utility routines ###################################################
2301
2302 # On VMS, if the given file is a logical name, File::Spec::Functions
2303 # will consider it an absolute path.  There are cases when we want a
2304 # purely syntactic check without checking the environment.
2305 sub isabsolute {
2306     my $file = shift;
2307
2308     # On non-platforms, we just use file_name_is_absolute().
2309     return file_name_is_absolute($file) unless $^O eq "VMS";
2310
2311     # If the file spec includes a device or a directpry spec,
2312     # file_name_is_absolute() is perfectly safe.
2313     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
2314
2315     # Here, we know the given file spec isn't absolute
2316     return 0;
2317 }
2318
2319 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
2320 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
2321 # realpath() requires that at least all path components except the last is an
2322 # existing directory.  On VMS, the last component of the directory spec must
2323 # exist.
2324 sub absolutedir {
2325     my $dir = shift;
2326
2327     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
2328     # will return the volume name for the device, no matter what.  Also,
2329     # it will return an incorrect directory spec if the argument is a
2330     # directory that doesn't exist.
2331     if ($^O eq "VMS") {
2332         return rel2abs($dir);
2333     }
2334
2335     # We use realpath() on Unix, since no other will properly clean out
2336     # a directory spec.
2337     use Cwd qw/realpath/;
2338
2339     return realpath($dir);
2340 }
2341
2342 sub which
2343         {
2344         my($name)=@_;
2345         my $path;
2346         foreach $path (split /:/, $ENV{PATH})
2347                 {
2348                 my $fullpath = "$path/$name$target{exe_extension}";
2349                 if (-f $fullpath and -x $fullpath)
2350                         {
2351                         return $fullpath
2352                             unless ($name eq "perl" and
2353                                     system("$fullpath -e " . '\'exit($]<5.0);\''));
2354                         }
2355                 }
2356         }
2357
2358 sub quotify {
2359     my %processors = (
2360         perl    => sub { my $x = shift;
2361                          $x =~ s/([\\\$\@"])/\\$1/g;
2362                          return '"'.$x.'"'; },
2363         );
2364     my $for = shift;
2365     my $processor =
2366         defined($processors{$for}) ? $processors{$for} : sub { shift; };
2367
2368     map { $processor->($_); } @_;
2369 }
2370
2371 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
2372 # $filename is a file name to read from
2373 # $line_concat_cond_re is a regexp detecting a line continuation ending
2374 # $line_concat is a CODEref that takes care of concatenating two lines
2375 sub collect_from_file {
2376     my $filename = shift;
2377     my $line_concat_cond_re = shift;
2378     my $line_concat = shift;
2379
2380     open my $fh, $filename || die "unable to read $filename: $!\n";
2381     return sub {
2382         my $saved_line = "";
2383         $_ = "";
2384         while (<$fh>) {
2385             s|\R$||;
2386             if (defined $line_concat) {
2387                 $_ = $line_concat->($saved_line, $_);
2388                 $saved_line = "";
2389             }
2390             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2391                 $saved_line = $_;
2392                 next;
2393             }
2394             return $_;
2395         }
2396         die "$filename ending with continuation line\n" if $_;
2397         close $fh;
2398         return undef;
2399     }
2400 }
2401
2402 # collect_from_array($array, $line_concat_cond_re, $line_concat)
2403 # $array is an ARRAYref of lines
2404 # $line_concat_cond_re is a regexp detecting a line continuation ending
2405 # $line_concat is a CODEref that takes care of concatenating two lines
2406 sub collect_from_array {
2407     my $array = shift;
2408     my $line_concat_cond_re = shift;
2409     my $line_concat = shift;
2410     my @array = (@$array);
2411
2412     return sub {
2413         my $saved_line = "";
2414         $_ = "";
2415         while (defined($_ = shift @array)) {
2416             s|\R$||;
2417             if (defined $line_concat) {
2418                 $_ = $line_concat->($saved_line, $_);
2419                 $saved_line = "";
2420             }
2421             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2422                 $saved_line = $_;
2423                 next;
2424             }
2425             return $_;
2426         }
2427         die "input text ending with continuation line\n" if $_;
2428         return undef;
2429     }
2430 }
2431
2432 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
2433 # $lineiterator is a CODEref that delivers one line at a time.
2434 # All following arguments are regex/CODEref pairs, where the regexp detects a
2435 # line and the CODEref does something with the result of the regexp.
2436 sub collect_information {
2437     my $lineiterator = shift;
2438     my %collectors = @_;
2439
2440     while(defined($_ = $lineiterator->())) {
2441         s|\R$||;
2442         my $found = 0;
2443         foreach my $re (keys %collectors) {
2444             if ($re ne "OTHERWISE" && /$re/) {
2445                 $collectors{$re}->($lineiterator);
2446                 $found = 1;
2447             };
2448         }
2449         if ($collectors{"OTHERWISE"}) {
2450             $collectors{"OTHERWISE"}->($lineiterator, $_)
2451                 unless $found || !defined $collectors{"OTHERWISE"};
2452         }
2453     }
2454 }