In 80-test_ssl_new, more "plan tests" to a more useful position
[openssl.git] / test / recipes / 80-test_ssl_new.t
1 #! /usr/bin/env perl
2 # Copyright 2015-2016 The OpenSSL Project Authors. All Rights Reserved.
3 #
4 # Licensed under the OpenSSL license (the "License").  You may not use
5 # this file except in compliance with the License.  You can obtain a copy
6 # in the file LICENSE in the source distribution or at
7 # https://www.openssl.org/source/license.html
8
9
10 use strict;
11 use warnings;
12
13 use File::Basename;
14 use File::Compare qw/compare_text/;
15 use if $^O ne "VMS", 'File::Glob' => qw/glob/;
16
17 use OpenSSL::Test qw/:DEFAULT srctop_dir srctop_file/;
18 use OpenSSL::Test::Utils qw/disabled alldisabled available_protocols/;
19
20 setup("test_ssl_new");
21
22 $ENV{TEST_CERTS_DIR} = srctop_dir("test", "certs");
23
24 my @conf_srcs =  glob(srctop_file("test", "ssl-tests", "*.conf.in"));
25 map { s/;.*// } @conf_srcs if $^O eq "VMS";
26 my @conf_files = map { basename($_) } @conf_srcs;
27 map { s/\.in// } @conf_files;
28
29 # We hard-code the number of tests to double-check that the globbing above
30 # finds all files as expected.
31 plan tests => 11;  # = scalar @conf_srcs
32
33 # Some test results depend on the configuration of enabled protocols. We only
34 # verify generated sources in the default configuration.
35 my $is_default_tls = (disabled("ssl3") && !disabled("tls1") &&
36                       !disabled("tls1_1") && !disabled("tls1_2"));
37
38 my $is_default_dtls = (!disabled("dtls1") && !disabled("dtls1_2"));
39
40 my $no_tls = alldisabled(available_protocols("tls"));
41 my $no_dtls = alldisabled(available_protocols("dtls"));
42 my $no_npn = disabled("nextprotoneg");
43
44 my %conf_dependent_tests = (
45   "02-protocol-version.conf" => !$is_default_tls,
46   "04-client_auth.conf" => !$is_default_tls,
47   "07-dtls-protocol-version.conf" => !$is_default_dtls,
48   "10-resumption.conf" => !$is_default_tls,
49   "11-dtls_resumption.conf" => !$is_default_dtls,
50 );
51
52 # Default is $no_tls but some tests have different skip conditions.
53 my %skip = (
54   "07-dtls-protocol-version.conf" => $no_dtls,
55   "08-npn.conf" => $no_tls || $no_npn,
56   "09-alpn.conf" => $no_tls || $no_npn,
57   "10-resumption.conf" => disabled("tls1_1") || disabled("tls1_2"),
58   "11-dtls_resumption.conf" => disabled("dtls1") || disabled("dtls1_2"),
59 );
60
61 foreach my $conf (@conf_files) {
62     subtest "Test configuration $conf" => sub {
63         test_conf($conf,
64                   $conf_dependent_tests{$conf} || $^O eq "VMS" ?  0 : 1,
65                   $skip{$conf} || $no_tls);
66     }
67 }
68
69 sub test_conf {
70     plan tests => 3;
71
72     my ($conf, $check_source, $skip) = @_;
73
74     my $conf_file = srctop_file("test", "ssl-tests", $conf);
75     my $tmp_file = "${conf}.$$.tmp";
76     my $run_test = 1;
77
78   SKIP: {
79       # "Test" 1. Generate the source.
80       my $input_file = $conf_file . ".in";
81
82       skip 'failure', 2 unless
83         ok(run(perltest(["generate_ssl_tests.pl", $input_file],
84                         interpreter_args => [ "-I", srctop_dir("test", "testlib")],
85                         stdout => $tmp_file)),
86            "Getting output from generate_ssl_tests.pl.");
87
88     SKIP: {
89         # Test 2. Compare against existing output in test/ssl_tests.conf.
90         skip "Skipping generated source test for $conf", 1
91           if !$check_source;
92
93         $run_test = is(cmp_text($tmp_file, $conf_file), 0,
94                        "Comparing generated sources.");
95       }
96
97       # Test 3. Run the test.
98       skip "No tests available; skipping tests", 1 if $skip;
99       skip "Stale sources; skipping tests", 1 if !$run_test;
100
101       ok(run(test(["ssl_test", $tmp_file])), "running ssl_test $conf");
102     }
103
104     unlink glob $tmp_file;
105 }
106
107 sub cmp_text {
108     return compare_text(@_, sub {
109         $_[0] =~ s/\R//g;
110         $_[1] =~ s/\R//g;
111         return $_[0] ne $_[1];
112     });
113 }