Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::Glob;
  21
  22 # see INSTALL for instructions.
  23
  24 my $orig_death_handler = $SIG{__DIE__};
  25 $SIG{__DIE__} = \&death_handler;
  26
  27 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  28
  29 # Options:
  30 #
  31 # --config      add the given configuration file, which will be read after
  32 #               any "Configurations*" files that are found in the same
  33 #               directory as this script.
  34 # --prefix      prefix for the OpenSSL installation, which includes the
  35 #               directories bin, lib, include, share/man, share/doc/openssl
  36 #               This becomes the value of INSTALLTOP in Makefile
  37 #               (Default: /usr/local)
  38 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  39 #               If it's a relative directory, it will be added on the directory
  40 #               given with --prefix.
  41 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  42 #               (Default: PREFIX/ssl)
  43 #
  44 # --cross-compile-prefix Add specified prefix to binutils components.
  45 #
  46 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0.0 / 3.
  47 #               Do not compile support for interfaces deprecated as of the
  48 #               specified OpenSSL version.
  49 #
  50 # no-hw-xxx     do not compile support for specific crypto hardware.
  51 #               Generic OpenSSL-style methods relating to this support
  52 #               are always compiled but return NULL if the hardware
  53 #               support isn't compiled.
  54 # no-hw         do not compile support for any crypto hardware.
  55 # [no-]threads  [don't] try to create a library that is suitable for
  56 #               multithreaded applications (default is "threads" if we
  57 #               know how to do it)
  58 # [no-]shared   [don't] try to create shared libraries when supported.
  59 # [no-]pic      [don't] try to build position independent code when supported.
  60 #               If disabled, it also disables shared and dynamic-engine.
  61 # no-asm        do not use assembler
  62 # no-egd        do not compile support for the entropy-gathering daemon APIs
  63 # [no-]zlib     [don't] compile support for zlib compression.
  64 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  65 #               library and will be loaded in run-time by the OpenSSL library.
  66 # sctp          include SCTP support
  67 # no-uplink     Don't build support for UPLINK interface.
  68 # enable-weak-ssl-ciphers
  69 #               Enable weak ciphers that are disabled by default.
  70 # 386           generate 80386 code in assembly modules
  71 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  72 #               mentioned '386' option implies this one
  73 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  74 # -<xxx> +<xxx> compiler options are passed through
  75 # -static       while -static is also a pass-through compiler option (and
  76 #               as such is limited to environments where it's actually
  77 #               meaningful), it triggers a number configuration options,
  78 #               namely no-pic, no-shared and no-threads. It is
  79 #               argued that the only reason to produce statically linked
  80 #               binaries (and in context it means executables linked with
  81 #               -static flag, and not just executables linked with static
  82 #               libcrypto.a) is to eliminate dependency on specific run-time,
  83 #               a.k.a. libc version. The mentioned config options are meant
  84 #               to achieve just that. Unfortunately on Linux it's impossible
  85 #               to eliminate the dependency completely for openssl executable
  86 #               because of getaddrinfo and gethostbyname calls, which can
  87 #               invoke dynamically loadable library facility anyway to meet
  88 #               the lookup requests. For this reason on Linux statically
  89 #               linked openssl executable has rather debugging value than
  90 #               production quality.
  91 #
  92 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  93 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  94 # Following are set automatically by this script
  95 #
  96 # MD5_ASM       use some extra md5 assembler,
  97 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
  98 # RMD160_ASM    use some extra ripemd160 assembler,
  99 # SHA256_ASM    sha256_block is implemented in assembler
 100 # SHA512_ASM    sha512_block is implemented in assembler
 101 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 102
 103 # Minimum warning options... any contributions to OpenSSL should at least
 104 # get past these.  Note that we only use these with C compilers, not with
 105 # C++ compilers.
 106
 107 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 108 # -DPEDANTIC complements -pedantic and is meant to mask code that
 109 # is not strictly standard-compliant and/or implementation-specific,
 110 # e.g. inline assembly, disregards to alignment requirements, such
 111 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 112 # to be used even in sanitized builds, because sanitizer too is
 113 # supposed to and does take notice of non-standard behaviour. Then
 114 # -pedantic with pre-C9x compiler would also complain about 'long
 115 # long' not being supported. As 64-bit algorithms are common now,
 116 # it grew impossible to resolve this without sizeable additional
 117 # code, so we just tell compiler to be pedantic about everything
 118 # but 'long long' type.
 119
 120 my @gcc_devteam_warn = qw(
 121     -DDEBUG_UNUSED
 122     -DPEDANTIC -pedantic -Wno-long-long
 123     -Wall
 124     -Wextra
 125     -Wno-unused-parameter
 126     -Wno-missing-field-initializers
 127     -Wswitch
 128     -Wsign-compare
 129     -Wshadow
 130     -Wformat
 131     -Wtype-limits
 132     -Wundef
 133     -Werror
 134     -Wmissing-prototypes
 135     -Wstrict-prototypes
 136 );
 137
 138 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 139 # TODO(openssl-team): fix problems and investigate if (at least) the
 140 # following warnings can also be enabled:
 141 #       -Wcast-align
 142 #       -Wunreachable-code -- no, too ugly/compiler-specific
 143 #       -Wlanguage-extension-token -- no, we use asm()
 144 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 145 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 146 my @clang_devteam_warn = qw(
 147     -Wswitch-default
 148     -Wno-parentheses-equality
 149     -Wno-language-extension-token
 150     -Wno-extended-offsetof
 151     -Wconditional-uninitialized
 152     -Wincompatible-pointer-types-discards-qualifiers
 153     -Wno-unknown-warning-option
 154     -Wmissing-variable-declarations
 155 );
 156
 157 # This adds backtrace information to the memory leak info.  Is only used
 158 # when crypto-mdebug-backtrace is enabled.
 159 my $memleak_devteam_backtrace = "-rdynamic";
 160
 161 my $strict_warnings = 0;
 162
 163 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 164 # which would cover all BSD flavors. -pthread applies to them all,
 165 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 166 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 167 # which has to be accompanied by explicit -D_THREAD_SAFE and
 168 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 169 # seems to be sufficient?
 170 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 171
 172 #
 173 # API compatibility name to version number mapping.
 174 #
 175 my $maxapi = "3.0.0";           # API for "no-deprecated" builds
 176 my $apitable = {
 177     "3.0.0" => 3,
 178     "1.1.1" => 2,
 179     "1.1.0" => 2,
 180     "1.0.2" => 1,
 181     "1.0.1" => 1,
 182     "1.0.0" => 1,
 183     "0.9.8" => 0,
 184 };
 185
 186 our %table = ();
 187 our %config = ();
 188 our %withargs = ();
 189 our $now_printing;      # set to current entry's name in print_table_entry
 190                         # (todo: right thing would be to encapsulate name
 191                         # into %target [class] and make print_table_entry
 192                         # a method)
 193
 194 # Forward declarations ###############################################
 195
 196 # read_config(filename)
 197 #
 198 # Reads a configuration file and populates %table with the contents
 199 # (which the configuration file places in %targets).
 200 sub read_config;
 201
 202 # resolve_config(target)
 203 #
 204 # Resolves all the late evaluations, inheritances and so on for the
 205 # chosen target and any target it inherits from.
 206 sub resolve_config;
 207
 208
 209 # Information collection #############################################
 210
 211 # Unified build supports separate build dir
 212 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 213 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 214 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 215
 216 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 217
 218 $config{sourcedir} = abs2rel($srcdir);
 219 $config{builddir} = abs2rel($blddir);
 220
 221 # Collect reconfiguration information if needed
 222 my @argvcopy=@ARGV;
 223
 224 if (grep /^reconf(igure)?$/, @argvcopy) {
 225     die "reconfiguring with other arguments present isn't supported"
 226         if scalar @argvcopy > 1;
 227     if (-f "./configdata.pm") {
 228         my $file = "./configdata.pm";
 229         unless (my $return = do $file) {
 230             die "couldn't parse $file: $@" if $@;
 231             die "couldn't do $file: $!"    unless defined $return;
 232             die "couldn't run $file"       unless $return;
 233         }
 234
 235         @argvcopy = defined($configdata::config{perlargv}) ?
 236             @{$configdata::config{perlargv}} : ();
 237         die "Incorrect data to reconfigure, please do a normal configuration\n"
 238             if (grep(/^reconf/,@argvcopy));
 239         $config{perlenv} = $configdata::config{perlenv} // {};
 240     } else {
 241         die "Insufficient data to reconfigure, please do a normal configuration\n";
 242     }
 243 }
 244
 245 $config{perlargv} = [ @argvcopy ];
 246
 247 # Collect version numbers
 248 $config{major} = "unknown";
 249 $config{minor} = "unknown";
 250 $config{patch} = "unknown";
 251 $config{prerelease} = "";
 252 $config{build_metadata} = "";
 253 $config{shlib_version} = "unknown";
 254
 255 collect_information(
 256     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 257     qr/#\s+define\s+OPENSSL_VERSION_MAJOR\s+(\d+)/ =>
 258         sub { $config{major} = $1; },
 259     qr/#\s+define\s+OPENSSL_VERSION_MINOR\s+(\d+)/ =>
 260         sub { $config{minor} = $1; },
 261     qr/#\s+define\s+OPENSSL_VERSION_PATCH\s+(\d+)/ =>
 262         sub { $config{patch} = $1; },
 263     qr/#\s+define\s+OPENSSL_VERSION_PRE_RELEASE\s+"((?:\\.|[^"])*)"/ =>
 264         sub { $config{prerelease} = $1; },
 265     qr/#\s+define\s+OPENSSL_VERSION_BUILD_METADATA\s+"((?:\\.|[^"])*)"/ =>
 266         sub { $config{build_metadata} = $1; },
 267     qr/#\s+define\s+OPENSSL_SHLIB_VERSION\s+([\d\.]+)/ =>
 268         sub { $config{shlib_version} = $1; },
 269     );
 270 die "erroneous version information in opensslv.h: ",
 271     "$config{major}.$config{minor}.$config{patch}, $config{shlib_version}\n"
 272     if ($config{major} eq "unknown"
 273             || $config{minor} eq "unknown"
 274             || $config{patch} eq "unknown"
 275             || $config{shlib_version} eq "unknown");
 276
 277 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 278 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 279
 280 # Collect target configurations
 281
 282 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 283 foreach (sort glob($pattern)) {
 284     &read_config($_);
 285 }
 286
 287 if (defined env($local_config_envname)) {
 288     if ($^O eq 'VMS') {
 289         # VMS environment variables are logical names,
 290         # which can be used as is
 291         $pattern = $local_config_envname . ':' . '*.conf';
 292     } else {
 293         $pattern = catfile(env($local_config_envname), '*.conf');
 294     }
 295
 296     foreach (sort glob($pattern)) {
 297         &read_config($_);
 298     }
 299 }
 300
 301 # Save away perl command information
 302 $config{perl_cmd} = $^X;
 303 $config{perl_version} = $Config{version};
 304 $config{perl_archname} = $Config{archname};
 305
 306 $config{prefix}="";
 307 $config{openssldir}="";
 308 $config{processor}="";
 309 $config{libdir}="";
 310 my $auto_threads=1;    # enable threads automatically? true by default
 311 my $default_ranlib;
 312
 313 # Known TLS and DTLS protocols
 314 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 315 my @dtls = qw(dtls1 dtls1_2);
 316
 317 # Explicitly known options that are possible to disable.  They can
 318 # be regexps, and will be used like this: /^no-${option}$/
 319 # For developers: keep it sorted alphabetically
 320
 321 my @disablables = (
 322     "ktls",
 323     "afalgeng",
 324     "aria",
 325     "asan",
 326     "asm",
 327     "async",
 328     "autoalginit",
 329     "autoerrinit",
 330     "autoload-config",
 331     "bf",
 332     "blake2",
 333     "buildtest-c++",
 334     "camellia",
 335     "capieng",
 336     "cast",
 337     "chacha",
 338     "cmac",
 339     "cmp",
 340     "cms",
 341     "comp",
 342     "crypto-mdebug",
 343     "crypto-mdebug-backtrace",
 344     "ct",
 345     "deprecated",
 346     "des",
 347     "devcryptoeng",
 348     "dgram",
 349     "dh",
 350     "dsa",
 351     "dtls",
 352     "dynamic-engine",
 353     "ec",
 354     "ec2m",
 355     "ecdh",
 356     "ecdsa",
 357     "ec_nistp_64_gcc_128",
 358     "egd",
 359     "engine",
 360     "err",
 361     "external-tests",
 362     "filenames",
 363     "fips",
 364     "fuzz-libfuzzer",
 365     "fuzz-afl",
 366     "gost",
 367     "idea",
 368     "legacy",
 369     "makedepend",
 370     "md2",
 371     "md4",
 372     "mdc2",
 373     "module",
 374     "msan",
 375     "multiblock",
 376     "nextprotoneg",
 377     "pinshared",
 378     "ocb",
 379     "ocsp",
 380     "padlockeng",
 381     "pic",
 382     "poly1305",
 383     "posix-io",
 384     "psk",
 385     "rc2",
 386     "rc4",
 387     "rc5",
 388     "rdrand",
 389     "rfc3779",
 390     "rmd160",
 391     "scrypt",
 392     "sctp",
 393     "seed",
 394     "shared",
 395     "siphash",
 396     "siv",
 397     "sm2",
 398     "sm3",
 399     "sm4",
 400     "sock",
 401     "srp",
 402     "srtp",
 403     "sse2",
 404     "ssl",
 405     "ssl-trace",
 406     "static-engine",
 407     "stdio",
 408     "tests",
 409     "threads",
 410     "tls",
 411     "trace",
 412     "ts",
 413     "ubsan",
 414     "ui-console",
 415     "unit-test",
 416     "uplink",
 417     "whirlpool",
 418     "weak-ssl-ciphers",
 419     "zlib",
 420     "zlib-dynamic",
 421     );
 422 foreach my $proto ((@tls, @dtls))
 423         {
 424         push(@disablables, $proto);
 425         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 426         }
 427
 428 # Internal disablables, for aliasing purposes.  They serve no special
 429 # purpose here, but allow scripts to get to know them through configdata.pm,
 430 # where these are merged with @disablables.
 431 # The actual aliasing mechanism is done via %disable_cascades
 432 my @disablables_int = qw(
 433     crmf
 434     );
 435
 436 my %deprecated_disablables = (
 437     "ssl2" => undef,
 438     "buf-freelists" => undef,
 439     "hw" => "hw",               # causes cascade, but no macro
 440     "hw-padlock" => "padlockeng",
 441     "ripemd" => "rmd160",
 442     "ui" => "ui-console",
 443     "dso" => undef,
 444     "heartbeats" => undef,
 445     );
 446
 447 # All of the following are disabled by default:
 448
 449 our %disabled = ( # "what"         => "comment"
 450                   "asan"                => "default",
 451                   "buildtest-c++"       => "default",
 452                   "crypto-mdebug"       => "default",
 453                   "crypto-mdebug-backtrace" => "default",
 454                   "devcryptoeng"        => "default",
 455                   "ec_nistp_64_gcc_128" => "default",
 456                   "egd"                 => "default",
 457                   "external-tests"      => "default",
 458                   "fuzz-libfuzzer"      => "default",
 459                   "fuzz-afl"            => "default",
 460                   "md2"                 => "default",
 461                   "msan"                => "default",
 462                   "rc5"                 => "default",
 463                   "sctp"                => "default",
 464                   "ssl-trace"           => "default",
 465                   "ssl3"                => "default",
 466                   "ssl3-method"         => "default",
 467                   "trace"               => "default",
 468                   "ubsan"               => "default",
 469                   "unit-test"           => "default",
 470                   "weak-ssl-ciphers"    => "default",
 471                   "zlib"                => "default",
 472                   "zlib-dynamic"        => "default",
 473                   "ktls"                => "default",
 474                 );
 475
 476 # Note: => pair form used for aesthetics, not to truly make a hash table
 477 my @disable_cascades = (
 478     # "what"            => [ "cascade", ... ]
 479     sub { $config{processor} eq "386" }
 480                         => [ "sse2" ],
 481     "ssl"               => [ "ssl3" ],
 482     "ssl3-method"       => [ "ssl3" ],
 483     "zlib"              => [ "zlib-dynamic" ],
 484     "des"               => [ "mdc2" ],
 485     "ec"                => [ "ecdsa", "ecdh", "sm2" ],
 486     sub { $disabled{"ec"} && $disabled{"dh"} }
 487                         => [ "tls1_3" ],
 488     "dgram"             => [ "dtls", "sctp" ],
 489     "sock"              => [ "dgram" ],
 490     "dtls"              => [ @dtls ],
 491     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 492                         => [ "dtls" ],
 493
 494     "tls"               => [ @tls ],
 495     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 496                         => [ "tls" ],
 497
 498     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 499
 500     # If no modules, then no dynamic engines either
 501     "module"            => [ "dynamic-engine" ],
 502
 503     # Without shared libraries, dynamic engines aren't possible.
 504     # This is due to them having to link with libcrypto and register features
 505     # using the ENGINE functionality, and since that relies on global tables,
 506     # those *have* to be exacty the same as the ones accessed from the app,
 507     # which cannot be guaranteed if shared libraries aren't present.
 508     # (note that even with shared libraries, both the app and dynamic engines
 509     # must be linked with the same library)
 510     "shared"            => [ "dynamic-engine", "uplink" ],
 511     # Other modules don't necessarily have to link with libcrypto, so shared
 512     # libraries do not have to be a condition to produce those.
 513
 514     # Without position independent code, there can be no shared libraries
 515     # or modules.
 516     "pic"               => [ "shared", "module" ],
 517
 518     "module"            => [ "fips", "legacy" ],
 519
 520     "engine"            => [ grep /eng$/, @disablables ],
 521     "hw"                => [ "padlockeng" ],
 522
 523     # no-autoalginit is only useful when building non-shared
 524     "autoalginit"       => [ "shared", "apps" ],
 525
 526     "stdio"             => [ "apps", "capieng", "egd" ],
 527     "apps"              => [ "tests" ],
 528     "tests"             => [ "external-tests" ],
 529     "comp"              => [ "zlib" ],
 530     "sm3"               => [ "sm2" ],
 531     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 532
 533     sub { !$disabled{"msan"} } => [ "asm" ],
 534
 535     sub { $disabled{cmac}; } => [ "siv" ],
 536     "legacy"                 => [ "md2" ],
 537
 538     "cmp"               => [ "crmf" ],
 539     );
 540
 541 # Avoid protocol support holes.  Also disable all versions below N, if version
 542 # N is disabled while N+1 is enabled.
 543 #
 544 my @list = (reverse @tls);
 545 while ((my $first, my $second) = (shift @list, shift @list)) {
 546     last unless @list;
 547     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 548                               => [ @list ] );
 549     unshift @list, $second;
 550 }
 551 my @list = (reverse @dtls);
 552 while ((my $first, my $second) = (shift @list, shift @list)) {
 553     last unless @list;
 554     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 555                               => [ @list ] );
 556     unshift @list, $second;
 557 }
 558
 559 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 560 # To remove something from %disabled, use "enable-foo".
 561 # For symmetry, "disable-foo" is a synonym for "no-foo".
 562
 563 &usage if ($#ARGV < 0);
 564
 565 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 566 # platform specific list separators.  Users from those platforms should
 567 # recognise those separators from how you set up the PATH to find executables.
 568 # The default is the Unix like separator, :, but as an exception, we also
 569 # support the space as separator.
 570 my $list_separator_re =
 571     { VMS           => qr/(?<!\^),/,
 572       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 573 # All the "make variables" we support
 574 # Some get pre-populated for the sake of backward compatibility
 575 # (we supported those before the change to "make variable" support.
 576 my %user = (
 577     AR          => env('AR'),
 578     ARFLAGS     => [],
 579     AS          => undef,
 580     ASFLAGS     => [],
 581     CC          => env('CC'),
 582     CFLAGS      => [ env('CFLAGS') || () ],
 583     CXX         => env('CXX'),
 584     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 585     CPP         => undef,
 586     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 587     CPPDEFINES  => [],  # Alternative for -D
 588     CPPINCLUDES => [],  # Alternative for -I
 589     CROSS_COMPILE => env('CROSS_COMPILE'),
 590     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 591     LD          => undef,
 592     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 593     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 594     MT          => undef,
 595     MTFLAGS     => [],
 596     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 597     RANLIB      => env('RANLIB'),
 598     RC          => env('RC') || env('WINDRES'),
 599     RCFLAGS     => [ env('RCFLAGS') || () ],
 600     RM          => undef,
 601    );
 602 # Info about what "make variables" may be prefixed with the cross compiler
 603 # prefix.  This should NEVER mention any such variable with a list for value.
 604 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 605 # The same but for flags given as Configure options.  These are *additional*
 606 # input, as opposed to the VAR=string option that override the corresponding
 607 # config target attributes
 608 my %useradd = (
 609     CPPDEFINES  => [],
 610     CPPINCLUDES => [],
 611     CPPFLAGS    => [],
 612     CFLAGS      => [],
 613     CXXFLAGS    => [],
 614     LDFLAGS     => [],
 615     LDLIBS      => [],
 616     RCFLAGS     => [],
 617    );
 618
 619 my %user_synonyms = (
 620     HASHBANGPERL=> 'PERL',
 621     RC          => 'WINDRES',
 622    );
 623
 624 # Some target attributes have been renamed, this is the translation table
 625 my %target_attr_translate =(
 626     ar          => 'AR',
 627     as          => 'AS',
 628     cc          => 'CC',
 629     cxx         => 'CXX',
 630     cpp         => 'CPP',
 631     hashbangperl => 'HASHBANGPERL',
 632     ld          => 'LD',
 633     mt          => 'MT',
 634     ranlib      => 'RANLIB',
 635     rc          => 'RC',
 636     rm          => 'RM',
 637    );
 638
 639 # Initialisers coming from 'config' scripts
 640 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 641 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 642 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 643 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 644 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 645 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 646 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 647
 648 $config{openssl_api_defines}=[];
 649 $config{openssl_sys_defines}=[];
 650 $config{openssl_feature_defines}=[];
 651 $config{options}="";
 652 $config{build_type} = "release";
 653 my $target="";
 654
 655 my %cmdvars = ();               # Stores FOO='blah' type arguments
 656 my %unsupported_options = ();
 657 my %deprecated_options = ();
 658 # If you change this, update apps/version.c
 659 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 660 my @seed_sources = ();
 661 while (@argvcopy)
 662         {
 663         $_ = shift @argvcopy;
 664
 665         # Support env variable assignments among the options
 666         if (m|^(\w+)=(.+)?$|)
 667                 {
 668                 $cmdvars{$1} = $2;
 669                 # Every time a variable is given as a configuration argument,
 670                 # it acts as a reset if the variable.
 671                 if (exists $user{$1})
 672                         {
 673                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 674                         }
 675                 #if (exists $useradd{$1})
 676                 #       {
 677                 #       $useradd{$1} = [];
 678                 #       }
 679                 next;
 680                 }
 681
 682         # VMS is a case insensitive environment, and depending on settings
 683         # out of our control, we may receive options uppercased.  Let's
 684         # downcase at least the part before any equal sign.
 685         if ($^O eq "VMS")
 686                 {
 687                 s/^([^=]*)/lc($1)/e;
 688                 }
 689
 690         # some people just can't read the instructions, clang people have to...
 691         s/^-no-(?!integrated-as)/no-/;
 692
 693         # rewrite some options in "enable-..." form
 694         s /^-?-?shared$/enable-shared/;
 695         s /^sctp$/enable-sctp/;
 696         s /^threads$/enable-threads/;
 697         s /^zlib$/enable-zlib/;
 698         s /^zlib-dynamic$/enable-zlib-dynamic/;
 699
 700         if (/^(no|disable|enable)-(.+)$/)
 701                 {
 702                 my $word = $2;
 703                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 704                         && !exists $deprecated_disablables{$word}
 705                         && !grep { $word eq $_ } @disablables)
 706                         {
 707                         $unsupported_options{$_} = 1;
 708                         next;
 709                         }
 710                 }
 711         if (/^no-(.+)$/ || /^disable-(.+)$/)
 712                 {
 713                 foreach my $proto ((@tls, @dtls))
 714                         {
 715                         if ($1 eq "$proto-method")
 716                                 {
 717                                 $disabled{"$proto"} = "option($proto-method)";
 718                                 last;
 719                                 }
 720                         }
 721                 if ($1 eq "dtls")
 722                         {
 723                         foreach my $proto (@dtls)
 724                                 {
 725                                 $disabled{$proto} = "option(dtls)";
 726                                 }
 727                         $disabled{"dtls"} = "option(dtls)";
 728                         }
 729                 elsif ($1 eq "ssl")
 730                         {
 731                         # Last one of its kind
 732                         $disabled{"ssl3"} = "option(ssl)";
 733                         }
 734                 elsif ($1 eq "tls")
 735                         {
 736                         # XXX: Tests will fail if all SSL/TLS
 737                         # protocols are disabled.
 738                         foreach my $proto (@tls)
 739                                 {
 740                                 $disabled{$proto} = "option(tls)";
 741                                 }
 742                         }
 743                 elsif ($1 eq "static-engine")
 744                         {
 745                         delete $disabled{"dynamic-engine"};
 746                         }
 747                 elsif ($1 eq "dynamic-engine")
 748                         {
 749                         $disabled{"dynamic-engine"} = "option";
 750                         }
 751                 elsif (exists $deprecated_disablables{$1})
 752                         {
 753                         $deprecated_options{$_} = 1;
 754                         if (defined $deprecated_disablables{$1})
 755                                 {
 756                                 $disabled{$deprecated_disablables{$1}} = "option";
 757                                 }
 758                         }
 759                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 760                         {
 761                         $deprecated_options{$_} = 1;
 762                         }
 763                 else
 764                         {
 765                         $disabled{$1} = "option";
 766                         }
 767                 # No longer an automatic choice
 768                 $auto_threads = 0 if ($1 eq "threads");
 769                 }
 770         elsif (/^enable-(.+)$/)
 771                 {
 772                 if ($1 eq "static-engine")
 773                         {
 774                         $disabled{"dynamic-engine"} = "option";
 775                         }
 776                 elsif ($1 eq "dynamic-engine")
 777                         {
 778                         delete $disabled{"dynamic-engine"};
 779                         }
 780                 elsif ($1 eq "zlib-dynamic")
 781                         {
 782                         delete $disabled{"zlib"};
 783                         }
 784                 my $algo = $1;
 785                 delete $disabled{$algo};
 786
 787                 # No longer an automatic choice
 788                 $auto_threads = 0 if ($1 eq "threads");
 789                 }
 790         elsif (/^--strict-warnings$/)
 791                 {
 792                 # Pretend that our strict flags is a C flag, and replace it
 793                 # with the proper flags later on
 794                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 795                 $strict_warnings=1;
 796                 }
 797         elsif (/^--debug$/)
 798                 {
 799                 $config{build_type} = "debug";
 800                 }
 801         elsif (/^--release$/)
 802                 {
 803                 $config{build_type} = "release";
 804                 }
 805         elsif (/^386$/)
 806                 { $config{processor}=386; }
 807         elsif (/^fips$/)
 808                 {
 809                 die "FIPS mode not supported\n";
 810                 }
 811         elsif (/^rsaref$/)
 812                 {
 813                 # No RSAref support any more since it's not needed.
 814                 # The check for the option is there so scripts aren't
 815                 # broken
 816                 }
 817         elsif (/^nofipscanistercheck$/)
 818                 {
 819                 die "FIPS mode not supported\n";
 820                 }
 821         elsif (/^[-+]/)
 822                 {
 823                 if (/^--prefix=(.*)$/)
 824                         {
 825                         $config{prefix}=$1;
 826                         die "Directory given with --prefix MUST be absolute\n"
 827                                 unless file_name_is_absolute($config{prefix});
 828                         }
 829                 elsif (/^--api=(.*)$/)
 830                         {
 831                         $config{api}=$1;
 832                         }
 833                 elsif (/^--libdir=(.*)$/)
 834                         {
 835                         $config{libdir}=$1;
 836                         }
 837                 elsif (/^--openssldir=(.*)$/)
 838                         {
 839                         $config{openssldir}=$1;
 840                         }
 841                 elsif (/^--with-zlib-lib=(.*)$/)
 842                         {
 843                         $withargs{zlib_lib}=$1;
 844                         }
 845                 elsif (/^--with-zlib-include=(.*)$/)
 846                         {
 847                         $withargs{zlib_include}=$1;
 848                         }
 849                 elsif (/^--with-fuzzer-lib=(.*)$/)
 850                         {
 851                         $withargs{fuzzer_lib}=$1;
 852                         }
 853                 elsif (/^--with-fuzzer-include=(.*)$/)
 854                         {
 855                         $withargs{fuzzer_include}=$1;
 856                         }
 857                 elsif (/^--with-rand-seed=(.*)$/)
 858                         {
 859                         foreach my $x (split(m|,|, $1))
 860                             {
 861                             die "Unknown --with-rand-seed choice $x\n"
 862                                 if ! grep { $x eq $_ } @known_seed_sources;
 863                             push @seed_sources, $x;
 864                             }
 865                         }
 866                 elsif (/^--cross-compile-prefix=(.*)$/)
 867                         {
 868                         $user{CROSS_COMPILE}=$1;
 869                         }
 870                 elsif (/^--config=(.*)$/)
 871                         {
 872                         read_config $1;
 873                         }
 874                 elsif (/^-l(.*)$/)
 875                         {
 876                         push @{$useradd{LDLIBS}}, $_;
 877                         }
 878                 elsif (/^-framework$/)
 879                         {
 880                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 881                         }
 882                 elsif (/^-L(.*)$/ or /^-Wl,/)
 883                         {
 884                         push @{$useradd{LDFLAGS}}, $_;
 885                         }
 886                 elsif (/^-rpath$/ or /^-R$/)
 887                         # -rpath is the OSF1 rpath flag
 888                         # -R is the old Solaris rpath flag
 889                         {
 890                         my $rpath = shift(@argvcopy) || "";
 891                         $rpath .= " " if $rpath ne "";
 892                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 893                         }
 894                 elsif (/^-static$/)
 895                         {
 896                         push @{$useradd{LDFLAGS}}, $_;
 897                         }
 898                 elsif (/^-D(.*)$/)
 899                         {
 900                         push @{$useradd{CPPDEFINES}}, $1;
 901                         }
 902                 elsif (/^-I(.*)$/)
 903                         {
 904                         push @{$useradd{CPPINCLUDES}}, $1;
 905                         }
 906                 elsif (/^-Wp,$/)
 907                         {
 908                         push @{$useradd{CPPFLAGS}}, $1;
 909                         }
 910                 else    # common if (/^[-+]/), just pass down...
 911                         {
 912                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 913                         push @{$useradd{CFLAGS}}, $_;
 914                         push @{$useradd{CXXFLAGS}}, $_;
 915                         }
 916                 }
 917         else
 918                 {
 919                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 920                 $target=$_;
 921                 }
 922         unless ($_ eq $target || /^no-/ || /^disable-/)
 923                 {
 924                 # "no-..." follows later after implied deactivations
 925                 # have been derived.  (Don't take this too seriously,
 926                 # we really only write OPTIONS to the Makefile out of
 927                 # nostalgia.)
 928
 929                 if ($config{options} eq "")
 930                         { $config{options} = $_; }
 931                 else
 932                         { $config{options} .= " ".$_; }
 933                 }
 934         }
 935
 936 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 937         die "***** Unsupported api compatibility level: $config{api}\n",
 938 }
 939
 940 if (keys %deprecated_options)
 941         {
 942         warn "***** Deprecated options: ",
 943                 join(", ", keys %deprecated_options), "\n";
 944         }
 945 if (keys %unsupported_options)
 946         {
 947         die "***** Unsupported options: ",
 948                 join(", ", keys %unsupported_options), "\n";
 949         }
 950
 951 # If any %useradd entry has been set, we must check that the "make
 952 # variables" haven't been set.  We start by checking of any %useradd entry
 953 # is set.
 954 if (grep { scalar @$_ > 0 } values %useradd) {
 955     # Hash of env / make variables names.  The possible values are:
 956     # 1 - "make vars"
 957     # 2 - %useradd entry set
 958     # 3 - both set
 959     my %detected_vars =
 960         map { my $v = 0;
 961               $v += 1 if $cmdvars{$_};
 962               $v += 2 if @{$useradd{$_}};
 963               $_ => $v }
 964         keys %useradd;
 965
 966     # If any of the corresponding "make variables" is set, we error
 967     if (grep { $_ & 1 } values %detected_vars) {
 968         my $names = join(', ', grep { $detected_vars{$_} > 0 }
 969                                sort keys %detected_vars);
 970         die <<"_____";
 971 ***** Mixing make variables and additional compiler/linker flags as
 972 ***** configure command line option is not permitted.
 973 ***** Affected make variables: $names
 974 _____
 975     }
 976 }
 977
 978 # Check through all supported command line variables to see if any of them
 979 # were set, and canonicalise the values we got.  If no compiler or linker
 980 # flag or anything else that affects %useradd was set, we also check the
 981 # environment for values.
 982 my $anyuseradd =
 983     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
 984 foreach (keys %user) {
 985     my $value = $cmdvars{$_};
 986     $value //= env($_) unless $anyuseradd;
 987     $value //=
 988         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
 989     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
 990         unless $anyuseradd;
 991
 992     if (defined $value) {
 993         if (ref $user{$_} eq 'ARRAY') {
 994             $user{$_} = [ split /$list_separator_re/, $value ];
 995         } elsif (!defined $user{$_}) {
 996             $user{$_} = $value;
 997         }
 998     }
 999 }
1000
1001 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1002     && !$disabled{shared}
1003     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1004     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1005         "***** any of asan, msan or ubsan\n";
1006 }
1007
1008 sub disable {
1009     my $disable_type = shift;
1010
1011     for (@_) {
1012         $disabled{$_} = $disable_type;
1013     }
1014
1015     my @tocheckfor = (@_ ? @_ : keys %disabled);
1016     while (@tocheckfor) {
1017         my %new_tocheckfor = ();
1018         my @cascade_copy = (@disable_cascades);
1019         while (@cascade_copy) {
1020             my ($test, $descendents) =
1021                 (shift @cascade_copy, shift @cascade_copy);
1022             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1023                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1024                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1025                 }
1026             }
1027         }
1028         @tocheckfor = (keys %new_tocheckfor);
1029     }
1030 }
1031 disable();                     # First cascade run
1032
1033 our $die = sub { die @_; };
1034 if ($target eq "TABLE") {
1035     local $die = sub { warn @_; };
1036     foreach (sort keys %table) {
1037         print_table_entry($_, "TABLE");
1038     }
1039     exit 0;
1040 }
1041
1042 if ($target eq "LIST") {
1043     foreach (sort keys %table) {
1044         print $_,"\n" unless $table{$_}->{template};
1045     }
1046     exit 0;
1047 }
1048
1049 if ($target eq "HASH") {
1050     local $die = sub { warn @_; };
1051     print "%table = (\n";
1052     foreach (sort keys %table) {
1053         print_table_entry($_, "HASH");
1054     }
1055     exit 0;
1056 }
1057
1058 print "Configuring OpenSSL version $config{full_version} ";
1059 print "for target $target\n";
1060
1061 if (scalar(@seed_sources) == 0) {
1062     print "Using os-specific seed configuration\n";
1063     push @seed_sources, 'os';
1064 }
1065 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1066     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1067     warn <<_____ if scalar(@seed_sources) == 1;
1068
1069 ============================== WARNING ===============================
1070 You have selected the --with-rand-seed=none option, which effectively
1071 disables automatic reseeding of the OpenSSL random generator.
1072 All operations depending on the random generator such as creating keys
1073 will not work unless the random generator is seeded manually by the
1074 application.
1075
1076 Please read the 'Note on random number generation' section in the
1077 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1078 ============================== WARNING ===============================
1079
1080 _____
1081 }
1082 push @{$config{openssl_feature_defines}},
1083      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1084         @seed_sources;
1085
1086 # Backward compatibility?
1087 if ($target =~ m/^CygWin32(-.*)$/) {
1088     $target = "Cygwin".$1;
1089 }
1090
1091 # Support for legacy targets having a name starting with 'debug-'
1092 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1093 if ($d) {
1094     $config{build_type} = "debug";
1095
1096     # If we do not find debug-foo in the table, the target is set to foo.
1097     if (!$table{$target}) {
1098         $target = $t;
1099     }
1100 }
1101
1102 &usage if !$table{$target} || $table{$target}->{template};
1103
1104 $config{target} = $target;
1105 my %target = resolve_config($target);
1106
1107 foreach (keys %target_attr_translate) {
1108     $target{$target_attr_translate{$_}} = $target{$_}
1109         if $target{$_};
1110     delete $target{$_};
1111 }
1112
1113 %target = ( %{$table{DEFAULTS}}, %target );
1114
1115 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1116 $config{conf_files} = [ sort keys %conf_files ];
1117
1118 # Using sub disable within these loops may prove fragile, so we run
1119 # a cascade afterwards
1120 foreach my $feature (@{$target{disable}}) {
1121     if (exists $deprecated_disablables{$feature}) {
1122         warn "***** config $target disables deprecated feature $feature\n";
1123     } elsif (!grep { $feature eq $_ } @disablables) {
1124         die "***** config $target disables unknown feature $feature\n";
1125     }
1126     $disabled{$feature} = 'config';
1127 }
1128 foreach my $feature (@{$target{enable}}) {
1129     if ("default" eq ($disabled{$feature} // "")) {
1130         if (exists $deprecated_disablables{$feature}) {
1131             warn "***** config $target enables deprecated feature $feature\n";
1132         } elsif (!grep { $feature eq $_ } @disablables) {
1133             die "***** config $target enables unknown feature $feature\n";
1134         }
1135         delete $disabled{$feature};
1136     }
1137 }
1138
1139 # If uplink_arch isn't defined, disable uplink
1140 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1141 # If asm_arch isn't defined, disable asm
1142 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1143
1144 disable();                      # Run a cascade now
1145
1146 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1147 $target{cxxflags}//=$target{cflags} if $target{CXX};
1148 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1149 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1150
1151 # Fill %config with values from %user, and in case those are undefined or
1152 # empty, use values from %target (acting as a default).
1153 foreach (keys %user) {
1154     my $ref_type = ref $user{$_};
1155
1156     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1157     # and a value that's to be coerced into that type.
1158     my $mkvalue = sub {
1159         my $type = shift;
1160         my $value = shift;
1161         my $undef_p = shift;
1162
1163         die "Too many arguments for \$mkvalue" if @_;
1164
1165         while (ref $value eq 'CODE') {
1166             $value = $value->();
1167         }
1168
1169         if ($type eq 'ARRAY') {
1170             return undef unless defined $value;
1171             return undef if ref $value ne 'ARRAY' && !$value;
1172             return undef if ref $value eq 'ARRAY' && !@$value;
1173             return [ $value ] unless ref $value eq 'ARRAY';
1174         }
1175         return undef unless $value;
1176         return $value;
1177     };
1178
1179     $config{$_} =
1180         $mkvalue->($ref_type, $user{$_})
1181         || $mkvalue->($ref_type, $target{$_});
1182     delete $config{$_} unless defined $config{$_};
1183 }
1184
1185 # Finish up %config by appending things the user gave us on the command line
1186 # apart from "make variables"
1187 foreach (keys %useradd) {
1188     # The must all be lists, so we assert that here
1189     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1190         unless ref $useradd{$_} eq 'ARRAY';
1191
1192     if (defined $config{$_}) {
1193         push @{$config{$_}}, @{$useradd{$_}};
1194     } else {
1195         $config{$_} = [ @{$useradd{$_}} ];
1196     }
1197 }
1198 # At this point, we can forget everything about %user and %useradd,
1199 # because it's now all been merged into the corresponding $config entry
1200
1201 # Allow overriding the build file name
1202 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1203
1204 ######################################################################
1205 # Build up information for skipping certain directories depending on disabled
1206 # features, as well as setting up macros for disabled features.
1207
1208 # This is a tentative database of directories to skip.  Some entries may not
1209 # correspond to anything real, but that's ok, they will simply be ignored.
1210 # The actual processing of these entries is done in the build.info lookup
1211 # loop further down.
1212 #
1213 # The key is a Unix formated path in the source tree, the value is an index
1214 # into %disabled_info, so any existing path gets added to a corresponding
1215 # 'skipped' entry in there with the list of skipped directories.
1216 my %skipdir = ();
1217 my %disabled_info = ();         # For configdata.pm
1218 foreach my $what (sort keys %disabled) {
1219     # There are deprecated disablables that translate to themselves.
1220     # They cause disabling cascades, but should otherwise not regiter.
1221     next if $deprecated_disablables{$what};
1222
1223     $config{options} .= " no-$what";
1224
1225     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1226                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1227                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1228         (my $WHAT = uc $what) =~ s|-|_|g;
1229         my $skipdir = $what;
1230
1231         # fix-up crypto/directory name(s)
1232         $skipdir = "ripemd" if $what eq "rmd160";
1233         $skipdir = "whrlpool" if $what eq "whirlpool";
1234
1235         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1236         push @{$config{openssl_feature_defines}}, $macro;
1237
1238         $skipdir{engines} = $what if $what eq 'engine';
1239         $skipdir{"crypto/$skipdir"} = $what
1240             unless $what eq 'async' || $what eq 'err';
1241     }
1242 }
1243
1244 # Make sure build_scheme is consistent.
1245 $target{build_scheme} = [ $target{build_scheme} ]
1246     if ref($target{build_scheme}) ne "ARRAY";
1247
1248 my ($builder, $builder_platform, @builder_opts) =
1249     @{$target{build_scheme}};
1250
1251 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1252                       $builder_platform."-checker.pm")) {
1253     my $checker_path = catfile($srcdir, "Configurations", $checker);
1254     if (-f $checker_path) {
1255         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1256             ? sub { warn $@; } : sub { die $@; };
1257         if (! do $checker_path) {
1258             if ($@) {
1259                 $fn->($@);
1260             } elsif ($!) {
1261                 $fn->($!);
1262             } else {
1263                 $fn->("The detected tools didn't match the platform\n");
1264             }
1265         }
1266         last;
1267     }
1268 }
1269
1270 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1271
1272 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1273         {
1274         push @{$config{cflags}}, "-mno-cygwin";
1275         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1276         push @{$config{shared_ldflag}}, "-mno-cygwin";
1277         }
1278
1279 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1280         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1281         # minimally required architecture flags for assembly modules
1282         my $value;
1283         $value = '-mips2' if ($target =~ /mips32/);
1284         $value = '-mips3' if ($target =~ /mips64/);
1285         unshift @{$config{cflags}}, $value;
1286         unshift @{$config{cxxflags}}, $value if $config{CXX};
1287 }
1288
1289 # If threads aren't disabled, check how possible they are
1290 unless ($disabled{threads}) {
1291     if ($auto_threads) {
1292         # Enabled by default, disable it forcibly if unavailable
1293         if ($target{thread_scheme} eq "(unknown)") {
1294             disable("unavailable", 'threads');
1295         }
1296     } else {
1297         # The user chose to enable threads explicitly, let's see
1298         # if there's a chance that's possible
1299         if ($target{thread_scheme} eq "(unknown)") {
1300             # If the user asked for "threads" and we don't have internal
1301             # knowledge how to do it, [s]he is expected to provide any
1302             # system-dependent compiler options that are necessary.  We
1303             # can't truly check that the given options are correct, but
1304             # we expect the user to know what [s]He is doing.
1305             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1306                 die "You asked for multi-threading support, but didn't\n"
1307                     ,"provide any system-specific compiler options\n";
1308             }
1309         }
1310     }
1311 }
1312
1313 # Find out if clang's sanitizers have been enabled with -fsanitize
1314 # flags and ensure that the corresponding %disabled elements area
1315 # removed to reflect that the sanitizers are indeed enabled.
1316 my %detected_sanitizers = ();
1317 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1318     (my $checks = $_) =~ s/^-fsanitize=//;
1319     foreach (split /,/, $checks) {
1320         my $d = { address       => 'asan',
1321                   undefined     => 'ubsan',
1322                   memory        => 'msan' } -> {$_};
1323         next unless defined $d;
1324
1325         $detected_sanitizers{$d} = 1;
1326         if (defined $disabled{$d}) {
1327             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1328                 if $disabled{$d} ne "default";
1329             delete $disabled{$d};
1330         }
1331     }
1332 }
1333
1334 # If threads still aren't disabled, add a C macro to ensure the source
1335 # code knows about it.  Any other flag is taken care of by the configs.
1336 unless($disabled{threads}) {
1337     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1338 }
1339
1340 # With "deprecated" disable all deprecated features.
1341 if (defined($disabled{"deprecated"})) {
1342         $config{api} = $maxapi;
1343 }
1344
1345 my $no_shared_warn=0;
1346 if ($target{shared_target} eq "")
1347         {
1348         $no_shared_warn = 1
1349             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1350         disable('no-shared-target', 'pic');
1351         }
1352
1353 if ($disabled{"dynamic-engine"}) {
1354         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1355         $config{dynamic_engines} = 0;
1356 } else {
1357         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1358         $config{dynamic_engines} = 1;
1359 }
1360
1361 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1362     push @{$config{cflags}}, "-fsanitize=address";
1363 }
1364
1365 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1366     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1367     # platforms.
1368     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1369 }
1370
1371 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1372   push @{$config{cflags}}, "-fsanitize=memory";
1373 }
1374
1375 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1376         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1377     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1378     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1379 }
1380 #
1381 # Platform fix-ups
1382 #
1383
1384 # This saves the build files from having to check
1385 if ($disabled{pic})
1386         {
1387         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1388                     shared_defines shared_includes shared_ldflag
1389                     module_cflags module_cxxflags module_cppflags
1390                     module_defines module_includes module_lflags))
1391                 {
1392                 delete $config{$_};
1393                 $target{$_} = "";
1394                 }
1395         }
1396 else
1397         {
1398         push @{$config{lib_defines}}, "OPENSSL_PIC";
1399         }
1400
1401 if ($target{sys_id} ne "")
1402         {
1403         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1404         }
1405
1406 unless ($disabled{asm}) {
1407     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1408         push @{$config{dso_defines}}, "PADLOCK_ASM";
1409     }
1410 }
1411
1412 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1413 my %predefined_CXX = $config{CXX}
1414     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1415     : ();
1416
1417 # Check for makedepend capabilities.
1418 if (!$disabled{makedepend}) {
1419     if ($config{target} =~ /^(VC|vms)-/) {
1420         # For VC- and vms- targets, there's nothing more to do here.  The
1421         # functionality is hard coded in the corresponding build files for
1422         # cl (Windows) and CC/DECC (VMS).
1423     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1424              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1425         # We know that GNU C version 3 and up as well as all clang
1426         # versions support dependency generation, but Xcode did not
1427         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1428         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1429     } else {
1430         # In all other cases, we look for 'makedepend', and disable the
1431         # capability if not found.
1432         $config{makedepprog} = which('makedepend');
1433         disable('unavailable', 'makedepend') unless $config{makedepprog};
1434     }
1435 }
1436
1437 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1438     # probe for -Wa,--noexecstack option...
1439     if ($predefined_C{__clang__}) {
1440         # clang has builtin assembler, which doesn't recognize --help,
1441         # but it apparently recognizes the option in question on all
1442         # supported platforms even when it's meaningless. In other words
1443         # probe would fail, but probed option always accepted...
1444         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1445     } else {
1446         my $cc = $config{CROSS_COMPILE}.$config{CC};
1447         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1448         while(<PIPE>) {
1449             if (m/--noexecstack/) {
1450                 push @{$config{cflags}}, "-Wa,--noexecstack";
1451                 last;
1452             }
1453         }
1454         close(PIPE);
1455         unlink("null.$$.o");
1456     }
1457 }
1458
1459 # Deal with bn_ops ###################################################
1460
1461 $config{bn_ll}                  =0;
1462 $config{export_var_as_fn}       =0;
1463 my $def_int="unsigned int";
1464 $config{rc4_int}                =$def_int;
1465 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1466
1467 my $count = 0;
1468 foreach (sort split(/\s+/,$target{bn_ops})) {
1469     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1470     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1471     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1472     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1473     ($config{b64l},$config{b64},$config{b32})
1474         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1475     ($config{b64l},$config{b64},$config{b32})
1476         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1477     ($config{b64l},$config{b64},$config{b32})
1478         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1479 }
1480 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1481     if $count > 1;
1482
1483
1484 # Hack cflags for better warnings (dev option) #######################
1485
1486 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1487 # a string and works as well on command lines.
1488 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1489                         @{$config{cflags}} ];
1490 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1491                           @{$config{cxxflags}} ] if $config{CXX};
1492
1493 $config{openssl_api_defines} = [
1494     "OPENSSL_MIN_API=".($apitable->{$config{api} // ""} // -1)
1495 ];
1496
1497 my @strict_warnings_collection=();
1498 if ($strict_warnings)
1499         {
1500         my $wopt;
1501         my $gccver = $predefined_C{__GNUC__} // -1;
1502
1503         warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike"
1504             unless $gccver >= 4;
1505         push @strict_warnings_collection, @gcc_devteam_warn;
1506         push @strict_warnings_collection, @clang_devteam_warn
1507             if (defined($predefined_C{__clang__}));
1508         }
1509
1510 if (grep { $_ eq '-static' } @{$config{LDFLAGS}}) {
1511     disable('static', 'pic', 'threads');
1512 }
1513
1514 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1515                               ? @strict_warnings_collection
1516                               : ( $_ ) }
1517                     @{$config{CFLAGS}} ];
1518
1519 unless ($disabled{"crypto-mdebug-backtrace"})
1520         {
1521         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1522                 {
1523                 push @{$config{cflags}}, $wopt
1524                         unless grep { $_ eq $wopt } @{$config{cflags}};
1525                 }
1526         if ($target =~ /^BSD-/)
1527                 {
1528                 push @{$config{ex_libs}}, "-lexecinfo";
1529                 }
1530         }
1531
1532 unless ($disabled{afalgeng}) {
1533     $config{afalgeng}="";
1534     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1535         my $minver = 4*10000 + 1*100 + 0;
1536         if ($config{CROSS_COMPILE} eq "") {
1537             my $verstr = `uname -r`;
1538             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1539             ($mi2) = $mi2 =~ /(\d+)/;
1540             my $ver = $ma*10000 + $mi1*100 + $mi2;
1541             if ($ver < $minver) {
1542                 disable('too-old-kernel', 'afalgeng');
1543             } else {
1544                 push @{$config{engdirs}}, "afalg";
1545             }
1546         } else {
1547             disable('cross-compiling', 'afalgeng');
1548         }
1549     } else {
1550         disable('not-linux', 'afalgeng');
1551     }
1552 }
1553
1554 push @{$config{openssl_feature_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1555
1556 unless ($disabled{ktls}) {
1557     $config{ktls}="";
1558     if ($target =~ m/^linux/) {
1559         my $usr = "/usr/$config{cross_compile_prefix}";
1560         chop($usr);
1561         if ($config{cross_compile_prefix} eq "") {
1562             $usr = "/usr";
1563         }
1564         my $minver = (4 << 16) + (13 << 8) + 0;
1565         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1566
1567         if ($verstr[2] < $minver) {
1568             disable('too-old-kernel', 'ktls');
1569         }
1570     } else {
1571         disable('not-linux', 'ktls');
1572     }
1573 }
1574
1575 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1576
1577 # Get the extra flags used when building shared libraries and modules.  We
1578 # do this late because some of them depend on %disabled.
1579
1580 # Make the flags to build DSOs the same as for shared libraries unless they
1581 # are already defined
1582 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1583 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1584 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1585 {
1586     my $shared_info_pl =
1587         catfile(dirname($0), "Configurations", "shared-info.pl");
1588     my %shared_info = read_eval_file($shared_info_pl);
1589     push @{$target{_conf_fname_int}}, $shared_info_pl;
1590     my $si = $target{shared_target};
1591     while (ref $si ne "HASH") {
1592         last if ! defined $si;
1593         if (ref $si eq "CODE") {
1594             $si = $si->();
1595         } else {
1596             $si = $shared_info{$si};
1597         }
1598     }
1599
1600     # Some of the 'shared_target' values don't have any entries in
1601     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1602     # template knows how to handle this.  That is currently the case for
1603     # Windows and VMS.
1604     if (defined $si) {
1605         # Just as above, copy certain shared_* attributes to the corresponding
1606         # module_ attribute unless the latter is already defined
1607         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1608         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1609         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1610         foreach (sort keys %$si) {
1611             $target{$_} = defined $target{$_}
1612                 ? add($si->{$_})->($target{$_})
1613                 : $si->{$_};
1614         }
1615     }
1616 }
1617
1618 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1619
1620 # If we use the unified build, collect information from build.info files
1621 my %unified_info = ();
1622
1623 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1624 if ($builder eq "unified") {
1625     use with_fallback qw(Text::Template);
1626
1627     sub cleandir {
1628         my $base = shift;
1629         my $dir = shift;
1630         my $relativeto = shift || ".";
1631
1632         $dir = catdir($base,$dir) unless isabsolute($dir);
1633
1634         # Make sure the directories we're building in exists
1635         mkpath($dir);
1636
1637         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1638         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1639         return $res;
1640     }
1641
1642     sub cleanfile {
1643         my $base = shift;
1644         my $file = shift;
1645         my $relativeto = shift || ".";
1646
1647         $file = catfile($base,$file) unless isabsolute($file);
1648
1649         my $d = dirname($file);
1650         my $f = basename($file);
1651
1652         # Make sure the directories we're building in exists
1653         mkpath($d);
1654
1655         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1656         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1657         return $res;
1658     }
1659
1660     # Store the name of the template file we will build the build file from
1661     # in %config.  This may be useful for the build file itself.
1662     my @build_file_template_names =
1663         ( $builder_platform."-".$target{build_file}.".tmpl",
1664           $target{build_file}.".tmpl" );
1665     my @build_file_templates = ();
1666
1667     # First, look in the user provided directory, if given
1668     if (defined env($local_config_envname)) {
1669         @build_file_templates =
1670             map {
1671                 if ($^O eq 'VMS') {
1672                     # VMS environment variables are logical names,
1673                     # which can be used as is
1674                     $local_config_envname . ':' . $_;
1675                 } else {
1676                     catfile(env($local_config_envname), $_);
1677                 }
1678             }
1679             @build_file_template_names;
1680     }
1681     # Then, look in our standard directory
1682     push @build_file_templates,
1683         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1684           @build_file_template_names );
1685
1686     my $build_file_template;
1687     for $_ (@build_file_templates) {
1688         $build_file_template = $_;
1689         last if -f $build_file_template;
1690
1691         $build_file_template = undef;
1692     }
1693     if (!defined $build_file_template) {
1694         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1695     }
1696     $config{build_file_templates}
1697       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1698                     $blddir),
1699           $build_file_template,
1700           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1701                     $blddir) ];
1702
1703     my @build_dirs = ( [ ] );   # current directory
1704
1705     $config{build_infos} = [ ];
1706
1707     my %ordinals = ();
1708     while (@build_dirs) {
1709         my @curd = @{shift @build_dirs};
1710         my $sourced = catdir($srcdir, @curd);
1711         my $buildd = catdir($blddir, @curd);
1712
1713         my $unixdir = join('/', @curd);
1714         if (exists $skipdir{$unixdir}) {
1715             my $what = $skipdir{$unixdir};
1716             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1717             next;
1718         }
1719
1720         mkpath($buildd);
1721
1722         my $f = 'build.info';
1723         # The basic things we're trying to build
1724         my @programs = ();
1725         my @libraries = ();
1726         my @modules = ();
1727         my @scripts = ();
1728
1729         my %attributes = ();
1730         my %sources = ();
1731         my %shared_sources = ();
1732         my %includes = ();
1733         my %defines = ();
1734         my %depends = ();
1735         my %generate = ();
1736
1737         # Support for $variablename in build.info files.
1738         # Embedded perl code is the ultimate master, still.  If its output
1739         # contains a dollar sign, it had better be escaped, or it will be
1740         # taken for a variable name prefix.
1741         my %variables = ();
1742         my $variable_re = qr/\$([[:alpha:]][[:alnum:]_]*)/;
1743         my $expand_variables = sub {
1744             my $value = '';
1745             my $value_rest = shift;
1746
1747             while ($value_rest =~ /(?<!\\)${variable_re}/) {
1748                 $value .= $`;
1749                 $value .= $variables{$1};
1750                 $value_rest = $';
1751             }
1752             return $value . $value_rest;
1753         };
1754
1755         # We want to detect configdata.pm in the source tree, so we
1756         # don't use it if the build tree is different.
1757         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1758
1759         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1760         my $template =
1761             Text::Template->new(TYPE => 'FILE',
1762                                 SOURCE => catfile($sourced, $f),
1763                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1764         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1765         my @text =
1766             split /^/m,
1767             $template->fill_in(HASH => { config => \%config,
1768                                          target => \%target,
1769                                          disabled => \%disabled,
1770                                          withargs => \%withargs,
1771                                          builddir => abs2rel($buildd, $blddir),
1772                                          sourcedir => abs2rel($sourced, $blddir),
1773                                          buildtop => abs2rel($blddir, $blddir),
1774                                          sourcetop => abs2rel($srcdir, $blddir) },
1775                                DELIMITERS => [ "{-", "-}" ]);
1776
1777         # The top item of this stack has the following values
1778         # -2 positive already run and we found ELSE (following ELSIF should fail)
1779         # -1 positive already run (skip until ENDIF)
1780         # 0 negatives so far (if we're at a condition, check it)
1781         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1782         # 2 positive ELSE (following ELSIF should fail)
1783         my @skip = ();
1784         collect_information(
1785             collect_from_array([ @text ],
1786                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1787                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1788             # Info we're looking for
1789             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1790             => sub {
1791                 if (! @skip || $skip[$#skip] > 0) {
1792                     push @skip, !! $expand_variables->($1);
1793                 } else {
1794                     push @skip, -1;
1795                 }
1796             },
1797             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1798             => sub { die "ELSIF out of scope" if ! @skip;
1799                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1800                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1801                      $skip[$#skip] = !! $expand_variables->($1)
1802                          if $skip[$#skip] == 0; },
1803             qr/^\s*ELSE\s*$/
1804             => sub { die "ELSE out of scope" if ! @skip;
1805                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1806                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1807             qr/^\s*ENDIF\s*$/
1808             => sub { die "ENDIF out of scope" if ! @skip;
1809                      pop @skip; },
1810             qr/^\s*${variable_re}\s*=\s*(.*?)\s*$/
1811             => sub {
1812                 if (!@skip || $skip[$#skip] > 0) {
1813                     my $n = $1;
1814                     my $v = $2;
1815                     $variables{$n} = $expand_variables->($v);
1816                 }
1817             },
1818             qr/^\s*SUBDIRS\s*=\s*(.*)\s*$/
1819             => sub {
1820                 if (!@skip || $skip[$#skip] > 0) {
1821                     foreach (tokenize($expand_variables->($1))) {
1822                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1823                     }
1824                 }
1825             },
1826             qr/^\s*PROGRAMS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1827             => sub {
1828                 if (!@skip || $skip[$#skip] > 0) {
1829                     my @a = tokenize($1, qr|\s*,\s*|);
1830                     my @p = tokenize($expand_variables->($2));
1831                     push @programs, @p;
1832                     foreach my $a (@a) {
1833                         my $ak = $a;
1834                         my $av = 1;
1835                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1836                             $ak = $1;
1837                             $av = $2;
1838                         }
1839                         foreach my $p (@p) {
1840                             $attributes{$p}->{$ak} = $av;
1841                         }
1842                     }
1843                 }
1844             },
1845             qr/^\s*LIBS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1846             => sub {
1847                 if (!@skip || $skip[$#skip] > 0) {
1848                     my @a = tokenize($1, qr|\s*,\s*|);
1849                     my @l = tokenize($expand_variables->($2));
1850                     push @libraries, @l;
1851                     foreach my $a (@a) {
1852                         my $ak = $a;
1853                         my $av = 1;
1854                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1855                             $ak = $1;
1856                             $av = $2;
1857                         }
1858                         foreach my $l (@l) {
1859                             $attributes{$l}->{$ak} = $av;
1860                         }
1861                     }
1862                 }
1863             },
1864             qr/^\s*MODULES(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1865             => sub {
1866                 if (!@skip || $skip[$#skip] > 0) {
1867                     my @a = tokenize($1, qr|\s*,\s*|);
1868                     my @m = tokenize($expand_variables->($2));
1869                     push @modules, @m;
1870                     foreach my $a (@a) {
1871                         my $ak = $a;
1872                         my $av = 1;
1873                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1874                             $ak = $1;
1875                             $av = $2;
1876                         }
1877                         foreach my $m (@m) {
1878                             $attributes{$m}->{$ak} = $av;
1879                         }
1880                     }
1881                 }
1882             },
1883             qr/^\s*SCRIPTS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1884             => sub {
1885                 if (!@skip || $skip[$#skip] > 0) {
1886                     my @a = tokenize($1, qr|\s*,\s*|);
1887                     my @s = tokenize($expand_variables->($2));
1888                     push @scripts, @s;
1889                     foreach my $a (@a) {
1890                         my $ak = $a;
1891                         my $av = 1;
1892                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1893                             $ak = $1;
1894                             $av = $2;
1895                         }
1896                         foreach my $s (@s) {
1897                             $attributes{$s}->{$ak} = $av;
1898                         }
1899                     }
1900                 }
1901             },
1902
1903             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1904             => sub { push @{$ordinals{$1}}, tokenize($expand_variables->($2))
1905                          if !@skip || $skip[$#skip] > 0 },
1906             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1907             => sub { push @{$sources{$1}}, tokenize($expand_variables->($2))
1908                          if !@skip || $skip[$#skip] > 0 },
1909             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1910             => sub { push @{$shared_sources{$1}},
1911                          tokenize($expand_variables->($2))
1912                          if !@skip || $skip[$#skip] > 0 },
1913             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1914             => sub { push @{$includes{$1}}, tokenize($expand_variables->($2))
1915                          if !@skip || $skip[$#skip] > 0 },
1916             qr/^\s*DEFINE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1917             => sub { push @{$defines{$1}}, tokenize($expand_variables->($2))
1918                          if !@skip || $skip[$#skip] > 0 },
1919             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1920             => sub { push @{$depends{$1}}, tokenize($expand_variables->($2))
1921                          if !@skip || $skip[$#skip] > 0 },
1922             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1923             => sub { push @{$generate{$1}}, $2
1924                          if !@skip || $skip[$#skip] > 0 },
1925             qr/^\s*(?:#.*)?$/ => sub { },
1926             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1927             "BEFORE" => sub {
1928                 if ($buildinfo_debug) {
1929                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1930                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1931                 }
1932             },
1933             "AFTER" => sub {
1934                 if ($buildinfo_debug) {
1935                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1936                 }
1937             },
1938             );
1939         die "runaway IF?" if (@skip);
1940
1941         if (grep { defined $attributes{$_}->{engine} } keys %attributes
1942                 and !$config{dynamic_engines}) {
1943             die <<"EOF"
1944 ENGINES can only be used if configured with 'dynamic-engine'.
1945 This is usually a fault in a build.info file.
1946 EOF
1947         }
1948
1949         foreach (keys %attributes) {
1950             my $dest = $_;
1951             my $ddest = cleanfile($buildd, $_, $blddir);
1952             foreach (keys %{$attributes{$dest} // {}}) {
1953                 $unified_info{attributes}->{$ddest}->{$_} =
1954                     $attributes{$dest}->{$_};
1955             }
1956         }
1957
1958         {
1959             my %infos = ( programs  => [ @programs  ],
1960                           libraries => [ @libraries ],
1961                           modules   => [ @modules   ],
1962                           scripts   => [ @scripts   ] );
1963             foreach my $k (keys %infos) {
1964                 foreach (@{$infos{$k}}) {
1965                     my $item = cleanfile($buildd, $_, $blddir);
1966                     $unified_info{$k}->{$item} = 1;
1967                 }
1968             }
1969         }
1970
1971         # Check that we haven't defined any library as both shared and
1972         # explicitly static.  That is forbidden.
1973         my @doubles = ();
1974         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
1975             (my $l = $_) =~ s/\.a$//;
1976             push @doubles, $l if defined $unified_info{libraries}->{$l};
1977         }
1978         die "these libraries are both explicitly static and shared:\n  ",
1979             join(" ", @doubles), "\n"
1980             if @doubles;
1981
1982         foreach (keys %sources) {
1983             my $dest = $_;
1984             my $ddest = cleanfile($buildd, $_, $blddir);
1985             foreach (@{$sources{$dest}}) {
1986                 my $s = cleanfile($sourced, $_, $blddir);
1987
1988                 # If it isn't in the source tree, we assume it's generated
1989                 # in the build tree
1990                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
1991                     $s = cleanfile($buildd, $_, $blddir);
1992                 }
1993                 # We recognise C++, C and asm files
1994                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1995                     my $o = $_;
1996                     $o =~ s/\.[csS]$/.o/; # C and assembler
1997                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1998                     $o = cleanfile($buildd, $o, $blddir);
1999                     $unified_info{sources}->{$ddest}->{$o} = -1;
2000                     $unified_info{sources}->{$o}->{$s} = -1;
2001                 } elsif ($s =~ /\.rc$/) {
2002                     # We also recognise resource files
2003                     my $o = $_;
2004                     $o =~ s/\.rc$/.res/; # Resource configuration
2005                     my $o = cleanfile($buildd, $o, $blddir);
2006                     $unified_info{sources}->{$ddest}->{$o} = -1;
2007                     $unified_info{sources}->{$o}->{$s} = -1;
2008                 } else {
2009                     $unified_info{sources}->{$ddest}->{$s} = 1;
2010                 }
2011             }
2012         }
2013
2014         foreach (keys %shared_sources) {
2015             my $dest = $_;
2016             my $ddest = cleanfile($buildd, $_, $blddir);
2017             foreach (@{$shared_sources{$dest}}) {
2018                 my $s = cleanfile($sourced, $_, $blddir);
2019
2020                 # If it isn't in the source tree, we assume it's generated
2021                 # in the build tree
2022                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2023                     $s = cleanfile($buildd, $_, $blddir);
2024                 }
2025
2026                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2027                     # We recognise C++, C and asm files
2028                     my $o = $_;
2029                     $o =~ s/\.[csS]$/.o/; # C and assembler
2030                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2031                     $o = cleanfile($buildd, $o, $blddir);
2032                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2033                     $unified_info{sources}->{$o}->{$s} = -1;
2034                 } elsif ($s =~ /\.rc$/) {
2035                     # We also recognise resource files
2036                     my $o = $_;
2037                     $o =~ s/\.rc$/.res/; # Resource configuration
2038                     my $o = cleanfile($buildd, $o, $blddir);
2039                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2040                     $unified_info{sources}->{$o}->{$s} = -1;
2041                 } elsif ($s =~ /\.ld$/) {
2042                     # We also recognise linker scripts (or corresponding)
2043                     # We know they are generated files
2044                     my $ld = cleanfile($buildd, $_, $blddir);
2045                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2046                 } else {
2047                     die "unrecognised source file type for shared library: $s\n";
2048                 }
2049             }
2050         }
2051
2052         foreach (keys %generate) {
2053             my $dest = $_;
2054             my $ddest = cleanfile($buildd, $_, $blddir);
2055             die "more than one generator for $dest: "
2056                     ,join(" ", @{$generate{$_}}),"\n"
2057                     if scalar @{$generate{$_}} > 1;
2058             my @generator = split /\s+/, $generate{$dest}->[0];
2059             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2060             $unified_info{generate}->{$ddest} = [ @generator ];
2061         }
2062
2063         foreach (keys %depends) {
2064             my $dest = $_;
2065             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2066
2067             # If the destination doesn't exist in source, it can only be
2068             # a generated file in the build tree.
2069             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2070                 $ddest = cleanfile($buildd, $_, $blddir);
2071             }
2072             foreach (@{$depends{$dest}}) {
2073                 my $d = cleanfile($sourced, $_, $blddir);
2074
2075                 # If we know it's generated, or assume it is because we can't
2076                 # find it in the source tree, we set file we depend on to be
2077                 # in the build tree rather than the source tree, and assume
2078                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2079                 # section or in the Makefile template.
2080                 if ($d eq $src_configdata
2081                     || ! -f $d
2082                     || (grep { $d eq $_ }
2083                         map { cleanfile($srcdir, $_, $blddir) }
2084                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2085                     $d = cleanfile($buildd, $_, $blddir);
2086                 }
2087                 # Take note if the file to depend on is being renamed
2088                 # Take extra care with files ending with .a, they should
2089                 # be treated without that extension, and the extension
2090                 # should be added back after treatment.
2091                 $d =~ /(\.a)?$/;
2092                 my $e = $1 // "";
2093                 $d = $`.$e;
2094                 $unified_info{depends}->{$ddest}->{$d} = 1;
2095             }
2096         }
2097
2098         foreach (keys %includes) {
2099             my $dest = $_;
2100             my $ddest = cleanfile($sourced, $_, $blddir);
2101
2102             # If the destination doesn't exist in source, it can only be
2103             # a generated file in the build tree.
2104             if ($ddest eq $src_configdata || ! -f $ddest) {
2105                 $ddest = cleanfile($buildd, $_, $blddir);
2106             }
2107             foreach (@{$includes{$dest}}) {
2108                 my $is = cleandir($sourced, $_, $blddir);
2109                 my $ib = cleandir($buildd, $_, $blddir);
2110                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2111                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2112                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2113                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2114             }
2115         }
2116
2117         foreach (keys %defines) {
2118             my $dest = $_;
2119             my $ddest = cleanfile($sourced, $_, $blddir);
2120
2121             # If the destination doesn't exist in source, it can only be
2122             # a generated file in the build tree.
2123             if (! -f $ddest) {
2124                 $ddest = cleanfile($buildd, $_, $blddir);
2125                 if ($unified_info{rename}->{$ddest}) {
2126                     $ddest = $unified_info{rename}->{$ddest};
2127                 }
2128             }
2129             foreach (@{$defines{$dest}}) {
2130                 m|^([^=]*)(=.*)?$|;
2131                 die "0 length macro name not permitted\n" if $1 eq "";
2132                 die "$1 defined more than once\n"
2133                     if defined $unified_info{defines}->{$ddest}->{$1};
2134                 $unified_info{defines}->{$ddest}->{$1} = $2;
2135             }
2136         }
2137     }
2138
2139     my $ordinals_text = join(', ', sort keys %ordinals);
2140     warn <<"EOF" if $ordinals_text;
2141
2142 WARNING: ORDINALS were specified for $ordinals_text
2143 They are ignored and should be replaced with a combination of GENERATE,
2144 DEPEND and SHARED_SOURCE.
2145 EOF
2146
2147
2148     # Go through the sources of all libraries and check that the same basename
2149     # doesn't appear more than once.  Some static library archivers depend on
2150     # them being unique.
2151     {
2152         my $err = 0;
2153         foreach my $prod (keys %{$unified_info{libraries}}) {
2154             my @prod_sources =
2155                 map { keys %{$unified_info{sources}->{$_}} }
2156                 keys %{$unified_info{sources}->{$prod}};
2157             my %srccnt = ();
2158
2159             # Count how many times a given each source basename
2160             # appears for each product.
2161             foreach my $src (@prod_sources) {
2162                 $srccnt{basename $src}++;
2163             }
2164
2165             foreach my $src (keys %srccnt) {
2166                 if ((my $cnt = $srccnt{$src}) > 1) {
2167                     print STDERR "$src appears $cnt times for the product $prod\n";
2168                     $err++
2169                 }
2170             }
2171         }
2172         die if $err > 0;
2173     }
2174
2175     # Massage the result
2176
2177     # If we depend on a header file or a perl module, add an inclusion of
2178     # its directory to allow smoothe inclusion
2179     foreach my $dest (keys %{$unified_info{depends}}) {
2180         next if $dest eq "";
2181         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2182             next unless $d =~ /\.(h|pm)$/;
2183             my $i = dirname($d);
2184             my $spot =
2185                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2186                 ? 'build' : 'source';
2187             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2188                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2189         }
2190     }
2191
2192     # Go through all intermediary files and change their names to something that
2193     # reflects what they will be built for.  Note that for some source files,
2194     # this leads to duplicate object files because they are used multiple times.
2195     # the goal is to rename all object files according to this scheme:
2196     #    {productname}-{midfix}-{origobjname}.[o|res]
2197     # the {midfix} is a keyword indicating the type of product, which is mostly
2198     # valuable for libraries since they come in two forms.
2199     #
2200     # This also reorganises the {sources} and {shared_sources} so that the
2201     # former only contains ALL object files that are supposed to end up in
2202     # static libraries and programs, while the latter contains ALL object files
2203     # that are supposed to end up in shared libraries and DSOs.
2204     # The main reason for having two different source structures is to allow
2205     # the same name to be used for the static and the shared variants of a
2206     # library.
2207     {
2208         # Take copies so we don't get interference from added stuff
2209         my %unified_copy = ();
2210         foreach (('sources', 'shared_sources')) {
2211             $unified_copy{$_} = { %{$unified_info{$_}} }
2212                 if defined($unified_info{$_});
2213             delete $unified_info{$_};
2214         }
2215         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2216             # $intent serves multi purposes:
2217             # - give a prefix for the new object files names
2218             # - in the case of libraries, rearrange the object files so static
2219             #   libraries use the 'sources' structure exclusively, while shared
2220             #   libraries use the 'shared_sources' structure exclusively.
2221             my $intent = {
2222                 programs  => { bin    => { src => [ 'sources' ],
2223                                            dst => 'sources' } },
2224                 libraries => { lib    => { src => [ 'sources' ],
2225                                            dst => 'sources' },
2226                                shlib  => { prodselect =>
2227                                                sub { grep !/\.a$/, @_ },
2228                                            src => [ 'sources',
2229                                                     'shared_sources' ],
2230                                            dst => 'shared_sources' } },
2231                 modules   => { dso    => { src => [ 'sources' ],
2232                                            dst => 'sources' } },
2233                 scripts   => { script => { src => [ 'sources' ],
2234                                            dst => 'sources' } }
2235                } -> {$prodtype};
2236             foreach my $kind (keys %$intent) {
2237                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2238                              && $disabled{shared});
2239
2240                 my @src = @{$intent->{$kind}->{src}};
2241                 my $dst = $intent->{$kind}->{dst};
2242                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2243                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2244                     # %prod_sources has all applicable objects as keys, and
2245                     # their corresponding sources as values
2246                     my %prod_sources =
2247                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2248                         map { keys %{$unified_copy{$_}->{$prod}} }
2249                         @src;
2250                     foreach (keys %prod_sources) {
2251                         # Only affect object files and resource files,
2252                         # the others simply get a new value
2253                         # (+1 instead of -1)
2254                         if ($_ =~ /\.(o|res)$/) {
2255                             (my $prodname = $prod) =~ s|\.a$||;
2256                             my $newobj =
2257                                 catfile(dirname($_),
2258                                         basename($prodname)
2259                                             . '-' . $kind
2260                                             . '-' . basename($_));
2261                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2262                             foreach my $src (@{$prod_sources{$_}}) {
2263                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2264                             }
2265                             # Adjust dependencies
2266                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2267                                 $unified_info{depends}->{$_}->{$deps} = -1;
2268                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2269                             }
2270                             # Adjust includes
2271                             foreach my $k (('source', 'build')) {
2272                                 next unless
2273                                     defined($unified_info{includes}->{$_}->{$k});
2274                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2275                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2276                             }
2277                         } else {
2278                             $unified_info{$dst}->{$prod}->{$_} = 1;
2279                         }
2280                     }
2281                 }
2282             }
2283         }
2284     }
2285
2286     # At this point, we have a number of sources with the value -1.  They
2287     # aren't part of the local build and are probably meant for a different
2288     # platform, and can therefore be cleaned away.  That happens when making
2289     # %unified_info more efficient below.
2290
2291     ### Make unified_info a bit more efficient
2292     # One level structures
2293     foreach (("programs", "libraries", "modules", "scripts")) {
2294         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2295     }
2296     # Two level structures
2297     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends")) {
2298         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2299             my @items =
2300                 sort
2301                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2302                 keys %{$unified_info{$l1}->{$l2}};
2303             if (@items) {
2304                 $unified_info{$l1}->{$l2} = [ @items ];
2305             } else {
2306                 delete $unified_info{$l1}->{$l2};
2307             }
2308         }
2309     }
2310     # Defines
2311     foreach my $dest (sort keys %{$unified_info{defines}}) {
2312         $unified_info{defines}->{$dest}
2313             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2314                 sort keys %{$unified_info{defines}->{$dest}} ];
2315     }
2316     # Includes
2317     foreach my $dest (sort keys %{$unified_info{includes}}) {
2318         if (defined($unified_info{includes}->{$dest}->{build})) {
2319             my @source_includes = ();
2320             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2321                 if defined($unified_info{includes}->{$dest}->{source});
2322             $unified_info{includes}->{$dest} =
2323                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2324             foreach my $inc (@source_includes) {
2325                 push @{$unified_info{includes}->{$dest}}, $inc
2326                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2327             }
2328         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2329             $unified_info{includes}->{$dest} =
2330                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2331         } else {
2332             delete $unified_info{includes}->{$dest};
2333         }
2334     }
2335
2336     # For convenience collect information regarding directories where
2337     # files are generated, those generated files and the end product
2338     # they end up in where applicable.  Then, add build rules for those
2339     # directories
2340     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2341                      "dso" => [ @{$unified_info{modules}} ],
2342                      "bin" => [ @{$unified_info{programs}} ],
2343                      "script" => [ @{$unified_info{scripts}} ] );
2344     foreach my $type (keys %loopinfo) {
2345         foreach my $product (@{$loopinfo{$type}}) {
2346             my %dirs = ();
2347             my $pd = dirname($product);
2348
2349             foreach (@{$unified_info{sources}->{$product} // []},
2350                      @{$unified_info{shared_sources}->{$product} // []}) {
2351                 my $d = dirname($_);
2352
2353                 # We don't want to create targets for source directories
2354                 # when building out of source
2355                 next if ($config{sourcedir} ne $config{builddir}
2356                              && $d =~ m|^\Q$config{sourcedir}\E|);
2357                 # We already have a "test" target, and the current directory
2358                 # is just silly to make a target for
2359                 next if $d eq "test" || $d eq ".";
2360
2361                 $dirs{$d} = 1;
2362                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2363                     if $d ne $pd;
2364             }
2365             foreach (keys %dirs) {
2366                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2367                     $product;
2368             }
2369         }
2370     }
2371 }
2372
2373 # For the schemes that need it, we provide the old *_obj configs
2374 # from the *_asm_obj ones
2375 foreach (grep /_(asm|aux)_src$/, keys %target) {
2376     my $src = $_;
2377     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2378     $target{$obj} = $target{$src};
2379     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2380     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2381 }
2382
2383 # Write down our configuration where it fits #########################
2384
2385 print "Creating configdata.pm\n";
2386 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2387 print OUT <<"EOF";
2388 #! $config{HASHBANGPERL}
2389
2390 package configdata;
2391
2392 use strict;
2393 use warnings;
2394
2395 use Exporter;
2396 #use vars qw(\@ISA \@EXPORT);
2397 our \@ISA = qw(Exporter);
2398 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables \@disablables_int);
2399
2400 EOF
2401 print OUT "our %config = (\n";
2402 foreach (sort keys %config) {
2403     if (ref($config{$_}) eq "ARRAY") {
2404         print OUT "  ", $_, " => [ ", join(", ",
2405                                            map { quotify("perl", $_) }
2406                                            @{$config{$_}}), " ],\n";
2407     } elsif (ref($config{$_}) eq "HASH") {
2408         print OUT "  ", $_, " => {";
2409         if (scalar keys %{$config{$_}} > 0) {
2410             print OUT "\n";
2411             foreach my $key (sort keys %{$config{$_}}) {
2412                 print OUT "      ",
2413                     join(" => ",
2414                          quotify("perl", $key),
2415                          defined $config{$_}->{$key}
2416                              ? quotify("perl", $config{$_}->{$key})
2417                              : "undef");
2418                 print OUT ",\n";
2419             }
2420             print OUT "  ";
2421         }
2422         print OUT "},\n";
2423     } else {
2424         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2425     }
2426 }
2427 print OUT <<"EOF";
2428 );
2429
2430 EOF
2431 print OUT "our %target = (\n";
2432 foreach (sort keys %target) {
2433     if (ref($target{$_}) eq "ARRAY") {
2434         print OUT "  ", $_, " => [ ", join(", ",
2435                                            map { quotify("perl", $_) }
2436                                            @{$target{$_}}), " ],\n";
2437     } else {
2438         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2439     }
2440 }
2441 print OUT <<"EOF";
2442 );
2443
2444 EOF
2445 print OUT "our \%available_protocols = (\n";
2446 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2447 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2448 print OUT <<"EOF";
2449 );
2450
2451 EOF
2452 print OUT "our \@disablables = (\n";
2453 foreach (@disablables) {
2454     print OUT "  ", quotify("perl", $_), ",\n";
2455 }
2456 print OUT <<"EOF";
2457 );
2458
2459 EOF
2460 print OUT "# The following come from Configure's @disablables_int\n";
2461 print OUT "our \@disablables_int = (\n";
2462 foreach (@disablables_int) {
2463     print OUT "  ", quotify("perl", $_), ",\n";
2464 }
2465 print OUT <<"EOF";
2466 );
2467
2468 EOF
2469 print OUT "our \%disabled = (\n";
2470 foreach (sort keys %disabled) {
2471     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2472 }
2473 print OUT <<"EOF";
2474 );
2475
2476 EOF
2477 print OUT "our %withargs = (\n";
2478 foreach (sort keys %withargs) {
2479     if (ref($withargs{$_}) eq "ARRAY") {
2480         print OUT "  ", $_, " => [ ", join(", ",
2481                                            map { quotify("perl", $_) }
2482                                            @{$withargs{$_}}), " ],\n";
2483     } else {
2484         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2485     }
2486 }
2487 print OUT <<"EOF";
2488 );
2489
2490 EOF
2491 if ($builder eq "unified") {
2492     my $recurse;
2493     $recurse = sub {
2494         my $indent = shift;
2495         foreach (@_) {
2496             if (ref $_ eq "ARRAY") {
2497                 print OUT " "x$indent, "[\n";
2498                 foreach (@$_) {
2499                     $recurse->($indent + 4, $_);
2500                 }
2501                 print OUT " "x$indent, "],\n";
2502             } elsif (ref $_ eq "HASH") {
2503                 my %h = %$_;
2504                 print OUT " "x$indent, "{\n";
2505                 foreach (sort keys %h) {
2506                     if (ref $h{$_} eq "") {
2507                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2508                     } else {
2509                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2510                         $recurse->($indent + 8, $h{$_});
2511                     }
2512                 }
2513                 print OUT " "x$indent, "},\n";
2514             } else {
2515                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2516             }
2517         }
2518     };
2519     print OUT "our %unified_info = (\n";
2520     foreach (sort keys %unified_info) {
2521         if (ref $unified_info{$_} eq "") {
2522             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2523         } else {
2524             print OUT " "x4, quotify("perl", $_), " =>\n";
2525             $recurse->(8, $unified_info{$_});
2526         }
2527     }
2528     print OUT <<"EOF";
2529 );
2530
2531 EOF
2532 }
2533 print OUT
2534     "# The following data is only used when this files is use as a script\n";
2535 print OUT "my \@makevars = (\n";
2536 foreach (sort keys %user) {
2537     print OUT "    '",$_,"',\n";
2538 }
2539 print OUT ");\n";
2540 print OUT "my \%disabled_info = (\n";
2541 foreach my $what (sort keys %disabled_info) {
2542     print OUT "    '$what' => {\n";
2543     foreach my $info (sort keys %{$disabled_info{$what}}) {
2544         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2545             print OUT "        $info => [ ",
2546                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2547                 " ],\n";
2548         } else {
2549             print OUT "        $info => '", $disabled_info{$what}->{$info},
2550                 "',\n";
2551         }
2552     }
2553     print OUT "    },\n";
2554 }
2555 print OUT ");\n";
2556 print OUT 'my @user_crossable = qw( ', join (' ', @user_crossable), " );\n";
2557 print OUT << 'EOF';
2558 # If run directly, we can give some answers, and even reconfigure
2559 unless (caller) {
2560     use Getopt::Long;
2561     use File::Spec::Functions;
2562     use File::Basename;
2563     use Pod::Usage;
2564
2565     my $here = dirname($0);
2566
2567     my $dump = undef;
2568     my $cmdline = undef;
2569     my $options = undef;
2570     my $target = undef;
2571     my $envvars = undef;
2572     my $makevars = undef;
2573     my $buildparams = undef;
2574     my $reconf = undef;
2575     my $verbose = undef;
2576     my $help = undef;
2577     my $man = undef;
2578     GetOptions('dump|d'                 => \$dump,
2579                'command-line|c'         => \$cmdline,
2580                'options|o'              => \$options,
2581                'target|t'               => \$target,
2582                'environment|e'          => \$envvars,
2583                'make-variables|m'       => \$makevars,
2584                'build-parameters|b'     => \$buildparams,
2585                'reconfigure|reconf|r'   => \$reconf,
2586                'verbose|v'              => \$verbose,
2587                'help'                   => \$help,
2588                'man'                    => \$man)
2589         or die "Errors in command line arguments\n";
2590
2591     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2592             || $buildparams || $reconf || $verbose || $help || $man) {
2593         print STDERR <<"_____";
2594 You must give at least one option.
2595 For more information, do '$0 --help'
2596 _____
2597         exit(2);
2598     }
2599
2600     if ($help) {
2601         pod2usage(-exitval => 0,
2602                   -verbose => 1);
2603     }
2604     if ($man) {
2605         pod2usage(-exitval => 0,
2606                   -verbose => 2);
2607     }
2608     if ($dump || $cmdline) {
2609         print "\nCommand line (with current working directory = $here):\n\n";
2610         print '    ',join(' ',
2611                           $config{PERL},
2612                           catfile($config{sourcedir}, 'Configure'),
2613                           @{$config{perlargv}}), "\n";
2614         print "\nPerl information:\n\n";
2615         print '    ',$config{perl_cmd},"\n";
2616         print '    ',$config{perl_version},' for ',$config{perl_archname},"\n";
2617     }
2618     if ($dump || $options) {
2619         my $longest = 0;
2620         my $longest2 = 0;
2621         foreach my $what (@disablables) {
2622             $longest = length($what) if $longest < length($what);
2623             $longest2 = length($disabled{$what})
2624                 if $disabled{$what} && $longest2 < length($disabled{$what});
2625         }
2626         print "\nEnabled features:\n\n";
2627         foreach my $what (@disablables) {
2628             print "    $what\n" unless $disabled{$what};
2629         }
2630         print "\nDisabled features:\n\n";
2631         foreach my $what (@disablables) {
2632             if ($disabled{$what}) {
2633                 print "    $what", ' ' x ($longest - length($what) + 1),
2634                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2635                 print $disabled_info{$what}->{macro}
2636                     if $disabled_info{$what}->{macro};
2637                 print ' (skip ',
2638                     join(', ', @{$disabled_info{$what}->{skipped}}),
2639                     ')'
2640                     if $disabled_info{$what}->{skipped};
2641                 print "\n";
2642             }
2643         }
2644     }
2645     if ($dump || $target) {
2646         print "\nConfig target attributes:\n\n";
2647         foreach (sort keys %target) {
2648             next if $_ =~ m|^_| || $_ eq 'template';
2649             my $quotify = sub {
2650                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2651             };
2652             print '    ', $_, ' => ';
2653             if (ref($target{$_}) eq "ARRAY") {
2654                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2655             } else {
2656                 print $quotify->($target{$_}), ",\n"
2657             }
2658         }
2659     }
2660     if ($dump || $envvars) {
2661         print "\nRecorded environment:\n\n";
2662         foreach (sort keys %{$config{perlenv}}) {
2663             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2664         }
2665     }
2666     if ($dump || $makevars) {
2667         print "\nMakevars:\n\n";
2668         foreach my $var (@makevars) {
2669             my $prefix = '';
2670             $prefix = $config{CROSS_COMPILE}
2671                 if grep { $var eq $_ } @user_crossable;
2672             $prefix //= '';
2673             print '    ',$var,' ' x (16 - length $var),'= ',
2674                 (ref $config{$var} eq 'ARRAY'
2675                  ? join(' ', @{$config{$var}})
2676                  : $prefix.$config{$var}),
2677                 "\n"
2678                 if defined $config{$var};
2679         }
2680
2681         my @buildfile = ($config{builddir}, $config{build_file});
2682         unshift @buildfile, $here
2683             unless file_name_is_absolute($config{builddir});
2684         my $buildfile = canonpath(catdir(@buildfile));
2685         print <<"_____";
2686
2687 NOTE: These variables only represent the configuration view.  The build file
2688 template may have processed these variables further, please have a look at the
2689 build file for more exact data:
2690     $buildfile
2691 _____
2692     }
2693     if ($dump || $buildparams) {
2694         my @buildfile = ($config{builddir}, $config{build_file});
2695         unshift @buildfile, $here
2696             unless file_name_is_absolute($config{builddir});
2697         print "\nbuild file:\n\n";
2698         print "    ", canonpath(catfile(@buildfile)),"\n";
2699
2700         print "\nbuild file templates:\n\n";
2701         foreach (@{$config{build_file_templates}}) {
2702             my @tmpl = ($_);
2703             unshift @tmpl, $here
2704                 unless file_name_is_absolute($config{sourcedir});
2705             print '    ',canonpath(catfile(@tmpl)),"\n";
2706         }
2707     }
2708     if ($reconf) {
2709         if ($verbose) {
2710             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2711             foreach (sort keys %{$config{perlenv}}) {
2712                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2713             }
2714         }
2715
2716         chdir $here;
2717         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2718     }
2719 }
2720
2721 1;
2722
2723 __END__
2724
2725 =head1 NAME
2726
2727 configdata.pm - configuration data for OpenSSL builds
2728
2729 =head1 SYNOPSIS
2730
2731 Interactive:
2732
2733   perl configdata.pm [options]
2734
2735 As data bank module:
2736
2737   use configdata;
2738
2739 =head1 DESCRIPTION
2740
2741 This module can be used in two modes, interactively and as a module containing
2742 all the data recorded by OpenSSL's Configure script.
2743
2744 When used interactively, simply run it as any perl script, with at least one
2745 option, and you will get the information you ask for.  See L</OPTIONS> below.
2746
2747 When loaded as a module, you get a few databanks with useful information to
2748 perform build related tasks.  The databanks are:
2749
2750     %config             Configured things.
2751     %target             The OpenSSL config target with all inheritances
2752                         resolved.
2753     %disabled           The features that are disabled.
2754     @disablables        The list of features that can be disabled.
2755     %withargs           All data given through --with-THING options.
2756     %unified_info       All information that was computed from the build.info
2757                         files.
2758
2759 =head1 OPTIONS
2760
2761 =over 4
2762
2763 =item B<--help>
2764
2765 Print a brief help message and exit.
2766
2767 =item B<--man>
2768
2769 Print the manual page and exit.
2770
2771 =item B<--dump> | B<-d>
2772
2773 Print all relevant configuration data.  This is equivalent to B<--command-line>
2774 B<--options> B<--target> B<--environment> B<--make-variables>
2775 B<--build-parameters>.
2776
2777 =item B<--command-line> | B<-c>
2778
2779 Print the current configuration command line.
2780
2781 =item B<--options> | B<-o>
2782
2783 Print the features, both enabled and disabled, and display defined macro and
2784 skipped directories where applicable.
2785
2786 =item B<--target> | B<-t>
2787
2788 Print the config attributes for this config target.
2789
2790 =item B<--environment> | B<-e>
2791
2792 Print the environment variables and their values at the time of configuration.
2793
2794 =item B<--make-variables> | B<-m>
2795
2796 Print the main make variables generated in the current configuration
2797
2798 =item B<--build-parameters> | B<-b>
2799
2800 Print the build parameters, i.e. build file and build file templates.
2801
2802 =item B<--reconfigure> | B<--reconf> | B<-r>
2803
2804 Redo the configuration.
2805
2806 =item B<--verbose> | B<-v>
2807
2808 Verbose output.
2809
2810 =back
2811
2812 =cut
2813
2814 EOF
2815 close(OUT);
2816 if ($builder_platform eq 'unix') {
2817     my $mode = (0755 & ~umask);
2818     chmod $mode, 'configdata.pm'
2819         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2820 }
2821
2822 my %builders = (
2823     unified => sub {
2824         print 'Creating ',$target{build_file},"\n";
2825         run_dofile(catfile($blddir, $target{build_file}),
2826                    @{$config{build_file_templates}});
2827     },
2828     );
2829
2830 $builders{$builder}->($builder_platform, @builder_opts);
2831
2832 $SIG{__DIE__} = $orig_death_handler;
2833
2834 print <<"EOF" if ($disabled{threads} eq "unavailable");
2835
2836 The library could not be configured for supporting multi-threaded
2837 applications as the compiler options required on this system are not known.
2838 See file INSTALL for details if you need multi-threading.
2839 EOF
2840
2841 print <<"EOF" if ($no_shared_warn);
2842
2843 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2844 platform, so we will pretend you gave the option 'no-pic', which also disables
2845 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2846 or position independent code, please let us know (but please first make sure
2847 you have tried with a current version of OpenSSL).
2848 EOF
2849
2850 print <<"EOF";
2851
2852 **********************************************************************
2853 ***                                                                ***
2854 ***   OpenSSL has been successfully configured                     ***
2855 ***                                                                ***
2856 ***   If you encounter a problem while building, please open an    ***
2857 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2858 ***   and include the output from the following command:           ***
2859 ***                                                                ***
2860 ***       perl configdata.pm --dump                                ***
2861 ***                                                                ***
2862 ***   (If you are new to OpenSSL, you might want to consult the    ***
2863 ***   'Troubleshooting' section in the INSTALL file first)         ***
2864 ***                                                                ***
2865 **********************************************************************
2866 EOF
2867
2868 exit(0);
2869
2870 ######################################################################
2871 #
2872 # Helpers and utility functions
2873 #
2874
2875 # Death handler, to print a helpful message in case of failure #######
2876 #
2877 sub death_handler {
2878     die @_ if $^S;              # To prevent the added message in eval blocks
2879     my $build_file = $target{build_file} // "build file";
2880     my @message = ( <<"_____", @_ );
2881
2882 Failure!  $build_file wasn't produced.
2883 Please read INSTALL and associated NOTES files.  You may also have to look over
2884 your available compiler tool chain or change your configuration.
2885
2886 _____
2887
2888     # Dying is terminal, so it's ok to reset the signal handler here.
2889     $SIG{__DIE__} = $orig_death_handler;
2890     die @message;
2891 }
2892
2893 # Configuration file reading #########################################
2894
2895 # Note: All of the helper functions are for lazy evaluation.  They all
2896 # return a CODE ref, which will return the intended value when evaluated.
2897 # Thus, whenever there's mention of a returned value, it's about that
2898 # intended value.
2899
2900 # Helper function to implement conditional inheritance depending on the
2901 # value of $disabled{asm}.  Used in inherit_from values as follows:
2902 #
2903 #      inherit_from => [ "template", asm("asm_tmpl") ]
2904 #
2905 sub asm {
2906     my @x = @_;
2907     sub {
2908         $disabled{asm} ? () : @x;
2909     }
2910 }
2911
2912 # Helper function to implement conditional value variants, with a default
2913 # plus additional values based on the value of $config{build_type}.
2914 # Arguments are given in hash table form:
2915 #
2916 #       picker(default => "Basic string: ",
2917 #              debug   => "debug",
2918 #              release => "release")
2919 #
2920 # When configuring with --debug, the resulting string will be
2921 # "Basic string: debug", and when not, it will be "Basic string: release"
2922 #
2923 # This can be used to create variants of sets of flags according to the
2924 # build type:
2925 #
2926 #       cflags => picker(default => "-Wall",
2927 #                        debug   => "-g -O0",
2928 #                        release => "-O3")
2929 #
2930 sub picker {
2931     my %opts = @_;
2932     return sub { add($opts{default} || (),
2933                      $opts{$config{build_type}} || ())->(); }
2934 }
2935
2936 # Helper function to combine several values of different types into one.
2937 # This is useful if you want to combine a string with the result of a
2938 # lazy function, such as:
2939 #
2940 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2941 #
2942 sub combine {
2943     my @stuff = @_;
2944     return sub { add(@stuff)->(); }
2945 }
2946
2947 # Helper function to implement conditional values depending on the value
2948 # of $disabled{threads}.  Can be used as follows:
2949 #
2950 #       cflags => combine("-Wall", threads("-pthread"))
2951 #
2952 sub threads {
2953     my @flags = @_;
2954     return sub { add($disabled{threads} ? () : @flags)->(); }
2955 }
2956
2957 sub shared {
2958     my @flags = @_;
2959     return sub { add($disabled{shared} ? () : @flags)->(); }
2960 }
2961
2962 our $add_called = 0;
2963 # Helper function to implement adding values to already existing configuration
2964 # values.  It handles elements that are ARRAYs, CODEs and scalars
2965 sub _add {
2966     my $separator = shift;
2967
2968     # If there's any ARRAY in the collection of values OR the separator
2969     # is undef, we will return an ARRAY of combined values, otherwise a
2970     # string of joined values with $separator as the separator.
2971     my $found_array = !defined($separator);
2972
2973     my @values =
2974         map {
2975             my $res = $_;
2976             while (ref($res) eq "CODE") {
2977                 $res = $res->();
2978             }
2979             if (defined($res)) {
2980                 if (ref($res) eq "ARRAY") {
2981                     $found_array = 1;
2982                     @$res;
2983                 } else {
2984                     $res;
2985                 }
2986             } else {
2987                 ();
2988             }
2989     } (@_);
2990
2991     $add_called = 1;
2992
2993     if ($found_array) {
2994         [ @values ];
2995     } else {
2996         join($separator, grep { defined($_) && $_ ne "" } @values);
2997     }
2998 }
2999 sub add_before {
3000     my $separator = " ";
3001     if (ref($_[$#_]) eq "HASH") {
3002         my $opts = pop;
3003         $separator = $opts->{separator};
3004     }
3005     my @x = @_;
3006     sub { _add($separator, @x, @_) };
3007 }
3008 sub add {
3009     my $separator = " ";
3010     if (ref($_[$#_]) eq "HASH") {
3011         my $opts = pop;
3012         $separator = $opts->{separator};
3013     }
3014     my @x = @_;
3015     sub { _add($separator, @_, @x) };
3016 }
3017
3018 sub read_eval_file {
3019     my $fname = shift;
3020     my $content;
3021     my @result;
3022
3023     open F, "< $fname" or die "Can't open '$fname': $!\n";
3024     {
3025         undef local $/;
3026         $content = <F>;
3027     }
3028     close F;
3029     {
3030         local $@;
3031
3032         @result = ( eval $content );
3033         warn $@ if $@;
3034     }
3035     return wantarray ? @result : $result[0];
3036 }
3037
3038 # configuration reader, evaluates the input file as a perl script and expects
3039 # it to fill %targets with target configurations.  Those are then added to
3040 # %table.
3041 sub read_config {
3042     my $fname = shift;
3043     my %targets;
3044
3045     {
3046         # Protect certain tables from tampering
3047         local %table = ();
3048
3049         %targets = read_eval_file($fname);
3050     }
3051     my %preexisting = ();
3052     foreach (sort keys %targets) {
3053         $preexisting{$_} = 1 if $table{$_};
3054     }
3055     die <<"EOF",
3056 The following config targets from $fname
3057 shadow pre-existing config targets with the same name:
3058 EOF
3059         map { "  $_\n" } sort keys %preexisting
3060         if %preexisting;
3061
3062
3063     # For each target, check that it's configured with a hash table.
3064     foreach (keys %targets) {
3065         if (ref($targets{$_}) ne "HASH") {
3066             if (ref($targets{$_}) eq "") {
3067                 warn "Deprecated target configuration for $_, ignoring...\n";
3068             } else {
3069                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3070             }
3071             delete $targets{$_};
3072         } else {
3073             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3074         }
3075     }
3076
3077     %table = (%table, %targets);
3078
3079 }
3080
3081 # configuration resolver.  Will only resolve all the lazy evaluation
3082 # codeblocks for the chosen target and all those it inherits from,
3083 # recursively
3084 sub resolve_config {
3085     my $target = shift;
3086     my @breadcrumbs = @_;
3087
3088 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3089
3090     if (grep { $_ eq $target } @breadcrumbs) {
3091         die "inherit_from loop!  target backtrace:\n  "
3092             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3093     }
3094
3095     if (!defined($table{$target})) {
3096         warn "Warning! target $target doesn't exist!\n";
3097         return ();
3098     }
3099     # Recurse through all inheritances.  They will be resolved on the
3100     # fly, so when this operation is done, they will all just be a
3101     # bunch of attributes with string values.
3102     # What we get here, though, are keys with references to lists of
3103     # the combined values of them all.  We will deal with lists after
3104     # this stage is done.
3105     my %combined_inheritance = ();
3106     if ($table{$target}->{inherit_from}) {
3107         my @inherit_from =
3108             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3109         foreach (@inherit_from) {
3110             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3111
3112             # 'template' is a marker that's considered private to
3113             # the config that had it.
3114             delete $inherited_config{template};
3115
3116             foreach (keys %inherited_config) {
3117                 if (!$combined_inheritance{$_}) {
3118                     $combined_inheritance{$_} = [];
3119                 }
3120                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3121             }
3122         }
3123     }
3124
3125     # We won't need inherit_from in this target any more, since we've
3126     # resolved all the inheritances that lead to this
3127     delete $table{$target}->{inherit_from};
3128
3129     # Now is the time to deal with those lists.  Here's the place to
3130     # decide what shall be done with those lists, all based on the
3131     # values of the target we're currently dealing with.
3132     # - If a value is a coderef, it will be executed with the list of
3133     #   inherited values as arguments.
3134     # - If the corresponding key doesn't have a value at all or is the
3135     #   empty string, the inherited value list will be run through the
3136     #   default combiner (below), and the result becomes this target's
3137     #   value.
3138     # - Otherwise, this target's value is assumed to be a string that
3139     #   will simply override the inherited list of values.
3140     my $default_combiner = add();
3141
3142     my %all_keys =
3143         map { $_ => 1 } (keys %combined_inheritance,
3144                          keys %{$table{$target}});
3145
3146     sub process_values {
3147         my $object    = shift;
3148         my $inherited = shift;  # Always a [ list ]
3149         my $target    = shift;
3150         my $entry     = shift;
3151
3152         $add_called = 0;
3153
3154         while(ref($object) eq "CODE") {
3155             $object = $object->(@$inherited);
3156         }
3157         if (!defined($object)) {
3158             return ();
3159         }
3160         elsif (ref($object) eq "ARRAY") {
3161             local $add_called;  # To make sure recursive calls don't affect it
3162             return [ map { process_values($_, $inherited, $target, $entry) }
3163                      @$object ];
3164         } elsif (ref($object) eq "") {
3165             return $object;
3166         } else {
3167             die "cannot handle reference type ",ref($object)
3168                 ," found in target ",$target," -> ",$entry,"\n";
3169         }
3170     }
3171
3172     foreach (sort keys %all_keys) {
3173         my $previous = $combined_inheritance{$_};
3174
3175         # Current target doesn't have a value for the current key?
3176         # Assign it the default combiner, the rest of this loop body
3177         # will handle it just like any other coderef.
3178         if (!exists $table{$target}->{$_}) {
3179             $table{$target}->{$_} = $default_combiner;
3180         }
3181
3182         $table{$target}->{$_} = process_values($table{$target}->{$_},
3183                                                $combined_inheritance{$_},
3184                                                $target, $_);
3185         unless(defined($table{$target}->{$_})) {
3186             delete $table{$target}->{$_};
3187         }
3188 #        if ($extra_checks &&
3189 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3190 #            warn "$_ got replaced in $target\n";
3191 #        }
3192     }
3193
3194     # Finally done, return the result.
3195     return %{$table{$target}};
3196 }
3197
3198 sub usage
3199         {
3200         print STDERR $usage;
3201         print STDERR "\npick os/compiler from:\n";
3202         my $j=0;
3203         my $i;
3204         my $k=0;
3205         foreach $i (sort keys %table)
3206                 {
3207                 next if $table{$i}->{template};
3208                 next if $i =~ /^debug/;
3209                 $k += length($i) + 1;
3210                 if ($k > 78)
3211                         {
3212                         print STDERR "\n";
3213                         $k=length($i);
3214                         }
3215                 print STDERR $i . " ";
3216                 }
3217         foreach $i (sort keys %table)
3218                 {
3219                 next if $table{$i}->{template};
3220                 next if $i !~ /^debug/;
3221                 $k += length($i) + 1;
3222                 if ($k > 78)
3223                         {
3224                         print STDERR "\n";
3225                         $k=length($i);
3226                         }
3227                 print STDERR $i . " ";
3228                 }
3229         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3230         exit(1);
3231         }
3232
3233 sub run_dofile
3234 {
3235     my $out = shift;
3236     my @templates = @_;
3237
3238     unlink $out || warn "Can't remove $out, $!"
3239         if -f $out;
3240     foreach (@templates) {
3241         die "Can't open $_, $!" unless -f $_;
3242     }
3243     my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
3244     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
3245     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
3246     system($cmd);
3247     exit 1 if $? != 0;
3248     rename("$out.new", $out) || die "Can't rename $out.new, $!";
3249 }
3250
3251 sub compiler_predefined {
3252     state %predefined;
3253     my $cc = shift;
3254
3255     return () if $^O eq 'VMS';
3256
3257     die 'compiler_predefined called without a compiler command'
3258         unless $cc;
3259
3260     if (! $predefined{$cc}) {
3261
3262         $predefined{$cc} = {};
3263
3264         # collect compiler pre-defines from gcc or gcc-alike...
3265         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3266         while (my $l = <PIPE>) {
3267             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3268             $predefined{$cc}->{$1} = $2 // '';
3269         }
3270         close(PIPE);
3271     }
3272
3273     return %{$predefined{$cc}};
3274 }
3275
3276 sub which
3277 {
3278     my ($name)=@_;
3279
3280     if (eval { require IPC::Cmd; 1; }) {
3281         IPC::Cmd->import();
3282         return scalar IPC::Cmd::can_run($name);
3283     } else {
3284         # if there is $directories component in splitpath,
3285         # then it's not something to test with $PATH...
3286         return $name if (File::Spec->splitpath($name))[1];
3287
3288         foreach (File::Spec->path()) {
3289             my $fullpath = catfile($_, "$name$target{exe_extension}");
3290             if (-f $fullpath and -x $fullpath) {
3291                 return $fullpath;
3292             }
3293         }
3294     }
3295 }
3296
3297 sub env
3298 {
3299     my $name = shift;
3300     my %opts = @_;
3301
3302     unless ($opts{cacheonly}) {
3303         # Note that if $ENV{$name} doesn't exist or is undefined,
3304         # $config{perlenv}->{$name} will be created with the value
3305         # undef.  This is intentional.
3306
3307         $config{perlenv}->{$name} = $ENV{$name}
3308             if ! exists $config{perlenv}->{$name};
3309     }
3310     return $config{perlenv}->{$name};
3311 }
3312
3313 # Configuration printer ##############################################
3314
3315 sub print_table_entry
3316 {
3317     local $now_printing = shift;
3318     my %target = resolve_config($now_printing);
3319     my $type = shift;
3320
3321     # Don't print the templates
3322     return if $target{template};
3323
3324     my @sequence = (
3325         "sys_id",
3326         "cpp",
3327         "cppflags",
3328         "defines",
3329         "includes",
3330         "cc",
3331         "cflags",
3332         "unistd",
3333         "ld",
3334         "lflags",
3335         "loutflag",
3336         "ex_libs",
3337         "bn_ops",
3338         "padlock_asm_src",
3339         "poly1035_asm_src",
3340         "thread_scheme",
3341         "perlasm_scheme",
3342         "dso_scheme",
3343         "shared_target",
3344         "shared_cflag",
3345         "shared_defines",
3346         "shared_ldflag",
3347         "shared_rcflag",
3348         "shared_extension",
3349         "dso_extension",
3350         "obj_extension",
3351         "exe_extension",
3352         "ranlib",
3353         "ar",
3354         "arflags",
3355         "aroutflag",
3356         "rc",
3357         "rcflags",
3358         "rcoutflag",
3359         "mt",
3360         "mtflags",
3361         "mtinflag",
3362         "mtoutflag",
3363         "multilib",
3364         "build_scheme",
3365         );
3366
3367     if ($type eq "TABLE") {
3368         print "\n";
3369         print "*** $now_printing\n";
3370         foreach (@sequence) {
3371             if (ref($target{$_}) eq "ARRAY") {
3372                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3373             } else {
3374                 printf "\$%-12s = %s\n", $_, $target{$_};
3375             }
3376         }
3377     } elsif ($type eq "HASH") {
3378         my $largest =
3379             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3380         print "    '$now_printing' => {\n";
3381         foreach (@sequence) {
3382             if ($target{$_}) {
3383                 if (ref($target{$_}) eq "ARRAY") {
3384                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3385                 } else {
3386                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3387                 }
3388             }
3389         }
3390         print "    },\n";
3391     }
3392 }
3393
3394 # Utility routines ###################################################
3395
3396 # On VMS, if the given file is a logical name, File::Spec::Functions
3397 # will consider it an absolute path.  There are cases when we want a
3398 # purely syntactic check without checking the environment.
3399 sub isabsolute {
3400     my $file = shift;
3401
3402     # On non-platforms, we just use file_name_is_absolute().
3403     return file_name_is_absolute($file) unless $^O eq "VMS";
3404
3405     # If the file spec includes a device or a directory spec,
3406     # file_name_is_absolute() is perfectly safe.
3407     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3408
3409     # Here, we know the given file spec isn't absolute
3410     return 0;
3411 }
3412
3413 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3414 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3415 # realpath() requires that at least all path components except the last is an
3416 # existing directory.  On VMS, the last component of the directory spec must
3417 # exist.
3418 sub absolutedir {
3419     my $dir = shift;
3420
3421     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3422     # will return the volume name for the device, no matter what.  Also,
3423     # it will return an incorrect directory spec if the argument is a
3424     # directory that doesn't exist.
3425     if ($^O eq "VMS") {
3426         return rel2abs($dir);
3427     }
3428
3429     # We use realpath() on Unix, since no other will properly clean out
3430     # a directory spec.
3431     use Cwd qw/realpath/;
3432
3433     return realpath($dir);
3434 }
3435
3436 sub quotify {
3437     my %processors = (
3438         perl    => sub { my $x = shift;
3439                          $x =~ s/([\\\$\@"])/\\$1/g;
3440                          return '"'.$x.'"'; },
3441         maybeshell => sub { my $x = shift;
3442                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3443                             if ($x ne $y || $x =~ m|\s|) {
3444                                 return '"'.$y.'"';
3445                             } else {
3446                                 return $x;
3447                             }
3448                         },
3449         );
3450     my $for = shift;
3451     my $processor =
3452         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3453
3454     return map { $processor->($_); } @_;
3455 }
3456
3457 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3458 # $filename is a file name to read from
3459 # $line_concat_cond_re is a regexp detecting a line continuation ending
3460 # $line_concat is a CODEref that takes care of concatenating two lines
3461 sub collect_from_file {
3462     my $filename = shift;
3463     my $line_concat_cond_re = shift;
3464     my $line_concat = shift;
3465
3466     open my $fh, $filename || die "unable to read $filename: $!\n";
3467     return sub {
3468         my $saved_line = "";
3469         $_ = "";
3470         while (<$fh>) {
3471             s|\R$||;
3472             if (defined $line_concat) {
3473                 $_ = $line_concat->($saved_line, $_);
3474                 $saved_line = "";
3475             }
3476             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3477                 $saved_line = $_;
3478                 next;
3479             }
3480             return $_;
3481         }
3482         die "$filename ending with continuation line\n" if $_;
3483         close $fh;
3484         return undef;
3485     }
3486 }
3487
3488 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3489 # $array is an ARRAYref of lines
3490 # $line_concat_cond_re is a regexp detecting a line continuation ending
3491 # $line_concat is a CODEref that takes care of concatenating two lines
3492 sub collect_from_array {
3493     my $array = shift;
3494     my $line_concat_cond_re = shift;
3495     my $line_concat = shift;
3496     my @array = (@$array);
3497
3498     return sub {
3499         my $saved_line = "";
3500         $_ = "";
3501         while (defined($_ = shift @array)) {
3502             s|\R$||;
3503             if (defined $line_concat) {
3504                 $_ = $line_concat->($saved_line, $_);
3505                 $saved_line = "";
3506             }
3507             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3508                 $saved_line = $_;
3509                 next;
3510             }
3511             return $_;
3512         }
3513         die "input text ending with continuation line\n" if $_;
3514         return undef;
3515     }
3516 }
3517
3518 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3519 # $lineiterator is a CODEref that delivers one line at a time.
3520 # All following arguments are regex/CODEref pairs, where the regexp detects a
3521 # line and the CODEref does something with the result of the regexp.
3522 sub collect_information {
3523     my $lineiterator = shift;
3524     my %collectors = @_;
3525
3526     while(defined($_ = $lineiterator->())) {
3527         s|\R$||;
3528         my $found = 0;
3529         if ($collectors{"BEFORE"}) {
3530             $collectors{"BEFORE"}->($_);
3531         }
3532         foreach my $re (keys %collectors) {
3533             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3534                 $collectors{$re}->($lineiterator);
3535                 $found = 1;
3536             };
3537         }
3538         if ($collectors{"OTHERWISE"}) {
3539             $collectors{"OTHERWISE"}->($lineiterator, $_)
3540                 unless $found || !defined $collectors{"OTHERWISE"};
3541         }
3542         if ($collectors{"AFTER"}) {
3543             $collectors{"AFTER"}->($_);
3544         }
3545     }
3546 }
3547
3548 # tokenize($line)
3549 # tokenize($line,$separator)
3550 # $line is a line of text to split up into tokens
3551 # $separator [optional] is a regular expression that separates the tokens,
3552 # the default being spaces.  Do not use quotes of any kind as separators,
3553 # that will give undefined results.
3554 # Returns a list of tokens.
3555 #
3556 # Tokens are divided by separator (spaces by default).  If the tokens include
3557 # the separators, they have to be quoted with single or double quotes.
3558 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3559 # with backslash.
3560 # Basically, the same quoting rules apply for " and ' as in any
3561 # Unix shell.
3562 sub tokenize {
3563     my $line = my $debug_line = shift;
3564     my $separator = shift // qr|\s+|;
3565     my @result = ();
3566
3567     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3568         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3569     }
3570
3571     while ($line =~ s|^${separator}||, $line ne "") {
3572         my $token = "";
3573     again:
3574         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3575         $token .= $1;
3576         $line = $2.$';
3577
3578         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3579             $token .= $1;
3580             $line = $';
3581             goto again;
3582         } elsif ($line =~ m/^'([^']*)'/) {
3583             $token .= $1;
3584             $line = $';
3585             goto again;
3586         }
3587         push @result, $token;
3588     }
3589
3590     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3591         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3592         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3593     }
3594     return @result;
3595 }