test/recipes/80-test_ssl_new.t

   1 #! /usr/bin/env perl
   2 # Copyright 2015-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9
  10 use strict;
  11 use warnings;
  12
  13 use File::Basename;
  14 use File::Compare qw/compare_text/;
  15 if ($^O ne "VMS") {
  16     use File::Glob qw/glob/;
  17 }
  18
  19 use OpenSSL::Test qw/:DEFAULT srctop_dir srctop_file/;
  20 use OpenSSL::Test::Utils qw/disabled alldisabled available_protocols/;
  21
  22 setup("test_ssl_new");
  23
  24 $ENV{TEST_CERTS_DIR} = srctop_dir("test", "certs");
  25
  26 my @conf_srcs =  glob(srctop_file("test", "ssl-tests", "*.conf.in"));
  27 map { s/;.*// } @conf_srcs if $^O eq "VMS";
  28 my @conf_files = map { basename($_) } @conf_srcs;
  29 map { s/\.in// } @conf_files;
  30
  31 # 02-protocol-version.conf test results depend on the configuration of enabled
  32 # protocols. We only verify generated sources in the default configuration.
  33 my $is_default = (disabled("ssl3") && !disabled("tls1") &&
  34                   !disabled("tls1_1") && !disabled("tls1_2"));
  35
  36 my %conf_dependent_tests = ("02-protocol-version.conf" => 1);
  37
  38 foreach my $conf (@conf_files) {
  39     subtest "Test configuration $conf" => sub {
  40         test_conf($conf,
  41                   $conf_dependent_tests{$conf} || $^O eq "VMS" ?  0 : 1);
  42     }
  43 }
  44
  45 # We hard-code the number of tests to double-check that the globbing above
  46 # finds all files as expected.
  47 plan tests => 3;  # = scalar @conf_srcs
  48
  49 sub test_conf {
  50     plan tests => 3;
  51
  52     my ($conf, $check_source) = @_;
  53
  54     my $conf_file = srctop_file("test", "ssl-tests", $conf);
  55     my $tmp_file = "${conf}.$$.tmp";
  56     my $run_test = 1;
  57
  58   SKIP: {
  59       # "Test" 1. Generate the source.
  60       my $input_file = $conf_file . ".in";
  61
  62       skip 'failure', 2 unless
  63         ok(run(perltest(["generate_ssl_tests.pl", $input_file],
  64                         interpreter_args => [ "-I", srctop_dir("test", "testlib")],
  65                         stdout => $tmp_file)),
  66            "Getting output from generate_ssl_tests.pl.");
  67
  68     SKIP: {
  69         # Test 2. Compare against existing output in test/ssl_tests.conf.
  70         skip "Skipping generated source test for $conf", 1
  71           if !$check_source;
  72
  73         $run_test = is(cmp_text($tmp_file, $conf_file), 0,
  74                        "Comparing generated sources.");
  75       }
  76
  77       # Test 3. Run the test.
  78       my $no_tls = alldisabled(available_protocols("tls"));
  79       skip "No TLS tests available; skipping tests", 1 if $no_tls;
  80       skip "Stale sources; skipping tests", 1 if !$run_test;
  81
  82       ok(run(test(["ssl_test", $tmp_file])), "running ssl_test $conf");
  83     }
  84
  85     unlink glob $tmp_file;
  86 }
  87
  88 sub cmp_text {
  89     return compare_text(@_, sub {
  90         $_[0] =~ s/\R//g;
  91         $_[1] =~ s/\R//g;
  92         return $_[0] ne $_[1];
  93     });
  94 }