test/recipes/80-test_ssl_new.t

   1 #! /usr/bin/env perl
   2 # Copyright 2015-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9
  10 use strict;
  11 use warnings;
  12
  13 use File::Basename;
  14 use File::Compare qw/compare_text/;
  15 use if $^O ne "VMS", 'File::Glob' => qw/glob/;
  16
  17 use OpenSSL::Test qw/:DEFAULT srctop_dir srctop_file/;
  18 use OpenSSL::Test::Utils qw/disabled alldisabled available_protocols/;
  19
  20 setup("test_ssl_new");
  21
  22 $ENV{TEST_CERTS_DIR} = srctop_dir("test", "certs");
  23 $ENV{CTLOG_FILE} = srctop_file("test", "ct", "log_list.conf");
  24
  25 my @conf_srcs =  glob(srctop_file("test", "ssl-tests", "*.conf.in"));
  26 map { s/;.*// } @conf_srcs if $^O eq "VMS";
  27 my @conf_files = map { basename($_) } @conf_srcs;
  28 map { s/\.in// } @conf_files;
  29
  30 # We hard-code the number of tests to double-check that the globbing above
  31 # finds all files as expected.
  32 plan tests => 14;  # = scalar @conf_srcs
  33
  34 # Some test results depend on the configuration of enabled protocols. We only
  35 # verify generated sources in the default configuration.
  36 my $is_default_tls = (disabled("ssl3") && !disabled("tls1") &&
  37                       !disabled("tls1_1") && !disabled("tls1_2"));
  38
  39 my $is_default_dtls = (!disabled("dtls1") && !disabled("dtls1_2"));
  40
  41 my $no_tls = alldisabled(available_protocols("tls"));
  42 my $no_dtls = alldisabled(available_protocols("dtls"));
  43 my $no_npn = disabled("nextprotoneg");
  44 my $no_ct = disabled("ct");
  45 my $no_ec = disabled("ec");
  46 my $no_ec2m = disabled("ec2m");
  47
  48 # Add your test here if the test conf.in generates test cases and/or
  49 # expectations dynamically based on the OpenSSL compile-time config.
  50 my %conf_dependent_tests = (
  51   "02-protocol-version.conf" => !$is_default_tls,
  52   "04-client_auth.conf" => !$is_default_tls,
  53   "07-dtls-protocol-version.conf" => !$is_default_dtls,
  54   "10-resumption.conf" => !$is_default_tls,
  55   "11-dtls_resumption.conf" => !$is_default_dtls,
  56 );
  57
  58 # Add your test here if it should be skipped for some compile-time
  59 # configurations. Default is $no_tls but some tests have different skip
  60 # conditions.
  61 my %skip = (
  62   "07-dtls-protocol-version.conf" => $no_dtls,
  63   "08-npn.conf" => $no_tls || $no_npn,
  64   "10-resumption.conf" => disabled("tls1_1") || disabled("tls1_2"),
  65   "11-dtls_resumption.conf" => disabled("dtls1") || disabled("dtls1_2"),
  66   "12-ct.conf" => $no_tls || $no_ct || $no_ec,
  67   # We could run some of these tests without TLS 1.2 if we had a per-test
  68   # disable instruction but that's a bizarre configuration not worth
  69   # special-casing for.
  70   # We should review this once we have TLS 1.3.
  71   "13-fragmentation.conf" => disabled("tls1_2"),
  72   "14-curves.conf" => disabled("tls1_2") || $no_ec || $no_ec2m
  73 );
  74
  75 foreach my $conf (@conf_files) {
  76     subtest "Test configuration $conf" => sub {
  77         test_conf($conf,
  78                   $conf_dependent_tests{$conf} || $^O eq "VMS" ?  0 : 1,
  79                   defined($skip{$conf}) ? $skip{$conf} : $no_tls);
  80     }
  81 }
  82
  83 sub test_conf {
  84     plan tests => 3;
  85
  86     my ($conf, $check_source, $skip) = @_;
  87
  88     my $conf_file = srctop_file("test", "ssl-tests", $conf);
  89     my $tmp_file = "${conf}.$$.tmp";
  90     my $run_test = 1;
  91
  92   SKIP: {
  93       # "Test" 1. Generate the source.
  94       my $input_file = $conf_file . ".in";
  95
  96       skip 'failure', 2 unless
  97         ok(run(perltest(["generate_ssl_tests.pl", $input_file],
  98                         interpreter_args => [ "-I", srctop_dir("test", "testlib")],
  99                         stdout => $tmp_file)),
 100            "Getting output from generate_ssl_tests.pl.");
 101
 102     SKIP: {
 103         # Test 2. Compare against existing output in test/ssl_tests.conf.
 104         skip "Skipping generated source test for $conf", 1
 105           if !$check_source;
 106
 107         $run_test = is(cmp_text($tmp_file, $conf_file), 0,
 108                        "Comparing generated sources.");
 109       }
 110
 111       # Test 3. Run the test.
 112       skip "No tests available; skipping tests", 1 if $skip;
 113       skip "Stale sources; skipping tests", 1 if !$run_test;
 114
 115       ok(run(test(["ssl_test", $tmp_file])), "running ssl_test $conf");
 116     }
 117
 118     unlink glob $tmp_file;
 119 }
 120
 121 sub cmp_text {
 122     return compare_text(@_, sub {
 123         $_[0] =~ s/\R//g;
 124         $_[1] =~ s/\R//g;
 125         return $_[0] ne $_[1];
 126     });
 127 }