test/recipes/70-test_sslsessiontick.t

   1 #! /usr/bin/env perl
   2 # Copyright 2015-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9 use strict;
  10 use OpenSSL::Test qw/:DEFAULT cmdstr srctop_file bldtop_dir/;
  11 use OpenSSL::Test::Utils;
  12 use TLSProxy::Proxy;
  13 use File::Temp qw(tempfile);
  14
  15 my $test_name = "test_sslsessiontick";
  16 setup($test_name);
  17
  18 plan skip_all => "TLSProxy isn't usable on $^O"
  19     if $^O =~ /^(VMS|MSWin32)$/;
  20
  21 plan skip_all => "$test_name needs the dynamic engine feature enabled"
  22     if disabled("engine") || disabled("dynamic-engine");
  23
  24 plan skip_all => "$test_name needs the sock feature enabled"
  25     if disabled("sock");
  26
  27 plan skip_all => "$test_name needs TLS enabled"
  28     if alldisabled(available_protocols("tls"));
  29
  30 $ENV{OPENSSL_ia32cap} = '~0x200000200000000';
  31
  32 sub checkmessages($$$$$$);
  33 sub clearclient();
  34 sub clearall();
  35
  36 my $chellotickext = 0;
  37 my $shellotickext = 0;
  38 my $fullhand = 0;
  39 my $ticketseen = 0;
  40
  41 my $proxy = TLSProxy::Proxy->new(
  42     undef,
  43     cmdstr(app(["openssl"]), display => 1),
  44     srctop_file("apps", "server.pem"),
  45     (!$ENV{HARNESS_ACTIVE} || $ENV{HARNESS_VERBOSE})
  46 );
  47
  48 plan tests => 8;
  49
  50 #Test 1: By default with no existing session we should get a session ticket
  51 #Expected result: ClientHello extension seen; ServerHello extension seen
  52 #                 NewSessionTicket message seen; Full handshake
  53 $proxy->start();
  54 checkmessages(1, "Default session ticket test", 1, 1, 1, 1);
  55
  56 #Test 2: If the server does not accept tickets we should get a normal handshake
  57 #with no session tickets
  58 #Expected result: ClientHello extension seen; ServerHello extension not seen
  59 #                 NewSessionTicket message not seen; Full handshake
  60 clearall();
  61 $proxy->serverflags("-no_ticket");
  62 $proxy->start();
  63 checkmessages(2, "No server support session ticket test", 1, 0, 0, 1);
  64
  65 #Test 3: If the client does not accept tickets we should get a normal handshake
  66 #with no session tickets
  67 #Expected result: ClientHello extension not seen; ServerHello extension not seen
  68 #                 NewSessionTicket message not seen; Full handshake
  69 clearall();
  70 $proxy->clientflags("-no_ticket");
  71 $proxy->start();
  72 checkmessages(3, "No client support session ticket test", 0, 0, 0, 1);
  73
  74 #Test 4: Test session resumption with session ticket
  75 #Expected result: ClientHello extension seen; ServerHello extension not seen
  76 #                 NewSessionTicket message not seen; Abbreviated handshake
  77 clearall();
  78 (my $fh, my $session) = tempfile();
  79 $proxy->serverconnects(2);
  80 $proxy->clientflags("-sess_out ".$session);
  81 $proxy->start();
  82 $proxy->clearClient();
  83 $proxy->clientflags("-sess_in ".$session);
  84 $proxy->clientstart();
  85 checkmessages(4, "Session resumption session ticket test", 1, 0, 0, 0);
  86
  87 #Test 5: Test session resumption with ticket capable client without a ticket
  88 #Expected result: ClientHello extension seen; ServerHello extension seen
  89 #                 NewSessionTicket message seen; Abbreviated handshake
  90 clearall();
  91 ($fh, $session) = tempfile();
  92 $proxy->serverconnects(2);
  93 $proxy->clientflags("-sess_out ".$session." -no_ticket");
  94 $proxy->start();
  95 $proxy->clearClient();
  96 $proxy->clientflags("-sess_in ".$session);
  97 $proxy->clientstart();
  98 checkmessages(5, "Session resumption with ticket capable client without a "
  99                  ."ticket", 1, 1, 1, 0);
 100
 101 #Test 6: Client accepts empty ticket.
 102 #Expected result: ClientHello extension seen; ServerHello extension seen;
 103 #                 NewSessionTicket message seen; Full handshake.
 104 clearall();
 105 $proxy->filter(\&ticket_filter);
 106 $proxy->start();
 107 checkmessages(6, "Empty ticket test",  1, 1, 1, 1);
 108
 109 #Test 7-8: Client keeps existing ticket on empty ticket.
 110 clearall();
 111 ($fh, $session) = tempfile();
 112 $proxy->serverconnects(3);
 113 $proxy->filter(undef);
 114 $proxy->clientflags("-sess_out ".$session);
 115 $proxy->start();
 116 $proxy->clearClient();
 117 $proxy->clientflags("-sess_in ".$session." -sess_out ".$session);
 118 $proxy->filter(\&inject_empty_ticket_filter);
 119 $proxy->clientstart();
 120 #Expected result: ClientHello extension seen; ServerHello extension seen;
 121 #                 NewSessionTicket message seen; Abbreviated handshake.
 122 checkmessages(7, "Empty ticket resumption test",  1, 1, 1, 0);
 123 clearclient();
 124 $proxy->clientflags("-sess_in ".$session);
 125 $proxy->filter(undef);
 126 $proxy->clientstart();
 127 #Expected result: ClientHello extension seen; ServerHello extension not seen;
 128 #                 NewSessionTicket message not seen; Abbreviated handshake.
 129 checkmessages(8, "Empty ticket resumption test",  1, 0, 0, 0);
 130
 131
 132 sub ticket_filter
 133 {
 134     my $proxy = shift;
 135
 136     foreach my $message (@{$proxy->message_list}) {
 137         if ($message->mt == TLSProxy::Message::MT_NEW_SESSION_TICKET) {
 138             $message->ticket("");
 139             $message->repack();
 140         }
 141     }
 142 }
 143
 144 sub inject_empty_ticket_filter {
 145     my $proxy = shift;
 146
 147     foreach my $message (@{$proxy->message_list}) {
 148         if ($message->mt == TLSProxy::Message::MT_NEW_SESSION_TICKET) {
 149             # Only inject the message first time we're called.
 150             return;
 151         }
 152     }
 153
 154     my @new_message_list = ();
 155     foreach my $message (@{$proxy->message_list}) {
 156         push @new_message_list, $message;
 157         if ($message->mt == TLSProxy::Message::MT_SERVER_HELLO) {
 158             $message->set_extension(TLSProxy::Message::EXT_SESSION_TICKET, "");
 159             $message->repack();
 160             # Tack NewSessionTicket onto the ServerHello record.
 161             # This only works if the ServerHello is exactly one record.
 162             my $record = ${$message->records}[0];
 163
 164             my $offset = $message->startoffset + $message->encoded_length;
 165             my $newsessionticket = TLSProxy::NewSessionTicket->new(
 166                 1, "", [$record], $offset, []);
 167             $newsessionticket->repack();
 168             push @new_message_list, $newsessionticket;
 169         }
 170     }
 171     $proxy->message_list([@new_message_list]);
 172 }
 173
 174 sub checkmessages($$$$$$)
 175 {
 176     my ($testno, $testname, $testch, $testsh, $testtickseen, $testhand) = @_;
 177
 178     subtest $testname => sub {
 179
 180         foreach my $message (@{$proxy->message_list}) {
 181             if ($message->mt == TLSProxy::Message::MT_CLIENT_HELLO
 182                 || $message->mt == TLSProxy::Message::MT_SERVER_HELLO) {
 183                 #Get the extensions data
 184                 my %extensions = %{$message->extension_data};
 185                 if (defined
 186                     $extensions{TLSProxy::Message::EXT_SESSION_TICKET}) {
 187                     if ($message->mt == TLSProxy::Message::MT_CLIENT_HELLO) {
 188                         $chellotickext = 1;
 189                     } else {
 190                         $shellotickext = 1;
 191                     }
 192                 }
 193             } elsif ($message->mt == TLSProxy::Message::MT_CLIENT_KEY_EXCHANGE) {
 194                 #Must be doing a full handshake
 195                 $fullhand = 1;
 196             } elsif ($message->mt == TLSProxy::Message::MT_NEW_SESSION_TICKET) {
 197                 $ticketseen = 1;
 198             }
 199         }
 200
 201         plan tests => 5;
 202
 203         ok(TLSProxy::Message->success, "Handshake");
 204         ok(($testch && $chellotickext) || (!$testch && !$chellotickext),
 205            "ClientHello extension Session Ticket check");
 206         ok(($testsh && $shellotickext) || (!$testsh && !$shellotickext),
 207            "ServerHello extension Session Ticket check");
 208         ok(($testtickseen && $ticketseen) || (!$testtickseen && !$ticketseen),
 209            "Session Ticket message presence check");
 210         ok(($testhand && $fullhand) || (!$testhand && !$fullhand),
 211            "Session Ticket full handshake check");
 212     }
 213 }
 214
 215
 216 sub clearclient()
 217 {
 218     $chellotickext = 0;
 219     $shellotickext = 0;
 220     $fullhand = 0;
 221     $ticketseen = 0;
 222     $proxy->clearClient();
 223 }
 224
 225 sub clearall()
 226 {
 227     clearclient();
 228     $proxy->clear();
 229 }