util/find-doc-nits

   1 #! /usr/bin/env perl
   2 # Copyright 2002-2018 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the Apache License 2.0 (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9
  10 require 5.10.0;
  11 use warnings;
  12 use strict;
  13 use Pod::Checker;
  14 use File::Find;
  15 use File::Basename;
  16 use File::Spec::Functions;
  17 use Getopt::Std;
  18 use lib catdir(dirname($0), "perl");
  19 use OpenSSL::Util::Pod;
  20
  21 # Options.
  22 our($opt_d);
  23 our($opt_h);
  24 our($opt_l);
  25 our($opt_n);
  26 our($opt_p);
  27 our($opt_u);
  28 our($opt_c);
  29
  30 sub help()
  31 {
  32     print <<EOF;
  33 Find small errors (nits) in documentation.  Options:
  34     -d Detailed list of undocumented (implies -u)
  35     -l Print bogus links
  36     -n Print nits in POD pages
  37     -p Warn if non-public name documented (implies -n)
  38     -u Count undocumented functions
  39     -h Print this help message
  40     -c List undocumented commands and options
  41 EOF
  42     exit;
  43 }
  44
  45 my $temp = '/tmp/docnits.txt';
  46 my $OUT;
  47 my %public;
  48
  49 my %mandatory_sections =
  50     ( '*'    => [ 'NAME', 'DESCRIPTION', 'COPYRIGHT' ],
  51       1      => [ 'SYNOPSIS', 'OPTIONS' ],
  52       3      => [ 'SYNOPSIS', 'RETURN VALUES' ],
  53       5      => [ ],
  54       7      => [ ] );
  55
  56 # Cross-check functions in the NAME and SYNOPSIS section.
  57 sub name_synopsis()
  58 {
  59     my $id = shift;
  60     my $filename = shift;
  61     my $contents = shift;
  62
  63     # Get NAME section and all words in it.
  64     return unless $contents =~ /=head1 NAME(.*)=head1 SYNOPSIS/ms;
  65     my $tmp = $1;
  66     $tmp =~ tr/\n/ /;
  67     print "$id trailing comma before - in NAME\n" if $tmp =~ /, *-/;
  68     $tmp =~ s/ -.*//g;
  69     $tmp =~ s/  */ /g;
  70     print "$id missing comma in NAME\n" if $tmp =~ /[^,] /;
  71
  72     my $dirname = dirname($filename);
  73     my $simplename = basename($filename);
  74     $simplename =~ s/.pod$//;
  75     my $foundfilename = 0;
  76     my %foundfilenames = ();
  77     my %names;
  78     foreach my $n ( split ',', $tmp ) {
  79         $n =~ s/^\s+//;
  80         $n =~ s/\s+$//;
  81         print "$id the name '$n' contains white-space\n"
  82             if $n =~ /\s/;
  83         $names{$n} = 1;
  84         $foundfilename++ if $n eq $simplename;
  85         $foundfilenames{$n} = 1
  86             if -f "$dirname/$n.pod" && $n ne $simplename;
  87     }
  88     print "$id the following exist as other .pod files:\n",
  89         join(" ", sort keys %foundfilenames), "\n"
  90         if %foundfilenames;
  91     print "$id $simplename (filename) missing from NAME section\n"
  92         unless $foundfilename;
  93     foreach my $n ( keys %names ) {
  94         print "$id $n is not public\n"
  95             if $opt_p and !defined $public{$n};
  96     }
  97
  98     # Find all functions in SYNOPSIS
  99     return unless $contents =~ /=head1 SYNOPSIS(.*)=head1 DESCRIPTION/ms;
 100     my $syn = $1;
 101     foreach my $line ( split /\n+/, $syn ) {
 102         next unless $line =~ /^\s/;
 103         my $sym;
 104         $line =~ s/STACK_OF\([^)]+\)/int/g;
 105         $line =~ s/SPARSE_ARRAY_OF\([^)]+\)/int/g;
 106         $line =~ s/__declspec\([^)]+\)//;
 107         if ( $line =~ /env (\S*)=/ ) {
 108             # environment variable env NAME=...
 109             $sym = $1;
 110         } elsif ( $line =~ /typedef.*\(\*(\S+)\)\(.*/ ) {
 111             # a callback function pointer: typedef ... (*NAME)(...
 112             $sym = $1;
 113         } elsif ( $line =~ /typedef.* (\S+)\(.*/ ) {
 114             # a callback function signature: typedef ... NAME(...
 115             $sym = $1;
 116         } elsif ( $line =~ /typedef.* (\S+);/ ) {
 117             # a simple typedef: typedef ... NAME;
 118             $sym = $1;
 119         } elsif ( $line =~ /enum (\S*) \{/ ) {
 120             # an enumeration: enum ... {
 121             $sym = $1;
 122         } elsif ( $line =~ /#(?:define|undef) ([A-Za-z0-9_]+)/ ) {
 123             $sym = $1;
 124         } elsif ( $line =~ /([A-Za-z0-9_]+)\(/ ) {
 125             $sym = $1;
 126         }
 127         else {
 128             next;
 129         }
 130         print "$id $sym missing from NAME section\n"
 131             unless defined $names{$sym};
 132         $names{$sym} = 2;
 133
 134         # Do some sanity checks on the prototype.
 135         print "$id prototype missing spaces around commas: $line\n"
 136             if ( $line =~ /[a-z0-9],[^ ]/ );
 137     }
 138
 139     foreach my $n ( keys %names ) {
 140         next if $names{$n} == 2;
 141         print "$id $n missing from SYNOPSIS\n";
 142     }
 143 }
 144
 145 # Check if EXAMPLES is located after RETURN VALUES section.
 146 sub check_example_location()
 147 {
 148     my $filename = shift;
 149     my $contents = shift;
 150
 151     return unless $contents =~ /=head1 RETURN VALUES/
 152         and $contents =~ /=head1 EXAMPLES/;
 153     print "$filename: RETURN VAULES should be placed before EXAMPLES section\n"
 154         if $contents =~ /=head1 EXAMPLES.*=head1 RETURN VALUES/ms;
 155 }
 156
 157 sub check()
 158 {
 159     my $filename = shift;
 160     my $dirname = basename(dirname($filename));
 161
 162     my $contents = '';
 163     {
 164         local $/ = undef;
 165         open POD, $filename or die "Couldn't open $filename, $!";
 166         $contents = <POD>;
 167         close POD;
 168     }
 169
 170     &check_example_location($filename, $contents) if $filename =~ m|man3/|;
 171
 172     my $id = "${filename}:1:";
 173
 174     &name_synopsis($id, $filename, $contents)
 175         unless $contents =~ /=for comment generic/
 176             or $filename =~ m@man[157]/@;
 177
 178     print "$id doesn't start with =pod\n"
 179         if $contents !~ /^=pod/;
 180     print "$id doesn't end with =cut\n"
 181         if $contents !~ /=cut\n$/;
 182     print "$id more than one cut line.\n"
 183         if $contents =~ /=cut.*=cut/ms;
 184     print "$id missing copyright\n"
 185         if $contents !~ /Copyright .* The OpenSSL Project Authors/;
 186     print "$id copyright not last\n"
 187         if $contents =~ /head1 COPYRIGHT.*=head/ms;
 188     print "$id head2 in All uppercase\n"
 189         if $contents =~ /head2\s+[A-Z ]+\n/;
 190     print "$id extra space after head\n"
 191         if $contents =~ /=head\d\s\s+/;
 192     print "$id period in NAME section\n"
 193         if $contents =~ /=head1 NAME.*\.\n.*=head1 SYNOPSIS/ms;
 194     print "$id POD markup in NAME section\n"
 195         if $contents =~ /=head1 NAME.*[<>].*=head1 SYNOPSIS/ms;
 196     print "$id Duplicate $1 in L<>\n"
 197         if $contents =~ /L<([^>]*)\|([^>]*)>/ && $1 eq $2;
 198     print "$id Bad =over $1\n"
 199         if $contents =~ /=over([^ ][^24])/;
 200     print "$id Possible version style issue\n"
 201         if $contents =~ /OpenSSL version [019]/;
 202
 203     if ( $contents !~ /=for comment multiple includes/ ) {
 204         # Look for multiple consecutive openssl #include lines
 205         # (non-consecutive lines are okay; see man3/MD5.pod).
 206         if ( $contents =~ /=head1 SYNOPSIS(.*)=head1 DESCRIPTION/ms ) {
 207             my $count = 0;
 208             foreach my $line ( split /\n+/, $1 ) {
 209                 if ( $line =~ m@include <openssl/@ ) {
 210                     print "$id has multiple includes\n" if ++$count == 2;
 211                 } else {
 212                     $count = 0;
 213                 }
 214             }
 215         }
 216     }
 217
 218     open my $OUT, '>', $temp
 219         or die "Can't open $temp, $!";
 220     podchecker($filename, $OUT);
 221     close $OUT;
 222     open $OUT, '<', $temp
 223         or die "Can't read $temp, $!";
 224     while ( <$OUT> ) {
 225         next if /\(section\) in.*deprecated/;
 226         print;
 227     }
 228     close $OUT;
 229     unlink $temp || warn "Can't remove $temp, $!";
 230
 231     # Find what section this page is in; assume 3.
 232     my $section = 3;
 233     $section = $1 if $dirname =~ /man([1-9])/;
 234
 235     foreach ((@{$mandatory_sections{'*'}}, @{$mandatory_sections{$section}})) {
 236         # Skip "return values" if not -s
 237         print "$id: missing $_ head1 section\n"
 238             if $contents !~ /^=head1\s+${_}\s*$/m;
 239     }
 240 }
 241
 242 my %dups;
 243
 244 sub parsenum()
 245 {
 246     my $file = shift;
 247     my @apis;
 248
 249     open my $IN, '<', $file
 250         or die "Can't open $file, $!, stopped";
 251
 252     while ( <$IN> ) {
 253         next if /^#/;
 254         next if /\bNOEXIST\b/;
 255         next if /\bEXPORT_VAR_AS_FUNC\b/;
 256         my @fields = split();
 257         die "Malformed line $_"
 258             if scalar @fields != 2 && scalar @fields != 4;
 259         push @apis, $fields[0];
 260     }
 261
 262     close $IN;
 263
 264     print "# Found ", scalar(@apis), " in $file\n" unless $opt_p;
 265     return sort @apis;
 266 }
 267
 268 sub getdocced
 269 {
 270     my $dir = shift;
 271     my %return;
 272
 273     foreach my $pod ( glob("$dir/*.pod") ) {
 274         my %podinfo = extract_pod_info($pod);
 275         foreach my $n ( @{$podinfo{names}} ) {
 276             $return{$n} = $pod;
 277             print "# Duplicate $n in $pod and $dups{$n}\n"
 278                 if defined $dups{$n} && $dups{$n} ne $pod;
 279             $dups{$n} = $pod;
 280         }
 281     }
 282
 283     return %return;
 284 }
 285
 286 my %docced;
 287
 288 sub checkmacros()
 289 {
 290     my $count = 0;
 291     my %seen;
 292
 293     print "# Checking macros (approximate)\n";
 294     foreach my $f ( glob('include/openssl/*.h') ) {
 295         # Skip some internals we don't want to document yet.
 296         next if $f eq 'include/openssl/asn1.h';
 297         next if $f eq 'include/openssl/asn1t.h';
 298         next if $f eq 'include/openssl/err.h';
 299         open(IN, $f) || die "Can't open $f, $!";
 300         while ( <IN> ) {
 301             next unless /^#\s*define\s*(\S+)\(/;
 302             my $macro = $1;
 303             next if $docced{$macro} || defined $seen{$macro};
 304             next if $macro =~ /i2d_/
 305                 || $macro =~ /d2i_/
 306                 || $macro =~ /DEPRECATEDIN/
 307                 || $macro =~ /IMPLEMENT_/
 308                 || $macro =~ /DECLARE_/;
 309             print "$f:$macro\n" if $opt_d;
 310             $count++;
 311             $seen{$macro} = 1;
 312         }
 313         close(IN);
 314     }
 315     print "# Found $count macros missing (not all should be documented)\n"
 316 }
 317
 318 sub printem()
 319 {
 320     my $libname = shift;
 321     my $numfile = shift;
 322     my $count = 0;
 323     my %seen;
 324
 325     foreach my $func ( &parsenum($numfile) ) {
 326         next if $docced{$func} || defined $seen{$func};
 327
 328         # Skip ASN1 utilities
 329         next if $func =~ /^ASN1_/;
 330
 331         print "$libname:$func\n" if $opt_d;
 332         $count++;
 333         $seen{$func} = 1;
 334     }
 335     print "# Found $count missing from $numfile\n\n";
 336 }
 337
 338
 339 # Collection of links in each POD file.
 340 # filename => [ "foo(1)", "bar(3)", ... ]
 341 my %link_collection = ();
 342 # Collection of names in each POD file.
 343 # "name(s)" => filename
 344 my %name_collection = ();
 345
 346 sub collectnames {
 347     my $filename = shift;
 348     $filename =~ m|man(\d)/|;
 349     my $section = $1;
 350     my $simplename = basename($filename, ".pod");
 351     my $id = "${filename}:1:";
 352
 353     my $contents = '';
 354     {
 355         local $/ = undef;
 356         open POD, $filename or die "Couldn't open $filename, $!";
 357         $contents = <POD>;
 358         close POD;
 359     }
 360
 361     $contents =~ /=head1 NAME([^=]*)=head1 /ms;
 362     my $tmp = $1;
 363     unless (defined $tmp) {
 364         print "$id weird name section\n";
 365         return;
 366     }
 367     $tmp =~ tr/\n/ /;
 368     $tmp =~ s/-.*//g;
 369
 370     my @names = map { s/^\s+//g; s/\s+$//g; $_ } split(/,/, $tmp);
 371     unless (grep { $simplename eq $_ } @names) {
 372         print "$id missing $simplename\n";
 373         push @names, $simplename;
 374     }
 375     foreach my $name (@names) {
 376         next if $name eq "";
 377         if ($name =~ /\s/) {
 378             print "$id '$name' contains white space\n";
 379         }
 380         my $name_sec = "$name($section)";
 381         if (! exists $name_collection{$name_sec}) {
 382             $name_collection{$name_sec} = $filename;
 383         } else { #elsif ($filename ne $name_collection{$name_sec}) {
 384             print "$id $name_sec also in $name_collection{$name_sec}\n";
 385         }
 386     }
 387
 388     my @foreign_names =
 389         map { map { s/\s+//g; $_ } split(/,/, $_) }
 390         $contents =~ /=for\s+comment\s+foreign\s+manuals:\s*(.*)\n\n/;
 391     foreach (@foreign_names) {
 392         $name_collection{$_} = undef; # It still exists!
 393     }
 394
 395     my @links = $contents =~ /L<
 396                               # if the link is of the form L<something|name(s)>,
 397                               # then remove 'something'.  Note that 'something'
 398                               # may contain POD codes as well...
 399                               (?:(?:[^\|]|<[^>]*>)*\|)?
 400                               # we're only interested in references that have
 401                               # a one digit section number
 402                               ([^\/>\(]+\(\d\))
 403                              /gx;
 404     $link_collection{$filename} = [ @links ];
 405 }
 406
 407 sub checklinks {
 408     foreach my $filename (sort keys %link_collection) {
 409         foreach my $link (@{$link_collection{$filename}}) {
 410             print "${filename}:1: reference to non-existing $link\n"
 411                 unless exists $name_collection{$link};
 412         }
 413     }
 414 }
 415
 416 sub publicize() {
 417     foreach my $name ( &parsenum('util/libcrypto.num') ) {
 418         $public{$name} = 1;
 419     }
 420     foreach my $name ( &parsenum('util/libssl.num') ) {
 421         $public{$name} = 1;
 422     }
 423     foreach my $name ( &parsenum('util/private.num') ) {
 424         $public{$name} = 1;
 425     }
 426 }
 427
 428 my %skips = (
 429     'aes128' => 1,
 430     'aes192' => 1,
 431     'aes256' => 1,
 432     'aria128' => 1,
 433     'aria192' => 1,
 434     'aria256' => 1,
 435     'camellia128' => 1,
 436     'camellia192' => 1,
 437     'camellia256' => 1,
 438     'des' => 1,
 439     'des3' => 1,
 440     'idea' => 1,
 441     '[cipher]' => 1,
 442     '[digest]' => 1,
 443 );
 444
 445 sub checkflags() {
 446     my $cmd = shift;
 447     my %cmdopts;
 448     my %docopts;
 449     my $ok = 1;
 450
 451     # Get the list of options in the command.
 452     open CFH, "./apps/openssl list --options $cmd|"
 453         || die "Can list options for $cmd, $!";
 454     while ( <CFH> ) {
 455         chop;
 456         s/ .$//;
 457         $cmdopts{$_} = 1;
 458     }
 459     close CFH;
 460
 461     # Get the list of flags from the synopsis
 462     open CFH, "<doc/man1/$cmd.pod"
 463         || die "Can't open $cmd.pod, $!";
 464     while ( <CFH> ) {
 465         chop;
 466         last if /DESCRIPTION/;
 467         next unless /\[B<-([^ >]+)/;
 468         $docopts{$1} = 1;
 469     }
 470     close CFH;
 471
 472     # See what's in the command not the manpage.
 473     my @undocced = ();
 474     foreach my $k ( keys %cmdopts ) {
 475         push @undocced, $k unless $docopts{$k};
 476     }
 477     if ( scalar @undocced > 0 ) {
 478         $ok = 0;
 479         foreach ( @undocced ) {
 480             print "doc/man1/$cmd.pod: Missing -$_\n";
 481         }
 482     }
 483
 484     # See what's in the command not the manpage.
 485     my @unimpl = ();
 486     foreach my $k ( keys %docopts ) {
 487         push @unimpl, $k unless $cmdopts{$k};
 488     }
 489     if ( scalar @unimpl > 0 ) {
 490         $ok = 0;
 491         foreach ( @unimpl ) {
 492             next if defined $skips{$_};
 493             print "doc/man1/$cmd.pod: Not implemented -$_\n";
 494         }
 495     }
 496
 497     return $ok;
 498 }
 499
 500 getopts('cdlnphu');
 501
 502 &help() if $opt_h;
 503 $opt_n = 1 if $opt_p;
 504 $opt_u = 1 if $opt_d;
 505
 506 die "Need one of -[cdlnpu] flags.\n"
 507     unless $opt_c or $opt_l or $opt_n or $opt_u;
 508
 509 if ( $opt_c ) {
 510     my $ok = 1;
 511     my @commands = ();
 512
 513     # Get list of commands.
 514     open FH, "./apps/openssl list -1 -commands|"
 515         || die "Can't list commands, $!";
 516     while ( <FH> ) {
 517         chop;
 518         push @commands, $_;
 519     }
 520     close FH;
 521
 522     # See if each has a manpage.
 523     foreach ( @commands ) {
 524         next if $_ eq 'help' || $_ eq 'exit';
 525         if ( ! -f "doc/man1/$_.pod" ) {
 526             print "doc/man1/$_.pod does not exist\n";
 527             $ok = 0;
 528         } else {
 529             $ok = 0 if not &checkflags($_);
 530         }
 531     }
 532
 533     # See what help is missing.
 534     open FH, "./apps/openssl list --missing-help |"
 535         || die "Can't list missing help, $!";
 536     while ( <FH> ) {
 537         chop;
 538         my ($cmd, $flag) = split;
 539         print "$cmd has no help for -$flag\n";
 540         $ok = 0;
 541     }
 542     close FH;
 543
 544     exit 1 if not $ok;
 545 }
 546
 547 if ( $opt_l ) {
 548     foreach (@ARGV ? @ARGV : (glob('doc/*/*.pod'),
 549                               glob('doc/internal/*/*.pod'))) {
 550         collectnames($_);
 551     }
 552     checklinks();
 553 }
 554
 555 if ( $opt_n ) {
 556     &publicize() if $opt_p;
 557     foreach (@ARGV ? @ARGV : glob('doc/*/*.pod')) {
 558         &check($_);
 559     }
 560     {
 561         local $opt_p = undef;
 562         foreach (@ARGV ? @ARGV : glob('doc/internal/*/*.pod')) {
 563             &check($_);
 564         }
 565     }
 566 }
 567
 568 if ( $opt_u ) {
 569     my %temp = getdocced('doc/man3');
 570     foreach ( keys %temp ) {
 571         $docced{$_} = $temp{$_};
 572     }
 573     &printem('crypto', 'util/libcrypto.num');
 574     &printem('ssl', 'util/libssl.num');
 575     &checkmacros();
 576 }
 577
 578 exit;