util/TLSProxy/Proxy.pm

   1 # Copyright 2016 The OpenSSL Project Authors. All Rights Reserved.
   2 #
   3 # Licensed under the OpenSSL license (the "License").  You may not use
   4 # this file except in compliance with the License.  You can obtain a copy
   5 # in the file LICENSE in the source distribution or at
   6 # https://www.openssl.org/source/license.html
   7
   8 use strict;
   9 use POSIX ":sys_wait_h";
  10
  11 package TLSProxy::Proxy;
  12
  13 use File::Spec;
  14 use IO::Socket;
  15 use IO::Select;
  16 use TLSProxy::Record;
  17 use TLSProxy::Message;
  18 use TLSProxy::ClientHello;
  19 use TLSProxy::ServerHello;
  20 use TLSProxy::EncryptedExtensions;
  21 use TLSProxy::Certificate;
  22 use TLSProxy::CertificateVerify;
  23 use TLSProxy::ServerKeyExchange;
  24 use TLSProxy::NewSessionTicket;
  25
  26 my $have_IPv6 = 0;
  27 my $IP_factory;
  28
  29 my $is_tls13 = 0;
  30 my $ciphersuite = undef;
  31
  32 sub new
  33 {
  34     my $class = shift;
  35     my ($filter,
  36         $execute,
  37         $cert,
  38         $debug) = @_;
  39
  40     my $self = {
  41         #Public read/write
  42         proxy_addr => "localhost",
  43         proxy_port => 4453,
  44         server_addr => "localhost",
  45         server_port => 4443,
  46         filter => $filter,
  47         serverflags => "",
  48         clientflags => "",
  49         serverconnects => 1,
  50         serverpid => 0,
  51         reneg => 0,
  52
  53         #Public read
  54         execute => $execute,
  55         cert => $cert,
  56         debug => $debug,
  57         cipherc => "",
  58         ciphers => "AES128-SHA:TLS13-AES-128-GCM-SHA256",
  59         flight => 0,
  60         record_list => [],
  61         message_list => [],
  62     };
  63
  64     # IO::Socket::IP is on the core module list, IO::Socket::INET6 isn't.
  65     # However, IO::Socket::INET6 is older and is said to be more widely
  66     # deployed for the moment, and may have less bugs, so we try the latter
  67     # first, then fall back on the code modules.  Worst case scenario, we
  68     # fall back to IO::Socket::INET, only supports IPv4.
  69     eval {
  70         require IO::Socket::INET6;
  71         my $s = IO::Socket::INET6->new(
  72             LocalAddr => "::1",
  73             LocalPort => 0,
  74             Listen=>1,
  75             );
  76         $s or die "\n";
  77         $s->close();
  78     };
  79     if ($@ eq "") {
  80         $IP_factory = sub { IO::Socket::INET6->new(@_); };
  81         $have_IPv6 = 1;
  82     } else {
  83         eval {
  84             require IO::Socket::IP;
  85             my $s = IO::Socket::IP->new(
  86                 LocalAddr => "::1",
  87                 LocalPort => 0,
  88                 Listen=>1,
  89                 );
  90             $s or die "\n";
  91             $s->close();
  92         };
  93         if ($@ eq "") {
  94             $IP_factory = sub { IO::Socket::IP->new(@_); };
  95             $have_IPv6 = 1;
  96         } else {
  97             $IP_factory = sub { IO::Socket::INET->new(@_); };
  98         }
  99     }
 100
 101     return bless $self, $class;
 102 }
 103
 104 sub clearClient
 105 {
 106     my $self = shift;
 107
 108     $self->{cipherc} = "";
 109     $self->{flight} = 0;
 110     $self->{record_list} = [];
 111     $self->{message_list} = [];
 112     $self->{clientflags} = "";
 113     $is_tls13 = 0;
 114     $ciphersuite = undef;
 115
 116     TLSProxy::Message->clear();
 117     TLSProxy::Record->clear();
 118 }
 119
 120 sub clear
 121 {
 122     my $self = shift;
 123
 124     $self->clearClient;
 125     $self->{ciphers} = "AES128-SHA:TLS13-AES-128-GCM-SHA256";
 126     $self->{serverflags} = "";
 127     $self->{serverconnects} = 1;
 128     $self->{serverpid} = 0;
 129     $self->{reneg} = 0;
 130 }
 131
 132 sub restart
 133 {
 134     my $self = shift;
 135
 136     $self->clear;
 137     $self->start;
 138 }
 139
 140 sub clientrestart
 141 {
 142     my $self = shift;
 143
 144     $self->clear;
 145     $self->clientstart;
 146 }
 147
 148 sub start
 149 {
 150     my ($self) = shift;
 151     my $pid;
 152
 153     $pid = fork();
 154     if ($pid == 0) {
 155         if (!$self->debug) {
 156             open(STDOUT, ">", File::Spec->devnull())
 157                 or die "Failed to redirect stdout: $!";
 158             open(STDERR, ">&STDOUT");
 159         }
 160         my $execcmd = $self->execute
 161             ." s_server -no_comp -rev -engine ossltest -accept "
 162             .($self->server_port)
 163             ." -cert ".$self->cert." -cert2 ".$self->cert
 164             ." -naccept ".$self->serverconnects;
 165         if ($self->ciphers ne "") {
 166             $execcmd .= " -cipher ".$self->ciphers;
 167         }
 168         if ($self->serverflags ne "") {
 169             $execcmd .= " ".$self->serverflags;
 170         }
 171         exec($execcmd);
 172     }
 173     $self->serverpid($pid);
 174
 175     return $self->clientstart;
 176 }
 177
 178 sub clientstart
 179 {
 180     my ($self) = shift;
 181     my $oldstdout;
 182
 183     if(!$self->debug) {
 184         open DEVNULL, ">", File::Spec->devnull();
 185         $oldstdout = select(DEVNULL);
 186     }
 187
 188     # Create the Proxy socket
 189     my $proxaddr = $self->proxy_addr;
 190     $proxaddr =~ s/[\[\]]//g; # Remove [ and ]
 191     my $proxy_sock = $IP_factory->(
 192         LocalHost   => $proxaddr,
 193         LocalPort   => $self->proxy_port,
 194         Proto       => "tcp",
 195         Listen      => SOMAXCONN,
 196         ReuseAddr   => 1
 197     );
 198
 199     if ($proxy_sock) {
 200         print "Proxy started on port ".$self->proxy_port."\n";
 201     } else {
 202         warn "Failed creating proxy socket (".$proxaddr.",".$self->proxy_port."): $!\n";
 203         return 0;
 204     }
 205
 206     if ($self->execute) {
 207         my $pid = fork();
 208         if ($pid == 0) {
 209             if (!$self->debug) {
 210                 open(STDOUT, ">", File::Spec->devnull())
 211                     or die "Failed to redirect stdout: $!";
 212                 open(STDERR, ">&STDOUT");
 213             }
 214             my $echostr;
 215             if ($self->reneg()) {
 216                 $echostr = "R";
 217             } else {
 218                 $echostr = "test";
 219             }
 220             my $execcmd = "echo ".$echostr." | ".$self->execute
 221                  ." s_client -engine ossltest -connect "
 222                  .($self->proxy_addr).":".($self->proxy_port);
 223             if ($self->cipherc ne "") {
 224                 $execcmd .= " -cipher ".$self->cipherc;
 225             }
 226             if ($self->clientflags ne "") {
 227                 $execcmd .= " ".$self->clientflags;
 228             }
 229             exec($execcmd);
 230         }
 231     }
 232
 233     # Wait for incoming connection from client
 234     my $client_sock;
 235     if(!($client_sock = $proxy_sock->accept())) {
 236         warn "Failed accepting incoming connection: $!\n";
 237         return 0;
 238     }
 239
 240     print "Connection opened\n";
 241
 242     # Now connect to the server
 243     my $retry = 3;
 244     my $server_sock;
 245     #We loop over this a few times because sometimes s_server can take a while
 246     #to start up
 247     do {
 248         my $servaddr = $self->server_addr;
 249         $servaddr =~ s/[\[\]]//g; # Remove [ and ]
 250         eval {
 251             $server_sock = $IP_factory->(
 252                 PeerAddr => $servaddr,
 253                 PeerPort => $self->server_port,
 254                 MultiHomed => 1,
 255                 Proto => 'tcp'
 256             );
 257         };
 258
 259         $retry--;
 260         #Some buggy IP factories can return a defined server_sock that hasn't
 261         #actually connected, so we check peerport too
 262         if ($@ || !defined($server_sock) || !defined($server_sock->peerport)) {
 263             $server_sock->close() if defined($server_sock);
 264             undef $server_sock;
 265             if ($retry) {
 266                 #Sleep for a short while
 267                 select(undef, undef, undef, 0.1);
 268             } else {
 269                 warn "Failed to start up server (".$servaddr.",".$self->server_port."): $!\n";
 270                 return 0;
 271             }
 272         }
 273     } while (!$server_sock);
 274
 275     my $sel = IO::Select->new($server_sock, $client_sock);
 276     my $indata;
 277     my @handles = ($server_sock, $client_sock);
 278
 279     #Wait for either the server socket or the client socket to become readable
 280     my @ready;
 281     while(!(TLSProxy::Message->end) && (@ready = $sel->can_read)) {
 282         foreach my $hand (@ready) {
 283             if ($hand == $server_sock) {
 284                 $server_sock->sysread($indata, 16384) or goto END;
 285                 $indata = $self->process_packet(1, $indata);
 286                 $client_sock->syswrite($indata);
 287             } elsif ($hand == $client_sock) {
 288                 $client_sock->sysread($indata, 16384) or goto END;
 289                 $indata = $self->process_packet(0, $indata);
 290                 $server_sock->syswrite($indata);
 291             } else {
 292                 print "Err\n";
 293                 goto END;
 294             }
 295         }
 296     }
 297
 298     END:
 299     print "Connection closed\n";
 300     if($server_sock) {
 301         $server_sock->close();
 302     }
 303     if($client_sock) {
 304         #Closing this also kills the child process
 305         $client_sock->close();
 306     }
 307     if($proxy_sock) {
 308         $proxy_sock->close();
 309     }
 310     if(!$self->debug) {
 311         select($oldstdout);
 312     }
 313     $self->serverconnects($self->serverconnects - 1);
 314     if ($self->serverconnects == 0) {
 315         die "serverpid is zero\n" if $self->serverpid == 0;
 316         print "Waiting for server process to close: "
 317               .$self->serverpid."\n";
 318         waitpid( $self->serverpid, 0);
 319     }
 320     return 1;
 321 }
 322
 323 sub process_packet
 324 {
 325     my ($self, $server, $packet) = @_;
 326     my $len_real;
 327     my $decrypt_len;
 328     my $data;
 329     my $recnum;
 330
 331     if ($server) {
 332         print "Received server packet\n";
 333     } else {
 334         print "Received client packet\n";
 335     }
 336
 337     print "Packet length = ".length($packet)."\n";
 338     print "Processing flight ".$self->flight."\n";
 339
 340     #Return contains the list of record found in the packet followed by the
 341     #list of messages in those records
 342     my @ret = TLSProxy::Record->get_records($server, $self->flight, $packet);
 343     push @{$self->record_list}, @{$ret[0]};
 344     push @{$self->{message_list}}, @{$ret[1]};
 345
 346     print "\n";
 347
 348     #Finished parsing. Call user provided filter here
 349     if(defined $self->filter) {
 350         $self->filter->($self);
 351     }
 352
 353     #Reconstruct the packet
 354     $packet = "";
 355     foreach my $record (@{$self->record_list}) {
 356         #We only replay the records for the current flight
 357         if ($record->flight != $self->flight) {
 358             next;
 359         }
 360         $packet .= $record->reconstruct_record($server);
 361     }
 362
 363     $self->{flight} = $self->{flight} + 1;
 364
 365     print "Forwarded packet length = ".length($packet)."\n\n";
 366
 367     return $packet;
 368 }
 369
 370 #Read accessors
 371 sub execute
 372 {
 373     my $self = shift;
 374     return $self->{execute};
 375 }
 376 sub cert
 377 {
 378     my $self = shift;
 379     return $self->{cert};
 380 }
 381 sub debug
 382 {
 383     my $self = shift;
 384     return $self->{debug};
 385 }
 386 sub flight
 387 {
 388     my $self = shift;
 389     return $self->{flight};
 390 }
 391 sub record_list
 392 {
 393     my $self = shift;
 394     return $self->{record_list};
 395 }
 396 sub success
 397 {
 398     my $self = shift;
 399     return $self->{success};
 400 }
 401 sub end
 402 {
 403     my $self = shift;
 404     return $self->{end};
 405 }
 406 sub supports_IPv6
 407 {
 408     my $self = shift;
 409     return $have_IPv6;
 410 }
 411
 412 #Read/write accessors
 413 sub proxy_addr
 414 {
 415     my $self = shift;
 416     if (@_) {
 417         $self->{proxy_addr} = shift;
 418     }
 419     return $self->{proxy_addr};
 420 }
 421 sub proxy_port
 422 {
 423     my $self = shift;
 424     if (@_) {
 425         $self->{proxy_port} = shift;
 426     }
 427     return $self->{proxy_port};
 428 }
 429 sub server_addr
 430 {
 431     my $self = shift;
 432     if (@_) {
 433         $self->{server_addr} = shift;
 434     }
 435     return $self->{server_addr};
 436 }
 437 sub server_port
 438 {
 439     my $self = shift;
 440     if (@_) {
 441         $self->{server_port} = shift;
 442     }
 443     return $self->{server_port};
 444 }
 445 sub filter
 446 {
 447     my $self = shift;
 448     if (@_) {
 449         $self->{filter} = shift;
 450     }
 451     return $self->{filter};
 452 }
 453 sub cipherc
 454 {
 455     my $self = shift;
 456     if (@_) {
 457         $self->{cipherc} = shift;
 458     }
 459     return $self->{cipherc};
 460 }
 461 sub ciphers
 462 {
 463     my $self = shift;
 464     if (@_) {
 465         $self->{ciphers} = shift;
 466     }
 467     return $self->{ciphers};
 468 }
 469 sub serverflags
 470 {
 471     my $self = shift;
 472     if (@_) {
 473         $self->{serverflags} = shift;
 474     }
 475     return $self->{serverflags};
 476 }
 477 sub clientflags
 478 {
 479     my $self = shift;
 480     if (@_) {
 481         $self->{clientflags} = shift;
 482     }
 483     return $self->{clientflags};
 484 }
 485 sub serverconnects
 486 {
 487     my $self = shift;
 488     if (@_) {
 489         $self->{serverconnects} = shift;
 490     }
 491     return $self->{serverconnects};
 492 }
 493 # This is a bit ugly because the caller is responsible for keeping the records
 494 # in sync with the updated message list; simply updating the message list isn't
 495 # sufficient to get the proxy to forward the new message.
 496 # But it does the trick for the one test (test_sslsessiontick) that needs it.
 497 sub message_list
 498 {
 499     my $self = shift;
 500     if (@_) {
 501         $self->{message_list} = shift;
 502     }
 503     return $self->{message_list};
 504 }
 505 sub serverpid
 506 {
 507     my $self = shift;
 508     if (@_) {
 509         $self->{serverpid} = shift;
 510     }
 511     return $self->{serverpid};
 512 }
 513
 514 sub fill_known_data
 515 {
 516     my $length = shift;
 517     my $ret = "";
 518     for (my $i = 0; $i < $length; $i++) {
 519         $ret .= chr($i);
 520     }
 521     return $ret;
 522 }
 523
 524 sub is_tls13
 525 {
 526     my $class = shift;
 527     if (@_) {
 528         $is_tls13 = shift;
 529     }
 530     return $is_tls13;
 531 }
 532
 533 sub reneg
 534 {
 535     my $self = shift;
 536     if (@_) {
 537         $self->{reneg} = shift;
 538     }
 539     return $self->{reneg};
 540 }
 541
 542 sub ciphersuite
 543 {
 544     my $class = shift;
 545     if (@_) {
 546         $ciphersuite = shift;
 547     }
 548     return $ciphersuite;
 549 }
 550
 551 1;