Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::Glob;
  21
  22 # see INSTALL for instructions.
  23
  24 my $orig_death_handler = $SIG{__DIE__};
  25 $SIG{__DIE__} = \&death_handler;
  26
  27 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  28
  29 # Options:
  30 #
  31 # --config      add the given configuration file, which will be read after
  32 #               any "Configurations*" files that are found in the same
  33 #               directory as this script.
  34 # --prefix      prefix for the OpenSSL installation, which includes the
  35 #               directories bin, lib, include, share/man, share/doc/openssl
  36 #               This becomes the value of INSTALLTOP in Makefile
  37 #               (Default: /usr/local)
  38 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  39 #               If it's a relative directory, it will be added on the directory
  40 #               given with --prefix.
  41 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  42 #               (Default: PREFIX/ssl)
  43 #
  44 # --cross-compile-prefix Add specified prefix to binutils components.
  45 #
  46 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0.0 / 3.
  47 #               Do not compile support for interfaces deprecated as of the
  48 #               specified OpenSSL version.
  49 #
  50 # no-hw-xxx     do not compile support for specific crypto hardware.
  51 #               Generic OpenSSL-style methods relating to this support
  52 #               are always compiled but return NULL if the hardware
  53 #               support isn't compiled.
  54 # no-hw         do not compile support for any crypto hardware.
  55 # [no-]threads  [don't] try to create a library that is suitable for
  56 #               multithreaded applications (default is "threads" if we
  57 #               know how to do it)
  58 # [no-]shared   [don't] try to create shared libraries when supported.
  59 # [no-]pic      [don't] try to build position independent code when supported.
  60 #               If disabled, it also disables shared and dynamic-engine.
  61 # no-asm        do not use assembler
  62 # no-egd        do not compile support for the entropy-gathering daemon APIs
  63 # [no-]zlib     [don't] compile support for zlib compression.
  64 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  65 #               library and will be loaded in run-time by the OpenSSL library.
  66 # sctp          include SCTP support
  67 # no-uplink     Don't build support for UPLINK interface.
  68 # enable-weak-ssl-ciphers
  69 #               Enable weak ciphers that are disabled by default.
  70 # 386           generate 80386 code in assembly modules
  71 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  72 #               mentioned '386' option implies this one
  73 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  74 # -<xxx> +<xxx> compiler options are passed through
  75 # -static       while -static is also a pass-through compiler option (and
  76 #               as such is limited to environments where it's actually
  77 #               meaningful), it triggers a number configuration options,
  78 #               namely no-pic, no-shared and no-threads. It is
  79 #               argued that the only reason to produce statically linked
  80 #               binaries (and in context it means executables linked with
  81 #               -static flag, and not just executables linked with static
  82 #               libcrypto.a) is to eliminate dependency on specific run-time,
  83 #               a.k.a. libc version. The mentioned config options are meant
  84 #               to achieve just that. Unfortunately on Linux it's impossible
  85 #               to eliminate the dependency completely for openssl executable
  86 #               because of getaddrinfo and gethostbyname calls, which can
  87 #               invoke dynamically loadable library facility anyway to meet
  88 #               the lookup requests. For this reason on Linux statically
  89 #               linked openssl executable has rather debugging value than
  90 #               production quality.
  91 #
  92 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  93 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  94 # Following are set automatically by this script
  95 #
  96 # MD5_ASM       use some extra md5 assembler,
  97 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
  98 # RMD160_ASM    use some extra ripemd160 assembler,
  99 # SHA256_ASM    sha256_block is implemented in assembler
 100 # SHA512_ASM    sha512_block is implemented in assembler
 101 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 102
 103 # Minimum warning options... any contributions to OpenSSL should at least
 104 # get past these.  Note that we only use these with C compilers, not with
 105 # C++ compilers.
 106
 107 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 108 # -DPEDANTIC complements -pedantic and is meant to mask code that
 109 # is not strictly standard-compliant and/or implementation-specific,
 110 # e.g. inline assembly, disregards to alignment requirements, such
 111 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 112 # to be used even in sanitized builds, because sanitizer too is
 113 # supposed to and does take notice of non-standard behaviour. Then
 114 # -pedantic with pre-C9x compiler would also complain about 'long
 115 # long' not being supported. As 64-bit algorithms are common now,
 116 # it grew impossible to resolve this without sizeable additional
 117 # code, so we just tell compiler to be pedantic about everything
 118 # but 'long long' type.
 119
 120 my @gcc_devteam_warn = qw(
 121     -DDEBUG_UNUSED
 122     -DPEDANTIC -pedantic -Wno-long-long
 123     -Wall
 124     -Wextra
 125     -Wno-unused-parameter
 126     -Wno-missing-field-initializers
 127     -Wswitch
 128     -Wsign-compare
 129     -Wshadow
 130     -Wformat
 131     -Wtype-limits
 132     -Wundef
 133     -Werror
 134     -Wmissing-prototypes
 135     -Wstrict-prototypes
 136 );
 137
 138 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 139 # TODO(openssl-team): fix problems and investigate if (at least) the
 140 # following warnings can also be enabled:
 141 #       -Wcast-align
 142 #       -Wunreachable-code -- no, too ugly/compiler-specific
 143 #       -Wlanguage-extension-token -- no, we use asm()
 144 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 145 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 146 my @clang_devteam_warn = qw(
 147     -Wswitch-default
 148     -Wno-parentheses-equality
 149     -Wno-language-extension-token
 150     -Wno-extended-offsetof
 151     -Wconditional-uninitialized
 152     -Wincompatible-pointer-types-discards-qualifiers
 153     -Wno-unknown-warning-option
 154     -Wmissing-variable-declarations
 155 );
 156
 157 # This adds backtrace information to the memory leak info.  Is only used
 158 # when crypto-mdebug-backtrace is enabled.
 159 my $memleak_devteam_backtrace = "-rdynamic";
 160
 161 my $strict_warnings = 0;
 162
 163 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 164 # which would cover all BSD flavors. -pthread applies to them all,
 165 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 166 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 167 # which has to be accompanied by explicit -D_THREAD_SAFE and
 168 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 169 # seems to be sufficient?
 170 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 171
 172 #
 173 # API compatibility name to version number mapping.
 174 #
 175 my $maxapi = "3.0.0";           # API for "no-deprecated" builds
 176 my $apitable = {
 177     "3.0.0" => 3,
 178     "1.1.1" => 2,
 179     "1.1.0" => 2,
 180     "1.0.2" => 1,
 181     "1.0.1" => 1,
 182     "1.0.0" => 1,
 183     "0.9.8" => 0,
 184 };
 185
 186 our %table = ();
 187 our %config = ();
 188 our %withargs = ();
 189 our $now_printing;      # set to current entry's name in print_table_entry
 190                         # (todo: right thing would be to encapsulate name
 191                         # into %target [class] and make print_table_entry
 192                         # a method)
 193
 194 # Forward declarations ###############################################
 195
 196 # read_config(filename)
 197 #
 198 # Reads a configuration file and populates %table with the contents
 199 # (which the configuration file places in %targets).
 200 sub read_config;
 201
 202 # resolve_config(target)
 203 #
 204 # Resolves all the late evaluations, inheritances and so on for the
 205 # chosen target and any target it inherits from.
 206 sub resolve_config;
 207
 208
 209 # Information collection #############################################
 210
 211 # Unified build supports separate build dir
 212 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 213 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 214 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 215
 216 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 217
 218 $config{sourcedir} = abs2rel($srcdir);
 219 $config{builddir} = abs2rel($blddir);
 220
 221 # Collect reconfiguration information if needed
 222 my @argvcopy=@ARGV;
 223
 224 if (grep /^reconf(igure)?$/, @argvcopy) {
 225     die "reconfiguring with other arguments present isn't supported"
 226         if scalar @argvcopy > 1;
 227     if (-f "./configdata.pm") {
 228         my $file = "./configdata.pm";
 229         unless (my $return = do $file) {
 230             die "couldn't parse $file: $@" if $@;
 231             die "couldn't do $file: $!"    unless defined $return;
 232             die "couldn't run $file"       unless $return;
 233         }
 234
 235         @argvcopy = defined($configdata::config{perlargv}) ?
 236             @{$configdata::config{perlargv}} : ();
 237         die "Incorrect data to reconfigure, please do a normal configuration\n"
 238             if (grep(/^reconf/,@argvcopy));
 239         $config{perlenv} = $configdata::config{perlenv} // {};
 240     } else {
 241         die "Insufficient data to reconfigure, please do a normal configuration\n";
 242     }
 243 }
 244
 245 $config{perlargv} = [ @argvcopy ];
 246
 247 # Collect version numbers
 248 $config{major} = "unknown";
 249 $config{minor} = "unknown";
 250 $config{patch} = "unknown";
 251 $config{prerelease} = "";
 252 $config{build_metadata} = "";
 253 $config{shlib_version} = "unknown";
 254
 255 collect_information(
 256     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 257     qr/#\s+define\s+OPENSSL_VERSION_MAJOR\s+(\d+)/ =>
 258         sub { $config{major} = $1; },
 259     qr/#\s+define\s+OPENSSL_VERSION_MINOR\s+(\d+)/ =>
 260         sub { $config{minor} = $1; },
 261     qr/#\s+define\s+OPENSSL_VERSION_PATCH\s+(\d+)/ =>
 262         sub { $config{patch} = $1; },
 263     qr/#\s+define\s+OPENSSL_VERSION_PRE_RELEASE\s+"((?:\\.|[^"])*)"/ =>
 264         sub { $config{prerelease} = $1; },
 265     qr/#\s+define\s+OPENSSL_VERSION_BUILD_METADATA\s+"((?:\\.|[^"])*)"/ =>
 266         sub { $config{build_metadata} = $1; },
 267     qr/#\s+define\s+OPENSSL_SHLIB_VERSION\s+([\d\.]+)/ =>
 268         sub { $config{shlib_version} = $1; },
 269     );
 270 die "erroneous version information in opensslv.h: ",
 271     "$config{major}.$config{minor}.$config{patch}, $config{shlib_version}\n"
 272     if ($config{major} eq "unknown"
 273             || $config{minor} eq "unknown"
 274             || $config{patch} eq "unknown"
 275             || $config{shlib_version} eq "unknown");
 276
 277 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 278 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 279
 280 # Collect target configurations
 281
 282 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 283 foreach (sort glob($pattern)) {
 284     &read_config($_);
 285 }
 286
 287 if (defined env($local_config_envname)) {
 288     if ($^O eq 'VMS') {
 289         # VMS environment variables are logical names,
 290         # which can be used as is
 291         $pattern = $local_config_envname . ':' . '*.conf';
 292     } else {
 293         $pattern = catfile(env($local_config_envname), '*.conf');
 294     }
 295
 296     foreach (sort glob($pattern)) {
 297         &read_config($_);
 298     }
 299 }
 300
 301 # Save away perl command information
 302 $config{perl_cmd} = $^X;
 303 $config{perl_version} = $Config{version};
 304 $config{perl_archname} = $Config{archname};
 305
 306 $config{prefix}="";
 307 $config{openssldir}="";
 308 $config{processor}="";
 309 $config{libdir}="";
 310 my $auto_threads=1;    # enable threads automatically? true by default
 311 my $default_ranlib;
 312
 313 # Known TLS and DTLS protocols
 314 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 315 my @dtls = qw(dtls1 dtls1_2);
 316
 317 # Explicitly known options that are possible to disable.  They can
 318 # be regexps, and will be used like this: /^no-${option}$/
 319 # For developers: keep it sorted alphabetically
 320
 321 my @disablables = (
 322     "ktls",
 323     "afalgeng",
 324     "aria",
 325     "asan",
 326     "asm",
 327     "async",
 328     "autoalginit",
 329     "autoerrinit",
 330     "autoload-config",
 331     "bf",
 332     "blake2",
 333     "buildtest-c++",
 334     "camellia",
 335     "capieng",
 336     "cast",
 337     "chacha",
 338     "cmac",
 339     "cmp",
 340     "cms",
 341     "comp",
 342     "crypto-mdebug",
 343     "crypto-mdebug-backtrace",
 344     "ct",
 345     "deprecated",
 346     "des",
 347     "devcryptoeng",
 348     "dgram",
 349     "dh",
 350     "dsa",
 351     "dtls",
 352     "dynamic-engine",
 353     "ec",
 354     "ec2m",
 355     "ecdh",
 356     "ecdsa",
 357     "ec_nistp_64_gcc_128",
 358     "egd",
 359     "engine",
 360     "err",
 361     "external-tests",
 362     "filenames",
 363     "fips",
 364     "fuzz-libfuzzer",
 365     "fuzz-afl",
 366     "gost",
 367     "idea",
 368     "legacy",
 369     "makedepend",
 370     "md2",
 371     "md4",
 372     "mdc2",
 373     "module",
 374     "msan",
 375     "multiblock",
 376     "nextprotoneg",
 377     "pinshared",
 378     "ocb",
 379     "ocsp",
 380     "padlockeng",
 381     "pic",
 382     "poly1305",
 383     "posix-io",
 384     "psk",
 385     "rc2",
 386     "rc4",
 387     "rc5",
 388     "rdrand",
 389     "rfc3779",
 390     "rmd160",
 391     "scrypt",
 392     "sctp",
 393     "seed",
 394     "shared",
 395     "siphash",
 396     "siv",
 397     "sm2",
 398     "sm3",
 399     "sm4",
 400     "sock",
 401     "srp",
 402     "srtp",
 403     "sse2",
 404     "ssl",
 405     "ssl-trace",
 406     "static-engine",
 407     "stdio",
 408     "tests",
 409     "threads",
 410     "tls",
 411     "trace",
 412     "ts",
 413     "ubsan",
 414     "ui-console",
 415     "unit-test",
 416     "uplink",
 417     "whirlpool",
 418     "weak-ssl-ciphers",
 419     "zlib",
 420     "zlib-dynamic",
 421     );
 422 foreach my $proto ((@tls, @dtls))
 423         {
 424         push(@disablables, $proto);
 425         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 426         }
 427
 428 # Internal disablables, for aliasing purposes.  They serve no special
 429 # purpose here, but allow scripts to get to know them through configdata.pm,
 430 # where these are merged with @disablables.
 431 # The actual aliasing mechanism is done via %disable_cascades
 432 my @disablables_int = qw(
 433     crmf
 434     );
 435
 436 my %deprecated_disablables = (
 437     "ssl2" => undef,
 438     "buf-freelists" => undef,
 439     "hw" => "hw",               # causes cascade, but no macro
 440     "hw-padlock" => "padlockeng",
 441     "ripemd" => "rmd160",
 442     "ui" => "ui-console",
 443     "dso" => undef,
 444     "heartbeats" => undef,
 445     );
 446
 447 # All of the following are disabled by default:
 448
 449 our %disabled = ( # "what"         => "comment"
 450                   "asan"                => "default",
 451                   "buildtest-c++"       => "default",
 452                   "crypto-mdebug"       => "default",
 453                   "crypto-mdebug-backtrace" => "default",
 454                   "devcryptoeng"        => "default",
 455                   "ec_nistp_64_gcc_128" => "default",
 456                   "egd"                 => "default",
 457                   "external-tests"      => "default",
 458                   "fuzz-libfuzzer"      => "default",
 459                   "fuzz-afl"            => "default",
 460                   "md2"                 => "default",
 461                   "msan"                => "default",
 462                   "rc5"                 => "default",
 463                   "sctp"                => "default",
 464                   "ssl-trace"           => "default",
 465                   "ssl3"                => "default",
 466                   "ssl3-method"         => "default",
 467                   "trace"               => "default",
 468                   "ubsan"               => "default",
 469                   "unit-test"           => "default",
 470                   "weak-ssl-ciphers"    => "default",
 471                   "zlib"                => "default",
 472                   "zlib-dynamic"        => "default",
 473                   "ktls"                => "default",
 474                 );
 475
 476 # Note: => pair form used for aesthetics, not to truly make a hash table
 477 my @disable_cascades = (
 478     # "what"            => [ "cascade", ... ]
 479     sub { $config{processor} eq "386" }
 480                         => [ "sse2" ],
 481     "ssl"               => [ "ssl3" ],
 482     "ssl3-method"       => [ "ssl3" ],
 483     "zlib"              => [ "zlib-dynamic" ],
 484     "des"               => [ "mdc2" ],
 485     "ec"                => [ "ecdsa", "ecdh", "sm2" ],
 486     sub { $disabled{"ec"} && $disabled{"dh"} }
 487                         => [ "tls1_3" ],
 488     "dgram"             => [ "dtls", "sctp" ],
 489     "sock"              => [ "dgram" ],
 490     "dtls"              => [ @dtls ],
 491     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 492                         => [ "dtls" ],
 493
 494     "tls"               => [ @tls ],
 495     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 496                         => [ "tls" ],
 497
 498     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 499
 500     # If no modules, then no dynamic engines either
 501     "module"            => [ "dynamic-engine" ],
 502
 503     # Without shared libraries, dynamic engines aren't possible.
 504     # This is due to them having to link with libcrypto and register features
 505     # using the ENGINE functionality, and since that relies on global tables,
 506     # those *have* to be exacty the same as the ones accessed from the app,
 507     # which cannot be guaranteed if shared libraries aren't present.
 508     # (note that even with shared libraries, both the app and dynamic engines
 509     # must be linked with the same library)
 510     "shared"            => [ "dynamic-engine", "uplink" ],
 511     # Other modules don't necessarily have to link with libcrypto, so shared
 512     # libraries do not have to be a condition to produce those.
 513
 514     # Without position independent code, there can be no shared libraries
 515     # or modules.
 516     "pic"               => [ "shared", "module" ],
 517
 518     "module"            => [ "fips", "legacy" ],
 519
 520     "engine"            => [ grep /eng$/, @disablables ],
 521     "hw"                => [ "padlockeng" ],
 522
 523     # no-autoalginit is only useful when building non-shared
 524     "autoalginit"       => [ "shared", "apps" ],
 525
 526     "stdio"             => [ "apps", "capieng", "egd" ],
 527     "apps"              => [ "tests" ],
 528     "tests"             => [ "external-tests" ],
 529     "comp"              => [ "zlib" ],
 530     "sm3"               => [ "sm2" ],
 531     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 532
 533     sub { !$disabled{"msan"} } => [ "asm" ],
 534
 535     sub { $disabled{cmac}; } => [ "siv" ],
 536     "legacy"                 => [ "md2" ],
 537
 538     "cmp"               => [ "crmf" ],
 539     );
 540
 541 # Avoid protocol support holes.  Also disable all versions below N, if version
 542 # N is disabled while N+1 is enabled.
 543 #
 544 my @list = (reverse @tls);
 545 while ((my $first, my $second) = (shift @list, shift @list)) {
 546     last unless @list;
 547     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 548                               => [ @list ] );
 549     unshift @list, $second;
 550 }
 551 my @list = (reverse @dtls);
 552 while ((my $first, my $second) = (shift @list, shift @list)) {
 553     last unless @list;
 554     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 555                               => [ @list ] );
 556     unshift @list, $second;
 557 }
 558
 559 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 560 # To remove something from %disabled, use "enable-foo".
 561 # For symmetry, "disable-foo" is a synonym for "no-foo".
 562
 563 &usage if ($#ARGV < 0);
 564
 565 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 566 # platform specific list separators.  Users from those platforms should
 567 # recognise those separators from how you set up the PATH to find executables.
 568 # The default is the Unix like separator, :, but as an exception, we also
 569 # support the space as separator.
 570 my $list_separator_re =
 571     { VMS           => qr/(?<!\^),/,
 572       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 573 # All the "make variables" we support
 574 # Some get pre-populated for the sake of backward compatibility
 575 # (we supported those before the change to "make variable" support.
 576 my %user = (
 577     AR          => env('AR'),
 578     ARFLAGS     => [],
 579     AS          => undef,
 580     ASFLAGS     => [],
 581     CC          => env('CC'),
 582     CFLAGS      => [ env('CFLAGS') || () ],
 583     CXX         => env('CXX'),
 584     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 585     CPP         => undef,
 586     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 587     CPPDEFINES  => [],  # Alternative for -D
 588     CPPINCLUDES => [],  # Alternative for -I
 589     CROSS_COMPILE => env('CROSS_COMPILE'),
 590     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 591     LD          => undef,
 592     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 593     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 594     MT          => undef,
 595     MTFLAGS     => [],
 596     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 597     RANLIB      => env('RANLIB'),
 598     RC          => env('RC') || env('WINDRES'),
 599     RCFLAGS     => [ env('RCFLAGS') || () ],
 600     RM          => undef,
 601    );
 602 # Info about what "make variables" may be prefixed with the cross compiler
 603 # prefix.  This should NEVER mention any such variable with a list for value.
 604 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 605 # The same but for flags given as Configure options.  These are *additional*
 606 # input, as opposed to the VAR=string option that override the corresponding
 607 # config target attributes
 608 my %useradd = (
 609     CPPDEFINES  => [],
 610     CPPINCLUDES => [],
 611     CPPFLAGS    => [],
 612     CFLAGS      => [],
 613     CXXFLAGS    => [],
 614     LDFLAGS     => [],
 615     LDLIBS      => [],
 616     RCFLAGS     => [],
 617    );
 618
 619 my %user_synonyms = (
 620     HASHBANGPERL=> 'PERL',
 621     RC          => 'WINDRES',
 622    );
 623
 624 # Some target attributes have been renamed, this is the translation table
 625 my %target_attr_translate =(
 626     ar          => 'AR',
 627     as          => 'AS',
 628     cc          => 'CC',
 629     cxx         => 'CXX',
 630     cpp         => 'CPP',
 631     hashbangperl => 'HASHBANGPERL',
 632     ld          => 'LD',
 633     mt          => 'MT',
 634     ranlib      => 'RANLIB',
 635     rc          => 'RC',
 636     rm          => 'RM',
 637    );
 638
 639 # Initialisers coming from 'config' scripts
 640 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 641 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 642 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 643 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 644 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 645 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 646 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 647
 648 $config{openssl_api_defines}=[];
 649 $config{openssl_sys_defines}=[];
 650 $config{openssl_feature_defines}=[];
 651 $config{options}="";
 652 $config{build_type} = "release";
 653 my $target="";
 654
 655 my %cmdvars = ();               # Stores FOO='blah' type arguments
 656 my %unsupported_options = ();
 657 my %deprecated_options = ();
 658 # If you change this, update apps/version.c
 659 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 660 my @seed_sources = ();
 661 while (@argvcopy)
 662         {
 663         $_ = shift @argvcopy;
 664
 665         # Support env variable assignments among the options
 666         if (m|^(\w+)=(.+)?$|)
 667                 {
 668                 $cmdvars{$1} = $2;
 669                 # Every time a variable is given as a configuration argument,
 670                 # it acts as a reset if the variable.
 671                 if (exists $user{$1})
 672                         {
 673                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 674                         }
 675                 #if (exists $useradd{$1})
 676                 #       {
 677                 #       $useradd{$1} = [];
 678                 #       }
 679                 next;
 680                 }
 681
 682         # VMS is a case insensitive environment, and depending on settings
 683         # out of our control, we may receive options uppercased.  Let's
 684         # downcase at least the part before any equal sign.
 685         if ($^O eq "VMS")
 686                 {
 687                 s/^([^=]*)/lc($1)/e;
 688                 }
 689
 690         # some people just can't read the instructions, clang people have to...
 691         s/^-no-(?!integrated-as)/no-/;
 692
 693         # rewrite some options in "enable-..." form
 694         s /^-?-?shared$/enable-shared/;
 695         s /^sctp$/enable-sctp/;
 696         s /^threads$/enable-threads/;
 697         s /^zlib$/enable-zlib/;
 698         s /^zlib-dynamic$/enable-zlib-dynamic/;
 699
 700         if (/^(no|disable|enable)-(.+)$/)
 701                 {
 702                 my $word = $2;
 703                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 704                         && !exists $deprecated_disablables{$word}
 705                         && !grep { $word eq $_ } @disablables)
 706                         {
 707                         $unsupported_options{$_} = 1;
 708                         next;
 709                         }
 710                 }
 711         if (/^no-(.+)$/ || /^disable-(.+)$/)
 712                 {
 713                 foreach my $proto ((@tls, @dtls))
 714                         {
 715                         if ($1 eq "$proto-method")
 716                                 {
 717                                 $disabled{"$proto"} = "option($proto-method)";
 718                                 last;
 719                                 }
 720                         }
 721                 if ($1 eq "dtls")
 722                         {
 723                         foreach my $proto (@dtls)
 724                                 {
 725                                 $disabled{$proto} = "option(dtls)";
 726                                 }
 727                         $disabled{"dtls"} = "option(dtls)";
 728                         }
 729                 elsif ($1 eq "ssl")
 730                         {
 731                         # Last one of its kind
 732                         $disabled{"ssl3"} = "option(ssl)";
 733                         }
 734                 elsif ($1 eq "tls")
 735                         {
 736                         # XXX: Tests will fail if all SSL/TLS
 737                         # protocols are disabled.
 738                         foreach my $proto (@tls)
 739                                 {
 740                                 $disabled{$proto} = "option(tls)";
 741                                 }
 742                         }
 743                 elsif ($1 eq "static-engine")
 744                         {
 745                         delete $disabled{"dynamic-engine"};
 746                         }
 747                 elsif ($1 eq "dynamic-engine")
 748                         {
 749                         $disabled{"dynamic-engine"} = "option";
 750                         }
 751                 elsif (exists $deprecated_disablables{$1})
 752                         {
 753                         $deprecated_options{$_} = 1;
 754                         if (defined $deprecated_disablables{$1})
 755                                 {
 756                                 $disabled{$deprecated_disablables{$1}} = "option";
 757                                 }
 758                         }
 759                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 760                         {
 761                         $deprecated_options{$_} = 1;
 762                         }
 763                 else
 764                         {
 765                         $disabled{$1} = "option";
 766                         }
 767                 # No longer an automatic choice
 768                 $auto_threads = 0 if ($1 eq "threads");
 769                 }
 770         elsif (/^enable-(.+)$/)
 771                 {
 772                 if ($1 eq "static-engine")
 773                         {
 774                         $disabled{"dynamic-engine"} = "option";
 775                         }
 776                 elsif ($1 eq "dynamic-engine")
 777                         {
 778                         delete $disabled{"dynamic-engine"};
 779                         }
 780                 elsif ($1 eq "zlib-dynamic")
 781                         {
 782                         delete $disabled{"zlib"};
 783                         }
 784                 my $algo = $1;
 785                 delete $disabled{$algo};
 786
 787                 # No longer an automatic choice
 788                 $auto_threads = 0 if ($1 eq "threads");
 789                 }
 790         elsif (/^--strict-warnings$/)
 791                 {
 792                 # Pretend that our strict flags is a C flag, and replace it
 793                 # with the proper flags later on
 794                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 795                 $strict_warnings=1;
 796                 }
 797         elsif (/^--debug$/)
 798                 {
 799                 $config{build_type} = "debug";
 800                 }
 801         elsif (/^--release$/)
 802                 {
 803                 $config{build_type} = "release";
 804                 }
 805         elsif (/^386$/)
 806                 { $config{processor}=386; }
 807         elsif (/^fips$/)
 808                 {
 809                 die "FIPS mode not supported\n";
 810                 }
 811         elsif (/^rsaref$/)
 812                 {
 813                 # No RSAref support any more since it's not needed.
 814                 # The check for the option is there so scripts aren't
 815                 # broken
 816                 }
 817         elsif (/^nofipscanistercheck$/)
 818                 {
 819                 die "FIPS mode not supported\n";
 820                 }
 821         elsif (/^[-+]/)
 822                 {
 823                 if (/^--prefix=(.*)$/)
 824                         {
 825                         $config{prefix}=$1;
 826                         die "Directory given with --prefix MUST be absolute\n"
 827                                 unless file_name_is_absolute($config{prefix});
 828                         }
 829                 elsif (/^--api=(.*)$/)
 830                         {
 831                         $config{api}=$1;
 832                         }
 833                 elsif (/^--libdir=(.*)$/)
 834                         {
 835                         $config{libdir}=$1;
 836                         }
 837                 elsif (/^--openssldir=(.*)$/)
 838                         {
 839                         $config{openssldir}=$1;
 840                         }
 841                 elsif (/^--with-zlib-lib=(.*)$/)
 842                         {
 843                         $withargs{zlib_lib}=$1;
 844                         }
 845                 elsif (/^--with-zlib-include=(.*)$/)
 846                         {
 847                         $withargs{zlib_include}=$1;
 848                         }
 849                 elsif (/^--with-fuzzer-lib=(.*)$/)
 850                         {
 851                         $withargs{fuzzer_lib}=$1;
 852                         }
 853                 elsif (/^--with-fuzzer-include=(.*)$/)
 854                         {
 855                         $withargs{fuzzer_include}=$1;
 856                         }
 857                 elsif (/^--with-rand-seed=(.*)$/)
 858                         {
 859                         foreach my $x (split(m|,|, $1))
 860                             {
 861                             die "Unknown --with-rand-seed choice $x\n"
 862                                 if ! grep { $x eq $_ } @known_seed_sources;
 863                             push @seed_sources, $x;
 864                             }
 865                         }
 866                 elsif (/^--cross-compile-prefix=(.*)$/)
 867                         {
 868                         $user{CROSS_COMPILE}=$1;
 869                         }
 870                 elsif (/^--config=(.*)$/)
 871                         {
 872                         read_config $1;
 873                         }
 874                 elsif (/^-l(.*)$/)
 875                         {
 876                         push @{$useradd{LDLIBS}}, $_;
 877                         }
 878                 elsif (/^-framework$/)
 879                         {
 880                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 881                         }
 882                 elsif (/^-L(.*)$/ or /^-Wl,/)
 883                         {
 884                         push @{$useradd{LDFLAGS}}, $_;
 885                         }
 886                 elsif (/^-rpath$/ or /^-R$/)
 887                         # -rpath is the OSF1 rpath flag
 888                         # -R is the old Solaris rpath flag
 889                         {
 890                         my $rpath = shift(@argvcopy) || "";
 891                         $rpath .= " " if $rpath ne "";
 892                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 893                         }
 894                 elsif (/^-static$/)
 895                         {
 896                         push @{$useradd{LDFLAGS}}, $_;
 897                         }
 898                 elsif (/^-D(.*)$/)
 899                         {
 900                         push @{$useradd{CPPDEFINES}}, $1;
 901                         }
 902                 elsif (/^-I(.*)$/)
 903                         {
 904                         push @{$useradd{CPPINCLUDES}}, $1;
 905                         }
 906                 elsif (/^-Wp,$/)
 907                         {
 908                         push @{$useradd{CPPFLAGS}}, $1;
 909                         }
 910                 else    # common if (/^[-+]/), just pass down...
 911                         {
 912                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 913                         push @{$useradd{CFLAGS}}, $_;
 914                         push @{$useradd{CXXFLAGS}}, $_;
 915                         }
 916                 }
 917         else
 918                 {
 919                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 920                 $target=$_;
 921                 }
 922         unless ($_ eq $target || /^no-/ || /^disable-/)
 923                 {
 924                 # "no-..." follows later after implied deactivations
 925                 # have been derived.  (Don't take this too seriously,
 926                 # we really only write OPTIONS to the Makefile out of
 927                 # nostalgia.)
 928
 929                 if ($config{options} eq "")
 930                         { $config{options} = $_; }
 931                 else
 932                         { $config{options} .= " ".$_; }
 933                 }
 934         }
 935
 936 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 937         die "***** Unsupported api compatibility level: $config{api}\n",
 938 }
 939
 940 if (keys %deprecated_options)
 941         {
 942         warn "***** Deprecated options: ",
 943                 join(", ", keys %deprecated_options), "\n";
 944         }
 945 if (keys %unsupported_options)
 946         {
 947         die "***** Unsupported options: ",
 948                 join(", ", keys %unsupported_options), "\n";
 949         }
 950
 951 # If any %useradd entry has been set, we must check that the "make
 952 # variables" haven't been set.  We start by checking of any %useradd entry
 953 # is set.
 954 if (grep { scalar @$_ > 0 } values %useradd) {
 955     # Hash of env / make variables names.  The possible values are:
 956     # 1 - "make vars"
 957     # 2 - %useradd entry set
 958     # 3 - both set
 959     my %detected_vars =
 960         map { my $v = 0;
 961               $v += 1 if $cmdvars{$_};
 962               $v += 2 if @{$useradd{$_}};
 963               $_ => $v }
 964         keys %useradd;
 965
 966     # If any of the corresponding "make variables" is set, we error
 967     if (grep { $_ & 1 } values %detected_vars) {
 968         my $names = join(', ', grep { $detected_vars{$_} > 0 }
 969                                sort keys %detected_vars);
 970         die <<"_____";
 971 ***** Mixing make variables and additional compiler/linker flags as
 972 ***** configure command line option is not permitted.
 973 ***** Affected make variables: $names
 974 _____
 975     }
 976 }
 977
 978 # Check through all supported command line variables to see if any of them
 979 # were set, and canonicalise the values we got.  If no compiler or linker
 980 # flag or anything else that affects %useradd was set, we also check the
 981 # environment for values.
 982 my $anyuseradd =
 983     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
 984 foreach (keys %user) {
 985     my $value = $cmdvars{$_};
 986     $value //= env($_) unless $anyuseradd;
 987     $value //=
 988         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
 989     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
 990         unless $anyuseradd;
 991
 992     if (defined $value) {
 993         if (ref $user{$_} eq 'ARRAY') {
 994             $user{$_} = [ split /$list_separator_re/, $value ];
 995         } elsif (!defined $user{$_}) {
 996             $user{$_} = $value;
 997         }
 998     }
 999 }
1000
1001 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1002     && !$disabled{shared}
1003     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1004     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1005         "***** any of asan, msan or ubsan\n";
1006 }
1007
1008 sub disable {
1009     my $disable_type = shift;
1010
1011     for (@_) {
1012         $disabled{$_} = $disable_type;
1013     }
1014
1015     my @tocheckfor = (@_ ? @_ : keys %disabled);
1016     while (@tocheckfor) {
1017         my %new_tocheckfor = ();
1018         my @cascade_copy = (@disable_cascades);
1019         while (@cascade_copy) {
1020             my ($test, $descendents) =
1021                 (shift @cascade_copy, shift @cascade_copy);
1022             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1023                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1024                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1025                 }
1026             }
1027         }
1028         @tocheckfor = (keys %new_tocheckfor);
1029     }
1030 }
1031 disable();                     # First cascade run
1032
1033 our $die = sub { die @_; };
1034 if ($target eq "TABLE") {
1035     local $die = sub { warn @_; };
1036     foreach (sort keys %table) {
1037         print_table_entry($_, "TABLE");
1038     }
1039     exit 0;
1040 }
1041
1042 if ($target eq "LIST") {
1043     foreach (sort keys %table) {
1044         print $_,"\n" unless $table{$_}->{template};
1045     }
1046     exit 0;
1047 }
1048
1049 if ($target eq "HASH") {
1050     local $die = sub { warn @_; };
1051     print "%table = (\n";
1052     foreach (sort keys %table) {
1053         print_table_entry($_, "HASH");
1054     }
1055     exit 0;
1056 }
1057
1058 print "Configuring OpenSSL version $config{full_version} ";
1059 print "for target $target\n";
1060
1061 if (scalar(@seed_sources) == 0) {
1062     print "Using os-specific seed configuration\n";
1063     push @seed_sources, 'os';
1064 }
1065 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1066     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1067     warn <<_____ if scalar(@seed_sources) == 1;
1068
1069 ============================== WARNING ===============================
1070 You have selected the --with-rand-seed=none option, which effectively
1071 disables automatic reseeding of the OpenSSL random generator.
1072 All operations depending on the random generator such as creating keys
1073 will not work unless the random generator is seeded manually by the
1074 application.
1075
1076 Please read the 'Note on random number generation' section in the
1077 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1078 ============================== WARNING ===============================
1079
1080 _____
1081 }
1082 push @{$config{openssl_feature_defines}},
1083      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1084         @seed_sources;
1085
1086 # Backward compatibility?
1087 if ($target =~ m/^CygWin32(-.*)$/) {
1088     $target = "Cygwin".$1;
1089 }
1090
1091 # Support for legacy targets having a name starting with 'debug-'
1092 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1093 if ($d) {
1094     $config{build_type} = "debug";
1095
1096     # If we do not find debug-foo in the table, the target is set to foo.
1097     if (!$table{$target}) {
1098         $target = $t;
1099     }
1100 }
1101
1102 &usage if !$table{$target} || $table{$target}->{template};
1103
1104 $config{target} = $target;
1105 my %target = resolve_config($target);
1106
1107 foreach (keys %target_attr_translate) {
1108     $target{$target_attr_translate{$_}} = $target{$_}
1109         if $target{$_};
1110     delete $target{$_};
1111 }
1112
1113 %target = ( %{$table{DEFAULTS}}, %target );
1114
1115 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1116 $config{conf_files} = [ sort keys %conf_files ];
1117
1118 # Using sub disable within these loops may prove fragile, so we run
1119 # a cascade afterwards
1120 foreach my $feature (@{$target{disable}}) {
1121     if (exists $deprecated_disablables{$feature}) {
1122         warn "***** config $target disables deprecated feature $feature\n";
1123     } elsif (!grep { $feature eq $_ } @disablables) {
1124         die "***** config $target disables unknown feature $feature\n";
1125     }
1126     $disabled{$feature} = 'config';
1127 }
1128 foreach my $feature (@{$target{enable}}) {
1129     if ("default" eq ($disabled{$feature} // "")) {
1130         if (exists $deprecated_disablables{$feature}) {
1131             warn "***** config $target enables deprecated feature $feature\n";
1132         } elsif (!grep { $feature eq $_ } @disablables) {
1133             die "***** config $target enables unknown feature $feature\n";
1134         }
1135         delete $disabled{$feature};
1136     }
1137 }
1138
1139 # If uplink_arch isn't defined, disable uplink
1140 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1141 # If asm_arch isn't defined, disable asm
1142 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1143
1144 disable();                      # Run a cascade now
1145
1146 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1147 $target{cxxflags}//=$target{cflags} if $target{CXX};
1148 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1149 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1150
1151 # Fill %config with values from %user, and in case those are undefined or
1152 # empty, use values from %target (acting as a default).
1153 foreach (keys %user) {
1154     my $ref_type = ref $user{$_};
1155
1156     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1157     # and a value that's to be coerced into that type.
1158     my $mkvalue = sub {
1159         my $type = shift;
1160         my $value = shift;
1161         my $undef_p = shift;
1162
1163         die "Too many arguments for \$mkvalue" if @_;
1164
1165         while (ref $value eq 'CODE') {
1166             $value = $value->();
1167         }
1168
1169         if ($type eq 'ARRAY') {
1170             return undef unless defined $value;
1171             return undef if ref $value ne 'ARRAY' && !$value;
1172             return undef if ref $value eq 'ARRAY' && !@$value;
1173             return [ $value ] unless ref $value eq 'ARRAY';
1174         }
1175         return undef unless $value;
1176         return $value;
1177     };
1178
1179     $config{$_} =
1180         $mkvalue->($ref_type, $user{$_})
1181         || $mkvalue->($ref_type, $target{$_});
1182     delete $config{$_} unless defined $config{$_};
1183 }
1184
1185 # Finish up %config by appending things the user gave us on the command line
1186 # apart from "make variables"
1187 foreach (keys %useradd) {
1188     # The must all be lists, so we assert that here
1189     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1190         unless ref $useradd{$_} eq 'ARRAY';
1191
1192     if (defined $config{$_}) {
1193         push @{$config{$_}}, @{$useradd{$_}};
1194     } else {
1195         $config{$_} = [ @{$useradd{$_}} ];
1196     }
1197 }
1198 # At this point, we can forget everything about %user and %useradd,
1199 # because it's now all been merged into the corresponding $config entry
1200
1201 # Allow overriding the build file name
1202 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1203
1204 ######################################################################
1205 # Build up information for skipping certain directories depending on disabled
1206 # features, as well as setting up macros for disabled features.
1207
1208 # This is a tentative database of directories to skip.  Some entries may not
1209 # correspond to anything real, but that's ok, they will simply be ignored.
1210 # The actual processing of these entries is done in the build.info lookup
1211 # loop further down.
1212 #
1213 # The key is a Unix formated path in the source tree, the value is an index
1214 # into %disabled_info, so any existing path gets added to a corresponding
1215 # 'skipped' entry in there with the list of skipped directories.
1216 my %skipdir = ();
1217 my %disabled_info = ();         # For configdata.pm
1218 foreach my $what (sort keys %disabled) {
1219     # There are deprecated disablables that translate to themselves.
1220     # They cause disabling cascades, but should otherwise not regiter.
1221     next if $deprecated_disablables{$what};
1222
1223     $config{options} .= " no-$what";
1224
1225     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1226                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1227                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1228         (my $WHAT = uc $what) =~ s|-|_|g;
1229         my $skipdir = $what;
1230
1231         # fix-up crypto/directory name(s)
1232         $skipdir = "ripemd" if $what eq "rmd160";
1233         $skipdir = "whrlpool" if $what eq "whirlpool";
1234
1235         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1236         push @{$config{openssl_feature_defines}}, $macro;
1237
1238         $skipdir{engines} = $what if $what eq 'engine';
1239         $skipdir{"crypto/$skipdir"} = $what
1240             unless $what eq 'async' || $what eq 'err';
1241     }
1242 }
1243
1244 # Make sure build_scheme is consistent.
1245 $target{build_scheme} = [ $target{build_scheme} ]
1246     if ref($target{build_scheme}) ne "ARRAY";
1247
1248 my ($builder, $builder_platform, @builder_opts) =
1249     @{$target{build_scheme}};
1250
1251 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1252                       $builder_platform."-checker.pm")) {
1253     my $checker_path = catfile($srcdir, "Configurations", $checker);
1254     if (-f $checker_path) {
1255         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1256             ? sub { warn $@; } : sub { die $@; };
1257         if (! do $checker_path) {
1258             if ($@) {
1259                 $fn->($@);
1260             } elsif ($!) {
1261                 $fn->($!);
1262             } else {
1263                 $fn->("The detected tools didn't match the platform\n");
1264             }
1265         }
1266         last;
1267     }
1268 }
1269
1270 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1271
1272 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1273         {
1274         push @{$config{cflags}}, "-mno-cygwin";
1275         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1276         push @{$config{shared_ldflag}}, "-mno-cygwin";
1277         }
1278
1279 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1280         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1281         # minimally required architecture flags for assembly modules
1282         my $value;
1283         $value = '-mips2' if ($target =~ /mips32/);
1284         $value = '-mips3' if ($target =~ /mips64/);
1285         unshift @{$config{cflags}}, $value;
1286         unshift @{$config{cxxflags}}, $value if $config{CXX};
1287 }
1288
1289 # If threads aren't disabled, check how possible they are
1290 unless ($disabled{threads}) {
1291     if ($auto_threads) {
1292         # Enabled by default, disable it forcibly if unavailable
1293         if ($target{thread_scheme} eq "(unknown)") {
1294             disable("unavailable", 'threads');
1295         }
1296     } else {
1297         # The user chose to enable threads explicitly, let's see
1298         # if there's a chance that's possible
1299         if ($target{thread_scheme} eq "(unknown)") {
1300             # If the user asked for "threads" and we don't have internal
1301             # knowledge how to do it, [s]he is expected to provide any
1302             # system-dependent compiler options that are necessary.  We
1303             # can't truly check that the given options are correct, but
1304             # we expect the user to know what [s]He is doing.
1305             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1306                 die "You asked for multi-threading support, but didn't\n"
1307                     ,"provide any system-specific compiler options\n";
1308             }
1309         }
1310     }
1311 }
1312
1313 # Find out if clang's sanitizers have been enabled with -fsanitize
1314 # flags and ensure that the corresponding %disabled elements area
1315 # removed to reflect that the sanitizers are indeed enabled.
1316 my %detected_sanitizers = ();
1317 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1318     (my $checks = $_) =~ s/^-fsanitize=//;
1319     foreach (split /,/, $checks) {
1320         my $d = { address       => 'asan',
1321                   undefined     => 'ubsan',
1322                   memory        => 'msan' } -> {$_};
1323         next unless defined $d;
1324
1325         $detected_sanitizers{$d} = 1;
1326         if (defined $disabled{$d}) {
1327             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1328                 if $disabled{$d} ne "default";
1329             delete $disabled{$d};
1330         }
1331     }
1332 }
1333
1334 # If threads still aren't disabled, add a C macro to ensure the source
1335 # code knows about it.  Any other flag is taken care of by the configs.
1336 unless($disabled{threads}) {
1337     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1338 }
1339
1340 # With "deprecated" disable all deprecated features.
1341 if (defined($disabled{"deprecated"})) {
1342         $config{api} = $maxapi;
1343 }
1344
1345 my $no_shared_warn=0;
1346 if ($target{shared_target} eq "")
1347         {
1348         $no_shared_warn = 1
1349             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1350         disable('no-shared-target', 'pic');
1351         }
1352
1353 if ($disabled{"dynamic-engine"}) {
1354         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1355         $config{dynamic_engines} = 0;
1356 } else {
1357         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1358         $config{dynamic_engines} = 1;
1359 }
1360
1361 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1362     push @{$config{cflags}}, "-fsanitize=address";
1363 }
1364
1365 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1366     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1367     # platforms.
1368     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1369 }
1370
1371 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1372   push @{$config{cflags}}, "-fsanitize=memory";
1373 }
1374
1375 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1376         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1377     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1378     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1379 }
1380 #
1381 # Platform fix-ups
1382 #
1383
1384 # This saves the build files from having to check
1385 if ($disabled{pic})
1386         {
1387         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1388                     shared_defines shared_includes shared_ldflag
1389                     module_cflags module_cxxflags module_cppflags
1390                     module_defines module_includes module_lflags))
1391                 {
1392                 delete $config{$_};
1393                 $target{$_} = "";
1394                 }
1395         }
1396 else
1397         {
1398         push @{$config{lib_defines}}, "OPENSSL_PIC";
1399         }
1400
1401 if ($target{sys_id} ne "")
1402         {
1403         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1404         }
1405
1406 unless ($disabled{asm}) {
1407     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1408     if ($target{cpuid_asm_src} ne "mem_clr.c") {
1409         push @{$config{lib_defines}}, "OPENSSL_CPUID_OBJ";
1410         push @{$config{module_defines}}, "OPENSSL_CPUID_OBJ";
1411     }
1412
1413     if ($target{sha1_asm_src}) {
1414         push @{$config{lib_defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1415         push @{$config{lib_defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1416         push @{$config{lib_defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1417     }
1418     if ($target{keccak1600_asm_src} ne $table{DEFAULTS}->{keccak1600_asm_src}) {
1419         push @{$config{lib_defines}}, "KECCAK1600_ASM";
1420     }
1421     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1422         push @{$config{lib_defines}}, "RC4_ASM";
1423     }
1424     if ($target{md5_asm_src}) {
1425         push @{$config{lib_defines}}, "MD5_ASM";
1426     }
1427     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1428     if ($target{rmd160_asm_src}) {
1429         push @{$config{lib_defines}}, "RMD160_ASM";
1430     }
1431     if ($target{aes_asm_src}) {
1432         if ($target{aes_asm_src} =~ m/\baes-/) {
1433             push @{$config{lib_defines}}, "AES_ASM";
1434             push @{$config{module_defines}}, "AES_ASM";
1435         }
1436         # aes-ctr.fake is not a real file, only indication that assembler
1437         # module implements AES_ctr32_encrypt...
1438         if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//) {
1439             push @{$config{lib_defines}}, "AES_CTR_ASM";
1440             push @{$config{module_defines}}, "AES_CTR_ASM";
1441         }
1442         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1443         if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//) {
1444             push @{$config{lib_defines}}, "AES_XTS_ASM";
1445             push @{$config{module_defines}}, "AES_XTS_ASM";
1446         }
1447         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($disabled{sse2});
1448         if ($target{aes_asm_src} =~ m/vpaes/) {
1449             push @{$config{lib_defines}}, "VPAES_ASM";
1450             push @{$config{module_defines}}, "VPAES_ASM";
1451         }
1452         if ($target{aes_asm_src} =~ m/bsaes/) {
1453             push @{$config{lib_defines}}, "BSAES_ASM";
1454             push @{$config{module_defines}}, "BSAES_ASM";
1455         }
1456     }
1457     if ($target{wp_asm_src} =~ /mmx/) {
1458         if ($config{processor} eq "386") {
1459             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1460         } elsif (!$disabled{"whirlpool"}) {
1461             push @{$config{lib_defines}}, "WHIRLPOOL_ASM";
1462         }
1463     }
1464     if ($target{modes_asm_src} =~ /ghash-/) {
1465         push @{$config{lib_defines}}, "GHASH_ASM";
1466     }
1467     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1468         push @{$config{lib_defines}}, "ECP_NISTZ256_ASM";
1469     }
1470     if ($target{ec_asm_src} =~ /x25519/) {
1471         push @{$config{lib_defines}}, "X25519_ASM";
1472     }
1473     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1474         push @{$config{dso_defines}}, "PADLOCK_ASM";
1475     }
1476     if ($target{poly1305_asm_src} ne "") {
1477         push @{$config{lib_defines}}, "POLY1305_ASM";
1478     }
1479 }
1480
1481 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1482 my %predefined_CXX = $config{CXX}
1483     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1484     : ();
1485
1486 # Check for makedepend capabilities.
1487 if (!$disabled{makedepend}) {
1488     if ($config{target} =~ /^(VC|vms)-/) {
1489         # For VC- and vms- targets, there's nothing more to do here.  The
1490         # functionality is hard coded in the corresponding build files for
1491         # cl (Windows) and CC/DECC (VMS).
1492     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1493              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1494         # We know that GNU C version 3 and up as well as all clang
1495         # versions support dependency generation, but Xcode did not
1496         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1497         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1498     } else {
1499         # In all other cases, we look for 'makedepend', and disable the
1500         # capability if not found.
1501         $config{makedepprog} = which('makedepend');
1502         disable('unavailable', 'makedepend') unless $config{makedepprog};
1503     }
1504 }
1505
1506 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1507     # probe for -Wa,--noexecstack option...
1508     if ($predefined_C{__clang__}) {
1509         # clang has builtin assembler, which doesn't recognize --help,
1510         # but it apparently recognizes the option in question on all
1511         # supported platforms even when it's meaningless. In other words
1512         # probe would fail, but probed option always accepted...
1513         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1514     } else {
1515         my $cc = $config{CROSS_COMPILE}.$config{CC};
1516         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1517         while(<PIPE>) {
1518             if (m/--noexecstack/) {
1519                 push @{$config{cflags}}, "-Wa,--noexecstack";
1520                 last;
1521             }
1522         }
1523         close(PIPE);
1524         unlink("null.$$.o");
1525     }
1526 }
1527
1528 # Deal with bn_ops ###################################################
1529
1530 $config{bn_ll}                  =0;
1531 $config{export_var_as_fn}       =0;
1532 my $def_int="unsigned int";
1533 $config{rc4_int}                =$def_int;
1534 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1535
1536 my $count = 0;
1537 foreach (sort split(/\s+/,$target{bn_ops})) {
1538     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1539     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1540     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1541     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1542     ($config{b64l},$config{b64},$config{b32})
1543         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1544     ($config{b64l},$config{b64},$config{b32})
1545         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1546     ($config{b64l},$config{b64},$config{b32})
1547         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1548 }
1549 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1550     if $count > 1;
1551
1552
1553 # Hack cflags for better warnings (dev option) #######################
1554
1555 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1556 # a string and works as well on command lines.
1557 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1558                         @{$config{cflags}} ];
1559 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1560                           @{$config{cxxflags}} ] if $config{CXX};
1561
1562 $config{openssl_api_defines} = [
1563     "OPENSSL_MIN_API=".($apitable->{$config{api} // ""} // -1)
1564 ];
1565
1566 my @strict_warnings_collection=();
1567 if ($strict_warnings)
1568         {
1569         my $wopt;
1570         my $gccver = $predefined_C{__GNUC__} // -1;
1571
1572         warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike"
1573             unless $gccver >= 4;
1574         push @strict_warnings_collection, @gcc_devteam_warn;
1575         push @strict_warnings_collection, @clang_devteam_warn
1576             if (defined($predefined_C{__clang__}));
1577         }
1578
1579 if (grep { $_ eq '-static' } @{$config{LDFLAGS}}) {
1580     disable('static', 'pic', 'threads');
1581 }
1582
1583 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1584                               ? @strict_warnings_collection
1585                               : ( $_ ) }
1586                     @{$config{CFLAGS}} ];
1587
1588 unless ($disabled{"crypto-mdebug-backtrace"})
1589         {
1590         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1591                 {
1592                 push @{$config{cflags}}, $wopt
1593                         unless grep { $_ eq $wopt } @{$config{cflags}};
1594                 }
1595         if ($target =~ /^BSD-/)
1596                 {
1597                 push @{$config{ex_libs}}, "-lexecinfo";
1598                 }
1599         }
1600
1601 unless ($disabled{afalgeng}) {
1602     $config{afalgeng}="";
1603     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1604         my $minver = 4*10000 + 1*100 + 0;
1605         if ($config{CROSS_COMPILE} eq "") {
1606             my $verstr = `uname -r`;
1607             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1608             ($mi2) = $mi2 =~ /(\d+)/;
1609             my $ver = $ma*10000 + $mi1*100 + $mi2;
1610             if ($ver < $minver) {
1611                 disable('too-old-kernel', 'afalgeng');
1612             } else {
1613                 push @{$config{engdirs}}, "afalg";
1614             }
1615         } else {
1616             disable('cross-compiling', 'afalgeng');
1617         }
1618     } else {
1619         disable('not-linux', 'afalgeng');
1620     }
1621 }
1622
1623 push @{$config{openssl_feature_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1624
1625 unless ($disabled{ktls}) {
1626     $config{ktls}="";
1627     if ($target =~ m/^linux/) {
1628         my $usr = "/usr/$config{cross_compile_prefix}";
1629         chop($usr);
1630         if ($config{cross_compile_prefix} eq "") {
1631             $usr = "/usr";
1632         }
1633         my $minver = (4 << 16) + (13 << 8) + 0;
1634         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1635
1636         if ($verstr[2] < $minver) {
1637             disable('too-old-kernel', 'ktls');
1638         }
1639     } else {
1640         disable('not-linux', 'ktls');
1641     }
1642 }
1643
1644 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1645
1646 # Get the extra flags used when building shared libraries and modules.  We
1647 # do this late because some of them depend on %disabled.
1648
1649 # Make the flags to build DSOs the same as for shared libraries unless they
1650 # are already defined
1651 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1652 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1653 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1654 {
1655     my $shared_info_pl =
1656         catfile(dirname($0), "Configurations", "shared-info.pl");
1657     my %shared_info = read_eval_file($shared_info_pl);
1658     push @{$target{_conf_fname_int}}, $shared_info_pl;
1659     my $si = $target{shared_target};
1660     while (ref $si ne "HASH") {
1661         last if ! defined $si;
1662         if (ref $si eq "CODE") {
1663             $si = $si->();
1664         } else {
1665             $si = $shared_info{$si};
1666         }
1667     }
1668
1669     # Some of the 'shared_target' values don't have any entries in
1670     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1671     # template knows how to handle this.  That is currently the case for
1672     # Windows and VMS.
1673     if (defined $si) {
1674         # Just as above, copy certain shared_* attributes to the corresponding
1675         # module_ attribute unless the latter is already defined
1676         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1677         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1678         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1679         foreach (sort keys %$si) {
1680             $target{$_} = defined $target{$_}
1681                 ? add($si->{$_})->($target{$_})
1682                 : $si->{$_};
1683         }
1684     }
1685 }
1686
1687 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1688
1689 # If we use the unified build, collect information from build.info files
1690 my %unified_info = ();
1691
1692 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1693 if ($builder eq "unified") {
1694     use with_fallback qw(Text::Template);
1695
1696     sub cleandir {
1697         my $base = shift;
1698         my $dir = shift;
1699         my $relativeto = shift || ".";
1700
1701         $dir = catdir($base,$dir) unless isabsolute($dir);
1702
1703         # Make sure the directories we're building in exists
1704         mkpath($dir);
1705
1706         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1707         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1708         return $res;
1709     }
1710
1711     sub cleanfile {
1712         my $base = shift;
1713         my $file = shift;
1714         my $relativeto = shift || ".";
1715
1716         $file = catfile($base,$file) unless isabsolute($file);
1717
1718         my $d = dirname($file);
1719         my $f = basename($file);
1720
1721         # Make sure the directories we're building in exists
1722         mkpath($d);
1723
1724         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1725         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1726         return $res;
1727     }
1728
1729     # Store the name of the template file we will build the build file from
1730     # in %config.  This may be useful for the build file itself.
1731     my @build_file_template_names =
1732         ( $builder_platform."-".$target{build_file}.".tmpl",
1733           $target{build_file}.".tmpl" );
1734     my @build_file_templates = ();
1735
1736     # First, look in the user provided directory, if given
1737     if (defined env($local_config_envname)) {
1738         @build_file_templates =
1739             map {
1740                 if ($^O eq 'VMS') {
1741                     # VMS environment variables are logical names,
1742                     # which can be used as is
1743                     $local_config_envname . ':' . $_;
1744                 } else {
1745                     catfile(env($local_config_envname), $_);
1746                 }
1747             }
1748             @build_file_template_names;
1749     }
1750     # Then, look in our standard directory
1751     push @build_file_templates,
1752         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1753           @build_file_template_names );
1754
1755     my $build_file_template;
1756     for $_ (@build_file_templates) {
1757         $build_file_template = $_;
1758         last if -f $build_file_template;
1759
1760         $build_file_template = undef;
1761     }
1762     if (!defined $build_file_template) {
1763         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1764     }
1765     $config{build_file_templates}
1766       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1767                     $blddir),
1768           $build_file_template,
1769           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1770                     $blddir) ];
1771
1772     my @build_dirs = ( [ ] );   # current directory
1773
1774     $config{build_infos} = [ ];
1775
1776     my %ordinals = ();
1777     while (@build_dirs) {
1778         my @curd = @{shift @build_dirs};
1779         my $sourced = catdir($srcdir, @curd);
1780         my $buildd = catdir($blddir, @curd);
1781
1782         my $unixdir = join('/', @curd);
1783         if (exists $skipdir{$unixdir}) {
1784             my $what = $skipdir{$unixdir};
1785             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1786             next;
1787         }
1788
1789         mkpath($buildd);
1790
1791         my $f = 'build.info';
1792         # The basic things we're trying to build
1793         my @programs = ();
1794         my @libraries = ();
1795         my @modules = ();
1796         my @scripts = ();
1797
1798         my %attributes = ();
1799         my %sources = ();
1800         my %shared_sources = ();
1801         my %includes = ();
1802         my %defines = ();
1803         my %depends = ();
1804         my %generate = ();
1805
1806         # Support for $variablename in build.info files.
1807         # Embedded perl code is the ultimate master, still.  If its output
1808         # contains a dollar sign, it had better be escaped, or it will be
1809         # taken for a variable name prefix.
1810         my %variables = ();
1811         my $variable_re = qr/\$([[:alpha:]][[:alnum:]_]*)/;
1812         my $expand_variables = sub {
1813             my $value = '';
1814             my $value_rest = shift;
1815
1816             while ($value_rest =~ /(?<!\\)${variable_re}/) {
1817                 $value .= $`;
1818                 $value .= $variables{$1};
1819                 $value_rest = $';
1820             }
1821             return $value . $value_rest;
1822         };
1823
1824         # We want to detect configdata.pm in the source tree, so we
1825         # don't use it if the build tree is different.
1826         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1827
1828         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1829         my $template =
1830             Text::Template->new(TYPE => 'FILE',
1831                                 SOURCE => catfile($sourced, $f),
1832                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1833         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1834         my @text =
1835             split /^/m,
1836             $template->fill_in(HASH => { config => \%config,
1837                                          target => \%target,
1838                                          disabled => \%disabled,
1839                                          withargs => \%withargs,
1840                                          builddir => abs2rel($buildd, $blddir),
1841                                          sourcedir => abs2rel($sourced, $blddir),
1842                                          buildtop => abs2rel($blddir, $blddir),
1843                                          sourcetop => abs2rel($srcdir, $blddir) },
1844                                DELIMITERS => [ "{-", "-}" ]);
1845
1846         # The top item of this stack has the following values
1847         # -2 positive already run and we found ELSE (following ELSIF should fail)
1848         # -1 positive already run (skip until ENDIF)
1849         # 0 negatives so far (if we're at a condition, check it)
1850         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1851         # 2 positive ELSE (following ELSIF should fail)
1852         my @skip = ();
1853         collect_information(
1854             collect_from_array([ @text ],
1855                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1856                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1857             # Info we're looking for
1858             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1859             => sub {
1860                 if (! @skip || $skip[$#skip] > 0) {
1861                     push @skip, !! $expand_variables->($1);
1862                 } else {
1863                     push @skip, -1;
1864                 }
1865             },
1866             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1867             => sub { die "ELSIF out of scope" if ! @skip;
1868                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1869                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1870                      $skip[$#skip] = !! $expand_variables->($1)
1871                          if $skip[$#skip] == 0; },
1872             qr/^\s*ELSE\s*$/
1873             => sub { die "ELSE out of scope" if ! @skip;
1874                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1875                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1876             qr/^\s*ENDIF\s*$/
1877             => sub { die "ENDIF out of scope" if ! @skip;
1878                      pop @skip; },
1879             qr/^\s*${variable_re}\s*=\s*(.*?)\s*$/
1880             => sub {
1881                 if (!@skip || $skip[$#skip] > 0) {
1882                     my $n = $1;
1883                     my $v = $2;
1884                     $variables{$n} = $expand_variables->($v);
1885                 }
1886             },
1887             qr/^\s*SUBDIRS\s*=\s*(.*)\s*$/
1888             => sub {
1889                 if (!@skip || $skip[$#skip] > 0) {
1890                     foreach (tokenize($expand_variables->($1))) {
1891                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1892                     }
1893                 }
1894             },
1895             qr/^\s*PROGRAMS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1896             => sub {
1897                 if (!@skip || $skip[$#skip] > 0) {
1898                     my @a = tokenize($1, qr|\s*,\s*|);
1899                     my @p = tokenize($expand_variables->($2));
1900                     push @programs, @p;
1901                     foreach my $a (@a) {
1902                         my $ak = $a;
1903                         my $av = 1;
1904                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1905                             $ak = $1;
1906                             $av = $2;
1907                         }
1908                         foreach my $p (@p) {
1909                             $attributes{$p}->{$ak} = $av;
1910                         }
1911                     }
1912                 }
1913             },
1914             qr/^\s*LIBS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1915             => sub {
1916                 if (!@skip || $skip[$#skip] > 0) {
1917                     my @a = tokenize($1, qr|\s*,\s*|);
1918                     my @l = tokenize($expand_variables->($2));
1919                     push @libraries, @l;
1920                     foreach my $a (@a) {
1921                         my $ak = $a;
1922                         my $av = 1;
1923                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1924                             $ak = $1;
1925                             $av = $2;
1926                         }
1927                         foreach my $l (@l) {
1928                             $attributes{$l}->{$ak} = $av;
1929                         }
1930                     }
1931                 }
1932             },
1933             qr/^\s*MODULES(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1934             => sub {
1935                 if (!@skip || $skip[$#skip] > 0) {
1936                     my @a = tokenize($1, qr|\s*,\s*|);
1937                     my @m = tokenize($expand_variables->($2));
1938                     push @modules, @m;
1939                     foreach my $a (@a) {
1940                         my $ak = $a;
1941                         my $av = 1;
1942                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1943                             $ak = $1;
1944                             $av = $2;
1945                         }
1946                         foreach my $m (@m) {
1947                             $attributes{$m}->{$ak} = $av;
1948                         }
1949                     }
1950                 }
1951             },
1952             qr/^\s*SCRIPTS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1953             => sub {
1954                 if (!@skip || $skip[$#skip] > 0) {
1955                     my @a = tokenize($1, qr|\s*,\s*|);
1956                     my @s = tokenize($expand_variables->($2));
1957                     push @scripts, @s;
1958                     foreach my $a (@a) {
1959                         my $ak = $a;
1960                         my $av = 1;
1961                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1962                             $ak = $1;
1963                             $av = $2;
1964                         }
1965                         foreach my $s (@s) {
1966                             $attributes{$s}->{$ak} = $av;
1967                         }
1968                     }
1969                 }
1970             },
1971
1972             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1973             => sub { push @{$ordinals{$1}}, tokenize($expand_variables->($2))
1974                          if !@skip || $skip[$#skip] > 0 },
1975             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1976             => sub { push @{$sources{$1}}, tokenize($expand_variables->($2))
1977                          if !@skip || $skip[$#skip] > 0 },
1978             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1979             => sub { push @{$shared_sources{$1}},
1980                          tokenize($expand_variables->($2))
1981                          if !@skip || $skip[$#skip] > 0 },
1982             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1983             => sub { push @{$includes{$1}}, tokenize($expand_variables->($2))
1984                          if !@skip || $skip[$#skip] > 0 },
1985             qr/^\s*DEFINE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1986             => sub { push @{$defines{$1}}, tokenize($expand_variables->($2))
1987                          if !@skip || $skip[$#skip] > 0 },
1988             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1989             => sub { push @{$depends{$1}}, tokenize($expand_variables->($2))
1990                          if !@skip || $skip[$#skip] > 0 },
1991             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1992             => sub { push @{$generate{$1}}, $2
1993                          if !@skip || $skip[$#skip] > 0 },
1994             qr/^\s*(?:#.*)?$/ => sub { },
1995             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1996             "BEFORE" => sub {
1997                 if ($buildinfo_debug) {
1998                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1999                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2000                 }
2001             },
2002             "AFTER" => sub {
2003                 if ($buildinfo_debug) {
2004                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2005                 }
2006             },
2007             );
2008         die "runaway IF?" if (@skip);
2009
2010         if (grep { defined $attributes{$_}->{engine} } keys %attributes
2011                 and !$config{dynamic_engines}) {
2012             die <<"EOF"
2013 ENGINES can only be used if configured with 'dynamic-engine'.
2014 This is usually a fault in a build.info file.
2015 EOF
2016         }
2017
2018         foreach (keys %attributes) {
2019             my $dest = $_;
2020             my $ddest = cleanfile($buildd, $_, $blddir);
2021             foreach (keys %{$attributes{$dest} // {}}) {
2022                 $unified_info{attributes}->{$ddest}->{$_} =
2023                     $attributes{$dest}->{$_};
2024             }
2025         }
2026
2027         {
2028             my %infos = ( programs  => [ @programs  ],
2029                           libraries => [ @libraries ],
2030                           modules   => [ @modules   ],
2031                           scripts   => [ @scripts   ] );
2032             foreach my $k (keys %infos) {
2033                 foreach (@{$infos{$k}}) {
2034                     my $item = cleanfile($buildd, $_, $blddir);
2035                     $unified_info{$k}->{$item} = 1;
2036                 }
2037             }
2038         }
2039
2040         # Check that we haven't defined any library as both shared and
2041         # explicitly static.  That is forbidden.
2042         my @doubles = ();
2043         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2044             (my $l = $_) =~ s/\.a$//;
2045             push @doubles, $l if defined $unified_info{libraries}->{$l};
2046         }
2047         die "these libraries are both explicitly static and shared:\n  ",
2048             join(" ", @doubles), "\n"
2049             if @doubles;
2050
2051         foreach (keys %sources) {
2052             my $dest = $_;
2053             my $ddest = cleanfile($buildd, $_, $blddir);
2054             foreach (@{$sources{$dest}}) {
2055                 my $s = cleanfile($sourced, $_, $blddir);
2056
2057                 # If it isn't in the source tree, we assume it's generated
2058                 # in the build tree
2059                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2060                     $s = cleanfile($buildd, $_, $blddir);
2061                 }
2062                 # We recognise C++, C and asm files
2063                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2064                     my $o = $_;
2065                     $o =~ s/\.[csS]$/.o/; # C and assembler
2066                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2067                     $o = cleanfile($buildd, $o, $blddir);
2068                     $unified_info{sources}->{$ddest}->{$o} = -1;
2069                     $unified_info{sources}->{$o}->{$s} = -1;
2070                 } elsif ($s =~ /\.rc$/) {
2071                     # We also recognise resource files
2072                     my $o = $_;
2073                     $o =~ s/\.rc$/.res/; # Resource configuration
2074                     my $o = cleanfile($buildd, $o, $blddir);
2075                     $unified_info{sources}->{$ddest}->{$o} = -1;
2076                     $unified_info{sources}->{$o}->{$s} = -1;
2077                 } else {
2078                     $unified_info{sources}->{$ddest}->{$s} = 1;
2079                 }
2080             }
2081         }
2082
2083         foreach (keys %shared_sources) {
2084             my $dest = $_;
2085             my $ddest = cleanfile($buildd, $_, $blddir);
2086             foreach (@{$shared_sources{$dest}}) {
2087                 my $s = cleanfile($sourced, $_, $blddir);
2088
2089                 # If it isn't in the source tree, we assume it's generated
2090                 # in the build tree
2091                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2092                     $s = cleanfile($buildd, $_, $blddir);
2093                 }
2094
2095                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2096                     # We recognise C++, C and asm files
2097                     my $o = $_;
2098                     $o =~ s/\.[csS]$/.o/; # C and assembler
2099                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2100                     $o = cleanfile($buildd, $o, $blddir);
2101                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2102                     $unified_info{sources}->{$o}->{$s} = -1;
2103                 } elsif ($s =~ /\.rc$/) {
2104                     # We also recognise resource files
2105                     my $o = $_;
2106                     $o =~ s/\.rc$/.res/; # Resource configuration
2107                     my $o = cleanfile($buildd, $o, $blddir);
2108                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2109                     $unified_info{sources}->{$o}->{$s} = -1;
2110                 } elsif ($s =~ /\.ld$/) {
2111                     # We also recognise linker scripts (or corresponding)
2112                     # We know they are generated files
2113                     my $ld = cleanfile($buildd, $_, $blddir);
2114                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2115                 } else {
2116                     die "unrecognised source file type for shared library: $s\n";
2117                 }
2118             }
2119         }
2120
2121         foreach (keys %generate) {
2122             my $dest = $_;
2123             my $ddest = cleanfile($buildd, $_, $blddir);
2124             die "more than one generator for $dest: "
2125                     ,join(" ", @{$generate{$_}}),"\n"
2126                     if scalar @{$generate{$_}} > 1;
2127             my @generator = split /\s+/, $generate{$dest}->[0];
2128             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2129             $unified_info{generate}->{$ddest} = [ @generator ];
2130         }
2131
2132         foreach (keys %depends) {
2133             my $dest = $_;
2134             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2135
2136             # If the destination doesn't exist in source, it can only be
2137             # a generated file in the build tree.
2138             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2139                 $ddest = cleanfile($buildd, $_, $blddir);
2140             }
2141             foreach (@{$depends{$dest}}) {
2142                 my $d = cleanfile($sourced, $_, $blddir);
2143
2144                 # If we know it's generated, or assume it is because we can't
2145                 # find it in the source tree, we set file we depend on to be
2146                 # in the build tree rather than the source tree, and assume
2147                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2148                 # section or in the Makefile template.
2149                 if ($d eq $src_configdata
2150                     || ! -f $d
2151                     || (grep { $d eq $_ }
2152                         map { cleanfile($srcdir, $_, $blddir) }
2153                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2154                     $d = cleanfile($buildd, $_, $blddir);
2155                 }
2156                 # Take note if the file to depend on is being renamed
2157                 # Take extra care with files ending with .a, they should
2158                 # be treated without that extension, and the extension
2159                 # should be added back after treatment.
2160                 $d =~ /(\.a)?$/;
2161                 my $e = $1 // "";
2162                 $d = $`.$e;
2163                 $unified_info{depends}->{$ddest}->{$d} = 1;
2164             }
2165         }
2166
2167         foreach (keys %includes) {
2168             my $dest = $_;
2169             my $ddest = cleanfile($sourced, $_, $blddir);
2170
2171             # If the destination doesn't exist in source, it can only be
2172             # a generated file in the build tree.
2173             if ($ddest eq $src_configdata || ! -f $ddest) {
2174                 $ddest = cleanfile($buildd, $_, $blddir);
2175             }
2176             foreach (@{$includes{$dest}}) {
2177                 my $is = cleandir($sourced, $_, $blddir);
2178                 my $ib = cleandir($buildd, $_, $blddir);
2179                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2180                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2181                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2182                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2183             }
2184         }
2185
2186         foreach (keys %defines) {
2187             my $dest = $_;
2188             my $ddest = cleanfile($sourced, $_, $blddir);
2189
2190             # If the destination doesn't exist in source, it can only be
2191             # a generated file in the build tree.
2192             if (! -f $ddest) {
2193                 $ddest = cleanfile($buildd, $_, $blddir);
2194                 if ($unified_info{rename}->{$ddest}) {
2195                     $ddest = $unified_info{rename}->{$ddest};
2196                 }
2197             }
2198             foreach (@{$defines{$dest}}) {
2199                 m|^([^=]*)(=.*)?$|;
2200                 die "0 length macro name not permitted\n" if $1 eq "";
2201                 die "$1 defined more than once\n"
2202                     if defined $unified_info{defines}->{$ddest}->{$1};
2203                 $unified_info{defines}->{$ddest}->{$1} = $2;
2204             }
2205         }
2206     }
2207
2208     my $ordinals_text = join(', ', sort keys %ordinals);
2209     warn <<"EOF" if $ordinals_text;
2210
2211 WARNING: ORDINALS were specified for $ordinals_text
2212 They are ignored and should be replaced with a combination of GENERATE,
2213 DEPEND and SHARED_SOURCE.
2214 EOF
2215
2216
2217     # Go through the sources of all libraries and check that the same basename
2218     # doesn't appear more than once.  Some static library archivers depend on
2219     # them being unique.
2220     {
2221         my $err = 0;
2222         foreach my $prod (keys %{$unified_info{libraries}}) {
2223             my @prod_sources =
2224                 map { keys %{$unified_info{sources}->{$_}} }
2225                 keys %{$unified_info{sources}->{$prod}};
2226             my %srccnt = ();
2227
2228             # Count how many times a given each source basename
2229             # appears for each product.
2230             foreach my $src (@prod_sources) {
2231                 $srccnt{basename $src}++;
2232             }
2233
2234             foreach my $src (keys %srccnt) {
2235                 if ((my $cnt = $srccnt{$src}) > 1) {
2236                     print STDERR "$src appears $cnt times for the product $prod\n";
2237                     $err++
2238                 }
2239             }
2240         }
2241         die if $err > 0;
2242     }
2243
2244     # Massage the result
2245
2246     # If we depend on a header file or a perl module, add an inclusion of
2247     # its directory to allow smoothe inclusion
2248     foreach my $dest (keys %{$unified_info{depends}}) {
2249         next if $dest eq "";
2250         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2251             next unless $d =~ /\.(h|pm)$/;
2252             my $i = dirname($d);
2253             my $spot =
2254                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2255                 ? 'build' : 'source';
2256             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2257                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2258         }
2259     }
2260
2261     # Go through all intermediary files and change their names to something that
2262     # reflects what they will be built for.  Note that for some source files,
2263     # this leads to duplicate object files because they are used multiple times.
2264     # the goal is to rename all object files according to this scheme:
2265     #    {productname}-{midfix}-{origobjname}.[o|res]
2266     # the {midfix} is a keyword indicating the type of product, which is mostly
2267     # valuable for libraries since they come in two forms.
2268     #
2269     # This also reorganises the {sources} and {shared_sources} so that the
2270     # former only contains ALL object files that are supposed to end up in
2271     # static libraries and programs, while the latter contains ALL object files
2272     # that are supposed to end up in shared libraries and DSOs.
2273     # The main reason for having two different source structures is to allow
2274     # the same name to be used for the static and the shared variants of a
2275     # library.
2276     {
2277         # Take copies so we don't get interference from added stuff
2278         my %unified_copy = ();
2279         foreach (('sources', 'shared_sources')) {
2280             $unified_copy{$_} = { %{$unified_info{$_}} }
2281                 if defined($unified_info{$_});
2282             delete $unified_info{$_};
2283         }
2284         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2285             # $intent serves multi purposes:
2286             # - give a prefix for the new object files names
2287             # - in the case of libraries, rearrange the object files so static
2288             #   libraries use the 'sources' structure exclusively, while shared
2289             #   libraries use the 'shared_sources' structure exclusively.
2290             my $intent = {
2291                 programs  => { bin    => { src => [ 'sources' ],
2292                                            dst => 'sources' } },
2293                 libraries => { lib    => { src => [ 'sources' ],
2294                                            dst => 'sources' },
2295                                shlib  => { prodselect =>
2296                                                sub { grep !/\.a$/, @_ },
2297                                            src => [ 'sources',
2298                                                     'shared_sources' ],
2299                                            dst => 'shared_sources' } },
2300                 modules   => { dso    => { src => [ 'sources' ],
2301                                            dst => 'sources' } },
2302                 scripts   => { script => { src => [ 'sources' ],
2303                                            dst => 'sources' } }
2304                } -> {$prodtype};
2305             foreach my $kind (keys %$intent) {
2306                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2307                              && $disabled{shared});
2308
2309                 my @src = @{$intent->{$kind}->{src}};
2310                 my $dst = $intent->{$kind}->{dst};
2311                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2312                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2313                     # %prod_sources has all applicable objects as keys, and
2314                     # their corresponding sources as values
2315                     my %prod_sources =
2316                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2317                         map { keys %{$unified_copy{$_}->{$prod}} }
2318                         @src;
2319                     foreach (keys %prod_sources) {
2320                         # Only affect object files and resource files,
2321                         # the others simply get a new value
2322                         # (+1 instead of -1)
2323                         if ($_ =~ /\.(o|res)$/) {
2324                             (my $prodname = $prod) =~ s|\.a$||;
2325                             my $newobj =
2326                                 catfile(dirname($_),
2327                                         basename($prodname)
2328                                             . '-' . $kind
2329                                             . '-' . basename($_));
2330                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2331                             foreach my $src (@{$prod_sources{$_}}) {
2332                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2333                             }
2334                             # Adjust dependencies
2335                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2336                                 $unified_info{depends}->{$_}->{$deps} = -1;
2337                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2338                             }
2339                             # Adjust includes
2340                             foreach my $k (('source', 'build')) {
2341                                 next unless
2342                                     defined($unified_info{includes}->{$_}->{$k});
2343                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2344                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2345                             }
2346                         } else {
2347                             $unified_info{$dst}->{$prod}->{$_} = 1;
2348                         }
2349                     }
2350                 }
2351             }
2352         }
2353     }
2354
2355     # At this point, we have a number of sources with the value -1.  They
2356     # aren't part of the local build and are probably meant for a different
2357     # platform, and can therefore be cleaned away.  That happens when making
2358     # %unified_info more efficient below.
2359
2360     ### Make unified_info a bit more efficient
2361     # One level structures
2362     foreach (("programs", "libraries", "modules", "scripts")) {
2363         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2364     }
2365     # Two level structures
2366     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends")) {
2367         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2368             my @items =
2369                 sort
2370                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2371                 keys %{$unified_info{$l1}->{$l2}};
2372             if (@items) {
2373                 $unified_info{$l1}->{$l2} = [ @items ];
2374             } else {
2375                 delete $unified_info{$l1}->{$l2};
2376             }
2377         }
2378     }
2379     # Defines
2380     foreach my $dest (sort keys %{$unified_info{defines}}) {
2381         $unified_info{defines}->{$dest}
2382             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2383                 sort keys %{$unified_info{defines}->{$dest}} ];
2384     }
2385     # Includes
2386     foreach my $dest (sort keys %{$unified_info{includes}}) {
2387         if (defined($unified_info{includes}->{$dest}->{build})) {
2388             my @source_includes = ();
2389             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2390                 if defined($unified_info{includes}->{$dest}->{source});
2391             $unified_info{includes}->{$dest} =
2392                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2393             foreach my $inc (@source_includes) {
2394                 push @{$unified_info{includes}->{$dest}}, $inc
2395                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2396             }
2397         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2398             $unified_info{includes}->{$dest} =
2399                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2400         } else {
2401             delete $unified_info{includes}->{$dest};
2402         }
2403     }
2404
2405     # For convenience collect information regarding directories where
2406     # files are generated, those generated files and the end product
2407     # they end up in where applicable.  Then, add build rules for those
2408     # directories
2409     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2410                      "dso" => [ @{$unified_info{modules}} ],
2411                      "bin" => [ @{$unified_info{programs}} ],
2412                      "script" => [ @{$unified_info{scripts}} ] );
2413     foreach my $type (keys %loopinfo) {
2414         foreach my $product (@{$loopinfo{$type}}) {
2415             my %dirs = ();
2416             my $pd = dirname($product);
2417
2418             foreach (@{$unified_info{sources}->{$product} // []},
2419                      @{$unified_info{shared_sources}->{$product} // []}) {
2420                 my $d = dirname($_);
2421
2422                 # We don't want to create targets for source directories
2423                 # when building out of source
2424                 next if ($config{sourcedir} ne $config{builddir}
2425                              && $d =~ m|^\Q$config{sourcedir}\E|);
2426                 # We already have a "test" target, and the current directory
2427                 # is just silly to make a target for
2428                 next if $d eq "test" || $d eq ".";
2429
2430                 $dirs{$d} = 1;
2431                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2432                     if $d ne $pd;
2433             }
2434             foreach (keys %dirs) {
2435                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2436                     $product;
2437             }
2438         }
2439     }
2440 }
2441
2442 # For the schemes that need it, we provide the old *_obj configs
2443 # from the *_asm_obj ones
2444 foreach (grep /_(asm|aux)_src$/, keys %target) {
2445     my $src = $_;
2446     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2447     $target{$obj} = $target{$src};
2448     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2449     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2450 }
2451
2452 # Write down our configuration where it fits #########################
2453
2454 print "Creating configdata.pm\n";
2455 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2456 print OUT <<"EOF";
2457 #! $config{HASHBANGPERL}
2458
2459 package configdata;
2460
2461 use strict;
2462 use warnings;
2463
2464 use Exporter;
2465 #use vars qw(\@ISA \@EXPORT);
2466 our \@ISA = qw(Exporter);
2467 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables \@disablables_int);
2468
2469 EOF
2470 print OUT "our %config = (\n";
2471 foreach (sort keys %config) {
2472     if (ref($config{$_}) eq "ARRAY") {
2473         print OUT "  ", $_, " => [ ", join(", ",
2474                                            map { quotify("perl", $_) }
2475                                            @{$config{$_}}), " ],\n";
2476     } elsif (ref($config{$_}) eq "HASH") {
2477         print OUT "  ", $_, " => {";
2478         if (scalar keys %{$config{$_}} > 0) {
2479             print OUT "\n";
2480             foreach my $key (sort keys %{$config{$_}}) {
2481                 print OUT "      ",
2482                     join(" => ",
2483                          quotify("perl", $key),
2484                          defined $config{$_}->{$key}
2485                              ? quotify("perl", $config{$_}->{$key})
2486                              : "undef");
2487                 print OUT ",\n";
2488             }
2489             print OUT "  ";
2490         }
2491         print OUT "},\n";
2492     } else {
2493         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2494     }
2495 }
2496 print OUT <<"EOF";
2497 );
2498
2499 EOF
2500 print OUT "our %target = (\n";
2501 foreach (sort keys %target) {
2502     if (ref($target{$_}) eq "ARRAY") {
2503         print OUT "  ", $_, " => [ ", join(", ",
2504                                            map { quotify("perl", $_) }
2505                                            @{$target{$_}}), " ],\n";
2506     } else {
2507         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2508     }
2509 }
2510 print OUT <<"EOF";
2511 );
2512
2513 EOF
2514 print OUT "our \%available_protocols = (\n";
2515 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2516 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2517 print OUT <<"EOF";
2518 );
2519
2520 EOF
2521 print OUT "our \@disablables = (\n";
2522 foreach (@disablables) {
2523     print OUT "  ", quotify("perl", $_), ",\n";
2524 }
2525 print OUT <<"EOF";
2526 );
2527
2528 EOF
2529 print OUT "# The following come from Configure's @disablables_int\n";
2530 print OUT "our \@disablables_int = (\n";
2531 foreach (@disablables_int) {
2532     print OUT "  ", quotify("perl", $_), ",\n";
2533 }
2534 print OUT <<"EOF";
2535 );
2536
2537 EOF
2538 print OUT "our \%disabled = (\n";
2539 foreach (sort keys %disabled) {
2540     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2541 }
2542 print OUT <<"EOF";
2543 );
2544
2545 EOF
2546 print OUT "our %withargs = (\n";
2547 foreach (sort keys %withargs) {
2548     if (ref($withargs{$_}) eq "ARRAY") {
2549         print OUT "  ", $_, " => [ ", join(", ",
2550                                            map { quotify("perl", $_) }
2551                                            @{$withargs{$_}}), " ],\n";
2552     } else {
2553         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2554     }
2555 }
2556 print OUT <<"EOF";
2557 );
2558
2559 EOF
2560 if ($builder eq "unified") {
2561     my $recurse;
2562     $recurse = sub {
2563         my $indent = shift;
2564         foreach (@_) {
2565             if (ref $_ eq "ARRAY") {
2566                 print OUT " "x$indent, "[\n";
2567                 foreach (@$_) {
2568                     $recurse->($indent + 4, $_);
2569                 }
2570                 print OUT " "x$indent, "],\n";
2571             } elsif (ref $_ eq "HASH") {
2572                 my %h = %$_;
2573                 print OUT " "x$indent, "{\n";
2574                 foreach (sort keys %h) {
2575                     if (ref $h{$_} eq "") {
2576                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2577                     } else {
2578                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2579                         $recurse->($indent + 8, $h{$_});
2580                     }
2581                 }
2582                 print OUT " "x$indent, "},\n";
2583             } else {
2584                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2585             }
2586         }
2587     };
2588     print OUT "our %unified_info = (\n";
2589     foreach (sort keys %unified_info) {
2590         if (ref $unified_info{$_} eq "") {
2591             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2592         } else {
2593             print OUT " "x4, quotify("perl", $_), " =>\n";
2594             $recurse->(8, $unified_info{$_});
2595         }
2596     }
2597     print OUT <<"EOF";
2598 );
2599
2600 EOF
2601 }
2602 print OUT
2603     "# The following data is only used when this files is use as a script\n";
2604 print OUT "my \@makevars = (\n";
2605 foreach (sort keys %user) {
2606     print OUT "    '",$_,"',\n";
2607 }
2608 print OUT ");\n";
2609 print OUT "my \%disabled_info = (\n";
2610 foreach my $what (sort keys %disabled_info) {
2611     print OUT "    '$what' => {\n";
2612     foreach my $info (sort keys %{$disabled_info{$what}}) {
2613         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2614             print OUT "        $info => [ ",
2615                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2616                 " ],\n";
2617         } else {
2618             print OUT "        $info => '", $disabled_info{$what}->{$info},
2619                 "',\n";
2620         }
2621     }
2622     print OUT "    },\n";
2623 }
2624 print OUT ");\n";
2625 print OUT 'my @user_crossable = qw( ', join (' ', @user_crossable), " );\n";
2626 print OUT << 'EOF';
2627 # If run directly, we can give some answers, and even reconfigure
2628 unless (caller) {
2629     use Getopt::Long;
2630     use File::Spec::Functions;
2631     use File::Basename;
2632     use Pod::Usage;
2633
2634     my $here = dirname($0);
2635
2636     my $dump = undef;
2637     my $cmdline = undef;
2638     my $options = undef;
2639     my $target = undef;
2640     my $envvars = undef;
2641     my $makevars = undef;
2642     my $buildparams = undef;
2643     my $reconf = undef;
2644     my $verbose = undef;
2645     my $help = undef;
2646     my $man = undef;
2647     GetOptions('dump|d'                 => \$dump,
2648                'command-line|c'         => \$cmdline,
2649                'options|o'              => \$options,
2650                'target|t'               => \$target,
2651                'environment|e'          => \$envvars,
2652                'make-variables|m'       => \$makevars,
2653                'build-parameters|b'     => \$buildparams,
2654                'reconfigure|reconf|r'   => \$reconf,
2655                'verbose|v'              => \$verbose,
2656                'help'                   => \$help,
2657                'man'                    => \$man)
2658         or die "Errors in command line arguments\n";
2659
2660     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2661             || $buildparams || $reconf || $verbose || $help || $man) {
2662         print STDERR <<"_____";
2663 You must give at least one option.
2664 For more information, do '$0 --help'
2665 _____
2666         exit(2);
2667     }
2668
2669     if ($help) {
2670         pod2usage(-exitval => 0,
2671                   -verbose => 1);
2672     }
2673     if ($man) {
2674         pod2usage(-exitval => 0,
2675                   -verbose => 2);
2676     }
2677     if ($dump || $cmdline) {
2678         print "\nCommand line (with current working directory = $here):\n\n";
2679         print '    ',join(' ',
2680                           $config{PERL},
2681                           catfile($config{sourcedir}, 'Configure'),
2682                           @{$config{perlargv}}), "\n";
2683         print "\nPerl information:\n\n";
2684         print '    ',$config{perl_cmd},"\n";
2685         print '    ',$config{perl_version},' for ',$config{perl_archname},"\n";
2686     }
2687     if ($dump || $options) {
2688         my $longest = 0;
2689         my $longest2 = 0;
2690         foreach my $what (@disablables) {
2691             $longest = length($what) if $longest < length($what);
2692             $longest2 = length($disabled{$what})
2693                 if $disabled{$what} && $longest2 < length($disabled{$what});
2694         }
2695         print "\nEnabled features:\n\n";
2696         foreach my $what (@disablables) {
2697             print "    $what\n" unless $disabled{$what};
2698         }
2699         print "\nDisabled features:\n\n";
2700         foreach my $what (@disablables) {
2701             if ($disabled{$what}) {
2702                 print "    $what", ' ' x ($longest - length($what) + 1),
2703                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2704                 print $disabled_info{$what}->{macro}
2705                     if $disabled_info{$what}->{macro};
2706                 print ' (skip ',
2707                     join(', ', @{$disabled_info{$what}->{skipped}}),
2708                     ')'
2709                     if $disabled_info{$what}->{skipped};
2710                 print "\n";
2711             }
2712         }
2713     }
2714     if ($dump || $target) {
2715         print "\nConfig target attributes:\n\n";
2716         foreach (sort keys %target) {
2717             next if $_ =~ m|^_| || $_ eq 'template';
2718             my $quotify = sub {
2719                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2720             };
2721             print '    ', $_, ' => ';
2722             if (ref($target{$_}) eq "ARRAY") {
2723                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2724             } else {
2725                 print $quotify->($target{$_}), ",\n"
2726             }
2727         }
2728     }
2729     if ($dump || $envvars) {
2730         print "\nRecorded environment:\n\n";
2731         foreach (sort keys %{$config{perlenv}}) {
2732             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2733         }
2734     }
2735     if ($dump || $makevars) {
2736         print "\nMakevars:\n\n";
2737         foreach my $var (@makevars) {
2738             my $prefix = '';
2739             $prefix = $config{CROSS_COMPILE}
2740                 if grep { $var eq $_ } @user_crossable;
2741             $prefix //= '';
2742             print '    ',$var,' ' x (16 - length $var),'= ',
2743                 (ref $config{$var} eq 'ARRAY'
2744                  ? join(' ', @{$config{$var}})
2745                  : $prefix.$config{$var}),
2746                 "\n"
2747                 if defined $config{$var};
2748         }
2749
2750         my @buildfile = ($config{builddir}, $config{build_file});
2751         unshift @buildfile, $here
2752             unless file_name_is_absolute($config{builddir});
2753         my $buildfile = canonpath(catdir(@buildfile));
2754         print <<"_____";
2755
2756 NOTE: These variables only represent the configuration view.  The build file
2757 template may have processed these variables further, please have a look at the
2758 build file for more exact data:
2759     $buildfile
2760 _____
2761     }
2762     if ($dump || $buildparams) {
2763         my @buildfile = ($config{builddir}, $config{build_file});
2764         unshift @buildfile, $here
2765             unless file_name_is_absolute($config{builddir});
2766         print "\nbuild file:\n\n";
2767         print "    ", canonpath(catfile(@buildfile)),"\n";
2768
2769         print "\nbuild file templates:\n\n";
2770         foreach (@{$config{build_file_templates}}) {
2771             my @tmpl = ($_);
2772             unshift @tmpl, $here
2773                 unless file_name_is_absolute($config{sourcedir});
2774             print '    ',canonpath(catfile(@tmpl)),"\n";
2775         }
2776     }
2777     if ($reconf) {
2778         if ($verbose) {
2779             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2780             foreach (sort keys %{$config{perlenv}}) {
2781                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2782             }
2783         }
2784
2785         chdir $here;
2786         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2787     }
2788 }
2789
2790 1;
2791
2792 __END__
2793
2794 =head1 NAME
2795
2796 configdata.pm - configuration data for OpenSSL builds
2797
2798 =head1 SYNOPSIS
2799
2800 Interactive:
2801
2802   perl configdata.pm [options]
2803
2804 As data bank module:
2805
2806   use configdata;
2807
2808 =head1 DESCRIPTION
2809
2810 This module can be used in two modes, interactively and as a module containing
2811 all the data recorded by OpenSSL's Configure script.
2812
2813 When used interactively, simply run it as any perl script, with at least one
2814 option, and you will get the information you ask for.  See L</OPTIONS> below.
2815
2816 When loaded as a module, you get a few databanks with useful information to
2817 perform build related tasks.  The databanks are:
2818
2819     %config             Configured things.
2820     %target             The OpenSSL config target with all inheritances
2821                         resolved.
2822     %disabled           The features that are disabled.
2823     @disablables        The list of features that can be disabled.
2824     %withargs           All data given through --with-THING options.
2825     %unified_info       All information that was computed from the build.info
2826                         files.
2827
2828 =head1 OPTIONS
2829
2830 =over 4
2831
2832 =item B<--help>
2833
2834 Print a brief help message and exit.
2835
2836 =item B<--man>
2837
2838 Print the manual page and exit.
2839
2840 =item B<--dump> | B<-d>
2841
2842 Print all relevant configuration data.  This is equivalent to B<--command-line>
2843 B<--options> B<--target> B<--environment> B<--make-variables>
2844 B<--build-parameters>.
2845
2846 =item B<--command-line> | B<-c>
2847
2848 Print the current configuration command line.
2849
2850 =item B<--options> | B<-o>
2851
2852 Print the features, both enabled and disabled, and display defined macro and
2853 skipped directories where applicable.
2854
2855 =item B<--target> | B<-t>
2856
2857 Print the config attributes for this config target.
2858
2859 =item B<--environment> | B<-e>
2860
2861 Print the environment variables and their values at the time of configuration.
2862
2863 =item B<--make-variables> | B<-m>
2864
2865 Print the main make variables generated in the current configuration
2866
2867 =item B<--build-parameters> | B<-b>
2868
2869 Print the build parameters, i.e. build file and build file templates.
2870
2871 =item B<--reconfigure> | B<--reconf> | B<-r>
2872
2873 Redo the configuration.
2874
2875 =item B<--verbose> | B<-v>
2876
2877 Verbose output.
2878
2879 =back
2880
2881 =cut
2882
2883 EOF
2884 close(OUT);
2885 if ($builder_platform eq 'unix') {
2886     my $mode = (0755 & ~umask);
2887     chmod $mode, 'configdata.pm'
2888         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2889 }
2890
2891 my %builders = (
2892     unified => sub {
2893         print 'Creating ',$target{build_file},"\n";
2894         run_dofile(catfile($blddir, $target{build_file}),
2895                    @{$config{build_file_templates}});
2896     },
2897     );
2898
2899 $builders{$builder}->($builder_platform, @builder_opts);
2900
2901 $SIG{__DIE__} = $orig_death_handler;
2902
2903 print <<"EOF" if ($disabled{threads} eq "unavailable");
2904
2905 The library could not be configured for supporting multi-threaded
2906 applications as the compiler options required on this system are not known.
2907 See file INSTALL for details if you need multi-threading.
2908 EOF
2909
2910 print <<"EOF" if ($no_shared_warn);
2911
2912 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2913 platform, so we will pretend you gave the option 'no-pic', which also disables
2914 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2915 or position independent code, please let us know (but please first make sure
2916 you have tried with a current version of OpenSSL).
2917 EOF
2918
2919 print <<"EOF";
2920
2921 **********************************************************************
2922 ***                                                                ***
2923 ***   OpenSSL has been successfully configured                     ***
2924 ***                                                                ***
2925 ***   If you encounter a problem while building, please open an    ***
2926 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2927 ***   and include the output from the following command:           ***
2928 ***                                                                ***
2929 ***       perl configdata.pm --dump                                ***
2930 ***                                                                ***
2931 ***   (If you are new to OpenSSL, you might want to consult the    ***
2932 ***   'Troubleshooting' section in the INSTALL file first)         ***
2933 ***                                                                ***
2934 **********************************************************************
2935 EOF
2936
2937 exit(0);
2938
2939 ######################################################################
2940 #
2941 # Helpers and utility functions
2942 #
2943
2944 # Death handler, to print a helpful message in case of failure #######
2945 #
2946 sub death_handler {
2947     die @_ if $^S;              # To prevent the added message in eval blocks
2948     my $build_file = $target{build_file} // "build file";
2949     my @message = ( <<"_____", @_ );
2950
2951 Failure!  $build_file wasn't produced.
2952 Please read INSTALL and associated NOTES files.  You may also have to look over
2953 your available compiler tool chain or change your configuration.
2954
2955 _____
2956
2957     # Dying is terminal, so it's ok to reset the signal handler here.
2958     $SIG{__DIE__} = $orig_death_handler;
2959     die @message;
2960 }
2961
2962 # Configuration file reading #########################################
2963
2964 # Note: All of the helper functions are for lazy evaluation.  They all
2965 # return a CODE ref, which will return the intended value when evaluated.
2966 # Thus, whenever there's mention of a returned value, it's about that
2967 # intended value.
2968
2969 # Helper function to implement conditional inheritance depending on the
2970 # value of $disabled{asm}.  Used in inherit_from values as follows:
2971 #
2972 #      inherit_from => [ "template", asm("asm_tmpl") ]
2973 #
2974 sub asm {
2975     my @x = @_;
2976     sub {
2977         $disabled{asm} ? () : @x;
2978     }
2979 }
2980
2981 # Helper function to implement conditional value variants, with a default
2982 # plus additional values based on the value of $config{build_type}.
2983 # Arguments are given in hash table form:
2984 #
2985 #       picker(default => "Basic string: ",
2986 #              debug   => "debug",
2987 #              release => "release")
2988 #
2989 # When configuring with --debug, the resulting string will be
2990 # "Basic string: debug", and when not, it will be "Basic string: release"
2991 #
2992 # This can be used to create variants of sets of flags according to the
2993 # build type:
2994 #
2995 #       cflags => picker(default => "-Wall",
2996 #                        debug   => "-g -O0",
2997 #                        release => "-O3")
2998 #
2999 sub picker {
3000     my %opts = @_;
3001     return sub { add($opts{default} || (),
3002                      $opts{$config{build_type}} || ())->(); }
3003 }
3004
3005 # Helper function to combine several values of different types into one.
3006 # This is useful if you want to combine a string with the result of a
3007 # lazy function, such as:
3008 #
3009 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
3010 #
3011 sub combine {
3012     my @stuff = @_;
3013     return sub { add(@stuff)->(); }
3014 }
3015
3016 # Helper function to implement conditional values depending on the value
3017 # of $disabled{threads}.  Can be used as follows:
3018 #
3019 #       cflags => combine("-Wall", threads("-pthread"))
3020 #
3021 sub threads {
3022     my @flags = @_;
3023     return sub { add($disabled{threads} ? () : @flags)->(); }
3024 }
3025
3026 sub shared {
3027     my @flags = @_;
3028     return sub { add($disabled{shared} ? () : @flags)->(); }
3029 }
3030
3031 our $add_called = 0;
3032 # Helper function to implement adding values to already existing configuration
3033 # values.  It handles elements that are ARRAYs, CODEs and scalars
3034 sub _add {
3035     my $separator = shift;
3036
3037     # If there's any ARRAY in the collection of values OR the separator
3038     # is undef, we will return an ARRAY of combined values, otherwise a
3039     # string of joined values with $separator as the separator.
3040     my $found_array = !defined($separator);
3041
3042     my @values =
3043         map {
3044             my $res = $_;
3045             while (ref($res) eq "CODE") {
3046                 $res = $res->();
3047             }
3048             if (defined($res)) {
3049                 if (ref($res) eq "ARRAY") {
3050                     $found_array = 1;
3051                     @$res;
3052                 } else {
3053                     $res;
3054                 }
3055             } else {
3056                 ();
3057             }
3058     } (@_);
3059
3060     $add_called = 1;
3061
3062     if ($found_array) {
3063         [ @values ];
3064     } else {
3065         join($separator, grep { defined($_) && $_ ne "" } @values);
3066     }
3067 }
3068 sub add_before {
3069     my $separator = " ";
3070     if (ref($_[$#_]) eq "HASH") {
3071         my $opts = pop;
3072         $separator = $opts->{separator};
3073     }
3074     my @x = @_;
3075     sub { _add($separator, @x, @_) };
3076 }
3077 sub add {
3078     my $separator = " ";
3079     if (ref($_[$#_]) eq "HASH") {
3080         my $opts = pop;
3081         $separator = $opts->{separator};
3082     }
3083     my @x = @_;
3084     sub { _add($separator, @_, @x) };
3085 }
3086
3087 sub read_eval_file {
3088     my $fname = shift;
3089     my $content;
3090     my @result;
3091
3092     open F, "< $fname" or die "Can't open '$fname': $!\n";
3093     {
3094         undef local $/;
3095         $content = <F>;
3096     }
3097     close F;
3098     {
3099         local $@;
3100
3101         @result = ( eval $content );
3102         warn $@ if $@;
3103     }
3104     return wantarray ? @result : $result[0];
3105 }
3106
3107 # configuration reader, evaluates the input file as a perl script and expects
3108 # it to fill %targets with target configurations.  Those are then added to
3109 # %table.
3110 sub read_config {
3111     my $fname = shift;
3112     my %targets;
3113
3114     {
3115         # Protect certain tables from tampering
3116         local %table = ();
3117
3118         %targets = read_eval_file($fname);
3119     }
3120     my %preexisting = ();
3121     foreach (sort keys %targets) {
3122         $preexisting{$_} = 1 if $table{$_};
3123     }
3124     die <<"EOF",
3125 The following config targets from $fname
3126 shadow pre-existing config targets with the same name:
3127 EOF
3128         map { "  $_\n" } sort keys %preexisting
3129         if %preexisting;
3130
3131
3132     # For each target, check that it's configured with a hash table.
3133     foreach (keys %targets) {
3134         if (ref($targets{$_}) ne "HASH") {
3135             if (ref($targets{$_}) eq "") {
3136                 warn "Deprecated target configuration for $_, ignoring...\n";
3137             } else {
3138                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3139             }
3140             delete $targets{$_};
3141         } else {
3142             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3143         }
3144     }
3145
3146     %table = (%table, %targets);
3147
3148 }
3149
3150 # configuration resolver.  Will only resolve all the lazy evaluation
3151 # codeblocks for the chosen target and all those it inherits from,
3152 # recursively
3153 sub resolve_config {
3154     my $target = shift;
3155     my @breadcrumbs = @_;
3156
3157 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3158
3159     if (grep { $_ eq $target } @breadcrumbs) {
3160         die "inherit_from loop!  target backtrace:\n  "
3161             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3162     }
3163
3164     if (!defined($table{$target})) {
3165         warn "Warning! target $target doesn't exist!\n";
3166         return ();
3167     }
3168     # Recurse through all inheritances.  They will be resolved on the
3169     # fly, so when this operation is done, they will all just be a
3170     # bunch of attributes with string values.
3171     # What we get here, though, are keys with references to lists of
3172     # the combined values of them all.  We will deal with lists after
3173     # this stage is done.
3174     my %combined_inheritance = ();
3175     if ($table{$target}->{inherit_from}) {
3176         my @inherit_from =
3177             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3178         foreach (@inherit_from) {
3179             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3180
3181             # 'template' is a marker that's considered private to
3182             # the config that had it.
3183             delete $inherited_config{template};
3184
3185             foreach (keys %inherited_config) {
3186                 if (!$combined_inheritance{$_}) {
3187                     $combined_inheritance{$_} = [];
3188                 }
3189                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3190             }
3191         }
3192     }
3193
3194     # We won't need inherit_from in this target any more, since we've
3195     # resolved all the inheritances that lead to this
3196     delete $table{$target}->{inherit_from};
3197
3198     # Now is the time to deal with those lists.  Here's the place to
3199     # decide what shall be done with those lists, all based on the
3200     # values of the target we're currently dealing with.
3201     # - If a value is a coderef, it will be executed with the list of
3202     #   inherited values as arguments.
3203     # - If the corresponding key doesn't have a value at all or is the
3204     #   empty string, the inherited value list will be run through the
3205     #   default combiner (below), and the result becomes this target's
3206     #   value.
3207     # - Otherwise, this target's value is assumed to be a string that
3208     #   will simply override the inherited list of values.
3209     my $default_combiner = add();
3210
3211     my %all_keys =
3212         map { $_ => 1 } (keys %combined_inheritance,
3213                          keys %{$table{$target}});
3214
3215     sub process_values {
3216         my $object    = shift;
3217         my $inherited = shift;  # Always a [ list ]
3218         my $target    = shift;
3219         my $entry     = shift;
3220
3221         $add_called = 0;
3222
3223         while(ref($object) eq "CODE") {
3224             $object = $object->(@$inherited);
3225         }
3226         if (!defined($object)) {
3227             return ();
3228         }
3229         elsif (ref($object) eq "ARRAY") {
3230             local $add_called;  # To make sure recursive calls don't affect it
3231             return [ map { process_values($_, $inherited, $target, $entry) }
3232                      @$object ];
3233         } elsif (ref($object) eq "") {
3234             return $object;
3235         } else {
3236             die "cannot handle reference type ",ref($object)
3237                 ," found in target ",$target," -> ",$entry,"\n";
3238         }
3239     }
3240
3241     foreach (sort keys %all_keys) {
3242         my $previous = $combined_inheritance{$_};
3243
3244         # Current target doesn't have a value for the current key?
3245         # Assign it the default combiner, the rest of this loop body
3246         # will handle it just like any other coderef.
3247         if (!exists $table{$target}->{$_}) {
3248             $table{$target}->{$_} = $default_combiner;
3249         }
3250
3251         $table{$target}->{$_} = process_values($table{$target}->{$_},
3252                                                $combined_inheritance{$_},
3253                                                $target, $_);
3254         unless(defined($table{$target}->{$_})) {
3255             delete $table{$target}->{$_};
3256         }
3257 #        if ($extra_checks &&
3258 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3259 #            warn "$_ got replaced in $target\n";
3260 #        }
3261     }
3262
3263     # Finally done, return the result.
3264     return %{$table{$target}};
3265 }
3266
3267 sub usage
3268         {
3269         print STDERR $usage;
3270         print STDERR "\npick os/compiler from:\n";
3271         my $j=0;
3272         my $i;
3273         my $k=0;
3274         foreach $i (sort keys %table)
3275                 {
3276                 next if $table{$i}->{template};
3277                 next if $i =~ /^debug/;
3278                 $k += length($i) + 1;
3279                 if ($k > 78)
3280                         {
3281                         print STDERR "\n";
3282                         $k=length($i);
3283                         }
3284                 print STDERR $i . " ";
3285                 }
3286         foreach $i (sort keys %table)
3287                 {
3288                 next if $table{$i}->{template};
3289                 next if $i !~ /^debug/;
3290                 $k += length($i) + 1;
3291                 if ($k > 78)
3292                         {
3293                         print STDERR "\n";
3294                         $k=length($i);
3295                         }
3296                 print STDERR $i . " ";
3297                 }
3298         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3299         exit(1);
3300         }
3301
3302 sub run_dofile
3303 {
3304     my $out = shift;
3305     my @templates = @_;
3306
3307     unlink $out || warn "Can't remove $out, $!"
3308         if -f $out;
3309     foreach (@templates) {
3310         die "Can't open $_, $!" unless -f $_;
3311     }
3312     my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
3313     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
3314     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
3315     system($cmd);
3316     exit 1 if $? != 0;
3317     rename("$out.new", $out) || die "Can't rename $out.new, $!";
3318 }
3319
3320 sub compiler_predefined {
3321     state %predefined;
3322     my $cc = shift;
3323
3324     return () if $^O eq 'VMS';
3325
3326     die 'compiler_predefined called without a compiler command'
3327         unless $cc;
3328
3329     if (! $predefined{$cc}) {
3330
3331         $predefined{$cc} = {};
3332
3333         # collect compiler pre-defines from gcc or gcc-alike...
3334         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3335         while (my $l = <PIPE>) {
3336             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3337             $predefined{$cc}->{$1} = $2 // '';
3338         }
3339         close(PIPE);
3340     }
3341
3342     return %{$predefined{$cc}};
3343 }
3344
3345 sub which
3346 {
3347     my ($name)=@_;
3348
3349     if (eval { require IPC::Cmd; 1; }) {
3350         IPC::Cmd->import();
3351         return scalar IPC::Cmd::can_run($name);
3352     } else {
3353         # if there is $directories component in splitpath,
3354         # then it's not something to test with $PATH...
3355         return $name if (File::Spec->splitpath($name))[1];
3356
3357         foreach (File::Spec->path()) {
3358             my $fullpath = catfile($_, "$name$target{exe_extension}");
3359             if (-f $fullpath and -x $fullpath) {
3360                 return $fullpath;
3361             }
3362         }
3363     }
3364 }
3365
3366 sub env
3367 {
3368     my $name = shift;
3369     my %opts = @_;
3370
3371     unless ($opts{cacheonly}) {
3372         # Note that if $ENV{$name} doesn't exist or is undefined,
3373         # $config{perlenv}->{$name} will be created with the value
3374         # undef.  This is intentional.
3375
3376         $config{perlenv}->{$name} = $ENV{$name}
3377             if ! exists $config{perlenv}->{$name};
3378     }
3379     return $config{perlenv}->{$name};
3380 }
3381
3382 # Configuration printer ##############################################
3383
3384 sub print_table_entry
3385 {
3386     local $now_printing = shift;
3387     my %target = resolve_config($now_printing);
3388     my $type = shift;
3389
3390     # Don't print the templates
3391     return if $target{template};
3392
3393     my @sequence = (
3394         "sys_id",
3395         "cpp",
3396         "cppflags",
3397         "defines",
3398         "includes",
3399         "cc",
3400         "cflags",
3401         "unistd",
3402         "ld",
3403         "lflags",
3404         "loutflag",
3405         "ex_libs",
3406         "bn_ops",
3407         "cpuid_asm_src",
3408         "ec_asm_src",
3409         "des_asm_src",
3410         "aes_asm_src",
3411         "bf_asm_src",
3412         "md5_asm_src",
3413         "cast_asm_src",
3414         "sha1_asm_src",
3415         "rc4_asm_src",
3416         "rmd160_asm_src",
3417         "rc5_asm_src",
3418         "wp_asm_src",
3419         "cmll_asm_src",
3420         "modes_asm_src",
3421         "padlock_asm_src",
3422         "chacha_asm_src",
3423         "poly1035_asm_src",
3424         "thread_scheme",
3425         "perlasm_scheme",
3426         "dso_scheme",
3427         "shared_target",
3428         "shared_cflag",
3429         "shared_defines",
3430         "shared_ldflag",
3431         "shared_rcflag",
3432         "shared_extension",
3433         "dso_extension",
3434         "obj_extension",
3435         "exe_extension",
3436         "ranlib",
3437         "ar",
3438         "arflags",
3439         "aroutflag",
3440         "rc",
3441         "rcflags",
3442         "rcoutflag",
3443         "mt",
3444         "mtflags",
3445         "mtinflag",
3446         "mtoutflag",
3447         "multilib",
3448         "build_scheme",
3449         );
3450
3451     if ($type eq "TABLE") {
3452         print "\n";
3453         print "*** $now_printing\n";
3454         foreach (@sequence) {
3455             if (ref($target{$_}) eq "ARRAY") {
3456                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3457             } else {
3458                 printf "\$%-12s = %s\n", $_, $target{$_};
3459             }
3460         }
3461     } elsif ($type eq "HASH") {
3462         my $largest =
3463             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3464         print "    '$now_printing' => {\n";
3465         foreach (@sequence) {
3466             if ($target{$_}) {
3467                 if (ref($target{$_}) eq "ARRAY") {
3468                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3469                 } else {
3470                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3471                 }
3472             }
3473         }
3474         print "    },\n";
3475     }
3476 }
3477
3478 # Utility routines ###################################################
3479
3480 # On VMS, if the given file is a logical name, File::Spec::Functions
3481 # will consider it an absolute path.  There are cases when we want a
3482 # purely syntactic check without checking the environment.
3483 sub isabsolute {
3484     my $file = shift;
3485
3486     # On non-platforms, we just use file_name_is_absolute().
3487     return file_name_is_absolute($file) unless $^O eq "VMS";
3488
3489     # If the file spec includes a device or a directory spec,
3490     # file_name_is_absolute() is perfectly safe.
3491     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3492
3493     # Here, we know the given file spec isn't absolute
3494     return 0;
3495 }
3496
3497 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3498 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3499 # realpath() requires that at least all path components except the last is an
3500 # existing directory.  On VMS, the last component of the directory spec must
3501 # exist.
3502 sub absolutedir {
3503     my $dir = shift;
3504
3505     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3506     # will return the volume name for the device, no matter what.  Also,
3507     # it will return an incorrect directory spec if the argument is a
3508     # directory that doesn't exist.
3509     if ($^O eq "VMS") {
3510         return rel2abs($dir);
3511     }
3512
3513     # We use realpath() on Unix, since no other will properly clean out
3514     # a directory spec.
3515     use Cwd qw/realpath/;
3516
3517     return realpath($dir);
3518 }
3519
3520 sub quotify {
3521     my %processors = (
3522         perl    => sub { my $x = shift;
3523                          $x =~ s/([\\\$\@"])/\\$1/g;
3524                          return '"'.$x.'"'; },
3525         maybeshell => sub { my $x = shift;
3526                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3527                             if ($x ne $y || $x =~ m|\s|) {
3528                                 return '"'.$y.'"';
3529                             } else {
3530                                 return $x;
3531                             }
3532                         },
3533         );
3534     my $for = shift;
3535     my $processor =
3536         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3537
3538     return map { $processor->($_); } @_;
3539 }
3540
3541 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3542 # $filename is a file name to read from
3543 # $line_concat_cond_re is a regexp detecting a line continuation ending
3544 # $line_concat is a CODEref that takes care of concatenating two lines
3545 sub collect_from_file {
3546     my $filename = shift;
3547     my $line_concat_cond_re = shift;
3548     my $line_concat = shift;
3549
3550     open my $fh, $filename || die "unable to read $filename: $!\n";
3551     return sub {
3552         my $saved_line = "";
3553         $_ = "";
3554         while (<$fh>) {
3555             s|\R$||;
3556             if (defined $line_concat) {
3557                 $_ = $line_concat->($saved_line, $_);
3558                 $saved_line = "";
3559             }
3560             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3561                 $saved_line = $_;
3562                 next;
3563             }
3564             return $_;
3565         }
3566         die "$filename ending with continuation line\n" if $_;
3567         close $fh;
3568         return undef;
3569     }
3570 }
3571
3572 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3573 # $array is an ARRAYref of lines
3574 # $line_concat_cond_re is a regexp detecting a line continuation ending
3575 # $line_concat is a CODEref that takes care of concatenating two lines
3576 sub collect_from_array {
3577     my $array = shift;
3578     my $line_concat_cond_re = shift;
3579     my $line_concat = shift;
3580     my @array = (@$array);
3581
3582     return sub {
3583         my $saved_line = "";
3584         $_ = "";
3585         while (defined($_ = shift @array)) {
3586             s|\R$||;
3587             if (defined $line_concat) {
3588                 $_ = $line_concat->($saved_line, $_);
3589                 $saved_line = "";
3590             }
3591             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3592                 $saved_line = $_;
3593                 next;
3594             }
3595             return $_;
3596         }
3597         die "input text ending with continuation line\n" if $_;
3598         return undef;
3599     }
3600 }
3601
3602 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3603 # $lineiterator is a CODEref that delivers one line at a time.
3604 # All following arguments are regex/CODEref pairs, where the regexp detects a
3605 # line and the CODEref does something with the result of the regexp.
3606 sub collect_information {
3607     my $lineiterator = shift;
3608     my %collectors = @_;
3609
3610     while(defined($_ = $lineiterator->())) {
3611         s|\R$||;
3612         my $found = 0;
3613         if ($collectors{"BEFORE"}) {
3614             $collectors{"BEFORE"}->($_);
3615         }
3616         foreach my $re (keys %collectors) {
3617             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3618                 $collectors{$re}->($lineiterator);
3619                 $found = 1;
3620             };
3621         }
3622         if ($collectors{"OTHERWISE"}) {
3623             $collectors{"OTHERWISE"}->($lineiterator, $_)
3624                 unless $found || !defined $collectors{"OTHERWISE"};
3625         }
3626         if ($collectors{"AFTER"}) {
3627             $collectors{"AFTER"}->($_);
3628         }
3629     }
3630 }
3631
3632 # tokenize($line)
3633 # tokenize($line,$separator)
3634 # $line is a line of text to split up into tokens
3635 # $separator [optional] is a regular expression that separates the tokens,
3636 # the default being spaces.  Do not use quotes of any kind as separators,
3637 # that will give undefined results.
3638 # Returns a list of tokens.
3639 #
3640 # Tokens are divided by separator (spaces by default).  If the tokens include
3641 # the separators, they have to be quoted with single or double quotes.
3642 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3643 # with backslash.
3644 # Basically, the same quoting rules apply for " and ' as in any
3645 # Unix shell.
3646 sub tokenize {
3647     my $line = my $debug_line = shift;
3648     my $separator = shift // qr|\s+|;
3649     my @result = ();
3650
3651     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3652         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3653     }
3654
3655     while ($line =~ s|^${separator}||, $line ne "") {
3656         my $token = "";
3657     again:
3658         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3659         $token .= $1;
3660         $line = $2.$';
3661
3662         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3663             $token .= $1;
3664             $line = $';
3665             goto again;
3666         } elsif ($line =~ m/^'([^']*)'/) {
3667             $token .= $1;
3668             $line = $';
3669             goto again;
3670         }
3671         push @result, $token;
3672     }
3673
3674     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3675         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3676         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3677     }
3678     return @result;
3679 }