test/recipes/80-test_ssl_new.t

   1 #! /usr/bin/env perl
   2 # Copyright 2015-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9
  10 use strict;
  11 use warnings;
  12
  13 use File::Basename;
  14 use File::Compare qw/compare_text/;
  15
  16 use OpenSSL::Test qw/:DEFAULT srctop_dir srctop_file/;
  17 use OpenSSL::Test::Utils qw/disabled alldisabled available_protocols/;
  18
  19 setup("test_ssl_new");
  20
  21 $ENV{TEST_CERTS_DIR} = srctop_dir("test", "certs");
  22
  23 my @conf_srcs =  glob(srctop_file("test", "ssl-tests", "*.conf.in"));
  24 my @conf_files = map { basename($_) } @conf_srcs;
  25 map { s/\.in// } @conf_files;
  26
  27 # 02-protocol-version.conf test results depend on the configuration of enabled
  28 # protocols. We only verify generated sources in the default configuration.
  29 my $is_default = (disabled("ssl3") && !disabled("tls1") &&
  30                   !disabled("tls1_1") && !disabled("tls1_2"));
  31
  32 my %conf_dependent_tests = ("02-protocol-version.conf" => 1);
  33
  34 foreach my $conf (@conf_files) {
  35     subtest "Test configuration $conf" => sub {
  36         test_conf($conf,
  37                   $conf_dependent_tests{$conf} || $^O eq "VMS" ?  0 : 1);
  38     }
  39 }
  40
  41 # We hard-code the number of tests to double-check that the globbing above
  42 # finds all files as expected.
  43 plan tests => 3;  # = scalar @conf_srcs
  44
  45 sub test_conf {
  46     plan tests => 3;
  47
  48     my ($conf, $check_source) = @_;
  49
  50     my $conf_file = srctop_file("test", "ssl-tests", $conf);
  51     my $tmp_file = "${conf}.$$.tmp";
  52     my $run_test = 1;
  53
  54   SKIP: {
  55       # "Test" 1. Generate the source.
  56       my $input_file = $conf_file . ".in";
  57
  58       skip 'failure', 2 unless
  59         ok(run(perltest(["generate_ssl_tests.pl", $input_file],
  60                         interpreter_args => [ "-I", srctop_dir("test", "testlib")],
  61                         stdout => $tmp_file)),
  62            "Getting output from generate_ssl_tests.pl.");
  63
  64     SKIP: {
  65         # Test 2. Compare against existing output in test/ssl_tests.conf.
  66         skip "Skipping generated source test for $conf", 1
  67           if !$check_source;
  68
  69         $run_test = is(cmp_text($tmp_file, $conf_file), 0,
  70                        "Comparing generated sources.");
  71       }
  72
  73       # Test 3. Run the test.
  74       my $no_tls = alldisabled(available_protocols("tls"));
  75       skip "No TLS tests available; skipping tests", 1 if $no_tls;
  76       skip "Stale sources; skipping tests", 1 if !$run_test;
  77
  78       ok(run(test(["ssl_test", $tmp_file])), "running ssl_test $conf");
  79     }
  80
  81     unlink glob $tmp_file;
  82 }
  83
  84 sub cmp_text {
  85     return compare_text(@_, sub {
  86         $_[0] =~ s/\R//g;
  87         $_[1] =~ s/\R//g;
  88         return $_[0] ne $_[1];
  89     });
  90 }