Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::Glob;
  21
  22 # see INSTALL for instructions.
  23
  24 my $orig_death_handler = $SIG{__DIE__};
  25 $SIG{__DIE__} = \&death_handler;
  26
  27 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  28
  29 # Options:
  30 #
  31 # --config      add the given configuration file, which will be read after
  32 #               any "Configurations*" files that are found in the same
  33 #               directory as this script.
  34 # --prefix      prefix for the OpenSSL installation, which includes the
  35 #               directories bin, lib, include, share/man, share/doc/openssl
  36 #               This becomes the value of INSTALLTOP in Makefile
  37 #               (Default: /usr/local)
  38 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  39 #               If it's a relative directory, it will be added on the directory
  40 #               given with --prefix.
  41 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  42 #               (Default: PREFIX/ssl)
  43 #
  44 # --cross-compile-prefix Add specified prefix to binutils components.
  45 #
  46 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0.0 / 3.
  47 #               Do not compile support for interfaces deprecated as of the
  48 #               specified OpenSSL version.
  49 #
  50 # no-hw-xxx     do not compile support for specific crypto hardware.
  51 #               Generic OpenSSL-style methods relating to this support
  52 #               are always compiled but return NULL if the hardware
  53 #               support isn't compiled.
  54 # no-hw         do not compile support for any crypto hardware.
  55 # [no-]threads  [don't] try to create a library that is suitable for
  56 #               multithreaded applications (default is "threads" if we
  57 #               know how to do it)
  58 # [no-]shared   [don't] try to create shared libraries when supported.
  59 # [no-]pic      [don't] try to build position independent code when supported.
  60 #               If disabled, it also disables shared and dynamic-engine.
  61 # no-asm        do not use assembler
  62 # no-dso        do not compile in any native shared-library methods. This
  63 #               will ensure that all methods just return NULL.
  64 # no-egd        do not compile support for the entropy-gathering daemon APIs
  65 # [no-]zlib     [don't] compile support for zlib compression.
  66 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  67 #               library and will be loaded in run-time by the OpenSSL library.
  68 # sctp          include SCTP support
  69 # enable-weak-ssl-ciphers
  70 #               Enable weak ciphers that are disabled by default.
  71 # 386           generate 80386 code in assembly modules
  72 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  73 #               mentioned '386' option implies this one
  74 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  75 # -<xxx> +<xxx> compiler options are passed through
  76 # -static       while -static is also a pass-through compiler option (and
  77 #               as such is limited to environments where it's actually
  78 #               meaningful), it triggers a number configuration options,
  79 #               namely no-dso, no-pic, no-shared and no-threads. It is
  80 #               argued that the only reason to produce statically linked
  81 #               binaries (and in context it means executables linked with
  82 #               -static flag, and not just executables linked with static
  83 #               libcrypto.a) is to eliminate dependency on specific run-time,
  84 #               a.k.a. libc version. The mentioned config options are meant
  85 #               to achieve just that. Unfortunately on Linux it's impossible
  86 #               to eliminate the dependency completely for openssl executable
  87 #               because of getaddrinfo and gethostbyname calls, which can
  88 #               invoke dynamically loadable library facility anyway to meet
  89 #               the lookup requests. For this reason on Linux statically
  90 #               linked openssl executable has rather debugging value than
  91 #               production quality.
  92 #
  93 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
  94 #               provided to stack calls. Generates unique stack functions for
  95 #               each possible stack type.
  96 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  97 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  98 # Following are set automatically by this script
  99 #
 100 # MD5_ASM       use some extra md5 assembler,
 101 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 102 # RMD160_ASM    use some extra ripemd160 assembler,
 103 # SHA256_ASM    sha256_block is implemented in assembler
 104 # SHA512_ASM    sha512_block is implemented in assembler
 105 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 106
 107 # Minimum warning options... any contributions to OpenSSL should at least get
 108 # past these.
 109
 110 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 111 # -DPEDANTIC complements -pedantic and is meant to mask code that
 112 # is not strictly standard-compliant and/or implementation-specific,
 113 # e.g. inline assembly, disregards to alignment requirements, such
 114 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 115 # to be used even in sanitized builds, because sanitizer too is
 116 # supposed to and does take notice of non-standard behaviour. Then
 117 # -pedantic with pre-C9x compiler would also complain about 'long
 118 # long' not being supported. As 64-bit algorithms are common now,
 119 # it grew impossible to resolve this without sizeable additional
 120 # code, so we just tell compiler to be pedantic about everything
 121 # but 'long long' type.
 122
 123 my $gcc_devteam_warn = "-DDEBUG_UNUSED"
 124         . " -DPEDANTIC -pedantic -Wno-long-long"
 125         . " -Wall"
 126         . " -Wextra"
 127         . " -Wno-unused-parameter"
 128         . " -Wno-missing-field-initializers"
 129         . " -Wswitch"
 130         . " -Wsign-compare"
 131         . " -Wmissing-prototypes"
 132         . " -Wstrict-prototypes"
 133         . " -Wshadow"
 134         . " -Wformat"
 135         . " -Wtype-limits"
 136         . " -Wundef"
 137         . " -Werror"
 138         ;
 139
 140 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 141 # TODO(openssl-team): fix problems and investigate if (at least) the
 142 # following warnings can also be enabled:
 143 #       -Wcast-align
 144 #       -Wunreachable-code -- no, too ugly/compiler-specific
 145 #       -Wlanguage-extension-token -- no, we use asm()
 146 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 147 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 148 my $clang_devteam_warn = ""
 149         . " -Wswitch-default"
 150         . " -Wno-parentheses-equality"
 151         . " -Wno-language-extension-token"
 152         . " -Wno-extended-offsetof"
 153         . " -Wconditional-uninitialized"
 154         . " -Wincompatible-pointer-types-discards-qualifiers"
 155         . " -Wmissing-variable-declarations"
 156         . " -Wno-unknown-warning-option"
 157         ;
 158
 159 # This adds backtrace information to the memory leak info.  Is only used
 160 # when crypto-mdebug-backtrace is enabled.
 161 my $memleak_devteam_backtrace = "-rdynamic";
 162
 163 my $strict_warnings = 0;
 164
 165 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 166 # which would cover all BSD flavors. -pthread applies to them all,
 167 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 168 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 169 # which has to be accompanied by explicit -D_THREAD_SAFE and
 170 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 171 # seems to be sufficient?
 172 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 173
 174 #
 175 # API compatibility name to version number mapping.
 176 #
 177 my $maxapi = "3.0.0";           # API for "no-deprecated" builds
 178 my $apitable = {
 179     "3.0.0" => 3,
 180     "1.1.1" => 2,
 181     "1.1.0" => 2,
 182     "1.0.2" => 1,
 183     "1.0.1" => 1,
 184     "1.0.0" => 1,
 185     "0.9.8" => 0,
 186 };
 187
 188 our %table = ();
 189 our %config = ();
 190 our %withargs = ();
 191 our $now_printing;      # set to current entry's name in print_table_entry
 192                         # (todo: right thing would be to encapsulate name
 193                         # into %target [class] and make print_table_entry
 194                         # a method)
 195
 196 # Forward declarations ###############################################
 197
 198 # read_config(filename)
 199 #
 200 # Reads a configuration file and populates %table with the contents
 201 # (which the configuration file places in %targets).
 202 sub read_config;
 203
 204 # resolve_config(target)
 205 #
 206 # Resolves all the late evaluations, inheritances and so on for the
 207 # chosen target and any target it inherits from.
 208 sub resolve_config;
 209
 210
 211 # Information collection #############################################
 212
 213 # Unified build supports separate build dir
 214 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 215 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 216 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 217
 218 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 219
 220 $config{sourcedir} = abs2rel($srcdir);
 221 $config{builddir} = abs2rel($blddir);
 222
 223 # Collect reconfiguration information if needed
 224 my @argvcopy=@ARGV;
 225
 226 if (grep /^reconf(igure)?$/, @argvcopy) {
 227     die "reconfiguring with other arguments present isn't supported"
 228         if scalar @argvcopy > 1;
 229     if (-f "./configdata.pm") {
 230         my $file = "./configdata.pm";
 231         unless (my $return = do $file) {
 232             die "couldn't parse $file: $@" if $@;
 233             die "couldn't do $file: $!"    unless defined $return;
 234             die "couldn't run $file"       unless $return;
 235         }
 236
 237         @argvcopy = defined($configdata::config{perlargv}) ?
 238             @{$configdata::config{perlargv}} : ();
 239         die "Incorrect data to reconfigure, please do a normal configuration\n"
 240             if (grep(/^reconf/,@argvcopy));
 241         $config{perlenv} = $configdata::config{perlenv} // {};
 242     } else {
 243         die "Insufficient data to reconfigure, please do a normal configuration\n";
 244     }
 245 }
 246
 247 $config{perlargv} = [ @argvcopy ];
 248
 249 # Collect version numbers
 250 $config{major} = "unknown";
 251 $config{minor} = "unknown";
 252 $config{patch} = "unknown";
 253 $config{prerelease} = "";
 254 $config{build_metadata} = "";
 255 $config{shlib_version} = "unknown";
 256
 257 collect_information(
 258     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 259     qr/#\s+define\s+OPENSSL_VERSION_MAJOR\s+(\d+)/ =>
 260         sub { $config{major} = $1; },
 261     qr/#\s+define\s+OPENSSL_VERSION_MINOR\s+(\d+)/ =>
 262         sub { $config{minor} = $1; },
 263     qr/#\s+define\s+OPENSSL_VERSION_PATCH\s+(\d+)/ =>
 264         sub { $config{patch} = $1; },
 265     qr/#\s+define\s+OPENSSL_VERSION_PRE_RELEASE\s+"((?:\\.|[^"])*)"/ =>
 266         sub { $config{prerelease} = $1; },
 267     qr/#\s+define\s+OPENSSL_VERSION_BUILD_METADATA\s+"((?:\\.|[^"])*)"/ =>
 268         sub { $config{build_metadata} = $1; },
 269     qr/#\s+define\s+OPENSSL_SHLIB_VERSION\s+([\d\.]+)/ =>
 270         sub { $config{shlib_version} = $1; },
 271     );
 272 die "erroneous version information in opensslv.h: ",
 273     "$config{major}.$config{minor}.$config{patch}, $config{shlib_version}\n"
 274     if ($config{major} eq "unknown"
 275             || $config{minor} eq "unknown"
 276             || $config{patch} eq "unknown"
 277             || $config{shlib_version} eq "unknown");
 278
 279 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 280 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 281
 282 # Collect target configurations
 283
 284 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 285 foreach (sort glob($pattern)) {
 286     &read_config($_);
 287 }
 288
 289 if (defined env($local_config_envname)) {
 290     if ($^O eq 'VMS') {
 291         # VMS environment variables are logical names,
 292         # which can be used as is
 293         $pattern = $local_config_envname . ':' . '*.conf';
 294     } else {
 295         $pattern = catfile(env($local_config_envname), '*.conf');
 296     }
 297
 298     foreach (sort glob($pattern)) {
 299         &read_config($_);
 300     }
 301 }
 302
 303 # Save away perl command information
 304 $config{perl_cmd} = $^X;
 305 $config{perl_version} = $Config{version};
 306 $config{perl_archname} = $Config{archname};
 307
 308 $config{prefix}="";
 309 $config{openssldir}="";
 310 $config{processor}="";
 311 $config{libdir}="";
 312 my $auto_threads=1;    # enable threads automatically? true by default
 313 my $default_ranlib;
 314
 315 # Known TLS and DTLS protocols
 316 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 317 my @dtls = qw(dtls1 dtls1_2);
 318
 319 # Explicitly known options that are possible to disable.  They can
 320 # be regexps, and will be used like this: /^no-${option}$/
 321 # For developers: keep it sorted alphabetically
 322
 323 my @disablables = (
 324     "ktls",
 325     "afalgeng",
 326     "aria",
 327     "asan",
 328     "asm",
 329     "async",
 330     "autoalginit",
 331     "autoerrinit",
 332     "autoload-config",
 333     "bf",
 334     "blake2",
 335     "camellia",
 336     "capieng",
 337     "cast",
 338     "chacha",
 339     "cmac",
 340     "cms",
 341     "comp",
 342     "crypto-mdebug",
 343     "crypto-mdebug-backtrace",
 344     "ct",
 345     "deprecated",
 346     "des",
 347     "devcryptoeng",
 348     "dgram",
 349     "dh",
 350     "dsa",
 351     "dso",
 352     "dtls",
 353     "dynamic-engine",
 354     "ec",
 355     "ec2m",
 356     "ecdh",
 357     "ecdsa",
 358     "ec_nistp_64_gcc_128",
 359     "egd",
 360     "engine",
 361     "err",
 362     "external-tests",
 363     "filenames",
 364     "fuzz-libfuzzer",
 365     "fuzz-afl",
 366     "gost",
 367     "heartbeats",
 368     "hw(-.+)?",
 369     "idea",
 370     "makedepend",
 371     "md2",
 372     "md4",
 373     "mdc2",
 374     "msan",
 375     "multiblock",
 376     "nextprotoneg",
 377     "pinshared",
 378     "ocb",
 379     "ocsp",
 380     "pic",
 381     "poly1305",
 382     "posix-io",
 383     "psk",
 384     "rc2",
 385     "rc4",
 386     "rc5",
 387     "rdrand",
 388     "rfc3779",
 389     "rmd160",
 390     "scrypt",
 391     "sctp",
 392     "seed",
 393     "shared",
 394     "siphash",
 395     "siv",
 396     "sm2",
 397     "sm3",
 398     "sm4",
 399     "sock",
 400     "srp",
 401     "srtp",
 402     "sse2",
 403     "ssl",
 404     "ssl-trace",
 405     "static-engine",
 406     "stdio",
 407     "tests",
 408     "threads",
 409     "tls",
 410     "ts",
 411     "ubsan",
 412     "ui-console",
 413     "unit-test",
 414     "whirlpool",
 415     "weak-ssl-ciphers",
 416     "zlib",
 417     "zlib-dynamic",
 418     );
 419 foreach my $proto ((@tls, @dtls))
 420         {
 421         push(@disablables, $proto);
 422         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 423         }
 424
 425 my %deprecated_disablables = (
 426     "ssl2" => undef,
 427     "buf-freelists" => undef,
 428     "ripemd" => "rmd160",
 429     "ui" => "ui-console",
 430     );
 431
 432 # All of the following are disabled by default:
 433
 434 our %disabled = ( # "what"         => "comment"
 435                   "asan"                => "default",
 436                   "crypto-mdebug"       => "default",
 437                   "crypto-mdebug-backtrace" => "default",
 438                   "devcryptoeng"        => "default",
 439                   "ec_nistp_64_gcc_128" => "default",
 440                   "egd"                 => "default",
 441                   "external-tests"      => "default",
 442                   "fuzz-libfuzzer"      => "default",
 443                   "fuzz-afl"            => "default",
 444                   "heartbeats"          => "default",
 445                   "md2"                 => "default",
 446                   "msan"                => "default",
 447                   "rc5"                 => "default",
 448                   "sctp"                => "default",
 449                   "ssl-trace"           => "default",
 450                   "ssl3"                => "default",
 451                   "ssl3-method"         => "default",
 452                   "ubsan"               => "default",
 453                   "unit-test"           => "default",
 454                   "weak-ssl-ciphers"    => "default",
 455                   "zlib"                => "default",
 456                   "zlib-dynamic"        => "default",
 457                   "ktls"                => "default",
 458                 );
 459
 460 # Note: => pair form used for aesthetics, not to truly make a hash table
 461 my @disable_cascades = (
 462     # "what"            => [ "cascade", ... ]
 463     sub { $config{processor} eq "386" }
 464                         => [ "sse2" ],
 465     "ssl"               => [ "ssl3" ],
 466     "ssl3-method"       => [ "ssl3" ],
 467     "zlib"              => [ "zlib-dynamic" ],
 468     "des"               => [ "mdc2" ],
 469     "ec"                => [ "ecdsa", "ecdh" ],
 470
 471     "dgram"             => [ "dtls", "sctp" ],
 472     "sock"              => [ "dgram" ],
 473     "dtls"              => [ @dtls ],
 474     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 475                         => [ "dtls" ],
 476
 477     "tls"               => [ @tls ],
 478     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 479                         => [ "tls" ],
 480
 481     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 482
 483     # Without DSO, we can't load dynamic engines, so don't build them dynamic
 484     "dso"               => [ "dynamic-engine" ],
 485
 486     # Without position independent code, there can be no shared libraries or DSOs
 487     "pic"               => [ "shared" ],
 488     "shared"            => [ "dynamic-engine" ],
 489     "engine"            => [ "afalgeng", "devcryptoeng" ],
 490
 491     # no-autoalginit is only useful when building non-shared
 492     "autoalginit"       => [ "shared", "apps" ],
 493
 494     "stdio"             => [ "apps", "capieng", "egd" ],
 495     "apps"              => [ "tests" ],
 496     "tests"             => [ "external-tests" ],
 497     "comp"              => [ "zlib" ],
 498     "ec"                => [ "tls1_3", "sm2" ],
 499     "sm3"               => [ "sm2" ],
 500     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 501
 502     sub { !$disabled{"msan"} } => [ "asm" ],
 503
 504     sub { $disabled{cmac}; } => [ "siv" ],
 505     );
 506
 507 # Avoid protocol support holes.  Also disable all versions below N, if version
 508 # N is disabled while N+1 is enabled.
 509 #
 510 my @list = (reverse @tls);
 511 while ((my $first, my $second) = (shift @list, shift @list)) {
 512     last unless @list;
 513     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 514                               => [ @list ] );
 515     unshift @list, $second;
 516 }
 517 my @list = (reverse @dtls);
 518 while ((my $first, my $second) = (shift @list, shift @list)) {
 519     last unless @list;
 520     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 521                               => [ @list ] );
 522     unshift @list, $second;
 523 }
 524
 525 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 526 # To remove something from %disabled, use "enable-foo".
 527 # For symmetry, "disable-foo" is a synonym for "no-foo".
 528
 529 &usage if ($#ARGV < 0);
 530
 531 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 532 # platform specific list separators.  Users from those platforms should
 533 # recognise those separators from how you set up the PATH to find executables.
 534 # The default is the Unix like separator, :, but as an exception, we also
 535 # support the space as separator.
 536 my $list_separator_re =
 537     { VMS           => qr/(?<!\^),/,
 538       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 539 # All the "make variables" we support
 540 # Some get pre-populated for the sake of backward compatibility
 541 # (we supported those before the change to "make variable" support.
 542 my %user = (
 543     AR          => env('AR'),
 544     ARFLAGS     => [],
 545     AS          => undef,
 546     ASFLAGS     => [],
 547     CC          => env('CC'),
 548     CFLAGS      => [],
 549     CXX         => env('CXX'),
 550     CXXFLAGS    => [],
 551     CPP         => undef,
 552     CPPFLAGS    => [],  # -D, -I, -Wp,
 553     CPPDEFINES  => [],  # Alternative for -D
 554     CPPINCLUDES => [],  # Alternative for -I
 555     CROSS_COMPILE => env('CROSS_COMPILE'),
 556     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 557     LD          => undef,
 558     LDFLAGS     => [],  # -L, -Wl,
 559     LDLIBS      => [],  # -l
 560     MT          => undef,
 561     MTFLAGS     => [],
 562     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 563     RANLIB      => env('RANLIB'),
 564     RC          => env('RC') || env('WINDRES'),
 565     RCFLAGS     => [],
 566     RM          => undef,
 567    );
 568 # Info about what "make variables" may be prefixed with the cross compiler
 569 # prefix.  This should NEVER mention any such variable with a list for value.
 570 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 571 # The same but for flags given as Configure options.  These are *additional*
 572 # input, as opposed to the VAR=string option that override the corresponding
 573 # config target attributes
 574 my %useradd = (
 575     CPPDEFINES  => [],
 576     CPPINCLUDES => [],
 577     CPPFLAGS    => [],
 578     CFLAGS      => [],
 579     CXXFLAGS    => [],
 580     LDFLAGS     => [],
 581     LDLIBS      => [],
 582    );
 583
 584 my %user_synonyms = (
 585     HASHBANGPERL=> 'PERL',
 586     RC          => 'WINDRES',
 587    );
 588
 589 # Some target attributes have been renamed, this is the translation table
 590 my %target_attr_translate =(
 591     ar          => 'AR',
 592     as          => 'AS',
 593     cc          => 'CC',
 594     cxx         => 'CXX',
 595     cpp         => 'CPP',
 596     hashbangperl => 'HASHBANGPERL',
 597     ld          => 'LD',
 598     mt          => 'MT',
 599     ranlib      => 'RANLIB',
 600     rc          => 'RC',
 601     rm          => 'RM',
 602    );
 603
 604 # Initialisers coming from 'config' scripts
 605 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 606 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 607 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 608 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 609 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 610 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 611 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 612
 613 $config{openssl_api_defines}=[];
 614 $config{openssl_sys_defines}=[];
 615 $config{openssl_feature_defines}=[];
 616 $config{options}="";
 617 $config{build_type} = "release";
 618 my $target="";
 619
 620 my %cmdvars = ();               # Stores FOO='blah' type arguments
 621 my %unsupported_options = ();
 622 my %deprecated_options = ();
 623 # If you change this, update apps/version.c
 624 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 625 my @seed_sources = ();
 626 while (@argvcopy)
 627         {
 628         $_ = shift @argvcopy;
 629
 630         # Support env variable assignments among the options
 631         if (m|^(\w+)=(.+)?$|)
 632                 {
 633                 $cmdvars{$1} = $2;
 634                 # Every time a variable is given as a configuration argument,
 635                 # it acts as a reset if the variable.
 636                 if (exists $user{$1})
 637                         {
 638                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 639                         }
 640                 #if (exists $useradd{$1})
 641                 #       {
 642                 #       $useradd{$1} = [];
 643                 #       }
 644                 next;
 645                 }
 646
 647         # VMS is a case insensitive environment, and depending on settings
 648         # out of our control, we may receive options uppercased.  Let's
 649         # downcase at least the part before any equal sign.
 650         if ($^O eq "VMS")
 651                 {
 652                 s/^([^=]*)/lc($1)/e;
 653                 }
 654
 655         # some people just can't read the instructions, clang people have to...
 656         s/^-no-(?!integrated-as)/no-/;
 657
 658         # rewrite some options in "enable-..." form
 659         s /^-?-?shared$/enable-shared/;
 660         s /^sctp$/enable-sctp/;
 661         s /^threads$/enable-threads/;
 662         s /^zlib$/enable-zlib/;
 663         s /^zlib-dynamic$/enable-zlib-dynamic/;
 664
 665         if (/^(no|disable|enable)-(.+)$/)
 666                 {
 667                 my $word = $2;
 668                 if (!exists $deprecated_disablables{$word}
 669                         && !grep { $word =~ /^${_}$/ } @disablables)
 670                         {
 671                         $unsupported_options{$_} = 1;
 672                         next;
 673                         }
 674                 }
 675         if (/^no-(.+)$/ || /^disable-(.+)$/)
 676                 {
 677                 foreach my $proto ((@tls, @dtls))
 678                         {
 679                         if ($1 eq "$proto-method")
 680                                 {
 681                                 $disabled{"$proto"} = "option($proto-method)";
 682                                 last;
 683                                 }
 684                         }
 685                 if ($1 eq "dtls")
 686                         {
 687                         foreach my $proto (@dtls)
 688                                 {
 689                                 $disabled{$proto} = "option(dtls)";
 690                                 }
 691                         $disabled{"dtls"} = "option(dtls)";
 692                         }
 693                 elsif ($1 eq "ssl")
 694                         {
 695                         # Last one of its kind
 696                         $disabled{"ssl3"} = "option(ssl)";
 697                         }
 698                 elsif ($1 eq "tls")
 699                         {
 700                         # XXX: Tests will fail if all SSL/TLS
 701                         # protocols are disabled.
 702                         foreach my $proto (@tls)
 703                                 {
 704                                 $disabled{$proto} = "option(tls)";
 705                                 }
 706                         }
 707                 elsif ($1 eq "static-engine")
 708                         {
 709                         delete $disabled{"dynamic-engine"};
 710                         }
 711                 elsif ($1 eq "dynamic-engine")
 712                         {
 713                         $disabled{"dynamic-engine"} = "option";
 714                         }
 715                 elsif (exists $deprecated_disablables{$1})
 716                         {
 717                         $deprecated_options{$_} = 1;
 718                         if (defined $deprecated_disablables{$1})
 719                                 {
 720                                 $disabled{$deprecated_disablables{$1}} = "option";
 721                                 }
 722                         }
 723                 else
 724                         {
 725                         $disabled{$1} = "option";
 726                         }
 727                 # No longer an automatic choice
 728                 $auto_threads = 0 if ($1 eq "threads");
 729                 }
 730         elsif (/^enable-(.+)$/)
 731                 {
 732                 if ($1 eq "static-engine")
 733                         {
 734                         $disabled{"dynamic-engine"} = "option";
 735                         }
 736                 elsif ($1 eq "dynamic-engine")
 737                         {
 738                         delete $disabled{"dynamic-engine"};
 739                         }
 740                 elsif ($1 eq "zlib-dynamic")
 741                         {
 742                         delete $disabled{"zlib"};
 743                         }
 744                 my $algo = $1;
 745                 delete $disabled{$algo};
 746
 747                 # No longer an automatic choice
 748                 $auto_threads = 0 if ($1 eq "threads");
 749                 }
 750         elsif (/^--strict-warnings$/)
 751                 {
 752                 $strict_warnings = 1;
 753                 }
 754         elsif (/^--debug$/)
 755                 {
 756                 $config{build_type} = "debug";
 757                 }
 758         elsif (/^--release$/)
 759                 {
 760                 $config{build_type} = "release";
 761                 }
 762         elsif (/^386$/)
 763                 { $config{processor}=386; }
 764         elsif (/^fips$/)
 765                 {
 766                 die "FIPS mode not supported\n";
 767                 }
 768         elsif (/^rsaref$/)
 769                 {
 770                 # No RSAref support any more since it's not needed.
 771                 # The check for the option is there so scripts aren't
 772                 # broken
 773                 }
 774         elsif (/^nofipscanistercheck$/)
 775                 {
 776                 die "FIPS mode not supported\n";
 777                 }
 778         elsif (/^[-+]/)
 779                 {
 780                 if (/^--prefix=(.*)$/)
 781                         {
 782                         $config{prefix}=$1;
 783                         die "Directory given with --prefix MUST be absolute\n"
 784                                 unless file_name_is_absolute($config{prefix});
 785                         }
 786                 elsif (/^--api=(.*)$/)
 787                         {
 788                         $config{api}=$1;
 789                         }
 790                 elsif (/^--libdir=(.*)$/)
 791                         {
 792                         $config{libdir}=$1;
 793                         }
 794                 elsif (/^--openssldir=(.*)$/)
 795                         {
 796                         $config{openssldir}=$1;
 797                         }
 798                 elsif (/^--with-zlib-lib=(.*)$/)
 799                         {
 800                         $withargs{zlib_lib}=$1;
 801                         }
 802                 elsif (/^--with-zlib-include=(.*)$/)
 803                         {
 804                         $withargs{zlib_include}=$1;
 805                         }
 806                 elsif (/^--with-fuzzer-lib=(.*)$/)
 807                         {
 808                         $withargs{fuzzer_lib}=$1;
 809                         }
 810                 elsif (/^--with-fuzzer-include=(.*)$/)
 811                         {
 812                         $withargs{fuzzer_include}=$1;
 813                         }
 814                 elsif (/^--with-rand-seed=(.*)$/)
 815                         {
 816                         foreach my $x (split(m|,|, $1))
 817                             {
 818                             die "Unknown --with-rand-seed choice $x\n"
 819                                 if ! grep { $x eq $_ } @known_seed_sources;
 820                             push @seed_sources, $x;
 821                             }
 822                         }
 823                 elsif (/^--cross-compile-prefix=(.*)$/)
 824                         {
 825                         $user{CROSS_COMPILE}=$1;
 826                         }
 827                 elsif (/^--config=(.*)$/)
 828                         {
 829                         read_config $1;
 830                         }
 831                 elsif (/^-l(.*)$/)
 832                         {
 833                         push @{$useradd{LDLIBS}}, $_;
 834                         }
 835                 elsif (/^-framework$/)
 836                         {
 837                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 838                         }
 839                 elsif (/^-L(.*)$/ or /^-Wl,/)
 840                         {
 841                         push @{$useradd{LDFLAGS}}, $_;
 842                         }
 843                 elsif (/^-rpath$/ or /^-R$/)
 844                         # -rpath is the OSF1 rpath flag
 845                         # -R is the old Solaris rpath flag
 846                         {
 847                         my $rpath = shift(@argvcopy) || "";
 848                         $rpath .= " " if $rpath ne "";
 849                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 850                         }
 851                 elsif (/^-static$/)
 852                         {
 853                         push @{$useradd{LDFLAGS}}, $_;
 854                         $disabled{"dso"} = "forced";
 855                         $disabled{"pic"} = "forced";
 856                         $disabled{"shared"} = "forced";
 857                         $disabled{"threads"} = "forced";
 858                         }
 859                 elsif (/^-D(.*)$/)
 860                         {
 861                         push @{$useradd{CPPDEFINES}}, $1;
 862                         }
 863                 elsif (/^-I(.*)$/)
 864                         {
 865                         push @{$useradd{CPPINCLUDES}}, $1;
 866                         }
 867                 elsif (/^-Wp,$/)
 868                         {
 869                         push @{$useradd{CPPFLAGS}}, $1;
 870                         }
 871                 else    # common if (/^[-+]/), just pass down...
 872                         {
 873                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 874                         push @{$useradd{CFLAGS}}, $_;
 875                         push @{$useradd{CXXFLAGS}}, $_;
 876                         }
 877                 }
 878         else
 879                 {
 880                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 881                 $target=$_;
 882                 }
 883         unless ($_ eq $target || /^no-/ || /^disable-/)
 884                 {
 885                 # "no-..." follows later after implied deactivations
 886                 # have been derived.  (Don't take this too seriously,
 887                 # we really only write OPTIONS to the Makefile out of
 888                 # nostalgia.)
 889
 890                 if ($config{options} eq "")
 891                         { $config{options} = $_; }
 892                 else
 893                         { $config{options} .= " ".$_; }
 894                 }
 895         }
 896
 897 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 898         die "***** Unsupported api compatibility level: $config{api}\n",
 899 }
 900
 901 if (keys %deprecated_options)
 902         {
 903         warn "***** Deprecated options: ",
 904                 join(", ", keys %deprecated_options), "\n";
 905         }
 906 if (keys %unsupported_options)
 907         {
 908         die "***** Unsupported options: ",
 909                 join(", ", keys %unsupported_options), "\n";
 910         }
 911
 912 # If any %useradd entry has been set, we must check that the "make
 913 # variables" haven't been set.  We start by checking of any %useradd entry
 914 # is set.
 915 if (grep { scalar @$_ > 0 } values %useradd) {
 916     # Hash of env / make variables names.  The possible values are:
 917     # 1 - "make vars"
 918     # 2 - %useradd entry set
 919     # 3 - both set
 920     my %detected_vars =
 921         map { my $v = 0;
 922               $v += 1 if $cmdvars{$_};
 923               $v += 2 if @{$useradd{$_}};
 924               $_ => $v }
 925         keys %useradd;
 926
 927     # If any of the corresponding "make variables" is set, we error
 928     if (grep { $_ & 1 } values %detected_vars) {
 929         my $names = join(', ', grep { $detected_vars{$_} > 0 }
 930                                sort keys %detected_vars);
 931         die <<"_____";
 932 ***** Mixing make variables and additional compiler/linker flags as
 933 ***** configure command line option is not permitted.
 934 ***** Affected make variables: $names
 935 _____
 936     }
 937 }
 938
 939 # Check through all supported command line variables to see if any of them
 940 # were set, and canonicalise the values we got.  If no compiler or linker
 941 # flag or anything else that affects %useradd was set, we also check the
 942 # environment for values.
 943 my $anyuseradd =
 944     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
 945 foreach (keys %user) {
 946     my $value = $cmdvars{$_};
 947     $value //= env($_) unless $anyuseradd;
 948     $value //=
 949         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
 950     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
 951         unless $anyuseradd;
 952
 953     if (defined $value) {
 954         if (ref $user{$_} eq 'ARRAY') {
 955             $user{$_} = [ split /$list_separator_re/, $value ];
 956         } elsif (!defined $user{$_}) {
 957             $user{$_} = $value;
 958         }
 959     }
 960 }
 961
 962 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
 963     && !$disabled{shared}
 964     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
 965     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
 966         "***** any of asan, msan or ubsan\n";
 967 }
 968
 969 my @tocheckfor = (keys %disabled);
 970 while (@tocheckfor) {
 971     my %new_tocheckfor = ();
 972     my @cascade_copy = (@disable_cascades);
 973     while (@cascade_copy) {
 974         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
 975         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
 976             foreach(grep { !defined($disabled{$_}) } @$descendents) {
 977                 $new_tocheckfor{$_} = 1; $disabled{$_} = "forced";
 978             }
 979         }
 980     }
 981     @tocheckfor = (keys %new_tocheckfor);
 982 }
 983
 984 our $die = sub { die @_; };
 985 if ($target eq "TABLE") {
 986     local $die = sub { warn @_; };
 987     foreach (sort keys %table) {
 988         print_table_entry($_, "TABLE");
 989     }
 990     exit 0;
 991 }
 992
 993 if ($target eq "LIST") {
 994     foreach (sort keys %table) {
 995         print $_,"\n" unless $table{$_}->{template};
 996     }
 997     exit 0;
 998 }
 999
1000 if ($target eq "HASH") {
1001     local $die = sub { warn @_; };
1002     print "%table = (\n";
1003     foreach (sort keys %table) {
1004         print_table_entry($_, "HASH");
1005     }
1006     exit 0;
1007 }
1008
1009 print "Configuring OpenSSL version $config{full_version} ";
1010 print "for target $target\n";
1011
1012 if (scalar(@seed_sources) == 0) {
1013     print "Using os-specific seed configuration\n";
1014     push @seed_sources, 'os';
1015 }
1016 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1017     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1018     warn <<_____ if scalar(@seed_sources) == 1;
1019
1020 ============================== WARNING ===============================
1021 You have selected the --with-rand-seed=none option, which effectively
1022 disables automatic reseeding of the OpenSSL random generator.
1023 All operations depending on the random generator such as creating keys
1024 will not work unless the random generator is seeded manually by the
1025 application.
1026
1027 Please read the 'Note on random number generation' section in the
1028 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1029 ============================== WARNING ===============================
1030
1031 _____
1032 }
1033 push @{$config{openssl_feature_defines}},
1034      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1035         @seed_sources;
1036
1037 # Backward compatibility?
1038 if ($target =~ m/^CygWin32(-.*)$/) {
1039     $target = "Cygwin".$1;
1040 }
1041
1042 # Support for legacy targets having a name starting with 'debug-'
1043 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1044 if ($d) {
1045     $config{build_type} = "debug";
1046
1047     # If we do not find debug-foo in the table, the target is set to foo.
1048     if (!$table{$target}) {
1049         $target = $t;
1050     }
1051 }
1052
1053 &usage if !$table{$target} || $table{$target}->{template};
1054
1055 $config{target} = $target;
1056 my %target = resolve_config($target);
1057
1058 foreach (keys %target_attr_translate) {
1059     $target{$target_attr_translate{$_}} = $target{$_}
1060         if $target{$_};
1061     delete $target{$_};
1062 }
1063
1064 %target = ( %{$table{DEFAULTS}}, %target );
1065
1066 # Make the flags to build DSOs the same as for shared libraries unless they
1067 # are already defined
1068 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1069 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1070 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1071 {
1072     my $shared_info_pl =
1073         catfile(dirname($0), "Configurations", "shared-info.pl");
1074     my %shared_info = read_eval_file($shared_info_pl);
1075     push @{$target{_conf_fname_int}}, $shared_info_pl;
1076     my $si = $target{shared_target};
1077     while (ref $si ne "HASH") {
1078         last if ! defined $si;
1079         if (ref $si eq "CODE") {
1080             $si = $si->();
1081         } else {
1082             $si = $shared_info{$si};
1083         }
1084     }
1085
1086     # Some of the 'shared_target' values don't have any entried in
1087     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1088     # template knows how to handle this.  That is currently the case for
1089     # Windows and VMS.
1090     if (defined $si) {
1091         # Just as above, copy certain shared_* attributes to the corresponding
1092         # module_ attribute unless the latter is already defined
1093         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1094         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1095         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1096         foreach (sort keys %$si) {
1097             $target{$_} = defined $target{$_}
1098                 ? add($si->{$_})->($target{$_})
1099                 : $si->{$_};
1100         }
1101     }
1102 }
1103
1104 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1105 $config{conf_files} = [ sort keys %conf_files ];
1106
1107 foreach my $feature (@{$target{disable}}) {
1108     if (exists $deprecated_disablables{$feature}) {
1109         warn "***** config $target disables deprecated feature $feature\n";
1110     } elsif (!grep { $feature eq $_ } @disablables) {
1111         die "***** config $target disables unknown feature $feature\n";
1112     }
1113     $disabled{$feature} = 'config';
1114 }
1115 foreach my $feature (@{$target{enable}}) {
1116     if ("default" eq ($disabled{$feature} // "")) {
1117         if (exists $deprecated_disablables{$feature}) {
1118             warn "***** config $target enables deprecated feature $feature\n";
1119         } elsif (!grep { $feature eq $_ } @disablables) {
1120             die "***** config $target enables unknown feature $feature\n";
1121         }
1122         delete $disabled{$feature};
1123     }
1124 }
1125
1126 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1127 $target{cxxflags}//=$target{cflags} if $target{CXX};
1128 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1129 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1130
1131 # Fill %config with values from %user, and in case those are undefined or
1132 # empty, use values from %target (acting as a default).
1133 foreach (keys %user) {
1134     my $ref_type = ref $user{$_};
1135
1136     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1137     # and a value that's to be coerced into that type.
1138     my $mkvalue = sub {
1139         my $type = shift;
1140         my $value = shift;
1141         my $undef_p = shift;
1142
1143         die "Too many arguments for \$mkvalue" if @_;
1144
1145         while (ref $value eq 'CODE') {
1146             $value = $value->();
1147         }
1148
1149         if ($type eq 'ARRAY') {
1150             return undef unless defined $value;
1151             return undef if ref $value ne 'ARRAY' && !$value;
1152             return undef if ref $value eq 'ARRAY' && !@$value;
1153             return [ $value ] unless ref $value eq 'ARRAY';
1154         }
1155         return undef unless $value;
1156         return $value;
1157     };
1158
1159     $config{$_} =
1160         $mkvalue->($ref_type, $user{$_})
1161         || $mkvalue->($ref_type, $target{$_});
1162     delete $config{$_} unless defined $config{$_};
1163 }
1164
1165 # Allow overriding the build file name
1166 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1167
1168 ######################################################################
1169 # Build up information for skipping certain directories depending on disabled
1170 # features, as well as setting up macros for disabled features.
1171
1172 # This is a tentative database of directories to skip.  Some entries may not
1173 # correspond to anything real, but that's ok, they will simply be ignored.
1174 # The actual processing of these entries is done in the build.info lookup
1175 # loop further down.
1176 #
1177 # The key is a Unix formated path in the source tree, the value is an index
1178 # into %disabled_info, so any existing path gets added to a corresponding
1179 # 'skipped' entry in there with the list of skipped directories.
1180 my %skipdir = ();
1181 my %disabled_info = ();         # For configdata.pm
1182 foreach my $what (sort keys %disabled) {
1183     $config{options} .= " no-$what";
1184
1185     if (!grep { $what eq $_ } ( 'dso', 'threads', 'shared', 'pic',
1186                                 'dynamic-engine', 'makedepend',
1187                                 'zlib-dynamic', 'zlib', 'sse2' )) {
1188         (my $WHAT = uc $what) =~ s|-|_|g;
1189         my $skipdir = $what;
1190
1191         # fix-up crypto/directory name(s)
1192         $skipdir = "ripemd" if $what eq "rmd160";
1193         $skipdir = "whrlpool" if $what eq "whirlpool";
1194
1195         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1196         push @{$config{openssl_feature_defines}}, $macro;
1197
1198         $skipdir{engines} = $what if $what eq 'engine';
1199         $skipdir{"crypto/$skipdir"} = $what
1200             unless $what eq 'async' || $what eq 'err';
1201     }
1202 }
1203
1204 # Make sure build_scheme is consistent.
1205 $target{build_scheme} = [ $target{build_scheme} ]
1206     if ref($target{build_scheme}) ne "ARRAY";
1207
1208 my ($builder, $builder_platform, @builder_opts) =
1209     @{$target{build_scheme}};
1210
1211 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1212                       $builder_platform."-checker.pm")) {
1213     my $checker_path = catfile($srcdir, "Configurations", $checker);
1214     if (-f $checker_path) {
1215         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1216             ? sub { warn $@; } : sub { die $@; };
1217         if (! do $checker_path) {
1218             if ($@) {
1219                 $fn->($@);
1220             } elsif ($!) {
1221                 $fn->($!);
1222             } else {
1223                 $fn->("The detected tools didn't match the platform\n");
1224             }
1225         }
1226         last;
1227     }
1228 }
1229
1230 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1231
1232 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1233         {
1234         push @{$config{cflags}}, "-mno-cygwin";
1235         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1236         push @{$config{shared_ldflag}}, "-mno-cygwin";
1237         }
1238
1239 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1240         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$user{CFLAGS}},
1241                                             @{$useradd{CFLAGS}})) {
1242         # minimally required architecture flags for assembly modules
1243         my $value;
1244         $value = '-mips2' if ($target =~ /mips32/);
1245         $value = '-mips3' if ($target =~ /mips64/);
1246         unshift @{$config{cflags}}, $value;
1247         unshift @{$config{cxxflags}}, $value if $config{CXX};
1248 }
1249
1250 # If threads aren't disabled, check how possible they are
1251 unless ($disabled{threads}) {
1252     if ($auto_threads) {
1253         # Enabled by default, disable it forcibly if unavailable
1254         if ($target{thread_scheme} eq "(unknown)") {
1255             $disabled{threads} = "unavailable";
1256         }
1257     } else {
1258         # The user chose to enable threads explicitly, let's see
1259         # if there's a chance that's possible
1260         if ($target{thread_scheme} eq "(unknown)") {
1261             # If the user asked for "threads" and we don't have internal
1262             # knowledge how to do it, [s]he is expected to provide any
1263             # system-dependent compiler options that are necessary.  We
1264             # can't truly check that the given options are correct, but
1265             # we expect the user to know what [s]He is doing.
1266             if (!@{$user{CFLAGS}} && !@{$useradd{CFLAGS}}
1267                     && !@{$user{CPPDEFINES}} && !@{$useradd{CPPDEFINES}}) {
1268                 die "You asked for multi-threading support, but didn't\n"
1269                     ,"provide any system-specific compiler options\n";
1270             }
1271         }
1272     }
1273 }
1274
1275 # If threads still aren't disabled, add a C macro to ensure the source
1276 # code knows about it.  Any other flag is taken care of by the configs.
1277 unless($disabled{threads}) {
1278     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1279 }
1280
1281 # With "deprecated" disable all deprecated features.
1282 if (defined($disabled{"deprecated"})) {
1283         $config{api} = $maxapi;
1284 }
1285
1286 my $no_shared_warn=0;
1287 if ($target{shared_target} eq "")
1288         {
1289         $no_shared_warn = 1
1290             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1291         $disabled{shared} = "no-shared-target";
1292         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
1293             "no-shared-target";
1294         }
1295
1296 if ($disabled{"dynamic-engine"}) {
1297         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1298         $config{dynamic_engines} = 0;
1299 } else {
1300         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1301         $config{dynamic_engines} = 1;
1302 }
1303
1304 unless ($disabled{asan}) {
1305     push @{$config{cflags}}, "-fsanitize=address";
1306     push @{$config{cxxflags}}, "-fsanitize=address" if $config{CXX};
1307 }
1308
1309 unless ($disabled{ubsan}) {
1310     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1311     # platforms.
1312     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1313     push @{$config{cxxflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all"
1314         if $config{CXX};
1315 }
1316
1317 unless ($disabled{msan}) {
1318   push @{$config{cflags}}, "-fsanitize=memory";
1319   push @{$config{cxxflags}}, "-fsanitize=memory" if $config{CXX};
1320 }
1321
1322 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1323         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1324     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1325     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1326 }
1327 #
1328 # Platform fix-ups
1329 #
1330
1331 # This saves the build files from having to check
1332 if ($disabled{pic})
1333         {
1334         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1335                     shared_defines shared_includes shared_ldflag
1336                     module_cflags module_cxxflags module_cppflags
1337                     module_defines module_includes module_lflags))
1338                 {
1339                 delete $config{$_};
1340                 $target{$_} = "";
1341                 }
1342         }
1343 else
1344         {
1345         push @{$config{lib_defines}}, "OPENSSL_PIC";
1346         }
1347
1348 if ($target{sys_id} ne "")
1349         {
1350         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1351         }
1352
1353 unless ($disabled{asm}) {
1354     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1355     push @{$config{lib_defines}}, "OPENSSL_CPUID_OBJ" if ($target{cpuid_asm_src} ne "mem_clr.c");
1356
1357     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1358
1359     # bn-586 is the only one implementing bn_*_part_words
1360     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1361     push @{$config{lib_defines}}, "OPENSSL_IA32_SSE2" if (!$disabled{sse2} && $target{bn_asm_src} =~ /86/);
1362
1363     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1364     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1365     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1366     push @{$config{lib_defines}}, "BN_DIV3W" if ($target{bn_asm_src} =~ /-div3w/);
1367
1368     if ($target{sha1_asm_src}) {
1369         push @{$config{lib_defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1370         push @{$config{lib_defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1371         push @{$config{lib_defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1372     }
1373     if ($target{keccak1600_asm_src} ne $table{DEFAULTS}->{keccak1600_asm_src}) {
1374         push @{$config{lib_defines}}, "KECCAK1600_ASM";
1375     }
1376     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1377         push @{$config{lib_defines}}, "RC4_ASM";
1378     }
1379     if ($target{md5_asm_src}) {
1380         push @{$config{lib_defines}}, "MD5_ASM";
1381     }
1382     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1383     if ($target{rmd160_asm_src}) {
1384         push @{$config{lib_defines}}, "RMD160_ASM";
1385     }
1386     if ($target{aes_asm_src}) {
1387         push @{$config{lib_defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1388         # aes-ctr.fake is not a real file, only indication that assembler
1389         # module implements AES_ctr32_encrypt...
1390         push @{$config{lib_defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1391         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1392         push @{$config{lib_defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1393         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($disabled{sse2});
1394         push @{$config{lib_defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1395         push @{$config{lib_defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1396     }
1397     if ($target{wp_asm_src} =~ /mmx/) {
1398         if ($config{processor} eq "386") {
1399             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1400         } elsif (!$disabled{"whirlpool"}) {
1401             push @{$config{lib_defines}}, "WHIRLPOOL_ASM";
1402         }
1403     }
1404     if ($target{modes_asm_src} =~ /ghash-/) {
1405         push @{$config{lib_defines}}, "GHASH_ASM";
1406     }
1407     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1408         push @{$config{lib_defines}}, "ECP_NISTZ256_ASM";
1409     }
1410     if ($target{ec_asm_src} =~ /x25519/) {
1411         push @{$config{lib_defines}}, "X25519_ASM";
1412     }
1413     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1414         push @{$config{lib_defines}}, "PADLOCK_ASM";
1415     }
1416     if ($target{poly1305_asm_src} ne "") {
1417         push @{$config{lib_defines}}, "POLY1305_ASM";
1418     }
1419 }
1420
1421 my %predefined = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1422
1423 # Check for makedepend capabilities.
1424 if (!$disabled{makedepend}) {
1425     if ($config{target} =~ /^(VC|vms)-/) {
1426         # For VC- and vms- targets, there's nothing more to do here.  The
1427         # functionality is hard coded in the corresponding build files for
1428         # cl (Windows) and CC/DECC (VMS).
1429     } elsif (($predefined{__GNUC__} // -1) >= 3
1430              && !($predefined{__APPLE_CC__} && !$predefined{__clang__})) {
1431         # We know that GNU C version 3 and up as well as all clang
1432         # versions support dependency generation, but Xcode did not
1433         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1434         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1435     } else {
1436         # In all other cases, we look for 'makedepend', and disable the
1437         # capability if not found.
1438         $config{makedepprog} = which('makedepend');
1439         $disabled{makedepend} = "unavailable" unless $config{makedepprog};
1440     }
1441 }
1442
1443 if (!$disabled{asm} && !$predefined{__MACH__} && $^O ne 'VMS') {
1444     # probe for -Wa,--noexecstack option...
1445     if ($predefined{__clang__}) {
1446         # clang has builtin assembler, which doesn't recognize --help,
1447         # but it apparently recognizes the option in question on all
1448         # supported platforms even when it's meaningless. In other words
1449         # probe would fail, but probed option always accepted...
1450         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1451     } else {
1452         my $cc = $config{CROSS_COMPILE}.$config{CC};
1453         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1454         while(<PIPE>) {
1455             if (m/--noexecstack/) {
1456                 push @{$config{cflags}}, "-Wa,--noexecstack";
1457                 last;
1458             }
1459         }
1460         close(PIPE);
1461         unlink("null.$$.o");
1462     }
1463 }
1464
1465 # Deal with bn_ops ###################################################
1466
1467 $config{bn_ll}                  =0;
1468 $config{export_var_as_fn}       =0;
1469 my $def_int="unsigned int";
1470 $config{rc4_int}                =$def_int;
1471 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1472
1473 my $count = 0;
1474 foreach (sort split(/\s+/,$target{bn_ops})) {
1475     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1476     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1477     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1478     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1479     ($config{b64l},$config{b64},$config{b32})
1480         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1481     ($config{b64l},$config{b64},$config{b32})
1482         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1483     ($config{b64l},$config{b64},$config{b32})
1484         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1485 }
1486 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1487     if $count > 1;
1488
1489
1490 # Hack cflags for better warnings (dev option) #######################
1491
1492 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1493 # a string and works as well on command lines.
1494 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1495                         @{$config{cflags}} ];
1496 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1497                           @{$config{cxxflags}} ] if $config{CXX};
1498
1499 $config{openssl_api_defines} = [
1500     "OPENSSL_MIN_API=".($apitable->{$config{api} // ""} // -1)
1501 ];
1502
1503 if ($strict_warnings)
1504         {
1505         my $wopt;
1506         my $gccver = $predefined{__GNUC__} // -1;
1507
1508         die "ERROR --strict-warnings requires gcc[>=4] or gcc-alike"
1509             unless $gccver >= 4;
1510         foreach $wopt (split /\s+/, $gcc_devteam_warn)
1511                 {
1512                 push @{$config{cflags}}, $wopt
1513                         unless grep { $_ eq $wopt } @{$config{cflags}};
1514                 push @{$config{cxxflags}}, $wopt
1515                         if ($config{CXX}
1516                             && !grep { $_ eq $wopt } @{$config{cxxflags}});
1517                 }
1518         if (defined($predefined{__clang__}))
1519                 {
1520                 foreach $wopt (split /\s+/, $clang_devteam_warn)
1521                         {
1522                         push @{$config{cflags}}, $wopt
1523                                 unless grep { $_ eq $wopt } @{$config{cflags}};
1524                         push @{$config{cxxflags}}, $wopt
1525                                 if ($config{CXX}
1526                                     && !grep { $_ eq $wopt } @{$config{cxxflags}});
1527                         }
1528                 }
1529         }
1530
1531 unless ($disabled{"crypto-mdebug-backtrace"})
1532         {
1533         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1534                 {
1535                 push @{$config{cflags}}, $wopt
1536                         unless grep { $_ eq $wopt } @{$config{cflags}};
1537                 push @{$config{cxxflags}}, $wopt
1538                         if ($config{CXX}
1539                             && !grep { $_ eq $wopt } @{$config{cxxflags}});
1540                 }
1541         if ($target =~ /^BSD-/)
1542                 {
1543                 push @{$config{ex_libs}}, "-lexecinfo";
1544                 }
1545         }
1546
1547 unless ($disabled{afalgeng}) {
1548     $config{afalgeng}="";
1549     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1550         my $minver = 4*10000 + 1*100 + 0;
1551         if ($config{CROSS_COMPILE} eq "") {
1552             my $verstr = `uname -r`;
1553             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1554             ($mi2) = $mi2 =~ /(\d+)/;
1555             my $ver = $ma*10000 + $mi1*100 + $mi2;
1556             if ($ver < $minver) {
1557                 $disabled{afalgeng} = "too-old-kernel";
1558             } else {
1559                 push @{$config{engdirs}}, "afalg";
1560             }
1561         } else {
1562             $disabled{afalgeng} = "cross-compiling";
1563         }
1564     } else {
1565         $disabled{afalgeng}  = "not-linux";
1566     }
1567 }
1568
1569 push @{$config{openssl_feature_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1570
1571 unless ($disabled{ktls}) {
1572     $config{ktls}="";
1573     if ($target =~ m/^linux/) {
1574         my $usr = "/usr/$config{cross_compile_prefix}";
1575         chop($usr);
1576         if ($config{cross_compile_prefix} eq "") {
1577             $usr = "/usr";
1578         }
1579         my $minver = (4 << 16) + (13 << 8) + 0;
1580         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1581
1582         if ($verstr[2] < $minver) {
1583             $disabled{ktls} = "too-old-kernel";
1584         }
1585     } else {
1586         $disabled{ktls}  = "not-linux";
1587     }
1588 }
1589
1590 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1591
1592 # Finish up %config by appending things the user gave us on the command line
1593 # apart from "make variables"
1594 foreach (keys %useradd) {
1595     # The must all be lists, so we assert that here
1596     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1597         unless ref $useradd{$_} eq 'ARRAY';
1598
1599     if (defined $config{$_}) {
1600         push @{$config{$_}}, @{$useradd{$_}};
1601     } else {
1602         $config{$_} = [ @{$useradd{$_}} ];
1603     }
1604 }
1605
1606 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1607
1608 # If we use the unified build, collect information from build.info files
1609 my %unified_info = ();
1610
1611 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1612 if ($builder eq "unified") {
1613     use with_fallback qw(Text::Template);
1614
1615     sub cleandir {
1616         my $base = shift;
1617         my $dir = shift;
1618         my $relativeto = shift || ".";
1619
1620         $dir = catdir($base,$dir) unless isabsolute($dir);
1621
1622         # Make sure the directories we're building in exists
1623         mkpath($dir);
1624
1625         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1626         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1627         return $res;
1628     }
1629
1630     sub cleanfile {
1631         my $base = shift;
1632         my $file = shift;
1633         my $relativeto = shift || ".";
1634
1635         $file = catfile($base,$file) unless isabsolute($file);
1636
1637         my $d = dirname($file);
1638         my $f = basename($file);
1639
1640         # Make sure the directories we're building in exists
1641         mkpath($d);
1642
1643         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1644         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1645         return $res;
1646     }
1647
1648     # Store the name of the template file we will build the build file from
1649     # in %config.  This may be useful for the build file itself.
1650     my @build_file_template_names =
1651         ( $builder_platform."-".$target{build_file}.".tmpl",
1652           $target{build_file}.".tmpl" );
1653     my @build_file_templates = ();
1654
1655     # First, look in the user provided directory, if given
1656     if (defined env($local_config_envname)) {
1657         @build_file_templates =
1658             map {
1659                 if ($^O eq 'VMS') {
1660                     # VMS environment variables are logical names,
1661                     # which can be used as is
1662                     $local_config_envname . ':' . $_;
1663                 } else {
1664                     catfile(env($local_config_envname), $_);
1665                 }
1666             }
1667             @build_file_template_names;
1668     }
1669     # Then, look in our standard directory
1670     push @build_file_templates,
1671         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1672           @build_file_template_names );
1673
1674     my $build_file_template;
1675     for $_ (@build_file_templates) {
1676         $build_file_template = $_;
1677         last if -f $build_file_template;
1678
1679         $build_file_template = undef;
1680     }
1681     if (!defined $build_file_template) {
1682         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1683     }
1684     $config{build_file_templates}
1685       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1686                     $blddir),
1687           $build_file_template,
1688           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1689                     $blddir) ];
1690
1691     my @build_dirs = ( [ ] );   # current directory
1692
1693     $config{build_infos} = [ ];
1694
1695     my %ordinals = ();
1696     while (@build_dirs) {
1697         my @curd = @{shift @build_dirs};
1698         my $sourced = catdir($srcdir, @curd);
1699         my $buildd = catdir($blddir, @curd);
1700
1701         my $unixdir = join('/', @curd);
1702         if (exists $skipdir{$unixdir}) {
1703             my $what = $skipdir{$unixdir};
1704             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1705             next;
1706         }
1707
1708         mkpath($buildd);
1709
1710         my $f = 'build.info';
1711         # The basic things we're trying to build
1712         my @programs = ();
1713         my @libraries = ();
1714         my @engines = ();
1715         my @scripts = ();
1716         my @intermediates = ();
1717
1718         my %attributes = ();
1719         my %sources = ();
1720         my %shared_sources = ();
1721         my %includes = ();
1722         my %defines = ();
1723         my %depends = ();
1724         my %generate = ();
1725
1726         # We want to detect configdata.pm in the source tree, so we
1727         # don't use it if the build tree is different.
1728         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1729
1730         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1731         my $template =
1732             Text::Template->new(TYPE => 'FILE',
1733                                 SOURCE => catfile($sourced, $f),
1734                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1735         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1736         my @text =
1737             split /^/m,
1738             $template->fill_in(HASH => { config => \%config,
1739                                          target => \%target,
1740                                          disabled => \%disabled,
1741                                          withargs => \%withargs,
1742                                          builddir => abs2rel($buildd, $blddir),
1743                                          sourcedir => abs2rel($sourced, $blddir),
1744                                          buildtop => abs2rel($blddir, $blddir),
1745                                          sourcetop => abs2rel($srcdir, $blddir) },
1746                                DELIMITERS => [ "{-", "-}" ]);
1747
1748         # The top item of this stack has the following values
1749         # -2 positive already run and we found ELSE (following ELSIF should fail)
1750         # -1 positive already run (skip until ENDIF)
1751         # 0 negatives so far (if we're at a condition, check it)
1752         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1753         # 2 positive ELSE (following ELSIF should fail)
1754         my @skip = ();
1755         collect_information(
1756             collect_from_array([ @text ],
1757                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1758                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1759             # Info we're looking for
1760             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1761             => sub {
1762                 if (! @skip || $skip[$#skip] > 0) {
1763                     push @skip, !! $1;
1764                 } else {
1765                     push @skip, -1;
1766                 }
1767             },
1768             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1769             => sub { die "ELSIF out of scope" if ! @skip;
1770                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1771                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1772                      $skip[$#skip] = !! $1
1773                          if $skip[$#skip] == 0; },
1774             qr/^\s*ELSE\s*$/
1775             => sub { die "ELSE out of scope" if ! @skip;
1776                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1777                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1778             qr/^\s*ENDIF\s*$/
1779             => sub { die "ENDIF out of scope" if ! @skip;
1780                      pop @skip; },
1781             qr/^\s*SUBDIRS\s*=\s*(.*)\s*$/
1782             => sub {
1783                 if (!@skip || $skip[$#skip] > 0) {
1784                     foreach (tokenize($1)) {
1785                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1786                     }
1787                 }
1788             },
1789             qr/^\s*PROGRAMS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1790             => sub {
1791                 if (!@skip || $skip[$#skip] > 0) {
1792                     my @a = tokenize($1, qr|\s*,\s*|);
1793                     my @p = tokenize($2);
1794                     push @programs, @p;
1795                     foreach my $a (@a) {
1796                         my $ak = $a;
1797                         my $av = 1;
1798                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1799                             $ak = $1;
1800                             $av = $2;
1801                         }
1802                         foreach my $p (@p) {
1803                             $attributes{$p}->{$ak} = $av;
1804                         }
1805                     }
1806                     push @programs, @p;
1807                 }
1808             },
1809             qr/^\s*LIBS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1810             => sub {
1811                 if (!@skip || $skip[$#skip] > 0) {
1812                     my @a = tokenize($1, qr|\s*,\s*|);
1813                     my @l = tokenize($2);
1814                     push @libraries, @l;
1815                     foreach my $a (@a) {
1816                         my $ak = $a;
1817                         my $av = 1;
1818                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1819                             $ak = $1;
1820                             $av = $2;
1821                         }
1822                         foreach my $l (@l) {
1823                             $attributes{$l}->{$ak} = $av;
1824                         }
1825                     }
1826                     push @libraries, @l;
1827                 }
1828             },
1829             qr/^\s*ENGINES(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1830             => sub {
1831                 if (!@skip || $skip[$#skip] > 0) {
1832                     my @a = tokenize($1, qr|\s*,\s*|);
1833                     my @e = tokenize($2);
1834                     push @engines, @e;
1835                     foreach my $a (@a) {
1836                         my $ak = $a;
1837                         my $av = 1;
1838                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1839                             $ak = $1;
1840                             $av = $2;
1841                         }
1842                         foreach my $e (@e) {
1843                             $attributes{$e}->{$ak} = $av;
1844                         }
1845                     }
1846                     push @engines, @e;
1847                 }
1848             },
1849             qr/^\s*SCRIPTS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1850             => sub {
1851                 if (!@skip || $skip[$#skip] > 0) {
1852                     my @a = tokenize($1, qr|\s*,\s*|);
1853                     my @s = tokenize($2);
1854                     push @scripts, @s;
1855                     foreach my $a (@a) {
1856                         my $ak = $a;
1857                         my $av = 1;
1858                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1859                             $ak = $1;
1860                             $av = $2;
1861                         }
1862                         foreach my $s (@s) {
1863                             $attributes{$s}->{$ak} = $av;
1864                         }
1865                     }
1866                     push @scripts, @s;
1867                 }
1868             },
1869
1870             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1871             => sub { push @{$ordinals{$1}}, tokenize($2)
1872                          if !@skip || $skip[$#skip] > 0 },
1873             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1874             => sub { push @{$sources{$1}}, tokenize($2)
1875                          if !@skip || $skip[$#skip] > 0 },
1876             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1877             => sub { push @{$shared_sources{$1}}, tokenize($2)
1878                          if !@skip || $skip[$#skip] > 0 },
1879             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1880             => sub { push @{$includes{$1}}, tokenize($2)
1881                          if !@skip || $skip[$#skip] > 0 },
1882             qr/^\s*DEFINE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1883             => sub { push @{$defines{$1}}, tokenize($2)
1884                          if !@skip || $skip[$#skip] > 0 },
1885             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1886             => sub { push @{$depends{$1}}, tokenize($2)
1887                          if !@skip || $skip[$#skip] > 0 },
1888             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1889             => sub { push @{$generate{$1}}, $2
1890                          if !@skip || $skip[$#skip] > 0 },
1891             qr/^\s*RENAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1892             => sub { warn "RENAME is no longer supported\n" },
1893              qr/^\s*SHARED_NAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1894             => sub { warn "SHARED_NAME is no longer supported\n" },
1895             qr/^\s*(?:#.*)?$/ => sub { },
1896             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1897             "BEFORE" => sub {
1898                 if ($buildinfo_debug) {
1899                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1900                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1901                 }
1902             },
1903             "AFTER" => sub {
1904                 if ($buildinfo_debug) {
1905                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1906                 }
1907             },
1908             );
1909         die "runaway IF?" if (@skip);
1910
1911         die <<"EOF" if scalar @engines and !$config{dynamic_engines};
1912 ENGINES can only be used if configured with 'dynamic-engine'.
1913 This is usually a fault in a build.info file.
1914 EOF
1915
1916         foreach (keys %attributes) {
1917             my $dest = $_;
1918             my $ddest = cleanfile($buildd, $_, $blddir);
1919             foreach (keys %{$attributes{$dest} // {}}) {
1920                 $unified_info{attributes}->{$ddest}->{$_} =
1921                     $attributes{$dest}->{$_};
1922             }
1923         }
1924
1925         {
1926             my %infos = ( programs  => [ @programs  ],
1927                           libraries => [ @libraries ],
1928                           engines   => [ @engines   ],
1929                           scripts   => [ @scripts   ] );
1930             foreach my $k (keys %infos) {
1931                 foreach (@{$infos{$k}}) {
1932                     my $item = cleanfile($buildd, $_, $blddir);
1933                     $unified_info{$k}->{$item} = 1;
1934                 }
1935             }
1936         }
1937
1938         # Check that we haven't defined any library as both shared and
1939         # explicitly static.  That is forbidden.
1940         my @doubles = ();
1941         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
1942             (my $l = $_) =~ s/\.a$//;
1943             push @doubles, $l if defined $unified_info{libraries}->{$l};
1944         }
1945         die "these libraries are both explicitly static and shared:\n  ",
1946             join(" ", @doubles), "\n"
1947             if @doubles;
1948
1949         foreach (keys %sources) {
1950             my $dest = $_;
1951             my $ddest = cleanfile($buildd, $_, $blddir);
1952             foreach (@{$sources{$dest}}) {
1953                 my $s = cleanfile($sourced, $_, $blddir);
1954
1955                 # If it isn't in the source tree, we assume it's generated
1956                 # in the build tree
1957                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
1958                     $s = cleanfile($buildd, $_, $blddir);
1959                 }
1960                 # We recognise C++, C and asm files
1961                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1962                     my $o = $_;
1963                     $o =~ s/\.[csS]$/.o/; # C and assembler
1964                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1965                     $o = cleanfile($buildd, $o, $blddir);
1966                     $unified_info{sources}->{$ddest}->{$o} = -1;
1967                     $unified_info{sources}->{$o}->{$s} = -1;
1968                 } elsif ($s =~ /\.rc$/) {
1969                     # We also recognise resource files
1970                     my $o = $_;
1971                     $o =~ s/\.rc$/.res/; # Resource configuration
1972                     my $o = cleanfile($buildd, $o, $blddir);
1973                     $unified_info{sources}->{$ddest}->{$o} = -1;
1974                     $unified_info{sources}->{$o}->{$s} = -1;
1975                 } else {
1976                     $unified_info{sources}->{$ddest}->{$s} = 1;
1977                 }
1978             }
1979         }
1980
1981         foreach (keys %shared_sources) {
1982             my $dest = $_;
1983             my $ddest = cleanfile($buildd, $_, $blddir);
1984             foreach (@{$shared_sources{$dest}}) {
1985                 my $s = cleanfile($sourced, $_, $blddir);
1986
1987                 # If it isn't in the source tree, we assume it's generated
1988                 # in the build tree
1989                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
1990                     $s = cleanfile($buildd, $_, $blddir);
1991                 }
1992
1993                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1994                     # We recognise C++, C and asm files
1995                     my $o = $_;
1996                     $o =~ s/\.[csS]$/.o/; # C and assembler
1997                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1998                     $o = cleanfile($buildd, $o, $blddir);
1999                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2000                     $unified_info{sources}->{$o}->{$s} = -1;
2001                 } elsif ($s =~ /\.rc$/) {
2002                     # We also recognise resource files
2003                     my $o = $_;
2004                     $o =~ s/\.rc$/.res/; # Resource configuration
2005                     my $o = cleanfile($buildd, $o, $blddir);
2006                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2007                     $unified_info{sources}->{$o}->{$s} = -1;
2008                 } elsif ($s =~ /\.ld$/) {
2009                     # We also recognise linker scripts (or corresponding)
2010                     # We know they are generated files
2011                     my $ld = cleanfile($buildd, $_, $blddir);
2012                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2013                 } else {
2014                     die "unrecognised source file type for shared library: $s\n";
2015                 }
2016             }
2017         }
2018
2019         foreach (keys %generate) {
2020             my $dest = $_;
2021             my $ddest = cleanfile($buildd, $_, $blddir);
2022             die "more than one generator for $dest: "
2023                     ,join(" ", @{$generate{$_}}),"\n"
2024                     if scalar @{$generate{$_}} > 1;
2025             my @generator = split /\s+/, $generate{$dest}->[0];
2026             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2027             $unified_info{generate}->{$ddest} = [ @generator ];
2028         }
2029
2030         foreach (keys %depends) {
2031             my $dest = $_;
2032             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2033
2034             # If the destination doesn't exist in source, it can only be
2035             # a generated file in the build tree.
2036             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2037                 $ddest = cleanfile($buildd, $_, $blddir);
2038             }
2039             foreach (@{$depends{$dest}}) {
2040                 my $d = cleanfile($sourced, $_, $blddir);
2041
2042                 # If we know it's generated, or assume it is because we can't
2043                 # find it in the source tree, we set file we depend on to be
2044                 # in the build tree rather than the source tree, and assume
2045                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2046                 # section or in the Makefile template.
2047                 if ($d eq $src_configdata
2048                     || ! -f $d
2049                     || (grep { $d eq $_ }
2050                         map { cleanfile($srcdir, $_, $blddir) }
2051                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2052                     $d = cleanfile($buildd, $_, $blddir);
2053                 }
2054                 # Take note if the file to depend on is being renamed
2055                 # Take extra care with files ending with .a, they should
2056                 # be treated without that extension, and the extension
2057                 # should be added back after treatment.
2058                 $d =~ /(\.a)?$/;
2059                 my $e = $1 // "";
2060                 $d = $`.$e;
2061                 $unified_info{depends}->{$ddest}->{$d} = 1;
2062             }
2063         }
2064
2065         foreach (keys %includes) {
2066             my $dest = $_;
2067             my $ddest = cleanfile($sourced, $_, $blddir);
2068
2069             # If the destination doesn't exist in source, it can only be
2070             # a generated file in the build tree.
2071             if ($ddest eq $src_configdata || ! -f $ddest) {
2072                 $ddest = cleanfile($buildd, $_, $blddir);
2073             }
2074             foreach (@{$includes{$dest}}) {
2075                 my $is = cleandir($sourced, $_, $blddir);
2076                 my $ib = cleandir($buildd, $_, $blddir);
2077                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2078                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2079                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2080                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2081             }
2082         }
2083
2084         foreach (keys %defines) {
2085             my $dest = $_;
2086             my $ddest = cleanfile($sourced, $_, $blddir);
2087
2088             # If the destination doesn't exist in source, it can only be
2089             # a generated file in the build tree.
2090             if (! -f $ddest) {
2091                 $ddest = cleanfile($buildd, $_, $blddir);
2092                 if ($unified_info{rename}->{$ddest}) {
2093                     $ddest = $unified_info{rename}->{$ddest};
2094                 }
2095             }
2096             foreach (@{$defines{$dest}}) {
2097                 m|^([^=]*)(=.*)?$|;
2098                 die "0 length macro name not permitted\n" if $1 eq "";
2099                 die "$1 defined more than once\n"
2100                     if defined $unified_info{defines}->{$ddest}->{$1};
2101                 $unified_info{defines}->{$ddest}->{$1} = $2;
2102             }
2103         }
2104     }
2105
2106     my $ordinals_text = join(', ', sort keys %ordinals);
2107     warn <<"EOF" if $ordinals_text;
2108
2109 WARNING: ORDINALS were specified for $ordinals_text
2110 They are ignored and should be replaced with a combination of GENERATE,
2111 DEPEND and SHARED_SOURCE.
2112 EOF
2113
2114     # Massage the result
2115
2116     # If we depend on a header file or a perl module, add an inclusion of
2117     # its directory to allow smoothe inclusion
2118     foreach my $dest (keys %{$unified_info{depends}}) {
2119         next if $dest eq "";
2120         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2121             next unless $d =~ /\.(h|pm)$/;
2122             my $i = dirname($d);
2123             my $spot =
2124                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2125                 ? 'build' : 'source';
2126             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2127                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2128         }
2129     }
2130
2131     # Go through all intermediary files and change their names to something that
2132     # reflects what they will be built for.  Note that for some source files,
2133     # this leads to duplicate object files because they are used multiple times.
2134     # the goal is to rename all object files according to this scheme:
2135     #    {productname}-{midfix}-{origobjname}.[o|res]
2136     # the {midfix} is a keyword indicating the type of product, which is mostly
2137     # valuable for libraries since they come in two forms.
2138     #
2139     # This also reorganises the {sources} and {shared_sources} so that the
2140     # former only contains ALL object files that are supposed to end up in
2141     # static libraries and programs, while the latter contains ALL object files
2142     # that are supposed to end up in shared libraries and DSOs.
2143     # The main reason for having two different source structures is to allow
2144     # the same name to be used for the static and the shared variants of a
2145     # library.
2146     {
2147         # Take copies so we don't get interference from added stuff
2148         my %unified_copy = ();
2149         foreach (('sources', 'shared_sources')) {
2150             $unified_copy{$_} = { %{$unified_info{$_}} }
2151                 if defined($unified_info{$_});
2152             delete $unified_info{$_};
2153         }
2154         foreach my $prodtype (('programs', 'libraries', 'engines', 'scripts')) {
2155             # $intent serves multi purposes:
2156             # - give a prefix for the new object files names
2157             # - in the case of libraries, rearrange the object files so static
2158             #   libraries use the 'sources' structure exclusively, while shared
2159             #   libraries use the 'shared_sources' structure exclusively.
2160             my $intent = {
2161                 programs  => { bin    => { src => [ 'sources' ],
2162                                            dst => 'sources' } },
2163                 libraries => { lib    => { src => [ 'sources' ],
2164                                            dst => 'sources' },
2165                                shlib  => { prodselect =>
2166                                                sub { grep !/\.a$/, @_ },
2167                                            src => [ 'sources',
2168                                                     'shared_sources' ],
2169                                            dst => 'shared_sources' } },
2170                 engines   => { dso    => { src => [ 'sources',
2171                                                     'shared_sources' ],
2172                                            dst => 'shared_sources' } },
2173                 scripts   => { script => { src => [ 'sources' ],
2174                                            dst => 'sources' } }
2175                } -> {$prodtype};
2176             foreach my $kind (keys %$intent) {
2177                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2178                              && $disabled{shared});
2179
2180                 my @src = @{$intent->{$kind}->{src}};
2181                 my $dst = $intent->{$kind}->{dst};
2182                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2183                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2184                     # %prod_sources has all applicable objects as keys, and
2185                     # their corresponding sources as values
2186                     my %prod_sources =
2187                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2188                         map { keys %{$unified_copy{$_}->{$prod}} }
2189                         @src;
2190                     foreach (keys %prod_sources) {
2191                         # Only affect object files and resource files,
2192                         # the others simply get a new value
2193                         # (+1 instead of -1)
2194                         if ($_ =~ /\.(o|res)$/) {
2195                             (my $prodname = $prod) =~ s|\.a$||;
2196                             my $newobj =
2197                                 catfile(dirname($_),
2198                                         basename($prodname)
2199                                             . '-' . $kind
2200                                             . '-' . basename($_));
2201                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2202                             foreach my $src (@{$prod_sources{$_}}) {
2203                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2204                             }
2205                             # Adjust dependencies
2206                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2207                                 $unified_info{depends}->{$_}->{$deps} = -1;
2208                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2209                             }
2210                             # Adjust includes
2211                             foreach my $k (('source', 'build')) {
2212                                 next unless
2213                                     defined($unified_info{includes}->{$_}->{$k});
2214                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2215                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2216                             }
2217                         } else {
2218                             $unified_info{$dst}->{$prod}->{$_} = 1;
2219                         }
2220                     }
2221                 }
2222             }
2223         }
2224     }
2225     # At this point, we have a number of sources with the value -1.  They
2226     # aren't part of the local build and are probably meant for a different
2227     # platform, and can therefore be cleaned away.  That happens when making
2228     # %unified_info more efficient below.
2229
2230     ### Make unified_info a bit more efficient
2231     # One level structures
2232     foreach (("programs", "libraries", "engines", "scripts")) {
2233         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2234     }
2235     # Two level structures
2236     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends")) {
2237         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2238             my @items =
2239                 sort
2240                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2241                 keys %{$unified_info{$l1}->{$l2}};
2242             if (@items) {
2243                 $unified_info{$l1}->{$l2} = [ @items ];
2244             } else {
2245                 delete $unified_info{$l1}->{$l2};
2246             }
2247         }
2248     }
2249     # Defines
2250     foreach my $dest (sort keys %{$unified_info{defines}}) {
2251         $unified_info{defines}->{$dest}
2252             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2253                 sort keys %{$unified_info{defines}->{$dest}} ];
2254     }
2255     # Includes
2256     foreach my $dest (sort keys %{$unified_info{includes}}) {
2257         if (defined($unified_info{includes}->{$dest}->{build})) {
2258             my @source_includes = ();
2259             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2260                 if defined($unified_info{includes}->{$dest}->{source});
2261             $unified_info{includes}->{$dest} =
2262                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2263             foreach my $inc (@source_includes) {
2264                 push @{$unified_info{includes}->{$dest}}, $inc
2265                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2266             }
2267         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2268             $unified_info{includes}->{$dest} =
2269                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2270         } else {
2271             delete $unified_info{includes}->{$dest};
2272         }
2273     }
2274
2275     # For convenience collect information regarding directories where
2276     # files are generated, those generated files and the end product
2277     # they end up in where applicable.  Then, add build rules for those
2278     # directories
2279     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2280                      "dso" => [ @{$unified_info{engines}} ],
2281                      "bin" => [ @{$unified_info{programs}} ],
2282                      "script" => [ @{$unified_info{scripts}} ] );
2283     foreach my $type (keys %loopinfo) {
2284         foreach my $product (@{$loopinfo{$type}}) {
2285             my %dirs = ();
2286             my $pd = dirname($product);
2287
2288             foreach (@{$unified_info{sources}->{$product} // []},
2289                      @{$unified_info{shared_sources}->{$product} // []}) {
2290                 my $d = dirname($_);
2291
2292                 # We don't want to create targets for source directories
2293                 # when building out of source
2294                 next if ($config{sourcedir} ne $config{builddir}
2295                              && $d =~ m|^\Q$config{sourcedir}\E|);
2296                 # We already have a "test" target, and the current directory
2297                 # is just silly to make a target for
2298                 next if $d eq "test" || $d eq ".";
2299
2300                 $dirs{$d} = 1;
2301                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2302                     if $d ne $pd;
2303             }
2304             foreach (keys %dirs) {
2305                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2306                     $product;
2307             }
2308         }
2309     }
2310 }
2311
2312 # For the schemes that need it, we provide the old *_obj configs
2313 # from the *_asm_obj ones
2314 foreach (grep /_(asm|aux)_src$/, keys %target) {
2315     my $src = $_;
2316     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2317     $target{$obj} = $target{$src};
2318     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2319     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2320 }
2321
2322 # Write down our configuration where it fits #########################
2323
2324 print "Creating configdata.pm\n";
2325 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2326 print OUT <<"EOF";
2327 #! $config{HASHBANGPERL}
2328
2329 package configdata;
2330
2331 use strict;
2332 use warnings;
2333
2334 use Exporter;
2335 #use vars qw(\@ISA \@EXPORT);
2336 our \@ISA = qw(Exporter);
2337 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables);
2338
2339 EOF
2340 print OUT "our %config = (\n";
2341 foreach (sort keys %config) {
2342     if (ref($config{$_}) eq "ARRAY") {
2343         print OUT "  ", $_, " => [ ", join(", ",
2344                                            map { quotify("perl", $_) }
2345                                            @{$config{$_}}), " ],\n";
2346     } elsif (ref($config{$_}) eq "HASH") {
2347         print OUT "  ", $_, " => {";
2348         if (scalar keys %{$config{$_}} > 0) {
2349             print OUT "\n";
2350             foreach my $key (sort keys %{$config{$_}}) {
2351                 print OUT "      ",
2352                     join(" => ",
2353                          quotify("perl", $key),
2354                          defined $config{$_}->{$key}
2355                              ? quotify("perl", $config{$_}->{$key})
2356                              : "undef");
2357                 print OUT ",\n";
2358             }
2359             print OUT "  ";
2360         }
2361         print OUT "},\n";
2362     } else {
2363         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2364     }
2365 }
2366 print OUT <<"EOF";
2367 );
2368
2369 EOF
2370 print OUT "our %target = (\n";
2371 foreach (sort keys %target) {
2372     if (ref($target{$_}) eq "ARRAY") {
2373         print OUT "  ", $_, " => [ ", join(", ",
2374                                            map { quotify("perl", $_) }
2375                                            @{$target{$_}}), " ],\n";
2376     } else {
2377         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2378     }
2379 }
2380 print OUT <<"EOF";
2381 );
2382
2383 EOF
2384 print OUT "our \%available_protocols = (\n";
2385 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2386 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2387 print OUT <<"EOF";
2388 );
2389
2390 EOF
2391 print OUT "our \@disablables = (\n";
2392 foreach (@disablables) {
2393     print OUT "  ", quotify("perl", $_), ",\n";
2394 }
2395 print OUT <<"EOF";
2396 );
2397
2398 EOF
2399 print OUT "our \%disabled = (\n";
2400 foreach (sort keys %disabled) {
2401     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2402 }
2403 print OUT <<"EOF";
2404 );
2405
2406 EOF
2407 print OUT "our %withargs = (\n";
2408 foreach (sort keys %withargs) {
2409     if (ref($withargs{$_}) eq "ARRAY") {
2410         print OUT "  ", $_, " => [ ", join(", ",
2411                                            map { quotify("perl", $_) }
2412                                            @{$withargs{$_}}), " ],\n";
2413     } else {
2414         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2415     }
2416 }
2417 print OUT <<"EOF";
2418 );
2419
2420 EOF
2421 if ($builder eq "unified") {
2422     my $recurse;
2423     $recurse = sub {
2424         my $indent = shift;
2425         foreach (@_) {
2426             if (ref $_ eq "ARRAY") {
2427                 print OUT " "x$indent, "[\n";
2428                 foreach (@$_) {
2429                     $recurse->($indent + 4, $_);
2430                 }
2431                 print OUT " "x$indent, "],\n";
2432             } elsif (ref $_ eq "HASH") {
2433                 my %h = %$_;
2434                 print OUT " "x$indent, "{\n";
2435                 foreach (sort keys %h) {
2436                     if (ref $h{$_} eq "") {
2437                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2438                     } else {
2439                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2440                         $recurse->($indent + 8, $h{$_});
2441                     }
2442                 }
2443                 print OUT " "x$indent, "},\n";
2444             } else {
2445                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2446             }
2447         }
2448     };
2449     print OUT "our %unified_info = (\n";
2450     foreach (sort keys %unified_info) {
2451         if (ref $unified_info{$_} eq "") {
2452             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2453         } else {
2454             print OUT " "x4, quotify("perl", $_), " =>\n";
2455             $recurse->(8, $unified_info{$_});
2456         }
2457     }
2458     print OUT <<"EOF";
2459 );
2460
2461 EOF
2462 }
2463 print OUT
2464     "# The following data is only used when this files is use as a script\n";
2465 print OUT "my \@makevars = (\n";
2466 foreach (sort keys %user) {
2467     print OUT "    '",$_,"',\n";
2468 }
2469 print OUT ");\n";
2470 print OUT "my \%disabled_info = (\n";
2471 foreach my $what (sort keys %disabled_info) {
2472     print OUT "    '$what' => {\n";
2473     foreach my $info (sort keys %{$disabled_info{$what}}) {
2474         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2475             print OUT "        $info => [ ",
2476                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2477                 " ],\n";
2478         } else {
2479             print OUT "        $info => '", $disabled_info{$what}->{$info},
2480                 "',\n";
2481         }
2482     }
2483     print OUT "    },\n";
2484 }
2485 print OUT ");\n";
2486 print OUT 'my @user_crossable = qw( ', join (' ', @user_crossable), " );\n";
2487 print OUT << 'EOF';
2488 # If run directly, we can give some answers, and even reconfigure
2489 unless (caller) {
2490     use Getopt::Long;
2491     use File::Spec::Functions;
2492     use File::Basename;
2493     use Pod::Usage;
2494
2495     my $here = dirname($0);
2496
2497     my $dump = undef;
2498     my $cmdline = undef;
2499     my $options = undef;
2500     my $target = undef;
2501     my $envvars = undef;
2502     my $makevars = undef;
2503     my $buildparams = undef;
2504     my $reconf = undef;
2505     my $verbose = undef;
2506     my $help = undef;
2507     my $man = undef;
2508     GetOptions('dump|d'                 => \$dump,
2509                'command-line|c'         => \$cmdline,
2510                'options|o'              => \$options,
2511                'target|t'               => \$target,
2512                'environment|e'          => \$envvars,
2513                'make-variables|m'       => \$makevars,
2514                'build-parameters|b'     => \$buildparams,
2515                'reconfigure|reconf|r'   => \$reconf,
2516                'verbose|v'              => \$verbose,
2517                'help'                   => \$help,
2518                'man'                    => \$man)
2519         or die "Errors in command line arguments\n";
2520
2521     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2522             || $buildparams || $reconf || $verbose || $help || $man) {
2523         print STDERR <<"_____";
2524 You must give at least one option.
2525 For more information, do '$0 --help'
2526 _____
2527         exit(2);
2528     }
2529
2530     if ($help) {
2531         pod2usage(-exitval => 0,
2532                   -verbose => 1);
2533     }
2534     if ($man) {
2535         pod2usage(-exitval => 0,
2536                   -verbose => 2);
2537     }
2538     if ($dump || $cmdline) {
2539         print "\nCommand line (with current working directory = $here):\n\n";
2540         print '    ',join(' ',
2541                           $config{PERL},
2542                           catfile($config{sourcedir}, 'Configure'),
2543                           @{$config{perlargv}}), "\n";
2544         print "\nPerl information:\n\n";
2545         print '    ',$config{perl_cmd},"\n";
2546         print '    ',$config{perl_version},' for ',$config{perl_archname},"\n";
2547     }
2548     if ($dump || $options) {
2549         my $longest = 0;
2550         my $longest2 = 0;
2551         foreach my $what (@disablables) {
2552             $longest = length($what) if $longest < length($what);
2553             $longest2 = length($disabled{$what})
2554                 if $disabled{$what} && $longest2 < length($disabled{$what});
2555         }
2556         print "\nEnabled features:\n\n";
2557         foreach my $what (@disablables) {
2558             print "    $what\n" unless $disabled{$what};
2559         }
2560         print "\nDisabled features:\n\n";
2561         foreach my $what (@disablables) {
2562             if ($disabled{$what}) {
2563                 print "    $what", ' ' x ($longest - length($what) + 1),
2564                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2565                 print $disabled_info{$what}->{macro}
2566                     if $disabled_info{$what}->{macro};
2567                 print ' (skip ',
2568                     join(', ', @{$disabled_info{$what}->{skipped}}),
2569                     ')'
2570                     if $disabled_info{$what}->{skipped};
2571                 print "\n";
2572             }
2573         }
2574     }
2575     if ($dump || $target) {
2576         print "\nConfig target attributes:\n\n";
2577         foreach (sort keys %target) {
2578             next if $_ =~ m|^_| || $_ eq 'template';
2579             my $quotify = sub {
2580                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2581             };
2582             print '    ', $_, ' => ';
2583             if (ref($target{$_}) eq "ARRAY") {
2584                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2585             } else {
2586                 print $quotify->($target{$_}), ",\n"
2587             }
2588         }
2589     }
2590     if ($dump || $envvars) {
2591         print "\nRecorded environment:\n\n";
2592         foreach (sort keys %{$config{perlenv}}) {
2593             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2594         }
2595     }
2596     if ($dump || $makevars) {
2597         print "\nMakevars:\n\n";
2598         foreach my $var (@makevars) {
2599             my $prefix = '';
2600             $prefix = $config{CROSS_COMPILE}
2601                 if grep { $var eq $_ } @user_crossable;
2602             $prefix //= '';
2603             print '    ',$var,' ' x (16 - length $var),'= ',
2604                 (ref $config{$var} eq 'ARRAY'
2605                  ? join(' ', @{$config{$var}})
2606                  : $prefix.$config{$var}),
2607                 "\n"
2608                 if defined $config{$var};
2609         }
2610
2611         my @buildfile = ($config{builddir}, $config{build_file});
2612         unshift @buildfile, $here
2613             unless file_name_is_absolute($config{builddir});
2614         my $buildfile = canonpath(catdir(@buildfile));
2615         print <<"_____";
2616
2617 NOTE: These variables only represent the configuration view.  The build file
2618 template may have processed these variables further, please have a look at the
2619 build file for more exact data:
2620     $buildfile
2621 _____
2622     }
2623     if ($dump || $buildparams) {
2624         my @buildfile = ($config{builddir}, $config{build_file});
2625         unshift @buildfile, $here
2626             unless file_name_is_absolute($config{builddir});
2627         print "\nbuild file:\n\n";
2628         print "    ", canonpath(catfile(@buildfile)),"\n";
2629
2630         print "\nbuild file templates:\n\n";
2631         foreach (@{$config{build_file_templates}}) {
2632             my @tmpl = ($_);
2633             unshift @tmpl, $here
2634                 unless file_name_is_absolute($config{sourcedir});
2635             print '    ',canonpath(catfile(@tmpl)),"\n";
2636         }
2637     }
2638     if ($reconf) {
2639         if ($verbose) {
2640             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2641             foreach (sort keys %{$config{perlenv}}) {
2642                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2643             }
2644         }
2645
2646         chdir $here;
2647         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2648     }
2649 }
2650
2651 1;
2652
2653 __END__
2654
2655 =head1 NAME
2656
2657 configdata.pm - configuration data for OpenSSL builds
2658
2659 =head1 SYNOPSIS
2660
2661 Interactive:
2662
2663   perl configdata.pm [options]
2664
2665 As data bank module:
2666
2667   use configdata;
2668
2669 =head1 DESCRIPTION
2670
2671 This module can be used in two modes, interactively and as a module containing
2672 all the data recorded by OpenSSL's Configure script.
2673
2674 When used interactively, simply run it as any perl script, with at least one
2675 option, and you will get the information you ask for.  See L</OPTIONS> below.
2676
2677 When loaded as a module, you get a few databanks with useful information to
2678 perform build related tasks.  The databanks are:
2679
2680     %config             Configured things.
2681     %target             The OpenSSL config target with all inheritances
2682                         resolved.
2683     %disabled           The features that are disabled.
2684     @disablables        The list of features that can be disabled.
2685     %withargs           All data given through --with-THING options.
2686     %unified_info       All information that was computed from the build.info
2687                         files.
2688
2689 =head1 OPTIONS
2690
2691 =over 4
2692
2693 =item B<--help>
2694
2695 Print a brief help message and exit.
2696
2697 =item B<--man>
2698
2699 Print the manual page and exit.
2700
2701 =item B<--dump> | B<-d>
2702
2703 Print all relevant configuration data.  This is equivalent to B<--command-line>
2704 B<--options> B<--target> B<--environment> B<--make-variables>
2705 B<--build-parameters>.
2706
2707 =item B<--command-line> | B<-c>
2708
2709 Print the current configuration command line.
2710
2711 =item B<--options> | B<-o>
2712
2713 Print the features, both enabled and disabled, and display defined macro and
2714 skipped directories where applicable.
2715
2716 =item B<--target> | B<-t>
2717
2718 Print the config attributes for this config target.
2719
2720 =item B<--environment> | B<-e>
2721
2722 Print the environment variables and their values at the time of configuration.
2723
2724 =item B<--make-variables> | B<-m>
2725
2726 Print the main make variables generated in the current configuration
2727
2728 =item B<--build-parameters> | B<-b>
2729
2730 Print the build parameters, i.e. build file and build file templates.
2731
2732 =item B<--reconfigure> | B<--reconf> | B<-r>
2733
2734 Redo the configuration.
2735
2736 =item B<--verbose> | B<-v>
2737
2738 Verbose output.
2739
2740 =back
2741
2742 =cut
2743
2744 EOF
2745 close(OUT);
2746 if ($builder_platform eq 'unix') {
2747     my $mode = (0755 & ~umask);
2748     chmod $mode, 'configdata.pm'
2749         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2750 }
2751
2752 my %builders = (
2753     unified => sub {
2754         print 'Creating ',$target{build_file},"\n";
2755         run_dofile(catfile($blddir, $target{build_file}),
2756                    @{$config{build_file_templates}});
2757     },
2758     );
2759
2760 $builders{$builder}->($builder_platform, @builder_opts);
2761
2762 $SIG{__DIE__} = $orig_death_handler;
2763
2764 print <<"EOF" if ($disabled{threads} eq "unavailable");
2765
2766 The library could not be configured for supporting multi-threaded
2767 applications as the compiler options required on this system are not known.
2768 See file INSTALL for details if you need multi-threading.
2769 EOF
2770
2771 print <<"EOF" if ($no_shared_warn);
2772
2773 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2774 platform, so we will pretend you gave the option 'no-pic', which also disables
2775 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2776 or position independent code, please let us know (but please first make sure
2777 you have tried with a current version of OpenSSL).
2778 EOF
2779
2780 print <<"EOF";
2781
2782 **********************************************************************
2783 ***                                                                ***
2784 ***   OpenSSL has been successfully configured                     ***
2785 ***                                                                ***
2786 ***   If you encounter a problem while building, please open an    ***
2787 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2788 ***   and include the output from the following command:           ***
2789 ***                                                                ***
2790 ***       perl configdata.pm --dump                                ***
2791 ***                                                                ***
2792 ***   (If you are new to OpenSSL, you might want to consult the    ***
2793 ***   'Troubleshooting' section in the INSTALL file first)         ***
2794 ***                                                                ***
2795 **********************************************************************
2796 EOF
2797
2798 exit(0);
2799
2800 ######################################################################
2801 #
2802 # Helpers and utility functions
2803 #
2804
2805 # Death handler, to print a helpful message in case of failure #######
2806 #
2807 sub death_handler {
2808     die @_ if $^S;              # To prevent the added message in eval blocks
2809     my $build_file = $target{build_file} // "build file";
2810     my @message = ( <<"_____", @_ );
2811
2812 Failure!  $build_file wasn't produced.
2813 Please read INSTALL and associated NOTES files.  You may also have to look over
2814 your available compiler tool chain or change your configuration.
2815
2816 _____
2817
2818     # Dying is terminal, so it's ok to reset the signal handler here.
2819     $SIG{__DIE__} = $orig_death_handler;
2820     die @message;
2821 }
2822
2823 # Configuration file reading #########################################
2824
2825 # Note: All of the helper functions are for lazy evaluation.  They all
2826 # return a CODE ref, which will return the intended value when evaluated.
2827 # Thus, whenever there's mention of a returned value, it's about that
2828 # intended value.
2829
2830 # Helper function to implement conditional inheritance depending on the
2831 # value of $disabled{asm}.  Used in inherit_from values as follows:
2832 #
2833 #      inherit_from => [ "template", asm("asm_tmpl") ]
2834 #
2835 sub asm {
2836     my @x = @_;
2837     sub {
2838         $disabled{asm} ? () : @x;
2839     }
2840 }
2841
2842 # Helper function to implement conditional value variants, with a default
2843 # plus additional values based on the value of $config{build_type}.
2844 # Arguments are given in hash table form:
2845 #
2846 #       picker(default => "Basic string: ",
2847 #              debug   => "debug",
2848 #              release => "release")
2849 #
2850 # When configuring with --debug, the resulting string will be
2851 # "Basic string: debug", and when not, it will be "Basic string: release"
2852 #
2853 # This can be used to create variants of sets of flags according to the
2854 # build type:
2855 #
2856 #       cflags => picker(default => "-Wall",
2857 #                        debug   => "-g -O0",
2858 #                        release => "-O3")
2859 #
2860 sub picker {
2861     my %opts = @_;
2862     return sub { add($opts{default} || (),
2863                      $opts{$config{build_type}} || ())->(); }
2864 }
2865
2866 # Helper function to combine several values of different types into one.
2867 # This is useful if you want to combine a string with the result of a
2868 # lazy function, such as:
2869 #
2870 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2871 #
2872 sub combine {
2873     my @stuff = @_;
2874     return sub { add(@stuff)->(); }
2875 }
2876
2877 # Helper function to implement conditional values depending on the value
2878 # of $disabled{threads}.  Can be used as follows:
2879 #
2880 #       cflags => combine("-Wall", threads("-pthread"))
2881 #
2882 sub threads {
2883     my @flags = @_;
2884     return sub { add($disabled{threads} ? () : @flags)->(); }
2885 }
2886
2887 sub shared {
2888     my @flags = @_;
2889     return sub { add($disabled{shared} ? () : @flags)->(); }
2890 }
2891
2892 our $add_called = 0;
2893 # Helper function to implement adding values to already existing configuration
2894 # values.  It handles elements that are ARRAYs, CODEs and scalars
2895 sub _add {
2896     my $separator = shift;
2897
2898     # If there's any ARRAY in the collection of values OR the separator
2899     # is undef, we will return an ARRAY of combined values, otherwise a
2900     # string of joined values with $separator as the separator.
2901     my $found_array = !defined($separator);
2902
2903     my @values =
2904         map {
2905             my $res = $_;
2906             while (ref($res) eq "CODE") {
2907                 $res = $res->();
2908             }
2909             if (defined($res)) {
2910                 if (ref($res) eq "ARRAY") {
2911                     $found_array = 1;
2912                     @$res;
2913                 } else {
2914                     $res;
2915                 }
2916             } else {
2917                 ();
2918             }
2919     } (@_);
2920
2921     $add_called = 1;
2922
2923     if ($found_array) {
2924         [ @values ];
2925     } else {
2926         join($separator, grep { defined($_) && $_ ne "" } @values);
2927     }
2928 }
2929 sub add_before {
2930     my $separator = " ";
2931     if (ref($_[$#_]) eq "HASH") {
2932         my $opts = pop;
2933         $separator = $opts->{separator};
2934     }
2935     my @x = @_;
2936     sub { _add($separator, @x, @_) };
2937 }
2938 sub add {
2939     my $separator = " ";
2940     if (ref($_[$#_]) eq "HASH") {
2941         my $opts = pop;
2942         $separator = $opts->{separator};
2943     }
2944     my @x = @_;
2945     sub { _add($separator, @_, @x) };
2946 }
2947
2948 sub read_eval_file {
2949     my $fname = shift;
2950     my $content;
2951     my @result;
2952
2953     open F, "< $fname" or die "Can't open '$fname': $!\n";
2954     {
2955         undef local $/;
2956         $content = <F>;
2957     }
2958     close F;
2959     {
2960         local $@;
2961
2962         @result = ( eval $content );
2963         warn $@ if $@;
2964     }
2965     return wantarray ? @result : $result[0];
2966 }
2967
2968 # configuration reader, evaluates the input file as a perl script and expects
2969 # it to fill %targets with target configurations.  Those are then added to
2970 # %table.
2971 sub read_config {
2972     my $fname = shift;
2973     my %targets;
2974
2975     {
2976         # Protect certain tables from tampering
2977         local %table = ();
2978
2979         %targets = read_eval_file($fname);
2980     }
2981     my %preexisting = ();
2982     foreach (sort keys %targets) {
2983         $preexisting{$_} = 1 if $table{$_};
2984     }
2985     die <<"EOF",
2986 The following config targets from $fname
2987 shadow pre-existing config targets with the same name:
2988 EOF
2989         map { "  $_\n" } sort keys %preexisting
2990         if %preexisting;
2991
2992
2993     # For each target, check that it's configured with a hash table.
2994     foreach (keys %targets) {
2995         if (ref($targets{$_}) ne "HASH") {
2996             if (ref($targets{$_}) eq "") {
2997                 warn "Deprecated target configuration for $_, ignoring...\n";
2998             } else {
2999                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3000             }
3001             delete $targets{$_};
3002         } else {
3003             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3004         }
3005     }
3006
3007     %table = (%table, %targets);
3008
3009 }
3010
3011 # configuration resolver.  Will only resolve all the lazy evaluation
3012 # codeblocks for the chosen target and all those it inherits from,
3013 # recursively
3014 sub resolve_config {
3015     my $target = shift;
3016     my @breadcrumbs = @_;
3017
3018 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3019
3020     if (grep { $_ eq $target } @breadcrumbs) {
3021         die "inherit_from loop!  target backtrace:\n  "
3022             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3023     }
3024
3025     if (!defined($table{$target})) {
3026         warn "Warning! target $target doesn't exist!\n";
3027         return ();
3028     }
3029     # Recurse through all inheritances.  They will be resolved on the
3030     # fly, so when this operation is done, they will all just be a
3031     # bunch of attributes with string values.
3032     # What we get here, though, are keys with references to lists of
3033     # the combined values of them all.  We will deal with lists after
3034     # this stage is done.
3035     my %combined_inheritance = ();
3036     if ($table{$target}->{inherit_from}) {
3037         my @inherit_from =
3038             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3039         foreach (@inherit_from) {
3040             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3041
3042             # 'template' is a marker that's considered private to
3043             # the config that had it.
3044             delete $inherited_config{template};
3045
3046             foreach (keys %inherited_config) {
3047                 if (!$combined_inheritance{$_}) {
3048                     $combined_inheritance{$_} = [];
3049                 }
3050                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3051             }
3052         }
3053     }
3054
3055     # We won't need inherit_from in this target any more, since we've
3056     # resolved all the inheritances that lead to this
3057     delete $table{$target}->{inherit_from};
3058
3059     # Now is the time to deal with those lists.  Here's the place to
3060     # decide what shall be done with those lists, all based on the
3061     # values of the target we're currently dealing with.
3062     # - If a value is a coderef, it will be executed with the list of
3063     #   inherited values as arguments.
3064     # - If the corresponding key doesn't have a value at all or is the
3065     #   empty string, the inherited value list will be run through the
3066     #   default combiner (below), and the result becomes this target's
3067     #   value.
3068     # - Otherwise, this target's value is assumed to be a string that
3069     #   will simply override the inherited list of values.
3070     my $default_combiner = add();
3071
3072     my %all_keys =
3073         map { $_ => 1 } (keys %combined_inheritance,
3074                          keys %{$table{$target}});
3075
3076     sub process_values {
3077         my $object    = shift;
3078         my $inherited = shift;  # Always a [ list ]
3079         my $target    = shift;
3080         my $entry     = shift;
3081
3082         $add_called = 0;
3083
3084         while(ref($object) eq "CODE") {
3085             $object = $object->(@$inherited);
3086         }
3087         if (!defined($object)) {
3088             return ();
3089         }
3090         elsif (ref($object) eq "ARRAY") {
3091             local $add_called;  # To make sure recursive calls don't affect it
3092             return [ map { process_values($_, $inherited, $target, $entry) }
3093                      @$object ];
3094         } elsif (ref($object) eq "") {
3095             return $object;
3096         } else {
3097             die "cannot handle reference type ",ref($object)
3098                 ," found in target ",$target," -> ",$entry,"\n";
3099         }
3100     }
3101
3102     foreach (sort keys %all_keys) {
3103         my $previous = $combined_inheritance{$_};
3104
3105         # Current target doesn't have a value for the current key?
3106         # Assign it the default combiner, the rest of this loop body
3107         # will handle it just like any other coderef.
3108         if (!exists $table{$target}->{$_}) {
3109             $table{$target}->{$_} = $default_combiner;
3110         }
3111
3112         $table{$target}->{$_} = process_values($table{$target}->{$_},
3113                                                $combined_inheritance{$_},
3114                                                $target, $_);
3115         unless(defined($table{$target}->{$_})) {
3116             delete $table{$target}->{$_};
3117         }
3118 #        if ($extra_checks &&
3119 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3120 #            warn "$_ got replaced in $target\n";
3121 #        }
3122     }
3123
3124     # Finally done, return the result.
3125     return %{$table{$target}};
3126 }
3127
3128 sub usage
3129         {
3130         print STDERR $usage;
3131         print STDERR "\npick os/compiler from:\n";
3132         my $j=0;
3133         my $i;
3134         my $k=0;
3135         foreach $i (sort keys %table)
3136                 {
3137                 next if $table{$i}->{template};
3138                 next if $i =~ /^debug/;
3139                 $k += length($i) + 1;
3140                 if ($k > 78)
3141                         {
3142                         print STDERR "\n";
3143                         $k=length($i);
3144                         }
3145                 print STDERR $i . " ";
3146                 }
3147         foreach $i (sort keys %table)
3148                 {
3149                 next if $table{$i}->{template};
3150                 next if $i !~ /^debug/;
3151                 $k += length($i) + 1;
3152                 if ($k > 78)
3153                         {
3154                         print STDERR "\n";
3155                         $k=length($i);
3156                         }
3157                 print STDERR $i . " ";
3158                 }
3159         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3160         exit(1);
3161         }
3162
3163 sub run_dofile
3164 {
3165     my $out = shift;
3166     my @templates = @_;
3167
3168     unlink $out || warn "Can't remove $out, $!"
3169         if -f $out;
3170     foreach (@templates) {
3171         die "Can't open $_, $!" unless -f $_;
3172     }
3173     my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
3174     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
3175     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
3176     system($cmd);
3177     exit 1 if $? != 0;
3178     rename("$out.new", $out) || die "Can't rename $out.new, $!";
3179 }
3180
3181 sub compiler_predefined {
3182     state %predefined;
3183     my $cc = shift;
3184
3185     return () if $^O eq 'VMS';
3186
3187     die 'compiler_predefined called without a compiler command'
3188         unless $cc;
3189
3190     if (! $predefined{$cc}) {
3191
3192         $predefined{$cc} = {};
3193
3194         # collect compiler pre-defines from gcc or gcc-alike...
3195         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3196         while (my $l = <PIPE>) {
3197             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3198             $predefined{$cc}->{$1} = $2 // '';
3199         }
3200         close(PIPE);
3201     }
3202
3203     return %{$predefined{$cc}};
3204 }
3205
3206 sub which
3207 {
3208     my ($name)=@_;
3209
3210     if (eval { require IPC::Cmd; 1; }) {
3211         IPC::Cmd->import();
3212         return scalar IPC::Cmd::can_run($name);
3213     } else {
3214         # if there is $directories component in splitpath,
3215         # then it's not something to test with $PATH...
3216         return $name if (File::Spec->splitpath($name))[1];
3217
3218         foreach (File::Spec->path()) {
3219             my $fullpath = catfile($_, "$name$target{exe_extension}");
3220             if (-f $fullpath and -x $fullpath) {
3221                 return $fullpath;
3222             }
3223         }
3224     }
3225 }
3226
3227 sub env
3228 {
3229     my $name = shift;
3230     my %opts = @_;
3231
3232     unless ($opts{cacheonly}) {
3233         # Note that if $ENV{$name} doesn't exist or is undefined,
3234         # $config{perlenv}->{$name} will be created with the value
3235         # undef.  This is intentional.
3236
3237         $config{perlenv}->{$name} = $ENV{$name}
3238             if ! exists $config{perlenv}->{$name};
3239     }
3240     return $config{perlenv}->{$name};
3241 }
3242
3243 # Configuration printer ##############################################
3244
3245 sub print_table_entry
3246 {
3247     local $now_printing = shift;
3248     my %target = resolve_config($now_printing);
3249     my $type = shift;
3250
3251     # Don't print the templates
3252     return if $target{template};
3253
3254     my @sequence = (
3255         "sys_id",
3256         "cpp",
3257         "cppflags",
3258         "defines",
3259         "includes",
3260         "cc",
3261         "cflags",
3262         "unistd",
3263         "ld",
3264         "lflags",
3265         "loutflag",
3266         "ex_libs",
3267         "bn_ops",
3268         "apps_aux_src",
3269         "cpuid_asm_src",
3270         "uplink_aux_src",
3271         "bn_asm_src",
3272         "ec_asm_src",
3273         "des_asm_src",
3274         "aes_asm_src",
3275         "bf_asm_src",
3276         "md5_asm_src",
3277         "cast_asm_src",
3278         "sha1_asm_src",
3279         "rc4_asm_src",
3280         "rmd160_asm_src",
3281         "rc5_asm_src",
3282         "wp_asm_src",
3283         "cmll_asm_src",
3284         "modes_asm_src",
3285         "padlock_asm_src",
3286         "chacha_asm_src",
3287         "poly1035_asm_src",
3288         "thread_scheme",
3289         "perlasm_scheme",
3290         "dso_scheme",
3291         "shared_target",
3292         "shared_cflag",
3293         "shared_defines",
3294         "shared_ldflag",
3295         "shared_rcflag",
3296         "shared_extension",
3297         "dso_extension",
3298         "obj_extension",
3299         "exe_extension",
3300         "ranlib",
3301         "ar",
3302         "arflags",
3303         "aroutflag",
3304         "rc",
3305         "rcflags",
3306         "rcoutflag",
3307         "mt",
3308         "mtflags",
3309         "mtinflag",
3310         "mtoutflag",
3311         "multilib",
3312         "build_scheme",
3313         );
3314
3315     if ($type eq "TABLE") {
3316         print "\n";
3317         print "*** $now_printing\n";
3318         foreach (@sequence) {
3319             if (ref($target{$_}) eq "ARRAY") {
3320                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3321             } else {
3322                 printf "\$%-12s = %s\n", $_, $target{$_};
3323             }
3324         }
3325     } elsif ($type eq "HASH") {
3326         my $largest =
3327             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3328         print "    '$now_printing' => {\n";
3329         foreach (@sequence) {
3330             if ($target{$_}) {
3331                 if (ref($target{$_}) eq "ARRAY") {
3332                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3333                 } else {
3334                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3335                 }
3336             }
3337         }
3338         print "    },\n";
3339     }
3340 }
3341
3342 # Utility routines ###################################################
3343
3344 # On VMS, if the given file is a logical name, File::Spec::Functions
3345 # will consider it an absolute path.  There are cases when we want a
3346 # purely syntactic check without checking the environment.
3347 sub isabsolute {
3348     my $file = shift;
3349
3350     # On non-platforms, we just use file_name_is_absolute().
3351     return file_name_is_absolute($file) unless $^O eq "VMS";
3352
3353     # If the file spec includes a device or a directory spec,
3354     # file_name_is_absolute() is perfectly safe.
3355     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3356
3357     # Here, we know the given file spec isn't absolute
3358     return 0;
3359 }
3360
3361 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3362 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3363 # realpath() requires that at least all path components except the last is an
3364 # existing directory.  On VMS, the last component of the directory spec must
3365 # exist.
3366 sub absolutedir {
3367     my $dir = shift;
3368
3369     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3370     # will return the volume name for the device, no matter what.  Also,
3371     # it will return an incorrect directory spec if the argument is a
3372     # directory that doesn't exist.
3373     if ($^O eq "VMS") {
3374         return rel2abs($dir);
3375     }
3376
3377     # We use realpath() on Unix, since no other will properly clean out
3378     # a directory spec.
3379     use Cwd qw/realpath/;
3380
3381     return realpath($dir);
3382 }
3383
3384 sub quotify {
3385     my %processors = (
3386         perl    => sub { my $x = shift;
3387                          $x =~ s/([\\\$\@"])/\\$1/g;
3388                          return '"'.$x.'"'; },
3389         maybeshell => sub { my $x = shift;
3390                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3391                             if ($x ne $y || $x =~ m|\s|) {
3392                                 return '"'.$y.'"';
3393                             } else {
3394                                 return $x;
3395                             }
3396                         },
3397         );
3398     my $for = shift;
3399     my $processor =
3400         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3401
3402     return map { $processor->($_); } @_;
3403 }
3404
3405 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3406 # $filename is a file name to read from
3407 # $line_concat_cond_re is a regexp detecting a line continuation ending
3408 # $line_concat is a CODEref that takes care of concatenating two lines
3409 sub collect_from_file {
3410     my $filename = shift;
3411     my $line_concat_cond_re = shift;
3412     my $line_concat = shift;
3413
3414     open my $fh, $filename || die "unable to read $filename: $!\n";
3415     return sub {
3416         my $saved_line = "";
3417         $_ = "";
3418         while (<$fh>) {
3419             s|\R$||;
3420             if (defined $line_concat) {
3421                 $_ = $line_concat->($saved_line, $_);
3422                 $saved_line = "";
3423             }
3424             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3425                 $saved_line = $_;
3426                 next;
3427             }
3428             return $_;
3429         }
3430         die "$filename ending with continuation line\n" if $_;
3431         close $fh;
3432         return undef;
3433     }
3434 }
3435
3436 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3437 # $array is an ARRAYref of lines
3438 # $line_concat_cond_re is a regexp detecting a line continuation ending
3439 # $line_concat is a CODEref that takes care of concatenating two lines
3440 sub collect_from_array {
3441     my $array = shift;
3442     my $line_concat_cond_re = shift;
3443     my $line_concat = shift;
3444     my @array = (@$array);
3445
3446     return sub {
3447         my $saved_line = "";
3448         $_ = "";
3449         while (defined($_ = shift @array)) {
3450             s|\R$||;
3451             if (defined $line_concat) {
3452                 $_ = $line_concat->($saved_line, $_);
3453                 $saved_line = "";
3454             }
3455             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3456                 $saved_line = $_;
3457                 next;
3458             }
3459             return $_;
3460         }
3461         die "input text ending with continuation line\n" if $_;
3462         return undef;
3463     }
3464 }
3465
3466 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3467 # $lineiterator is a CODEref that delivers one line at a time.
3468 # All following arguments are regex/CODEref pairs, where the regexp detects a
3469 # line and the CODEref does something with the result of the regexp.
3470 sub collect_information {
3471     my $lineiterator = shift;
3472     my %collectors = @_;
3473
3474     while(defined($_ = $lineiterator->())) {
3475         s|\R$||;
3476         my $found = 0;
3477         if ($collectors{"BEFORE"}) {
3478             $collectors{"BEFORE"}->($_);
3479         }
3480         foreach my $re (keys %collectors) {
3481             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3482                 $collectors{$re}->($lineiterator);
3483                 $found = 1;
3484             };
3485         }
3486         if ($collectors{"OTHERWISE"}) {
3487             $collectors{"OTHERWISE"}->($lineiterator, $_)
3488                 unless $found || !defined $collectors{"OTHERWISE"};
3489         }
3490         if ($collectors{"AFTER"}) {
3491             $collectors{"AFTER"}->($_);
3492         }
3493     }
3494 }
3495
3496 # tokenize($line)
3497 # tokenize($line,$separator)
3498 # $line is a line of text to split up into tokens
3499 # $separator [optional] is a regular expression that separates the tokens,
3500 # the default being spaces.  Do not use quotes of any kind as separators,
3501 # that will give undefined results.
3502 # Returns a list of tokens.
3503 #
3504 # Tokens are divided by separator (spaces by default).  If the tokens include
3505 # the separators, they have to be quoted with single or double quotes.
3506 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3507 # with backslash.
3508 # Basically, the same quoting rules apply for " and ' as in any
3509 # Unix shell.
3510 sub tokenize {
3511     my $line = my $debug_line = shift;
3512     my $separator = shift // qr|\s+|;
3513     my @result = ();
3514
3515     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3516         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3517     }
3518
3519     while ($line =~ s|^${separator}||, $line ne "") {
3520         my $token = "";
3521     again:
3522         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3523         $token .= $1;
3524         $line = $2.$';
3525
3526         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3527             $token .= $1;
3528             $line = $';
3529             goto again;
3530         } elsif ($line =~ m/^'([^']*)'/) {
3531             $token .= $1;
3532             $line = $';
3533             goto again;
3534         }
3535         push @result, $token;
3536     }
3537
3538     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3539         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3540         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3541     }
3542     return @result;
3543 }