test/recipes/80-test_ssl_new.t

   1 #! /usr/bin/env perl
   2 # Copyright 2015-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9
  10 use strict;
  11 use warnings;
  12
  13 use File::Basename;
  14 use File::Compare qw/compare_text/;
  15
  16 use OpenSSL::Test qw/:DEFAULT srctop_dir srctop_file/;
  17 use OpenSSL::Test::Utils qw/disabled alldisabled available_protocols/;
  18
  19 setup("test_ssl_new");
  20
  21 $ENV{TEST_CERTS_DIR} = srctop_dir("test", "certs");
  22
  23 my @conf_srcs =  glob('"'.srctop_file("test", "ssl-tests", "*.conf.in").'"');
  24 map { s/;.*// } @conf_srcs if $^O eq "VMS";
  25 my @conf_files = map { basename($_) } @conf_srcs;
  26 map { s/\.in// } @conf_files;
  27
  28 # 02-protocol-version.conf test results depend on the configuration of enabled
  29 # protocols. We only verify generated sources in the default configuration.
  30 my $is_default = (disabled("ssl3") && !disabled("tls1") &&
  31                   !disabled("tls1_1") && !disabled("tls1_2"));
  32
  33 my %conf_dependent_tests = ("02-protocol-version.conf" => 1);
  34
  35 foreach my $conf (@conf_files) {
  36     subtest "Test configuration $conf" => sub {
  37         test_conf($conf,
  38                   $conf_dependent_tests{$conf} || $^O eq "VMS" ?  0 : 1);
  39     }
  40 }
  41
  42 # We hard-code the number of tests to double-check that the globbing above
  43 # finds all files as expected.
  44 plan tests => 3;  # = scalar @conf_srcs
  45
  46 sub test_conf {
  47     plan tests => 3;
  48
  49     my ($conf, $check_source) = @_;
  50
  51     my $conf_file = srctop_file("test", "ssl-tests", $conf);
  52     my $tmp_file = "${conf}.$$.tmp";
  53     my $run_test = 1;
  54
  55   SKIP: {
  56       # "Test" 1. Generate the source.
  57       my $input_file = $conf_file . ".in";
  58
  59       skip 'failure', 2 unless
  60         ok(run(perltest(["generate_ssl_tests.pl", $input_file],
  61                         interpreter_args => [ "-I", srctop_dir("test", "testlib")],
  62                         stdout => $tmp_file)),
  63            "Getting output from generate_ssl_tests.pl.");
  64
  65     SKIP: {
  66         # Test 2. Compare against existing output in test/ssl_tests.conf.
  67         skip "Skipping generated source test for $conf", 1
  68           if !$check_source;
  69
  70         $run_test = is(cmp_text($tmp_file, $conf_file), 0,
  71                        "Comparing generated sources.");
  72       }
  73
  74       # Test 3. Run the test.
  75       my $no_tls = alldisabled(available_protocols("tls"));
  76       skip "No TLS tests available; skipping tests", 1 if $no_tls;
  77       skip "Stale sources; skipping tests", 1 if !$run_test;
  78
  79       ok(run(test(["ssl_test", $tmp_file])), "running ssl_test $conf");
  80     }
  81
  82     unlink glob $tmp_file;
  83 }
  84
  85 sub cmp_text {
  86     return compare_text(@_, sub {
  87         $_[0] =~ s/\R//g;
  88         $_[1] =~ s/\R//g;
  89         return $_[0] ne $_[1];
  90     });
  91 }