Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the OpenSSL license (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 require 5.10.0;
  13 use strict;
  14 use File::Basename;
  15 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs/;
  16 use File::Path qw/mkpath/;
  17 use if $^O ne "VMS", 'File::Glob' => qw/glob/;
  18
  19 # see INSTALL for instructions.
  20
  21 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  22
  23 # Options:
  24 #
  25 # --config      add the given configuration file, which will be read after
  26 #               any "Configurations*" files that are found in the same
  27 #               directory as this script.
  28 # --prefix      prefix for the OpenSSL installation, which includes the
  29 #               directories bin, lib, include, share/man, share/doc/openssl
  30 #               This becomes the value of INSTALLTOP in Makefile
  31 #               (Default: /usr/local)
  32 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  33 #               If it's a relative directory, it will be added on the directory
  34 #               given with --prefix.
  35 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  36 #               (Default: PREFIX/ssl)
  37 #
  38 # --cross-compile-prefix Add specified prefix to binutils components.
  39 #
  40 # --api         One of 0.9.8, 1.0.0 or 1.1.0.  Do not compile support for
  41 #               interfaces deprecated as of the specified OpenSSL version.
  42 #
  43 # no-hw-xxx     do not compile support for specific crypto hardware.
  44 #               Generic OpenSSL-style methods relating to this support
  45 #               are always compiled but return NULL if the hardware
  46 #               support isn't compiled.
  47 # no-hw         do not compile support for any crypto hardware.
  48 # [no-]threads  [don't] try to create a library that is suitable for
  49 #               multithreaded applications (default is "threads" if we
  50 #               know how to do it)
  51 # [no-]shared   [don't] try to create shared libraries when supported.
  52 # [no-]pic      [don't] try to build position independent code when supported.
  53 #               If disabled, it also disables shared and dynamic-engine.
  54 # no-asm        do not use assembler
  55 # no-dso        do not compile in any native shared-library methods. This
  56 #               will ensure that all methods just return NULL.
  57 # no-egd        do not compile support for the entropy-gathering daemon APIs
  58 # [no-]zlib     [don't] compile support for zlib compression.
  59 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  60 #               library and will be loaded in run-time by the OpenSSL library.
  61 # sctp          include SCTP support
  62 # 386           generate 80386 code
  63 # enable-weak-ssl-ciphers
  64 #               Enable weak ciphers that are disabled by default. This currently
  65 #               only includes RC4 based ciphers.
  66 # no-sse2       disables IA-32 SSE2 code, above option implies no-sse2
  67 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  68 # -<xxx> +<xxx> compiler options are passed through
  69 # -static       while -static is also a pass-through compiler option (and
  70 #               as such is limited to environments where it's actually
  71 #               meaningful), it triggers a number configuration options,
  72 #               namely no-dso, no-pic, no-shared and no-threads. It is
  73 #               argued that the only reason to produce statically linked
  74 #               binaries (and in context it means executables linked with
  75 #               -static flag, and not just executables linked with static
  76 #               libcrypto.a) is to eliminate dependency on specific run-time,
  77 #               a.k.a. libc version. The mentioned config options are meant
  78 #               to achieve just that. Unfortunately on Linux it's impossible
  79 #               to eliminate the dependency completely for openssl executable
  80 #               because of getaddrinfo and gethostbyname calls, which can
  81 #               invoke dynamically loadable library facility anyway to meet
  82 #               the lookup requests. For this reason on Linux statically
  83 #               linked openssl executable has rather debugging value than
  84 #               production quality.
  85 #
  86 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
  87 #               provided to stack calls. Generates unique stack functions for
  88 #               each possible stack type.
  89 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  90 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  91 # Following are set automatically by this script
  92 #
  93 # MD5_ASM       use some extra md5 assembler,
  94 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
  95 # RMD160_ASM    use some extra ripemd160 assembler,
  96 # SHA256_ASM    sha256_block is implemented in assembler
  97 # SHA512_ASM    sha512_block is implemented in assembler
  98 # AES_ASM       AES_[en|de]crypt is implemented in assembler
  99
 100 # Minimum warning options... any contributions to OpenSSL should at least get
 101 # past these.
 102
 103 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 104 my $gcc_devteam_warn = "-DDEBUG_UNUSED"
 105         # -DPEDANTIC complements -pedantic and is meant to mask code that
 106         # is not strictly standard-compliant and/or implementation-specific,
 107         # e.g. inline assembly, disregards to alignment requirements, such
 108         # that -pedantic would complain about. Incidentally -DPEDANTIC has
 109         # to be used even in sanitized builds, because sanitizer too is
 110         # supposed to and does take notice of non-standard behaviour. Then
 111         # -pedantic with pre-C9x compiler would also complain about 'long
 112         # long' not being supported. As 64-bit algorithms are common now,
 113         # it grew impossible to resolve this without sizeable additional
 114         # code, so we just tell compiler to be pedantic about everything
 115         # but 'long long' type.
 116         . " -DPEDANTIC -pedantic -Wno-long-long"
 117         . " -Wall"
 118         . " -Wsign-compare"
 119         . " -Wmissing-prototypes"
 120         . " -Wshadow"
 121         . " -Wformat"
 122         . " -Wtype-limits"
 123         . " -Werror"
 124         ;
 125
 126 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 127 # TODO(openssl-team): fix problems and investigate if (at least) the
 128 # following warnings can also be enabled:
 129 #       -Wswitch-enum
 130 #       -Wcast-align
 131 #       -Wunreachable-code
 132 #       -Wlanguage-extension-token -- no, we use asm()
 133 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 134 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 135 my $clang_devteam_warn = ""
 136         . " -Qunused-arguments"
 137         . " -Wextra"
 138         . " -Wno-unused-parameter"
 139         . " -Wno-missing-field-initializers"
 140         . " -Wno-language-extension-token"
 141         . " -Wno-extended-offsetof"
 142         . " -Wconditional-uninitialized"
 143         . " -Wincompatible-pointer-types-discards-qualifiers"
 144         . " -Wmissing-variable-declarations"
 145         ;
 146
 147 # This adds backtrace information to the memory leak info.  Is only used
 148 # when crypto-mdebug-backtrace is enabled.
 149 my $memleak_devteam_backtrace = "-rdynamic";
 150
 151 my $strict_warnings = 0;
 152
 153 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 154 # which would cover all BSD flavors. -pthread applies to them all,
 155 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 156 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 157 # which has to be accompanied by explicit -D_THREAD_SAFE and
 158 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 159 # seems to be sufficient?
 160 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 161
 162 #
 163 # API compatibility name to version number mapping.
 164 #
 165 my $maxapi = "1.1.0";           # API for "no-deprecated" builds
 166 my $apitable = {
 167     "1.1.0" => "0x10100000L",
 168     "1.0.0" => "0x10000000L",
 169     "0.9.8" => "0x00908000L",
 170 };
 171
 172 our %table = ();
 173 our %config = ();
 174 our %withargs = ();
 175
 176 # Forward declarations ###############################################
 177
 178 # read_config(filename)
 179 #
 180 # Reads a configuration file and populates %table with the contents
 181 # (which the configuration file places in %targets).
 182 sub read_config;
 183
 184 # resolve_config(target)
 185 #
 186 # Resolves all the late evaluations, inheritances and so on for the
 187 # chosen target and any target it inherits from.
 188 sub resolve_config;
 189
 190
 191 # Information collection #############################################
 192
 193 # Unified build supports separate build dir
 194 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 195 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 196 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 197
 198 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 199
 200 $config{sourcedir} = abs2rel($srcdir);
 201 $config{builddir} = abs2rel($blddir);
 202
 203 # Collect reconfiguration information if needed
 204 my @argvcopy=@ARGV;
 205
 206 if (grep /^reconf(igure)?$/, @argvcopy) {
 207     if (-f "./configdata.pm") {
 208         my $file = "./configdata.pm";
 209         unless (my $return = do $file) {
 210             die "couldn't parse $file: $@" if $@;
 211             die "couldn't do $file: $!"    unless defined $return;
 212             die "couldn't run $file"       unless $return;
 213         }
 214
 215         @argvcopy = defined($configdata::config{perlargv}) ?
 216             @{$configdata::config{perlargv}} : ();
 217         die "Incorrect data to reconfigure, please do a normal configuration\n"
 218             if (grep(/^reconf/,@argvcopy));
 219         $ENV{CROSS_COMPILE} = $configdata::config{cross_compile_prefix}
 220             if defined($configdata::config{cross_compile_prefix});
 221         $ENV{CC} = $configdata::config{cc}
 222             if defined($configdata::config{cc});
 223         $ENV{BUILDFILE} = $configdata::config{build_file}
 224             if defined($configdata::config{build_file});
 225         $ENV{$local_config_envname} = $configdata::config{local_config_dir}
 226             if defined($configdata::config{local_config_dir});
 227
 228         print "Reconfiguring with: ", join(" ",@argvcopy), "\n";
 229         print "    CROSS_COMPILE = ",$ENV{CROSS_COMPILE},"\n"
 230             if $ENV{CROSS_COMPILE};
 231         print "    CC = ",$ENV{CC},"\n" if $ENV{CC};
 232         print "    BUILDFILE = ",$ENV{BUILDFILE},"\n" if $ENV{BUILDFILE};
 233         print "    $local_config_envname = ",$ENV{$local_config_envname},"\n"
 234             if $ENV{$local_config_envname};
 235     } else {
 236         die "Insufficient data to reconfigure, please do a normal configuration\n";
 237     }
 238 }
 239
 240 $config{perlargv} = [ @argvcopy ];
 241
 242 # Collect version numbers
 243 $config{version} = "unknown";
 244 $config{version_num} = "unknown";
 245 $config{shlib_version_number} = "unknown";
 246 $config{shlib_version_history} = "unknown";
 247
 248 collect_information(
 249     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 250     qr/OPENSSL.VERSION.TEXT.*OpenSSL (\S+) / => sub { $config{version} = $1; },
 251     qr/OPENSSL.VERSION.NUMBER.*(0x\S+)/      => sub { $config{version_num}=$1 },
 252     qr/SHLIB_VERSION_NUMBER *"([^"]+)"/      => sub { $config{shlib_version_number}=$1 },
 253     qr/SHLIB_VERSION_HISTORY *"([^"]*)"/     => sub { $config{shlib_version_history}=$1 }
 254     );
 255 if ($config{shlib_version_history} ne "") { $config{shlib_version_history} .= ":"; }
 256
 257 ($config{major}, $config{minor})
 258     = ($config{version} =~ /^([0-9]+)\.([0-9\.]+)/);
 259 ($config{shlib_major}, $config{shlib_minor})
 260     = ($config{shlib_version_number} =~ /^([0-9]+)\.([0-9\.]+)/);
 261 die "erroneous version information in opensslv.h: ",
 262     "$config{major}, $config{minor}, $config{shlib_major}, $config{shlib_minor}\n"
 263     if ($config{major} eq "" || $config{minor} eq ""
 264         || $config{shlib_major} eq "" ||  $config{shlib_minor} eq "");
 265
 266 # Collect target configurations
 267
 268 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 269 foreach (sort glob($pattern)) {
 270     &read_config($_);
 271 }
 272
 273 if (defined $ENV{$local_config_envname}) {
 274     if ($^O eq 'VMS') {
 275         # VMS environment variables are logical names,
 276         # which can be used as is
 277         $pattern = $local_config_envname . ':' . '*.conf';
 278     } else {
 279         $pattern = catfile($ENV{$local_config_envname}, '*.conf');
 280     }
 281
 282     foreach (sort glob($pattern)) {
 283         &read_config($_);
 284     }
 285 }
 286
 287
 288 print "Configuring OpenSSL version $config{version} ($config{version_num})\n";
 289
 290 $config{prefix}="";
 291 $config{openssldir}="";
 292 $config{processor}="";
 293 $config{libdir}="";
 294 $config{cross_compile_prefix}="";
 295 $config{fipslibdir}="/usr/local/ssl/fips-2.0/lib/";
 296 my $nofipscanistercheck=0;
 297 $config{baseaddr}="0xFB00000";
 298 my $auto_threads=1;    # enable threads automatically? true by default
 299 my $default_ranlib;
 300 $config{fips}=0;
 301
 302 # Top level directories to build
 303 $config{dirs} = [ "crypto", "ssl", "engines", "apps", "test", "util", "tools", "fuzz" ];
 304 # crypto/ subdirectories to build
 305 $config{sdirs} = [
 306     "objects",
 307     "md2", "md4", "md5", "sha", "mdc2", "hmac", "ripemd", "whrlpool", "poly1305", "blake2",
 308     "des", "aes", "rc2", "rc4", "rc5", "idea", "bf", "cast", "camellia", "seed", "chacha", "modes",
 309     "bn", "ec", "rsa", "dsa", "dh", "dso", "engine",
 310     "buffer", "bio", "stack", "lhash", "rand", "err",
 311     "evp", "asn1", "pem", "x509", "x509v3", "conf", "txt_db", "pkcs7", "pkcs12", "comp", "ocsp", "ui",
 312     "cms", "ts", "srp", "cmac", "ct", "async", "kdf"
 313     ];
 314
 315 # Known TLS and DTLS protocols
 316 my @tls = qw(ssl3 tls1 tls1_1 tls1_2);
 317 my @dtls = qw(dtls1 dtls1_2);
 318
 319 # Explicitly known options that are possible to disable.  They can
 320 # be regexps, and will be used like this: /^no-${option}$/
 321 # For developers: keep it sorted alphabetically
 322
 323 my @disablables = (
 324     "afalgeng",
 325     "asan",
 326     "asm",
 327     "async",
 328     "autoalginit",
 329     "autoerrinit",
 330     "bf",
 331     "blake2",
 332     "camellia",
 333     "capieng",
 334     "cast",
 335     "chacha",
 336     "cmac",
 337     "cms",
 338     "comp",
 339     "crypto-mdebug",
 340     "crypto-mdebug-backtrace",
 341     "ct",
 342     "deprecated",
 343     "des",
 344     "dgram",
 345     "dh",
 346     "dsa",
 347     "dso",
 348     "dtls",
 349     "dynamic-engine",
 350     "ec",
 351     "ec2m",
 352     "ecdh",
 353     "ecdsa",
 354     "ec_nistp_64_gcc_128",
 355     "egd",
 356     "engine",
 357     "err",
 358     "filenames",
 359     "fuzz-libfuzzer",
 360     "fuzz-afl",
 361     "gost",
 362     "heartbeats",
 363     "hw(-.+)?",
 364     "idea",
 365     "makedepend",
 366     "md2",
 367     "md4",
 368     "mdc2",
 369     "msan",
 370     "multiblock",
 371     "nextprotoneg",
 372     "ocb",
 373     "ocsp",
 374     "pic",
 375     "poly1305",
 376     "posix-io",
 377     "psk",
 378     "rc2",
 379     "rc4",
 380     "rc5",
 381     "rdrand",
 382     "rfc3779",
 383     "rmd160",
 384     "scrypt",
 385     "sctp",
 386     "seed",
 387     "shared",
 388     "sock",
 389     "srp",
 390     "srtp",
 391     "sse2",
 392     "ssl",
 393     "ssl-trace",
 394     "static-engine",
 395     "stdio",
 396     "threads",
 397     "tls",
 398     "ts",
 399     "ubsan",
 400     "ui",
 401     "unit-test",
 402     "whirlpool",
 403     "weak-ssl-ciphers",
 404     "zlib",
 405     "zlib-dynamic",
 406     );
 407 foreach my $proto ((@tls, @dtls))
 408         {
 409         push(@disablables, $proto);
 410         push(@disablables, "$proto-method");
 411         }
 412
 413 my %deprecated_disablables = (
 414     "ssl2" => undef,
 415     "buf-freelists" => undef,
 416     "ripemd" => "rmd160"
 417     );
 418
 419 # All of the following is disabled by default (RC5 was enabled before 0.9.8):
 420
 421 our %disabled = ( # "what"         => "comment"
 422                   "asan"                => "default",
 423                   "crypto-mdebug"       => "default",
 424                   "crypto-mdebug-backtrace" => "default",
 425                   "ec_nistp_64_gcc_128" => "default",
 426                   "egd"                 => "default",
 427                   "fuzz-libfuzzer"      => "default",
 428                   "fuzz-afl"            => "default",
 429                   "heartbeats"          => "default",
 430                   "md2"                 => "default",
 431                   "msan"                => "default",
 432                   "rc5"                 => "default",
 433                   "sctp"                => "default",
 434                   "ssl-trace"           => "default",
 435                   "ssl3"                => "default",
 436                   "ssl3-method"         => "default",
 437                   "ubsan"               => "default",
 438                   "unit-test"           => "default",
 439                   "weak-ssl-ciphers"    => "default",
 440                   "zlib"                => "default",
 441                   "zlib-dynamic"        => "default",
 442                 );
 443
 444 # Note: => pair form used for aesthetics, not to truly make a hash table
 445 my @disable_cascades = (
 446     # "what"            => [ "cascade", ... ]
 447     sub { $config{processor} eq "386" }
 448                         => [ "sse2" ],
 449     "ssl"               => [ "ssl3" ],
 450     "ssl3-method"       => [ "ssl3" ],
 451     "zlib"              => [ "zlib-dynamic" ],
 452     "des"               => [ "mdc2" ],
 453     "ec"                => [ "ecdsa", "ecdh" ],
 454
 455     "dgram"             => [ "dtls", "sctp" ],
 456     "sock"              => [ "dgram" ],
 457     "dtls"              => [ @dtls ],
 458
 459     # SSL 3.0, (D)TLS 1.0 and TLS 1.1 require MD5 and SHA
 460     "md5"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
 461     "sha"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
 462
 463     # Additionally, SSL 3.0 requires either RSA or DSA+DH
 464     sub { $disabled{rsa}
 465           && ($disabled{dsa} || $disabled{dh}); }
 466                         => [ "ssl" ],
 467
 468     # (D)TLS 1.0 and TLS 1.1 also require either RSA or DSA+DH
 469     # or ECDSA + ECDH.  (D)TLS 1.2 has this requirement as well.
 470     # (XXX: We don't support PSK-only builds).
 471     sub { $disabled{rsa}
 472           && ($disabled{dsa} || $disabled{dh})
 473           && ($disabled{ecdsa} || $disabled{ecdh}); }
 474                         => [ "tls1", "tls1_1", "tls1_2",
 475                              "dtls1", "dtls1_2" ],
 476
 477     "tls"               => [ @tls ],
 478
 479     # SRP and HEARTBEATS require TLSEXT
 480     "tlsext"            => [ "srp", "heartbeats" ],
 481
 482     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 483
 484     # Without DSO, we can't load dynamic engines, so don't build them dynamic
 485     "dso"               => [ "dynamic-engine" ],
 486
 487     # Without position independent code, there can be no shared libraries or DSOs
 488     "pic"               => [ "shared" ],
 489     "shared"            => [ "dynamic-engine" ],
 490     "engine"            => [ "afalgeng" ],
 491
 492     # no-autoalginit is only useful when building non-shared
 493     "autoalginit"       => [ "shared", "apps" ],
 494
 495     "stdio"             => [ "apps", "capieng" ],
 496     "apps"              => [ "tests" ],
 497     "comp"              => [ "zlib" ],
 498     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 499
 500     sub { !$disabled{"msan"} } => [ "asm" ],
 501     );
 502
 503 # Avoid protocol support holes.  Also disable all versions below N, if version
 504 # N is disabled while N+1 is enabled.
 505 #
 506 my @list = (reverse @tls);
 507 while ((my $first, my $second) = (shift @list, shift @list)) {
 508     last unless @list;
 509     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 510                               => [ @list ] );
 511     unshift @list, $second;
 512 }
 513 my @list = (reverse @dtls);
 514 while ((my $first, my $second) = (shift @list, shift @list)) {
 515     last unless @list;
 516     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 517                               => [ @list ] );
 518     unshift @list, $second;
 519 }
 520
 521 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 522 # To remove something from %disabled, use "enable-foo".
 523 # For symmetry, "disable-foo" is a synonym for "no-foo".
 524
 525 my $no_sse2=0;
 526
 527 &usage if ($#ARGV < 0);
 528
 529 my $user_cflags="";
 530 my @user_defines=();
 531 $config{openssl_api_defines}=[];
 532 $config{openssl_algorithm_defines}=[];
 533 $config{openssl_thread_defines}=[];
 534 $config{openssl_sys_defines}=[];
 535 $config{openssl_other_defines}=[];
 536 my $libs="";
 537 my $target="";
 538 $config{options}="";
 539 $config{build_type} = "release";
 540
 541 my %unsupported_options = ();
 542 my %deprecated_options = ();
 543 while (@argvcopy)
 544         {
 545         $_ = shift @argvcopy;
 546         # VMS is a case insensitive environment, and depending on settings
 547         # out of our control, we may receive options uppercased.  Let's
 548         # downcase at least the part before any equal sign.
 549         if ($^O eq "VMS")
 550                 {
 551                 s/^([^=]*)/lc($1)/e;
 552                 }
 553         s /^-no-/no-/; # some people just can't read the instructions
 554
 555         # rewrite some options in "enable-..." form
 556         s /^-?-?shared$/enable-shared/;
 557         s /^sctp$/enable-sctp/;
 558         s /^threads$/enable-threads/;
 559         s /^zlib$/enable-zlib/;
 560         s /^zlib-dynamic$/enable-zlib-dynamic/;
 561
 562         if (/^(no|disable|enable)-(.+)$/)
 563                 {
 564                 my $word = $2;
 565                 if (!exists $deprecated_disablables{$word}
 566                         && !grep { $word =~ /^${_}$/ } @disablables)
 567                         {
 568                         $unsupported_options{$_} = 1;
 569                         next;
 570                         }
 571                 }
 572         if (/^no-(.+)$/ || /^disable-(.+)$/)
 573                 {
 574                 foreach my $proto ((@tls, @dtls))
 575                         {
 576                         if ($1 eq "$proto-method")
 577                                 {
 578                                 $disabled{"$proto"} = "option($proto-method)";
 579                                 last;
 580                                 }
 581                         }
 582                 if ($1 eq "dtls")
 583                         {
 584                         foreach my $proto (@dtls)
 585                                 {
 586                                 $disabled{$proto} = "option(dtls)";
 587                                 }
 588                         $disabled{"dtls"} = "option(dtls)";
 589                         }
 590                 elsif ($1 eq "ssl")
 591                         {
 592                         # Last one of its kind
 593                         $disabled{"ssl3"} = "option(ssl)";
 594                         }
 595                 elsif ($1 eq "tls")
 596                         {
 597                         # XXX: Tests will fail if all SSL/TLS
 598                         # protocols are disabled.
 599                         foreach my $proto (@tls)
 600                                 {
 601                                 $disabled{$proto} = "option(tls)";
 602                                 }
 603                         }
 604                 elsif ($1 eq "static-engine")
 605                         {
 606                         delete $disabled{"dynamic-engine"};
 607                         }
 608                 elsif ($1 eq "dynamic-engine")
 609                         {
 610                         $disabled{"dynamic-engine"} = "option";
 611                         }
 612                 elsif (exists $deprecated_disablables{$1})
 613                         {
 614                         $deprecated_options{$_} = 1;
 615                         if (defined $deprecated_disablables{$1})
 616                                 {
 617                                 $disabled{$deprecated_disablables{$1}} = "option";
 618                                 }
 619                         }
 620                 else
 621                         {
 622                         $disabled{$1} = "option";
 623                         }
 624                 # No longer an automatic choice
 625                 $auto_threads = 0 if ($1 eq "threads");
 626                 }
 627         elsif (/^enable-(.+)$/)
 628                 {
 629                 if ($1 eq "static-engine")
 630                         {
 631                         $disabled{"dynamic-engine"} = "option";
 632                         }
 633                 elsif ($1 eq "dynamic-engine")
 634                         {
 635                         delete $disabled{"dynamic-engine"};
 636                         }
 637                 elsif ($1 eq "zlib-dynamic")
 638                         {
 639                         delete $disabled{"zlib"};
 640                         }
 641                 my $algo = $1;
 642                 delete $disabled{$algo};
 643
 644                 # No longer an automatic choice
 645                 $auto_threads = 0 if ($1 eq "threads");
 646                 }
 647         elsif (/^--strict-warnings$/)
 648                 {
 649                 $strict_warnings = 1;
 650                 }
 651         elsif (/^--debug$/)
 652                 {
 653                 $config{build_type} = "debug";
 654                 }
 655         elsif (/^--release$/)
 656                 {
 657                 $config{build_type} = "release";
 658                 }
 659         elsif (/^386$/)
 660                 { $config{processor}=386; }
 661         elsif (/^fips$/)
 662                 {
 663                 $config{fips}=1;
 664                 }
 665         elsif (/^rsaref$/)
 666                 {
 667                 # No RSAref support any more since it's not needed.
 668                 # The check for the option is there so scripts aren't
 669                 # broken
 670                 }
 671         elsif (/^nofipscanistercheck$/)
 672                 {
 673                 $config{fips} = 1;
 674                 $nofipscanistercheck = 1;
 675                 }
 676         elsif (/^[-+]/)
 677                 {
 678                 if (/^--prefix=(.*)$/)
 679                         {
 680                         $config{prefix}=$1;
 681                         die "Directory given with --prefix MUST be absolute\n"
 682                                 unless file_name_is_absolute($config{prefix});
 683                         }
 684                 elsif (/^--api=(.*)$/)
 685                         {
 686                         $config{api}=$1;
 687                         }
 688                 elsif (/^--libdir=(.*)$/)
 689                         {
 690                         $config{libdir}=$1;
 691                         }
 692                 elsif (/^--openssldir=(.*)$/)
 693                         {
 694                         $config{openssldir}=$1;
 695                         }
 696                 elsif (/^--with-zlib-lib=(.*)$/)
 697                         {
 698                         $withargs{zlib_lib}=$1;
 699                         }
 700                 elsif (/^--with-zlib-include=(.*)$/)
 701                         {
 702                         $withargs{zlib_include}=$1;
 703                         }
 704                 elsif (/^--with-fuzzer-lib=(.*)$/)
 705                         {
 706                         $withargs{fuzzer_lib}=$1;
 707                         }
 708                 elsif (/^--with-fuzzer-include=(.*)$/)
 709                         {
 710                         $withargs{fuzzer_include}=$1;
 711                         }
 712                 elsif (/^--with-fipslibdir=(.*)$/)
 713                         {
 714                         $config{fipslibdir}="$1/";
 715                         }
 716                 elsif (/^--with-baseaddr=(.*)$/)
 717                         {
 718                         $config{baseaddr}="$1";
 719                         }
 720                 elsif (/^--cross-compile-prefix=(.*)$/)
 721                         {
 722                         $config{cross_compile_prefix}=$1;
 723                         }
 724                 elsif (/^--config=(.*)$/)
 725                         {
 726                         read_config $1;
 727                         }
 728                 elsif (/^-[lL](.*)$/ or /^-Wl,/)
 729                         {
 730                         $libs.=$_." ";
 731                         }
 732                 elsif (/^-rpath$/ or /^-R$/)
 733                         # -rpath is the OSF1 rpath flag
 734                         # -R is the old Solaris rpath flag
 735                         {
 736                         my $rpath = shift(@argvcopy) || "";
 737                         $rpath .= " " if $rpath ne "";
 738                         $libs.=$_." ".$rpath;
 739                         }
 740                 elsif (/^-static$/)
 741                         {
 742                         $libs.=$_." ";
 743                         $disabled{"dso"} = "forced";
 744                         $disabled{"pic"} = "forced";
 745                         $disabled{"shared"} = "forced";
 746                         $disabled{"threads"} = "forced";
 747                         }
 748                 elsif (/^-D(.*)$/)
 749                         {
 750                         push @user_defines, $1;
 751                         }
 752                 else    # common if (/^[-+]/), just pass down...
 753                         {
 754                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 755                         $user_cflags.=" ".$_;
 756                         }
 757                 }
 758         else
 759                 {
 760                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 761                 $target=$_;
 762                 }
 763         unless ($_ eq $target || /^no-/ || /^disable-/)
 764                 {
 765                 # "no-..." follows later after implied disactivations
 766                 # have been derived.  (Don't take this too seriously,
 767                 # we really only write OPTIONS to the Makefile out of
 768                 # nostalgia.)
 769
 770                 if ($config{options} eq "")
 771                         { $config{options} = $_; }
 772                 else
 773                         { $config{options} .= " ".$_; }
 774                 }
 775
 776         if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 777                 die "***** Unsupported api compatibility level: $config{api}\n",
 778         }
 779
 780         if (keys %deprecated_options)
 781                 {
 782                 warn "***** Deprecated options: ",
 783                         join(", ", keys %deprecated_options), "\n";
 784                 }
 785         if (keys %unsupported_options)
 786                 {
 787                 die "***** Unsupported options: ",
 788                         join(", ", keys %unsupported_options), "\n";
 789                 }
 790         }
 791
 792 if ($libs =~ /(^|\s)-Wl,-rpath,/
 793     && !$disabled{shared}
 794     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
 795     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
 796         "***** any of asan, msan or ubsan\n";
 797 }
 798
 799 if ($config{fips})
 800         {
 801         delete $disabled{"shared"} if ($disabled{"shared"} =~ /^default/);
 802         }
 803 else
 804         {
 805         @{$config{dirs}} = grep !/^fips$/, @{$config{dirs}};
 806         }
 807
 808 my @tocheckfor = (keys %disabled);
 809 while (@tocheckfor) {
 810     my %new_tocheckfor = ();
 811     my @cascade_copy = (@disable_cascades);
 812     while (@cascade_copy) {
 813         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
 814         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
 815             foreach(grep { !defined($disabled{$_}) } @$descendents) {
 816                 $new_tocheckfor{$_} = 1; $disabled{$_} = "forced";
 817             }
 818         }
 819     }
 820     @tocheckfor = (keys %new_tocheckfor);
 821 }
 822
 823 our $die = sub { die @_; };
 824 if ($target eq "TABLE") {
 825     local $die = sub { warn @_; };
 826     foreach (sort keys %table) {
 827         print_table_entry($_, "TABLE");
 828     }
 829     exit 0;
 830 }
 831
 832 if ($target eq "LIST") {
 833     foreach (sort keys %table) {
 834         print $_,"\n" unless $table{$_}->{template};
 835     }
 836     exit 0;
 837 }
 838
 839 if ($target eq "HASH") {
 840     local $die = sub { warn @_; };
 841     print "%table = (\n";
 842     foreach (sort keys %table) {
 843         print_table_entry($_, "HASH");
 844     }
 845     exit 0;
 846 }
 847
 848 # Backward compatibility?
 849 if ($target =~ m/^CygWin32(-.*)$/) {
 850     $target = "Cygwin".$1;
 851 }
 852
 853 foreach (sort (keys %disabled))
 854         {
 855         $config{options} .= " no-$_";
 856
 857         printf "    no-%-12s %-10s", $_, "[$disabled{$_}]";
 858
 859         if (/^dso$/)
 860                 { }
 861         elsif (/^threads$/)
 862                 { }
 863         elsif (/^shared$/)
 864                 { }
 865         elsif (/^pic$/)
 866                 { }
 867         elsif (/^zlib$/)
 868                 { }
 869         elsif (/^dynamic-engine$/)
 870                 { }
 871         elsif (/^makedepend$/)
 872                 { }
 873         elsif (/^zlib-dynamic$/)
 874                 { }
 875         elsif (/^sse2$/)
 876                 { $no_sse2 = 1; }
 877         elsif (/^engine$/)
 878                 {
 879                 @{$config{dirs}} = grep !/^engines$/, @{$config{dirs}};
 880                 @{$config{sdirs}} = grep !/^engine$/, @{$config{sdirs}};
 881                 push @{$config{openssl_other_defines}}, "OPENSSL_NO_ENGINE";
 882                 print " OPENSSL_NO_ENGINE (skip engines)";
 883                 }
 884         else
 885                 {
 886                 my ($WHAT, $what);
 887
 888                 ($WHAT = $what = $_) =~ tr/[\-a-z]/[_A-Z]/;
 889
 890                 # Fix up C macro end names
 891                 $WHAT = "RMD160" if $what eq "ripemd";
 892
 893                 # fix-up crypto/directory name(s)
 894                 $what = "ripemd" if $what eq "rmd160";
 895                 $what = "whrlpool" if $what eq "whirlpool";
 896
 897                 if ($what ne "async" && $what ne "err"
 898                     && grep { $_ eq $what } @{$config{sdirs}})
 899                         {
 900                         push @{$config{openssl_algorithm_defines}}, "OPENSSL_NO_$WHAT";
 901                         @{$config{sdirs}} = grep { $_ ne $what} @{$config{sdirs}};
 902
 903                         print " OPENSSL_NO_$WHAT (skip dir)";
 904                         }
 905                 else
 906                         {
 907                         push @{$config{openssl_other_defines}}, "OPENSSL_NO_$WHAT";
 908                         print " OPENSSL_NO_$WHAT";
 909
 910                         if (/^err$/)    { push @user_defines, "OPENSSL_NO_ERR"; }
 911                         }
 912                 }
 913
 914         print "\n";
 915         }
 916
 917 print "Configuring for $target\n";
 918
 919 # Support for legacy targets having a name starting with 'debug-'
 920 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
 921 if ($d) {
 922     $config{build_type} = "debug";
 923
 924     # If we do not find debug-foo in the table, the target is set to foo.
 925     if (!$table{$target}) {
 926         $target = $t;
 927     }
 928 }
 929 $config{target} = $target;
 930 my %target = resolve_config($target);
 931
 932 &usage if (!%target || $target{template});
 933
 934 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
 935 $config{conf_files} = [ sort keys %conf_files ];
 936 %target = ( %{$table{DEFAULTS}}, %target );
 937
 938 $target{exe_extension}="";
 939 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP"
 940                                   || $config{target} =~ /^(?:Cygwin|mingw)/);
 941 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
 942
 943 ($target{shared_extension_simple}=$target{shared_extension})
 944     =~ s|\.\$\(SHLIB_MAJOR\)\.\$\(SHLIB_MINOR\)||;
 945 $target{dso_extension}=$target{shared_extension_simple};
 946 ($target{shared_import_extension}=$target{shared_extension_simple}.".a")
 947     if ($config{target} =~ /^(?:Cygwin|mingw)/);
 948
 949
 950 $config{cross_compile_prefix} = $ENV{'CROSS_COMPILE'}
 951     if $config{cross_compile_prefix} eq "";
 952
 953 # Allow overriding the names of some tools.  USE WITH CARE
 954 # Note: only Unix cares about HASHBANGPERL...  that explains
 955 # the default string.
 956 $config{perl} =    $ENV{'PERL'}    || ($^O ne "VMS" ? $^X : "perl");
 957 $config{hashbangperl} =
 958     $ENV{'HASHBANGPERL'}           || $ENV{'PERL'}     || "/usr/bin/env perl";
 959 $target{cc} =      $ENV{'CC'}      || $target{cc}      || "cc";
 960 $target{ranlib} =  $ENV{'RANLIB'}  || $target{ranlib}  ||
 961                    (which("$config{cross_compile_prefix}ranlib") ?
 962                           "\$(CROSS_COMPILE)ranlib" : "true");
 963 $target{ar} =      $ENV{'AR'}      || $target{ar}      || "ar";
 964 $target{nm} =      $ENV{'NM'}      || $target{nm}      || "nm";
 965 $target{rc} =
 966     $ENV{'RC'}  || $ENV{'WINDRES'} || $target{rc}      || "windres";
 967
 968 # Allow overriding the build file name
 969 $target{build_file} = $ENV{BUILDFILE} || $target{build_file} || "Makefile";
 970
 971 # Cache information necessary for reconfiguration
 972 $config{cc} = $target{cc};
 973 $config{build_file} = $target{build_file};
 974
 975 # For cflags, lflags, plib_lflags, ex_libs and defines, add the debug_
 976 # or release_ attributes.
 977 # Do it in such a way that no spurious space is appended (hence the grep).
 978 $config{defines} = [];
 979 $config{cflags} = "";
 980 $config{ex_libs} = "";
 981 $config{shared_ldflag} = "";
 982
 983 # Make sure build_scheme is consistent.
 984 $target{build_scheme} = [ $target{build_scheme} ]
 985     if ref($target{build_scheme}) ne "ARRAY";
 986
 987 my ($builder, $builder_platform, @builder_opts) =
 988     @{$target{build_scheme}};
 989
 990 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
 991
 992 if ($target =~ /^mingw/ && `$target{cc} --target-help 2>&1` =~ m/-mno-cygwin/m)
 993         {
 994         $config{cflags} .= " -mno-cygwin";
 995         $config{shared_ldflag} .= " -mno-cygwin";
 996         }
 997
 998 if ($target =~ /linux.*-mips/ && !$disabled{asm} && $user_cflags !~ /-m(ips|arch=)/) {
 999         # minimally required architecture flags for assembly modules
1000         $config{cflags}="-mips2 $config{cflags}" if ($target =~ /mips32/);
1001         $config{cflags}="-mips3 $config{cflags}" if ($target =~ /mips64/);
1002 }
1003
1004 my $no_shared_warn=0;
1005 my $no_user_cflags=0;
1006 my $no_user_defines=0;
1007
1008 # The DSO code currently always implements all functions so that no
1009 # applications will have to worry about that from a compilation point
1010 # of view. However, the "method"s may return zero unless that platform
1011 # has support compiled in for them. Currently each method is enabled
1012 # by a define "DSO_<name>" ... we translate the "dso_scheme" config
1013 # string entry into using the following logic;
1014 if (!$disabled{dso} && $target{dso_scheme} ne "")
1015         {
1016         $target{dso_scheme} =~ tr/[a-z]/[A-Z]/;
1017         if ($target{dso_scheme} eq "DLFCN")
1018                 {
1019                 unshift @{$config{defines}}, "DSO_DLFCN", "HAVE_DLFCN_H";
1020                 }
1021         elsif ($target{dso_scheme} eq "DLFCN_NO_H")
1022                 {
1023                 unshift @{$config{defines}}, "DSO_DLFCN";
1024                 }
1025         else
1026                 {
1027                 unshift @{$config{defines}}, "DSO_$target{dso_scheme}";
1028                 }
1029         }
1030
1031 $config{ex_libs}="$libs$config{ex_libs}" if ($libs ne "");
1032
1033 if ($disabled{asm})
1034         {
1035         if ($config{fips})
1036                 {
1037                 @{$config{defines}} = grep !/^[BL]_ENDIAN$/, @{$config{defines}};
1038                 @{$target{defines}} = grep !/^[BL]_ENDIAN$/, @{$target{defines}};
1039                 }
1040         }
1041
1042 # If threads aren't disabled, check how possible they are
1043 unless ($disabled{threads}) {
1044     if ($auto_threads) {
1045         # Enabled by default, disable it forcibly if unavailable
1046         if ($target{thread_scheme} eq "(unknown)") {
1047             $disabled{threads} = "unavailable";
1048         }
1049     } else {
1050         # The user chose to enable threads explicitly, let's see
1051         # if there's a chance that's possible
1052         if ($target{thread_scheme} eq "(unknown)") {
1053             # If the user asked for "threads" and we don't have internal
1054             # knowledge how to do it, [s]he is expected to provide any
1055             # system-dependent compiler options that are necessary.  We
1056             # can't truly check that the given options are correct, but
1057             # we expect the user to know what [s]He is doing.
1058             if ($no_user_cflags && $no_user_defines) {
1059                 die "You asked for multi-threading support, but didn't\n"
1060                     ,"provide any system-specific compiler options\n";
1061             }
1062         }
1063     }
1064 }
1065
1066 # If threads still aren't disabled, add a C macro to ensure the source
1067 # code knows about it.  Any other flag is taken care of by the configs.
1068 unless($disabled{threads}) {
1069     foreach (("defines", "openssl_thread_defines")) {
1070         push @{$config{$_}}, "OPENSSL_THREADS";
1071     }
1072 }
1073
1074 # With "deprecated" disable all deprecated features.
1075 if (defined($disabled{"deprecated"})) {
1076         $config{api} = $maxapi;
1077 }
1078
1079 if ($target{shared_target} eq "")
1080         {
1081         $no_shared_warn = 1
1082             if ((!$disabled{shared} || !$disabled{"dynamic-engine"})
1083                 && !$config{fips});
1084         $disabled{shared} = "no-shared-target";
1085         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
1086             "no-shared-target";
1087         }
1088
1089 if ($disabled{"dynamic-engine"}) {
1090         push @{$config{defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1091         $config{dynamic_engines} = 0;
1092 } else {
1093         push @{$config{defines}}, "OPENSSL_NO_STATIC_ENGINE";
1094         $config{dynamic_engines} = 1;
1095 }
1096
1097 unless ($disabled{"fuzz-libfuzzer"}) {
1098     $config{cflags} .= "-fsanitize-coverage=edge,indirect-calls ";
1099 }
1100
1101 unless ($disabled{asan}) {
1102     $config{cflags} .= "-fsanitize=address ";
1103 }
1104
1105 unless ($disabled{ubsan}) {
1106     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1107     # platforms.
1108     $config{cflags} .= "-fsanitize=undefined -fno-sanitize-recover=all ";
1109 }
1110
1111 unless ($disabled{msan}) {
1112   $config{cflags} .= "-fsanitize=memory ";
1113 }
1114
1115 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1116         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1117     $config{cflags} .= "-fno-omit-frame-pointer -g ";
1118 }
1119 #
1120 # Platform fix-ups
1121 #
1122
1123 # This saves the build files from having to check
1124 if ($disabled{pic})
1125         {
1126         $target{shared_cflag} = $target{shared_ldflag} =
1127                 $target{shared_rcflag} = "";
1128         }
1129 else
1130         {
1131         push @{$config{defines}}, "OPENSSL_PIC";
1132         }
1133
1134 if ($target{sys_id} ne "")
1135         {
1136         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1137         }
1138
1139 unless ($disabled{asm}) {
1140     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1141     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1142
1143     # bn-586 is the only one implementing bn_*_part_words
1144     push @{$config{defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1145     push @{$config{defines}}, "OPENSSL_IA32_SSE2" if (!$no_sse2 && $target{bn_asm_src} =~ /86/);
1146
1147     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1148     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1149     push @{$config{defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1150
1151     if ($config{fips}) {
1152         push @{$config{openssl_other_defines}}, "OPENSSL_FIPS";
1153     }
1154
1155     if ($target{sha1_asm_src}) {
1156         push @{$config{defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1157         push @{$config{defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1158         push @{$config{defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1159     }
1160     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1161         push @{$config{defines}}, "RC4_ASM";
1162     }
1163     if ($target{md5_asm_src}) {
1164         push @{$config{defines}}, "MD5_ASM";
1165     }
1166     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1167     if ($target{rmd160_asm_src}) {
1168         push @{$config{defines}}, "RMD160_ASM";
1169     }
1170     if ($target{aes_asm_src}) {
1171         push @{$config{defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1172         # aes-ctr.fake is not a real file, only indication that assembler
1173         # module implements AES_ctr32_encrypt...
1174         push @{$config{defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1175         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1176         push @{$config{defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1177         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($no_sse2);
1178         push @{$config{defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1179         push @{$config{defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1180     }
1181     if ($target{wp_asm_src} =~ /mmx/) {
1182         if ($config{processor} eq "386") {
1183             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1184         } elsif (!$disabled{"whirlpool"}) {
1185             push @{$config{defines}}, "WHIRLPOOL_ASM";
1186         }
1187     }
1188     if ($target{modes_asm_src} =~ /ghash-/) {
1189         push @{$config{defines}}, "GHASH_ASM";
1190     }
1191     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1192         push @{$config{defines}}, "ECP_NISTZ256_ASM";
1193     }
1194     if ($target{poly1305_asm_src} ne "") {
1195         push @{$config{defines}}, "POLY1305_ASM";
1196     }
1197 }
1198
1199 my $ecc = $target{cc};
1200 if ($^O ne "VMS" && !$disabled{makedepend}) {
1201     # Is the compiler gcc or clang?  $ecc is used below to see if
1202     # error-checking can be turned on.
1203     my $ccpcc = "$config{cross_compile_prefix}$target{cc}";
1204     open(PIPE, "$ccpcc --version 2>&1 |");
1205     my $lines = 2;
1206     while ( <PIPE> ) {
1207         # Find the version number and save the major.
1208         m|(?:.*)\b(\d+)\.\d+\.\d+\b(?:.*)|;
1209         my $compiler_major = $1;
1210         # We know that GNU C version 3 and up as well as all clang
1211         # versions support dependency generation
1212         $config{makedepprog} = $ccpcc
1213             if (/clang/ || (/gcc/ && $compiler_major >= 3));
1214         $ecc = "clang" if /clang/;
1215         $ecc = "gcc" if /gcc/;
1216         last if ($config{makedepprog} || !$lines--);
1217     }
1218     close(PIPE);
1219
1220     $config{makedepprog} = which('makedepend') unless $config{makedepprog};
1221     $disabled{makedepend} = "unavailable" unless $config{makedepprog};
1222 }
1223
1224
1225
1226 # Deal with bn_ops ###################################################
1227
1228 $config{bn_ll}                  =0;
1229 $config{export_var_as_fn}       =0;
1230 my $def_int="unsigned int";
1231 $config{rc4_int}                =$def_int;
1232 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1233
1234 my $count = 0;
1235 foreach (sort split(/\s+/,$target{bn_ops})) {
1236     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1237     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1238     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1239     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1240     ($config{b64l},$config{b64},$config{b32})
1241         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1242     ($config{b64l},$config{b64},$config{b32})
1243         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1244     ($config{b64l},$config{b64},$config{b32})
1245         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1246 }
1247 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1248     if $count > 1;
1249
1250
1251 # Hack cflags for better warnings (dev option) #######################
1252
1253 # "Stringify" the C flags string.  This permits it to be made part of a string
1254 # and works as well on command lines.
1255 $config{cflags} =~ s/([\\\"])/\\$1/g;
1256
1257 if (defined($config{api})) {
1258     $config{openssl_api_defines} = [ "OPENSSL_MIN_API=".$apitable->{$config{api}} ];
1259     my $apiflag = sprintf("OPENSSL_API_COMPAT=%s", $apitable->{$config{api}});
1260     push @{$config{defines}}, $apiflag;
1261 }
1262
1263 if ($strict_warnings)
1264         {
1265         my $wopt;
1266         die "ERROR --strict-warnings requires gcc or clang"
1267             unless $ecc eq 'gcc' || $ecc eq 'clang';
1268         foreach $wopt (split /\s+/, $gcc_devteam_warn)
1269                 {
1270                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1271                 }
1272         if ($ecc eq "clang")
1273                 {
1274                 foreach $wopt (split /\s+/, $clang_devteam_warn)
1275                         {
1276                         $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1277                         }
1278                 }
1279         }
1280
1281 unless ($disabled{"crypto-mdebug-backtrace"})
1282         {
1283         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1284                 {
1285                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1286                 }
1287         if ($target =~ /^BSD-/)
1288                 {
1289                 $config{ex_libs} .= " -lexecinfo";
1290                 }
1291         }
1292
1293 if ($user_cflags ne "") { $config{cflags}="$config{cflags}$user_cflags"; }
1294 else                    { $no_user_cflags=1;  }
1295 if (@user_defines) { $config{defines}=[ @{$config{defines}}, @user_defines ]; }
1296 else               { $no_user_defines=1;    }
1297
1298 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1299
1300 unless ($disabled{afalgeng}) {
1301     $config{afalgeng}="";
1302     if ($target =~ m/^linux/) {
1303         my $minver = 4*10000 + 1*100 + 0;
1304         if ($config{cross_compile_prefix} eq "") {
1305             my $verstr = `uname -r`;
1306             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1307             ($mi2) = $mi2 =~ /(\d+)/;
1308             my $ver = $ma*10000 + $mi1*100 + $mi2;
1309             if ($ver < $minver) {
1310                 $disabled{afalgeng} = "too-old-kernel";
1311             } else {
1312                 push @{$config{engdirs}}, "afalg";
1313             }
1314         } else {
1315             $disabled{afalgeng} = "cross-compiling";
1316         }
1317     } else {
1318         $disabled{afalgeng}  = "not-linux";
1319     }
1320 }
1321
1322 push @{$config{openssl_other_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1323
1324 # If we use the unified build, collect information from build.info files
1325 my %unified_info = ();
1326
1327 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1328 if ($builder eq "unified") {
1329     use lib catdir(dirname(__FILE__),"util");
1330     use with_fallback qw(Text::Template);
1331
1332     sub cleandir {
1333         my $base = shift;
1334         my $dir = shift;
1335         my $relativeto = shift || ".";
1336
1337         $dir = catdir($base,$dir) unless isabsolute($dir);
1338
1339         # Make sure the directories we're building in exists
1340         mkpath($dir);
1341
1342         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1343         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1344         return $res;
1345     }
1346
1347     sub cleanfile {
1348         my $base = shift;
1349         my $file = shift;
1350         my $relativeto = shift || ".";
1351
1352         $file = catfile($base,$file) unless isabsolute($file);
1353
1354         my $d = dirname($file);
1355         my $f = basename($file);
1356
1357         # Make sure the directories we're building in exists
1358         mkpath($d);
1359
1360         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1361         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1362         return $res;
1363     }
1364
1365     # Store the name of the template file we will build the build file from
1366     # in %config.  This may be useful for the build file itself.
1367     my @build_file_template_names =
1368         ( $builder_platform."-".$target{build_file}.".tmpl",
1369           $target{build_file}.".tmpl" );
1370     my @build_file_templates = ();
1371
1372     # First, look in the user provided directory, if given
1373     if (defined $ENV{$local_config_envname}) {
1374         @build_file_templates =
1375             map {
1376                 if ($^O eq 'VMS') {
1377                     # VMS environment variables are logical names,
1378                     # which can be used as is
1379                     $local_config_envname . ':' . $_;
1380                 } else {
1381                     catfile($ENV{$local_config_envname}, $_);
1382                 }
1383             }
1384             @build_file_template_names;
1385     }
1386     # Then, look in our standard directory
1387     push @build_file_templates,
1388         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1389           @build_file_template_names );
1390
1391     my $build_file_template;
1392     for $_ (@build_file_templates) {
1393         $build_file_template = $_;
1394         last if -f $build_file_template;
1395
1396         $build_file_template = undef;
1397     }
1398     if (!defined $build_file_template) {
1399         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1400     }
1401     $config{build_file_templates}
1402       = [ $build_file_template,
1403           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1404                     $blddir) ];
1405
1406     my @build_infos = ( [ ".", "build.info" ] );
1407     foreach (@{$config{dirs}}) {
1408         push @build_infos, [ $_, "build.info" ]
1409             if (-f catfile($srcdir, $_, "build.info"));
1410     }
1411     foreach (@{$config{sdirs}}) {
1412         push @build_infos, [ catdir("crypto", $_), "build.info" ]
1413             if (-f catfile($srcdir, "crypto", $_, "build.info"));
1414     }
1415     foreach (@{$config{engdirs}}) {
1416         push @build_infos, [ catdir("engines", $_), "build.info" ]
1417             if (-f catfile($srcdir, "engines", $_, "build.info"));
1418     }
1419
1420     $config{build_infos} = [ ];
1421
1422     foreach (@build_infos) {
1423         my $sourced = catdir($srcdir, $_->[0]);
1424         my $buildd = catdir($blddir, $_->[0]);
1425
1426         mkpath($buildd);
1427
1428         my $f = $_->[1];
1429         # The basic things we're trying to build
1430         my @programs = ();
1431         my @programs_install = ();
1432         my @libraries = ();
1433         my @libraries_install = ();
1434         my @engines = ();
1435         my @engines_install = ();
1436         my @scripts = ();
1437         my @scripts_install = ();
1438         my @extra = ();
1439         my @overrides = ();
1440         my @intermediates = ();
1441         my @rawlines = ();
1442
1443         my %ordinals = ();
1444         my %sources = ();
1445         my %shared_sources = ();
1446         my %includes = ();
1447         my %depends = ();
1448         my %renames = ();
1449         my %sharednames = ();
1450         my %generate = ();
1451
1452         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1453         my $template = Text::Template->new(TYPE => 'FILE',
1454                                            SOURCE => catfile($sourced, $f));
1455         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1456         my @text =
1457             split /^/m,
1458             $template->fill_in(HASH => { config => \%config,
1459                                          target => \%target,
1460                                          disabled => \%disabled,
1461                                          withargs => \%withargs,
1462                                          builddir => abs2rel($buildd, $blddir),
1463                                          sourcedir => abs2rel($sourced, $blddir),
1464                                          buildtop => abs2rel($blddir, $blddir),
1465                                          sourcetop => abs2rel($srcdir, $blddir) },
1466                                DELIMITERS => [ "{-", "-}" ]);
1467
1468         # The top item of this stack has the following values
1469         # -2 positive already run and we found ELSE (following ELSIF should fail)
1470         # -1 positive already run (skip until ENDIF)
1471         # 0 negatives so far (if we're at a condition, check it)
1472         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1473         # 2 positive ELSE (following ELSIF should fail)
1474         my @skip = ();
1475         collect_information(
1476             collect_from_array([ @text ],
1477                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1478                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1479             # Info we're looking for
1480             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1481             => sub {
1482                 if (! @skip || $skip[$#skip] > 0) {
1483                     push @skip, !! $1;
1484                 } else {
1485                     push @skip, -1;
1486                 }
1487             },
1488             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1489             => sub { die "ELSIF out of scope" if ! @skip;
1490                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1491                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1492                      $skip[$#skip] = !! $1
1493                          if $skip[$#skip] == 0; },
1494             qr/^\s*ELSE\s*$/
1495             => sub { die "ELSE out of scope" if ! @skip;
1496                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1497                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1498             qr/^\s*ENDIF\s*$/
1499             => sub { die "ENDIF out of scope" if ! @skip;
1500                      pop @skip; },
1501             qr/^\s*PROGRAMS(_NO_INST)?\s*=\s*(.*)\s*$/
1502             => sub {
1503                 if (!@skip || $skip[$#skip] > 0) {
1504                     my $install = $1;
1505                     my @x = tokenize($2);
1506                     push @programs, @x;
1507                     push @programs_install, @x unless $install;
1508                 }
1509             },
1510             qr/^\s*LIBS(_NO_INST)?\s*=\s*(.*)\s*$/
1511             => sub {
1512                 if (!@skip || $skip[$#skip] > 0) {
1513                     my $install = $1;
1514                     my @x = tokenize($2);
1515                     push @libraries, @x;
1516                     push @libraries_install, @x unless $install;
1517                 }
1518             },
1519             qr/^\s*ENGINES(_NO_INST)?\s*=\s*(.*)\s*$/
1520             => sub {
1521                 if (!@skip || $skip[$#skip] > 0) {
1522                     my $install = $1;
1523                     my @x = tokenize($2);
1524                     push @engines, @x;
1525                     push @engines_install, @x unless $install;
1526                 }
1527             },
1528             qr/^\s*SCRIPTS(_NO_INST)?\s*=\s*(.*)\s*$/
1529             => sub {
1530                 if (!@skip || $skip[$#skip] > 0) {
1531                     my $install = $1;
1532                     my @x = tokenize($2);
1533                     push @scripts, @x;
1534                     push @scripts_install, @x unless $install;
1535                 }
1536             },
1537             qr/^\s*EXTRA\s*=\s*(.*)\s*$/
1538             => sub { push @extra, tokenize($1)
1539                          if !@skip || $skip[$#skip] > 0 },
1540             qr/^\s*OVERRIDES\s*=\s*(.*)\s*$/
1541             => sub { push @overrides, tokenize($1)
1542                          if !@skip || $skip[$#skip] > 0 },
1543
1544             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1545             => sub { push @{$ordinals{$1}}, tokenize($2)
1546                          if !@skip || $skip[$#skip] > 0 },
1547             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1548             => sub { push @{$sources{$1}}, tokenize($2)
1549                          if !@skip || $skip[$#skip] > 0 },
1550             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1551             => sub { push @{$shared_sources{$1}}, tokenize($2)
1552                          if !@skip || $skip[$#skip] > 0 },
1553             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1554             => sub { push @{$includes{$1}}, tokenize($2)
1555                          if !@skip || $skip[$#skip] > 0 },
1556             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1557             => sub { push @{$depends{$1}}, tokenize($2)
1558                          if !@skip || $skip[$#skip] > 0 },
1559             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1560             => sub { push @{$generate{$1}}, $2
1561                          if !@skip || $skip[$#skip] > 0 },
1562             qr/^\s*RENAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1563             => sub { push @{$renames{$1}}, tokenize($2)
1564                          if !@skip || $skip[$#skip] > 0 },
1565             qr/^\s*SHARED_NAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1566             => sub { push @{$sharednames{$1}}, tokenize($2)
1567                          if !@skip || $skip[$#skip] > 0 },
1568             qr/^\s*BEGINRAW\[((?:\\.|[^\\\]])+)\]\s*$/
1569             => sub {
1570                 my $lineiterator = shift;
1571                 my $target_kind = $1;
1572                 while (defined $lineiterator->()) {
1573                     s|\R$||;
1574                     if (/^\s*ENDRAW\[((?:\\.|[^\\\]])+)\]\s*$/) {
1575                         die "ENDRAW doesn't match BEGINRAW"
1576                             if $1 ne $target_kind;
1577                         last;
1578                     }
1579                     next if @skip && $skip[$#skip] <= 0;
1580                     push @rawlines,  $_
1581                         if ($target_kind eq $target{build_file}
1582                             || $target_kind eq $target{build_file}."(".$builder_platform.")");
1583                 }
1584             },
1585             qr/^(?:#.*|\s*)$/ => sub { },
1586             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1587             "BEFORE" => sub {
1588                 if ($buildinfo_debug) {
1589                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1590                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1591                 }
1592             },
1593             "AFTER" => sub {
1594                 if ($buildinfo_debug) {
1595                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1596                 }
1597             },
1598             );
1599         die "runaway IF?" if (@skip);
1600
1601         foreach (keys %renames) {
1602             die "$_ renamed to more than one thing: "
1603                 ,join(" ", @{$renames{$_}}),"\n"
1604                 if scalar @{$renames{$_}} > 1;
1605             my $dest = cleanfile($buildd, $_, $blddir);
1606             my $to = cleanfile($buildd, $renames{$_}->[0], $blddir);
1607             die "$dest renamed to more than one thing: "
1608                 ,$unified_info{rename}->{$dest}, $to
1609                 unless !defined($unified_info{rename}->{$dest})
1610                 or $unified_info{rename}->{$dest} eq $to;
1611             $unified_info{rename}->{$dest} = $to;
1612         }
1613
1614         foreach (@programs) {
1615             my $program = cleanfile($buildd, $_, $blddir);
1616             if ($unified_info{rename}->{$program}) {
1617                 $program = $unified_info{rename}->{$program};
1618             }
1619             $unified_info{programs}->{$program} = 1;
1620         }
1621
1622         foreach (@programs_install) {
1623             my $program = cleanfile($buildd, $_, $blddir);
1624             if ($unified_info{rename}->{$program}) {
1625                 $program = $unified_info{rename}->{$program};
1626             }
1627             $unified_info{install}->{programs}->{$program} = 1;
1628         }
1629
1630         foreach (@libraries) {
1631             my $library = cleanfile($buildd, $_, $blddir);
1632             if ($unified_info{rename}->{$library}) {
1633                 $library = $unified_info{rename}->{$library};
1634             }
1635             $unified_info{libraries}->{$library} = 1;
1636         }
1637
1638         foreach (@libraries_install) {
1639             my $library = cleanfile($buildd, $_, $blddir);
1640             if ($unified_info{rename}->{$library}) {
1641                 $library = $unified_info{rename}->{$library};
1642             }
1643             $unified_info{install}->{libraries}->{$library} = 1;
1644         }
1645
1646         die <<"EOF" if scalar @engines and !$config{dynamic_engines};
1647 ENGINES can only be used if configured with 'dynamic-engine'.
1648 This is usually a fault in a build.info file.
1649 EOF
1650         foreach (@engines) {
1651             my $library = cleanfile($buildd, $_, $blddir);
1652             if ($unified_info{rename}->{$library}) {
1653                 $library = $unified_info{rename}->{$library};
1654             }
1655             $unified_info{engines}->{$library} = 1;
1656         }
1657
1658         foreach (@engines_install) {
1659             my $library = cleanfile($buildd, $_, $blddir);
1660             if ($unified_info{rename}->{$library}) {
1661                 $library = $unified_info{rename}->{$library};
1662             }
1663             $unified_info{install}->{engines}->{$library} = 1;
1664         }
1665
1666         foreach (@scripts) {
1667             my $script = cleanfile($buildd, $_, $blddir);
1668             if ($unified_info{rename}->{$script}) {
1669                 $script = $unified_info{rename}->{$script};
1670             }
1671             $unified_info{scripts}->{$script} = 1;
1672         }
1673
1674         foreach (@scripts_install) {
1675             my $script = cleanfile($buildd, $_, $blddir);
1676             if ($unified_info{rename}->{$script}) {
1677                 $script = $unified_info{rename}->{$script};
1678             }
1679             $unified_info{install}->{scripts}->{$script} = 1;
1680         }
1681
1682         foreach (@extra) {
1683             my $extra = cleanfile($buildd, $_, $blddir);
1684             $unified_info{extra}->{$extra} = 1;
1685         }
1686
1687         foreach (@overrides) {
1688             my $override = cleanfile($buildd, $_, $blddir);
1689             $unified_info{overrides}->{$override} = 1;
1690         }
1691
1692         push @{$unified_info{rawlines}}, @rawlines;
1693
1694         unless ($disabled{shared}) {
1695             # Check sharednames.
1696             foreach (keys %sharednames) {
1697                 my $dest = cleanfile($buildd, $_, $blddir);
1698                 if ($unified_info{rename}->{$dest}) {
1699                     $dest = $unified_info{rename}->{$dest};
1700                 }
1701                 die "shared_name for $dest with multiple values: "
1702                     ,join(" ", @{$sharednames{$_}}),"\n"
1703                     if scalar @{$sharednames{$_}} > 1;
1704                 my $to = cleanfile($buildd, $sharednames{$_}->[0], $blddir);
1705                 die "shared_name found for a library $dest that isn't defined\n"
1706                     unless $unified_info{libraries}->{$dest};
1707                 die "shared_name for $dest with multiple values: "
1708                     ,$unified_info{sharednames}->{$dest}, ", ", $to
1709                     unless !defined($unified_info{sharednames}->{$dest})
1710                     or $unified_info{sharednames}->{$dest} eq $to;
1711                 $unified_info{sharednames}->{$dest} = $to;
1712             }
1713
1714             # Additionally, we set up sharednames for libraries that don't
1715             # have any, as themselves.
1716             foreach (keys %{$unified_info{libraries}}) {
1717                 if (!defined $unified_info{sharednames}->{$_}) {
1718                     $unified_info{sharednames}->{$_} = $_
1719                 }
1720             }
1721         }
1722
1723         foreach (keys %ordinals) {
1724             my $dest = $_;
1725             my $ddest = cleanfile($buildd, $_, $blddir);
1726             if ($unified_info{rename}->{$ddest}) {
1727                 $ddest = $unified_info{rename}->{$ddest};
1728             }
1729             foreach (@{$ordinals{$dest}}) {
1730                 my %known_ordinals =
1731                     (
1732                      crypto =>
1733                      cleanfile($sourced, catfile("util", "libcrypto.num"), $blddir),
1734                      ssl =>
1735                      cleanfile($sourced, catfile("util", "libssl.num"), $blddir)
1736                     );
1737                 my $o = $known_ordinals{$_};
1738                 die "Ordinals for $ddest defined more than once\n"
1739                     if $unified_info{ordinals}->{$ddest};
1740                 $unified_info{ordinals}->{$ddest} = [ $_, $o ];
1741             }
1742         }
1743
1744         foreach (keys %sources) {
1745             my $dest = $_;
1746             my $ddest = cleanfile($buildd, $_, $blddir);
1747             if ($unified_info{rename}->{$ddest}) {
1748                 $ddest = $unified_info{rename}->{$ddest};
1749             }
1750             foreach (@{$sources{$dest}}) {
1751                 my $s = cleanfile($sourced, $_, $blddir);
1752
1753                 # If it isn't in the source tree, we assume it's generated
1754                 # in the build tree
1755                 if (! -f $s) {
1756                     $s = cleanfile($buildd, $_, $blddir);
1757                 }
1758                 # We recognise C and asm files
1759                 if ($s =~ /\.[csS]\b$/) {
1760                     (my $o = $_) =~ s/\.[csS]\b$/.o/;
1761                     $o = cleanfile($buildd, $o, $blddir);
1762                     $unified_info{sources}->{$ddest}->{$o} = 1;
1763                     $unified_info{sources}->{$o}->{$s} = 1;
1764                 } else {
1765                     $unified_info{sources}->{$ddest}->{$s} = 1;
1766                 }
1767             }
1768         }
1769
1770         foreach (keys %shared_sources) {
1771             my $dest = $_;
1772             my $ddest = cleanfile($buildd, $_, $blddir);
1773             if ($unified_info{rename}->{$ddest}) {
1774                 $ddest = $unified_info{rename}->{$ddest};
1775             }
1776             foreach (@{$shared_sources{$dest}}) {
1777                 my $s = cleanfile($sourced, $_, $blddir);
1778
1779                 # If it isn't in the source tree, we assume it's generated
1780                 # in the build tree
1781                 if (! -f $s) {
1782                     $s = cleanfile($buildd, $_, $blddir);
1783                 }
1784                 # We recognise C and asm files
1785                 if ($s =~ /\.[csS]\b$/) {
1786                     (my $o = $_) =~ s/\.[csS]\b$/.o/;
1787                     $o = cleanfile($buildd, $o, $blddir);
1788                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
1789                     $unified_info{sources}->{$o}->{$s} = 1;
1790                 } else {
1791                     die "unrecognised source file type for shared library: $s\n";
1792                 }
1793             }
1794         }
1795
1796         foreach (keys %generate) {
1797             my $dest = $_;
1798             my $ddest = cleanfile($buildd, $_, $blddir);
1799             if ($unified_info{rename}->{$ddest}) {
1800                 $ddest = $unified_info{rename}->{$ddest};
1801             }
1802             die "more than one generator for $dest: "
1803                     ,join(" ", @{$generate{$_}}),"\n"
1804                     if scalar @{$generate{$_}} > 1;
1805             my @generator = split /\s+/, $generate{$dest}->[0];
1806             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
1807             $unified_info{generate}->{$ddest} = [ @generator ];
1808         }
1809
1810         foreach (keys %depends) {
1811             my $dest = $_;
1812             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
1813
1814             # If the destination doesn't exist in source, it can only be
1815             # a generated file in the build tree.
1816             if ($ddest ne "" && ! -f $ddest) {
1817                 $ddest = cleanfile($buildd, $_, $blddir);
1818                 if ($unified_info{rename}->{$ddest}) {
1819                     $ddest = $unified_info{rename}->{$ddest};
1820                 }
1821             }
1822             foreach (@{$depends{$dest}}) {
1823                 my $d = cleanfile($sourced, $_, $blddir);
1824
1825                 # If we know it's generated, or assume it is because we can't
1826                 # find it in the source tree, we set file we depend on to be
1827                 # in the build tree rather than the source tree, and assume
1828                 # and that there are lines to build it in a BEGINRAW..ENDRAW
1829                 # section or in the Makefile template.
1830                 if (! -f $d
1831                     || (grep { $d eq $_ }
1832                         map { cleanfile($srcdir, $_, $blddir) }
1833                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
1834                     $d = cleanfile($buildd, $_, $blddir);
1835                 }
1836                 # Take note if the file to depend on is being renamed
1837                 if ($unified_info{rename}->{$d}) {
1838                     $d = $unified_info{rename}->{$d};
1839                 }
1840                 $unified_info{depends}->{$ddest}->{$d} = 1;
1841                 # If we depend on a header file or a perl module, let's make
1842                 # sure it can get included
1843                 if ($dest ne "" && $d =~ /\.(h|pm)$/) {
1844                     my $i = dirname($d);
1845                     push @{$unified_info{includes}->{$ddest}->{source}}, $i
1846                         unless grep { $_ eq $i } @{$unified_info{includes}->{$ddest}->{source}};
1847                 }
1848             }
1849         }
1850
1851         foreach (keys %includes) {
1852             my $dest = $_;
1853             my $ddest = cleanfile($sourced, $_, $blddir);
1854
1855             # If the destination doesn't exist in source, it can only be
1856             # a generated file in the build tree.
1857             if (! -f $ddest) {
1858                 $ddest = cleanfile($buildd, $_, $blddir);
1859                 if ($unified_info{rename}->{$ddest}) {
1860                     $ddest = $unified_info{rename}->{$ddest};
1861                 }
1862             }
1863             foreach (@{$includes{$dest}}) {
1864                 my $is = cleandir($sourced, $_, $blddir);
1865                 my $ib = cleandir($buildd, $_, $blddir);
1866                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
1867                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
1868                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
1869                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
1870             }
1871         }
1872     }
1873
1874     ### Make unified_info a bit more efficient
1875     # One level structures
1876     foreach (("programs", "libraries", "engines", "scripts", "extra", "overrides")) {
1877         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
1878     }
1879     # Two level structures
1880     foreach my $l1 (("install", "sources", "shared_sources", "ldadd", "depends")) {
1881         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
1882             $unified_info{$l1}->{$l2} =
1883                 [ sort keys %{$unified_info{$l1}->{$l2}} ];
1884         }
1885     }
1886     # Includes
1887     foreach my $dest (sort keys %{$unified_info{includes}}) {
1888         if (defined($unified_info{includes}->{$dest}->{build})) {
1889             my @source_includes =
1890                 ( @{$unified_info{includes}->{$dest}->{source}} );
1891             $unified_info{includes}->{$dest} =
1892                 [ @{$unified_info{includes}->{$dest}->{build}} ];
1893             foreach my $inc (@source_includes) {
1894                 push @{$unified_info{includes}->{$dest}}, $inc
1895                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
1896             }
1897         } else {
1898             $unified_info{includes}->{$dest} =
1899                 [ @{$unified_info{includes}->{$dest}->{source}} ];
1900         }
1901     }
1902 }
1903
1904 # For the schemes that need it, we provide the old *_obj configs
1905 # from the *_asm_obj ones
1906 foreach (grep /_(asm|aux)_src$/, keys %target) {
1907     my $src = $_;
1908     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
1909     ($target{$obj} = $target{$src}) =~ s/\.[csS]\b/.o/g;
1910 }
1911
1912 # Write down our configuration where it fits #########################
1913
1914 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
1915 print OUT <<"EOF";
1916 package configdata;
1917
1918 use strict;
1919 use warnings;
1920
1921 use Exporter;
1922 #use vars qw(\@ISA \@EXPORT);
1923 our \@ISA = qw(Exporter);
1924 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables);
1925
1926 EOF
1927 print OUT "our %config = (\n";
1928 foreach (sort keys %config) {
1929     if (ref($config{$_}) eq "ARRAY") {
1930         print OUT "  ", $_, " => [ ", join(", ",
1931                                            map { quotify("perl", $_) }
1932                                            @{$config{$_}}), " ],\n";
1933     } else {
1934         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
1935     }
1936 }
1937 print OUT <<"EOF";
1938 );
1939
1940 EOF
1941 print OUT "our %target = (\n";
1942 foreach (sort keys %target) {
1943     if (ref($target{$_}) eq "ARRAY") {
1944         print OUT "  ", $_, " => [ ", join(", ",
1945                                            map { quotify("perl", $_) }
1946                                            @{$target{$_}}), " ],\n";
1947     } else {
1948         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
1949     }
1950 }
1951 print OUT <<"EOF";
1952 );
1953
1954 EOF
1955 print OUT "our \%available_protocols = (\n";
1956 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
1957 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
1958 print OUT <<"EOF";
1959 );
1960
1961 EOF
1962 print OUT "our \@disablables = (\n";
1963 foreach (@disablables) {
1964     print OUT "  ", quotify("perl", $_), ",\n";
1965 }
1966 print OUT <<"EOF";
1967 );
1968
1969 EOF
1970 print OUT "our \%disabled = (\n";
1971 foreach (sort keys %disabled) {
1972     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
1973 }
1974 print OUT <<"EOF";
1975 );
1976
1977 EOF
1978 print OUT "our %withargs = (\n";
1979 foreach (sort keys %withargs) {
1980     if (ref($withargs{$_}) eq "ARRAY") {
1981         print OUT "  ", $_, " => [ ", join(", ",
1982                                            map { quotify("perl", $_) }
1983                                            @{$withargs{$_}}), " ],\n";
1984     } else {
1985         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
1986     }
1987 }
1988 print OUT <<"EOF";
1989 );
1990
1991 EOF
1992 if ($builder eq "unified") {
1993     my $recurse;
1994     $recurse = sub {
1995         my $indent = shift;
1996         foreach (@_) {
1997             if (ref $_ eq "ARRAY") {
1998                 print OUT " "x$indent, "[\n";
1999                 foreach (@$_) {
2000                     $recurse->($indent + 4, $_);
2001                 }
2002                 print OUT " "x$indent, "],\n";
2003             } elsif (ref $_ eq "HASH") {
2004                 my %h = %$_;
2005                 print OUT " "x$indent, "{\n";
2006                 foreach (sort keys %h) {
2007                     if (ref $h{$_} eq "") {
2008                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2009                     } else {
2010                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2011                         $recurse->($indent + 8, $h{$_});
2012                     }
2013                 }
2014                 print OUT " "x$indent, "},\n";
2015             } else {
2016                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2017             }
2018         }
2019     };
2020     print OUT "our %unified_info = (\n";
2021     foreach (sort keys %unified_info) {
2022         if (ref $unified_info{$_} eq "") {
2023             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2024         } else {
2025             print OUT " "x4, quotify("perl", $_), " =>\n";
2026             $recurse->(8, $unified_info{$_});
2027         }
2028     }
2029     print OUT <<"EOF";
2030 );
2031
2032 EOF
2033 }
2034 print OUT "1;\n";
2035 close(OUT);
2036
2037
2038 print "CC            =$config{cross_compile_prefix}$target{cc}\n";
2039 print "CFLAG         =$target{cflags} $config{cflags}\n";
2040 print "SHARED_CFLAG  =$target{shared_cflag}\n";
2041 print "DEFINES       =",join(" ", @{$target{defines}}, @{$config{defines}}),"\n";
2042 print "LFLAG         =$target{lflags}\n";
2043 print "PLIB_LFLAG    =$target{plib_lflags}\n";
2044 print "EX_LIBS       =$target{ex_libs} $config{ex_libs}\n";
2045 print "APPS_OBJ      =$target{apps_obj}\n";
2046 print "CPUID_OBJ     =$target{cpuid_obj}\n";
2047 print "UPLINK_OBJ    =$target{uplink_obj}\n";
2048 print "BN_ASM        =$target{bn_obj}\n";
2049 print "EC_ASM        =$target{ec_obj}\n";
2050 print "DES_ENC       =$target{des_obj}\n";
2051 print "AES_ENC       =$target{aes_obj}\n";
2052 print "BF_ENC        =$target{bf_obj}\n";
2053 print "CAST_ENC      =$target{cast_obj}\n";
2054 print "RC4_ENC       =$target{rc4_obj}\n";
2055 print "RC5_ENC       =$target{rc5_obj}\n";
2056 print "MD5_OBJ_ASM   =$target{md5_obj}\n";
2057 print "SHA1_OBJ_ASM  =$target{sha1_obj}\n";
2058 print "RMD160_OBJ_ASM=$target{rmd160_obj}\n";
2059 print "CMLL_ENC      =$target{cmll_obj}\n";
2060 print "MODES_OBJ     =$target{modes_obj}\n";
2061 print "PADLOCK_OBJ   =$target{padlock_obj}\n";
2062 print "CHACHA_ENC    =$target{chacha_obj}\n";
2063 print "POLY1305_OBJ  =$target{poly1305_obj}\n";
2064 print "BLAKE2_OBJ    =$target{blake2_obj}\n";
2065 print "PROCESSOR     =$config{processor}\n";
2066 print "RANLIB        =", $target{ranlib} eq '$(CROSS_COMPILE)ranlib' ?
2067                              "$config{cross_compile_prefix}ranlib" :
2068                              "$target{ranlib}", "\n";
2069 print "ARFLAGS       =$target{arflags}\n";
2070 print "PERL          =$config{perl}\n";
2071 print "\n";
2072 print "SIXTY_FOUR_BIT_LONG mode\n" if $config{b64l};
2073 print "SIXTY_FOUR_BIT mode\n" if $config{b64};
2074 print "THIRTY_TWO_BIT mode\n" if $config{b32};
2075 print "BN_LLONG mode\n" if $config{bn_ll};
2076 print "RC4 uses $config{rc4_int}\n" if $config{rc4_int} ne $def_int;
2077
2078 my %builders = (
2079     unified => sub {
2080         run_dofile(catfile($blddir, $target{build_file}),
2081                    @{$config{build_file_templates}});
2082     },
2083     );
2084
2085 $builders{$builder}->($builder_platform, @builder_opts);
2086
2087 print <<"EOF";
2088
2089 Configured for $target.
2090 EOF
2091
2092 print <<"EOF" if ($disabled{threads} eq "unavailable");
2093
2094 The library could not be configured for supporting multi-threaded
2095 applications as the compiler options required on this system are not known.
2096 See file INSTALL for details if you need multi-threading.
2097 EOF
2098
2099 print <<"EOF" if ($no_shared_warn);
2100
2101 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2102 platform, so we will pretend you gave the option 'no-pic', which also disables
2103 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2104 or position independent code, please let us know (but please first make sure
2105 you have tried with a current version of OpenSSL).
2106 EOF
2107
2108 print <<"EOF" if (-f catfile($srcdir, "configdata.pm") && $srcdir ne $blddir);
2109
2110 WARNING: there are indications that another build was made in the source
2111 directory.  This build may have picked up artifacts from that build, the
2112 safest course of action is to clean the source directory and redo this
2113 configuration.
2114 EOF
2115
2116 exit(0);
2117
2118 ######################################################################
2119 #
2120 # Helpers and utility functions
2121 #
2122
2123 # Configuration file reading #########################################
2124
2125 # Note: All of the helper functions are for lazy evaluation.  They all
2126 # return a CODE ref, which will return the intended value when evaluated.
2127 # Thus, whenever there's mention of a returned value, it's about that
2128 # intended value.
2129
2130 # Helper function to implement conditional inheritance depending on the
2131 # value of $disabled{asm}.  Used in inherit_from values as follows:
2132 #
2133 #      inherit_from => [ "template", asm("asm_tmpl") ]
2134 #
2135 sub asm {
2136     my @x = @_;
2137     sub {
2138         $disabled{asm} ? () : @x;
2139     }
2140 }
2141
2142 # Helper function to implement conditional value variants, with a default
2143 # plus additional values based on the value of $config{build_type}.
2144 # Arguments are given in hash table form:
2145 #
2146 #       picker(default => "Basic string: ",
2147 #              debug   => "debug",
2148 #              release => "release")
2149 #
2150 # When configuring with --debug, the resulting string will be
2151 # "Basic string: debug", and when not, it will be "Basic string: release"
2152 #
2153 # This can be used to create variants of sets of flags according to the
2154 # build type:
2155 #
2156 #       cflags => picker(default => "-Wall",
2157 #                        debug   => "-g -O0",
2158 #                        release => "-O3")
2159 #
2160 sub picker {
2161     my %opts = @_;
2162     return sub { add($opts{default} || (),
2163                      $opts{$config{build_type}} || ())->(); }
2164 }
2165
2166 # Helper function to combine several values of different types into one.
2167 # This is useful if you want to combine a string with the result of a
2168 # lazy function, such as:
2169 #
2170 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2171 #
2172 sub combine {
2173     my @stuff = @_;
2174     return sub { add(@stuff)->(); }
2175 }
2176
2177 # Helper function to implement conditional values depending on the value
2178 # of $disabled{threads}.  Can be used as follows:
2179 #
2180 #       cflags => combine("-Wall", threads("-pthread"))
2181 #
2182 sub threads {
2183     my @flags = @_;
2184     return sub { add($disabled{threads} ? () : @flags)->(); }
2185 }
2186
2187
2188
2189 our $add_called = 0;
2190 # Helper function to implement adding values to already existing configuration
2191 # values.  It handles elements that are ARRAYs, CODEs and scalars
2192 sub _add {
2193     my $separator = shift;
2194
2195     # If there's any ARRAY in the collection of values OR the separator
2196     # is undef, we will return an ARRAY of combined values, otherwise a
2197     # string of joined values with $separator as the separator.
2198     my $found_array = !defined($separator);
2199
2200     my @values =
2201         map {
2202             my $res = $_;
2203             while (ref($res) eq "CODE") {
2204                 $res = $res->();
2205             }
2206             if (defined($res)) {
2207                 if (ref($res) eq "ARRAY") {
2208                     $found_array = 1;
2209                     @$res;
2210                 } else {
2211                     $res;
2212                 }
2213             } else {
2214                 ();
2215             }
2216     } (@_);
2217
2218     $add_called = 1;
2219
2220     if ($found_array) {
2221         [ @values ];
2222     } else {
2223         join($separator, grep { defined($_) && $_ ne "" } @values);
2224     }
2225 }
2226 sub add_before {
2227     my $separator = " ";
2228     if (ref($_[$#_]) eq "HASH") {
2229         my $opts = pop;
2230         $separator = $opts->{separator};
2231     }
2232     my @x = @_;
2233     sub { _add($separator, @x, @_) };
2234 }
2235 sub add {
2236     my $separator = " ";
2237     if (ref($_[$#_]) eq "HASH") {
2238         my $opts = pop;
2239         $separator = $opts->{separator};
2240     }
2241     my @x = @_;
2242     sub { _add($separator, @_, @x) };
2243 }
2244
2245 # configuration reader, evaluates the input file as a perl script and expects
2246 # it to fill %targets with target configurations.  Those are then added to
2247 # %table.
2248 sub read_config {
2249     my $fname = shift;
2250     open(CONFFILE, "< $fname")
2251         or die "Can't open configuration file '$fname'!\n";
2252     my $x = $/;
2253     undef $/;
2254     my $content = <CONFFILE>;
2255     $/ = $x;
2256     close(CONFFILE);
2257     my %targets = ();
2258     {
2259         # Protect certain tables from tampering
2260         local %table = %::table;
2261
2262         eval $content;
2263         warn $@ if $@;
2264     }
2265
2266     # For each target, check that it's configured with a hash table.
2267     foreach (keys %targets) {
2268         if (ref($targets{$_}) ne "HASH") {
2269             if (ref($targets{$_}) eq "") {
2270                 warn "Deprecated target configuration for $_, ignoring...\n";
2271             } else {
2272                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2273             }
2274             delete $targets{$_};
2275         } else {
2276             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
2277         }
2278     }
2279
2280     %table = (%table, %targets);
2281
2282 }
2283
2284 # configuration resolver.  Will only resolve all the lazy evaluation
2285 # codeblocks for the chosen target and all those it inherits from,
2286 # recursively
2287 sub resolve_config {
2288     my $target = shift;
2289     my @breadcrumbs = @_;
2290
2291 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2292
2293     if (grep { $_ eq $target } @breadcrumbs) {
2294         die "inherit_from loop!  target backtrace:\n  "
2295             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2296     }
2297
2298     if (!defined($table{$target})) {
2299         warn "Warning! target $target doesn't exist!\n";
2300         return ();
2301     }
2302     # Recurse through all inheritances.  They will be resolved on the
2303     # fly, so when this operation is done, they will all just be a
2304     # bunch of attributes with string values.
2305     # What we get here, though, are keys with references to lists of
2306     # the combined values of them all.  We will deal with lists after
2307     # this stage is done.
2308     my %combined_inheritance = ();
2309     if ($table{$target}->{inherit_from}) {
2310         my @inherit_from =
2311             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2312         foreach (@inherit_from) {
2313             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2314
2315             # 'template' is a marker that's considered private to
2316             # the config that had it.
2317             delete $inherited_config{template};
2318
2319             foreach (keys %inherited_config) {
2320                 if (!$combined_inheritance{$_}) {
2321                     $combined_inheritance{$_} = [];
2322                 }
2323                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2324             }
2325         }
2326     }
2327
2328     # We won't need inherit_from in this target any more, since we've
2329     # resolved all the inheritances that lead to this
2330     delete $table{$target}->{inherit_from};
2331
2332     # Now is the time to deal with those lists.  Here's the place to
2333     # decide what shall be done with those lists, all based on the
2334     # values of the target we're currently dealing with.
2335     # - If a value is a coderef, it will be executed with the list of
2336     #   inherited values as arguments.
2337     # - If the corresponding key doesn't have a value at all or is the
2338     #   empty string, the inherited value list will be run through the
2339     #   default combiner (below), and the result becomes this target's
2340     #   value.
2341     # - Otherwise, this target's value is assumed to be a string that
2342     #   will simply override the inherited list of values.
2343     my $default_combiner = add();
2344
2345     my %all_keys =
2346         map { $_ => 1 } (keys %combined_inheritance,
2347                          keys %{$table{$target}});
2348
2349     sub process_values {
2350         my $object    = shift;
2351         my $inherited = shift;  # Always a [ list ]
2352         my $target    = shift;
2353         my $entry     = shift;
2354
2355         $add_called = 0;
2356
2357         while(ref($object) eq "CODE") {
2358             $object = $object->(@$inherited);
2359         }
2360         if (!defined($object)) {
2361             return ();
2362         }
2363         elsif (ref($object) eq "ARRAY") {
2364             local $add_called;  # To make sure recursive calls don't affect it
2365             return [ map { process_values($_, $inherited, $target, $entry) }
2366                      @$object ];
2367         } elsif (ref($object) eq "") {
2368             return $object;
2369         } else {
2370             die "cannot handle reference type ",ref($object)
2371                 ," found in target ",$target," -> ",$entry,"\n";
2372         }
2373     }
2374
2375     foreach (sort keys %all_keys) {
2376         my $previous = $combined_inheritance{$_};
2377
2378         # Current target doesn't have a value for the current key?
2379         # Assign it the default combiner, the rest of this loop body
2380         # will handle it just like any other coderef.
2381         if (!exists $table{$target}->{$_}) {
2382             $table{$target}->{$_} = $default_combiner;
2383         }
2384
2385         $table{$target}->{$_} = process_values($table{$target}->{$_},
2386                                                $combined_inheritance{$_},
2387                                                $target, $_);
2388         unless(defined($table{$target}->{$_})) {
2389             delete $table{$target}->{$_};
2390         }
2391 #        if ($extra_checks &&
2392 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2393 #            warn "$_ got replaced in $target\n";
2394 #        }
2395     }
2396
2397     # Finally done, return the result.
2398     return %{$table{$target}};
2399 }
2400
2401 sub usage
2402         {
2403         print STDERR $usage;
2404         print STDERR "\npick os/compiler from:\n";
2405         my $j=0;
2406         my $i;
2407         my $k=0;
2408         foreach $i (sort keys %table)
2409                 {
2410                 next if $table{$i}->{template};
2411                 next if $i =~ /^debug/;
2412                 $k += length($i) + 1;
2413                 if ($k > 78)
2414                         {
2415                         print STDERR "\n";
2416                         $k=length($i);
2417                         }
2418                 print STDERR $i . " ";
2419                 }
2420         foreach $i (sort keys %table)
2421                 {
2422                 next if $table{$i}->{template};
2423                 next if $i !~ /^debug/;
2424                 $k += length($i) + 1;
2425                 if ($k > 78)
2426                         {
2427                         print STDERR "\n";
2428                         $k=length($i);
2429                         }
2430                 print STDERR $i . " ";
2431                 }
2432         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2433         exit(1);
2434         }
2435
2436 sub run_dofile
2437 {
2438     my $out = shift;
2439     my @templates = @_;
2440
2441     unlink $out || warn "Can't remove $out, $!"
2442         if -f $out;
2443     foreach (@templates) {
2444         die "Can't open $_, $!" unless -f $_;
2445     }
2446     my $perlcmd = (quotify("maybeshell", $config{perl}))[0];
2447     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
2448     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2449     system($cmd);
2450     exit 1 if $? != 0;
2451     rename("$out.new", $out) || die "Can't rename $out.new, $!";
2452 }
2453
2454 sub which
2455 {
2456     my ($name)=@_;
2457
2458     if (eval { require IPC::Cmd; 1; }) {
2459         IPC::Cmd->import();
2460         return scalar IPC::Cmd::can_run($name);
2461     } else {
2462         # if there is $directories component in splitpath,
2463         # then it's not something to test with $PATH...
2464         return $name if (File::Spec->splitpath($name))[1];
2465
2466         foreach (File::Spec->path()) {
2467             my $fullpath = catfile($_, "$name$target{exe_extension}");
2468             if (-f $fullpath and -x $fullpath) {
2469                 return $fullpath;
2470             }
2471         }
2472     }
2473 }
2474
2475 # Configuration printer ##############################################
2476
2477 sub print_table_entry
2478 {
2479     my $target = shift;
2480     my %target = resolve_config($target);
2481     my $type = shift;
2482
2483     # Don't print the templates
2484     return if $target{template};
2485
2486     my @sequence = (
2487         "sys_id",
2488         "cc",
2489         "cflags",
2490         "defines",
2491         "unistd",
2492         "ld",
2493         "lflags",
2494         "loutflag",
2495         "plib_lflags",
2496         "ex_libs",
2497         "bn_ops",
2498         "apps_aux_src",
2499         "cpuid_asm_src",
2500         "uplink_aux_src",
2501         "bn_asm_src",
2502         "ec_asm_src",
2503         "des_asm_src",
2504         "aes_asm_src",
2505         "bf_asm_src",
2506         "md5_asm_src",
2507         "cast_asm_src",
2508         "sha1_asm_src",
2509         "rc4_asm_src",
2510         "rmd160_asm_src",
2511         "rc5_asm_src",
2512         "wp_asm_src",
2513         "cmll_asm_src",
2514         "modes_asm_src",
2515         "padlock_asm_src",
2516         "chacha_asm_src",
2517         "poly1035_asm_src",
2518         "thread_scheme",
2519         "perlasm_scheme",
2520         "dso_scheme",
2521         "shared_target",
2522         "shared_cflag",
2523         "shared_defines",
2524         "shared_ldflag",
2525         "shared_rcflag",
2526         "shared_extension",
2527         "dso_extension",
2528         "obj_extension",
2529         "exe_extension",
2530         "ranlib",
2531         "ar",
2532         "arflags",
2533         "aroutflag",
2534         "rc",
2535         "rcflags",
2536         "rcoutflag",
2537         "mt",
2538         "mtflags",
2539         "mtinflag",
2540         "mtoutflag",
2541         "multilib",
2542         "build_scheme",
2543         );
2544
2545     if ($type eq "TABLE") {
2546         print "\n";
2547         print "*** $target\n";
2548         foreach (@sequence) {
2549             if (ref($target{$_}) eq "ARRAY") {
2550                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
2551             } else {
2552                 printf "\$%-12s = %s\n", $_, $target{$_};
2553             }
2554         }
2555     } elsif ($type eq "HASH") {
2556         my $largest =
2557             length((sort { length($a) <=> length($b) } @sequence)[-1]);
2558         print "    '$target' => {\n";
2559         foreach (@sequence) {
2560             if ($target{$_}) {
2561                 if (ref($target{$_}) eq "ARRAY") {
2562                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
2563                 } else {
2564                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
2565                 }
2566             }
2567         }
2568         print "    },\n";
2569     }
2570 }
2571
2572 # Utility routines ###################################################
2573
2574 # On VMS, if the given file is a logical name, File::Spec::Functions
2575 # will consider it an absolute path.  There are cases when we want a
2576 # purely syntactic check without checking the environment.
2577 sub isabsolute {
2578     my $file = shift;
2579
2580     # On non-platforms, we just use file_name_is_absolute().
2581     return file_name_is_absolute($file) unless $^O eq "VMS";
2582
2583     # If the file spec includes a device or a directpry spec,
2584     # file_name_is_absolute() is perfectly safe.
2585     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
2586
2587     # Here, we know the given file spec isn't absolute
2588     return 0;
2589 }
2590
2591 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
2592 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
2593 # realpath() requires that at least all path components except the last is an
2594 # existing directory.  On VMS, the last component of the directory spec must
2595 # exist.
2596 sub absolutedir {
2597     my $dir = shift;
2598
2599     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
2600     # will return the volume name for the device, no matter what.  Also,
2601     # it will return an incorrect directory spec if the argument is a
2602     # directory that doesn't exist.
2603     if ($^O eq "VMS") {
2604         return rel2abs($dir);
2605     }
2606
2607     # We use realpath() on Unix, since no other will properly clean out
2608     # a directory spec.
2609     use Cwd qw/realpath/;
2610
2611     return realpath($dir);
2612 }
2613
2614 sub quotify {
2615     my %processors = (
2616         perl    => sub { my $x = shift;
2617                          $x =~ s/([\\\$\@"])/\\$1/g;
2618                          return '"'.$x.'"'; },
2619         maybeshell => sub { my $x = shift;
2620                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
2621                             if ($x ne $y || $x =~ m|\s|) {
2622                                 return '"'.$y.'"';
2623                             } else {
2624                                 return $x;
2625                             }
2626                         },
2627         );
2628     my $for = shift;
2629     my $processor =
2630         defined($processors{$for}) ? $processors{$for} : sub { shift; };
2631
2632     return map { $processor->($_); } @_;
2633 }
2634
2635 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
2636 # $filename is a file name to read from
2637 # $line_concat_cond_re is a regexp detecting a line continuation ending
2638 # $line_concat is a CODEref that takes care of concatenating two lines
2639 sub collect_from_file {
2640     my $filename = shift;
2641     my $line_concat_cond_re = shift;
2642     my $line_concat = shift;
2643
2644     open my $fh, $filename || die "unable to read $filename: $!\n";
2645     return sub {
2646         my $saved_line = "";
2647         $_ = "";
2648         while (<$fh>) {
2649             s|\R$||;
2650             if (defined $line_concat) {
2651                 $_ = $line_concat->($saved_line, $_);
2652                 $saved_line = "";
2653             }
2654             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2655                 $saved_line = $_;
2656                 next;
2657             }
2658             return $_;
2659         }
2660         die "$filename ending with continuation line\n" if $_;
2661         close $fh;
2662         return undef;
2663     }
2664 }
2665
2666 # collect_from_array($array, $line_concat_cond_re, $line_concat)
2667 # $array is an ARRAYref of lines
2668 # $line_concat_cond_re is a regexp detecting a line continuation ending
2669 # $line_concat is a CODEref that takes care of concatenating two lines
2670 sub collect_from_array {
2671     my $array = shift;
2672     my $line_concat_cond_re = shift;
2673     my $line_concat = shift;
2674     my @array = (@$array);
2675
2676     return sub {
2677         my $saved_line = "";
2678         $_ = "";
2679         while (defined($_ = shift @array)) {
2680             s|\R$||;
2681             if (defined $line_concat) {
2682                 $_ = $line_concat->($saved_line, $_);
2683                 $saved_line = "";
2684             }
2685             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2686                 $saved_line = $_;
2687                 next;
2688             }
2689             return $_;
2690         }
2691         die "input text ending with continuation line\n" if $_;
2692         return undef;
2693     }
2694 }
2695
2696 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
2697 # $lineiterator is a CODEref that delivers one line at a time.
2698 # All following arguments are regex/CODEref pairs, where the regexp detects a
2699 # line and the CODEref does something with the result of the regexp.
2700 sub collect_information {
2701     my $lineiterator = shift;
2702     my %collectors = @_;
2703
2704     while(defined($_ = $lineiterator->())) {
2705         s|\R$||;
2706         my $found = 0;
2707         if ($collectors{"BEFORE"}) {
2708             $collectors{"BEFORE"}->($_);
2709         }
2710         foreach my $re (keys %collectors) {
2711             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
2712                 $collectors{$re}->($lineiterator);
2713                 $found = 1;
2714             };
2715         }
2716         if ($collectors{"OTHERWISE"}) {
2717             $collectors{"OTHERWISE"}->($lineiterator, $_)
2718                 unless $found || !defined $collectors{"OTHERWISE"};
2719         }
2720         if ($collectors{"AFTER"}) {
2721             $collectors{"AFTER"}->($_);
2722         }
2723     }
2724 }
2725
2726 # tokenize($line)
2727 # $line is a line of text to split up into tokens
2728 # returns a list of tokens
2729 #
2730 # Tokens are divided by spaces.  If the tokens include spaces, they
2731 # have to be quoted with single or double quotes.  Double quotes
2732 # inside a double quoted token must be escaped.  Escaping is done
2733 # with backslash.
2734 # Basically, the same quoting rules apply for " and ' as in any
2735 # Unix shell.
2736 sub tokenize {
2737     my $line = my $debug_line = shift;
2738     my @result = ();
2739
2740     while ($line =~ s|^\s+||, $line ne "") {
2741         my $token = "";
2742         while ($line ne "" && $line !~ m|^\s|) {
2743             if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
2744                 $token .= $1;
2745                 $line = $';
2746             } elsif ($line =~ m/^'([^']*)'/) {
2747                 $token .= $1;
2748                 $line = $';
2749             } elsif ($line =~ m/^(\S+)/) {
2750                 $token .= $1;
2751                 $line = $';
2752             }
2753         }
2754         push @result, $token;
2755     }
2756
2757     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
2758         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
2759         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
2760     }
2761     return @result;
2762 }