6d8b7144dfac31eb1e5d953ceaec8f5eda37b9b1
[openssl.git] / util / find-doc-nits
1 #! /usr/bin/env perl
2 # Copyright 2002-2020 The OpenSSL Project Authors. All Rights Reserved.
3 #
4 # Licensed under the Apache License 2.0 (the "License").  You may not use
5 # this file except in compliance with the License.  You can obtain a copy
6 # in the file LICENSE in the source distribution or at
7 # https://www.openssl.org/source/license.html
8
9
10 require 5.10.0;
11 use warnings;
12 use strict;
13
14 use Carp qw(:DEFAULT cluck);
15 use Pod::Checker;
16 use File::Find;
17 use File::Basename;
18 use File::Spec::Functions;
19 use Getopt::Std;
20 use FindBin;
21 use lib "$FindBin::Bin/perl";
22
23 use OpenSSL::Util::Pod;
24
25 use lib '.';
26 use configdata;
27
28 # Set to 1 for debug output
29 my $debug = 0;
30
31 # Where to find openssl command
32 my $openssl = "./util/opensslwrap.sh";
33
34 # Options.
35 our($opt_d);
36 our($opt_e);
37 our($opt_s);
38 our($opt_o);
39 our($opt_h);
40 our($opt_l);
41 our($opt_n);
42 our($opt_p);
43 our($opt_u);
44 our($opt_v);
45 our($opt_c);
46
47 # Print usage message and exit.
48 sub help {
49     print <<EOF;
50 Find small errors (nits) in documentation.  Options:
51     -c List undocumented commands and options
52     -d Detailed list of undocumented (implies -u)
53     -e Detailed list of new undocumented (implies -v)
54     -h Print this help message
55     -l Print bogus links
56     -n Print nits in POD pages
57     -o Causes -e/-v to count symbols added since 1.1.1 as new (implies -v)
58     -u Count undocumented functions
59     -v Count new undocumented functions
60 EOF
61     exit;
62 }
63
64 getopts('cdehlnouv');
65
66 help() if $opt_h;
67 $opt_u = 1 if $opt_d;
68 $opt_v = 1 if $opt_o || $opt_e;
69 die "Cannot use both -u and -v"
70     if $opt_u && $opt_v;
71 die "Cannot use both -d and -e"
72     if $opt_d && $opt_e;
73
74 # We only need to check c, l, n, u and v.
75 # Options d, e, o imply one of the above.
76 die "Need one of -[cdehlnouv] flags.\n"
77     unless $opt_c or $opt_l or $opt_n or $opt_u or $opt_v;
78
79
80 my $temp = '/tmp/docnits.txt';
81 my $OUT;
82 my $status = 0;
83
84 my @sections = ( 'man1', 'man3', 'man5', 'man7' );
85 my %mandatory_sections = (
86     '*' => [ 'NAME', 'DESCRIPTION', 'COPYRIGHT' ],
87     1   => [ 'SYNOPSIS', 'OPTIONS' ],
88     3   => [ 'SYNOPSIS', 'RETURN VALUES' ],
89     5   => [ ],
90     7   => [ ]
91                          );
92
93 # Symbols that we ignored.
94 # They are reserved macros that we currently don't document
95 my $ignored = qr/(?| ^i2d_
96                  |   ^d2i_
97                  |   ^DEPRECATEDIN
98                  |   ^OSSL_DEPRECATED
99                  |   \Q_fnsig(3)\E$
100                  |   ^IMPLEMENT_
101                  |   ^_?DECLARE_
102                  |   ^sk_
103                  |   ^SKM_DEFINE_STACK_OF_INTERNAL
104                  |   ^lh_
105                  |   ^DEFINE_LHASH_OF_INTERNAL
106                  )/x;
107
108 # A common regexp for C symbol names
109 my $C_symbol = qr/\b[[:alpha:]][_[:alnum:]]*\b/;
110
111 # Collect all POD files, both internal and public, and regardless of location
112 # We collect them in a hash table with each file being a key, so we can attach
113 # tags to them.  For example, internal docs will have the word "internal"
114 # attached to them.
115 my %files = ();
116 # We collect files names on the fly, on known tag basis
117 my %collected_tags = ();
118 # We cache results based on tags
119 my %collected_results = ();
120
121 # files OPTIONS
122 #
123 # Example:
124 #
125 #       files(TAGS => 'manual');
126 #       files(TAGS => [ 'manual', 'man1' ]);
127 #
128 # This function returns an array of files corresponding to a set of tags
129 # given with the options "TAGS".  The value of this option can be a single
130 # word, or an array of several words, which work as inclusive or exclusive
131 # selectors.  Inclusive selectors are used to add one more set of files to
132 # the returned array, while exclusive selectors limit the set of files added
133 # to the array.  The recognised tag values are:
134 #
135 # 'public_manual'       - inclusive selector, adds public manuals to the
136 #                         returned array of files.
137 # 'internal_manual'     - inclusive selector, adds internal manuals to the
138 #                         returned array of files.
139 # 'manual'              - inclusive selector, adds any manual to the returned
140 #                         array of files.  This is really a shorthand for
141 #                         'public_manual' and 'internal_manual' combined.
142 # 'public_header'       - inclusive selector, adds public headers to the
143 #                         returned array of files.
144 # 'header'              - inclusive selector, adds any header file to the
145 #                         returned array of files.  Since we currently only
146 #                         care about public headers, this is exactly
147 #                         equivalent to 'public_header', but is present for
148 #                         consistency.
149 #
150 # 'man1', 'man3', 'man5', 'man7'
151 #                       - exclusive selectors, only applicable together with
152 #                         any of the manual selectors.  If any of these are
153 #                         present, only the manuals from the given sections
154 #                         will be include.  If none of these are present,
155 #                         the manuals from all sections will be returned.
156 #
157 # All returned manual files come from configdata.pm.
158 # All returned header files come from looking inside
159 # "$config{sourcedir}/include/openssl"
160 #
161 sub files {
162     my %opts = ( @_ );          # Make a copy of the arguments
163
164     $opts{TAGS} = [ $opts{TAGS} ] if ref($opts{TAGS}) eq '';
165
166     croak "No tags given, or not an array"
167         unless exists $opts{TAGS} && ref($opts{TAGS}) eq 'ARRAY';
168
169     my %tags = map { $_ => 1 } @{$opts{TAGS}};
170     $tags{public_manual} = 1
171         if $tags{manual} && ($tags{public} // !$tags{internal});
172     $tags{internal_manual} = 1
173         if $tags{manual} && ($tags{internal} // !$tags{public});
174     $tags{public_header} = 1
175         if $tags{header} && ($tags{public} // !$tags{internal});
176     delete $tags{manual};
177     delete $tags{header};
178     delete $tags{public};
179     delete $tags{internal};
180
181     my $tags_as_key = join(':', sort keys %tags);
182
183     cluck  "DEBUG[files]: This is how we got here!" if $debug;
184     print STDERR "DEBUG[files]: tags: $tags_as_key\n" if $debug;
185
186     my %tags_to_collect = ( map { $_ => 1 }
187                             grep { !exists $collected_tags{$_} }
188                             keys %tags );
189
190     if ($tags_to_collect{public_manual}) {
191         print STDERR "DEBUG[files]: collecting public manuals\n"
192             if $debug;
193
194         # The structure in configdata.pm is that $unified_info{mandocs}
195         # contains lists of man files, and in turn, $unified_info{depends}
196         # contains hash tables showing which POD file each of those man
197         # files depend on.  We use that information to find the POD files,
198         # and to attach the man section they belong to as tags
199         foreach my $mansect ( @sections ) {
200             foreach ( map { @{$unified_info{depends}->{$_}} }
201                       @{$unified_info{mandocs}->{$mansect}} ) {
202                 $files{$_} = { $mansect => 1, public_manual => 1 };
203             }
204         }
205         $collected_tags{public_manual} = 1;
206     }
207
208     if ($tags_to_collect{internal_manual}) {
209         print STDERR "DEBUG[files]: collecting internal manuals\n"
210             if $debug;
211
212         # We don't have the internal docs in configdata.pm.  However, they
213         # are all in the source tree, so they're easy to find.
214         foreach my $mansect ( @sections ) {
215             foreach ( glob(catfile($config{sourcedir},
216                                    'doc', 'internal', $mansect, '*.pod')) ) {
217                 $files{$_} = { $mansect => 1, internal_manual => 1 };
218             }
219         }
220         $collected_tags{internal_manual} = 1;
221     }
222
223     if ($tags_to_collect{public_header}) {
224         print STDERR "DEBUG[files]: collecting public headers\n"
225             if $debug;
226
227         foreach ( glob(catfile($config{sourcedir},
228                                'include', 'openssl', '*.h')) ) {
229             $files{$_} = { public_header => 1 };
230         }
231     }
232
233     my @result = @{$collected_results{$tags_as_key} // []};
234
235     if (!@result) {
236         # Produce a result based on caller tags
237         foreach my $type ( ( 'public_manual', 'internal_manual' ) ) {
238             next unless $tags{$type};
239
240             # If caller asked for specific sections, we care about sections.
241             # Otherwise, we give back all of them.
242             my @selected_sections =
243                 grep { $tags{$_} } @sections;
244             @selected_sections = @sections unless @selected_sections;
245
246             foreach my $section ( ( @selected_sections ) ) {
247                 push @result,
248                     ( sort { basename($a) cmp basename($b) }
249                       grep { $files{$_}->{$type} && $files{$_}->{$section} }
250                       keys %files );
251             }
252         }
253         if ($tags{public_header}) {
254             push @result,
255                 ( sort { basename($a) cmp basename($b) }
256                   grep { $files{$_}->{public_header} }
257                   keys %files );
258         }
259
260         if ($debug) {
261             print STDERR "DEBUG[files]: result:\n";
262             print STDERR "DEBUG[files]:     $_\n" foreach @result;
263         }
264         $collected_results{$tags_as_key} = [ @result ];
265     }
266
267     return @result;
268 }
269
270 # Print error message, set $status.
271 sub err {
272     print join(" ", @_), "\n";
273     $status = 1
274 }
275
276 # Cross-check functions in the NAME and SYNOPSIS section.
277 sub name_synopsis {
278     my $id = shift;
279     my $filename = shift;
280     my $contents = shift;
281
282     # Get NAME section and all words in it.
283     return unless $contents =~ /=head1 NAME(.*)=head1 SYNOPSIS/ms;
284     my $tmp = $1;
285     $tmp =~ tr/\n/ /;
286     err($id, "Trailing comma before - in NAME")
287         if $tmp =~ /, *-/;
288     $tmp =~ s/ -.*//g;
289     err($id, "POD markup among the names in NAME")
290         if $tmp =~ /[<>]/;
291     $tmp =~ s/  */ /g;
292     err($id, "Missing comma in NAME")
293         if $tmp =~ /[^,] /;
294
295     my $dirname = dirname($filename);
296     my $section = basename($dirname);
297     my $simplename = basename($filename, ".pod");
298     my $foundfilename = 0;
299     my %foundfilenames = ();
300     my %names;
301     foreach my $n ( split ',', $tmp ) {
302         $n =~ s/^\s+//;
303         $n =~ s/\s+$//;
304         err($id, "The name '$n' contains white-space")
305             if $n =~ /\s/;
306         $names{$n} = 1;
307         $foundfilename++ if $n eq $simplename;
308         $foundfilenames{$n} = 1
309             if ( ( grep { basename($_) eq "$n.pod" }
310                    files(TAGS => [ 'manual', $section ]) )
311                  && $n ne $simplename );
312     }
313     err($id, "The following exist as other .pod files:",
314          sort keys %foundfilenames)
315         if %foundfilenames;
316     err($id, "$simplename (filename) missing from NAME section")
317         unless $foundfilename;
318
319     # Find all functions in SYNOPSIS
320     return unless $contents =~ /=head1 SYNOPSIS(.*)=head1 DESCRIPTION/ms;
321     my $syn = $1;
322     my $ignore_until = undef;   # If defined, this is a regexp
323     # Remove all non-code lines
324     $syn =~ s/^(?:\s*?|\S.*?)$//msg;
325     # Remove all comments
326     $syn =~ s/\/\*.*?\*\///msg;
327     while ( $syn ) {
328         # "env" lines end at a newline.
329         # Preprocessor lines start with a # and end at a newline.
330         # Other lines end with a semicolon, and may cover more than
331         # one physical line.
332         if ( $syn !~ /^ \s*(env .*?|#.*?|.*?;)\s*$/ms ) {
333             err($id, "Can't parse rest of synopsis:\n$syn\n(declarations not ending with a semicolon (;)?)");
334             last;
335         }
336         my $line = $1;
337         $syn = $';
338
339         print STDERR "DEBUG[name_synopsis] \$line = '$line'\n" if $debug;
340
341         # Special code to skip over documented structures
342         if ( defined $ignore_until) {
343             next if $line !~ /$ignore_until/;
344             $ignore_until = undef;
345             next;
346         }
347         if ( $line =~ /^\s*(?:typedef\s+)?struct(?:\s+\S+)\s*\{/ ) {
348             $ignore_until = qr/\}.*?;/;
349             next;
350         }
351
352         my $sym;
353         my $is_prototype = 1;
354         $line =~ s/STACK_OF\([^)]+\)/int/g;
355         $line =~ s/SPARSE_ARRAY_OF\([^)]+\)/int/g;
356         $line =~ s/__declspec\([^)]+\)//;
357
358         ## We don't prohibit that space, to allow typedefs looking like
359         ## this:
360         ##
361         ## typedef int (fantastically_long_name_breaks_80char_limit)
362         ##     (fantastically_long_name_breaks_80char_limit *something);
363         ##
364         #if ( $line =~ /typedef.*\(\*?\S+\)\s+\(/ ) {
365         #    # a callback function with whitespace before the argument list:
366         #    # typedef ... (*NAME) (...
367         #    # typedef ... (NAME) (...
368         #    err($id, "Function typedef has space before arg list: $line");
369         #}
370
371         if ( $line =~ /env (\S*)=/ ) {
372             # environment variable env NAME=...
373             $sym = $1;
374         } elsif ( $line =~ /typedef.*\(\*?($C_symbol)\)\s*\(/ ) {
375             # a callback function pointer: typedef ... (*NAME)(...
376             # a callback function signature: typedef ... (NAME)(...
377             $sym = $1;
378         } elsif ( $line =~ /typedef.*($C_symbol)\s*\(/ ) {
379             # a callback function signature: typedef ... NAME(...
380             $sym = $1;
381         } elsif ( $line =~ /typedef.*($C_symbol);/ ) {
382             # a simple typedef: typedef ... NAME;
383             $is_prototype = 0;
384             $sym = $1;
385         } elsif ( $line =~ /enum ($C_symbol) \{/ ) {
386             # an enumeration: enum ... {
387             $sym = $1;
388         } elsif ( $line =~ /#\s*(?:define|undef) ($C_symbol)/ ) {
389             $is_prototype = 0;
390             $sym = $1;
391         } elsif ( $line =~ /^[^\(]*?\(\*($C_symbol)\s*\(/ ) {
392             # a function returning a function pointer: TYPE (*NAME(args))(args)
393             $sym = $1;
394         } elsif ( $line =~ /^[^\(]*?($C_symbol)\s*\(/ ) {
395             # a simple function declaration
396             $sym = $1;
397         }
398         else {
399             next;
400         }
401
402         print STDERR "DEBUG[name_synopsis] \$sym = '$sym'\n" if $debug;
403
404         err($id, "$sym missing from NAME section")
405             unless defined $names{$sym};
406         $names{$sym} = 2;
407
408         # Do some sanity checks on the prototype.
409         err($id, "Prototype missing spaces around commas: $line")
410             if $is_prototype && $line =~ /[a-z0-9],[^\s]/;
411     }
412
413     foreach my $n ( keys %names ) {
414         next if $names{$n} == 2;
415         err($id, "$n missing from SYNOPSIS")
416     }
417 }
418
419 # Check if SECTION ($3) is located before BEFORE ($4)
420 sub check_section_location {
421     my $id = shift;
422     my $contents = shift;
423     my $section = shift;
424     my $before = shift;
425
426     return unless $contents =~ /=head1 $section/
427         and $contents =~ /=head1 $before/;
428     err($id, "$section should appear before $before section")
429         if $contents =~ /=head1 $before.*=head1 $section/ms;
430 }
431
432 # Check if a =head1 is duplicated, or a =headX is duplicated within a
433 # =head1.  Treats =head2 =head3 as equivalent -- it doesn't reset the head3
434 # sets if it finds a =head2 -- but that is good enough for now. Also check
435 # for proper capitalization, trailing periods, etc.
436 sub check_head_style {
437     my $id = shift;
438     my $contents = shift;
439     my %head1;
440     my %subheads;
441
442     foreach my $line ( split /\n+/, $contents ) {
443         next unless $line =~ /^=head/;
444         if ( $line =~ /head1/ ) {
445             err($id, "Duplicate section $line")
446                 if defined $head1{$line};
447             $head1{$line} = 1;
448             %subheads = ();
449         } else {
450             err($id, "Duplicate subsection $line")
451                 if defined $subheads{$line};
452             $subheads{$line} = 1;
453         }
454         err($id, "Period in =head")
455             if $line =~ /\.[^\w]/ or $line =~ /\.$/;
456         err($id, "not all uppercase in =head1")
457             if $line =~ /head1.*[a-z]/;
458         err($id, "All uppercase in subhead")
459             if $line =~ /head[234][ A-Z0-9]+$/;
460     }
461 }
462
463 # Because we have options and symbols with extra markup, we need
464 # to take that into account, so we need a regexp that extracts
465 # markup chunks, including recursive markup.
466 # please read up on /(?R)/ in perlre(1)
467 # (note: order is important, (?R) needs to come before .)
468 # (note: non-greedy is important, or something like 'B<foo> and B<bar>'
469 # will be captured as one item)
470 my $markup_re =
471     qr/(                        # Capture group
472            [BIL]<               # The start of what we recurse on
473            (?:(?-1)|.)*?        # recurse the whole regexp (referring to
474                                 # the last opened capture group, i.e. the
475                                 # start of this regexp), or pick next
476                                 # character.  Do NOT be greedy!
477            >                    # The end of what we recurse on
478        )/x;                     # (the x allows this sort of split up regexp)
479
480 # Options must start with a dash, followed by a letter, possibly
481 # followed by letters, digits, dashes and underscores, and the last
482 # character must be a letter or a digit.
483 # We do also accept the single -? or -n, where n is a digit
484 my $option_re =
485     qr/(?:
486             \?                  # Single question mark
487             |
488             \d                  # Single digit
489             |
490             -                   # Single dash (--)
491             |
492             [[:alpha:]](?:[-_[:alnum:]]*?[[:alnum:]])?
493        )/x;
494
495 # Helper function to check if a given $thing is properly marked up
496 # option.  It returns one of these values:
497 #     undef         if it's not an option
498 #     ""            if it's a malformed option
499 #     $unwrapped    the option with the outermost B<> wrapping removed.
500 sub normalise_option {
501     my $id = shift;
502     my $filename = shift;
503     my $thing = shift;
504
505     my $unwrapped = $thing;
506     my $unmarked = $thing;
507
508     # $unwrapped is the option with the outer B<> markup removed
509     $unwrapped =~ s/^B<//;
510     $unwrapped =~ s/>$//;
511     # $unmarked is the option with *all* markup removed
512     $unmarked =~ s/[BIL]<|>//msg;
513
514
515     # If we found an option, check it, collect it
516     if ( $unwrapped =~ /^\s*-/ ) {
517         return $unwrapped       # return option with outer B<> removed
518             if $unmarked =~ /^-${option_re}$/;
519         return "";              # Malformed option
520     }
521     return undef;               # Something else
522 }
523
524 # Checks of command option (man1) formatting.  The man1 checks are
525 # restricted to the SYNOPSIS and OPTIONS sections, the rest is too
526 # free form, we simply cannot be too strict there.
527
528 sub option_check {
529     my $id = shift;
530     my $filename = shift;
531     my $contents = shift;
532
533     my $synopsis = ($contents =~ /=head1\s+SYNOPSIS(.*?)=head1/s, $1);
534
535     # Some pages have more than one OPTIONS section, let's make sure
536     # to get them all
537     my $options = '';
538     while ( $contents =~ /=head1\s+[A-Z ]*?OPTIONS$(.*?)(?==head1)/msg ) {
539         $options .= $1;
540     }
541
542     # Look for options with no or incorrect markup
543     while ( $synopsis =~
544             /(?<![-<[:alnum:]])-(?:$markup_re|.)*(?![->[:alnum:]])/msg ) {
545         err($id, "Malformed option [1] in SYNOPSIS: $&");
546     }
547
548     while ( $synopsis =~ /$markup_re/msg ) {
549         my $found = $&;
550         print STDERR "$id:DEBUG[option_check] SYNOPSIS: found $found\n"
551             if $debug;
552         my $option_uw = normalise_option($id, $filename, $found);
553         err($id, "Malformed option [2] in SYNOPSIS: $found")
554             if defined $option_uw && $option_uw eq '';
555     }
556
557     # In OPTIONS, we look for =item paragraphs.
558     # (?=^\s*$) detects an empty line.
559     while ( $options =~ /=item\s+(.*?)(?=^\s*$)/msg ) {
560         my $item = $&;
561
562         while ( $item =~ /(\[\s*)?($markup_re)/msg ) {
563             my $found = $2;
564             print STDERR "$id:DEBUG[option_check] OPTIONS: found $&\n"
565                 if $debug;
566             err($id, "Unexpected bracket in OPTIONS =item: $item")
567                 if ($1 // '') ne '' && $found =~ /^B<\s*-/;
568
569             my $option_uw = normalise_option($id, $filename, $found);
570             err($id, "Malformed option in OPTIONS: $found")
571                 if defined $option_uw && $option_uw eq '';
572         }
573     }
574 }
575
576 # Normal symbol form
577 my $symbol_re = qr/[[:alpha:]_][_[:alnum:]]*?/;
578
579 # Checks of function name (man3) formatting.  The man3 checks are
580 # easier than the man1 checks, we only check the names followed by (),
581 # and only the names that have POD markup.
582 sub functionname_check {
583     my $id = shift;
584     my $filename = shift;
585     my $contents = shift;
586
587     while ( $contents =~ /($markup_re)\(\)/msg ) {
588         print STDERR "$id:DEBUG[functionname_check] SYNOPSIS: found $&\n"
589             if $debug;
590
591         my $symbol = $1;
592         my $unmarked = $symbol;
593         $unmarked =~ s/[BIL]<|>//msg;
594
595         err($id, "Malformed symbol: $symbol")
596             unless $symbol =~ /^B<.*?>$/ && $unmarked =~ /^${symbol_re}$/
597     }
598
599     # We can't do the kind of collecting coolness that option_check()
600     # does, because there are too many things that can't be found in
601     # name repositories like the NAME sections, such as symbol names
602     # with a variable part (typically marked up as B<foo_I<TYPE>_bar>
603 }
604
605 # This is from http://man7.org/linux/man-pages/man7/man-pages.7.html
606 my %preferred_words = (
607     '16bit'         => '16-bit',
608     'a.k.a.'        => 'aka',
609     'bitmask'       => 'bit mask',
610     'builtin'       => 'built-in',
611    #'epoch'         => 'Epoch', # handled specially, below
612     'file name'     => 'filename',
613     'file system'   => 'filesystem',
614     'host name'     => 'hostname',
615     'i-node'        => 'inode',
616     'lower case'    => 'lowercase',
617     'lower-case'    => 'lowercase',
618     'manpage'       => 'man page',
619     'non-blocking'  => 'nonblocking',
620     'non-default'   => 'nondefault',
621     'non-empty'     => 'nonempty',
622     'non-negative'  => 'nonnegative',
623     'non-zero'      => 'nonzero',
624     'path name'     => 'pathname',
625     'pre-allocated' => 'preallocated',
626     'pseudo-terminal' => 'pseudoterminal',
627     'real time'     => 'real-time',
628     'realtime'      => 'real-time',
629     'reserved port' => 'privileged port',
630     'runtime'       => 'run time',
631     'saved group ID'=> 'saved set-group-ID',
632     'saved set-GID' => 'saved set-group-ID',
633     'saved set-UID' => 'saved set-user-ID',
634     'saved user ID' => 'saved set-user-ID',
635     'set-GID'       => 'set-group-ID',
636     'set-UID'       => 'set-user-ID',
637     'setgid'        => 'set-group-ID',
638     'setuid'        => 'set-user-ID',
639     'sub-system'    => 'subsystem',
640     'super block'   => 'superblock',
641     'super-block'   => 'superblock',
642     'super user'    => 'superuser',
643     'super-user'    => 'superuser',
644     'system port'   => 'privileged port',
645     'time stamp'    => 'timestamp',
646     'time zone'     => 'timezone',
647     'upper case'    => 'uppercase',
648     'upper-case'    => 'uppercase',
649     'useable'       => 'usable',
650     'user name'     => 'username',
651     'userspace'     => 'user space',
652     'zeroes'        => 'zeros'
653 );
654
655 # Search manpage for words that have a different preferred use.
656 sub wording {
657     my $id = shift;
658     my $contents = shift;
659
660     foreach my $k ( keys %preferred_words ) {
661         # Sigh, trademark
662         next if $k eq 'file system'
663             and $contents =~ /Microsoft Encrypted File System/;
664         err($id, "Found '$k' should use '$preferred_words{$k}'")
665             if $contents =~ /\b\Q$k\E\b/i;
666     }
667     err($id, "Found 'epoch' should use 'Epoch'")
668         if $contents =~ /\bepoch\b/;
669     if ( $id =~ m@man1/@ ) {
670         err($id, "found 'tool' in NAME, should use 'command'")
671             if $contents =~ /=head1 NAME.*\btool\b.*=head1 SYNOPSIS/s;
672         err($id, "found 'utility' in NAME, should use 'command'")
673             if $contents =~ /NAME.*\butility\b.*=head1 SYNOPSIS/s;
674
675     }
676 }
677
678 # Perform all sorts of nit/error checks on a manpage
679 sub check {
680     my %podinfo = @_;
681     my $filename = $podinfo{filename};
682     my $dirname = basename(dirname($filename));
683     my $contents = $podinfo{contents};
684
685     my $id = "${filename}:1:";
686     check_head_style($id, $contents);
687
688     # Check ordering of some sections in man3
689     if ( $filename =~ m|man3/| ) {
690         check_section_location($id, $contents, "RETURN VALUES", "EXAMPLES");
691         check_section_location($id, $contents, "SEE ALSO", "HISTORY");
692         check_section_location($id, $contents, "EXAMPLES", "SEE ALSO");
693     }
694
695     # Make sure every link has a section.
696     while ( $contents =~ /$markup_re/msg ) {
697         my $target = $1;
698         next unless $target =~ /^L<(.*)>$/;     # Skip if not L<...>
699         $target = $1;                           # Peal away L< and >
700         $target =~ s/\/[^\/]*$//;               # Peal away possible anchor
701         $target =~ s/.*\|//g;                   # Peal away possible link text
702         next if $target eq '';                  # Skip if links within page, or
703         next if $target =~ /::/;                #   links to a Perl module, or
704         next if $target =~ /^https?:/;          #   is a URL link, or
705         next if $target =~ /\([1357]\)$/;       #   it has a section
706         err($id, "Section missing in $target")
707     }
708     # Check for proper links to commands.
709     while ( $contents =~ /L<([^>]*)\(1\)(?:\/.*)?>/g ) {
710         my $target = $1;
711         next if $target =~ /openssl-?/;
712         next if ( grep { basename($_) eq "$target.pod" }
713                   files(TAGS => [ 'manual', 'man1' ]) );
714         # TODO: Filter out "foreign manual" links.
715         next if $target =~ /ps|apropos|sha1sum|procmail|perl/;
716         err($id, "Bad command link L<$target(1)>");
717     }
718     # Check for proper in-man-3 API links.
719     while ( $contents =~ /L<([^>]*)\(3\)(?:\/.*)?>/g ) {
720         my $target = $1;
721         err($id, "Bad L<$target>")
722             unless $target =~ /^[_[:alpha:]][_[:alnum:]]*$/
723     }
724
725     unless ( $contents =~ /^=for openssl generic/ms ) {
726         if ( $filename =~ m|man3/| ) {
727             name_synopsis($id, $filename, $contents);
728             functionname_check($id, $filename, $contents);
729         } elsif ( $filename =~ m|man1/| ) {
730             option_check($id, $filename, $contents)
731         }
732     }
733
734     wording($id, $contents);
735
736     err($id, "Doesn't start with =pod")
737         if $contents !~ /^=pod/;
738     err($id, "Doesn't end with =cut")
739         if $contents !~ /=cut\n$/;
740     err($id, "More than one cut line.")
741         if $contents =~ /=cut.*=cut/ms;
742     err($id, "EXAMPLE not EXAMPLES section.")
743         if $contents =~ /=head1 EXAMPLE[^S]/;
744     err($id, "WARNING not WARNINGS section.")
745         if $contents =~ /=head1 WARNING[^S]/;
746     err($id, "Missing copyright")
747         if $contents !~ /Copyright .* The OpenSSL Project Authors/;
748     err($id, "Copyright not last")
749         if $contents =~ /head1 COPYRIGHT.*=head/ms;
750     err($id, "head2 in All uppercase")
751         if $contents =~ /head2\s+[A-Z ]+\n/;
752     err($id, "Extra space after head")
753         if $contents =~ /=head\d\s\s+/;
754     err($id, "Period in NAME section")
755         if $contents =~ /=head1 NAME.*\.\n.*=head1 SYNOPSIS/ms;
756     err($id, "Duplicate $1 in L<>")
757         if $contents =~ /L<([^>]*)\|([^>]*)>/ && $1 eq $2;
758     err($id, "Bad =over $1")
759         if $contents =~ /=over([^ ][^24])/;
760     err($id, "Possible version style issue")
761         if $contents =~ /OpenSSL version [019]/;
762
763     if ( $contents !~ /=for openssl multiple includes/ ) {
764         # Look for multiple consecutive openssl #include lines
765         # (non-consecutive lines are okay; see man3/MD5.pod).
766         if ( $contents =~ /=head1 SYNOPSIS(.*)=head1 DESCRIPTION/ms ) {
767             my $count = 0;
768             foreach my $line ( split /\n+/, $1 ) {
769                 if ( $line =~ m@include <openssl/@ ) {
770                     err($id, "Has multiple includes")
771                         if ++$count == 2;
772                 } else {
773                     $count = 0;
774                 }
775             }
776         }
777     }
778
779     open my $OUT, '>', $temp
780         or die "Can't open $temp, $!";
781     err($id, "POD errors")
782         if podchecker($filename, $OUT) != 0;
783     close $OUT;
784     open $OUT, '<', $temp
785         or die "Can't read $temp, $!";
786     while ( <$OUT> ) {
787         next if /\(section\) in.*deprecated/;
788         print;
789     }
790     close $OUT;
791     unlink $temp || warn "Can't remove $temp, $!";
792
793     # Find what section this page is in; assume 3.
794     my $section = 3;
795     $section = $1 if $dirname =~ /man([1-9])/;
796
797     foreach ( (@{$mandatory_sections{'*'}}, @{$mandatory_sections{$section}}) ) {
798         err($id, "Missing $_ head1 section")
799             if $contents !~ /^=head1\s+${_}\s*$/m;
800     }
801 }
802
803 # Information database ###############################################
804
805 # Map of links in each POD file; filename => [ "foo(1)", "bar(3)", ... ]
806 my %link_map = ();
807 # Map of names in each POD file or from "missing" files; possible values are:
808 # If found in a POD files, "name(s)" => filename
809 # If found in a "missing" file or external, "name(s)" => ''
810 my %name_map = ();
811
812 # State of man-page names.
813 # %state is affected by loading util/*.num and util/*.syms
814 # Values may be one of:
815 # 'crypto' : belongs in libcrypto (loaded from libcrypto.num)
816 # 'ssl' : belongs in libssl (loaded from libssl.num)
817 # 'other' : belongs in libcrypto or libssl (loaded from other.syms)
818 # 'internal' : Internal
819 # 'public' : Public (generic name or external documentation)
820 # Any of these values except 'public' may be prefixed with 'missing_'
821 # to indicate that they are known to be missing.
822 my %state;
823 # %missing is affected by loading util/missing*.txt.  Values may be one of:
824 # 'crypto' : belongs in libcrypto (loaded from libcrypto.num)
825 # 'ssl' : belongs in libssl (loaded from libssl.num)
826 # 'other' : belongs in libcrypto or libssl (loaded from other.syms)
827 # 'internal' : Internal
828 my %missing;
829
830 # Parse libcrypto.num, etc., and return sorted list of what's there.
831 sub loadnum ($;$) {
832     my $file = shift;
833     my $type = shift;
834     my @symbols;
835
836     open my $IN, '<', catfile($config{sourcedir}, $file)
837         or die "Can't open $file, $!, stopped";
838
839     while ( <$IN> ) {
840         next if /^#/;
841         next if /\bNOEXIST\b/;
842         my @fields = split();
843         die "Malformed line $. in $file: $_"
844             if scalar @fields != 2 && scalar @fields != 4;
845         $state{$fields[0].'(3)'} = $type // 'internal';
846     }
847     close $IN;
848 }
849
850 # Load file of symbol names that we know aren't documented.
851 sub loadmissing($;$)
852 {
853     my $missingfile = shift;
854     my $type = shift;
855
856     open FH, catfile($config{sourcedir}, $missingfile)
857         or die "Can't open $missingfile";
858     while ( <FH> ) {
859         chomp;
860         next if /^#/;
861         $missing{$_} = $type // 'internal';
862     }
863     close FH;
864 }
865
866 # Check that we have consistent public / internal documentation and declaration
867 sub checkstate () {
868     # Collect all known names, no matter where they come from
869     my %names = map { $_ => 1 } (keys %name_map, keys %state, keys %missing);
870
871     # Check section 3, i.e. functions and macros
872     foreach ( grep { $_ =~ /\(3\)$/ } sort keys %names ) {
873         next if ( $name_map{$_} // '') eq '' || $_ =~ /$ignored/;
874
875         # If a man-page isn't recorded public or if it's recorded missing
876         # and internal, it's declared to be internal.
877         my $declared_internal =
878             ($state{$_} // 'internal') eq 'internal'
879             || ($missing{$_} // '') eq 'internal';
880         # If a man-page isn't recorded internal or if it's recorded missing
881         # and not internal, it's declared to be public
882         my $declared_public =
883             ($state{$_} // 'internal') ne 'internal'
884             || ($missing{$_} // 'internal') ne 'internal';
885
886         err("$_ is supposedly public but is documented as internal")
887             if ( $declared_public && $name_map{$_} =~ /\/internal\// );
888         err("$_ is supposedly internal but is documented as public")
889             if ( $declared_internal && $name_map{$_} !~ /\/internal\// );
890     }
891 }
892
893 # Check for undocumented macros; ignore those in the "missing" file
894 # and do simple check for #define in our header files.
895 sub checkmacros {
896     my $count = 0;
897     my %seen;
898
899     foreach my $f ( files(TAGS => 'public_header') ) {
900         # Skip some internals we don't want to document yet.
901         my $b = basename($f);
902         next if $b eq 'asn1.h';
903         next if $b eq 'asn1t.h';
904         next if $b eq 'err.h';
905         open(IN, $f)
906             or die "Can't open $f, $!";
907         while ( <IN> ) {
908             next unless /^#\s*define\s*(\S+)\(/;
909             my $macro = "$1(3)"; # We know they're all in section 3
910             next if defined $name_map{$macro}
911                 || defined $missing{$macro}
912                 || defined $seen{$macro}
913                 || $macro =~ /$ignored/;
914
915             err("$f:", "macro $macro undocumented")
916                 if $opt_d || $opt_e;
917             $count++;
918             $seen{$macro} = 1;
919         }
920         close(IN);
921     }
922     err("# $count macros undocumented (count is approximate)")
923         if $count > 0;
924 }
925
926 # Find out what is undocumented (filtering out the known missing ones)
927 # and display them.
928 sub printem ($) {
929     my $type = shift;
930     my $count = 0;
931
932     foreach my $func ( grep { $state{$_} eq $type } sort keys %state ) {
933         next if defined $name_map{$func}
934             || defined $missing{$func};
935
936         err("$type:", "function $func undocumented")
937             if $opt_d || $opt_e;
938         $count++;
939     }
940     err("# $count lib$type names are not documented")
941         if $count > 0;
942 }
943
944 # Collect all the names in a manpage.
945 sub collectnames {
946     my %podinfo = @_;
947     my $filename = $podinfo{filename};
948     $filename =~ m|man(\d)/|;
949     my $section = $1;
950     my $simplename = basename($filename, ".pod");
951     my $id = "${filename}:1:";
952     my $is_generic = $podinfo{contents} =~ /^=for openssl generic/ms;
953
954     unless ( grep { $simplename eq $_ } @{$podinfo{names}} ) {
955         err($id, "$simplename not in NAME section");
956         push @{$podinfo{names}}, $simplename;
957     }
958     foreach my $name ( @{$podinfo{names}} ) {
959         next if $name eq "";
960         err($id, "'$name' contains whitespace")
961             if $name =~ /\s/;
962         my $name_sec = "$name($section)";
963         if ( !defined $name_map{$name_sec} ) {
964             $name_map{$name_sec} = $filename;
965             $state{$name_sec} //=
966                 ( $filename =~ /\/internal\// ? 'internal' : 'public' )
967                 if $is_generic;
968         } elsif ( $filename eq $name_map{$name_sec} ) {
969             err($id, "$name_sec duplicated in NAME section of",
970                  $name_map{$name_sec});
971         } elsif ( $name_map{$name_sec} ne '' ) {
972             err($id, "$name_sec also in NAME section of",
973                  $name_map{$name_sec});
974         }
975     }
976
977     if ( $podinfo{contents} =~ /=for openssl foreign manual (.*)\n/ ) {
978         foreach my $f ( split / /, $1 ) {
979             $name_map{$f} = ''; # It still exists!
980             $state{$f} = 'public'; # We assume!
981         }
982     }
983
984     my @links =
985         $podinfo{contents} =~ /L<
986                               # if the link is of the form L<something|name(s)>,
987                               # then remove 'something'.  Note that 'something'
988                               # may contain POD codes as well...
989                               (?:(?:[^\|]|<[^>]*>)*\|)?
990                               # we're only interested in references that have
991                               # a one digit section number
992                               ([^\/>\(]+\(\d\))
993                              /gx;
994     $link_map{$filename} = [ @links ];
995 }
996
997 # Look for L<> ("link") references that point to files that do not exist.
998 sub checklinks {
999     foreach my $filename ( sort keys %link_map ) {
1000         foreach my $link ( @{$link_map{$filename}} ) {
1001             err("${filename}:1:", "reference to non-existing $link")
1002                 unless defined $name_map{$link} || defined $missing{$link};
1003             err("${filename}:1:", "reference of internal $link in public documentation $filename")
1004                 if ( ( ($state{$link} // '') eq 'internal'
1005                        || ($missing{$link} // '') eq 'internal' )
1006                      && $filename !~ /\/internal\// );
1007         }
1008     }
1009 }
1010
1011 # Cipher/digests to skip if they show up as "not implemented"
1012 # because they are, via the "-*" construct.
1013 my %skips = (
1014     'aes128' => 1,
1015     'aes192' => 1,
1016     'aes256' => 1,
1017     'aria128' => 1,
1018     'aria192' => 1,
1019     'aria256' => 1,
1020     'camellia128' => 1,
1021     'camellia192' => 1,
1022     'camellia256' => 1,
1023     'des' => 1,
1024     'des3' => 1,
1025     'idea' => 1,
1026     'cipher' => 1,
1027     'digest' => 1,
1028 );
1029
1030 # Check the flags of a command and see if everything is in the manpage
1031 sub checkflags {
1032     my $cmd = shift;
1033     my $doc = shift;
1034     my %cmdopts;
1035     my %docopts;
1036     my %localskips;
1037
1038     # Get the list of options in the command.
1039     open CFH, "$openssl list --options $cmd|"
1040         or die "Can list options for $cmd, $!";
1041     while ( <CFH> ) {
1042         chop;
1043         s/ .$//;
1044         $cmdopts{$_} = 1;
1045     }
1046     close CFH;
1047
1048     # Get the list of flags from the synopsis
1049     open CFH, "<$doc"
1050         or die "Can't open $doc, $!";
1051     while ( <CFH> ) {
1052         chop;
1053         last if /DESCRIPTION/;
1054         if ( /=for openssl ifdef (.*)/ ) {
1055             foreach my $f ( split / /, $1 ) {
1056                 $localskips{$f} = 1;
1057             }
1058             next;
1059         }
1060         my $opt;
1061         if ( /\[B<-([^ >]+)/ ) {
1062             $opt = $1;
1063         } elsif ( /^B<-([^ >]+)/ ) {
1064             $opt = $1;
1065         } else {
1066             next;
1067         }
1068         $opt = $1 if $opt =~ /I<(.*)/;
1069         $docopts{$1} = 1;
1070     }
1071     close CFH;
1072
1073     # See what's in the command not the manpage.
1074     my @undocced = sort grep { !defined $docopts{$_} } keys %cmdopts;
1075     foreach ( @undocced ) {
1076         next if /-/; # Skip the -- end-of-flags marker
1077         err("$doc: undocumented option -$_");
1078     }
1079
1080     # See what's in the command not the manpage.
1081     my @unimpl = sort grep { !defined $cmdopts{$_} } keys %docopts;
1082     foreach ( @unimpl ) {
1083         next if defined $skips{$_} || defined $localskips{$_};
1084         err("$doc: $cmd does not implement -$_");
1085     }
1086 }
1087
1088 ##
1089 ##  MAIN()
1090 ##  Do the work requested by the various getopt flags.
1091 ##  The flags are parsed in alphabetical order, just because we have
1092 ##  to have *some way* of listing them.
1093 ##
1094
1095 if ( $opt_c ) {
1096     my @commands = ();
1097
1098     # Get list of commands.
1099     open FH, "$openssl list -1 -commands|"
1100         or die "Can't list commands, $!";
1101     while ( <FH> ) {
1102         chop;
1103         push @commands, $_;
1104     }
1105     close FH;
1106
1107     # See if each has a manpage.
1108     foreach my $cmd ( @commands ) {
1109         next if $cmd eq 'help' || $cmd eq 'exit';
1110         my @doc = ( grep { basename($_) eq "openssl-$cmd.pod"
1111                            # For "tsget" and "CA.pl" pod pages
1112                            || basename($_) eq "$cmd.pod" }
1113                     files(TAGS => [ 'manual', 'man1' ]) );
1114         my $num = scalar @doc;
1115         if ($num > 1) {
1116             err("$num manuals for 'openssl $cmd': ".join(", ", @doc));
1117         } elsif ($num < 1) {
1118             err("no manual for 'openssl $cmd'");
1119         } else {
1120             checkflags($cmd, @doc);
1121         }
1122     }
1123
1124     # See what help is missing.
1125     open FH, "$openssl list --missing-help |"
1126         or die "Can't list missing help, $!";
1127     while ( <FH> ) {
1128         chop;
1129         my ($cmd, $flag) = split;
1130         err("$cmd has no help for -$flag");
1131     }
1132     close FH;
1133
1134     exit $status;
1135 }
1136
1137 # Populate %state
1138 loadnum('util/libcrypto.num', 'crypto');
1139 loadnum('util/libssl.num', 'ssl');
1140 loadnum('util/other.syms', 'other');
1141 loadnum('util/other-internal.syms');
1142 if ( $opt_o ) {
1143     loadmissing('util/missingmacro111.txt', 'crypto');
1144     loadmissing('util/missingcrypto111.txt', 'crypto');
1145     loadmissing('util/missingssl111.txt', 'ssl');
1146 } elsif ( !$opt_u ) {
1147     loadmissing('util/missingmacro.txt', 'crypto');
1148     loadmissing('util/missingcrypto.txt', 'crypto');
1149     loadmissing('util/missingssl.txt', 'ssl');
1150     loadmissing('util/missingcrypto-internal.txt');
1151     loadmissing('util/missingssl-internal.txt');
1152 }
1153
1154 if ( $opt_n || $opt_l || $opt_u || $opt_v ) {
1155     my @files_to_read = ( $opt_n && @ARGV ) ? @ARGV : files(TAGS => 'manual');
1156
1157     foreach (@files_to_read) {
1158         my %podinfo = extract_pod_info($_, { debug => $debug });
1159
1160         collectnames(%podinfo)
1161             if ( $opt_l || $opt_u || $opt_v );
1162
1163         check(%podinfo)
1164             if ( $opt_n );
1165     }
1166 }
1167
1168 if ( $opt_l ) {
1169     checklinks();
1170 }
1171
1172 if ( $opt_n ) {
1173     # If not given args, check that all man1 commands are named properly.
1174     if ( scalar @ARGV == 0 ) {
1175         foreach ( files(TAGS => [ 'public_manual', 'man1' ]) ) {
1176             next if /openssl\.pod/
1177                 || /CA\.pl/ || /tsget\.pod/; # these commands are special cases
1178             err("$_ doesn't start with openssl-") unless /openssl-/;
1179         }
1180     }
1181 }
1182
1183 checkstate();
1184
1185 if ( $opt_u || $opt_v) {
1186     printem('crypto');
1187     printem('ssl');
1188     checkmacros();
1189 }
1190
1191 exit $status;