crypto/arm64cpuid.pl

   1 #! /usr/bin/env perl
   2 # Copyright 2015-2020 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the Apache License 2.0 (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9
  10 # $output is the last argument if it looks like a file (it has an extension)
  11 # $flavour is the first argument if it doesn't look like a file
  12 $output = $#ARGV >= 0 && $ARGV[$#ARGV] =~ m|\.\w+$| ? pop : undef;
  13 $flavour = $#ARGV >= 0 && $ARGV[0] !~ m|\.| ? shift : undef;
  14
  15 $0 =~ m/(.*[\/\\])[^\/\\]+$/; $dir=$1;
  16 ( $xlate="${dir}arm-xlate.pl" and -f $xlate ) or
  17 ( $xlate="${dir}perlasm/arm-xlate.pl" and -f $xlate) or
  18 die "can't locate arm-xlate.pl";
  19
  20 open OUT,"| \"$^X\" $xlate $flavour \"$output\""
  21     or die "can't call $xlate: $!";
  22 *STDOUT=*OUT;
  23
  24 $code.=<<___;
  25 #include "arm_arch.h"
  26
  27 .text
  28 .arch   armv8-a+crypto
  29
  30 .align  5
  31 .globl  _armv7_neon_probe
  32 .type   _armv7_neon_probe,%function
  33 _armv7_neon_probe:
  34         AARCH64_VALID_CALL_TARGET
  35         orr     v15.16b, v15.16b, v15.16b
  36         ret
  37 .size   _armv7_neon_probe,.-_armv7_neon_probe
  38
  39 .globl  _armv7_tick
  40 .type   _armv7_tick,%function
  41 _armv7_tick:
  42         AARCH64_VALID_CALL_TARGET
  43 #ifdef  __APPLE__
  44         mrs     x0, CNTPCT_EL0
  45 #else
  46         mrs     x0, CNTVCT_EL0
  47 #endif
  48         ret
  49 .size   _armv7_tick,.-_armv7_tick
  50
  51 .globl  _armv8_aes_probe
  52 .type   _armv8_aes_probe,%function
  53 _armv8_aes_probe:
  54         AARCH64_VALID_CALL_TARGET
  55         aese    v0.16b, v0.16b
  56         ret
  57 .size   _armv8_aes_probe,.-_armv8_aes_probe
  58
  59 .globl  _armv8_sha1_probe
  60 .type   _armv8_sha1_probe,%function
  61 _armv8_sha1_probe:
  62         AARCH64_VALID_CALL_TARGET
  63         sha1h   s0, s0
  64         ret
  65 .size   _armv8_sha1_probe,.-_armv8_sha1_probe
  66
  67 .globl  _armv8_sha256_probe
  68 .type   _armv8_sha256_probe,%function
  69 _armv8_sha256_probe:
  70         AARCH64_VALID_CALL_TARGET
  71         sha256su0       v0.4s, v0.4s
  72         ret
  73 .size   _armv8_sha256_probe,.-_armv8_sha256_probe
  74
  75 .globl  _armv8_pmull_probe
  76 .type   _armv8_pmull_probe,%function
  77 _armv8_pmull_probe:
  78         AARCH64_VALID_CALL_TARGET
  79         pmull   v0.1q, v0.1d, v0.1d
  80         ret
  81 .size   _armv8_pmull_probe,.-_armv8_pmull_probe
  82
  83 .globl  _armv8_sha512_probe
  84 .type   _armv8_sha512_probe,%function
  85 _armv8_sha512_probe:
  86         AARCH64_VALID_CALL_TARGET
  87         .long   0xcec08000      // sha512su0    v0.2d,v0.2d
  88         ret
  89 .size   _armv8_sha512_probe,.-_armv8_sha512_probe
  90
  91 .globl  _armv8_cpuid_probe
  92 .type   _armv8_cpuid_probe,%function
  93 _armv8_cpuid_probe:
  94         AARCH64_VALID_CALL_TARGET
  95         mrs     x0, midr_el1
  96         ret
  97 .size   _armv8_cpuid_probe,.-_armv8_cpuid_probe
  98
  99 .globl  OPENSSL_cleanse
 100 .type   OPENSSL_cleanse,%function
 101 .align  5
 102 OPENSSL_cleanse:
 103         AARCH64_VALID_CALL_TARGET
 104         cbz     x1,.Lret        // len==0?
 105         cmp     x1,#15
 106         b.hi    .Lot            // len>15
 107         nop
 108 .Little:
 109         strb    wzr,[x0],#1     // store byte-by-byte
 110         subs    x1,x1,#1
 111         b.ne    .Little
 112 .Lret:  ret
 113
 114 .align  4
 115 .Lot:   tst     x0,#7
 116         b.eq    .Laligned       // inp is aligned
 117         strb    wzr,[x0],#1     // store byte-by-byte
 118         sub     x1,x1,#1
 119         b       .Lot
 120
 121 .align  4
 122 .Laligned:
 123         str     xzr,[x0],#8     // store word-by-word
 124         sub     x1,x1,#8
 125         tst     x1,#-8
 126         b.ne    .Laligned       // len>=8
 127         cbnz    x1,.Little      // len!=0?
 128         ret
 129 .size   OPENSSL_cleanse,.-OPENSSL_cleanse
 130
 131 .globl  CRYPTO_memcmp
 132 .type   CRYPTO_memcmp,%function
 133 .align  4
 134 CRYPTO_memcmp:
 135         AARCH64_VALID_CALL_TARGET
 136         eor     w3,w3,w3
 137         cbz     x2,.Lno_data    // len==0?
 138         cmp     x2,#16
 139         b.ne    .Loop_cmp
 140         ldp     x8,x9,[x0]
 141         ldp     x10,x11,[x1]
 142         eor     x8,x8,x10
 143         eor     x9,x9,x11
 144         orr     x8,x8,x9
 145         mov     x0,#1
 146         cmp     x8,#0
 147         csel    x0,xzr,x0,eq
 148         ret
 149
 150 .align  4
 151 .Loop_cmp:
 152         ldrb    w4,[x0],#1
 153         ldrb    w5,[x1],#1
 154         eor     w4,w4,w5
 155         orr     w3,w3,w4
 156         subs    x2,x2,#1
 157         b.ne    .Loop_cmp
 158
 159 .Lno_data:
 160         neg     w0,w3
 161         lsr     w0,w0,#31
 162         ret
 163 .size   CRYPTO_memcmp,.-CRYPTO_memcmp
 164 ___
 165
 166 print $code;
 167 close STDOUT or die "error closing STDOUT: $!";