test/recipes/80-test_ssl_new.t

   1 #! /usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use File::Basename;
   7 use File::Compare qw/compare_text/;
   8
   9 use OpenSSL::Test qw/:DEFAULT srctop_dir srctop_file/;
  10 use OpenSSL::Test::Utils qw/disabled alldisabled available_protocols/;
  11
  12 setup("test_ssl_new");
  13
  14 $ENV{TEST_CERTS_DIR} = srctop_dir("test", "certs");
  15
  16 my @conf_srcs =  glob(srctop_file("test", "ssl-tests", "*.conf"));
  17 my @conf_files = map {basename($_)} @conf_srcs;
  18
  19 # 02-protocol-version.conf test results depend on the configuration of enabled
  20 # protocols. We only verify generated sources in the default configuration.
  21 my $is_default = (disabled("ssl3") && !disabled("tls1") &&
  22                   !disabled("tls1_1") && !disabled("tls1_2"));
  23
  24 my %conf_dependent_tests = ("02-protocol-version.conf" => 1);
  25
  26 foreach my $conf (@conf_files) {
  27     subtest "Test configuration $conf" => sub {
  28         test_conf($conf, $conf_dependent_tests{$conf} ?  0 : 1);
  29     }
  30 }
  31
  32 # We hard-code the number of tests to double-check that the globbing above
  33 # finds all files as expected.
  34 plan tests => 2;  # = scalar @conf_files
  35
  36 sub test_conf {
  37     plan tests => 3;
  38
  39     my ($conf, $check_source) = @_;
  40
  41     my $conf_file = srctop_file("test", "ssl-tests", $conf);
  42     my $tmp_file = "${conf}.$$.tmp";
  43     my $run_test = 1;
  44
  45   SKIP: {
  46       # "Test" 1. Generate the source.
  47       my $input_file = $conf_file . ".in";
  48
  49       skip 'failure', 2 unless
  50         ok(run(perltest(["generate_ssl_tests.pl", $input_file],
  51                         stdout => $tmp_file)),
  52            "Getting output from generate_ssl_tests.pl.");
  53
  54     SKIP: {
  55         # Test 2. Compare against existing output in test/ssl_tests.conf.
  56         skip "Skipping generated source test for $conf", 1
  57           if !$check_source;
  58
  59         $run_test = is(cmp_text($tmp_file, $conf_file), 0,
  60                        "Comparing generated sources.");
  61       }
  62
  63       # Test 3. Run the test.
  64       my $no_tls = alldisabled(available_protocols("tls"));
  65       skip "No TLS tests available; skipping tests", 1 if $no_tls;
  66       skip "Stale sources; skipping tests", 1 if !$run_test;
  67
  68       ok(run(test(["ssl_test", $tmp_file])), "running ssl_test $conf");
  69     }
  70
  71     unlink glob $tmp_file;
  72 }
  73
  74 sub cmp_text {
  75     return compare_text(@_, sub {
  76         $_[0] =~ s/\R//g;
  77         $_[1] =~ s/\R//g;
  78         return $_[0] ne $_[1];
  79     });
  80 }