crypto/aes/asm/aes-armv4.pl

   1 #!/usr/bin/env perl
   2
   3 # ====================================================================
   4 # Written by Andy Polyakov <appro@fy.chalmers.se> for the OpenSSL
   5 # project. The module is, however, dual licensed under OpenSSL and
   6 # CRYPTOGAMS licenses depending on where you obtain it. For further
   7 # details see http://www.openssl.org/~appro/cryptogams/.
   8 # ====================================================================
   9
  10 # AES for ARMv4
  11
  12 # January 2007.
  13 #
  14 # Code uses single 1K S-box and is >2 times faster than code generated
  15 # by gcc-3.4.1. This is thanks to unique feature of ARMv4 ISA, which
  16 # allows to merge logical or arithmetic operation with shift or rotate
  17 # in one instruction and emit combined result every cycle. The module
  18 # is endian-neutral. The performance is ~42 cycles/byte for 128-bit
  19 # key.
  20
  21 # May 2007.
  22 #
  23 # AES_set_[en|de]crypt_key is added.
  24
  25 while (($output=shift) && ($output!~/^\w[\w\-]*\.\w+$/)) {}
  26 open STDOUT,">$output";
  27
  28 $s0="r0";
  29 $s1="r1";
  30 $s2="r2";
  31 $s3="r3";
  32 $t1="r4";
  33 $t2="r5";
  34 $t3="r6";
  35 $i1="r7";
  36 $i2="r8";
  37 $i3="r9";
  38
  39 $tbl="r10";
  40 $key="r11";
  41 $rounds="r12";
  42
  43 $code=<<___;
  44 .text
  45 .code   32
  46
  47 .type   AES_Te,%object
  48 .align  5
  49 AES_Te:
  50 .word   0xc66363a5, 0xf87c7c84, 0xee777799, 0xf67b7b8d
  51 .word   0xfff2f20d, 0xd66b6bbd, 0xde6f6fb1, 0x91c5c554
  52 .word   0x60303050, 0x02010103, 0xce6767a9, 0x562b2b7d
  53 .word   0xe7fefe19, 0xb5d7d762, 0x4dababe6, 0xec76769a
  54 .word   0x8fcaca45, 0x1f82829d, 0x89c9c940, 0xfa7d7d87
  55 .word   0xeffafa15, 0xb25959eb, 0x8e4747c9, 0xfbf0f00b
  56 .word   0x41adadec, 0xb3d4d467, 0x5fa2a2fd, 0x45afafea
  57 .word   0x239c9cbf, 0x53a4a4f7, 0xe4727296, 0x9bc0c05b
  58 .word   0x75b7b7c2, 0xe1fdfd1c, 0x3d9393ae, 0x4c26266a
  59 .word   0x6c36365a, 0x7e3f3f41, 0xf5f7f702, 0x83cccc4f
  60 .word   0x6834345c, 0x51a5a5f4, 0xd1e5e534, 0xf9f1f108
  61 .word   0xe2717193, 0xabd8d873, 0x62313153, 0x2a15153f
  62 .word   0x0804040c, 0x95c7c752, 0x46232365, 0x9dc3c35e
  63 .word   0x30181828, 0x379696a1, 0x0a05050f, 0x2f9a9ab5
  64 .word   0x0e070709, 0x24121236, 0x1b80809b, 0xdfe2e23d
  65 .word   0xcdebeb26, 0x4e272769, 0x7fb2b2cd, 0xea75759f
  66 .word   0x1209091b, 0x1d83839e, 0x582c2c74, 0x341a1a2e
  67 .word   0x361b1b2d, 0xdc6e6eb2, 0xb45a5aee, 0x5ba0a0fb
  68 .word   0xa45252f6, 0x763b3b4d, 0xb7d6d661, 0x7db3b3ce
  69 .word   0x5229297b, 0xdde3e33e, 0x5e2f2f71, 0x13848497
  70 .word   0xa65353f5, 0xb9d1d168, 0x00000000, 0xc1eded2c
  71 .word   0x40202060, 0xe3fcfc1f, 0x79b1b1c8, 0xb65b5bed
  72 .word   0xd46a6abe, 0x8dcbcb46, 0x67bebed9, 0x7239394b
  73 .word   0x944a4ade, 0x984c4cd4, 0xb05858e8, 0x85cfcf4a
  74 .word   0xbbd0d06b, 0xc5efef2a, 0x4faaaae5, 0xedfbfb16
  75 .word   0x864343c5, 0x9a4d4dd7, 0x66333355, 0x11858594
  76 .word   0x8a4545cf, 0xe9f9f910, 0x04020206, 0xfe7f7f81
  77 .word   0xa05050f0, 0x783c3c44, 0x259f9fba, 0x4ba8a8e3
  78 .word   0xa25151f3, 0x5da3a3fe, 0x804040c0, 0x058f8f8a
  79 .word   0x3f9292ad, 0x219d9dbc, 0x70383848, 0xf1f5f504
  80 .word   0x63bcbcdf, 0x77b6b6c1, 0xafdada75, 0x42212163
  81 .word   0x20101030, 0xe5ffff1a, 0xfdf3f30e, 0xbfd2d26d
  82 .word   0x81cdcd4c, 0x180c0c14, 0x26131335, 0xc3ecec2f
  83 .word   0xbe5f5fe1, 0x359797a2, 0x884444cc, 0x2e171739
  84 .word   0x93c4c457, 0x55a7a7f2, 0xfc7e7e82, 0x7a3d3d47
  85 .word   0xc86464ac, 0xba5d5de7, 0x3219192b, 0xe6737395
  86 .word   0xc06060a0, 0x19818198, 0x9e4f4fd1, 0xa3dcdc7f
  87 .word   0x44222266, 0x542a2a7e, 0x3b9090ab, 0x0b888883
  88 .word   0x8c4646ca, 0xc7eeee29, 0x6bb8b8d3, 0x2814143c
  89 .word   0xa7dede79, 0xbc5e5ee2, 0x160b0b1d, 0xaddbdb76
  90 .word   0xdbe0e03b, 0x64323256, 0x743a3a4e, 0x140a0a1e
  91 .word   0x924949db, 0x0c06060a, 0x4824246c, 0xb85c5ce4
  92 .word   0x9fc2c25d, 0xbdd3d36e, 0x43acacef, 0xc46262a6
  93 .word   0x399191a8, 0x319595a4, 0xd3e4e437, 0xf279798b
  94 .word   0xd5e7e732, 0x8bc8c843, 0x6e373759, 0xda6d6db7
  95 .word   0x018d8d8c, 0xb1d5d564, 0x9c4e4ed2, 0x49a9a9e0
  96 .word   0xd86c6cb4, 0xac5656fa, 0xf3f4f407, 0xcfeaea25
  97 .word   0xca6565af, 0xf47a7a8e, 0x47aeaee9, 0x10080818
  98 .word   0x6fbabad5, 0xf0787888, 0x4a25256f, 0x5c2e2e72
  99 .word   0x381c1c24, 0x57a6a6f1, 0x73b4b4c7, 0x97c6c651
 100 .word   0xcbe8e823, 0xa1dddd7c, 0xe874749c, 0x3e1f1f21
 101 .word   0x964b4bdd, 0x61bdbddc, 0x0d8b8b86, 0x0f8a8a85
 102 .word   0xe0707090, 0x7c3e3e42, 0x71b5b5c4, 0xcc6666aa
 103 .word   0x904848d8, 0x06030305, 0xf7f6f601, 0x1c0e0e12
 104 .word   0xc26161a3, 0x6a35355f, 0xae5757f9, 0x69b9b9d0
 105 .word   0x17868691, 0x99c1c158, 0x3a1d1d27, 0x279e9eb9
 106 .word   0xd9e1e138, 0xebf8f813, 0x2b9898b3, 0x22111133
 107 .word   0xd26969bb, 0xa9d9d970, 0x078e8e89, 0x339494a7
 108 .word   0x2d9b9bb6, 0x3c1e1e22, 0x15878792, 0xc9e9e920
 109 .word   0x87cece49, 0xaa5555ff, 0x50282878, 0xa5dfdf7a
 110 .word   0x038c8c8f, 0x59a1a1f8, 0x09898980, 0x1a0d0d17
 111 .word   0x65bfbfda, 0xd7e6e631, 0x844242c6, 0xd06868b8
 112 .word   0x824141c3, 0x299999b0, 0x5a2d2d77, 0x1e0f0f11
 113 .word   0x7bb0b0cb, 0xa85454fc, 0x6dbbbbd6, 0x2c16163a
 114 @ Te4[256]
 115 .byte   0x63, 0x7c, 0x77, 0x7b, 0xf2, 0x6b, 0x6f, 0xc5
 116 .byte   0x30, 0x01, 0x67, 0x2b, 0xfe, 0xd7, 0xab, 0x76
 117 .byte   0xca, 0x82, 0xc9, 0x7d, 0xfa, 0x59, 0x47, 0xf0
 118 .byte   0xad, 0xd4, 0xa2, 0xaf, 0x9c, 0xa4, 0x72, 0xc0
 119 .byte   0xb7, 0xfd, 0x93, 0x26, 0x36, 0x3f, 0xf7, 0xcc
 120 .byte   0x34, 0xa5, 0xe5, 0xf1, 0x71, 0xd8, 0x31, 0x15
 121 .byte   0x04, 0xc7, 0x23, 0xc3, 0x18, 0x96, 0x05, 0x9a
 122 .byte   0x07, 0x12, 0x80, 0xe2, 0xeb, 0x27, 0xb2, 0x75
 123 .byte   0x09, 0x83, 0x2c, 0x1a, 0x1b, 0x6e, 0x5a, 0xa0
 124 .byte   0x52, 0x3b, 0xd6, 0xb3, 0x29, 0xe3, 0x2f, 0x84
 125 .byte   0x53, 0xd1, 0x00, 0xed, 0x20, 0xfc, 0xb1, 0x5b
 126 .byte   0x6a, 0xcb, 0xbe, 0x39, 0x4a, 0x4c, 0x58, 0xcf
 127 .byte   0xd0, 0xef, 0xaa, 0xfb, 0x43, 0x4d, 0x33, 0x85
 128 .byte   0x45, 0xf9, 0x02, 0x7f, 0x50, 0x3c, 0x9f, 0xa8
 129 .byte   0x51, 0xa3, 0x40, 0x8f, 0x92, 0x9d, 0x38, 0xf5
 130 .byte   0xbc, 0xb6, 0xda, 0x21, 0x10, 0xff, 0xf3, 0xd2
 131 .byte   0xcd, 0x0c, 0x13, 0xec, 0x5f, 0x97, 0x44, 0x17
 132 .byte   0xc4, 0xa7, 0x7e, 0x3d, 0x64, 0x5d, 0x19, 0x73
 133 .byte   0x60, 0x81, 0x4f, 0xdc, 0x22, 0x2a, 0x90, 0x88
 134 .byte   0x46, 0xee, 0xb8, 0x14, 0xde, 0x5e, 0x0b, 0xdb
 135 .byte   0xe0, 0x32, 0x3a, 0x0a, 0x49, 0x06, 0x24, 0x5c
 136 .byte   0xc2, 0xd3, 0xac, 0x62, 0x91, 0x95, 0xe4, 0x79
 137 .byte   0xe7, 0xc8, 0x37, 0x6d, 0x8d, 0xd5, 0x4e, 0xa9
 138 .byte   0x6c, 0x56, 0xf4, 0xea, 0x65, 0x7a, 0xae, 0x08
 139 .byte   0xba, 0x78, 0x25, 0x2e, 0x1c, 0xa6, 0xb4, 0xc6
 140 .byte   0xe8, 0xdd, 0x74, 0x1f, 0x4b, 0xbd, 0x8b, 0x8a
 141 .byte   0x70, 0x3e, 0xb5, 0x66, 0x48, 0x03, 0xf6, 0x0e
 142 .byte   0x61, 0x35, 0x57, 0xb9, 0x86, 0xc1, 0x1d, 0x9e
 143 .byte   0xe1, 0xf8, 0x98, 0x11, 0x69, 0xd9, 0x8e, 0x94
 144 .byte   0x9b, 0x1e, 0x87, 0xe9, 0xce, 0x55, 0x28, 0xdf
 145 .byte   0x8c, 0xa1, 0x89, 0x0d, 0xbf, 0xe6, 0x42, 0x68
 146 .byte   0x41, 0x99, 0x2d, 0x0f, 0xb0, 0x54, 0xbb, 0x16
 147 @ rcon[]
 148 .word   0x01000000, 0x02000000, 0x04000000, 0x08000000
 149 .word   0x10000000, 0x20000000, 0x40000000, 0x80000000
 150 .word   0x1B000000, 0x36000000, 0, 0, 0, 0, 0, 0
 151 .size   AES_Te,.-AES_Te
 152
 153 @ void AES_encrypt(const unsigned char *in, unsigned char *out,
 154 @                const AES_KEY *key) {
 155 .global AES_encrypt
 156 .type   AES_encrypt,%function
 157 .align  5
 158 AES_encrypt:
 159         sub     r3,pc,#8                @ AES_encrypt
 160         stmdb   sp!,{r1,r4-r12,lr}
 161         mov     $rounds,r0              @ inp
 162         mov     $key,r2
 163         sub     $tbl,r3,#AES_encrypt-AES_Te     @ Te
 164
 165         ldrb    $s0,[$rounds,#3]        @ load input data in endian-neutral
 166         ldrb    $t1,[$rounds,#2]        @ manner...
 167         ldrb    $t2,[$rounds,#1]
 168         ldrb    $t3,[$rounds,#0]
 169         orr     $s0,$s0,$t1,lsl#8
 170         orr     $s0,$s0,$t2,lsl#16
 171         orr     $s0,$s0,$t3,lsl#24
 172         ldrb    $s1,[$rounds,#7]
 173         ldrb    $t1,[$rounds,#6]
 174         ldrb    $t2,[$rounds,#5]
 175         ldrb    $t3,[$rounds,#4]
 176         orr     $s1,$s1,$t1,lsl#8
 177         orr     $s1,$s1,$t2,lsl#16
 178         orr     $s1,$s1,$t3,lsl#24
 179         ldrb    $s2,[$rounds,#11]
 180         ldrb    $t1,[$rounds,#10]
 181         ldrb    $t2,[$rounds,#9]
 182         ldrb    $t3,[$rounds,#8]
 183         orr     $s2,$s2,$t1,lsl#8
 184         orr     $s2,$s2,$t2,lsl#16
 185         orr     $s2,$s2,$t3,lsl#24
 186         ldrb    $s3,[$rounds,#15]
 187         ldrb    $t1,[$rounds,#14]
 188         ldrb    $t2,[$rounds,#13]
 189         ldrb    $t3,[$rounds,#12]
 190         orr     $s3,$s3,$t1,lsl#8
 191         orr     $s3,$s3,$t2,lsl#16
 192         orr     $s3,$s3,$t3,lsl#24
 193
 194         bl      _armv4_AES_encrypt
 195
 196         ldr     $rounds,[sp],#4         @ pop out
 197         mov     $t1,$s0,lsr#24          @ write output in endian-neutral
 198         mov     $t2,$s0,lsr#16          @ manner...
 199         mov     $t3,$s0,lsr#8
 200         strb    $t1,[$rounds,#0]
 201         strb    $t2,[$rounds,#1]
 202         strb    $t3,[$rounds,#2]
 203         strb    $s0,[$rounds,#3]
 204         mov     $t1,$s1,lsr#24
 205         mov     $t2,$s1,lsr#16
 206         mov     $t3,$s1,lsr#8
 207         strb    $t1,[$rounds,#4]
 208         strb    $t2,[$rounds,#5]
 209         strb    $t3,[$rounds,#6]
 210         strb    $s1,[$rounds,#7]
 211         mov     $t1,$s2,lsr#24
 212         mov     $t2,$s2,lsr#16
 213         mov     $t3,$s2,lsr#8
 214         strb    $t1,[$rounds,#8]
 215         strb    $t2,[$rounds,#9]
 216         strb    $t3,[$rounds,#10]
 217         strb    $s2,[$rounds,#11]
 218         mov     $t1,$s3,lsr#24
 219         mov     $t2,$s3,lsr#16
 220         mov     $t3,$s3,lsr#8
 221         strb    $t1,[$rounds,#12]
 222         strb    $t2,[$rounds,#13]
 223         strb    $t3,[$rounds,#14]
 224         strb    $s3,[$rounds,#15]
 225
 226         ldmia   sp!,{r4-r12,lr}
 227         tst     lr,#1
 228         moveq   pc,lr                   @ be binary compatible with V4, yet
 229         bx      lr                      @ interoperable with Thumb ISA:-)
 230 .size   AES_encrypt,.-AES_encrypt
 231
 232 .type   _armv4_AES_encrypt,%function
 233 .align  2
 234 _armv4_AES_encrypt:
 235         str     lr,[sp,#-4]!            @ push lr
 236         ldr     $t1,[$key],#16
 237         ldr     $t2,[$key,#-12]
 238         ldr     $t3,[$key,#-8]
 239         ldr     $i1,[$key,#-4]
 240         ldr     $rounds,[$key,#240-16]
 241         eor     $s0,$s0,$t1
 242         eor     $s1,$s1,$t2
 243         eor     $s2,$s2,$t3
 244         eor     $s3,$s3,$i1
 245         sub     $rounds,$rounds,#1
 246         mov     lr,#255
 247
 248 .Lenc_loop:
 249         and     $i2,lr,$s0,lsr#8
 250         and     $i3,lr,$s0,lsr#16
 251         and     $i1,lr,$s0
 252         mov     $s0,$s0,lsr#24
 253         ldr     $t1,[$tbl,$i1,lsl#2]    @ Te3[s0>>0]
 254         ldr     $s0,[$tbl,$s0,lsl#2]    @ Te0[s0>>24]
 255         ldr     $t2,[$tbl,$i2,lsl#2]    @ Te2[s0>>8]
 256         ldr     $t3,[$tbl,$i3,lsl#2]    @ Te1[s0>>16]
 257
 258         and     $i1,lr,$s1,lsr#16       @ i0
 259         and     $i2,lr,$s1
 260         and     $i3,lr,$s1,lsr#8
 261         mov     $s1,$s1,lsr#24
 262         ldr     $i1,[$tbl,$i1,lsl#2]    @ Te1[s1>>16]
 263         ldr     $s1,[$tbl,$s1,lsl#2]    @ Te0[s1>>24]
 264         ldr     $i2,[$tbl,$i2,lsl#2]    @ Te3[s1>>0]
 265         ldr     $i3,[$tbl,$i3,lsl#2]    @ Te2[s1>>8]
 266         eor     $s0,$s0,$i1,ror#8
 267         eor     $s1,$s1,$t1,ror#24
 268         eor     $t2,$t2,$i2,ror#8
 269         eor     $t3,$t3,$i3,ror#8
 270
 271         and     $i1,lr,$s2,lsr#8        @ i0
 272         and     $i2,lr,$s2,lsr#16       @ i1
 273         and     $i3,lr,$s2
 274         mov     $s2,$s2,lsr#24
 275         ldr     $i1,[$tbl,$i1,lsl#2]    @ Te2[s2>>8]
 276         ldr     $i2,[$tbl,$i2,lsl#2]    @ Te1[s2>>16]
 277         ldr     $s2,[$tbl,$s2,lsl#2]    @ Te0[s2>>24]
 278         ldr     $i3,[$tbl,$i3,lsl#2]    @ Te3[s2>>0]
 279         eor     $s0,$s0,$i1,ror#16
 280         eor     $s1,$s1,$i2,ror#8
 281         eor     $s2,$s2,$t2,ror#16
 282         eor     $t3,$t3,$i3,ror#16
 283
 284         and     $i1,lr,$s3              @ i0
 285         and     $i2,lr,$s3,lsr#8        @ i1
 286         and     $i3,lr,$s3,lsr#16       @ i2
 287         mov     $s3,$s3,lsr#24
 288         ldr     $i1,[$tbl,$i1,lsl#2]    @ Te3[s3>>0]
 289         ldr     $i2,[$tbl,$i2,lsl#2]    @ Te2[s3>>8]
 290         ldr     $i3,[$tbl,$i3,lsl#2]    @ Te1[s3>>16]
 291         ldr     $s3,[$tbl,$s3,lsl#2]    @ Te0[s3>>24]
 292         eor     $s0,$s0,$i1,ror#24
 293         eor     $s1,$s1,$i2,ror#16
 294         eor     $s2,$s2,$i3,ror#8
 295         eor     $s3,$s3,$t3,ror#8
 296
 297         ldr     $t1,[$key],#16
 298         ldr     $t2,[$key,#-12]
 299         ldr     $t3,[$key,#-8]
 300         ldr     $i1,[$key,#-4]
 301         eor     $s0,$s0,$t1
 302         eor     $s1,$s1,$t2
 303         eor     $s2,$s2,$t3
 304         eor     $s3,$s3,$i1
 305
 306         subs    $rounds,$rounds,#1
 307         bne     .Lenc_loop
 308
 309         add     $tbl,$tbl,#2
 310
 311         and     $i1,lr,$s0
 312         and     $i2,lr,$s0,lsr#8
 313         and     $i3,lr,$s0,lsr#16
 314         mov     $s0,$s0,lsr#24
 315         ldrb    $t1,[$tbl,$i1,lsl#2]    @ Te4[s0>>0]
 316         ldrb    $s0,[$tbl,$s0,lsl#2]    @ Te4[s0>>24]
 317         ldrb    $t2,[$tbl,$i2,lsl#2]    @ Te4[s0>>8]
 318         ldrb    $t3,[$tbl,$i3,lsl#2]    @ Te4[s0>>16]
 319
 320         and     $i1,lr,$s1,lsr#16       @ i0
 321         and     $i2,lr,$s1
 322         and     $i3,lr,$s1,lsr#8
 323         mov     $s1,$s1,lsr#24
 324         ldrb    $i1,[$tbl,$i1,lsl#2]    @ Te4[s1>>16]
 325         ldrb    $s1,[$tbl,$s1,lsl#2]    @ Te4[s1>>24]
 326         ldrb    $i2,[$tbl,$i2,lsl#2]    @ Te4[s1>>0]
 327         ldrb    $i3,[$tbl,$i3,lsl#2]    @ Te4[s1>>8]
 328         eor     $s0,$i1,$s0,lsl#8
 329         eor     $s1,$t1,$s1,lsl#24
 330         eor     $t2,$i2,$t2,lsl#8
 331         eor     $t3,$i3,$t3,lsl#8
 332
 333         and     $i1,lr,$s2,lsr#8        @ i0
 334         and     $i2,lr,$s2,lsr#16       @ i1
 335         and     $i3,lr,$s2
 336         mov     $s2,$s2,lsr#24
 337         ldrb    $i1,[$tbl,$i1,lsl#2]    @ Te4[s2>>8]
 338         ldrb    $i2,[$tbl,$i2,lsl#2]    @ Te4[s2>>16]
 339         ldrb    $s2,[$tbl,$s2,lsl#2]    @ Te4[s2>>24]
 340         ldrb    $i3,[$tbl,$i3,lsl#2]    @ Te4[s2>>0]
 341         eor     $s0,$i1,$s0,lsl#8
 342         eor     $s1,$s1,$i2,lsl#16
 343         eor     $s2,$t2,$s2,lsl#24
 344         eor     $t3,$i3,$t3,lsl#8
 345
 346         and     $i1,lr,$s3              @ i0
 347         and     $i2,lr,$s3,lsr#8        @ i1
 348         and     $i3,lr,$s3,lsr#16       @ i2
 349         mov     $s3,$s3,lsr#24
 350         ldrb    $i1,[$tbl,$i1,lsl#2]    @ Te4[s3>>0]
 351         ldrb    $i2,[$tbl,$i2,lsl#2]    @ Te4[s3>>8]
 352         ldrb    $i3,[$tbl,$i3,lsl#2]    @ Te4[s3>>16]
 353         ldrb    $s3,[$tbl,$s3,lsl#2]    @ Te4[s3>>24]
 354         eor     $s0,$i1,$s0,lsl#8
 355         eor     $s1,$s1,$i2,lsl#8
 356         eor     $s2,$s2,$i3,lsl#16
 357         eor     $s3,$t3,$s3,lsl#24
 358
 359         ldr     lr,[sp],#4              @ pop lr
 360         ldr     $t1,[$key,#0]
 361         ldr     $t2,[$key,#4]
 362         ldr     $t3,[$key,#8]
 363         ldr     $i1,[$key,#12]
 364         eor     $s0,$s0,$t1
 365         eor     $s1,$s1,$t2
 366         eor     $s2,$s2,$t3
 367         eor     $s3,$s3,$i1
 368
 369         sub     $tbl,$tbl,#2
 370         mov     pc,lr                   @ return
 371 .size   _armv4_AES_encrypt,.-_armv4_AES_encrypt
 372
 373 .global AES_set_encrypt_key
 374 .type   AES_set_encrypt_key,%function
 375 .align  5
 376 AES_set_encrypt_key:
 377         sub     r3,pc,#8                @ AES_set_encrypt_key
 378         teq     r0,#0
 379         moveq   r0,#-1
 380         beq     .Labrt
 381         teq     r2,#0
 382         moveq   r0,#-1
 383         beq     .Labrt
 384
 385         teq     r1,#128
 386         beq     .Lok
 387         teq     r1,#192
 388         beq     .Lok
 389         teq     r1,#256
 390         movne   r0,#-1
 391         bne     .Labrt
 392
 393 .Lok:   stmdb   sp!,{r4-r12,lr}
 394         sub     $tbl,r3,#AES_set_encrypt_key-AES_Te-1024        @ Te4
 395
 396         mov     $rounds,r0              @ inp
 397         mov     lr,r1                   @ bits
 398         mov     $key,r2                 @ key
 399
 400         ldrb    $s0,[$rounds,#3]        @ load input data in endian-neutral
 401         ldrb    $t1,[$rounds,#2]        @ manner...
 402         ldrb    $t2,[$rounds,#1]
 403         ldrb    $t3,[$rounds,#0]
 404         orr     $s0,$s0,$t1,lsl#8
 405         orr     $s0,$s0,$t2,lsl#16
 406         orr     $s0,$s0,$t3,lsl#24
 407         ldrb    $s1,[$rounds,#7]
 408         ldrb    $t1,[$rounds,#6]
 409         ldrb    $t2,[$rounds,#5]
 410         ldrb    $t3,[$rounds,#4]
 411         orr     $s1,$s1,$t1,lsl#8
 412         orr     $s1,$s1,$t2,lsl#16
 413         orr     $s1,$s1,$t3,lsl#24
 414         ldrb    $s2,[$rounds,#11]
 415         ldrb    $t1,[$rounds,#10]
 416         ldrb    $t2,[$rounds,#9]
 417         ldrb    $t3,[$rounds,#8]
 418         orr     $s2,$s2,$t1,lsl#8
 419         orr     $s2,$s2,$t2,lsl#16
 420         orr     $s2,$s2,$t3,lsl#24
 421         ldrb    $s3,[$rounds,#15]
 422         ldrb    $t1,[$rounds,#14]
 423         ldrb    $t2,[$rounds,#13]
 424         ldrb    $t3,[$rounds,#12]
 425         orr     $s3,$s3,$t1,lsl#8
 426         orr     $s3,$s3,$t2,lsl#16
 427         orr     $s3,$s3,$t3,lsl#24
 428         str     $s0,[$key],#16
 429         str     $s1,[$key,#-12]
 430         str     $s2,[$key,#-8]
 431         str     $s3,[$key,#-4]
 432
 433         teq     lr,#128
 434         bne     .Lnot128
 435         mov     $rounds,#10
 436         str     $rounds,[$key,#240-16]
 437         add     $t3,$tbl,#256                   @ rcon
 438         mov     lr,#255
 439
 440 .L128_loop:
 441         and     $t2,lr,$s3,lsr#24
 442         and     $i1,lr,$s3,lsr#16
 443         and     $i2,lr,$s3,lsr#8
 444         and     $i3,lr,$s3
 445         ldrb    $t2,[$tbl,$t2]
 446         ldrb    $i1,[$tbl,$i1]
 447         ldrb    $i2,[$tbl,$i2]
 448         ldrb    $i3,[$tbl,$i3]
 449         ldr     $t1,[$t3],#4                    @ rcon[i++]
 450         orr     $t2,$t2,$i1,lsl#24
 451         orr     $t2,$t2,$i2,lsl#16
 452         orr     $t2,$t2,$i3,lsl#8
 453         eor     $t2,$t2,$t1
 454         eor     $s0,$s0,$t2                     @ rk[4]=rk[0]^...
 455         eor     $s1,$s1,$s0                     @ rk[5]=rk[1]^rk[4]
 456         eor     $s2,$s2,$s1                     @ rk[6]=rk[2]^rk[5]
 457         eor     $s3,$s3,$s2                     @ rk[7]=rk[3]^rk[6]
 458         str     $s0,[$key],#16
 459         str     $s1,[$key,#-12]
 460         str     $s2,[$key,#-8]
 461         str     $s3,[$key,#-4]
 462
 463         subs    $rounds,$rounds,#1
 464         bne     .L128_loop
 465         sub     r2,$key,#176
 466         b       .Ldone
 467
 468 .Lnot128:
 469         ldrb    $i2,[$rounds,#19]
 470         ldrb    $t1,[$rounds,#18]
 471         ldrb    $t2,[$rounds,#17]
 472         ldrb    $t3,[$rounds,#16]
 473         orr     $i2,$i2,$t1,lsl#8
 474         orr     $i2,$i2,$t2,lsl#16
 475         orr     $i2,$i2,$t3,lsl#24
 476         ldrb    $i3,[$rounds,#23]
 477         ldrb    $t1,[$rounds,#22]
 478         ldrb    $t2,[$rounds,#21]
 479         ldrb    $t3,[$rounds,#20]
 480         orr     $i3,$i3,$t1,lsl#8
 481         orr     $i3,$i3,$t2,lsl#16
 482         orr     $i3,$i3,$t3,lsl#24
 483         str     $i2,[$key],#8
 484         str     $i3,[$key,#-4]
 485
 486         teq     lr,#192
 487         bne     .Lnot192
 488         mov     $rounds,#12
 489         str     $rounds,[$key,#240-24]
 490         add     $t3,$tbl,#256                   @ rcon
 491         mov     lr,#255
 492         mov     $rounds,#8
 493
 494 .L192_loop:
 495         and     $t2,lr,$i3,lsr#24
 496         and     $i1,lr,$i3,lsr#16
 497         and     $i2,lr,$i3,lsr#8
 498         and     $i3,lr,$i3
 499         ldrb    $t2,[$tbl,$t2]
 500         ldrb    $i1,[$tbl,$i1]
 501         ldrb    $i2,[$tbl,$i2]
 502         ldrb    $i3,[$tbl,$i3]
 503         ldr     $t1,[$t3],#4                    @ rcon[i++]
 504         orr     $t2,$t2,$i1,lsl#24
 505         orr     $t2,$t2,$i2,lsl#16
 506         orr     $t2,$t2,$i3,lsl#8
 507         eor     $i3,$t2,$t1
 508         eor     $s0,$s0,$i3                     @ rk[6]=rk[0]^...
 509         eor     $s1,$s1,$s0                     @ rk[7]=rk[1]^rk[6]
 510         eor     $s2,$s2,$s1                     @ rk[8]=rk[2]^rk[7]
 511         eor     $s3,$s3,$s2                     @ rk[9]=rk[3]^rk[8]
 512         str     $s0,[$key],#24
 513         str     $s1,[$key,#-20]
 514         str     $s2,[$key,#-16]
 515         str     $s3,[$key,#-12]
 516
 517         subs    $rounds,$rounds,#1
 518         subeq   r2,$key,#216
 519         beq     .Ldone
 520
 521         ldr     $i1,[$key,#-32]
 522         ldr     $i2,[$key,#-28]
 523         eor     $i1,$i1,$s3                     @ rk[10]=rk[4]^rk[9]
 524         eor     $i3,$i2,$i1                     @ rk[11]=rk[5]^rk[10]
 525         str     $i1,[$key,#-8]
 526         str     $i3,[$key,#-4]
 527         b       .L192_loop
 528
 529 .Lnot192:
 530         ldrb    $i2,[$rounds,#27]
 531         ldrb    $t1,[$rounds,#26]
 532         ldrb    $t2,[$rounds,#25]
 533         ldrb    $t3,[$rounds,#24]
 534         orr     $i2,$i2,$t1,lsl#8
 535         orr     $i2,$i2,$t2,lsl#16
 536         orr     $i2,$i2,$t3,lsl#24
 537         ldrb    $i3,[$rounds,#31]
 538         ldrb    $t1,[$rounds,#30]
 539         ldrb    $t2,[$rounds,#29]
 540         ldrb    $t3,[$rounds,#28]
 541         orr     $i3,$i3,$t1,lsl#8
 542         orr     $i3,$i3,$t2,lsl#16
 543         orr     $i3,$i3,$t3,lsl#24
 544         str     $i2,[$key],#8
 545         str     $i3,[$key,#-4]
 546
 547         mov     $rounds,#14
 548         str     $rounds,[$key,#240-32]
 549         add     $t3,$tbl,#256                   @ rcon
 550         mov     lr,#255
 551         mov     $rounds,#7
 552
 553 .L256_loop:
 554         and     $t2,lr,$i3,lsr#24
 555         and     $i1,lr,$i3,lsr#16
 556         and     $i2,lr,$i3,lsr#8
 557         and     $i3,lr,$i3
 558         ldrb    $t2,[$tbl,$t2]
 559         ldrb    $i1,[$tbl,$i1]
 560         ldrb    $i2,[$tbl,$i2]
 561         ldrb    $i3,[$tbl,$i3]
 562         ldr     $t1,[$t3],#4                    @ rcon[i++]
 563         orr     $t2,$t2,$i1,lsl#24
 564         orr     $t2,$t2,$i2,lsl#16
 565         orr     $t2,$t2,$i3,lsl#8
 566         eor     $i3,$t2,$t1
 567         eor     $s0,$s0,$i3                     @ rk[8]=rk[0]^...
 568         eor     $s1,$s1,$s0                     @ rk[9]=rk[1]^rk[8]
 569         eor     $s2,$s2,$s1                     @ rk[10]=rk[2]^rk[9]
 570         eor     $s3,$s3,$s2                     @ rk[11]=rk[3]^rk[10]
 571         str     $s0,[$key],#32
 572         str     $s1,[$key,#-28]
 573         str     $s2,[$key,#-24]
 574         str     $s3,[$key,#-20]
 575
 576         subs    $rounds,$rounds,#1
 577         subeq   r2,$key,#256
 578         beq     .Ldone
 579
 580         and     $t2,lr,$s3
 581         and     $i1,lr,$s3,lsr#8
 582         and     $i2,lr,$s3,lsr#16
 583         and     $i3,lr,$s3,lsr#24
 584         ldrb    $t2,[$tbl,$t2]
 585         ldrb    $i1,[$tbl,$i1]
 586         ldrb    $i2,[$tbl,$i2]
 587         ldrb    $i3,[$tbl,$i3]
 588         orr     $t2,$t2,$i1,lsl#8
 589         orr     $t2,$t2,$i2,lsl#16
 590         orr     $t2,$t2,$i3,lsl#24
 591
 592         ldr     $t1,[$key,#-48]
 593         ldr     $i1,[$key,#-44]
 594         ldr     $i2,[$key,#-40]
 595         ldr     $i3,[$key,#-36]
 596         eor     $t1,$t1,$t2                     @ rk[12]=rk[4]^...
 597         eor     $i1,$i1,$t1                     @ rk[13]=rk[5]^rk[12]
 598         eor     $i2,$i2,$i1                     @ rk[14]=rk[6]^rk[13]
 599         eor     $i3,$i3,$i2                     @ rk[15]=rk[7]^rk[14]
 600         str     $t1,[$key,#-16]
 601         str     $i1,[$key,#-12]
 602         str     $i2,[$key,#-8]
 603         str     $i3,[$key,#-4]
 604         b       .L256_loop
 605
 606 .Ldone: mov     r0,#0
 607         ldmia   sp!,{r4-r12,lr}
 608 .Labrt: tst     lr,#1
 609         moveq   pc,lr                   @ be binary compatible with V4, yet
 610         bx      lr                      @ interoperable with Thumb ISA:-)
 611 .size   AES_set_encrypt_key,.-AES_set_encrypt_key
 612
 613 .global AES_set_decrypt_key
 614 .type   AES_set_decrypt_key,%function
 615 .align  5
 616 AES_set_decrypt_key:
 617         str     lr,[sp,#-4]!            @ push lr
 618         bl      AES_set_encrypt_key
 619         teq     r0,#0
 620         ldrne   lr,[sp],#4              @ pop lr
 621         bne     .Labrt
 622
 623         stmdb   sp!,{r4-r12}
 624
 625         ldr     $rounds,[r2,#240]       @ AES_set_encrypt_key preserves r2,
 626         mov     $key,r2                 @ which is AES_KEY *key
 627         mov     $i1,r2
 628         add     $i2,r2,$rounds,lsl#4
 629
 630 .Linv:  ldr     $s0,[$i1]
 631         ldr     $s1,[$i1,#4]
 632         ldr     $s2,[$i1,#8]
 633         ldr     $s3,[$i1,#12]
 634         ldr     $t1,[$i2]
 635         ldr     $t2,[$i2,#4]
 636         ldr     $t3,[$i2,#8]
 637         ldr     $i3,[$i2,#12]
 638         str     $s0,[$i2],#-16
 639         str     $s1,[$i2,#16+4]
 640         str     $s2,[$i2,#16+8]
 641         str     $s3,[$i2,#16+12]
 642         str     $t1,[$i1],#16
 643         str     $t2,[$i1,#-12]
 644         str     $t3,[$i1,#-8]
 645         str     $i3,[$i1,#-4]
 646         teq     $i1,$i2
 647         bne     .Linv
 648 ___
 649 $mask80=$i1;
 650 $mask1b=$i2;
 651 $mask7f=$i3;
 652 $code.=<<___;
 653         ldr     $s0,[$key,#16]!         @ prefetch tp1
 654         mov     $mask80,#0x80
 655         mov     $mask1b,#0x1b
 656         orr     $mask80,$mask80,#0x8000
 657         orr     $mask1b,$mask1b,#0x1b00
 658         orr     $mask80,$mask80,$mask80,lsl#16
 659         orr     $mask1b,$mask1b,$mask1b,lsl#16
 660         sub     $rounds,$rounds,#1
 661         mvn     $mask7f,$mask80
 662         mov     $rounds,$rounds,lsl#2   @ (rounds-1)*4
 663
 664 .Lmix:  and     $t1,$s0,$mask80
 665         and     $s1,$s0,$mask7f
 666         sub     $t1,$t1,$t1,lsr#7
 667         and     $t1,$t1,$mask1b
 668         eor     $s1,$t1,$s1,lsl#1       @ tp2
 669
 670         and     $t1,$s1,$mask80
 671         and     $s2,$s1,$mask7f
 672         sub     $t1,$t1,$t1,lsr#7
 673         and     $t1,$t1,$mask1b
 674         eor     $s2,$t1,$s2,lsl#1       @ tp4
 675
 676         and     $t1,$s2,$mask80
 677         and     $s3,$s2,$mask7f
 678         sub     $t1,$t1,$t1,lsr#7
 679         and     $t1,$t1,$mask1b
 680         eor     $s3,$t1,$s3,lsl#1       @ tp8
 681
 682         eor     $t1,$s1,$s2
 683         eor     $t2,$s0,$s3             @ tp9
 684         eor     $t1,$t1,$s3             @ tpe
 685         eor     $t1,$t1,$s1,ror#24
 686         eor     $t1,$t1,$t2,ror#24      @ ^= ROTATE(tpb=tp9^tp2,8)
 687         eor     $t1,$t1,$s2,ror#16
 688         eor     $t1,$t1,$t2,ror#16      @ ^= ROTATE(tpd=tp9^tp4,16)
 689         eor     $t1,$t1,$t2,ror#8       @ ^= ROTATE(tp9,24)
 690
 691         ldr     $s0,[$key,#4]           @ prefetch tp1
 692         str     $t1,[$key],#4
 693         subs    $rounds,$rounds,#1
 694         bne     .Lmix
 695
 696         mov     r0,#0
 697         ldmia   sp!,{r4-r12,lr}
 698         tst     lr,#1
 699         moveq   pc,lr                   @ be binary compatible with V4, yet
 700         bx      lr                      @ interoperable with Thumb ISA:-)
 701 .size   AES_set_decrypt_key,.-AES_set_decrypt_key
 702
 703 .type   AES_Td,%object
 704 .align  5
 705 AES_Td:
 706 .word   0x51f4a750, 0x7e416553, 0x1a17a4c3, 0x3a275e96
 707 .word   0x3bab6bcb, 0x1f9d45f1, 0xacfa58ab, 0x4be30393
 708 .word   0x2030fa55, 0xad766df6, 0x88cc7691, 0xf5024c25
 709 .word   0x4fe5d7fc, 0xc52acbd7, 0x26354480, 0xb562a38f
 710 .word   0xdeb15a49, 0x25ba1b67, 0x45ea0e98, 0x5dfec0e1
 711 .word   0xc32f7502, 0x814cf012, 0x8d4697a3, 0x6bd3f9c6
 712 .word   0x038f5fe7, 0x15929c95, 0xbf6d7aeb, 0x955259da
 713 .word   0xd4be832d, 0x587421d3, 0x49e06929, 0x8ec9c844
 714 .word   0x75c2896a, 0xf48e7978, 0x99583e6b, 0x27b971dd
 715 .word   0xbee14fb6, 0xf088ad17, 0xc920ac66, 0x7dce3ab4
 716 .word   0x63df4a18, 0xe51a3182, 0x97513360, 0x62537f45
 717 .word   0xb16477e0, 0xbb6bae84, 0xfe81a01c, 0xf9082b94
 718 .word   0x70486858, 0x8f45fd19, 0x94de6c87, 0x527bf8b7
 719 .word   0xab73d323, 0x724b02e2, 0xe31f8f57, 0x6655ab2a
 720 .word   0xb2eb2807, 0x2fb5c203, 0x86c57b9a, 0xd33708a5
 721 .word   0x302887f2, 0x23bfa5b2, 0x02036aba, 0xed16825c
 722 .word   0x8acf1c2b, 0xa779b492, 0xf307f2f0, 0x4e69e2a1
 723 .word   0x65daf4cd, 0x0605bed5, 0xd134621f, 0xc4a6fe8a
 724 .word   0x342e539d, 0xa2f355a0, 0x058ae132, 0xa4f6eb75
 725 .word   0x0b83ec39, 0x4060efaa, 0x5e719f06, 0xbd6e1051
 726 .word   0x3e218af9, 0x96dd063d, 0xdd3e05ae, 0x4de6bd46
 727 .word   0x91548db5, 0x71c45d05, 0x0406d46f, 0x605015ff
 728 .word   0x1998fb24, 0xd6bde997, 0x894043cc, 0x67d99e77
 729 .word   0xb0e842bd, 0x07898b88, 0xe7195b38, 0x79c8eedb
 730 .word   0xa17c0a47, 0x7c420fe9, 0xf8841ec9, 0x00000000
 731 .word   0x09808683, 0x322bed48, 0x1e1170ac, 0x6c5a724e
 732 .word   0xfd0efffb, 0x0f853856, 0x3daed51e, 0x362d3927
 733 .word   0x0a0fd964, 0x685ca621, 0x9b5b54d1, 0x24362e3a
 734 .word   0x0c0a67b1, 0x9357e70f, 0xb4ee96d2, 0x1b9b919e
 735 .word   0x80c0c54f, 0x61dc20a2, 0x5a774b69, 0x1c121a16
 736 .word   0xe293ba0a, 0xc0a02ae5, 0x3c22e043, 0x121b171d
 737 .word   0x0e090d0b, 0xf28bc7ad, 0x2db6a8b9, 0x141ea9c8
 738 .word   0x57f11985, 0xaf75074c, 0xee99ddbb, 0xa37f60fd
 739 .word   0xf701269f, 0x5c72f5bc, 0x44663bc5, 0x5bfb7e34
 740 .word   0x8b432976, 0xcb23c6dc, 0xb6edfc68, 0xb8e4f163
 741 .word   0xd731dcca, 0x42638510, 0x13972240, 0x84c61120
 742 .word   0x854a247d, 0xd2bb3df8, 0xaef93211, 0xc729a16d
 743 .word   0x1d9e2f4b, 0xdcb230f3, 0x0d8652ec, 0x77c1e3d0
 744 .word   0x2bb3166c, 0xa970b999, 0x119448fa, 0x47e96422
 745 .word   0xa8fc8cc4, 0xa0f03f1a, 0x567d2cd8, 0x223390ef
 746 .word   0x87494ec7, 0xd938d1c1, 0x8ccaa2fe, 0x98d40b36
 747 .word   0xa6f581cf, 0xa57ade28, 0xdab78e26, 0x3fadbfa4
 748 .word   0x2c3a9de4, 0x5078920d, 0x6a5fcc9b, 0x547e4662
 749 .word   0xf68d13c2, 0x90d8b8e8, 0x2e39f75e, 0x82c3aff5
 750 .word   0x9f5d80be, 0x69d0937c, 0x6fd52da9, 0xcf2512b3
 751 .word   0xc8ac993b, 0x10187da7, 0xe89c636e, 0xdb3bbb7b
 752 .word   0xcd267809, 0x6e5918f4, 0xec9ab701, 0x834f9aa8
 753 .word   0xe6956e65, 0xaaffe67e, 0x21bccf08, 0xef15e8e6
 754 .word   0xbae79bd9, 0x4a6f36ce, 0xea9f09d4, 0x29b07cd6
 755 .word   0x31a4b2af, 0x2a3f2331, 0xc6a59430, 0x35a266c0
 756 .word   0x744ebc37, 0xfc82caa6, 0xe090d0b0, 0x33a7d815
 757 .word   0xf104984a, 0x41ecdaf7, 0x7fcd500e, 0x1791f62f
 758 .word   0x764dd68d, 0x43efb04d, 0xccaa4d54, 0xe49604df
 759 .word   0x9ed1b5e3, 0x4c6a881b, 0xc12c1fb8, 0x4665517f
 760 .word   0x9d5eea04, 0x018c355d, 0xfa877473, 0xfb0b412e
 761 .word   0xb3671d5a, 0x92dbd252, 0xe9105633, 0x6dd64713
 762 .word   0x9ad7618c, 0x37a10c7a, 0x59f8148e, 0xeb133c89
 763 .word   0xcea927ee, 0xb761c935, 0xe11ce5ed, 0x7a47b13c
 764 .word   0x9cd2df59, 0x55f2733f, 0x1814ce79, 0x73c737bf
 765 .word   0x53f7cdea, 0x5ffdaa5b, 0xdf3d6f14, 0x7844db86
 766 .word   0xcaaff381, 0xb968c43e, 0x3824342c, 0xc2a3405f
 767 .word   0x161dc372, 0xbce2250c, 0x283c498b, 0xff0d9541
 768 .word   0x39a80171, 0x080cb3de, 0xd8b4e49c, 0x6456c190
 769 .word   0x7bcb8461, 0xd532b670, 0x486c5c74, 0xd0b85742
 770 @ Td4[256]
 771 .byte   0x52, 0x09, 0x6a, 0xd5, 0x30, 0x36, 0xa5, 0x38
 772 .byte   0xbf, 0x40, 0xa3, 0x9e, 0x81, 0xf3, 0xd7, 0xfb
 773 .byte   0x7c, 0xe3, 0x39, 0x82, 0x9b, 0x2f, 0xff, 0x87
 774 .byte   0x34, 0x8e, 0x43, 0x44, 0xc4, 0xde, 0xe9, 0xcb
 775 .byte   0x54, 0x7b, 0x94, 0x32, 0xa6, 0xc2, 0x23, 0x3d
 776 .byte   0xee, 0x4c, 0x95, 0x0b, 0x42, 0xfa, 0xc3, 0x4e
 777 .byte   0x08, 0x2e, 0xa1, 0x66, 0x28, 0xd9, 0x24, 0xb2
 778 .byte   0x76, 0x5b, 0xa2, 0x49, 0x6d, 0x8b, 0xd1, 0x25
 779 .byte   0x72, 0xf8, 0xf6, 0x64, 0x86, 0x68, 0x98, 0x16
 780 .byte   0xd4, 0xa4, 0x5c, 0xcc, 0x5d, 0x65, 0xb6, 0x92
 781 .byte   0x6c, 0x70, 0x48, 0x50, 0xfd, 0xed, 0xb9, 0xda
 782 .byte   0x5e, 0x15, 0x46, 0x57, 0xa7, 0x8d, 0x9d, 0x84
 783 .byte   0x90, 0xd8, 0xab, 0x00, 0x8c, 0xbc, 0xd3, 0x0a
 784 .byte   0xf7, 0xe4, 0x58, 0x05, 0xb8, 0xb3, 0x45, 0x06
 785 .byte   0xd0, 0x2c, 0x1e, 0x8f, 0xca, 0x3f, 0x0f, 0x02
 786 .byte   0xc1, 0xaf, 0xbd, 0x03, 0x01, 0x13, 0x8a, 0x6b
 787 .byte   0x3a, 0x91, 0x11, 0x41, 0x4f, 0x67, 0xdc, 0xea
 788 .byte   0x97, 0xf2, 0xcf, 0xce, 0xf0, 0xb4, 0xe6, 0x73
 789 .byte   0x96, 0xac, 0x74, 0x22, 0xe7, 0xad, 0x35, 0x85
 790 .byte   0xe2, 0xf9, 0x37, 0xe8, 0x1c, 0x75, 0xdf, 0x6e
 791 .byte   0x47, 0xf1, 0x1a, 0x71, 0x1d, 0x29, 0xc5, 0x89
 792 .byte   0x6f, 0xb7, 0x62, 0x0e, 0xaa, 0x18, 0xbe, 0x1b
 793 .byte   0xfc, 0x56, 0x3e, 0x4b, 0xc6, 0xd2, 0x79, 0x20
 794 .byte   0x9a, 0xdb, 0xc0, 0xfe, 0x78, 0xcd, 0x5a, 0xf4
 795 .byte   0x1f, 0xdd, 0xa8, 0x33, 0x88, 0x07, 0xc7, 0x31
 796 .byte   0xb1, 0x12, 0x10, 0x59, 0x27, 0x80, 0xec, 0x5f
 797 .byte   0x60, 0x51, 0x7f, 0xa9, 0x19, 0xb5, 0x4a, 0x0d
 798 .byte   0x2d, 0xe5, 0x7a, 0x9f, 0x93, 0xc9, 0x9c, 0xef
 799 .byte   0xa0, 0xe0, 0x3b, 0x4d, 0xae, 0x2a, 0xf5, 0xb0
 800 .byte   0xc8, 0xeb, 0xbb, 0x3c, 0x83, 0x53, 0x99, 0x61
 801 .byte   0x17, 0x2b, 0x04, 0x7e, 0xba, 0x77, 0xd6, 0x26
 802 .byte   0xe1, 0x69, 0x14, 0x63, 0x55, 0x21, 0x0c, 0x7d
 803 .size   AES_Td,.-AES_Td
 804
 805 @ void AES_decrypt(const unsigned char *in, unsigned char *out,
 806 @                const AES_KEY *key) {
 807 .global AES_decrypt
 808 .type   AES_decrypt,%function
 809 .align  5
 810 AES_decrypt:
 811         sub     r3,pc,#8                @ AES_decrypt
 812         stmdb   sp!,{r1,r4-r12,lr}
 813         mov     $rounds,r0              @ inp
 814         mov     $key,r2
 815         sub     $tbl,r3,#AES_decrypt-AES_Td             @ Td
 816
 817         ldrb    $s0,[$rounds,#3]        @ load input data in endian-neutral
 818         ldrb    $t1,[$rounds,#2]        @ manner...
 819         ldrb    $t2,[$rounds,#1]
 820         ldrb    $t3,[$rounds,#0]
 821         orr     $s0,$s0,$t1,lsl#8
 822         orr     $s0,$s0,$t2,lsl#16
 823         orr     $s0,$s0,$t3,lsl#24
 824         ldrb    $s1,[$rounds,#7]
 825         ldrb    $t1,[$rounds,#6]
 826         ldrb    $t2,[$rounds,#5]
 827         ldrb    $t3,[$rounds,#4]
 828         orr     $s1,$s1,$t1,lsl#8
 829         orr     $s1,$s1,$t2,lsl#16
 830         orr     $s1,$s1,$t3,lsl#24
 831         ldrb    $s2,[$rounds,#11]
 832         ldrb    $t1,[$rounds,#10]
 833         ldrb    $t2,[$rounds,#9]
 834         ldrb    $t3,[$rounds,#8]
 835         orr     $s2,$s2,$t1,lsl#8
 836         orr     $s2,$s2,$t2,lsl#16
 837         orr     $s2,$s2,$t3,lsl#24
 838         ldrb    $s3,[$rounds,#15]
 839         ldrb    $t1,[$rounds,#14]
 840         ldrb    $t2,[$rounds,#13]
 841         ldrb    $t3,[$rounds,#12]
 842         orr     $s3,$s3,$t1,lsl#8
 843         orr     $s3,$s3,$t2,lsl#16
 844         orr     $s3,$s3,$t3,lsl#24
 845
 846         bl      _armv4_AES_decrypt
 847
 848         ldr     $rounds,[sp],#4         @ pop out
 849         mov     $t1,$s0,lsr#24          @ write output in endian-neutral
 850         mov     $t2,$s0,lsr#16          @ manner...
 851         mov     $t3,$s0,lsr#8
 852         strb    $t1,[$rounds,#0]
 853         strb    $t2,[$rounds,#1]
 854         strb    $t3,[$rounds,#2]
 855         strb    $s0,[$rounds,#3]
 856         mov     $t1,$s1,lsr#24
 857         mov     $t2,$s1,lsr#16
 858         mov     $t3,$s1,lsr#8
 859         strb    $t1,[$rounds,#4]
 860         strb    $t2,[$rounds,#5]
 861         strb    $t3,[$rounds,#6]
 862         strb    $s1,[$rounds,#7]
 863         mov     $t1,$s2,lsr#24
 864         mov     $t2,$s2,lsr#16
 865         mov     $t3,$s2,lsr#8
 866         strb    $t1,[$rounds,#8]
 867         strb    $t2,[$rounds,#9]
 868         strb    $t3,[$rounds,#10]
 869         strb    $s2,[$rounds,#11]
 870         mov     $t1,$s3,lsr#24
 871         mov     $t2,$s3,lsr#16
 872         mov     $t3,$s3,lsr#8
 873         strb    $t1,[$rounds,#12]
 874         strb    $t2,[$rounds,#13]
 875         strb    $t3,[$rounds,#14]
 876         strb    $s3,[$rounds,#15]
 877
 878         ldmia   sp!,{r4-r12,lr}
 879         tst     lr,#1
 880         moveq   pc,lr                   @ be binary compatible with V4, yet
 881         bx      lr                      @ interoperable with Thumb ISA:-)
 882 .size   AES_decrypt,.-AES_decrypt
 883
 884 .type   _armv4_AES_decrypt,%function
 885 .align  2
 886 _armv4_AES_decrypt:
 887         str     lr,[sp,#-4]!            @ push lr
 888         ldr     $t1,[$key],#16
 889         ldr     $t2,[$key,#-12]
 890         ldr     $t3,[$key,#-8]
 891         ldr     $i1,[$key,#-4]
 892         ldr     $rounds,[$key,#240-16]
 893         eor     $s0,$s0,$t1
 894         eor     $s1,$s1,$t2
 895         eor     $s2,$s2,$t3
 896         eor     $s3,$s3,$i1
 897         sub     $rounds,$rounds,#1
 898         mov     lr,#255
 899
 900 .Ldec_loop:
 901         and     $i1,lr,$s0,lsr#16
 902         and     $i2,lr,$s0,lsr#8
 903         and     $i3,lr,$s0
 904         mov     $s0,$s0,lsr#24
 905         ldr     $t1,[$tbl,$i1,lsl#2]    @ Td1[s0>>16]
 906         ldr     $s0,[$tbl,$s0,lsl#2]    @ Td0[s0>>24]
 907         ldr     $t2,[$tbl,$i2,lsl#2]    @ Td2[s0>>8]
 908         ldr     $t3,[$tbl,$i3,lsl#2]    @ Td3[s0>>0]
 909
 910         and     $i1,lr,$s1              @ i0
 911         and     $i2,lr,$s1,lsr#16
 912         and     $i3,lr,$s1,lsr#8
 913         mov     $s1,$s1,lsr#24
 914         ldr     $i1,[$tbl,$i1,lsl#2]    @ Td3[s1>>0]
 915         ldr     $s1,[$tbl,$s1,lsl#2]    @ Td0[s1>>24]
 916         ldr     $i2,[$tbl,$i2,lsl#2]    @ Td1[s1>>16]
 917         ldr     $i3,[$tbl,$i3,lsl#2]    @ Td2[s1>>8]
 918         eor     $s0,$s0,$i1,ror#24
 919         eor     $s1,$s1,$t1,ror#8
 920         eor     $t2,$i2,$t2,ror#8
 921         eor     $t3,$i3,$t3,ror#8
 922
 923         and     $i1,lr,$s2,lsr#8        @ i0
 924         and     $i2,lr,$s2              @ i1
 925         and     $i3,lr,$s2,lsr#16
 926         mov     $s2,$s2,lsr#24
 927         ldr     $i1,[$tbl,$i1,lsl#2]    @ Td2[s2>>8]
 928         ldr     $i2,[$tbl,$i2,lsl#2]    @ Td3[s2>>0]
 929         ldr     $s2,[$tbl,$s2,lsl#2]    @ Td0[s2>>24]
 930         ldr     $i3,[$tbl,$i3,lsl#2]    @ Td1[s2>>16]
 931         eor     $s0,$s0,$i1,ror#16
 932         eor     $s1,$s1,$i2,ror#24
 933         eor     $s2,$s2,$t2,ror#8
 934         eor     $t3,$i3,$t3,ror#8
 935
 936         and     $i1,lr,$s3,lsr#16       @ i0
 937         and     $i2,lr,$s3,lsr#8        @ i1
 938         and     $i3,lr,$s3              @ i2
 939         mov     $s3,$s3,lsr#24
 940         ldr     $i1,[$tbl,$i1,lsl#2]    @ Td1[s3>>16]
 941         ldr     $i2,[$tbl,$i2,lsl#2]    @ Td2[s3>>8]
 942         ldr     $i3,[$tbl,$i3,lsl#2]    @ Td3[s3>>0]
 943         ldr     $s3,[$tbl,$s3,lsl#2]    @ Td0[s3>>24]
 944         eor     $s0,$s0,$i1,ror#8
 945         eor     $s1,$s1,$i2,ror#16
 946         eor     $s2,$s2,$i3,ror#24
 947         eor     $s3,$s3,$t3,ror#8
 948
 949         ldr     $t1,[$key],#16
 950         ldr     $t2,[$key,#-12]
 951         ldr     $t3,[$key,#-8]
 952         ldr     $i1,[$key,#-4]
 953         eor     $s0,$s0,$t1
 954         eor     $s1,$s1,$t2
 955         eor     $s2,$s2,$t3
 956         eor     $s3,$s3,$i1
 957
 958         subs    $rounds,$rounds,#1
 959         bne     .Ldec_loop
 960
 961         add     $tbl,$tbl,#1024
 962
 963         ldr     $t1,[$tbl,#0]           @ prefetch Td4
 964         ldr     $t2,[$tbl,#32]
 965         ldr     $t3,[$tbl,#64]
 966         ldr     $i1,[$tbl,#96]
 967         ldr     $i2,[$tbl,#128]
 968         ldr     $i3,[$tbl,#160]
 969         ldr     $t1,[$tbl,#192]
 970         ldr     $t2,[$tbl,#224]
 971
 972         and     $i1,lr,$s0,lsr#16
 973         and     $i2,lr,$s0,lsr#8
 974         and     $i3,lr,$s0
 975         ldrb    $s0,[$tbl,$s0,lsr#24]   @ Td4[s0>>24]
 976         ldrb    $t1,[$tbl,$i1]          @ Td4[s0>>16]
 977         ldrb    $t2,[$tbl,$i2]          @ Td4[s0>>8]
 978         ldrb    $t3,[$tbl,$i3]          @ Td4[s0>>0]
 979
 980         and     $i1,lr,$s1              @ i0
 981         and     $i2,lr,$s1,lsr#16
 982         and     $i3,lr,$s1,lsr#8
 983         ldrb    $i1,[$tbl,$i1]          @ Td4[s1>>0]
 984         ldrb    $s1,[$tbl,$s1,lsr#24]   @ Td4[s1>>24]
 985         ldrb    $i2,[$tbl,$i2]          @ Td4[s1>>16]
 986         ldrb    $i3,[$tbl,$i3]          @ Td4[s1>>8]
 987         eor     $s0,$i1,$s0,lsl#24
 988         eor     $s1,$t1,$s1,lsl#8
 989         eor     $t2,$t2,$i2,lsl#8
 990         eor     $t3,$t3,$i3,lsl#8
 991
 992         and     $i1,lr,$s2,lsr#8        @ i0
 993         and     $i2,lr,$s2              @ i1
 994         and     $i3,lr,$s2,lsr#16
 995         ldrb    $i1,[$tbl,$i1]          @ Td4[s2>>8]
 996         ldrb    $i2,[$tbl,$i2]          @ Td4[s2>>0]
 997         ldrb    $s2,[$tbl,$s2,lsr#24]   @ Td4[s2>>24]
 998         ldrb    $i3,[$tbl,$i3]          @ Td4[s2>>16]
 999         eor     $s0,$s0,$i1,lsl#8
1000         eor     $s1,$i2,$s1,lsl#16
1001         eor     $s2,$t2,$s2,lsl#16
1002         eor     $t3,$t3,$i3,lsl#16
1003
1004         and     $i1,lr,$s3,lsr#16       @ i0
1005         and     $i2,lr,$s3,lsr#8        @ i1
1006         and     $i3,lr,$s3              @ i2
1007         ldrb    $i1,[$tbl,$i1]          @ Td4[s3>>16]
1008         ldrb    $i2,[$tbl,$i2]          @ Td4[s3>>8]
1009         ldrb    $i3,[$tbl,$i3]          @ Td4[s3>>0]
1010         ldrb    $s3,[$tbl,$s3,lsr#24]   @ Td4[s3>>24]
1011         eor     $s0,$s0,$i1,lsl#16
1012         eor     $s1,$s1,$i2,lsl#8
1013         eor     $s2,$i3,$s2,lsl#8
1014         eor     $s3,$t3,$s3,lsl#24
1015
1016         ldr     lr,[sp],#4              @ pop lr
1017         ldr     $t1,[$key,#0]
1018         ldr     $t2,[$key,#4]
1019         ldr     $t3,[$key,#8]
1020         ldr     $i1,[$key,#12]
1021         eor     $s0,$s0,$t1
1022         eor     $s1,$s1,$t2
1023         eor     $s2,$s2,$t3
1024         eor     $s3,$s3,$i1
1025
1026         sub     $tbl,$tbl,#1024
1027         mov     pc,lr                   @ return
1028 .size   _armv4_AES_decrypt,.-_armv4_AES_decrypt
1029 .asciz  "AES for ARMv4, CRYPTOGAMS by <appro\@openssl.org>"
1030 .align  2
1031 ___
1032
1033 $code =~ s/\bbx\s+lr\b/.word\t0xe12fff1e/gm;    # make it possible to compile with -march=armv4
1034 print $code;
1035 close STDOUT;   # enforce flush