+# Collect all POD files, both internal and public, and regardless of location
+# We collect them in a hash table with each file being a key, so we can attach
+# tags to them. For example, internal docs will have the word "internal"
+# attached to them.
+my %files = ();
+# We collect files names on the fly, on known tag basis
+my %collected_tags = ();
+# We cache results based on tags
+my %collected_results = ();
+
+# files OPTIONS
+#
+# Example:
+#
+# files(TAGS => 'manual');
+# files(TAGS => [ 'manual', 'man1' ]);
+#
+# This function returns an array of files corresponding to a set of tags
+# given with the options "TAGS". The value of this option can be a single
+# word, or an array of several words, which work as inclusive or exclusive
+# selectors. Inclusive selectors are used to add one more set of files to
+# the returned array, while exclusive selectors limit the set of files added
+# to the array. The recognised tag values are:
+#
+# 'public_manual' - inclusive selector, adds public manuals to the
+# returned array of files.
+# 'internal_manual' - inclusive selector, adds internal manuals to the
+# returned array of files.
+# 'manual' - inclusive selector, adds any manual to the returned
+# array of files. This is really a shorthand for
+# 'public_manual' and 'internal_manual' combined.
+# 'public_header' - inclusive selector, adds public headers to the
+# returned array of files.
+# 'header' - inclusive selector, adds any header file to the
+# returned array of files. Since we currently only
+# care about public headers, this is exactly
+# equivalent to 'public_header', but is present for
+# consistency.
+#
+# 'man1', 'man3', 'man5', 'man7'
+# - exclusive selectors, only applicable together with
+# any of the manual selectors. If any of these are
+# present, only the manuals from the given sections
+# will be include. If none of these are present,
+# the manuals from all sections will be returned.
+#
+# All returned manual files come from configdata.pm.
+# All returned header files come from looking inside
+# "$config{sourcedir}/include/openssl"
+#
+sub files {
+ my %opts = ( @_ ); # Make a copy of the arguments
+
+ $opts{TAGS} = [ $opts{TAGS} ] if ref($opts{TAGS}) eq '';
+
+ croak "No tags given, or not an array"
+ unless exists $opts{TAGS} && ref($opts{TAGS}) eq 'ARRAY';
+
+ my %tags = map { $_ => 1 } @{$opts{TAGS}};
+ $tags{public_manual} = 1
+ if $tags{manual} && ($tags{public} // !$tags{internal});
+ $tags{internal_manual} = 1
+ if $tags{manual} && ($tags{internal} // !$tags{public});
+ $tags{public_header} = 1
+ if $tags{header} && ($tags{public} // !$tags{internal});
+ delete $tags{manual};
+ delete $tags{header};
+ delete $tags{public};
+ delete $tags{internal};
+
+ my $tags_as_key = join(':', sort keys %tags);
+
+ cluck "DEBUG[files]: This is how we got here!" if $debug;
+ print STDERR "DEBUG[files]: tags: $tags_as_key\n" if $debug;
+
+ my %tags_to_collect = ( map { $_ => 1 }
+ grep { !exists $collected_tags{$_} }
+ keys %tags );
+
+ if ($tags_to_collect{public_manual}) {
+ print STDERR "DEBUG[files]: collecting public manuals\n"
+ if $debug;
+
+ # The structure in configdata.pm is that $unified_info{mandocs}
+ # contains lists of man files, and in turn, $unified_info{depends}
+ # contains hash tables showing which POD file each of those man
+ # files depend on. We use that information to find the POD files,
+ # and to attach the man section they belong to as tags
+ foreach my $mansect ( @sections ) {
+ foreach ( map { @{$unified_info{depends}->{$_}} }
+ @{$unified_info{mandocs}->{$mansect}} ) {
+ $files{$_} = { $mansect => 1, public_manual => 1 };
+ }
+ }
+ $collected_tags{public_manual} = 1;
+ }
+
+ if ($tags_to_collect{internal_manual}) {
+ print STDERR "DEBUG[files]: collecting internal manuals\n"
+ if $debug;
+
+ # We don't have the internal docs in configdata.pm. However, they
+ # are all in the source tree, so they're easy to find.
+ foreach my $mansect ( @sections ) {
+ foreach ( glob(catfile($config{sourcedir},
+ 'doc', 'internal', $mansect, '*.pod')) ) {
+ $files{$_} = { $mansect => 1, internal_manual => 1 };
+ }
+ }
+ $collected_tags{internal_manual} = 1;
+ }
+
+ if ($tags_to_collect{public_header}) {
+ print STDERR "DEBUG[files]: collecting public headers\n"
+ if $debug;
+
+ foreach ( glob(catfile($config{sourcedir},
+ 'include', 'openssl', '*.h')) ) {
+ $files{$_} = { public_header => 1 };
+ }
+ }
+
+ my @result = @{$collected_results{$tags_as_key} // []};
+
+ if (!@result) {
+ # Produce a result based on caller tags
+ foreach my $type ( ( 'public_manual', 'internal_manual' ) ) {
+ next unless $tags{$type};
+
+ # If caller asked for specific sections, we care about sections.
+ # Otherwise, we give back all of them.
+ my @selected_sections =
+ grep { $tags{$_} } @sections;
+ @selected_sections = @sections unless @selected_sections;
+
+ foreach my $section ( ( @selected_sections ) ) {
+ push @result,
+ ( sort { basename($a) cmp basename($b) }
+ grep { $files{$_}->{$type} && $files{$_}->{$section} }
+ keys %files );
+ }
+ }
+ if ($tags{public_header}) {
+ push @result,
+ ( sort { basename($a) cmp basename($b) }
+ grep { $files{$_}->{public_header} }
+ keys %files );
+ }
+
+ if ($debug) {
+ print STDERR "DEBUG[files]: result:\n";
+ print STDERR "DEBUG[files]: $_\n" foreach @result;
+ }
+ $collected_results{$tags_as_key} = [ @result ];
+ }
+
+ return @result;
+}
projects / openssl.git / commitdiff