Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::fallback "$FindBin::Bin/external/perl/MODULES.txt";
  21 use OpenSSL::Glob;
  22 use OpenSSL::Template;
  23
  24 # see INSTALL for instructions.
  25
  26 my $orig_death_handler = $SIG{__DIE__};
  27 $SIG{__DIE__} = \&death_handler;
  28
  29 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  30
  31 # Options:
  32 #
  33 # --config      add the given configuration file, which will be read after
  34 #               any "Configurations*" files that are found in the same
  35 #               directory as this script.
  36 # --prefix      prefix for the OpenSSL installation, which includes the
  37 #               directories bin, lib, include, share/man, share/doc/openssl
  38 #               This becomes the value of INSTALLTOP in Makefile
  39 #               (Default: /usr/local)
  40 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  41 #               If it's a relative directory, it will be added on the directory
  42 #               given with --prefix.
  43 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  44 #               (Default: PREFIX/ssl)
  45 #
  46 # --cross-compile-prefix Add specified prefix to binutils components.
  47 #
  48 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0
  49 #               Define the public APIs as they were for that version
  50 #               including patch releases.  If 'no-deprecated' is also
  51 #               given, do not compile support for interfaces deprecated
  52 #               up to and including the specified OpenSSL version.
  53 #
  54 # no-hw-xxx     do not compile support for specific crypto hardware.
  55 #               Generic OpenSSL-style methods relating to this support
  56 #               are always compiled but return NULL if the hardware
  57 #               support isn't compiled.
  58 # no-hw         do not compile support for any crypto hardware.
  59 # [no-]threads  [don't] try to create a library that is suitable for
  60 #               multithreaded applications (default is "threads" if we
  61 #               know how to do it)
  62 # [no-]shared   [don't] try to create shared libraries when supported.
  63 # [no-]pic      [don't] try to build position independent code when supported.
  64 #               If disabled, it also disables shared and dynamic-engine.
  65 # no-asm        do not use assembler
  66 # no-egd        do not compile support for the entropy-gathering daemon APIs
  67 # [no-]zlib     [don't] compile support for zlib compression.
  68 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  69 #               library and will be loaded in run-time by the OpenSSL library.
  70 # sctp          include SCTP support
  71 # no-uplink     Don't build support for UPLINK interface.
  72 # enable-weak-ssl-ciphers
  73 #               Enable weak ciphers that are disabled by default.
  74 # 386           generate 80386 code in assembly modules
  75 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  76 #               mentioned '386' option implies this one
  77 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  78 # -<xxx> +<xxx> All options which are unknown to the 'Configure' script are
  79 # /<xxx>        passed through to the compiler. Unix-style options beginning
  80 #               with a '-' or '+' are recognized, as well as Windows-style
  81 #               options beginning with a '/'. If the option contains arguments
  82 #               separated by spaces, then the URL-style notation %20 can be
  83 #               used for the space character in order to avoid having to quote
  84 #               the option. For example, -opt%20arg gets expanded to -opt arg.
  85 #               In fact, any ASCII character can be encoded as %xx using its
  86 #               hexadecimal encoding.
  87 # -static       while -static is also a pass-through compiler option (and
  88 #               as such is limited to environments where it's actually
  89 #               meaningful), it triggers a number configuration options,
  90 #               namely no-pic, no-shared and no-threads. It is
  91 #               argued that the only reason to produce statically linked
  92 #               binaries (and in context it means executables linked with
  93 #               -static flag, and not just executables linked with static
  94 #               libcrypto.a) is to eliminate dependency on specific run-time,
  95 #               a.k.a. libc version. The mentioned config options are meant
  96 #               to achieve just that. Unfortunately on Linux it's impossible
  97 #               to eliminate the dependency completely for openssl executable
  98 #               because of getaddrinfo and gethostbyname calls, which can
  99 #               invoke dynamically loadable library facility anyway to meet
 100 #               the lookup requests. For this reason on Linux statically
 101 #               linked openssl executable has rather debugging value than
 102 #               production quality.
 103 #
 104 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
 105 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
 106 # Following are set automatically by this script
 107 #
 108 # MD5_ASM       use some extra md5 assembler,
 109 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 110 # RMD160_ASM    use some extra ripemd160 assembler,
 111 # SHA256_ASM    sha256_block is implemented in assembler
 112 # SHA512_ASM    sha512_block is implemented in assembler
 113 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 114
 115 # Minimum warning options... any contributions to OpenSSL should at least
 116 # get past these.  Note that we only use these with C compilers, not with
 117 # C++ compilers.
 118
 119 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 120 # -DPEDANTIC complements -pedantic and is meant to mask code that
 121 # is not strictly standard-compliant and/or implementation-specific,
 122 # e.g. inline assembly, disregards to alignment requirements, such
 123 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 124 # to be used even in sanitized builds, because sanitizer too is
 125 # supposed to and does take notice of non-standard behaviour. Then
 126 # -pedantic with pre-C9x compiler would also complain about 'long
 127 # long' not being supported. As 64-bit algorithms are common now,
 128 # it grew impossible to resolve this without sizeable additional
 129 # code, so we just tell compiler to be pedantic about everything
 130 # but 'long long' type.
 131
 132 my @gcc_devteam_warn = qw(
 133     -DDEBUG_UNUSED
 134     -DPEDANTIC -pedantic -Wno-long-long
 135     -Wall
 136     -Wextra
 137     -Wno-unused-parameter
 138     -Wno-missing-field-initializers
 139     -Wswitch
 140     -Wsign-compare
 141     -Wshadow
 142     -Wformat
 143     -Wtype-limits
 144     -Wundef
 145     -Werror
 146     -Wmissing-prototypes
 147     -Wstrict-prototypes
 148 );
 149
 150 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 151 # TODO(openssl-team): fix problems and investigate if (at least) the
 152 # following warnings can also be enabled:
 153 #       -Wcast-align
 154 #       -Wunreachable-code -- no, too ugly/compiler-specific
 155 #       -Wlanguage-extension-token -- no, we use asm()
 156 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 157 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 158 my @clang_devteam_warn = qw(
 159     -Wno-unknown-warning-option
 160     -Wswitch-default
 161     -Wno-parentheses-equality
 162     -Wno-language-extension-token
 163     -Wno-extended-offsetof
 164     -Wconditional-uninitialized
 165     -Wincompatible-pointer-types-discards-qualifiers
 166     -Wmissing-variable-declarations
 167 );
 168
 169 my @cl_devteam_warn = qw(
 170     /WX
 171 );
 172
 173 # This adds backtrace information to the memory leak info.  Is only used
 174 # when crypto-mdebug-backtrace is enabled.
 175 my $memleak_devteam_backtrace = "-rdynamic";
 176
 177 my $strict_warnings = 0;
 178
 179 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 180 # which would cover all BSD flavors. -pthread applies to them all,
 181 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 182 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 183 # which has to be accompanied by explicit -D_THREAD_SAFE and
 184 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 185 # seems to be sufficient?
 186 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 187
 188 #
 189 # API compatibility name to version number mapping.
 190 #
 191 my $apitable = {
 192     # This table expresses when API additions or changes can occur.
 193     # The numbering used changes from 3.0 and on because we updated
 194     # (solidified) our version numbering scheme at that point.
 195
 196     # From 3.0 and on, we internalise the given version number in dedcimal
 197     # as MAJOR * 10000 + MINOR * 100 + 0
 198     "3.0.0" => 30000,
 199     "3.0"   => 30000,
 200
 201     # Note that before 3.0, we didn't have the same version number scheme.
 202     # Still, the numbering we use here covers what we need.
 203     "1.1.1" => 10101,
 204     "1.1.0" => 10100,
 205     "1.0.2" => 10002,
 206     "1.0.1" => 10001,
 207     "1.0.0" => 10000,
 208     "0.9.8" =>   908,
 209 };
 210
 211 our %table = ();
 212 our %config = ();
 213 our %withargs = ();
 214 our $now_printing;      # set to current entry's name in print_table_entry
 215                         # (todo: right thing would be to encapsulate name
 216                         # into %target [class] and make print_table_entry
 217                         # a method)
 218
 219 # Forward declarations ###############################################
 220
 221 # read_config(filename)
 222 #
 223 # Reads a configuration file and populates %table with the contents
 224 # (which the configuration file places in %targets).
 225 sub read_config;
 226
 227 # resolve_config(target)
 228 #
 229 # Resolves all the late evaluations, inheritances and so on for the
 230 # chosen target and any target it inherits from.
 231 sub resolve_config;
 232
 233
 234 # Information collection #############################################
 235
 236 # Unified build supports separate build dir
 237 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 238 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 239 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 240
 241 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 242
 243 $config{sourcedir} = abs2rel($srcdir);
 244 $config{builddir} = abs2rel($blddir);
 245
 246 # Collect reconfiguration information if needed
 247 my @argvcopy=@ARGV;
 248
 249 if (grep /^reconf(igure)?$/, @argvcopy) {
 250     die "reconfiguring with other arguments present isn't supported"
 251         if scalar @argvcopy > 1;
 252     if (-f "./configdata.pm") {
 253         my $file = "./configdata.pm";
 254         unless (my $return = do $file) {
 255             die "couldn't parse $file: $@" if $@;
 256             die "couldn't do $file: $!"    unless defined $return;
 257             die "couldn't run $file"       unless $return;
 258         }
 259
 260         @argvcopy = defined($configdata::config{perlargv}) ?
 261             @{$configdata::config{perlargv}} : ();
 262         die "Incorrect data to reconfigure, please do a normal configuration\n"
 263             if (grep(/^reconf/,@argvcopy));
 264         $config{perlenv} = $configdata::config{perlenv} // {};
 265     } else {
 266         die "Insufficient data to reconfigure, please do a normal configuration\n";
 267     }
 268 }
 269
 270 $config{perlargv} = [ @argvcopy ];
 271
 272 # Collect version numbers
 273 my %version = ();
 274
 275 collect_information(
 276     collect_from_file(catfile($srcdir,'VERSION')),
 277     qr/\s*(\w+)\s*=\s*(.*?)\s*$/ =>
 278         sub {
 279             # Only define it if there is a value at all
 280             $version{uc $1} = $2 if $2 ne '';
 281         },
 282     "OTHERWISE" =>
 283         sub { die "Something wrong with this line:\n$_\nin $srcdir/VERSION" },
 284     );
 285
 286 $config{major} = $version{MAJOR} // 'unknown';
 287 $config{minor} = $version{MINOR} // 'unknown';
 288 $config{patch} = $version{PATCH} // 'unknown';
 289 $config{prerelease} =
 290     defined $version{PRE_RELEASE_TAG} ? "-$version{PRE_RELEASE_TAG}" : '';
 291 $config{build_metadata} =
 292     defined $version{BUILD_METADATA} ? "+$version{BUILD_METADATA}" : '';
 293 $config{shlib_version} = $version{SHLIB_VERSION} // 'unknown';
 294 $config{release_date} = $version{RELEASE_DATE} // 'xx XXX xxxx';
 295
 296 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 297 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 298
 299 die "erroneous version information in VERSION: ",
 300     "$config{version}, $config{shlib_version}\n"
 301     unless (defined $version{MAJOR}
 302             && defined $version{MINOR}
 303             && defined $version{PATCH}
 304             && defined $version{SHLIB_VERSION});
 305
 306 # Collect target configurations
 307
 308 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 309 foreach (sort glob($pattern)) {
 310     &read_config($_);
 311 }
 312
 313 if (defined env($local_config_envname)) {
 314     if ($^O eq 'VMS') {
 315         # VMS environment variables are logical names,
 316         # which can be used as is
 317         $pattern = $local_config_envname . ':' . '*.conf';
 318     } else {
 319         $pattern = catfile(env($local_config_envname), '*.conf');
 320     }
 321
 322     foreach (sort glob($pattern)) {
 323         &read_config($_);
 324     }
 325 }
 326
 327 # Save away perl command information
 328 $config{perl_cmd} = $^X;
 329 $config{perl_version} = $Config{version};
 330 $config{perl_archname} = $Config{archname};
 331
 332 $config{prefix}="";
 333 $config{openssldir}="";
 334 $config{processor}="";
 335 $config{libdir}="";
 336 my $auto_threads=1;    # enable threads automatically? true by default
 337 my $default_ranlib;
 338
 339 # Known TLS and DTLS protocols
 340 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 341 my @dtls = qw(dtls1 dtls1_2);
 342
 343 # Explicitly known options that are possible to disable.  They can
 344 # be regexps, and will be used like this: /^no-${option}$/
 345 # For developers: keep it sorted alphabetically
 346
 347 my @disablables = (
 348     "ktls",
 349     "afalgeng",
 350     "aria",
 351     "asan",
 352     "asm",
 353     "async",
 354     "autoalginit",
 355     "autoerrinit",
 356     "autoload-config",
 357     "bf",
 358     "blake2",
 359     "buildtest-c++",
 360     "camellia",
 361     "capieng",
 362     "cast",
 363     "chacha",
 364     "cmac",
 365     "cmp",
 366     "cms",
 367     "comp",
 368     "crypto-mdebug",
 369     "crypto-mdebug-backtrace",
 370     "ct",
 371     "deprecated",
 372     "des",
 373     "devcryptoeng",
 374     "dgram",
 375     "dh",
 376     "dsa",
 377     "dso",
 378     "dtls",
 379     "dynamic-engine",
 380     "ec",
 381     "ec2m",
 382     "ecdh",
 383     "ecdsa",
 384     "ec_nistp_64_gcc_128",
 385     "egd",
 386     "engine",
 387     "err",
 388     "external-tests",
 389     "filenames",
 390     "fips",
 391     "fuzz-libfuzzer",
 392     "fuzz-afl",
 393     "gost",
 394     "idea",
 395     "legacy",
 396     "makedepend",
 397     "md2",
 398     "md4",
 399     "mdc2",
 400     "module",
 401     "msan",
 402     "multiblock",
 403     "nextprotoneg",
 404     "pinshared",
 405     "ocb",
 406     "ocsp",
 407     "padlockeng",
 408     "pic",
 409     "poly1305",
 410     "posix-io",
 411     "psk",
 412     "rc2",
 413     "rc4",
 414     "rc5",
 415     "rdrand",
 416     "rfc3779",
 417     "rmd160",
 418     "scrypt",
 419     "sctp",
 420     "seed",
 421     "shared",
 422     "siphash",
 423     "siv",
 424     "sm2",
 425     "sm3",
 426     "sm4",
 427     "sock",
 428     "srp",
 429     "srtp",
 430     "sse2",
 431     "ssl",
 432     "ssl-trace",
 433     "static-engine",
 434     "stdio",
 435     "tests",
 436     "threads",
 437     "tls",
 438     "trace",
 439     "ts",
 440     "ubsan",
 441     "ui-console",
 442     "unit-test",
 443     "uplink",
 444     "whirlpool",
 445     "weak-ssl-ciphers",
 446     "zlib",
 447     "zlib-dynamic",
 448     );
 449 foreach my $proto ((@tls, @dtls))
 450         {
 451         push(@disablables, $proto);
 452         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 453         }
 454
 455 # Internal disablables, for aliasing purposes.  They serve no special
 456 # purpose here, but allow scripts to get to know them through configdata.pm,
 457 # where these are merged with @disablables.
 458 # The actual aliasing mechanism is done via %disable_cascades
 459 my @disablables_int = qw(
 460     crmf
 461     );
 462
 463 my %deprecated_disablables = (
 464     "ssl2" => undef,
 465     "buf-freelists" => undef,
 466     "hw" => "hw",               # causes cascade, but no macro
 467     "hw-padlock" => "padlockeng",
 468     "ripemd" => "rmd160",
 469     "ui" => "ui-console",
 470     "heartbeats" => undef,
 471     );
 472
 473 # All of the following are disabled by default:
 474
 475 our %disabled = ( # "what"         => "comment"
 476                   "asan"                => "default",
 477                   "buildtest-c++"       => "default",
 478                   "crypto-mdebug"       => "default",
 479                   "crypto-mdebug-backtrace" => "default",
 480                   "devcryptoeng"        => "default",
 481                   "ec_nistp_64_gcc_128" => "default",
 482                   "egd"                 => "default",
 483                   "external-tests"      => "default",
 484                   "fuzz-libfuzzer"      => "default",
 485                   "fuzz-afl"            => "default",
 486                   "md2"                 => "default",
 487                   "msan"                => "default",
 488                   "rc5"                 => "default",
 489                   "sctp"                => "default",
 490                   "ssl-trace"           => "default",
 491                   "ssl3"                => "default",
 492                   "ssl3-method"         => "default",
 493                   "trace"               => "default",
 494                   "ubsan"               => "default",
 495                   "unit-test"           => "default",
 496                   "weak-ssl-ciphers"    => "default",
 497                   "zlib"                => "default",
 498                   "zlib-dynamic"        => "default",
 499                   "ktls"                => "default",
 500                 );
 501
 502 # Note: => pair form used for aesthetics, not to truly make a hash table
 503 my @disable_cascades = (
 504     # "what"            => [ "cascade", ... ]
 505     sub { $config{processor} eq "386" }
 506                         => [ "sse2" ],
 507     "ssl"               => [ "ssl3" ],
 508     "ssl3-method"       => [ "ssl3" ],
 509     "zlib"              => [ "zlib-dynamic" ],
 510     "des"               => [ "mdc2" ],
 511     "ec"                => [ "ecdsa", "ecdh", "sm2" ],
 512     sub { $disabled{"ec"} && $disabled{"dh"} }
 513                         => [ "tls1_3" ],
 514     "dgram"             => [ "dtls", "sctp" ],
 515     "sock"              => [ "dgram" ],
 516     "dtls"              => [ @dtls ],
 517     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 518                         => [ "dtls" ],
 519
 520     "tls"               => [ @tls ],
 521     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 522                         => [ "tls" ],
 523
 524     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 525
 526     # If no modules, then no dynamic engines either
 527     "module"            => [ "dynamic-engine" ],
 528
 529     # Without shared libraries, dynamic engines aren't possible.
 530     # This is due to them having to link with libcrypto and register features
 531     # using the ENGINE functionality, and since that relies on global tables,
 532     # those *have* to be exacty the same as the ones accessed from the app,
 533     # which cannot be guaranteed if shared libraries aren't present.
 534     # (note that even with shared libraries, both the app and dynamic engines
 535     # must be linked with the same library)
 536     "shared"            => [ "dynamic-engine", "uplink" ],
 537     "dso"               => [ "dynamic-engine", "module" ],
 538     # Other modules don't necessarily have to link with libcrypto, so shared
 539     # libraries do not have to be a condition to produce those.
 540
 541     # Without position independent code, there can be no shared libraries
 542     # or modules.
 543     "pic"               => [ "shared", "module" ],
 544
 545     "module"            => [ "fips" ],
 546
 547     "engine"            => [ grep /eng$/, @disablables ],
 548     "hw"                => [ "padlockeng" ],
 549
 550     # no-autoalginit is only useful when building non-shared
 551     "autoalginit"       => [ "shared", "apps" ],
 552
 553     "stdio"             => [ "apps", "capieng", "egd" ],
 554     "apps"              => [ "tests" ],
 555     "tests"             => [ "external-tests" ],
 556     "comp"              => [ "zlib" ],
 557     "sm3"               => [ "sm2" ],
 558     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 559
 560     sub { !$disabled{"msan"} } => [ "asm" ],
 561
 562     sub { $disabled{cmac}; } => [ "siv" ],
 563     "legacy"                 => [ "md2" ],
 564
 565     "cmp"               => [ "crmf" ],
 566     );
 567
 568 # Avoid protocol support holes.  Also disable all versions below N, if version
 569 # N is disabled while N+1 is enabled.
 570 #
 571 my @list = (reverse @tls);
 572 while ((my $first, my $second) = (shift @list, shift @list)) {
 573     last unless @list;
 574     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 575                               => [ @list ] );
 576     unshift @list, $second;
 577 }
 578 my @list = (reverse @dtls);
 579 while ((my $first, my $second) = (shift @list, shift @list)) {
 580     last unless @list;
 581     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 582                               => [ @list ] );
 583     unshift @list, $second;
 584 }
 585
 586 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 587 # To remove something from %disabled, use "enable-foo".
 588 # For symmetry, "disable-foo" is a synonym for "no-foo".
 589
 590 &usage if ($#ARGV < 0);
 591
 592 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 593 # platform specific list separators.  Users from those platforms should
 594 # recognise those separators from how you set up the PATH to find executables.
 595 # The default is the Unix like separator, :, but as an exception, we also
 596 # support the space as separator.
 597 my $list_separator_re =
 598     { VMS           => qr/(?<!\^),/,
 599       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 600 # All the "make variables" we support
 601 # Some get pre-populated for the sake of backward compatibility
 602 # (we supported those before the change to "make variable" support.
 603 my %user = (
 604     AR          => env('AR'),
 605     ARFLAGS     => [],
 606     AS          => undef,
 607     ASFLAGS     => [],
 608     CC          => env('CC'),
 609     CFLAGS      => [ env('CFLAGS') || () ],
 610     CXX         => env('CXX'),
 611     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 612     CPP         => undef,
 613     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 614     CPPDEFINES  => [],  # Alternative for -D
 615     CPPINCLUDES => [],  # Alternative for -I
 616     CROSS_COMPILE => env('CROSS_COMPILE'),
 617     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 618     LD          => undef,
 619     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 620     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 621     MT          => undef,
 622     MTFLAGS     => [],
 623     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 624     RANLIB      => env('RANLIB'),
 625     RC          => env('RC') || env('WINDRES'),
 626     RCFLAGS     => [ env('RCFLAGS') || () ],
 627     RM          => undef,
 628    );
 629 # Info about what "make variables" may be prefixed with the cross compiler
 630 # prefix.  This should NEVER mention any such variable with a list for value.
 631 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 632 # The same but for flags given as Configure options.  These are *additional*
 633 # input, as opposed to the VAR=string option that override the corresponding
 634 # config target attributes
 635 my %useradd = (
 636     CPPDEFINES  => [],
 637     CPPINCLUDES => [],
 638     CPPFLAGS    => [],
 639     CFLAGS      => [],
 640     CXXFLAGS    => [],
 641     LDFLAGS     => [],
 642     LDLIBS      => [],
 643     RCFLAGS     => [],
 644    );
 645
 646 my %user_synonyms = (
 647     HASHBANGPERL=> 'PERL',
 648     RC          => 'WINDRES',
 649    );
 650
 651 # Some target attributes have been renamed, this is the translation table
 652 my %target_attr_translate =(
 653     ar          => 'AR',
 654     as          => 'AS',
 655     cc          => 'CC',
 656     cxx         => 'CXX',
 657     cpp         => 'CPP',
 658     hashbangperl => 'HASHBANGPERL',
 659     ld          => 'LD',
 660     mt          => 'MT',
 661     ranlib      => 'RANLIB',
 662     rc          => 'RC',
 663     rm          => 'RM',
 664    );
 665
 666 # Initialisers coming from 'config' scripts
 667 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 668 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 669 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 670 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 671 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 672 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 673 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 674
 675 $config{openssl_api_defines}=[];
 676 $config{openssl_sys_defines}=[];
 677 $config{openssl_feature_defines}=[];
 678 $config{options}="";
 679 $config{build_type} = "release";
 680 my $target="";
 681
 682 my %cmdvars = ();               # Stores FOO='blah' type arguments
 683 my %unsupported_options = ();
 684 my %deprecated_options = ();
 685 # If you change this, update apps/version.c
 686 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 687 my @seed_sources = ();
 688 while (@argvcopy)
 689         {
 690         $_ = shift @argvcopy;
 691
 692         # Support env variable assignments among the options
 693         if (m|^(\w+)=(.+)?$|)
 694                 {
 695                 $cmdvars{$1} = $2;
 696                 # Every time a variable is given as a configuration argument,
 697                 # it acts as a reset if the variable.
 698                 if (exists $user{$1})
 699                         {
 700                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 701                         }
 702                 #if (exists $useradd{$1})
 703                 #       {
 704                 #       $useradd{$1} = [];
 705                 #       }
 706                 next;
 707                 }
 708
 709         # VMS is a case insensitive environment, and depending on settings
 710         # out of our control, we may receive options uppercased.  Let's
 711         # downcase at least the part before any equal sign.
 712         if ($^O eq "VMS")
 713                 {
 714                 s/^([^=]*)/lc($1)/e;
 715                 }
 716
 717         # some people just can't read the instructions, clang people have to...
 718         s/^-no-(?!integrated-as)/no-/;
 719
 720         # rewrite some options in "enable-..." form
 721         s /^-?-?shared$/enable-shared/;
 722         s /^sctp$/enable-sctp/;
 723         s /^threads$/enable-threads/;
 724         s /^zlib$/enable-zlib/;
 725         s /^zlib-dynamic$/enable-zlib-dynamic/;
 726
 727         if (/^(no|disable|enable)-(.+)$/)
 728                 {
 729                 my $word = $2;
 730                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 731                         && !exists $deprecated_disablables{$word}
 732                         && !grep { $word eq $_ } @disablables)
 733                         {
 734                         $unsupported_options{$_} = 1;
 735                         next;
 736                         }
 737                 }
 738         if (/^no-(.+)$/ || /^disable-(.+)$/)
 739                 {
 740                 foreach my $proto ((@tls, @dtls))
 741                         {
 742                         if ($1 eq "$proto-method")
 743                                 {
 744                                 $disabled{"$proto"} = "option($proto-method)";
 745                                 last;
 746                                 }
 747                         }
 748                 if ($1 eq "dtls")
 749                         {
 750                         foreach my $proto (@dtls)
 751                                 {
 752                                 $disabled{$proto} = "option(dtls)";
 753                                 }
 754                         $disabled{"dtls"} = "option(dtls)";
 755                         }
 756                 elsif ($1 eq "ssl")
 757                         {
 758                         # Last one of its kind
 759                         $disabled{"ssl3"} = "option(ssl)";
 760                         }
 761                 elsif ($1 eq "tls")
 762                         {
 763                         # XXX: Tests will fail if all SSL/TLS
 764                         # protocols are disabled.
 765                         foreach my $proto (@tls)
 766                                 {
 767                                 $disabled{$proto} = "option(tls)";
 768                                 }
 769                         }
 770                 elsif ($1 eq "static-engine")
 771                         {
 772                         delete $disabled{"dynamic-engine"};
 773                         }
 774                 elsif ($1 eq "dynamic-engine")
 775                         {
 776                         $disabled{"dynamic-engine"} = "option";
 777                         }
 778                 elsif (exists $deprecated_disablables{$1})
 779                         {
 780                         $deprecated_options{$_} = 1;
 781                         if (defined $deprecated_disablables{$1})
 782                                 {
 783                                 $disabled{$deprecated_disablables{$1}} = "option";
 784                                 }
 785                         }
 786                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 787                         {
 788                         $deprecated_options{$_} = 1;
 789                         }
 790                 else
 791                         {
 792                         $disabled{$1} = "option";
 793                         }
 794                 # No longer an automatic choice
 795                 $auto_threads = 0 if ($1 eq "threads");
 796                 }
 797         elsif (/^enable-(.+)$/)
 798                 {
 799                 if ($1 eq "static-engine")
 800                         {
 801                         $disabled{"dynamic-engine"} = "option";
 802                         }
 803                 elsif ($1 eq "dynamic-engine")
 804                         {
 805                         delete $disabled{"dynamic-engine"};
 806                         }
 807                 elsif ($1 eq "zlib-dynamic")
 808                         {
 809                         delete $disabled{"zlib"};
 810                         }
 811                 my $algo = $1;
 812                 delete $disabled{$algo};
 813
 814                 # No longer an automatic choice
 815                 $auto_threads = 0 if ($1 eq "threads");
 816                 }
 817         elsif (/^--strict-warnings$/)
 818                 {
 819                 # Pretend that our strict flags is a C flag, and replace it
 820                 # with the proper flags later on
 821                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 822                 $strict_warnings=1;
 823                 }
 824         elsif (/^--debug$/)
 825                 {
 826                 $config{build_type} = "debug";
 827                 }
 828         elsif (/^--release$/)
 829                 {
 830                 $config{build_type} = "release";
 831                 }
 832         elsif (/^386$/)
 833                 { $config{processor}=386; }
 834         elsif (/^fips$/)
 835                 {
 836                 die "FIPS mode not supported\n";
 837                 }
 838         elsif (/^rsaref$/)
 839                 {
 840                 # No RSAref support any more since it's not needed.
 841                 # The check for the option is there so scripts aren't
 842                 # broken
 843                 }
 844         elsif (/^nofipscanistercheck$/)
 845                 {
 846                 die "FIPS mode not supported\n";
 847                 }
 848         elsif (m|^[-+/]|)
 849                 {
 850                 if (/^--prefix=(.*)$/)
 851                         {
 852                         $config{prefix}=$1;
 853                         die "Directory given with --prefix MUST be absolute\n"
 854                                 unless file_name_is_absolute($config{prefix});
 855                         }
 856                 elsif (/^--api=(.*)$/)
 857                         {
 858                         my $api = $1;
 859                         die "Unknown API compatibility level $api"
 860                                 unless defined $apitable->{$api};
 861                         $config{api}=$apitable->{$api};
 862                         }
 863                 elsif (/^--libdir=(.*)$/)
 864                         {
 865                         $config{libdir}=$1;
 866                         }
 867                 elsif (/^--openssldir=(.*)$/)
 868                         {
 869                         $config{openssldir}=$1;
 870                         }
 871                 elsif (/^--with-zlib-lib=(.*)$/)
 872                         {
 873                         $withargs{zlib_lib}=$1;
 874                         }
 875                 elsif (/^--with-zlib-include=(.*)$/)
 876                         {
 877                         $withargs{zlib_include}=$1;
 878                         }
 879                 elsif (/^--with-fuzzer-lib=(.*)$/)
 880                         {
 881                         $withargs{fuzzer_lib}=$1;
 882                         }
 883                 elsif (/^--with-fuzzer-include=(.*)$/)
 884                         {
 885                         $withargs{fuzzer_include}=$1;
 886                         }
 887                 elsif (/^--with-rand-seed=(.*)$/)
 888                         {
 889                         foreach my $x (split(m|,|, $1))
 890                             {
 891                             die "Unknown --with-rand-seed choice $x\n"
 892                                 if ! grep { $x eq $_ } @known_seed_sources;
 893                             push @seed_sources, $x;
 894                             }
 895                         }
 896                 elsif (/^--cross-compile-prefix=(.*)$/)
 897                         {
 898                         $user{CROSS_COMPILE}=$1;
 899                         }
 900                 elsif (/^--config=(.*)$/)
 901                         {
 902                         read_config $1;
 903                         }
 904                 elsif (/^-l(.*)$/)
 905                         {
 906                         push @{$useradd{LDLIBS}}, $_;
 907                         }
 908                 elsif (/^-framework$/)
 909                         {
 910                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 911                         }
 912                 elsif (/^-L(.*)$/ or /^-Wl,/)
 913                         {
 914                         push @{$useradd{LDFLAGS}}, $_;
 915                         }
 916                 elsif (/^-rpath$/ or /^-R$/)
 917                         # -rpath is the OSF1 rpath flag
 918                         # -R is the old Solaris rpath flag
 919                         {
 920                         my $rpath = shift(@argvcopy) || "";
 921                         $rpath .= " " if $rpath ne "";
 922                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 923                         }
 924                 elsif (/^-static$/)
 925                         {
 926                         push @{$useradd{LDFLAGS}}, $_;
 927                         }
 928                 elsif (m|^[-/]D(.*)$|)
 929                         {
 930                         push @{$useradd{CPPDEFINES}}, $1;
 931                         }
 932                 elsif (m|^[-/]I(.*)$|)
 933                         {
 934                         push @{$useradd{CPPINCLUDES}}, $1;
 935                         }
 936                 elsif (/^-Wp,$/)
 937                         {
 938                         push @{$useradd{CPPFLAGS}}, $1;
 939                         }
 940                 else    # common if (/^[-+]/), just pass down...
 941                         {
 942                         # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
 943                         # This provides a simple way to pass options with arguments separated
 944                         # by spaces without quoting (e.g. -opt%20arg translates to -opt arg).
 945                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 946                         push @{$useradd{CFLAGS}}, $_;
 947                         push @{$useradd{CXXFLAGS}}, $_;
 948                         }
 949                 }
 950         elsif (m|^/|)
 951                 {
 952                 # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
 953                 # This provides a simple way to pass options with arguments separated
 954                 # by spaces without quoting (e.g. /opt%20arg translates to /opt arg).
 955                 $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 956                 push @{$useradd{CFLAGS}}, $_;
 957                 push @{$useradd{CXXFLAGS}}, $_;
 958                 }
 959         else
 960                 {
 961                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 962                 $target=$_;
 963                 }
 964         unless ($_ eq $target || /^no-/ || /^disable-/)
 965                 {
 966                 # "no-..." follows later after implied deactivations
 967                 # have been derived.  (Don't take this too seriously,
 968                 # we really only write OPTIONS to the Makefile out of
 969                 # nostalgia.)
 970
 971                 if ($config{options} eq "")
 972                         { $config{options} = $_; }
 973                 else
 974                         { $config{options} .= " ".$_; }
 975                 }
 976         }
 977
 978 if (keys %deprecated_options)
 979         {
 980         warn "***** Deprecated options: ",
 981                 join(", ", keys %deprecated_options), "\n";
 982         }
 983 if (keys %unsupported_options)
 984         {
 985         die "***** Unsupported options: ",
 986                 join(", ", keys %unsupported_options), "\n";
 987         }
 988
 989 # If any %useradd entry has been set, we must check that the "make
 990 # variables" haven't been set.  We start by checking of any %useradd entry
 991 # is set.
 992 if (grep { scalar @$_ > 0 } values %useradd) {
 993     # Hash of env / make variables names.  The possible values are:
 994     # 1 - "make vars"
 995     # 2 - %useradd entry set
 996     # 3 - both set
 997     my %detected_vars =
 998         map { my $v = 0;
 999               $v += 1 if $cmdvars{$_};
1000               $v += 2 if @{$useradd{$_}};
1001               $_ => $v }
1002         keys %useradd;
1003
1004     # If any of the corresponding "make variables" is set, we error
1005     if (grep { $_ & 1 } values %detected_vars) {
1006         my $names = join(', ', grep { $detected_vars{$_} > 0 }
1007                                sort keys %detected_vars);
1008         die <<"_____";
1009 ***** Mixing make variables and additional compiler/linker flags as
1010 ***** configure command line option is not permitted.
1011 ***** Affected make variables: $names
1012 _____
1013     }
1014 }
1015
1016 # Check through all supported command line variables to see if any of them
1017 # were set, and canonicalise the values we got.  If no compiler or linker
1018 # flag or anything else that affects %useradd was set, we also check the
1019 # environment for values.
1020 my $anyuseradd =
1021     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
1022 foreach (keys %user) {
1023     my $value = $cmdvars{$_};
1024     $value //= env($_) unless $anyuseradd;
1025     $value //=
1026         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
1027     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
1028         unless $anyuseradd;
1029
1030     if (defined $value) {
1031         if (ref $user{$_} eq 'ARRAY') {
1032             $user{$_} = [ split /$list_separator_re/, $value ];
1033         } elsif (!defined $user{$_}) {
1034             $user{$_} = $value;
1035         }
1036     }
1037 }
1038
1039 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1040     && !$disabled{shared}
1041     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1042     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1043         "***** any of asan, msan or ubsan\n";
1044 }
1045
1046 sub disable {
1047     my $disable_type = shift;
1048
1049     for (@_) {
1050         $disabled{$_} = $disable_type;
1051     }
1052
1053     my @tocheckfor = (@_ ? @_ : keys %disabled);
1054     while (@tocheckfor) {
1055         my %new_tocheckfor = ();
1056         my @cascade_copy = (@disable_cascades);
1057         while (@cascade_copy) {
1058             my ($test, $descendents) =
1059                 (shift @cascade_copy, shift @cascade_copy);
1060             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1061                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1062                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1063                 }
1064             }
1065         }
1066         @tocheckfor = (keys %new_tocheckfor);
1067     }
1068 }
1069 disable();                     # First cascade run
1070
1071 our $die = sub { die @_; };
1072 if ($target eq "TABLE") {
1073     local $die = sub { warn @_; };
1074     foreach (sort keys %table) {
1075         print_table_entry($_, "TABLE");
1076     }
1077     exit 0;
1078 }
1079
1080 if ($target eq "LIST") {
1081     foreach (sort keys %table) {
1082         print $_,"\n" unless $table{$_}->{template};
1083     }
1084     exit 0;
1085 }
1086
1087 if ($target eq "HASH") {
1088     local $die = sub { warn @_; };
1089     print "%table = (\n";
1090     foreach (sort keys %table) {
1091         print_table_entry($_, "HASH");
1092     }
1093     exit 0;
1094 }
1095
1096 print "Configuring OpenSSL version $config{full_version} ";
1097 print "for target $target\n";
1098
1099 if (scalar(@seed_sources) == 0) {
1100     print "Using os-specific seed configuration\n";
1101     push @seed_sources, 'os';
1102 }
1103 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1104     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1105     warn <<_____ if scalar(@seed_sources) == 1;
1106
1107 ============================== WARNING ===============================
1108 You have selected the --with-rand-seed=none option, which effectively
1109 disables automatic reseeding of the OpenSSL random generator.
1110 All operations depending on the random generator such as creating keys
1111 will not work unless the random generator is seeded manually by the
1112 application.
1113
1114 Please read the 'Note on random number generation' section in the
1115 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1116 ============================== WARNING ===============================
1117
1118 _____
1119 }
1120 push @{$config{openssl_feature_defines}},
1121      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1122         @seed_sources;
1123
1124 # Backward compatibility?
1125 if ($target =~ m/^CygWin32(-.*)$/) {
1126     $target = "Cygwin".$1;
1127 }
1128
1129 # Support for legacy targets having a name starting with 'debug-'
1130 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1131 if ($d) {
1132     $config{build_type} = "debug";
1133
1134     # If we do not find debug-foo in the table, the target is set to foo.
1135     if (!$table{$target}) {
1136         $target = $t;
1137     }
1138 }
1139
1140 &usage if !$table{$target} || $table{$target}->{template};
1141
1142 $config{target} = $target;
1143 my %target = resolve_config($target);
1144
1145 foreach (keys %target_attr_translate) {
1146     $target{$target_attr_translate{$_}} = $target{$_}
1147         if $target{$_};
1148     delete $target{$_};
1149 }
1150
1151 %target = ( %{$table{DEFAULTS}}, %target );
1152
1153 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1154 $config{conf_files} = [ sort keys %conf_files ];
1155
1156 # Using sub disable within these loops may prove fragile, so we run
1157 # a cascade afterwards
1158 foreach my $feature (@{$target{disable}}) {
1159     if (exists $deprecated_disablables{$feature}) {
1160         warn "***** config $target disables deprecated feature $feature\n";
1161     } elsif (!grep { $feature eq $_ } @disablables) {
1162         die "***** config $target disables unknown feature $feature\n";
1163     }
1164     $disabled{$feature} = 'config';
1165 }
1166 foreach my $feature (@{$target{enable}}) {
1167     if ("default" eq ($disabled{$feature} // "")) {
1168         if (exists $deprecated_disablables{$feature}) {
1169             warn "***** config $target enables deprecated feature $feature\n";
1170         } elsif (!grep { $feature eq $_ } @disablables) {
1171             die "***** config $target enables unknown feature $feature\n";
1172         }
1173         delete $disabled{$feature};
1174     }
1175 }
1176
1177 # If uplink_arch isn't defined, disable uplink
1178 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1179 # If asm_arch isn't defined, disable asm
1180 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1181
1182 disable();                      # Run a cascade now
1183
1184 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1185 $target{cxxflags}//=$target{cflags} if $target{CXX};
1186 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1187 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1188
1189 # Fill %config with values from %user, and in case those are undefined or
1190 # empty, use values from %target (acting as a default).
1191 foreach (keys %user) {
1192     my $ref_type = ref $user{$_};
1193
1194     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1195     # and a value that's to be coerced into that type.
1196     my $mkvalue = sub {
1197         my $type = shift;
1198         my $value = shift;
1199         my $undef_p = shift;
1200
1201         die "Too many arguments for \$mkvalue" if @_;
1202
1203         while (ref $value eq 'CODE') {
1204             $value = $value->();
1205         }
1206
1207         if ($type eq 'ARRAY') {
1208             return undef unless defined $value;
1209             return undef if ref $value ne 'ARRAY' && !$value;
1210             return undef if ref $value eq 'ARRAY' && !@$value;
1211             return [ $value ] unless ref $value eq 'ARRAY';
1212         }
1213         return undef unless $value;
1214         return $value;
1215     };
1216
1217     $config{$_} =
1218         $mkvalue->($ref_type, $user{$_})
1219         || $mkvalue->($ref_type, $target{$_});
1220     delete $config{$_} unless defined $config{$_};
1221 }
1222
1223 # Finish up %config by appending things the user gave us on the command line
1224 # apart from "make variables"
1225 foreach (keys %useradd) {
1226     # The must all be lists, so we assert that here
1227     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1228         unless ref $useradd{$_} eq 'ARRAY';
1229
1230     if (defined $config{$_}) {
1231         push @{$config{$_}}, @{$useradd{$_}};
1232     } else {
1233         $config{$_} = [ @{$useradd{$_}} ];
1234     }
1235 }
1236 # At this point, we can forget everything about %user and %useradd,
1237 # because it's now all been merged into the corresponding $config entry
1238
1239 # Allow overriding the build file name
1240 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1241
1242 # Make sure build_scheme is consistent.
1243 $target{build_scheme} = [ $target{build_scheme} ]
1244     if ref($target{build_scheme}) ne "ARRAY";
1245
1246 my ($builder, $builder_platform, @builder_opts) =
1247     @{$target{build_scheme}};
1248
1249 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1250                       $builder_platform."-checker.pm")) {
1251     my $checker_path = catfile($srcdir, "Configurations", $checker);
1252     if (-f $checker_path) {
1253         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1254             ? sub { warn $@; } : sub { die $@; };
1255         if (! do $checker_path) {
1256             if ($@) {
1257                 $fn->($@);
1258             } elsif ($!) {
1259                 $fn->($!);
1260             } else {
1261                 $fn->("The detected tools didn't match the platform\n");
1262             }
1263         }
1264         last;
1265     }
1266 }
1267
1268 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1269
1270 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1271         {
1272         push @{$config{cflags}}, "-mno-cygwin";
1273         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1274         push @{$config{shared_ldflag}}, "-mno-cygwin";
1275         }
1276
1277 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1278         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1279         # minimally required architecture flags for assembly modules
1280         my $value;
1281         $value = '-mips2' if ($target =~ /mips32/);
1282         $value = '-mips3' if ($target =~ /mips64/);
1283         unshift @{$config{cflags}}, $value;
1284         unshift @{$config{cxxflags}}, $value if $config{CXX};
1285 }
1286
1287 # If threads aren't disabled, check how possible they are
1288 unless ($disabled{threads}) {
1289     if ($auto_threads) {
1290         # Enabled by default, disable it forcibly if unavailable
1291         if ($target{thread_scheme} eq "(unknown)") {
1292             disable("unavailable", 'threads');
1293         }
1294     } else {
1295         # The user chose to enable threads explicitly, let's see
1296         # if there's a chance that's possible
1297         if ($target{thread_scheme} eq "(unknown)") {
1298             # If the user asked for "threads" and we don't have internal
1299             # knowledge how to do it, [s]he is expected to provide any
1300             # system-dependent compiler options that are necessary.  We
1301             # can't truly check that the given options are correct, but
1302             # we expect the user to know what [s]He is doing.
1303             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1304                 die "You asked for multi-threading support, but didn't\n"
1305                     ,"provide any system-specific compiler options\n";
1306             }
1307         }
1308     }
1309 }
1310
1311 # Find out if clang's sanitizers have been enabled with -fsanitize
1312 # flags and ensure that the corresponding %disabled elements area
1313 # removed to reflect that the sanitizers are indeed enabled.
1314 my %detected_sanitizers = ();
1315 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1316     (my $checks = $_) =~ s/^-fsanitize=//;
1317     foreach (split /,/, $checks) {
1318         my $d = { address       => 'asan',
1319                   undefined     => 'ubsan',
1320                   memory        => 'msan' } -> {$_};
1321         next unless defined $d;
1322
1323         $detected_sanitizers{$d} = 1;
1324         if (defined $disabled{$d}) {
1325             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1326                 if $disabled{$d} ne "default";
1327             delete $disabled{$d};
1328         }
1329     }
1330 }
1331
1332 # If threads still aren't disabled, add a C macro to ensure the source
1333 # code knows about it.  Any other flag is taken care of by the configs.
1334 unless($disabled{threads}) {
1335     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1336 }
1337
1338 my $no_shared_warn=0;
1339 if ($target{shared_target} eq "")
1340         {
1341         $no_shared_warn = 1
1342             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1343         disable('no-shared-target', 'pic');
1344         }
1345
1346 if ($disabled{"dynamic-engine"}) {
1347         $config{dynamic_engines} = 0;
1348 } else {
1349         $config{dynamic_engines} = 1;
1350 }
1351
1352 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1353     push @{$config{cflags}}, "-fsanitize=address";
1354 }
1355
1356 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1357     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1358     # platforms.
1359     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1360 }
1361
1362 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1363   push @{$config{cflags}}, "-fsanitize=memory";
1364 }
1365
1366 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1367         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1368     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1369     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1370 }
1371 #
1372 # Platform fix-ups
1373 #
1374
1375 # This saves the build files from having to check
1376 if ($disabled{pic})
1377         {
1378         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1379                     shared_defines shared_includes shared_ldflag
1380                     module_cflags module_cxxflags module_cppflags
1381                     module_defines module_includes module_lflags))
1382                 {
1383                 delete $config{$_};
1384                 $target{$_} = "";
1385                 }
1386         }
1387 else
1388         {
1389         push @{$config{lib_defines}}, "OPENSSL_PIC";
1390         }
1391
1392 if ($target{sys_id} ne "")
1393         {
1394         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1395         }
1396
1397 unless ($disabled{asm}) {
1398 }
1399
1400 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1401 my %predefined_CXX = $config{CXX}
1402     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1403     : ();
1404
1405 # Check for makedepend capabilities.
1406 if (!$disabled{makedepend}) {
1407     if ($config{target} =~ /^(VC|vms)-/) {
1408         # For VC- and vms- targets, there's nothing more to do here.  The
1409         # functionality is hard coded in the corresponding build files for
1410         # cl (Windows) and CC/DECC (VMS).
1411     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1412              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1413         # We know that GNU C version 3 and up as well as all clang
1414         # versions support dependency generation, but Xcode did not
1415         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1416         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1417     } else {
1418         # In all other cases, we look for 'makedepend', and disable the
1419         # capability if not found.
1420         $config{makedepprog} = which('makedepend');
1421         disable('unavailable', 'makedepend') unless $config{makedepprog};
1422     }
1423 }
1424
1425 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1426     # probe for -Wa,--noexecstack option...
1427     if ($predefined_C{__clang__}) {
1428         # clang has builtin assembler, which doesn't recognize --help,
1429         # but it apparently recognizes the option in question on all
1430         # supported platforms even when it's meaningless. In other words
1431         # probe would fail, but probed option always accepted...
1432         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1433     } else {
1434         my $cc = $config{CROSS_COMPILE}.$config{CC};
1435         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1436         while(<PIPE>) {
1437             if (m/--noexecstack/) {
1438                 push @{$config{cflags}}, "-Wa,--noexecstack";
1439                 last;
1440             }
1441         }
1442         close(PIPE);
1443         unlink("null.$$.o");
1444     }
1445 }
1446
1447 # Deal with bn_ops ###################################################
1448
1449 $config{bn_ll}                  =0;
1450 my $def_int="unsigned int";
1451 $config{rc4_int}                =$def_int;
1452 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1453
1454 my $count = 0;
1455 foreach (sort split(/\s+/,$target{bn_ops})) {
1456     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1457     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1458     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1459     ($config{b64l},$config{b64},$config{b32})
1460         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1461     ($config{b64l},$config{b64},$config{b32})
1462         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1463     ($config{b64l},$config{b64},$config{b32})
1464         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1465 }
1466 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1467     if $count > 1;
1468
1469 $config{api} = $config{major} * 10000 + $config{minor} * 100
1470     unless $config{api};
1471
1472 # Hack cflags for better warnings (dev option) #######################
1473
1474 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1475 # a string and works as well on command lines.
1476 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1477                         @{$config{cflags}} ];
1478 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1479                           @{$config{cxxflags}} ] if $config{CXX};
1480
1481 $config{openssl_api_defines} = [
1482     "OPENSSL_CONFIGURED_API=".$config{api}
1483 ];
1484
1485 my @strict_warnings_collection=();
1486 if ($strict_warnings)
1487         {
1488         my $wopt;
1489         my $gccver = $predefined_C{__GNUC__} // -1;
1490
1491         if ($gccver >= 4)
1492                 {
1493                 push @strict_warnings_collection, @gcc_devteam_warn;
1494                 push @strict_warnings_collection, @clang_devteam_warn
1495                     if (defined($predefined_C{__clang__}));
1496                 }
1497         elsif ($config{target} =~ /^VC-/)
1498                 {
1499                 push @strict_warnings_collection, @cl_devteam_warn;
1500                 }
1501         else
1502                 {
1503                 warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike, or MSVC"
1504                 }
1505         }
1506
1507 if (grep { $_ eq '-static' } @{$config{LDFLAGS}}) {
1508     disable('static', 'pic', 'threads');
1509 }
1510
1511 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1512                               ? @strict_warnings_collection
1513                               : ( $_ ) }
1514                     @{$config{CFLAGS}} ];
1515
1516 unless ($disabled{"crypto-mdebug-backtrace"})
1517         {
1518         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1519                 {
1520                 push @{$config{cflags}}, $wopt
1521                         unless grep { $_ eq $wopt } @{$config{cflags}};
1522                 }
1523         if ($target =~ /^BSD-/)
1524                 {
1525                 push @{$config{ex_libs}}, "-lexecinfo";
1526                 }
1527         }
1528
1529 unless ($disabled{afalgeng}) {
1530     $config{afalgeng}="";
1531     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1532         my $minver = 4*10000 + 1*100 + 0;
1533         if ($config{CROSS_COMPILE} eq "") {
1534             my $verstr = `uname -r`;
1535             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1536             ($mi2) = $mi2 =~ /(\d+)/;
1537             my $ver = $ma*10000 + $mi1*100 + $mi2;
1538             if ($ver < $minver) {
1539                 disable('too-old-kernel', 'afalgeng');
1540             } else {
1541                 push @{$config{engdirs}}, "afalg";
1542             }
1543         } else {
1544             disable('cross-compiling', 'afalgeng');
1545         }
1546     } else {
1547         disable('not-linux', 'afalgeng');
1548     }
1549 }
1550
1551 unless ($disabled{devcryptoeng}) {
1552     if ($target =~ m/^BSD/) {
1553         my $maxver = 5*100 + 7;
1554         my $sysstr = `uname -s`;
1555         my $verstr = `uname -r`;
1556         $sysstr =~ s|\R$||;
1557         $verstr =~ s|\R$||;
1558         my ($ma, $mi, @rest) = split m|\.|, $verstr;
1559         my $ver = $ma*100 + $mi;
1560         if ($sysstr eq 'OpenBSD' && $ver >= $maxver) {
1561             disable('too-new-kernel', 'devcryptoeng');
1562         }
1563     }
1564 }
1565
1566 unless ($disabled{ktls}) {
1567     $config{ktls}="";
1568     if ($target =~ m/^linux/) {
1569         my $usr = "/usr/$config{cross_compile_prefix}";
1570         chop($usr);
1571         if ($config{cross_compile_prefix} eq "") {
1572             $usr = "/usr";
1573         }
1574         my $minver = (4 << 16) + (13 << 8) + 0;
1575         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1576
1577         if ($verstr[2] < $minver) {
1578             disable('too-old-kernel', 'ktls');
1579         }
1580     } elsif ($target =~ m/^BSD/) {
1581         my $cc = $config{CROSS_COMPILE}.$config{CC};
1582         system("printf '#include <sys/types.h>\n#include <sys/ktls.h>' | $cc -E - >/dev/null 2>&1");
1583         if ($? != 0) {
1584             disable('too-old-freebsd', 'ktls');
1585         }
1586     } else {
1587         disable('not-linux-or-freebsd', 'ktls');
1588     }
1589 }
1590
1591 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1592
1593 # Get the extra flags used when building shared libraries and modules.  We
1594 # do this late because some of them depend on %disabled.
1595
1596 # Make the flags to build DSOs the same as for shared libraries unless they
1597 # are already defined
1598 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1599 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1600 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1601 {
1602     my $shared_info_pl =
1603         catfile(dirname($0), "Configurations", "shared-info.pl");
1604     my %shared_info = read_eval_file($shared_info_pl);
1605     push @{$target{_conf_fname_int}}, $shared_info_pl;
1606     my $si = $target{shared_target};
1607     while (ref $si ne "HASH") {
1608         last if ! defined $si;
1609         if (ref $si eq "CODE") {
1610             $si = $si->();
1611         } else {
1612             $si = $shared_info{$si};
1613         }
1614     }
1615
1616     # Some of the 'shared_target' values don't have any entries in
1617     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1618     # template knows how to handle this.  That is currently the case for
1619     # Windows and VMS.
1620     if (defined $si) {
1621         # Just as above, copy certain shared_* attributes to the corresponding
1622         # module_ attribute unless the latter is already defined
1623         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1624         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1625         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1626         foreach (sort keys %$si) {
1627             $target{$_} = defined $target{$_}
1628                 ? add($si->{$_})->($target{$_})
1629                 : $si->{$_};
1630         }
1631     }
1632 }
1633
1634 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1635
1636 ######################################################################
1637 # Build up information for skipping certain directories depending on disabled
1638 # features, as well as setting up macros for disabled features.
1639
1640 # This is a tentative database of directories to skip.  Some entries may not
1641 # correspond to anything real, but that's ok, they will simply be ignored.
1642 # The actual processing of these entries is done in the build.info lookup
1643 # loop further down.
1644 #
1645 # The key is a Unix formatted path in the source tree, the value is an index
1646 # into %disabled_info, so any existing path gets added to a corresponding
1647 # 'skipped' entry in there with the list of skipped directories.
1648 my %skipdir = ();
1649 my %disabled_info = ();         # For configdata.pm
1650 foreach my $what (sort keys %disabled) {
1651     # There are deprecated disablables that translate to themselves.
1652     # They cause disabling cascades, but should otherwise not regiter.
1653     next if $deprecated_disablables{$what};
1654
1655     $config{options} .= " no-$what";
1656
1657     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1658                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1659                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1660         (my $WHAT = uc $what) =~ s|-|_|g;
1661         my $skipdir = $what;
1662
1663         # fix-up crypto/directory name(s)
1664         $skipdir = "ripemd" if $what eq "rmd160";
1665         $skipdir = "whrlpool" if $what eq "whirlpool";
1666
1667         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1668         push @{$config{openssl_feature_defines}}, $macro;
1669
1670         $skipdir{engines} = $what if $what eq 'engine';
1671         $skipdir{"crypto/$skipdir"} = $what
1672             unless $what eq 'async' || $what eq 'err' || $what eq 'dso';
1673     }
1674 }
1675
1676 if ($disabled{"dynamic-engine"}) {
1677     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1678 } else {
1679     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1680 }
1681
1682 # If we use the unified build, collect information from build.info files
1683 my %unified_info = ();
1684
1685 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1686 if ($builder eq "unified") {
1687     use Text::Template 1.46;
1688
1689     sub cleandir {
1690         my $base = shift;
1691         my $dir = shift;
1692         my $relativeto = shift || ".";
1693
1694         $dir = catdir($base,$dir) unless isabsolute($dir);
1695
1696         # Make sure the directories we're building in exists
1697         mkpath($dir);
1698
1699         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1700         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1701         return $res;
1702     }
1703
1704     sub cleanfile {
1705         my $base = shift;
1706         my $file = shift;
1707         my $relativeto = shift || ".";
1708
1709         $file = catfile($base,$file) unless isabsolute($file);
1710
1711         my $d = dirname($file);
1712         my $f = basename($file);
1713
1714         # Make sure the directories we're building in exists
1715         mkpath($d);
1716
1717         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1718         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1719         return $res;
1720     }
1721
1722     # Store the name of the template file we will build the build file from
1723     # in %config.  This may be useful for the build file itself.
1724     my @build_file_template_names =
1725         ( $builder_platform."-".$target{build_file}.".tmpl",
1726           $target{build_file}.".tmpl" );
1727     my @build_file_templates = ();
1728
1729     # First, look in the user provided directory, if given
1730     if (defined env($local_config_envname)) {
1731         @build_file_templates =
1732             map {
1733                 if ($^O eq 'VMS') {
1734                     # VMS environment variables are logical names,
1735                     # which can be used as is
1736                     $local_config_envname . ':' . $_;
1737                 } else {
1738                     catfile(env($local_config_envname), $_);
1739                 }
1740             }
1741             @build_file_template_names;
1742     }
1743     # Then, look in our standard directory
1744     push @build_file_templates,
1745         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1746           @build_file_template_names );
1747
1748     my $build_file_template;
1749     for $_ (@build_file_templates) {
1750         $build_file_template = $_;
1751         last if -f $build_file_template;
1752
1753         $build_file_template = undef;
1754     }
1755     if (!defined $build_file_template) {
1756         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1757     }
1758     $config{build_file_templates}
1759       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1760                     $blddir),
1761           $build_file_template,
1762           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1763                     $blddir) ];
1764
1765     my @build_dirs = ( [ ] );   # current directory
1766
1767     $config{build_infos} = [ ];
1768
1769     my %ordinals = ();
1770     while (@build_dirs) {
1771         my @curd = @{shift @build_dirs};
1772         my $sourced = catdir($srcdir, @curd);
1773         my $buildd = catdir($blddir, @curd);
1774
1775         my $unixdir = join('/', @curd);
1776         if (exists $skipdir{$unixdir}) {
1777             my $what = $skipdir{$unixdir};
1778             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1779             next;
1780         }
1781
1782         mkpath($buildd);
1783
1784         my $f = 'build.info';
1785         # The basic things we're trying to build
1786         my @programs = ();
1787         my @libraries = ();
1788         my @modules = ();
1789         my @scripts = ();
1790
1791         my %sources = ();
1792         my %shared_sources = ();
1793         my %includes = ();
1794         my %defines = ();
1795         my %depends = ();
1796         my %generate = ();
1797         my %htmldocs = ();
1798         my %mandocs = ();
1799
1800         # Support for $variablename in build.info files.
1801         # Embedded perl code is the ultimate master, still.  If its output
1802         # contains a dollar sign, it had better be escaped, or it will be
1803         # taken for a variable name prefix.
1804         my %variables = ();
1805         my $variable_re = qr/\$(?P<VARIABLE>[[:alpha:]][[:alnum:]_]*)/;
1806         my $expand_variables = sub {
1807             my $value = '';
1808             my $value_rest = shift;
1809
1810             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1811                 print STDERR
1812                     "DEBUG[\$expand_variables] Parsed '$value_rest' into:\n"
1813             }
1814             while ($value_rest =~ /(?<!\\)${variable_re}/) {
1815                 $value .= $`;
1816                 $value .= $variables{$+{VARIABLE}};
1817                 $value_rest = $';
1818             }
1819             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1820                 print STDERR
1821                     "DEBUG[\$expand_variables] ... '$value$value_rest'\n";
1822             }
1823             return $value . $value_rest;
1824         };
1825
1826         # Support for attributes in build.info files
1827         my %attributes = ();
1828         my $handle_attributes = sub {
1829             my $attr_str = shift;
1830             my $ref = shift;
1831             my @goals = @_;
1832
1833             return unless defined $attr_str;
1834
1835             my @a = tokenize($attr_str, qr|\s*,\s*|);
1836             foreach my $a (@a) {
1837                 my $ac = 1;
1838                 my $ak = $a;
1839                 my $av = 1;
1840                 if ($a =~ m|^(!)?(.*?)\s* = \s*(.*?)$|) {
1841                     $ac = ! $1;
1842                     $ak = $1;
1843                     $av = $2;
1844                 }
1845                 foreach my $g (@goals) {
1846                     if ($ac) {
1847                         $$ref->{$g}->{$ak} = $av;
1848                     } else {
1849                         delete $$ref->{$g}->{$ak};
1850                     }
1851                 }
1852             }
1853         };
1854
1855         # We want to detect configdata.pm in the source tree, so we
1856         # don't use it if the build tree is different.
1857         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1858
1859
1860         if ($buildinfo_debug) {
1861             print STDERR "DEBUG: Reading ",catfile($sourced, $f),"\n";
1862         }
1863         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1864         my $template =
1865             Text::Template->new(TYPE => 'FILE',
1866                                 SOURCE => catfile($sourced, $f),
1867                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1868         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1869         my @text =
1870             split /^/m,
1871             $template->fill_in(HASH => { config => \%config,
1872                                          target => \%target,
1873                                          disabled => \%disabled,
1874                                          withargs => \%withargs,
1875                                          builddir => abs2rel($buildd, $blddir),
1876                                          sourcedir => abs2rel($sourced, $blddir),
1877                                          buildtop => abs2rel($blddir, $blddir),
1878                                          sourcetop => abs2rel($srcdir, $blddir) },
1879                                DELIMITERS => [ "{-", "-}" ]);
1880
1881         # The top item of this stack has the following values
1882         # -2 positive already run and we found ELSE (following ELSIF should fail)
1883         # -1 positive already run (skip until ENDIF)
1884         # 0 negatives so far (if we're at a condition, check it)
1885         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1886         # 2 positive ELSE (following ELSIF should fail)
1887         my @skip = ();
1888
1889         # A few useful generic regexps
1890         my $index_re = qr/\[\s*(?P<INDEX>(?:\\.|.)*?)\s*\]/;
1891         my $cond_re = qr/\[\s*(?P<COND>(?:\\.|.)*?)\s*\]/;
1892         my $attribs_re = qr/(?:\{\s*(?P<ATTRIBS>(?:\\.|.)*?)\s*\})?/;
1893         my $value_re = qr/\s*(?P<VALUE>.*?)\s*/;
1894         collect_information(
1895             collect_from_array([ @text ],
1896                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1897                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1898             # Info we're looking for
1899             qr/^\s* IF ${cond_re} \s*$/x
1900             => sub {
1901                 if (! @skip || $skip[$#skip] > 0) {
1902                     push @skip, !! $expand_variables->($+{COND});
1903                 } else {
1904                     push @skip, -1;
1905                 }
1906             },
1907             qr/^\s* ELSIF ${cond_re} \s*$/x
1908             => sub { die "ELSIF out of scope" if ! @skip;
1909                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1910                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1911                      $skip[$#skip] = !! $expand_variables->($+{COND})
1912                          if $skip[$#skip] == 0; },
1913             qr/^\s* ELSE \s*$/x
1914             => sub { die "ELSE out of scope" if ! @skip;
1915                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1916                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1917             qr/^\s* ENDIF \s*$/x
1918             => sub { die "ENDIF out of scope" if ! @skip;
1919                      pop @skip; },
1920             qr/^\s* ${variable_re} \s* = ${value_re} $/x
1921             => sub {
1922                 if (!@skip || $skip[$#skip] > 0) {
1923                     $variables{$+{VARIABLE}} = $expand_variables->($+{VALUE});
1924                 }
1925             },
1926             qr/^\s* SUBDIRS \s* = ${value_re} $/x
1927             => sub {
1928                 if (!@skip || $skip[$#skip] > 0) {
1929                     foreach (tokenize($expand_variables->($+{VALUE}))) {
1930                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1931                     }
1932                 }
1933             },
1934             qr/^\s* PROGRAMS ${attribs_re} \s* =  ${value_re} $/x
1935             => sub {
1936                 if (!@skip || $skip[$#skip] > 0) {
1937                     my @p = tokenize($expand_variables->($+{VALUE}));
1938                     push @programs, @p;
1939                     $handle_attributes->($+{ATTRIBS},
1940                                          \$attributes{programs},
1941                                          @p);
1942                 }
1943             },
1944             qr/^\s* LIBS ${attribs_re} \s* =  ${value_re} $/x
1945             => sub {
1946                 if (!@skip || $skip[$#skip] > 0) {
1947                     my @l = tokenize($expand_variables->($+{VALUE}));
1948                     push @libraries, @l;
1949                     $handle_attributes->($+{ATTRIBS},
1950                                          \$attributes{libraries},
1951                                          @l);
1952                 }
1953             },
1954             qr/^\s* MODULES ${attribs_re} \s* =  ${value_re} $/x
1955             => sub {
1956                 if (!@skip || $skip[$#skip] > 0) {
1957                     my @m = tokenize($expand_variables->($+{VALUE}));
1958                     push @modules, @m;
1959                     $handle_attributes->($+{ATTRIBS},
1960                                          \$attributes{modules},
1961                                          @m);
1962                 }
1963             },
1964             qr/^\s* SCRIPTS ${attribs_re} \s* =  ${value_re} $/x
1965             => sub {
1966                 if (!@skip || $skip[$#skip] > 0) {
1967                     my @s = tokenize($expand_variables->($+{VALUE}));
1968                     push @scripts, @s;
1969                     $handle_attributes->($+{ATTRIBS},
1970                                          \$attributes{scripts},
1971                                          @s);
1972                 }
1973             },
1974             qr/^\s* HTMLDOCS ${index_re} = ${value_re} $/x
1975             => sub { push @{$htmldocs{$expand_variables->($+{INDEX})}},
1976                          tokenize($expand_variables->($+{VALUE}))
1977                          if !@skip || $skip[$#skip] > 0 },
1978             qr/^\s* MANDOCS ${index_re} = ${value_re} $/x
1979             => sub { push @{$mandocs{$expand_variables->($+{INDEX})}},
1980                          tokenize($expand_variables->($+{VALUE}))
1981                          if !@skip || $skip[$#skip] > 0 },
1982             qr/^\s* ORDINALS ${index_re} = ${value_re} $/x
1983             => sub { push @{$ordinals{$expand_variables->($+{INDEX})}},
1984                          tokenize($expand_variables->($+{VALUE}))
1985                          if !@skip || $skip[$#skip] > 0 },
1986             qr/^\s* SOURCE ${index_re} = ${value_re} $/x
1987             => sub { push @{$sources{$expand_variables->($+{INDEX})}},
1988                          tokenize($expand_variables->($+{VALUE}))
1989                          if !@skip || $skip[$#skip] > 0 },
1990             qr/^\s* SHARED_SOURCE ${index_re} = ${value_re} $/x
1991             => sub { push @{$shared_sources{$expand_variables->($+{INDEX})}},
1992                          tokenize($expand_variables->($+{VALUE}))
1993                          if !@skip || $skip[$#skip] > 0 },
1994             qr/^\s* INCLUDE ${index_re} = ${value_re} $/x
1995             => sub { push @{$includes{$expand_variables->($+{INDEX})}},
1996                          tokenize($expand_variables->($+{VALUE}))
1997                          if !@skip || $skip[$#skip] > 0 },
1998             qr/^\s* DEFINE ${index_re} = ${value_re} $/x
1999             => sub { push @{$defines{$expand_variables->($+{INDEX})}},
2000                          tokenize($expand_variables->($+{VALUE}))
2001                          if !@skip || $skip[$#skip] > 0 },
2002             qr/^\s* DEPEND ${index_re} ${attribs_re} = ${value_re} $/x
2003             => sub {
2004                 if (!@skip || $skip[$#skip] > 0) {
2005                     my $i = $expand_variables->($+{INDEX});
2006                     my @d = tokenize($expand_variables->($+{VALUE}));
2007                     push @{$depends{$i}}, @d;
2008                     $handle_attributes->($+{ATTRIBS},
2009                                          \$attributes{depends}->{$i},
2010                                          @d);
2011                 }
2012             },
2013             qr/^\s* GENERATE ${index_re} = ${value_re} $/x
2014             => sub { push @{$generate{$expand_variables->($+{INDEX})}},
2015                          $+{VALUE}
2016                          if !@skip || $skip[$#skip] > 0 },
2017             qr/^\s* (?:\#.*)? $/x => sub { },
2018             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
2019             "BEFORE" => sub {
2020                 if ($buildinfo_debug) {
2021                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
2022                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2023                 }
2024             },
2025             "AFTER" => sub {
2026                 if ($buildinfo_debug) {
2027                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2028                 }
2029             },
2030             );
2031         die "runaway IF?" if (@skip);
2032
2033         if (grep { defined $attributes{modules}->{$_}->{engine} } keys %attributes
2034                 and !$config{dynamic_engines}) {
2035             die <<"EOF"
2036 ENGINES can only be used if configured with 'dynamic-engine'.
2037 This is usually a fault in a build.info file.
2038 EOF
2039         }
2040
2041         {
2042             my %infos = ( programs  => [ @programs  ],
2043                           libraries => [ @libraries ],
2044                           modules   => [ @modules   ],
2045                           scripts   => [ @scripts   ] );
2046             foreach my $k (keys %infos) {
2047                 foreach (@{$infos{$k}}) {
2048                     my $item = cleanfile($buildd, $_, $blddir);
2049                     $unified_info{$k}->{$item} = 1;
2050
2051                     # Fix up associated attributes
2052                     $unified_info{attributes}->{$k}->{$item} =
2053                         $attributes{$k}->{$_}
2054                         if defined $attributes{$k}->{$_};
2055                 }
2056             }
2057         }
2058
2059         # Check that we haven't defined any library as both shared and
2060         # explicitly static.  That is forbidden.
2061         my @doubles = ();
2062         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2063             (my $l = $_) =~ s/\.a$//;
2064             push @doubles, $l if defined $unified_info{libraries}->{$l};
2065         }
2066         die "these libraries are both explicitly static and shared:\n  ",
2067             join(" ", @doubles), "\n"
2068             if @doubles;
2069
2070         foreach (keys %sources) {
2071             my $dest = $_;
2072             my $ddest = cleanfile($buildd, $_, $blddir);
2073             foreach (@{$sources{$dest}}) {
2074                 my $s = cleanfile($sourced, $_, $blddir);
2075
2076                 # If it isn't in the source tree, we assume it's generated
2077                 # in the build tree
2078                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2079                     $s = cleanfile($buildd, $_, $blddir);
2080                 }
2081                 # We recognise C++, C and asm files
2082                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2083                     my $o = $_;
2084                     $o =~ s/\.[csS]$/.o/; # C and assembler
2085                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2086                     $o = cleanfile($buildd, $o, $blddir);
2087                     $unified_info{sources}->{$ddest}->{$o} = -1;
2088                     $unified_info{sources}->{$o}->{$s} = -1;
2089                 } elsif ($s =~ /\.rc$/) {
2090                     # We also recognise resource files
2091                     my $o = $_;
2092                     $o =~ s/\.rc$/.res/; # Resource configuration
2093                     my $o = cleanfile($buildd, $o, $blddir);
2094                     $unified_info{sources}->{$ddest}->{$o} = -1;
2095                     $unified_info{sources}->{$o}->{$s} = -1;
2096                 } else {
2097                     $unified_info{sources}->{$ddest}->{$s} = 1;
2098                 }
2099             }
2100         }
2101
2102         foreach (keys %shared_sources) {
2103             my $dest = $_;
2104             my $ddest = cleanfile($buildd, $_, $blddir);
2105             foreach (@{$shared_sources{$dest}}) {
2106                 my $s = cleanfile($sourced, $_, $blddir);
2107
2108                 # If it isn't in the source tree, we assume it's generated
2109                 # in the build tree
2110                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2111                     $s = cleanfile($buildd, $_, $blddir);
2112                 }
2113
2114                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2115                     # We recognise C++, C and asm files
2116                     my $o = $_;
2117                     $o =~ s/\.[csS]$/.o/; # C and assembler
2118                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2119                     $o = cleanfile($buildd, $o, $blddir);
2120                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2121                     $unified_info{sources}->{$o}->{$s} = -1;
2122                 } elsif ($s =~ /\.rc$/) {
2123                     # We also recognise resource files
2124                     my $o = $_;
2125                     $o =~ s/\.rc$/.res/; # Resource configuration
2126                     my $o = cleanfile($buildd, $o, $blddir);
2127                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2128                     $unified_info{sources}->{$o}->{$s} = -1;
2129                 } elsif ($s =~ /\.ld$/) {
2130                     # We also recognise linker scripts (or corresponding)
2131                     # We know they are generated files
2132                     my $ld = cleanfile($buildd, $_, $blddir);
2133                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2134                 } else {
2135                     die "unrecognised source file type for shared library: $s\n";
2136                 }
2137             }
2138         }
2139
2140         foreach (keys %generate) {
2141             my $dest = $_;
2142             my $ddest = cleanfile($buildd, $_, $blddir);
2143             die "more than one generator for $dest: "
2144                 ,join(" ", @{$generate{$_}}),"\n"
2145                 if scalar @{$generate{$_}} > 1;
2146             my @generator = split /\s+/, $generate{$dest}->[0];
2147             my $gen = $generator[0];
2148             $generator[0] = cleanfile($sourced, $gen, $blddir);
2149
2150             # If the generator isn't in the source tree, we assume it's
2151             # generated in the build tree
2152             if ($generate{$gen}) {
2153                 $generator[0] = cleanfile($buildd, $gen, $blddir);
2154             }
2155
2156             $unified_info{generate}->{$ddest} = [ @generator ];
2157         }
2158
2159         foreach (keys %depends) {
2160             my $dest = $_;
2161             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2162
2163             # If the destination doesn't exist in source, it can only be
2164             # a generated file in the build tree.
2165             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2166                 $ddest = cleanfile($buildd, $_, $blddir);
2167             }
2168             foreach (@{$depends{$dest}}) {
2169                 my $d = cleanfile($sourced, $_, $blddir);
2170
2171                 # If we know it's generated, or assume it is because we can't
2172                 # find it in the source tree, we set file we depend on to be
2173                 # in the build tree rather than the source tree, and assume
2174                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2175                 # section or in the Makefile template.
2176                 if ($d eq $src_configdata
2177                     || ! -f $d
2178                     || (grep { $d eq $_ }
2179                         map { cleanfile($srcdir, $_, $blddir) }
2180                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2181                     $d = cleanfile($buildd, $_, $blddir);
2182                 }
2183                 # Take note if the file to depend on is being renamed
2184                 # Take extra care with files ending with .a, they should
2185                 # be treated without that extension, and the extension
2186                 # should be added back after treatment.
2187                 $d =~ /(\.a)?$/;
2188                 my $e = $1 // "";
2189                 $d = $`.$e;
2190                 $unified_info{depends}->{$ddest}->{$d} = 1;
2191
2192                 # Fix up associated attributes
2193                 $unified_info{attributes}->{depends}->{$ddest}->{$d} =
2194                     $attributes{depends}->{$dest}->{$_}
2195                     if defined $attributes{depends}->{$dest}->{$_};
2196             }
2197         }
2198
2199         foreach (keys %includes) {
2200             my $dest = $_;
2201             my $ddest = cleanfile($sourced, $_, $blddir);
2202
2203             # If the destination doesn't exist in source, it can only be
2204             # a generated file in the build tree.
2205             if ($ddest eq $src_configdata || ! -f $ddest) {
2206                 $ddest = cleanfile($buildd, $_, $blddir);
2207             }
2208             foreach (@{$includes{$dest}}) {
2209                 my $is = cleandir($sourced, $_, $blddir);
2210                 my $ib = cleandir($buildd, $_, $blddir);
2211                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2212                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2213                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2214                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2215             }
2216         }
2217
2218         foreach my $dest (keys %defines) {
2219             my $ddest;
2220
2221             if ($dest ne "") {
2222                 $ddest = cleanfile($sourced, $dest, $blddir);
2223
2224                 # If the destination doesn't exist in source, it can only
2225                 # be a generated file in the build tree.
2226                 if (! -f $ddest) {
2227                     $ddest = cleanfile($buildd, $dest, $blddir);
2228                     if ($unified_info{rename}->{$ddest}) {
2229                         $ddest = $unified_info{rename}->{$ddest};
2230                     }
2231                 }
2232             }
2233             foreach my $v (@{$defines{$dest}}) {
2234                 $v =~ m|^([^=]*)(=.*)?$|;
2235                 die "0 length macro name not permitted\n" if $1 eq "";
2236                 if ($dest ne "") {
2237                     die "$1 defined more than once\n"
2238                         if defined $unified_info{defines}->{$ddest}->{$1};
2239                     $unified_info{defines}->{$ddest}->{$1} = $2;
2240                 } else {
2241                     die "$1 defined more than once\n"
2242                         if grep { $v eq $_ } @{$config{defines}};
2243                     push @{$config{defines}}, $v;
2244                 }
2245             }
2246         }
2247
2248         foreach my $section (keys %htmldocs) {
2249             foreach (@{$htmldocs{$section}}) {
2250                 my $htmldocs = cleanfile($buildd, $_, $blddir);
2251                 $unified_info{htmldocs}->{$section}->{$htmldocs} = 1;
2252             }
2253         }
2254
2255         foreach my $section (keys %mandocs) {
2256             foreach (@{$mandocs{$section}}) {
2257                 my $mandocs = cleanfile($buildd, $_, $blddir);
2258                 $unified_info{mandocs}->{$section}->{$mandocs} = 1;
2259             }
2260         }
2261     }
2262
2263     my $ordinals_text = join(', ', sort keys %ordinals);
2264     warn <<"EOF" if $ordinals_text;
2265
2266 WARNING: ORDINALS were specified for $ordinals_text
2267 They are ignored and should be replaced with a combination of GENERATE,
2268 DEPEND and SHARED_SOURCE.
2269 EOF
2270
2271
2272     # Go through the sources of all libraries and check that the same basename
2273     # doesn't appear more than once.  Some static library archivers depend on
2274     # them being unique.
2275     {
2276         my $err = 0;
2277         foreach my $prod (keys %{$unified_info{libraries}}) {
2278             my @prod_sources =
2279                 map { keys %{$unified_info{sources}->{$_}} }
2280                 keys %{$unified_info{sources}->{$prod}};
2281             my %srccnt = ();
2282
2283             # Count how many times a given each source basename
2284             # appears for each product.
2285             foreach my $src (@prod_sources) {
2286                 $srccnt{basename $src}++;
2287             }
2288
2289             foreach my $src (keys %srccnt) {
2290                 if ((my $cnt = $srccnt{$src}) > 1) {
2291                     print STDERR "$src appears $cnt times for the product $prod\n";
2292                     $err++
2293                 }
2294             }
2295         }
2296         die if $err > 0;
2297     }
2298
2299     # Massage the result
2300
2301     # If we depend on a header file or a perl module, add an inclusion of
2302     # its directory to allow smoothe inclusion
2303     foreach my $dest (keys %{$unified_info{depends}}) {
2304         next if $dest eq "";
2305         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2306             next unless $d =~ /\.(h|pm)$/;
2307             my $i = dirname($d);
2308             my $spot =
2309                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2310                 ? 'build' : 'source';
2311             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2312                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2313         }
2314     }
2315
2316     # Go through all intermediary files and change their names to something that
2317     # reflects what they will be built for.  Note that for some source files,
2318     # this leads to duplicate object files because they are used multiple times.
2319     # the goal is to rename all object files according to this scheme:
2320     #    {productname}-{midfix}-{origobjname}.[o|res]
2321     # the {midfix} is a keyword indicating the type of product, which is mostly
2322     # valuable for libraries since they come in two forms.
2323     #
2324     # This also reorganises the {sources} and {shared_sources} so that the
2325     # former only contains ALL object files that are supposed to end up in
2326     # static libraries and programs, while the latter contains ALL object files
2327     # that are supposed to end up in shared libraries and DSOs.
2328     # The main reason for having two different source structures is to allow
2329     # the same name to be used for the static and the shared variants of a
2330     # library.
2331     {
2332         # Take copies so we don't get interference from added stuff
2333         my %unified_copy = ();
2334         foreach (('sources', 'shared_sources')) {
2335             $unified_copy{$_} = { %{$unified_info{$_}} }
2336                 if defined($unified_info{$_});
2337             delete $unified_info{$_};
2338         }
2339         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2340             # $intent serves multi purposes:
2341             # - give a prefix for the new object files names
2342             # - in the case of libraries, rearrange the object files so static
2343             #   libraries use the 'sources' structure exclusively, while shared
2344             #   libraries use the 'shared_sources' structure exclusively.
2345             my $intent = {
2346                 programs  => { bin    => { src => [ 'sources' ],
2347                                            dst => 'sources' } },
2348                 libraries => { lib    => { src => [ 'sources' ],
2349                                            dst => 'sources' },
2350                                shlib  => { prodselect =>
2351                                                sub { grep !/\.a$/, @_ },
2352                                            src => [ 'sources',
2353                                                     'shared_sources' ],
2354                                            dst => 'shared_sources' } },
2355                 modules   => { dso    => { src => [ 'sources' ],
2356                                            dst => 'sources' } },
2357                 scripts   => { script => { src => [ 'sources' ],
2358                                            dst => 'sources' } }
2359                } -> {$prodtype};
2360             foreach my $kind (keys %$intent) {
2361                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2362                              && $disabled{shared});
2363
2364                 my @src = @{$intent->{$kind}->{src}};
2365                 my $dst = $intent->{$kind}->{dst};
2366                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2367                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2368                     # %prod_sources has all applicable objects as keys, and
2369                     # their corresponding sources as values
2370                     my %prod_sources =
2371                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2372                         map { keys %{$unified_copy{$_}->{$prod}} }
2373                         @src;
2374                     foreach (keys %prod_sources) {
2375                         # Only affect object files and resource files,
2376                         # the others simply get a new value
2377                         # (+1 instead of -1)
2378                         if ($_ =~ /\.(o|res)$/) {
2379                             (my $prodname = $prod) =~ s|\.a$||;
2380                             my $newobj =
2381                                 catfile(dirname($_),
2382                                         basename($prodname)
2383                                             . '-' . $kind
2384                                             . '-' . basename($_));
2385                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2386                             foreach my $src (@{$prod_sources{$_}}) {
2387                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2388                             }
2389                             # Adjust dependencies
2390                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2391                                 $unified_info{depends}->{$_}->{$deps} = -1;
2392                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2393                             }
2394                             # Adjust includes
2395                             foreach my $k (('source', 'build')) {
2396                                 next unless
2397                                     defined($unified_info{includes}->{$_}->{$k});
2398                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2399                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2400                             }
2401                         } else {
2402                             $unified_info{$dst}->{$prod}->{$_} = 1;
2403                         }
2404                     }
2405                 }
2406             }
2407         }
2408     }
2409
2410     # At this point, we have a number of sources with the value -1.  They
2411     # aren't part of the local build and are probably meant for a different
2412     # platform, and can therefore be cleaned away.  That happens when making
2413     # %unified_info more efficient below.
2414
2415     ### Make unified_info a bit more efficient
2416     # One level structures
2417     foreach (("programs", "libraries", "modules", "scripts")) {
2418         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2419     }
2420     # Two level structures
2421     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends",
2422                      "htmldocs", "mandocs")) {
2423         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2424             my @items =
2425                 sort
2426                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2427                 keys %{$unified_info{$l1}->{$l2}};
2428             if (@items) {
2429                 $unified_info{$l1}->{$l2} = [ @items ];
2430             } else {
2431                 delete $unified_info{$l1}->{$l2};
2432             }
2433         }
2434     }
2435     # Defines
2436     foreach my $dest (sort keys %{$unified_info{defines}}) {
2437         $unified_info{defines}->{$dest}
2438             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2439                 sort keys %{$unified_info{defines}->{$dest}} ];
2440     }
2441     # Includes
2442     foreach my $dest (sort keys %{$unified_info{includes}}) {
2443         if (defined($unified_info{includes}->{$dest}->{build})) {
2444             my @source_includes = ();
2445             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2446                 if defined($unified_info{includes}->{$dest}->{source});
2447             $unified_info{includes}->{$dest} =
2448                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2449             foreach my $inc (@source_includes) {
2450                 push @{$unified_info{includes}->{$dest}}, $inc
2451                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2452             }
2453         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2454             $unified_info{includes}->{$dest} =
2455                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2456         } else {
2457             delete $unified_info{includes}->{$dest};
2458         }
2459     }
2460
2461     # For convenience collect information regarding directories where
2462     # files are generated, those generated files and the end product
2463     # they end up in where applicable.  Then, add build rules for those
2464     # directories
2465     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2466                      "dso" => [ @{$unified_info{modules}} ],
2467                      "bin" => [ @{$unified_info{programs}} ],
2468                      "script" => [ @{$unified_info{scripts}} ],
2469                      "docs" => [ (map { @{$unified_info{htmldocs}->{$_} // []} }
2470                                   keys %{$unified_info{htmldocs} // {}}),
2471                                  (map { @{$unified_info{mandocs}->{$_} // []} }
2472                                   keys %{$unified_info{mandocs} // {}}) ] );
2473     foreach my $type (keys %loopinfo) {
2474         foreach my $product (@{$loopinfo{$type}}) {
2475             my %dirs = ();
2476             my $pd = dirname($product);
2477
2478             foreach (@{$unified_info{sources}->{$product} // []},
2479                      @{$unified_info{shared_sources}->{$product} // []}) {
2480                 my $d = dirname($_);
2481
2482                 # We don't want to create targets for source directories
2483                 # when building out of source
2484                 next if ($config{sourcedir} ne $config{builddir}
2485                              && $d =~ m|^\Q$config{sourcedir}\E|);
2486                 # We already have a "test" target, and the current directory
2487                 # is just silly to make a target for
2488                 next if $d eq "test" || $d eq ".";
2489
2490                 $dirs{$d} = 1;
2491                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2492                     if $d ne $pd;
2493             }
2494             foreach (keys %dirs) {
2495                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2496                     $product;
2497             }
2498         }
2499     }
2500 }
2501
2502 # For the schemes that need it, we provide the old *_obj configs
2503 # from the *_asm_obj ones
2504 foreach (grep /_(asm|aux)_src$/, keys %target) {
2505     my $src = $_;
2506     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2507     $target{$obj} = $target{$src};
2508     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2509     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2510 }
2511
2512 # Write down our configuration where it fits #########################
2513
2514 my %template_vars = (
2515     config => \%config,
2516     target => \%target,
2517     disablables => \@disablables,
2518     disablables_int => \@disablables_int,
2519     disabled => \%disabled,
2520     withargs => \%withargs,
2521     unified_info => \%unified_info,
2522     tls => \@tls,
2523     dtls => \@dtls,
2524     makevars => [ sort keys %user ],
2525     disabled_info => \%disabled_info,
2526     user_crossable => \@user_crossable,
2527 );
2528 my $configdata_outname = 'configdata.pm';
2529 print "Creating $configdata_outname\n";
2530 open CONFIGDATA, ">$configdata_outname.new"
2531             or die "Trying to create $configdata_outname.new: $!";
2532 my $configdata_tmplname = cleanfile($srcdir, "configdata.pm.in", $blddir);
2533 my $configdata_tmpl =
2534     OpenSSL::Template->new(TYPE => 'FILE', SOURCE => $configdata_tmplname);
2535 $configdata_tmpl->fill_in(
2536     FILENAME => $configdata_tmplname,
2537     OUTPUT => \*CONFIGDATA,
2538     HASH => { %template_vars,
2539               autowarntext => [
2540                   'WARNING: do not edit!',
2541                   "Generated by Configure from $configdata_tmplname",
2542               ] }
2543 ) or die $Text::Template::ERROR;
2544 close CONFIGDATA;
2545 rename "$configdata_outname.new", $configdata_outname;
2546 if ($builder_platform eq 'unix') {
2547     my $mode = (0755 & ~umask);
2548     chmod $mode, 'configdata.pm'
2549         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2550 }
2551
2552 print "Running $configdata_outname\n";
2553 my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
2554 my $cmd = "$perlcmd $configdata_outname";
2555 #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2556 system($cmd);
2557 exit 1 if $? != 0;
2558
2559 $SIG{__DIE__} = $orig_death_handler;
2560
2561 print <<"EOF" if ($disabled{threads} eq "unavailable");
2562
2563 The library could not be configured for supporting multi-threaded
2564 applications as the compiler options required on this system are not known.
2565 See file INSTALL for details if you need multi-threading.
2566 EOF
2567
2568 print <<"EOF" if ($no_shared_warn);
2569
2570 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2571 platform, so we will pretend you gave the option 'no-pic', which also disables
2572 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2573 or position independent code, please let us know (but please first make sure
2574 you have tried with a current version of OpenSSL).
2575 EOF
2576
2577 print <<"EOF";
2578
2579 **********************************************************************
2580 ***                                                                ***
2581 ***   OpenSSL has been successfully configured                     ***
2582 ***                                                                ***
2583 ***   If you encounter a problem while building, please open an    ***
2584 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2585 ***   and include the output from the following command:           ***
2586 ***                                                                ***
2587 ***       perl configdata.pm --dump                                ***
2588 ***                                                                ***
2589 ***   (If you are new to OpenSSL, you might want to consult the    ***
2590 ***   'Troubleshooting' section in the INSTALL file first)         ***
2591 ***                                                                ***
2592 **********************************************************************
2593 EOF
2594
2595 exit(0);
2596
2597 ######################################################################
2598 #
2599 # Helpers and utility functions
2600 #
2601
2602 # Death handler, to print a helpful message in case of failure #######
2603 #
2604 sub death_handler {
2605     die @_ if $^S;              # To prevent the added message in eval blocks
2606     my $build_file = $target{build_file} // "build file";
2607     my @message = ( <<"_____", @_ );
2608
2609 Failure!  $build_file wasn't produced.
2610 Please read INSTALL and associated NOTES files.  You may also have to look over
2611 your available compiler tool chain or change your configuration.
2612
2613 _____
2614
2615     # Dying is terminal, so it's ok to reset the signal handler here.
2616     $SIG{__DIE__} = $orig_death_handler;
2617     die @message;
2618 }
2619
2620 # Configuration file reading #########################################
2621
2622 # Note: All of the helper functions are for lazy evaluation.  They all
2623 # return a CODE ref, which will return the intended value when evaluated.
2624 # Thus, whenever there's mention of a returned value, it's about that
2625 # intended value.
2626
2627 # Helper function to implement conditional value variants, with a default
2628 # plus additional values based on the value of $config{build_type}.
2629 # Arguments are given in hash table form:
2630 #
2631 #       picker(default => "Basic string: ",
2632 #              debug   => "debug",
2633 #              release => "release")
2634 #
2635 # When configuring with --debug, the resulting string will be
2636 # "Basic string: debug", and when not, it will be "Basic string: release"
2637 #
2638 # This can be used to create variants of sets of flags according to the
2639 # build type:
2640 #
2641 #       cflags => picker(default => "-Wall",
2642 #                        debug   => "-g -O0",
2643 #                        release => "-O3")
2644 #
2645 sub picker {
2646     my %opts = @_;
2647     return sub { add($opts{default} || (),
2648                      $opts{$config{build_type}} || ())->(); }
2649 }
2650
2651 # Helper function to combine several values of different types into one.
2652 # This is useful if you want to combine a string with the result of a
2653 # lazy function, such as:
2654 #
2655 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2656 #
2657 sub combine {
2658     my @stuff = @_;
2659     return sub { add(@stuff)->(); }
2660 }
2661
2662 # Helper function to implement conditional values depending on the value
2663 # of $disabled{threads}.  Can be used as follows:
2664 #
2665 #       cflags => combine("-Wall", threads("-pthread"))
2666 #
2667 sub threads {
2668     my @flags = @_;
2669     return sub { add($disabled{threads} ? () : @flags)->(); }
2670 }
2671
2672 sub shared {
2673     my @flags = @_;
2674     return sub { add($disabled{shared} ? () : @flags)->(); }
2675 }
2676
2677 our $add_called = 0;
2678 # Helper function to implement adding values to already existing configuration
2679 # values.  It handles elements that are ARRAYs, CODEs and scalars
2680 sub _add {
2681     my $separator = shift;
2682
2683     # If there's any ARRAY in the collection of values OR the separator
2684     # is undef, we will return an ARRAY of combined values, otherwise a
2685     # string of joined values with $separator as the separator.
2686     my $found_array = !defined($separator);
2687
2688     my @values =
2689         map {
2690             my $res = $_;
2691             while (ref($res) eq "CODE") {
2692                 $res = $res->();
2693             }
2694             if (defined($res)) {
2695                 if (ref($res) eq "ARRAY") {
2696                     $found_array = 1;
2697                     @$res;
2698                 } else {
2699                     $res;
2700                 }
2701             } else {
2702                 ();
2703             }
2704     } (@_);
2705
2706     $add_called = 1;
2707
2708     if ($found_array) {
2709         [ @values ];
2710     } else {
2711         join($separator, grep { defined($_) && $_ ne "" } @values);
2712     }
2713 }
2714 sub add_before {
2715     my $separator = " ";
2716     if (ref($_[$#_]) eq "HASH") {
2717         my $opts = pop;
2718         $separator = $opts->{separator};
2719     }
2720     my @x = @_;
2721     sub { _add($separator, @x, @_) };
2722 }
2723 sub add {
2724     my $separator = " ";
2725     if (ref($_[$#_]) eq "HASH") {
2726         my $opts = pop;
2727         $separator = $opts->{separator};
2728     }
2729     my @x = @_;
2730     sub { _add($separator, @_, @x) };
2731 }
2732
2733 sub read_eval_file {
2734     my $fname = shift;
2735     my $content;
2736     my @result;
2737
2738     open F, "< $fname" or die "Can't open '$fname': $!\n";
2739     {
2740         undef local $/;
2741         $content = <F>;
2742     }
2743     close F;
2744     {
2745         local $@;
2746
2747         @result = ( eval $content );
2748         warn $@ if $@;
2749     }
2750     return wantarray ? @result : $result[0];
2751 }
2752
2753 # configuration reader, evaluates the input file as a perl script and expects
2754 # it to fill %targets with target configurations.  Those are then added to
2755 # %table.
2756 sub read_config {
2757     my $fname = shift;
2758     my %targets;
2759
2760     {
2761         # Protect certain tables from tampering
2762         local %table = ();
2763
2764         %targets = read_eval_file($fname);
2765     }
2766     my %preexisting = ();
2767     foreach (sort keys %targets) {
2768         $preexisting{$_} = 1 if $table{$_};
2769     }
2770     die <<"EOF",
2771 The following config targets from $fname
2772 shadow pre-existing config targets with the same name:
2773 EOF
2774         map { "  $_\n" } sort keys %preexisting
2775         if %preexisting;
2776
2777
2778     # For each target, check that it's configured with a hash table.
2779     foreach (keys %targets) {
2780         if (ref($targets{$_}) ne "HASH") {
2781             if (ref($targets{$_}) eq "") {
2782                 warn "Deprecated target configuration for $_, ignoring...\n";
2783             } else {
2784                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2785             }
2786             delete $targets{$_};
2787         } else {
2788             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
2789         }
2790     }
2791
2792     %table = (%table, %targets);
2793
2794 }
2795
2796 # configuration resolver.  Will only resolve all the lazy evaluation
2797 # codeblocks for the chosen target and all those it inherits from,
2798 # recursively
2799 sub resolve_config {
2800     my $target = shift;
2801     my @breadcrumbs = @_;
2802
2803 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2804
2805     if (grep { $_ eq $target } @breadcrumbs) {
2806         die "inherit_from loop!  target backtrace:\n  "
2807             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2808     }
2809
2810     if (!defined($table{$target})) {
2811         warn "Warning! target $target doesn't exist!\n";
2812         return ();
2813     }
2814     # Recurse through all inheritances.  They will be resolved on the
2815     # fly, so when this operation is done, they will all just be a
2816     # bunch of attributes with string values.
2817     # What we get here, though, are keys with references to lists of
2818     # the combined values of them all.  We will deal with lists after
2819     # this stage is done.
2820     my %combined_inheritance = ();
2821     if ($table{$target}->{inherit_from}) {
2822         my @inherit_from =
2823             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2824         foreach (@inherit_from) {
2825             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2826
2827             # 'template' is a marker that's considered private to
2828             # the config that had it.
2829             delete $inherited_config{template};
2830
2831             foreach (keys %inherited_config) {
2832                 if (!$combined_inheritance{$_}) {
2833                     $combined_inheritance{$_} = [];
2834                 }
2835                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2836             }
2837         }
2838     }
2839
2840     # We won't need inherit_from in this target any more, since we've
2841     # resolved all the inheritances that lead to this
2842     delete $table{$target}->{inherit_from};
2843
2844     # Now is the time to deal with those lists.  Here's the place to
2845     # decide what shall be done with those lists, all based on the
2846     # values of the target we're currently dealing with.
2847     # - If a value is a coderef, it will be executed with the list of
2848     #   inherited values as arguments.
2849     # - If the corresponding key doesn't have a value at all or is the
2850     #   empty string, the inherited value list will be run through the
2851     #   default combiner (below), and the result becomes this target's
2852     #   value.
2853     # - Otherwise, this target's value is assumed to be a string that
2854     #   will simply override the inherited list of values.
2855     my $default_combiner = add();
2856
2857     my %all_keys =
2858         map { $_ => 1 } (keys %combined_inheritance,
2859                          keys %{$table{$target}});
2860
2861     sub process_values {
2862         my $object    = shift;
2863         my $inherited = shift;  # Always a [ list ]
2864         my $target    = shift;
2865         my $entry     = shift;
2866
2867         $add_called = 0;
2868
2869         while(ref($object) eq "CODE") {
2870             $object = $object->(@$inherited);
2871         }
2872         if (!defined($object)) {
2873             return ();
2874         }
2875         elsif (ref($object) eq "ARRAY") {
2876             local $add_called;  # To make sure recursive calls don't affect it
2877             return [ map { process_values($_, $inherited, $target, $entry) }
2878                      @$object ];
2879         } elsif (ref($object) eq "") {
2880             return $object;
2881         } else {
2882             die "cannot handle reference type ",ref($object)
2883                 ," found in target ",$target," -> ",$entry,"\n";
2884         }
2885     }
2886
2887     foreach (sort keys %all_keys) {
2888         my $previous = $combined_inheritance{$_};
2889
2890         # Current target doesn't have a value for the current key?
2891         # Assign it the default combiner, the rest of this loop body
2892         # will handle it just like any other coderef.
2893         if (!exists $table{$target}->{$_}) {
2894             $table{$target}->{$_} = $default_combiner;
2895         }
2896
2897         $table{$target}->{$_} = process_values($table{$target}->{$_},
2898                                                $combined_inheritance{$_},
2899                                                $target, $_);
2900         unless(defined($table{$target}->{$_})) {
2901             delete $table{$target}->{$_};
2902         }
2903 #        if ($extra_checks &&
2904 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2905 #            warn "$_ got replaced in $target\n";
2906 #        }
2907     }
2908
2909     # Finally done, return the result.
2910     return %{$table{$target}};
2911 }
2912
2913 sub usage
2914         {
2915         print STDERR $usage;
2916         print STDERR "\npick os/compiler from:\n";
2917         my $j=0;
2918         my $i;
2919         my $k=0;
2920         foreach $i (sort keys %table)
2921                 {
2922                 next if $table{$i}->{template};
2923                 next if $i =~ /^debug/;
2924                 $k += length($i) + 1;
2925                 if ($k > 78)
2926                         {
2927                         print STDERR "\n";
2928                         $k=length($i);
2929                         }
2930                 print STDERR $i . " ";
2931                 }
2932         foreach $i (sort keys %table)
2933                 {
2934                 next if $table{$i}->{template};
2935                 next if $i !~ /^debug/;
2936                 $k += length($i) + 1;
2937                 if ($k > 78)
2938                         {
2939                         print STDERR "\n";
2940                         $k=length($i);
2941                         }
2942                 print STDERR $i . " ";
2943                 }
2944         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2945         exit(1);
2946         }
2947
2948 sub compiler_predefined {
2949     state %predefined;
2950     my $cc = shift;
2951
2952     return () if $^O eq 'VMS';
2953
2954     die 'compiler_predefined called without a compiler command'
2955         unless $cc;
2956
2957     if (! $predefined{$cc}) {
2958
2959         $predefined{$cc} = {};
2960
2961         # collect compiler pre-defines from gcc or gcc-alike...
2962         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
2963         while (my $l = <PIPE>) {
2964             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
2965             $predefined{$cc}->{$1} = $2 // '';
2966         }
2967         close(PIPE);
2968     }
2969
2970     return %{$predefined{$cc}};
2971 }
2972
2973 sub which
2974 {
2975     my ($name)=@_;
2976
2977     if (eval { require IPC::Cmd; 1; }) {
2978         IPC::Cmd->import();
2979         return scalar IPC::Cmd::can_run($name);
2980     } else {
2981         # if there is $directories component in splitpath,
2982         # then it's not something to test with $PATH...
2983         return $name if (File::Spec->splitpath($name))[1];
2984
2985         foreach (File::Spec->path()) {
2986             my $fullpath = catfile($_, "$name$target{exe_extension}");
2987             if (-f $fullpath and -x $fullpath) {
2988                 return $fullpath;
2989             }
2990         }
2991     }
2992 }
2993
2994 sub env
2995 {
2996     my $name = shift;
2997     my %opts = @_;
2998
2999     unless ($opts{cacheonly}) {
3000         # Note that if $ENV{$name} doesn't exist or is undefined,
3001         # $config{perlenv}->{$name} will be created with the value
3002         # undef.  This is intentional.
3003
3004         $config{perlenv}->{$name} = $ENV{$name}
3005             if ! exists $config{perlenv}->{$name};
3006     }
3007     return $config{perlenv}->{$name};
3008 }
3009
3010 # Configuration printer ##############################################
3011
3012 sub print_table_entry
3013 {
3014     local $now_printing = shift;
3015     my %target = resolve_config($now_printing);
3016     my $type = shift;
3017
3018     # Don't print the templates
3019     return if $target{template};
3020
3021     my @sequence = (
3022         "sys_id",
3023         "cpp",
3024         "cppflags",
3025         "defines",
3026         "includes",
3027         "cc",
3028         "cflags",
3029         "ld",
3030         "lflags",
3031         "loutflag",
3032         "ex_libs",
3033         "bn_ops",
3034         "poly1035_asm_src",
3035         "thread_scheme",
3036         "perlasm_scheme",
3037         "dso_scheme",
3038         "shared_target",
3039         "shared_cflag",
3040         "shared_defines",
3041         "shared_ldflag",
3042         "shared_rcflag",
3043         "shared_extension",
3044         "dso_extension",
3045         "obj_extension",
3046         "exe_extension",
3047         "ranlib",
3048         "ar",
3049         "arflags",
3050         "aroutflag",
3051         "rc",
3052         "rcflags",
3053         "rcoutflag",
3054         "mt",
3055         "mtflags",
3056         "mtinflag",
3057         "mtoutflag",
3058         "multilib",
3059         "build_scheme",
3060         );
3061
3062     if ($type eq "TABLE") {
3063         print "\n";
3064         print "*** $now_printing\n";
3065         foreach (@sequence) {
3066             if (ref($target{$_}) eq "ARRAY") {
3067                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3068             } else {
3069                 printf "\$%-12s = %s\n", $_, $target{$_};
3070             }
3071         }
3072     } elsif ($type eq "HASH") {
3073         my $largest =
3074             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3075         print "    '$now_printing' => {\n";
3076         foreach (@sequence) {
3077             if ($target{$_}) {
3078                 if (ref($target{$_}) eq "ARRAY") {
3079                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3080                 } else {
3081                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3082                 }
3083             }
3084         }
3085         print "    },\n";
3086     }
3087 }
3088
3089 # Utility routines ###################################################
3090
3091 # On VMS, if the given file is a logical name, File::Spec::Functions
3092 # will consider it an absolute path.  There are cases when we want a
3093 # purely syntactic check without checking the environment.
3094 sub isabsolute {
3095     my $file = shift;
3096
3097     # On non-platforms, we just use file_name_is_absolute().
3098     return file_name_is_absolute($file) unless $^O eq "VMS";
3099
3100     # If the file spec includes a device or a directory spec,
3101     # file_name_is_absolute() is perfectly safe.
3102     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3103
3104     # Here, we know the given file spec isn't absolute
3105     return 0;
3106 }
3107
3108 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3109 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3110 # realpath() requires that at least all path components except the last is an
3111 # existing directory.  On VMS, the last component of the directory spec must
3112 # exist.
3113 sub absolutedir {
3114     my $dir = shift;
3115
3116     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3117     # will return the volume name for the device, no matter what.  Also,
3118     # it will return an incorrect directory spec if the argument is a
3119     # directory that doesn't exist.
3120     if ($^O eq "VMS") {
3121         return rel2abs($dir);
3122     }
3123
3124     # We use realpath() on Unix, since no other will properly clean out
3125     # a directory spec.
3126     use Cwd qw/realpath/;
3127
3128     return realpath($dir);
3129 }
3130
3131 sub quotify {
3132     my %processors = (
3133         perl    => sub { my $x = shift;
3134                          $x =~ s/([\\\$\@"])/\\$1/g;
3135                          return '"'.$x.'"'; },
3136         maybeshell => sub { my $x = shift;
3137                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3138                             if ($x ne $y || $x =~ m|\s|) {
3139                                 return '"'.$y.'"';
3140                             } else {
3141                                 return $x;
3142                             }
3143                         },
3144         );
3145     my $for = shift;
3146     my $processor =
3147         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3148
3149     return map { $processor->($_); } @_;
3150 }
3151
3152 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3153 # $filename is a file name to read from
3154 # $line_concat_cond_re is a regexp detecting a line continuation ending
3155 # $line_concat is a CODEref that takes care of concatenating two lines
3156 sub collect_from_file {
3157     my $filename = shift;
3158     my $line_concat_cond_re = shift;
3159     my $line_concat = shift;
3160
3161     open my $fh, $filename || die "unable to read $filename: $!\n";
3162     return sub {
3163         my $saved_line = "";
3164         $_ = "";
3165         while (<$fh>) {
3166             s|\R$||;
3167             if (defined $line_concat) {
3168                 $_ = $line_concat->($saved_line, $_);
3169                 $saved_line = "";
3170             }
3171             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3172                 $saved_line = $_;
3173                 next;
3174             }
3175             return $_;
3176         }
3177         die "$filename ending with continuation line\n" if $_;
3178         close $fh;
3179         return undef;
3180     }
3181 }
3182
3183 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3184 # $array is an ARRAYref of lines
3185 # $line_concat_cond_re is a regexp detecting a line continuation ending
3186 # $line_concat is a CODEref that takes care of concatenating two lines
3187 sub collect_from_array {
3188     my $array = shift;
3189     my $line_concat_cond_re = shift;
3190     my $line_concat = shift;
3191     my @array = (@$array);
3192
3193     return sub {
3194         my $saved_line = "";
3195         $_ = "";
3196         while (defined($_ = shift @array)) {
3197             s|\R$||;
3198             if (defined $line_concat) {
3199                 $_ = $line_concat->($saved_line, $_);
3200                 $saved_line = "";
3201             }
3202             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3203                 $saved_line = $_;
3204                 next;
3205             }
3206             return $_;
3207         }
3208         die "input text ending with continuation line\n" if $_;
3209         return undef;
3210     }
3211 }
3212
3213 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3214 # $lineiterator is a CODEref that delivers one line at a time.
3215 # All following arguments are regex/CODEref pairs, where the regexp detects a
3216 # line and the CODEref does something with the result of the regexp.
3217 sub collect_information {
3218     my $lineiterator = shift;
3219     my %collectors = @_;
3220
3221     while(defined($_ = $lineiterator->())) {
3222         s|\R$||;
3223         my $found = 0;
3224         if ($collectors{"BEFORE"}) {
3225             $collectors{"BEFORE"}->($_);
3226         }
3227         foreach my $re (keys %collectors) {
3228             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3229                 $collectors{$re}->($lineiterator);
3230                 $found = 1;
3231             };
3232         }
3233         if ($collectors{"OTHERWISE"}) {
3234             $collectors{"OTHERWISE"}->($lineiterator, $_)
3235                 unless $found || !defined $collectors{"OTHERWISE"};
3236         }
3237         if ($collectors{"AFTER"}) {
3238             $collectors{"AFTER"}->($_);
3239         }
3240     }
3241 }
3242
3243 # tokenize($line)
3244 # tokenize($line,$separator)
3245 # $line is a line of text to split up into tokens
3246 # $separator [optional] is a regular expression that separates the tokens,
3247 # the default being spaces.  Do not use quotes of any kind as separators,
3248 # that will give undefined results.
3249 # Returns a list of tokens.
3250 #
3251 # Tokens are divided by separator (spaces by default).  If the tokens include
3252 # the separators, they have to be quoted with single or double quotes.
3253 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3254 # with backslash.
3255 # Basically, the same quoting rules apply for " and ' as in any
3256 # Unix shell.
3257 sub tokenize {
3258     my $line = my $debug_line = shift;
3259     my $separator = shift // qr|\s+|;
3260     my @result = ();
3261
3262     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3263         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3264     }
3265
3266     while ($line =~ s|^${separator}||, $line ne "") {
3267         my $token = "";
3268     again:
3269         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3270         $token .= $1;
3271         $line = $2.$';
3272
3273         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3274             $token .= $1;
3275             $line = $';
3276             goto again;
3277         } elsif ($line =~ m/^'([^']*)'/) {
3278             $token .= $1;
3279             $line = $';
3280             goto again;
3281         }
3282         push @result, $token;
3283     }
3284
3285     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3286         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3287         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3288     }
3289     return @result;
3290 }