util/TLSProxy/HelloRetryRequest.pm

   1 # Copyright 2016 The OpenSSL Project Authors. All Rights Reserved.
   2 #
   3 # Licensed under the OpenSSL license (the "License").  You may not use
   4 # this file except in compliance with the License.  You can obtain a copy
   5 # in the file LICENSE in the source distribution or at
   6 # https://www.openssl.org/source/license.html
   7
   8 use strict;
   9
  10 package TLSProxy::HelloRetryRequest;
  11
  12 use vars '@ISA';
  13 push @ISA, 'TLSProxy::Message';
  14
  15 sub new
  16 {
  17     my $class = shift;
  18     my ($server,
  19         $data,
  20         $records,
  21         $startoffset,
  22         $message_frag_lens) = @_;
  23
  24     my $self = $class->SUPER::new(
  25         $server,
  26         TLSProxy::Message::MT_HELLO_RETRY_REQUEST,
  27         $data,
  28         $records,
  29         $startoffset,
  30         $message_frag_lens);
  31
  32     $self->{extension_data} = "";
  33
  34     return $self;
  35 }
  36
  37 sub parse
  38 {
  39     my $self = shift;
  40     my $ptr = 2;
  41
  42     TLSProxy::Proxy->is_tls13(1);
  43
  44     my ($server_version) = unpack('n', $self->data);
  45     # TODO(TLS1.3): Replace this reference to draft version before release
  46     if ($server_version == TLSProxy::Record::VERS_TLS_1_3_DRAFT) {
  47         $server_version = TLSProxy::Record::VERS_TLS_1_3;
  48     }
  49
  50     my $extensions_len = unpack('n', substr($self->data, $ptr));
  51     if (!defined $extensions_len) {
  52         $extensions_len = 0;
  53     }
  54
  55     $ptr += 2;
  56     my $extension_data;
  57     if ($extensions_len != 0) {
  58         $extension_data = substr($self->data, $ptr);
  59
  60         if (length($extension_data) != $extensions_len) {
  61             die "Invalid extension length\n";
  62         }
  63     } else {
  64         if (length($self->data) != 2) {
  65             die "Invalid extension length\n";
  66         }
  67         $extension_data = "";
  68     }
  69     my %extensions = ();
  70     while (length($extension_data) >= 4) {
  71         my ($type, $size) = unpack("nn", $extension_data);
  72         my $extdata = substr($extension_data, 4, $size);
  73         $extension_data = substr($extension_data, 4 + $size);
  74         $extensions{$type} = $extdata;
  75     }
  76
  77     $self->server_version($server_version);
  78     $self->extension_data(\%extensions);
  79
  80     print "    Extensions Len:".$extensions_len."\n";
  81 }
  82
  83 #Reconstruct the on-the-wire message data following changes
  84 sub set_message_contents
  85 {
  86     my $self = shift;
  87     my $data;
  88     my $extensions = "";
  89
  90     foreach my $key (keys %{$self->extension_data}) {
  91         my $extdata = ${$self->extension_data}{$key};
  92         $extensions .= pack("n", $key);
  93         $extensions .= pack("n", length($extdata));
  94         $extensions .= $extdata;
  95         if ($key == TLSProxy::Message::EXT_DUPLICATE_EXTENSION) {
  96             $extensions .= pack("n", $key);
  97             $extensions .= pack("n", length($extdata));
  98             $extensions .= $extdata;
  99         }
 100     }
 101
 102     $data = pack('n', $self->server_version);
 103     $data .= pack('n', length($extensions));
 104     $data .= $extensions;
 105     $self->data($data);
 106 }
 107
 108 #Read/write accessors
 109 sub server_version
 110 {
 111     my $self = shift;
 112     if (@_) {
 113       $self->{server_version} = shift;
 114     }
 115     return $self->{server_version};
 116 }
 117 sub extension_data
 118 {
 119     my $self = shift;
 120     if (@_) {
 121         $self->{extension_data} = shift;
 122     }
 123     return $self->{extension_data};
 124 }
 125 sub set_extension
 126 {
 127     my ($self, $ext_type, $ext_data) = @_;
 128     $self->{extension_data}{$ext_type} = $ext_data;
 129 }
 130 sub delete_extension
 131 {
 132     my ($self, $ext_type) = @_;
 133     delete $self->{extension_data}{$ext_type};
 134 }
 135 1;