Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::fallback "$FindBin::Bin/external/perl/MODULES.txt";
  21 use OpenSSL::Glob;
  22 use OpenSSL::Template;
  23
  24 # see INSTALL for instructions.
  25
  26 my $orig_death_handler = $SIG{__DIE__};
  27 $SIG{__DIE__} = \&death_handler;
  28
  29 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  30
  31 # Options:
  32 #
  33 # --config      add the given configuration file, which will be read after
  34 #               any "Configurations*" files that are found in the same
  35 #               directory as this script.
  36 # --prefix      prefix for the OpenSSL installation, which includes the
  37 #               directories bin, lib, include, share/man, share/doc/openssl
  38 #               This becomes the value of INSTALLTOP in Makefile
  39 #               (Default: /usr/local)
  40 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  41 #               If it's a relative directory, it will be added on the directory
  42 #               given with --prefix.
  43 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  44 #               (Default: PREFIX/ssl)
  45 #
  46 # --cross-compile-prefix Add specified prefix to binutils components.
  47 #
  48 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0
  49 #               Define the public APIs as they were for that version
  50 #               including patch releases.  If 'no-deprecated' is also
  51 #               given, do not compile support for interfaces deprecated
  52 #               up to and including the specified OpenSSL version.
  53 #
  54 # no-hw-xxx     do not compile support for specific crypto hardware.
  55 #               Generic OpenSSL-style methods relating to this support
  56 #               are always compiled but return NULL if the hardware
  57 #               support isn't compiled.
  58 # no-hw         do not compile support for any crypto hardware.
  59 # [no-]threads  [don't] try to create a library that is suitable for
  60 #               multithreaded applications (default is "threads" if we
  61 #               know how to do it)
  62 # [no-]shared   [don't] try to create shared libraries when supported.
  63 # [no-]pic      [don't] try to build position independent code when supported.
  64 #               If disabled, it also disables shared and dynamic-engine.
  65 # no-asm        do not use assembler
  66 # no-egd        do not compile support for the entropy-gathering daemon APIs
  67 # [no-]zlib     [don't] compile support for zlib compression.
  68 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  69 #               library and will be loaded in run-time by the OpenSSL library.
  70 # sctp          include SCTP support
  71 # no-uplink     Don't build support for UPLINK interface.
  72 # enable-weak-ssl-ciphers
  73 #               Enable weak ciphers that are disabled by default.
  74 # 386           generate 80386 code in assembly modules
  75 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  76 #               mentioned '386' option implies this one
  77 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  78 # -<xxx> +<xxx> All options which are unknown to the 'Configure' script are
  79 # /<xxx>        passed through to the compiler. Unix-style options beginning
  80 #               with a '-' or '+' are recognized, as well as Windows-style
  81 #               options beginning with a '/'. If the option contains arguments
  82 #               separated by spaces, then the URL-style notation %20 can be
  83 #               used for the space character in order to avoid having to quote
  84 #               the option. For example, -opt%20arg gets expanded to -opt arg.
  85 #               In fact, any ASCII character can be encoded as %xx using its
  86 #               hexadecimal encoding.
  87 # -static       while -static is also a pass-through compiler option (and
  88 #               as such is limited to environments where it's actually
  89 #               meaningful), it triggers a number configuration options,
  90 #               namely no-pic, no-shared and no-threads. It is
  91 #               argued that the only reason to produce statically linked
  92 #               binaries (and in context it means executables linked with
  93 #               -static flag, and not just executables linked with static
  94 #               libcrypto.a) is to eliminate dependency on specific run-time,
  95 #               a.k.a. libc version. The mentioned config options are meant
  96 #               to achieve just that. Unfortunately on Linux it's impossible
  97 #               to eliminate the dependency completely for openssl executable
  98 #               because of getaddrinfo and gethostbyname calls, which can
  99 #               invoke dynamically loadable library facility anyway to meet
 100 #               the lookup requests. For this reason on Linux statically
 101 #               linked openssl executable has rather debugging value than
 102 #               production quality.
 103 #
 104 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
 105 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
 106 # Following are set automatically by this script
 107 #
 108 # MD5_ASM       use some extra md5 assembler,
 109 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 110 # RMD160_ASM    use some extra ripemd160 assembler,
 111 # SHA256_ASM    sha256_block is implemented in assembler
 112 # SHA512_ASM    sha512_block is implemented in assembler
 113 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 114
 115 # Minimum warning options... any contributions to OpenSSL should at least
 116 # get past these.  Note that we only use these with C compilers, not with
 117 # C++ compilers.
 118
 119 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 120 # -DPEDANTIC complements -pedantic and is meant to mask code that
 121 # is not strictly standard-compliant and/or implementation-specific,
 122 # e.g. inline assembly, disregards to alignment requirements, such
 123 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 124 # to be used even in sanitized builds, because sanitizer too is
 125 # supposed to and does take notice of non-standard behaviour. Then
 126 # -pedantic with pre-C9x compiler would also complain about 'long
 127 # long' not being supported. As 64-bit algorithms are common now,
 128 # it grew impossible to resolve this without sizeable additional
 129 # code, so we just tell compiler to be pedantic about everything
 130 # but 'long long' type.
 131
 132 my @gcc_devteam_warn = qw(
 133     -DDEBUG_UNUSED
 134     -DPEDANTIC -pedantic -Wno-long-long
 135     -Wall
 136     -Wextra
 137     -Wno-unused-parameter
 138     -Wno-missing-field-initializers
 139     -Wswitch
 140     -Wsign-compare
 141     -Wshadow
 142     -Wformat
 143     -Wtype-limits
 144     -Wundef
 145     -Werror
 146     -Wmissing-prototypes
 147     -Wstrict-prototypes
 148 );
 149
 150 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 151 # TODO(openssl-team): fix problems and investigate if (at least) the
 152 # following warnings can also be enabled:
 153 #       -Wcast-align
 154 #       -Wunreachable-code -- no, too ugly/compiler-specific
 155 #       -Wlanguage-extension-token -- no, we use asm()
 156 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 157 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 158 my @clang_devteam_warn = qw(
 159     -Wno-unknown-warning-option
 160     -Wswitch-default
 161     -Wno-parentheses-equality
 162     -Wno-language-extension-token
 163     -Wno-extended-offsetof
 164     -Wconditional-uninitialized
 165     -Wincompatible-pointer-types-discards-qualifiers
 166     -Wmissing-variable-declarations
 167 );
 168
 169 my @cl_devteam_warn = qw(
 170     /WX
 171 );
 172
 173 my $strict_warnings = 0;
 174
 175 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 176 # which would cover all BSD flavors. -pthread applies to them all,
 177 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 178 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 179 # which has to be accompanied by explicit -D_THREAD_SAFE and
 180 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 181 # seems to be sufficient?
 182 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 183
 184 #
 185 # API compatibility name to version number mapping.
 186 #
 187 my $apitable = {
 188     # This table expresses when API additions or changes can occur.
 189     # The numbering used changes from 3.0 and on because we updated
 190     # (solidified) our version numbering scheme at that point.
 191
 192     # From 3.0 and on, we internalise the given version number in dedcimal
 193     # as MAJOR * 10000 + MINOR * 100 + 0
 194     "3.0.0" => 30000,
 195     "3.0"   => 30000,
 196
 197     # Note that before 3.0, we didn't have the same version number scheme.
 198     # Still, the numbering we use here covers what we need.
 199     "1.1.1" => 10101,
 200     "1.1.0" => 10100,
 201     "1.0.2" => 10002,
 202     "1.0.1" => 10001,
 203     "1.0.0" => 10000,
 204     "0.9.8" =>   908,
 205 };
 206
 207 our %table = ();
 208 our %config = ();
 209 our %withargs = ();
 210 our $now_printing;      # set to current entry's name in print_table_entry
 211                         # (todo: right thing would be to encapsulate name
 212                         # into %target [class] and make print_table_entry
 213                         # a method)
 214
 215 # Forward declarations ###############################################
 216
 217 # read_config(filename)
 218 #
 219 # Reads a configuration file and populates %table with the contents
 220 # (which the configuration file places in %targets).
 221 sub read_config;
 222
 223 # resolve_config(target)
 224 #
 225 # Resolves all the late evaluations, inheritances and so on for the
 226 # chosen target and any target it inherits from.
 227 sub resolve_config;
 228
 229
 230 # Information collection #############################################
 231
 232 # Unified build supports separate build dir
 233 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 234 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 235 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 236
 237 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 238
 239 $config{sourcedir} = abs2rel($srcdir);
 240 $config{builddir} = abs2rel($blddir);
 241
 242 # Collect reconfiguration information if needed
 243 my @argvcopy=@ARGV;
 244
 245 if (grep /^reconf(igure)?$/, @argvcopy) {
 246     die "reconfiguring with other arguments present isn't supported"
 247         if scalar @argvcopy > 1;
 248     if (-f "./configdata.pm") {
 249         my $file = "./configdata.pm";
 250         unless (my $return = do $file) {
 251             die "couldn't parse $file: $@" if $@;
 252             die "couldn't do $file: $!"    unless defined $return;
 253             die "couldn't run $file"       unless $return;
 254         }
 255
 256         @argvcopy = defined($configdata::config{perlargv}) ?
 257             @{$configdata::config{perlargv}} : ();
 258         die "Incorrect data to reconfigure, please do a normal configuration\n"
 259             if (grep(/^reconf/,@argvcopy));
 260         $config{perlenv} = $configdata::config{perlenv} // {};
 261     } else {
 262         die "Insufficient data to reconfigure, please do a normal configuration\n";
 263     }
 264 }
 265
 266 $config{perlargv} = [ @argvcopy ];
 267
 268 # Collect version numbers
 269 my %version = ();
 270
 271 collect_information(
 272     collect_from_file(catfile($srcdir,'VERSION')),
 273     qr/\s*(\w+)\s*=\s*(.*?)\s*$/ =>
 274         sub {
 275             # Only define it if there is a value at all
 276             $version{uc $1} = $2 if $2 ne '';
 277         },
 278     "OTHERWISE" =>
 279         sub { die "Something wrong with this line:\n$_\nin $srcdir/VERSION" },
 280     );
 281
 282 $config{major} = $version{MAJOR} // 'unknown';
 283 $config{minor} = $version{MINOR} // 'unknown';
 284 $config{patch} = $version{PATCH} // 'unknown';
 285 $config{prerelease} =
 286     defined $version{PRE_RELEASE_TAG} ? "-$version{PRE_RELEASE_TAG}" : '';
 287 $config{build_metadata} =
 288     defined $version{BUILD_METADATA} ? "+$version{BUILD_METADATA}" : '';
 289 $config{shlib_version} = $version{SHLIB_VERSION} // 'unknown';
 290 $config{release_date} = $version{RELEASE_DATE} // 'xx XXX xxxx';
 291
 292 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 293 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 294
 295 die "erroneous version information in VERSION: ",
 296     "$config{version}, $config{shlib_version}\n"
 297     unless (defined $version{MAJOR}
 298             && defined $version{MINOR}
 299             && defined $version{PATCH}
 300             && defined $version{SHLIB_VERSION});
 301
 302 # Collect target configurations
 303
 304 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 305 foreach (sort glob($pattern)) {
 306     &read_config($_);
 307 }
 308
 309 if (defined env($local_config_envname)) {
 310     if ($^O eq 'VMS') {
 311         # VMS environment variables are logical names,
 312         # which can be used as is
 313         $pattern = $local_config_envname . ':' . '*.conf';
 314     } else {
 315         $pattern = catfile(env($local_config_envname), '*.conf');
 316     }
 317
 318     foreach (sort glob($pattern)) {
 319         &read_config($_);
 320     }
 321 }
 322
 323 # Save away perl command information
 324 $config{perl_cmd} = $^X;
 325 $config{perl_version} = $Config{version};
 326 $config{perl_archname} = $Config{archname};
 327
 328 $config{prefix}="";
 329 $config{openssldir}="";
 330 $config{processor}="";
 331 $config{libdir}="";
 332 my $auto_threads=1;    # enable threads automatically? true by default
 333 my $default_ranlib;
 334
 335 # Known TLS and DTLS protocols
 336 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 337 my @dtls = qw(dtls1 dtls1_2);
 338
 339 # Explicitly known options that are possible to disable.  They can
 340 # be regexps, and will be used like this: /^no-${option}$/
 341 # For developers: keep it sorted alphabetically
 342
 343 my @disablables = (
 344     "afalgeng",
 345     "aria",
 346     "asan",
 347     "asm",
 348     "async",
 349     "autoalginit",
 350     "autoerrinit",
 351     "autoload-config",
 352     "bf",
 353     "blake2",
 354     "buildtest-c++",
 355     "camellia",
 356     "capieng",
 357     "cast",
 358     "chacha",
 359     "cmac",
 360     "cmp",
 361     "cms",
 362     "comp",
 363     "crypto-mdebug",
 364     "ct",
 365     "deprecated",
 366     "des",
 367     "devcryptoeng",
 368     "dgram",
 369     "dh",
 370     "dsa",
 371     "dso",
 372     "dtls",
 373     "dynamic-engine",
 374     "ec",
 375     "ec2m",
 376     "ecdh",
 377     "ecdsa",
 378     "ec_nistp_64_gcc_128",
 379     "egd",
 380     "engine",
 381     "err",
 382     "external-tests",
 383     "filenames",
 384     "fips",
 385     "fuzz-libfuzzer",
 386     "fuzz-afl",
 387     "gost",
 388     "idea",
 389     "ktls",
 390     "legacy",
 391     "makedepend",
 392     "md2",
 393     "md4",
 394     "mdc2",
 395     "module",
 396     "msan",
 397     "multiblock",
 398     "nextprotoneg",
 399     "pinshared",
 400     "ocb",
 401     "ocsp",
 402     "padlockeng",
 403     "pic",
 404     "poly1305",
 405     "posix-io",
 406     "psk",
 407     "rc2",
 408     "rc4",
 409     "rc5",
 410     "rdrand",
 411     "rfc3779",
 412     "rmd160",
 413     "scrypt",
 414     "sctp",
 415     "secure-memory",
 416     "seed",
 417     "shared",
 418     "siphash",
 419     "siv",
 420     "sm2",
 421     "sm3",
 422     "sm4",
 423     "sock",
 424     "srp",
 425     "srtp",
 426     "sse2",
 427     "ssl",
 428     "ssl-trace",
 429     "static-engine",
 430     "stdio",
 431     "tests",
 432     "threads",
 433     "tls",
 434     "trace",
 435     "ts",
 436     "ubsan",
 437     "ui-console",
 438     "unit-test",
 439     "uplink",
 440     "whirlpool",
 441     "weak-ssl-ciphers",
 442     "zlib",
 443     "zlib-dynamic",
 444     );
 445 foreach my $proto ((@tls, @dtls))
 446         {
 447         push(@disablables, $proto);
 448         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 449         }
 450
 451 # Internal disablables, for aliasing purposes.  They serve no special
 452 # purpose here, but allow scripts to get to know them through configdata.pm,
 453 # where these are merged with @disablables.
 454 # The actual aliasing mechanism is done via %disable_cascades
 455 my @disablables_int = qw(
 456     crmf
 457     );
 458
 459 my %deprecated_disablables = (
 460     "ssl2" => undef,
 461     "buf-freelists" => undef,
 462     "crypto-mdebug-backtrace" => undef,
 463     "hw" => "hw",               # causes cascade, but no macro
 464     "hw-padlock" => "padlockeng",
 465     "ripemd" => "rmd160",
 466     "ui" => "ui-console",
 467     "heartbeats" => undef,
 468     );
 469
 470 # All of the following are disabled by default:
 471
 472 our %disabled = ( # "what"         => "comment"
 473                   "asan"                => "default",
 474                   "buildtest-c++"       => "default",
 475                   "crypto-mdebug"       => "default",
 476                   "crypto-mdebug-backtrace" => "default",
 477                   "devcryptoeng"        => "default",
 478                   "ec_nistp_64_gcc_128" => "default",
 479                   "egd"                 => "default",
 480                   "external-tests"      => "default",
 481                   "fuzz-libfuzzer"      => "default",
 482                   "fuzz-afl"            => "default",
 483                   "md2"                 => "default",
 484                   "msan"                => "default",
 485                   "rc5"                 => "default",
 486                   "sctp"                => "default",
 487                   "ssl-trace"           => "default",
 488                   "ssl3"                => "default",
 489                   "ssl3-method"         => "default",
 490                   "trace"               => "default",
 491                   "ubsan"               => "default",
 492                   "unit-test"           => "default",
 493                   "weak-ssl-ciphers"    => "default",
 494                   "zlib"                => "default",
 495                   "zlib-dynamic"        => "default",
 496                   "ktls"                => "default",
 497                 );
 498
 499 # Note: => pair form used for aesthetics, not to truly make a hash table
 500 my @disable_cascades = (
 501     # "what"            => [ "cascade", ... ]
 502     sub { $config{processor} eq "386" }
 503                         => [ "sse2" ],
 504     "ssl"               => [ "ssl3" ],
 505     "ssl3-method"       => [ "ssl3" ],
 506     "zlib"              => [ "zlib-dynamic" ],
 507     "des"               => [ "mdc2" ],
 508     "ec"                => [ "ecdsa", "ecdh", "sm2" ],
 509     sub { $disabled{"ec"} && $disabled{"dh"} }
 510                         => [ "tls1_3" ],
 511     "dgram"             => [ "dtls", "sctp" ],
 512     "sock"              => [ "dgram" ],
 513     "dtls"              => [ @dtls ],
 514     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 515                         => [ "dtls" ],
 516
 517     "tls"               => [ @tls ],
 518     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 519                         => [ "tls" ],
 520
 521     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 522
 523     # If no modules, then no dynamic engines either
 524     "module"            => [ "dynamic-engine" ],
 525
 526     # Without shared libraries, dynamic engines aren't possible.
 527     # This is due to them having to link with libcrypto and register features
 528     # using the ENGINE functionality, and since that relies on global tables,
 529     # those *have* to be exacty the same as the ones accessed from the app,
 530     # which cannot be guaranteed if shared libraries aren't present.
 531     # (note that even with shared libraries, both the app and dynamic engines
 532     # must be linked with the same library)
 533     "shared"            => [ "dynamic-engine", "uplink" ],
 534     "dso"               => [ "dynamic-engine", "module" ],
 535     # Other modules don't necessarily have to link with libcrypto, so shared
 536     # libraries do not have to be a condition to produce those.
 537
 538     # Without position independent code, there can be no shared libraries
 539     # or modules.
 540     "pic"               => [ "shared", "module" ],
 541
 542     "module"            => [ "fips" ],
 543
 544     "engine"            => [ grep /eng$/, @disablables ],
 545     "hw"                => [ "padlockeng" ],
 546
 547     # no-autoalginit is only useful when building non-shared
 548     "autoalginit"       => [ "shared", "apps" ],
 549
 550     "stdio"             => [ "apps", "capieng", "egd" ],
 551     "apps"              => [ "tests" ],
 552     "tests"             => [ "external-tests" ],
 553     "comp"              => [ "zlib" ],
 554     "sm3"               => [ "sm2" ],
 555     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 556
 557     sub { !$disabled{"msan"} } => [ "asm" ],
 558
 559     sub { $disabled{cmac}; } => [ "siv" ],
 560     "legacy"                 => [ "md2" ],
 561
 562     "cmp"               => [ "crmf" ],
 563
 564     # Padlock engine uses low-level AES APIs which are deprecated
 565     sub { $disabled{"deprecated-3.0"} }
 566           => [ "padlockeng" ]
 567     );
 568
 569 # Avoid protocol support holes.  Also disable all versions below N, if version
 570 # N is disabled while N+1 is enabled.
 571 #
 572 my @list = (reverse @tls);
 573 while ((my $first, my $second) = (shift @list, shift @list)) {
 574     last unless @list;
 575     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 576                               => [ @list ] );
 577     unshift @list, $second;
 578 }
 579 my @list = (reverse @dtls);
 580 while ((my $first, my $second) = (shift @list, shift @list)) {
 581     last unless @list;
 582     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 583                               => [ @list ] );
 584     unshift @list, $second;
 585 }
 586
 587 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 588 # To remove something from %disabled, use "enable-foo".
 589 # For symmetry, "disable-foo" is a synonym for "no-foo".
 590
 591 &usage if ($#ARGV < 0);
 592
 593 # For the "make variables" CPPINCLUDES and CPPDEFINES, we support lists with
 594 # platform specific list separators.  Users from those platforms should
 595 # recognise those separators from how you set up the PATH to find executables.
 596 # The default is the Unix like separator, :, but as an exception, we also
 597 # support the space as separator.
 598 my $list_separator_re =
 599     { VMS           => qr/(?<!\^),/,
 600       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 601 # All the "make variables" we support
 602 # Some get pre-populated for the sake of backward compatibility
 603 # (we supported those before the change to "make variable" support.
 604 my %user = (
 605     AR          => env('AR'),
 606     ARFLAGS     => [],
 607     AS          => undef,
 608     ASFLAGS     => [],
 609     CC          => env('CC'),
 610     CFLAGS      => [ env('CFLAGS') || () ],
 611     CXX         => env('CXX'),
 612     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 613     CPP         => undef,
 614     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 615     CPPDEFINES  => [],  # Alternative for -D
 616     CPPINCLUDES => [],  # Alternative for -I
 617     CROSS_COMPILE => env('CROSS_COMPILE'),
 618     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 619     LD          => undef,
 620     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 621     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 622     MT          => undef,
 623     MTFLAGS     => [],
 624     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 625     RANLIB      => env('RANLIB'),
 626     RC          => env('RC') || env('WINDRES'),
 627     RCFLAGS     => [ env('RCFLAGS') || () ],
 628     RM          => undef,
 629    );
 630 # Info about what "make variables" may be prefixed with the cross compiler
 631 # prefix.  This should NEVER mention any such variable with a list for value.
 632 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 633 # The same but for flags given as Configure options.  These are *additional*
 634 # input, as opposed to the VAR=string option that override the corresponding
 635 # config target attributes
 636 my %useradd = (
 637     CPPDEFINES  => [],
 638     CPPINCLUDES => [],
 639     CPPFLAGS    => [],
 640     CFLAGS      => [],
 641     CXXFLAGS    => [],
 642     LDFLAGS     => [],
 643     LDLIBS      => [],
 644     RCFLAGS     => [],
 645    );
 646
 647 my %user_synonyms = (
 648     HASHBANGPERL=> 'PERL',
 649     RC          => 'WINDRES',
 650    );
 651
 652 # Some target attributes have been renamed, this is the translation table
 653 my %target_attr_translate =(
 654     ar          => 'AR',
 655     as          => 'AS',
 656     cc          => 'CC',
 657     cxx         => 'CXX',
 658     cpp         => 'CPP',
 659     hashbangperl => 'HASHBANGPERL',
 660     ld          => 'LD',
 661     mt          => 'MT',
 662     ranlib      => 'RANLIB',
 663     rc          => 'RC',
 664     rm          => 'RM',
 665    );
 666
 667 # Initialisers coming from 'config' scripts
 668 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 669 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 670 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 671 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 672 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 673 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 674 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 675
 676 $config{openssl_api_defines}=[];
 677 $config{openssl_sys_defines}=[];
 678 $config{openssl_feature_defines}=[];
 679 $config{options}="";
 680 $config{build_type} = "release";
 681 my $target="";
 682
 683 my %cmdvars = ();               # Stores FOO='blah' type arguments
 684 my %unsupported_options = ();
 685 my %deprecated_options = ();
 686 # If you change this, update apps/version.c
 687 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 688 my @seed_sources = ();
 689 while (@argvcopy)
 690         {
 691         $_ = shift @argvcopy;
 692
 693         # Support env variable assignments among the options
 694         if (m|^(\w+)=(.+)?$|)
 695                 {
 696                 $cmdvars{$1} = $2;
 697                 # Every time a variable is given as a configuration argument,
 698                 # it acts as a reset if the variable.
 699                 if (exists $user{$1})
 700                         {
 701                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 702                         }
 703                 #if (exists $useradd{$1})
 704                 #       {
 705                 #       $useradd{$1} = [];
 706                 #       }
 707                 next;
 708                 }
 709
 710         # VMS is a case insensitive environment, and depending on settings
 711         # out of our control, we may receive options uppercased.  Let's
 712         # downcase at least the part before any equal sign.
 713         if ($^O eq "VMS")
 714                 {
 715                 s/^([^=]*)/lc($1)/e;
 716                 }
 717
 718         # some people just can't read the instructions, clang people have to...
 719         s/^-no-(?!integrated-as)/no-/;
 720
 721         # rewrite some options in "enable-..." form
 722         s /^-?-?shared$/enable-shared/;
 723         s /^sctp$/enable-sctp/;
 724         s /^threads$/enable-threads/;
 725         s /^zlib$/enable-zlib/;
 726         s /^zlib-dynamic$/enable-zlib-dynamic/;
 727
 728         if (/^(no|disable|enable)-(.+)$/)
 729                 {
 730                 my $word = $2;
 731                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 732                         && !exists $deprecated_disablables{$word}
 733                         && !grep { $word eq $_ } @disablables)
 734                         {
 735                         $unsupported_options{$_} = 1;
 736                         next;
 737                         }
 738                 }
 739         if (/^no-(.+)$/ || /^disable-(.+)$/)
 740                 {
 741                 foreach my $proto ((@tls, @dtls))
 742                         {
 743                         if ($1 eq "$proto-method")
 744                                 {
 745                                 $disabled{"$proto"} = "option($proto-method)";
 746                                 last;
 747                                 }
 748                         }
 749                 if ($1 eq "dtls")
 750                         {
 751                         foreach my $proto (@dtls)
 752                                 {
 753                                 $disabled{$proto} = "option(dtls)";
 754                                 }
 755                         $disabled{"dtls"} = "option(dtls)";
 756                         }
 757                 elsif ($1 eq "ssl")
 758                         {
 759                         # Last one of its kind
 760                         $disabled{"ssl3"} = "option(ssl)";
 761                         }
 762                 elsif ($1 eq "tls")
 763                         {
 764                         # XXX: Tests will fail if all SSL/TLS
 765                         # protocols are disabled.
 766                         foreach my $proto (@tls)
 767                                 {
 768                                 $disabled{$proto} = "option(tls)";
 769                                 }
 770                         }
 771                 elsif ($1 eq "static-engine")
 772                         {
 773                         delete $disabled{"dynamic-engine"};
 774                         }
 775                 elsif ($1 eq "dynamic-engine")
 776                         {
 777                         $disabled{"dynamic-engine"} = "option";
 778                         }
 779                 elsif (exists $deprecated_disablables{$1})
 780                         {
 781                         $deprecated_options{$_} = 1;
 782                         if (defined $deprecated_disablables{$1})
 783                                 {
 784                                 $disabled{$deprecated_disablables{$1}} = "option";
 785                                 }
 786                         }
 787                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 788                         {
 789                         $deprecated_options{$_} = 1;
 790                         }
 791                 else
 792                         {
 793                         $disabled{$1} = "option";
 794                         }
 795                 # No longer an automatic choice
 796                 $auto_threads = 0 if ($1 eq "threads");
 797                 }
 798         elsif (/^enable-(.+)$/)
 799                 {
 800                 if ($1 eq "static-engine")
 801                         {
 802                         $disabled{"dynamic-engine"} = "option";
 803                         }
 804                 elsif ($1 eq "dynamic-engine")
 805                         {
 806                         delete $disabled{"dynamic-engine"};
 807                         }
 808                 elsif ($1 eq "zlib-dynamic")
 809                         {
 810                         delete $disabled{"zlib"};
 811                         }
 812                 my $algo = $1;
 813                 delete $disabled{$algo};
 814
 815                 # No longer an automatic choice
 816                 $auto_threads = 0 if ($1 eq "threads");
 817                 }
 818         elsif (/^--strict-warnings$/)
 819                 {
 820                 # Pretend that our strict flags is a C flag, and replace it
 821                 # with the proper flags later on
 822                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 823                 $strict_warnings=1;
 824                 }
 825         elsif (/^--debug$/)
 826                 {
 827                 $config{build_type} = "debug";
 828                 }
 829         elsif (/^--release$/)
 830                 {
 831                 $config{build_type} = "release";
 832                 }
 833         elsif (/^386$/)
 834                 { $config{processor}=386; }
 835         elsif (/^fips$/)
 836                 {
 837                 die "FIPS mode not supported\n";
 838                 }
 839         elsif (/^rsaref$/)
 840                 {
 841                 # No RSAref support any more since it's not needed.
 842                 # The check for the option is there so scripts aren't
 843                 # broken
 844                 }
 845         elsif (/^nofipscanistercheck$/)
 846                 {
 847                 die "FIPS mode not supported\n";
 848                 }
 849         elsif (m|^[-+/]|)
 850                 {
 851                 if (/^--prefix=(.*)$/)
 852                         {
 853                         $config{prefix}=$1;
 854                         die "Directory given with --prefix MUST be absolute\n"
 855                                 unless file_name_is_absolute($config{prefix});
 856                         }
 857                 elsif (/^--api=(.*)$/)
 858                         {
 859                         my $api = $1;
 860                         die "Unknown API compatibility level $api"
 861                                 unless defined $apitable->{$api};
 862                         $config{api}=$apitable->{$api};
 863                         }
 864                 elsif (/^--libdir=(.*)$/)
 865                         {
 866                         $config{libdir}=$1;
 867                         }
 868                 elsif (/^--openssldir=(.*)$/)
 869                         {
 870                         $config{openssldir}=$1;
 871                         }
 872                 elsif (/^--with-zlib-lib=(.*)$/)
 873                         {
 874                         $withargs{zlib_lib}=$1;
 875                         }
 876                 elsif (/^--with-zlib-include=(.*)$/)
 877                         {
 878                         $withargs{zlib_include}=$1;
 879                         }
 880                 elsif (/^--with-fuzzer-lib=(.*)$/)
 881                         {
 882                         $withargs{fuzzer_lib}=$1;
 883                         }
 884                 elsif (/^--with-fuzzer-include=(.*)$/)
 885                         {
 886                         $withargs{fuzzer_include}=$1;
 887                         }
 888                 elsif (/^--with-rand-seed=(.*)$/)
 889                         {
 890                         foreach my $x (split(m|,|, $1))
 891                             {
 892                             die "Unknown --with-rand-seed choice $x\n"
 893                                 if ! grep { $x eq $_ } @known_seed_sources;
 894                             push @seed_sources, $x;
 895                             }
 896                         }
 897                 elsif (/^--cross-compile-prefix=(.*)$/)
 898                         {
 899                         $user{CROSS_COMPILE}=$1;
 900                         }
 901                 elsif (/^--config=(.*)$/)
 902                         {
 903                         read_config $1;
 904                         }
 905                 elsif (/^-l(.*)$/)
 906                         {
 907                         push @{$useradd{LDLIBS}}, $_;
 908                         }
 909                 elsif (/^-framework$/)
 910                         {
 911                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 912                         }
 913                 elsif (/^-L(.*)$/ or /^-Wl,/)
 914                         {
 915                         push @{$useradd{LDFLAGS}}, $_;
 916                         }
 917                 elsif (/^-rpath$/ or /^-R$/)
 918                         # -rpath is the OSF1 rpath flag
 919                         # -R is the old Solaris rpath flag
 920                         {
 921                         my $rpath = shift(@argvcopy) || "";
 922                         $rpath .= " " if $rpath ne "";
 923                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 924                         }
 925                 elsif (/^-static$/)
 926                         {
 927                         push @{$useradd{LDFLAGS}}, $_;
 928                         }
 929                 elsif (m|^[-/]D(.*)$|)
 930                         {
 931                         push @{$useradd{CPPDEFINES}}, $1;
 932                         }
 933                 elsif (m|^[-/]I(.*)$|)
 934                         {
 935                         push @{$useradd{CPPINCLUDES}}, $1;
 936                         }
 937                 elsif (/^-Wp,$/)
 938                         {
 939                         push @{$useradd{CPPFLAGS}}, $1;
 940                         }
 941                 else    # common if (/^[-+]/), just pass down...
 942                         {
 943                         # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
 944                         # This provides a simple way to pass options with arguments separated
 945                         # by spaces without quoting (e.g. -opt%20arg translates to -opt arg).
 946                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 947                         push @{$useradd{CFLAGS}}, $_;
 948                         push @{$useradd{CXXFLAGS}}, $_;
 949                         }
 950                 }
 951         elsif (m|^/|)
 952                 {
 953                 # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
 954                 # This provides a simple way to pass options with arguments separated
 955                 # by spaces without quoting (e.g. /opt%20arg translates to /opt arg).
 956                 $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 957                 push @{$useradd{CFLAGS}}, $_;
 958                 push @{$useradd{CXXFLAGS}}, $_;
 959                 }
 960         else
 961                 {
 962                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 963                 $target=$_;
 964                 }
 965         unless ($_ eq $target || /^no-/ || /^disable-/)
 966                 {
 967                 # "no-..." follows later after implied deactivations
 968                 # have been derived.  (Don't take this too seriously,
 969                 # we really only write OPTIONS to the Makefile out of
 970                 # nostalgia.)
 971
 972                 if ($config{options} eq "")
 973                         { $config{options} = $_; }
 974                 else
 975                         { $config{options} .= " ".$_; }
 976                 }
 977         }
 978
 979 if (keys %deprecated_options)
 980         {
 981         warn "***** Deprecated options: ",
 982                 join(", ", keys %deprecated_options), "\n";
 983         }
 984 if (keys %unsupported_options)
 985         {
 986         die "***** Unsupported options: ",
 987                 join(", ", keys %unsupported_options), "\n";
 988         }
 989
 990 # If any %useradd entry has been set, we must check that the "make
 991 # variables" haven't been set.  We start by checking of any %useradd entry
 992 # is set.
 993 if (grep { scalar @$_ > 0 } values %useradd) {
 994     # Hash of env / make variables names.  The possible values are:
 995     # 1 - "make vars"
 996     # 2 - %useradd entry set
 997     # 3 - both set
 998     my %detected_vars =
 999         map { my $v = 0;
1000               $v += 1 if $cmdvars{$_};
1001               $v += 2 if @{$useradd{$_}};
1002               $_ => $v }
1003         keys %useradd;
1004
1005     # If any of the corresponding "make variables" is set, we error
1006     if (grep { $_ & 1 } values %detected_vars) {
1007         my $names = join(', ', grep { $detected_vars{$_} > 0 }
1008                                sort keys %detected_vars);
1009         die <<"_____";
1010 ***** Mixing make variables and additional compiler/linker flags as
1011 ***** configure command line option is not permitted.
1012 ***** Affected make variables: $names
1013 _____
1014     }
1015 }
1016
1017 # Check through all supported command line variables to see if any of them
1018 # were set, and canonicalise the values we got.  If no compiler or linker
1019 # flag or anything else that affects %useradd was set, we also check the
1020 # environment for values.
1021 my $anyuseradd =
1022     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
1023 foreach (keys %user) {
1024     my $value = $cmdvars{$_};
1025     $value //= env($_) unless $anyuseradd;
1026     $value //=
1027         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
1028     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
1029         unless $anyuseradd;
1030
1031     if (defined $value) {
1032         if (ref $user{$_} eq 'ARRAY') {
1033             if ($_ eq 'CPPDEFINES' || $_ eq 'CPPINCLUDES') {
1034                 $user{$_} = [ split /$list_separator_re/, $value ];
1035             } else {
1036                 $user{$_} = [ $value ];
1037             }
1038         } elsif (!defined $user{$_}) {
1039             $user{$_} = $value;
1040         }
1041     }
1042 }
1043
1044 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1045     && !$disabled{shared}
1046     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1047     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1048         "***** any of asan, msan or ubsan\n";
1049 }
1050
1051 sub disable {
1052     my $disable_type = shift;
1053
1054     for (@_) {
1055         $disabled{$_} = $disable_type;
1056     }
1057
1058     my @tocheckfor = (@_ ? @_ : keys %disabled);
1059     while (@tocheckfor) {
1060         my %new_tocheckfor = ();
1061         my @cascade_copy = (@disable_cascades);
1062         while (@cascade_copy) {
1063             my ($test, $descendents) =
1064                 (shift @cascade_copy, shift @cascade_copy);
1065             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1066                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1067                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1068                 }
1069             }
1070         }
1071         @tocheckfor = (keys %new_tocheckfor);
1072     }
1073 }
1074 disable();                     # First cascade run
1075
1076 our $die = sub { die @_; };
1077 if ($target eq "TABLE") {
1078     local $die = sub { warn @_; };
1079     foreach (sort keys %table) {
1080         print_table_entry($_, "TABLE");
1081     }
1082     exit 0;
1083 }
1084
1085 if ($target eq "LIST") {
1086     foreach (sort keys %table) {
1087         print $_,"\n" unless $table{$_}->{template};
1088     }
1089     exit 0;
1090 }
1091
1092 if ($target eq "HASH") {
1093     local $die = sub { warn @_; };
1094     print "%table = (\n";
1095     foreach (sort keys %table) {
1096         print_table_entry($_, "HASH");
1097     }
1098     exit 0;
1099 }
1100
1101 print "Configuring OpenSSL version $config{full_version} ";
1102 print "for target $target\n";
1103
1104 if (scalar(@seed_sources) == 0) {
1105     print "Using os-specific seed configuration\n";
1106     push @seed_sources, 'os';
1107 }
1108 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1109     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1110     warn <<_____ if scalar(@seed_sources) == 1;
1111
1112 ============================== WARNING ===============================
1113 You have selected the --with-rand-seed=none option, which effectively
1114 disables automatic reseeding of the OpenSSL random generator.
1115 All operations depending on the random generator such as creating keys
1116 will not work unless the random generator is seeded manually by the
1117 application.
1118
1119 Please read the 'Note on random number generation' section in the
1120 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1121 ============================== WARNING ===============================
1122
1123 _____
1124 }
1125 push @{$config{openssl_feature_defines}},
1126      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1127         @seed_sources;
1128
1129 # Backward compatibility?
1130 if ($target =~ m/^CygWin32(-.*)$/) {
1131     $target = "Cygwin".$1;
1132 }
1133
1134 # Support for legacy targets having a name starting with 'debug-'
1135 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1136 if ($d) {
1137     $config{build_type} = "debug";
1138
1139     # If we do not find debug-foo in the table, the target is set to foo.
1140     if (!$table{$target}) {
1141         $target = $t;
1142     }
1143 }
1144
1145 &usage if !$table{$target} || $table{$target}->{template};
1146
1147 $config{target} = $target;
1148 my %target = resolve_config($target);
1149
1150 foreach (keys %target_attr_translate) {
1151     $target{$target_attr_translate{$_}} = $target{$_}
1152         if $target{$_};
1153     delete $target{$_};
1154 }
1155
1156 %target = ( %{$table{DEFAULTS}}, %target );
1157
1158 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1159 $config{conf_files} = [ sort keys %conf_files ];
1160
1161 # Using sub disable within these loops may prove fragile, so we run
1162 # a cascade afterwards
1163 foreach my $feature (@{$target{disable}}) {
1164     if (exists $deprecated_disablables{$feature}) {
1165         warn "***** config $target disables deprecated feature $feature\n";
1166     } elsif (!grep { $feature eq $_ } @disablables) {
1167         die "***** config $target disables unknown feature $feature\n";
1168     }
1169     $disabled{$feature} = 'config';
1170 }
1171 foreach my $feature (@{$target{enable}}) {
1172     if ("default" eq ($disabled{$feature} // "")) {
1173         if (exists $deprecated_disablables{$feature}) {
1174             warn "***** config $target enables deprecated feature $feature\n";
1175         } elsif (!grep { $feature eq $_ } @disablables) {
1176             die "***** config $target enables unknown feature $feature\n";
1177         }
1178         delete $disabled{$feature};
1179     }
1180 }
1181
1182 # If uplink_arch isn't defined, disable uplink
1183 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1184 # If asm_arch isn't defined, disable asm
1185 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1186
1187 disable();                      # Run a cascade now
1188
1189 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1190 $target{cxxflags}//=$target{cflags} if $target{CXX};
1191 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1192 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1193
1194 # Fill %config with values from %user, and in case those are undefined or
1195 # empty, use values from %target (acting as a default).
1196 foreach (keys %user) {
1197     my $ref_type = ref $user{$_};
1198
1199     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1200     # and a value that's to be coerced into that type.
1201     my $mkvalue = sub {
1202         my $type = shift;
1203         my $value = shift;
1204         my $undef_p = shift;
1205
1206         die "Too many arguments for \$mkvalue" if @_;
1207
1208         while (ref $value eq 'CODE') {
1209             $value = $value->();
1210         }
1211
1212         if ($type eq 'ARRAY') {
1213             return undef unless defined $value;
1214             return undef if ref $value ne 'ARRAY' && !$value;
1215             return undef if ref $value eq 'ARRAY' && !@$value;
1216             return [ $value ] unless ref $value eq 'ARRAY';
1217         }
1218         return undef unless $value;
1219         return $value;
1220     };
1221
1222     $config{$_} =
1223         $mkvalue->($ref_type, $user{$_})
1224         || $mkvalue->($ref_type, $target{$_});
1225     delete $config{$_} unless defined $config{$_};
1226 }
1227
1228 # Finish up %config by appending things the user gave us on the command line
1229 # apart from "make variables"
1230 foreach (keys %useradd) {
1231     # The must all be lists, so we assert that here
1232     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1233         unless ref $useradd{$_} eq 'ARRAY';
1234
1235     if (defined $config{$_}) {
1236         push @{$config{$_}}, @{$useradd{$_}};
1237     } else {
1238         $config{$_} = [ @{$useradd{$_}} ];
1239     }
1240 }
1241 # At this point, we can forget everything about %user and %useradd,
1242 # because it's now all been merged into the corresponding $config entry
1243
1244 # Allow overriding the build file name
1245 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1246
1247 # Make sure build_scheme is consistent.
1248 $target{build_scheme} = [ $target{build_scheme} ]
1249     if ref($target{build_scheme}) ne "ARRAY";
1250
1251 my ($builder, $builder_platform, @builder_opts) =
1252     @{$target{build_scheme}};
1253
1254 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1255                       $builder_platform."-checker.pm")) {
1256     my $checker_path = catfile($srcdir, "Configurations", $checker);
1257     if (-f $checker_path) {
1258         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1259             ? sub { warn $@; } : sub { die $@; };
1260         if (! do $checker_path) {
1261             if ($@) {
1262                 $fn->($@);
1263             } elsif ($!) {
1264                 $fn->($!);
1265             } else {
1266                 $fn->("The detected tools didn't match the platform\n");
1267             }
1268         }
1269         last;
1270     }
1271 }
1272
1273 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1274
1275 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1276         {
1277         push @{$config{cflags}}, "-mno-cygwin";
1278         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1279         push @{$config{shared_ldflag}}, "-mno-cygwin";
1280         }
1281
1282 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1283         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1284         # minimally required architecture flags for assembly modules
1285         my $value;
1286         $value = '-mips2' if ($target =~ /mips32/);
1287         $value = '-mips3' if ($target =~ /mips64/);
1288         unshift @{$config{cflags}}, $value;
1289         unshift @{$config{cxxflags}}, $value if $config{CXX};
1290 }
1291
1292 # If threads aren't disabled, check how possible they are
1293 unless ($disabled{threads}) {
1294     if ($auto_threads) {
1295         # Enabled by default, disable it forcibly if unavailable
1296         if ($target{thread_scheme} eq "(unknown)") {
1297             disable("unavailable", 'threads');
1298         }
1299     } else {
1300         # The user chose to enable threads explicitly, let's see
1301         # if there's a chance that's possible
1302         if ($target{thread_scheme} eq "(unknown)") {
1303             # If the user asked for "threads" and we don't have internal
1304             # knowledge how to do it, [s]he is expected to provide any
1305             # system-dependent compiler options that are necessary.  We
1306             # can't truly check that the given options are correct, but
1307             # we expect the user to know what [s]He is doing.
1308             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1309                 die "You asked for multi-threading support, but didn't\n"
1310                     ,"provide any system-specific compiler options\n";
1311             }
1312         }
1313     }
1314 }
1315
1316 # Find out if clang's sanitizers have been enabled with -fsanitize
1317 # flags and ensure that the corresponding %disabled elements area
1318 # removed to reflect that the sanitizers are indeed enabled.
1319 my %detected_sanitizers = ();
1320 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1321     (my $checks = $_) =~ s/^-fsanitize=//;
1322     foreach (split /,/, $checks) {
1323         my $d = { address       => 'asan',
1324                   undefined     => 'ubsan',
1325                   memory        => 'msan' } -> {$_};
1326         next unless defined $d;
1327
1328         $detected_sanitizers{$d} = 1;
1329         if (defined $disabled{$d}) {
1330             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1331                 if $disabled{$d} ne "default";
1332             delete $disabled{$d};
1333         }
1334     }
1335 }
1336
1337 # If threads still aren't disabled, add a C macro to ensure the source
1338 # code knows about it.  Any other flag is taken care of by the configs.
1339 unless($disabled{threads}) {
1340     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1341 }
1342
1343 my $no_shared_warn=0;
1344 if ($target{shared_target} eq "")
1345         {
1346         $no_shared_warn = 1
1347             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1348         disable('no-shared-target', 'pic');
1349         }
1350
1351 if ($disabled{"dynamic-engine"}) {
1352         $config{dynamic_engines} = 0;
1353 } else {
1354         $config{dynamic_engines} = 1;
1355 }
1356
1357 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1358     push @{$config{cflags}}, "-fsanitize=address";
1359 }
1360
1361 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1362     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1363     # platforms.
1364     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1365 }
1366
1367 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1368   push @{$config{cflags}}, "-fsanitize=memory";
1369 }
1370
1371 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1372         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1373     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1374     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1375 }
1376 #
1377 # Platform fix-ups
1378 #
1379
1380 # This saves the build files from having to check
1381 if ($disabled{pic})
1382         {
1383         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1384                     shared_defines shared_includes shared_ldflag
1385                     module_cflags module_cxxflags module_cppflags
1386                     module_defines module_includes module_lflags))
1387                 {
1388                 delete $config{$_};
1389                 $target{$_} = "";
1390                 }
1391         }
1392 else
1393         {
1394         push @{$config{lib_defines}}, "OPENSSL_PIC";
1395         }
1396
1397 if ($target{sys_id} ne "")
1398         {
1399         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1400         }
1401
1402 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1403 my %predefined_CXX = $config{CXX}
1404     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1405     : ();
1406
1407 unless ($disabled{asm}) {
1408     # big endian systems can use ELFv2 ABI
1409     if ($target eq "linux-ppc64") {
1410         $target{perlasm_scheme} = "linux64v2" if ($predefined_C{_CALL_ELF} == 2);
1411     }
1412 }
1413
1414 # Check for makedepend capabilities.
1415 if (!$disabled{makedepend}) {
1416     if ($config{target} =~ /^(VC|vms)-/) {
1417         # For VC- and vms- targets, there's nothing more to do here.  The
1418         # functionality is hard coded in the corresponding build files for
1419         # cl (Windows) and CC/DECC (VMS).
1420     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1421              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1422         # We know that GNU C version 3 and up as well as all clang
1423         # versions support dependency generation, but Xcode did not
1424         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1425         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1426     } else {
1427         # In all other cases, we look for 'makedepend', and disable the
1428         # capability if not found.
1429         $config{makedepprog} = which('makedepend');
1430         disable('unavailable', 'makedepend') unless $config{makedepprog};
1431     }
1432 }
1433
1434 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1435     # probe for -Wa,--noexecstack option...
1436     if ($predefined_C{__clang__}) {
1437         # clang has builtin assembler, which doesn't recognize --help,
1438         # but it apparently recognizes the option in question on all
1439         # supported platforms even when it's meaningless. In other words
1440         # probe would fail, but probed option always accepted...
1441         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1442     } else {
1443         my $cc = $config{CROSS_COMPILE}.$config{CC};
1444         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1445         while(<PIPE>) {
1446             if (m/--noexecstack/) {
1447                 push @{$config{cflags}}, "-Wa,--noexecstack";
1448                 last;
1449             }
1450         }
1451         close(PIPE);
1452         unlink("null.$$.o");
1453     }
1454 }
1455
1456 # Deal with bn_ops ###################################################
1457
1458 $config{bn_ll}                  =0;
1459 my $def_int="unsigned int";
1460 $config{rc4_int}                =$def_int;
1461 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1462
1463 my $count = 0;
1464 foreach (sort split(/\s+/,$target{bn_ops})) {
1465     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1466     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1467     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1468     ($config{b64l},$config{b64},$config{b32})
1469         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1470     ($config{b64l},$config{b64},$config{b32})
1471         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1472     ($config{b64l},$config{b64},$config{b32})
1473         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1474 }
1475 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1476     if $count > 1;
1477
1478 $config{api} = $config{major} * 10000 + $config{minor} * 100
1479     unless $config{api};
1480 foreach (keys %$apitable) {
1481     $disabled{"deprecated-$_"} = "deprecation"
1482         if $disabled{deprecated} && $config{api} >= $apitable->{$_};
1483 }
1484
1485 disable();                      # Run a cascade now
1486
1487 # Hack cflags for better warnings (dev option) #######################
1488
1489 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1490 # a string and works as well on command lines.
1491 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1492                         @{$config{cflags}} ];
1493 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1494                           @{$config{cxxflags}} ] if $config{CXX};
1495
1496 $config{openssl_api_defines} = [
1497     "OPENSSL_CONFIGURED_API=".$config{api},
1498 ];
1499
1500 my @strict_warnings_collection=();
1501 if ($strict_warnings)
1502         {
1503         my $wopt;
1504         my $gccver = $predefined_C{__GNUC__} // -1;
1505
1506         if ($gccver >= 4)
1507                 {
1508                 push @strict_warnings_collection, @gcc_devteam_warn;
1509                 push @strict_warnings_collection, @clang_devteam_warn
1510                     if (defined($predefined_C{__clang__}));
1511                 }
1512         elsif ($config{target} =~ /^VC-/)
1513                 {
1514                 push @strict_warnings_collection, @cl_devteam_warn;
1515                 }
1516         else
1517                 {
1518                 warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike, or MSVC"
1519                 }
1520         }
1521
1522 if (grep { $_ =~ /(?:^|\s)-static(?:\s|$)/ } @{$config{LDFLAGS}}) {
1523     disable('static', 'pic', 'threads');
1524 }
1525
1526 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1527                               ? @strict_warnings_collection
1528                               : ( $_ ) }
1529                     @{$config{CFLAGS}} ];
1530
1531 unless ($disabled{afalgeng}) {
1532     $config{afalgeng}="";
1533     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1534         my $minver = 4*10000 + 1*100 + 0;
1535         if ($config{CROSS_COMPILE} eq "") {
1536             my $verstr = `uname -r`;
1537             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1538             ($mi2) = $mi2 =~ /(\d+)/;
1539             my $ver = $ma*10000 + $mi1*100 + $mi2;
1540             if ($ver < $minver) {
1541                 disable('too-old-kernel', 'afalgeng');
1542             } else {
1543                 push @{$config{engdirs}}, "afalg";
1544             }
1545         } else {
1546             disable('cross-compiling', 'afalgeng');
1547         }
1548     } else {
1549         disable('not-linux', 'afalgeng');
1550     }
1551 }
1552
1553 unless ($disabled{devcryptoeng}) {
1554     if ($target =~ m/^BSD/) {
1555         my $maxver = 5*100 + 7;
1556         my $sysstr = `uname -s`;
1557         my $verstr = `uname -r`;
1558         $sysstr =~ s|\R$||;
1559         $verstr =~ s|\R$||;
1560         my ($ma, $mi, @rest) = split m|\.|, $verstr;
1561         my $ver = $ma*100 + $mi;
1562         if ($sysstr eq 'OpenBSD' && $ver >= $maxver) {
1563             disable('too-new-kernel', 'devcryptoeng');
1564         }
1565     }
1566 }
1567
1568 unless ($disabled{ktls}) {
1569     $config{ktls}="";
1570     if ($target =~ m/^linux/) {
1571         my $usr = "/usr/$config{cross_compile_prefix}";
1572         chop($usr);
1573         if ($config{cross_compile_prefix} eq "") {
1574             $usr = "/usr";
1575         }
1576         my $minver = (4 << 16) + (13 << 8) + 0;
1577         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1578
1579         if ($verstr[2] < $minver) {
1580             disable('too-old-kernel', 'ktls');
1581         }
1582     } elsif ($target =~ m/^BSD/) {
1583         my $cc = $config{CROSS_COMPILE}.$config{CC};
1584         system("printf '#include <sys/types.h>\n#include <sys/ktls.h>' | $cc -E - >/dev/null 2>&1");
1585         if ($? != 0) {
1586             disable('too-old-freebsd', 'ktls');
1587         }
1588     } else {
1589         disable('not-linux-or-freebsd', 'ktls');
1590     }
1591 }
1592
1593 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1594
1595 # Get the extra flags used when building shared libraries and modules.  We
1596 # do this late because some of them depend on %disabled.
1597
1598 # Make the flags to build DSOs the same as for shared libraries unless they
1599 # are already defined
1600 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1601 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1602 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1603 {
1604     my $shared_info_pl =
1605         catfile(dirname($0), "Configurations", "shared-info.pl");
1606     my %shared_info = read_eval_file($shared_info_pl);
1607     push @{$target{_conf_fname_int}}, $shared_info_pl;
1608     my $si = $target{shared_target};
1609     while (ref $si ne "HASH") {
1610         last if ! defined $si;
1611         if (ref $si eq "CODE") {
1612             $si = $si->();
1613         } else {
1614             $si = $shared_info{$si};
1615         }
1616     }
1617
1618     # Some of the 'shared_target' values don't have any entries in
1619     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1620     # template knows how to handle this.  That is currently the case for
1621     # Windows and VMS.
1622     if (defined $si) {
1623         # Just as above, copy certain shared_* attributes to the corresponding
1624         # module_ attribute unless the latter is already defined
1625         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1626         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1627         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1628         foreach (sort keys %$si) {
1629             $target{$_} = defined $target{$_}
1630                 ? add($si->{$_})->($target{$_})
1631                 : $si->{$_};
1632         }
1633     }
1634 }
1635
1636 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1637
1638 ######################################################################
1639 # Build up information for skipping certain directories depending on disabled
1640 # features, as well as setting up macros for disabled features.
1641
1642 # This is a tentative database of directories to skip.  Some entries may not
1643 # correspond to anything real, but that's ok, they will simply be ignored.
1644 # The actual processing of these entries is done in the build.info lookup
1645 # loop further down.
1646 #
1647 # The key is a Unix formatted path in the source tree, the value is an index
1648 # into %disabled_info, so any existing path gets added to a corresponding
1649 # 'skipped' entry in there with the list of skipped directories.
1650 my %skipdir = ();
1651 my %disabled_info = ();         # For configdata.pm
1652 foreach my $what (sort keys %disabled) {
1653     # There are deprecated disablables that translate to themselves.
1654     # They cause disabling cascades, but should otherwise not regiter.
1655     next if $deprecated_disablables{$what};
1656     # The generated $disabled{"deprecated-x.y"} entries are special
1657     # and treated properly elsewhere
1658     next if $what =~ m|^deprecated-|;
1659
1660     $config{options} .= " no-$what";
1661
1662     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1663                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1664                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1665         (my $WHAT = uc $what) =~ s|-|_|g;
1666         my $skipdir = $what;
1667
1668         # fix-up crypto/directory name(s)
1669         $skipdir = "ripemd" if $what eq "rmd160";
1670         $skipdir = "whrlpool" if $what eq "whirlpool";
1671
1672         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1673         push @{$config{openssl_feature_defines}}, $macro;
1674
1675         $skipdir{engines} = $what if $what eq 'engine';
1676         $skipdir{"crypto/$skipdir"} = $what
1677             unless $what eq 'async' || $what eq 'err' || $what eq 'dso';
1678     }
1679 }
1680
1681 if ($disabled{"dynamic-engine"}) {
1682     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1683 } else {
1684     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1685 }
1686
1687 # If we use the unified build, collect information from build.info files
1688 my %unified_info = ();
1689
1690 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1691 if ($builder eq "unified") {
1692     use Text::Template 1.46;
1693
1694     sub cleandir {
1695         my $base = shift;
1696         my $dir = shift;
1697         my $relativeto = shift || ".";
1698
1699         $dir = catdir($base,$dir) unless isabsolute($dir);
1700
1701         # Make sure the directories we're building in exists
1702         mkpath($dir);
1703
1704         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1705         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1706         return $res;
1707     }
1708
1709     sub cleanfile {
1710         my $base = shift;
1711         my $file = shift;
1712         my $relativeto = shift || ".";
1713
1714         $file = catfile($base,$file) unless isabsolute($file);
1715
1716         my $d = dirname($file);
1717         my $f = basename($file);
1718
1719         # Make sure the directories we're building in exists
1720         mkpath($d);
1721
1722         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1723         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1724         return $res;
1725     }
1726
1727     # Store the name of the template file we will build the build file from
1728     # in %config.  This may be useful for the build file itself.
1729     my @build_file_template_names =
1730         ( $builder_platform."-".$target{build_file}.".tmpl",
1731           $target{build_file}.".tmpl" );
1732     my @build_file_templates = ();
1733
1734     # First, look in the user provided directory, if given
1735     if (defined env($local_config_envname)) {
1736         @build_file_templates =
1737             map {
1738                 if ($^O eq 'VMS') {
1739                     # VMS environment variables are logical names,
1740                     # which can be used as is
1741                     $local_config_envname . ':' . $_;
1742                 } else {
1743                     catfile(env($local_config_envname), $_);
1744                 }
1745             }
1746             @build_file_template_names;
1747     }
1748     # Then, look in our standard directory
1749     push @build_file_templates,
1750         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1751           @build_file_template_names );
1752
1753     my $build_file_template;
1754     for $_ (@build_file_templates) {
1755         $build_file_template = $_;
1756         last if -f $build_file_template;
1757
1758         $build_file_template = undef;
1759     }
1760     if (!defined $build_file_template) {
1761         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1762     }
1763     $config{build_file_templates}
1764       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1765                     $blddir),
1766           $build_file_template,
1767           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1768                     $blddir) ];
1769
1770     my @build_dirs = ( [ ] );   # current directory
1771
1772     $config{build_infos} = [ ];
1773
1774     my %ordinals = ();
1775     while (@build_dirs) {
1776         my @curd = @{shift @build_dirs};
1777         my $sourced = catdir($srcdir, @curd);
1778         my $buildd = catdir($blddir, @curd);
1779
1780         my $unixdir = join('/', @curd);
1781         if (exists $skipdir{$unixdir}) {
1782             my $what = $skipdir{$unixdir};
1783             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1784             next;
1785         }
1786
1787         mkpath($buildd);
1788
1789         my $f = 'build.info';
1790         # The basic things we're trying to build
1791         my @programs = ();
1792         my @libraries = ();
1793         my @modules = ();
1794         my @scripts = ();
1795
1796         my %sources = ();
1797         my %shared_sources = ();
1798         my %includes = ();
1799         my %defines = ();
1800         my %depends = ();
1801         my %generate = ();
1802         my %htmldocs = ();
1803         my %mandocs = ();
1804
1805         # Support for $variablename in build.info files.
1806         # Embedded perl code is the ultimate master, still.  If its output
1807         # contains a dollar sign, it had better be escaped, or it will be
1808         # taken for a variable name prefix.
1809         my %variables = ();
1810         # Variable name syntax
1811         my $variable_name_re = qr/(?P<VARIABLE>[[:alpha:]][[:alnum:]_]*)/;
1812         # Value modifier syntaxes
1813         my $variable_subst_re = qr/\/(?P<RE>(?:\\\/|.)*?)\/(?P<SUBST>.*?)/;
1814         # Put it all together
1815         my $variable_re = qr/\$
1816                              (?|
1817                                  # Simple case, just the name
1818                                  ${variable_name_re}
1819                              |
1820                                  # Expressive case, with braces and possible
1821                                  # modifier expressions
1822                                  \{
1823                                  ${variable_name_re}
1824                                  (?:
1825                                      # Pile on modifier expressions,
1826                                      # separated by |
1827                                      ${variable_subst_re}
1828                                  )
1829                                  \}
1830                              )/x;
1831         my $expand_variables = sub {
1832             my $value = '';
1833             my $value_rest = shift;
1834
1835             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1836                 print STDERR
1837                     "DEBUG[\$expand_variables] Parsed '$value_rest' ...\n"
1838             }
1839             while ($value_rest =~ /(?<!\\)${variable_re}/) {
1840                 $value_rest = $';
1841                 $value .= $`;
1842
1843                 my $variable_value = $variables{$+{VARIABLE}};
1844
1845                 # Process modifier expressions, if present
1846                 if (defined $+{RE}) {
1847                     # We must save important %+ values, because the s///
1848                     # below clears them
1849                     my $re = $+{RE};
1850                     my $subst = $+{SUBST};
1851
1852                     $variable_value =~ s/\Q$re\E/$subst/g;
1853
1854                     if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1855                         print STDERR
1856                             "DEBUG[\$expand_variables] ... and substituted ",
1857                             "'$re' with '$subst'\n";
1858                     }
1859                 }
1860
1861                 $value .= $variable_value;
1862             }
1863             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1864                 print STDERR
1865                     "DEBUG[\$expand_variables] ... into: '$value$value_rest'\n";
1866             }
1867             return $value . $value_rest;
1868         };
1869
1870         # Support for attributes in build.info files
1871         my %attributes = ();
1872         my $handle_attributes = sub {
1873             my $attr_str = shift;
1874             my $ref = shift;
1875             my @goals = @_;
1876
1877             return unless defined $attr_str;
1878
1879             my @a = tokenize($attr_str, qr|\s*,\s*|);
1880             foreach my $a (@a) {
1881                 my $ac = 1;
1882                 my $ak = $a;
1883                 my $av = 1;
1884                 if ($a =~ m|^(!)?(.*?)\s* = \s*(.*?)$|) {
1885                     $ac = ! $1;
1886                     $ak = $1;
1887                     $av = $2;
1888                 }
1889                 foreach my $g (@goals) {
1890                     if ($ac) {
1891                         $$ref->{$g}->{$ak} = $av;
1892                     } else {
1893                         delete $$ref->{$g}->{$ak};
1894                     }
1895                 }
1896             }
1897         };
1898
1899         # Support for pushing values on multiple indexes of a given hash
1900         # array.
1901         my $push_to = sub {
1902             my $valueref = shift;
1903             my $index_str = shift; # May be undef or empty
1904             my $attrref = shift;   # May be undef
1905             my $attr_str = shift;
1906             my @values = @_;
1907
1908             if (defined $index_str) {
1909                 my @indexes = ( '' );
1910                 if ($index_str !~ m|^\s*$|) {
1911                     @indexes = tokenize($index_str);
1912                 }
1913                 foreach (@indexes) {
1914                     push @{$valueref->{$_}}, @values;
1915                     if (defined $attrref) {
1916                         $handle_attributes->($attr_str, \$$attrref->{$_},
1917                                              @values);
1918                     }
1919                 }
1920             } else {
1921                 push @$valueref, @values;
1922                 $handle_attributes->($attr_str, $attrref, @values)
1923                     if defined $attrref;
1924             }
1925         };
1926
1927         # We want to detect configdata.pm in the source tree, so we
1928         # don't use it if the build tree is different.
1929         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1930
1931
1932         if ($buildinfo_debug) {
1933             print STDERR "DEBUG: Reading ",catfile($sourced, $f),"\n";
1934         }
1935         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1936         my $template =
1937             Text::Template->new(TYPE => 'FILE',
1938                                 SOURCE => catfile($sourced, $f),
1939                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1940         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1941         my @text =
1942             split /^/m,
1943             $template->fill_in(HASH => { config => \%config,
1944                                          target => \%target,
1945                                          disabled => \%disabled,
1946                                          withargs => \%withargs,
1947                                          builddir => abs2rel($buildd, $blddir),
1948                                          sourcedir => abs2rel($sourced, $blddir),
1949                                          buildtop => abs2rel($blddir, $blddir),
1950                                          sourcetop => abs2rel($srcdir, $blddir) },
1951                                DELIMITERS => [ "{-", "-}" ]);
1952
1953         # The top item of this stack has the following values
1954         # -2 positive already run and we found ELSE (following ELSIF should fail)
1955         # -1 positive already run (skip until ENDIF)
1956         # 0 negatives so far (if we're at a condition, check it)
1957         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1958         # 2 positive ELSE (following ELSIF should fail)
1959         my @skip = ();
1960
1961         # A few useful generic regexps
1962         my $index_re = qr/\[\s*(?P<INDEX>(?:\\.|.)*?)\s*\]/;
1963         my $cond_re = qr/\[\s*(?P<COND>(?:\\.|.)*?)\s*\]/;
1964         my $attribs_re = qr/(?:\{\s*(?P<ATTRIBS>(?:\\.|.)*?)\s*\})?/;
1965         my $value_re = qr/\s*(?P<VALUE>.*?)\s*/;
1966         collect_information(
1967             collect_from_array([ @text ],
1968                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1969                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1970             # Info we're looking for
1971             qr/^\s* IF ${cond_re} \s*$/x
1972             => sub {
1973                 if (! @skip || $skip[$#skip] > 0) {
1974                     push @skip, !! $expand_variables->($+{COND});
1975                 } else {
1976                     push @skip, -1;
1977                 }
1978             },
1979             qr/^\s* ELSIF ${cond_re} \s*$/x
1980             => sub { die "ELSIF out of scope" if ! @skip;
1981                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1982                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1983                      $skip[$#skip] = !! $expand_variables->($+{COND})
1984                          if $skip[$#skip] == 0; },
1985             qr/^\s* ELSE \s*$/x
1986             => sub { die "ELSE out of scope" if ! @skip;
1987                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1988                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1989             qr/^\s* ENDIF \s*$/x
1990             => sub { die "ENDIF out of scope" if ! @skip;
1991                      pop @skip; },
1992             qr/^\s* ${variable_re} \s* = ${value_re} $/x
1993             => sub {
1994                 if (!@skip || $skip[$#skip] > 0) {
1995                     $variables{$+{VARIABLE}} = $expand_variables->($+{VALUE});
1996                 }
1997             },
1998             qr/^\s* SUBDIRS \s* = ${value_re} $/x
1999             => sub {
2000                 if (!@skip || $skip[$#skip] > 0) {
2001                     foreach (tokenize($expand_variables->($+{VALUE}))) {
2002                         push @build_dirs, [ @curd, splitdir($_, 1) ];
2003                     }
2004                 }
2005             },
2006             qr/^\s* PROGRAMS ${attribs_re} \s* =  ${value_re} $/x
2007             => sub { $push_to->(\@programs, undef,
2008                                 \$attributes{programs}, $+{ATTRIBS},
2009                                 tokenize($expand_variables->($+{VALUE})))
2010                          if !@skip || $skip[$#skip] > 0; },
2011             qr/^\s* LIBS ${attribs_re} \s* =  ${value_re} $/x
2012             => sub { $push_to->(\@libraries, undef,
2013                                 \$attributes{libraries}, $+{ATTRIBS},
2014                                 tokenize($expand_variables->($+{VALUE})))
2015                          if !@skip || $skip[$#skip] > 0; },
2016             qr/^\s* MODULES ${attribs_re} \s* =  ${value_re} $/x
2017             => sub { $push_to->(\@modules, undef,
2018                                 \$attributes{modules}, $+{ATTRIBS},
2019                                 tokenize($expand_variables->($+{VALUE})))
2020                          if !@skip || $skip[$#skip] > 0; },
2021             qr/^\s* SCRIPTS ${attribs_re} \s* =  ${value_re} $/x
2022             => sub { $push_to->(\@scripts, undef,
2023                                 \$attributes{scripts}, $+{ATTRIBS},
2024                                 tokenize($expand_variables->($+{VALUE})))
2025                          if !@skip || $skip[$#skip] > 0; },
2026             qr/^\s* HTMLDOCS ${index_re} = ${value_re} $/x
2027             => sub { $push_to->(\%htmldocs, $expand_variables->($+{INDEX}),
2028                                 undef, undef,
2029                                 tokenize($expand_variables->($+{VALUE})))
2030                          if !@skip || $skip[$#skip] > 0; },
2031             qr/^\s* MANDOCS ${index_re} = ${value_re} $/x
2032             => sub { $push_to->(\%mandocs, $expand_variables->($+{INDEX}),
2033                                 undef, undef,
2034                                 tokenize($expand_variables->($+{VALUE})))
2035                          if !@skip || $skip[$#skip] > 0; },
2036             qr/^\s* SOURCE ${index_re} = ${value_re} $/x
2037             => sub { $push_to->(\%sources, $expand_variables->($+{INDEX}),
2038                                 undef, undef,
2039                                 tokenize($expand_variables->($+{VALUE})))
2040                          if !@skip || $skip[$#skip] > 0; },
2041             qr/^\s* SHARED_SOURCE ${index_re} = ${value_re} $/x
2042             => sub { $push_to->(\%shared_sources, $expand_variables->($+{INDEX}),
2043                                 undef, undef,
2044                                 tokenize($expand_variables->($+{VALUE})))
2045                          if !@skip || $skip[$#skip] > 0; },
2046             qr/^\s* INCLUDE ${index_re} = ${value_re} $/x
2047             => sub { $push_to->(\%includes, $expand_variables->($+{INDEX}),
2048                                 undef, undef,
2049                                 tokenize($expand_variables->($+{VALUE})))
2050                          if !@skip || $skip[$#skip] > 0; },
2051             qr/^\s* DEFINE ${index_re} = ${value_re} $/x
2052             => sub { $push_to->(\%defines, $expand_variables->($+{INDEX}),
2053                                 undef, undef,
2054                                 tokenize($expand_variables->($+{VALUE})))
2055                          if !@skip || $skip[$#skip] > 0; },
2056             qr/^\s* DEPEND ${index_re} ${attribs_re} = ${value_re} $/x
2057             => sub { $push_to->(\%depends, $expand_variables->($+{INDEX}),
2058                                 \$attributes{depends}, $+{ATTRIBS},
2059                                 tokenize($expand_variables->($+{VALUE})))
2060                          if !@skip || $skip[$#skip] > 0; },
2061             qr/^\s* GENERATE ${index_re} = ${value_re} $/x
2062             => sub { $push_to->(\%generate, $expand_variables->($+{INDEX}),
2063                                 undef, undef, $+{VALUE})
2064                          if !@skip || $skip[$#skip] > 0; },
2065             qr/^\s* (?:\#.*)? $/x => sub { },
2066             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
2067             "BEFORE" => sub {
2068                 if ($buildinfo_debug) {
2069                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
2070                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2071                 }
2072             },
2073             "AFTER" => sub {
2074                 if ($buildinfo_debug) {
2075                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2076                 }
2077             },
2078             );
2079         die "runaway IF?" if (@skip);
2080
2081         if (grep { defined $attributes{modules}->{$_}->{engine} } keys %attributes
2082                 and !$config{dynamic_engines}) {
2083             die <<"EOF"
2084 ENGINES can only be used if configured with 'dynamic-engine'.
2085 This is usually a fault in a build.info file.
2086 EOF
2087         }
2088
2089         {
2090             my %infos = ( programs  => [ @programs  ],
2091                           libraries => [ @libraries ],
2092                           modules   => [ @modules   ],
2093                           scripts   => [ @scripts   ] );
2094             foreach my $k (keys %infos) {
2095                 foreach (@{$infos{$k}}) {
2096                     my $item = cleanfile($buildd, $_, $blddir);
2097                     $unified_info{$k}->{$item} = 1;
2098
2099                     # Fix up associated attributes
2100                     $unified_info{attributes}->{$k}->{$item} =
2101                         $attributes{$k}->{$_}
2102                         if defined $attributes{$k}->{$_};
2103                 }
2104             }
2105         }
2106
2107         # Check that we haven't defined any library as both shared and
2108         # explicitly static.  That is forbidden.
2109         my @doubles = ();
2110         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2111             (my $l = $_) =~ s/\.a$//;
2112             push @doubles, $l if defined $unified_info{libraries}->{$l};
2113         }
2114         die "these libraries are both explicitly static and shared:\n  ",
2115             join(" ", @doubles), "\n"
2116             if @doubles;
2117
2118         foreach (keys %sources) {
2119             my $dest = $_;
2120             my $ddest = cleanfile($buildd, $_, $blddir);
2121             foreach (@{$sources{$dest}}) {
2122                 my $s = cleanfile($sourced, $_, $blddir);
2123
2124                 # If it's generated or we simply don't find it in the source
2125                 # tree, we assume it's in the build tree.
2126                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2127                     $s = cleanfile($buildd, $_, $blddir);
2128                 }
2129                 # We recognise C++, C and asm files
2130                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2131                     my $o = $_;
2132                     $o =~ s/\.[csS]$/.o/; # C and assembler
2133                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2134                     $o = cleanfile($buildd, $o, $blddir);
2135                     $unified_info{sources}->{$ddest}->{$o} = -1;
2136                     $unified_info{sources}->{$o}->{$s} = -1;
2137                 } elsif ($s =~ /\.rc$/) {
2138                     # We also recognise resource files
2139                     my $o = $_;
2140                     $o =~ s/\.rc$/.res/; # Resource configuration
2141                     my $o = cleanfile($buildd, $o, $blddir);
2142                     $unified_info{sources}->{$ddest}->{$o} = -1;
2143                     $unified_info{sources}->{$o}->{$s} = -1;
2144                 } else {
2145                     $unified_info{sources}->{$ddest}->{$s} = 1;
2146                 }
2147             }
2148         }
2149
2150         foreach (keys %shared_sources) {
2151             my $dest = $_;
2152             my $ddest = cleanfile($buildd, $_, $blddir);
2153             foreach (@{$shared_sources{$dest}}) {
2154                 my $s = cleanfile($sourced, $_, $blddir);
2155
2156                 # If it's generated or we simply don't find it in the source
2157                 # tree, we assume it's in the build tree.
2158                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2159                     $s = cleanfile($buildd, $_, $blddir);
2160                 }
2161
2162                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2163                     # We recognise C++, C and asm files
2164                     my $o = $_;
2165                     $o =~ s/\.[csS]$/.o/; # C and assembler
2166                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2167                     $o = cleanfile($buildd, $o, $blddir);
2168                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2169                     $unified_info{sources}->{$o}->{$s} = -1;
2170                 } elsif ($s =~ /\.rc$/) {
2171                     # We also recognise resource files
2172                     my $o = $_;
2173                     $o =~ s/\.rc$/.res/; # Resource configuration
2174                     my $o = cleanfile($buildd, $o, $blddir);
2175                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2176                     $unified_info{sources}->{$o}->{$s} = -1;
2177                 } elsif ($s =~ /\.ld$/) {
2178                     # We also recognise linker scripts (or corresponding)
2179                     # We know they are generated files
2180                     my $ld = cleanfile($buildd, $_, $blddir);
2181                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2182                 } else {
2183                     die "unrecognised source file type for shared library: $s\n";
2184                 }
2185             }
2186         }
2187
2188         foreach (keys %generate) {
2189             my $dest = $_;
2190             my $ddest = cleanfile($buildd, $_, $blddir);
2191             die "more than one generator for $dest: "
2192                 ,join(" ", @{$generate{$_}}),"\n"
2193                 if scalar @{$generate{$_}} > 1;
2194             my @generator = split /\s+/, $generate{$dest}->[0];
2195             my $gen = $generator[0];
2196             $generator[0] = cleanfile($sourced, $gen, $blddir);
2197
2198             # If the generator is itself generated, it's in the build tree
2199             if ($generate{$gen}) {
2200                 $generator[0] = cleanfile($buildd, $gen, $blddir);
2201             }
2202
2203             $unified_info{generate}->{$ddest} = [ @generator ];
2204         }
2205
2206         foreach (keys %depends) {
2207             my $dest = $_;
2208             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2209
2210             # If the destination doesn't exist in source, it can only be
2211             # a generated file in the build tree.
2212             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2213                 $ddest = cleanfile($buildd, $_, $blddir);
2214             }
2215             foreach (@{$depends{$dest}}) {
2216                 my $d = cleanfile($sourced, $_, $blddir);
2217
2218                 # If we know it's generated, or assume it is because we can't
2219                 # find it in the source tree, we set file we depend on to be
2220                 # in the build tree rather than the source tree.
2221                 if ($d eq $src_configdata
2222                     || (grep { $d eq $_ }
2223                         map { cleanfile($srcdir, $_, $blddir) }
2224                         grep { /\.h$/ } keys %{$unified_info{generate}})
2225                     || ! -f $d) {
2226                     $d = cleanfile($buildd, $_, $blddir);
2227                 }
2228                 $unified_info{depends}->{$ddest}->{$d} = 1;
2229
2230                 # Fix up associated attributes
2231                 $unified_info{attributes}->{depends}->{$ddest}->{$d} =
2232                     $attributes{depends}->{$dest}->{$_}
2233                     if defined $attributes{depends}->{$dest}->{$_};
2234             }
2235         }
2236
2237         foreach (keys %includes) {
2238             my $dest = $_;
2239             my $ddest = cleanfile($sourced, $_, $blddir);
2240
2241             # If the destination doesn't exist in source, it can only be
2242             # a generated file in the build tree.
2243             if ($ddest eq $src_configdata || ! -f $ddest) {
2244                 $ddest = cleanfile($buildd, $_, $blddir);
2245             }
2246             foreach (@{$includes{$dest}}) {
2247                 my $is = cleandir($sourced, $_, $blddir);
2248                 my $ib = cleandir($buildd, $_, $blddir);
2249                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2250                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2251                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2252                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2253             }
2254         }
2255
2256         foreach my $dest (keys %defines) {
2257             my $ddest;
2258
2259             if ($dest ne "") {
2260                 $ddest = cleanfile($sourced, $dest, $blddir);
2261
2262                 # If the destination doesn't exist in source, it can only
2263                 # be a generated file in the build tree.
2264                 if (! -f $ddest) {
2265                     $ddest = cleanfile($buildd, $dest, $blddir);
2266                 }
2267             }
2268             foreach my $v (@{$defines{$dest}}) {
2269                 $v =~ m|^([^=]*)(=.*)?$|;
2270                 die "0 length macro name not permitted\n" if $1 eq "";
2271                 if ($dest ne "") {
2272                     die "$1 defined more than once\n"
2273                         if defined $unified_info{defines}->{$ddest}->{$1};
2274                     $unified_info{defines}->{$ddest}->{$1} = $2;
2275                 } else {
2276                     die "$1 defined more than once\n"
2277                         if grep { $v eq $_ } @{$config{defines}};
2278                     push @{$config{defines}}, $v;
2279                 }
2280             }
2281         }
2282
2283         foreach my $section (keys %htmldocs) {
2284             foreach (@{$htmldocs{$section}}) {
2285                 my $htmldocs = cleanfile($buildd, $_, $blddir);
2286                 $unified_info{htmldocs}->{$section}->{$htmldocs} = 1;
2287             }
2288         }
2289
2290         foreach my $section (keys %mandocs) {
2291             foreach (@{$mandocs{$section}}) {
2292                 my $mandocs = cleanfile($buildd, $_, $blddir);
2293                 $unified_info{mandocs}->{$section}->{$mandocs} = 1;
2294             }
2295         }
2296     }
2297
2298     my $ordinals_text = join(', ', sort keys %ordinals);
2299     warn <<"EOF" if $ordinals_text;
2300
2301 WARNING: ORDINALS were specified for $ordinals_text
2302 They are ignored and should be replaced with a combination of GENERATE,
2303 DEPEND and SHARED_SOURCE.
2304 EOF
2305
2306
2307     # Go through the sources of all libraries and check that the same basename
2308     # doesn't appear more than once.  Some static library archivers depend on
2309     # them being unique.
2310     {
2311         my $err = 0;
2312         foreach my $prod (keys %{$unified_info{libraries}}) {
2313             my @prod_sources =
2314                 map { keys %{$unified_info{sources}->{$_}} }
2315                 keys %{$unified_info{sources}->{$prod}};
2316             my %srccnt = ();
2317
2318             # Count how many times a given each source basename
2319             # appears for each product.
2320             foreach my $src (@prod_sources) {
2321                 $srccnt{basename $src}++;
2322             }
2323
2324             foreach my $src (keys %srccnt) {
2325                 if ((my $cnt = $srccnt{$src}) > 1) {
2326                     print STDERR "$src appears $cnt times for the product $prod\n";
2327                     $err++
2328                 }
2329             }
2330         }
2331         die if $err > 0;
2332     }
2333
2334     # Massage the result
2335
2336     # If we depend on a header file or a perl module, add an inclusion of
2337     # its directory to allow smoothe inclusion
2338     foreach my $dest (keys %{$unified_info{depends}}) {
2339         next if $dest eq "";
2340         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2341             next unless $d =~ /\.(h|pm)$/;
2342             my $i = dirname($d);
2343             my $spot =
2344                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2345                 ? 'build' : 'source';
2346             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2347                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2348         }
2349     }
2350
2351     # Go through all intermediary files and change their names to something that
2352     # reflects what they will be built for.  Note that for some source files,
2353     # this leads to duplicate object files because they are used multiple times.
2354     # the goal is to rename all object files according to this scheme:
2355     #    {productname}-{midfix}-{origobjname}.[o|res]
2356     # the {midfix} is a keyword indicating the type of product, which is mostly
2357     # valuable for libraries since they come in two forms.
2358     #
2359     # This also reorganises the {sources} and {shared_sources} so that the
2360     # former only contains ALL object files that are supposed to end up in
2361     # static libraries and programs, while the latter contains ALL object files
2362     # that are supposed to end up in shared libraries and DSOs.
2363     # The main reason for having two different source structures is to allow
2364     # the same name to be used for the static and the shared variants of a
2365     # library.
2366     {
2367         # Take copies so we don't get interference from added stuff
2368         my %unified_copy = ();
2369         foreach (('sources', 'shared_sources')) {
2370             $unified_copy{$_} = { %{$unified_info{$_}} }
2371                 if defined($unified_info{$_});
2372             delete $unified_info{$_};
2373         }
2374         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2375             # $intent serves multi purposes:
2376             # - give a prefix for the new object files names
2377             # - in the case of libraries, rearrange the object files so static
2378             #   libraries use the 'sources' structure exclusively, while shared
2379             #   libraries use the 'shared_sources' structure exclusively.
2380             my $intent = {
2381                 programs  => { bin    => { src => [ 'sources' ],
2382                                            dst => 'sources' } },
2383                 libraries => { lib    => { src => [ 'sources' ],
2384                                            dst => 'sources' },
2385                                shlib  => { prodselect =>
2386                                                sub { grep !/\.a$/, @_ },
2387                                            src => [ 'sources',
2388                                                     'shared_sources' ],
2389                                            dst => 'shared_sources' } },
2390                 modules   => { dso    => { src => [ 'sources' ],
2391                                            dst => 'sources' } },
2392                 scripts   => { script => { src => [ 'sources' ],
2393                                            dst => 'sources' } }
2394                } -> {$prodtype};
2395             foreach my $kind (keys %$intent) {
2396                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2397                              && $disabled{shared});
2398
2399                 my @src = @{$intent->{$kind}->{src}};
2400                 my $dst = $intent->{$kind}->{dst};
2401                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2402                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2403                     # %prod_sources has all applicable objects as keys, and
2404                     # their corresponding sources as values
2405                     my %prod_sources =
2406                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2407                         map { keys %{$unified_copy{$_}->{$prod}} }
2408                         @src;
2409                     foreach (keys %prod_sources) {
2410                         # Only affect object files and resource files,
2411                         # the others simply get a new value
2412                         # (+1 instead of -1)
2413                         if ($_ =~ /\.(o|res)$/) {
2414                             (my $prodname = $prod) =~ s|\.a$||;
2415                             my $newobj =
2416                                 catfile(dirname($_),
2417                                         basename($prodname)
2418                                             . '-' . $kind
2419                                             . '-' . basename($_));
2420                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2421                             foreach my $src (@{$prod_sources{$_}}) {
2422                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2423                             }
2424                             # Adjust dependencies
2425                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2426                                 $unified_info{depends}->{$_}->{$deps} = -1;
2427                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2428                             }
2429                             # Adjust includes
2430                             foreach my $k (('source', 'build')) {
2431                                 next unless
2432                                     defined($unified_info{includes}->{$_}->{$k});
2433                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2434                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2435                             }
2436                         } else {
2437                             $unified_info{$dst}->{$prod}->{$_} = 1;
2438                         }
2439                     }
2440                 }
2441             }
2442         }
2443     }
2444
2445     # At this point, we have a number of sources with the value -1.  They
2446     # aren't part of the local build and are probably meant for a different
2447     # platform, and can therefore be cleaned away.  That happens when making
2448     # %unified_info more efficient below.
2449
2450     ### Make unified_info a bit more efficient
2451     # One level structures
2452     foreach (("programs", "libraries", "modules", "scripts")) {
2453         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2454     }
2455     # Two level structures
2456     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends",
2457                      "htmldocs", "mandocs")) {
2458         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2459             my @items =
2460                 sort
2461                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2462                 keys %{$unified_info{$l1}->{$l2}};
2463             if (@items) {
2464                 $unified_info{$l1}->{$l2} = [ @items ];
2465             } else {
2466                 delete $unified_info{$l1}->{$l2};
2467             }
2468         }
2469     }
2470     # Defines
2471     foreach my $dest (sort keys %{$unified_info{defines}}) {
2472         $unified_info{defines}->{$dest}
2473             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2474                 sort keys %{$unified_info{defines}->{$dest}} ];
2475     }
2476     # Includes
2477     foreach my $dest (sort keys %{$unified_info{includes}}) {
2478         if (defined($unified_info{includes}->{$dest}->{build})) {
2479             my @source_includes = ();
2480             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2481                 if defined($unified_info{includes}->{$dest}->{source});
2482             $unified_info{includes}->{$dest} =
2483                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2484             foreach my $inc (@source_includes) {
2485                 push @{$unified_info{includes}->{$dest}}, $inc
2486                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2487             }
2488         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2489             $unified_info{includes}->{$dest} =
2490                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2491         } else {
2492             delete $unified_info{includes}->{$dest};
2493         }
2494     }
2495
2496     # For convenience collect information regarding directories where
2497     # files are generated, those generated files and the end product
2498     # they end up in where applicable.  Then, add build rules for those
2499     # directories
2500     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2501                      "dso" => [ @{$unified_info{modules}} ],
2502                      "bin" => [ @{$unified_info{programs}} ],
2503                      "script" => [ @{$unified_info{scripts}} ],
2504                      "docs" => [ (map { @{$unified_info{htmldocs}->{$_} // []} }
2505                                   keys %{$unified_info{htmldocs} // {}}),
2506                                  (map { @{$unified_info{mandocs}->{$_} // []} }
2507                                   keys %{$unified_info{mandocs} // {}}) ] );
2508     foreach my $type (keys %loopinfo) {
2509         foreach my $product (@{$loopinfo{$type}}) {
2510             my %dirs = ();
2511             my $pd = dirname($product);
2512
2513             foreach (@{$unified_info{sources}->{$product} // []},
2514                      @{$unified_info{shared_sources}->{$product} // []}) {
2515                 my $d = dirname($_);
2516
2517                 # We don't want to create targets for source directories
2518                 # when building out of source
2519                 next if ($config{sourcedir} ne $config{builddir}
2520                              && $d =~ m|^\Q$config{sourcedir}\E|);
2521                 # We already have a "test" target, and the current directory
2522                 # is just silly to make a target for
2523                 next if $d eq "test" || $d eq ".";
2524
2525                 $dirs{$d} = 1;
2526                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2527                     if $d ne $pd;
2528             }
2529             foreach (keys %dirs) {
2530                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2531                     $product;
2532             }
2533         }
2534     }
2535 }
2536
2537 # For the schemes that need it, we provide the old *_obj configs
2538 # from the *_asm_obj ones
2539 foreach (grep /_(asm|aux)_src$/, keys %target) {
2540     my $src = $_;
2541     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2542     $target{$obj} = $target{$src};
2543     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2544     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2545 }
2546
2547 # Write down our configuration where it fits #########################
2548
2549 my %template_vars = (
2550     config => \%config,
2551     target => \%target,
2552     disablables => \@disablables,
2553     disablables_int => \@disablables_int,
2554     disabled => \%disabled,
2555     withargs => \%withargs,
2556     unified_info => \%unified_info,
2557     tls => \@tls,
2558     dtls => \@dtls,
2559     makevars => [ sort keys %user ],
2560     disabled_info => \%disabled_info,
2561     user_crossable => \@user_crossable,
2562 );
2563 my $configdata_outname = 'configdata.pm';
2564 print "Creating $configdata_outname\n";
2565 open CONFIGDATA, ">$configdata_outname.new"
2566             or die "Trying to create $configdata_outname.new: $!";
2567 my $configdata_tmplname = cleanfile($srcdir, "configdata.pm.in", $blddir);
2568 my $configdata_tmpl =
2569     OpenSSL::Template->new(TYPE => 'FILE', SOURCE => $configdata_tmplname);
2570 $configdata_tmpl->fill_in(
2571     FILENAME => $configdata_tmplname,
2572     OUTPUT => \*CONFIGDATA,
2573     HASH => { %template_vars,
2574               autowarntext => [
2575                   'WARNING: do not edit!',
2576                   "Generated by Configure from $configdata_tmplname",
2577               ] }
2578 ) or die $Text::Template::ERROR;
2579 close CONFIGDATA;
2580 rename "$configdata_outname.new", $configdata_outname;
2581 if ($builder_platform eq 'unix') {
2582     my $mode = (0755 & ~umask);
2583     chmod $mode, 'configdata.pm'
2584         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2585 }
2586
2587 print "Running $configdata_outname\n";
2588 my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
2589 my $cmd = "$perlcmd $configdata_outname";
2590 #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2591 system($cmd);
2592 exit 1 if $? != 0;
2593
2594 $SIG{__DIE__} = $orig_death_handler;
2595
2596 print <<"EOF" if ($disabled{threads} eq "unavailable");
2597
2598 The library could not be configured for supporting multi-threaded
2599 applications as the compiler options required on this system are not known.
2600 See file INSTALL for details if you need multi-threading.
2601 EOF
2602
2603 print <<"EOF" if ($no_shared_warn);
2604
2605 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2606 platform, so we will pretend you gave the option 'no-pic', which also disables
2607 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2608 or position independent code, please let us know (but please first make sure
2609 you have tried with a current version of OpenSSL).
2610 EOF
2611
2612 print <<"EOF";
2613
2614 **********************************************************************
2615 ***                                                                ***
2616 ***   OpenSSL has been successfully configured                     ***
2617 ***                                                                ***
2618 ***   If you encounter a problem while building, please open an    ***
2619 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2620 ***   and include the output from the following command:           ***
2621 ***                                                                ***
2622 ***       perl configdata.pm --dump                                ***
2623 ***                                                                ***
2624 ***   (If you are new to OpenSSL, you might want to consult the    ***
2625 ***   'Troubleshooting' section in the INSTALL file first)         ***
2626 ***                                                                ***
2627 **********************************************************************
2628 EOF
2629
2630 exit(0);
2631
2632 ######################################################################
2633 #
2634 # Helpers and utility functions
2635 #
2636
2637 # Death handler, to print a helpful message in case of failure #######
2638 #
2639 sub death_handler {
2640     die @_ if $^S;              # To prevent the added message in eval blocks
2641     my $build_file = $target{build_file} // "build file";
2642     my @message = ( <<"_____", @_ );
2643
2644 Failure!  $build_file wasn't produced.
2645 Please read INSTALL and associated NOTES files.  You may also have to look over
2646 your available compiler tool chain or change your configuration.
2647
2648 _____
2649
2650     # Dying is terminal, so it's ok to reset the signal handler here.
2651     $SIG{__DIE__} = $orig_death_handler;
2652     die @message;
2653 }
2654
2655 # Configuration file reading #########################################
2656
2657 # Note: All of the helper functions are for lazy evaluation.  They all
2658 # return a CODE ref, which will return the intended value when evaluated.
2659 # Thus, whenever there's mention of a returned value, it's about that
2660 # intended value.
2661
2662 # Helper function to implement conditional value variants, with a default
2663 # plus additional values based on the value of $config{build_type}.
2664 # Arguments are given in hash table form:
2665 #
2666 #       picker(default => "Basic string: ",
2667 #              debug   => "debug",
2668 #              release => "release")
2669 #
2670 # When configuring with --debug, the resulting string will be
2671 # "Basic string: debug", and when not, it will be "Basic string: release"
2672 #
2673 # This can be used to create variants of sets of flags according to the
2674 # build type:
2675 #
2676 #       cflags => picker(default => "-Wall",
2677 #                        debug   => "-g -O0",
2678 #                        release => "-O3")
2679 #
2680 sub picker {
2681     my %opts = @_;
2682     return sub { add($opts{default} || (),
2683                      $opts{$config{build_type}} || ())->(); }
2684 }
2685
2686 # Helper function to combine several values of different types into one.
2687 # This is useful if you want to combine a string with the result of a
2688 # lazy function, such as:
2689 #
2690 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2691 #
2692 sub combine {
2693     my @stuff = @_;
2694     return sub { add(@stuff)->(); }
2695 }
2696
2697 # Helper function to implement conditional values depending on the value
2698 # of $disabled{threads}.  Can be used as follows:
2699 #
2700 #       cflags => combine("-Wall", threads("-pthread"))
2701 #
2702 sub threads {
2703     my @flags = @_;
2704     return sub { add($disabled{threads} ? () : @flags)->(); }
2705 }
2706
2707 sub shared {
2708     my @flags = @_;
2709     return sub { add($disabled{shared} ? () : @flags)->(); }
2710 }
2711
2712 our $add_called = 0;
2713 # Helper function to implement adding values to already existing configuration
2714 # values.  It handles elements that are ARRAYs, CODEs and scalars
2715 sub _add {
2716     my $separator = shift;
2717
2718     # If there's any ARRAY in the collection of values OR the separator
2719     # is undef, we will return an ARRAY of combined values, otherwise a
2720     # string of joined values with $separator as the separator.
2721     my $found_array = !defined($separator);
2722
2723     my @values =
2724         map {
2725             my $res = $_;
2726             while (ref($res) eq "CODE") {
2727                 $res = $res->();
2728             }
2729             if (defined($res)) {
2730                 if (ref($res) eq "ARRAY") {
2731                     $found_array = 1;
2732                     @$res;
2733                 } else {
2734                     $res;
2735                 }
2736             } else {
2737                 ();
2738             }
2739     } (@_);
2740
2741     $add_called = 1;
2742
2743     if ($found_array) {
2744         [ @values ];
2745     } else {
2746         join($separator, grep { defined($_) && $_ ne "" } @values);
2747     }
2748 }
2749 sub add_before {
2750     my $separator = " ";
2751     if (ref($_[$#_]) eq "HASH") {
2752         my $opts = pop;
2753         $separator = $opts->{separator};
2754     }
2755     my @x = @_;
2756     sub { _add($separator, @x, @_) };
2757 }
2758 sub add {
2759     my $separator = " ";
2760     if (ref($_[$#_]) eq "HASH") {
2761         my $opts = pop;
2762         $separator = $opts->{separator};
2763     }
2764     my @x = @_;
2765     sub { _add($separator, @_, @x) };
2766 }
2767
2768 sub read_eval_file {
2769     my $fname = shift;
2770     my $content;
2771     my @result;
2772
2773     open F, "< $fname" or die "Can't open '$fname': $!\n";
2774     {
2775         undef local $/;
2776         $content = <F>;
2777     }
2778     close F;
2779     {
2780         local $@;
2781
2782         @result = ( eval $content );
2783         warn $@ if $@;
2784     }
2785     return wantarray ? @result : $result[0];
2786 }
2787
2788 # configuration reader, evaluates the input file as a perl script and expects
2789 # it to fill %targets with target configurations.  Those are then added to
2790 # %table.
2791 sub read_config {
2792     my $fname = shift;
2793     my %targets;
2794
2795     {
2796         # Protect certain tables from tampering
2797         local %table = ();
2798
2799         %targets = read_eval_file($fname);
2800     }
2801     my %preexisting = ();
2802     foreach (sort keys %targets) {
2803         $preexisting{$_} = 1 if $table{$_};
2804     }
2805     die <<"EOF",
2806 The following config targets from $fname
2807 shadow pre-existing config targets with the same name:
2808 EOF
2809         map { "  $_\n" } sort keys %preexisting
2810         if %preexisting;
2811
2812
2813     # For each target, check that it's configured with a hash table.
2814     foreach (keys %targets) {
2815         if (ref($targets{$_}) ne "HASH") {
2816             if (ref($targets{$_}) eq "") {
2817                 warn "Deprecated target configuration for $_, ignoring...\n";
2818             } else {
2819                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2820             }
2821             delete $targets{$_};
2822         } else {
2823             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
2824         }
2825     }
2826
2827     %table = (%table, %targets);
2828
2829 }
2830
2831 # configuration resolver.  Will only resolve all the lazy evaluation
2832 # codeblocks for the chosen target and all those it inherits from,
2833 # recursively
2834 sub resolve_config {
2835     my $target = shift;
2836     my @breadcrumbs = @_;
2837
2838 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2839
2840     if (grep { $_ eq $target } @breadcrumbs) {
2841         die "inherit_from loop!  target backtrace:\n  "
2842             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2843     }
2844
2845     if (!defined($table{$target})) {
2846         warn "Warning! target $target doesn't exist!\n";
2847         return ();
2848     }
2849     # Recurse through all inheritances.  They will be resolved on the
2850     # fly, so when this operation is done, they will all just be a
2851     # bunch of attributes with string values.
2852     # What we get here, though, are keys with references to lists of
2853     # the combined values of them all.  We will deal with lists after
2854     # this stage is done.
2855     my %combined_inheritance = ();
2856     if ($table{$target}->{inherit_from}) {
2857         my @inherit_from =
2858             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2859         foreach (@inherit_from) {
2860             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2861
2862             # 'template' is a marker that's considered private to
2863             # the config that had it.
2864             delete $inherited_config{template};
2865
2866             foreach (keys %inherited_config) {
2867                 if (!$combined_inheritance{$_}) {
2868                     $combined_inheritance{$_} = [];
2869                 }
2870                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2871             }
2872         }
2873     }
2874
2875     # We won't need inherit_from in this target any more, since we've
2876     # resolved all the inheritances that lead to this
2877     delete $table{$target}->{inherit_from};
2878
2879     # Now is the time to deal with those lists.  Here's the place to
2880     # decide what shall be done with those lists, all based on the
2881     # values of the target we're currently dealing with.
2882     # - If a value is a coderef, it will be executed with the list of
2883     #   inherited values as arguments.
2884     # - If the corresponding key doesn't have a value at all or is the
2885     #   empty string, the inherited value list will be run through the
2886     #   default combiner (below), and the result becomes this target's
2887     #   value.
2888     # - Otherwise, this target's value is assumed to be a string that
2889     #   will simply override the inherited list of values.
2890     my $default_combiner = add();
2891
2892     my %all_keys =
2893         map { $_ => 1 } (keys %combined_inheritance,
2894                          keys %{$table{$target}});
2895
2896     sub process_values {
2897         my $object    = shift;
2898         my $inherited = shift;  # Always a [ list ]
2899         my $target    = shift;
2900         my $entry     = shift;
2901
2902         $add_called = 0;
2903
2904         while(ref($object) eq "CODE") {
2905             $object = $object->(@$inherited);
2906         }
2907         if (!defined($object)) {
2908             return ();
2909         }
2910         elsif (ref($object) eq "ARRAY") {
2911             local $add_called;  # To make sure recursive calls don't affect it
2912             return [ map { process_values($_, $inherited, $target, $entry) }
2913                      @$object ];
2914         } elsif (ref($object) eq "") {
2915             return $object;
2916         } else {
2917             die "cannot handle reference type ",ref($object)
2918                 ," found in target ",$target," -> ",$entry,"\n";
2919         }
2920     }
2921
2922     foreach (sort keys %all_keys) {
2923         my $previous = $combined_inheritance{$_};
2924
2925         # Current target doesn't have a value for the current key?
2926         # Assign it the default combiner, the rest of this loop body
2927         # will handle it just like any other coderef.
2928         if (!exists $table{$target}->{$_}) {
2929             $table{$target}->{$_} = $default_combiner;
2930         }
2931
2932         $table{$target}->{$_} = process_values($table{$target}->{$_},
2933                                                $combined_inheritance{$_},
2934                                                $target, $_);
2935         unless(defined($table{$target}->{$_})) {
2936             delete $table{$target}->{$_};
2937         }
2938 #        if ($extra_checks &&
2939 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2940 #            warn "$_ got replaced in $target\n";
2941 #        }
2942     }
2943
2944     # Finally done, return the result.
2945     return %{$table{$target}};
2946 }
2947
2948 sub usage
2949         {
2950         print STDERR $usage;
2951         print STDERR "\npick os/compiler from:\n";
2952         my $j=0;
2953         my $i;
2954         my $k=0;
2955         foreach $i (sort keys %table)
2956                 {
2957                 next if $table{$i}->{template};
2958                 next if $i =~ /^debug/;
2959                 $k += length($i) + 1;
2960                 if ($k > 78)
2961                         {
2962                         print STDERR "\n";
2963                         $k=length($i);
2964                         }
2965                 print STDERR $i . " ";
2966                 }
2967         foreach $i (sort keys %table)
2968                 {
2969                 next if $table{$i}->{template};
2970                 next if $i !~ /^debug/;
2971                 $k += length($i) + 1;
2972                 if ($k > 78)
2973                         {
2974                         print STDERR "\n";
2975                         $k=length($i);
2976                         }
2977                 print STDERR $i . " ";
2978                 }
2979         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2980         exit(1);
2981         }
2982
2983 sub compiler_predefined {
2984     state %predefined;
2985     my $cc = shift;
2986
2987     return () if $^O eq 'VMS';
2988
2989     die 'compiler_predefined called without a compiler command'
2990         unless $cc;
2991
2992     if (! $predefined{$cc}) {
2993
2994         $predefined{$cc} = {};
2995
2996         # collect compiler pre-defines from gcc or gcc-alike...
2997         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
2998         while (my $l = <PIPE>) {
2999             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3000             $predefined{$cc}->{$1} = $2 // '';
3001         }
3002         close(PIPE);
3003     }
3004
3005     return %{$predefined{$cc}};
3006 }
3007
3008 sub which
3009 {
3010     my ($name)=@_;
3011
3012     if (eval { require IPC::Cmd; 1; }) {
3013         IPC::Cmd->import();
3014         return scalar IPC::Cmd::can_run($name);
3015     } else {
3016         # if there is $directories component in splitpath,
3017         # then it's not something to test with $PATH...
3018         return $name if (File::Spec->splitpath($name))[1];
3019
3020         foreach (File::Spec->path()) {
3021             my $fullpath = catfile($_, "$name$target{exe_extension}");
3022             if (-f $fullpath and -x $fullpath) {
3023                 return $fullpath;
3024             }
3025         }
3026     }
3027 }
3028
3029 sub env
3030 {
3031     my $name = shift;
3032     my %opts = @_;
3033
3034     unless ($opts{cacheonly}) {
3035         # Note that if $ENV{$name} doesn't exist or is undefined,
3036         # $config{perlenv}->{$name} will be created with the value
3037         # undef.  This is intentional.
3038
3039         $config{perlenv}->{$name} = $ENV{$name}
3040             if ! exists $config{perlenv}->{$name};
3041     }
3042     return $config{perlenv}->{$name};
3043 }
3044
3045 # Configuration printer ##############################################
3046
3047 sub print_table_entry
3048 {
3049     local $now_printing = shift;
3050     my %target = resolve_config($now_printing);
3051     my $type = shift;
3052
3053     # Don't print the templates
3054     return if $target{template};
3055
3056     my @sequence = (
3057         "sys_id",
3058         "cpp",
3059         "cppflags",
3060         "defines",
3061         "includes",
3062         "cc",
3063         "cflags",
3064         "ld",
3065         "lflags",
3066         "loutflag",
3067         "ex_libs",
3068         "bn_ops",
3069         "poly1035_asm_src",
3070         "thread_scheme",
3071         "perlasm_scheme",
3072         "dso_scheme",
3073         "shared_target",
3074         "shared_cflag",
3075         "shared_defines",
3076         "shared_ldflag",
3077         "shared_rcflag",
3078         "shared_extension",
3079         "dso_extension",
3080         "obj_extension",
3081         "exe_extension",
3082         "ranlib",
3083         "ar",
3084         "arflags",
3085         "aroutflag",
3086         "rc",
3087         "rcflags",
3088         "rcoutflag",
3089         "mt",
3090         "mtflags",
3091         "mtinflag",
3092         "mtoutflag",
3093         "multilib",
3094         "build_scheme",
3095         );
3096
3097     if ($type eq "TABLE") {
3098         print "\n";
3099         print "*** $now_printing\n";
3100         foreach (@sequence) {
3101             if (ref($target{$_}) eq "ARRAY") {
3102                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3103             } else {
3104                 printf "\$%-12s = %s\n", $_, $target{$_};
3105             }
3106         }
3107     } elsif ($type eq "HASH") {
3108         my $largest =
3109             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3110         print "    '$now_printing' => {\n";
3111         foreach (@sequence) {
3112             if ($target{$_}) {
3113                 if (ref($target{$_}) eq "ARRAY") {
3114                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3115                 } else {
3116                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3117                 }
3118             }
3119         }
3120         print "    },\n";
3121     }
3122 }
3123
3124 # Utility routines ###################################################
3125
3126 # On VMS, if the given file is a logical name, File::Spec::Functions
3127 # will consider it an absolute path.  There are cases when we want a
3128 # purely syntactic check without checking the environment.
3129 sub isabsolute {
3130     my $file = shift;
3131
3132     # On non-platforms, we just use file_name_is_absolute().
3133     return file_name_is_absolute($file) unless $^O eq "VMS";
3134
3135     # If the file spec includes a device or a directory spec,
3136     # file_name_is_absolute() is perfectly safe.
3137     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3138
3139     # Here, we know the given file spec isn't absolute
3140     return 0;
3141 }
3142
3143 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3144 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3145 # realpath() requires that at least all path components except the last is an
3146 # existing directory.  On VMS, the last component of the directory spec must
3147 # exist.
3148 sub absolutedir {
3149     my $dir = shift;
3150
3151     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3152     # will return the volume name for the device, no matter what.  Also,
3153     # it will return an incorrect directory spec if the argument is a
3154     # directory that doesn't exist.
3155     if ($^O eq "VMS") {
3156         return rel2abs($dir);
3157     }
3158
3159     # We use realpath() on Unix, since no other will properly clean out
3160     # a directory spec.
3161     use Cwd qw/realpath/;
3162
3163     return realpath($dir);
3164 }
3165
3166 sub quotify {
3167     my %processors = (
3168         perl    => sub { my $x = shift;
3169                          $x =~ s/([\\\$\@"])/\\$1/g;
3170                          return '"'.$x.'"'; },
3171         maybeshell => sub { my $x = shift;
3172                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3173                             if ($x ne $y || $x =~ m|\s|) {
3174                                 return '"'.$y.'"';
3175                             } else {
3176                                 return $x;
3177                             }
3178                         },
3179         );
3180     my $for = shift;
3181     my $processor =
3182         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3183
3184     return map { $processor->($_); } @_;
3185 }
3186
3187 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3188 # $filename is a file name to read from
3189 # $line_concat_cond_re is a regexp detecting a line continuation ending
3190 # $line_concat is a CODEref that takes care of concatenating two lines
3191 sub collect_from_file {
3192     my $filename = shift;
3193     my $line_concat_cond_re = shift;
3194     my $line_concat = shift;
3195
3196     open my $fh, $filename || die "unable to read $filename: $!\n";
3197     return sub {
3198         my $saved_line = "";
3199         $_ = "";
3200         while (<$fh>) {
3201             s|\R$||;
3202             if (defined $line_concat) {
3203                 $_ = $line_concat->($saved_line, $_);
3204                 $saved_line = "";
3205             }
3206             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3207                 $saved_line = $_;
3208                 next;
3209             }
3210             return $_;
3211         }
3212         die "$filename ending with continuation line\n" if $_;
3213         close $fh;
3214         return undef;
3215     }
3216 }
3217
3218 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3219 # $array is an ARRAYref of lines
3220 # $line_concat_cond_re is a regexp detecting a line continuation ending
3221 # $line_concat is a CODEref that takes care of concatenating two lines
3222 sub collect_from_array {
3223     my $array = shift;
3224     my $line_concat_cond_re = shift;
3225     my $line_concat = shift;
3226     my @array = (@$array);
3227
3228     return sub {
3229         my $saved_line = "";
3230         $_ = "";
3231         while (defined($_ = shift @array)) {
3232             s|\R$||;
3233             if (defined $line_concat) {
3234                 $_ = $line_concat->($saved_line, $_);
3235                 $saved_line = "";
3236             }
3237             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3238                 $saved_line = $_;
3239                 next;
3240             }
3241             return $_;
3242         }
3243         die "input text ending with continuation line\n" if $_;
3244         return undef;
3245     }
3246 }
3247
3248 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3249 # $lineiterator is a CODEref that delivers one line at a time.
3250 # All following arguments are regex/CODEref pairs, where the regexp detects a
3251 # line and the CODEref does something with the result of the regexp.
3252 sub collect_information {
3253     my $lineiterator = shift;
3254     my %collectors = @_;
3255
3256     while(defined($_ = $lineiterator->())) {
3257         s|\R$||;
3258         my $found = 0;
3259         if ($collectors{"BEFORE"}) {
3260             $collectors{"BEFORE"}->($_);
3261         }
3262         foreach my $re (keys %collectors) {
3263             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3264                 $collectors{$re}->($lineiterator);
3265                 $found = 1;
3266             };
3267         }
3268         if ($collectors{"OTHERWISE"}) {
3269             $collectors{"OTHERWISE"}->($lineiterator, $_)
3270                 unless $found || !defined $collectors{"OTHERWISE"};
3271         }
3272         if ($collectors{"AFTER"}) {
3273             $collectors{"AFTER"}->($_);
3274         }
3275     }
3276 }
3277
3278 # tokenize($line)
3279 # tokenize($line,$separator)
3280 # $line is a line of text to split up into tokens
3281 # $separator [optional] is a regular expression that separates the tokens,
3282 # the default being spaces.  Do not use quotes of any kind as separators,
3283 # that will give undefined results.
3284 # Returns a list of tokens.
3285 #
3286 # Tokens are divided by separator (spaces by default).  If the tokens include
3287 # the separators, they have to be quoted with single or double quotes.
3288 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3289 # with backslash.
3290 # Basically, the same quoting rules apply for " and ' as in any
3291 # Unix shell.
3292 sub tokenize {
3293     my $line = my $debug_line = shift;
3294     my $separator = shift // qr|\s+|;
3295     my @result = ();
3296
3297     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3298         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3299     }
3300
3301     while ($line =~ s|^${separator}||, $line ne "") {
3302         my $token = "";
3303     again:
3304         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3305         $token .= $1;
3306         $line = $2.$';
3307
3308         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3309             $token .= $1;
3310             $line = $';
3311             goto again;
3312         } elsif ($line =~ m/^'([^']*)'/) {
3313             $token .= $1;
3314             $line = $';
3315             goto again;
3316         }
3317         push @result, $token;
3318     }
3319
3320     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3321         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3322         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3323     }
3324     return @result;
3325 }