util/TLSProxy/Message.pm

   1 # Copyright 2016 The OpenSSL Project Authors. All Rights Reserved.
   2 #
   3 # Licensed under the OpenSSL license (the "License").  You may not use
   4 # this file except in compliance with the License.  You can obtain a copy
   5 # in the file LICENSE in the source distribution or at
   6 # https://www.openssl.org/source/license.html
   7
   8 use strict;
   9
  10 package TLSProxy::Message;
  11
  12 use constant TLS_MESSAGE_HEADER_LENGTH => 4;
  13
  14 #Message types
  15 use constant {
  16     MT_HELLO_REQUEST => 0,
  17     MT_CLIENT_HELLO => 1,
  18     MT_SERVER_HELLO => 2,
  19     MT_NEW_SESSION_TICKET => 4,
  20     MT_ENCRYPTED_EXTENSIONS => 8,
  21     MT_CERTIFICATE => 11,
  22     MT_SERVER_KEY_EXCHANGE => 12,
  23     MT_CERTIFICATE_REQUEST => 13,
  24     MT_SERVER_HELLO_DONE => 14,
  25     MT_CERTIFICATE_VERIFY => 15,
  26     MT_CLIENT_KEY_EXCHANGE => 16,
  27     MT_FINISHED => 20,
  28     MT_CERTIFICATE_STATUS => 22,
  29     MT_NEXT_PROTO => 67
  30 };
  31
  32 #Alert levels
  33 use constant {
  34     AL_LEVEL_WARN => 1,
  35     AL_LEVEL_FATAL => 2
  36 };
  37
  38 #Alert descriptions
  39 use constant {
  40     AL_DESC_CLOSE_NOTIFY => 0,
  41     AL_DESC_UNEXPECTED_MESSAGE => 10,
  42     AL_DESC_NO_RENEGOTIATION => 100
  43 };
  44
  45 my %message_type = (
  46     MT_HELLO_REQUEST, "HelloRequest",
  47     MT_CLIENT_HELLO, "ClientHello",
  48     MT_SERVER_HELLO, "ServerHello",
  49     MT_NEW_SESSION_TICKET, "NewSessionTicket",
  50     MT_ENCRYPTED_EXTENSIONS, "EncryptedExtensions",
  51     MT_CERTIFICATE, "Certificate",
  52     MT_SERVER_KEY_EXCHANGE, "ServerKeyExchange",
  53     MT_CERTIFICATE_REQUEST, "CertificateRequest",
  54     MT_SERVER_HELLO_DONE, "ServerHelloDone",
  55     MT_CERTIFICATE_VERIFY, "CertificateVerify",
  56     MT_CLIENT_KEY_EXCHANGE, "ClientKeyExchange",
  57     MT_FINISHED, "Finished",
  58     MT_CERTIFICATE_STATUS, "CertificateStatus",
  59     MT_NEXT_PROTO, "NextProto"
  60 );
  61
  62 use constant {
  63     EXT_SERVER_NAME => 0,
  64     EXT_STATUS_REQUEST => 5,
  65     EXT_SUPPORTED_GROUPS => 10,
  66     EXT_EC_POINT_FORMATS => 11,
  67     EXT_SRP => 12,
  68     EXT_SIG_ALGS => 13,
  69     EXT_USE_SRTP => 14,
  70     EXT_ALPN => 16,
  71     EXT_SCT => 18,
  72     EXT_PADDING => 21,
  73     EXT_ENCRYPT_THEN_MAC => 22,
  74     EXT_EXTENDED_MASTER_SECRET => 23,
  75     EXT_SESSION_TICKET => 35,
  76     EXT_KEY_SHARE => 40,
  77     EXT_SUPPORTED_VERSIONS => 43,
  78     EXT_RENEGOTIATE => 65281,
  79     EXT_NPN => 13172,
  80     # This extension is an unofficial extension only ever written by OpenSSL
  81     # (i.e. not read), and even then only when enabled. We use it to test
  82     # handling of duplicate extensions.
  83     EXT_DUPLICATE_EXTENSION => 0xfde8
  84 };
  85
  86 use constant {
  87     CIPHER_DHE_RSA_AES_128_SHA => 0x0033,
  88     CIPHER_ADH_AES_128_SHA => 0x0034
  89 };
  90
  91 my $payload = "";
  92 my $messlen = -1;
  93 my $mt;
  94 my $startoffset = -1;
  95 my $server = 0;
  96 my $success = 0;
  97 my $end = 0;
  98 my @message_rec_list = ();
  99 my @message_frag_lens = ();
 100 my $ciphersuite = 0;
 101
 102 sub clear
 103 {
 104     $payload = "";
 105     $messlen = -1;
 106     $startoffset = -1;
 107     $server = 0;
 108     $success = 0;
 109     $end = 0;
 110     @message_rec_list = ();
 111     @message_frag_lens = ();
 112 }
 113
 114 #Class method to extract messages from a record
 115 sub get_messages
 116 {
 117     my $class = shift;
 118     my $serverin = shift;
 119     my $record = shift;
 120     my @messages = ();
 121     my $message;
 122
 123     @message_frag_lens = ();
 124
 125     if ($serverin != $server && length($payload) != 0) {
 126         die "Changed peer, but we still have fragment data\n";
 127     }
 128     $server = $serverin;
 129
 130     if ($record->content_type == TLSProxy::Record::RT_CCS) {
 131         if ($payload ne "") {
 132             #We can't handle this yet
 133             die "CCS received before message data complete\n";
 134         }
 135         if ($server) {
 136             TLSProxy::Record->server_encrypting(1);
 137         } else {
 138             TLSProxy::Record->client_encrypting(1);
 139         }
 140     } elsif ($record->content_type == TLSProxy::Record::RT_HANDSHAKE) {
 141         if ($record->len == 0 || $record->len_real == 0) {
 142             print "  Message truncated\n";
 143         } else {
 144             my $recoffset = 0;
 145
 146             if (length $payload > 0) {
 147                 #We are continuing processing a message started in a previous
 148                 #record. Add this record to the list associated with this
 149                 #message
 150                 push @message_rec_list, $record;
 151
 152                 if ($messlen <= length($payload)) {
 153                     #Shouldn't happen
 154                     die "Internal error: invalid messlen: ".$messlen
 155                         ." payload length:".length($payload)."\n";
 156                 }
 157                 if (length($payload) + $record->decrypt_len >= $messlen) {
 158                     #We can complete the message with this record
 159                     $recoffset = $messlen - length($payload);
 160                     $payload .= substr($record->decrypt_data, 0, $recoffset);
 161                     push @message_frag_lens, $recoffset;
 162                     $message = create_message($server, $mt, $payload,
 163                                               $startoffset);
 164                     push @messages, $message;
 165
 166                     $payload = "";
 167                 } else {
 168                     #This is just part of the total message
 169                     $payload .= $record->decrypt_data;
 170                     $recoffset = $record->decrypt_len;
 171                     push @message_frag_lens, $record->decrypt_len;
 172                 }
 173                 print "  Partial message data read: ".$recoffset." bytes\n";
 174             }
 175
 176             while ($record->decrypt_len > $recoffset) {
 177                 #We are at the start of a new message
 178                 if ($record->decrypt_len - $recoffset < 4) {
 179                     #Whilst technically probably valid we can't cope with this
 180                     die "End of record in the middle of a message header\n";
 181                 }
 182                 @message_rec_list = ($record);
 183                 my $lenhi;
 184                 my $lenlo;
 185                 ($mt, $lenhi, $lenlo) = unpack('CnC',
 186                                                substr($record->decrypt_data,
 187                                                       $recoffset));
 188                 $messlen = ($lenhi << 8) | $lenlo;
 189                 print "  Message type: $message_type{$mt}\n";
 190                 print "  Message Length: $messlen\n";
 191                 $startoffset = $recoffset;
 192                 $recoffset += 4;
 193                 $payload = "";
 194
 195                 if ($recoffset <= $record->decrypt_len) {
 196                     #Some payload data is present in this record
 197                     if ($record->decrypt_len - $recoffset >= $messlen) {
 198                         #We can complete the message with this record
 199                         $payload .= substr($record->decrypt_data, $recoffset,
 200                                            $messlen);
 201                         $recoffset += $messlen;
 202                         push @message_frag_lens, $messlen;
 203                         $message = create_message($server, $mt, $payload,
 204                                                   $startoffset);
 205                         push @messages, $message;
 206
 207                         $payload = "";
 208                     } else {
 209                         #This is just part of the total message
 210                         $payload .= substr($record->decrypt_data, $recoffset,
 211                                            $record->decrypt_len - $recoffset);
 212                         $recoffset = $record->decrypt_len;
 213                         push @message_frag_lens, $recoffset;
 214                     }
 215                 }
 216             }
 217         }
 218     } elsif ($record->content_type == TLSProxy::Record::RT_APPLICATION_DATA) {
 219         print "  [ENCRYPTED APPLICATION DATA]\n";
 220         print "  [".$record->decrypt_data."]\n";
 221     } elsif ($record->content_type == TLSProxy::Record::RT_ALERT) {
 222         my ($alertlev, $alertdesc) = unpack('CC', $record->decrypt_data);
 223         #A CloseNotify from the client indicates we have finished successfully
 224         #(we assume)
 225         if (!$end && !$server && $alertlev == AL_LEVEL_WARN
 226             && $alertdesc == AL_DESC_CLOSE_NOTIFY) {
 227             $success = 1;
 228         }
 229         #All alerts end the test
 230         $end = 1;
 231     }
 232
 233     return @messages;
 234 }
 235
 236 #Function to work out which sub-class we need to create and then
 237 #construct it
 238 sub create_message
 239 {
 240     my ($server, $mt, $data, $startoffset) = @_;
 241     my $message;
 242
 243     #We only support ClientHello in this version...needs to be extended for
 244     #others
 245     if ($mt == MT_CLIENT_HELLO) {
 246         $message = TLSProxy::ClientHello->new(
 247             $server,
 248             $data,
 249             [@message_rec_list],
 250             $startoffset,
 251             [@message_frag_lens]
 252         );
 253         $message->parse();
 254     } elsif ($mt == MT_SERVER_HELLO) {
 255         $message = TLSProxy::ServerHello->new(
 256             $server,
 257             $data,
 258             [@message_rec_list],
 259             $startoffset,
 260             [@message_frag_lens]
 261         );
 262         $message->parse();
 263     } elsif ($mt == MT_ENCRYPTED_EXTENSIONS) {
 264         $message = TLSProxy::EncryptedExtensions->new(
 265             $server,
 266             $data,
 267             [@message_rec_list],
 268             $startoffset,
 269             [@message_frag_lens]
 270         );
 271         $message->parse();
 272     } elsif ($mt == MT_CERTIFICATE) {
 273         $message = TLSProxy::Certificate->new(
 274             $server,
 275             $data,
 276             [@message_rec_list],
 277             $startoffset,
 278             [@message_frag_lens]
 279         );
 280         $message->parse();
 281     } elsif ($mt == MT_CERTIFICATE_VERIFY) {
 282         $message = TLSProxy::CertificateVerify->new(
 283             $server,
 284             $data,
 285             [@message_rec_list],
 286             $startoffset,
 287             [@message_frag_lens]
 288         );
 289         $message->parse();
 290     } elsif ($mt == MT_SERVER_KEY_EXCHANGE) {
 291         $message = TLSProxy::ServerKeyExchange->new(
 292             $server,
 293             $data,
 294             [@message_rec_list],
 295             $startoffset,
 296             [@message_frag_lens]
 297         );
 298         $message->parse();
 299     } elsif ($mt == MT_NEW_SESSION_TICKET) {
 300         $message = TLSProxy::NewSessionTicket->new(
 301             $server,
 302             $data,
 303             [@message_rec_list],
 304             $startoffset,
 305             [@message_frag_lens]
 306         );
 307         $message->parse();
 308     } else {
 309         #Unknown message type
 310         $message = TLSProxy::Message->new(
 311             $server,
 312             $mt,
 313             $data,
 314             [@message_rec_list],
 315             $startoffset,
 316             [@message_frag_lens]
 317         );
 318     }
 319
 320     return $message;
 321 }
 322
 323 sub end
 324 {
 325     my $class = shift;
 326     return $end;
 327 }
 328 sub success
 329 {
 330     my $class = shift;
 331     return $success;
 332 }
 333 sub fail
 334 {
 335     my $class = shift;
 336     return !$success && $end;
 337 }
 338 sub new
 339 {
 340     my $class = shift;
 341     my ($server,
 342         $mt,
 343         $data,
 344         $records,
 345         $startoffset,
 346         $message_frag_lens) = @_;
 347
 348     my $self = {
 349         server => $server,
 350         data => $data,
 351         records => $records,
 352         mt => $mt,
 353         startoffset => $startoffset,
 354         message_frag_lens => $message_frag_lens
 355     };
 356
 357     return bless $self, $class;
 358 }
 359
 360 sub ciphersuite
 361 {
 362     my $class = shift;
 363     if (@_) {
 364       $ciphersuite = shift;
 365     }
 366     return $ciphersuite;
 367 }
 368
 369 #Update all the underlying records with the modified data from this message
 370 #Note: Only supports re-encrypting for TLSv1.3
 371 sub repack
 372 {
 373     my $self = shift;
 374     my $msgdata;
 375
 376     my $numrecs = $#{$self->records};
 377
 378     $self->set_message_contents();
 379
 380     my $lenhi;
 381     my $lenlo;
 382
 383     $lenlo = length($self->data) & 0xff;
 384     $lenhi = length($self->data) >> 8;
 385     $msgdata = pack('CnC', $self->mt, $lenhi, $lenlo).$self->data;
 386
 387     if ($numrecs == 0) {
 388         #The message is fully contained within one record
 389         my ($rec) = @{$self->records};
 390         my $recdata = $rec->decrypt_data;
 391
 392         my $old_length;
 393
 394         # We use empty message_frag_lens to indicates that pre-repacking,
 395         # the message wasn't present. The first fragment length doesn't include
 396         # the TLS header, so we need to check and compute the right length.
 397         if (@{$self->message_frag_lens}) {
 398             $old_length = ${$self->message_frag_lens}[0] +
 399               TLS_MESSAGE_HEADER_LENGTH;
 400         } else {
 401             $old_length = 0;
 402         }
 403
 404         my $prefix = substr($recdata, 0, $self->startoffset);
 405         my $suffix = substr($recdata, $self->startoffset + $old_length);
 406
 407         $rec->decrypt_data($prefix.($msgdata).($suffix));
 408         # TODO(openssl-team): don't keep explicit lengths.
 409         # (If a length override is ever needed to construct invalid packets,
 410         #  use an explicit override field instead.)
 411         $rec->decrypt_len(length($rec->decrypt_data));
 412         $rec->len($rec->len + length($msgdata) - $old_length);
 413         # Only support re-encryption for TLSv1.3.
 414         if (TLSProxy::Proxy->is_tls13() && $rec->encrypted()) {
 415             #Add content type (1 byte) and 16 tag bytes
 416             $rec->data($rec->decrypt_data
 417                 .pack("C", TLSProxy::Record::RT_HANDSHAKE).("\0"x16));
 418         } else {
 419             $rec->data($rec->decrypt_data);
 420         }
 421
 422         #Update the fragment len in case we changed it above
 423         ${$self->message_frag_lens}[0] = length($msgdata)
 424                                          - TLS_MESSAGE_HEADER_LENGTH;
 425         return;
 426     }
 427
 428     #Note we don't currently support changing a fragmented message length
 429     my $recctr = 0;
 430     my $datadone = 0;
 431     foreach my $rec (@{$self->records}) {
 432         my $recdata = $rec->decrypt_data;
 433         if ($recctr == 0) {
 434             #This is the first record
 435             my $remainlen = length($recdata) - $self->startoffset;
 436             $rec->data(substr($recdata, 0, $self->startoffset)
 437                        .substr(($msgdata), 0, $remainlen));
 438             $datadone += $remainlen;
 439         } elsif ($recctr + 1 == $numrecs) {
 440             #This is the last record
 441             $rec->data(substr($msgdata, $datadone));
 442         } else {
 443             #This is a middle record
 444             $rec->data(substr($msgdata, $datadone, length($rec->data)));
 445             $datadone += length($rec->data);
 446         }
 447         $recctr++;
 448     }
 449 }
 450
 451 #To be overridden by sub-classes
 452 sub set_message_contents
 453 {
 454 }
 455
 456 #Read only accessors
 457 sub server
 458 {
 459     my $self = shift;
 460     return $self->{server};
 461 }
 462
 463 #Read/write accessors
 464 sub mt
 465 {
 466     my $self = shift;
 467     if (@_) {
 468       $self->{mt} = shift;
 469     }
 470     return $self->{mt};
 471 }
 472 sub data
 473 {
 474     my $self = shift;
 475     if (@_) {
 476       $self->{data} = shift;
 477     }
 478     return $self->{data};
 479 }
 480 sub records
 481 {
 482     my $self = shift;
 483     if (@_) {
 484       $self->{records} = shift;
 485     }
 486     return $self->{records};
 487 }
 488 sub startoffset
 489 {
 490     my $self = shift;
 491     if (@_) {
 492       $self->{startoffset} = shift;
 493     }
 494     return $self->{startoffset};
 495 }
 496 sub message_frag_lens
 497 {
 498     my $self = shift;
 499     if (@_) {
 500       $self->{message_frag_lens} = shift;
 501     }
 502     return $self->{message_frag_lens};
 503 }
 504 sub encoded_length
 505 {
 506     my $self = shift;
 507     return TLS_MESSAGE_HEADER_LENGTH + length($self->data);
 508 }
 509
 510 1;