Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2023 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::fallback "$FindBin::Bin/external/perl/MODULES.txt";
  21 use OpenSSL::Glob;
  22 use OpenSSL::Template;
  23 use OpenSSL::config;
  24
  25 # see INSTALL.md for instructions.
  26
  27 my $orig_death_handler = $SIG{__DIE__};
  28 $SIG{__DIE__} = \&death_handler;
  29
  30 my $usage="Usage: Configure [no-<feature> ...] [enable-<feature> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]thread-pool] [[no-]default-thread-pool] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  31
  32 my $banner = <<"EOF";
  33
  34 **********************************************************************
  35 ***                                                                ***
  36 ***   OpenSSL has been successfully configured                     ***
  37 ***                                                                ***
  38 ***   If you encounter a problem while building, please open an    ***
  39 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
  40 ***   and include the output from the following command:           ***
  41 ***                                                                ***
  42 ***       perl configdata.pm --dump                                ***
  43 ***                                                                ***
  44 ***   (If you are new to OpenSSL, you might want to consult the    ***
  45 ***   'Troubleshooting' section in the INSTALL.md file first)      ***
  46 ***                                                                ***
  47 **********************************************************************
  48 EOF
  49
  50 # Options:
  51 #
  52 # --config      add the given configuration file, which will be read after
  53 #               any "Configurations*" files that are found in the same
  54 #               directory as this script.
  55 # --prefix      prefix for the OpenSSL installation, which includes the
  56 #               directories bin, lib, include, share/man, share/doc/openssl
  57 #               This becomes the value of INSTALLTOP in Makefile
  58 #               (Default: /usr/local)
  59 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  60 #               If it's a relative directory, it will be added on the directory
  61 #               given with --prefix.
  62 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  63 #               (Default: PREFIX/ssl)
  64 # --banner=".." Output specified text instead of default completion banner
  65 #
  66 # -w            Don't wait after showing a Configure warning
  67 #
  68 # --cross-compile-prefix Add specified prefix to binutils components.
  69 #
  70 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0
  71 #               Define the public APIs as they were for that version
  72 #               including patch releases.  If 'no-deprecated' is also
  73 #               given, do not compile support for interfaces deprecated
  74 #               up to and including the specified OpenSSL version.
  75 #
  76 # no-hw-xxx     do not compile support for specific crypto hardware.
  77 #               Generic OpenSSL-style methods relating to this support
  78 #               are always compiled but return NULL if the hardware
  79 #               support isn't compiled.
  80 # no-hw         do not compile support for any crypto hardware.
  81 # [no-]threads  [don't] try to create a library that is suitable for
  82 #               multithreaded applications (default is "threads" if we
  83 #               know how to do it)
  84 # [no-]thread-pool
  85 #               [don't] allow thread pool functionality
  86 # [no-]default-thread-pool
  87 #               [don't] allow default thread pool functionality
  88 # [no-]shared   [don't] try to create shared libraries when supported.
  89 # [no-]pic      [don't] try to build position independent code when supported.
  90 #               If disabled, it also disables shared and dynamic-engine.
  91 # no-asm        do not use assembler
  92 # no-egd        do not compile support for the entropy-gathering daemon APIs
  93 # [no-]zlib     [don't] compile support for zlib compression.
  94 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  95 #               library and will be loaded at run-time by the OpenSSL library.
  96 # sctp          include SCTP support
  97 # no-quic       disable QUIC support
  98 # no-uplink     Don't build support for UPLINK interface.
  99 # enable-weak-ssl-ciphers
 100 #               Enable weak ciphers that are disabled by default.
 101 # 386           generate 80386 code in assembly modules
 102 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
 103 #               mentioned '386' option implies this one
 104 # no-<cipher>   build without specified algorithm (dsa, idea, rc5, ...)
 105 # -<xxx> +<xxx> All options which are unknown to the 'Configure' script are
 106 # /<xxx>        passed through to the compiler. Unix-style options beginning
 107 #               with a '-' or '+' are recognized, as well as Windows-style
 108 #               options beginning with a '/'. If the option contains arguments
 109 #               separated by spaces, then the URL-style notation %20 can be
 110 #               used for the space character in order to avoid having to quote
 111 #               the option. For example, -opt%20arg gets expanded to -opt arg.
 112 #               In fact, any ASCII character can be encoded as %xx using its
 113 #               hexadecimal encoding.
 114 # -static       while -static is also a pass-through compiler option (and
 115 #               as such is limited to environments where it's actually
 116 #               meaningful), it triggers a number configuration options,
 117 #               namely no-pic, no-shared and no-threads. It is
 118 #               argued that the only reason to produce statically linked
 119 #               binaries (and in context it means executables linked with
 120 #               -static flag, and not just executables linked with static
 121 #               libcrypto.a) is to eliminate dependency on specific run-time,
 122 #               a.k.a. libc version. The mentioned config options are meant
 123 #               to achieve just that. Unfortunately on Linux it's impossible
 124 #               to eliminate the dependency completely for openssl executable
 125 #               because of getaddrinfo and gethostbyname calls, which can
 126 #               invoke dynamically loadable library facility anyway to meet
 127 #               the lookup requests. For this reason on Linux statically
 128 #               linked openssl executable has rather debugging value than
 129 #               production quality.
 130 #
 131 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
 132 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
 133 # Following are set automatically by this script
 134 #
 135 # MD5_ASM       use some extra md5 assembler,
 136 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 137 # RMD160_ASM    use some extra ripemd160 assembler,
 138 # SHA256_ASM    sha256_block is implemented in assembler
 139 # SHA512_ASM    sha512_block is implemented in assembler
 140 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 141
 142 # Minimum warning options... any contributions to OpenSSL should at least
 143 # get past these.  Note that we only use these with C compilers, not with
 144 # C++ compilers.
 145
 146 # -DPEDANTIC complements -pedantic and is meant to mask code that
 147 # is not strictly standard-compliant and/or implementation-specific,
 148 # e.g. inline assembly, disregards to alignment requirements, such
 149 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 150 # to be used even in sanitized builds, because sanitizer too is
 151 # supposed to and does take notice of non-standard behaviour. Then
 152 # -pedantic with pre-C9x compiler would also complain about 'long
 153 # long' not being supported. As 64-bit algorithms are common now,
 154 # it grew impossible to resolve this without sizeable additional
 155 # code, so we just tell compiler to be pedantic about everything
 156 # but 'long long' type.
 157
 158 my @gcc_devteam_warn = qw(
 159     -DPEDANTIC -pedantic -Wno-long-long -DUNUSEDRESULT_DEBUG
 160     -Wall
 161     -Wmissing-declarations
 162     -Wextra
 163     -Wno-unused-parameter
 164     -Wno-missing-field-initializers
 165     -Wswitch
 166     -Wsign-compare
 167     -Wshadow
 168     -Wformat
 169     -Wno-type-limits
 170     -Wno-tautological-constant-out-of-range-compare
 171     -Wundef
 172     -Werror
 173     -Wmissing-prototypes
 174     -Wstrict-prototypes
 175 );
 176
 177 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 178 # TODO(openssl-team): fix problems and investigate if (at least) the
 179 # following warnings can also be enabled:
 180 #       -Wcast-align
 181 #       -Wunreachable-code -- no, too ugly/compiler-specific
 182 #       -Wlanguage-extension-token -- no, we use asm()
 183 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 184 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 185 my @clang_devteam_warn = qw(
 186     -Wno-unknown-warning-option
 187     -Wswitch-default
 188     -Wno-parentheses-equality
 189     -Wno-language-extension-token
 190     -Wno-extended-offsetof
 191     -Wno-missing-braces
 192     -Wconditional-uninitialized
 193     -Wincompatible-pointer-types-discards-qualifiers
 194     -Wmissing-variable-declarations
 195 );
 196
 197 my @cl_devteam_warn = qw(
 198     /WX
 199 );
 200
 201 my $strict_warnings = 0;
 202
 203 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 204 # which would cover all BSD flavors. -pthread applies to them all,
 205 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 206 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 207 # which has to be accompanied by explicit -D_THREAD_SAFE and
 208 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 209 # seems to be sufficient?
 210 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 211
 212 #
 213 # API compatibility name to version number mapping.
 214 #
 215 my $apitable = {
 216     # This table expresses when API additions or changes can occur.
 217     # The numbering used changes from 3.0 and on because we updated
 218     # (solidified) our version numbering scheme at that point.
 219
 220     # From 3.0 and on, we internalise the given version number in decimal
 221     # as MAJOR * 10000 + MINOR * 100 + 0
 222     "3.0.0" => 30000,
 223     "3.0"   => 30000,
 224
 225     # Note that before 3.0, we didn't have the same version number scheme.
 226     # Still, the numbering we use here covers what we need.
 227     "1.1.1" => 10101,
 228     "1.1.0" => 10100,
 229     "1.0.2" => 10002,
 230     "1.0.1" => 10001,
 231     "1.0.0" => 10000,
 232     "0.9.8" =>   908,
 233 };
 234
 235 # For OpenSSL::config::get_platform
 236 my %guess_opts = ();
 237
 238 my $dryrun = 0;
 239
 240 our %table = ();
 241 our %config = ();
 242 our %withargs = ();
 243 our $now_printing;      # set to current entry's name in print_table_entry
 244                         # (todo: right thing would be to encapsulate name
 245                         # into %target [class] and make print_table_entry
 246                         # a method)
 247
 248 # Forward declarations ###############################################
 249
 250 # read_config(filename)
 251 #
 252 # Reads a configuration file and populates %table with the contents
 253 # (which the configuration file places in %targets).
 254 sub read_config;
 255
 256 # resolve_config(target)
 257 #
 258 # Resolves all the late evaluations, inheritances and so on for the
 259 # chosen target and any target it inherits from.
 260 sub resolve_config;
 261
 262
 263 # Information collection #############################################
 264
 265 # Unified build supports separate build dir
 266 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 267 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 268
 269 # File::Spec::Unix doesn't detect case insensitivity, so we make sure to
 270 # check if the source and build directory are really the same, and make
 271 # them so.  This avoids all kinds of confusion later on.
 272 # We must check @File::Spec::ISA rather than using File::Spec->isa() to
 273 # know if File::Spec ended up loading File::Spec::Unix.
 274 $srcdir = $blddir
 275     if (grep(/::Unix$/, @File::Spec::ISA)
 276         && samedir($srcdir, $blddir));
 277
 278 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 279
 280 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 281
 282 $config{sourcedir} = abs2rel($srcdir, $blddir);
 283 $config{builddir} = abs2rel($blddir, $blddir);
 284 # echo -n 'holy hand grenade of antioch' | openssl sha256
 285 $config{FIPSKEY} =
 286     'f4556650ac31d35461610bac4ed81b1a181b2d8a43ea2854cbae22ca74560813';
 287
 288 # Collect reconfiguration information if needed
 289 my @argvcopy=@ARGV;
 290
 291 if (grep /^reconf(igure)?$/, @argvcopy) {
 292     die "reconfiguring with other arguments present isn't supported"
 293         if scalar @argvcopy > 1;
 294     if (-f "./configdata.pm") {
 295         my $file = "./configdata.pm";
 296         unless (my $return = do $file) {
 297             die "couldn't parse $file: $@" if $@;
 298             die "couldn't do $file: $!"    unless defined $return;
 299             die "couldn't run $file"       unless $return;
 300         }
 301
 302         @argvcopy = defined($configdata::config{perlargv}) ?
 303             @{$configdata::config{perlargv}} : ();
 304         die "Incorrect data to reconfigure, please do a normal configuration\n"
 305             if (grep(/^reconf/,@argvcopy));
 306         $config{perlenv} = $configdata::config{perlenv} // {};
 307     } else {
 308         die "Insufficient data to reconfigure, please do a normal configuration\n";
 309     }
 310 }
 311
 312 $config{perlargv} = [ @argvcopy ];
 313
 314 # Historical: if known directories in crypto/ have been removed, it means
 315 # that those sub-systems are disabled.
 316 # (the other option would be to removed them from the SUBDIRS statement in
 317 # crypto/build.info)
 318 # We reverse the input list for cosmetic purely reasons, to compensate that
 319 # 'unshift' adds at the front of the list (i.e. in reverse input order).
 320 foreach ( reverse sort( 'aes', 'aria', 'bf', 'camellia', 'cast', 'des', 'dh',
 321                         'dsa', 'ec', 'hmac', 'idea', 'md2', 'md5', 'mdc2',
 322                         'rc2', 'rc4', 'rc5', 'ripemd', 'seed', 'sha',
 323                         'sm2', 'sm3', 'sm4') ) {
 324     unshift @argvcopy, "no-$_" if ! -d catdir($srcdir, 'crypto', $_);
 325 }
 326
 327 # Collect version numbers
 328 my %version = ();
 329
 330 collect_information(
 331     collect_from_file(catfile($srcdir,'VERSION.dat')),
 332     qr/\s*(\w+)\s*=\s*(.*?)\s*$/ =>
 333         sub {
 334             # Only define it if there is a value at all
 335             if ($2 ne '') {
 336                 my $k = $1;
 337                 my $v = $2;
 338                 # Some values are quoted.  Trim the quotes
 339                 $v = $1 if $v =~ /^"(.*)"$/;
 340                 $version{uc $k} = $v;
 341             }
 342         },
 343     "OTHERWISE" =>
 344         sub { die "Something wrong with this line:\n$_\nin $srcdir/VERSION.dat" },
 345     );
 346
 347 $config{major} = $version{MAJOR} // 'unknown';
 348 $config{minor} = $version{MINOR} // 'unknown';
 349 $config{patch} = $version{PATCH} // 'unknown';
 350 $config{prerelease} =
 351     defined $version{PRE_RELEASE_TAG} ? "-$version{PRE_RELEASE_TAG}" : '';
 352 $config{build_metadata} =
 353     defined $version{BUILD_METADATA} ? "+$version{BUILD_METADATA}" : '';
 354 $config{shlib_version} = $version{SHLIB_VERSION} // 'unknown';
 355 $config{release_date} = $version{RELEASE_DATE} // 'xx XXX xxxx';
 356
 357 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 358 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 359
 360 die "erroneous version information in VERSION.dat: ",
 361     "$config{version}, $config{shlib_version}\n"
 362     unless (defined $version{MAJOR}
 363             && defined $version{MINOR}
 364             && defined $version{PATCH}
 365             && defined $version{SHLIB_VERSION});
 366
 367 # Collect target configurations
 368
 369 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 370 foreach (sort glob($pattern)) {
 371     &read_config($_);
 372 }
 373
 374 if (defined env($local_config_envname)) {
 375     if ($^O eq 'VMS') {
 376         # VMS environment variables are logical names,
 377         # which can be used as is
 378         $pattern = $local_config_envname . ':' . '*.conf';
 379     } else {
 380         $pattern = catfile(env($local_config_envname), '*.conf');
 381     }
 382
 383     foreach (sort glob($pattern)) {
 384         &read_config($_);
 385     }
 386 }
 387
 388 # Save away perl command information
 389 $config{perl_cmd} = $^X;
 390 $config{perl_version} = $Config{version};
 391 $config{perl_archname} = $Config{archname};
 392
 393 $config{prefix}="";
 394 $config{openssldir}="";
 395 $config{processor}="";
 396 $config{libdir}="";
 397 my $auto_threads=1;    # enable threads automatically? true by default
 398 my $default_ranlib;
 399
 400 # Known TLS and DTLS protocols
 401 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 402 my @dtls = qw(dtls1 dtls1_2);
 403
 404 # Explicitly known options that are possible to disable.  They can
 405 # be regexps, and will be used like this: /^no-${option}$/
 406 # For developers: keep it sorted alphabetically
 407
 408 my @disablables = (
 409     "acvp-tests",
 410     "afalgeng",
 411     "apps",
 412     "argon2",
 413     "aria",
 414     "asan",
 415     "asm",
 416     "async",
 417     "autoalginit",
 418     "autoerrinit",
 419     "autoload-config",
 420     "bf",
 421     "blake2",
 422     "brotli",
 423     "brotli-dynamic",
 424     "buildtest-c++",
 425     "bulk",
 426     "cached-fetch",
 427     "camellia",
 428     "capieng",
 429     "winstore",
 430     "cast",
 431     "chacha",
 432     "cmac",
 433     "cmp",
 434     "cms",
 435     "comp",
 436     "crypto-mdebug",
 437     "ct",
 438     "default-thread-pool",
 439     "deprecated",
 440     "des",
 441     "devcryptoeng",
 442     "dgram",
 443     "dh",
 444     "docs",
 445     "dsa",
 446     "dso",
 447     "dtls",
 448     "dynamic-engine",
 449     "ec",
 450     "ec2m",
 451     "ec_nistp_64_gcc_128",
 452     "ecdh",
 453     "ecdsa",
 454     "ecx",
 455     "egd",
 456     "engine",
 457     "err",
 458     "external-tests",
 459     "filenames",
 460     "fips",
 461     "fips-securitychecks",
 462     "fuzz-afl",
 463     "fuzz-libfuzzer",
 464     "gost",
 465     "http",
 466     "idea",
 467     "ktls",
 468     "legacy",
 469     "loadereng",
 470     "makedepend",
 471     "md2",
 472     "md4",
 473     "mdc2",
 474     "module",
 475     "msan",
 476     "multiblock",
 477     "nextprotoneg",
 478     "ocb",
 479     "ocsp",
 480     "padlockeng",
 481     "pic",
 482     "pinshared",
 483     "poly1305",
 484     "posix-io",
 485     "psk",
 486     "quic",
 487     "rc2",
 488     "rc4",
 489     "rc5",
 490     "rdrand",
 491     "rfc3779",
 492     "rmd160",
 493     "scrypt",
 494     "sctp",
 495     "secure-memory",
 496     "seed",
 497     "shared",
 498     "siphash",
 499     "siv",
 500     "sm2",
 501     "sm2-precomp",
 502     "sm3",
 503     "sm4",
 504     "sock",
 505     "srp",
 506     "srtp",
 507     "sse2",
 508     "ssl",
 509     "ssl-trace",
 510     "static-engine",
 511     "stdio",
 512     "tests",
 513     "tfo",
 514     "thread-pool",
 515     "threads",
 516     "tls",
 517     "trace",
 518     "ts",
 519     "ubsan",
 520     "ui-console",
 521     "unit-test",
 522     "uplink",
 523     "weak-ssl-ciphers",
 524     "whirlpool",
 525     "zlib",
 526     "zlib-dynamic",
 527     "zstd",
 528     "zstd-dynamic",
 529     );
 530 foreach my $proto ((@tls, @dtls))
 531         {
 532         push(@disablables, $proto);
 533         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 534         }
 535
 536 # Internal disablables, for aliasing purposes.  They serve no special
 537 # purpose here, but allow scripts to get to know them through configdata.pm,
 538 # where these are merged with @disablables.
 539 # The actual aliasing mechanism is done via %disable_cascades
 540 my @disablables_int = qw(
 541     crmf
 542     );
 543
 544 my %deprecated_disablables = (
 545     "ssl2" => undef,
 546     "buf-freelists" => undef,
 547     "crypto-mdebug-backtrace" => undef,
 548     "hw" => "hw",               # causes cascade, but no macro
 549     "hw-padlock" => "padlockeng",
 550     "ripemd" => "rmd160",
 551     "ui" => "ui-console",
 552     "heartbeats" => undef,
 553     );
 554
 555 # All of the following are disabled by default:
 556
 557 our %disabled = ( # "what"         => "comment"
 558                   "fips"                => "default",
 559                   "asan"                => "default",
 560                   "brotli"              => "default",
 561                   "brotli-dynamic"      => "default",
 562                   "buildtest-c++"       => "default",
 563                   "crypto-mdebug"       => "default",
 564                   "crypto-mdebug-backtrace" => "default",
 565                   "devcryptoeng"        => "default",
 566                   "ec_nistp_64_gcc_128" => "default",
 567                   "egd"                 => "default",
 568                   "external-tests"      => "default",
 569                   "fuzz-afl"            => "default",
 570                   "fuzz-libfuzzer"      => "default",
 571                   "ktls"                => "default",
 572                   "md2"                 => "default",
 573                   "msan"                => "default",
 574                   "rc5"                 => "default",
 575                   "sctp"                => "default",
 576                   "ssl3"                => "default",
 577                   "ssl3-method"         => "default",
 578                   "tfo"                 => "default",
 579                   "trace"               => "default",
 580                   "ubsan"               => "default",
 581                   "unit-test"           => "default",
 582                   "weak-ssl-ciphers"    => "default",
 583                   "zlib"                => "default",
 584                   "zlib-dynamic"        => "default",
 585                   "zstd"                => "default",
 586                   "zstd-dynamic"        => "default",
 587                 );
 588
 589 # Note: => pair form used for aesthetics, not to truly make a hash table
 590 my @disable_cascades = (
 591     # "what"            => [ "cascade", ... ]
 592     "bulk"              => [ "shared", "dso",
 593                              "aria", "async", "autoload-config",
 594                              "blake2", "bf", "camellia", "cast", "chacha",
 595                              "cmac", "cms", "cmp", "comp", "ct",
 596                              "des", "dgram", "dh", "dsa",
 597                              "ec", "engine",
 598                              "filenames",
 599                              "idea", "ktls",
 600                              "md4", "multiblock", "nextprotoneg",
 601                              "ocsp", "ocb", "poly1305", "psk",
 602                              "rc2", "rc4", "rmd160",
 603                              "seed", "siphash", "siv",
 604                              "sm3", "sm4", "srp",
 605                              "srtp", "ssl3-method", "ssl-trace",
 606                              "tfo",
 607                              "ts", "ui-console", "whirlpool",
 608                              "fips-securitychecks" ],
 609     sub { $config{processor} eq "386" }
 610                         => [ "sse2" ],
 611     "ssl"               => [ "ssl3" ],
 612     "ssl3-method"       => [ "ssl3" ],
 613     "zlib"              => [ "zlib-dynamic" ],
 614     "brotli"            => [ "brotli-dynamic" ],
 615     "zstd"              => [ "zstd-dynamic" ],
 616     "des"               => [ "mdc2" ],
 617     "ec"                => [ "ec2m", "ecdsa", "ecdh", "sm2", "gost", "ecx" ],
 618     "dgram"             => [ "dtls", "quic", "sctp" ],
 619     "sock"              => [ "dgram", "tfo" ],
 620     "dtls"              => [ @dtls ],
 621     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 622                         => [ "dtls" ],
 623
 624     "tls"               => [ @tls ],
 625     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 626                         => [ "tls" ],
 627     "tls1_3"            => [ "quic" ],
 628
 629     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 630
 631     "module"            => [ "dynamic-engine", "fips" ],
 632
 633     # Without shared libraries, dynamic engines aren't possible.
 634     # This is due to them having to link with libcrypto and register features
 635     # using the ENGINE functionality, and since that relies on global tables,
 636     # those *have* to be exactly the same as the ones accessed from the app,
 637     # which cannot be guaranteed if shared libraries aren't present.
 638     # (note that even with shared libraries, both the app and dynamic engines
 639     # must be linked with the same library)
 640     "shared"            => [ "dynamic-engine", "uplink" ],
 641     "dso"               => [ "dynamic-engine", "module" ],
 642     # Other modules don't necessarily have to link with libcrypto, so shared
 643     # libraries do not have to be a condition to produce those.
 644
 645     # Without position independent code, there can be no shared libraries
 646     # or modules.
 647     "pic"               => [ "shared", "module" ],
 648
 649     "engine"            => [ "dynamic-engine", grep(/eng$/, @disablables) ],
 650     "dynamic-engine"    => [ "loadereng" ],
 651     "hw"                => [ "padlockeng" ],
 652
 653     # no-autoalginit is only useful when building non-shared
 654     "autoalginit"       => [ "shared", "apps", "fips" ],
 655
 656     "stdio"             => [ "apps", "capieng", "egd" ],
 657     "apps"              => [ "tests" ],
 658     "tests"             => [ "external-tests" ],
 659     "comp"              => [ "zlib", "brotli", "zstd" ],
 660     "sm3"               => [ "sm2" ],
 661     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 662
 663     sub { !$disabled{"msan"} } => [ "asm" ],
 664
 665     "cmac"              => [ "siv" ],
 666     "legacy"            => [ "md2" ],
 667
 668     "cmp"               => [ "crmf" ],
 669
 670     "fips"              => [ "fips-securitychecks", "acvp-tests" ],
 671
 672     "threads"           => [ "thread-pool" ],
 673     "thread-pool"       => [ "default-thread-pool" ],
 674
 675     "blake2"            => [ "argon2" ],
 676
 677     "deprecated-3.0"    => [ "engine", "srp" ],
 678
 679     "http"              => [ "ocsp" ]
 680     );
 681
 682 # Avoid protocol support holes.  Also disable all versions below N, if version
 683 # N is disabled while N+1 is enabled.
 684 #
 685 my @list = (reverse @tls);
 686 while ((my $first, my $second) = (shift @list, shift @list)) {
 687     last unless @list;
 688     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 689                               => [ @list ] );
 690     unshift @list, $second;
 691 }
 692 my @list = (reverse @dtls);
 693 while ((my $first, my $second) = (shift @list, shift @list)) {
 694     last unless @list;
 695     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 696                               => [ @list ] );
 697     unshift @list, $second;
 698 }
 699
 700 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 701 # To remove something from %disabled, use "enable-foo".
 702 # For symmetry, "disable-foo" is a synonym for "no-foo".
 703
 704 # For the "make variables" CPPINCLUDES and CPPDEFINES, we support lists with
 705 # platform specific list separators.  Users from those platforms should
 706 # recognise those separators from how you set up the PATH to find executables.
 707 # The default is the Unix like separator, :, but as an exception, we also
 708 # support the space as separator.
 709 my $list_separator_re =
 710     { VMS           => qr/(?<!\^),/,
 711       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 712 # All the "make variables" we support
 713 # Some get pre-populated for the sake of backward compatibility
 714 # (we supported those before the change to "make variable" support.
 715 my %user = (
 716     AR          => env('AR'),
 717     ARFLAGS     => [],
 718     AS          => undef,
 719     ASFLAGS     => [],
 720     CC          => env('CC'),
 721     CFLAGS      => [ env('CFLAGS') || () ],
 722     CXX         => env('CXX'),
 723     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 724     CPP         => undef,
 725     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 726     CPPDEFINES  => [],  # Alternative for -D
 727     CPPINCLUDES => [],  # Alternative for -I
 728     CROSS_COMPILE => env('CROSS_COMPILE'),
 729     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 730     LD          => undef,
 731     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 732     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 733     MT          => undef,
 734     MTFLAGS     => [],
 735     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 736     RANLIB      => env('RANLIB'),
 737     RC          => env('RC') || env('WINDRES'),
 738     RCFLAGS     => [ env('RCFLAGS') || () ],
 739     RM          => undef,
 740    );
 741 # Info about what "make variables" may be prefixed with the cross compiler
 742 # prefix.  This should NEVER mention any such variable with a list for value.
 743 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 744 # The same but for flags given as Configure options.  These are *additional*
 745 # input, as opposed to the VAR=string option that override the corresponding
 746 # config target attributes
 747 my %useradd = (
 748     ASFLAGS     => [],
 749     CPPDEFINES  => [],
 750     CPPINCLUDES => [],
 751     CPPFLAGS    => [],
 752     CFLAGS      => [],
 753     CXXFLAGS    => [],
 754     LDFLAGS     => [],
 755     LDLIBS      => [],
 756     RCFLAGS     => [],
 757    );
 758
 759 my %user_synonyms = (
 760     HASHBANGPERL=> 'PERL',
 761     RC          => 'WINDRES',
 762    );
 763
 764 # Some target attributes have been renamed, this is the translation table
 765 my %target_attr_translate =(
 766     ar          => 'AR',
 767     as          => 'AS',
 768     cc          => 'CC',
 769     cxx         => 'CXX',
 770     cpp         => 'CPP',
 771     hashbangperl => 'HASHBANGPERL',
 772     ld          => 'LD',
 773     mt          => 'MT',
 774     ranlib      => 'RANLIB',
 775     rc          => 'RC',
 776     rm          => 'RM',
 777    );
 778
 779 # Initialisers coming from 'config' scripts
 780 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 781 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 782 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 783 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 784 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 785 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 786 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 787
 788 $config{openssl_api_defines}=[];
 789 $config{openssl_sys_defines}=[];
 790 $config{openssl_feature_defines}=[];
 791 $config{options}="";
 792 $config{build_type} = "release";
 793 my $target="";
 794
 795 my %cmdvars = ();               # Stores FOO='blah' type arguments
 796 my %unsupported_options = ();
 797 my %deprecated_options = ();
 798 # If you change this, update apps/version.c
 799 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 800 my @seed_sources = ();
 801 while (@argvcopy)
 802         {
 803         $_ = shift @argvcopy;
 804
 805         # Support env variable assignments among the options
 806         if (m|^(\w+)=(.+)?$|)
 807                 {
 808                 $cmdvars{$1} = $2;
 809                 # Every time a variable is given as a configuration argument,
 810                 # it acts as a reset if the variable.
 811                 if (exists $user{$1})
 812                         {
 813                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 814                         }
 815                 #if (exists $useradd{$1})
 816                 #       {
 817                 #       $useradd{$1} = [];
 818                 #       }
 819                 next;
 820                 }
 821
 822         # VMS is a case insensitive environment, and depending on settings
 823         # out of our control, we may receive options uppercased.  Let's
 824         # downcase at least the part before any equal sign.
 825         if ($^O eq "VMS")
 826                 {
 827                 s/^([^=]*)/lc($1)/e;
 828                 }
 829
 830         # some people just can't read the instructions, clang people have to...
 831         s/^-no-(?!integrated-as)/no-/;
 832
 833         # rewrite some options in "enable-..." form
 834         s /^-?-?shared$/enable-shared/;
 835         s /^sctp$/enable-sctp/;
 836         s /^threads$/enable-threads/;
 837         s /^zlib$/enable-zlib/;
 838         s /^zlib-dynamic$/enable-zlib-dynamic/;
 839         s /^fips$/enable-fips/;
 840
 841         if (/^(no|disable|enable)-(.+)$/)
 842                 {
 843                 my $word = $2;
 844                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 845                         && !exists $deprecated_disablables{$word}
 846                         && !grep { $word eq $_ } @disablables)
 847                         {
 848                         $unsupported_options{$_} = 1;
 849                         next;
 850                         }
 851                 }
 852         if (/^no-(.+)$/ || /^disable-(.+)$/)
 853                 {
 854                 foreach my $proto ((@tls, @dtls))
 855                         {
 856                         if ($1 eq "$proto-method")
 857                                 {
 858                                 $disabled{"$proto"} = "option($proto-method)";
 859                                 last;
 860                                 }
 861                         }
 862                 if ($1 eq "dtls")
 863                         {
 864                         foreach my $proto (@dtls)
 865                                 {
 866                                 $disabled{$proto} = "option(dtls)";
 867                                 }
 868                         $disabled{"dtls"} = "option(dtls)";
 869                         }
 870                 elsif ($1 eq "ssl")
 871                         {
 872                         # Last one of its kind
 873                         $disabled{"ssl3"} = "option(ssl)";
 874                         }
 875                 elsif ($1 eq "tls")
 876                         {
 877                         # XXX: Tests will fail if all SSL/TLS
 878                         # protocols are disabled.
 879                         foreach my $proto (@tls)
 880                                 {
 881                                 $disabled{$proto} = "option(tls)";
 882                                 }
 883                         }
 884                 elsif ($1 eq "static-engine")
 885                         {
 886                         delete $disabled{"dynamic-engine"};
 887                         }
 888                 elsif ($1 eq "dynamic-engine")
 889                         {
 890                         $disabled{"dynamic-engine"} = "option";
 891                         }
 892                 elsif (exists $deprecated_disablables{$1})
 893                         {
 894                         $deprecated_options{$_} = 1;
 895                         if (defined $deprecated_disablables{$1})
 896                                 {
 897                                 $disabled{$deprecated_disablables{$1}} = "option";
 898                                 }
 899                         }
 900                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 901                         {
 902                         $deprecated_options{$_} = 1;
 903                         }
 904                 else
 905                         {
 906                         $disabled{$1} = "option";
 907                         }
 908                 # No longer an automatic choice
 909                 $auto_threads = 0 if ($1 eq "threads");
 910                 }
 911         elsif (/^enable-(.+)$/)
 912                 {
 913                 if ($1 eq "static-engine")
 914                         {
 915                         $disabled{"dynamic-engine"} = "option";
 916                         }
 917                 elsif ($1 eq "dynamic-engine")
 918                         {
 919                         delete $disabled{"dynamic-engine"};
 920                         }
 921                 elsif ($1 eq "zlib-dynamic")
 922                         {
 923                         delete $disabled{"zlib"};
 924                         }
 925                 elsif ($1 eq "brotli-dynamic")
 926                         {
 927                         delete $disabled{"brotli"};
 928                         }
 929                 elsif ($1 eq "zstd-dynamic")
 930                         {
 931                         delete $disabled{"zstd"};
 932                         }
 933                 my $algo = $1;
 934                 delete $disabled{$algo};
 935
 936                 # No longer an automatic choice
 937                 $auto_threads = 0 if ($1 eq "threads");
 938                 }
 939         elsif (/^-d$/)          # From older 'config'
 940                 {
 941                 $config{build_type} = "debug";
 942                 }
 943         elsif (/^-v$/)          # From older 'config'
 944                 {
 945                 $guess_opts{verbose} = 1;
 946                 }
 947         elsif (/^-w$/)
 948                 {
 949                 $guess_opts{nowait} = 1;
 950                 }
 951         elsif (/^-t$/)          # From older 'config'
 952                 {
 953                 $dryrun = 1;
 954                 }
 955         elsif (/^--strict-warnings$/)
 956                 {
 957                 # Pretend that our strict flags is a C flag, and replace it
 958                 # with the proper flags later on
 959                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 960                 $strict_warnings=1;
 961                 }
 962         elsif (/^--debug$/)
 963                 {
 964                 $config{build_type} = "debug";
 965                 }
 966         elsif (/^--release$/)
 967                 {
 968                 $config{build_type} = "release";
 969                 }
 970         elsif (/^386$/)
 971                 { $config{processor}=386; }
 972         elsif (/^rsaref$/)
 973                 {
 974                 # No RSAref support any more since it's not needed.
 975                 # The check for the option is there so scripts aren't
 976                 # broken
 977                 }
 978         elsif (m|^[-+/]|)
 979                 {
 980                 if (/^--prefix=(.*)$/)
 981                         {
 982                         $config{prefix}=$1;
 983                         }
 984                 elsif (/^--api=(.*)$/)
 985                         {
 986                         my $api = $1;
 987                         die "Unknown API compatibility level $api"
 988                                 unless defined $apitable->{$api};
 989                         $config{api}=$apitable->{$api};
 990                         }
 991                 elsif (/^--libdir=(.*)$/)
 992                         {
 993                         $config{libdir}=$1;
 994                         }
 995                 elsif (/^--openssldir=(.*)$/)
 996                         {
 997                         $config{openssldir}=$1;
 998                         }
 999                 elsif (/^--with-zlib-lib=(.*)$/)
1000                         {
1001                         $withargs{zlib_lib}=$1;
1002                         }
1003                 elsif (/^--with-zlib-include=(.*)$/)
1004                         {
1005                         $withargs{zlib_include}=$1;
1006                         }
1007                 elsif (/^--with-brotli-lib=(.*)$/)
1008                         {
1009                         $withargs{brotli_lib}=$1;
1010                         }
1011                 elsif (/^--with-brotli-include=(.*)$/)
1012                         {
1013                         $withargs{brotli_include}=$1;
1014                         }
1015                 elsif (/^--with-zstd-lib=(.*)$/)
1016                         {
1017                         $withargs{zstd_lib}=$1;
1018                         }
1019                 elsif (/^--with-zstd-include=(.*)$/)
1020                         {
1021                         $withargs{zstd_include}=$1;
1022                         }
1023                 elsif (/^--with-fuzzer-lib=(.*)$/)
1024                         {
1025                         $withargs{fuzzer_lib}=$1;
1026                         }
1027                 elsif (/^--with-fuzzer-include=(.*)$/)
1028                         {
1029                         $withargs{fuzzer_include}=$1;
1030                         }
1031                 elsif (/^--with-rand-seed=(.*)$/)
1032                         {
1033                         foreach my $x (split(m|,|, $1))
1034                             {
1035                             die "Unknown --with-rand-seed choice $x\n"
1036                                 if ! grep { $x eq $_ } @known_seed_sources;
1037                             push @seed_sources, $x;
1038                             }
1039                         }
1040                 elsif (/^--fips-key=(.*)$/)
1041                         {
1042                         $user{FIPSKEY}=lc($1);
1043                         die "Non-hex character in FIPS key\n"
1044                            if $user{FIPSKEY} =~ /[^a-f0-9]/;
1045                         die "FIPS key must have even number of characters\n"
1046                            if length $1 & 1;
1047                         die "FIPS key too long (64 bytes max)\n"
1048                            if length $1 > 64;
1049                         }
1050                 elsif (/^--banner=(.*)$/)
1051                         {
1052                         $banner = $1 . "\n";
1053                         }
1054                 elsif (/^--cross-compile-prefix=(.*)$/)
1055                         {
1056                         $user{CROSS_COMPILE}=$1;
1057                         }
1058                 elsif (/^--config=(.*)$/)
1059                         {
1060                         read_config $1;
1061                         }
1062                 elsif (/^-l(.*)$/)
1063                         {
1064                         push @{$useradd{LDLIBS}}, $_;
1065                         }
1066                 elsif (/^-framework$/)
1067                         {
1068                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
1069                         }
1070                 elsif (/^-L(.*)$/ or /^-Wl,/)
1071                         {
1072                         push @{$useradd{LDFLAGS}}, $_;
1073                         }
1074                 elsif (/^-rpath$/ or /^-R$/)
1075                         # -rpath is the OSF1 rpath flag
1076                         # -R is the old Solaris rpath flag
1077                         {
1078                         my $rpath = shift(@argvcopy) || "";
1079                         $rpath .= " " if $rpath ne "";
1080                         push @{$useradd{LDFLAGS}}, $_, $rpath;
1081                         }
1082                 elsif (/^-static$/)
1083                         {
1084                         push @{$useradd{LDFLAGS}}, $_;
1085                         }
1086                 elsif (m|^[-/]D(.*)$|)
1087                         {
1088                         push @{$useradd{CPPDEFINES}}, $1;
1089                         }
1090                 elsif (m|^[-/]I(.*)$|)
1091                         {
1092                         push @{$useradd{CPPINCLUDES}}, $1;
1093                         }
1094                 elsif (/^-Wp,$/)
1095                         {
1096                         push @{$useradd{CPPFLAGS}}, $1;
1097                         }
1098                 else    # common if (/^[-+]/), just pass down...
1099                         {
1100                         # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
1101                         # This provides a simple way to pass options with arguments separated
1102                         # by spaces without quoting (e.g. -opt%20arg translates to -opt arg).
1103                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
1104                         push @{$useradd{CFLAGS}}, $_;
1105                         push @{$useradd{CXXFLAGS}}, $_;
1106                         }
1107                 }
1108         elsif (m|^/|)
1109                 {
1110                 # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
1111                 # This provides a simple way to pass options with arguments separated
1112                 # by spaces without quoting (e.g. /opt%20arg translates to /opt arg).
1113                 $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
1114                 push @{$useradd{CFLAGS}}, $_;
1115                 push @{$useradd{CXXFLAGS}}, $_;
1116                 }
1117         else
1118                 {
1119                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
1120                 $target=$_;
1121                 }
1122         unless ($_ eq $target || /^no-/ || /^disable-/)
1123                 {
1124                 # "no-..." follows later after implied deactivations
1125                 # have been derived.  (Don't take this too seriously,
1126                 # we really only write OPTIONS to the Makefile out of
1127                 # nostalgia.)
1128
1129                 if ($config{options} eq "")
1130                         { $config{options} = $_; }
1131                 else
1132                         { $config{options} .= " ".$_; }
1133                 }
1134         }
1135
1136 if (keys %deprecated_options)
1137         {
1138         warn "***** Deprecated options: ",
1139                 join(", ", keys %deprecated_options), "\n";
1140         }
1141 if (keys %unsupported_options)
1142         {
1143         die "***** Unsupported options: ",
1144                 join(", ", keys %unsupported_options), "\n";
1145         }
1146
1147 # If any %useradd entry has been set, we must check that the "make
1148 # variables" haven't been set.  We start by checking of any %useradd entry
1149 # is set.
1150 if (grep { scalar @$_ > 0 } values %useradd) {
1151     # Hash of env / make variables names.  The possible values are:
1152     # 1 - "make vars"
1153     # 2 - %useradd entry set
1154     # 3 - both set
1155     my %detected_vars =
1156         map { my $v = 0;
1157               $v += 1 if $cmdvars{$_};
1158               $v += 2 if @{$useradd{$_}};
1159               $_ => $v }
1160         keys %useradd;
1161
1162     # If any of the corresponding "make variables" is set, we error
1163     if (grep { $_ & 1 } values %detected_vars) {
1164         my $names = join(', ', grep { $detected_vars{$_} > 0 }
1165                                sort keys %detected_vars);
1166         die <<"_____";
1167 ***** Mixing make variables and additional compiler/linker flags as
1168 ***** configure command line option is not permitted.
1169 ***** Affected make variables: $names
1170 _____
1171     }
1172 }
1173
1174 # Check through all supported command line variables to see if any of them
1175 # were set, and canonicalise the values we got.  If no compiler or linker
1176 # flag or anything else that affects %useradd was set, we also check the
1177 # environment for values.
1178 my $anyuseradd =
1179     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
1180 foreach (keys %user) {
1181     my $value = $cmdvars{$_};
1182     $value //= env($_) unless $anyuseradd;
1183     $value //=
1184         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
1185     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
1186         unless $anyuseradd;
1187
1188     if (defined $value) {
1189         if (ref $user{$_} eq 'ARRAY') {
1190             if ($_ eq 'CPPDEFINES' || $_ eq 'CPPINCLUDES') {
1191                 $user{$_} = [ split /$list_separator_re/, $value ];
1192             } else {
1193                 $user{$_} = [ $value ];
1194             }
1195         } elsif (!defined $user{$_}) {
1196             $user{$_} = $value;
1197         }
1198     }
1199 }
1200
1201 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1202     && !$disabled{shared}
1203     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1204     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1205         "***** any of asan, msan or ubsan\n";
1206 }
1207
1208 # If no target was given, try guessing.
1209 unless ($target) {
1210     my %system_config = OpenSSL::config::get_platform(%guess_opts, %user);
1211
1212     # The $system_config{disable} is used to populate %disabled with
1213     # entries that aren't already there.
1214     foreach ( @{$system_config{disable} // []} ) {
1215         $disabled{$_} = 'system' unless defined $disabled{$_};
1216     }
1217     delete $system_config{disable};
1218
1219     # Override config entries with stuff from the guesser.
1220     # It's assumed that this really is nothing new.
1221     %config = ( %config, %system_config );
1222     $target = $system_config{target};
1223 }
1224
1225 sub disable {
1226     my $disable_type = shift;
1227
1228     for (@_) {
1229         $disabled{$_} = $disable_type;
1230     }
1231
1232     my @tocheckfor = (@_ ? @_ : keys %disabled);
1233     while (@tocheckfor) {
1234         my %new_tocheckfor = ();
1235         my @cascade_copy = (@disable_cascades);
1236         while (@cascade_copy) {
1237             my ($test, $descendents) =
1238                 (shift @cascade_copy, shift @cascade_copy);
1239             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1240                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1241                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1242                 }
1243             }
1244         }
1245         @tocheckfor = (keys %new_tocheckfor);
1246     }
1247 }
1248 disable();                     # First cascade run
1249
1250 our $die = sub { die @_; };
1251 if ($target eq "TABLE") {
1252     local $die = sub { warn @_; };
1253     foreach (sort keys %table) {
1254         print_table_entry($_, "TABLE");
1255     }
1256     exit 0;
1257 }
1258
1259 if ($target eq "LIST") {
1260     foreach (sort keys %table) {
1261         print $_,"\n" unless $table{$_}->{template};
1262     }
1263     exit 0;
1264 }
1265
1266 if ($target eq "HASH") {
1267     local $die = sub { warn @_; };
1268     print "%table = (\n";
1269     foreach (sort keys %table) {
1270         print_table_entry($_, "HASH");
1271     }
1272     exit 0;
1273 }
1274
1275 print "Configuring OpenSSL version $config{full_version} ";
1276 print "for target $target\n";
1277
1278 if (scalar(@seed_sources) == 0) {
1279     print "Using os-specific seed configuration\n";
1280     push @seed_sources, 'os';
1281 }
1282 if (scalar(grep { $_ eq 'egd' } @seed_sources) > 0) {
1283     delete $disabled{'egd'};
1284 }
1285 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1286     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1287     warn <<_____ if scalar(@seed_sources) == 1;
1288
1289 ============================== WARNING ===============================
1290 You have selected the --with-rand-seed=none option, which effectively
1291 disables automatic reseeding of the OpenSSL random generator.
1292 All operations depending on the random generator such as creating keys
1293 will not work unless the random generator is seeded manually by the
1294 application.
1295
1296 Please read the 'Note on random number generation' section in the
1297 INSTALL.md instructions and the RAND_DRBG(7) manual page for more
1298 details.
1299 ============================== WARNING ===============================
1300
1301 _____
1302 }
1303 push @{$config{openssl_feature_defines}},
1304      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1305         @seed_sources;
1306
1307 # Backward compatibility?
1308 if ($target =~ m/^CygWin32(-.*)$/) {
1309     $target = "Cygwin".$1;
1310 }
1311
1312 # Support for legacy targets having a name starting with 'debug-'
1313 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1314 if ($d) {
1315     $config{build_type} = "debug";
1316
1317     # If we do not find debug-foo in the table, the target is set to foo.
1318     if (!$table{$target}) {
1319         $target = $t;
1320     }
1321 }
1322
1323 if ($target) {
1324     # It's possible that we have different config targets for specific
1325     # toolchains, so we try to detect them, and go for the plain config
1326     # target if not.
1327     my $found;
1328     foreach ( ( "$target-$user{CC}", "$target", undef ) ) {
1329         $found=$_ if $table{$_} && !$table{$_}->{template};
1330         last if $found;
1331     }
1332     $target = $found;
1333 } else {
1334     # If we don't have a config target now, we try the C compiler as we
1335     # fallback
1336     my $cc = $user{CC} // 'cc';
1337     $target = $cc if $table{$cc} && !$table{$cc}->{template};
1338 }
1339
1340 &usage unless $target;
1341
1342 exit 0 if $dryrun;              # From older 'config'
1343
1344 $config{target} = $target;
1345 my %target = resolve_config($target);
1346
1347 foreach (keys %target_attr_translate) {
1348     $target{$target_attr_translate{$_}} = $target{$_}
1349         if $target{$_};
1350     delete $target{$_};
1351 }
1352
1353 %target = ( %{$table{DEFAULTS}}, %target );
1354
1355 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1356 $config{conf_files} = [ sort keys %conf_files ];
1357
1358 # Using sub disable within these loops may prove fragile, so we run
1359 # a cascade afterwards
1360 foreach my $feature (@{$target{disable}}) {
1361     if (exists $deprecated_disablables{$feature}) {
1362         warn "***** config $target disables deprecated feature $feature\n";
1363     } elsif (!grep { $feature eq $_ } @disablables) {
1364         die "***** config $target disables unknown feature $feature\n";
1365     }
1366     $disabled{$feature} = 'config';
1367 }
1368 foreach my $feature (@{$target{enable}}) {
1369     if ("default" eq ($disabled{$feature} // "")) {
1370         if (exists $deprecated_disablables{$feature}) {
1371             warn "***** config $target enables deprecated feature $feature\n";
1372         } elsif (!grep { $feature eq $_ } @disablables) {
1373             die "***** config $target enables unknown feature $feature\n";
1374         }
1375         delete $disabled{$feature};
1376     }
1377 }
1378
1379 # If uplink_arch isn't defined, disable uplink
1380 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1381 # If asm_arch isn't defined, disable asm
1382 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1383
1384 disable();                      # Run a cascade now
1385
1386 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1387 $target{cxxflags}//=$target{cflags} if $target{CXX};
1388 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1389 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1390
1391 # Fill %config with values from %user, and in case those are undefined or
1392 # empty, use values from %target (acting as a default).
1393 foreach (keys %user) {
1394     my $ref_type = ref $user{$_};
1395
1396     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1397     # and a value that's to be coerced into that type.
1398     my $mkvalue = sub {
1399         my $type = shift;
1400         my $value = shift;
1401         my $undef_p = shift;
1402
1403         die "Too many arguments for \$mkvalue" if @_;
1404
1405         while (ref $value eq 'CODE') {
1406             $value = $value->();
1407         }
1408
1409         if ($type eq 'ARRAY') {
1410             return undef unless defined $value;
1411             return undef if ref $value ne 'ARRAY' && !$value;
1412             return undef if ref $value eq 'ARRAY' && !@$value;
1413             return [ $value ] unless ref $value eq 'ARRAY';
1414         }
1415         return undef unless $value;
1416         return $value;
1417     };
1418
1419     $config{$_} =
1420         $mkvalue->($ref_type, $user{$_})
1421         || $mkvalue->($ref_type, $target{$_});
1422     delete $config{$_} unless defined $config{$_};
1423 }
1424
1425 # Finish up %config by appending things the user gave us on the command line
1426 # apart from "make variables"
1427 foreach (keys %useradd) {
1428     # The must all be lists, so we assert that here
1429     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1430         unless ref $useradd{$_} eq 'ARRAY';
1431
1432     if (defined $config{$_}) {
1433         push @{$config{$_}}, @{$useradd{$_}};
1434     } else {
1435         $config{$_} = [ @{$useradd{$_}} ];
1436     }
1437 }
1438 # At this point, we can forget everything about %user and %useradd,
1439 # because it's now all been merged into the corresponding $config entry
1440
1441 if ($config{prefix} && !$config{CROSS_COMPILE}) {
1442     die "Directory given with --prefix MUST be absolute\n"
1443         unless file_name_is_absolute($config{prefix});
1444 }
1445
1446 if (grep { $_ =~ /(?:^|\s)-static(?:\s|$)/ } @{$config{LDFLAGS}}) {
1447     disable('static', 'pic', 'threads');
1448 }
1449
1450 # Allow overriding the build file name
1451 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1452
1453 # Make sure build_scheme is consistent.
1454 $target{build_scheme} = [ $target{build_scheme} ]
1455     if ref($target{build_scheme}) ne "ARRAY";
1456
1457 my ($builder, $builder_platform, @builder_opts) =
1458     @{$target{build_scheme}};
1459
1460 foreach my $checker (($builder_platform."-".$config{build_file}."-checker.pm",
1461                       $builder_platform."-checker.pm")) {
1462     my $checker_path = catfile($srcdir, "Configurations", $checker);
1463     if (-f $checker_path) {
1464         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1465             ? sub { warn $@; } : sub { die $@; };
1466         if (! do $checker_path) {
1467             if ($@) {
1468                 $fn->($@);
1469             } elsif ($!) {
1470                 $fn->($!);
1471             } else {
1472                 $fn->("The detected tools didn't match the platform\n");
1473             }
1474         }
1475         last;
1476     }
1477 }
1478
1479 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1480
1481 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1482         {
1483         push @{$config{cflags}}, "-mno-cygwin";
1484         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1485         push @{$config{shared_ldflag}}, "-mno-cygwin";
1486         }
1487
1488 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1489         && !grep { $_ =~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1490         # minimally required architecture flags for assembly modules
1491         my $value;
1492         $value = '-mips2' if ($target =~ /mips32/);
1493         $value = '-mips3' if ($target =~ /mips64/);
1494         unshift @{$config{cflags}}, $value;
1495         unshift @{$config{cxxflags}}, $value if $config{CXX};
1496 }
1497
1498 # If threads aren't disabled, check how possible they are
1499 unless ($disabled{threads}) {
1500     if ($auto_threads) {
1501         # Enabled by default, disable it forcibly if unavailable
1502         if ($target{thread_scheme} eq "(unknown)") {
1503             disable("unavailable", 'threads');
1504         }
1505     } else {
1506         # The user chose to enable threads explicitly, let's see
1507         # if there's a chance that's possible
1508         if ($target{thread_scheme} eq "(unknown)") {
1509             # If the user asked for "threads" and we don't have internal
1510             # knowledge how to do it, [s]he is expected to provide any
1511             # system-dependent compiler options that are necessary.  We
1512             # can't truly check that the given options are correct, but
1513             # we expect the user to know what [s]He is doing.
1514             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1515                 die "You asked for multi-threading support, but didn't\n"
1516                     ,"provide any system-specific compiler options\n";
1517             }
1518         }
1519     }
1520 }
1521
1522 # Find out if clang's sanitizers have been enabled with -fsanitize
1523 # flags and ensure that the corresponding %disabled elements area
1524 # removed to reflect that the sanitizers are indeed enabled.
1525 my %detected_sanitizers = ();
1526 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1527     (my $checks = $_) =~ s/^-fsanitize=//;
1528     foreach (split /,/, $checks) {
1529         my $d = { address       => 'asan',
1530                   undefined     => 'ubsan',
1531                   memory        => 'msan' } -> {$_};
1532         next unless defined $d;
1533
1534         $detected_sanitizers{$d} = 1;
1535         if (defined $disabled{$d}) {
1536             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1537                 if $disabled{$d} ne "default";
1538             delete $disabled{$d};
1539         }
1540     }
1541 }
1542
1543 # If threads still aren't disabled, add a C macro to ensure the source
1544 # code knows about it.  Any other flag is taken care of by the configs.
1545 unless($disabled{threads}) {
1546     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1547 }
1548
1549 my $no_shared_warn=0;
1550 if (($target{shared_target} // '') eq "")
1551         {
1552         $no_shared_warn = 1
1553             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1554         disable('no-shared-target', 'pic');
1555         }
1556
1557 if ($disabled{"dynamic-engine"}) {
1558         $config{dynamic_engines} = 0;
1559 } else {
1560         $config{dynamic_engines} = 1;
1561 }
1562
1563 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1564     push @{$config{cflags}}, "-fsanitize=address";
1565 }
1566
1567 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1568     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all", "-DPEDANTIC";
1569 }
1570
1571 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1572   push @{$config{cflags}}, "-fsanitize=memory";
1573 }
1574
1575 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1576         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1577     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1578     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1579 }
1580 #
1581 # Platform fix-ups
1582 #
1583
1584 # This saves the build files from having to check
1585 if ($disabled{pic})
1586         {
1587         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1588                     shared_defines shared_includes shared_ldflag
1589                     module_cflags module_cxxflags module_cppflags
1590                     module_defines module_includes module_lflags))
1591                 {
1592                 delete $config{$_};
1593                 $target{$_} = "";
1594                 }
1595         }
1596 else
1597         {
1598         push @{$config{lib_defines}}, "OPENSSL_PIC";
1599         }
1600
1601 if ($target{sys_id} ne "")
1602         {
1603         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1604         }
1605
1606 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1607 my %predefined_CXX = $config{CXX}
1608     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1609     : ();
1610
1611 unless ($disabled{asm}) {
1612     # big endian systems can use ELFv2 ABI
1613     if ($target eq "linux-ppc64" || $target eq "BSD-ppc64") {
1614         $target{perlasm_scheme} = "linux64v2" if ($predefined_C{_CALL_ELF} == 2);
1615     }
1616 }
1617
1618 # Check for makedepend capabilities.
1619 if (!$disabled{makedepend}) {
1620     # If the attribute makedep_scheme is defined, then we assume that the
1621     # config target and its associated build file are programmed to deal
1622     # with it.
1623     # If makedep_scheme is undefined, we go looking for GCC compatible
1624     # dependency making, and if that's not available, we try to fall back
1625     # on 'makedepend'.
1626     if ($target{makedep_scheme}) {
1627         $config{makedep_scheme} = $target{makedep_scheme};
1628         # If the makedepcmd attribute is defined, copy it.  If not, the
1629         # build files will have to fend for themselves.
1630         $config{makedepcmd} = $target{makedepcmd} if $target{makedepcmd};
1631     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1632              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1633         # We know that GNU C version 3 and up as well as all clang
1634         # versions support dependency generation, but Xcode did not
1635         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1636         $config{makedep_scheme} = 'gcc';
1637     } else {
1638         # In all other cases, we look for 'makedepend', and set the
1639         # makedep_scheme value if we found it.
1640         $config{makedepcmd} = which('makedepend');
1641         $config{makedep_scheme} = 'makedepend' if $config{makedepcmd};
1642     }
1643
1644     # If no depend scheme is set, we disable makedepend
1645     disable('unavailable', 'makedepend') unless $config{makedep_scheme};
1646 }
1647
1648 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1649     # probe for -Wa,--noexecstack option...
1650     if ($predefined_C{__clang__}) {
1651         # clang has builtin assembler, which doesn't recognize --help,
1652         # but it apparently recognizes the option in question on all
1653         # supported platforms even when it's meaningless. In other words
1654         # probe would fail, but probed option always accepted...
1655         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1656     } else {
1657         my $cc = $config{CROSS_COMPILE}.$config{CC};
1658         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1659         while(<PIPE>) {
1660             if (m/--noexecstack/) {
1661                 push @{$config{cflags}}, "-Wa,--noexecstack";
1662                 last;
1663             }
1664         }
1665         close(PIPE);
1666         unlink("null.$$.o");
1667     }
1668 }
1669
1670 # Deal with bn_ops ###################################################
1671
1672 $config{bn_ll}                  =0;
1673 my $def_int="unsigned int";
1674 $config{rc4_int}                =$def_int;
1675 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1676
1677 my $count = 0;
1678 foreach (sort split(/\s+/,$target{bn_ops})) {
1679     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1680     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1681     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1682     ($config{b64l},$config{b64},$config{b32})
1683         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1684     ($config{b64l},$config{b64},$config{b32})
1685         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1686     ($config{b64l},$config{b64},$config{b32})
1687         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1688 }
1689 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1690     if $count > 1;
1691
1692 $config{api} = $config{major} * 10000 + $config{minor} * 100
1693     unless $config{api};
1694 foreach (keys %$apitable) {
1695     $disabled{"deprecated-$_"} = "deprecation"
1696         if $disabled{deprecated} && $config{api} >= $apitable->{$_};
1697 }
1698
1699 disable();                      # Run a cascade now
1700
1701 # Hack cflags for better warnings (dev option) #######################
1702
1703 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1704 # a string and works as well on command lines.
1705 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1706                         @{$config{cflags}} ];
1707 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1708                           @{$config{cxxflags}} ] if $config{CXX};
1709
1710 $config{openssl_api_defines} = [
1711     "OPENSSL_CONFIGURED_API=".$config{api},
1712 ];
1713
1714 my @strict_warnings_collection=();
1715 if ($strict_warnings)
1716         {
1717         my $wopt;
1718         my $gccver = $predefined_C{__GNUC__} // -1;
1719
1720         if ($gccver >= 4)
1721                 {
1722                 push @strict_warnings_collection, @gcc_devteam_warn;
1723                 push @strict_warnings_collection, @clang_devteam_warn
1724                     if (defined($predefined_C{__clang__}));
1725                 }
1726         elsif ($config{target} =~ /^VC-/)
1727                 {
1728                 push @strict_warnings_collection, @cl_devteam_warn;
1729                 }
1730         else
1731                 {
1732                 warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike, or MSVC"
1733                 }
1734         }
1735
1736 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1737                               ? @strict_warnings_collection
1738                               : ( $_ ) }
1739                     @{$config{CFLAGS}} ];
1740
1741 unless ($disabled{afalgeng}) {
1742     $config{afalgeng}="";
1743     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1744         push @{$config{engdirs}}, "afalg";
1745     } else {
1746         disable('not-linux', 'afalgeng');
1747     }
1748 }
1749
1750 unless ($disabled{devcryptoeng}) {
1751     if ($target =~ m/^BSD/) {
1752         my $maxver = 5*100 + 7;
1753         my $sysstr = `uname -s`;
1754         my $verstr = `uname -r`;
1755         $sysstr =~ s|\R$||;
1756         $verstr =~ s|\R$||;
1757         my ($ma, $mi, @rest) = split m|\.|, $verstr;
1758         my $ver = $ma*100 + $mi;
1759         if ($sysstr eq 'OpenBSD' && $ver >= $maxver) {
1760             disable('too-new-kernel', 'devcryptoeng');
1761         }
1762     }
1763 }
1764
1765 unless ($disabled{ktls}) {
1766     $config{ktls}="";
1767     my $cc = $config{CROSS_COMPILE}.$config{CC};
1768     if ($target =~ m/^linux/) {
1769         system("printf '#include <sys/types.h>\n#include <linux/tls.h>' | $cc -E - >/dev/null 2>&1");
1770         if ($? != 0) {
1771             disable('too-old-kernel', 'ktls');
1772         }
1773     } elsif ($target =~ m/^BSD/) {
1774         system("printf '#include <sys/types.h>\n#include <sys/ktls.h>' | $cc -E - >/dev/null 2>&1");
1775         if ($? != 0) {
1776             disable('too-old-freebsd', 'ktls');
1777         }
1778     } else {
1779         disable('not-linux-or-freebsd', 'ktls');
1780     }
1781 }
1782
1783 unless ($disabled{winstore}) {
1784     unless ($target =~ /^(?:Cygwin|mingw|VC-|BC-)/) {
1785         disable('not-windows', 'winstore');
1786     }
1787 }
1788
1789 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1790
1791 # Get the extra flags used when building shared libraries and modules.  We
1792 # do this late because some of them depend on %disabled.
1793
1794 # Make the flags to build DSOs the same as for shared libraries unless they
1795 # are already defined
1796 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1797 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1798 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1799 {
1800     my $shared_info_pl =
1801         catfile(dirname($0), "Configurations", "shared-info.pl");
1802     my %shared_info = read_eval_file($shared_info_pl);
1803     push @{$target{_conf_fname_int}}, $shared_info_pl;
1804     my $si = $target{shared_target};
1805     while (ref $si ne "HASH") {
1806         last if ! defined $si;
1807         if (ref $si eq "CODE") {
1808             $si = $si->();
1809         } else {
1810             $si = $shared_info{$si};
1811         }
1812     }
1813
1814     # Some of the 'shared_target' values don't have any entries in
1815     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1816     # template knows how to handle this.  That is currently the case for
1817     # Windows and VMS.
1818     if (defined $si) {
1819         # Just as above, copy certain shared_* attributes to the corresponding
1820         # module_ attribute unless the latter is already defined
1821         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1822         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1823         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1824         foreach (sort keys %$si) {
1825             $target{$_} = defined $target{$_}
1826                 ? add($si->{$_})->($target{$_})
1827                 : $si->{$_};
1828         }
1829     }
1830 }
1831
1832 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1833
1834 ######################################################################
1835 # Build up information for skipping certain directories depending on disabled
1836 # features, as well as setting up macros for disabled features.
1837
1838 # This is a tentative database of directories to skip.  Some entries may not
1839 # correspond to anything real, but that's ok, they will simply be ignored.
1840 # The actual processing of these entries is done in the build.info lookup
1841 # loop further down.
1842 #
1843 # The key is a Unix formatted path in the source tree, the value is an index
1844 # into %disabled_info, so any existing path gets added to a corresponding
1845 # 'skipped' entry in there with the list of skipped directories.
1846 my %skipdir = ();
1847 my %disabled_info = ();         # For configdata.pm
1848 foreach my $what (sort keys %disabled) {
1849     # There are deprecated disablables that translate to themselves.
1850     # They cause disabling cascades, but should otherwise not register.
1851     next if $deprecated_disablables{$what};
1852     # The generated $disabled{"deprecated-x.y"} entries are special
1853     # and treated properly elsewhere
1854     next if $what =~ m|^deprecated-|;
1855
1856     $config{options} .= " no-$what";
1857
1858     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1859                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1860                                 'sse2', 'legacy' )) {
1861         (my $WHAT = uc $what) =~ s|-|_|g;
1862         my $skipdir = $what;
1863
1864         # fix-up crypto/directory name(s)
1865         $skipdir = "ripemd" if $what eq "rmd160";
1866         $skipdir = "whrlpool" if $what eq "whirlpool";
1867
1868         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1869         push @{$config{openssl_feature_defines}}, $macro;
1870
1871         $skipdir{engines} = $what if $what eq 'engine';
1872         $skipdir{"crypto/$skipdir"} = $what
1873             unless $what eq 'async' || $what eq 'err' || $what eq 'dso';
1874     }
1875 }
1876
1877 if ($disabled{"dynamic-engine"}) {
1878     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1879 } else {
1880     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1881 }
1882
1883 # If we use the unified build, collect information from build.info files
1884 my %unified_info = ();
1885
1886 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1887 if ($builder eq "unified") {
1888     use Text::Template 1.46;
1889
1890     sub cleandir {
1891         my $base = shift;
1892         my $dir = shift;
1893         my $relativeto = shift || ".";
1894
1895         $dir = catdir($base,$dir) unless isabsolute($dir);
1896
1897         # Make sure the directories we're building in exists
1898         mkpath($dir);
1899
1900         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1901         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1902         return $res;
1903     }
1904
1905     sub cleanfile {
1906         my $base = shift;
1907         my $file = shift;
1908         my $relativeto = shift || ".";
1909
1910         $file = catfile($base,$file) unless isabsolute($file);
1911
1912         my $d = dirname($file);
1913         my $f = basename($file);
1914
1915         # Make sure the directories we're building in exists
1916         mkpath($d);
1917
1918         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1919         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1920         return $res;
1921     }
1922
1923     # Store the name of the template file we will build the build file from
1924     # in %config.  This may be useful for the build file itself.
1925     my @build_file_template_names =
1926         ( $builder_platform."-".$config{build_file}.".tmpl",
1927           $config{build_file}.".tmpl" );
1928     my @build_file_templates = ();
1929
1930     # First, look in the user provided directory, if given
1931     if (defined env($local_config_envname)) {
1932         @build_file_templates =
1933             map {
1934                 if ($^O eq 'VMS') {
1935                     # VMS environment variables are logical names,
1936                     # which can be used as is
1937                     $local_config_envname . ':' . $_;
1938                 } else {
1939                     catfile(env($local_config_envname), $_);
1940                 }
1941             }
1942             @build_file_template_names;
1943     }
1944     # Then, look in our standard directory
1945     push @build_file_templates,
1946         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1947           @build_file_template_names );
1948
1949     my $build_file_template;
1950     for $_ (@build_file_templates) {
1951         $build_file_template = $_;
1952         last if -f $build_file_template;
1953
1954         $build_file_template = undef;
1955     }
1956     if (!defined $build_file_template) {
1957         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1958     }
1959     $config{build_file_templates}
1960       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1961                     $blddir),
1962            $build_file_template ];
1963
1964     my @build_dirs = ( [ ] );   # current directory
1965
1966     $config{build_infos} = [ ];
1967
1968     # We want to detect configdata.pm in the source tree, so we
1969     # don't use it if the build tree is different.
1970     my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1971
1972     # Any source file that we recognise is placed in this hash table, with
1973     # the list of its intended destinations as value.  When everything has
1974     # been collected, there's a routine that checks that these source files
1975     # exist, or if they are generated, that the generator exists.
1976     my %check_exist = ();
1977     my %check_generate = ();
1978
1979     my %ordinals = ();
1980     while (@build_dirs) {
1981         my @curd = @{shift @build_dirs};
1982         my $sourced = catdir($srcdir, @curd);
1983         my $buildd = catdir($blddir, @curd);
1984
1985         my $unixdir = join('/', @curd);
1986         if (exists $skipdir{$unixdir}) {
1987             my $what = $skipdir{$unixdir};
1988             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1989             next;
1990         }
1991
1992         mkpath($buildd);
1993
1994         my $f = 'build.info';
1995         # The basic things we're trying to build
1996         my @programs = ();
1997         my @libraries = ();
1998         my @modules = ();
1999         my @scripts = ();
2000
2001         my %sources = ();
2002         my %shared_sources = ();
2003         my %includes = ();
2004         my %defines = ();
2005         my %depends = ();
2006         my %generate = ();
2007         my %imagedocs = ();
2008         my %htmldocs = ();
2009         my %mandocs = ();
2010
2011         # Support for $variablename in build.info files.
2012         # Embedded perl code is the ultimate master, still.  If its output
2013         # contains a dollar sign, it had better be escaped, or it will be
2014         # taken for a variable name prefix.
2015         my %variables = ();
2016         # Variable name syntax
2017         my $variable_name_re = qr/(?P<VARIABLE>[[:alpha:]][[:alnum:]_]*)/;
2018         # Value modifier syntaxes
2019         my $variable_subst_re = qr/\/(?P<RE>(?:\\\/|.)*?)\/(?P<SUBST>.*?)/;
2020         # Variable reference
2021         my $variable_simple_re = qr/(?<!\\)\$${variable_name_re}/;
2022         my $variable_w_mod_re =
2023             qr/(?<!\\)\$\{${variable_name_re}(?P<MOD>(?:\\\/|.)*?)\}/;
2024         # Tie it all together
2025         my $variable_re = qr/${variable_simple_re}|${variable_w_mod_re}/;
2026
2027         my $expand_variables = sub {
2028             my $value = '';
2029             my $value_rest = shift;
2030
2031             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2032                 print STDERR
2033                     "DEBUG[\$expand_variables] Parsed '$value_rest' ...\n"
2034             }
2035
2036             while ($value_rest =~ /${variable_re}/) {
2037                 # We must save important regexp values, because the next
2038                 # regexp clears them
2039                 my $mod = $+{MOD};
2040                 my $variable_value = $variables{$+{VARIABLE}};
2041
2042                 $value_rest = $';
2043                 $value .= $`;
2044
2045                 # Process modifier expressions, if present
2046                 if (defined $mod) {
2047                     if ($mod =~ /^${variable_subst_re}$/) {
2048                         my $re = $+{RE};
2049                         my $subst = $+{SUBST};
2050
2051                         $variable_value =~ s/\Q$re\E/$subst/g;
2052
2053                         if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2054                             print STDERR
2055                                 "DEBUG[\$expand_variables] ... and substituted ",
2056                                 "'$re' with '$subst'\n";
2057                         }
2058                     }
2059                 }
2060
2061                 $value .= $variable_value;
2062             }
2063             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2064                 print STDERR
2065                     "DEBUG[\$expand_variables] ... into: '$value$value_rest'\n";
2066             }
2067             return $value . $value_rest;
2068         };
2069
2070         # Support for attributes in build.info files
2071         my %attributes = ();
2072         my $handle_attributes = sub {
2073             my $attr_str = shift;
2074             my $ref = shift;
2075             my @goals = @_;
2076
2077             return unless defined $attr_str;
2078
2079             my @a = tokenize($attr_str, qr|\s*,\s*|);
2080             foreach my $a (@a) {
2081                 my $ac = 1;
2082                 my $ak = $a;
2083                 my $av = 1;
2084                 if ($a =~ m|^(!)?(.*?)\s* = \s*(.*?)$|x) {
2085                     $ac = ! $1;
2086                     $ak = $2;
2087                     $av = $3;
2088                 }
2089                 foreach my $g (@goals) {
2090                     if ($ac) {
2091                         $$ref->{$g}->{$ak} = $av;
2092                     } else {
2093                         delete $$ref->{$g}->{$ak};
2094                     }
2095                 }
2096             }
2097         };
2098
2099         # Support for pushing values on multiple indexes of a given hash
2100         # array.
2101         my $push_to = sub {
2102             my $valueref = shift;
2103             my $index_str = shift; # May be undef or empty
2104             my $attrref = shift;   # May be undef
2105             my $attr_str = shift;
2106             my @values = @_;
2107
2108             if (defined $index_str) {
2109                 my @indexes = ( '' );
2110                 if ($index_str !~ m|^\s*$|) {
2111                     @indexes = tokenize($index_str);
2112                 }
2113                 foreach (@indexes) {
2114                     push @{$valueref->{$_}}, @values;
2115                     if (defined $attrref) {
2116                         $handle_attributes->($attr_str, \$$attrref->{$_},
2117                                              @values);
2118                     }
2119                 }
2120             } else {
2121                 push @$valueref, @values;
2122                 $handle_attributes->($attr_str, $attrref, @values)
2123                     if defined $attrref;
2124             }
2125         };
2126
2127         if ($buildinfo_debug) {
2128             print STDERR "DEBUG: Reading ",catfile($sourced, $f),"\n";
2129         }
2130         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
2131         my $template =
2132             Text::Template->new(TYPE => 'FILE',
2133                                 SOURCE => catfile($sourced, $f),
2134                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
2135         die "Something went wrong with $sourced/$f: $!\n" unless $template;
2136         my @text =
2137             split /^/m,
2138             $template->fill_in(HASH => { config => \%config,
2139                                          target => \%target,
2140                                          disabled => \%disabled,
2141                                          withargs => \%withargs,
2142                                          builddir => abs2rel($buildd, $blddir),
2143                                          sourcedir => abs2rel($sourced, $blddir),
2144                                          buildtop => abs2rel($blddir, $blddir),
2145                                          sourcetop => abs2rel($srcdir, $blddir) },
2146                                DELIMITERS => [ "{-", "-}" ]);
2147
2148         # The top item of this stack has the following values
2149         # -2 positive already run and we found ELSE (following ELSIF should fail)
2150         # -1 positive already run (skip until ENDIF)
2151         # 0 negatives so far (if we're at a condition, check it)
2152         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
2153         # 2 positive ELSE (following ELSIF should fail)
2154         my @skip = ();
2155
2156         # A few useful generic regexps
2157         my $index_re = qr/\[\s*(?P<INDEX>(?:\\.|.)*?)\s*\]/;
2158         my $cond_re = qr/\[\s*(?P<COND>(?:\\.|.)*?)\s*\]/;
2159         my $attribs_re = qr/(?:\{\s*(?P<ATTRIBS>(?:\\.|.)*?)\s*\})?/;
2160         my $value_re = qr/(?P<VALUE>.*?)/;
2161         collect_information(
2162             collect_from_array([ @text ],
2163                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
2164                                                 $l1 =~ s/\\$//; $l1.$l2 }),
2165             # Info we're looking for
2166             qr/^\s* IF ${cond_re} \s*$/x
2167             => sub {
2168                 if (! @skip || $skip[$#skip] > 0) {
2169                     push @skip, !! $expand_variables->($+{COND});
2170                 } else {
2171                     push @skip, -1;
2172                 }
2173             },
2174             qr/^\s* ELSIF ${cond_re} \s*$/x
2175             => sub { die "ELSIF out of scope" if ! @skip;
2176                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
2177                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
2178                      $skip[$#skip] = !! $expand_variables->($+{COND})
2179                          if $skip[$#skip] == 0; },
2180             qr/^\s* ELSE \s*$/x
2181             => sub { die "ELSE out of scope" if ! @skip;
2182                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
2183                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
2184             qr/^\s* ENDIF \s*$/x
2185             => sub { die "ENDIF out of scope" if ! @skip;
2186                      pop @skip; },
2187             qr/^\s* ${variable_re} \s* = \s* ${value_re} \s* $/x
2188             => sub {
2189                 if (!@skip || $skip[$#skip] > 0) {
2190                     $variables{$+{VARIABLE}} = $expand_variables->($+{VALUE});
2191                 }
2192             },
2193             qr/^\s* SUBDIRS \s* = \s* ${value_re} \s* $/x
2194             => sub {
2195                 if (!@skip || $skip[$#skip] > 0) {
2196                     foreach (tokenize($expand_variables->($+{VALUE}))) {
2197                         push @build_dirs, [ @curd, splitdir($_, 1) ];
2198                     }
2199                 }
2200             },
2201             qr/^\s* PROGRAMS ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2202             => sub { $push_to->(\@programs, undef,
2203                                 \$attributes{programs}, $+{ATTRIBS},
2204                                 tokenize($expand_variables->($+{VALUE})))
2205                          if !@skip || $skip[$#skip] > 0; },
2206             qr/^\s* LIBS ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2207             => sub { $push_to->(\@libraries, undef,
2208                                 \$attributes{libraries}, $+{ATTRIBS},
2209                                 tokenize($expand_variables->($+{VALUE})))
2210                          if !@skip || $skip[$#skip] > 0; },
2211             qr/^\s* MODULES ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2212             => sub { $push_to->(\@modules, undef,
2213                                 \$attributes{modules}, $+{ATTRIBS},
2214                                 tokenize($expand_variables->($+{VALUE})))
2215                          if !@skip || $skip[$#skip] > 0; },
2216             qr/^\s* SCRIPTS ${attribs_re} \s* = \s* ${value_re} \s* $/x
2217             => sub { $push_to->(\@scripts, undef,
2218                                 \$attributes{scripts}, $+{ATTRIBS},
2219                                 tokenize($expand_variables->($+{VALUE})))
2220                          if !@skip || $skip[$#skip] > 0; },
2221             qr/^\s* IMAGEDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2222             => sub { $push_to->(\%imagedocs, $expand_variables->($+{INDEX}),
2223                                 undef, undef,
2224                                 tokenize($expand_variables->($+{VALUE})))
2225                          if !@skip || $skip[$#skip] > 0; },
2226             qr/^\s* HTMLDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2227             => sub { $push_to->(\%htmldocs, $expand_variables->($+{INDEX}),
2228                                 undef, undef,
2229                                 tokenize($expand_variables->($+{VALUE})))
2230                          if !@skip || $skip[$#skip] > 0; },
2231             qr/^\s* MANDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2232             => sub { $push_to->(\%mandocs, $expand_variables->($+{INDEX}),
2233                                 undef, undef,
2234                                 tokenize($expand_variables->($+{VALUE})))
2235                          if !@skip || $skip[$#skip] > 0; },
2236             qr/^\s* SOURCE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2237             => sub { $push_to->(\%sources, $expand_variables->($+{INDEX}),
2238                                 \$attributes{sources}, $+{ATTRIBS},
2239                                 tokenize($expand_variables->($+{VALUE})))
2240                          if !@skip || $skip[$#skip] > 0; },
2241             qr/^\s* SHARED_SOURCE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2242             => sub { $push_to->(\%shared_sources, $expand_variables->($+{INDEX}),
2243                                 \$attributes{sources}, $+{ATTRIBS},
2244                                 tokenize($expand_variables->($+{VALUE})))
2245                          if !@skip || $skip[$#skip] > 0; },
2246             qr/^\s* INCLUDE ${index_re} \s* = \s* ${value_re} \s* $/x
2247             => sub { $push_to->(\%includes, $expand_variables->($+{INDEX}),
2248                                 undef, undef,
2249                                 tokenize($expand_variables->($+{VALUE})))
2250                          if !@skip || $skip[$#skip] > 0; },
2251             qr/^\s* DEFINE ${index_re} \s* = \s* ${value_re} \s* $/x
2252             => sub { $push_to->(\%defines, $expand_variables->($+{INDEX}),
2253                                 undef, undef,
2254                                 tokenize($expand_variables->($+{VALUE})))
2255                          if !@skip || $skip[$#skip] > 0; },
2256             qr/^\s* DEPEND ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2257             => sub { $push_to->(\%depends, $expand_variables->($+{INDEX}),
2258                                 \$attributes{depends}, $+{ATTRIBS},
2259                                 tokenize($expand_variables->($+{VALUE})))
2260                          if !@skip || $skip[$#skip] > 0; },
2261             qr/^\s* GENERATE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2262             => sub { $push_to->(\%generate, $expand_variables->($+{INDEX}),
2263                                 \$attributes{generate}, $+{ATTRIBS},
2264                                 $expand_variables->($+{VALUE}))
2265                          if !@skip || $skip[$#skip] > 0; },
2266             qr/^\s* (?:\#.*)? $/x => sub { },
2267             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
2268             "BEFORE" => sub {
2269                 if ($buildinfo_debug) {
2270                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
2271                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2272                 }
2273             },
2274             "AFTER" => sub {
2275                 if ($buildinfo_debug) {
2276                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2277                 }
2278             },
2279             );
2280         die "runaway IF?" if (@skip);
2281
2282         if (grep { defined $attributes{modules}->{$_}->{engine} } keys %attributes
2283                 and !$config{dynamic_engines}) {
2284             die <<"EOF"
2285 ENGINES can only be used if configured with 'dynamic-engine'.
2286 This is usually a fault in a build.info file.
2287 EOF
2288         }
2289
2290         {
2291             my %infos = ( programs  => [ @programs  ],
2292                           libraries => [ @libraries ],
2293                           modules   => [ @modules   ],
2294                           scripts   => [ @scripts   ] );
2295             foreach my $k (keys %infos) {
2296                 foreach (@{$infos{$k}}) {
2297                     my $item = cleanfile($buildd, $_, $blddir);
2298                     $unified_info{$k}->{$item} = 1;
2299
2300                     # Fix up associated attributes
2301                     $unified_info{attributes}->{$k}->{$item} =
2302                         $attributes{$k}->{$_}
2303                         if defined $attributes{$k}->{$_};
2304                 }
2305             }
2306         }
2307
2308         # Check that we haven't defined any library as both shared and
2309         # explicitly static.  That is forbidden.
2310         my @doubles = ();
2311         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2312             (my $l = $_) =~ s/\.a$//;
2313             push @doubles, $l if defined $unified_info{libraries}->{$l};
2314         }
2315         die "these libraries are both explicitly static and shared:\n  ",
2316             join(" ", @doubles), "\n"
2317             if @doubles;
2318
2319         foreach (keys %sources) {
2320             my $dest = $_;
2321             my $ddest = cleanfile($buildd, $_, $blddir);
2322             foreach (@{$sources{$dest}}) {
2323                 my $s = cleanfile($sourced, $_, $blddir);
2324
2325                 # If it's generated or we simply don't find it in the source
2326                 # tree, we assume it's in the build tree.
2327                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2328                     $s = cleanfile($buildd, $_, $blddir);
2329                 }
2330                 my $o = $_;
2331                 # We recognise C++, C and asm files
2332                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2333                     push @{$check_exist{$s}}, $ddest;
2334                     $o =~ s/\.[csS]$/.o/; # C and assembler
2335                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2336                     $o = cleanfile($buildd, $o, $blddir);
2337                     $unified_info{sources}->{$ddest}->{$o} = -1;
2338                     $unified_info{sources}->{$o}->{$s} = -1;
2339                 } elsif ($s =~ /\.rc$/) {
2340                     # We also recognise resource files
2341                     push @{$check_exist{$s}}, $ddest;
2342                     $o =~ s/\.rc$/.res/; # Resource configuration
2343                     $o = cleanfile($buildd, $o, $blddir);
2344                     $unified_info{sources}->{$ddest}->{$o} = -1;
2345                     $unified_info{sources}->{$o}->{$s} = -1;
2346                 } else {
2347                     push @{$check_exist{$s}}, $ddest;
2348                     $unified_info{sources}->{$ddest}->{$s} = 1;
2349                 }
2350                 # Fix up associated attributes
2351                 if ($o ne $_) {
2352                     $unified_info{attributes}->{sources}->{$ddest}->{$o} =
2353                         $unified_info{attributes}->{sources}->{$o}->{$s} =
2354                         $attributes{sources}->{$dest}->{$_}
2355                         if defined $attributes{sources}->{$dest}->{$_};
2356                 } else {
2357                     $unified_info{attributes}->{sources}->{$ddest}->{$s} =
2358                         $attributes{sources}->{$dest}->{$_}
2359                         if defined $attributes{sources}->{$dest}->{$_};
2360                 }
2361             }
2362         }
2363
2364         foreach (keys %shared_sources) {
2365             my $dest = $_;
2366             my $ddest = cleanfile($buildd, $_, $blddir);
2367             foreach (@{$shared_sources{$dest}}) {
2368                 my $s = cleanfile($sourced, $_, $blddir);
2369
2370                 # If it's generated or we simply don't find it in the source
2371                 # tree, we assume it's in the build tree.
2372                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2373                     $s = cleanfile($buildd, $_, $blddir);
2374                 }
2375
2376                 my $o = $_;
2377                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2378                     # We recognise C++, C and asm files
2379                     push @{$check_exist{$s}}, $ddest;
2380                     $o =~ s/\.[csS]$/.o/; # C and assembler
2381                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2382                     $o = cleanfile($buildd, $o, $blddir);
2383                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2384                     $unified_info{sources}->{$o}->{$s} = -1;
2385                 } elsif ($s =~ /\.rc$/) {
2386                     # We also recognise resource files
2387                     push @{$check_exist{$s}}, $ddest;
2388                     $o =~ s/\.rc$/.res/; # Resource configuration
2389                     $o = cleanfile($buildd, $o, $blddir);
2390                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2391                     $unified_info{sources}->{$o}->{$s} = -1;
2392                 } elsif ($s =~ /\.ld$/) {
2393                     # We also recognise linker scripts (or corresponding)
2394                     # We know they are generated files
2395                     push @{$check_exist{$s}}, $ddest;
2396                     $o = cleanfile($buildd, $_, $blddir);
2397                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
2398                 } else {
2399                     die "unrecognised source file type for shared library: $s\n";
2400                 }
2401                 # Fix up associated attributes
2402                 if ($o ne $_) {
2403                     $unified_info{attributes}->{shared_sources}->{$ddest}->{$o} =
2404                         $unified_info{attributes}->{sources}->{$o}->{$s} =
2405                         $attributes{sources}->{$dest}->{$_}
2406                         if defined $attributes{sources}->{$dest}->{$_};
2407                 } else {
2408                     $unified_info{attributes}->{shared_sources}->{$ddest}->{$o} =
2409                         $attributes{sources}->{$dest}->{$_}
2410                         if defined $attributes{sources}->{$dest}->{$_};
2411                 }
2412             }
2413         }
2414
2415         foreach (keys %generate) {
2416             my $dest = $_;
2417             my $ddest = cleanfile($buildd, $_, $blddir);
2418             die "more than one generator for $dest: "
2419                 ,join(" ", @{$generate{$_}}),"\n"
2420                 if scalar @{$generate{$_}} > 1;
2421             my @generator = split /\s+/, $generate{$dest}->[0];
2422             my $gen = $generator[0];
2423             $generator[0] = cleanfile($sourced, $gen, $blddir);
2424
2425             # If the generator is itself generated, it's in the build tree
2426             if ($generate{$gen} || ! -f $generator[0]) {
2427                 $generator[0] = cleanfile($buildd, $gen, $blddir);
2428             }
2429             $check_generate{$ddest}->{$generator[0]}++;
2430
2431             $unified_info{generate}->{$ddest} = [ @generator ];
2432             # Fix up associated attributes
2433             $unified_info{attributes}->{generate}->{$ddest} =
2434                 $attributes{generate}->{$dest}->{$gen}
2435                 if defined $attributes{generate}->{$dest}->{$gen};
2436         }
2437
2438         foreach (keys %depends) {
2439             my $dest = $_;
2440             my $ddest = $dest;
2441
2442             if ($dest =~ /^\|(.*)\|$/) {
2443                 # Collect the raw target
2444                 $unified_info{targets}->{$1} = 1;
2445                 $ddest = $1;
2446             } elsif ($dest eq '') {
2447                 $ddest = '';
2448             } else {
2449                 $ddest = cleanfile($sourced, $dest, $blddir);
2450
2451                 # If the destination doesn't exist in source, it can only be
2452                 # a generated file in the build tree.
2453                 if ($ddest eq $src_configdata || ! -f $ddest) {
2454                     $ddest = cleanfile($buildd, $dest, $blddir);
2455                 }
2456             }
2457             foreach my $f (@{$depends{$dest}}) {
2458                 # If the dependency destination is generated, dependencies
2459                 # may have an extra syntax to separate the intended inclusion
2460                 # directory from the module to be loaded: a | instead of a
2461                 # / as directory separator.
2462                 # Do note that this has to be handled in the build file
2463                 # template as well.
2464                 # $i = inclusion path in source directory
2465                 # $i2 = inclusion path in build directory
2466                 # $m = module path (within the inclusion path)
2467                 # $i = full module path in source directory
2468                 # $i2 = full module path in build directory
2469                 my $i; my $i2; my $m; my $d; my $d2;
2470                 if ($unified_info{generate}->{$ddest}
2471                     && $f =~ m/^(.*?)\|(.*)$/) {
2472                     $i = $1;
2473                     $m = $2;
2474                     $i = cleanfile($sourced, $i, $blddir);
2475                     $i2 = cleanfile($buildd, $i, $blddir);
2476                     $d = cleanfile($sourced, "$i/$m", $blddir);
2477                     $d2 = cleanfile($buildd, "$i/$m", $blddir);
2478                 } else {
2479                     $d = cleanfile($sourced, $f, $blddir);
2480                     $d2 = cleanfile($buildd, $f, $blddir);
2481                 }
2482
2483                 # If we know it's generated, or assume it is because we can't
2484                 # find it in the source tree, we set file we depend on to be
2485                 # in the build tree rather than the source tree.
2486                 if ($d eq $src_configdata
2487                     || (grep { $d2 eq $_ }
2488                         keys %{$unified_info{generate}})
2489                     || ! -f $d) {
2490                     $d = $d2;
2491                     $i = $i2;
2492                 }
2493                 if ($i) {
2494                     # Put together the computed inclusion dir with the
2495                     # original module name.  Do note that we conserve the
2496                     # Unixly path syntax for the module path.
2497                     $d = "$i|$m";
2498                 }
2499                 $unified_info{depends}->{$ddest}->{$d} = 1;
2500
2501                 # Fix up associated attributes
2502                 $unified_info{attributes}->{depends}->{$ddest}->{$d} =
2503                     $attributes{depends}->{$dest}->{$f}
2504                     if defined $attributes{depends}->{$dest}->{$f};
2505             }
2506         }
2507
2508         foreach (keys %includes) {
2509             my $dest = $_;
2510             my $ddest = cleanfile($sourced, $_, $blddir);
2511
2512             # If the destination doesn't exist in source, it can only be
2513             # a generated file in the build tree.
2514             if ($ddest eq $src_configdata || ! -f $ddest) {
2515                 $ddest = cleanfile($buildd, $_, $blddir);
2516             }
2517             foreach (@{$includes{$dest}}) {
2518                 my $is = cleandir($sourced, $_, $blddir);
2519                 my $ib = cleandir($buildd, $_, $blddir);
2520                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2521                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2522                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2523                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2524             }
2525         }
2526
2527         foreach my $dest (keys %defines) {
2528             my $ddest;
2529
2530             if ($dest ne "") {
2531                 $ddest = cleanfile($sourced, $dest, $blddir);
2532
2533                 # If the destination doesn't exist in source, it can only
2534                 # be a generated file in the build tree.
2535                 if (! -f $ddest) {
2536                     $ddest = cleanfile($buildd, $dest, $blddir);
2537                 }
2538             }
2539             foreach my $v (@{$defines{$dest}}) {
2540                 $v =~ m|^([^=]*)(=.*)?$|;
2541                 die "0 length macro name not permitted\n" if $1 eq "";
2542                 if ($dest ne "") {
2543                     die "$1 defined more than once\n"
2544                         if defined $unified_info{defines}->{$ddest}->{$1};
2545                     $unified_info{defines}->{$ddest}->{$1} = $2;
2546                 } else {
2547                     die "$1 defined more than once\n"
2548                         if grep { $v eq $_ } @{$config{defines}};
2549                     push @{$config{defines}}, $v;
2550                 }
2551             }
2552         }
2553
2554         foreach my $section (keys %imagedocs) {
2555             foreach (@{$imagedocs{$section}}) {
2556                 my $imagedocs = cleanfile($buildd, $_, $blddir);
2557                 $unified_info{imagedocs}->{$section}->{$imagedocs} = 1;
2558             }
2559         }
2560
2561         foreach my $section (keys %htmldocs) {
2562             foreach (@{$htmldocs{$section}}) {
2563                 my $htmldocs = cleanfile($buildd, $_, $blddir);
2564                 $unified_info{htmldocs}->{$section}->{$htmldocs} = 1;
2565             }
2566         }
2567
2568         foreach my $section (keys %mandocs) {
2569             foreach (@{$mandocs{$section}}) {
2570                 my $mandocs = cleanfile($buildd, $_, $blddir);
2571                 $unified_info{mandocs}->{$section}->{$mandocs} = 1;
2572             }
2573         }
2574     }
2575
2576     my $ordinals_text = join(', ', sort keys %ordinals);
2577     warn <<"EOF" if $ordinals_text;
2578
2579 WARNING: ORDINALS were specified for $ordinals_text
2580 They are ignored and should be replaced with a combination of GENERATE,
2581 DEPEND and SHARED_SOURCE.
2582 EOF
2583
2584     # Check that each generated file is only generated once
2585     my $ambiguous_generation = 0;
2586     foreach (sort keys %check_generate) {
2587         my @generators = sort keys %{$check_generate{$_}};
2588         my $generators_txt = join(', ', @generators);
2589         if (scalar @generators > 1) {
2590             warn "$_ is GENERATEd by more than one generator ($generators_txt)\n";
2591             $ambiguous_generation++;
2592         }
2593         if ($check_generate{$_}->{$generators[0]} > 1) {
2594             warn "INFO: $_ has more than one GENERATE declaration (same generator)\n"
2595         }
2596     }
2597     die "There are ambiguous source file generations\n"
2598         if $ambiguous_generation > 0;
2599
2600     # All given source files should exist, or if generated, their
2601     # generator should exist.  This loop ensures this is true.
2602     my $missing = 0;
2603     foreach my $orig (sort keys %check_exist) {
2604         foreach my $dest (@{$check_exist{$orig}}) {
2605             if ($orig ne $src_configdata) {
2606                 if ($orig =~ /\.a$/) {
2607                     # Static library names may be used as sources, so we
2608                     # need to detect those and give them special treatment.
2609                     unless (grep { $_ eq $orig }
2610                             keys %{$unified_info{libraries}}) {
2611                         warn "$orig is given as source for $dest, but no such library is built\n";
2612                         $missing++;
2613                     }
2614                 } else {
2615                     # A source may be generated, and its generator may be
2616                     # generated as well.  We therefore loop to dig out the
2617                     # first generator.
2618                     my $gen = $orig;
2619
2620                     while (my @next = keys %{$check_generate{$gen}}) {
2621                         $gen = $next[0];
2622                     }
2623
2624                     if (! -f $gen) {
2625                         if ($gen ne $orig) {
2626                             $missing++;
2627                             warn "$orig is given as source for $dest, but its generator (leading to $gen) is missing\n";
2628                         } else {
2629                             $missing++;
2630                             warn "$orig is given as source for $dest, but is missing\n";
2631                         }
2632                     }
2633                 }
2634             }
2635         }
2636     }
2637     die "There are files missing\n" if $missing > 0;
2638
2639     # Go through the sources of all libraries and check that the same basename
2640     # doesn't appear more than once.  Some static library archivers depend on
2641     # them being unique.
2642     {
2643         my $err = 0;
2644         foreach my $prod (keys %{$unified_info{libraries}}) {
2645             my @prod_sources =
2646                 map { keys %{$unified_info{sources}->{$_}} }
2647                 keys %{$unified_info{sources}->{$prod}};
2648             my %srccnt = ();
2649
2650             # Count how many times a given each source basename
2651             # appears for each product.
2652             foreach my $src (@prod_sources) {
2653                 $srccnt{basename $src}++;
2654             }
2655
2656             foreach my $src (keys %srccnt) {
2657                 if ((my $cnt = $srccnt{$src}) > 1) {
2658                     print STDERR "$src appears $cnt times for the product $prod\n";
2659                     $err++
2660                 }
2661             }
2662         }
2663         die if $err > 0;
2664     }
2665
2666     # Massage the result
2667
2668     # If we depend on a header file or a perl module, add an inclusion of
2669     # its directory to allow smoothe inclusion
2670     foreach my $dest (keys %{$unified_info{depends}}) {
2671         next if $dest eq "";
2672         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2673             next unless $d =~ /\.(h|pm)$/;
2674             # Take into account when a dependency uses the inclusion|module
2675             # syntax
2676             my $i = $d =~ m/\|/ ? $` : dirname($d);
2677             my $spot =
2678                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2679                 ? 'build' : 'source';
2680             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2681                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2682         }
2683     }
2684
2685     # Go through all intermediary files and change their names to something that
2686     # reflects what they will be built for.  Note that for some source files,
2687     # this leads to duplicate object files because they are used multiple times.
2688     # the goal is to rename all object files according to this scheme:
2689     #    {productname}-{midfix}-{origobjname}.[o|res]
2690     # the {midfix} is a keyword indicating the type of product, which is mostly
2691     # valuable for libraries since they come in two forms.
2692     #
2693     # This also reorganises the {sources} and {shared_sources} so that the
2694     # former only contains ALL object files that are supposed to end up in
2695     # static libraries and programs, while the latter contains ALL object files
2696     # that are supposed to end up in shared libraries and DSOs.
2697     # The main reason for having two different source structures is to allow
2698     # the same name to be used for the static and the shared variants of a
2699     # library.
2700     {
2701         # Take copies so we don't get interference from added stuff
2702         my %unified_copy = ();
2703         foreach (('sources', 'shared_sources')) {
2704             $unified_copy{$_} = { %{$unified_info{$_}} }
2705                 if defined($unified_info{$_});
2706             delete $unified_info{$_};
2707         }
2708         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2709             # $intent serves multi purposes:
2710             # - give a prefix for the new object files names
2711             # - in the case of libraries, rearrange the object files so static
2712             #   libraries use the 'sources' structure exclusively, while shared
2713             #   libraries use the 'shared_sources' structure exclusively.
2714             my $intent = {
2715                 programs  => { bin    => { src => [ 'sources' ],
2716                                            dst => 'sources' } },
2717                 libraries => { lib    => { src => [ 'sources' ],
2718                                            dst => 'sources' },
2719                                shlib  => { prodselect =>
2720                                                sub { grep !/\.a$/, @_ },
2721                                            src => [ 'sources',
2722                                                     'shared_sources' ],
2723                                            dst => 'shared_sources' } },
2724                 modules   => { dso    => { src => [ 'sources' ],
2725                                            dst => 'sources' } },
2726                 scripts   => { script => { src => [ 'sources' ],
2727                                            dst => 'sources' } }
2728                } -> {$prodtype};
2729             foreach my $kind (keys %$intent) {
2730                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2731                              && $disabled{shared});
2732
2733                 my @src = @{$intent->{$kind}->{src}};
2734                 my $dst = $intent->{$kind}->{dst};
2735                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2736                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2737                     # %prod_sources has all applicable objects as keys, and
2738                     # their corresponding sources as values
2739                     my %prod_sources =
2740                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2741                         map { keys %{$unified_copy{$_}->{$prod}} }
2742                         @src;
2743                     foreach (keys %prod_sources) {
2744                         # Only affect object files and resource files,
2745                         # the others simply get a new value
2746                         # (+1 instead of -1)
2747                         if ($_ =~ /\.(o|res)$/) {
2748                             (my $prodname = $prod) =~ s|\.a$||;
2749                             my $newobj =
2750                                 catfile(dirname($_),
2751                                         basename($prodname)
2752                                             . '-' . $kind
2753                                             . '-' . basename($_));
2754                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2755                             foreach my $src (@{$prod_sources{$_}}) {
2756                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2757                                 # Adjust source attributes
2758                                 my $attrs = $unified_info{attributes}->{sources};
2759                                 if (defined $attrs->{$prod}
2760                                     && defined $attrs->{$prod}->{$_}) {
2761                                     $attrs->{$prod}->{$newobj} =
2762                                         $attrs->{$prod}->{$_};
2763                                     delete $attrs->{$prod}->{$_};
2764                                 }
2765                                 foreach my $objsrc (keys %{$attrs->{$_} // {}}) {
2766                                     $attrs->{$newobj}->{$objsrc} =
2767                                         $attrs->{$_}->{$objsrc};
2768                                     delete $attrs->{$_}->{$objsrc};
2769                                 }
2770                             }
2771                             # Adjust dependencies
2772                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2773                                 $unified_info{depends}->{$_}->{$deps} = -1;
2774                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2775                             }
2776                             # Adjust includes
2777                             foreach my $k (('source', 'build')) {
2778                                 next unless
2779                                     defined($unified_info{includes}->{$_}->{$k});
2780                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2781                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2782                             }
2783                         } else {
2784                             $unified_info{$dst}->{$prod}->{$_} = 1;
2785                         }
2786                     }
2787                 }
2788             }
2789         }
2790     }
2791
2792     # At this point, we have a number of sources with the value -1.  They
2793     # aren't part of the local build and are probably meant for a different
2794     # platform, and can therefore be cleaned away.  That happens when making
2795     # %unified_info more efficient below.
2796
2797     ### Make unified_info a bit more efficient
2798     # One level structures
2799     foreach (("programs", "libraries", "modules", "scripts", "targets")) {
2800         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2801     }
2802     # Two level structures
2803     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends",
2804                      "imagedocs", "htmldocs", "mandocs")) {
2805         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2806             my @items =
2807                 sort
2808                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2809                 keys %{$unified_info{$l1}->{$l2}};
2810             if (@items) {
2811                 $unified_info{$l1}->{$l2} = [ @items ];
2812             } else {
2813                 delete $unified_info{$l1}->{$l2};
2814             }
2815         }
2816     }
2817     # Defines
2818     foreach my $dest (sort keys %{$unified_info{defines}}) {
2819         $unified_info{defines}->{$dest}
2820             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2821                 sort keys %{$unified_info{defines}->{$dest}} ];
2822     }
2823     # Includes
2824     foreach my $dest (sort keys %{$unified_info{includes}}) {
2825         if (defined($unified_info{includes}->{$dest}->{build})) {
2826             my @source_includes = ();
2827             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2828                 if defined($unified_info{includes}->{$dest}->{source});
2829             $unified_info{includes}->{$dest} =
2830                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2831             foreach my $inc (@source_includes) {
2832                 push @{$unified_info{includes}->{$dest}}, $inc
2833                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2834             }
2835         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2836             $unified_info{includes}->{$dest} =
2837                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2838         } else {
2839             delete $unified_info{includes}->{$dest};
2840         }
2841     }
2842
2843     # For convenience collect information regarding directories where
2844     # files are generated, those generated files and the end product
2845     # they end up in where applicable.  Then, add build rules for those
2846     # directories
2847     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2848                      "dso" => [ @{$unified_info{modules}} ],
2849                      "bin" => [ @{$unified_info{programs}} ],
2850                      "script" => [ @{$unified_info{scripts}} ],
2851                      "docs" => [ (map { @{$unified_info{imagedocs}->{$_} // []} }
2852                                   keys %{$unified_info{imagedocs} // {}}),
2853                                  (map { @{$unified_info{htmldocs}->{$_} // []} }
2854                                   keys %{$unified_info{htmldocs} // {}}),
2855                                  (map { @{$unified_info{mandocs}->{$_} // []} }
2856                                   keys %{$unified_info{mandocs} // {}}) ] );
2857     foreach my $type (sort keys %loopinfo) {
2858         foreach my $product (@{$loopinfo{$type}}) {
2859             my %dirs = ();
2860             my $pd = dirname($product);
2861
2862             foreach (@{$unified_info{sources}->{$product} // []},
2863                      @{$unified_info{shared_sources}->{$product} // []}) {
2864                 my $d = dirname($_);
2865
2866                 # We don't want to create targets for source directories
2867                 # when building out of source
2868                 next if ($config{sourcedir} ne $config{builddir}
2869                              && $d =~ m|^\Q$config{sourcedir}\E|);
2870                 # We already have a "test" target, and the current directory
2871                 # is just silly to make a target for
2872                 next if $d eq "test" || $d eq ".";
2873
2874                 $dirs{$d} = 1;
2875                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2876                     if $d ne $pd;
2877             }
2878             foreach (sort keys %dirs) {
2879                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2880                     $product;
2881             }
2882         }
2883     }
2884 }
2885
2886 # For the schemes that need it, we provide the old *_obj configs
2887 # from the *_asm_obj ones
2888 foreach (grep /_(asm|aux)_src$/, keys %target) {
2889     my $src = $_;
2890     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2891     $target{$obj} = $target{$src};
2892     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2893     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2894 }
2895
2896 # Write down our configuration where it fits #########################
2897
2898 my %template_vars = (
2899     config => \%config,
2900     target => \%target,
2901     disablables => \@disablables,
2902     disablables_int => \@disablables_int,
2903     disabled => \%disabled,
2904     withargs => \%withargs,
2905     unified_info => \%unified_info,
2906     tls => \@tls,
2907     dtls => \@dtls,
2908     makevars => [ sort keys %user ],
2909     disabled_info => \%disabled_info,
2910     user_crossable => \@user_crossable,
2911 );
2912 my $configdata_outname = 'configdata.pm';
2913 open CONFIGDATA, ">$configdata_outname.new"
2914     or die "Trying to create $configdata_outname.new: $!";
2915 my $configdata_tmplname = cleanfile($srcdir, "configdata.pm.in", $blddir);
2916 my $configdata_tmpl =
2917     OpenSSL::Template->new(TYPE => 'FILE', SOURCE => $configdata_tmplname);
2918 $configdata_tmpl->fill_in(
2919     FILENAME => $configdata_tmplname,
2920     OUTPUT => \*CONFIGDATA,
2921     HASH => { %template_vars,
2922               autowarntext => [
2923                   'WARNING: do not edit!',
2924                   "Generated by Configure from $configdata_tmplname",
2925               ] }
2926 ) or die $Text::Template::ERROR;
2927 close CONFIGDATA;
2928
2929 rename "$configdata_outname.new", $configdata_outname;
2930 if ($builder_platform eq 'unix') {
2931     my $mode = (0755 & ~umask);
2932     chmod $mode, 'configdata.pm'
2933         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2934 }
2935 print "Created $configdata_outname\n";
2936
2937 print "Running $configdata_outname\n";
2938 my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
2939 my $cmd = "$perlcmd $configdata_outname";
2940 #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2941 system($cmd);
2942 exit 1 if $? != 0;
2943
2944 $SIG{__DIE__} = $orig_death_handler;
2945
2946 print <<"EOF" if ($disabled{threads} eq "unavailable");
2947
2948 The library could not be configured for supporting multi-threaded
2949 applications as the compiler options required on this system are not known.
2950 See file INSTALL.md for details if you need multi-threading.
2951 EOF
2952
2953 print <<"EOF" if ($no_shared_warn);
2954
2955 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2956 platform, so we will pretend you gave the option 'no-pic', which also disables
2957 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2958 or position independent code, please let us know (but please first make sure
2959 you have tried with a current version of OpenSSL).
2960 EOF
2961
2962 print $banner;
2963
2964 exit(0);
2965
2966 ######################################################################
2967 #
2968 # Helpers and utility functions
2969 #
2970
2971 # Death handler, to print a helpful message in case of failure #######
2972 #
2973 sub death_handler {
2974     die @_ if $^S;              # To prevent the added message in eval blocks
2975     my $build_file = $config{build_file} // "build file";
2976     my @message = ( <<"_____", @_ );
2977
2978 Failure!  $build_file wasn't produced.
2979 Please read INSTALL.md and associated NOTES-* files.  You may also have to
2980 look over your available compiler tool chain or change your configuration.
2981
2982 _____
2983
2984     # Dying is terminal, so it's ok to reset the signal handler here.
2985     $SIG{__DIE__} = $orig_death_handler;
2986     die @message;
2987 }
2988
2989 # Configuration file reading #########################################
2990
2991 # Note: All of the helper functions are for lazy evaluation.  They all
2992 # return a CODE ref, which will return the intended value when evaluated.
2993 # Thus, whenever there's mention of a returned value, it's about that
2994 # intended value.
2995
2996 # Helper function to implement conditional value variants, with a default
2997 # plus additional values based on the value of $config{build_type}.
2998 # Arguments are given in hash table form:
2999 #
3000 #       picker(default => "Basic string: ",
3001 #              debug   => "debug",
3002 #              release => "release")
3003 #
3004 # When configuring with --debug, the resulting string will be
3005 # "Basic string: debug", and when not, it will be "Basic string: release"
3006 #
3007 # This can be used to create variants of sets of flags according to the
3008 # build type:
3009 #
3010 #       cflags => picker(default => "-Wall",
3011 #                        debug   => "-g -O0",
3012 #                        release => "-O3")
3013 #
3014 sub picker {
3015     my %opts = @_;
3016     return sub { add($opts{default} || (),
3017                      $opts{$config{build_type}} || ())->(); }
3018 }
3019
3020 # Helper function to combine several values of different types into one.
3021 # This is useful if you want to combine a string with the result of a
3022 # lazy function, such as:
3023 #
3024 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
3025 #
3026 sub combine {
3027     my @stuff = @_;
3028     return sub { add(@stuff)->(); }
3029 }
3030
3031 # Helper function to implement conditional values depending on the value
3032 # of $disabled{threads}.  Can be used as follows:
3033 #
3034 #       cflags => combine("-Wall", threads("-pthread"))
3035 #
3036 sub threads {
3037     my @flags = @_;
3038     return sub { add($disabled{threads} ? () : @flags)->(); }
3039 }
3040
3041 sub shared {
3042     my @flags = @_;
3043     return sub { add($disabled{shared} ? () : @flags)->(); }
3044 }
3045
3046 our $add_called = 0;
3047 # Helper function to implement adding values to already existing configuration
3048 # values.  It handles elements that are ARRAYs, CODEs and scalars
3049 sub _add {
3050     my $separator = shift;
3051
3052     # If there's any ARRAY in the collection of values OR the separator
3053     # is undef, we will return an ARRAY of combined values, otherwise a
3054     # string of joined values with $separator as the separator.
3055     my $found_array = !defined($separator);
3056
3057     my @values =
3058         map {
3059             my $res = $_;
3060             while (ref($res) eq "CODE") {
3061                 $res = $res->();
3062             }
3063             if (defined($res)) {
3064                 if (ref($res) eq "ARRAY") {
3065                     $found_array = 1;
3066                     @$res;
3067                 } else {
3068                     $res;
3069                 }
3070             } else {
3071                 ();
3072             }
3073     } (@_);
3074
3075     $add_called = 1;
3076
3077     if ($found_array) {
3078         [ @values ];
3079     } else {
3080         join($separator, grep { defined($_) && $_ ne "" } @values);
3081     }
3082 }
3083 sub add_before {
3084     my $separator = " ";
3085     if (ref($_[$#_]) eq "HASH") {
3086         my $opts = pop;
3087         $separator = $opts->{separator};
3088     }
3089     my @x = @_;
3090     sub { _add($separator, @x, @_) };
3091 }
3092 sub add {
3093     my $separator = " ";
3094     if (ref($_[$#_]) eq "HASH") {
3095         my $opts = pop;
3096         $separator = $opts->{separator};
3097     }
3098     my @x = @_;
3099     sub { _add($separator, @_, @x) };
3100 }
3101
3102 sub read_eval_file {
3103     my $fname = shift;
3104     my $content;
3105     my @result;
3106
3107     open F, "< $fname" or die "Can't open '$fname': $!\n";
3108     {
3109         undef local $/;
3110         $content = <F>;
3111     }
3112     close F;
3113     {
3114         local $@;
3115
3116         @result = ( eval $content );
3117         warn $@ if $@;
3118     }
3119     return wantarray ? @result : $result[0];
3120 }
3121
3122 # configuration reader, evaluates the input file as a perl script and expects
3123 # it to fill %targets with target configurations.  Those are then added to
3124 # %table.
3125 sub read_config {
3126     my $fname = shift;
3127     my %targets;
3128
3129     {
3130         # Protect certain tables from tampering
3131         local %table = ();
3132
3133         %targets = read_eval_file($fname);
3134     }
3135     my %preexisting = ();
3136     foreach (sort keys %targets) {
3137         $preexisting{$_} = 1 if $table{$_};
3138     }
3139     die <<"EOF",
3140 The following config targets from $fname
3141 shadow pre-existing config targets with the same name:
3142 EOF
3143         map { "  $_\n" } sort keys %preexisting
3144         if %preexisting;
3145
3146
3147     # For each target, check that it's configured with a hash table.
3148     foreach (keys %targets) {
3149         if (ref($targets{$_}) ne "HASH") {
3150             if (ref($targets{$_}) eq "") {
3151                 warn "Deprecated target configuration for $_, ignoring...\n";
3152             } else {
3153                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3154             }
3155             delete $targets{$_};
3156         } else {
3157             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3158         }
3159     }
3160
3161     %table = (%table, %targets);
3162
3163 }
3164
3165 # configuration resolver.  Will only resolve all the lazy evaluation
3166 # codeblocks for the chosen target and all those it inherits from,
3167 # recursively
3168 sub resolve_config {
3169     my $target = shift;
3170     my @breadcrumbs = @_;
3171
3172 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3173
3174     if (grep { $_ eq $target } @breadcrumbs) {
3175         die "inherit_from loop!  target backtrace:\n  "
3176             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3177     }
3178
3179     if (!defined($table{$target})) {
3180         warn "Warning! target $target doesn't exist!\n";
3181         return ();
3182     }
3183     # Recurse through all inheritances.  They will be resolved on the
3184     # fly, so when this operation is done, they will all just be a
3185     # bunch of attributes with string values.
3186     # What we get here, though, are keys with references to lists of
3187     # the combined values of them all.  We will deal with lists after
3188     # this stage is done.
3189     my %combined_inheritance = ();
3190     if ($table{$target}->{inherit_from}) {
3191         my @inherit_from =
3192             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3193         foreach (@inherit_from) {
3194             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3195
3196             # 'template' is a marker that's considered private to
3197             # the config that had it.
3198             delete $inherited_config{template};
3199
3200             foreach (keys %inherited_config) {
3201                 if (!$combined_inheritance{$_}) {
3202                     $combined_inheritance{$_} = [];
3203                 }
3204                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3205             }
3206         }
3207     }
3208
3209     # We won't need inherit_from in this target any more, since we've
3210     # resolved all the inheritances that lead to this
3211     delete $table{$target}->{inherit_from};
3212
3213     # Now is the time to deal with those lists.  Here's the place to
3214     # decide what shall be done with those lists, all based on the
3215     # values of the target we're currently dealing with.
3216     # - If a value is a coderef, it will be executed with the list of
3217     #   inherited values as arguments.
3218     # - If the corresponding key doesn't have a value at all or is the
3219     #   empty string, the inherited value list will be run through the
3220     #   default combiner (below), and the result becomes this target's
3221     #   value.
3222     # - Otherwise, this target's value is assumed to be a string that
3223     #   will simply override the inherited list of values.
3224     my $default_combiner = add();
3225
3226     my %all_keys =
3227         map { $_ => 1 } (keys %combined_inheritance,
3228                          keys %{$table{$target}});
3229
3230     sub process_values {
3231         my $object    = shift;
3232         my $inherited = shift;  # Always a [ list ]
3233         my $target    = shift;
3234         my $entry     = shift;
3235
3236         $add_called = 0;
3237
3238         while(ref($object) eq "CODE") {
3239             $object = $object->(@$inherited);
3240         }
3241         if (!defined($object)) {
3242             return ();
3243         }
3244         elsif (ref($object) eq "ARRAY") {
3245             local $add_called;  # To make sure recursive calls don't affect it
3246             return [ map { process_values($_, $inherited, $target, $entry) }
3247                      @$object ];
3248         } elsif (ref($object) eq "") {
3249             return $object;
3250         } else {
3251             die "cannot handle reference type ",ref($object)
3252                 ," found in target ",$target," -> ",$entry,"\n";
3253         }
3254     }
3255
3256     foreach my $key (sort keys %all_keys) {
3257         my $previous = $combined_inheritance{$key};
3258
3259         # Current target doesn't have a value for the current key?
3260         # Assign it the default combiner, the rest of this loop body
3261         # will handle it just like any other coderef.
3262         if (!exists $table{$target}->{$key}) {
3263             $table{$target}->{$key} = $default_combiner;
3264         }
3265
3266         $table{$target}->{$key} = process_values($table{$target}->{$key},
3267                                                $combined_inheritance{$key},
3268                                                $target, $key);
3269         unless(defined($table{$target}->{$key})) {
3270             delete $table{$target}->{$key};
3271         }
3272 #        if ($extra_checks &&
3273 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$key})) {
3274 #            warn "$key got replaced in $target\n";
3275 #        }
3276     }
3277
3278     # Finally done, return the result.
3279     return %{$table{$target}};
3280 }
3281
3282 sub usage
3283         {
3284         print STDERR $usage;
3285         print STDERR "\npick os/compiler from:\n";
3286         my $j=0;
3287         my $i;
3288         my $k=0;
3289         foreach $i (sort keys %table)
3290                 {
3291                 next if $table{$i}->{template};
3292                 next if $i =~ /^debug/;
3293                 $k += length($i) + 1;
3294                 if ($k > 78)
3295                         {
3296                         print STDERR "\n";
3297                         $k=length($i);
3298                         }
3299                 print STDERR $i . " ";
3300                 }
3301         foreach $i (sort keys %table)
3302                 {
3303                 next if $table{$i}->{template};
3304                 next if $i !~ /^debug/;
3305                 $k += length($i) + 1;
3306                 if ($k > 78)
3307                         {
3308                         print STDERR "\n";
3309                         $k=length($i);
3310                         }
3311                 print STDERR $i . " ";
3312                 }
3313         exit(1);
3314         }
3315
3316 sub compiler_predefined {
3317     state %predefined;
3318     my $cc = shift;
3319
3320     return () if $^O eq 'VMS';
3321
3322     die 'compiler_predefined called without a compiler command'
3323         unless $cc;
3324
3325     if (! $predefined{$cc}) {
3326
3327         $predefined{$cc} = {};
3328
3329         # collect compiler pre-defines from gcc or gcc-alike...
3330         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3331         while (my $l = <PIPE>) {
3332             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3333             $predefined{$cc}->{$1} = $2 // '';
3334         }
3335         close(PIPE);
3336     }
3337
3338     return %{$predefined{$cc}};
3339 }
3340
3341 sub which
3342 {
3343     my ($name)=@_;
3344
3345     if (eval { require IPC::Cmd; 1; }) {
3346         IPC::Cmd->import();
3347         return scalar IPC::Cmd::can_run($name);
3348     } else {
3349         # if there is $directories component in splitpath,
3350         # then it's not something to test with $PATH...
3351         return $name if (File::Spec->splitpath($name))[1];
3352
3353         foreach (File::Spec->path()) {
3354             my $fullpath = catfile($_, "$name$target{exe_extension}");
3355             if (-f $fullpath and -x $fullpath) {
3356                 return $fullpath;
3357             }
3358         }
3359     }
3360 }
3361
3362 sub env
3363 {
3364     my $name = shift;
3365     my %opts = @_;
3366
3367     unless ($opts{cacheonly}) {
3368         # Note that if $ENV{$name} doesn't exist or is undefined,
3369         # $config{perlenv}->{$name} will be created with the value
3370         # undef.  This is intentional.
3371
3372         $config{perlenv}->{$name} = $ENV{$name}
3373             if ! exists $config{perlenv}->{$name};
3374     }
3375     return $config{perlenv}->{$name};
3376 }
3377
3378 # Configuration printer ##############################################
3379
3380 sub print_table_entry
3381 {
3382     local $now_printing = shift;
3383     my %target = resolve_config($now_printing);
3384     my $type = shift;
3385
3386     # Don't print the templates
3387     return if $target{template};
3388
3389     my @sequence = (
3390         "sys_id",
3391         "cpp",
3392         "cppflags",
3393         "defines",
3394         "includes",
3395         "cc",
3396         "cflags",
3397         "ld",
3398         "lflags",
3399         "loutflag",
3400         "ex_libs",
3401         "bn_ops",
3402         "enable",
3403         "disable",
3404         "poly1035_asm_src",
3405         "thread_scheme",
3406         "perlasm_scheme",
3407         "dso_scheme",
3408         "shared_target",
3409         "shared_cflag",
3410         "shared_defines",
3411         "shared_ldflag",
3412         "shared_rcflag",
3413         "shared_extension",
3414         "dso_extension",
3415         "obj_extension",
3416         "exe_extension",
3417         "ranlib",
3418         "ar",
3419         "arflags",
3420         "aroutflag",
3421         "rc",
3422         "rcflags",
3423         "rcoutflag",
3424         "mt",
3425         "mtflags",
3426         "mtinflag",
3427         "mtoutflag",
3428         "multilib",
3429         "build_scheme",
3430         );
3431
3432     if ($type eq "TABLE") {
3433         print "\n";
3434         print "*** $now_printing\n";
3435         foreach (@sequence) {
3436             if (ref($target{$_}) eq "ARRAY") {
3437                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3438             } else {
3439                 printf "\$%-12s = %s\n", $_, $target{$_};
3440             }
3441         }
3442     } elsif ($type eq "HASH") {
3443         my $largest =
3444             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3445         print "    '$now_printing' => {\n";
3446         foreach (@sequence) {
3447             if ($target{$_}) {
3448                 if (ref($target{$_}) eq "ARRAY") {
3449                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3450                 } else {
3451                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3452                 }
3453             }
3454         }
3455         print "    },\n";
3456     }
3457 }
3458
3459 # Utility routines ###################################################
3460
3461 # On VMS, if the given file is a logical name, File::Spec::Functions
3462 # will consider it an absolute path.  There are cases when we want a
3463 # purely syntactic check without checking the environment.
3464 sub isabsolute {
3465     my $file = shift;
3466
3467     # On non-platforms, we just use file_name_is_absolute().
3468     return file_name_is_absolute($file) unless $^O eq "VMS";
3469
3470     # If the file spec includes a device or a directory spec,
3471     # file_name_is_absolute() is perfectly safe.
3472     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3473
3474     # Here, we know the given file spec isn't absolute
3475     return 0;
3476 }
3477
3478 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3479 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3480 # realpath() requires that at least all path components except the last is an
3481 # existing directory.  On VMS, the last component of the directory spec must
3482 # exist.
3483 sub absolutedir {
3484     my $dir = shift;
3485
3486     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3487     # will return the volume name for the device, no matter what.  Also,
3488     # it will return an incorrect directory spec if the argument is a
3489     # directory that doesn't exist.
3490     if ($^O eq "VMS") {
3491         return rel2abs($dir);
3492     }
3493
3494     # We use realpath() on Unix, since no other will properly clean out
3495     # a directory spec.
3496     use Cwd qw/realpath/;
3497
3498     return realpath($dir);
3499 }
3500
3501 # Check if all paths are one and the same, using stat.  They must both exist
3502 # We need this for the cases when File::Spec doesn't detect case insensitivity
3503 # (File::Spec::Unix assumes case sensitivity)
3504 sub samedir {
3505     die "samedir expects two arguments\n" unless scalar @_ == 2;
3506
3507     my @stat0 = stat($_[0]);    # First argument
3508     my @stat1 = stat($_[1]);    # Second argument
3509
3510     die "Couldn't stat $_[0]" unless @stat0;
3511     die "Couldn't stat $_[1]" unless @stat1;
3512
3513     # Compare device number
3514     return 0 unless ($stat0[0] == $stat1[0]);
3515     # Compare "inode".  The perl manual recommends comparing as
3516     # string rather than as number.
3517     return 0 unless ($stat0[1] eq $stat1[1]);
3518
3519     return 1;                   # All the same
3520 }
3521
3522 sub quotify {
3523     my %processors = (
3524         perl    => sub { my $x = shift;
3525                          $x =~ s/([\\\$\@"])/\\$1/g;
3526                          return '"'.$x.'"'; },
3527         maybeshell => sub { my $x = shift;
3528                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3529                             if ($x ne $y || $x =~ m|\s|) {
3530                                 return '"'.$y.'"';
3531                             } else {
3532                                 return $x;
3533                             }
3534                         },
3535         );
3536     my $for = shift;
3537     my $processor =
3538         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3539
3540     return map { $processor->($_); } @_;
3541 }
3542
3543 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3544 # $filename is a file name to read from
3545 # $line_concat_cond_re is a regexp detecting a line continuation ending
3546 # $line_concat is a CODEref that takes care of concatenating two lines
3547 sub collect_from_file {
3548     my $filename = shift;
3549     my $line_concat_cond_re = shift;
3550     my $line_concat = shift;
3551
3552     open my $fh, $filename || die "unable to read $filename: $!\n";
3553     return sub {
3554         my $saved_line = "";
3555         $_ = "";
3556         while (<$fh>) {
3557             s|\R$||;
3558             if (defined $line_concat) {
3559                 $_ = $line_concat->($saved_line, $_);
3560                 $saved_line = "";
3561             }
3562             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3563                 $saved_line = $_;
3564                 next;
3565             }
3566             return $_;
3567         }
3568         die "$filename ending with continuation line\n" if $_;
3569         close $fh;
3570         return undef;
3571     }
3572 }
3573
3574 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3575 # $array is an ARRAYref of lines
3576 # $line_concat_cond_re is a regexp detecting a line continuation ending
3577 # $line_concat is a CODEref that takes care of concatenating two lines
3578 sub collect_from_array {
3579     my $array = shift;
3580     my $line_concat_cond_re = shift;
3581     my $line_concat = shift;
3582     my @array = (@$array);
3583
3584     return sub {
3585         my $saved_line = "";
3586         $_ = "";
3587         while (defined($_ = shift @array)) {
3588             s|\R$||;
3589             if (defined $line_concat) {
3590                 $_ = $line_concat->($saved_line, $_);
3591                 $saved_line = "";
3592             }
3593             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3594                 $saved_line = $_;
3595                 next;
3596             }
3597             return $_;
3598         }
3599         die "input text ending with continuation line\n" if $_;
3600         return undef;
3601     }
3602 }
3603
3604 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3605 # $lineiterator is a CODEref that delivers one line at a time.
3606 # All following arguments are regex/CODEref pairs, where the regexp detects a
3607 # line and the CODEref does something with the result of the regexp.
3608 sub collect_information {
3609     my $lineiterator = shift;
3610     my %collectors = @_;
3611
3612     while(defined($_ = $lineiterator->())) {
3613         s|\R$||;
3614         my $found = 0;
3615         if ($collectors{"BEFORE"}) {
3616             $collectors{"BEFORE"}->($_);
3617         }
3618         foreach my $re (keys %collectors) {
3619             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3620                 $collectors{$re}->($lineiterator);
3621                 $found = 1;
3622             };
3623         }
3624         if ($collectors{"OTHERWISE"}) {
3625             $collectors{"OTHERWISE"}->($lineiterator, $_)
3626                 unless $found || !defined $collectors{"OTHERWISE"};
3627         }
3628         if ($collectors{"AFTER"}) {
3629             $collectors{"AFTER"}->($_);
3630         }
3631     }
3632 }
3633
3634 # tokenize($line)
3635 # tokenize($line,$separator)
3636 # $line is a line of text to split up into tokens
3637 # $separator [optional] is a regular expression that separates the tokens,
3638 # the default being spaces.  Do not use quotes of any kind as separators,
3639 # that will give undefined results.
3640 # Returns a list of tokens.
3641 #
3642 # Tokens are divided by separator (spaces by default).  If the tokens include
3643 # the separators, they have to be quoted with single or double quotes.
3644 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3645 # with backslash.
3646 # Basically, the same quoting rules apply for " and ' as in any
3647 # Unix shell.
3648 sub tokenize {
3649     my $line = my $debug_line = shift;
3650     my $separator = shift // qr|\s+|;
3651     my @result = ();
3652
3653     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3654         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3655     }
3656
3657     while ($line =~ s|^${separator}||, $line ne "") {
3658         my $token = "";
3659     again:
3660         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3661         $token .= $1;
3662         $line = $2.$';
3663
3664         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3665             $token .= $1;
3666             $line = $';
3667             goto again;
3668         } elsif ($line =~ m/^'([^']*)'/) {
3669             $token .= $1;
3670             $line = $';
3671             goto again;
3672         }
3673         push @result, $token;
3674     }
3675
3676     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3677         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3678         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3679     }
3680     return @result;
3681 }