test/recipes/70-test_sslsessiontick.t

   1 #!/usr/bin/perl
   2 # Written by Matt Caswell for the OpenSSL project.
   3 # ====================================================================
   4 # Copyright (c) 1998-2015 The OpenSSL Project.  All rights reserved.
   5 #
   6 # Redistribution and use in source and binary forms, with or without
   7 # modification, are permitted provided that the following conditions
   8 # are met:
   9 #
  10 # 1. Redistributions of source code must retain the above copyright
  11 #    notice, this list of conditions and the following disclaimer.
  12 #
  13 # 2. Redistributions in binary form must reproduce the above copyright
  14 #    notice, this list of conditions and the following disclaimer in
  15 #    the documentation and/or other materials provided with the
  16 #    distribution.
  17 #
  18 # 3. All advertising materials mentioning features or use of this
  19 #    software must display the following acknowledgment:
  20 #    "This product includes software developed by the OpenSSL Project
  21 #    for use in the OpenSSL Toolkit. (http://www.openssl.org/)"
  22 #
  23 # 4. The names "OpenSSL Toolkit" and "OpenSSL Project" must not be used to
  24 #    endorse or promote products derived from this software without
  25 #    prior written permission. For written permission, please contact
  26 #    openssl-core@openssl.org.
  27 #
  28 # 5. Products derived from this software may not be called "OpenSSL"
  29 #    nor may "OpenSSL" appear in their names without prior written
  30 #    permission of the OpenSSL Project.
  31 #
  32 # 6. Redistributions of any form whatsoever must retain the following
  33 #    acknowledgment:
  34 #    "This product includes software developed by the OpenSSL Project
  35 #    for use in the OpenSSL Toolkit (http://www.openssl.org/)"
  36 #
  37 # THIS SOFTWARE IS PROVIDED BY THE OpenSSL PROJECT ``AS IS'' AND ANY
  38 # EXPRESSED OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  39 # IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  40 # PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE OpenSSL PROJECT OR
  41 # ITS CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  42 # SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  43 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  44 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  45 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
  46 # STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  47 # ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
  48 # OF THE POSSIBILITY OF SUCH DAMAGE.
  49 # ====================================================================
  50 #
  51 # This product includes cryptographic software written by Eric Young
  52 # (eay@cryptsoft.com).  This product includes software written by Tim
  53 # Hudson (tjh@cryptsoft.com).
  54
  55 use strict;
  56 use OpenSSL::Test qw/:DEFAULT cmdstr top_file top_dir/;
  57 use TLSProxy::Proxy;
  58 use File::Temp qw(tempfile);
  59
  60 my $test_name = "test_sslsessiontick";
  61 setup($test_name);
  62
  63 plan skip_all => "$test_name can only be performed with OpenSSL configured shared"
  64     unless (map { chomp; s/^SHARED_LIBS=\s*//; $_ }
  65             grep { /^SHARED_LIBS=/ }
  66             do { local @ARGV = ( top_file("Makefile") ); <> })[0] ne "";
  67
  68 $ENV{OPENSSL_ENGINES} = top_dir("engines");
  69 $ENV{OPENSSL_ia32cap} = '~0x200000200000000';
  70
  71 sub checkmessages($$$$$$);
  72 sub clearall();
  73
  74 my $chellotickext = 0;
  75 my $shellotickext = 0;
  76 my $fullhand = 0;
  77 my $ticketseen = 0;
  78
  79 my $proxy = TLSProxy::Proxy->new(
  80     undef,
  81     cmdstr(app(["openssl"])),
  82     top_file("apps", "server.pem")
  83 );
  84
  85 plan tests => 8;
  86
  87 #Test 1: By default with no existing session we should get a session ticket
  88 #Expected result: ClientHello extension seen; ServerHello extension seen
  89 #                 NewSessionTicket message seen; Full handshake
  90 $proxy->start();
  91 checkmessages(1, "Default session ticket test", 1, 1, 1, 1);
  92
  93 #Test 2: If the server does not accept tickets we should get a normal handshake
  94 #with no session tickets
  95 #Expected result: ClientHello extension seen; ServerHello extension not seen
  96 #                 NewSessionTicket message not seen; Full handshake
  97 clearall();
  98 $proxy->serverflags("-no_ticket");
  99 $proxy->start();
 100 checkmessages(2, "No server support session ticket test", 1, 0, 0, 1);
 101
 102 #Test 3: If the client does not accept tickets we should get a normal handshake
 103 #with no session tickets
 104 #Expected result: ClientHello extension not seen; ServerHello extension not seen
 105 #                 NewSessionTicket message not seen; Full handshake
 106 clearall();
 107 $proxy->clientflags("-no_ticket");
 108 $proxy->start();
 109 checkmessages(3, "No client support session ticket test", 0, 0, 0, 1);
 110
 111 #Test 4: Test session resumption with session ticket
 112 #Expected result: ClientHello extension seen; ServerHello extension not seen
 113 #                 NewSessionTicket message not seen; Abbreviated handshake
 114 clearall();
 115 (my $fh, my $session) = tempfile();
 116 $proxy->serverconnects(2);
 117 $proxy->clientflags("-sess_out ".$session);
 118 $proxy->start();
 119 $proxy->clear();
 120 $proxy->clientflags("-sess_in ".$session);
 121 $proxy->clientstart();
 122 checkmessages(4, "Session resumption session ticket test", 1, 0, 0, 0);
 123
 124 #Test 5: Test session resumption with ticket capable client without a ticket
 125 #Expected result: ClientHello extension seen; ServerHello extension seen
 126 #                 NewSessionTicket message seen; Abbreviated handshake
 127 clearall();
 128 ($fh, $session) = tempfile();
 129 $proxy->serverconnects(2);
 130 $proxy->clientflags("-sess_out ".$session." -no_ticket");
 131 $proxy->start();
 132 $proxy->clear();
 133 $proxy->clientflags("-sess_in ".$session);
 134 $proxy->clientstart();
 135 checkmessages(5, "Session resumption with ticket capable client without a "
 136                  ."ticket", 1, 1, 1, 0);
 137
 138 #Test 6: Client accepts empty ticket.
 139 #Expected result: ClientHello extension seen; ServerHello extension seen;
 140 #                 NewSessionTicket message seen; Full handshake.
 141 clearall();
 142 $proxy->filter(\&ticket_filter);
 143 $proxy->start();
 144 checkmessages(6, "Empty ticket test",  1, 1, 1, 1);
 145
 146 #Test 7-8: Client keeps existing ticket on empty ticket.
 147 clearall();
 148 ($fh, $session) = tempfile();
 149 $proxy->serverconnects(3);
 150 $proxy->filter(undef);
 151 $proxy->clientflags("-sess_out ".$session);
 152 $proxy->start();
 153 $proxy->clear();
 154 $proxy->clientflags("-sess_in ".$session." -sess_out ".$session);
 155 $proxy->filter(\&inject_empty_ticket_filter);
 156 $proxy->clientstart();
 157 #Expected result: ClientHello extension seen; ServerHello extension seen;
 158 #                 NewSessionTicket message seen; Abbreviated handshake.
 159 checkmessages(7, "Empty ticket resumption test",  1, 1, 1, 0);
 160 clearall();
 161 $proxy->clientflags("-sess_in ".$session);
 162 $proxy->filter(undef);
 163 $proxy->clientstart();
 164 #Expected result: ClientHello extension seen; ServerHello extension not seen;
 165 #                 NewSessionTicket message not seen; Abbreviated handshake.
 166 checkmessages(8, "Empty ticket resumption test",  1, 0, 0, 0);
 167
 168
 169 sub ticket_filter
 170 {
 171     my $proxy = shift;
 172
 173     foreach my $message (@{$proxy->message_list}) {
 174         if ($message->mt == TLSProxy::Message::MT_NEW_SESSION_TICKET) {
 175             $message->ticket("");
 176             $message->repack();
 177         }
 178     }
 179 }
 180
 181 sub inject_empty_ticket_filter {
 182     my $proxy = shift;
 183
 184     foreach my $message (@{$proxy->message_list}) {
 185         if ($message->mt == TLSProxy::Message::MT_NEW_SESSION_TICKET) {
 186             # Only inject the message first time we're called.
 187             return;
 188         }
 189     }
 190
 191     my @new_message_list = ();
 192     foreach my $message (@{$proxy->message_list}) {
 193         push @new_message_list, $message;
 194         if ($message->mt == TLSProxy::Message::MT_SERVER_HELLO) {
 195             $message->set_extension(TLSProxy::ClientHello::EXT_SESSION_TICKET, "");
 196             $message->repack();
 197             # Tack NewSessionTicket onto the ServerHello record.
 198             # This only works if the ServerHello is exactly one record.
 199             my $record = ${$message->records}[0];
 200
 201             my $offset = $message->startoffset + $message->encoded_length;
 202             my $newsessionticket = TLSProxy::NewSessionTicket->new(
 203                 1, "", [$record], $offset, []);
 204             $newsessionticket->repack();
 205             push @new_message_list, $newsessionticket;
 206         }
 207     }
 208     $proxy->message_list([@new_message_list]);
 209 }
 210
 211 sub checkmessages($$$$$$)
 212 {
 213     my ($testno, $testname, $testch, $testsh, $testtickseen, $testhand) = @_;
 214
 215     subtest $testname => sub {
 216
 217         foreach my $message (@{$proxy->message_list}) {
 218             if ($message->mt == TLSProxy::Message::MT_CLIENT_HELLO
 219                 || $message->mt == TLSProxy::Message::MT_SERVER_HELLO) {
 220                 #Get the extensions data
 221                 my %extensions = %{$message->extension_data};
 222                 if (defined
 223                     $extensions{TLSProxy::ClientHello::EXT_SESSION_TICKET}) {
 224                     if ($message->mt == TLSProxy::Message::MT_CLIENT_HELLO) {
 225                         $chellotickext = 1;
 226                     } else {
 227                         $shellotickext = 1;
 228                     }
 229                 }
 230             } elsif ($message->mt == TLSProxy::Message::MT_CLIENT_KEY_EXCHANGE) {
 231                 #Must be doing a full handshake
 232                 $fullhand = 1;
 233             } elsif ($message->mt == TLSProxy::Message::MT_NEW_SESSION_TICKET) {
 234                 $ticketseen = 1;
 235             }
 236         }
 237
 238         plan tests => 5;
 239
 240         ok(TLSProxy::Message->success, "Handshake");
 241         ok(($testch && $chellotickext) || (!$testch && !$chellotickext),
 242            "ClientHello extension Session Ticket check");
 243         ok(($testsh && $shellotickext) || (!$testsh && !$shellotickext),
 244            "ServerHello extension Session Ticket check");
 245         ok(($testtickseen && $ticketseen) || (!$testtickseen && !$ticketseen),
 246            "Session Ticket message presence check");
 247         ok(($testhand && $fullhand) || (!$testhand && !$fullhand),
 248            "Session Ticket full handshake check");
 249     }
 250 }
 251
 252 sub clearall()
 253 {
 254     $chellotickext = 0;
 255     $shellotickext = 0;
 256     $fullhand = 0;
 257     $ticketseen = 0;
 258     $proxy->clear();
 259 }