Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::Glob;
  21
  22 # see INSTALL for instructions.
  23
  24 my $orig_death_handler = $SIG{__DIE__};
  25 $SIG{__DIE__} = \&death_handler;
  26
  27 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  28
  29 # Options:
  30 #
  31 # --config      add the given configuration file, which will be read after
  32 #               any "Configurations*" files that are found in the same
  33 #               directory as this script.
  34 # --prefix      prefix for the OpenSSL installation, which includes the
  35 #               directories bin, lib, include, share/man, share/doc/openssl
  36 #               This becomes the value of INSTALLTOP in Makefile
  37 #               (Default: /usr/local)
  38 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  39 #               If it's a relative directory, it will be added on the directory
  40 #               given with --prefix.
  41 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  42 #               (Default: PREFIX/ssl)
  43 #
  44 # --cross-compile-prefix Add specified prefix to binutils components.
  45 #
  46 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0.0 / 3.
  47 #               Do not compile support for interfaces deprecated as of the
  48 #               specified OpenSSL version.
  49 #
  50 # no-hw-xxx     do not compile support for specific crypto hardware.
  51 #               Generic OpenSSL-style methods relating to this support
  52 #               are always compiled but return NULL if the hardware
  53 #               support isn't compiled.
  54 # no-hw         do not compile support for any crypto hardware.
  55 # [no-]threads  [don't] try to create a library that is suitable for
  56 #               multithreaded applications (default is "threads" if we
  57 #               know how to do it)
  58 # [no-]shared   [don't] try to create shared libraries when supported.
  59 # [no-]pic      [don't] try to build position independent code when supported.
  60 #               If disabled, it also disables shared and dynamic-engine.
  61 # no-asm        do not use assembler
  62 # no-dso        do not compile in any native shared-library methods. This
  63 #               will ensure that all methods just return NULL.
  64 # no-egd        do not compile support for the entropy-gathering daemon APIs
  65 # [no-]zlib     [don't] compile support for zlib compression.
  66 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  67 #               library and will be loaded in run-time by the OpenSSL library.
  68 # sctp          include SCTP support
  69 # enable-weak-ssl-ciphers
  70 #               Enable weak ciphers that are disabled by default.
  71 # 386           generate 80386 code in assembly modules
  72 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  73 #               mentioned '386' option implies this one
  74 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  75 # -<xxx> +<xxx> compiler options are passed through
  76 # -static       while -static is also a pass-through compiler option (and
  77 #               as such is limited to environments where it's actually
  78 #               meaningful), it triggers a number configuration options,
  79 #               namely no-dso, no-pic, no-shared and no-threads. It is
  80 #               argued that the only reason to produce statically linked
  81 #               binaries (and in context it means executables linked with
  82 #               -static flag, and not just executables linked with static
  83 #               libcrypto.a) is to eliminate dependency on specific run-time,
  84 #               a.k.a. libc version. The mentioned config options are meant
  85 #               to achieve just that. Unfortunately on Linux it's impossible
  86 #               to eliminate the dependency completely for openssl executable
  87 #               because of getaddrinfo and gethostbyname calls, which can
  88 #               invoke dynamically loadable library facility anyway to meet
  89 #               the lookup requests. For this reason on Linux statically
  90 #               linked openssl executable has rather debugging value than
  91 #               production quality.
  92 #
  93 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
  94 #               provided to stack calls. Generates unique stack functions for
  95 #               each possible stack type.
  96 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  97 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  98 # Following are set automatically by this script
  99 #
 100 # MD5_ASM       use some extra md5 assembler,
 101 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 102 # RMD160_ASM    use some extra ripemd160 assembler,
 103 # SHA256_ASM    sha256_block is implemented in assembler
 104 # SHA512_ASM    sha512_block is implemented in assembler
 105 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 106
 107 # Minimum warning options... any contributions to OpenSSL should at least get
 108 # past these.
 109
 110 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 111 # -DPEDANTIC complements -pedantic and is meant to mask code that
 112 # is not strictly standard-compliant and/or implementation-specific,
 113 # e.g. inline assembly, disregards to alignment requirements, such
 114 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 115 # to be used even in sanitized builds, because sanitizer too is
 116 # supposed to and does take notice of non-standard behaviour. Then
 117 # -pedantic with pre-C9x compiler would also complain about 'long
 118 # long' not being supported. As 64-bit algorithms are common now,
 119 # it grew impossible to resolve this without sizeable additional
 120 # code, so we just tell compiler to be pedantic about everything
 121 # but 'long long' type.
 122
 123 my %gcc_devteam_warn = ();
 124 {
 125     my @common = qw( -DDEBUG_UNUSED
 126                      -DPEDANTIC -pedantic -Wno-long-long
 127                      -Wall
 128                      -Wextra
 129                      -Wno-unused-parameter
 130                      -Wno-missing-field-initializers
 131                      -Wswitch
 132                      -Wsign-compare
 133                      -Wshadow
 134                      -Wformat
 135                      -Wtype-limits
 136                      -Wundef
 137                      -Werror );
 138     %gcc_devteam_warn = (
 139         CFLAGS          => [ @common, qw( -Wmissing-prototypes
 140                                           -Wstrict-prototypes ) ],
 141         CXXFLAGS        => [ @common ]
 142     );
 143 }
 144
 145 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 146 # TODO(openssl-team): fix problems and investigate if (at least) the
 147 # following warnings can also be enabled:
 148 #       -Wcast-align
 149 #       -Wunreachable-code -- no, too ugly/compiler-specific
 150 #       -Wlanguage-extension-token -- no, we use asm()
 151 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 152 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 153 my %clang_devteam_warn = ();
 154 {
 155     my @common = qw( -Wswitch-default
 156                      -Wno-parentheses-equality
 157                      -Wno-language-extension-token
 158                      -Wno-extended-offsetof
 159                      -Wconditional-uninitialized
 160                      -Wincompatible-pointer-types-discards-qualifiers
 161                      -Wno-unknown-warning-option );
 162     %clang_devteam_warn = (
 163         CFLAGS          => [ @common, qw( -Wmissing-variable-declarations ) ],
 164         CXXFLAGS        => [ @common ]
 165     );
 166 }
 167
 168 # This adds backtrace information to the memory leak info.  Is only used
 169 # when crypto-mdebug-backtrace is enabled.
 170 my $memleak_devteam_backtrace = "-rdynamic";
 171
 172 my $strict_warnings = 0;
 173
 174 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 175 # which would cover all BSD flavors. -pthread applies to them all,
 176 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 177 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 178 # which has to be accompanied by explicit -D_THREAD_SAFE and
 179 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 180 # seems to be sufficient?
 181 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 182
 183 #
 184 # API compatibility name to version number mapping.
 185 #
 186 my $maxapi = "3.0.0";           # API for "no-deprecated" builds
 187 my $apitable = {
 188     "3.0.0" => 3,
 189     "1.1.1" => 2,
 190     "1.1.0" => 2,
 191     "1.0.2" => 1,
 192     "1.0.1" => 1,
 193     "1.0.0" => 1,
 194     "0.9.8" => 0,
 195 };
 196
 197 our %table = ();
 198 our %config = ();
 199 our %withargs = ();
 200 our $now_printing;      # set to current entry's name in print_table_entry
 201                         # (todo: right thing would be to encapsulate name
 202                         # into %target [class] and make print_table_entry
 203                         # a method)
 204
 205 # Forward declarations ###############################################
 206
 207 # read_config(filename)
 208 #
 209 # Reads a configuration file and populates %table with the contents
 210 # (which the configuration file places in %targets).
 211 sub read_config;
 212
 213 # resolve_config(target)
 214 #
 215 # Resolves all the late evaluations, inheritances and so on for the
 216 # chosen target and any target it inherits from.
 217 sub resolve_config;
 218
 219
 220 # Information collection #############################################
 221
 222 # Unified build supports separate build dir
 223 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 224 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 225 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 226
 227 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 228
 229 $config{sourcedir} = abs2rel($srcdir);
 230 $config{builddir} = abs2rel($blddir);
 231
 232 # Collect reconfiguration information if needed
 233 my @argvcopy=@ARGV;
 234
 235 if (grep /^reconf(igure)?$/, @argvcopy) {
 236     die "reconfiguring with other arguments present isn't supported"
 237         if scalar @argvcopy > 1;
 238     if (-f "./configdata.pm") {
 239         my $file = "./configdata.pm";
 240         unless (my $return = do $file) {
 241             die "couldn't parse $file: $@" if $@;
 242             die "couldn't do $file: $!"    unless defined $return;
 243             die "couldn't run $file"       unless $return;
 244         }
 245
 246         @argvcopy = defined($configdata::config{perlargv}) ?
 247             @{$configdata::config{perlargv}} : ();
 248         die "Incorrect data to reconfigure, please do a normal configuration\n"
 249             if (grep(/^reconf/,@argvcopy));
 250         $config{perlenv} = $configdata::config{perlenv} // {};
 251     } else {
 252         die "Insufficient data to reconfigure, please do a normal configuration\n";
 253     }
 254 }
 255
 256 $config{perlargv} = [ @argvcopy ];
 257
 258 # Collect version numbers
 259 $config{major} = "unknown";
 260 $config{minor} = "unknown";
 261 $config{patch} = "unknown";
 262 $config{prerelease} = "";
 263 $config{build_metadata} = "";
 264 $config{shlib_version} = "unknown";
 265
 266 collect_information(
 267     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 268     qr/#\s+define\s+OPENSSL_VERSION_MAJOR\s+(\d+)/ =>
 269         sub { $config{major} = $1; },
 270     qr/#\s+define\s+OPENSSL_VERSION_MINOR\s+(\d+)/ =>
 271         sub { $config{minor} = $1; },
 272     qr/#\s+define\s+OPENSSL_VERSION_PATCH\s+(\d+)/ =>
 273         sub { $config{patch} = $1; },
 274     qr/#\s+define\s+OPENSSL_VERSION_PRE_RELEASE\s+"((?:\\.|[^"])*)"/ =>
 275         sub { $config{prerelease} = $1; },
 276     qr/#\s+define\s+OPENSSL_VERSION_BUILD_METADATA\s+"((?:\\.|[^"])*)"/ =>
 277         sub { $config{build_metadata} = $1; },
 278     qr/#\s+define\s+OPENSSL_SHLIB_VERSION\s+([\d\.]+)/ =>
 279         sub { $config{shlib_version} = $1; },
 280     );
 281 die "erroneous version information in opensslv.h: ",
 282     "$config{major}.$config{minor}.$config{patch}, $config{shlib_version}\n"
 283     if ($config{major} eq "unknown"
 284             || $config{minor} eq "unknown"
 285             || $config{patch} eq "unknown"
 286             || $config{shlib_version} eq "unknown");
 287
 288 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 289 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 290
 291 # Collect target configurations
 292
 293 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 294 foreach (sort glob($pattern)) {
 295     &read_config($_);
 296 }
 297
 298 if (defined env($local_config_envname)) {
 299     if ($^O eq 'VMS') {
 300         # VMS environment variables are logical names,
 301         # which can be used as is
 302         $pattern = $local_config_envname . ':' . '*.conf';
 303     } else {
 304         $pattern = catfile(env($local_config_envname), '*.conf');
 305     }
 306
 307     foreach (sort glob($pattern)) {
 308         &read_config($_);
 309     }
 310 }
 311
 312 # Save away perl command information
 313 $config{perl_cmd} = $^X;
 314 $config{perl_version} = $Config{version};
 315 $config{perl_archname} = $Config{archname};
 316
 317 $config{prefix}="";
 318 $config{openssldir}="";
 319 $config{processor}="";
 320 $config{libdir}="";
 321 my $auto_threads=1;    # enable threads automatically? true by default
 322 my $default_ranlib;
 323
 324 # Known TLS and DTLS protocols
 325 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 326 my @dtls = qw(dtls1 dtls1_2);
 327
 328 # Explicitly known options that are possible to disable.  They can
 329 # be regexps, and will be used like this: /^no-${option}$/
 330 # For developers: keep it sorted alphabetically
 331
 332 my @disablables = (
 333     "ktls",
 334     "afalgeng",
 335     "aria",
 336     "asan",
 337     "asm",
 338     "async",
 339     "autoalginit",
 340     "autoerrinit",
 341     "autoload-config",
 342     "bf",
 343     "blake2",
 344     "buildtest-c++",
 345     "camellia",
 346     "capieng",
 347     "cast",
 348     "chacha",
 349     "cmac",
 350     "cms",
 351     "comp",
 352     "crypto-mdebug",
 353     "crypto-mdebug-backtrace",
 354     "ct",
 355     "deprecated",
 356     "des",
 357     "devcryptoeng",
 358     "dgram",
 359     "dh",
 360     "dsa",
 361     "dso",
 362     "dtls",
 363     "dynamic-engine",
 364     "ec",
 365     "ec2m",
 366     "ecdh",
 367     "ecdsa",
 368     "ec_nistp_64_gcc_128",
 369     "egd",
 370     "engine",
 371     "err",
 372     "external-tests",
 373     "filenames",
 374     "fuzz-libfuzzer",
 375     "fuzz-afl",
 376     "gost",
 377     "heartbeats",
 378     "idea",
 379     "makedepend",
 380     "md2",
 381     "md4",
 382     "mdc2",
 383     "msan",
 384     "multiblock",
 385     "nextprotoneg",
 386     "pinshared",
 387     "ocb",
 388     "ocsp",
 389     "padlockeng",
 390     "pic",
 391     "poly1305",
 392     "posix-io",
 393     "psk",
 394     "rc2",
 395     "rc4",
 396     "rc5",
 397     "rdrand",
 398     "rfc3779",
 399     "rmd160",
 400     "scrypt",
 401     "sctp",
 402     "seed",
 403     "shared",
 404     "siphash",
 405     "siv",
 406     "sm2",
 407     "sm3",
 408     "sm4",
 409     "sock",
 410     "srp",
 411     "srtp",
 412     "sse2",
 413     "ssl",
 414     "ssl-trace",
 415     "static-engine",
 416     "stdio",
 417     "tests",
 418     "threads",
 419     "tls",
 420     "ts",
 421     "ubsan",
 422     "ui-console",
 423     "unit-test",
 424     "whirlpool",
 425     "weak-ssl-ciphers",
 426     "zlib",
 427     "zlib-dynamic",
 428     );
 429 foreach my $proto ((@tls, @dtls))
 430         {
 431         push(@disablables, $proto);
 432         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 433         }
 434
 435 my %deprecated_disablables = (
 436     "ssl2" => undef,
 437     "buf-freelists" => undef,
 438     "hw" => "hw",               # causes cascade, but no macro
 439     "hw-padlock" => "padlockeng",
 440     "ripemd" => "rmd160",
 441     "ui" => "ui-console",
 442     );
 443
 444 # All of the following are disabled by default:
 445
 446 our %disabled = ( # "what"         => "comment"
 447                   "asan"                => "default",
 448                   "buildtest-c++"       => "default",
 449                   "crypto-mdebug"       => "default",
 450                   "crypto-mdebug-backtrace" => "default",
 451                   "devcryptoeng"        => "default",
 452                   "ec_nistp_64_gcc_128" => "default",
 453                   "egd"                 => "default",
 454                   "external-tests"      => "default",
 455                   "fuzz-libfuzzer"      => "default",
 456                   "fuzz-afl"            => "default",
 457                   "heartbeats"          => "default",
 458                   "md2"                 => "default",
 459                   "msan"                => "default",
 460                   "rc5"                 => "default",
 461                   "sctp"                => "default",
 462                   "ssl-trace"           => "default",
 463                   "ssl3"                => "default",
 464                   "ssl3-method"         => "default",
 465                   "ubsan"               => "default",
 466                   "unit-test"           => "default",
 467                   "weak-ssl-ciphers"    => "default",
 468                   "zlib"                => "default",
 469                   "zlib-dynamic"        => "default",
 470                   "ktls"                => "default",
 471                 );
 472
 473 # Note: => pair form used for aesthetics, not to truly make a hash table
 474 my @disable_cascades = (
 475     # "what"            => [ "cascade", ... ]
 476     sub { $config{processor} eq "386" }
 477                         => [ "sse2" ],
 478     "ssl"               => [ "ssl3" ],
 479     "ssl3-method"       => [ "ssl3" ],
 480     "zlib"              => [ "zlib-dynamic" ],
 481     "des"               => [ "mdc2" ],
 482     "ec"                => [ "ecdsa", "ecdh" ],
 483
 484     "dgram"             => [ "dtls", "sctp" ],
 485     "sock"              => [ "dgram" ],
 486     "dtls"              => [ @dtls ],
 487     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 488                         => [ "dtls" ],
 489
 490     "tls"               => [ @tls ],
 491     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 492                         => [ "tls" ],
 493
 494     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 495
 496     # Without DSO, we can't load dynamic engines, so don't build them dynamic
 497     "dso"               => [ "dynamic-engine" ],
 498
 499     # Without position independent code, there can be no shared libraries or DSOs
 500     "pic"               => [ "shared" ],
 501     "shared"            => [ "dynamic-engine" ],
 502
 503     "engine"            => [ grep /eng$/, @disablables ],
 504     "hw"                => [ "padlockeng" ],
 505
 506     # no-autoalginit is only useful when building non-shared
 507     "autoalginit"       => [ "shared", "apps" ],
 508
 509     "stdio"             => [ "apps", "capieng", "egd" ],
 510     "apps"              => [ "tests" ],
 511     "tests"             => [ "external-tests" ],
 512     "comp"              => [ "zlib" ],
 513     "ec"                => [ "tls1_3", "sm2" ],
 514     "sm3"               => [ "sm2" ],
 515     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 516
 517     sub { !$disabled{"msan"} } => [ "asm" ],
 518
 519     sub { $disabled{cmac}; } => [ "siv" ],
 520     );
 521
 522 # Avoid protocol support holes.  Also disable all versions below N, if version
 523 # N is disabled while N+1 is enabled.
 524 #
 525 my @list = (reverse @tls);
 526 while ((my $first, my $second) = (shift @list, shift @list)) {
 527     last unless @list;
 528     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 529                               => [ @list ] );
 530     unshift @list, $second;
 531 }
 532 my @list = (reverse @dtls);
 533 while ((my $first, my $second) = (shift @list, shift @list)) {
 534     last unless @list;
 535     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 536                               => [ @list ] );
 537     unshift @list, $second;
 538 }
 539
 540 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 541 # To remove something from %disabled, use "enable-foo".
 542 # For symmetry, "disable-foo" is a synonym for "no-foo".
 543
 544 &usage if ($#ARGV < 0);
 545
 546 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 547 # platform specific list separators.  Users from those platforms should
 548 # recognise those separators from how you set up the PATH to find executables.
 549 # The default is the Unix like separator, :, but as an exception, we also
 550 # support the space as separator.
 551 my $list_separator_re =
 552     { VMS           => qr/(?<!\^),/,
 553       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 554 # All the "make variables" we support
 555 # Some get pre-populated for the sake of backward compatibility
 556 # (we supported those before the change to "make variable" support.
 557 my %user = (
 558     AR          => env('AR'),
 559     ARFLAGS     => [],
 560     AS          => undef,
 561     ASFLAGS     => [],
 562     CC          => env('CC'),
 563     CFLAGS      => [ env('CFLAGS') || () ],
 564     CXX         => env('CXX'),
 565     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 566     CPP         => undef,
 567     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 568     CPPDEFINES  => [],  # Alternative for -D
 569     CPPINCLUDES => [],  # Alternative for -I
 570     CROSS_COMPILE => env('CROSS_COMPILE'),
 571     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 572     LD          => undef,
 573     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 574     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 575     MT          => undef,
 576     MTFLAGS     => [],
 577     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 578     RANLIB      => env('RANLIB'),
 579     RC          => env('RC') || env('WINDRES'),
 580     RCFLAGS     => [],
 581     RM          => undef,
 582    );
 583 # Info about what "make variables" may be prefixed with the cross compiler
 584 # prefix.  This should NEVER mention any such variable with a list for value.
 585 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 586 # The same but for flags given as Configure options.  These are *additional*
 587 # input, as opposed to the VAR=string option that override the corresponding
 588 # config target attributes
 589 my %useradd = (
 590     CPPDEFINES  => [],
 591     CPPINCLUDES => [],
 592     CPPFLAGS    => [],
 593     CFLAGS      => [],
 594     CXXFLAGS    => [],
 595     LDFLAGS     => [],
 596     LDLIBS      => [],
 597    );
 598
 599 my %user_synonyms = (
 600     HASHBANGPERL=> 'PERL',
 601     RC          => 'WINDRES',
 602    );
 603
 604 # Some target attributes have been renamed, this is the translation table
 605 my %target_attr_translate =(
 606     ar          => 'AR',
 607     as          => 'AS',
 608     cc          => 'CC',
 609     cxx         => 'CXX',
 610     cpp         => 'CPP',
 611     hashbangperl => 'HASHBANGPERL',
 612     ld          => 'LD',
 613     mt          => 'MT',
 614     ranlib      => 'RANLIB',
 615     rc          => 'RC',
 616     rm          => 'RM',
 617    );
 618
 619 # Initialisers coming from 'config' scripts
 620 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 621 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 622 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 623 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 624 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 625 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 626 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 627
 628 $config{openssl_api_defines}=[];
 629 $config{openssl_sys_defines}=[];
 630 $config{openssl_feature_defines}=[];
 631 $config{options}="";
 632 $config{build_type} = "release";
 633 my $target="";
 634
 635 my %cmdvars = ();               # Stores FOO='blah' type arguments
 636 my %unsupported_options = ();
 637 my %deprecated_options = ();
 638 # If you change this, update apps/version.c
 639 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 640 my @seed_sources = ();
 641 while (@argvcopy)
 642         {
 643         $_ = shift @argvcopy;
 644
 645         # Support env variable assignments among the options
 646         if (m|^(\w+)=(.+)?$|)
 647                 {
 648                 $cmdvars{$1} = $2;
 649                 # Every time a variable is given as a configuration argument,
 650                 # it acts as a reset if the variable.
 651                 if (exists $user{$1})
 652                         {
 653                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 654                         }
 655                 #if (exists $useradd{$1})
 656                 #       {
 657                 #       $useradd{$1} = [];
 658                 #       }
 659                 next;
 660                 }
 661
 662         # VMS is a case insensitive environment, and depending on settings
 663         # out of our control, we may receive options uppercased.  Let's
 664         # downcase at least the part before any equal sign.
 665         if ($^O eq "VMS")
 666                 {
 667                 s/^([^=]*)/lc($1)/e;
 668                 }
 669
 670         # some people just can't read the instructions, clang people have to...
 671         s/^-no-(?!integrated-as)/no-/;
 672
 673         # rewrite some options in "enable-..." form
 674         s /^-?-?shared$/enable-shared/;
 675         s /^sctp$/enable-sctp/;
 676         s /^threads$/enable-threads/;
 677         s /^zlib$/enable-zlib/;
 678         s /^zlib-dynamic$/enable-zlib-dynamic/;
 679
 680         if (/^(no|disable|enable)-(.+)$/)
 681                 {
 682                 my $word = $2;
 683                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 684                         && !exists $deprecated_disablables{$word}
 685                         && !grep { $word eq $_ } @disablables)
 686                         {
 687                         $unsupported_options{$_} = 1;
 688                         next;
 689                         }
 690                 }
 691         if (/^no-(.+)$/ || /^disable-(.+)$/)
 692                 {
 693                 foreach my $proto ((@tls, @dtls))
 694                         {
 695                         if ($1 eq "$proto-method")
 696                                 {
 697                                 $disabled{"$proto"} = "option($proto-method)";
 698                                 last;
 699                                 }
 700                         }
 701                 if ($1 eq "dtls")
 702                         {
 703                         foreach my $proto (@dtls)
 704                                 {
 705                                 $disabled{$proto} = "option(dtls)";
 706                                 }
 707                         $disabled{"dtls"} = "option(dtls)";
 708                         }
 709                 elsif ($1 eq "ssl")
 710                         {
 711                         # Last one of its kind
 712                         $disabled{"ssl3"} = "option(ssl)";
 713                         }
 714                 elsif ($1 eq "tls")
 715                         {
 716                         # XXX: Tests will fail if all SSL/TLS
 717                         # protocols are disabled.
 718                         foreach my $proto (@tls)
 719                                 {
 720                                 $disabled{$proto} = "option(tls)";
 721                                 }
 722                         }
 723                 elsif ($1 eq "static-engine")
 724                         {
 725                         delete $disabled{"dynamic-engine"};
 726                         }
 727                 elsif ($1 eq "dynamic-engine")
 728                         {
 729                         $disabled{"dynamic-engine"} = "option";
 730                         }
 731                 elsif (exists $deprecated_disablables{$1})
 732                         {
 733                         $deprecated_options{$_} = 1;
 734                         if (defined $deprecated_disablables{$1})
 735                                 {
 736                                 $disabled{$deprecated_disablables{$1}} = "option";
 737                                 }
 738                         }
 739                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 740                         {
 741                         $deprecated_options{$_} = 1;
 742                         }
 743                 else
 744                         {
 745                         $disabled{$1} = "option";
 746                         }
 747                 # No longer an automatic choice
 748                 $auto_threads = 0 if ($1 eq "threads");
 749                 }
 750         elsif (/^enable-(.+)$/)
 751                 {
 752                 if ($1 eq "static-engine")
 753                         {
 754                         $disabled{"dynamic-engine"} = "option";
 755                         }
 756                 elsif ($1 eq "dynamic-engine")
 757                         {
 758                         delete $disabled{"dynamic-engine"};
 759                         }
 760                 elsif ($1 eq "zlib-dynamic")
 761                         {
 762                         delete $disabled{"zlib"};
 763                         }
 764                 my $algo = $1;
 765                 delete $disabled{$algo};
 766
 767                 # No longer an automatic choice
 768                 $auto_threads = 0 if ($1 eq "threads");
 769                 }
 770         elsif (/^--strict-warnings$/)
 771                 {
 772                 # Pretend that our strict flags is a C flag, and replace it
 773                 # with the proper flags later on
 774                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 775                 push @{$useradd{CXXFLAGS}}, '--ossl-strict-warnings';
 776                 $strict_warnings=1;
 777                 }
 778         elsif (/^--debug$/)
 779                 {
 780                 $config{build_type} = "debug";
 781                 }
 782         elsif (/^--release$/)
 783                 {
 784                 $config{build_type} = "release";
 785                 }
 786         elsif (/^386$/)
 787                 { $config{processor}=386; }
 788         elsif (/^fips$/)
 789                 {
 790                 die "FIPS mode not supported\n";
 791                 }
 792         elsif (/^rsaref$/)
 793                 {
 794                 # No RSAref support any more since it's not needed.
 795                 # The check for the option is there so scripts aren't
 796                 # broken
 797                 }
 798         elsif (/^nofipscanistercheck$/)
 799                 {
 800                 die "FIPS mode not supported\n";
 801                 }
 802         elsif (/^[-+]/)
 803                 {
 804                 if (/^--prefix=(.*)$/)
 805                         {
 806                         $config{prefix}=$1;
 807                         die "Directory given with --prefix MUST be absolute\n"
 808                                 unless file_name_is_absolute($config{prefix});
 809                         }
 810                 elsif (/^--api=(.*)$/)
 811                         {
 812                         $config{api}=$1;
 813                         }
 814                 elsif (/^--libdir=(.*)$/)
 815                         {
 816                         $config{libdir}=$1;
 817                         }
 818                 elsif (/^--openssldir=(.*)$/)
 819                         {
 820                         $config{openssldir}=$1;
 821                         }
 822                 elsif (/^--with-zlib-lib=(.*)$/)
 823                         {
 824                         $withargs{zlib_lib}=$1;
 825                         }
 826                 elsif (/^--with-zlib-include=(.*)$/)
 827                         {
 828                         $withargs{zlib_include}=$1;
 829                         }
 830                 elsif (/^--with-fuzzer-lib=(.*)$/)
 831                         {
 832                         $withargs{fuzzer_lib}=$1;
 833                         }
 834                 elsif (/^--with-fuzzer-include=(.*)$/)
 835                         {
 836                         $withargs{fuzzer_include}=$1;
 837                         }
 838                 elsif (/^--with-rand-seed=(.*)$/)
 839                         {
 840                         foreach my $x (split(m|,|, $1))
 841                             {
 842                             die "Unknown --with-rand-seed choice $x\n"
 843                                 if ! grep { $x eq $_ } @known_seed_sources;
 844                             push @seed_sources, $x;
 845                             }
 846                         }
 847                 elsif (/^--cross-compile-prefix=(.*)$/)
 848                         {
 849                         $user{CROSS_COMPILE}=$1;
 850                         }
 851                 elsif (/^--config=(.*)$/)
 852                         {
 853                         read_config $1;
 854                         }
 855                 elsif (/^-l(.*)$/)
 856                         {
 857                         push @{$useradd{LDLIBS}}, $_;
 858                         }
 859                 elsif (/^-framework$/)
 860                         {
 861                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 862                         }
 863                 elsif (/^-L(.*)$/ or /^-Wl,/)
 864                         {
 865                         push @{$useradd{LDFLAGS}}, $_;
 866                         }
 867                 elsif (/^-rpath$/ or /^-R$/)
 868                         # -rpath is the OSF1 rpath flag
 869                         # -R is the old Solaris rpath flag
 870                         {
 871                         my $rpath = shift(@argvcopy) || "";
 872                         $rpath .= " " if $rpath ne "";
 873                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 874                         }
 875                 elsif (/^-static$/)
 876                         {
 877                         push @{$useradd{LDFLAGS}}, $_;
 878                         $disabled{"dso"} = "forced";
 879                         $disabled{"pic"} = "forced";
 880                         $disabled{"shared"} = "forced";
 881                         $disabled{"threads"} = "forced";
 882                         }
 883                 elsif (/^-D(.*)$/)
 884                         {
 885                         push @{$useradd{CPPDEFINES}}, $1;
 886                         }
 887                 elsif (/^-I(.*)$/)
 888                         {
 889                         push @{$useradd{CPPINCLUDES}}, $1;
 890                         }
 891                 elsif (/^-Wp,$/)
 892                         {
 893                         push @{$useradd{CPPFLAGS}}, $1;
 894                         }
 895                 else    # common if (/^[-+]/), just pass down...
 896                         {
 897                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 898                         push @{$useradd{CFLAGS}}, $_;
 899                         push @{$useradd{CXXFLAGS}}, $_;
 900                         }
 901                 }
 902         else
 903                 {
 904                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 905                 $target=$_;
 906                 }
 907         unless ($_ eq $target || /^no-/ || /^disable-/)
 908                 {
 909                 # "no-..." follows later after implied deactivations
 910                 # have been derived.  (Don't take this too seriously,
 911                 # we really only write OPTIONS to the Makefile out of
 912                 # nostalgia.)
 913
 914                 if ($config{options} eq "")
 915                         { $config{options} = $_; }
 916                 else
 917                         { $config{options} .= " ".$_; }
 918                 }
 919         }
 920
 921 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 922         die "***** Unsupported api compatibility level: $config{api}\n",
 923 }
 924
 925 if (keys %deprecated_options)
 926         {
 927         warn "***** Deprecated options: ",
 928                 join(", ", keys %deprecated_options), "\n";
 929         }
 930 if (keys %unsupported_options)
 931         {
 932         die "***** Unsupported options: ",
 933                 join(", ", keys %unsupported_options), "\n";
 934         }
 935
 936 # If any %useradd entry has been set, we must check that the "make
 937 # variables" haven't been set.  We start by checking of any %useradd entry
 938 # is set.
 939 if (grep { scalar @$_ > 0 } values %useradd) {
 940     # Hash of env / make variables names.  The possible values are:
 941     # 1 - "make vars"
 942     # 2 - %useradd entry set
 943     # 3 - both set
 944     my %detected_vars =
 945         map { my $v = 0;
 946               $v += 1 if $cmdvars{$_};
 947               $v += 2 if @{$useradd{$_}};
 948               $_ => $v }
 949         keys %useradd;
 950
 951     # If any of the corresponding "make variables" is set, we error
 952     if (grep { $_ & 1 } values %detected_vars) {
 953         my $names = join(', ', grep { $detected_vars{$_} > 0 }
 954                                sort keys %detected_vars);
 955         die <<"_____";
 956 ***** Mixing make variables and additional compiler/linker flags as
 957 ***** configure command line option is not permitted.
 958 ***** Affected make variables: $names
 959 _____
 960     }
 961 }
 962
 963 # Check through all supported command line variables to see if any of them
 964 # were set, and canonicalise the values we got.  If no compiler or linker
 965 # flag or anything else that affects %useradd was set, we also check the
 966 # environment for values.
 967 my $anyuseradd =
 968     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
 969 foreach (keys %user) {
 970     my $value = $cmdvars{$_};
 971     $value //= env($_) unless $anyuseradd;
 972     $value //=
 973         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
 974     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
 975         unless $anyuseradd;
 976
 977     if (defined $value) {
 978         if (ref $user{$_} eq 'ARRAY') {
 979             $user{$_} = [ split /$list_separator_re/, $value ];
 980         } elsif (!defined $user{$_}) {
 981             $user{$_} = $value;
 982         }
 983     }
 984 }
 985
 986 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
 987     && !$disabled{shared}
 988     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
 989     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
 990         "***** any of asan, msan or ubsan\n";
 991 }
 992
 993 my @tocheckfor = (keys %disabled);
 994 while (@tocheckfor) {
 995     my %new_tocheckfor = ();
 996     my @cascade_copy = (@disable_cascades);
 997     while (@cascade_copy) {
 998         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
 999         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1000             foreach(grep { !defined($disabled{$_}) } @$descendents) {
1001                 $new_tocheckfor{$_} = 1; $disabled{$_} = "forced";
1002             }
1003         }
1004     }
1005     @tocheckfor = (keys %new_tocheckfor);
1006 }
1007
1008 our $die = sub { die @_; };
1009 if ($target eq "TABLE") {
1010     local $die = sub { warn @_; };
1011     foreach (sort keys %table) {
1012         print_table_entry($_, "TABLE");
1013     }
1014     exit 0;
1015 }
1016
1017 if ($target eq "LIST") {
1018     foreach (sort keys %table) {
1019         print $_,"\n" unless $table{$_}->{template};
1020     }
1021     exit 0;
1022 }
1023
1024 if ($target eq "HASH") {
1025     local $die = sub { warn @_; };
1026     print "%table = (\n";
1027     foreach (sort keys %table) {
1028         print_table_entry($_, "HASH");
1029     }
1030     exit 0;
1031 }
1032
1033 print "Configuring OpenSSL version $config{full_version} ";
1034 print "for target $target\n";
1035
1036 if (scalar(@seed_sources) == 0) {
1037     print "Using os-specific seed configuration\n";
1038     push @seed_sources, 'os';
1039 }
1040 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1041     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1042     warn <<_____ if scalar(@seed_sources) == 1;
1043
1044 ============================== WARNING ===============================
1045 You have selected the --with-rand-seed=none option, which effectively
1046 disables automatic reseeding of the OpenSSL random generator.
1047 All operations depending on the random generator such as creating keys
1048 will not work unless the random generator is seeded manually by the
1049 application.
1050
1051 Please read the 'Note on random number generation' section in the
1052 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1053 ============================== WARNING ===============================
1054
1055 _____
1056 }
1057 push @{$config{openssl_feature_defines}},
1058      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1059         @seed_sources;
1060
1061 # Backward compatibility?
1062 if ($target =~ m/^CygWin32(-.*)$/) {
1063     $target = "Cygwin".$1;
1064 }
1065
1066 # Support for legacy targets having a name starting with 'debug-'
1067 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1068 if ($d) {
1069     $config{build_type} = "debug";
1070
1071     # If we do not find debug-foo in the table, the target is set to foo.
1072     if (!$table{$target}) {
1073         $target = $t;
1074     }
1075 }
1076
1077 &usage if !$table{$target} || $table{$target}->{template};
1078
1079 $config{target} = $target;
1080 my %target = resolve_config($target);
1081
1082 foreach (keys %target_attr_translate) {
1083     $target{$target_attr_translate{$_}} = $target{$_}
1084         if $target{$_};
1085     delete $target{$_};
1086 }
1087
1088 %target = ( %{$table{DEFAULTS}}, %target );
1089
1090 # Make the flags to build DSOs the same as for shared libraries unless they
1091 # are already defined
1092 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1093 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1094 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1095 {
1096     my $shared_info_pl =
1097         catfile(dirname($0), "Configurations", "shared-info.pl");
1098     my %shared_info = read_eval_file($shared_info_pl);
1099     push @{$target{_conf_fname_int}}, $shared_info_pl;
1100     my $si = $target{shared_target};
1101     while (ref $si ne "HASH") {
1102         last if ! defined $si;
1103         if (ref $si eq "CODE") {
1104             $si = $si->();
1105         } else {
1106             $si = $shared_info{$si};
1107         }
1108     }
1109
1110     # Some of the 'shared_target' values don't have any entried in
1111     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1112     # template knows how to handle this.  That is currently the case for
1113     # Windows and VMS.
1114     if (defined $si) {
1115         # Just as above, copy certain shared_* attributes to the corresponding
1116         # module_ attribute unless the latter is already defined
1117         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1118         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1119         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1120         foreach (sort keys %$si) {
1121             $target{$_} = defined $target{$_}
1122                 ? add($si->{$_})->($target{$_})
1123                 : $si->{$_};
1124         }
1125     }
1126 }
1127
1128 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1129 $config{conf_files} = [ sort keys %conf_files ];
1130
1131 foreach my $feature (@{$target{disable}}) {
1132     if (exists $deprecated_disablables{$feature}) {
1133         warn "***** config $target disables deprecated feature $feature\n";
1134     } elsif (!grep { $feature eq $_ } @disablables) {
1135         die "***** config $target disables unknown feature $feature\n";
1136     }
1137     $disabled{$feature} = 'config';
1138 }
1139 foreach my $feature (@{$target{enable}}) {
1140     if ("default" eq ($disabled{$feature} // "")) {
1141         if (exists $deprecated_disablables{$feature}) {
1142             warn "***** config $target enables deprecated feature $feature\n";
1143         } elsif (!grep { $feature eq $_ } @disablables) {
1144             die "***** config $target enables unknown feature $feature\n";
1145         }
1146         delete $disabled{$feature};
1147     }
1148 }
1149
1150 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1151 $target{cxxflags}//=$target{cflags} if $target{CXX};
1152 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1153 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1154
1155 # Fill %config with values from %user, and in case those are undefined or
1156 # empty, use values from %target (acting as a default).
1157 foreach (keys %user) {
1158     my $ref_type = ref $user{$_};
1159
1160     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1161     # and a value that's to be coerced into that type.
1162     my $mkvalue = sub {
1163         my $type = shift;
1164         my $value = shift;
1165         my $undef_p = shift;
1166
1167         die "Too many arguments for \$mkvalue" if @_;
1168
1169         while (ref $value eq 'CODE') {
1170             $value = $value->();
1171         }
1172
1173         if ($type eq 'ARRAY') {
1174             return undef unless defined $value;
1175             return undef if ref $value ne 'ARRAY' && !$value;
1176             return undef if ref $value eq 'ARRAY' && !@$value;
1177             return [ $value ] unless ref $value eq 'ARRAY';
1178         }
1179         return undef unless $value;
1180         return $value;
1181     };
1182
1183     $config{$_} =
1184         $mkvalue->($ref_type, $user{$_})
1185         || $mkvalue->($ref_type, $target{$_});
1186     delete $config{$_} unless defined $config{$_};
1187 }
1188
1189 # Allow overriding the build file name
1190 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1191
1192 ######################################################################
1193 # Build up information for skipping certain directories depending on disabled
1194 # features, as well as setting up macros for disabled features.
1195
1196 # This is a tentative database of directories to skip.  Some entries may not
1197 # correspond to anything real, but that's ok, they will simply be ignored.
1198 # The actual processing of these entries is done in the build.info lookup
1199 # loop further down.
1200 #
1201 # The key is a Unix formated path in the source tree, the value is an index
1202 # into %disabled_info, so any existing path gets added to a corresponding
1203 # 'skipped' entry in there with the list of skipped directories.
1204 my %skipdir = ();
1205 my %disabled_info = ();         # For configdata.pm
1206 foreach my $what (sort keys %disabled) {
1207     # There are deprecated disablables that translate to themselves.
1208     # They cause disabling cascades, but should otherwise not regiter.
1209     next if $deprecated_disablables{$what};
1210
1211     $config{options} .= " no-$what";
1212
1213     if (!grep { $what eq $_ } ( 'buildtest-c++', 'dso', 'threads', 'shared',
1214                                 'pic', 'dynamic-engine', 'makedepend',
1215                                 'zlib-dynamic', 'zlib', 'sse2' )) {
1216         (my $WHAT = uc $what) =~ s|-|_|g;
1217         my $skipdir = $what;
1218
1219         # fix-up crypto/directory name(s)
1220         $skipdir = "ripemd" if $what eq "rmd160";
1221         $skipdir = "whrlpool" if $what eq "whirlpool";
1222
1223         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1224         push @{$config{openssl_feature_defines}}, $macro;
1225
1226         $skipdir{engines} = $what if $what eq 'engine';
1227         $skipdir{"crypto/$skipdir"} = $what
1228             unless $what eq 'async' || $what eq 'err';
1229     }
1230 }
1231
1232 # Make sure build_scheme is consistent.
1233 $target{build_scheme} = [ $target{build_scheme} ]
1234     if ref($target{build_scheme}) ne "ARRAY";
1235
1236 my ($builder, $builder_platform, @builder_opts) =
1237     @{$target{build_scheme}};
1238
1239 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1240                       $builder_platform."-checker.pm")) {
1241     my $checker_path = catfile($srcdir, "Configurations", $checker);
1242     if (-f $checker_path) {
1243         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1244             ? sub { warn $@; } : sub { die $@; };
1245         if (! do $checker_path) {
1246             if ($@) {
1247                 $fn->($@);
1248             } elsif ($!) {
1249                 $fn->($!);
1250             } else {
1251                 $fn->("The detected tools didn't match the platform\n");
1252             }
1253         }
1254         last;
1255     }
1256 }
1257
1258 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1259
1260 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1261         {
1262         push @{$config{cflags}}, "-mno-cygwin";
1263         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1264         push @{$config{shared_ldflag}}, "-mno-cygwin";
1265         }
1266
1267 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1268         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$user{CFLAGS}},
1269                                             @{$useradd{CFLAGS}})) {
1270         # minimally required architecture flags for assembly modules
1271         my $value;
1272         $value = '-mips2' if ($target =~ /mips32/);
1273         $value = '-mips3' if ($target =~ /mips64/);
1274         unshift @{$config{cflags}}, $value;
1275         unshift @{$config{cxxflags}}, $value if $config{CXX};
1276 }
1277
1278 # If threads aren't disabled, check how possible they are
1279 unless ($disabled{threads}) {
1280     if ($auto_threads) {
1281         # Enabled by default, disable it forcibly if unavailable
1282         if ($target{thread_scheme} eq "(unknown)") {
1283             $disabled{threads} = "unavailable";
1284         }
1285     } else {
1286         # The user chose to enable threads explicitly, let's see
1287         # if there's a chance that's possible
1288         if ($target{thread_scheme} eq "(unknown)") {
1289             # If the user asked for "threads" and we don't have internal
1290             # knowledge how to do it, [s]he is expected to provide any
1291             # system-dependent compiler options that are necessary.  We
1292             # can't truly check that the given options are correct, but
1293             # we expect the user to know what [s]He is doing.
1294             if (!@{$user{CFLAGS}} && !@{$useradd{CFLAGS}}
1295                     && !@{$user{CPPDEFINES}} && !@{$useradd{CPPDEFINES}}) {
1296                 die "You asked for multi-threading support, but didn't\n"
1297                     ,"provide any system-specific compiler options\n";
1298             }
1299         }
1300     }
1301 }
1302
1303 # If threads still aren't disabled, add a C macro to ensure the source
1304 # code knows about it.  Any other flag is taken care of by the configs.
1305 unless($disabled{threads}) {
1306     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1307 }
1308
1309 # With "deprecated" disable all deprecated features.
1310 if (defined($disabled{"deprecated"})) {
1311         $config{api} = $maxapi;
1312 }
1313
1314 my $no_shared_warn=0;
1315 if ($target{shared_target} eq "")
1316         {
1317         $no_shared_warn = 1
1318             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1319         $disabled{shared} = "no-shared-target";
1320         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
1321             "no-shared-target";
1322         }
1323
1324 if ($disabled{"dynamic-engine"}) {
1325         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1326         $config{dynamic_engines} = 0;
1327 } else {
1328         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1329         $config{dynamic_engines} = 1;
1330 }
1331
1332 unless ($disabled{asan}) {
1333     push @{$config{cflags}}, "-fsanitize=address";
1334     push @{$config{cxxflags}}, "-fsanitize=address" if $config{CXX};
1335 }
1336
1337 unless ($disabled{ubsan}) {
1338     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1339     # platforms.
1340     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1341     push @{$config{cxxflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all"
1342         if $config{CXX};
1343 }
1344
1345 unless ($disabled{msan}) {
1346   push @{$config{cflags}}, "-fsanitize=memory";
1347   push @{$config{cxxflags}}, "-fsanitize=memory" if $config{CXX};
1348 }
1349
1350 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1351         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1352     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1353     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1354 }
1355 #
1356 # Platform fix-ups
1357 #
1358
1359 # This saves the build files from having to check
1360 if ($disabled{pic})
1361         {
1362         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1363                     shared_defines shared_includes shared_ldflag
1364                     module_cflags module_cxxflags module_cppflags
1365                     module_defines module_includes module_lflags))
1366                 {
1367                 delete $config{$_};
1368                 $target{$_} = "";
1369                 }
1370         }
1371 else
1372         {
1373         push @{$config{lib_defines}}, "OPENSSL_PIC";
1374         }
1375
1376 if ($target{sys_id} ne "")
1377         {
1378         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1379         }
1380
1381 unless ($disabled{asm}) {
1382     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1383     push @{$config{lib_defines}}, "OPENSSL_CPUID_OBJ" if ($target{cpuid_asm_src} ne "mem_clr.c");
1384
1385     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1386
1387     # bn-586 is the only one implementing bn_*_part_words
1388     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1389     push @{$config{lib_defines}}, "OPENSSL_IA32_SSE2" if (!$disabled{sse2} && $target{bn_asm_src} =~ /86/);
1390
1391     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1392     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1393     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1394     push @{$config{lib_defines}}, "BN_DIV3W" if ($target{bn_asm_src} =~ /-div3w/);
1395
1396     if ($target{sha1_asm_src}) {
1397         push @{$config{lib_defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1398         push @{$config{lib_defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1399         push @{$config{lib_defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1400     }
1401     if ($target{keccak1600_asm_src} ne $table{DEFAULTS}->{keccak1600_asm_src}) {
1402         push @{$config{lib_defines}}, "KECCAK1600_ASM";
1403     }
1404     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1405         push @{$config{lib_defines}}, "RC4_ASM";
1406     }
1407     if ($target{md5_asm_src}) {
1408         push @{$config{lib_defines}}, "MD5_ASM";
1409     }
1410     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1411     if ($target{rmd160_asm_src}) {
1412         push @{$config{lib_defines}}, "RMD160_ASM";
1413     }
1414     if ($target{aes_asm_src}) {
1415         push @{$config{lib_defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1416         # aes-ctr.fake is not a real file, only indication that assembler
1417         # module implements AES_ctr32_encrypt...
1418         push @{$config{lib_defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1419         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1420         push @{$config{lib_defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1421         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($disabled{sse2});
1422         push @{$config{lib_defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1423         push @{$config{lib_defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1424     }
1425     if ($target{wp_asm_src} =~ /mmx/) {
1426         if ($config{processor} eq "386") {
1427             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1428         } elsif (!$disabled{"whirlpool"}) {
1429             push @{$config{lib_defines}}, "WHIRLPOOL_ASM";
1430         }
1431     }
1432     if ($target{modes_asm_src} =~ /ghash-/) {
1433         push @{$config{lib_defines}}, "GHASH_ASM";
1434     }
1435     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1436         push @{$config{lib_defines}}, "ECP_NISTZ256_ASM";
1437     }
1438     if ($target{ec_asm_src} =~ /x25519/) {
1439         push @{$config{lib_defines}}, "X25519_ASM";
1440     }
1441     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1442         push @{$config{dso_defines}}, "PADLOCK_ASM";
1443     }
1444     if ($target{poly1305_asm_src} ne "") {
1445         push @{$config{lib_defines}}, "POLY1305_ASM";
1446     }
1447 }
1448
1449 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1450 my %predefined_CXX = $config{CXX}
1451     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1452     : ();
1453
1454 # Check for makedepend capabilities.
1455 if (!$disabled{makedepend}) {
1456     if ($config{target} =~ /^(VC|vms)-/) {
1457         # For VC- and vms- targets, there's nothing more to do here.  The
1458         # functionality is hard coded in the corresponding build files for
1459         # cl (Windows) and CC/DECC (VMS).
1460     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1461              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1462         # We know that GNU C version 3 and up as well as all clang
1463         # versions support dependency generation, but Xcode did not
1464         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1465         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1466     } else {
1467         # In all other cases, we look for 'makedepend', and disable the
1468         # capability if not found.
1469         $config{makedepprog} = which('makedepend');
1470         $disabled{makedepend} = "unavailable" unless $config{makedepprog};
1471     }
1472 }
1473
1474 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1475     # probe for -Wa,--noexecstack option...
1476     if ($predefined_C{__clang__}) {
1477         # clang has builtin assembler, which doesn't recognize --help,
1478         # but it apparently recognizes the option in question on all
1479         # supported platforms even when it's meaningless. In other words
1480         # probe would fail, but probed option always accepted...
1481         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1482     } else {
1483         my $cc = $config{CROSS_COMPILE}.$config{CC};
1484         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1485         while(<PIPE>) {
1486             if (m/--noexecstack/) {
1487                 push @{$config{cflags}}, "-Wa,--noexecstack";
1488                 last;
1489             }
1490         }
1491         close(PIPE);
1492         unlink("null.$$.o");
1493     }
1494 }
1495
1496 # Deal with bn_ops ###################################################
1497
1498 $config{bn_ll}                  =0;
1499 $config{export_var_as_fn}       =0;
1500 my $def_int="unsigned int";
1501 $config{rc4_int}                =$def_int;
1502 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1503
1504 my $count = 0;
1505 foreach (sort split(/\s+/,$target{bn_ops})) {
1506     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1507     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1508     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1509     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1510     ($config{b64l},$config{b64},$config{b32})
1511         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1512     ($config{b64l},$config{b64},$config{b32})
1513         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1514     ($config{b64l},$config{b64},$config{b32})
1515         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1516 }
1517 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1518     if $count > 1;
1519
1520
1521 # Hack cflags for better warnings (dev option) #######################
1522
1523 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1524 # a string and works as well on command lines.
1525 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1526                         @{$config{cflags}} ];
1527 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1528                           @{$config{cxxflags}} ] if $config{CXX};
1529
1530 $config{openssl_api_defines} = [
1531     "OPENSSL_MIN_API=".($apitable->{$config{api} // ""} // -1)
1532 ];
1533
1534 my %strict_warnings_collection=( CFLAGS => [], CXXFLAGS => []);
1535 if ($strict_warnings)
1536         {
1537         my $wopt;
1538         my $gccver = $predefined_C{__GNUC__} // -1;
1539         my $gxxver = $predefined_CXX{__GNUC__} // -1;
1540
1541         warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike"
1542             unless $gccver >= 4;
1543         warn "WARNING --strict-warnings requires g++[>=4] or g++-alike"
1544             unless $gxxver >= 4;
1545         foreach (qw(CFLAGS CXXFLAGS))
1546                 {
1547                 push @{$strict_warnings_collection{$_}},
1548                         @{$gcc_devteam_warn{$_}};
1549                 }
1550         push @{$strict_warnings_collection{CFLAGS}},
1551                 @{$clang_devteam_warn{CFLAGS}}
1552                         if (defined($predefined_C{__clang__}));
1553         push @{$strict_warnings_collection{CXXFLAGS}},
1554                 @{$clang_devteam_warn{CXXFLAGS}}
1555                         if (defined($predefined_CXX{__clang__}));
1556         }
1557 foreach my $idx (qw(CFLAGS CXXFLAGS))
1558         {
1559         $useradd{$idx} = [ map { $_ eq '--ossl-strict-warnings'
1560                                      ? @{$strict_warnings_collection{$idx}}
1561                                      : ( $_ ) }
1562                                @{$useradd{$idx}} ];
1563         }
1564
1565 unless ($disabled{"crypto-mdebug-backtrace"})
1566         {
1567         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1568                 {
1569                 push @{$config{cflags}}, $wopt
1570                         unless grep { $_ eq $wopt } @{$config{cflags}};
1571                 push @{$config{cxxflags}}, $wopt
1572                         if ($config{CXX}
1573                             && !grep { $_ eq $wopt } @{$config{cxxflags}});
1574                 }
1575         if ($target =~ /^BSD-/)
1576                 {
1577                 push @{$config{ex_libs}}, "-lexecinfo";
1578                 }
1579         }
1580
1581 unless ($disabled{afalgeng}) {
1582     $config{afalgeng}="";
1583     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1584         my $minver = 4*10000 + 1*100 + 0;
1585         if ($config{CROSS_COMPILE} eq "") {
1586             my $verstr = `uname -r`;
1587             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1588             ($mi2) = $mi2 =~ /(\d+)/;
1589             my $ver = $ma*10000 + $mi1*100 + $mi2;
1590             if ($ver < $minver) {
1591                 $disabled{afalgeng} = "too-old-kernel";
1592             } else {
1593                 push @{$config{engdirs}}, "afalg";
1594             }
1595         } else {
1596             $disabled{afalgeng} = "cross-compiling";
1597         }
1598     } else {
1599         $disabled{afalgeng}  = "not-linux";
1600     }
1601 }
1602
1603 push @{$config{openssl_feature_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1604
1605 unless ($disabled{ktls}) {
1606     $config{ktls}="";
1607     if ($target =~ m/^linux/) {
1608         my $usr = "/usr/$config{cross_compile_prefix}";
1609         chop($usr);
1610         if ($config{cross_compile_prefix} eq "") {
1611             $usr = "/usr";
1612         }
1613         my $minver = (4 << 16) + (13 << 8) + 0;
1614         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1615
1616         if ($verstr[2] < $minver) {
1617             $disabled{ktls} = "too-old-kernel";
1618         }
1619     } else {
1620         $disabled{ktls}  = "not-linux";
1621     }
1622 }
1623
1624 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1625
1626 # Finish up %config by appending things the user gave us on the command line
1627 # apart from "make variables"
1628 foreach (keys %useradd) {
1629     # The must all be lists, so we assert that here
1630     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1631         unless ref $useradd{$_} eq 'ARRAY';
1632
1633     if (defined $config{$_}) {
1634         push @{$config{$_}}, @{$useradd{$_}};
1635     } else {
1636         $config{$_} = [ @{$useradd{$_}} ];
1637     }
1638 }
1639
1640 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1641
1642 # If we use the unified build, collect information from build.info files
1643 my %unified_info = ();
1644
1645 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1646 if ($builder eq "unified") {
1647     use with_fallback qw(Text::Template);
1648
1649     sub cleandir {
1650         my $base = shift;
1651         my $dir = shift;
1652         my $relativeto = shift || ".";
1653
1654         $dir = catdir($base,$dir) unless isabsolute($dir);
1655
1656         # Make sure the directories we're building in exists
1657         mkpath($dir);
1658
1659         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1660         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1661         return $res;
1662     }
1663
1664     sub cleanfile {
1665         my $base = shift;
1666         my $file = shift;
1667         my $relativeto = shift || ".";
1668
1669         $file = catfile($base,$file) unless isabsolute($file);
1670
1671         my $d = dirname($file);
1672         my $f = basename($file);
1673
1674         # Make sure the directories we're building in exists
1675         mkpath($d);
1676
1677         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1678         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1679         return $res;
1680     }
1681
1682     # Store the name of the template file we will build the build file from
1683     # in %config.  This may be useful for the build file itself.
1684     my @build_file_template_names =
1685         ( $builder_platform."-".$target{build_file}.".tmpl",
1686           $target{build_file}.".tmpl" );
1687     my @build_file_templates = ();
1688
1689     # First, look in the user provided directory, if given
1690     if (defined env($local_config_envname)) {
1691         @build_file_templates =
1692             map {
1693                 if ($^O eq 'VMS') {
1694                     # VMS environment variables are logical names,
1695                     # which can be used as is
1696                     $local_config_envname . ':' . $_;
1697                 } else {
1698                     catfile(env($local_config_envname), $_);
1699                 }
1700             }
1701             @build_file_template_names;
1702     }
1703     # Then, look in our standard directory
1704     push @build_file_templates,
1705         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1706           @build_file_template_names );
1707
1708     my $build_file_template;
1709     for $_ (@build_file_templates) {
1710         $build_file_template = $_;
1711         last if -f $build_file_template;
1712
1713         $build_file_template = undef;
1714     }
1715     if (!defined $build_file_template) {
1716         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1717     }
1718     $config{build_file_templates}
1719       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1720                     $blddir),
1721           $build_file_template,
1722           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1723                     $blddir) ];
1724
1725     my @build_dirs = ( [ ] );   # current directory
1726
1727     $config{build_infos} = [ ];
1728
1729     my %ordinals = ();
1730     while (@build_dirs) {
1731         my @curd = @{shift @build_dirs};
1732         my $sourced = catdir($srcdir, @curd);
1733         my $buildd = catdir($blddir, @curd);
1734
1735         my $unixdir = join('/', @curd);
1736         if (exists $skipdir{$unixdir}) {
1737             my $what = $skipdir{$unixdir};
1738             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1739             next;
1740         }
1741
1742         mkpath($buildd);
1743
1744         my $f = 'build.info';
1745         # The basic things we're trying to build
1746         my @programs = ();
1747         my @libraries = ();
1748         my @modules = ();
1749         my @scripts = ();
1750
1751         my %attributes = ();
1752         my %sources = ();
1753         my %shared_sources = ();
1754         my %includes = ();
1755         my %defines = ();
1756         my %depends = ();
1757         my %generate = ();
1758
1759         # We want to detect configdata.pm in the source tree, so we
1760         # don't use it if the build tree is different.
1761         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1762
1763         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1764         my $template =
1765             Text::Template->new(TYPE => 'FILE',
1766                                 SOURCE => catfile($sourced, $f),
1767                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1768         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1769         my @text =
1770             split /^/m,
1771             $template->fill_in(HASH => { config => \%config,
1772                                          target => \%target,
1773                                          disabled => \%disabled,
1774                                          withargs => \%withargs,
1775                                          builddir => abs2rel($buildd, $blddir),
1776                                          sourcedir => abs2rel($sourced, $blddir),
1777                                          buildtop => abs2rel($blddir, $blddir),
1778                                          sourcetop => abs2rel($srcdir, $blddir) },
1779                                DELIMITERS => [ "{-", "-}" ]);
1780
1781         # The top item of this stack has the following values
1782         # -2 positive already run and we found ELSE (following ELSIF should fail)
1783         # -1 positive already run (skip until ENDIF)
1784         # 0 negatives so far (if we're at a condition, check it)
1785         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1786         # 2 positive ELSE (following ELSIF should fail)
1787         my @skip = ();
1788         collect_information(
1789             collect_from_array([ @text ],
1790                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1791                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1792             # Info we're looking for
1793             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1794             => sub {
1795                 if (! @skip || $skip[$#skip] > 0) {
1796                     push @skip, !! $1;
1797                 } else {
1798                     push @skip, -1;
1799                 }
1800             },
1801             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1802             => sub { die "ELSIF out of scope" if ! @skip;
1803                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1804                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1805                      $skip[$#skip] = !! $1
1806                          if $skip[$#skip] == 0; },
1807             qr/^\s*ELSE\s*$/
1808             => sub { die "ELSE out of scope" if ! @skip;
1809                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1810                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1811             qr/^\s*ENDIF\s*$/
1812             => sub { die "ENDIF out of scope" if ! @skip;
1813                      pop @skip; },
1814             qr/^\s*SUBDIRS\s*=\s*(.*)\s*$/
1815             => sub {
1816                 if (!@skip || $skip[$#skip] > 0) {
1817                     foreach (tokenize($1)) {
1818                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1819                     }
1820                 }
1821             },
1822             qr/^\s*PROGRAMS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1823             => sub {
1824                 if (!@skip || $skip[$#skip] > 0) {
1825                     my @a = tokenize($1, qr|\s*,\s*|);
1826                     my @p = tokenize($2);
1827                     push @programs, @p;
1828                     foreach my $a (@a) {
1829                         my $ak = $a;
1830                         my $av = 1;
1831                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1832                             $ak = $1;
1833                             $av = $2;
1834                         }
1835                         foreach my $p (@p) {
1836                             $attributes{$p}->{$ak} = $av;
1837                         }
1838                     }
1839                 }
1840             },
1841             qr/^\s*LIBS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1842             => sub {
1843                 if (!@skip || $skip[$#skip] > 0) {
1844                     my @a = tokenize($1, qr|\s*,\s*|);
1845                     my @l = tokenize($2);
1846                     push @libraries, @l;
1847                     foreach my $a (@a) {
1848                         my $ak = $a;
1849                         my $av = 1;
1850                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1851                             $ak = $1;
1852                             $av = $2;
1853                         }
1854                         foreach my $l (@l) {
1855                             $attributes{$l}->{$ak} = $av;
1856                         }
1857                     }
1858                 }
1859             },
1860             qr/^\s*MODULES(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1861             => sub {
1862                 if (!@skip || $skip[$#skip] > 0) {
1863                     my @a = tokenize($1, qr|\s*,\s*|);
1864                     my @m = tokenize($2);
1865                     push @modules, @m;
1866                     foreach my $a (@a) {
1867                         my $ak = $a;
1868                         my $av = 1;
1869                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1870                             $ak = $1;
1871                             $av = $2;
1872                         }
1873                         foreach my $m (@m) {
1874                             $attributes{$m}->{$ak} = $av;
1875                         }
1876                     }
1877                 }
1878             },
1879             qr/^\s*SCRIPTS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1880             => sub {
1881                 if (!@skip || $skip[$#skip] > 0) {
1882                     my @a = tokenize($1, qr|\s*,\s*|);
1883                     my @s = tokenize($2);
1884                     push @scripts, @s;
1885                     foreach my $a (@a) {
1886                         my $ak = $a;
1887                         my $av = 1;
1888                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1889                             $ak = $1;
1890                             $av = $2;
1891                         }
1892                         foreach my $s (@s) {
1893                             $attributes{$s}->{$ak} = $av;
1894                         }
1895                     }
1896                 }
1897             },
1898
1899             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1900             => sub { push @{$ordinals{$1}}, tokenize($2)
1901                          if !@skip || $skip[$#skip] > 0 },
1902             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1903             => sub { push @{$sources{$1}}, tokenize($2)
1904                          if !@skip || $skip[$#skip] > 0 },
1905             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1906             => sub { push @{$shared_sources{$1}}, tokenize($2)
1907                          if !@skip || $skip[$#skip] > 0 },
1908             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1909             => sub { push @{$includes{$1}}, tokenize($2)
1910                          if !@skip || $skip[$#skip] > 0 },
1911             qr/^\s*DEFINE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1912             => sub { push @{$defines{$1}}, tokenize($2)
1913                          if !@skip || $skip[$#skip] > 0 },
1914             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1915             => sub { push @{$depends{$1}}, tokenize($2)
1916                          if !@skip || $skip[$#skip] > 0 },
1917             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1918             => sub { push @{$generate{$1}}, $2
1919                          if !@skip || $skip[$#skip] > 0 },
1920             qr/^\s*(?:#.*)?$/ => sub { },
1921             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1922             "BEFORE" => sub {
1923                 if ($buildinfo_debug) {
1924                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1925                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1926                 }
1927             },
1928             "AFTER" => sub {
1929                 if ($buildinfo_debug) {
1930                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1931                 }
1932             },
1933             );
1934         die "runaway IF?" if (@skip);
1935
1936         if (grep { defined $attributes{$_}->{engine} } keys %attributes
1937                 and !$config{dynamic_engines}) {
1938             die <<"EOF"
1939 ENGINES can only be used if configured with 'dynamic-engine'.
1940 This is usually a fault in a build.info file.
1941 EOF
1942         }
1943
1944         foreach (keys %attributes) {
1945             my $dest = $_;
1946             my $ddest = cleanfile($buildd, $_, $blddir);
1947             foreach (keys %{$attributes{$dest} // {}}) {
1948                 $unified_info{attributes}->{$ddest}->{$_} =
1949                     $attributes{$dest}->{$_};
1950             }
1951         }
1952
1953         {
1954             my %infos = ( programs  => [ @programs  ],
1955                           libraries => [ @libraries ],
1956                           modules   => [ @modules   ],
1957                           scripts   => [ @scripts   ] );
1958             foreach my $k (keys %infos) {
1959                 foreach (@{$infos{$k}}) {
1960                     my $item = cleanfile($buildd, $_, $blddir);
1961                     $unified_info{$k}->{$item} = 1;
1962                 }
1963             }
1964         }
1965
1966         # Check that we haven't defined any library as both shared and
1967         # explicitly static.  That is forbidden.
1968         my @doubles = ();
1969         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
1970             (my $l = $_) =~ s/\.a$//;
1971             push @doubles, $l if defined $unified_info{libraries}->{$l};
1972         }
1973         die "these libraries are both explicitly static and shared:\n  ",
1974             join(" ", @doubles), "\n"
1975             if @doubles;
1976
1977         foreach (keys %sources) {
1978             my $dest = $_;
1979             my $ddest = cleanfile($buildd, $_, $blddir);
1980             foreach (@{$sources{$dest}}) {
1981                 my $s = cleanfile($sourced, $_, $blddir);
1982
1983                 # If it isn't in the source tree, we assume it's generated
1984                 # in the build tree
1985                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
1986                     $s = cleanfile($buildd, $_, $blddir);
1987                 }
1988                 # We recognise C++, C and asm files
1989                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1990                     my $o = $_;
1991                     $o =~ s/\.[csS]$/.o/; # C and assembler
1992                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1993                     $o = cleanfile($buildd, $o, $blddir);
1994                     $unified_info{sources}->{$ddest}->{$o} = -1;
1995                     $unified_info{sources}->{$o}->{$s} = -1;
1996                 } elsif ($s =~ /\.rc$/) {
1997                     # We also recognise resource files
1998                     my $o = $_;
1999                     $o =~ s/\.rc$/.res/; # Resource configuration
2000                     my $o = cleanfile($buildd, $o, $blddir);
2001                     $unified_info{sources}->{$ddest}->{$o} = -1;
2002                     $unified_info{sources}->{$o}->{$s} = -1;
2003                 } else {
2004                     $unified_info{sources}->{$ddest}->{$s} = 1;
2005                 }
2006             }
2007         }
2008
2009         foreach (keys %shared_sources) {
2010             my $dest = $_;
2011             my $ddest = cleanfile($buildd, $_, $blddir);
2012             foreach (@{$shared_sources{$dest}}) {
2013                 my $s = cleanfile($sourced, $_, $blddir);
2014
2015                 # If it isn't in the source tree, we assume it's generated
2016                 # in the build tree
2017                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2018                     $s = cleanfile($buildd, $_, $blddir);
2019                 }
2020
2021                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2022                     # We recognise C++, C and asm files
2023                     my $o = $_;
2024                     $o =~ s/\.[csS]$/.o/; # C and assembler
2025                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2026                     $o = cleanfile($buildd, $o, $blddir);
2027                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2028                     $unified_info{sources}->{$o}->{$s} = -1;
2029                 } elsif ($s =~ /\.rc$/) {
2030                     # We also recognise resource files
2031                     my $o = $_;
2032                     $o =~ s/\.rc$/.res/; # Resource configuration
2033                     my $o = cleanfile($buildd, $o, $blddir);
2034                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2035                     $unified_info{sources}->{$o}->{$s} = -1;
2036                 } elsif ($s =~ /\.ld$/) {
2037                     # We also recognise linker scripts (or corresponding)
2038                     # We know they are generated files
2039                     my $ld = cleanfile($buildd, $_, $blddir);
2040                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2041                 } else {
2042                     die "unrecognised source file type for shared library: $s\n";
2043                 }
2044             }
2045         }
2046
2047         foreach (keys %generate) {
2048             my $dest = $_;
2049             my $ddest = cleanfile($buildd, $_, $blddir);
2050             die "more than one generator for $dest: "
2051                     ,join(" ", @{$generate{$_}}),"\n"
2052                     if scalar @{$generate{$_}} > 1;
2053             my @generator = split /\s+/, $generate{$dest}->[0];
2054             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2055             $unified_info{generate}->{$ddest} = [ @generator ];
2056         }
2057
2058         foreach (keys %depends) {
2059             my $dest = $_;
2060             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2061
2062             # If the destination doesn't exist in source, it can only be
2063             # a generated file in the build tree.
2064             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2065                 $ddest = cleanfile($buildd, $_, $blddir);
2066             }
2067             foreach (@{$depends{$dest}}) {
2068                 my $d = cleanfile($sourced, $_, $blddir);
2069
2070                 # If we know it's generated, or assume it is because we can't
2071                 # find it in the source tree, we set file we depend on to be
2072                 # in the build tree rather than the source tree, and assume
2073                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2074                 # section or in the Makefile template.
2075                 if ($d eq $src_configdata
2076                     || ! -f $d
2077                     || (grep { $d eq $_ }
2078                         map { cleanfile($srcdir, $_, $blddir) }
2079                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2080                     $d = cleanfile($buildd, $_, $blddir);
2081                 }
2082                 # Take note if the file to depend on is being renamed
2083                 # Take extra care with files ending with .a, they should
2084                 # be treated without that extension, and the extension
2085                 # should be added back after treatment.
2086                 $d =~ /(\.a)?$/;
2087                 my $e = $1 // "";
2088                 $d = $`.$e;
2089                 $unified_info{depends}->{$ddest}->{$d} = 1;
2090             }
2091         }
2092
2093         foreach (keys %includes) {
2094             my $dest = $_;
2095             my $ddest = cleanfile($sourced, $_, $blddir);
2096
2097             # If the destination doesn't exist in source, it can only be
2098             # a generated file in the build tree.
2099             if ($ddest eq $src_configdata || ! -f $ddest) {
2100                 $ddest = cleanfile($buildd, $_, $blddir);
2101             }
2102             foreach (@{$includes{$dest}}) {
2103                 my $is = cleandir($sourced, $_, $blddir);
2104                 my $ib = cleandir($buildd, $_, $blddir);
2105                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2106                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2107                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2108                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2109             }
2110         }
2111
2112         foreach (keys %defines) {
2113             my $dest = $_;
2114             my $ddest = cleanfile($sourced, $_, $blddir);
2115
2116             # If the destination doesn't exist in source, it can only be
2117             # a generated file in the build tree.
2118             if (! -f $ddest) {
2119                 $ddest = cleanfile($buildd, $_, $blddir);
2120                 if ($unified_info{rename}->{$ddest}) {
2121                     $ddest = $unified_info{rename}->{$ddest};
2122                 }
2123             }
2124             foreach (@{$defines{$dest}}) {
2125                 m|^([^=]*)(=.*)?$|;
2126                 die "0 length macro name not permitted\n" if $1 eq "";
2127                 die "$1 defined more than once\n"
2128                     if defined $unified_info{defines}->{$ddest}->{$1};
2129                 $unified_info{defines}->{$ddest}->{$1} = $2;
2130             }
2131         }
2132     }
2133
2134     my $ordinals_text = join(', ', sort keys %ordinals);
2135     warn <<"EOF" if $ordinals_text;
2136
2137 WARNING: ORDINALS were specified for $ordinals_text
2138 They are ignored and should be replaced with a combination of GENERATE,
2139 DEPEND and SHARED_SOURCE.
2140 EOF
2141
2142     # Massage the result
2143
2144     # If we depend on a header file or a perl module, add an inclusion of
2145     # its directory to allow smoothe inclusion
2146     foreach my $dest (keys %{$unified_info{depends}}) {
2147         next if $dest eq "";
2148         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2149             next unless $d =~ /\.(h|pm)$/;
2150             my $i = dirname($d);
2151             my $spot =
2152                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2153                 ? 'build' : 'source';
2154             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2155                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2156         }
2157     }
2158
2159     # Go through all intermediary files and change their names to something that
2160     # reflects what they will be built for.  Note that for some source files,
2161     # this leads to duplicate object files because they are used multiple times.
2162     # the goal is to rename all object files according to this scheme:
2163     #    {productname}-{midfix}-{origobjname}.[o|res]
2164     # the {midfix} is a keyword indicating the type of product, which is mostly
2165     # valuable for libraries since they come in two forms.
2166     #
2167     # This also reorganises the {sources} and {shared_sources} so that the
2168     # former only contains ALL object files that are supposed to end up in
2169     # static libraries and programs, while the latter contains ALL object files
2170     # that are supposed to end up in shared libraries and DSOs.
2171     # The main reason for having two different source structures is to allow
2172     # the same name to be used for the static and the shared variants of a
2173     # library.
2174     {
2175         # Take copies so we don't get interference from added stuff
2176         my %unified_copy = ();
2177         foreach (('sources', 'shared_sources')) {
2178             $unified_copy{$_} = { %{$unified_info{$_}} }
2179                 if defined($unified_info{$_});
2180             delete $unified_info{$_};
2181         }
2182         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2183             # $intent serves multi purposes:
2184             # - give a prefix for the new object files names
2185             # - in the case of libraries, rearrange the object files so static
2186             #   libraries use the 'sources' structure exclusively, while shared
2187             #   libraries use the 'shared_sources' structure exclusively.
2188             my $intent = {
2189                 programs  => { bin    => { src => [ 'sources' ],
2190                                            dst => 'sources' } },
2191                 libraries => { lib    => { src => [ 'sources' ],
2192                                            dst => 'sources' },
2193                                shlib  => { prodselect =>
2194                                                sub { grep !/\.a$/, @_ },
2195                                            src => [ 'sources',
2196                                                     'shared_sources' ],
2197                                            dst => 'shared_sources' } },
2198                 modules   => { dso    => { src => [ 'sources',
2199                                                     'shared_sources' ],
2200                                            dst => 'shared_sources' } },
2201                 scripts   => { script => { src => [ 'sources' ],
2202                                            dst => 'sources' } }
2203                } -> {$prodtype};
2204             foreach my $kind (keys %$intent) {
2205                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2206                              && $disabled{shared});
2207
2208                 my @src = @{$intent->{$kind}->{src}};
2209                 my $dst = $intent->{$kind}->{dst};
2210                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2211                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2212                     # %prod_sources has all applicable objects as keys, and
2213                     # their corresponding sources as values
2214                     my %prod_sources =
2215                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2216                         map { keys %{$unified_copy{$_}->{$prod}} }
2217                         @src;
2218                     foreach (keys %prod_sources) {
2219                         # Only affect object files and resource files,
2220                         # the others simply get a new value
2221                         # (+1 instead of -1)
2222                         if ($_ =~ /\.(o|res)$/) {
2223                             (my $prodname = $prod) =~ s|\.a$||;
2224                             my $newobj =
2225                                 catfile(dirname($_),
2226                                         basename($prodname)
2227                                             . '-' . $kind
2228                                             . '-' . basename($_));
2229                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2230                             foreach my $src (@{$prod_sources{$_}}) {
2231                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2232                             }
2233                             # Adjust dependencies
2234                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2235                                 $unified_info{depends}->{$_}->{$deps} = -1;
2236                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2237                             }
2238                             # Adjust includes
2239                             foreach my $k (('source', 'build')) {
2240                                 next unless
2241                                     defined($unified_info{includes}->{$_}->{$k});
2242                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2243                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2244                             }
2245                         } else {
2246                             $unified_info{$dst}->{$prod}->{$_} = 1;
2247                         }
2248                     }
2249                 }
2250             }
2251         }
2252     }
2253     # At this point, we have a number of sources with the value -1.  They
2254     # aren't part of the local build and are probably meant for a different
2255     # platform, and can therefore be cleaned away.  That happens when making
2256     # %unified_info more efficient below.
2257
2258     ### Make unified_info a bit more efficient
2259     # One level structures
2260     foreach (("programs", "libraries", "modules", "scripts")) {
2261         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2262     }
2263     # Two level structures
2264     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends")) {
2265         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2266             my @items =
2267                 sort
2268                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2269                 keys %{$unified_info{$l1}->{$l2}};
2270             if (@items) {
2271                 $unified_info{$l1}->{$l2} = [ @items ];
2272             } else {
2273                 delete $unified_info{$l1}->{$l2};
2274             }
2275         }
2276     }
2277     # Defines
2278     foreach my $dest (sort keys %{$unified_info{defines}}) {
2279         $unified_info{defines}->{$dest}
2280             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2281                 sort keys %{$unified_info{defines}->{$dest}} ];
2282     }
2283     # Includes
2284     foreach my $dest (sort keys %{$unified_info{includes}}) {
2285         if (defined($unified_info{includes}->{$dest}->{build})) {
2286             my @source_includes = ();
2287             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2288                 if defined($unified_info{includes}->{$dest}->{source});
2289             $unified_info{includes}->{$dest} =
2290                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2291             foreach my $inc (@source_includes) {
2292                 push @{$unified_info{includes}->{$dest}}, $inc
2293                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2294             }
2295         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2296             $unified_info{includes}->{$dest} =
2297                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2298         } else {
2299             delete $unified_info{includes}->{$dest};
2300         }
2301     }
2302
2303     # For convenience collect information regarding directories where
2304     # files are generated, those generated files and the end product
2305     # they end up in where applicable.  Then, add build rules for those
2306     # directories
2307     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2308                      "dso" => [ @{$unified_info{modules}} ],
2309                      "bin" => [ @{$unified_info{programs}} ],
2310                      "script" => [ @{$unified_info{scripts}} ] );
2311     foreach my $type (keys %loopinfo) {
2312         foreach my $product (@{$loopinfo{$type}}) {
2313             my %dirs = ();
2314             my $pd = dirname($product);
2315
2316             foreach (@{$unified_info{sources}->{$product} // []},
2317                      @{$unified_info{shared_sources}->{$product} // []}) {
2318                 my $d = dirname($_);
2319
2320                 # We don't want to create targets for source directories
2321                 # when building out of source
2322                 next if ($config{sourcedir} ne $config{builddir}
2323                              && $d =~ m|^\Q$config{sourcedir}\E|);
2324                 # We already have a "test" target, and the current directory
2325                 # is just silly to make a target for
2326                 next if $d eq "test" || $d eq ".";
2327
2328                 $dirs{$d} = 1;
2329                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2330                     if $d ne $pd;
2331             }
2332             foreach (keys %dirs) {
2333                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2334                     $product;
2335             }
2336         }
2337     }
2338 }
2339
2340 # For the schemes that need it, we provide the old *_obj configs
2341 # from the *_asm_obj ones
2342 foreach (grep /_(asm|aux)_src$/, keys %target) {
2343     my $src = $_;
2344     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2345     $target{$obj} = $target{$src};
2346     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2347     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2348 }
2349
2350 # Write down our configuration where it fits #########################
2351
2352 print "Creating configdata.pm\n";
2353 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2354 print OUT <<"EOF";
2355 #! $config{HASHBANGPERL}
2356
2357 package configdata;
2358
2359 use strict;
2360 use warnings;
2361
2362 use Exporter;
2363 #use vars qw(\@ISA \@EXPORT);
2364 our \@ISA = qw(Exporter);
2365 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables);
2366
2367 EOF
2368 print OUT "our %config = (\n";
2369 foreach (sort keys %config) {
2370     if (ref($config{$_}) eq "ARRAY") {
2371         print OUT "  ", $_, " => [ ", join(", ",
2372                                            map { quotify("perl", $_) }
2373                                            @{$config{$_}}), " ],\n";
2374     } elsif (ref($config{$_}) eq "HASH") {
2375         print OUT "  ", $_, " => {";
2376         if (scalar keys %{$config{$_}} > 0) {
2377             print OUT "\n";
2378             foreach my $key (sort keys %{$config{$_}}) {
2379                 print OUT "      ",
2380                     join(" => ",
2381                          quotify("perl", $key),
2382                          defined $config{$_}->{$key}
2383                              ? quotify("perl", $config{$_}->{$key})
2384                              : "undef");
2385                 print OUT ",\n";
2386             }
2387             print OUT "  ";
2388         }
2389         print OUT "},\n";
2390     } else {
2391         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2392     }
2393 }
2394 print OUT <<"EOF";
2395 );
2396
2397 EOF
2398 print OUT "our %target = (\n";
2399 foreach (sort keys %target) {
2400     if (ref($target{$_}) eq "ARRAY") {
2401         print OUT "  ", $_, " => [ ", join(", ",
2402                                            map { quotify("perl", $_) }
2403                                            @{$target{$_}}), " ],\n";
2404     } else {
2405         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2406     }
2407 }
2408 print OUT <<"EOF";
2409 );
2410
2411 EOF
2412 print OUT "our \%available_protocols = (\n";
2413 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2414 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2415 print OUT <<"EOF";
2416 );
2417
2418 EOF
2419 print OUT "our \@disablables = (\n";
2420 foreach (@disablables) {
2421     print OUT "  ", quotify("perl", $_), ",\n";
2422 }
2423 print OUT <<"EOF";
2424 );
2425
2426 EOF
2427 print OUT "our \%disabled = (\n";
2428 foreach (sort keys %disabled) {
2429     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2430 }
2431 print OUT <<"EOF";
2432 );
2433
2434 EOF
2435 print OUT "our %withargs = (\n";
2436 foreach (sort keys %withargs) {
2437     if (ref($withargs{$_}) eq "ARRAY") {
2438         print OUT "  ", $_, " => [ ", join(", ",
2439                                            map { quotify("perl", $_) }
2440                                            @{$withargs{$_}}), " ],\n";
2441     } else {
2442         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2443     }
2444 }
2445 print OUT <<"EOF";
2446 );
2447
2448 EOF
2449 if ($builder eq "unified") {
2450     my $recurse;
2451     $recurse = sub {
2452         my $indent = shift;
2453         foreach (@_) {
2454             if (ref $_ eq "ARRAY") {
2455                 print OUT " "x$indent, "[\n";
2456                 foreach (@$_) {
2457                     $recurse->($indent + 4, $_);
2458                 }
2459                 print OUT " "x$indent, "],\n";
2460             } elsif (ref $_ eq "HASH") {
2461                 my %h = %$_;
2462                 print OUT " "x$indent, "{\n";
2463                 foreach (sort keys %h) {
2464                     if (ref $h{$_} eq "") {
2465                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2466                     } else {
2467                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2468                         $recurse->($indent + 8, $h{$_});
2469                     }
2470                 }
2471                 print OUT " "x$indent, "},\n";
2472             } else {
2473                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2474             }
2475         }
2476     };
2477     print OUT "our %unified_info = (\n";
2478     foreach (sort keys %unified_info) {
2479         if (ref $unified_info{$_} eq "") {
2480             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2481         } else {
2482             print OUT " "x4, quotify("perl", $_), " =>\n";
2483             $recurse->(8, $unified_info{$_});
2484         }
2485     }
2486     print OUT <<"EOF";
2487 );
2488
2489 EOF
2490 }
2491 print OUT
2492     "# The following data is only used when this files is use as a script\n";
2493 print OUT "my \@makevars = (\n";
2494 foreach (sort keys %user) {
2495     print OUT "    '",$_,"',\n";
2496 }
2497 print OUT ");\n";
2498 print OUT "my \%disabled_info = (\n";
2499 foreach my $what (sort keys %disabled_info) {
2500     print OUT "    '$what' => {\n";
2501     foreach my $info (sort keys %{$disabled_info{$what}}) {
2502         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2503             print OUT "        $info => [ ",
2504                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2505                 " ],\n";
2506         } else {
2507             print OUT "        $info => '", $disabled_info{$what}->{$info},
2508                 "',\n";
2509         }
2510     }
2511     print OUT "    },\n";
2512 }
2513 print OUT ");\n";
2514 print OUT 'my @user_crossable = qw( ', join (' ', @user_crossable), " );\n";
2515 print OUT << 'EOF';
2516 # If run directly, we can give some answers, and even reconfigure
2517 unless (caller) {
2518     use Getopt::Long;
2519     use File::Spec::Functions;
2520     use File::Basename;
2521     use Pod::Usage;
2522
2523     my $here = dirname($0);
2524
2525     my $dump = undef;
2526     my $cmdline = undef;
2527     my $options = undef;
2528     my $target = undef;
2529     my $envvars = undef;
2530     my $makevars = undef;
2531     my $buildparams = undef;
2532     my $reconf = undef;
2533     my $verbose = undef;
2534     my $help = undef;
2535     my $man = undef;
2536     GetOptions('dump|d'                 => \$dump,
2537                'command-line|c'         => \$cmdline,
2538                'options|o'              => \$options,
2539                'target|t'               => \$target,
2540                'environment|e'          => \$envvars,
2541                'make-variables|m'       => \$makevars,
2542                'build-parameters|b'     => \$buildparams,
2543                'reconfigure|reconf|r'   => \$reconf,
2544                'verbose|v'              => \$verbose,
2545                'help'                   => \$help,
2546                'man'                    => \$man)
2547         or die "Errors in command line arguments\n";
2548
2549     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2550             || $buildparams || $reconf || $verbose || $help || $man) {
2551         print STDERR <<"_____";
2552 You must give at least one option.
2553 For more information, do '$0 --help'
2554 _____
2555         exit(2);
2556     }
2557
2558     if ($help) {
2559         pod2usage(-exitval => 0,
2560                   -verbose => 1);
2561     }
2562     if ($man) {
2563         pod2usage(-exitval => 0,
2564                   -verbose => 2);
2565     }
2566     if ($dump || $cmdline) {
2567         print "\nCommand line (with current working directory = $here):\n\n";
2568         print '    ',join(' ',
2569                           $config{PERL},
2570                           catfile($config{sourcedir}, 'Configure'),
2571                           @{$config{perlargv}}), "\n";
2572         print "\nPerl information:\n\n";
2573         print '    ',$config{perl_cmd},"\n";
2574         print '    ',$config{perl_version},' for ',$config{perl_archname},"\n";
2575     }
2576     if ($dump || $options) {
2577         my $longest = 0;
2578         my $longest2 = 0;
2579         foreach my $what (@disablables) {
2580             $longest = length($what) if $longest < length($what);
2581             $longest2 = length($disabled{$what})
2582                 if $disabled{$what} && $longest2 < length($disabled{$what});
2583         }
2584         print "\nEnabled features:\n\n";
2585         foreach my $what (@disablables) {
2586             print "    $what\n" unless $disabled{$what};
2587         }
2588         print "\nDisabled features:\n\n";
2589         foreach my $what (@disablables) {
2590             if ($disabled{$what}) {
2591                 print "    $what", ' ' x ($longest - length($what) + 1),
2592                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2593                 print $disabled_info{$what}->{macro}
2594                     if $disabled_info{$what}->{macro};
2595                 print ' (skip ',
2596                     join(', ', @{$disabled_info{$what}->{skipped}}),
2597                     ')'
2598                     if $disabled_info{$what}->{skipped};
2599                 print "\n";
2600             }
2601         }
2602     }
2603     if ($dump || $target) {
2604         print "\nConfig target attributes:\n\n";
2605         foreach (sort keys %target) {
2606             next if $_ =~ m|^_| || $_ eq 'template';
2607             my $quotify = sub {
2608                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2609             };
2610             print '    ', $_, ' => ';
2611             if (ref($target{$_}) eq "ARRAY") {
2612                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2613             } else {
2614                 print $quotify->($target{$_}), ",\n"
2615             }
2616         }
2617     }
2618     if ($dump || $envvars) {
2619         print "\nRecorded environment:\n\n";
2620         foreach (sort keys %{$config{perlenv}}) {
2621             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2622         }
2623     }
2624     if ($dump || $makevars) {
2625         print "\nMakevars:\n\n";
2626         foreach my $var (@makevars) {
2627             my $prefix = '';
2628             $prefix = $config{CROSS_COMPILE}
2629                 if grep { $var eq $_ } @user_crossable;
2630             $prefix //= '';
2631             print '    ',$var,' ' x (16 - length $var),'= ',
2632                 (ref $config{$var} eq 'ARRAY'
2633                  ? join(' ', @{$config{$var}})
2634                  : $prefix.$config{$var}),
2635                 "\n"
2636                 if defined $config{$var};
2637         }
2638
2639         my @buildfile = ($config{builddir}, $config{build_file});
2640         unshift @buildfile, $here
2641             unless file_name_is_absolute($config{builddir});
2642         my $buildfile = canonpath(catdir(@buildfile));
2643         print <<"_____";
2644
2645 NOTE: These variables only represent the configuration view.  The build file
2646 template may have processed these variables further, please have a look at the
2647 build file for more exact data:
2648     $buildfile
2649 _____
2650     }
2651     if ($dump || $buildparams) {
2652         my @buildfile = ($config{builddir}, $config{build_file});
2653         unshift @buildfile, $here
2654             unless file_name_is_absolute($config{builddir});
2655         print "\nbuild file:\n\n";
2656         print "    ", canonpath(catfile(@buildfile)),"\n";
2657
2658         print "\nbuild file templates:\n\n";
2659         foreach (@{$config{build_file_templates}}) {
2660             my @tmpl = ($_);
2661             unshift @tmpl, $here
2662                 unless file_name_is_absolute($config{sourcedir});
2663             print '    ',canonpath(catfile(@tmpl)),"\n";
2664         }
2665     }
2666     if ($reconf) {
2667         if ($verbose) {
2668             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2669             foreach (sort keys %{$config{perlenv}}) {
2670                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2671             }
2672         }
2673
2674         chdir $here;
2675         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2676     }
2677 }
2678
2679 1;
2680
2681 __END__
2682
2683 =head1 NAME
2684
2685 configdata.pm - configuration data for OpenSSL builds
2686
2687 =head1 SYNOPSIS
2688
2689 Interactive:
2690
2691   perl configdata.pm [options]
2692
2693 As data bank module:
2694
2695   use configdata;
2696
2697 =head1 DESCRIPTION
2698
2699 This module can be used in two modes, interactively and as a module containing
2700 all the data recorded by OpenSSL's Configure script.
2701
2702 When used interactively, simply run it as any perl script, with at least one
2703 option, and you will get the information you ask for.  See L</OPTIONS> below.
2704
2705 When loaded as a module, you get a few databanks with useful information to
2706 perform build related tasks.  The databanks are:
2707
2708     %config             Configured things.
2709     %target             The OpenSSL config target with all inheritances
2710                         resolved.
2711     %disabled           The features that are disabled.
2712     @disablables        The list of features that can be disabled.
2713     %withargs           All data given through --with-THING options.
2714     %unified_info       All information that was computed from the build.info
2715                         files.
2716
2717 =head1 OPTIONS
2718
2719 =over 4
2720
2721 =item B<--help>
2722
2723 Print a brief help message and exit.
2724
2725 =item B<--man>
2726
2727 Print the manual page and exit.
2728
2729 =item B<--dump> | B<-d>
2730
2731 Print all relevant configuration data.  This is equivalent to B<--command-line>
2732 B<--options> B<--target> B<--environment> B<--make-variables>
2733 B<--build-parameters>.
2734
2735 =item B<--command-line> | B<-c>
2736
2737 Print the current configuration command line.
2738
2739 =item B<--options> | B<-o>
2740
2741 Print the features, both enabled and disabled, and display defined macro and
2742 skipped directories where applicable.
2743
2744 =item B<--target> | B<-t>
2745
2746 Print the config attributes for this config target.
2747
2748 =item B<--environment> | B<-e>
2749
2750 Print the environment variables and their values at the time of configuration.
2751
2752 =item B<--make-variables> | B<-m>
2753
2754 Print the main make variables generated in the current configuration
2755
2756 =item B<--build-parameters> | B<-b>
2757
2758 Print the build parameters, i.e. build file and build file templates.
2759
2760 =item B<--reconfigure> | B<--reconf> | B<-r>
2761
2762 Redo the configuration.
2763
2764 =item B<--verbose> | B<-v>
2765
2766 Verbose output.
2767
2768 =back
2769
2770 =cut
2771
2772 EOF
2773 close(OUT);
2774 if ($builder_platform eq 'unix') {
2775     my $mode = (0755 & ~umask);
2776     chmod $mode, 'configdata.pm'
2777         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2778 }
2779
2780 my %builders = (
2781     unified => sub {
2782         print 'Creating ',$target{build_file},"\n";
2783         run_dofile(catfile($blddir, $target{build_file}),
2784                    @{$config{build_file_templates}});
2785     },
2786     );
2787
2788 $builders{$builder}->($builder_platform, @builder_opts);
2789
2790 $SIG{__DIE__} = $orig_death_handler;
2791
2792 print <<"EOF" if ($disabled{threads} eq "unavailable");
2793
2794 The library could not be configured for supporting multi-threaded
2795 applications as the compiler options required on this system are not known.
2796 See file INSTALL for details if you need multi-threading.
2797 EOF
2798
2799 print <<"EOF" if ($no_shared_warn);
2800
2801 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2802 platform, so we will pretend you gave the option 'no-pic', which also disables
2803 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2804 or position independent code, please let us know (but please first make sure
2805 you have tried with a current version of OpenSSL).
2806 EOF
2807
2808 print <<"EOF";
2809
2810 **********************************************************************
2811 ***                                                                ***
2812 ***   OpenSSL has been successfully configured                     ***
2813 ***                                                                ***
2814 ***   If you encounter a problem while building, please open an    ***
2815 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2816 ***   and include the output from the following command:           ***
2817 ***                                                                ***
2818 ***       perl configdata.pm --dump                                ***
2819 ***                                                                ***
2820 ***   (If you are new to OpenSSL, you might want to consult the    ***
2821 ***   'Troubleshooting' section in the INSTALL file first)         ***
2822 ***                                                                ***
2823 **********************************************************************
2824 EOF
2825
2826 exit(0);
2827
2828 ######################################################################
2829 #
2830 # Helpers and utility functions
2831 #
2832
2833 # Death handler, to print a helpful message in case of failure #######
2834 #
2835 sub death_handler {
2836     die @_ if $^S;              # To prevent the added message in eval blocks
2837     my $build_file = $target{build_file} // "build file";
2838     my @message = ( <<"_____", @_ );
2839
2840 Failure!  $build_file wasn't produced.
2841 Please read INSTALL and associated NOTES files.  You may also have to look over
2842 your available compiler tool chain or change your configuration.
2843
2844 _____
2845
2846     # Dying is terminal, so it's ok to reset the signal handler here.
2847     $SIG{__DIE__} = $orig_death_handler;
2848     die @message;
2849 }
2850
2851 # Configuration file reading #########################################
2852
2853 # Note: All of the helper functions are for lazy evaluation.  They all
2854 # return a CODE ref, which will return the intended value when evaluated.
2855 # Thus, whenever there's mention of a returned value, it's about that
2856 # intended value.
2857
2858 # Helper function to implement conditional inheritance depending on the
2859 # value of $disabled{asm}.  Used in inherit_from values as follows:
2860 #
2861 #      inherit_from => [ "template", asm("asm_tmpl") ]
2862 #
2863 sub asm {
2864     my @x = @_;
2865     sub {
2866         $disabled{asm} ? () : @x;
2867     }
2868 }
2869
2870 # Helper function to implement conditional value variants, with a default
2871 # plus additional values based on the value of $config{build_type}.
2872 # Arguments are given in hash table form:
2873 #
2874 #       picker(default => "Basic string: ",
2875 #              debug   => "debug",
2876 #              release => "release")
2877 #
2878 # When configuring with --debug, the resulting string will be
2879 # "Basic string: debug", and when not, it will be "Basic string: release"
2880 #
2881 # This can be used to create variants of sets of flags according to the
2882 # build type:
2883 #
2884 #       cflags => picker(default => "-Wall",
2885 #                        debug   => "-g -O0",
2886 #                        release => "-O3")
2887 #
2888 sub picker {
2889     my %opts = @_;
2890     return sub { add($opts{default} || (),
2891                      $opts{$config{build_type}} || ())->(); }
2892 }
2893
2894 # Helper function to combine several values of different types into one.
2895 # This is useful if you want to combine a string with the result of a
2896 # lazy function, such as:
2897 #
2898 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2899 #
2900 sub combine {
2901     my @stuff = @_;
2902     return sub { add(@stuff)->(); }
2903 }
2904
2905 # Helper function to implement conditional values depending on the value
2906 # of $disabled{threads}.  Can be used as follows:
2907 #
2908 #       cflags => combine("-Wall", threads("-pthread"))
2909 #
2910 sub threads {
2911     my @flags = @_;
2912     return sub { add($disabled{threads} ? () : @flags)->(); }
2913 }
2914
2915 sub shared {
2916     my @flags = @_;
2917     return sub { add($disabled{shared} ? () : @flags)->(); }
2918 }
2919
2920 our $add_called = 0;
2921 # Helper function to implement adding values to already existing configuration
2922 # values.  It handles elements that are ARRAYs, CODEs and scalars
2923 sub _add {
2924     my $separator = shift;
2925
2926     # If there's any ARRAY in the collection of values OR the separator
2927     # is undef, we will return an ARRAY of combined values, otherwise a
2928     # string of joined values with $separator as the separator.
2929     my $found_array = !defined($separator);
2930
2931     my @values =
2932         map {
2933             my $res = $_;
2934             while (ref($res) eq "CODE") {
2935                 $res = $res->();
2936             }
2937             if (defined($res)) {
2938                 if (ref($res) eq "ARRAY") {
2939                     $found_array = 1;
2940                     @$res;
2941                 } else {
2942                     $res;
2943                 }
2944             } else {
2945                 ();
2946             }
2947     } (@_);
2948
2949     $add_called = 1;
2950
2951     if ($found_array) {
2952         [ @values ];
2953     } else {
2954         join($separator, grep { defined($_) && $_ ne "" } @values);
2955     }
2956 }
2957 sub add_before {
2958     my $separator = " ";
2959     if (ref($_[$#_]) eq "HASH") {
2960         my $opts = pop;
2961         $separator = $opts->{separator};
2962     }
2963     my @x = @_;
2964     sub { _add($separator, @x, @_) };
2965 }
2966 sub add {
2967     my $separator = " ";
2968     if (ref($_[$#_]) eq "HASH") {
2969         my $opts = pop;
2970         $separator = $opts->{separator};
2971     }
2972     my @x = @_;
2973     sub { _add($separator, @_, @x) };
2974 }
2975
2976 sub read_eval_file {
2977     my $fname = shift;
2978     my $content;
2979     my @result;
2980
2981     open F, "< $fname" or die "Can't open '$fname': $!\n";
2982     {
2983         undef local $/;
2984         $content = <F>;
2985     }
2986     close F;
2987     {
2988         local $@;
2989
2990         @result = ( eval $content );
2991         warn $@ if $@;
2992     }
2993     return wantarray ? @result : $result[0];
2994 }
2995
2996 # configuration reader, evaluates the input file as a perl script and expects
2997 # it to fill %targets with target configurations.  Those are then added to
2998 # %table.
2999 sub read_config {
3000     my $fname = shift;
3001     my %targets;
3002
3003     {
3004         # Protect certain tables from tampering
3005         local %table = ();
3006
3007         %targets = read_eval_file($fname);
3008     }
3009     my %preexisting = ();
3010     foreach (sort keys %targets) {
3011         $preexisting{$_} = 1 if $table{$_};
3012     }
3013     die <<"EOF",
3014 The following config targets from $fname
3015 shadow pre-existing config targets with the same name:
3016 EOF
3017         map { "  $_\n" } sort keys %preexisting
3018         if %preexisting;
3019
3020
3021     # For each target, check that it's configured with a hash table.
3022     foreach (keys %targets) {
3023         if (ref($targets{$_}) ne "HASH") {
3024             if (ref($targets{$_}) eq "") {
3025                 warn "Deprecated target configuration for $_, ignoring...\n";
3026             } else {
3027                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3028             }
3029             delete $targets{$_};
3030         } else {
3031             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3032         }
3033     }
3034
3035     %table = (%table, %targets);
3036
3037 }
3038
3039 # configuration resolver.  Will only resolve all the lazy evaluation
3040 # codeblocks for the chosen target and all those it inherits from,
3041 # recursively
3042 sub resolve_config {
3043     my $target = shift;
3044     my @breadcrumbs = @_;
3045
3046 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3047
3048     if (grep { $_ eq $target } @breadcrumbs) {
3049         die "inherit_from loop!  target backtrace:\n  "
3050             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3051     }
3052
3053     if (!defined($table{$target})) {
3054         warn "Warning! target $target doesn't exist!\n";
3055         return ();
3056     }
3057     # Recurse through all inheritances.  They will be resolved on the
3058     # fly, so when this operation is done, they will all just be a
3059     # bunch of attributes with string values.
3060     # What we get here, though, are keys with references to lists of
3061     # the combined values of them all.  We will deal with lists after
3062     # this stage is done.
3063     my %combined_inheritance = ();
3064     if ($table{$target}->{inherit_from}) {
3065         my @inherit_from =
3066             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3067         foreach (@inherit_from) {
3068             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3069
3070             # 'template' is a marker that's considered private to
3071             # the config that had it.
3072             delete $inherited_config{template};
3073
3074             foreach (keys %inherited_config) {
3075                 if (!$combined_inheritance{$_}) {
3076                     $combined_inheritance{$_} = [];
3077                 }
3078                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3079             }
3080         }
3081     }
3082
3083     # We won't need inherit_from in this target any more, since we've
3084     # resolved all the inheritances that lead to this
3085     delete $table{$target}->{inherit_from};
3086
3087     # Now is the time to deal with those lists.  Here's the place to
3088     # decide what shall be done with those lists, all based on the
3089     # values of the target we're currently dealing with.
3090     # - If a value is a coderef, it will be executed with the list of
3091     #   inherited values as arguments.
3092     # - If the corresponding key doesn't have a value at all or is the
3093     #   empty string, the inherited value list will be run through the
3094     #   default combiner (below), and the result becomes this target's
3095     #   value.
3096     # - Otherwise, this target's value is assumed to be a string that
3097     #   will simply override the inherited list of values.
3098     my $default_combiner = add();
3099
3100     my %all_keys =
3101         map { $_ => 1 } (keys %combined_inheritance,
3102                          keys %{$table{$target}});
3103
3104     sub process_values {
3105         my $object    = shift;
3106         my $inherited = shift;  # Always a [ list ]
3107         my $target    = shift;
3108         my $entry     = shift;
3109
3110         $add_called = 0;
3111
3112         while(ref($object) eq "CODE") {
3113             $object = $object->(@$inherited);
3114         }
3115         if (!defined($object)) {
3116             return ();
3117         }
3118         elsif (ref($object) eq "ARRAY") {
3119             local $add_called;  # To make sure recursive calls don't affect it
3120             return [ map { process_values($_, $inherited, $target, $entry) }
3121                      @$object ];
3122         } elsif (ref($object) eq "") {
3123             return $object;
3124         } else {
3125             die "cannot handle reference type ",ref($object)
3126                 ," found in target ",$target," -> ",$entry,"\n";
3127         }
3128     }
3129
3130     foreach (sort keys %all_keys) {
3131         my $previous = $combined_inheritance{$_};
3132
3133         # Current target doesn't have a value for the current key?
3134         # Assign it the default combiner, the rest of this loop body
3135         # will handle it just like any other coderef.
3136         if (!exists $table{$target}->{$_}) {
3137             $table{$target}->{$_} = $default_combiner;
3138         }
3139
3140         $table{$target}->{$_} = process_values($table{$target}->{$_},
3141                                                $combined_inheritance{$_},
3142                                                $target, $_);
3143         unless(defined($table{$target}->{$_})) {
3144             delete $table{$target}->{$_};
3145         }
3146 #        if ($extra_checks &&
3147 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3148 #            warn "$_ got replaced in $target\n";
3149 #        }
3150     }
3151
3152     # Finally done, return the result.
3153     return %{$table{$target}};
3154 }
3155
3156 sub usage
3157         {
3158         print STDERR $usage;
3159         print STDERR "\npick os/compiler from:\n";
3160         my $j=0;
3161         my $i;
3162         my $k=0;
3163         foreach $i (sort keys %table)
3164                 {
3165                 next if $table{$i}->{template};
3166                 next if $i =~ /^debug/;
3167                 $k += length($i) + 1;
3168                 if ($k > 78)
3169                         {
3170                         print STDERR "\n";
3171                         $k=length($i);
3172                         }
3173                 print STDERR $i . " ";
3174                 }
3175         foreach $i (sort keys %table)
3176                 {
3177                 next if $table{$i}->{template};
3178                 next if $i !~ /^debug/;
3179                 $k += length($i) + 1;
3180                 if ($k > 78)
3181                         {
3182                         print STDERR "\n";
3183                         $k=length($i);
3184                         }
3185                 print STDERR $i . " ";
3186                 }
3187         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3188         exit(1);
3189         }
3190
3191 sub run_dofile
3192 {
3193     my $out = shift;
3194     my @templates = @_;
3195
3196     unlink $out || warn "Can't remove $out, $!"
3197         if -f $out;
3198     foreach (@templates) {
3199         die "Can't open $_, $!" unless -f $_;
3200     }
3201     my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
3202     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
3203     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
3204     system($cmd);
3205     exit 1 if $? != 0;
3206     rename("$out.new", $out) || die "Can't rename $out.new, $!";
3207 }
3208
3209 sub compiler_predefined {
3210     state %predefined;
3211     my $cc = shift;
3212
3213     return () if $^O eq 'VMS';
3214
3215     die 'compiler_predefined called without a compiler command'
3216         unless $cc;
3217
3218     if (! $predefined{$cc}) {
3219
3220         $predefined{$cc} = {};
3221
3222         # collect compiler pre-defines from gcc or gcc-alike...
3223         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3224         while (my $l = <PIPE>) {
3225             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3226             $predefined{$cc}->{$1} = $2 // '';
3227         }
3228         close(PIPE);
3229     }
3230
3231     return %{$predefined{$cc}};
3232 }
3233
3234 sub which
3235 {
3236     my ($name)=@_;
3237
3238     if (eval { require IPC::Cmd; 1; }) {
3239         IPC::Cmd->import();
3240         return scalar IPC::Cmd::can_run($name);
3241     } else {
3242         # if there is $directories component in splitpath,
3243         # then it's not something to test with $PATH...
3244         return $name if (File::Spec->splitpath($name))[1];
3245
3246         foreach (File::Spec->path()) {
3247             my $fullpath = catfile($_, "$name$target{exe_extension}");
3248             if (-f $fullpath and -x $fullpath) {
3249                 return $fullpath;
3250             }
3251         }
3252     }
3253 }
3254
3255 sub env
3256 {
3257     my $name = shift;
3258     my %opts = @_;
3259
3260     unless ($opts{cacheonly}) {
3261         # Note that if $ENV{$name} doesn't exist or is undefined,
3262         # $config{perlenv}->{$name} will be created with the value
3263         # undef.  This is intentional.
3264
3265         $config{perlenv}->{$name} = $ENV{$name}
3266             if ! exists $config{perlenv}->{$name};
3267     }
3268     return $config{perlenv}->{$name};
3269 }
3270
3271 # Configuration printer ##############################################
3272
3273 sub print_table_entry
3274 {
3275     local $now_printing = shift;
3276     my %target = resolve_config($now_printing);
3277     my $type = shift;
3278
3279     # Don't print the templates
3280     return if $target{template};
3281
3282     my @sequence = (
3283         "sys_id",
3284         "cpp",
3285         "cppflags",
3286         "defines",
3287         "includes",
3288         "cc",
3289         "cflags",
3290         "unistd",
3291         "ld",
3292         "lflags",
3293         "loutflag",
3294         "ex_libs",
3295         "bn_ops",
3296         "apps_aux_src",
3297         "cpuid_asm_src",
3298         "uplink_aux_src",
3299         "bn_asm_src",
3300         "ec_asm_src",
3301         "des_asm_src",
3302         "aes_asm_src",
3303         "bf_asm_src",
3304         "md5_asm_src",
3305         "cast_asm_src",
3306         "sha1_asm_src",
3307         "rc4_asm_src",
3308         "rmd160_asm_src",
3309         "rc5_asm_src",
3310         "wp_asm_src",
3311         "cmll_asm_src",
3312         "modes_asm_src",
3313         "padlock_asm_src",
3314         "chacha_asm_src",
3315         "poly1035_asm_src",
3316         "thread_scheme",
3317         "perlasm_scheme",
3318         "dso_scheme",
3319         "shared_target",
3320         "shared_cflag",
3321         "shared_defines",
3322         "shared_ldflag",
3323         "shared_rcflag",
3324         "shared_extension",
3325         "dso_extension",
3326         "obj_extension",
3327         "exe_extension",
3328         "ranlib",
3329         "ar",
3330         "arflags",
3331         "aroutflag",
3332         "rc",
3333         "rcflags",
3334         "rcoutflag",
3335         "mt",
3336         "mtflags",
3337         "mtinflag",
3338         "mtoutflag",
3339         "multilib",
3340         "build_scheme",
3341         );
3342
3343     if ($type eq "TABLE") {
3344         print "\n";
3345         print "*** $now_printing\n";
3346         foreach (@sequence) {
3347             if (ref($target{$_}) eq "ARRAY") {
3348                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3349             } else {
3350                 printf "\$%-12s = %s\n", $_, $target{$_};
3351             }
3352         }
3353     } elsif ($type eq "HASH") {
3354         my $largest =
3355             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3356         print "    '$now_printing' => {\n";
3357         foreach (@sequence) {
3358             if ($target{$_}) {
3359                 if (ref($target{$_}) eq "ARRAY") {
3360                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3361                 } else {
3362                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3363                 }
3364             }
3365         }
3366         print "    },\n";
3367     }
3368 }
3369
3370 # Utility routines ###################################################
3371
3372 # On VMS, if the given file is a logical name, File::Spec::Functions
3373 # will consider it an absolute path.  There are cases when we want a
3374 # purely syntactic check without checking the environment.
3375 sub isabsolute {
3376     my $file = shift;
3377
3378     # On non-platforms, we just use file_name_is_absolute().
3379     return file_name_is_absolute($file) unless $^O eq "VMS";
3380
3381     # If the file spec includes a device or a directory spec,
3382     # file_name_is_absolute() is perfectly safe.
3383     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3384
3385     # Here, we know the given file spec isn't absolute
3386     return 0;
3387 }
3388
3389 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3390 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3391 # realpath() requires that at least all path components except the last is an
3392 # existing directory.  On VMS, the last component of the directory spec must
3393 # exist.
3394 sub absolutedir {
3395     my $dir = shift;
3396
3397     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3398     # will return the volume name for the device, no matter what.  Also,
3399     # it will return an incorrect directory spec if the argument is a
3400     # directory that doesn't exist.
3401     if ($^O eq "VMS") {
3402         return rel2abs($dir);
3403     }
3404
3405     # We use realpath() on Unix, since no other will properly clean out
3406     # a directory spec.
3407     use Cwd qw/realpath/;
3408
3409     return realpath($dir);
3410 }
3411
3412 sub quotify {
3413     my %processors = (
3414         perl    => sub { my $x = shift;
3415                          $x =~ s/([\\\$\@"])/\\$1/g;
3416                          return '"'.$x.'"'; },
3417         maybeshell => sub { my $x = shift;
3418                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3419                             if ($x ne $y || $x =~ m|\s|) {
3420                                 return '"'.$y.'"';
3421                             } else {
3422                                 return $x;
3423                             }
3424                         },
3425         );
3426     my $for = shift;
3427     my $processor =
3428         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3429
3430     return map { $processor->($_); } @_;
3431 }
3432
3433 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3434 # $filename is a file name to read from
3435 # $line_concat_cond_re is a regexp detecting a line continuation ending
3436 # $line_concat is a CODEref that takes care of concatenating two lines
3437 sub collect_from_file {
3438     my $filename = shift;
3439     my $line_concat_cond_re = shift;
3440     my $line_concat = shift;
3441
3442     open my $fh, $filename || die "unable to read $filename: $!\n";
3443     return sub {
3444         my $saved_line = "";
3445         $_ = "";
3446         while (<$fh>) {
3447             s|\R$||;
3448             if (defined $line_concat) {
3449                 $_ = $line_concat->($saved_line, $_);
3450                 $saved_line = "";
3451             }
3452             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3453                 $saved_line = $_;
3454                 next;
3455             }
3456             return $_;
3457         }
3458         die "$filename ending with continuation line\n" if $_;
3459         close $fh;
3460         return undef;
3461     }
3462 }
3463
3464 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3465 # $array is an ARRAYref of lines
3466 # $line_concat_cond_re is a regexp detecting a line continuation ending
3467 # $line_concat is a CODEref that takes care of concatenating two lines
3468 sub collect_from_array {
3469     my $array = shift;
3470     my $line_concat_cond_re = shift;
3471     my $line_concat = shift;
3472     my @array = (@$array);
3473
3474     return sub {
3475         my $saved_line = "";
3476         $_ = "";
3477         while (defined($_ = shift @array)) {
3478             s|\R$||;
3479             if (defined $line_concat) {
3480                 $_ = $line_concat->($saved_line, $_);
3481                 $saved_line = "";
3482             }
3483             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3484                 $saved_line = $_;
3485                 next;
3486             }
3487             return $_;
3488         }
3489         die "input text ending with continuation line\n" if $_;
3490         return undef;
3491     }
3492 }
3493
3494 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3495 # $lineiterator is a CODEref that delivers one line at a time.
3496 # All following arguments are regex/CODEref pairs, where the regexp detects a
3497 # line and the CODEref does something with the result of the regexp.
3498 sub collect_information {
3499     my $lineiterator = shift;
3500     my %collectors = @_;
3501
3502     while(defined($_ = $lineiterator->())) {
3503         s|\R$||;
3504         my $found = 0;
3505         if ($collectors{"BEFORE"}) {
3506             $collectors{"BEFORE"}->($_);
3507         }
3508         foreach my $re (keys %collectors) {
3509             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3510                 $collectors{$re}->($lineiterator);
3511                 $found = 1;
3512             };
3513         }
3514         if ($collectors{"OTHERWISE"}) {
3515             $collectors{"OTHERWISE"}->($lineiterator, $_)
3516                 unless $found || !defined $collectors{"OTHERWISE"};
3517         }
3518         if ($collectors{"AFTER"}) {
3519             $collectors{"AFTER"}->($_);
3520         }
3521     }
3522 }
3523
3524 # tokenize($line)
3525 # tokenize($line,$separator)
3526 # $line is a line of text to split up into tokens
3527 # $separator [optional] is a regular expression that separates the tokens,
3528 # the default being spaces.  Do not use quotes of any kind as separators,
3529 # that will give undefined results.
3530 # Returns a list of tokens.
3531 #
3532 # Tokens are divided by separator (spaces by default).  If the tokens include
3533 # the separators, they have to be quoted with single or double quotes.
3534 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3535 # with backslash.
3536 # Basically, the same quoting rules apply for " and ' as in any
3537 # Unix shell.
3538 sub tokenize {
3539     my $line = my $debug_line = shift;
3540     my $separator = shift // qr|\s+|;
3541     my @result = ();
3542
3543     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3544         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3545     }
3546
3547     while ($line =~ s|^${separator}||, $line ne "") {
3548         my $token = "";
3549     again:
3550         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3551         $token .= $1;
3552         $line = $2.$';
3553
3554         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3555             $token .= $1;
3556             $line = $';
3557             goto again;
3558         } elsif ($line =~ m/^'([^']*)'/) {
3559             $token .= $1;
3560             $line = $';
3561             goto again;
3562         }
3563         push @result, $token;
3564     }
3565
3566     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3567         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3568         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3569     }
3570     return @result;
3571 }