Add TLS 1.3 certificate selection tests.
[openssl.git] / test / recipes / 80-test_ssl_new.t
1 #! /usr/bin/env perl
2 # Copyright 2015-2016 The OpenSSL Project Authors. All Rights Reserved.
3 #
4 # Licensed under the OpenSSL license (the "License").  You may not use
5 # this file except in compliance with the License.  You can obtain a copy
6 # in the file LICENSE in the source distribution or at
7 # https://www.openssl.org/source/license.html
8
9
10 use strict;
11 use warnings;
12
13 use File::Basename;
14 use File::Compare qw/compare_text/;
15 use if $^O ne "VMS", 'File::Glob' => qw/glob/;
16
17 use OpenSSL::Test qw/:DEFAULT srctop_dir srctop_file/;
18 use OpenSSL::Test::Utils qw/disabled alldisabled available_protocols/;
19
20 setup("test_ssl_new");
21
22 $ENV{TEST_CERTS_DIR} = srctop_dir("test", "certs");
23 $ENV{CTLOG_FILE} = srctop_file("test", "ct", "log_list.conf");
24
25 my @conf_srcs =  glob(srctop_file("test", "ssl-tests", "*.conf.in"));
26 map { s/;.*// } @conf_srcs if $^O eq "VMS";
27 my @conf_files = map { basename($_) } @conf_srcs;
28 map { s/\.in// } @conf_files;
29
30 # We hard-code the number of tests to double-check that the globbing above
31 # finds all files as expected.
32 plan tests => 20;  # = scalar @conf_srcs
33
34 # Some test results depend on the configuration of enabled protocols. We only
35 # verify generated sources in the default configuration.
36 my $is_default_tls = (disabled("ssl3") && !disabled("tls1") &&
37                       !disabled("tls1_1") && !disabled("tls1_2") &&
38                       disabled("tls1_3"));
39
40 my $is_default_dtls = (!disabled("dtls1") && !disabled("dtls1_2"));
41
42 my @all_pre_tls1_3 = ("ssl3", "tls1", "tls1_1", "tls1_2");
43 my $no_tls = alldisabled(available_protocols("tls"));
44 my $no_pre_tls1_3 = alldisabled(@all_pre_tls1_3);
45 my $no_dtls = alldisabled(available_protocols("dtls"));
46 my $no_npn = disabled("nextprotoneg");
47 my $no_ct = disabled("ct");
48 my $no_ec = disabled("ec");
49 my $no_ec2m = disabled("ec2m");
50 my $no_ocsp = disabled("ocsp");
51
52 # Add your test here if the test conf.in generates test cases and/or
53 # expectations dynamically based on the OpenSSL compile-time config.
54 my %conf_dependent_tests = (
55   "02-protocol-version.conf" => !$is_default_tls,
56   "04-client_auth.conf" => !$is_default_tls,
57   "07-dtls-protocol-version.conf" => !$is_default_dtls,
58   "10-resumption.conf" => !$is_default_tls,
59   "11-dtls_resumption.conf" => !$is_default_dtls,
60   "19-mac-then-encrypt.conf" => !$is_default_tls,
61   "20-cert-select.conf" => !$is_default_tls,
62 );
63
64 # Add your test here if it should be skipped for some compile-time
65 # configurations. Default is $no_tls but some tests have different skip
66 # conditions.
67 my %skip = (
68   "07-dtls-protocol-version.conf" => $no_dtls,
69   "08-npn.conf" => (disabled("tls1") && disabled("tls1_1")
70                     && disabled("tls1_2")) || $no_npn,
71   "10-resumption.conf" => disabled("tls1_1") || disabled("tls1_2"),
72   "11-dtls_resumption.conf" => disabled("dtls1") || disabled("dtls1_2"),
73   "12-ct.conf" => $no_tls || $no_ct || $no_ec,
74   # We could run some of these tests without TLS 1.2 if we had a per-test
75   # disable instruction but that's a bizarre configuration not worth
76   # special-casing for.
77   # We should review this once we have TLS 1.3.
78   "13-fragmentation.conf" => disabled("tls1_2"),
79   "14-curves.conf" => disabled("tls1_2") || $no_ec || $no_ec2m,
80   "15-certstatus.conf" => $no_tls || $no_ocsp,
81   "16-dtls-certstatus.conf" => $no_dtls || $no_ocsp,
82   "18-dtls-renegotiate.conf" => $no_dtls,
83   "19-mac-then-encrypt.conf" => $no_pre_tls1_3,
84   "20-cert-select.conf" => disabled("tls1_2") || $no_ec,
85 );
86
87 foreach my $conf (@conf_files) {
88     subtest "Test configuration $conf" => sub {
89         test_conf($conf,
90                   $conf_dependent_tests{$conf} || $^O eq "VMS" ?  0 : 1,
91                   defined($skip{$conf}) ? $skip{$conf} : $no_tls);
92     }
93 }
94
95 sub test_conf {
96     plan tests => 3;
97
98     my ($conf, $check_source, $skip) = @_;
99
100     my $conf_file = srctop_file("test", "ssl-tests", $conf);
101     my $tmp_file = "${conf}.$$.tmp";
102     my $run_test = 1;
103
104   SKIP: {
105       # "Test" 1. Generate the source.
106       my $input_file = $conf_file . ".in";
107
108       skip 'failure', 2 unless
109         ok(run(perltest(["generate_ssl_tests.pl", $input_file],
110                         interpreter_args => [ "-I", srctop_dir("test", "testlib")],
111                         stdout => $tmp_file)),
112            "Getting output from generate_ssl_tests.pl.");
113
114     SKIP: {
115         # Test 2. Compare against existing output in test/ssl_tests.conf.
116         skip "Skipping generated source test for $conf", 1
117           if !$check_source;
118
119         $run_test = is(cmp_text($tmp_file, $conf_file), 0,
120                        "Comparing generated sources.");
121       }
122
123       # Test 3. Run the test.
124       skip "No tests available; skipping tests", 1 if $skip;
125       skip "Stale sources; skipping tests", 1 if !$run_test;
126
127       ok(run(test(["ssl_test", $tmp_file])), "running ssl_test $conf");
128     }
129
130     unlink glob $tmp_file;
131 }
132
133 sub cmp_text {
134     return compare_text(@_, sub {
135         $_[0] =~ s/\R//g;
136         $_[1] =~ s/\R//g;
137         return $_[0] ne $_[1];
138     });
139 }